boehm-gc/configure.ac

   1 # Copyright (c) 1999, 2000, 2001, 2002, 2003, 2006, 2010, 2011 by Red Hat, Inc.
   2 # All rights reserved.
   3 # Copyright 2004 Nathanael Nerode
   4 #
   5 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   6 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   7 #
   8 # Permission is hereby granted to use or copy this program
   9 # for any purpose,  provided the above notices are retained on all copies.
  10 # Permission to modify the code and to distribute modified code is granted,
  11 # provided the above notices are retained, and a notice that the code was
  12 # modified is included with the above copyright notice.
  13 #
  14 # Original author: Tom Tromey
  15 # Modified by Nathanael Nerode
  16
  17 dnl Process this file with autoconf to produce configure.
  18
  19 AC_PREREQ(2.64)
  20 AC_INIT
  21 AC_CONFIG_SRCDIR(gcj_mlc.c)
  22 # This works around the fact that libtool configuration may change LD
  23 # for this particular configuration, but some shells, instead of
  24 # keeping the changes in LD private, export them just because LD is
  25 # exported.
  26 ORIGINAL_LD_FOR_MULTILIBS=$LD
  27
  28 AM_ENABLE_MULTILIB(, ..)
  29
  30 AC_CANONICAL_HOST
  31 AC_CANONICAL_TARGET
  32
  33 # Get the 'noncanonical' system names.
  34 ACX_NONCANONICAL_TARGET
  35
  36 # This works around an automake problem.
  37 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  38 AC_SUBST(mkinstalldirs)
  39
  40 AM_INIT_AUTOMAKE(gc, 6.6, no-define)
  41
  42 # The autoconf 2.5x version of the no-executables hack.
  43 GCC_NO_EXECUTABLES
  44
  45 # Yak.  We must force CC and CXX to /not/ be precious variables; otherwise
  46 # the wrong, non-multilib-adjusted value will be used in multilibs.
  47 # As a side effect, we have to subst CFLAGS and CXXFLAGS ourselves.
  48
  49 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  50 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  51 AC_PROG_CC
  52 AC_PROG_CXX
  53 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  54
  55 AM_PROG_CC_C_O
  56
  57 AC_SUBST(CFLAGS)
  58 AC_SUBST(CXXFLAGS)
  59
  60 # Newer automakes demand CCAS and CCASFLAGS.
  61 : ${CCAS='$(CC)'}
  62 : ${CCASFLAGS='$(CFLAGS)'}
  63 AC_SUBST(CCAS)
  64 AC_SUBST(CCASFLAGS)
  65
  66 AC_CHECK_TOOL(AS, as)
  67 AC_CHECK_TOOL(AR, ar)
  68 AC_CHECK_TOOL(RANLIB, ranlib, :)
  69
  70 AC_PROG_INSTALL
  71
  72 AM_MAINTAINER_MODE
  73
  74 . ${srcdir}/configure.host
  75
  76 case ${gc_basedir} in
  77 /* | [A-Za-z]:[/\\]*) gc_flagbasedir=${gc_basedir} ;;
  78 *) gc_flagbasedir='$(top_builddir)/'${gc_basedir} ;;
  79 esac
  80
  81 gc_cflags="${gc_cflags} -Iinclude -I"'$(top_builddir)'"/./targ-include -I${gc_flagbasedir}/libc/include"
  82 case "${host}" in
  83   *-*-cygwin32*)
  84     gc_cflags="${gc_cflags} -I${gc_flagbasedir}/../winsup/include"
  85     ;;
  86 esac
  87
  88 dnl Add for mingw targets GC_BUILD option
  89 case "${host}" in
  90   *-*-mingw*)
  91     gc_cflags="${gc_cflags} -DGC_BUILD=1"
  92     ;;
  93 esac
  94
  95 dnl gc_cflags="${gc_cflags} -fno-builtin"
  96
  97 GC_CFLAGS=${gc_cflags}
  98 AC_SUBST(GC_CFLAGS)
  99
 100 AC_PROG_LIBTOOL
 101
 102 dnl We use these options to decide which functions to include.
 103 AC_ARG_WITH(target-subdir,
 104 [  --with-target-subdir=SUBDIR
 105                           configuring with a cross compiler])
 106 AC_ARG_WITH(cross-host,
 107 [  --with-cross-host=HOST  configuring with a cross compiler])
 108
 109 AC_MSG_CHECKING([for thread model used by GCC])
 110 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 111 if test -z "$THREADS"; then
 112    THREADS=no
 113 fi
 114 AC_MSG_RESULT([$THREADS])
 115
 116 AC_ARG_ENABLE(parallel-mark,
 117 [  --enable-parallel-mark       parallelize marking and free list construction],
 118    [case "$THREADS" in
 119       no | none | single)
 120         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
 121         ;;
 122     esac]
 123 )
 124
 125 AM_CPPFLAGS="-I`cd $srcdir && ${PWDCMD-pwd}`/include"
 126 THREADCFLAGS=
 127 THREADLIBS=
 128 case "$THREADS" in
 129  no | none | single)
 130     THREADS=none
 131     ;;
 132  posix | pthreads)
 133     THREADS=posix
 134     THREADLIBS=-lpthread
 135     case "$host" in
 136      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* | alpha-*-linux*)
 137         AC_DEFINE(GC_LINUX_THREADS,1,[support for Xavier Leroy's Linux threads])
 138         AC_DEFINE(_REENTRANT,1,[Use reentrant code])
 139         if test "${enable_parallel_mark}" = yes; then
 140           AC_DEFINE(PARALLEL_MARK,1,[allow the marker to run in multiple threads])
 141         fi
 142         AC_DEFINE(THREAD_LOCAL_ALLOC,1,[define GC_local_malloc() & GC_local_malloc_atomic()])
 143         ;;
 144      *-*-linux*)
 145         AC_DEFINE(GC_LINUX_THREADS,1)
 146         AC_DEFINE(_REENTRANT,1)
 147         ;;
 148      *-*-aix*)
 149         AC_DEFINE(GC_AIX_THREADS,1,[support AIX threads])
 150         AC_DEFINE(_REENTRANT,1)
 151         ;;
 152      *-*-hpux11*)
 153         AC_MSG_WARN("Only HP-UX 11 POSIX threads are supported.")
 154         AC_DEFINE(GC_HPUX_THREADS,1,[enables support for HP/UX 11 pthreads])
 155         AC_DEFINE(_POSIX_C_SOURCE,199506L,[POSIX version of C Source])
 156         if test "${enable_parallel_mark}" = yes; then
 157           AC_DEFINE(PARALLEL_MARK,1)
 158         fi
 159         AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 160         THREADLIBS="-lpthread -lrt"
 161         # HPUX needs REENTRANT for the _r calls.
 162         AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 163         ;;
 164      *-*-hpux10*)
 165         AC_MSG_WARN("Only HP-UX 11 POSIX threads are supported.")
 166         ;;
 167      *-*-kfreebsd*-gnu)
 168        AC_DEFINE(GC_FREEBSD_THREADS)
 169        THREADCFLAGS=-pthread
 170        THREADLIBS=-pthread
 171        AC_DEFINE(_REENTRANT)
 172          if test "${enable_parallel_mark}" = yes; then
 173          AC_DEFINE(PARALLEL_MARK)
 174        fi
 175        AC_DEFINE(THREAD_LOCAL_ALLOC)
 176        AC_DEFINE(USE_COMPILER_TLS, 1,[use tls for boehm])
 177        ;;
 178      *-*-gnu*)
 179         AC_DEFINE(GC_GNU_THREADS,1,[support GNU threads])
 180         AC_DEFINE(_REENTRANT)
 181         AC_DEFINE(THREAD_LOCAL_ALLOC)
 182         ;;
 183      *-*-freebsd*)
 184         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
 185         AC_DEFINE(GC_FREEBSD_THREADS,1,[support FreeBSD threads])
 186         THREADCFLAGS=-pthread
 187         THREADLIBS=-pthread
 188         ;;
 189      *-*-solaris2.8*)
 190         AC_DEFINE(GC_SOLARIS_PTHREADS,1,[support for Solaris pthreads])
 191         # Need to use alternate thread library, otherwise gctest hangs
 192         # on Solaris 8.
 193         multi_os_directory=`$CC -print-multi-os-directory`
 194         THREADLIBS="-L/usr/lib/lwp/$multi_os_directory \
 195                     -R/usr/lib/lwp/$multi_os_directory -lpthread -lthread -lrt"
 196         ;;
 197      *-*-solaris2*)
 198         AC_DEFINE(GC_SOLARIS_PTHREADS,1,[support for Solaris pthreads])
 199         # The alternate thread library was only introduced in Solaris 8 and
 200         # became the default in Solaris 9, so no need for the special code
 201         # above otherwise.
 202         # nanosleep, sched_yield, and sem_* only live in librt before
 203         # Solaris 11.
 204         THREADLIBS="-lpthread -lrt"
 205         ;;
 206      *-*-irix*)
 207         AC_DEFINE(GC_IRIX_THREADS,1,[support for Irix pthreads])
 208         ;;
 209      *-*-cygwin*)
 210         AC_DEFINE(GC_WIN32_THREADS,1,[support for win32 threads])
 211         ;;
 212      *-*-darwin*)
 213         AC_DEFINE(GC_DARWIN_THREADS,1,[support for Mac OS X pthreads])
 214         AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 215         if test "${enable_parallel_mark}" = yes; then
 216           AC_DEFINE(PARALLEL_MARK,1)
 217         fi
 218         ;;
 219      *-*-osf*)
 220         AC_DEFINE(GC_OSF1_THREADS,1,[support for Tru64 pthreads])
 221         if test "${enable_parallel_mark}" = yes; then
 222           AC_DEFINE(PARALLEL_MARK,1)
 223           AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 224           # May want to enable it in other cases, too.
 225           # Measurements havent yet been done.
 226         fi
 227         THREADCFLAGS=-pthread
 228         THREADLIBS="-lpthread -lrt"
 229         ;;
 230     esac
 231     ;;
 232  win32)
 233     AC_DEFINE(GC_WIN32_THREADS,1)
 234     dnl Old wine getenv may not return NULL for missing entry.
 235     dnl Define EMPTY_GETENV_RESULTS here to work around the bug.
 236     ;;
 237  aix)
 238     THREADS=posix
 239     THREADLIBS=-lpthread
 240     AC_DEFINE(GC_AIX_THREADS,1)
 241     AC_DEFINE(_REENTRANT,1)
 242     ;;
 243  dce | vxworks)
 244     AC_MSG_ERROR(thread package $THREADS not yet supported)
 245     ;;
 246  *)
 247     AC_MSG_ERROR($THREADS is an unknown thread package)
 248     ;;
 249 esac
 250 AC_SUBST(THREADCFLAGS)
 251 AC_SUBST(THREADLIBS)
 252
 253 case "$host" in
 254    powerpc-*-darwin*)
 255       powerpc_darwin=true
 256       ;;
 257 esac
 258 AM_CONDITIONAL(POWERPC_DARWIN,test x$powerpc_darwin = xtrue)
 259
 260 # Darwin needs a few extra special tests to deal with variation in the
 261 # system headers.
 262 case "$host" in
 263   powerpc*-*-darwin*)
 264     AC_CHECK_MEMBER(ppc_thread_state_t.r0,
 265       AC_DEFINE(HAS_PPC_THREAD_STATE_R0,1,
 266         [ppc_thread_state_t has field r0]),,
 267       [#include <mach/thread_status.h>])
 268     AC_CHECK_MEMBER(ppc_thread_state_t.__r0,
 269       AC_DEFINE(HAS_PPC_THREAD_STATE___R0,1,dnl
 270         [ppc_thread_state_t has field __r0]),,
 271       [#include <mach/thread_status.h>])
 272     AC_CHECK_MEMBER(ppc_thread_state64_t.r0,
 273       AC_DEFINE(HAS_PPC_THREAD_STATE64_R0,1,dnl
 274         [ppc_thread_state64_t has field r0]),,
 275       [#include <mach/thread_status.h>])
 276     AC_CHECK_MEMBER(ppc_thread_state64_t.__r0,
 277       AC_DEFINE(HAS_PPC_THREAD_STATE64___R0,1,dnl
 278         [ppc_thread_state64_t has field __r0]),,
 279       [#include <mach/thread_status.h>])
 280     ;;
 281   i?86*-*-darwin*)
 282     AC_CHECK_MEMBER(x86_thread_state32_t.eax,
 283       AC_DEFINE(HAS_X86_THREAD_STATE32_EAX,1,dnl
 284         [x86_thread_state32_t has field eax]),,
 285       [#include <sys/cdefs.h>
 286       #include <mach/thread_status.h>])
 287     AC_CHECK_MEMBER(x86_thread_state32_t.__eax,
 288       AC_DEFINE(HAS_X86_THREAD_STATE32___EAX,1,dnl
 289         [x86_thread_state32_t has field __eax]),,
 290       [#include <sys/cdefs.h>
 291       #include <mach/thread_status.h>])
 292     ;;
 293   x86_64-*-darwin*)
 294     AC_CHECK_MEMBER(x86_thread_state64_t.rax,
 295       AC_DEFINE(HAS_X86_THREAD_STATE64_RAX,1,dnl
 296         [x86_thread_state64_t has field rax]),,
 297       [#include <sys/cdefs.h>
 298       #include <mach/thread_status.h>])
 299     AC_CHECK_MEMBER(x86_thread_state64_t.__rax,
 300       AC_DEFINE(HAS_X86_THREAD_STATE64___RAX,1,dnl
 301         [x86_thread_state64_t has field __rax]),,
 302       [#include <sys/cdefs.h>
 303       #include <mach/thread_status.h>])
 304      ;;
 305   *) ;;
 306 esac
 307
 308 case "$host" in
 309   # While IRIX 6 has libdl for the O32 and N32 ABIs, it's missing for N64
 310   # and unnecessary everywhere.
 311   mips-sgi-irix6*) ;;
 312   # We never want libdl on darwin. It is a fake libdl that just ends up making
 313   # dyld calls anyway
 314   *-*-darwin*) ;;
 315   *)
 316     AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 317     ;;
 318 esac
 319
 320 # extra LD Flags which are required for targets
 321 case "${host}" in
 322   *-*-darwin*)
 323     extra_ldflags_libgc=-Wl,-single_module
 324     ;;
 325 esac
 326 AC_SUBST(extra_ldflags_libgc)
 327
 328 AC_SUBST(EXTRA_TEST_LIBS)
 329
 330 target_all=libgcjgc.la
 331 AC_SUBST(target_all)
 332
 333 dnl If the target is an eCos system, use the appropriate eCos
 334 dnl I/O routines.
 335 dnl FIXME: this should not be a local option but a global target
 336 dnl system; at present there is no eCos target.
 337 TARGET_ECOS="no"
 338 AC_ARG_WITH(ecos,
 339 [  --with-ecos             enable runtime eCos target support],
 340 TARGET_ECOS="$with_ecos"
 341 )
 342
 343 addobjs=
 344 addlibs=
 345 addincludes=
 346 addtests=
 347 case "$TARGET_ECOS" in
 348    no)
 349       ;;
 350    *)
 351       AC_DEFINE(ECOS,1,[Target is ECOS])
 352       AM_CPPFLAGS="${AM_CPPFLAGS} -I${TARGET_ECOS}/include"
 353       addobjs="$addobjs ecos.lo"
 354       ;;
 355 esac
 356
 357 if test "${enable_cplusplus}" = yes; then
 358       addincludes="$addincludes include/gc_cpp.h include/gc_allocator.h"
 359       addtests="$addtests test_cpp"
 360 fi
 361
 362 AM_CONDITIONAL(CPLUSPLUS, test "${enable_cplusplus}" = yes)
 363
 364 AC_SUBST(CXX)
 365
 366 AC_SUBST(AM_CPPFLAGS)
 367
 368 # Configuration of shared libraries
 369 #
 370 AC_MSG_CHECKING(whether to build shared libraries)
 371 AC_ENABLE_SHARED
 372
 373 case "$host" in
 374  alpha-*-openbsd*)
 375      enable_shared=no
 376      AC_MSG_RESULT(no)
 377      ;;
 378  *)
 379      AC_MSG_RESULT(yes)
 380      ;;
 381 esac
 382
 383 # Checks for pthreads functions
 384 #
 385 oldLIBS="$LIBS"
 386 LIBS="$LIBS $THREADLIBS"
 387 AC_CHECK_FUNCS([pthread_getattr_np])
 388 AC_CHECK_FUNCS([pthread_get_stackaddr_np])
 389 LIBS="$oldLIBS"
 390
 391 # Configuration of machine-dependent code
 392 #
 393 # Set NO_EXECUTE_PERMISSION by default because gcj already uses
 394 # ffi_closure_{alloc,free} which takes care of allocating trampolines
 395 # in executable memory.
 396 #
 397 AC_MSG_CHECKING(which machine-dependent code should be used)
 398 machdep=
 399 case "$host" in
 400  alpha*-*-openbsd*)
 401     machdep="alpha_mach_dep.lo"
 402     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 403        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 404     fi
 405     ;;
 406  alpha*-*-linux*)
 407     machdep="alpha_mach_dep.lo"
 408     ;;
 409  i?86-*-solaris2.[[89]] | i?86-*-solaris2.1? | x86_64-*-solaris2.1?)
 410     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED,1,[PROC_VDB in Solaris 2.5 gives wrong values for dirty bits])
 411     ;;
 412  mipstx39-*-elf*)
 413     machdep="mips_ultrix_mach_dep.lo"
 414     AC_DEFINE(STACKBASE, __stackbase,[No description])
 415     AC_DEFINE(DATASTART_IS_ETEXT,1,[No description])
 416     ;;
 417  mips-dec-ultrix*)
 418     machdep="mips_ultrix_mach-dep.lo"
 419     ;;
 420  mips-nec-sysv*|mips-unknown-sysv*)
 421     ;;
 422  mips*-*-linux*)
 423     ;;
 424  mips-*-*)
 425     machdep="mips_sgi_mach_dep.lo"
 426     ;;
 427  sparc-*-netbsd*)
 428     machdep="sparc_netbsd_mach_dep.lo"
 429     ;;
 430  sparc-sun-solaris2.3)
 431     machdep="sparc_mach_dep.lo"
 432     AC_DEFINE(SUNOS53_SHARED_LIB,1,[Avoid Solaris 5.3 dynamic library bug])
 433     ;;
 434  sparc*-sun-solaris2.*)
 435     machdep="sparc_mach_dep.lo"
 436     ;;
 437  ia64-*-*)
 438     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 439     ;;
 440 esac
 441 AC_DEFINE(NO_EXECUTE_PERMISSION,1,[cause some or all of the heap to not have execute permission])
 442 if test x"$machdep" = x; then
 443 AC_MSG_RESULT($machdep)
 444    machdep="mach_dep.lo"
 445 fi
 446 addobjs="$addobjs $machdep"
 447 AC_SUBST(addobjs)
 448 AC_SUBST(addincludes)
 449 AC_SUBST(addlibs)
 450 AC_SUBST(addtests)
 451
 452 dnl As of 4.13a2, the collector will not properly work on Solaris when
 453 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 454 dnl Not needed anymore on Solaris.
 455 AC_MSG_CHECKING([whether GCC optimization should be disabled])
 456 O0_CFLAGS=
 457 case "$host" in
 458  *aix*) test "$GCC" = yes && O0_CFLAGS=-O0 ;;
 459  *) ;;
 460 esac
 461 if test x"$O0_CFLAGS" != x; then
 462    AC_MSG_RESULT(yes)
 463 else
 464    AC_MSG_RESULT(no)
 465 fi
 466 AC_SUBST([O0_CFLAGS])
 467
 468 dnl Include defines that have become de facto standard.
 469 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 470 AC_DEFINE(SILENT,1,[disables statistics printing])
 471 AC_DEFINE(NO_SIGNALS,1,[does not disable signals])
 472 AC_DEFINE(ALL_INTERIOR_POINTERS,1,[allows all pointers to the interior of objects to be recognized])
 473
 474 dnl By default, make the library as general as possible.
 475 AC_DEFINE(JAVA_FINALIZATION,1,[make it somewhat safer to finalize objects out of order])
 476 AC_DEFINE(GC_GCJ_SUPPORT,1,[include support for gcj])
 477 AC_DEFINE(ATOMIC_UNCOLLECTABLE,1,[include code for GC_malloc_atomic_uncollectable])
 478
 479 AC_ARG_ENABLE(gc-debug,
 480 [  --enable-gc-debug    include full support for pointer backtracing etc.],
 481 [ if test "$enable_gc_debug" = "yes"; then
 482     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 483     AC_DEFINE(KEEP_BACK_PTRS,1,[Add code to save back pointers])
 484     AC_DEFINE(DBG_HDRS_ALL,1,[Make sure that all objects have debug headers])
 485     case $host in
 486       ia64-*-linux* )
 487         AC_DEFINE(MAKE_BACK_GRAPH,1,[Enable GC_PRINT_BACK_HEIGHT environment variable])
 488       ;;
 489       x86-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* )
 490         AC_DEFINE(MAKE_BACK_GRAPH,1)
 491         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 492         AC_DEFINE(SAVE_CALL_COUNT, 8, [number of call frames saved with objects allocated through the debugging interface])
 493       ;;
 494     esac
 495   fi])
 496
 497 if test "${gc_use_mmap}" = "yes"; then
 498   AC_DEFINE(USE_MMAP, 1, [use MMAP instead of sbrk to get new memory])
 499 fi
 500
 501 if test -n "$with_cross_host" &&
 502    test x"$with_cross_host" != x"no"; then
 503   toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 504   toolexeclibdir='$(toolexecdir)/lib'
 505 else
 506   toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 507   toolexeclibdir='$(libdir)'
 508 fi
 509 multi_os_directory=`$CC -print-multi-os-directory`
 510 case $multi_os_directory in
 511   .) ;; # Avoid trailing /.
 512   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 513 esac
 514 AC_SUBST(toolexecdir)
 515 AC_SUBST(toolexeclibdir)
 516
 517 if test "${multilib}" = "yes"; then
 518   multilib_arg="--enable-multilib"
 519 else
 520   multilib_arg=
 521 fi
 522
 523 AC_CONFIG_HEADERS([include/gc_config.h include/gc_ext_config.h])
 524
 525 AC_CONFIG_FILES(Makefile include/Makefile testsuite/Makefile threads.mk)
 526 AC_OUTPUT