configure.ac

   1 ###############################################################################
   2 #                                                                             #
   3 # Pakfire - The IPFire package management system                              #
   4 # Copyright (C) 2013 Pakfire development team                                 #
   5 #                                                                             #
   6 # This program is free software: you can redistribute it and/or modify        #
   7 # it under the terms of the GNU General Public License as published by        #
   8 # the Free Software Foundation, either version 3 of the License, or           #
   9 # (at your option) any later version.                                         #
  10 #                                                                             #
  11 # This program is distributed in the hope that it will be useful,             #
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of              #
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the               #
  14 # GNU General Public License for more details.                                #
  15 #                                                                             #
  16 # You should have received a copy of the GNU General Public License           #
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.       #
  18 #                                                                             #
  19 ###############################################################################
  20
  21 AC_PREREQ([2.64])
  22
  23 AC_INIT([ddns],
  24         [007],
  25         [info@ipfire.org],
  26         [ddns],
  27         [http://git.ipfire.org/?p=oddments/ddns.git;a=summary])
  28
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AC_PREFIX_DEFAULT([/usr])
  33
  34 AM_INIT_AUTOMAKE([
  35         foreign
  36         1.11
  37         -Wall
  38         -Wno-portability
  39         silent-rules
  40         tar-pax
  41         subdir-objects
  42 ])
  43 AM_SILENT_RULES([yes])
  44
  45 IT_PROG_INTLTOOL([0.40.0])
  46
  47 GETTEXT_PACKAGE=ddns
  48 AC_SUBST(GETTEXT_PACKAGE)
  49
  50 AC_PROG_LN_S
  51 AC_PROG_MKDIR_P
  52 AC_PROG_SED
  53
  54 AC_PATH_PROG([XSLTPROC], [xsltproc])
  55
  56 # Python
  57 AM_PATH_PYTHON([2.7])
  58
  59 save_LIBS="$LIBS"
  60
  61 # pkg-config
  62 PKG_PROG_PKG_CONFIG
  63 # This makes sure pkg.m4 is available.
  64 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  65
  66 # ------------------------------------------------------------------------------
  67 have_manpages=no
  68 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-man-pages],
  69         [do not install man pages]))
  70 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
  71 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
  72
  73 # ------------------------------------------------------------------------------
  74
  75 AC_ARG_WITH([systemd],
  76         AS_HELP_STRING([--with-systemd], [Enable systemd support.])
  77 )
  78
  79 AS_IF([test "x$with_systemd" != "xno"],
  80       [PKG_CHECK_MODULES(systemd, [libsystemd-daemon],
  81       [have_systemd=yes], [have_systemd=no])],
  82       [have_systemd=no]
  83 )
  84
  85 AS_IF([test "x$have_systemd" = "xyes"],
  86       [AC_MSG_CHECKING([for systemd system unit directory])
  87         AC_ARG_WITH([systemdsystemunitdir],
  88                 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
  89                 [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)]
  90         )
  91
  92         AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
  93
  94         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
  95                 AC_MSG_RESULT([$systemdsystemunitdir])
  96         else
  97                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
  98         fi
  99       ],
 100       [AS_IF([test "x$with_systemd" = "xyes"],
 101              [AC_MSG_ERROR([Systemd support is enabled but no systemd has been found.])
 102       ])
 103 ])
 104
 105 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" = "xyes"])
 106
 107 # ------------------------------------------------------------------------------
 108
 109 AC_CONFIG_FILES([
 110         Makefile
 111         po/Makefile.in
 112         src/ddns/__version__.py
 113 ])
 114
 115 AC_OUTPUT
 116 AC_MSG_RESULT([
 117         ${PACKAGE_NAME} ${VERSION}
 118
 119         prefix:                 ${prefix}
 120         sysconfdir:             ${sysconfdir}
 121
 122         Systemd support         ${have_systemd}
 123         Generate man-pages:     ${have_manpages}
 124 ])