configure.ac

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([conf/confbase.Y])
   7 AC_CONFIG_AUX_DIR([tools])
   8
   9 AC_ARG_ENABLE([client],
  10   [AS_HELP_STRING([--enable-client], [enable building of BIRD client @<:@yes@:>@])],
  11   [],
  12   [enable_client=yes]
  13 )
  14
  15 AC_ARG_ENABLE([debug],
  16   [AS_HELP_STRING([--enable-debug], [enable internal debugging routines @<:@no@:>@])],
  17   [],
  18   [enable_debug=no]
  19 )
  20
  21 AC_ARG_ENABLE([debug-generated],
  22   [AS_HELP_STRING([--enable-debug-generated], [enable this to abstain from generating #line @<:@no@:>@])],
  23   [],
  24   [enable_debug_generated=no]
  25 )
  26
  27 AC_ARG_ENABLE([debug-expensive],
  28   [AS_HELP_STRING([--enable-debug-expensive], [enable expensive consistency checks (implies --enable-debug) @<:@no@:>@])],
  29   [],
  30   [enable_debug_expensive=no]
  31 )
  32
  33 AC_ARG_ENABLE([memcheck],
  34   [AS_HELP_STRING([--enable-memcheck], [check memory allocations when debugging @<:@yes@:>@])],
  35   [],
  36   [enable_memcheck=yes]
  37 )
  38
  39 AC_ARG_ENABLE([compact-tries],
  40   [AS_HELP_STRING([--enable-compact-tries], [use 4-way tries instead of 16-way ones @<:@no@:>@])],
  41   [],
  42   [enable_compact_tries=no]
  43 )
  44
  45 AC_ARG_ENABLE([pthreads],
  46   [AS_HELP_STRING([--enable-pthreads], [enable POSIX threads support @<:@try@:>@])],
  47   [],
  48   [enable_pthreads=try]
  49 )
  50
  51 AC_ARG_ENABLE([libssh],
  52   [AS_HELP_STRING([--enable-libssh], [enable LibSSH support in RPKI @<:@try@:>@])],
  53   [],
  54   [enable_libssh=try]
  55 )
  56
  57 AC_ARG_ENABLE([mpls-kernel],
  58   [AS_HELP_STRING([--enable-mpls-kernel], [enable MPLS support in kernel protocol @<:@try@:>@])],
  59   [],
  60   [enable_mpls_kernel=try]
  61 )
  62
  63 AC_ARG_WITH([protocols],
  64   [AS_HELP_STRING([--with-protocols=LIST], [include specified routing protocols @<:@all@:>@])],
  65   [],
  66   [with_protocols="all"]
  67 )
  68
  69 AC_ARG_WITH([sysconfig],
  70   [AS_HELP_STRING([--with-sysconfig=FILE], [use specified BIRD system configuration file])]
  71 )
  72
  73 AC_ARG_WITH([runtimedir],
  74   [AS_HELP_STRING([--with-runtimedir=PATH], [run-state data, obsolete variant of --runstatedir])],
  75   [runstatedir="$with_runtimedir"]
  76 )
  77
  78 AC_ARG_WITH([iproutedir],
  79   [AS_HELP_STRING([--with-iproutedir=PATH], [path to iproute2 config files @<:@/etc/iproute2@:>@])],
  80   [given_iproutedir="yes"]
  81 )
  82
  83 AC_ARG_VAR([FLEX], [location of the Flex program])
  84 AC_ARG_VAR([BISON], [location of the Bison program])
  85 AC_ARG_VAR([M4], [location of the M4 program])
  86
  87 if test "$enable_debug_expensive" = yes; then
  88   enable_debug=yes
  89 fi
  90
  91 if test "$srcdir" = . ; then
  92   # Building in current directory => create obj directory holding all objects
  93   objdir=obj
  94 else
  95   # Building in separate directory
  96   objdir=.
  97 fi
  98
  99 exedir=.
 100
 101 AC_SUBST([objdir])
 102 AC_SUBST([exedir])
 103 AC_SUBST([srcdir])
 104
 105 # Workaround for older Autoconfs that do not define runstatedir
 106 AS_IF([test -z "${runstatedir}"], [runstatedir='${localstatedir}/run'])
 107 AC_SUBST([runstatedir])
 108
 109 CONFIG_FILE="\$(sysconfdir)/bird.conf"
 110 AC_SUBST([CONFIG_FILE])
 111
 112 CONTROL_SOCKET="\$(runstatedir)/bird.ctl"
 113 AC_SUBST([CONTROL_SOCKET])
 114
 115 AC_SEARCH_LIBS([clock_gettime], [rt posix4],
 116   [],
 117   [AC_MSG_ERROR([Function clock_gettime not available.])]
 118 )
 119
 120 AC_CANONICAL_HOST
 121
 122 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
 123 if test "$ac_test_CFLAGS" != set ; then
 124   bird_cflags_default=yes
 125 fi
 126
 127 AC_PROG_CC
 128 AC_PROG_CC_C99
 129 if test -z "$GCC" ; then
 130   AC_MSG_ERROR([This program requires the GNU C Compiler.])
 131 fi
 132
 133 BIRD_CHECK_THREAD_LOCAL
 134 if test "$bird_cv_thread_local" = yes ; then
 135   AC_DEFINE([HAVE_THREAD_LOCAL], [1], [Define to 1 if _Thread_local is available])
 136 fi
 137
 138 if test "$enable_pthreads" != no ; then
 139   BIRD_CHECK_PTHREADS
 140
 141   if test "$bird_cv_lib_pthreads" = yes ; then
 142     AC_DEFINE([USE_PTHREADS], [1], [Define to 1 if pthreads are enabled])
 143     CFLAGS="$CFLAGS -pthread"
 144     LDFLAGS="$LDFLAGS -pthread"
 145     proto_bfd=bfd
 146   elif test "$enable_pthreads" = yes ; then
 147     AC_MSG_ERROR([POSIX threads not available.])
 148   fi
 149
 150   if test "$enable_pthreads" = try ; then
 151     enable_pthreads="$bird_cv_lib_pthreads"
 152   fi
 153 fi
 154
 155 # This is assumed to be necessary for proper BIRD build
 156 CFLAGS="$CFLAGS -fno-strict-aliasing -fno-strict-overflow"
 157
 158 if test "$bird_cflags_default" = yes ; then
 159   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign], [-Wall])
 160   BIRD_CHECK_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers], [-Wall -Wextra])
 161
 162   if test "$enable_debug" = no; then
 163     BIRD_CHECK_LTO
 164   fi
 165
 166   if test "$bird_cv_c_lto" = yes; then
 167     CFLAGS="$CFLAGS -flto"
 168     LDFLAGS="$LDFLAGS -flto=4 -g"
 169   else
 170     LDFLAGS="$LDFLAGS -g"
 171   fi
 172
 173   CFLAGS="$CFLAGS -Wall -Wextra -Wstrict-prototypes -Wno-parentheses"
 174   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_pointer_sign], [-Wno-pointer-sign])
 175   BIRD_ADD_GCC_OPTION([bird_cv_c_option_wno_missing_init], [-Wno-missing-field-initializers])
 176 fi
 177
 178
 179 AC_MSG_CHECKING([CFLAGS])
 180 AC_MSG_RESULT([$CFLAGS])
 181
 182 AC_MSG_CHECKING([LDFLAGS])
 183 AC_MSG_RESULT([$LDFLAGS])
 184
 185 AC_PROG_CPP
 186 AC_PROG_INSTALL
 187 AC_PROG_RANLIB
 188 AC_CHECK_PROG([FLEX], [flex], [flex])
 189 AC_CHECK_PROG([BISON], [bison], [bison])
 190 AC_CHECK_PROGS([M4], [gm4 m4])
 191
 192 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 193 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 194 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 195
 196 AC_MSG_CHECKING([bison version])
 197 BIRD_CHECK_BISON_VERSION(BISON_VERSION)
 198 AC_MSG_RESULT([$BISON_VERSION])
 199 if test "$bird_bison_synclines" = yes && test "$enable_debug_generated" = no; then
 200   M4FLAGS="$M4FLAGS -s"
 201 fi
 202
 203 if test "$bird_bison_enhanced_error" = yes; then
 204   BISONFLAGS="$BISONFLAGS -Dparse.lac=full -Dparse.error=verbose"
 205 fi
 206
 207 AC_SUBST([M4FLAGS])
 208 AC_SUBST([BISONFLAGS])
 209
 210 BIRD_CHECK_PROG_FLAVOR_GNU([$M4],
 211   [],
 212   [AC_MSG_ERROR([Provided M4 is not GNU M4.])]
 213 )
 214
 215 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 216   if test -f $with_sysconfig ; then
 217     sysdesc=$with_sysconfig
 218   else
 219     sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 220     if ! test -f $sysdesc ; then
 221       sysdesc=$sysdesc.h
 222     fi
 223   fi
 224 elif test -f sysconfig.h ; then
 225   sysdesc=sysconfig
 226 else
 227   case "$host_os" in
 228     linux*)
 229       sysdesc=linux
 230       default_iproutedir="/etc/iproute2"
 231       ;;
 232     freebsd*)
 233       sysdesc=bsd
 234       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 235       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 236       ;;
 237     kfreebsd*)
 238       sysdesc=bsd
 239       ;;
 240     netbsd*)
 241       sysdesc=bsd
 242       CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 243       LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 244       ;;
 245     openbsd*)
 246       sysdesc=bsd
 247       CPPFLAGS="$CPPFLAGS -I/usr/local/include"
 248       LDFLAGS="$LDFLAGS -L/usr/local/lib"
 249       ;;
 250     dragonfly*)
 251       sysdesc=bsd
 252       ;;
 253     *)
 254       AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 255       ;;
 256     esac
 257     sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 258 fi
 259 AC_MSG_CHECKING([which OS configuration should we use])
 260 AC_MSG_RESULT([$sysdesc])
 261 if ! test -f $sysdesc ; then
 262   AC_MSG_ERROR([The system configuration file is missing.])
 263 fi
 264 sysname=`echo $sysdesc | sed 's/\.h$//'`
 265 AC_DEFINE_UNQUOTED([SYSCONF_INCLUDE], ["$sysdesc"], [Which sysdep header to include])
 266
 267 AC_MSG_CHECKING([system-dependent directories])
 268 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '`"
 269 AC_MSG_RESULT([$sysdep_dirs])
 270 AC_SUBST([sysdep_dirs])
 271
 272 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 273
 274 if test -n "$given_iproutedir"
 275 then iproutedir=$with_iproutedir
 276 else iproutedir=$default_iproutedir
 277 fi
 278
 279 AC_SUBST([iproutedir])
 280
 281 DAEMON_LIBS=
 282 AC_SUBST(DAEMON_LIBS)
 283
 284 if test "$enable_libssh" != no ; then
 285   AC_CHECK_HEADER([libssh/libssh.h], [true], [fail=yes], [ ])
 286   AC_CHECK_LIB([ssh], [ssh_connect], [true], [fail=yes])
 287
 288   if test "$fail" != yes ; then
 289     AC_DEFINE([HAVE_LIBSSH], [1], [Define to 1 if you have the `ssh' library (-lssh).])
 290     DAEMON_LIBS="-lssh $DAEMON_LIBS"
 291     enable_libssh=yes
 292   else
 293     if test "$enable_libssh" = yes ; then
 294       AC_MSG_ERROR([LibSSH not available.])
 295     else
 296       enable_libssh=no
 297     fi
 298   fi
 299 fi
 300
 301 if test "$enable_mpls_kernel" != no ; then
 302   BIRD_CHECK_MPLS_KERNEL
 303
 304   if test "$bird_cv_mpls_kernel" = yes ; then
 305     AC_DEFINE([HAVE_MPLS_KERNEL], [1], [Define to 1 if kernel is MPLS capable])
 306   elif test "$enable_mpls_kernel" = yes ; then
 307     AC_MSG_ERROR([Kernel MPLS support not found.])
 308   fi
 309
 310   if test "$enable_mpls_kernel" = try ; then
 311     enable_mpls_kernel="$bird_cv_mpls_kernel"
 312   fi
 313 fi
 314
 315 all_protocols="aggregator $proto_bfd babel bgp l3vpn mrt ospf perf pipe radv rip rpki static"
 316
 317 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 318
 319 if test "$with_protocols" = all ; then
 320   with_protocols="$all_protocols"
 321 fi
 322
 323 AH_TEMPLATE([CONFIG_AGGREGATOR],[Aggregator protocol])
 324 AH_TEMPLATE([CONFIG_BABEL],     [Babel protocol])
 325 AH_TEMPLATE([CONFIG_BFD],       [BFD protocol])
 326 AH_TEMPLATE([CONFIG_BGP],       [BGP protocol])
 327 AH_TEMPLATE([CONFIG_BMP],       [BMP protocol])
 328 AH_TEMPLATE([CONFIG_L3VPN],     [L3VPN protocol])
 329 AH_TEMPLATE([CONFIG_MRT],       [MRT protocol])
 330 AH_TEMPLATE([CONFIG_OSPF],      [OSPF protocol])
 331 AH_TEMPLATE([CONFIG_PIPE],      [Pipe protocol])
 332 AH_TEMPLATE([CONFIG_RADV],      [RAdv protocol])
 333 AH_TEMPLATE([CONFIG_RIP],       [RIP protocol])
 334 AH_TEMPLATE([CONFIG_RPKI],      [RPKI protocol])
 335 AH_TEMPLATE([CONFIG_STATIC],    [Static protocol])
 336
 337 AC_MSG_CHECKING([protocols])
 338 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 339 if test "$protocols" = no ; then protocols= ; fi
 340 for a in $protocols ; do
 341   if ! test -f $srcdir/proto/$a/Makefile ; then
 342     AC_MSG_RESULT([failed])
 343     AC_MSG_ERROR([Requested protocol $a not found])
 344   fi
 345   AC_DEFINE_UNQUOTED([CONFIG_`echo $a | tr 'a-z' 'A-Z'`])
 346 done
 347 AC_MSG_RESULT([ok])
 348 AC_SUBST([protocols])
 349
 350 case $sysdesc in
 351   */linux*)
 352     AC_CHECK_HEADER([linux/rtnetlink.h],
 353       [],
 354       [AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],
 355       [
 356         dnl Some older versions of Linux kernel headers require these includes
 357         #include <asm/types.h>
 358         #include <sys/socket.h>
 359       ]
 360     )
 361     ;;
 362 esac
 363
 364 AC_CHECK_HEADERS_ONCE([alloca.h syslog.h])
 365 AC_CHECK_HEADER([sys/mman.h], [AC_DEFINE([HAVE_MMAP], [1], [Define to 1 if mmap() is available.])])
 366 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [], [#include <sys/socket.h>])
 367
 368 AC_C_BIGENDIAN(
 369   [AC_DEFINE([CPU_BIG_ENDIAN], [1], [Define to 1 if cpu is big endian])],
 370   [AC_DEFINE([CPU_LITTLE_ENDIAN], [1], [Define to 1 if cpu is little endian])],
 371   [AC_MSG_ERROR([Cannot determine CPU endianity.])]
 372 )
 373
 374 BIRD_CHECK_ANDROID_GLOB
 375 if test "$bird_cv_lib_glob" = no ; then
 376   AC_MSG_ERROR([glob.h not found.])
 377 elif test "$bird_cv_lib_glob" != yes ; then
 378   LIBS="$LIBS $bird_cv_lib_glob"
 379 fi
 380
 381 BIRD_CHECK_ANDROID_LOG
 382 if test "$bird_cv_lib_log" = no ; then
 383   AC_MSG_ERROR([don't know how to link syslog.])
 384 elif test "$bird_cv_lib_log" != yes ; then
 385   LIBS="$LIBS $bird_cv_lib_log"
 386 fi
 387
 388 AC_CHECK_FUNCS(getrandom)
 389 AC_CHECK_FUNCS(getentropy)
 390
 391 if test "$enable_debug" = yes ; then
 392   AC_DEFINE([DEBUGGING], [1], [Define to 1 if debugging is enabled])
 393   LDFLAGS="$LDFLAGS -rdynamic"
 394   CFLAGS="$CFLAGS -O0 -ggdb -g3"
 395
 396   BIRD_CHECK_AND_ADD_GCC_OPTION([bird_cv_c_option_dwarf4], [-gdwarf-4], [])
 397
 398   AC_CHECK_HEADER([execinfo.h],
 399     [
 400       AC_DEFINE([HAVE_EXECINFO_H], [1], [Define to 1 if you have the <execinfo.h> header file.])
 401       AC_SEARCH_LIBS([backtrace], [execinfo],
 402         [],
 403         [AC_MSG_ERROR([Function backtrace not available.])]
 404       )
 405     ]
 406   )
 407
 408   if test "$enable_memcheck" = yes ; then
 409     AC_CHECK_LIB([dmalloc], [dmalloc_debug])
 410     if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 411       AC_CHECK_LIB([efence], [malloc])
 412     fi
 413   fi
 414
 415   if test "$enable_debug_expensive" = yes ; then
 416     AC_DEFINE([ENABLE_EXPENSIVE_CHECKS], [1], [Define to 1 if you want to run expensive consistency checks.])
 417   fi
 418 fi
 419
 420 if test "$enable_compact_tries" = yes ; then
 421   AC_DEFINE([ENABLE_COMPACT_TRIES], [1], [Define to 1 if you want 4-way tries instead of 16-way ones.])
 422 fi
 423
 424 CLIENT=birdcl
 425 CLIENT_LIBS=
 426 if test "$enable_client" = yes ; then
 427   CLIENT="$CLIENT birdc"
 428   BASE_LIBS="$LIBS"
 429   LIBS=""
 430
 431   AC_CHECK_HEADERS([curses.h],
 432     [],
 433     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 434     [AC_INCLUDES_DEFAULT]
 435   )
 436
 437   AC_SEARCH_LIBS([tgetent], [tinfo tinfow ncurses curses termcap],
 438     [TINFO_LIBS="$LIBS"; LIBS=""],
 439     [AC_MSG_ERROR([The client requires ncurses library. Either install the library or use --disable-client to compile without the client.])],
 440   )
 441
 442   AC_CHECK_HEADERS([readline/readline.h readline/history.h],
 443     [],
 444     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 445     [AC_INCLUDES_DEFAULT]
 446   )
 447
 448   AC_SEARCH_LIBS([rl_callback_read_char], [readline],
 449     [READLINE_LIBS="$LIBS"; LIBS=""],
 450     [AC_MSG_ERROR([The client requires GNU Readline library. Either install the library or use --disable-client to compile without the client.])],
 451     [$TINFO_LIBS]
 452   )
 453
 454   AC_CHECK_LIB([readline], [rl_crlf],
 455     [AC_DEFINE([HAVE_RL_CRLF], [1], [Define to 1 if you have rl_crlf()])],
 456     [],
 457     [$TINFO_LIBS]
 458   )
 459
 460   AC_CHECK_LIB([readline], [rl_ding],
 461     [AC_DEFINE([HAVE_RL_DING], [1], [Define to 1 if you have rl_ding()])],
 462     [],
 463     [$TINFO_LIBS]
 464   )
 465
 466   LIBS="$BASE_LIBS"
 467   CLIENT_LIBS="$READLINE_LIBS $TINFO_LIBS"
 468 fi
 469 AC_SUBST([CLIENT])
 470 AC_SUBST([CLIENT_LIBS])
 471
 472 mkdir -p $objdir/sysdep
 473 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 474 AC_CONFIG_FILES([Makefile:Makefile.in])
 475 AC_OUTPUT
 476
 477 AC_MSG_RESULT()
 478 AC_MSG_RESULT([BIRD was configured with the following options:])
 479 AC_MSG_RESULT([        Source directory:        $srcdir])
 480 AC_MSG_RESULT([        Object directory:        $objdir])
 481 AC_MSG_RESULT([        Iproute2 directory:      $iproutedir])
 482 AC_MSG_RESULT([        System configuration:    $sysdesc])
 483 AC_MSG_RESULT([        Debugging:               $enable_debug])
 484 AC_MSG_RESULT([        Compact tries:           $enable_compact_tries])
 485 AC_MSG_RESULT([        POSIX threads:           $enable_pthreads])
 486 AC_MSG_RESULT([        Routing protocols:       $protocols])
 487 AC_MSG_RESULT([        LibSSH support in RPKI:  $enable_libssh])
 488 AC_MSG_RESULT([        Kernel MPLS support:     $enable_mpls_kernel])
 489 AC_MSG_RESULT([        Client:                  $enable_client])
 490
 491 rm -f $objdir/.*-stamp