configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax no-dist-gzip dist-xz subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  19
  20 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  21 AC_PREFIX_DEFAULT([/usr])
  22
  23 dnl version details from <major>.<minor>[-<suffix>]
  24 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  25 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  26                                                    sub("-.*","",$2); print $2}')
  27 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  28                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  29
  30 dnl libblkid version
  31 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  32 LIBBLKID_DATE="21-Mar-2018"
  33 LIBBLKID_LT_MAJOR=1
  34 LIBBLKID_LT_MINOR=1
  35 LIBBLKID_LT_MICRO=0
  36 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  37
  38 dnl libuuid version
  39 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  40 LIBUUID_LT_MAJOR=1
  41 LIBUUID_LT_MINOR=3
  42 LIBUUID_LT_MICRO=0
  43 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  44
  45 dnl libmount version
  46 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  47 LIBMOUNT_LT_MAJOR=1
  48 LIBMOUNT_LT_MINOR=1
  49 LIBMOUNT_LT_MICRO=0
  50 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  51
  52 dnl libsmartcols version
  53 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  54 LIBSMARTCOLS_LT_MAJOR=1
  55 LIBSMARTCOLS_LT_MINOR=1
  56 LIBSMARTCOLS_LT_MICRO=0
  57 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  58
  59 dnl libfdisk version
  60 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  61 LIBFDISK_LT_MAJOR=1
  62 LIBFDISK_LT_MINOR=1
  63 LIBFDISK_LT_MICRO=0
  64 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  65
  66 # Check whether exec_prefix=/usr:
  67 AS_CASE([$exec_prefix:$prefix],
  68 [NONE:NONE | NONE:/usr | /usr:*],
  69   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  70    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  71    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  72    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  73   ]
  74 )
  75
  76
  77 # default for old versions without $runstatedir
  78 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  79
  80 # our default if $localstatedir unchanged
  81 AS_CASE([$localstatedir:$runstatedir],
  82  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  83    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  84 )
  85
  86 AC_SUBST([runstatedir])
  87
  88
  89 # The original default values of {bin,sbin,lib}dir
  90 usrbin_execdir='${exec_prefix}/bin'
  91 AC_SUBST([usrbin_execdir])
  92
  93 usrsbin_execdir='${exec_prefix}/sbin'
  94 AC_SUBST([usrsbin_execdir])
  95
  96 AS_CASE([$libdir],
  97  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  98    [usrlib_execdir=$libdir],
  99  [usrlib_execdir='${exec_prefix}'$libdir]
 100 )
 101 AC_SUBST([usrlib_execdir])
 102
 103
 104 AM_PROG_CC_C_O
 105 AC_PROG_MKDIR_P
 106 AC_PROG_CC_STDC
 107 AC_PROG_YACC
 108 AC_CANONICAL_HOST
 109 AC_C_CONST
 110 AC_C_VOLATILE
 111 AC_C_BIGENDIAN
 112
 113 dnl Compiler warnings
 114 UL_WARN_ADD([-fno-common])
 115 UL_WARN_ADD([-Wall])
 116 UL_WARN_ADD([-Werror=sequence-point])
 117 UL_WARN_ADD([-Wextra])
 118 UL_WARN_ADD([-Wextra-semi])
 119 UL_WARN_ADD([-Wembedded-directive])
 120 UL_WARN_ADD([-Wmissing-declarations])
 121 UL_WARN_ADD([-Wmissing-parameter-type])
 122 UL_WARN_ADD([-Wmissing-prototypes])
 123 UL_WARN_ADD([-Wno-missing-field-initializers])
 124 UL_WARN_ADD([-Wredundant-decls])
 125 UL_WARN_ADD([-Wsign-compare])
 126 UL_WARN_ADD([-Wtype-limits])
 127 UL_WARN_ADD([-Wuninitialized])
 128 UL_WARN_ADD([-Wunused-but-set-parameter])
 129 UL_WARN_ADD([-Wunused-but-set-variable])
 130 UL_WARN_ADD([-Wunused-parameter])
 131 UL_WARN_ADD([-Wunused-result])
 132 UL_WARN_ADD([-Wunused-variable])
 133 UL_WARN_ADD([-Wnested-externs])
 134 UL_WARN_ADD([-Wpointer-arith])
 135 UL_WARN_ADD([-Wstrict-prototypes])
 136 UL_WARN_ADD([-Wformat-security])
 137 UL_WARN_ADD([-Wimplicit-function-declaration])
 138 AC_SUBST([WARN_CFLAGS])
 139
 140 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 141 AC_SUBST([BSD_WARN_CFLAGS])
 142 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 143 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 144
 145
 146 AC_ARG_ENABLE([asan],
 147   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 148   [], [enable_asan=no]
 149 )
 150 AS_IF([test "x$enable_asan" = xyes], [
 151   UL_WARN_ADD([-fsanitize=address])
 152 ])
 153
 154
 155
 156 dnl libtool-2
 157 LT_INIT
 158
 159 dnl check supported linker flags
 160 AX_CHECK_VSCRIPT
 161
 162 m4_ifndef([PKG_PROG_PKG_CONFIG],
 163   [m4_fatal([Could not locate the pkg-config autoconf
 164     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 165     If your macros are in a different location, try setting the
 166     environment variable AL_OPTS="-I/other/macro/dir" before running
 167     ./autogen.sh or autoreconf again. Make sure pkg-config is installed.])])
 168 PKG_PROG_PKG_CONFIG
 169
 170 GTK_DOC_CHECK([1.10])
 171 AC_PATH_PROG([XSLTPROC], [xsltproc])
 172
 173 linux_os=no
 174 bsd_os=no
 175 AS_CASE([${host_os}],
 176   [*linux*],
 177      [linux_os=yes],
 178   [*darwin*],
 179      [darwin_os=yes],
 180   [*bsd*],
 181      [bsd_os=yes])
 182 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 183 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 184 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 185
 186 AS_IF([test  "x$darwin_os" = xyes], [
 187   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 188 ])
 189
 190 dnl define ARCH_<NAME> conditionals
 191 UL_SET_ARCH([I86], [i?86-*])
 192 UL_SET_ARCH([86_64], [x86_64*])
 193 UL_SET_ARCH([IA64], [ia64*])
 194 UL_SET_ARCH([S390], [s390*])
 195 UL_SET_ARCH([SPARC], [sparc*])
 196 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 197 UL_SET_ARCH([M68K], [m68*])
 198 UL_SET_ARCH([MIPS], [mips*])
 199 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 200
 201 AC_SYS_LARGEFILE
 202 AC_HEADER_ASSERT
 203 AC_STRUCT_TIMEZONE
 204
 205 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 206 AM_GNU_GETTEXT_VERSION([0.18.3])
 207 AM_GNU_GETTEXT([external])
 208
 209 AS_IF([test -d "$srcdir/po"], [
 210   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 211 ], [
 212   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 213 ])
 214
 215 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 216 #ifdef HAVE_LINUX_COMPILER_H
 217 #include <linux/compiler.h>
 218 #endif
 219 ])
 220 AC_CHECK_HEADERS([ \
 221         asm/io.h \
 222         err.h \
 223         errno.h \
 224         fcntl.h \
 225         getopt.h \
 226         inttypes.h \
 227         lastlog.h \
 228         libutil.h \
 229         linux/btrfs.h \
 230         linux/cdrom.h \
 231         linux/falloc.h \
 232         linux/watchdog.h \
 233         linux/fd.h \
 234         linux/raw.h \
 235         linux/tiocl.h \
 236         linux/version.h \
 237         linux/securebits.h \
 238         linux/net_namespace.h \
 239         locale.h \
 240         mntent.h \
 241         net/if.h \
 242         net/if_dl.h \
 243         netinet/in.h \
 244         paths.h \
 245         pty.h \
 246         security/pam_appl.h \
 247         stdint.h \
 248         stdio_ext.h \
 249         stdlib.h \
 250         endian.h \
 251         byteswap.h \
 252         sys/endian.h \
 253         sys/disk.h \
 254         sys/disklabel.h \
 255         sys/file.h \
 256         sys/io.h \
 257         sys/ioccom.h \
 258         sys/ioctl.h \
 259         sys/mkdev.h \
 260         sys/mount.h \
 261         sys/param.h \
 262         sys/prctl.h \
 263         sys/resource.h \
 264         sys/signalfd.h \
 265         sys/socket.h \
 266         sys/sockio.h \
 267         sys/stat.h \
 268         sys/sysmacros.h \
 269         sys/swap.h \
 270         sys/syscall.h \
 271         sys/time.h \
 272         sys/timex.h \
 273         sys/ttydefaults.h \
 274         sys/types.h \
 275         sys/ucred.h \
 276         sys/un.h \
 277         unistd.h \
 278         shadow.h \
 279         utmp.h \
 280         utmpx.h \
 281 ])
 282
 283 # There is a collision in old kernel-headers. The both files mount.h and fs.h
 284 # define MS_* macros. Fixed by kernel commit e462ec50cb5fad19f6003a3d8087f4a0945dd2b1.
 285 #
 286 AC_CHECK_HEADERS([linux/fs.h ], [], [],
 287  [#ifdef HAVE_SYS_MOUNT_H
 288    # include <linux/fs.h>
 289    # include <sys/mount.h>
 290   #endif
 291 ])
 292
 293 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 294  [#ifdef LINUX_GSMMUX_H
 295    # include <linux/gsmmux.h>
 296    #endif
 297 ])
 298
 299 AC_CHECK_HEADERS([security/pam_misc.h],
 300                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 301                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 302 #ifdef HAVE_SECURITY_PAM_APPL_H
 303 #include <security/pam_appl.h>
 304 #endif
 305 ])
 306
 307 AC_CHECK_HEADERS([linux/blkzoned.h])
 308
 309 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 310 #ifdef HAVE_SECURITY_PAM_APPL_H
 311 #include <security/pam_appl.h>
 312 #endif
 313 ])
 314
 315 AC_CHECK_HEADERS([langinfo.h],
 316                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 317                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 318
 319 AC_MSG_CHECKING([whether langinfo.h defines ALTMON_x constants])
 320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 321         #include <langinfo.h>
 322 ]], [[
 323         char *str;
 324         str = nl_langinfo (ALTMON_1);
 325         str = nl_langinfo (ALTMON_2);
 326         str = nl_langinfo (ALTMON_3);
 327         str = nl_langinfo (ALTMON_4);
 328         str = nl_langinfo (ALTMON_5);
 329         str = nl_langinfo (ALTMON_6);
 330         str = nl_langinfo (ALTMON_7);
 331         str = nl_langinfo (ALTMON_8);
 332         str = nl_langinfo (ALTMON_9);
 333         str = nl_langinfo (ALTMON_10);
 334         str = nl_langinfo (ALTMON_11);
 335         str = nl_langinfo (ALTMON_12);
 336 ]])], [
 337         AC_MSG_RESULT([yes])
 338         AC_DEFINE([HAVE_LANGINFO_ALTMON], [1],
 339                 [Define if langinfo.h defines ALTMON_x constants])
 340 ], [
 341         AC_MSG_RESULT([no])
 342 ])
 343
 344
 345 AC_MSG_CHECKING([whether langinfo.h defines _NL_ABALTMON_x constants])
 346 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 347         #include <langinfo.h>
 348 ]], [[
 349         char *str;
 350         str = nl_langinfo (_NL_ABALTMON_1);
 351         str = nl_langinfo (_NL_ABALTMON_2);
 352         str = nl_langinfo (_NL_ABALTMON_3);
 353         str = nl_langinfo (_NL_ABALTMON_4);
 354         str = nl_langinfo (_NL_ABALTMON_5);
 355         str = nl_langinfo (_NL_ABALTMON_6);
 356         str = nl_langinfo (_NL_ABALTMON_7);
 357         str = nl_langinfo (_NL_ABALTMON_8);
 358         str = nl_langinfo (_NL_ABALTMON_9);
 359         str = nl_langinfo (_NL_ABALTMON_10);
 360         str = nl_langinfo (_NL_ABALTMON_11);
 361         str = nl_langinfo (_NL_ABALTMON_12);
 362 ]])], [
 363         AC_MSG_RESULT([yes])
 364         AC_DEFINE([HAVE_LANGINFO_NL_ABALTMON], [1],
 365                 [Define if langinfo.h defines _NL_ABALTMON_x constants])
 366 ], [
 367         AC_MSG_RESULT([no])
 368 ])
 369
 370
 371 dnl Convert some ac_cv_header_* variables to have_*
 372 dnl
 373 have_linux_version_h=$ac_cv_header_linux_version_h
 374 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 375 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 376 have_linux_raw_h=$ac_cv_header_linux_raw_h
 377 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 378 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 379 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 380 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 381 have_security_openpam_h=$ac_cv_header_security_openpam_h
 382 have_shadow_h=$ac_cv_header_shadow_h
 383 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 384 have_utmpx_h=$ac_cv_header_utmpx_h
 385
 386 AS_CASE([$linux_os:$have_linux_version_h],
 387   [yes:no],
 388     [AC_MSG_ERROR([kernel headers required on Linux])]
 389 )
 390
 391 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 392 #include <time.h>
 393 #include <unistd.h>
 394 ]], [[
 395     int a = 0;
 396     struct tm *tm = localtime(0);
 397     if (a == -1)  /* false */
 398         sleep(tm->tm_gmtoff);
 399 ]])],
 400 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 401 ])
 402
 403 AC_CHECK_MEMBERS([struct termios.c_line],,,
 404     [[#include <termios.h>]])
 405
 406 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 407         [#include <sys/stat.h>])
 408
 409 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 410
 411 AC_CHECK_DECL([llseek],
 412         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 413                         [Define to 1 if have llseek prototype])],
 414         [],
 415         [#include <unistd.h>])
 416
 417 AC_CHECK_DECL([lseek64],
 418         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 419                         [Define to 1 if have lseek64 prototype])],
 420         [],
 421         [#define _LARGEFILE_SOURCE
 422          #define _LARGEFILE64_SOURCE
 423          #include <unistd.h>])
 424
 425 AC_CHECK_DECL([environ],
 426         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 427                 [Define to 1 if have **environ prototype])],
 428 )
 429
 430 AC_CHECK_DECL([strsignal],
 431         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 432                 [Define to 1 if have strsignal function prototype])],
 433 )
 434
 435 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 436               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 437               [#include <sys/ioctl.h>])
 438 AC_CHECK_DECL([SOCK_CLOEXEC],
 439               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 440               [#include <sys/types.h>
 441                #include <sys/socket.h>])
 442 AC_CHECK_DECL([SOCK_NONBLOCK],
 443               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 444               [#include <sys/types.h>
 445                #include <sys/socket.h>])
 446 AC_CHECK_DECL([SO_PASSCRED],
 447               [have_so_passcred=yes], [have_so_passcred=no],
 448               [#include <sys/types.h>
 449                #include <sys/socket.h>])
 450
 451 AC_CHECK_FUNCS([ \
 452         __fpurge \
 453         fpurge \
 454         __fpending \
 455         secure_getenv \
 456         __secure_getenv \
 457         eaccess \
 458         err \
 459         errx \
 460         explicit_bzero \
 461         fsync \
 462         utimensat \
 463         getdomainname \
 464         getdtablesize \
 465         getexecname \
 466         getmntinfo \
 467         getrandom \
 468         getrlimit \
 469         getsgnam \
 470         inotify_init \
 471         jrand48 \
 472         lchown \
 473         llseek \
 474         lseek64 \
 475         mempcpy \
 476         mkostemp \
 477         nanosleep \
 478         ntp_gettime \
 479         personality \
 480         posix_fadvise \
 481         prctl \
 482         qsort_r \
 483         rpmatch \
 484         scandirat \
 485         setprogname \
 486         setresgid \
 487         setresuid \
 488         sched_setattr \
 489         sched_setscheduler \
 490         sigqueue \
 491         srandom \
 492         strnchr \
 493         strndup \
 494         strnlen \
 495         sysconf \
 496         sysinfo \
 497         timegm \
 498         usleep \
 499         vwarnx \
 500         warn \
 501         warnx \
 502 ])
 503 AC_FUNC_FSEEKO
 504
 505 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 506 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 507 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 508 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 509 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 510 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 511 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 512 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 513
 514 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 515
 516
 517 AC_CHECK_FUNCS([isnan], [],
 518         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 519         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 520 )
 521 AC_SUBST([MATH_LIBS])
 522
 523
 524 dnl lib/mononotic.c may require -lrt
 525 AC_CHECK_FUNCS([clock_gettime], [],
 526         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 527 )
 528
 529 have_timer="no"
 530 AC_CHECK_FUNCS([timer_create],
 531         [have_timer="yes"],
 532         [AC_CHECK_LIB([rt], [timer_create], [
 533                 have_timer="yes"
 534                 REALTIME_LIBS="-lrt"
 535         ],[
 536                 AC_SEARCH_LIBS([timer_create], [rt], [
 537                         AC_MSG_RESULT(yes)
 538                         have_timer="yes"
 539                         REALTIME_LIBS="-lrt -lpthread"
 540                 ],[], [-lpthread]
 541                 )
 542                 ])]
 543 )
 544
 545 AC_SUBST([REALTIME_LIBS])
 546
 547
 548 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 549         RTAS_LIBS="-lrtas"
 550         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 551 ])
 552 AC_SUBST([RTAS_LIBS])
 553
 554
 555 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 556                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 557         [#include <sys/types.h>
 558          #include <sys/socket.h>])
 559
 560 SOCKET_LIBS=
 561 AC_SEARCH_LIBS([socket], [socket],
 562         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 563                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 564 ])
 565 AC_SUBST([SOCKET_LIBS])
 566
 567
 568 have_dirfd=no
 569 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 570 AS_IF([test x"$have_dirfd" = xno], [
 571         AC_CHECK_DECLS([dirfd],
 572                 [have_dirfd=yes], [have_dirfd=no],
 573                 [#include <sys/types.h>
 574                  #include <dirent.h>])
 575 ])
 576
 577 have_ddfd=no
 578 AS_IF([test x"$have_dirfd" = xno], [
 579         AC_CHECK_MEMBERS([DIR.dd_fd],
 580                 [have_ddfd=yes], [have_ddfd=no],
 581                 [#include <sys/types.h>
 582                  #include <dirent.h>])
 583 ])
 584
 585 AS_CASE([$have_dirfd:$have_ddfd],
 586   [no:no],
 587     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 588 )
 589
 590
 591 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 592 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 593         #include <errno.h>
 594 ]], [[
 595         program_invocation_short_name = "test";
 596 ]])], [
 597         AC_MSG_RESULT([yes])
 598         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 599                 [Define if program_invocation_short_name is defined])
 600 ], [
 601         AC_MSG_RESULT([no])
 602 ])
 603
 604
 605 AC_MSG_CHECKING([whether __progname is defined])
 606 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 607            [if (*__progname == 0) return 1;])],
 608            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 609            AC_MSG_RESULT([yes]),
 610            AC_MSG_RESULT([no]))
 611
 612 dnl Static compilation
 613 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 614
 615 AC_ARG_ENABLE([static-programs],
 616   [AS_HELP_STRING([--enable-static-programs=LIST],
 617       [link static the programs in LIST (comma-separated,
 618       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 619
 620 AS_CASE([$enable_static_programs],
 621   [yes],
 622     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 623   [no],
 624     [enable_static_programs=]
 625 )
 626
 627 dnl Set all the individual AM_CONDITIONALs
 628 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 629   AS_CASE([,$enable_static_programs,],
 630    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 631   )
 632   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 633   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 634     [test "x$static_[]UL_PRG" = xyes])
 635 ])
 636
 637
 638 AC_ARG_ENABLE([all-programs],
 639   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 640   [], [enable_all_programs=undefined]
 641 )
 642
 643 AS_CASE([$enable_all_programs],
 644   [yes], [AC_MSG_WARN([force to build all programs by default])
 645           ul_default_estate=check],
 646   [no],  [AC_MSG_WARN([disable all programs by default])
 647           ul_default_estate=no]
 648 )
 649
 650
 651 AX_CHECK_TLS
 652
 653 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 654 # include <stdio.h>
 655 # include <stdlib.h>
 656 int main()
 657 {
 658         int i;
 659         int rc = 1;
 660         char *s;
 661         i = sscanf("x", $1, &s);
 662         if (i == 1  && *s == 'x')
 663                 rc = 0;
 664         free(s);
 665         return rc;
 666 }])
 667
 668 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 669   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 670     [scanf_cv_alloc_modifier=ms],
 671     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 672       [scanf_cv_alloc_modifier=as],
 673       [scanf_cv_alloc_modifier=no]
 674     )
 675     ,
 676
 677     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 678      #include <stdio.h>
 679      #include <unistd.h>
 680
 681      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 682
 683      #if !(__GLIBC_PREREQ(2, 7))
 684      #error %m is not available
 685      #endif
 686
 687      #elif defined(_POSIX_VERSION)
 688
 689      #if _POSIX_VERSION < 200809L
 690      #error %m is not available
 691      #endif
 692
 693      #else
 694      #error Your C-library is not supported.
 695      #endif
 696      ])],
 697     [scanf_cv_alloc_modifier=ms],
 698     [scanf_cv_alloc_modifier=no])]
 699   )
 700 )
 701
 702 AC_MSG_CHECKING([scanf string alloc modifiers])
 703 AS_CASE([$scanf_cv_alloc_modifier],
 704   [ms],
 705     [AC_MSG_RESULT([(%ms) yes])
 706      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 707      have_scanf_alloc_modifier=yes],
 708   [as],
 709     [AC_MSG_RESULT([(%as) yes])
 710      have_scanf_alloc_modifier=yes
 711      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 712   [AC_MSG_RESULT([no])
 713    have_scanf_alloc_modifier=no]
 714 )
 715
 716
 717 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 718   [], [with_util=auto]
 719 )
 720 AS_IF([test "x$with_util" = xno], [
 721   AM_CONDITIONAL([HAVE_UTIL], [false])
 722   have_util=no
 723 ], [
 724   UL_CHECK_LIB([util], [openpty])
 725 ])
 726
 727
 728 AC_CHECK_TYPES([union semun], [], [], [[
 729 #include <sys/sem.h>
 730 ]])
 731 AC_CHECK_TYPES([loff_t])
 732
 733
 734 AC_ARG_ENABLE([widechar],
 735   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 736   [], [enable_widechar=check]
 737 )
 738 UL_BUILD_INIT([widechar])
 739 UL_REQUIRES_COMPILE([widechar], [[
 740   #include <wchar.h>
 741   #include <wctype.h>
 742   #include <stdio.h>
 743   ]], [[
 744     wchar_t wc;
 745     wint_t w;
 746     w = fgetwc(stdin);
 747     if (w == WEOF) exit(1);
 748     wc = w;
 749     fputwc(wc,stdout);
 750   ]],
 751   [wchar_t support])
 752
 753 AS_IF([test "x$build_widechar" = xyes ], [
 754   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 755 ])
 756
 757
 758 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 759 #include <sched.h>
 760 ]])
 761
 762 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 763
 764 AC_CHECK_TYPES([sighandler_t], [], [], [[
 765 #include <signal.h>
 766 ]])
 767
 768 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 769 #include <sched.h>
 770 ]])
 771
 772 # on Solaris, you can't mix and match standards, since we use c99
 773 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 774 # check for crypt.h and use that without XOPEN_SOURCE.
 775 AC_CHECK_HEADERS([crypt.h])
 776 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 777 #ifdef HAVE_CRYPT_H
 778 #include <crypt.h>
 779 #else
 780 #define _XOPEN_SOURCE
 781 #include <unistd.h>
 782 #endif
 783 ]], [[
 784 char *c = crypt("abc","pw");
 785 ]])],[],[
 786   LIBS="$LIBS -lcrypt"
 787   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 788   #ifdef HAVE_CRYPT_H
 789   #include <crypt.h>
 790   #else
 791   #define _XOPEN_SOURCE
 792   #include <unistd.h>
 793   #endif
 794   ]], [[
 795   char *c = crypt("abc","pw");
 796   ]])],[
 797   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 798   have_libcrypt=yes
 799   ],[
 800   AC_MSG_ERROR([crypt() is not available])
 801   ])
 802 ])
 803 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 804
 805
 806 AC_ARG_WITH([selinux],
 807   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 808   [], [with_selinux=no]
 809 )
 810
 811 AS_IF([test "x$with_selinux" = xno], [
 812   AM_CONDITIONAL([HAVE_SELINUX], [false])
 813 ], [
 814   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 815         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 816          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 817          AM_CONDITIONAL([HAVE_SELINUX], [true])
 818          have_selinux=yes],
 819         [have_selinux=no])
 820
 821   AS_CASE([$with_selinux:$have_selinux],
 822     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 823   )
 824
 825   AS_IF([test "x$have_selinux" = xyes], [
 826     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 827     # This function is missing in old libselinux 1.xx versions
 828     AC_CHECK_FUNCS([security_get_initial_context])
 829     UL_RESTORE_FLAGS
 830   ])
 831 ])
 832 AC_SUBST([SELINUX_LIBS])
 833 AC_SUBST([SELINUX_LIBS_STATIC])
 834
 835
 836 AC_ARG_WITH([audit],
 837   AS_HELP_STRING([--with-audit], [compile with audit support]),
 838   [], [with_audit=no]
 839 )
 840
 841 AS_IF([test "x$with_audit" = xno], [
 842   AM_CONDITIONAL([HAVE_AUDIT], [false])
 843 ], [
 844   UL_CHECK_LIB([audit], [audit_log_user_message])
 845   AS_CASE([$with_audit:$have_audit],
 846     [yes:no],
 847       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 848   )
 849 ])
 850
 851 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 852   [], [with_udev=auto]
 853 )
 854
 855 AS_IF([test "x$with_udev" = xno], [
 856   AM_CONDITIONAL([HAVE_UDEV], [false])
 857 ], [
 858   UL_CHECK_LIB([udev], [udev_new])
 859   AS_CASE([$with_udev:$have_udev],
 860     [yes:no],
 861       [AC_MSG_ERROR([udev selected but libudev not found])]
 862   )
 863 ])
 864
 865
 866 dnl wide-char ncurses
 867 AC_ARG_WITH([ncursesw],
 868   AS_HELP_STRING([--without-ncursesw], [do not build with wide-char ncurses]),
 869   [], [with_ncursesw=auto]
 870 )
 871 have_ncursesw=no
 872 have_ncursesw_header=no
 873 AS_IF([test "x$with_ncursesw" != xno], [
 874   UL_NCURSES_CHECK([ncursesw])
 875   AS_IF([test "x$have_ncursesw" = xyes], [
 876     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 877     AC_CHECK_HEADERS([ncursesw/term.h])
 878
 879     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 880     # unsuccessful to avoid too many *_H permitations in config.h
 881     AS_IF([test "x$have_ncursesw_header" = xno], [
 882            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 883            AC_CHECK_HEADERS([term.h])
 884     ])
 885     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 886   ])
 887   AS_IF([test "x$have_ncursesw" = xyes], [
 888     CURSES_LIB_NAME="ncursesw"
 889     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 890   ])
 891 ])
 892 AS_CASE([$with_ncursesw:$have_ncursesw],
 893   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 894
 895
 896 dnl non-wide ncurses
 897 AC_ARG_WITH([ncurses],
 898   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses]),
 899   [], [with_ncurses=auto]
 900 )
 901 have_ncurses=no
 902 have_ncurses_header=no
 903 AS_CASE([$with_ncurses:$build_widechar],
 904   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 905
 906 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 907   UL_NCURSES_CHECK([ncurses])
 908   AS_IF([test "x$have_ncurses" = xyes], [
 909     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 910     AC_CHECK_HEADERS([ncurses/term.h])
 911
 912     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 913     # unsuccessful to avoid too many *_H permitations in config.h
 914     AS_IF([test "x$have_ncurses_header" = xno], [
 915            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 916            AC_CHECK_HEADERS([term.h])
 917     ])
 918     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 919   ])
 920   AS_IF([test "x$have_ncurses" = xyes], [
 921     CURSES_LIB_NAME="ncurses"
 922     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 923   ])
 924 ])
 925 AS_CASE([$with_ncurses:$have_ncurses],
 926   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 927
 928 AC_SUBST([NCURSES_CFLAGS])
 929 AC_SUBST([NCURSES_LIBS])
 930 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 931
 932
 933 AC_ARG_WITH([slang],
 934   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 935   [], [with_slang=no]
 936 )
 937 have_slang=no
 938 AS_IF([test "x$with_slang" = xyes], [
 939   AC_CHECK_HEADERS([slang.h slang/slang.h])
 940   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 941                    [have_slang=yes], [], [
 942 #ifdef HAVE_SLANG_H
 943 #include <slang.h>
 944 #elif defined(HAVE_SLANG_SLANG_H)
 945 #include <slang/slang.h>
 946 #endif
 947 ])
 948   AS_IF([test "x$have_slang" = xno], [
 949     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 950     [CURSES_LIB_NAME=slang
 951   ])
 952 ])
 953 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 954
 955
 956 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 957         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 958                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 959                                [Define if curses library has the use_default_colors().])
 960         ])
 961         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 962                      AC_DEFINE(HAVE_RESIZETERM, 1,
 963                                [Define if curses library has the resizeterm().])
 964         ])
 965 ])
 966
 967
 968 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 969   [], [with_tinfo=auto]
 970 )
 971 have_tinfo=no
 972 have_tinfow=no
 973 AS_IF([test "x$with_tinfo" != xno], [
 974   AS_IF([test "x$have_ncursesw" = xyes], [
 975     UL_TINFO_CHECK([tinfow])
 976   ])
 977   AS_IF([test "x$have_tinfow" = xno], [
 978     UL_TINFO_CHECK([tinfo])
 979   ])
 980 ])
 981 AC_SUBST([TINFO_LIBS])
 982 AC_SUBST([TINFO_LIBS_STATIC])
 983 AC_SUBST([TINFO_CFLAGS])
 984 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 985 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 986   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 987 ])
 988
 989
 990 AC_ARG_WITH([readline],
 991   AS_HELP_STRING([--without-readline], [do not build with GNU Readline support]),
 992   [], [with_readline=auto]
 993 )
 994
 995 AS_IF([test "x$with_readline" = xno], [
 996   AM_CONDITIONAL([HAVE_READLINE], [false])
 997 ], [
 998   UL_CHECK_LIB([readline], [readline])
 999   AS_CASE([$with_readline:$have_readline],
1000     [yes:no],
1001       [AC_MSG_ERROR([readline selected but libreadline not found ])],
1002     [*:yes],
1003       [READLINE_LIBS="-lreadline"
1004        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
1005   )
1006 ])
1007 AC_SUBST([READLINE_LIBS])
1008 AC_SUBST([READLINE_LIBS_STATIC])
1009
1010
1011 AC_ARG_WITH([utempter],
1012   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
1013   [], [with_utempter=no]
1014 )
1015
1016 AS_IF([test "x$with_utempter" = xyes], [
1017   UL_CHECK_LIB([utempter], [utempter_add_record])
1018   AS_IF([test "x$have_utempter" = xno], [
1019     AC_MSG_ERROR([utempter selected but libutempter not found])
1020   ])
1021 ], [
1022   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
1023 ])
1024
1025
1026 dnl
1027 dnl libuuid
1028 dnl
1029 AC_ARG_ENABLE([libuuid],
1030   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
1031   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
1032 )
1033 UL_BUILD_INIT([libuuid])
1034 AC_SUBST([LIBUUID_VERSION])
1035 AC_SUBST([LIBUUID_VERSION_INFO])
1036 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
1037
1038 AC_ARG_ENABLE([libuuid-force-uuidd],
1039   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
1040   [], [enable_libuuid_force_uuidd=no]
1041 )
1042
1043 AS_IF([test "x$build_libuuid" = xyes], [
1044   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
1045 ])
1046
1047 dnl
1048 dnl libblkid
1049 dnl
1050 AC_ARG_ENABLE([libblkid],
1051   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
1052   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
1053 )
1054 UL_BUILD_INIT([libblkid])
1055 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
1056 AC_SUBST([LIBBLKID_DATE])
1057 AC_SUBST([LIBBLKID_VERSION])
1058 AC_SUBST([LIBBLKID_VERSION_INFO])
1059 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
1060 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
1061 AS_IF([test "x$build_libblkid" = xyes], [
1062   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
1063 ])
1064 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1065 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1066
1067 dnl
1068 dnl libmount
1069 dnl
1070 AC_ARG_ENABLE([libmount],
1071   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1072   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1073 )
1074 UL_BUILD_INIT([libmount])
1075 UL_REQUIRES_BUILD([libmount], [libblkid])
1076 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1077 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1078 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1079 AS_IF([test "x$build_libmount" = xyes], [
1080         AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1081 ])
1082
1083 AC_SUBST([LIBMOUNT_VERSION])
1084 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1085 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1086 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1087 AC_SUBST([LIBMOUNT_VERSION_INFO])
1088 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1089
1090 AC_ARG_ENABLE([libmount-support-mtab],
1091   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1092   [], [enable_libmount_support_mtab=no]
1093 )
1094
1095 AS_IF([test "x$enable_libmount_support_mtab" = xyes], [
1096   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1097 ])
1098
1099
1100 dnl
1101 dnl libsmartcols
1102 dnl
1103 AC_ARG_ENABLE([libsmartcols],
1104   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1105   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1106 )
1107 UL_BUILD_INIT([libsmartcols])
1108 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1109
1110 AC_SUBST([LIBSMARTCOLS_VERSION])
1111 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1112 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1113
1114
1115 dnl
1116 dnl libfdisk
1117 dnl
1118 AC_ARG_ENABLE([libfdisk],
1119   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1120   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1121 )
1122 UL_BUILD_INIT([libfdisk])
1123 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1124 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1125 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1126
1127 AS_IF([test "x$build_libblkid" = xyes],
1128   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1129 AC_SUBST([LIBFDISK_PC_REQUIRES])
1130
1131 AC_SUBST([LIBFDISK_VERSION])
1132 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1133 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1134 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1135 AC_SUBST([LIBFDISK_VERSION_INFO])
1136 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1137
1138
1139 UL_BUILD_INIT([fdisk], [check])
1140 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1141 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1142 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1143 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1144
1145
1146 UL_BUILD_INIT([sfdisk], [check])
1147 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1148 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1149 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1150 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1151
1152
1153 UL_BUILD_INIT([cfdisk], [check])
1154 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1155 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1156 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1157 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1158 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1159
1160
1161 AC_ARG_ENABLE([mount],
1162   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1163   [], [UL_DEFAULT_ENABLE([mount], [check])]
1164 )
1165 UL_BUILD_INIT([mount])
1166 UL_REQUIRES_LINUX([mount])
1167 UL_REQUIRES_BUILD([mount], [libmount])
1168 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1169
1170
1171 AC_ARG_ENABLE([losetup],
1172   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1173   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1174 )
1175 UL_BUILD_INIT([losetup])
1176 UL_REQUIRES_LINUX([losetup])
1177 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1178 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1179
1180 AC_ARG_ENABLE([zramctl],
1181   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1182   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1183 )
1184 UL_BUILD_INIT([zramctl])
1185 UL_REQUIRES_LINUX([zramctl])
1186 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1187 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1188
1189 AC_ARG_ENABLE([fsck],
1190   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1191   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1192 )
1193 UL_BUILD_INIT([fsck])
1194 UL_REQUIRES_BUILD([fsck], [libmount])
1195 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1196
1197
1198 AC_ARG_ENABLE([partx],
1199   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1200   [], [UL_DEFAULT_ENABLE([partx], [check])]
1201 )
1202 UL_BUILD_INIT([partx])
1203 UL_REQUIRES_LINUX([partx])
1204 UL_REQUIRES_BUILD([partx], [libblkid])
1205 UL_REQUIRES_BUILD([partx], [libsmartcols])
1206 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1207
1208
1209 AC_ARG_ENABLE([uuidd],
1210   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1211   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1212 )
1213 UL_BUILD_INIT([uuidd])
1214 UL_REQUIRES_BUILD([uuidd], [libuuid])
1215 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1216 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1217 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" = xyes], [
1218   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1219 ])
1220 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1221
1222
1223 UL_BUILD_INIT([uuidgen], [check])
1224 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1225 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1226
1227 UL_BUILD_INIT([uuidparse], [check])
1228 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1229 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1230 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1231
1232 UL_BUILD_INIT([blkid], [check])
1233 UL_REQUIRES_BUILD([blkid], [libblkid])
1234 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1235
1236 UL_BUILD_INIT([findfs], [check])
1237 UL_REQUIRES_BUILD([findfs], [libblkid])
1238 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1239
1240 UL_BUILD_INIT([wipefs], [check])
1241 UL_REQUIRES_BUILD([wipefs], [libblkid])
1242 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1243 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1244
1245 UL_BUILD_INIT([findmnt], [check])
1246 UL_REQUIRES_BUILD([findmnt], [libmount])
1247 UL_REQUIRES_BUILD([findmnt], [libblkid])
1248 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1249 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1250
1251
1252 AC_ARG_ENABLE([mountpoint],
1253   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1254   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1255 )
1256 UL_BUILD_INIT([mountpoint])
1257 UL_REQUIRES_BUILD([mountpoint], [libmount])
1258 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1259
1260
1261 AC_ARG_ENABLE([fallocate],
1262   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1263   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1264 )
1265 UL_BUILD_INIT([fallocate])
1266 UL_REQUIRES_LINUX([fallocate])
1267 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1268 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1269
1270 AS_IF([test "x$build_fallocate" = xyes], [
1271   dnl check for valid fallocate() function
1272   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1273   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1274   dnl and program can't be linked.
1275   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1276   dnl function prototype.
1277   AC_MSG_CHECKING([for valid fallocate() function])
1278   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1279 #ifdef HAVE_UNISTD_H
1280 # include <unistd.h>
1281 #endif
1282 #ifdef HAVE_SYS_TYPES_H
1283 # include <sys/types.h>
1284 #endif
1285 #ifdef HAVE_LINUX_FALLOC_H
1286 # include <linux/falloc.h>
1287 #endif
1288 #ifdef HAVE_FCNTL_H
1289 # include <fcntl.h>
1290 #endif
1291 ]],[[
1292    long ret;
1293    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1294    if (ret != 0) {
1295       return 1;
1296    }
1297    ]])],[
1298   AC_MSG_RESULT([yes])
1299   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1300   AC_MSG_RESULT([no])])
1301 ])
1302
1303 AS_IF([test "x$build_fallocate" = xyes], [
1304   dnl check for valid posix_fallocate() function
1305   AC_MSG_CHECKING([for valid posix_fallocate() function])
1306   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1307 #ifdef HAVE_UNISTD_H
1308 # include <unistd.h>
1309 #endif
1310 #ifdef HAVE_SYS_TYPES_H
1311 # include <sys/types.h>
1312 #endif
1313 #ifdef HAVE_LINUX_FALLOC_H
1314 # include <linux/falloc.h>
1315 #endif
1316 #ifdef HAVE_FCNTL_H
1317 # include <fcntl.h>
1318 #endif
1319 ]],[[
1320    long ret;
1321    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1322    if (ret != 0) {
1323       return 1;
1324    }
1325    ]])],[
1326   AC_MSG_RESULT([yes])
1327   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1328   AC_MSG_RESULT([no])])
1329 ])
1330
1331
1332 AC_ARG_ENABLE([unshare],
1333   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1334   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1335 )
1336 UL_BUILD_INIT([unshare])
1337 UL_REQUIRES_LINUX([unshare])
1338 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1339 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1340 AC_CHECK_FUNCS([unshare])
1341
1342 AC_ARG_ENABLE([nsenter],
1343   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1344   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1345 )
1346 UL_BUILD_INIT([nsenter])
1347 UL_REQUIRES_LINUX([nsenter])
1348 UL_REQUIRES_SYSCALL_CHECK([nsenter], [UL_CHECK_SYSCALL([setns])], [setns])
1349 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1350 AC_CHECK_FUNCS([setns])
1351
1352
1353 AC_ARG_WITH([cap_ng],
1354   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1355   [], [with_cap_ng=auto]
1356 )
1357 AS_IF([test "x$with_cap_ng" = xno], [
1358   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1359   have_cap_ng=no
1360 ],[
1361   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1362 ])
1363
1364
1365 AC_ARG_ENABLE([setpriv],
1366   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1367   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1368 )
1369 UL_BUILD_INIT([setpriv])
1370 UL_REQUIRES_LINUX([setpriv])
1371 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1372 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1373 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1374
1375 PKG_CHECK_MODULES([PCRE], [libpcre2-8], [have_pcre=yes], [have_pcre=no])
1376 AS_IF([test "x$have_pcre" = xyes ], [
1377     AC_DEFINE([HAVE_PCRE], [1], [Define if libpcre2 is available])
1378 ])
1379 AM_CONDITIONAL([HAVE_PCRE], [test "x$have_pcre" = xyes])
1380
1381 AC_ARG_ENABLE([hardlink],
1382   AS_HELP_STRING([--disable-hardlink], [do not build hardlink]),
1383   [], [UL_DEFAULT_ENABLE([hardlink], [check])]
1384 )
1385 UL_BUILD_INIT([hardlink])
1386 AM_CONDITIONAL([BUILD_HARDLINK], [test "x$build_hardlink" = xyes])
1387
1388 AC_ARG_ENABLE([eject],
1389   AS_HELP_STRING([--disable-eject], [do not build eject]),
1390   [], [UL_DEFAULT_ENABLE([eject], [check])]
1391 )
1392 UL_BUILD_INIT([eject])
1393 UL_REQUIRES_LINUX([eject])
1394 UL_REQUIRES_BUILD([eject], [libmount])
1395 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1396
1397
1398 AC_ARG_ENABLE([agetty],
1399   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1400   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1401 )
1402 UL_BUILD_INIT([agetty])
1403 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1404 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx functions])
1405 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1406 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1407   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1408 ],[
1409   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1410 ])
1411
1412
1413 AC_ARG_ENABLE([plymouth_support],
1414   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1415   [], [enable_plymouth_support=check]
1416 )
1417 UL_BUILD_INIT([plymouth_support])
1418 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1419 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1420 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1421 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1422 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1423 AS_IF([test "x$build_plymouth_support" = xyes ], [
1424     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1425 ])
1426
1427
1428 AC_ARG_WITH([libz],
1429   AS_HELP_STRING([--without-libz], [compile without libz]),
1430   [], [with_libz=auto]
1431 )
1432 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1433   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1434 ])
1435
1436
1437 AC_ARG_ENABLE([cramfs],
1438   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1439   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1440 )
1441 UL_BUILD_INIT([cramfs])
1442 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1443 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1444
1445
1446 AC_ARG_ENABLE([bfs],
1447   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1448   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1449 )
1450 UL_BUILD_INIT([bfs])
1451 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1452
1453
1454 AC_ARG_ENABLE([minix],
1455   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1456   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1457 )
1458 UL_BUILD_INIT([minix])
1459 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1460
1461
1462 AC_ARG_ENABLE([fdformat],
1463   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1464   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1465 )
1466 UL_BUILD_INIT([fdformat])
1467 UL_REQUIRES_LINUX([fdformat])
1468 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1469
1470
1471 AC_ARG_ENABLE([hwclock],
1472   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1473   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1474 )
1475 have_linuxdummy=$linux_os
1476
1477 UL_BUILD_INIT([hwclock])
1478 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1479 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1480
1481
1482 UL_BUILD_INIT([mkfs], [yes])
1483 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1484
1485 UL_BUILD_INIT([isosize], [yes])
1486 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1487
1488
1489 UL_BUILD_INIT([fstrim], [check])
1490 UL_REQUIRES_LINUX([fstrim])
1491 UL_REQUIRES_BUILD([fstrim], [libmount])
1492 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1493
1494
1495 UL_BUILD_INIT([swapon], [check])
1496 UL_REQUIRES_LINUX([swapon])
1497 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1498 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1499 UL_REQUIRES_BUILD([swapon], [libblkid])
1500 UL_REQUIRES_BUILD([swapon], [libmount])
1501 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1502 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1503 AC_CHECK_FUNCS([swapon])
1504 AC_CHECK_FUNCS([swapoff])
1505
1506
1507 UL_BUILD_INIT([lsblk], [check])
1508 UL_REQUIRES_LINUX([lsblk])
1509 UL_REQUIRES_BUILD([lsblk], [libblkid])
1510 UL_REQUIRES_BUILD([lsblk], [libmount])
1511 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1512 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1513
1514
1515 UL_BUILD_INIT([lscpu], [check])
1516 UL_REQUIRES_LINUX([lscpu])
1517 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1518 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1519 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1520
1521
1522 AC_ARG_ENABLE([lslogins],
1523   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1524   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1525 )
1526 UL_BUILD_INIT([lslogins])
1527 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1528 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1529 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1530 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx functions])
1531 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1532
1533
1534 UL_BUILD_INIT([chcpu], [check])
1535 UL_REQUIRES_LINUX([chcpu])
1536 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1537 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1538
1539
1540 AC_ARG_ENABLE([wdctl],
1541   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1542   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1543 )
1544 UL_BUILD_INIT([wdctl])
1545 UL_REQUIRES_LINUX([wdctl])
1546 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1547 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1548 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1549
1550
1551 UL_BUILD_INIT([swaplabel], [check])
1552 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1553 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1554
1555
1556 UL_BUILD_INIT([mkswap], [yes])
1557 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1558 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1559   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1560 ])
1561
1562
1563 AC_ARG_ENABLE([cal],
1564   AS_HELP_STRING([--disable-cal], [do not build cal]),
1565   [], [UL_DEFAULT_ENABLE([cal], [check])]
1566 )
1567 UL_BUILD_INIT([cal])
1568 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1569
1570 AC_ARG_ENABLE([logger],
1571   AS_HELP_STRING([--disable-logger], [do not build logger]),
1572   [], [UL_DEFAULT_ENABLE([logger], [check])]
1573 )
1574 UL_BUILD_INIT([logger])
1575 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1576
1577 UL_BUILD_INIT([look], [yes])
1578 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1579
1580 UL_BUILD_INIT([mcookie], [yes])
1581 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1582
1583 UL_BUILD_INIT([namei], [yes])
1584 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1585
1586 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1587 if test "x$matriplet" != "x"; then
1588   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1589   ["Multi-arch triplet for whereis library search path"])
1590 fi
1591 UL_BUILD_INIT([whereis], [yes])
1592 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1593
1594 UL_BUILD_INIT([getopt], [yes])
1595 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1596
1597
1598 UL_BUILD_INIT([blockdev], [check])
1599 UL_REQUIRES_LINUX([blockdev])
1600 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1601
1602
1603 UL_BUILD_INIT([prlimit], [check])
1604 UL_REQUIRES_LINUX([prlimit])
1605 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1606 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1607 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1608 AS_IF([test "x$build_prlimit" = xyes], [
1609   AC_CHECK_FUNCS([prlimit])
1610 ])
1611
1612
1613 UL_BUILD_INIT([lslocks], [check])
1614 UL_REQUIRES_LINUX([lslocks])
1615 UL_REQUIRES_BUILD([lslocks], [libmount])
1616 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1617 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1618
1619
1620 AC_ARG_ENABLE([switch_root],
1621   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1622   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1623 )
1624 UL_BUILD_INIT([switch_root])
1625 UL_REQUIRES_LINUX([switch_root])
1626 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1627 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1628
1629
1630 AC_ARG_ENABLE([pivot_root],
1631   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1632   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1633 )
1634 UL_BUILD_INIT([pivot_root])
1635 UL_REQUIRES_LINUX([pivot_root])
1636 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1637 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1638
1639
1640 UL_BUILD_INIT([flock], [check])
1641 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1642 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1643
1644
1645 AC_ARG_ENABLE([lsmem],
1646   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1647   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1648 )
1649 UL_BUILD_INIT([lsmem])
1650 UL_REQUIRES_LINUX([lsmem])
1651 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1652 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1653
1654
1655 AC_ARG_ENABLE([chmem],
1656   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1657   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1658 )
1659 UL_BUILD_INIT([chmem])
1660 UL_REQUIRES_LINUX([chmem])
1661 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1662
1663 UL_BUILD_INIT([ipcmk], [yes])
1664 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1665
1666
1667 AC_ARG_ENABLE([ipcrm],
1668   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1669   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1670 )
1671 UL_BUILD_INIT([ipcrm])
1672 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1673
1674 AC_ARG_ENABLE([ipcs],
1675   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1676   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1677 )
1678 UL_BUILD_INIT([ipcs])
1679 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1680
1681 UL_BUILD_INIT([choom], [check])
1682 UL_REQUIRES_LINUX([choom])
1683 AM_CONDITIONAL([BUILD_CHOOM], [test "x$build_choom" = xyes])
1684
1685 UL_BUILD_INIT([lsipc], [check])
1686 UL_REQUIRES_LINUX([lsipc])
1687 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1688 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1689
1690 UL_BUILD_INIT([lsns], [check])
1691 UL_REQUIRES_LINUX([lsns])
1692 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1693 UL_REQUIRES_BUILD([lsns], [libmount])
1694 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1695
1696 UL_BUILD_INIT([renice], [yes])
1697 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1698
1699
1700 AC_ARG_ENABLE([rfkill],
1701   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1702   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1703 )
1704 UL_BUILD_INIT([rfkill])
1705 UL_REQUIRES_LINUX([rfkill])
1706 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1707 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1708
1709
1710 UL_BUILD_INIT([setsid], [yes])
1711 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1712
1713 UL_BUILD_INIT([readprofile], [check])
1714 UL_REQUIRES_LINUX([readprofile])
1715 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1716
1717 UL_BUILD_INIT([dmesg], [check])
1718 UL_REQUIRES_LINUX([dmesg])
1719 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1720
1721 UL_BUILD_INIT([ctrlaltdel], [check])
1722 UL_REQUIRES_LINUX([ctrlaltdel])
1723 dnl we assume reboot() to be the 1-argument variant, because even considering
1724 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1725 dnl reboot() with multiple arguments is yet only found in glibc versions
1726 dnl earlier than 2.x.
1727 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1728 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1729
1730 UL_BUILD_INIT([fincore], [check])
1731 UL_REQUIRES_LINUX([fincore])
1732 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1733 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1734
1735 UL_BUILD_INIT([fsfreeze], [check])
1736 UL_REQUIRES_LINUX([fsfreeze])
1737 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1738
1739 UL_BUILD_INIT([blkdiscard], [check])
1740 UL_REQUIRES_LINUX([blkdiscard])
1741 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1742
1743 UL_BUILD_INIT([blkzone], [check])
1744 UL_REQUIRES_LINUX([blkzone])
1745 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1746 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1747
1748 UL_BUILD_INIT([ldattach], [check])
1749 UL_REQUIRES_LINUX([ldattach])
1750 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1751
1752 UL_BUILD_INIT([rtcwake], [check])
1753 UL_REQUIRES_LINUX([rtcwake])
1754 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1755
1756 UL_BUILD_INIT([setarch], [check])
1757 UL_REQUIRES_LINUX([setarch])
1758 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1759
1760 UL_BUILD_INIT([script], [check])
1761 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1762 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1763
1764 UL_BUILD_INIT([scriptreplay], [yes])
1765 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1766
1767 UL_BUILD_INIT([col], [yes])
1768 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1769
1770 UL_BUILD_INIT([colcrt], [yes])
1771 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1772
1773 UL_BUILD_INIT([colrm], [yes])
1774 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1775
1776 UL_BUILD_INIT([column], [check])
1777 UL_REQUIRES_BUILD([column], [libsmartcols])
1778 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1779
1780 UL_BUILD_INIT([hexdump], [yes])
1781 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1782
1783 UL_BUILD_INIT([rev], [yes])
1784 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1785
1786
1787 AC_ARG_ENABLE([tunelp],
1788   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1789   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1790 )
1791 UL_BUILD_INIT([tunelp])
1792 UL_REQUIRES_LINUX([tunelp])
1793 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1794
1795
1796 AC_ARG_ENABLE([kill],
1797   AS_HELP_STRING([--disable-kill], [do not build kill]),
1798   [], [UL_DEFAULT_ENABLE([kill], [check])]
1799 )
1800 UL_BUILD_INIT([kill])
1801 UL_REQUIRES_LINUX([kill])
1802 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1803
1804
1805 AC_ARG_ENABLE([last],
1806   AS_HELP_STRING([--disable-last], [do not build last]),
1807   [], [UL_DEFAULT_ENABLE([last], [check])]
1808 )
1809 UL_BUILD_INIT([last])
1810 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1811 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx functions])
1812 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1813
1814
1815 AC_ARG_ENABLE([utmpdump],
1816   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1817   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1818 )
1819 UL_BUILD_INIT([utmpdump])
1820 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1821 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx functions])
1822 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1823
1824
1825 AC_ARG_ENABLE([line],
1826   AS_HELP_STRING([--enable-line], [build line]),
1827   [], [UL_DEFAULT_ENABLE([line], [no])]
1828 )
1829 UL_BUILD_INIT([line])
1830 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1831
1832
1833 AC_ARG_ENABLE([mesg],
1834   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1835   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1836 )
1837 UL_BUILD_INIT([mesg])
1838 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1839
1840
1841 AC_ARG_ENABLE([raw],
1842   AS_HELP_STRING([--disable-raw], [do not build raw]),
1843   [], [UL_DEFAULT_ENABLE([raw], [check])]
1844 )
1845 UL_BUILD_INIT([raw])
1846 UL_REQUIRES_LINUX([raw])
1847 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1848 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1849
1850
1851 AC_ARG_ENABLE([rename],
1852   AS_HELP_STRING([--disable-rename], [do not build rename]),
1853   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1854 )
1855 UL_BUILD_INIT([rename])
1856 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1857
1858
1859 AC_ARG_ENABLE([vipw],
1860   AS_HELP_STRING([--enable-vipw], [build vipw]),
1861   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1862 )
1863 UL_BUILD_INIT([vipw])
1864 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1865 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1866
1867
1868 AC_ARG_ENABLE([newgrp],
1869   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1870   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1871 )
1872 UL_BUILD_INIT([newgrp])
1873 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1874
1875
1876 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1877   [], [with_user=check]
1878 )
1879 have_user=no
1880 AS_IF([test "x$with_user" != xno], [
1881   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1882   AS_CASE([$with_user:$have_user],
1883     [yes:no],
1884       [AC_MSG_ERROR([user selected but libuser not found])],
1885     [*:yes],
1886       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1887   )
1888   # temporary solution, libuser has stupid .pc where are exported all
1889   # private dependencies to Requires: instead of Requires.private:
1890   AS_IF([test "x$have_user" = xyes], [
1891     LIBUSER_LIBS=-luser
1892   ])
1893 ])
1894 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1895
1896 AC_ARG_ENABLE([chfn-chsh-password],
1897   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1898   [], [enable_chfn_chsh_password=yes]
1899 )
1900
1901 AC_ARG_ENABLE([chfn-chsh],
1902   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1903   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1904 )
1905 UL_BUILD_INIT([chfn_chsh])
1906 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1907 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1908
1909 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1910   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1911   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1912 ])
1913 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1914 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1915
1916 AC_ARG_ENABLE([chsh-only-listed],
1917   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1918   [], enable_chsh_only_listed=yes
1919 )
1920
1921 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1922   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1923 ])
1924
1925
1926 AC_ARG_ENABLE([login],
1927   AS_HELP_STRING([--disable-login], [do not build login]),
1928   [], [UL_DEFAULT_ENABLE([login], [check])]
1929 )
1930 UL_BUILD_INIT([login])
1931 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1932 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1933 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1934 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx functions])
1935 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1936
1937 AC_ARG_ENABLE([login-chown-vcs],
1938   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1939   [], [enable_login_chown_vcs=no]
1940 )
1941
1942 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1943   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1944 ])
1945
1946 AC_ARG_ENABLE([login-stat-mail],
1947   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1948   [], [enable_login_stat_mail=no]
1949 )
1950
1951 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1952   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1953 ])
1954
1955
1956 AC_ARG_ENABLE([nologin],
1957   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1958   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1959 )
1960 UL_BUILD_INIT([nologin])
1961 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1962
1963
1964 AC_ARG_ENABLE([sulogin],
1965   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1966   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1967 )
1968 UL_BUILD_INIT([sulogin])
1969 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1970 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1971
1972
1973 AC_ARG_ENABLE([su],
1974   AS_HELP_STRING([--disable-su], [do not build su]),
1975   [], [UL_DEFAULT_ENABLE([su], [check])]
1976 )
1977 UL_BUILD_INIT([su])
1978 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1979 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1980 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx functions])
1981 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1982
1983
1984 AC_ARG_ENABLE([runuser],
1985   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1986   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1987 )
1988 UL_BUILD_INIT([runuser])
1989 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1990 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1991 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx functions])
1992 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1993
1994
1995 AC_ARG_ENABLE([ul],
1996   AS_HELP_STRING([--disable-ul], [do not build ul]),
1997   [], [UL_DEFAULT_ENABLE([ul], [check])]
1998 )
1999 UL_BUILD_INIT([ul])
2000 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2001 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
2002
2003
2004 AC_ARG_ENABLE([more],
2005   AS_HELP_STRING([--disable-more], [do not build more]),
2006   [], [UL_DEFAULT_ENABLE([more], [check])]
2007 )
2008 UL_BUILD_INIT([more])
2009 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
2010 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
2011
2012
2013 AC_ARG_ENABLE([pg],
2014   AS_HELP_STRING([--enable-pg], [build pg]),
2015   [], [UL_DEFAULT_ENABLE([pg], [no])]
2016 )
2017 UL_BUILD_INIT([pg])
2018 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
2019 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
2020
2021
2022 AC_ARG_ENABLE([setterm],
2023   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
2024   [], [UL_DEFAULT_ENABLE([setterm], [check])]
2025 )
2026 UL_BUILD_INIT([setterm])
2027 UL_REQUIRES_LINUX([setterm])
2028 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
2029 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
2030
2031 # build_schedutils= is just configure-only variable to control
2032 # ionice, taskset and chrt
2033 AC_ARG_ENABLE([schedutils],
2034   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
2035   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
2036 )
2037
2038
2039 UL_ENABLE_ALIAS([ionice], [schedutils])
2040 UL_BUILD_INIT([ionice])
2041 UL_REQUIRES_SYSCALL_CHECK([ionice],
2042         [UL_CHECK_SYSCALL([ioprio_set],
2043           [alpha],      [442],
2044           [i*86],       [289],
2045           [ia64*],      [1274],
2046           [powerpc*],   [273],
2047           [s390*],      [282],
2048           [sparc*],     [196],
2049           [sh*],        [288],
2050           [x86_64*],    [251])],
2051         [ioprio_set])
2052
2053 UL_REQUIRES_SYSCALL_CHECK([ionice],
2054         [UL_CHECK_SYSCALL([ioprio_get],
2055           [alpha],      [443],
2056           [i*86],       [290],
2057           [ia64*],      [1275],
2058           [powerpc*],   [274],
2059           [s390*],      [283],
2060           [sparc*],     [218],
2061           [sh*],        [289],
2062           [x86_64*],    [252])],
2063         [ioprio_get])
2064
2065 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
2066
2067
2068 UL_ENABLE_ALIAS([taskset], [schedutils])
2069 UL_BUILD_INIT([taskset])
2070 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
2071 UL_REQUIRES_SYSCALL_CHECK([taskset],
2072         [UL_CHECK_SYSCALL([sched_getaffinity])],
2073         [sched_getaffinity])
2074 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
2075
2076
2077 have_schedsetter=no
2078 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
2079       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
2080
2081 UL_ENABLE_ALIAS([chrt], [schedutils])
2082 UL_BUILD_INIT([chrt])
2083 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2084 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2085
2086 AS_IF([test "x$build_chrt" = xyes], [
2087         UL_CHECK_SYSCALL([sched_setattr])
2088 ])
2089
2090
2091 AC_ARG_ENABLE([wall],
2092   AS_HELP_STRING([--disable-wall], [do not build wall]),
2093   [], [UL_DEFAULT_ENABLE([wall], [check])]
2094 )
2095 UL_BUILD_INIT([wall])
2096 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2097 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2098
2099
2100 AC_ARG_ENABLE([write],
2101   AS_HELP_STRING([--enable-write], [build write]),
2102   [], [UL_DEFAULT_ENABLE([write], [no])]
2103 )
2104 UL_BUILD_INIT([write])
2105 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2106 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx functions])
2107 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2108
2109
2110 AC_ARG_WITH([btrfs],
2111   AS_HELP_STRING([--without-btrfs], [do not build with btrfs support]),
2112   [], [with_btrfs=check]
2113 )
2114 have_btrfs=no
2115 AS_IF([test "x$with_btrfs" != xno], [
2116   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2117     [yes:no],
2118     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2119     [check:no],
2120        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2121     [*:yes],
2122        [have_btrfs=yes
2123         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2124   )
2125 ])
2126 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2127
2128
2129 AC_ARG_WITH([systemd],
2130   AS_HELP_STRING([--without-systemd], [do not build with systemd support]),
2131   [], [with_systemd=check]
2132 )
2133
2134 have_systemd=no
2135 AS_IF([test "x$with_systemd" != xno], [
2136   # new version -- all libsystemd-* libs merged into libsystemd
2137   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2138   # old versions
2139   AS_IF([test "x$have_systemd" != "xyes"], [
2140     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2141                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2142     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2143                       [have_systemd_journal=yes], [have_systemd_journal=no])
2144     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2145            have_systemd=yes])
2146   ])
2147   AS_CASE([$with_systemd:$have_systemd],
2148     [yes:no],
2149       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2150     [*:yes],
2151        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2152   )
2153 ])
2154 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2155
2156
2157 AC_ARG_WITH([systemdsystemunitdir],
2158   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd unit files (requires systemd support)]),
2159   [], [with_systemdsystemunitdir=check]
2160 )
2161 AS_IF([test "x$with_systemdsystemunitdir" = xcheck], [
2162   AS_IF([test "x$have_systemd" = xyes], [
2163     with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`
2164   ],[
2165     with_systemdsystemunitdir=no
2166   ])
2167 ])
2168 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2169   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2170 ])
2171
2172
2173 AC_ARG_WITH([smack],
2174   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2175   [], [with_smack=no]
2176 )
2177 AS_IF([test "x$with_smack" = xyes], [
2178   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2179 ])
2180
2181
2182 AC_ARG_WITH([bashcompletiondir],
2183   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2184   [],
2185   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2186     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2187   ], [
2188     with_bashcompletiondir=${datadir}/bash-completion/completions
2189   ])
2190 ])
2191 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2192
2193 AC_ARG_ENABLE([bash-completion],
2194   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2195   [], [enable_bash_completion=yes]
2196 )
2197
2198 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2199
2200
2201 AC_ARG_WITH([python],
2202   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2203   [], [with_python=check withval=check]
2204 )
2205
2206 have_python=no
2207 have_libpython=no
2208 AS_IF([test "x$with_python" != xno], [
2209   # We follow distributions default and look for PKG module name "python"
2210   # (minimal version is 2) but if major version is explicitly specified by
2211   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2212   # "python3".
2213   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2214         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2215
2216   # check for python interpreter
2217   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2218   AS_CASE([$with_python:$have_python],
2219     [yes:no],
2220       [AC_MSG_ERROR([python selected but python interpreter not found])],
2221     [check:no],
2222        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2223     [*:yes],
2224        # check for python development stuff
2225        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2226                           [have_libpython=yes], [have_libpython=no])]
2227   )
2228 ])
2229
2230
2231 AC_ARG_ENABLE([pylibmount],
2232   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2233   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2234 )
2235 UL_BUILD_INIT([pylibmount])
2236 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2237 UL_REQUIRES_BUILD([pylibmount], [libmount])
2238 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2239
2240 # We need to introduce a verbatim dependency into the Makefile, without automake
2241 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2242 verbatim_pylibmount_dependency='
2243
2244 # pylibmountexec module must be installed after usrlib_exec libraries,
2245 # otherwise the libtool relink step will fail to find libmount.la and
2246 # will try -lmount which is possibly not available.
2247 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2248
2249 '
2250 AC_SUBST([verbatim_pylibmount_dependency])
2251 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2252
2253 AC_ARG_ENABLE([pg-bell],
2254   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2255   [], [enable_pg_bell=yes]
2256 )
2257
2258 AS_IF([test "x$enable_pg_bell" = xyes], [
2259   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2260 ])
2261
2262
2263 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2264 AC_ARG_ENABLE([fs-paths-default],
2265   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2266   [AS_CASE([$enableval],
2267     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2268     [no],  [fs_paths_defaults=""],
2269     [fs_paths_defaults="$enableval"]
2270   )],
2271   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2272 )
2273 AC_ARG_ENABLE([fs-paths-extra],
2274   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2275   [AS_CASE([$enableval],
2276      [yes|no], [fs_paths_extra=""],
2277      [fs_paths_extra="$enableval"]
2278   )],
2279   [fs_paths_extra=""]
2280 )
2281 fs_paths="$fs_paths_defaults"
2282 AS_IF([test "x$fs_paths_extra" != "x"], [
2283   AS_IF([test "x$fs_paths" != "x"], [
2284     fs_paths="${fs_paths}:"
2285   ])
2286   fs_paths="${fs_paths}${fs_paths_extra}"
2287 ])
2288 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2289
2290
2291 AC_ARG_ENABLE([use-tty-group],
2292   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2293   [], [enable_use_tty_group=yes]
2294 )
2295 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2296
2297 AS_IF([test "x$enable_use_tty_group" = xyes], [
2298   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2299 ])
2300
2301
2302 AC_ARG_ENABLE([sulogin-emergency-mount],
2303   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2304                  [use emergency mount of /dev and /proc for sulogin]),
2305   [], [enable_sulogin_emergency_mount=no]
2306 )
2307
2308 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2309   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2310             [Should sulogin use a emergency mount of /dev and /proc?])
2311 ])
2312
2313
2314 AC_ARG_ENABLE([usrdir-path],
2315   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2316   [], [enable_usrdir_path=no]
2317 )
2318
2319 AS_IF([test "x$enable_usrdir_path" = xyes], [
2320   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2321 ])
2322
2323
2324 AC_ARG_ENABLE([makeinstall-chown],
2325   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2326   [], [enable_makeinstall_chown=yes]
2327 )
2328 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2329
2330
2331 AC_ARG_ENABLE([makeinstall-setuid],
2332   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2333   [], [enable_makeinstall_setuid=yes]
2334 )
2335 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2336
2337
2338 AC_ARG_ENABLE([colors-default],
2339   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2340   [], [enable_colors_default=yes]
2341 )
2342 AS_IF([test "x$enable_colors_default" = xyes], [
2343   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2344 ])
2345
2346
2347 AC_ARG_VAR([SUID_CFLAGS],
2348            [CFLAGS used for binaries which are usually with the suid bit])
2349 AC_ARG_VAR([SUID_LDFLAGS],
2350            [LDFLAGS used for binaries which are usually with the suid bit])
2351
2352 AC_ARG_VAR([DAEMON_CFLAGS],
2353            [CFLAGS used for binaries which are usually executed as daemons])
2354 AC_ARG_VAR([DAEMON_LDFLAGS],
2355            [LDFLAGS used for binaries which are usually executed as daemons])
2356
2357 AC_ARG_VAR([SOLIB_CFLAGS],
2358            [CFLAGS used for shared libraries])
2359 AC_ARG_VAR([SOLIB_LDFLAGS],
2360            [LDFLAGS used for shared libraries])
2361
2362 AC_ARG_VAR([ADJTIME_PATH],
2363            [Path to hwclock adjtime file, default /etc/adjtime])
2364 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2365 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2366
2367
2368 LIBS=""
2369
2370
2371 AC_CONFIG_HEADERS([config.h])
2372
2373 #
2374 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2375 # more details.
2376 #
2377 AC_CONFIG_FILES([
2378 Makefile
2379 libblkid/docs/Makefile
2380 libblkid/docs/version.xml
2381 libblkid/src/blkid.h
2382 libfdisk/docs/Makefile
2383 libfdisk/docs/version.xml
2384 libfdisk/src/libfdisk.h
2385 libmount/docs/Makefile
2386 libmount/docs/version.xml
2387 libmount/src/libmount.h
2388 libsmartcols/docs/Makefile
2389 libsmartcols/docs/version.xml
2390 libsmartcols/src/libsmartcols.h
2391 po/Makefile.in
2392 ])
2393
2394 AC_OUTPUT
2395
2396 AC_MSG_RESULT([
2397         ${PACKAGE}  ${VERSION}
2398
2399         prefix:            ${prefix}
2400         exec prefix:       ${exec_prefix}
2401
2402         runstatedir:       ${runstatedir}
2403         bindir:            ${bindir}
2404         sbindir:           ${sbindir}
2405         libdir:            ${libdir}
2406         includedir:        ${includedir}
2407         usrbin_execdir:    ${usrbin_execdir}
2408         usrsbin_execdir:   ${usrsbin_execdir}
2409         usrlib_execdir:    ${usrlib_execdir}
2410
2411         compiler:          ${CC}
2412         cflags:            ${CFLAGS}
2413         suid cflags:       ${SUID_CFLAGS}
2414         ldflags:           ${LDFLAGS}
2415         suid ldflags:      ${SUID_LDFLAGS}
2416
2417         Python:            ${PYTHON}
2418         Python version:    ${PYTHON_VERSION}
2419         Python libs:       ${pyexecdir}
2420
2421         Bash completions:  ${with_bashcompletiondir}
2422         Systemd support:   ${have_systemd}
2423         Systemd unitdir:   ${with_systemdsystemunitdir}
2424         Btrfs support:     ${have_btrfs}
2425         Wide-char support: ${build_widechar}
2426
2427         warnings:
2428
2429 ${WARN_CFLAGS}
2430
2431         Type 'make' or 'make <utilname>' to compile.
2432 ])