CMakeLists.txt

   1 CMAKE_MINIMUM_REQUIRED (VERSION 2.6)
   2 PROJECT(sarg C)
   3 SET(sarg_VERSION 2)
   4 SET(sarg_REVISION "4.0-pre1")
   5 SET(sarg_BUILD "")
   6 SET(sarg_BUILDDATE "May-19-2013")
   7
   8 INCLUDE(AddFileDependencies)
   9 INCLUDE(CheckIncludeFile)
  10 INCLUDE(CheckLibraryExists)
  11 INCLUDE(CheckFunctionExists)
  12 INCLUDE(CheckTypeSize)
  13 INCLUDE(CheckSymbolExists)
  14 INCLUDE(CheckCCompilerFlag)
  15 INCLUDE(CheckStructHasMember)
  16
  17 DEFINE_PROPERTY(GLOBAL PROPERTY enable-htmldir BRIEF_DOCS "--enable-htmldir=htmldir"
  18                         FULL_DOCS "Select htmldir as the root of your WWW documents")
  19
  20 SET(PACKAGE_NAME "sarg")
  21 SET(PACKAGE_VERSION "${sarg_VERSION}.${sarg_REVISION}${sarg_BUILD}")
  22
  23 MACRO(SET_ABS_SOURCE VAR DOC)
  24    IF(${VAR} AND NOT ${VAR}_SOURCE)
  25       SET(PATH "${${VAR}}")
  26       IF(NOT IS_ABSOLUTE ${PATH})
  27          SET(PATH "${CMAKE_INSTALL_PREFIX}/${PATH}")
  28       ENDIF(NOT IS_ABSOLUTE ${PATH})
  29       GET_FILENAME_COMPONENT(SOURCE_PATH "${PATH}" ABSOLUTE)
  30       SET(${VAR}_SOURCE "${SOURCE_PATH}" CACHE PATH "${DOC}")
  31    ENDIF(${VAR} AND NOT ${VAR}_SOURCE)
  32 ENDMACRO(SET_ABS_SOURCE VAR DOC)
  33
  34 SET_ABS_SOURCE(SYSCONFDIR "The full path of the configuration directory to be compiled in the program")
  35 SET_ABS_SOURCE(FONTDIR "The full path of the fonts directory to be compiled in the program")
  36 SET_ABS_SOURCE(IMAGEDIR "The full path of the images directory to be compiled in the program")
  37
  38 SET(SYSCONFDIR "etc/sarg" CACHE PATH "The configuration directory relative to the install directory")
  39 SET(BINDIR "bin" CACHE PATH "The directory to install the exec relative to the install directory")
  40 SET(MANDIR "share/man/man1" CACHE PATH "The directory to copy the man page relative to the install directory")
  41 SET(FONTDIR "share/sarg/fonts" CACHE PATH "The directory to copy the fonts relative to the install directory")
  42 SET(IMAGEDIR "share/sarg/images" CACHE PATH "The directory to copy the images files relative to the install directory")
  43 SET(SARGPHPDIR "share/sarg/sarg-php" CACHE PATH "The directory to copy sarg-php relative to the install directory")
  44
  45 # Sources to compile
  46 INCLUDE_DIRECTORIES("${CMAKE_BINARY_DIR}") #Make it find this config.h before the one in src/include
  47 INCLUDE_DIRECTORIES("${CMAKE_SOURCE_DIR}/include")
  48 SET(SRC util.c log.c report.c topuser.c email.c sort.c html.c
  49        index.c getconf.c usage.c decomp.c ip2name.c ip2name_dns.c
  50        useragent.c exclude.c convlog.c totday.c repday.c datafile.c
  51        indexonly.c splitlog.c lastlog.c topsites.c siteuser.c css.c
  52        smartfilter.c denied.c authfail.c charset.c dichotomic.c
  53        redirector.c auth.c download.c grepday.c ip2name_exec.c
  54        dansguardian_log.c dansguardian_report.c realtime.c btree_cache.c
  55        usertab.c userinfo.c longline.c url.c fnmatch.c stringbuffer.c
  56        filelist.c readlog.c alias.c
  57        readlog_squid.c readlog_sarg.c readlog_extlog.c readlog_common.c)
  58
  59 FOREACH(f ${SRC})
  60    ADD_FILE_DEPENDENCIES(${f} ${CMAKE_BINARY_DIR}/config.h ${CMAKE_SOURCE_DIR}/include/conf.h ${CMAKE_SOURCE_DIR}/include/info.h ${CMAKE_SOURCE_DIR}/include/defs.h)
  61 ENDFOREACH(f)
  62
  63 ADD_EXECUTABLE(sarg ${SRC})
  64
  65 SET_TARGET_PROPERTIES(sarg PROPERTIES VERSION "${sarg_VERSION}.${sarg_REVISION}.${sarg_BUILD}")
  66
  67 SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "$ENV{CFLAGS} -Wall -Wno-sign-compare")
  68 SET_TARGET_PROPERTIES(sarg PROPERTIES LINK_FLAGS "$ENV{LDFLAGS}")
  69
  70 CHECK_C_COMPILER_FLAG("-Wextra" HAVE_WEXTRA)
  71 IF(HAVE_WEXTRA)
  72    # Not supported by gcc 3.3
  73    GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
  74    SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -Wextra -Wno-unused-parameter")
  75 ENDIF(HAVE_WEXTRA)
  76
  77 CHECK_C_COMPILER_FLAG("-Werror=implicit-function-declaration" HAVE_WERROR_IMPLICIT_FUNCTION)
  78 IF(HAVE_WERROR_IMPLICIT_FUNCTION)
  79    GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
  80    SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -Werror=implicit-function-declaration")
  81 ENDIF(HAVE_WERROR_IMPLICIT_FUNCTION)
  82
  83 CHECK_C_COMPILER_FLAG("-Werror=format" HAVE_WERROR_FORMAT)
  84 IF(HAVE_WERROR_FORMAT)
  85    GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
  86    SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -Werror=format")
  87 ENDIF(HAVE_WERROR_FORMAT)
  88
  89 # Required header files
  90 CHECK_INCLUDE_FILE(stdio.h HAVE_STDIO_H)
  91 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
  92 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
  93 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
  94 CHECK_INCLUDE_FILE(sys/time.h HAVE_SYS_TIME_H)
  95 CHECK_INCLUDE_FILE(time.h HAVE_TIME_H)
  96 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
  97 CHECK_INCLUDE_FILE(sys/dirent.h HAVE_SYS_DIRENT_H)
  98 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
  99 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 100 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 101 CHECK_INCLUDE_FILE(netdb.h HAVE_NETDB_H)
 102 CHECK_INCLUDE_FILE(arpa/inet.h HAVE_ARPA_INET_H)
 103 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_H)
 104 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 105 CHECK_INCLUDE_FILE(ctype.h HAVE_CTYPE_H)
 106 CHECK_INCLUDE_FILE(errno.h HAVE_ERRNO_H)
 107 CHECK_INCLUDE_FILE(sys/resource.h HAVE_SYS_RESOURCE_H)
 108 CHECK_INCLUDE_FILE(sys/wait.h HAVE_SYS_WAIT_H)
 109 CHECK_INCLUDE_FILE(stdarg.h HAVE_STDARG_H)
 110 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 111 CHECK_INCLUDE_FILE(limits.h HAVE_LIMITS_H)
 112 CHECK_INCLUDE_FILE(math.h HAVE_MATH_H)
 113 CHECK_INCLUDE_FILE(locale.h HAVE_LOCALE_H)
 114 CHECK_INCLUDE_FILE(execinfo.h HAVE_EXECINFO_H)
 115 CHECK_INCLUDE_FILE(libintl.h HAVE_LIBINTL_H)
 116 CHECK_INCLUDE_FILE(libgen.h HAVE_LIBGEN_H)
 117 CHECK_INCLUDE_FILE(stdbool.h HAVE_STDBOOL_H)
 118 CHECK_INCLUDE_FILE(getopt.h HAVE_GETOPT_H)
 119 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 120 CHECK_INCLUDE_FILE(fnmatch.h HAVE_FNMATCH_H)
 121
 122 IF(!HAVE_GETOPT_H)
 123    MESSAGE(SEND_ERROR "getopt.h is required to compile sarg")
 124 ENDIF(!HAVE_GETOPT_H)
 125
 126 # Windows need lib wsock32 and ws2_32
 127 IF(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 128    CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
 129    CHECK_INCLUDE_FILE(winsock.h HAVE_WINSOCK_H)
 130    CHECK_INCLUDE_FILE(ws2tcpip.h HAVE_WS2TCPIP_H)
 131
 132    FIND_LIBRARY(WSOCK_LIB NAMES wsock32 DOC "The winsock library")
 133    IF(WSOCK_LIB)
 134       TARGET_LINK_LIBRARIES(sarg wsock32)
 135       LIST(APPEND CMAKE_REQUIRED_LIBRARIES wsock32)
 136    ENDIF(WSOCK_LIB)
 137
 138    FIND_LIBRARY(WSOCK2_LIB NAMES ws2_32 DOC "The winsock 2 library")
 139    IF(WSOCK2_LIB)
 140       TARGET_LINK_LIBRARIES(sarg ws2_32)
 141       LIST(APPEND CMAKE_REQUIRED_LIBRARIES ws2_32)
 142    ENDIF(WSOCK2_LIB)
 143
 144    ADD_DEFINITIONS(-DWINDOWS)
 145 ENDIF(CMAKE_SYSTEM_NAME STREQUAL "Windows")
 146
 147 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 148 CHECK_FUNCTION_EXISTS(backtrace HAVE_BACKTRACE)
 149 CHECK_FUNCTION_EXISTS(symlink HAVE_SYMLINK)
 150 CHECK_FUNCTION_EXISTS(lstat HAVE_LSTAT)
 151 CHECK_FUNCTION_EXISTS(getnameinfo HAVE_GETNAMEINFO)
 152 CHECK_FUNCTION_EXISTS(getaddrinfo HAVE_GETADDRINFO)
 153 CHECK_FUNCTION_EXISTS(inet_aton HAVE_INET_ATON)
 154 CHECK_FUNCTION_EXISTS(fnmatch HAVE_FNMATCH)
 155
 156 CHECK_STRUCT_HAS_MEMBER("struct sockaddr_storage" ss_len sys/socket.h HAVE_SOCKADDR_SA_LEN)
 157
 158 # Find gd
 159 CHECK_INCLUDE_FILE(gd.h HAVE_GD_H)
 160 IF(HAVE_GD_H)
 161    CHECK_INCLUDE_FILE(gdfontl.h HAVE_GDFONTL_H)
 162    CHECK_INCLUDE_FILE(gdfontt.h HAVE_GDFONTT_H)
 163    CHECK_INCLUDE_FILE(gdfonts.h HAVE_GDFONTS_H)
 164    CHECK_INCLUDE_FILE(gdfontmb.h HAVE_GDFONTMB_H)
 165    CHECK_INCLUDE_FILE(gdfontg.h HAVE_GDFONTG_H)
 166    FIND_LIBRARY(GD_LIBRARY NAMES gd bgd DOC "The GD library")
 167    IF(GD_LIBRARY)
 168       #CHECK_LIBRARY_EXISTS(gd gdImagePng "." HAVE_GD_LIB)
 169       TARGET_LINK_LIBRARIES(sarg ${GD_LIBRARY})
 170       SET(HAVE_GD_LIB GD_LIBRARY CACHE PATH DOC "True IF GD was found")
 171       SET(HAVE_GD_LIB CACHE BOOL DOC "True IF must use GD")
 172    ENDIF(GD_LIBRARY)
 173 ENDIF(HAVE_GD_H)
 174
 175 # Find iconv
 176 OPTION(ENABLE_ICONV "Enable the usage of iconv" ON)
 177 IF(ENABLE_ICONV)
 178    CHECK_INCLUDE_FILE(iconv.h HAVE_ICONV_H)
 179    IF(HAVE_ICONV_H)
 180       FIND_PATH(ICONV_INCLUDE_PATH NAMES iconv.h)
 181       FIND_LIBRARY(ICONV_LIBRARY NAMES iconv DOC "The ICONV library")
 182       IF(ICONV_LIBRARY)
 183          TARGET_LINK_LIBRARIES(sarg ${ICONV_LIBRARY})
 184       ENDIF(ICONV_LIBRARY)
 185       CHECK_FUNCTION_EXISTS(iconv_open HAVE_ICONV)
 186
 187       IF(NOT USE_CONST_ICONV)
 188          SET(ICONV_CONST_FILE ${CMAKE_BINARY_DIR}/consticonv.c)
 189          FILE(WRITE ${ICONV_CONST_FILE} "
 190 #include <iconv.h>
 191 #ifdef __CLASSIC_C__
 192 int main(){
 193   int ac;
 194   char*av[];
 195 #else
 196 int main(int ac, char*av[]){
 197 #endif
 198   iconv_t localtoutf=(iconv_t)-1;
 199   const char *str=\"\";
 200   char *sstr=\"\";
 201   size_t slen=0, sslen=0;
 202
 203   iconv (localtoutf, (const char **)&str, &slen, &sstr, &sslen);
 204   if(ac > 1000)
 205     {
 206     return *av[0];
 207     }
 208   return 0;
 209 }
 210 ")
 211          TRY_COMPILE(USE_CONST_ICONV ${CMAKE_BINARY_DIR} ${ICONV_CONST_FILE} CMAKE_FLAGS -DLINK_LIBRARIES="iconv")
 212          FILE(REMOVE ${ICONV_CONST_FILE})
 213          IF(USE_CONST_ICONV)
 214             SET(ICONV_CONST "const" CACHE STRING "The type of char to use with iconv")
 215             MESSAGE(STATUS "iconv requires const char **")
 216          ELSEIF(USE_CONST_ICONV)
 217             SET(ICONV_CONST "" CACHE STRING "The type of char to use with iconv")
 218             MESSAGE(STATUS "iconv requires char **")
 219          ENDIF(USE_CONST_ICONV)
 220          SET(USE_CONST_ICONV TRUE CACHE BOOL "Use const char ** with iconv")
 221       ENDIF(NOT USE_CONST_ICONV)
 222    ENDIF(HAVE_ICONV_H)
 223 ENDIF(ENABLE_ICONV)
 224
 225 # Find ldap
 226 CHECK_INCLUDE_FILE(ldap.h HAVE_LDAP_H)
 227 IF(HAVE_LDAP_H)
 228    FIND_LIBRARY(LDAP_LIBRARY NAMES ldap DOC "The ldap library")
 229    IF(LDAP_LIBRARY)
 230       TARGET_LINK_LIBRARIES(sarg ${LDAP_LIBRARY})
 231       SET(HAVE_LDAP LDAP_LIBRARY CACHE PATH DOC "True if LDAP was found")
 232       SET(HAVE_LDAP CACHE BOOL DOC "True if must use LDAP")
 233    ENDIF(LDAP_LIBRARY)
 234 ENDIF(HAVE_LDAP_H)
 235
 236 # Find pcre
 237 CHECK_INCLUDE_FILE(pcre.h HAVE_PCRE_H)
 238 IF(HAVE_PCRE_H)
 239    FIND_LIBRARY(PCRE_LIBRARY NAMES pcre DOC "The pcre library")
 240    IF(PCRE_LIBRARY)
 241       TARGET_LINK_LIBRARIES(sarg ${PCRE_LIBRARY})
 242       SET(HAVE_PCRE PCRE_LIBRARY CACHE PATH DOC "True if pcre was found")
 243       SET(HAVE_PCRE CACHE BOOL DOC "True if must use pcre")
 244    ENDIF(PCRE_LIBRARY)
 245 ENDIF(HAVE_PCRE_H)
 246
 247 # Support for large files
 248 OPTION(ENABLE_LARGEFILE "Enable the usage of large files" ON)
 249 IF(ENABLE_LARGEFILE)
 250    IF(LFS_SEARCHED MATCHES "^LFS_SEARCHED$")
 251       SET(SEARCH_LARGEFILE TRUE)
 252    ENDIF(LFS_SEARCHED MATCHES "^LFS_SEARCHED$")
 253 ENDIF(ENABLE_LARGEFILE)
 254
 255 IF(SEARCH_LARGEFILE)
 256    SET(LFS_SEARCHED TRUE CACHE INTERNAL "LFS has been searched")
 257    MESSAGE(STATUS "Looking for large file support")
 258    SET(LFS_FILE "${CMAKE_BINARY_DIR}/lfsfopen64.c")
 259    FILE(WRITE ${LFS_FILE} "
 260 #include <stdio.h>
 261 int main(void)
 262 {
 263 FILE *f = fopen64 (\"/tmp/foo\",\"r\");
 264 return(0);
 265 }
 266 ")
 267    TRY_COMPILE(HAVE_FOPEN64 ${CMAKE_BINARY_DIR} ${LFS_FILE} COMPILE_DEFINITIONS "-Wall -Werror")
 268    IF(HAVE_FOPEN64)
 269       MESSAGE(STATUS "Looking for large file support - found")
 270    ELSE(HAVE_FOPEN64)
 271       SET(LFS_NEED_DEFINE FALSE CACHE BOOL "Does LFS require _LARGEFILE64_SOURCE ?")
 272       MESSAGE(STATUS "Looking for large file support with _LARGEFILE64_SOURCE")
 273       FILE(WRITE ${LFS_FILE} "
 274 #define _LARGEFILE64_SOURCE
 275 #include <stdio.h>
 276 int main(void)
 277 {
 278 FILE *f = fopen64 (\"/tmp/foo\",\"r\");
 279 return(0);
 280 }
 281 ")
 282       TRY_COMPILE(HAVE_FOPEN64 ${CMAKE_BINARY_DIR} ${LFS_FILE} OUTPUT_VARIABLE LFS_OUTPUT)
 283       IF(HAVE_FOPEN64)
 284          MESSAGE(STATUS "Looking for large file support with _LARGEFILE64_SOURCE - found")
 285          SET(LFS_NEED_DEFINE TRUE CACHE BOOL "Does LFS require _LARGEFILE64_SOURCE ?" FORCE)
 286       ELSE(HAVE_FOPEN64)
 287          MESSAGE("Failed with output ${LFS_OUTPUT}")
 288       ENDIF(HAVE_FOPEN64)
 289    ENDIF(HAVE_FOPEN64)
 290    FILE(REMOVE ${LFS_FILE})
 291 ENDIF(SEARCH_LARGEFILE)
 292
 293 IF(LFS_NEED_DEFINE)
 294    ADD_DEFINITIONS(-D_LARGEFILE64_SOURCE)
 295 ENDIF(LFS_NEED_DEFINE)
 296
 297 # Find rlim_t
 298 IF(HAVE_SYS_RESOURCE_H)
 299    SET(CMAKE_EXTRA_INCLUDE_FILES "sys/resource.h")
 300 ENDIF(HAVE_SYS_RESOURCE_H)
 301 CHECK_TYPE_SIZE(rlim_t RLIM_T)
 302 IF(HAVE_RLIM_T)
 303    IF(RLIM_T STREQUAL 4)
 304       SET(RLIM_STRING "%d")
 305    ELSEIF(RLIM_T STREQUAL 8)
 306       SET(RLIM_STRING "%lli")
 307    ELSE(RLIM_T STREQUAL 4)
 308       MESSAGE("Unknown rlim_t size")
 309    ENDIF(RLIM_T STREQUAL 4)
 310 #ELSE(HAVE_RLIM_T)
 311 #   MESSAGE("Cannot detect the size of your system's rlim_t type")
 312 ENDIF(HAVE_RLIM_T)
 313
 314 CHECK_FUNCTION_EXISTS(mkstemp HAVE_MKSTEMP)
 315 IF(NOT HAVE_MKSTEMP)
 316    # MingW provide mkstemps in libiberty but doesn't declare it in any header file
 317    FIND_LIBRARY(IBERTY_LIB NAMES iberty DOC "The library of mingw containing mkstemps")
 318    IF(IBERTY_LIB)
 319       TARGET_LINK_LIBRARIES(sarg iberty)
 320    ENDIF(IBERTY_LIB)
 321 ENDIF(NOT HAVE_MKSTEMP)
 322
 323 # Gettext and friends
 324 IF(NOT HAVE_LC_MESSAGES)
 325    SET(FILES)
 326    IF(HAVE_LOCALE_H)
 327       LIST(APPEND FILES "locale.h")
 328    ENDIF(HAVE_LOCALE_H)
 329    IF(HAVE_LIBINTL_H)
 330       LIST(APPEND FILES "libintl.h")
 331    ENDIF(HAVE_LIBINTL_H)
 332    LIST(LENGTH FILES NFILES)
 333    IF(NFILES GREATER 0)
 334       CHECK_SYMBOL_EXISTS(LC_MESSAGES "${FILES}" HAVE_LC_MESSAGES)
 335    ENDIF(NFILES GREATER 0)
 336 ENDIF(NOT HAVE_LC_MESSAGES)
 337
 338 # System particularities
 339 IF(CMAKE_SYSTEM_NAME STREQUAL "solaris")
 340    TARGET_LINK_LIBRARIES(sarg socket nsl)
 341    #SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_DEFINITIONS="-DSOLARIS ${COMPILE_DEFINITIONS}")
 342    ADD_DEFINITIONS(-DSOLARIS)
 343 ENDIF(CMAKE_SYSTEM_NAME STREQUAL "solaris")
 344
 345 OPTION(ENABLE_EXTRA_PROTECT "Enable compile and runtime extra protections" OFF)
 346 IF(ENABLE_EXTRA_PROTECT)
 347    GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
 348    SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -fstack-protector -D_FORTIFY_SOURCE=2 -Werror")
 349
 350    CHECK_C_COMPILER_FLAG("-Wformat -Werror=format-security" HAVE_WERROR_FORMAT_SECURITY)
 351    IF(HAVE_WERROR_FORMAT_SECURITY)
 352       GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
 353       SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -Wformat -Werror=format-security")
 354    ENDIF(HAVE_WERROR_FORMAT_SECURITY)
 355
 356    CHECK_C_COMPILER_FLAG("-Wempty-body" HAVE_EMPTY_BODY)
 357    IF(HAVE_EMPTY_BODY)
 358       GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
 359       SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -Wempty-body")
 360    ENDIF(HAVE_EMPTY_BODY)
 361 ENDIF(ENABLE_EXTRA_PROTECT)
 362
 363 # Compile sarg for debugging
 364 OPTION(ENABLE_DEBUG "Compile sarg with debugging symbols" OFF)
 365 IF(ENABLE_DEBUG)
 366    GET_TARGET_PROPERTY(TMPCFLAGS sarg COMPILE_FLAGS)
 367    SET_TARGET_PROPERTIES(sarg PROPERTIES COMPILE_FLAGS "${TMPCFLAGS} -g")
 368 ENDIF(ENABLE_DEBUG)
 369
 370 # Enable double check of the data written in the reports
 371 OPTION(ENABLE_DOUBLE_CHECK_DATA "Make sarg double check the data it manipulates and output a warning if an error is found" OFF)
 372
 373 # Save the configuration for the project
 374 CONFIGURE_FILE("${CMAKE_SOURCE_DIR}/include/config.h.in" "${CMAKE_BINARY_DIR}/config.h" @ONLY)
 375
 376 # Installation of the project
 377 INSTALL(TARGETS sarg DESTINATION "${BINDIR}")
 378 INSTALL(FILES sarg.conf DESTINATION "${SYSCONFDIR}" RENAME sarg.conf.exemple)
 379 INSTALL(FILES exclude_codes user_limit_block css.tpl DESTINATION "${SYSCONFDIR}")
 380 INSTALL(FILES sarg.1 DESTINATION "${MANDIR}")
 381 INSTALL(DIRECTORY images/ DESTINATION "${IMAGEDIR}" PATTERN ".svn" EXCLUDE)
 382 INSTALL(DIRECTORY fonts/ DESTINATION "${FONTDIR}" FILES_MATCHING PATTERN "*.ttf" PATTERN ".svn" EXCLUDE)
 383 INSTALL(DIRECTORY sarg-php/ DESTINATION "${SARGPHPDIR}" PATTERN ".svn" EXCLUDE)
 384
 385 # Package creation
 386 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Squid Analysis Report Generator")
 387 SET(CPACK_PACKAGE_VERSION_MAJOR "${sarg_VERSION}")
 388 SET(CPACK_PACKAGE_VERSION_MINOR "${sarg_REVISION}")
 389 SET(CPACK_PACKAGE_VERSION_PATCH "${sarg_BUILD}")
 390 SET(CPACK_GENERATOR TGZ)
 391 SET(CPACK_SOURCE_GENERATOR TGZ)
 392 SET(CPACK_SOURCE_IGNORE_FILES "/.svn/" "/debian/" "/html/" "Makefile$" "config\\\\.log$" "config\\\\.status$" ".*~$" "\\\\.o$")
 393 INCLUDE(CPack)