Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-dso        do not compile in any native shared-library methods. This
  63 #               will ensure that all methods just return NULL.
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # enable-weak-ssl-ciphers
  70 #               Enable weak ciphers that are disabled by default.
  71 # 386           generate 80386 code in assembly modules
  72 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  73 #               mentioned '386' option implies this one
  74 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  75 # -<xxx> +<xxx> compiler options are passed through
  76 # -static       while -static is also a pass-through compiler option (and
  77 #               as such is limited to environments where it's actually
  78 #               meaningful), it triggers a number configuration options,
  79 #               namely no-dso, no-pic, no-shared and no-threads. It is
  80 #               argued that the only reason to produce statically linked
  81 #               binaries (and in context it means executables linked with
  82 #               -static flag, and not just executables linked with static
  83 #               libcrypto.a) is to eliminate dependency on specific run-time,
  84 #               a.k.a. libc version. The mentioned config options are meant
  85 #               to achieve just that. Unfortunately on Linux it's impossible
  86 #               to eliminate the dependency completely for openssl executable
  87 #               because of getaddrinfo and gethostbyname calls, which can
  88 #               invoke dynamically loadable library facility anyway to meet
  89 #               the lookup requests. For this reason on Linux statically
  90 #               linked openssl executable has rather debugging value than
  91 #               production quality.
  92 #
  93 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  94 #               provided to stack calls. Generates unique stack functions for
  95 #               each possible stack type.
  96 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  97 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  98 # Following are set automatically by this script
  99 #
 100 # MD5_ASM       use some extra md5 assembler,
 101 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 102 # RMD160_ASM    use some extra ripemd160 assembler,
 103 # SHA256_ASM    sha256_block is implemented in assembler
 104 # SHA512_ASM    sha512_block is implemented in assembler
 105 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 106
 107 # Minimum warning options... any contributions to OpenSSL should at least get
 108 # past these.
 109
 110 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 111 # -DPEDANTIC complements -pedantic and is meant to mask code that
 112 # is not strictly standard-compliant and/or implementation-specific,
 113 # e.g. inline assembly, disregards to alignment requirements, such
 114 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 115 # to be used even in sanitized builds, because sanitizer too is
 116 # supposed to and does take notice of non-standard behaviour. Then
 117 # -pedantic with pre-C9x compiler would also complain about 'long
 118 # long' not being supported. As 64-bit algorithms are common now,
 119 # it grew impossible to resolve this without sizeable additional
 120 # code, so we just tell compiler to be pedantic about everything
 121 # but 'long long' type.
 122
 123 my %gcc_devteam_warn = ();
 124 {
 125     my @common = qw( -DDEBUG_UNUSED
 126                      -DPEDANTIC -pedantic -Wno-long-long
 127                      -Wall
 128                      -Wextra
 129                      -Wno-unused-parameter
 130                      -Wno-missing-field-initializers
 131                      -Wswitch
 132                      -Wsign-compare
 133                      -Wshadow
 134                      -Wformat
 135                      -Wtype-limits
 136                      -Wundef
 137                      -Werror );
 138     %gcc_devteam_warn = (
 139         CFLAGS          => [ @common, qw( -Wmissing-prototypes
 140                                           -Wstrict-prototypes ) ],
 141         CXXFLAGS        => [ @common ]
 142     );
 143 }
 144
 145 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 146 # TODO(openssl-team): fix problems and investigate if (at least) the
 147 # following warnings can also be enabled:
 148 #       -Wcast-align
 149 #       -Wunreachable-code -- no, too ugly/compiler-specific
 150 #       -Wlanguage-extension-token -- no, we use asm()
 151 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 152 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 153 my %clang_devteam_warn = ();
 154 {
 155     my @common = qw( -Wswitch-default
 156                      -Wno-parentheses-equality
 157                      -Wno-language-extension-token
 158                      -Wno-extended-offsetof
 159                      -Wconditional-uninitialized
 160                      -Wincompatible-pointer-types-discards-qualifiers
 161                      -Wno-unknown-warning-option );
 162     %clang_devteam_warn = (
 163         CFLAGS          => [ @common, qw( -Wmissing-variable-declarations ) ],
 164         CXXFLAGS        => [ @common ]
 165     );
 166 }
 167
 168 # This adds backtrace information to the memory leak info.  Is only used
 169 # when crypto-mdebug-backtrace is enabled.
 170 my $memleak_devteam_backtrace = "-rdynamic";
 171
 172 my $strict_warnings = 0;
 173
 174 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 175 # which would cover all BSD flavors. -pthread applies to them all,
 176 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 177 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 178 # which has to be accompanied by explicit -D_THREAD_SAFE and
 179 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 180 # seems to be sufficient?
 181 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 182
 183 #
 184 # API compatibility name to version number mapping.
 185 #
 186 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 187 my $apitable = {
 188     "3.0.0" => 3,
 189     "1.1.1" => 2,
 190     "1.1.0" => 2,
 191     "1.0.2" => 1,
 192     "1.0.1" => 1,
 193     "1.0.0" => 1,
 194     "0.9.8" => 0,
 195 };
 196
 197 our %table = ();
 198 our %config = ();
 199 our %withargs = ();
 200 our $now_printing;      # set to current entry's name in print_table_entry
 201                         # (todo: right thing would be to encapsulate name
 202                         # into %target [class] and make print_table_entry
 203                         # a method)
 204
 205 # Forward declarations ###############################################
 206
 207 # read_config(filename)
 208 #
 209 # Reads a configuration file and populates %table with the contents
 210 # (which the configuration file places in %targets).
 211 sub read_config;
 212
 213 # resolve_config(target)
 214 #
 215 # Resolves all the late evaluations, inheritances and so on for the
 216 # chosen target and any target it inherits from.
 217 sub resolve_config;
 218
 219
 220 # Information collection #############################################
 221
 222 # Unified build supports separate build dir
 223 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 224 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 225 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 226
 227 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 228
 229 $config{sourcedir} = abs2rel($srcdir);
 230 $config{builddir} = abs2rel($blddir);
 231
 232 # Collect reconfiguration information if needed
 233 my @argvcopy=@ARGV;
 234
 235 if (grep /^reconf(igure)?$/, @argvcopy) {
 236     die "reconfiguring with other arguments present isn't supported"
 237         if scalar @argvcopy > 1;
 238     if (-f "./configdata.pm") {
 239         my $file = "./configdata.pm";
 240         unless (my $return = do $file) {
 241             die "couldn't parse $file: $@" if $@;
 242             die "couldn't do $file: $!"    unless defined $return;
 243             die "couldn't run $file"       unless $return;
 244         }
 245
 246         @argvcopy = defined($configdata::config{perlargv}) ?
 247             @{$configdata::config{perlargv}} : ();
 248         die "Incorrect data to reconfigure, please do a normal configuration\n"
 249             if (grep(/^reconf/,@argvcopy));
 250         $config{perlenv} = $configdata::config{perlenv} // {};
 251     } else {
 252         die "Insufficient data to reconfigure, please do a normal configuration\n";
 253     }
 254 }
 255
 256 $config{perlargv} = [ @argvcopy ];
 257
 258 # Collect version numbers
 259 $config{major} = "unknown";
 260 $config{minor} = "unknown";
 261 $config{patch} = "unknown";
 262 $config{prerelease} = "";
 263 $config{build_metadata} = "";
 264 $config{shlib_version} = "unknown";
 265
 266 collect_information(
 267     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 268     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 269         sub { $config{major} = $1; },
 270     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 271         sub { $config{minor} = $1; },
 272     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 273         sub { $config{patch} = $1; },
 274     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 275         sub { $config{prerelease} = $1; },
 276     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 277         sub { $config{build_metadata} = $1; },
 278     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 279         sub { $config{shlib_version} = $1; },
 280     );
 281 die "erroneous version information in opensslv.h: ",
 282     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 283     if ($config{major} eq "unknown"
 284             || $config{minor} eq "unknown"
 285             || $config{patch} eq "unknown"
 286             || $config{shlib_version} eq "unknown");
 287
 288 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 289 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 290
 291 # Collect target configurations
 292
 293 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 294 foreach (sort glob($pattern)) {
 295     &read_config($_);
 296 }
 297
 298 if (defined env($local_config_envname)) {
 299     if ($^O eq 'VMS') {
 300         # VMS environment variables are logical names,
 301         # which can be used as is
 302         $pattern = $local_config_envname . ':' . '*.conf';
 303     } else {
 304         $pattern = catfile(env($local_config_envname), '*.conf');
 305     }
 306
 307     foreach (sort glob($pattern)) {
 308         &read_config($_);
 309     }
 310 }
 311
 312 # Save away perl command information
 313 $config{perl_cmd} = $^X;
 314 $config{perl_version} = $Config{version};
 315 $config{perl_archname} = $Config{archname};
 316
 317 $config{prefix}="";
 318 $config{openssldir}="";
 319 $config{processor}="";
 320 $config{libdir}="";
 321 my $auto_threads=1;    # enable threads automatically? true by default
 322 my $default_ranlib;
 323
 324 # Known TLS and DTLS protocols
 325 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 326 my @dtls = qw(dtls1 dtls1_2);
 327
 328 # Explicitly known options that are possible to disable.  They can
 329 # be regexps, and will be used like this: /^no-${option}$/
 330 # For developers: keep it sorted alphabetically
 331
 332 my @disablables = (
 333     "ktls",
 334     "afalgeng",
 335     "aria",
 336     "asan",
 337     "asm",
 338     "async",
 339     "autoalginit",
 340     "autoerrinit",
 341     "autoload-config",
 342     "bf",
 343     "blake2",
 344     "camellia",
 345     "capieng",
 346     "cast",
 347     "chacha",
 348     "cmac",
 349     "cms",
 350     "comp",
 351     "crypto-mdebug",
 352     "crypto-mdebug-backtrace",
 353     "ct",
 354     "deprecated",
 355     "des",
 356     "devcryptoeng",
 357     "dgram",
 358     "dh",
 359     "dsa",
 360     "dso",
 361     "dtls",
 362     "dynamic-engine",
 363     "ec",
 364     "ec2m",
 365     "ecdh",
 366     "ecdsa",
 367     "ec_nistp_64_gcc_128",
 368     "egd",
 369     "engine",
 370     "err",
 371     "external-tests",
 372     "filenames",
 373     "fuzz-libfuzzer",
 374     "fuzz-afl",
 375     "gost",
 376     "heartbeats",
 377     "idea",
 378     "makedepend",
 379     "md2",
 380     "md4",
 381     "mdc2",
 382     "msan",
 383     "multiblock",
 384     "nextprotoneg",
 385     "pinshared",
 386     "ocb",
 387     "ocsp",
 388     "padlockeng",
 389     "pic",
 390     "poly1305",
 391     "posix-io",
 392     "psk",
 393     "rc2",
 394     "rc4",
 395     "rc5",
 396     "rdrand",
 397     "rfc3779",
 398     "rmd160",
 399     "scrypt",
 400     "sctp",
 401     "seed",
 402     "shared",
 403     "siphash",
 404     "siv",
 405     "sm2",
 406     "sm3",
 407     "sm4",
 408     "sock",
 409     "srp",
 410     "srtp",
 411     "sse2",
 412     "ssl",
 413     "ssl-trace",
 414     "static-engine",
 415     "stdio",
 416     "tests",
 417     "threads",
 418     "tls",
 419     "ts",
 420     "ubsan",
 421     "ui-console",
 422     "unit-test",
 423     "whirlpool",
 424     "weak-ssl-ciphers",
 425     "zlib",
 426     "zlib-dynamic",
 427     );
 428 foreach my $proto ((@tls, @dtls))
 429         {
 430         push(@disablables, $proto);
 431         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 432         }
 433
 434 my %deprecated_disablables = (
 435     "ssl2" => undef,
 436     "buf-freelists" => undef,
 437     "hw" => "hw",               # causes cascade, but no macro
 438     "hw-padlock" => "padlockeng",
 439     "ripemd" => "rmd160",
 440     "ui" => "ui-console",
 441     );
 442
 443 # All of the following are disabled by default:
 444
 445 our %disabled = ( # "what"         => "comment"
 446                   "asan"                => "default",
 447                   "crypto-mdebug"       => "default",
 448                   "crypto-mdebug-backtrace" => "default",
 449                   "devcryptoeng"        => "default",
 450                   "ec_nistp_64_gcc_128" => "default",
 451                   "egd"                 => "default",
 452                   "external-tests"      => "default",
 453                   "fuzz-libfuzzer"      => "default",
 454                   "fuzz-afl"            => "default",
 455                   "heartbeats"          => "default",
 456                   "md2"                 => "default",
 457                   "msan"                => "default",
 458                   "rc5"                 => "default",
 459                   "sctp"                => "default",
 460                   "ssl-trace"           => "default",
 461                   "ssl3"                => "default",
 462                   "ssl3-method"         => "default",
 463                   "ubsan"               => "default",
 464                   "unit-test"           => "default",
 465                   "weak-ssl-ciphers"    => "default",
 466                   "zlib"                => "default",
 467                   "zlib-dynamic"        => "default",
 468                   "ktls"                => "default",
 469                 );
 470
 471 # Note: => pair form used for aesthetics, not to truly make a hash table
 472 my @disable_cascades = (
 473     # "what"            => [ "cascade", ... ]
 474     sub { $config{processor} eq "386" }
 475                         => [ "sse2" ],
 476     "ssl"               => [ "ssl3" ],
 477     "ssl3-method"       => [ "ssl3" ],
 478     "zlib"              => [ "zlib-dynamic" ],
 479     "des"               => [ "mdc2" ],
 480     "ec"                => [ "ecdsa", "ecdh" ],
 481
 482     "dgram"             => [ "dtls", "sctp" ],
 483     "sock"              => [ "dgram" ],
 484     "dtls"              => [ @dtls ],
 485     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 486                         => [ "dtls" ],
 487
 488     "tls"               => [ @tls ],
 489     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 490                         => [ "tls" ],
 491
 492     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 493
 494     # Without DSO, we can't load dynamic engines, so don't build them dynamic
 495     "dso"               => [ "dynamic-engine" ],
 496
 497     # Without position independent code, there can be no shared libraries or DSOs
 498     "pic"               => [ "shared" ],
 499     "shared"            => [ "dynamic-engine" ],
 500
 501     "engine"            => [ grep /eng$/, @disablables ],
 502     "hw"                => [ "padlockeng" ],
 503
 504     # no-autoalginit is only useful when building non-shared
 505     "autoalginit"       => [ "shared", "apps" ],
 506
 507     "stdio"             => [ "apps", "capieng", "egd" ],
 508     "apps"              => [ "tests" ],
 509     "tests"             => [ "external-tests" ],
 510     "comp"              => [ "zlib" ],
 511     "ec"                => [ "tls1_3", "sm2" ],
 512     "sm3"               => [ "sm2" ],
 513     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 514
 515     sub { !$disabled{"msan"} } => [ "asm" ],
 516
 517     sub { $disabled{cmac}; } => [ "siv" ],
 518     );
 519
 520 # Avoid protocol support holes.  Also disable all versions below N, if version
 521 # N is disabled while N+1 is enabled.
 522 #
 523 my @list = (reverse @tls);
 524 while ((my $first, my $second) = (shift @list, shift @list)) {
 525     last unless @list;
 526     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 527                               => [ @list ] );
 528     unshift @list, $second;
 529 }
 530 my @list = (reverse @dtls);
 531 while ((my $first, my $second) = (shift @list, shift @list)) {
 532     last unless @list;
 533     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 534                               => [ @list ] );
 535     unshift @list, $second;
 536 }
 537
 538 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 539 # To remove something from %disabled, use "enable-foo".
 540 # For symmetry, "disable-foo" is a synonym for "no-foo".
 541
 542 &usage if ($#ARGV < 0);
 543
 544 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 545 # platform specific list separators.  Users from those platforms should
 546 # recognise those separators from how you set up the PATH to find executables.
 547 # The default is the Unix like separator, :, but as an exception, we also
 548 # support the space as separator.
 549 my $list_separator_re =
 550     { VMS           => qr/(?<!\^),/,
 551       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 552 # All the "make variables" we support
 553 # Some get pre-populated for the sake of backward compatibility
 554 # (we supported those before the change to "make variable" support.
 555 my %user = (
 556     AR          => env('AR'),
 557     ARFLAGS     => [],
 558     AS          => undef,
 559     ASFLAGS     => [],
 560     CC          => env('CC'),
 561     CFLAGS      => [ env('CFLAGS') || () ],
 562     CXX         => env('CXX'),
 563     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 564     CPP         => undef,
 565     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 566     CPPDEFINES  => [],  # Alternative for -D
 567     CPPINCLUDES => [],  # Alternative for -I
 568     CROSS_COMPILE => env('CROSS_COMPILE'),
 569     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 570     LD          => undef,
 571     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 572     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 573     MT          => undef,
 574     MTFLAGS     => [],
 575     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 576     RANLIB      => env('RANLIB'),
 577     RC          => env('RC') || env('WINDRES'),
 578     RCFLAGS     => [],
 579     RM          => undef,
 580    );
 581 # Info about what "make variables" may be prefixed with the cross compiler
 582 # prefix.  This should NEVER mention any such variable with a list for value.
 583 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 584 # The same but for flags given as Configure options.  These are *additional*
 585 # input, as opposed to the VAR=string option that override the corresponding
 586 # config target attributes
 587 my %useradd = (
 588     CPPDEFINES  => [],
 589     CPPINCLUDES => [],
 590     CPPFLAGS    => [],
 591     CFLAGS      => [],
 592     CXXFLAGS    => [],
 593     LDFLAGS     => [],
 594     LDLIBS      => [],
 595    );
 596
 597 my %user_synonyms = (
 598     HASHBANGPERL=> 'PERL',
 599     RC          => 'WINDRES',
 600    );
 601
 602 # Some target attributes have been renamed, this is the translation table
 603 my %target_attr_translate =(
 604     ar          => 'AR',
 605     as          => 'AS',
 606     cc          => 'CC',
 607     cxx         => 'CXX',
 608     cpp         => 'CPP',
 609     hashbangperl => 'HASHBANGPERL',
 610     ld          => 'LD',
 611     mt          => 'MT',
 612     ranlib      => 'RANLIB',
 613     rc          => 'RC',
 614     rm          => 'RM',
 615    );
 616
 617 # Initialisers coming from 'config' scripts
 618 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 619 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 620 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 621 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 622 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 623 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 624 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 625
 626 $config{openssl_api_defines}=[];
 627 $config{openssl_sys_defines}=[];
 628 $config{openssl_feature_defines}=[];
 629 $config{options}="";
 630 $config{build_type} = "release";
 631 my $target="";
 632
 633 my %cmdvars = ();               # Stores FOO='blah' type arguments
 634 my %unsupported_options = ();
 635 my %deprecated_options = ();
 636 # If you change this, update apps/version.c
 637 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 638 my @seed_sources = ();
 639 while (@argvcopy)
 640         {
 641         $_ = shift @argvcopy;
 642
 643         # Support env variable assignments among the options
 644         if (m|^(\w+)=(.+)?$|)
 645                 {
 646                 $cmdvars{$1} = $2;
 647                 # Every time a variable is given as a configuration argument,
 648                 # it acts as a reset if the variable.
 649                 if (exists $user{$1})
 650                         {
 651                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 652                         }
 653                 #if (exists $useradd{$1})
 654                 #       {
 655                 #       $useradd{$1} = [];
 656                 #       }
 657                 next;
 658                 }
 659
 660         # VMS is a case insensitive environment, and depending on settings
 661         # out of our control, we may receive options uppercased.  Let's
 662         # downcase at least the part before any equal sign.
 663         if ($^O eq "VMS")
 664                 {
 665                 s/^([^=]*)/lc($1)/e;
 666                 }
 667
 668         # some people just can't read the instructions, clang people have to...
 669         s/^-no-(?!integrated-as)/no-/;
 670
 671         # rewrite some options in "enable-..." form
 672         s /^-?-?shared$/enable-shared/;
 673         s /^sctp$/enable-sctp/;
 674         s /^threads$/enable-threads/;
 675         s /^zlib$/enable-zlib/;
 676         s /^zlib-dynamic$/enable-zlib-dynamic/;
 677
 678         if (/^(no|disable|enable)-(.+)$/)
 679                 {
 680                 my $word = $2;
 681                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 682                         && !exists $deprecated_disablables{$word}
 683                         && !grep { $word eq $_ } @disablables)
 684                         {
 685                         $unsupported_options{$_} = 1;
 686                         next;
 687                         }
 688                 }
 689         if (/^no-(.+)$/ || /^disable-(.+)$/)
 690                 {
 691                 foreach my $proto ((@tls, @dtls))
 692                         {
 693                         if ($1 eq "$proto-method")
 694                                 {
 695                                 $disabled{"$proto"} = "option($proto-method)";
 696                                 last;
 697                                 }
 698                         }
 699                 if ($1 eq "dtls")
 700                         {
 701                         foreach my $proto (@dtls)
 702                                 {
 703                                 $disabled{$proto} = "option(dtls)";
 704                                 }
 705                         $disabled{"dtls"} = "option(dtls)";
 706                         }
 707                 elsif ($1 eq "ssl")
 708                         {
 709                         # Last one of its kind
 710                         $disabled{"ssl3"} = "option(ssl)";
 711                         }
 712                 elsif ($1 eq "tls")
 713                         {
 714                         # XXX: Tests will fail if all SSL/TLS
 715                         # protocols are disabled.
 716                         foreach my $proto (@tls)
 717                                 {
 718                                 $disabled{$proto} = "option(tls)";
 719                                 }
 720                         }
 721                 elsif ($1 eq "static-engine")
 722                         {
 723                         delete $disabled{"dynamic-engine"};
 724                         }
 725                 elsif ($1 eq "dynamic-engine")
 726                         {
 727                         $disabled{"dynamic-engine"} = "option";
 728                         }
 729                 elsif (exists $deprecated_disablables{$1})
 730                         {
 731                         $deprecated_options{$_} = 1;
 732                         if (defined $deprecated_disablables{$1})
 733                                 {
 734                                 $disabled{$deprecated_disablables{$1}} = "option";
 735                                 }
 736                         }
 737                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 738                         {
 739                         $deprecated_options{$_} = 1;
 740                         }
 741                 else
 742                         {
 743                         $disabled{$1} = "option";
 744                         }
 745                 # No longer an automatic choice
 746                 $auto_threads = 0 if ($1 eq "threads");
 747                 }
 748         elsif (/^enable-(.+)$/)
 749                 {
 750                 if ($1 eq "static-engine")
 751                         {
 752                         $disabled{"dynamic-engine"} = "option";
 753                         }
 754                 elsif ($1 eq "dynamic-engine")
 755                         {
 756                         delete $disabled{"dynamic-engine"};
 757                         }
 758                 elsif ($1 eq "zlib-dynamic")
 759                         {
 760                         delete $disabled{"zlib"};
 761                         }
 762                 my $algo = $1;
 763                 delete $disabled{$algo};
 764
 765                 # No longer an automatic choice
 766                 $auto_threads = 0 if ($1 eq "threads");
 767                 }
 768         elsif (/^--strict-warnings$/)
 769                 {
 770                 # Pretend that our strict flags is a C flag, and replace it
 771                 # with the proper flags later on
 772                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 773                 push @{$useradd{CXXFLAGS}}, '--ossl-strict-warnings';
 774                 $strict_warnings=1;
 775                 }
 776         elsif (/^--debug$/)
 777                 {
 778                 $config{build_type} = "debug";
 779                 }
 780         elsif (/^--release$/)
 781                 {
 782                 $config{build_type} = "release";
 783                 }
 784         elsif (/^386$/)
 785                 { $config{processor}=386; }
 786         elsif (/^fips$/)
 787                 {
 788                 die "FIPS mode not supported\n";
 789                 }
 790         elsif (/^rsaref$/)
 791                 {
 792                 # No RSAref support any more since it's not needed.
 793                 # The check for the option is there so scripts aren't
 794                 # broken
 795                 }
 796         elsif (/^nofipscanistercheck$/)
 797                 {
 798                 die "FIPS mode not supported\n";
 799                 }
 800         elsif (/^[-+]/)
 801                 {
 802                 if (/^--prefix=(.*)$/)
 803                         {
 804                         $config{prefix}=$1;
 805                         die "Directory given with --prefix MUST be absolute\n"
 806                                 unless file_name_is_absolute($config{prefix});
 807                         }
 808                 elsif (/^--api=(.*)$/)
 809                         {
 810                         $config{api}=$1;
 811                         }
 812                 elsif (/^--libdir=(.*)$/)
 813                         {
 814                         $config{libdir}=$1;
 815                         }
 816                 elsif (/^--openssldir=(.*)$/)
 817                         {
 818                         $config{openssldir}=$1;
 819                         }
 820                 elsif (/^--with-zlib-lib=(.*)$/)
 821                         {
 822                         $withargs{zlib_lib}=$1;
 823                         }
 824                 elsif (/^--with-zlib-include=(.*)$/)
 825                         {
 826                         $withargs{zlib_include}=$1;
 827                         }
 828                 elsif (/^--with-fuzzer-lib=(.*)$/)
 829                         {
 830                         $withargs{fuzzer_lib}=$1;
 831                         }
 832                 elsif (/^--with-fuzzer-include=(.*)$/)
 833                         {
 834                         $withargs{fuzzer_include}=$1;
 835                         }
 836                 elsif (/^--with-rand-seed=(.*)$/)
 837                         {
 838                         foreach my $x (split(m|,|, $1))
 839                             {
 840                             die "Unknown --with-rand-seed choice $x\n"
 841                                 if ! grep { $x eq $_ } @known_seed_sources;
 842                             push @seed_sources, $x;
 843                             }
 844                         }
 845                 elsif (/^--cross-compile-prefix=(.*)$/)
 846                         {
 847                         $user{CROSS_COMPILE}=$1;
 848                         }
 849                 elsif (/^--config=(.*)$/)
 850                         {
 851                         read_config $1;
 852                         }
 853                 elsif (/^-l(.*)$/)
 854                         {
 855                         push @{$useradd{LDLIBS}}, $_;
 856                         }
 857                 elsif (/^-framework$/)
 858                         {
 859                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 860                         }
 861                 elsif (/^-L(.*)$/ or /^-Wl,/)
 862                         {
 863                         push @{$useradd{LDFLAGS}}, $_;
 864                         }
 865                 elsif (/^-rpath$/ or /^-R$/)
 866                         # -rpath is the OSF1 rpath flag
 867                         # -R is the old Solaris rpath flag
 868                         {
 869                         my $rpath = shift(@argvcopy) || "";
 870                         $rpath .= " " if $rpath ne "";
 871                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 872                         }
 873                 elsif (/^-static$/)
 874                         {
 875                         push @{$useradd{LDFLAGS}}, $_;
 876                         $disabled{"dso"} = "forced";
 877                         $disabled{"pic"} = "forced";
 878                         $disabled{"shared"} = "forced";
 879                         $disabled{"threads"} = "forced";
 880                         }
 881                 elsif (/^-D(.*)$/)
 882                         {
 883                         push @{$useradd{CPPDEFINES}}, $1;
 884                         }
 885                 elsif (/^-I(.*)$/)
 886                         {
 887                         push @{$useradd{CPPINCLUDES}}, $1;
 888                         }
 889                 elsif (/^-Wp,$/)
 890                         {
 891                         push @{$useradd{CPPFLAGS}}, $1;
 892                         }
 893                 else    # common if (/^[-+]/), just pass down...
 894                         {
 895                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 896                         push @{$useradd{CFLAGS}}, $_;
 897                         push @{$useradd{CXXFLAGS}}, $_;
 898                         }
 899                 }
 900         else
 901                 {
 902                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 903                 $target=$_;
 904                 }
 905         unless ($_ eq $target || /^no-/ || /^disable-/)
 906                 {
 907                 # "no-..." follows later after implied deactivations
 908                 # have been derived.  (Don't take this too seriously,
 909                 # we really only write OPTIONS to the Makefile out of
 910                 # nostalgia.)
 911
 912                 if ($config{options} eq "")
 913                         { $config{options} = $_; }
 914                 else
 915                         { $config{options} .= " ".$_; }
 916                 }
 917         }
 918
 919 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 920         die "***** Unsupported api compatibility level: $config{api}\n",
 921 }
 922
 923 if (keys %deprecated_options)
 924         {
 925         warn "***** Deprecated options: ",
 926                 join(", ", keys %deprecated_options), "\n";
 927         }
 928 if (keys %unsupported_options)
 929         {
 930         die "***** Unsupported options: ",
 931                 join(", ", keys %unsupported_options), "\n";
 932         }
 933
 934 # If any %useradd entry has been set, we must check that the "make
 935 # variables" haven't been set.  We start by checking of any %useradd entry
 936 # is set.
 937 if (grep { scalar @$_ > 0 } values %useradd) {
 938     # Hash of env / make variables names.  The possible values are:
 939     # 1 - "make vars"
 940     # 2 - %useradd entry set
 941     # 3 - both set
 942     my %detected_vars =
 943         map { my $v = 0;
 944               $v += 1 if $cmdvars{$_};
 945               $v += 2 if @{$useradd{$_}};
 946               $_ => $v }
 947         keys %useradd;
 948
 949     # If any of the corresponding "make variables" is set, we error
 950     if (grep { $_ & 1 } values %detected_vars) {
 951         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 952                                sort keys %detected_vars);
 953         die <<"_____";
 954 ***** Mixing make variables and additional compiler/linker flags as
 955 ***** configure command line option is not permitted.
 956 ***** Affected make variables: $names
 957 _____
 958     }
 959 }
 960
 961 # Check through all supported command line variables to see if any of them
 962 # were set, and canonicalise the values we got.  If no compiler or linker
 963 # flag or anything else that affects %useradd was set, we also check the
 964 # environment for values.
 965 my $anyuseradd =
 966     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 967 foreach (keys %user) {
 968     my $value = $cmdvars{$_};
 969     $value //= env($_) unless $anyuseradd;
 970     $value //=
 971         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 972     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 973         unless $anyuseradd;
 974
 975     if (defined $value) {
 976         if (ref $user{$_} eq 'ARRAY') {
 977             $user{$_} = [ split /$list_separator_re/, $value ];
 978         } elsif (!defined $user{$_}) {
 979             $user{$_} = $value;
 980         }
 981     }
 982 }
 983
 984 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
 985     && !$disabled{shared}
 986     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
 987     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
 988         "***** any of asan, msan or ubsan\n";
 989 }
 990
 991 my @tocheckfor = (keys %disabled);
 992 while (@tocheckfor) {
 993     my %new_tocheckfor = ();
 994     my @cascade_copy = (@disable_cascades);
 995     while (@cascade_copy) {
 996         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 997         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 998             foreach(grep { !defined($disabled{$_}) } @$descendents) {
 999                 $new_tocheckfor{$_} = 1; $disabled{$_} = "forced";
1000             }
1001         }
1002     }
1003     @tocheckfor = (keys %new_tocheckfor);
1004 }
1005
1006 our $die = sub { die @_; };
1007 if ($target eq "TABLE") {
1008     local $die = sub { warn @_; };
1009     foreach (sort keys %table) {
1010         print_table_entry($_, "TABLE");
1011     }
1012     exit 0;
1013 }
1014
1015 if ($target eq "LIST") {
1016     foreach (sort keys %table) {
1017         print $_,"\n" unless $table{$_}->{template};
1018     }
1019     exit 0;
1020 }
1021
1022 if ($target eq "HASH") {
1023     local $die = sub { warn @_; };
1024     print "%table = (\n";
1025     foreach (sort keys %table) {
1026         print_table_entry($_, "HASH");
1027     }
1028     exit 0;
1029 }
1030
1031 print "Configuring OpenSSL version $config{full_version} ";
1032 print "for target $target\n";
1033
1034 if (scalar(@seed_sources) == 0) {
1035     print "Using os-specific seed configuration\n";
1036     push @seed_sources, 'os';
1037 }
1038 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1039     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1040     warn <<_____ if scalar(@seed_sources) == 1;
1041
1042 ============================== WARNING ===============================
1043 You have selected the --with-rand-seed=none option, which effectively
1044 disables automatic reseeding of the OpenSSL random generator.
1045 All operations depending on the random generator such as creating keys
1046 will not work unless the random generator is seeded manually by the
1047 application.
1048
1049 Please read the 'Note on random number generation' section in the
1050 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1051 ============================== WARNING ===============================
1052
1053 _____
1054 }
1055 push @{$config{openssl_feature_defines}},
1056      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1057         @seed_sources;
1058
1059 # Backward compatibility?
1060 if ($target =~ m/^CygWin32(-.*)$/) {
1061     $target = "Cygwin".$1;
1062 }
1063
1064 # Support for legacy targets having a name starting with 'debug-'
1065 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1066 if ($d) {
1067     $config{build_type} = "debug";
1068
1069     # If we do not find debug-foo in the table, the target is set to foo.
1070     if (!$table{$target}) {
1071         $target = $t;
1072     }
1073 }
1074
1075 &usage if !$table{$target} || $table{$target}->{template};
1076
1077 $config{target} = $target;
1078 my %target = resolve_config($target);
1079
1080 foreach (keys %target_attr_translate) {
1081     $target{$target_attr_translate{$_}} = $target{$_}
1082         if $target{$_};
1083     delete $target{$_};
1084 }
1085
1086 %target = ( %{$table{DEFAULTS}}, %target );
1087
1088 # Make the flags to build DSOs the same as for shared libraries unless they
1089 # are already defined
1090 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1091 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1092 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1093 {
1094     my $shared_info_pl =
1095         catfile(dirname($0), "Configurations", "shared-info.pl");
1096     my %shared_info = read_eval_file($shared_info_pl);
1097     push @{$target{_conf_fname_int}}, $shared_info_pl;
1098     my $si = $target{shared_target};
1099     while (ref $si ne "HASH") {
1100         last if ! defined $si;
1101         if (ref $si eq "CODE") {
1102             $si = $si->();
1103         } else {
1104             $si = $shared_info{$si};
1105         }
1106     }
1107
1108     # Some of the 'shared_target' values don't have any entried in
1109     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1110     # template knows how to handle this.  That is currently the case for
1111     # Windows and VMS.
1112     if (defined $si) {
1113         # Just as above, copy certain shared_* attributes to the corresponding
1114         # module_ attribute unless the latter is already defined
1115         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1116         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1117         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1118         foreach (sort keys %$si) {
1119             $target{$_} = defined $target{$_}
1120                 ? add($si->{$_})->($target{$_})
1121                 : $si->{$_};
1122         }
1123     }
1124 }
1125
1126 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1127 $config{conf_files} = [ sort keys %conf_files ];
1128
1129 foreach my $feature (@{$target{disable}}) {
1130     if (exists $deprecated_disablables{$feature}) {
1131         warn "***** config $target disables deprecated feature $feature\n";
1132     } elsif (!grep { $feature eq $_ } @disablables) {
1133         die "***** config $target disables unknown feature $feature\n";
1134     }
1135     $disabled{$feature} = 'config';
1136 }
1137 foreach my $feature (@{$target{enable}}) {
1138     if ("default" eq ($disabled{$feature} // "")) {
1139         if (exists $deprecated_disablables{$feature}) {
1140             warn "***** config $target enables deprecated feature $feature\n";
1141         } elsif (!grep { $feature eq $_ } @disablables) {
1142             die "***** config $target enables unknown feature $feature\n";
1143         }
1144         delete $disabled{$feature};
1145     }
1146 }
1147
1148 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1149 $target{cxxflags}//=$target{cflags} if $target{CXX};
1150 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1151 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1152
1153 # Fill %config with values from %user, and in case those are undefined or
1154 # empty, use values from %target (acting as a default).
1155 foreach (keys %user) {
1156     my $ref_type = ref $user{$_};
1157
1158     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1159     # and a value that's to be coerced into that type.
1160     my $mkvalue = sub {
1161         my $type = shift;
1162         my $value = shift;
1163         my $undef_p = shift;
1164
1165         die "Too many arguments for \$mkvalue" if @_;
1166
1167         while (ref $value eq 'CODE') {
1168             $value = $value->();
1169         }
1170
1171         if ($type eq 'ARRAY') {
1172             return undef unless defined $value;
1173             return undef if ref $value ne 'ARRAY' && !$value;
1174             return undef if ref $value eq 'ARRAY' && !@$value;
1175             return [ $value ] unless ref $value eq 'ARRAY';
1176         }
1177         return undef unless $value;
1178         return $value;
1179     };
1180
1181     $config{$_} =
1182         $mkvalue->($ref_type, $user{$_})
1183         || $mkvalue->($ref_type, $target{$_});
1184     delete $config{$_} unless defined $config{$_};
1185 }
1186
1187 # Allow overriding the build file name
1188 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1189
1190 ######################################################################
1191 # Build up information for skipping certain directories depending on disabled
1192 # features, as well as setting up macros for disabled features.
1193
1194 # This is a tentative database of directories to skip.  Some entries may not
1195 # correspond to anything real, but that's ok, they will simply be ignored.
1196 # The actual processing of these entries is done in the build.info lookup
1197 # loop further down.
1198 #
1199 # The key is a Unix formated path in the source tree, the value is an index
1200 # into %disabled_info, so any existing path gets added to a corresponding
1201 # 'skipped' entry in there with the list of skipped directories.
1202 my %skipdir = ();
1203 my %disabled_info = ();         # For configdata.pm
1204 foreach my $what (sort keys %disabled) {
1205     # There are deprecated disablables that translate to themselves.
1206     # They cause disabling cascades, but should otherwise not regiter.
1207     next if $deprecated_disablables{$what};
1208
1209     $config{options} .= " no-$what";
1210
1211     if (!grep { $what eq $_ } ( 'dso', 'threads', 'shared', 'pic',
1212                                 'dynamic-engine', 'makedepend',
1213                                 'zlib-dynamic', 'zlib', 'sse2' )) {
1214         (my $WHAT = uc $what) =~ s|-|_|g;
1215         my $skipdir = $what;
1216
1217         # fix-up crypto/directory name(s)
1218         $skipdir = "ripemd" if $what eq "rmd160";
1219         $skipdir = "whrlpool" if $what eq "whirlpool";
1220
1221         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1222         push @{$config{openssl_feature_defines}}, $macro;
1223
1224         $skipdir{engines} = $what if $what eq 'engine';
1225         $skipdir{"crypto/$skipdir"} = $what
1226             unless $what eq 'async' || $what eq 'err';
1227     }
1228 }
1229
1230 # Make sure build_scheme is consistent.
1231 $target{build_scheme} = [ $target{build_scheme} ]
1232     if ref($target{build_scheme}) ne "ARRAY";
1233
1234 my ($builder, $builder_platform, @builder_opts) =
1235     @{$target{build_scheme}};
1236
1237 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1238                       $builder_platform."-checker.pm")) {
1239     my $checker_path = catfile($srcdir, "Configurations", $checker);
1240     if (-f $checker_path) {
1241         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1242             ? sub { warn $@; } : sub { die $@; };
1243         if (! do $checker_path) {
1244             if ($@) {
1245                 $fn->($@);
1246             } elsif ($!) {
1247                 $fn->($!);
1248             } else {
1249                 $fn->("The detected tools didn't match the platform\n");
1250             }
1251         }
1252         last;
1253     }
1254 }
1255
1256 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1257
1258 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1259         {
1260         push @{$config{cflags}}, "-mno-cygwin";
1261         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1262         push @{$config{shared_ldflag}}, "-mno-cygwin";
1263         }
1264
1265 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1266         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$user{CFLAGS}},
1267                                             @{$useradd{CFLAGS}})) {
1268         # minimally required architecture flags for assembly modules
1269         my $value;
1270         $value = '-mips2' if ($target =~ /mips32/);
1271         $value = '-mips3' if ($target =~ /mips64/);
1272         unshift @{$config{cflags}}, $value;
1273         unshift @{$config{cxxflags}}, $value if $config{CXX};
1274 }
1275
1276 # If threads aren't disabled, check how possible they are
1277 unless ($disabled{threads}) {
1278     if ($auto_threads) {
1279         # Enabled by default, disable it forcibly if unavailable
1280         if ($target{thread_scheme} eq "(unknown)") {
1281             $disabled{threads} = "unavailable";
1282         }
1283     } else {
1284         # The user chose to enable threads explicitly, let's see
1285         # if there's a chance that's possible
1286         if ($target{thread_scheme} eq "(unknown)") {
1287             # If the user asked for "threads" and we don't have internal
1288             # knowledge how to do it, [s]he is expected to provide any
1289             # system-dependent compiler options that are necessary.  We
1290             # can't truly check that the given options are correct, but
1291             # we expect the user to know what [s]He is doing.
1292             if (!@{$user{CFLAGS}} && !@{$useradd{CFLAGS}}
1293                     && !@{$user{CPPDEFINES}} && !@{$useradd{CPPDEFINES}}) {
1294                 die "You asked for multi-threading support, but didn't\n"
1295                     ,"provide any system-specific compiler options\n";
1296             }
1297         }
1298     }
1299 }
1300
1301 # If threads still aren't disabled, add a C macro to ensure the source
1302 # code knows about it.  Any other flag is taken care of by the configs.
1303 unless($disabled{threads}) {
1304     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1305 }
1306
1307 # With "deprecated" disable all deprecated features.
1308 if (defined($disabled{"deprecated"})) {
1309         $config{api} = $maxapi;
1310 }
1311
1312 my $no_shared_warn=0;
1313 if ($target{shared_target} eq "")
1314         {
1315         $no_shared_warn = 1
1316             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1317         $disabled{shared} = "no-shared-target";
1318         $disabled{pic} = $disabled{shared} = $disabled{"dynamic-engine"} =
1319             "no-shared-target";
1320         }
1321
1322 if ($disabled{"dynamic-engine"}) {
1323         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1324         $config{dynamic_engines} = 0;
1325 } else {
1326         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1327         $config{dynamic_engines} = 1;
1328 }
1329
1330 unless ($disabled{asan}) {
1331     push @{$config{cflags}}, "-fsanitize=address";
1332     push @{$config{cxxflags}}, "-fsanitize=address" if $config{CXX};
1333 }
1334
1335 unless ($disabled{ubsan}) {
1336     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1337     # platforms.
1338     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1339     push @{$config{cxxflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all"
1340         if $config{CXX};
1341 }
1342
1343 unless ($disabled{msan}) {
1344   push @{$config{cflags}}, "-fsanitize=memory";
1345   push @{$config{cxxflags}}, "-fsanitize=memory" if $config{CXX};
1346 }
1347
1348 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1349         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1350     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1351     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1352 }
1353 #
1354 # Platform fix-ups
1355 #
1356
1357 # This saves the build files from having to check
1358 if ($disabled{pic})
1359         {
1360         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1361                     shared_defines shared_includes shared_ldflag
1362                     module_cflags module_cxxflags module_cppflags
1363                     module_defines module_includes module_lflags))
1364                 {
1365                 delete $config{$_};
1366                 $target{$_} = "";
1367                 }
1368         }
1369 else
1370         {
1371         push @{$config{lib_defines}}, "OPENSSL_PIC";
1372         }
1373
1374 if ($target{sys_id} ne "")
1375         {
1376         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1377         }
1378
1379 unless ($disabled{asm}) {
1380     $target{cpuid_asm_src}=$table{DEFAULTS}->{cpuid_asm_src} if ($config{processor} eq "386");
1381     push @{$config{lib_defines}}, "OPENSSL_CPUID_OBJ" if ($target{cpuid_asm_src} ne "mem_clr.c");
1382
1383     $target{bn_asm_src} =~ s/\w+-gf2m.c// if (defined($disabled{ec2m}));
1384
1385     # bn-586 is the only one implementing bn_*_part_words
1386     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_PART_WORDS" if ($target{bn_asm_src} =~ /bn-586/);
1387     push @{$config{lib_defines}}, "OPENSSL_IA32_SSE2" if (!$disabled{sse2} && $target{bn_asm_src} =~ /86/);
1388
1389     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT" if ($target{bn_asm_src} =~ /-mont/);
1390     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_MONT5" if ($target{bn_asm_src} =~ /-mont5/);
1391     push @{$config{lib_defines}}, "OPENSSL_BN_ASM_GF2m" if ($target{bn_asm_src} =~ /-gf2m/);
1392     push @{$config{lib_defines}}, "BN_DIV3W" if ($target{bn_asm_src} =~ /-div3w/);
1393
1394     if ($target{sha1_asm_src}) {
1395         push @{$config{lib_defines}}, "SHA1_ASM"   if ($target{sha1_asm_src} =~ /sx86/ || $target{sha1_asm_src} =~ /sha1/);
1396         push @{$config{lib_defines}}, "SHA256_ASM" if ($target{sha1_asm_src} =~ /sha256/);
1397         push @{$config{lib_defines}}, "SHA512_ASM" if ($target{sha1_asm_src} =~ /sha512/);
1398     }
1399     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1400         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1401     }
1402     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1403         push @{$config{lib_defines}}, "RC4_ASM";
1404     }
1405     if ($target{md5_asm_src}) {
1406         push @{$config{lib_defines}}, "MD5_ASM";
1407     }
1408     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1409     if ($target{rmd160_asm_src}) {
1410         push @{$config{lib_defines}}, "RMD160_ASM";
1411     }
1412     if ($target{aes_asm_src}) {
1413         push @{$config{lib_defines}}, "AES_ASM" if ($target{aes_asm_src} =~ m/\baes-/);;
1414         # aes-ctr.fake is not a real file, only indication that assembler
1415         # module implements AES_ctr32_encrypt...
1416         push @{$config{lib_defines}}, "AES_CTR_ASM" if ($target{aes_asm_src} =~ s/\s*aes-ctr\.fake//);
1417         # aes-xts.fake indicates presence of AES_xts_[en|de]crypt...
1418         push @{$config{lib_defines}}, "AES_XTS_ASM" if ($target{aes_asm_src} =~ s/\s*aes-xts\.fake//);
1419         $target{aes_asm_src} =~ s/\s*(vpaes|aesni)-x86\.s//g if ($disabled{sse2});
1420         push @{$config{lib_defines}}, "VPAES_ASM" if ($target{aes_asm_src} =~ m/vpaes/);
1421         push @{$config{lib_defines}}, "BSAES_ASM" if ($target{aes_asm_src} =~ m/bsaes/);
1422     }
1423     if ($target{wp_asm_src} =~ /mmx/) {
1424         if ($config{processor} eq "386") {
1425             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1426         } elsif (!$disabled{"whirlpool"}) {
1427             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1428         }
1429     }
1430     if ($target{modes_asm_src} =~ /ghash-/) {
1431         push @{$config{lib_defines}}, "GHASH_ASM";
1432     }
1433     if ($target{ec_asm_src} =~ /ecp_nistz256/) {
1434         push @{$config{lib_defines}}, "ECP_NISTZ256_ASM";
1435     }
1436     if ($target{ec_asm_src} =~ /x25519/) {
1437         push @{$config{lib_defines}}, "X25519_ASM";
1438     }
1439     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1440         push @{$config{dso_defines}}, "PADLOCK_ASM";
1441     }
1442     if ($target{poly1305_asm_src} ne "") {
1443         push @{$config{lib_defines}}, "POLY1305_ASM";
1444     }
1445 }
1446
1447 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1448 my %predefined_CXX = $config{CXX}
1449     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1450     : ();
1451
1452 # Check for makedepend capabilities.
1453 if (!$disabled{makedepend}) {
1454     if ($config{target} =~ /^(VC|vms)-/) {
1455         # For VC- and vms- targets, there's nothing more to do here.  The
1456         # functionality is hard coded in the corresponding build files for
1457         # cl (Windows) and CC/DECC (VMS).
1458     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1459              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1460         # We know that GNU C version 3 and up as well as all clang
1461         # versions support dependency generation, but Xcode did not
1462         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1463         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1464     } else {
1465         # In all other cases, we look for 'makedepend', and disable the
1466         # capability if not found.
1467         $config{makedepprog} = which('makedepend');
1468         $disabled{makedepend} = "unavailable" unless $config{makedepprog};
1469     }
1470 }
1471
1472 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1473     # probe for -Wa,--noexecstack option...
1474     if ($predefined_C{__clang__}) {
1475         # clang has builtin assembler, which doesn't recognize --help,
1476         # but it apparently recognizes the option in question on all
1477         # supported platforms even when it's meaningless. In other words
1478         # probe would fail, but probed option always accepted...
1479         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1480     } else {
1481         my $cc = $config{CROSS_COMPILE}.$config{CC};
1482         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1483         while(<PIPE>) {
1484             if (m/--noexecstack/) {
1485                 push @{$config{cflags}}, "-Wa,--noexecstack";
1486                 last;
1487             }
1488         }
1489         close(PIPE);
1490         unlink("null.$$.o");
1491     }
1492 }
1493
1494 # Deal with bn_ops ###################################################
1495
1496 $config{bn_ll}                  =0;
1497 $config{export_var_as_fn}       =0;
1498 my $def_int="unsigned int";
1499 $config{rc4_int}                =$def_int;
1500 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1501
1502 my $count = 0;
1503 foreach (sort split(/\s+/,$target{bn_ops})) {
1504     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1505     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1506     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1507     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1508     ($config{b64l},$config{b64},$config{b32})
1509         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1510     ($config{b64l},$config{b64},$config{b32})
1511         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1512     ($config{b64l},$config{b64},$config{b32})
1513         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1514 }
1515 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1516     if $count > 1;
1517
1518
1519 # Hack cflags for better warnings (dev option) #######################
1520
1521 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1522 # a string and works as well on command lines.
1523 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1524                         @{$config{cflags}} ];
1525 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1526                           @{$config{cxxflags}} ] if $config{CXX};
1527
1528 $config{openssl_api_defines} = [
1529     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1530 ];
1531
1532 my %strict_warnings_collection=( CFLAGS => [], CXXFLAGS => []);
1533 if ($strict_warnings)
1534         {
1535         my $wopt;
1536         my $gccver = $predefined_C{__GNUC__} // -1;
1537         my $gxxver = $predefined_CXX{__GNUC__} // -1;
1538
1539         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1540             unless $gccver >= 4;
1541         warn "WARNING --strict-warnings requires g++[>=4] or g++-alike"
1542             unless $gxxver >= 4;
1543         foreach (qw(CFLAGS CXXFLAGS))
1544                 {
1545                 push @{$strict_warnings_collection{$_}},
1546                         @{$gcc_devteam_warn{$_}};
1547                 }
1548         push @{$strict_warnings_collection{CFLAGS}},
1549                 @{$clang_devteam_warn{CFLAGS}}
1550                         if (defined($predefined_C{__clang__}));
1551         push @{$strict_warnings_collection{CXXFLAGS}},
1552                 @{$clang_devteam_warn{CXXFLAGS}}
1553                         if (defined($predefined_CXX{__clang__}));
1554         }
1555 foreach my $idx (qw(CFLAGS CXXFLAGS))
1556         {
1557         $useradd{$idx} = [ map { $_ eq '--ossl-strict-warnings'
1558                                      ? @{$strict_warnings_collection{$idx}}
1559                                      : ( $_ ) }
1560                                @{$useradd{$idx}} ];
1561         }
1562
1563 unless ($disabled{"crypto-mdebug-backtrace"})
1564         {
1565         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1566                 {
1567                 push @{$config{cflags}}, $wopt
1568                         unless grep { $_ eq $wopt } @{$config{cflags}};
1569                 push @{$config{cxxflags}}, $wopt
1570                         if ($config{CXX}
1571                             && !grep { $_ eq $wopt } @{$config{cxxflags}});
1572                 }
1573         if ($target =~ /^BSD-/)
1574                 {
1575                 push @{$config{ex_libs}}, "-lexecinfo";
1576                 }
1577         }
1578
1579 unless ($disabled{afalgeng}) {
1580     $config{afalgeng}="";
1581     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1582         my $minver = 4*10000 + 1*100 + 0;
1583         if ($config{CROSS_COMPILE} eq "") {
1584             my $verstr = `uname -r`;
1585             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1586             ($mi2) = $mi2 =~ /(\d+)/;
1587             my $ver = $ma*10000 + $mi1*100 + $mi2;
1588             if ($ver < $minver) {
1589                 $disabled{afalgeng} = "too-old-kernel";
1590             } else {
1591                 push @{$config{engdirs}}, "afalg";
1592             }
1593         } else {
1594             $disabled{afalgeng} = "cross-compiling";
1595         }
1596     } else {
1597         $disabled{afalgeng}  = "not-linux";
1598     }
1599 }
1600
1601 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1602
1603 unless ($disabled{ktls}) {
1604     $config{ktls}="";
1605     if ($target =~ m/^linux/) {
1606         my $usr = "/usr/$config{cross_compile_prefix}";
1607         chop($usr);
1608         if ($config{cross_compile_prefix} eq "") {
1609             $usr = "/usr";
1610         }
1611         my $minver = (4 << 16) + (13 << 8) + 0;
1612         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1613
1614         if ($verstr[2] < $minver) {
1615             $disabled{ktls} = "too-old-kernel";
1616         }
1617     } else {
1618         $disabled{ktls}  = "not-linux";
1619     }
1620 }
1621
1622 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1623
1624 # Finish up %config by appending things the user gave us on the command line
1625 # apart from "make variables"
1626 foreach (keys %useradd) {
1627     # The must all be lists, so we assert that here
1628     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1629         unless ref $useradd{$_} eq 'ARRAY';
1630
1631     if (defined $config{$_}) {
1632         push @{$config{$_}}, @{$useradd{$_}};
1633     } else {
1634         $config{$_} = [ @{$useradd{$_}} ];
1635     }
1636 }
1637
1638 # ALL MODIFICATIONS TO %config and %target MUST BE DONE FROM HERE ON
1639
1640 # If we use the unified build, collect information from build.info files
1641 my %unified_info = ();
1642
1643 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1644 if ($builder eq "unified") {
1645     use with_fallback qw(Text::Template);
1646
1647     sub cleandir {
1648         my $base = shift;
1649         my $dir = shift;
1650         my $relativeto = shift || ".";
1651
1652         $dir = catdir($base,$dir) unless isabsolute($dir);
1653
1654         # Make sure the directories we're building in exists
1655         mkpath($dir);
1656
1657         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1658         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1659         return $res;
1660     }
1661
1662     sub cleanfile {
1663         my $base = shift;
1664         my $file = shift;
1665         my $relativeto = shift || ".";
1666
1667         $file = catfile($base,$file) unless isabsolute($file);
1668
1669         my $d = dirname($file);
1670         my $f = basename($file);
1671
1672         # Make sure the directories we're building in exists
1673         mkpath($d);
1674
1675         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1676         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1677         return $res;
1678     }
1679
1680     # Store the name of the template file we will build the build file from
1681     # in %config.  This may be useful for the build file itself.
1682     my @build_file_template_names =
1683         ( $builder_platform."-".$target{build_file}.".tmpl",
1684           $target{build_file}.".tmpl" );
1685     my @build_file_templates = ();
1686
1687     # First, look in the user provided directory, if given
1688     if (defined env($local_config_envname)) {
1689         @build_file_templates =
1690             map {
1691                 if ($^O eq 'VMS') {
1692                     # VMS environment variables are logical names,
1693                     # which can be used as is
1694                     $local_config_envname . ':' . $_;
1695                 } else {
1696                     catfile(env($local_config_envname), $_);
1697                 }
1698             }
1699             @build_file_template_names;
1700     }
1701     # Then, look in our standard directory
1702     push @build_file_templates,
1703         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1704           @build_file_template_names );
1705
1706     my $build_file_template;
1707     for $_ (@build_file_templates) {
1708         $build_file_template = $_;
1709         last if -f $build_file_template;
1710
1711         $build_file_template = undef;
1712     }
1713     if (!defined $build_file_template) {
1714         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1715     }
1716     $config{build_file_templates}
1717       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1718                     $blddir),
1719           $build_file_template,
1720           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1721                     $blddir) ];
1722
1723     my @build_dirs = ( [ ] );   # current directory
1724
1725     $config{build_infos} = [ ];
1726
1727     my %ordinals = ();
1728     while (@build_dirs) {
1729         my @curd = @{shift @build_dirs};
1730         my $sourced = catdir($srcdir, @curd);
1731         my $buildd = catdir($blddir, @curd);
1732
1733         my $unixdir = join('/', @curd);
1734         if (exists $skipdir{$unixdir}) {
1735             my $what = $skipdir{$unixdir};
1736             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1737             next;
1738         }
1739
1740         mkpath($buildd);
1741
1742         my $f = 'build.info';
1743         # The basic things we're trying to build
1744         my @programs = ();
1745         my @libraries = ();
1746         my @modules = ();
1747         my @scripts = ();
1748
1749         my %attributes = ();
1750         my %sources = ();
1751         my %shared_sources = ();
1752         my %includes = ();
1753         my %defines = ();
1754         my %depends = ();
1755         my %generate = ();
1756
1757         # We want to detect configdata.pm in the source tree, so we
1758         # don't use it if the build tree is different.
1759         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1760
1761         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1762         my $template =
1763             Text::Template->new(TYPE => 'FILE',
1764                                 SOURCE => catfile($sourced, $f),
1765                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1766         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1767         my @text =
1768             split /^/m,
1769             $template->fill_in(HASH => { config => \%config,
1770                                          target => \%target,
1771                                          disabled => \%disabled,
1772                                          withargs => \%withargs,
1773                                          builddir => abs2rel($buildd, $blddir),
1774                                          sourcedir => abs2rel($sourced, $blddir),
1775                                          buildtop => abs2rel($blddir, $blddir),
1776                                          sourcetop => abs2rel($srcdir, $blddir) },
1777                                DELIMITERS => [ "{-", "-}" ]);
1778
1779         # The top item of this stack has the following values
1780         # -2 positive already run and we found ELSE (following ELSIF should fail)
1781         # -1 positive already run (skip until ENDIF)
1782         # 0 negatives so far (if we're at a condition, check it)
1783         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1784         # 2 positive ELSE (following ELSIF should fail)
1785         my @skip = ();
1786         collect_information(
1787             collect_from_array([ @text ],
1788                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1789                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1790             # Info we're looking for
1791             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1792             => sub {
1793                 if (! @skip || $skip[$#skip] > 0) {
1794                     push @skip, !! $1;
1795                 } else {
1796                     push @skip, -1;
1797                 }
1798             },
1799             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1800             => sub { die "ELSIF out of scope" if ! @skip;
1801                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1802                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1803                      $skip[$#skip] = !! $1
1804                          if $skip[$#skip] == 0; },
1805             qr/^\s*ELSE\s*$/
1806             => sub { die "ELSE out of scope" if ! @skip;
1807                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1808                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1809             qr/^\s*ENDIF\s*$/
1810             => sub { die "ENDIF out of scope" if ! @skip;
1811                      pop @skip; },
1812             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1813             => sub {
1814                 if (!@skip || $skip[$#skip] > 0) {
1815                     foreach (tokenize($1)) {
1816                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1817                     }
1818                 }
1819             },
1820             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1821             => sub {
1822                 if (!@skip || $skip[$#skip] > 0) {
1823                     my @a = tokenize($1, qr|\s*,\s*|);
1824                     my @p = tokenize($2);
1825                     push @programs, @p;
1826                     foreach my $a (@a) {
1827                         my $ak = $a;
1828                         my $av = 1;
1829                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1830                             $ak = $1;
1831                             $av = $2;
1832                         }
1833                         foreach my $p (@p) {
1834                             $attributes{$p}->{$ak} = $av;
1835                         }
1836                     }
1837                 }
1838             },
1839             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1840             => sub {
1841                 if (!@skip || $skip[$#skip] > 0) {
1842                     my @a = tokenize($1, qr|\s*,\s*|);
1843                     my @l = tokenize($2);
1844                     push @libraries, @l;
1845                     foreach my $a (@a) {
1846                         my $ak = $a;
1847                         my $av = 1;
1848                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1849                             $ak = $1;
1850                             $av = $2;
1851                         }
1852                         foreach my $l (@l) {
1853                             $attributes{$l}->{$ak} = $av;
1854                         }
1855                     }
1856                 }
1857             },
1858             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1859             => sub {
1860                 if (!@skip || $skip[$#skip] > 0) {
1861                     my @a = tokenize($1, qr|\s*,\s*|);
1862                     my @m = tokenize($2);
1863                     push @modules, @m;
1864                     foreach my $a (@a) {
1865                         my $ak = $a;
1866                         my $av = 1;
1867                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1868                             $ak = $1;
1869                             $av = $2;
1870                         }
1871                         foreach my $m (@m) {
1872                             $attributes{$m}->{$ak} = $av;
1873                         }
1874                     }
1875                 }
1876             },
1877             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1878             => sub {
1879                 if (!@skip || $skip[$#skip] > 0) {
1880                     my @a = tokenize($1, qr|\s*,\s*|);
1881                     my @s = tokenize($2);
1882                     push @scripts, @s;
1883                     foreach my $a (@a) {
1884                         my $ak = $a;
1885                         my $av = 1;
1886                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1887                             $ak = $1;
1888                             $av = $2;
1889                         }
1890                         foreach my $s (@s) {
1891                             $attributes{$s}->{$ak} = $av;
1892                         }
1893                     }
1894                 }
1895             },
1896
1897             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1898             => sub { push @{$ordinals{$1}}, tokenize($2)
1899                          if !@skip || $skip[$#skip] > 0 },
1900             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1901             => sub { push @{$sources{$1}}, tokenize($2)
1902                          if !@skip || $skip[$#skip] > 0 },
1903             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1904             => sub { push @{$shared_sources{$1}}, tokenize($2)
1905                          if !@skip || $skip[$#skip] > 0 },
1906             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1907             => sub { push @{$includes{$1}}, tokenize($2)
1908                          if !@skip || $skip[$#skip] > 0 },
1909             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1910             => sub { push @{$defines{$1}}, tokenize($2)
1911                          if !@skip || $skip[$#skip] > 0 },
1912             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1913             => sub { push @{$depends{$1}}, tokenize($2)
1914                          if !@skip || $skip[$#skip] > 0 },
1915             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1916             => sub { push @{$generate{$1}}, $2
1917                          if !@skip || $skip[$#skip] > 0 },
1918             qr/^\s*(?:#.*)?$/ => sub { },
1919             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1920             "BEFORE" => sub {
1921                 if ($buildinfo_debug) {
1922                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1923                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1924                 }
1925             },
1926             "AFTER" => sub {
1927                 if ($buildinfo_debug) {
1928                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1929                 }
1930             },
1931             );
1932         die "runaway IF?" if (@skip);
1933
1934         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1935                 and !$config{dynamic_engines}) {
1936             die <<"EOF"
1937 ENGINES can only be used if configured with 'dynamic-engine'.
1938 This is usually a fault in a build.info file.
1939 EOF
1940         }
1941
1942         foreach (keys %attributes) {
1943             my $dest = $_;
1944             my $ddest = cleanfile($buildd, $_, $blddir);
1945             foreach (keys %{$attributes{$dest} // {}}) {
1946                 $unified_info{attributes}->{$ddest}->{$_} =
1947                     $attributes{$dest}->{$_};
1948             }
1949         }
1950
1951         {
1952             my %infos = ( programs  => [ @programs  ],
1953                           libraries => [ @libraries ],
1954                           modules   => [ @modules   ],
1955                           scripts   => [ @scripts   ] );
1956             foreach my $k (keys %infos) {
1957                 foreach (@{$infos{$k}}) {
1958                     my $item = cleanfile($buildd, $_, $blddir);
1959                     $unified_info{$k}->{$item} = 1;
1960                 }
1961             }
1962         }
1963
1964         # Check that we haven't defined any library as both shared and
1965         # explicitly static.  That is forbidden.
1966         my @doubles = ();
1967         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1968             (my $l = $_) =~ s/\.a$//;
1969             push @doubles, $l if defined $unified_info{libraries}->{$l};
1970         }
1971         die "these libraries are both explicitly static and shared:\n  ",
1972             join(" ", @doubles), "\n"
1973             if @doubles;
1974
1975         foreach (keys %sources) {
1976             my $dest = $_;
1977             my $ddest = cleanfile($buildd, $_, $blddir);
1978             foreach (@{$sources{$dest}}) {
1979                 my $s = cleanfile($sourced, $_, $blddir);
1980
1981                 # If it isn't in the source tree, we assume it's generated
1982                 # in the build tree
1983                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
1984                     $s = cleanfile($buildd, $_, $blddir);
1985                 }
1986                 # We recognise C++, C and asm files
1987                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
1988                     my $o = $_;
1989                     $o =~ s/\.[csS]$/.o/; # C and assembler
1990                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
1991                     $o = cleanfile($buildd, $o, $blddir);
1992                     $unified_info{sources}->{$ddest}->{$o} = -1;
1993                     $unified_info{sources}->{$o}->{$s} = -1;
1994                 } elsif ($s =~ /\.rc$/) {
1995                     # We also recognise resource files
1996                     my $o = $_;
1997                     $o =~ s/\.rc$/.res/; # Resource configuration
1998                     my $o = cleanfile($buildd, $o, $blddir);
1999                     $unified_info{sources}->{$ddest}->{$o} = -1;
2000                     $unified_info{sources}->{$o}->{$s} = -1;
2001                 } else {
2002                     $unified_info{sources}->{$ddest}->{$s} = 1;
2003                 }
2004             }
2005         }
2006
2007         foreach (keys %shared_sources) {
2008             my $dest = $_;
2009             my $ddest = cleanfile($buildd, $_, $blddir);
2010             foreach (@{$shared_sources{$dest}}) {
2011                 my $s = cleanfile($sourced, $_, $blddir);
2012
2013                 # If it isn't in the source tree, we assume it's generated
2014                 # in the build tree
2015                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2016                     $s = cleanfile($buildd, $_, $blddir);
2017                 }
2018
2019                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2020                     # We recognise C++, C and asm files
2021                     my $o = $_;
2022                     $o =~ s/\.[csS]$/.o/; # C and assembler
2023                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2024                     $o = cleanfile($buildd, $o, $blddir);
2025                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2026                     $unified_info{sources}->{$o}->{$s} = -1;
2027                 } elsif ($s =~ /\.rc$/) {
2028                     # We also recognise resource files
2029                     my $o = $_;
2030                     $o =~ s/\.rc$/.res/; # Resource configuration
2031                     my $o = cleanfile($buildd, $o, $blddir);
2032                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2033                     $unified_info{sources}->{$o}->{$s} = -1;
2034                 } elsif ($s =~ /\.ld$/) {
2035                     # We also recognise linker scripts (or corresponding)
2036                     # We know they are generated files
2037                     my $ld = cleanfile($buildd, $_, $blddir);
2038                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2039                 } else {
2040                     die "unrecognised source file type for shared library: $s\n";
2041                 }
2042             }
2043         }
2044
2045         foreach (keys %generate) {
2046             my $dest = $_;
2047             my $ddest = cleanfile($buildd, $_, $blddir);
2048             die "more than one generator for $dest: "
2049                     ,join(" ", @{$generate{$_}}),"\n"
2050                     if scalar @{$generate{$_}} > 1;
2051             my @generator = split /\s+/, $generate{$dest}->[0];
2052             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2053             $unified_info{generate}->{$ddest} = [ @generator ];
2054         }
2055
2056         foreach (keys %depends) {
2057             my $dest = $_;
2058             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2059
2060             # If the destination doesn't exist in source, it can only be
2061             # a generated file in the build tree.
2062             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2063                 $ddest = cleanfile($buildd, $_, $blddir);
2064             }
2065             foreach (@{$depends{$dest}}) {
2066                 my $d = cleanfile($sourced, $_, $blddir);
2067
2068                 # If we know it's generated, or assume it is because we can't
2069                 # find it in the source tree, we set file we depend on to be
2070                 # in the build tree rather than the source tree, and assume
2071                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2072                 # section or in the Makefile template.
2073                 if ($d eq $src_configdata
2074                     || ! -f $d
2075                     || (grep { $d eq $_ }
2076                         map { cleanfile($srcdir, $_, $blddir) }
2077                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2078                     $d = cleanfile($buildd, $_, $blddir);
2079                 }
2080                 # Take note if the file to depend on is being renamed
2081                 # Take extra care with files ending with .a, they should
2082                 # be treated without that extension, and the extension
2083                 # should be added back after treatment.
2084                 $d =~ /(\.a)?$/;
2085                 my $e = $1 // "";
2086                 $d = $`.$e;
2087                 $unified_info{depends}->{$ddest}->{$d} = 1;
2088             }
2089         }
2090
2091         foreach (keys %includes) {
2092             my $dest = $_;
2093             my $ddest = cleanfile($sourced, $_, $blddir);
2094
2095             # If the destination doesn't exist in source, it can only be
2096             # a generated file in the build tree.
2097             if ($ddest eq $src_configdata || ! -f $ddest) {
2098                 $ddest = cleanfile($buildd, $_, $blddir);
2099             }
2100             foreach (@{$includes{$dest}}) {
2101                 my $is = cleandir($sourced, $_, $blddir);
2102                 my $ib = cleandir($buildd, $_, $blddir);
2103                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2104                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2105                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2106                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2107             }
2108         }
2109
2110         foreach (keys %defines) {
2111             my $dest = $_;
2112             my $ddest = cleanfile($sourced, $_, $blddir);
2113
2114             # If the destination doesn't exist in source, it can only be
2115             # a generated file in the build tree.
2116             if (! -f $ddest) {
2117                 $ddest = cleanfile($buildd, $_, $blddir);
2118                 if ($unified_info{rename}->{$ddest}) {
2119                     $ddest = $unified_info{rename}->{$ddest};
2120                 }
2121             }
2122             foreach (@{$defines{$dest}}) {
2123                 m|^([^=]*)(=.*)?$|;
2124                 die "0 length macro name not permitted\n" if $1 eq "";
2125                 die "$1 defined more than once\n"
2126                     if defined $unified_info{defines}->{$ddest}->{$1};
2127                 $unified_info{defines}->{$ddest}->{$1} = $2;
2128             }
2129         }
2130     }
2131
2132     my $ordinals_text = join(', ', sort keys %ordinals);
2133     warn <<"EOF" if $ordinals_text;
2134
2135 WARNING: ORDINALS were specified for $ordinals_text
2136 They are ignored and should be replaced with a combination of GENERATE,
2137 DEPEND and SHARED_SOURCE.
2138 EOF
2139
2140     # Massage the result
2141
2142     # If we depend on a header file or a perl module, add an inclusion of
2143     # its directory to allow smoothe inclusion
2144     foreach my $dest (keys %{$unified_info{depends}}) {
2145         next if $dest eq "";
2146         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2147             next unless $d =~ /\.(h|pm)$/;
2148             my $i = dirname($d);
2149             my $spot =
2150                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2151                 ? 'build' : 'source';
2152             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2153                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2154         }
2155     }
2156
2157     # Go through all intermediary files and change their names to something that
2158     # reflects what they will be built for.  Note that for some source files,
2159     # this leads to duplicate object files because they are used multiple times.
2160     # the goal is to rename all object files according to this scheme:
2161     #    {productname}-{midfix}-{origobjname}.[o|res]
2162     # the {midfix} is a keyword indicating the type of product, which is mostly
2163     # valuable for libraries since they come in two forms.
2164     #
2165     # This also reorganises the {sources} and {shared_sources} so that the
2166     # former only contains ALL object files that are supposed to end up in
2167     # static libraries and programs, while the latter contains ALL object files
2168     # that are supposed to end up in shared libraries and DSOs.
2169     # The main reason for having two different source structures is to allow
2170     # the same name to be used for the static and the shared variants of a
2171     # library.
2172     {
2173         # Take copies so we don't get interference from added stuff
2174         my %unified_copy = ();
2175         foreach (('sources', 'shared_sources')) {
2176             $unified_copy{$_} = { %{$unified_info{$_}} }
2177                 if defined($unified_info{$_});
2178             delete $unified_info{$_};
2179         }
2180         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2181             # $intent serves multi purposes:
2182             # - give a prefix for the new object files names
2183             # - in the case of libraries, rearrange the object files so static
2184             #   libraries use the 'sources' structure exclusively, while shared
2185             #   libraries use the 'shared_sources' structure exclusively.
2186             my $intent = {
2187                 programs  => { bin    => { src => [ 'sources' ],
2188                                            dst => 'sources' } },
2189                 libraries => { lib    => { src => [ 'sources' ],
2190                                            dst => 'sources' },
2191                                shlib  => { prodselect =>
2192                                                sub { grep !/\.a$/, @_ },
2193                                            src => [ 'sources',
2194                                                     'shared_sources' ],
2195                                            dst => 'shared_sources' } },
2196                 modules   => { dso    => { src => [ 'sources',
2197                                                     'shared_sources' ],
2198                                            dst => 'shared_sources' } },
2199                 scripts   => { script => { src => [ 'sources' ],
2200                                            dst => 'sources' } }
2201                } -> {$prodtype};
2202             foreach my $kind (keys %$intent) {
2203                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2204                              && $disabled{shared});
2205
2206                 my @src = @{$intent->{$kind}->{src}};
2207                 my $dst = $intent->{$kind}->{dst};
2208                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2209                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2210                     # %prod_sources has all applicable objects as keys, and
2211                     # their corresponding sources as values
2212                     my %prod_sources =
2213                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2214                         map { keys %{$unified_copy{$_}->{$prod}} }
2215                         @src;
2216                     foreach (keys %prod_sources) {
2217                         # Only affect object files and resource files,
2218                         # the others simply get a new value
2219                         # (+1 instead of -1)
2220                         if ($_ =~ /\.(o|res)$/) {
2221                             (my $prodname = $prod) =~ s|\.a$||;
2222                             my $newobj =
2223                                 catfile(dirname($_),
2224                                         basename($prodname)
2225                                             . '-' . $kind
2226                                             . '-' . basename($_));
2227                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2228                             foreach my $src (@{$prod_sources{$_}}) {
2229                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2230                             }
2231                             # Adjust dependencies
2232                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2233                                 $unified_info{depends}->{$_}->{$deps} = -1;
2234                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2235                             }
2236                             # Adjust includes
2237                             foreach my $k (('source', 'build')) {
2238                                 next unless
2239                                     defined($unified_info{includes}->{$_}->{$k});
2240                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2241                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2242                             }
2243                         } else {
2244                             $unified_info{$dst}->{$prod}->{$_} = 1;
2245                         }
2246                     }
2247                 }
2248             }
2249         }
2250     }
2251     # At this point, we have a number of sources with the value -1.  They
2252     # aren't part of the local build and are probably meant for a different
2253     # platform, and can therefore be cleaned away.  That happens when making
2254     # %unified_info more efficient below.
2255
2256     ### Make unified_info a bit more efficient
2257     # One level structures
2258     foreach (("programs", "libraries", "modules", "scripts")) {
2259         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2260     }
2261     # Two level structures
2262     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2263         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2264             my @items =
2265                 sort
2266                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2267                 keys %{$unified_info{$l1}->{$l2}};
2268             if (@items) {
2269                 $unified_info{$l1}->{$l2} = [ @items ];
2270             } else {
2271                 delete $unified_info{$l1}->{$l2};
2272             }
2273         }
2274     }
2275     # Defines
2276     foreach my $dest (sort keys %{$unified_info{defines}}) {
2277         $unified_info{defines}->{$dest}
2278             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2279                 sort keys %{$unified_info{defines}->{$dest}} ];
2280     }
2281     # Includes
2282     foreach my $dest (sort keys %{$unified_info{includes}}) {
2283         if (defined($unified_info{includes}->{$dest}->{build})) {
2284             my @source_includes = ();
2285             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2286                 if defined($unified_info{includes}->{$dest}->{source});
2287             $unified_info{includes}->{$dest} =
2288                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2289             foreach my $inc (@source_includes) {
2290                 push @{$unified_info{includes}->{$dest}}, $inc
2291                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2292             }
2293         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2294             $unified_info{includes}->{$dest} =
2295                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2296         } else {
2297             delete $unified_info{includes}->{$dest};
2298         }
2299     }
2300
2301     # For convenience collect information regarding directories where
2302     # files are generated, those generated files and the end product
2303     # they end up in where applicable.  Then, add build rules for those
2304     # directories
2305     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2306                      "dso" => [ @{$unified_info{modules}} ],
2307                      "bin" => [ @{$unified_info{programs}} ],
2308                      "script" => [ @{$unified_info{scripts}} ] );
2309     foreach my $type (keys %loopinfo) {
2310         foreach my $product (@{$loopinfo{$type}}) {
2311             my %dirs = ();
2312             my $pd = dirname($product);
2313
2314             foreach (@{$unified_info{sources}->{$product} // []},
2315                      @{$unified_info{shared_sources}->{$product} // []}) {
2316                 my $d = dirname($_);
2317
2318                 # We don't want to create targets for source directories
2319                 # when building out of source
2320                 next if ($config{sourcedir} ne $config{builddir}
2321                              && $d =~ m|^\Q$config{sourcedir}\E|);
2322                 # We already have a "test" target, and the current directory
2323                 # is just silly to make a target for
2324                 next if $d eq "test" || $d eq ".";
2325
2326                 $dirs{$d} = 1;
2327                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2328                     if $d ne $pd;
2329             }
2330             foreach (keys %dirs) {
2331                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2332                     $product;
2333             }
2334         }
2335     }
2336 }
2337
2338 # For the schemes that need it, we provide the old *_obj configs
2339 # from the *_asm_obj ones
2340 foreach (grep /_(asm|aux)_src$/, keys %target) {
2341     my $src = $_;
2342     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2343     $target{$obj} = $target{$src};
2344     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2345     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2346 }
2347
2348 # Write down our configuration where it fits #########################
2349
2350 print "Creating configdata.pm\n";
2351 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2352 print OUT <<"EOF";
2353 #! $config{HASHBANGPERL}
2354
2355 package configdata;
2356
2357 use strict;
2358 use warnings;
2359
2360 use Exporter;
2361 #use vars qw(\@ISA \@EXPORT);
2362 our \@ISA = qw(Exporter);
2363 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables);
2364
2365 EOF
2366 print OUT "our %config = (\n";
2367 foreach (sort keys %config) {
2368     if (ref($config{$_}) eq "ARRAY") {
2369         print OUT "  ", $_, " => [ ", join(", ",
2370                                            map { quotify("perl", $_) }
2371                                            @{$config{$_}}), " ],\n";
2372     } elsif (ref($config{$_}) eq "HASH") {
2373         print OUT "  ", $_, " => {";
2374         if (scalar keys %{$config{$_}} > 0) {
2375             print OUT "\n";
2376             foreach my $key (sort keys %{$config{$_}}) {
2377                 print OUT "      ",
2378                     join(" => ",
2379                          quotify("perl", $key),
2380                          defined $config{$_}->{$key}
2381                              ? quotify("perl", $config{$_}->{$key})
2382                              : "undef");
2383                 print OUT ",\n";
2384             }
2385             print OUT "  ";
2386         }
2387         print OUT "},\n";
2388     } else {
2389         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2390     }
2391 }
2392 print OUT <<"EOF";
2393 );
2394
2395 EOF
2396 print OUT "our %target = (\n";
2397 foreach (sort keys %target) {
2398     if (ref($target{$_}) eq "ARRAY") {
2399         print OUT "  ", $_, " => [ ", join(", ",
2400                                            map { quotify("perl", $_) }
2401                                            @{$target{$_}}), " ],\n";
2402     } else {
2403         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2404     }
2405 }
2406 print OUT <<"EOF";
2407 );
2408
2409 EOF
2410 print OUT "our \%available_protocols = (\n";
2411 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2412 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2413 print OUT <<"EOF";
2414 );
2415
2416 EOF
2417 print OUT "our \@disablables = (\n";
2418 foreach (@disablables) {
2419     print OUT "  ", quotify("perl", $_), ",\n";
2420 }
2421 print OUT <<"EOF";
2422 );
2423
2424 EOF
2425 print OUT "our \%disabled = (\n";
2426 foreach (sort keys %disabled) {
2427     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2428 }
2429 print OUT <<"EOF";
2430 );
2431
2432 EOF
2433 print OUT "our %withargs = (\n";
2434 foreach (sort keys %withargs) {
2435     if (ref($withargs{$_}) eq "ARRAY") {
2436         print OUT "  ", $_, " => [ ", join(", ",
2437                                            map { quotify("perl", $_) }
2438                                            @{$withargs{$_}}), " ],\n";
2439     } else {
2440         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2441     }
2442 }
2443 print OUT <<"EOF";
2444 );
2445
2446 EOF
2447 if ($builder eq "unified") {
2448     my $recurse;
2449     $recurse = sub {
2450         my $indent = shift;
2451         foreach (@_) {
2452             if (ref $_ eq "ARRAY") {
2453                 print OUT " "x$indent, "[\n";
2454                 foreach (@$_) {
2455                     $recurse->($indent + 4, $_);
2456                 }
2457                 print OUT " "x$indent, "],\n";
2458             } elsif (ref $_ eq "HASH") {
2459                 my %h = %$_;
2460                 print OUT " "x$indent, "{\n";
2461                 foreach (sort keys %h) {
2462                     if (ref $h{$_} eq "") {
2463                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2464                     } else {
2465                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2466                         $recurse->($indent + 8, $h{$_});
2467                     }
2468                 }
2469                 print OUT " "x$indent, "},\n";
2470             } else {
2471                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2472             }
2473         }
2474     };
2475     print OUT "our %unified_info = (\n";
2476     foreach (sort keys %unified_info) {
2477         if (ref $unified_info{$_} eq "") {
2478             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2479         } else {
2480             print OUT " "x4, quotify("perl", $_), " =>\n";
2481             $recurse->(8, $unified_info{$_});
2482         }
2483     }
2484     print OUT <<"EOF";
2485 );
2486
2487 EOF
2488 }
2489 print OUT
2490     "# The following data is only used when this files is use as a script\n";
2491 print OUT "my \@makevars = (\n";
2492 foreach (sort keys %user) {
2493     print OUT "    '",$_,"',\n";
2494 }
2495 print OUT ");\n";
2496 print OUT "my \%disabled_info = (\n";
2497 foreach my $what (sort keys %disabled_info) {
2498     print OUT "    '$what' => {\n";
2499     foreach my $info (sort keys %{$disabled_info{$what}}) {
2500         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2501             print OUT "        $info => [ ",
2502                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2503                 " ],\n";
2504         } else {
2505             print OUT "        $info => '", $disabled_info{$what}->{$info},
2506                 "',\n";
2507         }
2508     }
2509     print OUT "    },\n";
2510 }
2511 print OUT ");\n";
2512 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2513 print OUT << 'EOF';
2514 # If run directly, we can give some answers, and even reconfigure
2515 unless (caller) {
2516     use Getopt::Long;
2517     use File::Spec::Functions;
2518     use File::Basename;
2519     use Pod::Usage;
2520
2521     my $here = dirname($0);
2522
2523     my $dump = undef;
2524     my $cmdline = undef;
2525     my $options = undef;
2526     my $target = undef;
2527     my $envvars = undef;
2528     my $makevars = undef;
2529     my $buildparams = undef;
2530     my $reconf = undef;
2531     my $verbose = undef;
2532     my $help = undef;
2533     my $man = undef;
2534     GetOptions('dump|d'                 => \$dump,
2535                'command-line|c'         => \$cmdline,
2536                'options|o'              => \$options,
2537                'target|t'               => \$target,
2538                'environment|e'          => \$envvars,
2539                'make-variables|m'       => \$makevars,
2540                'build-parameters|b'     => \$buildparams,
2541                'reconfigure|reconf|r'   => \$reconf,
2542                'verbose|v'              => \$verbose,
2543                'help'                   => \$help,
2544                'man'                    => \$man)
2545         or die "Errors in command line arguments\n";
2546
2547     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2548             || $buildparams || $reconf || $verbose || $help || $man) {
2549         print STDERR <<"_____";
2550 You must give at least one option.
2551 For more information, do '$0 --help'
2552 _____
2553         exit(2);
2554     }
2555
2556     if ($help) {
2557         pod2usage(-exitval => 0,
2558                   -verbose => 1);
2559     }
2560     if ($man) {
2561         pod2usage(-exitval => 0,
2562                   -verbose => 2);
2563     }
2564     if ($dump || $cmdline) {
2565         print "\nCommand line (with current working directory = $here):\n\n";
2566         print '    ',join(' ',
2567                           $config{PERL},
2568                           catfile($config{sourcedir}, 'Configure'),
2569                           @{$config{perlargv}}), "\n";
2570         print "\nPerl information:\n\n";
2571         print '    ',$config{perl_cmd},"\n";
2572         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2573     }
2574     if ($dump || $options) {
2575         my $longest = 0;
2576         my $longest2 = 0;
2577         foreach my $what (@disablables) {
2578             $longest = length($what) if $longest < length($what);
2579             $longest2 = length($disabled{$what})
2580                 if $disabled{$what} && $longest2 < length($disabled{$what});
2581         }
2582         print "\nEnabled features:\n\n";
2583         foreach my $what (@disablables) {
2584             print "    $what\n" unless $disabled{$what};
2585         }
2586         print "\nDisabled features:\n\n";
2587         foreach my $what (@disablables) {
2588             if ($disabled{$what}) {
2589                 print "    $what", ' ' x ($longest - length($what) + 1),
2590                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2591                 print $disabled_info{$what}->{macro}
2592                     if $disabled_info{$what}->{macro};
2593                 print ' (skip ',
2594                     join(', ', @{$disabled_info{$what}->{skipped}}),
2595                     ')'
2596                     if $disabled_info{$what}->{skipped};
2597                 print "\n";
2598             }
2599         }
2600     }
2601     if ($dump || $target) {
2602         print "\nConfig target attributes:\n\n";
2603         foreach (sort keys %target) {
2604             next if $_ =~ m|^_| || $_ eq 'template';
2605             my $quotify = sub {
2606                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2607             };
2608             print '    ', $_, ' => ';
2609             if (ref($target{$_}) eq "ARRAY") {
2610                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2611             } else {
2612                 print $quotify->($target{$_}), ",\n"
2613             }
2614         }
2615     }
2616     if ($dump || $envvars) {
2617         print "\nRecorded environment:\n\n";
2618         foreach (sort keys %{$config{perlenv}}) {
2619             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2620         }
2621     }
2622     if ($dump || $makevars) {
2623         print "\nMakevars:\n\n";
2624         foreach my $var (@makevars) {
2625             my $prefix = '';
2626             $prefix = $config{CROSS_COMPILE}
2627                 if grep { $var eq $_ } @user_crossable;
2628             $prefix //= '';
2629             print '    ',$var,' ' x (16 - length $var),'= ',
2630                 (ref $config{$var} eq 'ARRAY'
2631                  ? join(' ', @{$config{$var}})
2632                  : $prefix.$config{$var}),
2633                 "\n"
2634                 if defined $config{$var};
2635         }
2636
2637         my @buildfile = ($config{builddir}, $config{build_file});
2638         unshift @buildfile, $here
2639             unless file_name_is_absolute($config{builddir});
2640         my $buildfile = canonpath(catdir(@buildfile));
2641         print <<"_____";
2642
2643 NOTE: These variables only represent the configuration view.  The build file
2644 template may have processed these variables further, please have a look at the
2645 build file for more exact data:
2646     $buildfile
2647 _____
2648     }
2649     if ($dump || $buildparams) {
2650         my @buildfile = ($config{builddir}, $config{build_file});
2651         unshift @buildfile, $here
2652             unless file_name_is_absolute($config{builddir});
2653         print "\nbuild file:\n\n";
2654         print "    ", canonpath(catfile(@buildfile)),"\n";
2655
2656         print "\nbuild file templates:\n\n";
2657         foreach (@{$config{build_file_templates}}) {
2658             my @tmpl = ($_);
2659             unshift @tmpl, $here
2660                 unless file_name_is_absolute($config{sourcedir});
2661             print '    ',canonpath(catfile(@tmpl)),"\n";
2662         }
2663     }
2664     if ($reconf) {
2665         if ($verbose) {
2666             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2667             foreach (sort keys %{$config{perlenv}}) {
2668                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2669             }
2670         }
2671
2672         chdir $here;
2673         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2674     }
2675 }
2676
2677 1;
2678
2679 __END__
2680
2681 =head1 NAME
2682
2683 configdata.pm - configuration data for OpenSSL builds
2684
2685 =head1 SYNOPSIS
2686
2687 Interactive:
2688
2689   perl configdata.pm [options]
2690
2691 As data bank module:
2692
2693   use configdata;
2694
2695 =head1 DESCRIPTION
2696
2697 This module can be used in two modes, interactively and as a module containing
2698 all the data recorded by OpenSSL's Configure script.
2699
2700 When used interactively, simply run it as any perl script, with at least one
2701 option, and you will get the information you ask for.  See L</OPTIONS> below.
2702
2703 When loaded as a module, you get a few databanks with useful information to
2704 perform build related tasks.  The databanks are:
2705
2706     %config             Configured things.
2707     %target             The OpenSSL config target with all inheritances
2708                         resolved.
2709     %disabled           The features that are disabled.
2710     @disablables        The list of features that can be disabled.
2711     %withargs           All data given through --with-THING options.
2712     %unified_info       All information that was computed from the build.info
2713                         files.
2714
2715 =head1 OPTIONS
2716
2717 =over 4
2718
2719 =item B<--help>
2720
2721 Print a brief help message and exit.
2722
2723 =item B<--man>
2724
2725 Print the manual page and exit.
2726
2727 =item B<--dump> | B<-d>
2728
2729 Print all relevant configuration data.  This is equivalent to B<--command-line>
2730 B<--options> B<--target> B<--environment> B<--make-variables>
2731 B<--build-parameters>.
2732
2733 =item B<--command-line> | B<-c>
2734
2735 Print the current configuration command line.
2736
2737 =item B<--options> | B<-o>
2738
2739 Print the features, both enabled and disabled, and display defined macro and
2740 skipped directories where applicable.
2741
2742 =item B<--target> | B<-t>
2743
2744 Print the config attributes for this config target.
2745
2746 =item B<--environment> | B<-e>
2747
2748 Print the environment variables and their values at the time of configuration.
2749
2750 =item B<--make-variables> | B<-m>
2751
2752 Print the main make variables generated in the current configuration
2753
2754 =item B<--build-parameters> | B<-b>
2755
2756 Print the build parameters, i.e. build file and build file templates.
2757
2758 =item B<--reconfigure> | B<--reconf> | B<-r>
2759
2760 Redo the configuration.
2761
2762 =item B<--verbose> | B<-v>
2763
2764 Verbose output.
2765
2766 =back
2767
2768 =cut
2769
2770 EOF
2771 close(OUT);
2772 if ($builder_platform eq 'unix') {
2773     my $mode = (0755 & ~umask);
2774     chmod $mode, 'configdata.pm'
2775         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2776 }
2777
2778 my %builders = (
2779     unified => sub {
2780         print 'Creating ',$target{build_file},"\n";
2781         run_dofile(catfile($blddir, $target{build_file}),
2782                    @{$config{build_file_templates}});
2783     },
2784     );
2785
2786 $builders{$builder}->($builder_platform, @builder_opts);
2787
2788 $SIG{__DIE__} = $orig_death_handler;
2789
2790 print <<"EOF" if ($disabled{threads} eq "unavailable");
2791
2792 The library could not be configured for supporting multi-threaded
2793 applications as the compiler options required on this system are not known.
2794 See file INSTALL for details if you need multi-threading.
2795 EOF
2796
2797 print <<"EOF" if ($no_shared_warn);
2798
2799 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2800 platform, so we will pretend you gave the option 'no-pic', which also disables
2801 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2802 or position independent code, please let us know (but please first make sure
2803 you have tried with a current version of OpenSSL).
2804 EOF
2805
2806 print <<"EOF";
2807
2808 **********************************************************************
2809 ***                                                                ***
2810 ***   OpenSSL has been successfully configured                     ***
2811 ***                                                                ***
2812 ***   If you encounter a problem while building, please open an    ***
2813 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2814 ***   and include the output from the following command:           ***
2815 ***                                                                ***
2816 ***       perl configdata.pm --dump                                ***
2817 ***                                                                ***
2818 ***   (If you are new to OpenSSL, you might want to consult the    ***
2819 ***   'Troubleshooting' section in the INSTALL file first)         ***
2820 ***                                                                ***
2821 **********************************************************************
2822 EOF
2823
2824 exit(0);
2825
2826 ######################################################################
2827 #
2828 # Helpers and utility functions
2829 #
2830
2831 # Death handler, to print a helpful message in case of failure #######
2832 #
2833 sub death_handler {
2834     die @_ if $^S;              # To prevent the added message in eval blocks
2835     my $build_file = $target{build_file} // "build file";
2836     my @message = ( <<"_____", @_ );
2837
2838 Failure!  $build_file wasn't produced.
2839 Please read INSTALL and associated NOTES files.  You may also have to look over
2840 your available compiler tool chain or change your configuration.
2841
2842 _____
2843
2844     # Dying is terminal, so it's ok to reset the signal handler here.
2845     $SIG{__DIE__} = $orig_death_handler;
2846     die @message;
2847 }
2848
2849 # Configuration file reading #########################################
2850
2851 # Note: All of the helper functions are for lazy evaluation.  They all
2852 # return a CODE ref, which will return the intended value when evaluated.
2853 # Thus, whenever there's mention of a returned value, it's about that
2854 # intended value.
2855
2856 # Helper function to implement conditional inheritance depending on the
2857 # value of $disabled{asm}.  Used in inherit_from values as follows:
2858 #
2859 #      inherit_from => [ "template", asm("asm_tmpl") ]
2860 #
2861 sub asm {
2862     my @x = @_;
2863     sub {
2864         $disabled{asm} ? () : @x;
2865     }
2866 }
2867
2868 # Helper function to implement conditional value variants, with a default
2869 # plus additional values based on the value of $config{build_type}.
2870 # Arguments are given in hash table form:
2871 #
2872 #       picker(default => "Basic string: ",
2873 #              debug   => "debug",
2874 #              release => "release")
2875 #
2876 # When configuring with --debug, the resulting string will be
2877 # "Basic string: debug", and when not, it will be "Basic string: release"
2878 #
2879 # This can be used to create variants of sets of flags according to the
2880 # build type:
2881 #
2882 #       cflags => picker(default => "-Wall",
2883 #                        debug   => "-g -O0",
2884 #                        release => "-O3")
2885 #
2886 sub picker {
2887     my %opts = @_;
2888     return sub { add($opts{default} || (),
2889                      $opts{$config{build_type}} || ())->(); }
2890 }
2891
2892 # Helper function to combine several values of different types into one.
2893 # This is useful if you want to combine a string with the result of a
2894 # lazy function, such as:
2895 #
2896 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2897 #
2898 sub combine {
2899     my @stuff = @_;
2900     return sub { add(@stuff)->(); }
2901 }
2902
2903 # Helper function to implement conditional values depending on the value
2904 # of $disabled{threads}.  Can be used as follows:
2905 #
2906 #       cflags => combine("-Wall", threads("-pthread"))
2907 #
2908 sub threads {
2909     my @flags = @_;
2910     return sub { add($disabled{threads} ? () : @flags)->(); }
2911 }
2912
2913 sub shared {
2914     my @flags = @_;
2915     return sub { add($disabled{shared} ? () : @flags)->(); }
2916 }
2917
2918 our $add_called = 0;
2919 # Helper function to implement adding values to already existing configuration
2920 # values.  It handles elements that are ARRAYs, CODEs and scalars
2921 sub _add {
2922     my $separator = shift;
2923
2924     # If there's any ARRAY in the collection of values OR the separator
2925     # is undef, we will return an ARRAY of combined values, otherwise a
2926     # string of joined values with $separator as the separator.
2927     my $found_array = !defined($separator);
2928
2929     my @values =
2930         map {
2931             my $res = $_;
2932             while (ref($res) eq "CODE") {
2933                 $res = $res->();
2934             }
2935             if (defined($res)) {
2936                 if (ref($res) eq "ARRAY") {
2937                     $found_array = 1;
2938                     @$res;
2939                 } else {
2940                     $res;
2941                 }
2942             } else {
2943                 ();
2944             }
2945     } (@_);
2946
2947     $add_called = 1;
2948
2949     if ($found_array) {
2950         [ @values ];
2951     } else {
2952         join($separator, grep { defined($_) && $_ ne "" } @values);
2953     }
2954 }
2955 sub add_before {
2956     my $separator = " ";
2957     if (ref($_[$#_]) eq "HASH") {
2958         my $opts = pop;
2959         $separator = $opts->{separator};
2960     }
2961     my @x = @_;
2962     sub { _add($separator, @x, @_) };
2963 }
2964 sub add {
2965     my $separator = " ";
2966     if (ref($_[$#_]) eq "HASH") {
2967         my $opts = pop;
2968         $separator = $opts->{separator};
2969     }
2970     my @x = @_;
2971     sub { _add($separator, @_, @x) };
2972 }
2973
2974 sub read_eval_file {
2975     my $fname = shift;
2976     my $content;
2977     my @result;
2978
2979     open F, "< $fname" or die "Can't open '$fname': $!\n";
2980     {
2981         undef local $/;
2982         $content = <F>;
2983     }
2984     close F;
2985     {
2986         local $@;
2987
2988         @result = ( eval $content );
2989         warn $@ if $@;
2990     }
2991     return wantarray ? @result : $result[0];
2992 }
2993
2994 # configuration reader, evaluates the input file as a perl script and expects
2995 # it to fill %targets with target configurations.  Those are then added to
2996 # %table.
2997 sub read_config {
2998     my $fname = shift;
2999     my %targets;
3000
3001     {
3002         # Protect certain tables from tampering
3003         local %table = ();
3004
3005         %targets = read_eval_file($fname);
3006     }
3007     my %preexisting = ();
3008     foreach (sort keys %targets) {
3009         $preexisting{$_} = 1 if $table{$_};
3010     }
3011     die <<"EOF",
3012 The following config targets from $fname
3013 shadow pre-existing config targets with the same name:
3014 EOF
3015         map { "  $_\n" } sort keys %preexisting
3016         if %preexisting;
3017
3018
3019     # For each target, check that it's configured with a hash table.
3020     foreach (keys %targets) {
3021         if (ref($targets{$_}) ne "HASH") {
3022             if (ref($targets{$_}) eq "") {
3023                 warn "Deprecated target configuration for $_, ignoring...\n";
3024             } else {
3025                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3026             }
3027             delete $targets{$_};
3028         } else {
3029             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3030         }
3031     }
3032
3033     %table = (%table, %targets);
3034
3035 }
3036
3037 # configuration resolver.  Will only resolve all the lazy evaluation
3038 # codeblocks for the chosen target and all those it inherits from,
3039 # recursively
3040 sub resolve_config {
3041     my $target = shift;
3042     my @breadcrumbs = @_;
3043
3044 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3045
3046     if (grep { $_ eq $target } @breadcrumbs) {
3047         die "inherit_from loop!  target backtrace:\n  "
3048             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3049     }
3050
3051     if (!defined($table{$target})) {
3052         warn "Warning! target $target doesn't exist!\n";
3053         return ();
3054     }
3055     # Recurse through all inheritances.  They will be resolved on the
3056     # fly, so when this operation is done, they will all just be a
3057     # bunch of attributes with string values.
3058     # What we get here, though, are keys with references to lists of
3059     # the combined values of them all.  We will deal with lists after
3060     # this stage is done.
3061     my %combined_inheritance = ();
3062     if ($table{$target}->{inherit_from}) {
3063         my @inherit_from =
3064             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3065         foreach (@inherit_from) {
3066             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3067
3068             # 'template' is a marker that's considered private to
3069             # the config that had it.
3070             delete $inherited_config{template};
3071
3072             foreach (keys %inherited_config) {
3073                 if (!$combined_inheritance{$_}) {
3074                     $combined_inheritance{$_} = [];
3075                 }
3076                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3077             }
3078         }
3079     }
3080
3081     # We won't need inherit_from in this target any more, since we've
3082     # resolved all the inheritances that lead to this
3083     delete $table{$target}->{inherit_from};
3084
3085     # Now is the time to deal with those lists.  Here's the place to
3086     # decide what shall be done with those lists, all based on the
3087     # values of the target we're currently dealing with.
3088     # - If a value is a coderef, it will be executed with the list of
3089     #   inherited values as arguments.
3090     # - If the corresponding key doesn't have a value at all or is the
3091     #   empty string, the inherited value list will be run through the
3092     #   default combiner (below), and the result becomes this target's
3093     #   value.
3094     # - Otherwise, this target's value is assumed to be a string that
3095     #   will simply override the inherited list of values.
3096     my $default_combiner = add();
3097
3098     my %all_keys =
3099         map { $_ => 1 } (keys %combined_inheritance,
3100                          keys %{$table{$target}});
3101
3102     sub process_values {
3103         my $object    = shift;
3104         my $inherited = shift;  # Always a [ list ]
3105         my $target    = shift;
3106         my $entry     = shift;
3107
3108         $add_called = 0;
3109
3110         while(ref($object) eq "CODE") {
3111             $object = $object->(@$inherited);
3112         }
3113         if (!defined($object)) {
3114             return ();
3115         }
3116         elsif (ref($object) eq "ARRAY") {
3117             local $add_called;  # To make sure recursive calls don't affect it
3118             return [ map { process_values($_, $inherited, $target, $entry) }
3119                      @$object ];
3120         } elsif (ref($object) eq "") {
3121             return $object;
3122         } else {
3123             die "cannot handle reference type ",ref($object)
3124                 ," found in target ",$target," -> ",$entry,"\n";
3125         }
3126     }
3127
3128     foreach (sort keys %all_keys) {
3129         my $previous = $combined_inheritance{$_};
3130
3131         # Current target doesn't have a value for the current key?
3132         # Assign it the default combiner, the rest of this loop body
3133         # will handle it just like any other coderef.
3134         if (!exists $table{$target}->{$_}) {
3135             $table{$target}->{$_} = $default_combiner;
3136         }
3137
3138         $table{$target}->{$_} = process_values($table{$target}->{$_},
3139                                                $combined_inheritance{$_},
3140                                                $target, $_);
3141         unless(defined($table{$target}->{$_})) {
3142             delete $table{$target}->{$_};
3143         }
3144 #        if ($extra_checks &&
3145 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3146 #            warn "$_ got replaced in $target\n";
3147 #        }
3148     }
3149
3150     # Finally done, return the result.
3151     return %{$table{$target}};
3152 }
3153
3154 sub usage
3155         {
3156         print STDERR $usage;
3157         print STDERR "\npick os/compiler from:\n";
3158         my $j=0;
3159         my $i;
3160         my $k=0;
3161         foreach $i (sort keys %table)
3162                 {
3163                 next if $table{$i}->{template};
3164                 next if $i =~ /^debug/;
3165                 $k += length($i) + 1;
3166                 if ($k > 78)
3167                         {
3168                         print STDERR "\n";
3169                         $k=length($i);
3170                         }
3171                 print STDERR $i . " ";
3172                 }
3173         foreach $i (sort keys %table)
3174                 {
3175                 next if $table{$i}->{template};
3176                 next if $i !~ /^debug/;
3177                 $k += length($i) + 1;
3178                 if ($k > 78)
3179                         {
3180                         print STDERR "\n";
3181                         $k=length($i);
3182                         }
3183                 print STDERR $i . " ";
3184                 }
3185         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3186         exit(1);
3187         }
3188
3189 sub run_dofile
3190 {
3191     my $out = shift;
3192     my @templates = @_;
3193
3194     unlink $out || warn "Can't remove $out, $!"
3195         if -f $out;
3196     foreach (@templates) {
3197         die "Can't open $_, $!" unless -f $_;
3198     }
3199     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3200     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3201     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3202     system($cmd);
3203     exit 1 if $? != 0;
3204     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3205 }
3206
3207 sub compiler_predefined {
3208     state %predefined;
3209     my $cc = shift;
3210
3211     return () if $^O eq 'VMS';
3212
3213     die 'compiler_predefined called without a compiler command'
3214         unless $cc;
3215
3216     if (! $predefined{$cc}) {
3217
3218         $predefined{$cc} = {};
3219
3220         # collect compiler pre-defines from gcc or gcc-alike...
3221         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3222         while (my $l = <PIPE>) {
3223             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3224             $predefined{$cc}->{$1} = $2 // '';
3225         }
3226         close(PIPE);
3227     }
3228
3229     return %{$predefined{$cc}};
3230 }
3231
3232 sub which
3233 {
3234     my ($name)=@_;
3235
3236     if (eval { require IPC::Cmd; 1; }) {
3237         IPC::Cmd->import();
3238         return scalar IPC::Cmd::can_run($name);
3239     } else {
3240         # if there is $directories component in splitpath,
3241         # then it's not something to test with $PATH...
3242         return $name if (File::Spec->splitpath($name))[1];
3243
3244         foreach (File::Spec->path()) {
3245             my $fullpath = catfile($_, "$name$target{exe_extension}");
3246             if (-f $fullpath and -x $fullpath) {
3247                 return $fullpath;
3248             }
3249         }
3250     }
3251 }
3252
3253 sub env
3254 {
3255     my $name = shift;
3256     my %opts = @_;
3257
3258     unless ($opts{cacheonly}) {
3259         # Note that if $ENV{$name} doesn't exist or is undefined,
3260         # $config{perlenv}->{$name} will be created with the value
3261         # undef.  This is intentional.
3262
3263         $config{perlenv}->{$name} = $ENV{$name}
3264             if ! exists $config{perlenv}->{$name};
3265     }
3266     return $config{perlenv}->{$name};
3267 }
3268
3269 # Configuration printer ##############################################
3270
3271 sub print_table_entry
3272 {
3273     local $now_printing = shift;
3274     my %target = resolve_config($now_printing);
3275     my $type = shift;
3276
3277     # Don't print the templates
3278     return if $target{template};
3279
3280     my @sequence = (
3281         "sys_id",
3282         "cpp",
3283         "cppflags",
3284         "defines",
3285         "includes",
3286         "cc",
3287         "cflags",
3288         "unistd",
3289         "ld",
3290         "lflags",
3291         "loutflag",
3292         "ex_libs",
3293         "bn_ops",
3294         "apps_aux_src",
3295         "cpuid_asm_src",
3296         "uplink_aux_src",
3297         "bn_asm_src",
3298         "ec_asm_src",
3299         "des_asm_src",
3300         "aes_asm_src",
3301         "bf_asm_src",
3302         "md5_asm_src",
3303         "cast_asm_src",
3304         "sha1_asm_src",
3305         "rc4_asm_src",
3306         "rmd160_asm_src",
3307         "rc5_asm_src",
3308         "wp_asm_src",
3309         "cmll_asm_src",
3310         "modes_asm_src",
3311         "padlock_asm_src",
3312         "chacha_asm_src",
3313         "poly1035_asm_src",
3314         "thread_scheme",
3315         "perlasm_scheme",
3316         "dso_scheme",
3317         "shared_target",
3318         "shared_cflag",
3319         "shared_defines",
3320         "shared_ldflag",
3321         "shared_rcflag",
3322         "shared_extension",
3323         "dso_extension",
3324         "obj_extension",
3325         "exe_extension",
3326         "ranlib",
3327         "ar",
3328         "arflags",
3329         "aroutflag",
3330         "rc",
3331         "rcflags",
3332         "rcoutflag",
3333         "mt",
3334         "mtflags",
3335         "mtinflag",
3336         "mtoutflag",
3337         "multilib",
3338         "build_scheme",
3339         );
3340
3341     if ($type eq "TABLE") {
3342         print "\n";
3343         print "*** $now_printing\n";
3344         foreach (@sequence) {
3345             if (ref($target{$_}) eq "ARRAY") {
3346                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3347             } else {
3348                 printf "\$%-12s = %s\n", $_, $target{$_};
3349             }
3350         }
3351     } elsif ($type eq "HASH") {
3352         my $largest =
3353             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3354         print "    '$now_printing' => {\n";
3355         foreach (@sequence) {
3356             if ($target{$_}) {
3357                 if (ref($target{$_}) eq "ARRAY") {
3358                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3359                 } else {
3360                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3361                 }
3362             }
3363         }
3364         print "    },\n";
3365     }
3366 }
3367
3368 # Utility routines ###################################################
3369
3370 # On VMS, if the given file is a logical name, File::Spec::Functions
3371 # will consider it an absolute path.  There are cases when we want a
3372 # purely syntactic check without checking the environment.
3373 sub isabsolute {
3374     my $file = shift;
3375
3376     # On non-platforms, we just use file_name_is_absolute().
3377     return file_name_is_absolute($file) unless $^O eq "VMS";
3378
3379     # If the file spec includes a device or a directory spec,
3380     # file_name_is_absolute() is perfectly safe.
3381     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3382
3383     # Here, we know the given file spec isn't absolute
3384     return 0;
3385 }
3386
3387 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3388 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3389 # realpath() requires that at least all path components except the last is an
3390 # existing directory.  On VMS, the last component of the directory spec must
3391 # exist.
3392 sub absolutedir {
3393     my $dir = shift;
3394
3395     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3396     # will return the volume name for the device, no matter what.  Also,
3397     # it will return an incorrect directory spec if the argument is a
3398     # directory that doesn't exist.
3399     if ($^O eq "VMS") {
3400         return rel2abs($dir);
3401     }
3402
3403     # We use realpath() on Unix, since no other will properly clean out
3404     # a directory spec.
3405     use Cwd qw/realpath/;
3406
3407     return realpath($dir);
3408 }
3409
3410 sub quotify {
3411     my %processors = (
3412         perl    => sub { my $x = shift;
3413                          $x =~ s/([\\\$\@"])/\\$1/g;
3414                          return '"'.$x.'"'; },
3415         maybeshell => sub { my $x = shift;
3416                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3417                             if ($x ne $y || $x =~ m|\s|) {
3418                                 return '"'.$y.'"';
3419                             } else {
3420                                 return $x;
3421                             }
3422                         },
3423         );
3424     my $for = shift;
3425     my $processor =
3426         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3427
3428     return map { $processor->($_); } @_;
3429 }
3430
3431 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3432 # $filename is a file name to read from
3433 # $line_concat_cond_re is a regexp detecting a line continuation ending
3434 # $line_concat is a CODEref that takes care of concatenating two lines
3435 sub collect_from_file {
3436     my $filename = shift;
3437     my $line_concat_cond_re = shift;
3438     my $line_concat = shift;
3439
3440     open my $fh, $filename || die "unable to read $filename: $!\n";
3441     return sub {
3442         my $saved_line = "";
3443         $_ = "";
3444         while (<$fh>) {
3445             s|\R$||;
3446             if (defined $line_concat) {
3447                 $_ = $line_concat->($saved_line, $_);
3448                 $saved_line = "";
3449             }
3450             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3451                 $saved_line = $_;
3452                 next;
3453             }
3454             return $_;
3455         }
3456         die "$filename ending with continuation line\n" if $_;
3457         close $fh;
3458         return undef;
3459     }
3460 }
3461
3462 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3463 # $array is an ARRAYref of lines
3464 # $line_concat_cond_re is a regexp detecting a line continuation ending
3465 # $line_concat is a CODEref that takes care of concatenating two lines
3466 sub collect_from_array {
3467     my $array = shift;
3468     my $line_concat_cond_re = shift;
3469     my $line_concat = shift;
3470     my @array = (@$array);
3471
3472     return sub {
3473         my $saved_line = "";
3474         $_ = "";
3475         while (defined($_ = shift @array)) {
3476             s|\R$||;
3477             if (defined $line_concat) {
3478                 $_ = $line_concat->($saved_line, $_);
3479                 $saved_line = "";
3480             }
3481             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3482                 $saved_line = $_;
3483                 next;
3484             }
3485             return $_;
3486         }
3487         die "input text ending with continuation line\n" if $_;
3488         return undef;
3489     }
3490 }
3491
3492 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3493 # $lineiterator is a CODEref that delivers one line at a time.
3494 # All following arguments are regex/CODEref pairs, where the regexp detects a
3495 # line and the CODEref does something with the result of the regexp.
3496 sub collect_information {
3497     my $lineiterator = shift;
3498     my %collectors = @_;
3499
3500     while(defined($_ = $lineiterator->())) {
3501         s|\R$||;
3502         my $found = 0;
3503         if ($collectors{"BEFORE"}) {
3504             $collectors{"BEFORE"}->($_);
3505         }
3506         foreach my $re (keys %collectors) {
3507             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3508                 $collectors{$re}->($lineiterator);
3509                 $found = 1;
3510             };
3511         }
3512         if ($collectors{"OTHERWISE"}) {
3513             $collectors{"OTHERWISE"}->($lineiterator, $_)
3514                 unless $found || !defined $collectors{"OTHERWISE"};
3515         }
3516         if ($collectors{"AFTER"}) {
3517             $collectors{"AFTER"}->($_);
3518         }
3519     }
3520 }
3521
3522 # tokenize($line)
3523 # tokenize($line,$separator)
3524 # $line is a line of text to split up into tokens
3525 # $separator [optional] is a regular expression that separates the tokens,
3526 # the default being spaces.  Do not use quotes of any kind as separators,
3527 # that will give undefined results.
3528 # Returns a list of tokens.
3529 #
3530 # Tokens are divided by separator (spaces by default).  If the tokens include
3531 # the separators, they have to be quoted with single or double quotes.
3532 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3533 # with backslash.
3534 # Basically, the same quoting rules apply for " and ' as in any
3535 # Unix shell.
3536 sub tokenize {
3537     my $line = my $debug_line = shift;
3538     my $separator = shift // qr|\s+|;
3539     my @result = ();
3540
3541     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3542         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3543     }
3544
3545     while ($line =~ s|^${separator}||, $line ne "") {
3546         my $token = "";
3547     again:
3548         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3549         $token .= $1;
3550         $line = $2.$';
3551
3552         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3553             $token .= $1;
3554             $line = $';
3555             goto again;
3556         } elsif ($line =~ m/^'([^']*)'/) {
3557             $token .= $1;
3558             $line = $';
3559             goto again;
3560         }
3561         push @result, $token;
3562     }
3563
3564     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3565         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3566         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3567     }
3568     return @result;
3569 }