src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4
   5 systemd_logind_sources = files('''
   6         logind.c
   7         logind.h
   8 '''.split())
   9
  10 logind_gperf_c = custom_target(
  11         'logind_gperf.c',
  12         input : 'logind-gperf.gperf',
  13         output : 'logind-gperf.c',
  14         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  15
  16 systemd_logind_sources += [logind_gperf_c]
  17
  18
  19 liblogind_core_sources = files('''
  20         logind-core.c
  21         logind-device.c
  22         logind-device.h
  23         logind-button.c
  24         logind-button.h
  25         logind-action.c
  26         logind-action.h
  27         logind-seat.c
  28         logind-seat.h
  29         logind-session.c
  30         logind-session.h
  31         logind-session-device.c
  32         logind-session-device.h
  33         logind-user.c
  34         logind-user.h
  35         logind-inhibit.c
  36         logind-inhibit.h
  37         logind-dbus.c
  38         logind-session-dbus.c
  39         logind-seat-dbus.c
  40         logind-user-dbus.c
  41         logind-utmp.c
  42         logind-acl.h
  43 '''.split())
  44
  45 logind_acl_c = files('logind-acl.c')
  46 if conf.get('HAVE_ACL') == 1
  47         liblogind_core_sources += logind_acl_c
  48 endif
  49
  50 liblogind_core = static_library(
  51         'logind-core',
  52         liblogind_core_sources,
  53         include_directories : includes,
  54         dependencies : [libacl])
  55
  56 loginctl_sources = files('''
  57         loginctl.c
  58         sysfs-show.h
  59         sysfs-show.c
  60 '''.split())
  61
  62 if conf.get('ENABLE_LOGIND') == 1
  63         logind_conf = configure_file(
  64                 input : 'logind.conf.in',
  65                 output : 'logind.conf',
  66                 configuration : substs)
  67         install_data(logind_conf,
  68                      install_dir : pkgsysconfdir)
  69
  70         pam_systemd_sym = 'src/login/pam_systemd.sym'
  71         pam_systemd_c = files('pam_systemd.c')
  72
  73         install_data('org.freedesktop.login1.conf',
  74                      install_dir : dbuspolicydir)
  75         install_data('org.freedesktop.login1.service',
  76                      install_dir : dbussystemservicedir)
  77         install_data('org.freedesktop.login1.policy',
  78                      install_dir : polkitpolicydir)
  79
  80         install_data('70-power-switch.rules', install_dir : udevrulesdir)
  81
  82         if conf.get('HAVE_ACL') == 1
  83                 install_data('70-uaccess.rules', install_dir : udevrulesdir)
  84         endif
  85
  86         seat_rules = configure_file(
  87                 input : '71-seat.rules.in',
  88                 output : '71-seat.rules',
  89                 configuration : substs)
  90         install_data(seat_rules,
  91                      install_dir : udevrulesdir)
  92
  93         custom_target(
  94                 '73-seat-late.rules',
  95                 input : '73-seat-late.rules.m4',
  96                 output: '73-seat-late.rules',
  97                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
  98                 capture : true,
  99                 install : true,
 100                 install_dir : udevrulesdir)
 101
 102         custom_target(
 103                 'systemd-user',
 104                 input : 'systemd-user.m4',
 105                 output: 'systemd-user',
 106                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 107                 capture : true,
 108                 install : pamconfdir != 'no',
 109                 install_dir : pamconfdir)
 110 endif