src/http/url_rewriters/helpers.m4

   1 ## Copyright (C) 1996-2020 The Squid Software Foundation and contributors
   2 ##
   3 ## Squid software is distributed under GPLv2+ license and includes
   4 ## contributions from numerous individuals and organizations.
   5 ## Please see the COPYING and CONTRIBUTORS files for details.
   6 ##
   7
   8 # This file is supposed to run all the tests required to identify which
   9 # configured modules are able to be built in this environment
  10
  11 # FIXME: de-duplicate $enable_url_rewrite_helpers list containing double entries.
  12
  13 #define list of modules to build
  14 auto_urlrewrite_modules=no
  15 if test "x${enable_url_rewrite_helpers:=yes}" = "xyes" ; then
  16     SQUID_LOOK_FOR_MODULES([$srcdir/src/http/url_rewriters],[enable_url_rewrite_helpers])
  17   auto_urlrewrite_modules=yes
  18 fi
  19
  20 enable_url_rewrite_helpers="`echo $enable_url_rewrite_helpers| sed -e 's/,/ /g;s/  */ /g'`"
  21 AC_MSG_NOTICE([URL rewrite helper candidates: $enable_url_rewrite_helpers])
  22 URL_REWRITE_HELPERS=""
  23 if test "x$enable_url_rewrite_helpers" != "xno" ; then
  24   for helper in $enable_url_rewrite_helpers; do
  25     dir="$srcdir/src/http/url_rewriters/$helper"
  26
  27     # modules converted to autoconf macros already
  28     # NP: we only need this list because m4_include() does not accept variables
  29     if test "x$helper" = "xfake" ; then
  30       m4_include([src/http/url_rewriters/fake/required.m4])
  31
  32     elif test "x$helper" = "xLFS" ; then
  33       m4_include([src/http/url_rewriters/LFS/required.m4])
  34
  35     # modules not yet converted to autoconf macros (or third party drop-in's)
  36     elif test -f "$dir/config.test" && sh "$dir/config.test" "$squid_host_os"; then
  37       BUILD_HELPER="$helper"
  38     fi
  39
  40     if test -d "$srcdir/src/http/url_rewriters/$helper"; then
  41       if test "$BUILD_HELPER" != "$helper"; then
  42         if test "x$auto_urlrewrite_modules" = "xyes"; then
  43           AC_MSG_NOTICE([URL rewrite helper $helper ... found but cannot be built])
  44         else
  45           AC_MSG_ERROR([URL rewrite helper $helper ... found but cannot be built])
  46         fi
  47       else
  48         URL_REWRITE_HELPERS="$URL_REWRITE_HELPERS $BUILD_HELPER"
  49       fi
  50     else
  51       AC_MSG_ERROR([URL rewrite helper $helper ... not found])
  52     fi
  53   done
  54 fi
  55 AC_MSG_NOTICE([URL rewrite helpers to be built: $URL_REWRITE_HELPERS])
  56 AC_SUBST(URL_REWRITE_HELPERS)