]>
Commit | Line | Data |
---|---|---|
1 | /* Vector optimized 32/64 bit S/390 version of strchrnul. | |
2 | Copyright (C) 2015-2019 Free Software Foundation, Inc. | |
3 | This file is part of the GNU C Library. | |
4 | ||
5 | The GNU C Library is free software; you can redistribute it and/or | |
6 | modify it under the terms of the GNU Lesser General Public | |
7 | License as published by the Free Software Foundation; either | |
8 | version 2.1 of the License, or (at your option) any later version. | |
9 | ||
10 | The GNU C Library is distributed in the hope that it will be useful, | |
11 | but WITHOUT ANY WARRANTY; without even the implied warranty of | |
12 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | |
13 | Lesser General Public License for more details. | |
14 | ||
15 | You should have received a copy of the GNU Lesser General Public | |
16 | License along with the GNU C Library; if not, see | |
17 | <https://www.gnu.org/licenses/>. */ | |
18 | ||
19 | #include <ifunc-strchrnul.h> | |
20 | ||
21 | #if HAVE_STRCHRNUL_Z13 | |
22 | ||
23 | # include "sysdep.h" | |
24 | # include "asm-syntax.h" | |
25 | ||
26 | .text | |
27 | ||
28 | /* char *strchrnul (const char *s, int c) | |
29 | Returns pointer to first c or to \0 if c not found. | |
30 | ||
31 | Register usage: | |
32 | -r1=tmp | |
33 | -r2=s and return pointer | |
34 | -r3=c | |
35 | -r4=tmp | |
36 | -r5=current_len | |
37 | -v16=part of s | |
38 | -v18=vector with c replicated in every byte | |
39 | */ | |
40 | ENTRY(STRCHRNUL_Z13) | |
41 | .machine "z13" | |
42 | .machinemode "zarch_nohighgprs" | |
43 | ||
44 | vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */ | |
45 | lcbb %r1,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */ | |
46 | ||
47 | lghi %r5,0 /* current_len = 0. */ | |
48 | ||
49 | vlvgb %v18,%r3,0 /* Generate vector which elements are all c. | |
50 | If c > 255, c will be truncated. */ | |
51 | vrepb %v18,%v18,0 | |
52 | ||
53 | vfeezbs %v16,%v16,%v18 /* Find element equal with zero search. */ | |
54 | vlgvb %r4,%v16,7 /* Load byte index of character or zero. */ | |
55 | clrjl %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes. */ | |
56 | ||
57 | /* Align s to 16 byte. */ | |
58 | risbgn %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */ | |
59 | lghi %r5,16 /* current_len = 16. */ | |
60 | slr %r5,%r4 /* Compute bytes to 16bytes boundary. */ | |
61 | ||
62 | /* Find c/zero in 16byte aligned loop */ | |
63 | .Lloop: | |
64 | vl %v16,0(%r5,%r2) /* Load s */ | |
65 | vfeezbs %v16,%v16,%v18 /* Find element equal with zero search. */ | |
66 | jno .Lfound /* Found c/zero (cc=0|1|2). */ | |
67 | vl %v16,16(%r5,%r2) | |
68 | vfeezbs %v16,%v16,%v18 | |
69 | jno .Lfound16 | |
70 | vl %v16,32(%r5,%r2) | |
71 | vfeezbs %v16,%v16,%v18 | |
72 | jno .Lfound32 | |
73 | vl %v16,48(%r5,%r2) | |
74 | vfeezbs %v16,%v16,%v18 | |
75 | jno .Lfound48 | |
76 | ||
77 | aghi %r5,64 | |
78 | j .Lloop /* No character and no zero -> loop. */ | |
79 | ||
80 | /* Found character or zero */ | |
81 | .Lfound48: | |
82 | aghi %r5,16 | |
83 | .Lfound32: | |
84 | aghi %r5,16 | |
85 | .Lfound16: | |
86 | aghi %r5,16 | |
87 | .Lfound: | |
88 | vlgvb %r1,%v16,7 /* Load byte index of character. */ | |
89 | algr %r5,%r1 | |
90 | la %r2,0(%r5,%r2) /* Return pointer to character. */ | |
91 | ||
92 | .Lend: | |
93 | br %r14 | |
94 | END(STRCHRNUL_Z13) | |
95 | ||
96 | # if ! HAVE_STRCHRNUL_IFUNC | |
97 | strong_alias (STRCHRNUL_Z13, __strchrnul) | |
98 | weak_alias (__strchrnul, strchrnul) | |
99 | # endif | |
100 | ||
101 | #endif /* HAVE_STRCHRNUL_Z13 */ |