Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3
   4 ##
   5 ##  Configure -- OpenSSL source tree configuration script
   6 ##  If editing this file, run this command before committing
   7 ##      make -f Makefile.in TABLE
   8 ##
   9
  10 require 5.000;
  11 use strict;
  12 use File::Basename;
  13 use File::Spec::Functions;
  14
  15 # see INSTALL for instructions.
  16
  17 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [experimental-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-dso] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  18
  19 # Options:
  20 #
  21 # --config      add the given configuration file, which will be read after
  22 #               any "Configurations*" files that are found in the same
  23 #               directory as this script.
  24 # --prefix      prefix for the OpenSSL installation, which includes the
  25 #               directories bin, lib, include, share/man, share/doc/openssl
  26 #               This becomes the value of INSTALLTOP in Makefile
  27 #               (Default: /usr/local)
  28 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  29 #               If it's a relative directory, it will be added on the directory
  30 #               given with --prefix.
  31 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  32 #               (Default: PREFIX/ssl)
  33 #
  34 # --install_prefix  Additional prefix for package builders (empty by
  35 #               default).  This needn't be set in advance, you can
  36 #               just as well use "make INSTALL_PREFIX=/whatever install".
  37 #
  38 # --cross-compile-prefix Add specified prefix to binutils components.
  39 #
  40 # --api         One of 0.9.8, 1.0.0 or 1.1.0.  Do not compile support for
  41 #               interfaces deprecated as of the specified OpenSSL version.
  42 #
  43 # no-hw-xxx     do not compile support for specific crypto hardware.
  44 #               Generic OpenSSL-style methods relating to this support
  45 #               are always compiled but return NULL if the hardware
  46 #               support isn't compiled.
  47 # no-hw         do not compile support for any crypto hardware.
  48 # [no-]threads  [don't] try to create a library that is suitable for
  49 #               multithreaded applications (default is "threads" if we
  50 #               know how to do it)
  51 # [no-]shared   [don't] try to create shared libraries when supported.
  52 # no-asm        do not use assembler
  53 # no-dso        do not compile in any native shared-library methods. This
  54 #               will ensure that all methods just return NULL.
  55 # no-egd        do not compile support for the entropy-gathering daemon APIs
  56 # [no-]zlib     [don't] compile support for zlib compression.
  57 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  58 #               library and will be loaded in run-time by the OpenSSL library.
  59 # sctp          include SCTP support
  60 # 386           generate 80386 code
  61 # no-sse2       disables IA-32 SSE2 code, above option implies no-sse2
  62 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  63 # -<xxx> +<xxx> compiler options are passed through
  64 #
  65 # DEBUG_SAFESTACK use type-safe stacks to enforce type-safety on stack items
  66 #               provided to stack calls. Generates unique stack functions for
  67 #               each possible stack type.
  68 # DES_PTR       use pointer lookup vs arrays in the DES in crypto/des/des_locl.h
  69 # DES_RISC1     use different DES_ENCRYPT macro that helps reduce register
  70 #               dependancies but needs to more registers, good for RISC CPU's
  71 # DES_RISC2     A different RISC variant.
  72 # DES_UNROLL    unroll the inner DES loop, sometimes helps, somtimes hinders.
  73 # DES_INT       use 'int' instead of 'long' for DES_LONG in crypto/des/des.h
  74 #               This is used on the DEC Alpha where long is 8 bytes
  75 #               and int is 4
  76 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  77 # MD2_CHAR      use 'char' instead of 'int' for MD2_INT in crypto/md2/md2.h
  78 # MD2_LONG      use 'long' instead of 'int' for MD2_INT in crypto/md2/md2.h
  79 # IDEA_SHORT    use 'short' instead of 'int' for IDEA_INT in crypto/idea/idea.h
  80 # IDEA_LONG     use 'long' instead of 'int' for IDEA_INT in crypto/idea/idea.h
  81 # RC2_SHORT     use 'short' instead of 'int' for RC2_INT in crypto/rc2/rc2.h
  82 # RC2_LONG      use 'long' instead of 'int' for RC2_INT in crypto/rc2/rc2.h
  83 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  84 # RC4_LONG      use 'long' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  85 # RC4_INDEX     define RC4_INDEX in crypto/rc4/rc4_locl.h.  This turns on
  86 #               array lookups instead of pointer use.
  87 # RC4_CHUNK     enables code that handles data aligned at long (natural CPU
  88 #               word) boundary.
  89 # RC4_CHUNK_LL  enables code that handles data aligned at long long boundary
  90 #               (intended for 64-bit CPUs running 32-bit OS).
  91 # BF_PTR        use 'pointer arithmatic' for Blowfish (unsafe on Alpha).
  92 # BF_PTR2       intel specific version (generic version is more efficient).
  93 #
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assember,
  97 # SHA1_ASM      use some extra sha1 assember, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assember,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       ASE_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least get
 104 # past these.
 105
 106 my $gcc_devteam_warn = "-Wall -pedantic -DPEDANTIC -Wno-long-long -Wsign-compare -Wmissing-prototypes -Wshadow -Wformat -Wtype-limits -Werror -DREF_CHECK -DDEBUG_UNUSED";
 107
 108 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 109 # TODO(openssl-team): fix problems and investigate if (at least) the
 110 # following warnings can also be enabled:
 111 # -Wswitch-enum, -Wunused-macros, -Wmissing-field-initializers,
 112 # -Wcast-align,
 113 # -Wunreachable-code -Wunused-parameter -Wlanguage-extension-token
 114 # -Wextended-offsetof
 115 my $clang_devteam_warn = "-Wno-unused-parameter -Wno-missing-field-initializers -Wno-language-extension-token -Wno-extended-offsetof -Wconditional-uninitialized -Qunused-arguments -Wincompatible-pointer-types-discards-qualifiers -Wmissing-variable-declarations";
 116
 117 # Warn that "make depend" should be run?
 118 my $warn_make_depend = 0;
 119
 120 # These are used in addition to $gcc_devteam_warn unless this is a mingw build.
 121 # This adds backtrace information to the memory leak info.
 122 my $memleak_devteam_backtrace = "-rdynamic -DCRYPTO_MDEBUG_BACKTRACE";
 123
 124
 125 my $strict_warnings = 0;
 126
 127 my $x86_gcc_des="DES_PTR DES_RISC1 DES_UNROLL";
 128
 129 # MD2_CHAR slags pentium pros
 130 my $x86_gcc_opts="RC4_INDEX MD2_INT";
 131
 132 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 133 # which would cover all BSD flavors. -pthread applies to them all,
 134 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 135 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 136 # which has to be accompanied by explicit -D_THREAD_SAFE and
 137 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 138 # seems to be sufficient?
 139 my $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 140
 141 #
 142 # API compability name to version number mapping.
 143 #
 144 my $maxapi = "1.1.0";           # API for "no-deprecated" builds
 145 my $apitable = {
 146     "1.1.0" => "0x10100000L",
 147     "1.0.0" => "0x10000000L",
 148     "0.9.8" => "0x00908000L",
 149 };
 150
 151 my $base_target = "BASE";   # The template that all other inherit from
 152 our %table = ();
 153 our %config = ();
 154
 155 # Forward declarations ###############################################
 156
 157 # read_config(filename)
 158 #
 159 # Reads a configuration file and populates %table with the contents
 160 # (which the configuration file places in %targets).
 161 sub read_config;
 162
 163 # resolve_config(target)
 164 #
 165 # Resolves all the late evalutations, inheritances and so on for the
 166 # chosen target and any target it inherits from.
 167 sub resolve_config;
 168
 169
 170 # Information collection #############################################
 171
 172 # Collect version numbers
 173 $config{version} = "unknown";
 174 $config{version_num} = "unknown";
 175 $config{shlib_version_number} = "unknown";
 176 $config{shlib_version_history} = "unknown";
 177
 178 collect_information(
 179     '<include/openssl/opensslv.h',
 180     undef,
 181     qr/OPENSSL.VERSION.TEXT.*OpenSSL (\S+) / => sub { $config{version} = $1; },
 182     qr/OPENSSL.VERSION.NUMBER.*(0x\S+)/      => sub { $config{version_num}=$1 },
 183     qr/SHLIB_VERSION_NUMBER *"([^"]+)"/      => sub { $config{shlib_version_number}=$1 },
 184     qr/SHLIB_VERSION_HISTORY *"([^"]*)"/     => sub { $config{shlib_version_history}=$1 }
 185     );
 186 if ($config{shlib_version_history} ne "") { $config{shlib_version_history} .= ":"; }
 187
 188 ($config{major}, $config{minor})
 189     = ($config{version} =~ /^([0-9]+)\.([0-9\.]+)/);
 190 ($config{shlib_major}, $config{shlib_minor})
 191     = ($config{shlib_version_number} =~ /^([0-9]+)\.([0-9\.]+)/);
 192 die "erroneous version information in opensslv.h: ",
 193     "$config{major}, $config{minor}, $config{shlib_major}, $config{shlib_minor}\n"
 194     if ($config{major} eq "" || $config{minor} eq ""
 195         || $config{shlib_major} eq "" ||  $config{shlib_minor} eq "");
 196
 197 # Collect target configurations
 198
 199 my ($vol, $dir, $dummy) = File::Spec->splitpath($0);
 200 my $pattern = File::Spec->catpath($vol, $dir, "Configurations/*.conf");
 201 foreach (sort glob($pattern) ) {
 202     &read_config($_);
 203 }
 204
 205
 206 print "Configuring OpenSSL version $config{version} (0x$config{version_num})\n";
 207
 208 $config{perl};
 209 $config{prefix}="";
 210 $config{openssldir}="";
 211 $config{processor}="";
 212 $config{libdir}="";
 213 $config{install_prefix}= "$ENV{'INSTALL_PREFIX'}";
 214 $config{cross_compile_prefix}="";
 215 $config{fipslibdir}="/usr/local/ssl/fips-2.0/lib/";
 216 my $nofipscanistercheck=0;
 217 $config{baseaddr}="0xFB00000";
 218 my $no_threads=0;
 219 my $threads=0;
 220 $config{no_shared}=0; # but "no-shared" is default
 221 my $zlib=1;      # but "no-zlib" is default
 222 my $no_rfc3779=0;
 223 my $no_asm=0;
 224 my $no_dso=0;
 225 my $Makefile="Makefile";
 226 my $default_ranlib;
 227 $config{fips}=0;
 228
 229 # Top level directories to build
 230 $config{dirs} = [ "crypto", "ssl", "engines", "apps", "test", "tools" ];
 231 # crypto/ subdirectories to build
 232 $config{sdirs} = [
 233     "objects",
 234     "md2", "md4", "md5", "sha", "mdc2", "hmac", "ripemd", "whrlpool", "poly1305",
 235     "des", "aes", "rc2", "rc4", "rc5", "idea", "bf", "cast", "camellia", "seed", "chacha", "modes",
 236     "bn", "ec", "rsa", "dsa", "dh", "dso", "engine",
 237     "buffer", "bio", "stack", "lhash", "rand", "err",
 238     "evp", "asn1", "pem", "x509", "x509v3", "conf", "txt_db", "pkcs7", "pkcs12", "comp", "ocsp", "ui",
 239     "cms", "ts", "jpake", "srp", "store", "cmac", "ct", "async", "kdf"
 240     ];
 241
 242 # Known TLS and DTLS protocols
 243 my @tls = qw(ssl3 tls1 tls1_1 tls1_2);
 244 my @dtls = qw(dtls1 dtls1_2);
 245
 246 # Explicitelly known options that are possible to disable.  They can
 247 # be regexps, and will be used like this: /^no-${option}$/
 248 # For developers: keep it sorted alphabetically
 249
 250 my @disablables = (
 251     "aes",
 252     "asm",
 253     "bf",
 254     "camellia",
 255     "capieng",
 256     "cast",
 257     "chacha",
 258     "cmac",
 259     "cms",
 260     "comp",
 261     "crypto-mdebug",
 262     "ct",
 263     "deprecated",
 264     "des",
 265     "dgram",
 266     "dh",
 267     "dsa",
 268     "dso",
 269     "dtls",
 270     "dynamic[-_]engine",
 271     "ec",
 272     "ec2m",
 273     "ecdh",
 274     "ecdsa",
 275     "ec_nistp_64_gcc_128",
 276     "engine",
 277     "err",                      # Really???
 278     "heartbeats",
 279     "hmac",
 280     "hw(-.+)?",
 281     "idea",
 282     "jpake",
 283     "locking",                  # Really???
 284     "md2",
 285     "md4",
 286     "md5",
 287     "mdc2",
 288     "md[-_]ghost94",
 289     "nextprotoneg",
 290     "ocb",
 291     "ocsp",
 292     "poly1305",
 293     "posix-io",
 294     "psk",
 295     "rc2",
 296     "rc4",
 297     "rc5",
 298     "rdrand",
 299     "rfc3779",
 300     "rijndael",                 # Old AES name
 301     "rmd160",
 302     "rsa",
 303     "scrypt",
 304     "sct",
 305     "sctp",
 306     "seed",
 307     "sha",
 308     "shared",
 309     "sock",
 310     "srp",
 311     "srtp",
 312     "sse2",
 313     "ssl",
 314     "ssl-trace",
 315     "static-engine",
 316     "stdio",
 317     "store",
 318     "threads",
 319     "tls",
 320     "unit-test",
 321     "whirlpool",
 322     "zlib",
 323     "zlib-dynamic",
 324     );
 325 foreach my $proto ((@tls, @dtls))
 326         {
 327         push(@disablables, $proto);
 328         push(@disablables, "$proto-method");
 329         }
 330
 331 # All of the following is disabled by default (RC5 was enabled before 0.9.8):
 332
 333 my %disabled = ( # "what"         => "comment" [or special keyword "experimental"]
 334                  "ec_nistp_64_gcc_128" => "default",
 335                  "egd"            => "default",
 336                  "jpake"          => "experimental",
 337                  "md2"            => "default",
 338                  "rc5"            => "default",
 339                  "sctp"           => "default",
 340                  "shared"         => "default",
 341                  "ssl-trace"      => "default",
 342                  "store"          => "experimental",
 343                  "unit-test"      => "default",
 344                  "zlib"           => "default",
 345                  "zlib-dynamic"   => "default",
 346                  "crypto-mdebug"  => "default",
 347                );
 348 my @experimental = ();
 349
 350 # Note: => pair form used for aesthetics, not to truly make a hash table
 351 my @disable_cascades = (
 352     # "what"            => [ "cascade", ... ]
 353     sub { $config{processor} eq "386" }
 354                         => [ "sse2" ],
 355     "ssl"               => [ "ssl3" ],
 356     "ssl3-method"       => [ "ssl3" ],
 357     "zlib"              => [ "zlib-dynamic" ],
 358     "rijndael"          => [ "aes" ],
 359     "des"               => [ "mdc2" ],
 360     "ec"                => [ "ecdsa", "ecdh" ],
 361     "psk"               => [ "jpake" ],
 362
 363     "dgram"             => [ "dtls" ],
 364     "dtls"              => [ @dtls ],
 365
 366     # SSL 3.0, (D)TLS 1.0 and TLS 1.1 require MD5 and SHA
 367     "md5"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 368     "sha"               => [ "ssl", "tls1", "tls1_1", "dtls1" ],
 369
 370     # Additionally, SSL 3.0 requires either RSA or DSA+DH
 371     sub { $disabled{rsa}
 372           && ($disabled{dsa} || $disabled{dh}); }
 373                         => [ "ssl" ],
 374
 375     # (D)TLS 1.0 and TLS 1.1 also require either RSA or DSA+DH
 376     # or ECDSA + ECDH.  (D)TLS 1.2 has this requirement as well.
 377     # (XXX: We don't support PSK-only builds).
 378     sub { $disabled{rsa}
 379           && ($disabled{dsa} || $disabled{dh})
 380           && ($disabled{ecdsa} || $disabled{ecdh}); }
 381                         => [ "tls1", "tls1_1", "tls1_2",
 382                              "dtls1", "dtls1_2" ],
 383
 384     "tls"               => [ @tls ],
 385
 386     # SRP and HEARTBEATS require TLSEXT
 387     "tlsext"            => [ "srp", "heartbeats" ],
 388     );
 389
 390 # Avoid protocol support holes.  Also disable all versions below N, if version
 391 # N is disabled while N+1 is enabled.
 392 #
 393 my @list = (reverse @tls);
 394 while ((my $first, my $second) = (shift @list, shift @list)) {
 395     last unless @list;
 396     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 397                               => [ @list ] );
 398     unshift @list, $second;
 399 }
 400 my @list = (reverse @dtls);
 401 while ((my $first, my $second) = (shift @list, shift @list)) {
 402     last unless @list;
 403     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 404                               => [ @list ] );
 405     unshift @list, $second;
 406 }
 407
 408 # Construct the string of what $config{depflags} should look like with the defaults
 409 # from %disabled above.  (we need this to see if we should advise the user
 410 # to run "make depend"):
 411 my $default_depflags = join(" ",
 412     map { my $x = $_; $x =~ tr{[a-z]-}{[A-Z]_}; "-DOPENSSL_NO_$x"; }
 413     grep { $disabled{$_} !~ /\(no-depflags\)$/ }
 414     sort keys %disabled);
 415
 416 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 417 # To remove something from %disabled, use "enable-foo" (unless it's experimental).
 418 # For symmetry, "disable-foo" is a synonym for "no-foo".
 419
 420 # For features called "experimental" here, a more explicit "experimental-foo" is needed to enable.
 421 # We will collect such requests in @experimental.
 422 # To avoid accidental use of experimental features, applications will have to use -DOPENSSL_EXPERIMENTAL_FOO.
 423
 424
 425 my $no_sse2=0;
 426
 427 &usage if ($#ARGV < 0);
 428
 429 my $flags="";
 430 $config{depflags}="";
 431 $config{openssl_experimental_defines}=[];
 432 $config{openssl_api_defines}=[];
 433 $config{openssl_algorithm_defines}=[];
 434 $config{openssl_thread_defines}=[];
 435 $config{openssl_sys_defines}=[];
 436 $config{openssl_other_defines}=[];
 437 my $libs="";
 438 my $target="";
 439 $config{options}="";
 440 my $make_depend=0;
 441 my %withargs=();
 442 my $build_prefix = "release_";
 443
 444 my @argvcopy=@ARGV;
 445
 446 if (grep /^reconf(igure)?$/, @argvcopy) {
 447     if (-f "./configdata.pm") {
 448         my $file = "./configdata.pm";
 449         unless (my $return = do $file) {
 450             die "couldn't parse $file: $@" if $@;
 451             die "couldn't do $file: $!"    unless defined $return;
 452             die "couldn't run $file"       unless $return;
 453         }
 454
 455         @argvcopy = defined($configdata::config{perlargv}) ?
 456             @{$configdata::config{perlargv}} : ();
 457         die "Incorrect data to reconfigure, please do a normal configuration\n"
 458             if (grep(/^reconf/,@argvcopy));
 459         $ENV{CROSS_COMPILE} = $configdata::config{cross_compile_prefix}
 460             if defined($configdata::config{cross_compile_prefix});
 461         $ENV{CROSS_COMPILE} = $configdata::config{cc}
 462             if defined($configdata::config{cc});
 463
 464         print "Reconfiguring with: ", join(" ",@argvcopy), "\n";
 465         print "    CROSS_COMPILE = ",$ENV{CROSS_COMPILE},"\n"
 466             if $ENV{CROSS_COMPILE};
 467         print "    CC = ",$ENV{CC},"\n" if $ENV{CC};
 468     } elsif (open IN, "<Makefile") {
 469         #
 470         # THIS SECTION IS TEMPORARY, it helps transitioning from Makefile
 471         # centered information gathering the reading configdata.pm
 472         #
 473         while (<IN>) {
 474             chomp;
 475             if (/^CONFIGURE_ARGS=\s*(.*)\s*/) {
 476                 # Older form, we split the string and hope for the best
 477                 @argvcopy = split /\s+/, $_;
 478                 die "Incorrect data to reconfigure, please do a normal configuration\n"
 479                     if (grep(/^reconf/,@argvcopy));
 480             } elsif (/^CROSS_COMPILE=\s*(.*)/) {
 481                 $ENV{CROSS_COMPILE}=$1;
 482             } elsif (/^CC=\s*(?:\$\(CROSS_COMPILE\))?(.*?)$/) {
 483                 $ENV{CC}=$1;
 484             }
 485         }
 486         #
 487         # END OF TEMPORARY SECTION
 488         #
 489     } else {
 490         die "Insufficient data to reconfigure, please do a normal configuration\n";
 491     }
 492 }
 493
 494 $config{perlargv} = [ @argvcopy ];
 495
 496 my %unsupported_options = ();
 497 foreach (@argvcopy)
 498         {
 499         s /^-no-/no-/; # some people just can't read the instructions
 500
 501         # rewrite some options in "enable-..." form
 502         s /^-?-?shared$/enable-shared/;
 503         s /^sctp$/enable-sctp/;
 504         s /^threads$/enable-threads/;
 505         s /^zlib$/enable-zlib/;
 506         s /^zlib-dynamic$/enable-zlib-dynamic/;
 507
 508         if (/^(no|disable|enable|experimental)-(.+)$/)
 509                 {
 510                 my $word = $2;
 511                 if (!grep { $word =~ /^${_}$/ } @disablables)
 512                         {
 513                         $unsupported_options{$_} = 1;
 514                         next;
 515                         }
 516                 }
 517         if (/^no-(.+)$/ || /^disable-(.+)$/)
 518                 {
 519                 if (!($disabled{$1} eq "experimental"))
 520                         {
 521                         foreach my $proto ((@tls, @dtls))
 522                                 {
 523                                 if ($1 eq "$proto-method")
 524                                         {
 525                                         $disabled{"$proto"} = "option($proto-method)";
 526                                         last;
 527                                         }
 528                                 }
 529                         if ($1 eq "dtls")
 530                                 {
 531                                 foreach my $proto (@dtls)
 532                                         {
 533                                         $disabled{$proto} = "option(dtls)";
 534                                         }
 535                                 }
 536                         elsif ($1 eq "ssl")
 537                                 {
 538                                 # Last one of its kind
 539                                 $disabled{"ssl3"} = "option(ssl)";
 540                                 }
 541                         elsif ($1 eq "tls")
 542                                 {
 543                                 # XXX: Tests will fail if all SSL/TLS
 544                                 # protocols are disabled.
 545                                 foreach my $proto (@tls)
 546                                         {
 547                                         $disabled{$proto} = "option(tls)";
 548                                         }
 549                                 }
 550                         else
 551                                 {
 552                                 $disabled{$1} = "option";
 553                                 }
 554                         }
 555                 }
 556         elsif (/^enable-(.+)$/ || /^experimental-(.+)$/)
 557                 {
 558                 my $algo = $1;
 559                 if ($disabled{$algo} eq "experimental")
 560                         {
 561                         die "You are requesting an experimental feature; please say 'experimental-$algo' if you are sure\n"
 562                                 unless (/^experimental-/);
 563                         push @experimental, $algo;
 564                         }
 565                 delete $disabled{$algo};
 566
 567                 $threads = 1 if ($algo eq "threads");
 568                 }
 569         elsif (/^--strict-warnings$/)
 570                 {
 571                 $strict_warnings = 1;
 572                 }
 573         elsif (/^--debug$/)
 574                 {
 575                 $build_prefix = "debug_";
 576                 }
 577         elsif (/^--release$/)
 578                 {
 579                 $build_prefix = "release_";
 580                 }
 581         elsif (/^386$/)
 582                 { $config{processor}=386; }
 583         elsif (/^fips$/)
 584                 {
 585                 $config{fips}=1;
 586                 }
 587         elsif (/^rsaref$/)
 588                 {
 589                 # No RSAref support any more since it's not needed.
 590                 # The check for the option is there so scripts aren't
 591                 # broken
 592                 }
 593         elsif (/^nofipscanistercheck$/)
 594                 {
 595                 $config{fips} = 1;
 596                 $nofipscanistercheck = 1;
 597                 }
 598         elsif (/^[-+]/)
 599                 {
 600                 if (/^--prefix=(.*)$/)
 601                         {
 602                         $config{prefix}=$1;
 603                         }
 604                 elsif (/^--api=(.*)$/)
 605                         {
 606                         $config{api}=$1;
 607                         }
 608                 elsif (/^--libdir=(.*)$/)
 609                         {
 610                         $config{libdir}=$1;
 611                         }
 612                 elsif (/^--openssldir=(.*)$/)
 613                         {
 614                         $config{openssldir}=$1;
 615                         }
 616                 elsif (/^--install.prefix=(.*)$/)
 617                         {
 618                         $config{install_prefix}=$1;
 619                         }
 620                 elsif (/^--with-zlib-lib=(.*)$/)
 621                         {
 622                         $withargs{"zlib-lib"}=$1;
 623                         }
 624                 elsif (/^--with-zlib-include=(.*)$/)
 625                         {
 626                         $withargs{"zlib-include"}="-I$1";
 627                         }
 628                 elsif (/^--with-fipslibdir=(.*)$/)
 629                         {
 630                         $config{fipslibdir}="$1/";
 631                         }
 632                 elsif (/^--with-baseaddr=(.*)$/)
 633                         {
 634                         $config{baseaddr}="$1";
 635                         }
 636                 elsif (/^--cross-compile-prefix=(.*)$/)
 637                         {
 638                         $config{cross_compile_prefix}=$1;
 639                         }
 640                 elsif (/^--config=(.*)$/)
 641                         {
 642                         read_config $1;
 643                         }
 644                 elsif (/^-[lL](.*)$/ or /^-Wl,/)
 645                         {
 646                         $libs.=$_." ";
 647                         }
 648                 else    # common if (/^[-+]/), just pass down...
 649                         {
 650                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 651                         $flags.=$_." ";
 652                         }
 653                 }
 654         elsif ($_ =~ /^([^:]+):(.+)$/)
 655                 {
 656                 eval "\$table{\$1} = \"$2\""; # allow $xxx constructs in the string
 657                 $target=$1;
 658                 }
 659         else
 660                 {
 661                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 662                 $target=$_;
 663                 }
 664         unless ($_ eq $target || /^no-/ || /^disable-/)
 665                 {
 666                 # "no-..." follows later after implied disactivations
 667                 # have been derived.  (Don't take this too seroiusly,
 668                 # we really only write OPTIONS to the Makefile out of
 669                 # nostalgia.)
 670
 671                 if ($config{options} eq "")
 672                         { $config{options} = $_; }
 673                 else
 674                         { $config{options} .= " ".$_; }
 675                 }
 676
 677         if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 678                 die "***** Unsupported api compatibility level: $config{api}\n",
 679         }
 680
 681         if (keys %unsupported_options)
 682                 {
 683                 die "***** Unsupported options: ",
 684                         join(", ", keys %unsupported_options), "\n";
 685                 }
 686         }
 687
 688 if ($config{fips})
 689         {
 690         delete $disabled{"shared"} if ($disabled{"shared"} =~ /^default/);
 691         }
 692 else
 693         {
 694         @{$config{dirs}} = grep !/^fips$/, @{$config{dirs}};
 695         }
 696
 697 my @tocheckfor = (keys %disabled);
 698 while (@tocheckfor) {
 699     my %new_tocheckfor = ();
 700     my @cascade_copy = (@disable_cascades);
 701     while (@cascade_copy) {
 702         my ($test, $descendents) = (shift @cascade_copy, shift @cascade_copy);
 703         if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
 704             map {
 705                 $new_tocheckfor{$_} => 1; $disabled{$_} = "forced";
 706             } grep { !defined($disabled{$_}) } @$descendents;
 707         }
 708     }
 709     @tocheckfor = (keys %new_tocheckfor);
 710 }
 711
 712 if ($target eq "TABLE") {
 713     foreach (sort keys %table) {
 714         print_table_entry($_, "TABLE");
 715     }
 716     exit 0;
 717 }
 718
 719 if ($target eq "LIST") {
 720     foreach (sort keys %table) {
 721         print $_,"\n" unless $table{$_}->{template};
 722     }
 723     exit 0;
 724 }
 725
 726 if ($target eq "HASH") {
 727     print "%table = (\n";
 728     foreach (sort keys %table) {
 729         print_table_entry($_, "HASH");
 730     }
 731     exit 0;
 732 }
 733
 734 # Backward compatibility?
 735 if ($target =~ m/^CygWin32(-.*)$/) {
 736     $target = "Cygwin".$1;
 737 }
 738
 739 foreach (sort (keys %disabled))
 740         {
 741         $config{options} .= " no-$_";
 742
 743         printf "    no-%-12s %-10s", $_, "[$disabled{$_}]";
 744
 745         if (/^dso$/)
 746                 { $no_dso = 1; }
 747         elsif (/^threads$/)
 748                 { $no_threads = 1; }
 749         elsif (/^shared$/)
 750                 { $config{no_shared} = 1; }
 751         elsif (/^zlib$/)
 752                 { $zlib = 0; }
 753         elsif (/^static-engine$/)
 754                 { }
 755         elsif (/^zlib-dynamic$/)
 756                 { }
 757         elsif (/^sse2$/)
 758                 { $no_sse2 = 1; }
 759         elsif (/^engine$/)
 760                 { @{$config{dirs}} = grep !/^engine$/, @{$config{dirs}}; }
 761         else
 762                 {
 763                 my ($ALGO, $algo);
 764                 ($ALGO = $algo = $_) =~ tr/[\-a-z]/[_A-Z]/;
 765
 766                 if (/^asm$/ || /^err$/ || /^hw$/ || /^hw-/)
 767                         {
 768                         push @{$config{openssl_other_defines}}, "OPENSSL_NO_$ALGO";
 769                         print " OPENSSL_NO_$ALGO";
 770
 771                         if (/^err$/)    { $flags .= "-DOPENSSL_NO_ERR "; }
 772                         elsif (/^asm$/) { $no_asm = 1; }
 773                         }
 774                 else
 775                         {
 776                         ($ALGO,$algo) = ("RMD160","rmd160") if ($algo eq "ripemd");
 777
 778                         push @{$config{openssl_algorithm_defines}}, "OPENSSL_NO_$ALGO";
 779                         $config{depflags} .= " -DOPENSSL_NO_$ALGO";
 780                         print " OPENSSL_NO_$ALGO";
 781
 782                         # fix-up crypto/directory name(s)
 783                         $algo="whrlpool" if $algo eq "whirlpool";
 784                         $algo="ripemd" if $algo eq "rmd160";
 785                         @{$config{sdirs}} = grep { $_ ne $algo} @{$config{sdirs}};
 786
 787                         print " (skip dir)";
 788                         }
 789                 }
 790
 791         print "\n";
 792         }
 793
 794 my $exp_cflags = "";
 795
 796 foreach (sort @experimental)
 797         {
 798         my $ALGO;
 799         ($ALGO = $_) =~ tr/[a-z]/[A-Z]/;
 800
 801         # opensslconf.h will set OPENSSL_NO_... unless OPENSSL_EXPERIMENTAL_... is defined
 802         push @{$config{openssl_experimental_defines}}, "OPENSSL_NO_$ALGO";
 803         $exp_cflags .= " -DOPENSSL_EXPERIMENTAL_$ALGO";
 804         }
 805
 806 print "Configuring for $target\n";
 807
 808 # Support for legacy targets having a name starting with 'debug-'
 809 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
 810 if ($d) {
 811     $build_prefix = "debug_";
 812
 813     # If we do not find debug-foo in the table, the target is set to foo.
 814     if (!$table{$target}) {
 815         $target = $t;
 816     }
 817 }
 818 $config{target} = $target;
 819 delete $table{$base_target}->{template}; # or the next test will fail.
 820 my %target = ( %{$table{$base_target}}, resolve_config($target) );
 821
 822 &usage if (!%target || $target{template});
 823
 824 $target{exe_extension}="";
 825 $target{exe_extension}=".exe" if ($config{target} eq "Cygwin" || $config{target} eq "DJGPP" || $config{target} =~ /^mingw/);
 826 $target{exe_extension}=".nlm" if ($config{target} =~ /netware/);
 827 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
 828
 829 $default_ranlib = which("ranlib") || "true";
 830 $config{perl}   = $ENV{'PERL'} || which("perl5") || which("perl") || "perl";
 831 my $make        = $ENV{'MAKE'} || "make";
 832
 833 $config{cross_compile_prefix} = $ENV{'CROSS_COMPILE'}
 834     if $config{cross_compile_prefix} eq "";
 835
 836 $config{prefix} = "/usr/local" if !$config{prefix};
 837 $config{openssldir} = "ssl" if !$config{openssldir};
 838 $config{openssldir} = catdir($config{prefix}, $config{openssldir})
 839     unless file_name_is_absolute($config{openssldir});
 840
 841 # Allow environment CC to override compiler...
 842 $target{cc} = $ENV{CC} || $target{cc};
 843
 844 # For cflags and lflags, add the debug_ or release_ attributes
 845 # Do it in such a way that no spurious space is appended (hence the grep).
 846 $config{cflags} = join(" ",
 847                        grep { $_ ne "" } ($target{cflags},
 848                                           $target{$build_prefix."cflags"}));
 849 $config{lflags} = join(" ",
 850                        grep { $_ ne "" } ($target{lflags},
 851                                           $target{$build_prefix."lflags"}));
 852
 853 $target{ranlib} = $ENV{'RANLIB'} || $target{ranlib} || $default_ranlib;
 854 $target{ar} = $ENV{'AR'} || "ar";
 855 $target{arflags} = "" if !defined($target{arflags});
 856 $target{nm} = "nm";
 857 # Make sure build_scheme is consistent.
 858 $target{build_scheme} = [ $target{build_scheme} ]
 859     if ref($target{build_scheme}) ne "ARRAY";
 860
 861 # if $config{prefix}/lib$target{multilib} is not an existing directory, then
 862 # assume that it's not searched by linker automatically, in
 863 # which case adding $target{multilib} suffix causes more grief than
 864 # we're ready to tolerate, so don't...
 865 $target{multilib}="" if !-d "$config{prefix}/lib$target{multilib}";
 866
 867 $config{libdir}="lib$target{multilib}" if $config{libdir} eq "";
 868 $config{enginesdir}=$config{prefix} . "/" . $config{libdir}  . "/engines";
 869
 870 $config{cflags} .= "$exp_cflags";
 871
 872 # '%' in $config{lflags} is used to split flags to "pre-" and post-flags
 873 my ($pre,$post)=split('%',$config{lflags});
 874 if (defined($post))     { $config{prelflags}=$pre; $config{lflags}=$post;       }
 875 else                    { $config{prelflags}="";   $config{lflags}=$pre;        }
 876
 877 if ($target =~ /^mingw/ && `$target{cc} --target-help 2>&1` !~ m/-mno-cygwin/m)
 878         {
 879         $config{cflags} =~ s/-mno-cygwin\s*//;
 880         $target{shared_ldflag} =~ s/-mno-cygwin\s*//;
 881         }
 882
 883 if ($target =~ /linux.*-mips/ && !$no_asm && $flags !~ /-m(ips|arch=)/) {
 884         # minimally required architecture flags for assembly modules
 885         $config{cflags}="-mips2 $config{cflags}" if ($target =~ /mips32/);
 886         $config{cflags}="-mips3 $config{cflags}" if ($target =~ /mips64/);
 887 }
 888
 889 my $no_shared_warn=0;
 890 my $no_user_cflags=0;
 891
 892 if ($flags ne "")       { $config{cflags}="$flags$config{cflags}"; }
 893 else                    { $no_user_cflags=1;       }
 894
 895 # The DSO code currently always implements all functions so that no
 896 # applications will have to worry about that from a compilation point
 897 # of view. However, the "method"s may return zero unless that platform
 898 # has support compiled in for them. Currently each method is enabled
 899 # by a define "DSO_<name>" ... we translate the "dso_scheme" config
 900 # string entry into using the following logic;
 901 my $dso_cflags;
 902 if (!$no_dso && $target{dso_scheme} ne "")
 903         {
 904         $target{dso_scheme} =~ tr/[a-z]/[A-Z]/;
 905         if ($target{dso_scheme} eq "DLFCN")
 906                 {
 907                 $dso_cflags = "-DDSO_DLFCN -DHAVE_DLFCN_H";
 908                 }
 909         elsif ($target{dso_scheme} eq "DLFCN_NO_H")
 910                 {
 911                 $dso_cflags = "-DDSO_DLFCN";
 912                 }
 913         else
 914                 {
 915                 $dso_cflags = "-DDSO_$target{dso_scheme}";
 916                 }
 917         $config{cflags} = "$dso_cflags $config{cflags}";
 918         }
 919
 920 my $thread_cflags;
 921 my @thread_defines;
 922 if ($target{thread_cflag} ne "(unknown)" && !$no_threads)
 923         {
 924         # If we know how to do it, support threads by default.
 925         $threads = 1;
 926         }
 927 if ($target{thread_cflag} eq "(unknown)" && $threads)
 928         {
 929         # If the user asked for "threads", [s]he is also expected to
 930         # provide any system-dependent compiler options that are
 931         # necessary.
 932         if ($no_user_cflags)
 933                 {
 934                 print "You asked for multi-threading support, but didn't\n";
 935                 print "provide any system-specific compiler options\n";
 936                 exit(1);
 937                 }
 938         $thread_cflags="-DOPENSSL_THREADS $config{cflags}" ;
 939         push @thread_defines, "OPENSSL_THREADS";
 940         }
 941 else
 942         {
 943         $thread_cflags="-DOPENSSL_THREADS $target{thread_cflag} $config{cflags}";
 944         push @thread_defines, "OPENSSL_THREADS";
 945 #       my $def;
 946 #       foreach $def (split ' ',$target{thread_cflag})
 947 #               {
 948 #               if ($def =~ s/^-D// && $def !~ /^_/)
 949 #                       {
 950 #                       push @thread_defines, "$def";
 951 #                       }
 952 #               }
 953         }
 954
 955 $config{lflags}="$libs$config{lflags}" if ($libs ne "");
 956
 957 if ($no_asm)
 958         {
 959         $config{cflags}=~s/-D[BL]_ENDIAN//              if ($config{fips});
 960         $thread_cflags=~s/-D[BL]_ENDIAN//       if ($config{fips});
 961         }
 962
 963 if ($threads)
 964         {
 965         $config{cflags}=$thread_cflags;
 966         push @{$config{openssl_thread_defines}}, @thread_defines;
 967         }
 968
 969 if ($zlib)
 970         {
 971         $config{cflags} = "-DZLIB $config{cflags}";
 972         if (defined($disabled{"zlib-dynamic"}))
 973                 {
 974                 if (defined($withargs{"zlib-lib"}))
 975                         {
 976                         $config{lflags} .= " -L" . $withargs{"zlib-lib"} . " -lz";
 977                         }
 978                 else
 979                         {
 980                         $config{lflags} .= " -lz";
 981                         }
 982                 }
 983         else
 984                 {
 985                 $config{cflags} = "-DZLIB_SHARED $config{cflags}";
 986                 }
 987         }
 988
 989 # With "deprecated" disable all deprecated features.
 990 if (defined($disabled{"deprecated"})) {
 991         $config{api} = $maxapi;
 992 }
 993
 994 if ($target{shared_target} eq "")
 995         {
 996         $no_shared_warn = 1 if !$config{no_shared} && !$config{fips};
 997         $config{no_shared} = 1;
 998         }
 999 if (!$config{no_shared})
1000         {
1001         if ($target{shared_cflag} ne "")
1002                 {
1003                 $config{cflags} = "$target{shared_cflag} -DOPENSSL_PIC $config{cflags}";
1004                 }
1005         }
1006
1007 if ($target{build_scheme}->[0] ne "mk1mf")
1008         {
1009         # add {no-}static-engine to options to allow mkdef.pl to work without extra arguments
1010         if ($config{no_shared})
1011                 {
1012                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1013                 $config{options}.=" static-engine";
1014                 }
1015         else
1016                 {
1017                 push @{$config{openssl_other_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1018                 $config{options}.=" no-static-engine";
1019                 }
1020         }
1021
1022 #
1023 # Platform fix-ups
1024 #
1025 if ($target =~ /-icc$/) # Intel C compiler
1026         {
1027         my $iccver=0;
1028         if (open(FD,"$target{cc} -V 2>&1 |"))
1029                 {
1030                 while(<FD>) { $iccver=$1 if (/Version ([0-9]+)\./); }
1031                 close(FD);
1032                 }
1033         if ($iccver>=8)
1034                 {
1035                 $config{cflags}=~s/-KPIC/-fPIC/;
1036                 # Eliminate unnecessary dependency from libirc.a. This is
1037                 # essential for shared library support, as otherwise
1038                 # apps/openssl can end up in endless loop upon startup...
1039                 $config{cflags}.=" -Dmemcpy=__builtin_memcpy -Dmemset=__builtin_memset";
1040                 }
1041         if ($iccver>=9)
1042                 {
1043                 $config{lflags}.=" -i-static";
1044                 $config{lflags}=~s/-no_cpprt/-no-cpprt/;
1045                 }
1046         if ($iccver>=10)
1047                 {
1048                 $config{lflags}=~s/-i-static/-static-intel/;
1049                 }
1050         if ($iccver>=11)
1051                 {
1052                 $config{cflags}.=" -no-intel-extensions";       # disable Cilk
1053                 $config{lflags}=~s/-no-cpprt/-no-cxxlib/;
1054                 }
1055         }
1056
1057 # Unlike other OSes (like Solaris, Linux, Tru64, IRIX) BSD run-time
1058 # linkers (tested OpenBSD, NetBSD and FreeBSD) "demand" RPATH set on
1059 # .so objects. Apparently application RPATH is not global and does
1060 # not apply to .so linked with other .so. Problem manifests itself
1061 # when libssl.so fails to load libcrypto.so. One can argue that we
1062 # should engrave this into Makefile.shared rules or into BSD-* config
1063 # lines above. Meanwhile let's try to be cautious and pass -rpath to
1064 # linker only when --prefix is not /usr.
1065 if ($target =~ /^BSD-/)
1066         {
1067         $target{shared_ldflag}.=" -Wl,-rpath,\$\$(LIBRPATH)" if ($config{prefix} !~ m|^/usr[/]*$|);
1068         }
1069
1070 if ($target{sys_id} ne "")
1071         {
1072         #$config{cflags}="-DOPENSSL_SYS_$target{sys_id} $config{cflags}";
1073         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1074         }
1075
1076 if ($target{ranlib} eq "")
1077         {
1078         $target{ranlib} = $default_ranlib;
1079         }
1080
1081 if (!$no_asm) {
1082     $target{cpuid_obj}=$table{BASE}->{cpuid_obj} if ($config{processor} eq "386");
1083     $target{cpuid_obj}.=" uplink.o uplink-x86.o" if ($config{cflags} =~ /-DOPENSSL_USE_APPLINK/);
1084
1085     $target{bn_obj} =~ s/\w+-gf2m.o// if (defined($disabled{ec2m}));
1086
1087     # bn-586 is the only one implementing bn_*_part_words
1088     $config{cflags}.=" -DOPENSSL_BN_ASM_PART_WORDS" if ($target{bn_obj} =~ /bn-586/);
1089     $config{cflags}.=" -DOPENSSL_IA32_SSE2" if (!$no_sse2 && $target{bn_obj} =~ /86/);
1090
1091     $config{cflags}.=" -DOPENSSL_BN_ASM_MONT" if ($target{bn_obj} =~ /-mont/);
1092     $config{cflags}.=" -DOPENSSL_BN_ASM_MONT5" if ($target{bn_obj} =~ /-mont5/);
1093     $config{cflags}.=" -DOPENSSL_BN_ASM_GF2m" if ($target{bn_obj} =~ /-gf2m/);
1094
1095     if ($config{fips}) {
1096         push @{$config{openssl_other_defines}}, "OPENSSL_FIPS";
1097     }
1098
1099     if ($target{sha1_obj} =~ /\.o$/) {
1100         $config{cflags}.=" -DSHA1_ASM"   if ($target{sha1_obj} =~ /sx86/ || $target{sha1_obj} =~ /sha1/);
1101         $config{cflags}.=" -DSHA256_ASM" if ($target{sha1_obj} =~ /sha256/);
1102         $config{cflags}.=" -DSHA512_ASM" if ($target{sha1_obj} =~ /sha512/);
1103         if ($target{sha1_obj} =~ /sse2/) {
1104             if ($no_sse2) {
1105                 $target{sha1_obj} =~ s/\S*sse2\S+//;
1106             } elsif ($config{cflags} !~ /OPENSSL_IA32_SSE2/) {
1107                 $config{cflags}.=" -DOPENSSL_IA32_SSE2";
1108             }
1109         }
1110     }
1111     if ($target{md5_obj} =~ /\.o$/) {
1112         $config{cflags}.=" -DMD5_ASM";
1113     }
1114     $target{cast_obj}=$table{BASE}->{cast_obj} if (!$config{no_shared}); # CAST assembler is not PIC
1115     if ($target{rmd160_obj} =~ /\.o$/) {
1116         $config{cflags}.=" -DRMD160_ASM";
1117     }
1118     if ($target{aes_obj} =~ /\.o$/) {
1119         $config{cflags}.=" -DAES_ASM" if ($target{aes_obj} =~ m/\baes-/);;
1120         # aes-ctr.o is not a real file, only indication that assembler
1121         # module implements AES_ctr32_encrypt...
1122         $config{cflags}.=" -DAES_CTR_ASM" if ($target{aes_obj} =~ s/\s*aes-ctr\.o//);
1123         # aes-xts.o indicates presence of AES_xts_[en|de]crypt...
1124         $config{cflags}.=" -DAES_XTS_ASM" if ($target{aes_obj} =~ s/\s*aes-xts\.o//);
1125         $target{aes_obj} =~ s/\s*(vpaes|aesni)-x86\.o//g if ($no_sse2);
1126         $config{cflags}.=" -DVPAES_ASM" if ($target{aes_obj} =~ m/vpaes/);
1127         $config{cflags}.=" -DBSAES_ASM" if ($target{aes_obj} =~ m/bsaes/);
1128     }
1129     if ($target{wp_obj} =~ /mmx/ && $config{processor} eq "386") {
1130         $target{wp_obj}=$table{BASE}->{wp_obj};
1131     } elsif (!$disabled{"whirlpool"}) {
1132         $config{cflags}.=" -DWHIRLPOOL_ASM";
1133     }
1134     if ($target{modes_obj} =~ /ghash-/) {
1135         $config{cflags}.=" -DGHASH_ASM";
1136     }
1137     if ($target{ec_obj} =~ /ecp_nistz256/) {
1138         $config{cflags}.=" -DECP_NISTZ256_ASM";
1139     }
1140     if ($target{poly1305_obj} =~ /\.o$/) {
1141         $config{cflags}.=" -DPOLY1305_ASM";
1142     }
1143 }
1144
1145 $config{makedepprog} = "makedepend";
1146 if ($target{cc} eq "gcc" || ($target{cc} eq 'cc' && $config{target} =~ /darwin/)) {
1147     $config{makedepprog} = $target{cc};
1148 }
1149 # On different platforms, shared library suffixes takes interesting forms.
1150 # On Most Unixen, it's .so.{version} or .sl.{version}, while on MacOS X,
1151 # it's .{version}.dylib.  We're want to separate the two so we can calculate
1152 # symlinks.
1153 # FIXME: is this actually needed any more?  Makefile.shared seems to just
1154 # symlink a file name without SOVER to the file with full SOVER, nothing in
1155 # between.
1156 if ($target{shared_extension} =~ /^(|(?<e>\.s[ol])(?<v>\..*)|(?<v>\..*)(?<e>\.dylib))$/) {
1157     my @vernums = split /\./, $+{v};
1158     shift @vernums;             # Because the initial period in shlib_extension.
1159     my @s = ();
1160     while (@vernums) {
1161         pop @vernums;
1162         push @s, join(".", $+{e} eq ".dylib" ? "" : $+{e},
1163                       @vernums,
1164                       $+{e} eq ".dylib" ? $+{e} : () );
1165     }
1166     $config{shared_link_extensions} = join(" ", @s);
1167 } else {
1168     $config{shared_link_extensions} = "";
1169 }
1170 $config{depflags} =~ s/^\s*//;
1171
1172
1173 # Deal with bn_ops ###################################################
1174
1175 $config{des_ptr}                =0;
1176 $config{des_risc1}              =0;
1177 $config{des_risc2}              =0;
1178 $config{des_unroll}             =0;
1179 $config{bn_ll}                  =0;
1180 $config{rc4_idx}                =0;
1181 $config{bf_ptr}                 =0;
1182 $config{export_var_as_fn}       =0;
1183 my $def_int="unsigned int";
1184 $config{rc4_int}                =$def_int;
1185 $config{rc4_chunk}              ="";
1186 $config{md2_int}                =$def_int;
1187 $config{idea_int}               =$def_int;
1188 $config{rc2_int}                =$def_int;
1189 ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})=(0,0,1,0,0);
1190
1191 $config{des_int} = "unsigned long";
1192
1193 foreach (sort split(/\s+/,$target{bn_ops})) {
1194     $config{des_ptr}=1                          if /DES_PTR/;
1195     $config{des_risc1}=1                        if /DES_RISC1/;
1196     $config{des_risc2}=1                        if /DES_RISC2/;
1197     $config{des_unroll}=1                       if /DES_UNROLL/;
1198     $config{des_int}="unsigned int"             if /DES_INT/;
1199     $config{bn_ll}=1                            if /BN_LLONG/;
1200     $config{rc4_int}="unsigned char"            if /RC4_CHAR/;
1201     $config{rc4_int}="unsigned long"            if /RC4_LONG/;
1202     $config{rc4_idx}=1                          if /RC4_INDEX/;
1203     $config{rc4_chunk}="unsigned long"          if /RC4_CHUNK/;
1204     $config{rc4_chunk}="unsigned long long"     if /RC4_CHUNK_LL/;
1205     $config{md2_int}="unsigned char"            if /MD2_CHAR/;
1206     $config{md2_int}="unsigned long"            if /MD2_LONG/;
1207     $config{idea_int}="unsigned char"           if /IDEA_CHAR/;
1208     $config{idea_int}="unsigned long"           if /IDEA_LONG/;
1209     $config{rc2_int}="unsigned char"            if /RC2_CHAR/;
1210     $config{rc2_int}="unsigned long"            if /RC2_LONG/;
1211     $config{bf_ptr}=1                           if $_ eq "BF_PTR";
1212     $config{bf_ptr}=2                           if $_ eq "BF_PTR2";
1213     ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})
1214         =(0,1,0,0,0)                            if /SIXTY_FOUR_BIT/;
1215     ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})
1216         =(1,0,0,0,0)                            if /SIXTY_FOUR_BIT_LONG/;
1217     ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})
1218         =(0,0,1,0,0)                            if /THIRTY_TWO_BIT/;
1219     ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})
1220         =(0,0,0,1,0)                            if /SIXTEEN_BIT/;
1221     ($config{b64l},$config{b64},$config{b32},$config{b16},$config{b8})
1222         =(0,0,0,0,1)                            if /EIGHT_BIT/;
1223     $config{export_var_as_fn}=1                 if /EXPORT_VAR_AS_FN/;
1224 }
1225
1226
1227 # Hack cflags for better warnings (dev option) #######################
1228
1229 # "Stringify" the C flags string.  This permits it to be made part of a string
1230 # and works as well on command lines.
1231 $config{cflags} =~ s/([\\\"])/\\\1/g;
1232
1233 if (defined($config{api})) {
1234     $config{openssl_api_defines} = [ "OPENSSL_MIN_API=".$apitable->{$config{api}} ];
1235     my $apiflag = sprintf("-DOPENSSL_API_COMPAT=%s", $apitable->{$config{api}});
1236     $default_depflags .= " $apiflag";
1237     $config{cflags} .= " $apiflag";
1238 }
1239
1240 my $ecc = $target{cc};
1241 $ecc = "clang" if `$target{cc} --version 2>&1` =~ /clang/;
1242
1243 if ($strict_warnings)
1244         {
1245         my $wopt;
1246         die "ERROR --strict-warnings requires gcc or clang" unless ($ecc =~ /gcc(-\d(\.\d)*)?$/ or $ecc =~ /clang$/);
1247         foreach $wopt (split /\s+/, $gcc_devteam_warn)
1248                 {
1249                 $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1250                 }
1251         if ($ecc eq "clang")
1252                 {
1253                 foreach $wopt (split /\s+/, $clang_devteam_warn)
1254                         {
1255                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1256                         }
1257                 }
1258         if ($target !~ /^mingw/)
1259                 {
1260                 foreach $wopt (split /\s+/, $memleak_devteam_backtrace)
1261                         {
1262                         $config{cflags} .= " $wopt" unless ($config{cflags} =~ /(^|\s)$wopt(\s|$)/)
1263                         }
1264                 if ($target =~ /^BSD-/)
1265                         {
1266                         $config{lflags} .= " -lexecinfo";
1267                         }
1268                 }
1269         }
1270
1271 # Write down our configuration where it fits #########################
1272
1273 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
1274 print OUT <<"EOF";
1275 package configdata;
1276
1277 use strict;
1278 use warnings;
1279
1280 use Exporter;
1281 #use vars qw(\@ISA \@EXPORT);
1282 our \@ISA = qw(Exporter);
1283 our \@EXPORT = qw(\%config \%target %withargs);
1284
1285 EOF
1286 print OUT "our %config = (\n";
1287 foreach (sort keys %config) {
1288     if (ref($config{$_}) eq "ARRAY") {
1289         print OUT "  ", $_, " => [ ", join(", ",
1290                                            map { quotify("perl", $_) }
1291                                            @{$config{$_}}), " ],\n";
1292     } else {
1293         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
1294     }
1295 }
1296 print OUT <<"EOF";
1297 );
1298
1299 EOF
1300 print OUT "our %target = (\n";
1301 foreach (sort keys %target) {
1302     if (ref($target{$_}) eq "ARRAY") {
1303         print OUT "  ", $_, " => [ ", join(", ",
1304                                            map { quotify("perl", $_) }
1305                                            @{$target{$_}}), " ],\n";
1306     } else {
1307         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
1308     }
1309 }
1310 print OUT <<"EOF";
1311 );
1312
1313 EOF
1314 print OUT "our %withargs = (\n";
1315 foreach (sort keys %withargs) {
1316     if (ref($withargs{$_}) eq "ARRAY") {
1317         print OUT "  ", $_, " => [ ", join(", ",
1318                                            map { quotify("perl", $_) }
1319                                            @{$withargs{$_}}), " ],\n";
1320     } else {
1321         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
1322     }
1323 }
1324 print OUT <<"EOF";
1325 );
1326
1327 1;
1328 EOF
1329 close(OUT);
1330
1331 print "IsMK1MF       =", ($target{build_scheme}->[0] eq "mk1mf" ? "yes" : "no"), "\n";
1332 print "CC            =$target{cc}\n";
1333 print "CFLAG         =$config{cflags}\n";
1334 print "EX_LIBS       =$config{lflags}\n";
1335 print "CPUID_OBJ     =$target{cpuid_obj}\n";
1336 print "BN_ASM        =$target{bn_obj}\n";
1337 print "EC_ASM        =$target{ec_obj}\n";
1338 print "DES_ENC       =$target{des_obj}\n";
1339 print "AES_ENC       =$target{aes_obj}\n";
1340 print "BF_ENC        =$target{bf_obj}\n";
1341 print "CAST_ENC      =$target{cast_obj}\n";
1342 print "RC4_ENC       =$target{rc4_obj}\n";
1343 print "RC5_ENC       =$target{rc5_obj}\n";
1344 print "MD5_OBJ_ASM   =$target{md5_obj}\n";
1345 print "SHA1_OBJ_ASM  =$target{sha1_obj}\n";
1346 print "RMD160_OBJ_ASM=$target{rmd160_obj}\n";
1347 print "CMLL_ENC      =$target{cmll_obj}\n";
1348 print "MODES_OBJ     =$target{modes_obj}\n";
1349 print "ENGINES_OBJ   =$target{engines_obj}\n";
1350 print "CHACHA_ENC    =$target{chacha_obj}\n";
1351 print "POLY1305_OBJ  =$target{poly1305_obj}\n";
1352 print "PROCESSOR     =$config{processor}\n";
1353 print "RANLIB        =$target{ranlib}\n";
1354 print "ARFLAGS       =$target{arflags}\n";
1355 print "PERL          =$config{perl}\n";
1356
1357 run_dofile("$Makefile.in","$Makefile");
1358
1359 run_dofile("include/openssl/opensslconf.h.in", "include/openssl/opensslconf.h");
1360
1361 foreach my $alg ( 'bf', 'bn', 'des', 'rc4' ) {
1362     run_dofile("crypto/include/internal/${alg}_conf.h.in",
1363                "crypto/include/internal/${alg}_conf.h");
1364 }
1365
1366 # Fix the date
1367
1368 print "SIXTY_FOUR_BIT_LONG mode\n" if $config{b64l};
1369 print "SIXTY_FOUR_BIT mode\n" if $config{b64};
1370 print "THIRTY_TWO_BIT mode\n" if $config{b32};
1371 print "SIXTEEN_BIT mode\n" if $config{b16};
1372 print "EIGHT_BIT mode\n" if $config{b8};
1373 print "DES_PTR used\n" if $config{des_ptr};
1374 print "DES_RISC1 used\n" if $config{des_risc1};
1375 print "DES_RISC2 used\n" if $config{des_risc2};
1376 print "DES_UNROLL used\n" if $config{des_unroll};
1377 print "DES_INT used\n" if $config{des_int} =~ / int$/;
1378 print "BN_LLONG mode\n" if $config{bn_ll};
1379 print "RC4 uses $config{rc4_int}\n" if $config{rc4_int} != $def_int;
1380 print "RC4_INDEX mode\n" if $config{rc4_idx};
1381 print "RC4_CHUNK is undefined\n" unless $config{rc4_chunk};
1382 print "RC4_CHUNK is $config{rc4_chunk}\n" if $config{rc4_chunk};
1383 print "MD2 uses $config{md2_int}\n" if $config{md2_int} != $def_int;
1384 print "IDEA uses $config{idea_int}\n" if $config{idea_int} != $def_int;
1385 print "RC2 uses $config{rc2_int}\n" if $config{rc2_int} != $def_int;
1386 print "BF_PTR used\n" if $config{bf_ptr} == 1;
1387 print "BF_PTR2 used\n" if $config{bf_ptr} == 2;
1388
1389 # Copy all Makefile.in to Makefile (except top-level)
1390 use File::Find;
1391 use IO::File;
1392 find(sub {
1393         return if ($_ ne "Makefile.in" || $File::Find::dir eq ".");
1394         my $in = IO::File->new($_, "r") or
1395             die sprintf "Error reading Makefile.in in %s: !$\n",
1396                 $File::Find::dir;
1397         my $out = IO::File->new("Makefile", "w") or
1398             die sprintf "Error writing Makefile in %s: !$\n",
1399                 $File::Find::dir;
1400         print $out "# Generated from $_, do not edit\n";
1401         while (my $line = <$in>) { print $out $line }
1402         $in->close() or
1403             die sprintf "Error reading Makefile.in in %s: !$\n",
1404                 $File::Find::dir;
1405         $out->close() or
1406             die sprintf "Error writing Makefile in %s: !$\n",
1407                 $File::Find::dir;
1408     }, ".");
1409
1410 my %builders = (
1411     unixmake => sub {
1412         my $make_command = "$make PERL=\'$config{perl}\'";
1413         my $make_targets = "";
1414         $make_targets .= " depend" if $config{depflags} ne $default_depflags && $make_depend;
1415         (system $make_command.$make_targets) == 0 or die "make $make_targets failed"
1416             if $make_targets ne "";
1417         if ($config{depflags} ne $default_depflags && !$make_depend) {
1418             $warn_make_depend++;
1419         }
1420     },
1421     mk1mf => sub {
1422         open (OUT,">crypto/buildinf.h") || die "Can't open buildinf.h";
1423         printf OUT <<"EOF";
1424 #ifndef MK1MF_BUILD
1425   /* auto-generated by Configure for crypto/cversion.c:
1426    * for Unix builds, crypto/Makefile.ssl generates functional definitions;
1427    * Windows builds (and other mk1mf builds) compile cversion.c with
1428    * -DMK1MF_BUILD and use definitions added to this file by util/mk1mf.pl. */
1429   #error "Windows builds (PLATFORM=$target) use mk1mf.pl-created Makefiles"
1430 #endif
1431 EOF
1432         close(OUT);
1433
1434         # create the ms/version32.rc file if needed
1435         if (! grep /^netware/, @{$target{build_scheme}}) {
1436             my ($v1, $v2, $v3, $v4);
1437             if ($config{version_num} =~ /^0x([0-9a-f]{1})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{2})([0-9a-f]{1})L$/i) {
1438                 $v1=hex $1;
1439                 $v2=hex $2;
1440                 $v3=hex $3;
1441                 $v4=hex $4;
1442             }
1443             open (OUT,">ms/version32.rc") || die "Can't open ms/version32.rc";
1444             print OUT <<"EOF";
1445 #include <winver.h>
1446
1447 LANGUAGE 0x09,0x01
1448
1449 1 VERSIONINFO
1450   FILEVERSION $v1,$v2,$v3,$v4
1451   PRODUCTVERSION $v1,$v2,$v3,$v4
1452   FILEFLAGSMASK 0x3fL
1453 #ifdef _DEBUG
1454   FILEFLAGS 0x01L
1455 #else
1456   FILEFLAGS 0x00L
1457 #endif
1458   FILEOS VOS__WINDOWS32
1459   FILETYPE VFT_DLL
1460   FILESUBTYPE 0x0L
1461 BEGIN
1462     BLOCK "StringFileInfo"
1463     BEGIN
1464         BLOCK "040904b0"
1465         BEGIN
1466             // Required:
1467             VALUE "CompanyName", "The OpenSSL Project, http://www.openssl.org/\\0"
1468             VALUE "FileDescription", "OpenSSL Shared Library\\0"
1469             VALUE "FileVersion", "$config{version}\\0"
1470 #if defined(CRYPTO)
1471             VALUE "InternalName", "libeay32\\0"
1472             VALUE "OriginalFilename", "libeay32.dll\\0"
1473 #elif defined(SSL)
1474             VALUE "InternalName", "ssleay32\\0"
1475             VALUE "OriginalFilename", "ssleay32.dll\\0"
1476 #endif
1477             VALUE "ProductName", "The OpenSSL Toolkit\\0"
1478             VALUE "ProductVersion", "$config{version}\\0"
1479             // Optional:
1480             //VALUE "Comments", "\\0"
1481             VALUE "LegalCopyright", "Copyright © 1998-2015 The OpenSSL Project. Copyright © 1995-1998 Eric A. Young, Tim J. Hudson. All rights reserved.\\0"
1482             //VALUE "LegalTrademarks", "\\0"
1483             //VALUE "PrivateBuild", "\\0"
1484             //VALUE "SpecialBuild", "\\0"
1485         END
1486     END
1487     BLOCK "VarFileInfo"
1488     BEGIN
1489         VALUE "Translation", 0x409, 0x4b0
1490     END
1491 END
1492 EOF
1493             close(OUT);
1494         }
1495     },
1496     );
1497
1498 my ($builder, @builder_opts) = @{$target{build_scheme}};
1499 $builders{$builder}->(@builder_opts);
1500
1501 print <<"EOF";
1502
1503 Configured for $target.
1504 EOF
1505
1506 print <<"EOF" if (!$no_threads && !$threads);
1507
1508 The library could not be configured for supporting multi-threaded
1509 applications as the compiler options required on this system are not known.
1510 See file INSTALL for details if you need multi-threading.
1511 EOF
1512
1513 print <<"EOF" if ($no_shared_warn);
1514
1515 You gave the option 'shared', which is not supported on this platform, so
1516 we will pretend you gave the option 'no-shared'.  If you know how to implement
1517 shared libraries, please let us know (but please first make sure you have
1518 tried with a current version of OpenSSL).
1519 EOF
1520
1521 print <<"EOF" if ($warn_make_depend);
1522
1523 *** Because of configuration changes, you MUST do the following before
1524 *** building:
1525
1526         make depend
1527 EOF
1528
1529 exit(0);
1530
1531 ######################################################################
1532 #
1533 # Helpers and utility functions
1534 #
1535
1536 # Configuration file reading #########################################
1537
1538 # Helper function to implement conditional inheritance depending on the
1539 # value of $no_asm.  Used in inherit_from values as follows:
1540 #
1541 #      inherit_from => [ "template", asm("asm_tmpl") ]
1542 #
1543 sub asm {
1544     my @x = @_;
1545     sub {
1546         $no_asm ? () : @x;
1547     }
1548 }
1549
1550 # Helper function to implement adding values to already existing configuration
1551 # values.  It handles elements that are ARRAYs, CODEs and scalars
1552 sub _add {
1553     my $separator = shift;
1554
1555     # If there's any ARRAY in the collection of values, we will return
1556     # an ARRAY of combined values, otherwise a string of joined values
1557     # with $separator as the separator.
1558     my $found_array = 0;
1559
1560     my @values =
1561         map {
1562             if (ref($_) eq "ARRAY") {
1563                 $found_array = 1;
1564                 @$_;
1565             } else {
1566                 $_;
1567             }
1568     } (@_);
1569
1570     if ($found_array) {
1571         [ @values ];
1572     } else {
1573         join($separator, @values);
1574     }
1575 }
1576 sub add_before {
1577     my $separator = shift;
1578     my @x = @_;
1579     sub { _add($separator, @x, @_) };
1580 }
1581 sub add {
1582     my $separator = shift;
1583     my @x = @_;
1584     sub { _add($separator, @_, @x) };
1585 }
1586
1587 # configuration reader, evaluates the input file as a perl script and expects
1588 # it to fill %targets with target configurations.  Those are then added to
1589 # %table.
1590 sub read_config {
1591     my $fname = shift;
1592     open(CONFFILE, "< $fname")
1593         or die "Can't open configuration file '$fname'!\n";
1594     my $x = $/;
1595     undef $/;
1596     my $content = <CONFFILE>;
1597     $/ = $x;
1598     close(CONFFILE);
1599     my %targets = ();
1600     {
1601         local %table = %::table;    # Protect %table from tampering
1602
1603         eval $content;
1604         warn $@ if $@;
1605     }
1606
1607     # For each target, check that it's configured with a hash table.
1608     foreach (keys %targets) {
1609         if (ref($targets{$_}) ne "HASH") {
1610             if (ref($targets{$_}) eq "") {
1611                 warn "Deprecated target configuration for $_, ignoring...\n";
1612             } else {
1613                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
1614             }
1615             delete $targets{$_};
1616         }
1617     }
1618
1619     %table = (%table, %targets);
1620
1621 }
1622
1623 # configuration resolver.  Will only resolve all the lazy evalutation
1624 # codeblocks for the chozen target and all those it inherits from,
1625 # recursively
1626 sub resolve_config {
1627     my $target = shift;
1628     my @breadcrumbs = @_;
1629
1630     if (grep { $_ eq $target } @breadcrumbs) {
1631         die "inherit_from loop!  target backtrace:\n  "
1632             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
1633     }
1634
1635     if (!defined($table{$target})) {
1636         warn "Warning! target $target doesn't exist!\n";
1637         return ();
1638     }
1639     # Recurse through all inheritances.  They will be resolved on the
1640     # fly, so when this operation is done, they will all just be a
1641     # bunch of attributes with string values.
1642     # What we get here, though, are keys with references to lists of
1643     # the combined values of them all.  We will deal with lists after
1644     # this stage is done.
1645     my %combined_inheritance = ();
1646     if ($table{$target}->{inherit_from}) {
1647         my @inherit_from =
1648             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
1649         foreach (@inherit_from) {
1650             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
1651
1652             # 'template' is a marker that's considered private to
1653             # the config that had it.
1654             delete $inherited_config{template};
1655
1656             map {
1657                 if (!$combined_inheritance{$_}) {
1658                     $combined_inheritance{$_} = [];
1659                 }
1660                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
1661             } keys %inherited_config;
1662         }
1663     }
1664
1665     # We won't need inherit_from in this target any more, since we've
1666     # resolved all the inheritances that lead to this
1667     delete $table{$target}->{inherit_from};
1668
1669     # Now is the time to deal with those lists.  Here's the place to
1670     # decide what shall be done with those lists, all based on the
1671     # values of the target we're currently dealing with.
1672     # - If a value is a coderef, it will be executed with the list of
1673     #   inherited values as arguments.
1674     # - If the corresponding key doesn't have a value at all or is the
1675     #   emoty string, the inherited value list will be run through the
1676     #   default combiner (below), and the result becomes this target's
1677     #   value.
1678     # - Otherwise, this target's value is assumed to be a string that
1679     #   will simply override the inherited list of values.
1680     my $default_combiner = add(" ");
1681
1682     my %all_keys =
1683         map { $_ => 1 } (keys %combined_inheritance,
1684                          keys %{$table{$target}});
1685     foreach (sort keys %all_keys) {
1686
1687         # Current target doesn't have a value for the current key?
1688         # Assign it the default combiner, the rest of this loop body
1689         # will handle it just like any other coderef.
1690         if (!exists $table{$target}->{$_}) {
1691             $table{$target}->{$_} = $default_combiner;
1692         }
1693
1694         my $valuetype = ref($table{$target}->{$_});
1695         if ($valuetype eq "CODE") {
1696             # CODE reference, execute it with the inherited values as
1697             # arguments.
1698             $table{$target}->{$_} =
1699                 $table{$target}->{$_}->(@{$combined_inheritance{$_}});
1700         } elsif ($valuetype eq "ARRAY" || $valuetype eq "") {
1701             # ARRAY or Scalar, just leave it as is.
1702         } else {
1703             # Some other type of reference that we don't handle.
1704             # Better to abort at this point.
1705             die "cannot handle reference type $valuetype,"
1706                 ," found in target $target -> $_\n";
1707         }
1708     }
1709
1710     # Finally done, return the result.
1711     return %{$table{$target}};
1712 }
1713
1714 sub usage
1715         {
1716         print STDERR $usage;
1717         print STDERR "\npick os/compiler from:\n";
1718         my $j=0;
1719         my $i;
1720         my $k=0;
1721         foreach $i (sort keys %table)
1722                 {
1723                 next if $table{$i}->{template};
1724                 next if $i =~ /^debug/;
1725                 $k += length($i) + 1;
1726                 if ($k > 78)
1727                         {
1728                         print STDERR "\n";
1729                         $k=length($i);
1730                         }
1731                 print STDERR $i . " ";
1732                 }
1733         foreach $i (sort keys %table)
1734                 {
1735                 next if $table{$i}->{template};
1736                 next if $i !~ /^debug/;
1737                 $k += length($i) + 1;
1738                 if ($k > 78)
1739                         {
1740                         print STDERR "\n";
1741                         $k=length($i);
1742                         }
1743                 print STDERR $i . " ";
1744                 }
1745         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
1746         exit(1);
1747         }
1748
1749 sub run_dofile()
1750 {
1751     my $in = shift;
1752     my $out = shift;
1753
1754     # should we remove $out ?
1755     system("$config{perl} -I. -Mconfigdata util/dofile.pl <$in >$out.new");
1756     exit 1 if $? != 0;
1757     rename("$out.new", $out) || die "Can't rename $out.new, $!";
1758 }
1759
1760 # Configuration printer ##############################################
1761
1762 sub print_table_entry
1763 {
1764     my $target = shift;
1765     my %target = resolve_config($target);
1766     my $type = shift;
1767
1768     # Don't print the templates
1769     return if $target{template};
1770
1771     my @sequence = (
1772         "cc",
1773         "cflags",
1774         "debug_cflags",
1775         "release_cflags",
1776         "unistd",
1777         "thread_cflag",
1778         "sys_id",
1779         "lflags",
1780         "debug_lflags",
1781         "release_lflags",
1782         "bn_ops",
1783         "cpuid_obj",
1784         "bn_obj",
1785         "ec_obj",
1786         "des_obj",
1787         "aes_obj",
1788         "bf_obj",
1789         "md5_obj",
1790         "sha1_obj",
1791         "cast_obj",
1792         "rc4_obj",
1793         "rmd160_obj",
1794         "rc5_obj",
1795         "wp_obj",
1796         "cmll_obj",
1797         "modes_obj",
1798         "engines_obj",
1799         "perlasm_scheme",
1800         "dso_scheme",
1801         "shared_target",
1802         "shared_cflag",
1803         "shared_ldflag",
1804         "shared_extension",
1805         "ranlib",
1806         "arflags",
1807         "multilib",
1808         );
1809
1810     if ($type eq "TABLE") {
1811         print "\n";
1812         print "*** $target\n";
1813         printf "\$%-12s = %s\n", $_, $target{$_} foreach (@sequence);
1814     } elsif ($type eq "HASH") {
1815         my $largest =
1816             length((sort { length($a) <=> length($b) } @sequence)[-1]);
1817         print "    '$target' => {\n";
1818         foreach (@sequence) {
1819             if ($target{$_}) {
1820                 print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
1821             }
1822         }
1823         print "    },\n";
1824     }
1825 }
1826
1827 # Utility routines ###################################################
1828
1829 sub which
1830         {
1831         my($name)=@_;
1832         my $path;
1833         foreach $path (split /:/, $ENV{PATH})
1834                 {
1835                 if (-f "$path/$name$target{exe_extension}" and -x _)
1836                         {
1837                         return "$path/$name$target{exe_extension}" unless ($name eq "perl" and
1838                          system("$path/$name$target{exe_extension} -e " . '\'exit($]<5.0);\''));
1839                         }
1840                 }
1841         }
1842
1843 sub quotify {
1844     my %processors = (
1845         perl    => sub { my $x = shift;
1846                          $x =~ s/([\\\$\@"])/\\$1/g;
1847                          return '"'.$x.'"'; },
1848         );
1849     my $for = shift;
1850     my $processor =
1851         defined($processors{$for}) ? $processors{$for} : sub { shift; };
1852
1853     map { $processor->($_); } @_;
1854 }
1855
1856 # collect_information($filename, $line_continue, $regexp => $CODEref, ...)
1857 # $filename is the file to read.
1858 # $line_continue is either undef (which is a noop), or two arguments, where
1859 # the first is a regexp detecting a line continuation ending, and the
1860 # following argument is a CODEref that takes care of concatenating two
1861 # lines.
1862 # All following arguments are regex/CODEref pairs, where the regexp detects a
1863 # line and the CODEref does something with the result of the regexp.
1864 sub collect_information {
1865     my $filename = shift;
1866     my $line_continue_re = shift;
1867     my $line_concat = defined($line_continue_re) ? shift : undef;
1868     my %collectors = @_;
1869
1870     my $saved_line = "";
1871     open IN, $filename || die "unable to read $filename: $!\n";
1872     while(<IN>) {
1873         chomp;
1874         if (defined $line_concat) {
1875             $_ = $line_concat->($saved_line, $_);
1876         }
1877         if (defined $line_continue_re && /$line_continue_re/) {
1878             $saved_line = $_;
1879             next;
1880         }
1881         foreach my $re (keys %collectors) {
1882             if (/$re/) { $collectors{$re}->() };
1883         }
1884     }
1885     close IN;
1886 }