]>
Commit | Line | Data |
---|---|---|
1 | dnl ** This is a configure script template for BIRD | |
2 | dnl ** Process it with autoconf to get ./configure | |
3 | dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz> | |
4 | ||
5 | AC_REVISION($Id$) | |
6 | AC_INIT(conf/confbase.Y) | |
7 | AC_CONFIG_AUX_DIR(tools) | |
8 | ||
9 | AC_ARG_ENABLE(debug, [ --enable-debug enable internal debugging routines (default: disabled)],,enable_debug=no) | |
10 | AC_ARG_ENABLE(memcheck, [ --enable-memcheck check memory allocations when debugging (default: enabled)],,enable_memcheck=yes) | |
11 | AC_ARG_ENABLE(client, [ --enable-client enable building of BIRD client (default: enabled)],,enable_client=yes) | |
12 | AC_ARG_ENABLE(ipv6, [ --enable-ipv6 enable building of IPv6 version (default: disabled)],,enable_ipv6=no) | |
13 | AC_ARG_ENABLE(pthreads, [ --enable-pthreads enable POSIX threads support (default: detect)],,enable_pthreads=try) | |
14 | AC_ARG_WITH(suffix, [ --with-suffix=STRING use specified suffix for BIRD files (default: 6 for IPv6 version)],[given_suffix="yes"]) | |
15 | AC_ARG_WITH(sysconfig, [ --with-sysconfig=FILE use specified BIRD system configuration file]) | |
16 | AC_ARG_WITH(protocols, [ --with-protocols=LIST include specified routing protocols (default: all)],,[with_protocols="all"]) | |
17 | AC_ARG_WITH(sysinclude, [ --with-sysinclude=PATH search for system includes on specified place]) | |
18 | AC_ARG_WITH(runtimedir, [ --with-runtimedir=PATH path for runtime files (default: $(localstatedir)/run)],[runtimedir="$with_runtimedir"],[runtimedir="\$(localstatedir)/run"]) | |
19 | AC_ARG_WITH(iproutedir, [ --with-iproutedir=PATH path to iproute2 config files (default: /etc/iproute2)],[given_iproutedir="yes"]) | |
20 | AC_ARG_VAR([FLEX], [location of the Flex program]) | |
21 | AC_ARG_VAR([BISON], [location of the Bison program]) | |
22 | AC_ARG_VAR([M4], [location of the M4 program]) | |
23 | ||
24 | ||
25 | if test "$srcdir" = . ; then | |
26 | # Building in current directory => create obj directory holding all objects | |
27 | objdir=obj | |
28 | mkdir -p obj | |
29 | srcdir_rel=.. | |
30 | makefiles="Makefile:tools/Makefile-top.in obj/Makefile:tools/Makefile.in obj/Rules:tools/Rules.in" | |
31 | exedir=.. | |
32 | else | |
33 | # Building in separate directory | |
34 | objdir=. | |
35 | srcdir_rel=$srcdir | |
36 | makefiles="Makefile:tools/Makefile.in Rules:tools/Rules.in" | |
37 | exedir=. | |
38 | fi | |
39 | case $srcdir_rel in | |
40 | /*) srcdir_rel_mf=$srcdir_rel ;; | |
41 | *) srcdir_rel_mf="\$(root-rel)$srcdir_rel" ;; | |
42 | esac | |
43 | AC_SUBST(objdir) | |
44 | AC_SUBST(exedir) | |
45 | AC_SUBST(srcdir_rel_mf) | |
46 | AC_SUBST(runtimedir) | |
47 | ||
48 | if test "$enable_ipv6" = yes ; then | |
49 | ip=ipv6 | |
50 | SUFFIX=6 | |
51 | proto_radv=radv | |
52 | else | |
53 | ip=ipv4 | |
54 | SUFFIX="" | |
55 | fi | |
56 | ||
57 | if test "$given_suffix" = yes ; then | |
58 | SUFFIX="$with_suffix" | |
59 | fi | |
60 | AC_SUBST(SUFFIX) | |
61 | ||
62 | if test "$enable_debug" = yes ; then | |
63 | CONFIG_FILE="bird$SUFFIX.conf" | |
64 | CONTROL_SOCKET="bird$SUFFIX.ctl" | |
65 | else | |
66 | CONFIG_FILE="\$(sysconfdir)/bird$SUFFIX.conf" | |
67 | CONTROL_SOCKET="$runtimedir/bird$SUFFIX.ctl" | |
68 | fi | |
69 | AC_SUBST(CONFIG_FILE) | |
70 | AC_SUBST(CONTROL_SOCKET) | |
71 | ||
72 | AC_SEARCH_LIBS(clock_gettime, [c rt posix4], , | |
73 | AC_MSG_ERROR([[Function clock_gettime not available.]])) | |
74 | ||
75 | AC_CANONICAL_HOST | |
76 | ||
77 | # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC | |
78 | if test "$ac_test_CFLAGS" != set ; then | |
79 | bird_cflags_default=yes | |
80 | fi | |
81 | ||
82 | AC_PROG_CC | |
83 | if test -z "$GCC" ; then | |
84 | AC_MSG_ERROR([This program requires the GNU C Compiler.]) | |
85 | fi | |
86 | ||
87 | # Enable threads by default just in Linux and FreeBSD | |
88 | if test "$enable_pthreads" = try ; then | |
89 | case "$host_os" in | |
90 | (linux* | freebsd*) enable_pthreads=try ;; | |
91 | (*) enable_pthreads=no ;; | |
92 | esac | |
93 | fi | |
94 | ||
95 | if test "$enable_pthreads" != no ; then | |
96 | BIRD_CHECK_PTHREADS | |
97 | ||
98 | if test "$bird_cv_lib_pthreads" = yes ; then | |
99 | AC_DEFINE(USE_PTHREADS) | |
100 | CFLAGS="$CFLAGS -pthread" | |
101 | LDFLAGS="$LDFLAGS -pthread" | |
102 | proto_bfd=bfd | |
103 | elif test "$enable_pthreads" = yes ; then | |
104 | AC_MSG_ERROR([POSIX threads not available.]) | |
105 | fi | |
106 | ||
107 | if test "$enable_pthreads" = try ; then | |
108 | enable_pthreads="$bird_cv_lib_pthreads" | |
109 | fi | |
110 | fi | |
111 | ||
112 | if test "$bird_cflags_default" = yes ; then | |
113 | BIRD_CHECK_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign, -Wall) | |
114 | BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing) | |
115 | BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow) | |
116 | ||
117 | CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -Wno-parentheses" | |
118 | BIRD_ADD_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign) | |
119 | BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing) | |
120 | BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow) | |
121 | fi | |
122 | AC_MSG_CHECKING([CFLAGS]) | |
123 | AC_MSG_RESULT($CFLAGS) | |
124 | ||
125 | ||
126 | AC_PROG_CPP | |
127 | AC_PROG_INSTALL | |
128 | AC_PROG_RANLIB | |
129 | AC_CHECK_PROG(FLEX, flex, flex) | |
130 | AC_CHECK_PROG(BISON, bison, bison) | |
131 | AC_CHECK_PROGS(M4, gm4 m4) | |
132 | ||
133 | test -z "$FLEX" && AC_MSG_ERROR([Flex is missing.]) | |
134 | test -z "$BISON" && AC_MSG_ERROR([Bison is missing.]) | |
135 | test -z "$M4" && AC_MSG_ERROR([M4 is missing.]) | |
136 | BIRD_CHECK_PROG_FLAVOR_GNU([$M4], , [AC_MSG_ERROR([Provided M4 is not GNU M4.])]) | |
137 | ||
138 | if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then | |
139 | if test -f $with_sysconfig ; then | |
140 | sysdesc=$with_sysconfig | |
141 | else | |
142 | sysdesc=$srcdir/sysdep/cf/$with_sysconfig | |
143 | if ! test -f $sysdesc ; then | |
144 | sysdesc=$sysdesc.h | |
145 | fi | |
146 | fi | |
147 | elif test -f sysconfig.h ; then | |
148 | sysdesc=sysconfig | |
149 | else | |
150 | case "$ip:$host_os" in | |
151 | ipv6:linux*) sysdesc=linux-v6 | |
152 | default_iproutedir="/etc/iproute2" | |
153 | ;; | |
154 | ipv4:linux*) sysdesc=linux | |
155 | default_iproutedir="/etc/iproute2" | |
156 | ;; | |
157 | ipv6:netbsd*) sysdesc=bsd-v6 | |
158 | CPPFLAGS="$CPPFLAGS -I/usr/pkg/include" | |
159 | LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib" | |
160 | ;; | |
161 | ipv4:netbsd*) sysdesc=bsd | |
162 | CPPFLAGS="$CPPFLAGS -I/usr/pkg/include" | |
163 | LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib" | |
164 | ;; | |
165 | ipv6:freebsd*) sysdesc=bsd-v6 | |
166 | ;; | |
167 | ipv4:freebsd*) sysdesc=bsd | |
168 | ;; | |
169 | ipv6:dragonfly*) sysdesc=bsd-v6 | |
170 | ;; | |
171 | ipv4:dragonfly*) sysdesc=bsd | |
172 | ;; | |
173 | ipv6:kfreebsd*) sysdesc=bsd-v6 | |
174 | ;; | |
175 | ipv4:kfreebsd*) sysdesc=bsd | |
176 | ;; | |
177 | ipv6:openbsd*) sysdesc=bsd-v6 | |
178 | ;; | |
179 | ipv4:openbsd*) sysdesc=bsd | |
180 | ;; | |
181 | *) AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.]) | |
182 | ;; | |
183 | esac | |
184 | sysdesc=$srcdir/sysdep/cf/$sysdesc.h | |
185 | fi | |
186 | AC_MSG_CHECKING([which OS configuration should we use]) | |
187 | AC_MSG_RESULT($sysdesc) | |
188 | if ! test -f $sysdesc ; then | |
189 | AC_MSG_ERROR([The system configuration file is missing.]) | |
190 | fi | |
191 | sysname=`echo $sysdesc | sed 's/\.h$//'` | |
192 | AC_DEFINE_UNQUOTED(SYSCONF_INCLUDE, "$sysdesc") | |
193 | ||
194 | AC_MSG_CHECKING([system-dependent directories]) | |
195 | sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '` lib" | |
196 | AC_MSG_RESULT($sysdep_dirs) | |
197 | AC_SUBST(sysdep_dirs) | |
198 | ||
199 | if test "$with_iproutedir" = no ; then with_iproutedir= ; fi | |
200 | ||
201 | if test -n "$given_iproutedir" | |
202 | then iproutedir=$with_iproutedir | |
203 | else iproutedir=$default_iproutedir | |
204 | fi | |
205 | ||
206 | AC_SUBST(iproutedir) | |
207 | ||
208 | all_protocols="$proto_bfd bgp ospf pipe $proto_radv rip static" | |
209 | all_protocols=`echo $all_protocols | sed 's/ /,/g'` | |
210 | ||
211 | if test "$with_protocols" = all ; then | |
212 | with_protocols="$all_protocols" | |
213 | fi | |
214 | ||
215 | AC_MSG_CHECKING([protocols]) | |
216 | protocols=`echo "$with_protocols" | sed 's/,/ /g'` | |
217 | if test "$protocols" = no ; then protocols= ; fi | |
218 | for a in $protocols ; do | |
219 | if ! test -f $srcdir/proto/$a/Makefile ; then | |
220 | AC_MSG_RESULT(failed) | |
221 | AC_MSG_ERROR([Requested protocol $a not found.]) | |
222 | fi | |
223 | AC_DEFINE_UNQUOTED(CONFIG_`echo $a | tr 'a-z' 'A-Z'`) | |
224 | done | |
225 | AC_MSG_RESULT(ok) | |
226 | AC_SUBST(protocols) | |
227 | ||
228 | case $sysdesc in | |
229 | */linux*|*/linux-v6*) | |
230 | AC_CHECK_HEADER(linux/rtnetlink.h,,[AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],[ | |
231 | #include <asm/types.h> | |
232 | #include <sys/socket.h> | |
233 | ]) | |
234 | ;; | |
235 | esac | |
236 | ||
237 | AC_CHECK_HEADER(syslog.h, [AC_DEFINE(HAVE_SYSLOG)]) | |
238 | AC_CHECK_HEADER(alloca.h, [AC_DEFINE(HAVE_ALLOCA_H)]) | |
239 | AC_MSG_CHECKING(whether 'struct sockaddr' has sa_len) | |
240 | AC_TRY_COMPILE([#include <sys/types.h> | |
241 | #include <sys/socket.h> | |
242 | ], [static struct sockaddr sa; int i = sizeof(sa.sa_len);], | |
243 | [AC_MSG_RESULT(yes) | |
244 | AC_DEFINE(HAVE_SIN_LEN,,sin_len)], | |
245 | AC_MSG_RESULT(no)) | |
246 | ||
247 | AC_C_BIGENDIAN([AC_DEFINE(CPU_BIG_ENDIAN)], [AC_DEFINE(CPU_LITTLE_ENDIAN)], | |
248 | [AC_MSG_ERROR([Cannot determine CPU endianity.])]) | |
249 | ||
250 | BIRD_CHECK_INTEGERS | |
251 | BIRD_CHECK_STRUCT_ALIGN | |
252 | BIRD_CHECK_TIME_T | |
253 | BIRD_CHECK_STRUCT_IP_MREQN | |
254 | ||
255 | if test "$enable_debug" = yes ; then | |
256 | AC_DEFINE(DEBUGGING) | |
257 | if test "$enable_memcheck" = yes ; then | |
258 | AC_CHECK_LIB(dmalloc, dmalloc_debug) | |
259 | if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then | |
260 | AC_CHECK_LIB(efence, malloc) | |
261 | fi | |
262 | fi | |
263 | fi | |
264 | ||
265 | CLIENT= | |
266 | CLIENT_LIBS= | |
267 | if test "$enable_client" = yes ; then | |
268 | CLIENT=birdc | |
269 | AC_CHECK_LIB(history, add_history, CLIENT_LIBS="-lhistory") | |
270 | AC_CHECK_LIB(ncurses, tgetent, USE_TERMCAP_LIB=-lncurses, | |
271 | AC_CHECK_LIB(curses, tgetent, USE_TERMCAP_LIB=-lcurses, | |
272 | AC_CHECK_LIB(tinfow, tgetent, USE_TERMCAP_LIB=-ltinfow, | |
273 | AC_CHECK_LIB(tinfo, tgetent, USE_TERMCAP_LIB=-ltinfo, | |
274 | AC_CHECK_LIB(termcap, tgetent, USE_TERMCAP_LIB=-ltermcap, | |
275 | AC_MSG_ERROR([[The client requires ncurses library. Either install the library or use --disable-client to compile without the client.]])))))) | |
276 | AC_CHECK_LIB(readline, rl_callback_read_char, CLIENT_LIBS="-lreadline $CLIENT_LIBS $USE_TERMCAP_LIB", | |
277 | AC_MSG_ERROR([[The client requires GNU readline library 2.1 or newer. Either install the library or use --disable-client to compile without the client.]]), $USE_TERMCAP_LIB) | |
278 | AC_CHECK_LIB(readline, rl_crlf, AC_DEFINE(HAVE_RL_CRLF),,$USE_TERMCAP_LIB) | |
279 | AC_CHECK_LIB(readline, rl_ding, AC_DEFINE(HAVE_RL_DING),,$USE_TERMCAP_LIB) | |
280 | fi | |
281 | AC_SUBST(CLIENT) | |
282 | AC_SUBST(CLIENT_LIBS) | |
283 | ||
284 | mkdir -p $objdir/sysdep | |
285 | AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in]) | |
286 | AC_CONFIG_COMMANDS([merge],[[export CPP="$CPP" | |
287 | $srcdir/tools/mergedirs $srcdir $srcdir_rel $objdir $sysdep_dirs]], | |
288 | [[srcdir=$srcdir] | |
289 | [srcdir_rel=$srcdir_rel] | |
290 | [objdir=$objdir] | |
291 | [sysdep_dirs="$sysdep_dirs"]]) | |
292 | AC_CONFIG_FILES($makefiles) | |
293 | AC_OUTPUT | |
294 | ||
295 | rm -f $objdir/sysdep/paths.h | |
296 | ||
297 | cat >&AC_FD_MSG <<EOF | |
298 | ||
299 | BIRD was configured with the following options: | |
300 | Source directory: $srcdir | |
301 | Object directory: $objdir | |
302 | Iproute2 directory: $iproutedir | |
303 | System configuration: $sysdesc | |
304 | Debugging: $enable_debug | |
305 | POSIX threads: $enable_pthreads | |
306 | Routing protocols: $protocols | |
307 | Client: $enable_client | |
308 | EOF | |
309 | rm -f $objdir/.*-stamp |