src/machine/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 systemd_machined_sources = files('''
   4         machined.c
   5         machined.h
   6 '''.split())
   7
   8 libmachine_core_sources = files('''
   9         image-dbus.c
  10         image-dbus.h
  11         machine-dbus.c
  12         machine-dbus.h
  13         machine.c
  14         machine.h
  15         machined-core.c
  16         machined-dbus.c
  17         machined-varlink.c
  18         machined-varlink.h
  19         operation.c
  20         operation.h
  21 '''.split())
  22
  23 libmachine_core = static_library(
  24         'machine-core',
  25         libmachine_core_sources,
  26         include_directories : includes,
  27         dependencies : [threads])
  28
  29 if conf.get('ENABLE_MACHINED') == 1
  30         install_data('org.freedesktop.machine1.conf',
  31                      install_dir : dbuspolicydir)
  32         install_data('org.freedesktop.machine1.service',
  33                      install_dir : dbussystemservicedir)
  34         install_data('org.freedesktop.machine1.policy',
  35                      install_dir : polkitpolicydir)
  36 endif
  37
  38 tests += [
  39         [['src/machine/test-machine-tables.c'],
  40          [libmachine_core,
  41           libshared],
  42          [threads],
  43          'ENABLE_MACHINED'],
  44 ]