test/recipes/80-test_ssl_new.t

   1 #! /usr/bin/env perl
   2 # Copyright 2015-2018 The OpenSSL Project Authors. All Rights Reserved.
   3 #
   4 # Licensed under the OpenSSL license (the "License").  You may not use
   5 # this file except in compliance with the License.  You can obtain a copy
   6 # in the file LICENSE in the source distribution or at
   7 # https://www.openssl.org/source/license.html
   8
   9
  10 use strict;
  11 use warnings;
  12
  13 use File::Basename;
  14 use File::Compare qw/compare_text/;
  15 use OpenSSL::Glob;
  16 use OpenSSL::Test qw/:DEFAULT srctop_dir srctop_file/;
  17 use OpenSSL::Test::Utils qw/disabled alldisabled available_protocols/;
  18
  19 setup("test_ssl_new");
  20
  21 $ENV{TEST_CERTS_DIR} = srctop_dir("test", "certs");
  22 $ENV{CTLOG_FILE} = srctop_file("test", "ct", "log_list.conf");
  23
  24 my @conf_srcs =  glob(srctop_file("test", "ssl-tests", "*.conf.in"));
  25 map { s/;.*// } @conf_srcs if $^O eq "VMS";
  26 my @conf_files = map { basename($_, ".in") } @conf_srcs;
  27 map { s/\^// } @conf_files if $^O eq "VMS";
  28
  29 # We hard-code the number of tests to double-check that the globbing above
  30 # finds all files as expected.
  31 plan tests => 26;  # = scalar @conf_srcs
  32
  33 # Some test results depend on the configuration of enabled protocols. We only
  34 # verify generated sources in the default configuration.
  35 my $is_default_tls = (disabled("ssl3") && !disabled("tls1") &&
  36                       !disabled("tls1_1") && !disabled("tls1_2") &&
  37                       !disabled("tls1_3"));
  38
  39 my $is_default_dtls = (!disabled("dtls1") && !disabled("dtls1_2"));
  40
  41 my @all_pre_tls1_3 = ("ssl3", "tls1", "tls1_1", "tls1_2");
  42 my $no_tls = alldisabled(available_protocols("tls"));
  43 my $no_tls_below1_3 = $no_tls || (disabled("tls1_2") && !disabled("tls1_3"));
  44 my $no_pre_tls1_3 = alldisabled(@all_pre_tls1_3);
  45 my $no_dtls = alldisabled(available_protocols("dtls"));
  46 my $no_npn = disabled("nextprotoneg");
  47 my $no_ct = disabled("ct");
  48 my $no_ec = disabled("ec");
  49 my $no_dh = disabled("dh");
  50 my $no_dsa = disabled("dsa");
  51 my $no_ec2m = disabled("ec2m");
  52 my $no_ocsp = disabled("ocsp");
  53
  54 # Add your test here if the test conf.in generates test cases and/or
  55 # expectations dynamically based on the OpenSSL compile-time config.
  56 my %conf_dependent_tests = (
  57   "02-protocol-version.conf" => !$is_default_tls,
  58   "04-client_auth.conf" => !$is_default_tls || !$is_default_dtls
  59                            || !disabled("sctp"),
  60   "05-sni.conf" => disabled("tls1_1"),
  61   "07-dtls-protocol-version.conf" => !$is_default_dtls || !disabled("sctp"),
  62   "10-resumption.conf" => !$is_default_tls,
  63   "11-dtls_resumption.conf" => !$is_default_dtls || !disabled("sctp"),
  64   "16-dtls-certstatus.conf" => !$is_default_dtls || !disabled("sctp"),
  65   "17-renegotiate.conf" => disabled("tls1_2"),
  66   "18-dtls-renegotiate.conf" => disabled("dtls1_2") || !disabled("sctp"),
  67   "19-mac-then-encrypt.conf" => !$is_default_tls,
  68   "20-cert-select.conf" => !$is_default_tls || $no_dh || $no_dsa,
  69   "22-compression.conf" => !$is_default_tls,
  70   "25-cipher.conf" => disabled("poly1305") || disabled("chacha"),
  71 );
  72
  73 # Add your test here if it should be skipped for some compile-time
  74 # configurations. Default is $no_tls but some tests have different skip
  75 # conditions.
  76 my %skip = (
  77   "06-sni-ticket.conf" => $no_tls_below1_3,
  78   "07-dtls-protocol-version.conf" => $no_dtls,
  79   "08-npn.conf" => (disabled("tls1") && disabled("tls1_1")
  80                     && disabled("tls1_2")) || $no_npn,
  81   "10-resumption.conf" => disabled("tls1_1") || disabled("tls1_2"),
  82   "11-dtls_resumption.conf" => disabled("dtls1") || disabled("dtls1_2"),
  83   "12-ct.conf" => $no_tls || $no_ct || $no_ec,
  84   # We could run some of these tests without TLS 1.2 if we had a per-test
  85   # disable instruction but that's a bizarre configuration not worth
  86   # special-casing for.
  87   # TODO(TLS 1.3): We should review this once we have TLS 1.3.
  88   "13-fragmentation.conf" => disabled("tls1_2"),
  89   "14-curves.conf" => disabled("tls1_2") || $no_ec || $no_ec2m,
  90   "15-certstatus.conf" => $no_tls || $no_ocsp,
  91   "16-dtls-certstatus.conf" => $no_dtls || $no_ocsp,
  92   "17-renegotiate.conf" => $no_tls_below1_3,
  93   "18-dtls-renegotiate.conf" => $no_dtls,
  94   "19-mac-then-encrypt.conf" => $no_pre_tls1_3,
  95   "20-cert-select.conf" => disabled("tls1_2") || $no_ec,
  96   "21-key-update.conf" => disabled("tls1_3"),
  97   "22-compression.conf" => disabled("zlib") || $no_tls,
  98   "23-srp.conf" => (disabled("tls1") && disabled ("tls1_1")
  99                     && disabled("tls1_2")) || disabled("srp"),
 100   "24-padding.conf" => disabled("tls1_3"),
 101   "25-cipher.conf" => disabled("ec") || disabled("tls1_2"),
 102   "26-tls13_client_auth.conf" => disabled("tls1_3"),
 103 );
 104
 105 foreach my $conf (@conf_files) {
 106     subtest "Test configuration $conf" => sub {
 107         test_conf($conf,
 108                   $conf_dependent_tests{$conf} || $^O eq "VMS" ?  0 : 1,
 109                   defined($skip{$conf}) ? $skip{$conf} : $no_tls);
 110     }
 111 }
 112
 113 sub test_conf {
 114     plan tests => 3;
 115
 116     my ($conf, $check_source, $skip) = @_;
 117
 118     my $conf_file = srctop_file("test", "ssl-tests", $conf);
 119     my $tmp_file = "${conf}.$$.tmp";
 120     my $run_test = 1;
 121
 122   SKIP: {
 123       # "Test" 1. Generate the source.
 124       my $input_file = $conf_file . ".in";
 125
 126       skip 'failure', 2 unless
 127         ok(run(perltest(["generate_ssl_tests.pl", $input_file],
 128                         interpreter_args => [ "-I", srctop_dir("util", "perl")],
 129                         stdout => $tmp_file)),
 130            "Getting output from generate_ssl_tests.pl.");
 131
 132     SKIP: {
 133         # Test 2. Compare against existing output in test/ssl_tests.conf.
 134         skip "Skipping generated source test for $conf", 1
 135           if !$check_source;
 136
 137         $run_test = is(cmp_text($tmp_file, $conf_file), 0,
 138                        "Comparing generated sources.");
 139       }
 140
 141       # Test 3. Run the test.
 142       skip "No tests available; skipping tests", 1 if $skip;
 143       skip "Stale sources; skipping tests", 1 if !$run_test;
 144
 145       ok(run(test(["ssl_test", $tmp_file])), "running ssl_test $conf");
 146     }
 147
 148     unlink glob $tmp_file;
 149 }
 150
 151 sub cmp_text {
 152     return compare_text(@_, sub {
 153         $_[0] =~ s/\R//g;
 154         $_[1] =~ s/\R//g;
 155         return $_[0] ne $_[1];
 156     });
 157 }