configure.ac

   1 AC_INIT([util-linux],
   2         m4_esyscmd([tools/git-version-gen .tarball-version]),
   3         [kzak@redhat.com],,
   4         [http://www.kernel.org/pub/linux/utils/util-linux/])
   5
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_CONFIG_AUX_DIR([config])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  12 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  13 AC_USE_SYSTEM_EXTENSIONS
  14 AM_INIT_AUTOMAKE([-Wall foreign 1.10 tar-pax dist-bzip2 no-dist-gzip dist-xz -Wno-portability subdir-objects])
  15
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  17                             [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  18
  19 AC_CONFIG_SRCDIR([sys-utils/mount.c])
  20 AC_PREFIX_DEFAULT([/usr])
  21
  22 dnl version details from <major>.<minor>[-<suffix>]
  23 PACKAGE_VERSION_MAJOR=$(echo $PACKAGE_VERSION | awk -F. '{print $1}')
  24 PACKAGE_VERSION_MINOR=$(echo $PACKAGE_VERSION | awk -F. '{
  25                                                    sub("-.*","",$2); print $2}')
  26 PACKAGE_VERSION_RELEASE=$(echo $PACKAGE_VERSION | awk -F. '{
  27                      sub("-.*","",$3); print $3 ~ /^@<:@0-9@:>@+$/ ? $3 : 0}')
  28
  29 dnl libblkid version
  30 LIBBLKID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  31 LIBBLKID_DATE="19-Oct-2017"
  32 LIBBLKID_LT_MAJOR=1
  33 LIBBLKID_LT_MINOR=1
  34 LIBBLKID_LT_MICRO=0
  35 LIBBLKID_VERSION_INFO=`expr $LIBBLKID_LT_MAJOR + $LIBBLKID_LT_MINOR`:$LIBBLKID_LT_MICRO:$LIBBLKID_LT_MINOR
  36
  37 dnl libuuid version
  38 LIBUUID_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  39 LIBUUID_LT_MAJOR=1
  40 LIBUUID_LT_MINOR=3
  41 LIBUUID_LT_MICRO=0
  42 LIBUUID_VERSION_INFO=`expr $LIBUUID_LT_MAJOR + $LIBUUID_LT_MINOR`:$LIBUUID_LT_MICRO:$LIBUUID_LT_MINOR
  43
  44 dnl libmount version
  45 LIBMOUNT_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  46 LIBMOUNT_LT_MAJOR=1
  47 LIBMOUNT_LT_MINOR=1
  48 LIBMOUNT_LT_MICRO=0
  49 LIBMOUNT_VERSION_INFO=`expr $LIBMOUNT_LT_MAJOR + $LIBMOUNT_LT_MINOR`:$LIBMOUNT_LT_MICRO:$LIBMOUNT_LT_MINOR
  50
  51 dnl libsmartcols version
  52 LIBSMARTCOLS_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  53 LIBSMARTCOLS_LT_MAJOR=1
  54 LIBSMARTCOLS_LT_MINOR=1
  55 LIBSMARTCOLS_LT_MICRO=0
  56 LIBSMARTCOLS_VERSION_INFO=`expr $LIBSMARTCOLS_LT_MAJOR + $LIBSMARTCOLS_LT_MINOR`:$LIBSMARTCOLS_LT_MICRO:$LIBSMARTCOLS_LT_MINOR
  57
  58 dnl libfdisk version
  59 LIBFDISK_VERSION="$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_RELEASE"
  60 LIBFDISK_LT_MAJOR=1
  61 LIBFDISK_LT_MINOR=1
  62 LIBFDISK_LT_MICRO=0
  63 LIBFDISK_VERSION_INFO=`expr $LIBFDISK_LT_MAJOR + $LIBFDISK_LT_MINOR`:$LIBFDISK_LT_MICRO:$LIBFDISK_LT_MINOR
  64
  65 # Check whether exec_prefix=/usr:
  66 AS_CASE([$exec_prefix:$prefix],
  67 [NONE:NONE | NONE:/usr | /usr:*],
  68   [AC_MSG_NOTICE([Default --exec-prefix detected.])
  69    AS_CASE([$bindir],  ['${exec_prefix}/bin'],  [bindir=/bin;   AC_MSG_NOTICE([  --bindir defaults to /bin])  ])
  70    AS_CASE([$sbindir], ['${exec_prefix}/sbin'], [sbindir=/sbin; AC_MSG_NOTICE([  --sbindir defaults to /sbin])])
  71    AS_CASE([$libdir],  ['${exec_prefix}/lib'],  [libdir=/lib;   AC_MSG_NOTICE([  --libdir defaults to /lib])  ])
  72   ]
  73 )
  74
  75
  76 # default for old versions without $runstatedir
  77 AS_IF([test x"$runstatedir" = x], [runstatedir='${localstatedir}/run'])
  78
  79 # our default if $localstatedir unchanged
  80 AS_CASE([$localstatedir:$runstatedir],
  81  [NONE:'${localstatedir}/run' | /var:'${localstatedir}/run' | NONE:'/run' ],
  82    [runstatedir=/run; AC_MSG_NOTICE([  --runstatedir defaults to /run])]
  83 )
  84
  85 AC_SUBST([runstatedir])
  86
  87
  88 # The original default values of {bin,sbin,lib}dir
  89 usrbin_execdir='${exec_prefix}/bin'
  90 AC_SUBST([usrbin_execdir])
  91
  92 usrsbin_execdir='${exec_prefix}/sbin'
  93 AC_SUBST([usrsbin_execdir])
  94
  95 AS_CASE([$libdir],
  96  ['${exec_prefix}/'* | '${prefix}/'* | /usr/* | "${prefix}"/* ],
  97    [usrlib_execdir=$libdir],
  98  [usrlib_execdir='${exec_prefix}'$libdir]
  99 )
 100 AC_SUBST([usrlib_execdir])
 101
 102
 103 AM_PROG_CC_C_O
 104 AC_PROG_MKDIR_P
 105 AC_PROG_CC_STDC
 106 AC_PROG_YACC
 107 AC_CANONICAL_HOST
 108 AC_C_CONST
 109 AC_C_VOLATILE
 110 AC_C_BIGENDIAN
 111
 112 dnl Compiler warnings
 113 UL_WARN_ADD([-fno-common])
 114 UL_WARN_ADD([-Wall])
 115 UL_WARN_ADD([-Werror=sequence-point])
 116 UL_WARN_ADD([-Wextra])
 117 UL_WARN_ADD([-Wextra-semi])
 118 UL_WARN_ADD([-Wembedded-directive])
 119 UL_WARN_ADD([-Wmissing-declarations])
 120 UL_WARN_ADD([-Wmissing-parameter-type])
 121 UL_WARN_ADD([-Wmissing-prototypes])
 122 UL_WARN_ADD([-Wno-missing-field-initializers])
 123 UL_WARN_ADD([-Wredundant-decls])
 124 UL_WARN_ADD([-Wsign-compare])
 125 UL_WARN_ADD([-Wtype-limits])
 126 UL_WARN_ADD([-Wuninitialized])
 127 UL_WARN_ADD([-Wunused-but-set-parameter])
 128 UL_WARN_ADD([-Wunused-but-set-variable])
 129 UL_WARN_ADD([-Wunused-parameter])
 130 UL_WARN_ADD([-Wunused-result])
 131 UL_WARN_ADD([-Wunused-variable])
 132 UL_WARN_ADD([-Wnested-externs])
 133 UL_WARN_ADD([-Wpointer-arith])
 134 UL_WARN_ADD([-Wstrict-prototypes])
 135 UL_WARN_ADD([-Wformat-security])
 136 UL_WARN_ADD([-Wimplicit-function-declaration])
 137 AC_SUBST([WARN_CFLAGS])
 138
 139 UL_WARN_ADD([-Wno-clobbered], [BSD_WARN_CFLAGS])
 140 AC_SUBST([BSD_WARN_CFLAGS])
 141 UL_WARN_ADD([-Wno-unused-parameter], [NO_UNUSED_WARN_CFLAGS])
 142 AC_SUBST([NO_UNUSED_WARN_CFLAGS])
 143
 144
 145 AC_ARG_ENABLE([asan],
 146   AS_HELP_STRING([--enable-asan], [compile with Address Sanitizer]),
 147   [], [enable_asan=no]
 148 )
 149 AS_IF([test "x$enable_asan" == xyes], [
 150   UL_WARN_ADD([-fsanitize=address])
 151 ])
 152
 153
 154
 155 dnl libtool-2
 156 LT_INIT
 157
 158 dnl check supported linker flags
 159 AX_CHECK_VSCRIPT
 160
 161 m4_ifndef([PKG_PROG_PKG_CONFIG],
 162   [m4_fatal([Could not locate the pkg-config autoconf
 163     macros. These are usually located in /usr/share/aclocal/pkg.m4.
 164     If your macros are in a different location, try setting the
 165     environment variable AL_OPTS="-I/other/macro/dir" before running
 166     ./autogen.sh or autoreconf again.])])
 167 PKG_PROG_PKG_CONFIG
 168
 169 GTK_DOC_CHECK([1.10])
 170 AC_PATH_PROG([XSLTPROC], [xsltproc])
 171
 172 linux_os=no
 173 bsd_os=no
 174 AS_CASE([${host_os}],
 175   [*linux*],
 176      [linux_os=yes],
 177   [*darwin*],
 178      [darwin_os=yes],
 179   [*bsd*],
 180      [bsd_os=yes])
 181 AM_CONDITIONAL([LINUX], [test "x$linux_os" = xyes])
 182 AM_CONDITIONAL([DARWIN], [test "x$darwin_os" = xyes])
 183 AM_CONDITIONAL([BSD], [test "x$bsd_os" = xyes])
 184
 185 AS_IF([test  "x$darwin_os" = xyes], [
 186   AC_DEFINE([_DARWIN_C_SOURCE], [1], [Enable MAP_ANON in sys/mman.h on Mac OS X])
 187 ])
 188
 189 dnl define ARCH_<NAME> conditionals
 190 UL_SET_ARCH([I86], [i?86-*])
 191 UL_SET_ARCH([86_64], [x86_64*])
 192 UL_SET_ARCH([IA64], [ia64*])
 193 UL_SET_ARCH([S390], [s390*])
 194 UL_SET_ARCH([SPARC], [sparc*])
 195 UL_SET_ARCH([PPC], [ppc*|powerpc*])
 196 UL_SET_ARCH([M68K], [m68*])
 197 UL_SET_ARCH([MIPS], [mips*])
 198 UL_SET_ARCH([HPPA], [hppa*|parisc*])
 199
 200 AC_SYS_LARGEFILE
 201 AC_HEADER_ASSERT
 202 AC_STRUCT_TIMEZONE
 203
 204 dnl Don't forget to maintain alternatively allowed versions in autogen.sh!
 205 AM_GNU_GETTEXT_VERSION([0.18.3])
 206 AM_GNU_GETTEXT([external])
 207
 208 AS_IF([test -d "$srcdir/po"], [
 209   ALL_LINGUAS=`cd $srcdir/po > /dev/null && echo *.po | sed 's/\.po//g'`
 210 ], [
 211   ALL_LINGUAS="af am ar as be bg bn_IN bn ca cs cy da de el en_GB es et eu_ES fa fi fr gl gu he hi hr hu hy id is it ja ka kn ko ku lo lt lv mk ml mr ms my nb nl nn no nso or pa pl pt_BR pt ro ru si sk sl sq sr@Latn sr sv ta te th tr uk ur vi zh_CN zh_TW zu"
 212 ])
 213
 214 AC_CHECK_HEADERS([linux/compiler.h linux/blkpg.h linux/major.h], [], [], [
 215 #ifdef HAVE_LINUX_COMPILER_H
 216 #include <linux/compiler.h>
 217 #endif
 218 ])
 219 AC_CHECK_HEADERS([ \
 220         asm/io.h \
 221         err.h \
 222         errno.h \
 223         fcntl.h \
 224         getopt.h \
 225         inttypes.h \
 226         lastlog.h \
 227         libutil.h \
 228         linux/btrfs.h \
 229         linux/cdrom.h \
 230         linux/falloc.h \
 231         linux/watchdog.h \
 232         linux/fd.h \
 233         linux/raw.h \
 234         linux/tiocl.h \
 235         linux/version.h \
 236         linux/securebits.h \
 237         linux/net_namespace.h \
 238         locale.h \
 239         mntent.h \
 240         net/if.h \
 241         net/if_dl.h \
 242         netinet/in.h \
 243         paths.h \
 244         pty.h \
 245         security/pam_appl.h \
 246         stdint.h \
 247         stdio_ext.h \
 248         stdlib.h \
 249         endian.h \
 250         byteswap.h \
 251         sys/endian.h \
 252         sys/disk.h \
 253         sys/disklabel.h \
 254         sys/file.h \
 255         sys/io.h \
 256         sys/ioccom.h \
 257         sys/ioctl.h \
 258         sys/mkdev.h \
 259         sys/mount.h \
 260         sys/param.h \
 261         sys/prctl.h \
 262         sys/resource.h \
 263         sys/signalfd.h \
 264         sys/socket.h \
 265         sys/sockio.h \
 266         sys/stat.h \
 267         sys/sysmacros.h \
 268         sys/swap.h \
 269         sys/syscall.h \
 270         sys/time.h \
 271         sys/timex.h \
 272         sys/ttydefaults.h \
 273         sys/types.h \
 274         sys/ucred.h \
 275         sys/un.h \
 276         unistd.h \
 277         shadow.h \
 278         utmp.h \
 279         utmpx.h \
 280 ])
 281
 282 AC_CHECK_HEADERS([linux/gsmmux.h ], [], [],
 283  [#ifdef LINUX_GSMMUX_H
 284    # include <linux/gsmmux.h>
 285    #endif
 286 ])
 287
 288 AC_CHECK_HEADERS([security/pam_misc.h],
 289                 [AM_CONDITIONAL([HAVE_LINUXPAM], [true])],
 290                 [AM_CONDITIONAL([HAVE_LINUXPAM], [false])], [
 291 #ifdef HAVE_SECURITY_PAM_APPL_H
 292 #include <security/pam_appl.h>
 293 #endif
 294 ])
 295
 296 AC_CHECK_HEADERS([linux/blkzoned.h])
 297
 298 AC_CHECK_HEADERS([security/openpam.h], [], [], [
 299 #ifdef HAVE_SECURITY_PAM_APPL_H
 300 #include <security/pam_appl.h>
 301 #endif
 302 ])
 303
 304 AC_CHECK_HEADERS([langinfo.h],
 305                 [AM_CONDITIONAL([HAVE_LANGINFO], [true])],
 306                 [AM_CONDITIONAL([HAVE_LANGINFO], [false])])
 307
 308 dnl Convert some ac_cv_header_* variables to have_*
 309 dnl
 310 have_linux_version_h=$ac_cv_header_linux_version_h
 311 have_linux_blkzoned_h=$ac_cv_header_linux_blkzoned_h
 312 have_linux_btrfs_h=$ac_cv_header_linux_btrfs_h
 313 have_linux_raw_h=$ac_cv_header_linux_raw_h
 314 have_linux_securebits_h=$ac_cv_header_linux_securebits_h
 315 have_linux_watchdog_h=$ac_cv_header_linux_watchdog_h
 316 have_security_pam_appl_h=$ac_cv_header_security_pam_appl_h
 317 have_security_pam_misc_h=$ac_cv_header_security_pam_misc_h
 318 have_security_openpam_h=$ac_cv_header_security_openpam_h
 319 have_shadow_h=$ac_cv_header_shadow_h
 320 have_sys_signalfd_h=$ac_cv_header_sys_signalfd_h
 321 have_utmpx_h=$ac_cv_header_utmpx_h
 322
 323 AS_CASE([$linux_os:$have_linux_version_h],
 324   [yes:no],
 325     [AC_MSG_ERROR([kernel headers required on Linux])]
 326 )
 327
 328 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 329 #include <time.h>
 330 #include <unistd.h>
 331 ]], [[
 332     int a = 0;
 333     struct tm *tm = localtime(0);
 334     if (a == -1)  /* false */
 335         sleep(tm->tm_gmtoff);
 336 ]])],
 337 [AC_DEFINE([HAVE_TM_GMTOFF], [1], [Does struct tm have a field tm_gmtoff?])
 338 ])
 339
 340 AC_CHECK_MEMBERS([struct termios.c_line],,,
 341     [[#include <termios.h>]])
 342
 343 AC_CHECK_MEMBERS([struct stat.st_mtim.tv_nsec],,,
 344         [#include <sys/stat.h>])
 345
 346 AC_CHECK_DECLS([_NL_TIME_WEEK_1STDAY],[],[],[[#include <langinfo.h>]])
 347
 348 AC_CHECK_DECL([llseek],
 349         [AC_DEFINE([HAVE_LLSEEK_PROTOTYPE], [1],
 350                         [Define to 1 if have llseek prototype])],
 351         [],
 352         [#include <unistd.h>])
 353
 354 AC_CHECK_DECL([lseek64],
 355         [AC_DEFINE([HAVE_LSEEK64_PROTOTYPE], [1],
 356                         [Define to 1 if have lseek64 prototype])],
 357         [],
 358         [#define _LARGEFILE_SOURCE
 359          #define _LARGEFILE64_SOURCE
 360          #include <unistd.h>])
 361
 362 AC_CHECK_DECL([environ],
 363         [AC_DEFINE([HAVE_ENVIRON_DECL], [1],
 364                 [Define to 1 if have **environ prototype])],
 365 )
 366
 367 AC_CHECK_DECL([strsignal],
 368         [AC_DEFINE([HAVE_STRSIGNAL_DECL], [1],
 369                 [Define to 1 if have strsignal function prototype])],
 370 )
 371
 372 AC_CHECK_DECL([TIOCGLCKTRMIOS],
 373               [have_tiocglcktrmios=yes], [have_tiocglcktrmios=no],
 374               [#include <sys/ioctl.h>])
 375 AC_CHECK_DECL([SOCK_CLOEXEC],
 376               [have_sock_cloexec=yes], [have_sock_cloexec=no],
 377               [#include <sys/types.h>
 378                #include <sys/socket.h>])
 379 AC_CHECK_DECL([SOCK_NONBLOCK],
 380               [have_sock_nonblock=yes], [have_sock_nonblock=no],
 381               [#include <sys/types.h>
 382                #include <sys/socket.h>])
 383 AC_CHECK_DECL([SO_PASSCRED],
 384               [have_so_passcred=yes], [have_so_passcred=no],
 385               [#include <sys/types.h>
 386                #include <sys/socket.h>])
 387
 388 AC_CHECK_FUNCS([ \
 389         __fpending \
 390         secure_getenv \
 391         __secure_getenv \
 392         eaccess \
 393         err \
 394         errx \
 395         explicit_bzero \
 396         fsync \
 397         utimensat \
 398         getdomainname \
 399         getdtablesize \
 400         getexecname \
 401         getmntinfo \
 402         getrandom \
 403         getrlimit \
 404         getsgnam \
 405         inotify_init \
 406         jrand48 \
 407         lchown \
 408         llseek \
 409         lseek64 \
 410         mempcpy \
 411         mkostemp \
 412         nanosleep \
 413         ntp_gettime \
 414         personality \
 415         posix_fadvise \
 416         prctl \
 417         qsort_r \
 418         rpmatch \
 419         scandirat \
 420         setprogname \
 421         setresgid \
 422         setresuid \
 423         sched_setattr \
 424         sched_setscheduler \
 425         sigqueue \
 426         srandom \
 427         strnchr \
 428         strndup \
 429         strnlen \
 430         sysconf \
 431         sysinfo \
 432         timegm \
 433         usleep \
 434         vwarnx \
 435         warn \
 436         warnx \
 437 ])
 438 AC_FUNC_FSEEKO
 439
 440 AC_CHECK_FUNCS([openat fstatat unlinkat], [have_openat=yes], [have_openat=no])
 441 AC_CHECK_FUNCS([ioperm iopl], [have_io=yes])
 442 AC_CHECK_FUNCS([futimens], [have_futimens=yes])
 443 AC_CHECK_FUNCS([inotify_init1], [have_inotify_init1=yes])
 444 AC_CHECK_FUNCS([open_memstream], [have_open_memstream=yes],[have_open_memstream=no])
 445 AC_CHECK_FUNCS([reboot], [have_reboot=yes],[have_reboot=no])
 446 AC_CHECK_FUNCS([updwtmpx updwtmpx], [have_gnu_utmpx=yes], [have_gnu_utmpx=no])
 447 AC_CHECK_FUNCS([getusershell], [have_getusershell=yes],[have_getusershell=no])
 448
 449 AM_CONDITIONAL([HAVE_OPENAT], [test "x$have_openat" = xyes])
 450
 451
 452 AC_CHECK_FUNCS([isnan], [],
 453         [AC_CHECK_LIB([m], [isnan], [MATH_LIBS="-lm"])]
 454         [AC_CHECK_LIB([m], [__isnan], [MATH_LIBS="-lm"])]
 455 )
 456 AC_SUBST([MATH_LIBS])
 457
 458
 459 dnl lib/mononotic.c may require -lrt
 460 AC_CHECK_FUNCS([clock_gettime], [],
 461         [AC_CHECK_LIB([rt], [clock_gettime], [REALTIME_LIBS="-lrt"])]
 462 )
 463
 464 have_timer="no"
 465 AC_CHECK_FUNCS([timer_create],
 466         [have_timer="yes"],
 467         [AC_CHECK_LIB([rt], [timer_create], [
 468                 have_timer="yes"
 469                 REALTIME_LIBS="-lrt"
 470         ],[
 471                 AC_SEARCH_LIBS([timer_create], [rt], [
 472                         AC_MSG_RESULT(yes)
 473                         have_timer="yes"
 474                         REALTIME_LIBS="-lrt -lpthread"
 475                 ],[], [-lpthread]
 476                 )
 477                 ])]
 478 )
 479
 480 AC_SUBST([REALTIME_LIBS])
 481
 482
 483 AC_CHECK_LIB([rtas], [rtas_get_sysparm], [
 484         RTAS_LIBS="-lrtas"
 485         AC_DEFINE_UNQUOTED([HAVE_LIBRTAS], [1], [Define if librtas exists]), [],
 486 ])
 487 AC_SUBST([RTAS_LIBS])
 488
 489
 490 AC_CHECK_MEMBER([struct sockaddr.sa_len],
 491                 AC_DEFINE_UNQUOTED([HAVE_SA_LEN], [1], [Define if struct sockaddr contains sa_len]), [],
 492         [#include <sys/types.h>
 493          #include <sys/socket.h>])
 494
 495 SOCKET_LIBS=
 496 AC_SEARCH_LIBS([socket], [socket],
 497         [AS_IF([test x"$ac_cv_search_socket" != x"none required"],
 498                 [SOCKET_LIBS="$SOCKET_LIBS -lsocket"])
 499 ])
 500 AC_SUBST([SOCKET_LIBS])
 501
 502
 503 have_dirfd=no
 504 AC_CHECK_FUNCS([dirfd], [have_dirfd=yes], [have_dirfd=no])
 505 AS_IF([test x"$have_dirfd" = xno], [
 506         AC_CHECK_DECLS([dirfd],
 507                 [have_dirfd=yes], [have_dirfd=no],
 508                 [#include <sys/types.h>
 509                  #include <dirent.h>])
 510 ])
 511
 512 have_ddfd=no
 513 AS_IF([test x"$have_dirfd" = xno], [
 514         AC_CHECK_MEMBERS([DIR.dd_fd],
 515                 [have_ddfd=yes], [have_ddfd=no],
 516                 [#include <sys/types.h>
 517                  #include <dirent.h>])
 518 ])
 519
 520 AS_CASE([$have_dirfd:$have_ddfd],
 521   [no:no],
 522     [AC_MSG_ERROR([cannot find a method to get filedescriptor of directory])]
 523 )
 524
 525
 526 AC_MSG_CHECKING([whether program_invocation_short_name is defined])
 527 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 528         #include <errno.h>
 529 ]], [[
 530         program_invocation_short_name = "test";
 531 ]])], [
 532         AC_MSG_RESULT([yes])
 533         AC_DEFINE([HAVE_PROGRAM_INVOCATION_SHORT_NAME], [1],
 534                 [Define if program_invocation_short_name is defined])
 535 ], [
 536         AC_MSG_RESULT([no])
 537 ])
 538
 539
 540 AC_MSG_CHECKING([whether __progname is defined])
 541 AC_LINK_IFELSE([AC_LANG_PROGRAM([extern char *__progname;],
 542            [if (*__progname == 0) return 1;])],
 543            AC_DEFINE([HAVE___PROGNAME], [1], [Define if __progname is defined])
 544            AC_MSG_RESULT([yes]),
 545            AC_MSG_RESULT([no]))
 546
 547 dnl Static compilation
 548 m4_define([UL_STATIC_PROGRAMS], [losetup, mount, umount, fdisk, sfdisk, blkid, nsenter, unshare])
 549
 550 AC_ARG_ENABLE([static-programs],
 551   [AS_HELP_STRING([--enable-static-programs=LIST],
 552       [link static the programs in LIST (comma-separated,
 553       supported for ]m4_defn([UL_STATIC_PROGRAMS])[)])])
 554
 555 AS_CASE([$enable_static_programs],
 556   [yes],
 557     [enable_static_programs=m4_quote(UL_STATIC_PROGRAMS)],
 558   [no],
 559     [enable_static_programs=]
 560 )
 561
 562 dnl Set all the individual AM_CONDITIONALs
 563 m4_foreach([UL_PRG], m4_defn([UL_STATIC_PROGRAMS]), [
 564   AS_CASE([,$enable_static_programs,],
 565    [*,UL_PRG,*], [static_[]UL_PRG=yes]
 566   )
 567   AS_IF([test "x$static_[]UL_PRG" = xyes], [AC_MSG_NOTICE([enable static build: UL_PRG.])])
 568   AM_CONDITIONAL([HAVE_STATIC_]m4_toupper(UL_PRG),
 569     [test "x$static_[]UL_PRG" = xyes])
 570 ])
 571
 572
 573 AC_ARG_ENABLE([all-programs],
 574   AS_HELP_STRING([--disable-all-programs], [disable everything, might be overridden by --enable-<name>]),
 575   [], [enable_all_programs=undefined]
 576 )
 577
 578 AS_CASE([$enable_all_programs],
 579   [yes], [AC_MSG_WARN([force to build all programs by default])
 580           ul_default_estate=check],
 581   [no],  [AC_MSG_WARN([disable all programs by default])
 582           ul_default_estate=no]
 583 )
 584
 585
 586 AX_CHECK_TLS
 587
 588 AC_DEFUN([UL_SCANF_TYPE_MODIFIER], [dnl
 589 # include <stdio.h>
 590 # include <stdlib.h>
 591 int main()
 592 {
 593         int i;
 594         int rc = 1;
 595         char *s;
 596         i = sscanf("x", $1, &s);
 597         if (i == 1  && *s == 'x')
 598                 rc = 0;
 599         free(s);
 600         return rc;
 601 }])
 602
 603 AC_CACHE_VAL([scanf_cv_alloc_modifier],
 604   AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%ms"])])],
 605     [scanf_cv_alloc_modifier=ms],
 606     AC_RUN_IFELSE([AC_LANG_SOURCE([UL_SCANF_TYPE_MODIFIER(["%as"])])],
 607       [scanf_cv_alloc_modifier=as],
 608       [scanf_cv_alloc_modifier=no]
 609     )
 610     ,
 611
 612     [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 613      #include <stdio.h>
 614      #include <unistd.h>
 615
 616      #if defined(__GLIBC__) && !defined(__UCLIBC__)
 617
 618      #if !(__GLIBC_PREREQ(2, 7))
 619      #error %m is not available
 620      #endif
 621
 622      #elif defined(_POSIX_VERSION)
 623
 624      #if _POSIX_VERSION < 200809L
 625      #error %m is not available
 626      #endif
 627
 628      #else
 629      #error Your C-library is not supported.
 630      #endif
 631      ])],
 632     [scanf_cv_alloc_modifier=ms],
 633     [scanf_cv_alloc_modifier=no])]
 634   )
 635 )
 636
 637 AC_MSG_CHECKING([scanf string alloc modifiers])
 638 AS_CASE([$scanf_cv_alloc_modifier],
 639   [ms],
 640     [AC_MSG_RESULT([(%ms) yes])
 641      AC_DEFINE([HAVE_SCANF_MS_MODIFIER], [1], [scanf %ms modifier])
 642      have_scanf_alloc_modifier=yes],
 643   [as],
 644     [AC_MSG_RESULT([(%as) yes])
 645      have_scanf_alloc_modifier=yes
 646      AC_DEFINE([HAVE_SCANF_AS_MODIFIER], [1], [scanf %as modifier])],
 647   [AC_MSG_RESULT([no])
 648    have_scanf_alloc_modifier=no]
 649 )
 650
 651
 652 AC_ARG_WITH([util], AS_HELP_STRING([--without-util], [compile without libutil]),
 653   [], [with_util=auto]
 654 )
 655 AS_IF([test "x$with_util" = xno], [
 656   AM_CONDITIONAL([HAVE_UTIL], [false])
 657   have_util=no
 658 ], [
 659   UL_CHECK_LIB([util], [openpty])
 660 ])
 661
 662
 663 AC_CHECK_TYPES([union semun], [], [], [[
 664 #include <sys/sem.h>
 665 ]])
 666 AC_CHECK_TYPES([loff_t])
 667
 668
 669 AC_ARG_ENABLE([widechar],
 670   AS_HELP_STRING([--disable-widechar], [do not compile wide character support]),
 671   [], [enable_widechar=check]
 672 )
 673 UL_BUILD_INIT([widechar])
 674 UL_REQUIRES_COMPILE([widechar], [[
 675   #include <wchar.h>
 676   #include <wctype.h>
 677   #include <stdio.h>
 678   ]], [[
 679     wchar_t wc;
 680     wint_t w;
 681     w = fgetwc(stdin);
 682     if (w == WEOF) exit(1);
 683     wc = w;
 684     fputwc(wc,stdout);
 685   ]],
 686   [wchar_t support])
 687
 688 AS_IF([test "x$build_widechar" = xyes ], [
 689   AC_DEFINE([HAVE_WIDECHAR], [1], [Do we have wide character support?])
 690 ])
 691
 692
 693 AC_CHECK_TYPES([cpu_set_t], [have_cpu_set_t=yes], [], [[
 694 #include <sched.h>
 695 ]])
 696
 697 AM_CONDITIONAL([HAVE_CPU_SET_T], [test "x$have_cpu_set_t" = xyes])
 698
 699 AC_CHECK_TYPES([sighandler_t], [], [], [[
 700 #include <signal.h>
 701 ]])
 702
 703 AC_CHECK_DECLS([CPU_ALLOC], [], [], [[
 704 #include <sched.h>
 705 ]])
 706
 707 # on Solaris, you can't mix and match standards, since we use c99
 708 # aparently at this stage, XOPEN_SOURCE will conflict.  As workaround,
 709 # check for crypt.h and use that without XOPEN_SOURCE.
 710 AC_CHECK_HEADERS([crypt.h])
 711 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 712 #ifdef HAVE_CRYPT_H
 713 #include <crypt.h>
 714 #else
 715 #define _XOPEN_SOURCE
 716 #include <unistd.h>
 717 #endif
 718 ]], [[
 719 char *c = crypt("abc","pw");
 720 ]])],[],[
 721   LIBS="$LIBS -lcrypt"
 722   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 723   #ifdef HAVE_CRYPT_H
 724   #include <crypt.h>
 725   #else
 726   #define _XOPEN_SOURCE
 727   #include <unistd.h>
 728   #endif
 729   ]], [[
 730   char *c = crypt("abc","pw");
 731   ]])],[
 732   AC_DEFINE([HAVE_LIBCRYPT], [1], [Do we need -lcrypt?])
 733   have_libcrypt=yes
 734   ],[
 735   AC_MSG_ERROR([crypt() is not available])
 736   ])
 737 ])
 738 AM_CONDITIONAL([HAVE_LIBCRYPT], [test "x$have_libcrypt" = xyes])
 739
 740
 741 AC_ARG_WITH([selinux],
 742   AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
 743   [], [with_selinux=no]
 744 )
 745
 746 AS_IF([test "x$with_selinux" = xno], [
 747   AM_CONDITIONAL([HAVE_SELINUX], [false])
 748 ], [
 749   PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.0],
 750         [AC_DEFINE([HAVE_LIBSELINUX], [1], [Define if SELinux is available])
 751          UL_PKG_STATIC([SELINUX_LIBS_STATIC], [libselinux])
 752          AM_CONDITIONAL([HAVE_SELINUX], [true])
 753          have_selinux=yes],
 754         [have_selinux=no])
 755
 756   AS_CASE([$with_selinux:$have_selinux],
 757     [yes:no], [AC_MSG_ERROR([SELinux selected but libselinux not found or too old])]
 758   )
 759
 760   AS_IF([test "x$have_selinux" = xyes], [
 761     UL_SET_FLAGS([], [], [$SELINUX_LIBS])
 762     # This function is missing in old libselinux 1.xx versions
 763     AC_CHECK_FUNCS([security_get_initial_context])
 764     UL_RESTORE_FLAGS
 765   ])
 766 ])
 767 AC_SUBST([SELINUX_LIBS])
 768 AC_SUBST([SELINUX_LIBS_STATIC])
 769
 770
 771 AC_ARG_WITH([audit],
 772   AS_HELP_STRING([--with-audit], [compile with audit support]),
 773   [], [with_audit=no]
 774 )
 775
 776 AS_IF([test "x$with_audit" = xno], [
 777   AM_CONDITIONAL([HAVE_AUDIT], [false])
 778 ], [
 779   UL_CHECK_LIB([audit], [audit_log_user_message])
 780   AS_CASE([$with_audit:$have_audit],
 781     [yes:no],
 782       [AC_MSG_ERROR([Audit selected but libaudit not found (or does not support audit_log_user_message())])]
 783   )
 784 ])
 785
 786 AC_ARG_WITH([udev], AS_HELP_STRING([--without-udev], [compile without udev support]),
 787   [], [with_udev=auto]
 788 )
 789
 790 AS_IF([test "x$with_udev" = xno], [
 791   AM_CONDITIONAL([HAVE_UDEV], [false])
 792 ], [
 793   UL_CHECK_LIB([udev], [udev_new])
 794   AS_CASE([$with_udev:$have_udev],
 795     [yes:no],
 796       [AC_MSG_ERROR([udev selected but libudev not found])]
 797   )
 798 ])
 799
 800
 801 dnl wide-char ncurses
 802 AC_ARG_WITH([ncursesw],
 803   AS_HELP_STRING([--with-ncursesw], [build with wide-char ncurses, enabled by default]),
 804   [], [with_ncursesw=auto]
 805 )
 806 have_ncursesw=no
 807 have_ncursesw_header=no
 808 AS_IF([test "x$with_ncursesw" != xno], [
 809   UL_NCURSES_CHECK([ncursesw])
 810   AS_IF([test "x$have_ncursesw" = xyes], [
 811     AC_CHECK_HEADERS([ncursesw/ncurses.h], [have_ncursesw_header=yes])
 812     AC_CHECK_HEADERS([ncursesw/term.h])
 813
 814     # Define HAVE_NCURSES_H only if check for HAVE_NCURSESW_NCURSES_H is
 815     # unsuccessful to avoid too many *_H permitations in config.h
 816     AS_IF([test "x$have_ncursesw_header" = xno], [
 817            AC_CHECK_HEADERS([ncurses.h], [have_ncursesw_header=yes])
 818            AC_CHECK_HEADERS([term.h])
 819     ])
 820     AS_IF([test "x$have_ncursesw_header" = xno], [have_ncursesw=no])
 821   ])
 822   AS_IF([test "x$have_ncursesw" = xyes], [
 823     CURSES_LIB_NAME="ncursesw"
 824     AC_DEFINE([HAVE_LIBNCURSESW], [1], [Define if ncursesw library available])
 825   ])
 826 ])
 827 AS_CASE([$with_ncursesw:$have_ncursesw],
 828   [yes:no], [AC_MSG_ERROR([ncursesw selected, but library not found])])
 829
 830
 831 dnl non-wide ncurses
 832 AC_ARG_WITH([ncurses],
 833   AS_HELP_STRING([--with-ncurses], [build with non-wide ncurses, disabled by default]),
 834   [], [with_ncurses=auto]
 835 )
 836 have_ncurses=no
 837 have_ncurses_header=no
 838 AS_CASE([$with_ncurses:$build_widechar],
 839   [yes:yes], [AC_MSG_ERROR([wide-char support enabled, but non-wide ncurses selects])])
 840
 841 AS_IF([test "x$have_ncursesw" = xno -a "x$with_ncurses" != xno ], [
 842   UL_NCURSES_CHECK([ncurses])
 843   AS_IF([test "x$have_ncurses" = xyes], [
 844     AC_CHECK_HEADERS([ncurses/ncurses.h], [have_ncurses_header=yes])
 845     AC_CHECK_HEADERS([ncurses/term.h])
 846
 847     # Define HAVE_NCURSES_H only if check for HAVE_NCURSES_NCURSES_H is
 848     # unsuccessful to avoid too many *_H permitations in config.h
 849     AS_IF([test "x$have_ncurses_header" = xno], [
 850            AC_CHECK_HEADERS([ncurses.h], [have_ncurses_header=yes])
 851            AC_CHECK_HEADERS([term.h])
 852     ])
 853     AS_IF([test "x$have_ncurses_header" = xno], [have_ncurses=no])
 854   ])
 855   AS_IF([test "x$have_ncurses" = xyes], [
 856     CURSES_LIB_NAME="ncurses"
 857     AC_DEFINE([HAVE_LIBNCURSES], [1], [Define if ncurses library available])
 858   ])
 859 ])
 860 AS_CASE([$with_ncurses:$have_ncurses],
 861   [yes:no], [AC_MSG_ERROR([ncurses selected, but library not found])])
 862
 863 AC_SUBST([NCURSES_CFLAGS])
 864 AC_SUBST([NCURSES_LIBS])
 865 AM_CONDITIONAL([HAVE_NCURSES], [test "x$have_ncursesw" = xyes -o  "x$have_ncurses" = xyes])
 866
 867
 868 AC_ARG_WITH([slang],
 869   AS_HELP_STRING([--with-slang], [compile cfdisk with slang rather than ncurses]),
 870   [], [with_slang=no]
 871 )
 872 have_slang=no
 873 AS_IF([test "x$with_slang" = xyes], [
 874   AC_CHECK_HEADERS([slang.h slang/slang.h])
 875   AC_CHECK_HEADERS([slcurses.h slang/slcurses.h],
 876                    [have_slang=yes], [], [
 877 #ifdef HAVE_SLANG_H
 878 #include <slang.h>
 879 #elif defined(HAVE_SLANG_SLANG_H)
 880 #include <slang/slang.h>
 881 #endif
 882 ])
 883   AS_IF([test "x$have_slang" = xno], [
 884     AC_MSG_ERROR([slang selected but slcurses.h not found])],
 885     [CURSES_LIB_NAME=slang
 886   ])
 887 ])
 888 AM_CONDITIONAL([HAVE_SLANG], [test "x$have_slang" = xyes])
 889
 890
 891 AS_IF([test "x$have_slang" = xyes -o "x$have_ncursesw" = xyes -o "x$have_ncurses" = xyes], [
 892         AC_CHECK_LIB([$CURSES_LIB_NAME], use_default_colors, [
 893                      AC_DEFINE(HAVE_USE_DEFAULT_COLORS, 1,
 894                                [Define if curses library has the use_default_colors().])
 895         ])
 896         AC_CHECK_LIB([$CURSES_LIB_NAME], resizeterm, [
 897                      AC_DEFINE(HAVE_RESIZETERM, 1,
 898                                [Define if curses library has the resizeterm().])
 899         ])
 900 ])
 901
 902
 903 AC_ARG_WITH([tinfo], AS_HELP_STRING([--without-tinfo], [compile without libtinfo]),
 904   [], [with_tinfo=auto]
 905 )
 906 have_tinfo=no
 907 have_tinfow=no
 908 AS_IF([test "x$with_tinfo" != xno], [
 909   AS_IF([test "x$have_ncursesw" = xyes], [
 910     UL_TINFO_CHECK([tinfow])
 911   ])
 912   AS_IF([test "x$have_tinfow" = xno], [
 913     UL_TINFO_CHECK([tinfo])
 914   ])
 915 ])
 916 AC_SUBST([TINFO_LIBS])
 917 AC_SUBST([TINFO_LIBS_STATIC])
 918 AC_SUBST([TINFO_CFLAGS])
 919 AM_CONDITIONAL([HAVE_TINFO], [test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes])
 920 AS_IF([test "x$have_tinfo" = xyes -o "x$have_tinfow" = xyes], [
 921   AC_DEFINE(HAVE_LIBTINFO, 1, [Define if libtinfo or libtinfow available.])
 922 ])
 923
 924
 925 AC_ARG_WITH([readline],
 926   AS_HELP_STRING([--with-readline], [compile with GNU Readline support]),
 927   [], [with_readline=auto]
 928 )
 929
 930 AS_IF([test "x$with_readline" = xno], [
 931   AM_CONDITIONAL([HAVE_READLINE], [false])
 932 ], [
 933   UL_CHECK_LIB([readline], [readline])
 934   AS_CASE([$with_readline:$have_readline],
 935     [yes:no],
 936       [AC_MSG_ERROR([readline selected but libreadline not found ])],
 937     [*:yes],
 938       [READLINE_LIBS="-lreadline"
 939        READLINE_LIBS_STATIC="-lreadline $TINFO_LIBS_STATIC"]
 940   )
 941 ])
 942 AC_SUBST([READLINE_LIBS])
 943 AC_SUBST([READLINE_LIBS_STATIC])
 944
 945
 946 AC_ARG_WITH([utempter],
 947   AS_HELP_STRING([--with-utempter], [compile script(1) with libutempter]),
 948   [], [with_utempter=no]
 949 )
 950
 951 AS_IF([test "x$with_utempter" = xyes], [
 952   UL_CHECK_LIB([utempter], [utempter_add_record])
 953   AS_IF([test "x$have_utempter" = xno], [
 954     AC_MSG_ERROR([utempter selected but libutempter not found])
 955   ])
 956 ], [
 957   AM_CONDITIONAL([HAVE_UTEMPTER], [false])
 958 ])
 959
 960
 961 dnl
 962 dnl libuuid
 963 dnl
 964 AC_ARG_ENABLE([libuuid],
 965   AS_HELP_STRING([--disable-libuuid], [do not build libuuid and uuid utilities]),
 966   [], [UL_DEFAULT_ENABLE([libuuid], [yes])]
 967 )
 968 UL_BUILD_INIT([libuuid])
 969 AC_SUBST([LIBUUID_VERSION])
 970 AC_SUBST([LIBUUID_VERSION_INFO])
 971 AM_CONDITIONAL(BUILD_LIBUUID, test "x$build_libuuid" = xyes)
 972
 973 AC_ARG_ENABLE([libuuid-force-uuidd],
 974   AS_HELP_STRING([--enable-libuuid-force-uuidd], [support uuidd even though the daemon is not built]),
 975   [], [enable_libuuid_force_uuidd=no]
 976 )
 977
 978 AS_IF([test "x$build_libuuid" = xyes], [
 979   AC_DEFINE(HAVE_LIBUUID, 1, [Define to 1 if you have the -luuid.])
 980 ])
 981
 982 dnl
 983 dnl libblkid
 984 dnl
 985 AC_ARG_ENABLE([libblkid],
 986   AS_HELP_STRING([--disable-libblkid], [do not build libblkid and many related utilities]),
 987   [], [UL_DEFAULT_ENABLE([libblkid], [check])]
 988 )
 989 UL_BUILD_INIT([libblkid])
 990 UL_REQUIRES_HAVE([libblkid], [openat], [openat functions])
 991 AC_SUBST([LIBBLKID_DATE])
 992 AC_SUBST([LIBBLKID_VERSION])
 993 AC_SUBST([LIBBLKID_VERSION_INFO])
 994 AC_DEFINE_UNQUOTED([LIBBLKID_VERSION], ["$LIBBLKID_VERSION"], [libblkid version string])
 995 AC_DEFINE_UNQUOTED([LIBBLKID_DATE], ["$LIBBLKID_DATE"], [libblkid date string])
 996 AS_IF([test "x$build_libblkid" = xyes], [
 997   AC_DEFINE([HAVE_LIBBLKID], [1], [Define to 1 if you have the -lblkid.])
 998 ])
 999 AM_CONDITIONAL([BUILD_LIBBLKID], [test "x$build_libblkid" = xyes])
1000 AM_CONDITIONAL([BUILD_LIBBLKID_TESTS], [test "x$build_libblkid" = xyes -a "x$enable_static" = xyes])
1001
1002 dnl
1003 dnl libmount
1004 dnl
1005 AC_ARG_ENABLE([libmount],
1006   AS_HELP_STRING([--disable-libmount], [do not build libmount]),
1007   [], [UL_DEFAULT_ENABLE([libmount], [check])]
1008 )
1009 UL_BUILD_INIT([libmount])
1010 UL_REQUIRES_BUILD([libmount], [libblkid])
1011 UL_REQUIRES_HAVE([libmount], [scanf_alloc_modifier], [scanf string alloc modifier])
1012 AM_CONDITIONAL([BUILD_LIBMOUNT], [test "x$build_libmount" = xyes])
1013 AM_CONDITIONAL([BUILD_LIBMOUNT_TESTS], [test "x$build_libmount" = xyes -a "x$enable_static" = xyes])
1014 AS_IF([test "x$build_libmount" = xyes], [
1015         AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount available.])
1016 ])
1017
1018 AC_SUBST([LIBMOUNT_VERSION])
1019 AC_SUBST([LIBMOUNT_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1020 AC_SUBST([LIBMOUNT_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1021 AC_SUBST([LIBMOUNT_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1022 AC_SUBST([LIBMOUNT_VERSION_INFO])
1023 AC_DEFINE_UNQUOTED([LIBMOUNT_VERSION], ["$LIBMOUNT_VERSION"], [libmount version string])
1024
1025 AC_ARG_ENABLE([libmount-support-mtab],
1026   AS_HELP_STRING([--enable-libmount-support-mtab], [support /etc/mtab (default is use /proc/self/mountinfo)]),
1027   [], [enable_libmount_support_mtab=no]
1028 )
1029
1030 AS_IF([test "x$enable_libmount_support_mtab" == xyes], [
1031   AC_DEFINE([USE_LIBMOUNT_SUPPORT_MTAB], [1], [Define to 1 if want to support mtab.])
1032 ])
1033
1034
1035 dnl
1036 dnl libsmartcols
1037 dnl
1038 AC_ARG_ENABLE([libsmartcols],
1039   AS_HELP_STRING([--disable-libsmartcols], [do not build libsmartcols]),
1040   [], [UL_DEFAULT_ENABLE([libsmartcols], [yes])]
1041 )
1042 UL_BUILD_INIT([libsmartcols])
1043 AM_CONDITIONAL([BUILD_LIBSMARTCOLS], [test "x$build_libsmartcols" = xyes])
1044
1045 AC_SUBST([LIBSMARTCOLS_VERSION])
1046 AC_SUBST([LIBSMARTCOLS_VERSION_INFO])
1047 AC_DEFINE_UNQUOTED([LIBSMARTCOLS_VERSION], ["$LIBSMARTCOLS_VERSION"], [libsmartcols version string])
1048
1049
1050 dnl
1051 dnl libfdisk
1052 dnl
1053 AC_ARG_ENABLE([libfdisk],
1054   AS_HELP_STRING([--disable-libfdisk], [do not build libfdisk]),
1055   [], [UL_DEFAULT_ENABLE([libfdisk], [check])]
1056 )
1057 UL_BUILD_INIT([libfdisk])
1058 UL_REQUIRES_BUILD([libfdisk], [libuuid])
1059 AM_CONDITIONAL([BUILD_LIBFDISK], [test "x$build_libfdisk" = xyes])
1060 AM_CONDITIONAL([BUILD_LIBFDISK_TESTS], [test "x$build_libfdisk" = xyes -a "x$enable_static" = xyes])
1061
1062 AS_IF([test "x$build_libblkid" = xyes],
1063   [LIBFDISK_PC_REQUIRES="uuid blkid"],[LIBFDISK_PC_REQUIRES="uuid"])
1064 AC_SUBST([LIBFDISK_PC_REQUIRES])
1065
1066 AC_SUBST([LIBFDISK_VERSION])
1067 AC_SUBST([LIBFDISK_MAJOR_VERSION], $PACKAGE_VERSION_MAJOR)
1068 AC_SUBST([LIBFDISK_MINOR_VERSION], $PACKAGE_VERSION_MINOR)
1069 AC_SUBST([LIBFDISK_PATCH_VERSION], $PACKAGE_VERSION_RELEASE)
1070 AC_SUBST([LIBFDISK_VERSION_INFO])
1071 AC_DEFINE_UNQUOTED([LIBFDISK_VERSION], ["$LIBFDISK_VERSION"], [libfdisk version string])
1072
1073
1074 UL_BUILD_INIT([fdisk], [check])
1075 UL_REQUIRES_HAVE([fdisk], [openat], [openat functions])
1076 UL_REQUIRES_BUILD([fdisk], [libfdisk])
1077 UL_REQUIRES_BUILD([fdisk], [libsmartcols])
1078 AM_CONDITIONAL([BUILD_FDISK], [test "x$build_fdisk" = xyes])
1079
1080
1081 UL_BUILD_INIT([sfdisk], [check])
1082 UL_REQUIRES_HAVE([sfdisk], [openat], [openat functions])
1083 UL_REQUIRES_BUILD([sfdisk], [libfdisk])
1084 UL_REQUIRES_BUILD([sfdisk], [libsmartcols])
1085 AM_CONDITIONAL([BUILD_SFDISK], [test "x$build_sfdisk" = xyes])
1086
1087
1088 UL_BUILD_INIT([cfdisk], [check])
1089 UL_REQUIRES_BUILD([cfdisk], [libfdisk])
1090 UL_REQUIRES_BUILD([cfdisk], [libsmartcols])
1091 UL_REQUIRES_HAVE([cfdisk], [open_memstream], [open_memstream function])
1092 UL_REQUIRES_HAVE([cfdisk], [ncursesw,slang,ncurses], [ncursesw, ncurses or slang library])
1093 AM_CONDITIONAL([BUILD_CFDISK], [test "x$build_cfdisk" = xyes])
1094
1095
1096 AC_ARG_ENABLE([mount],
1097   AS_HELP_STRING([--disable-mount], [do not build mount(8) and umount(8)]),
1098   [], [UL_DEFAULT_ENABLE([mount], [check])]
1099 )
1100 UL_BUILD_INIT([mount])
1101 UL_REQUIRES_LINUX([mount])
1102 UL_REQUIRES_BUILD([mount], [libmount])
1103 AM_CONDITIONAL([BUILD_MOUNT], [test "x$build_mount" = xyes])
1104
1105
1106 AC_ARG_ENABLE([losetup],
1107   AS_HELP_STRING([--disable-losetup], [do not build losetup]),
1108   [], [UL_DEFAULT_ENABLE([losetup], [check])]
1109 )
1110 UL_BUILD_INIT([losetup])
1111 UL_REQUIRES_LINUX([losetup])
1112 UL_REQUIRES_BUILD([losetup], [libsmartcols])
1113 AM_CONDITIONAL([BUILD_LOSETUP], [test "x$build_losetup" = xyes])
1114
1115 AC_ARG_ENABLE([zramctl],
1116   AS_HELP_STRING([--disable-zramctl], [do not build zramctl]),
1117   [], [UL_DEFAULT_ENABLE([zramctl], [check])]
1118 )
1119 UL_BUILD_INIT([zramctl])
1120 UL_REQUIRES_LINUX([zramctl])
1121 UL_REQUIRES_BUILD([zramctl], [libsmartcols])
1122 AM_CONDITIONAL([BUILD_ZRAMCTL], [test "x$build_zramctl" = xyes])
1123
1124 AC_ARG_ENABLE([fsck],
1125   AS_HELP_STRING([--disable-fsck], [do not build fsck]),
1126   [], [UL_DEFAULT_ENABLE([fsck], [check])]
1127 )
1128 UL_BUILD_INIT([fsck])
1129 UL_REQUIRES_BUILD([fsck], [libmount])
1130 AM_CONDITIONAL([BUILD_FSCK], [test "x$build_fsck" = xyes])
1131
1132
1133 AC_ARG_ENABLE([partx],
1134   AS_HELP_STRING([--disable-partx], [do not build addpart, delpart, partx]),
1135   [], [UL_DEFAULT_ENABLE([partx], [check])]
1136 )
1137 UL_BUILD_INIT([partx])
1138 UL_REQUIRES_LINUX([partx])
1139 UL_REQUIRES_BUILD([partx], [libblkid])
1140 UL_REQUIRES_BUILD([partx], [libsmartcols])
1141 AM_CONDITIONAL([BUILD_PARTX], [test "x$build_partx" = xyes])
1142
1143
1144 AC_ARG_ENABLE([uuidd],
1145   AS_HELP_STRING([--disable-uuidd], [do not build the uuid daemon]),
1146   [], [UL_DEFAULT_ENABLE([uuidd], [check])]
1147 )
1148 UL_BUILD_INIT([uuidd])
1149 UL_REQUIRES_BUILD([uuidd], [libuuid])
1150 UL_REQUIRES_HAVE([uuidd], [timer], [timer_create function])
1151 UL_REQUIRES_HAVE([uuidd], [sys_signalfd_h], [sys/signalfd.h header])
1152 AS_IF([test "x$build_uuidd" = xyes || test "x$enable_libuuid_force_uuidd" == xyes ], [
1153   AC_DEFINE([HAVE_UUIDD], [1], [Define to 1 if you want to use uuid daemon.])
1154 ])
1155 AM_CONDITIONAL([BUILD_UUIDD], [test "x$build_uuidd" = xyes])
1156
1157
1158 UL_BUILD_INIT([uuidgen], [check])
1159 UL_REQUIRES_BUILD([uuidgen], [libuuid])
1160 AM_CONDITIONAL([BUILD_UUIDGEN], [test "x$build_uuidgen" = xyes])
1161
1162 UL_BUILD_INIT([uuidparse], [check])
1163 UL_REQUIRES_BUILD([uuidparse], [libuuid])
1164 UL_REQUIRES_BUILD([uuidparse], [libsmartcols])
1165 AM_CONDITIONAL([BUILD_UUIDPARSE], [test "x$build_uuidparse" = xyes])
1166
1167 UL_BUILD_INIT([blkid], [check])
1168 UL_REQUIRES_BUILD([blkid], [libblkid])
1169 AM_CONDITIONAL([BUILD_BLKID], [test "x$build_blkid" = xyes])
1170
1171 UL_BUILD_INIT([findfs], [check])
1172 UL_REQUIRES_BUILD([findfs], [libblkid])
1173 AM_CONDITIONAL([BUILD_FINDFS], [test "x$build_findfs" = xyes])
1174
1175 UL_BUILD_INIT([wipefs], [check])
1176 UL_REQUIRES_BUILD([wipefs], [libblkid])
1177 UL_REQUIRES_BUILD([wipefs], [libsmartcols])
1178 AM_CONDITIONAL([BUILD_WIPEFS], [test "x$build_wipefs" = xyes])
1179
1180 UL_BUILD_INIT([findmnt], [check])
1181 UL_REQUIRES_BUILD([findmnt], [libmount])
1182 UL_REQUIRES_BUILD([findmnt], [libblkid])
1183 UL_REQUIRES_BUILD([findmnt], [libsmartcols])
1184 AM_CONDITIONAL([BUILD_FINDMNT], [test "x$build_findmnt" = xyes])
1185
1186
1187 AC_ARG_ENABLE([mountpoint],
1188   AS_HELP_STRING([--disable-mountpoint], [do not build mountpoint]),
1189   [], [UL_DEFAULT_ENABLE([mountpoint], [check])]
1190 )
1191 UL_BUILD_INIT([mountpoint])
1192 UL_REQUIRES_BUILD([mountpoint], [libmount])
1193 AM_CONDITIONAL([BUILD_MOUNTPOINT], [test "x$build_mountpoint" = xyes])
1194
1195
1196 AC_ARG_ENABLE([fallocate],
1197   AS_HELP_STRING([--disable-fallocate], [do not build fallocate]),
1198   [], [UL_DEFAULT_ENABLE([fallocate], [check])]
1199 )
1200 UL_BUILD_INIT([fallocate])
1201 UL_REQUIRES_LINUX([fallocate])
1202 UL_REQUIRES_SYSCALL_CHECK([fallocate], [UL_CHECK_SYSCALL([fallocate])])
1203 AM_CONDITIONAL([BUILD_FALLOCATE], [test "x$build_fallocate" = xyes])
1204
1205 AS_IF([test "x$build_fallocate" = xyes], [
1206   dnl check for valid fallocate() function
1207   dnl with 32 bits glibc 2.10, fallocate() exists but not fallocate64()
1208   dnl when _FILE_OFFSET_BITS==64, fallocate() is redirect to fallocate64()
1209   dnl and program can't be linked.
1210   dnl AC_CHECK_FUNC can't catch such errors since it's redefining
1211   dnl function prototype.
1212   AC_MSG_CHECKING([for valid fallocate() function])
1213   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1214 #ifdef HAVE_UNISTD_H
1215 # include <unistd.h>
1216 #endif
1217 #ifdef HAVE_SYS_TYPES_H
1218 # include <sys/types.h>
1219 #endif
1220 #ifdef HAVE_LINUX_FALLOC_H
1221 # include <linux/falloc.h>
1222 #endif
1223 #ifdef HAVE_FCNTL_H
1224 # include <fcntl.h>
1225 #endif
1226 ]],[[
1227    long ret;
1228    ret = fallocate(0, FALLOC_FL_KEEP_SIZE, 0xfffffffful, 0xfffffffful);
1229    if (ret != 0) {
1230       return 1;
1231    }
1232    ]])],[
1233   AC_MSG_RESULT([yes])
1234   AC_DEFINE([HAVE_FALLOCATE], [1], [Have valid fallocate() function])],[
1235   AC_MSG_RESULT([no])])
1236 ])
1237
1238 AS_IF([test "x$build_fallocate" = xyes], [
1239   dnl check for valid posix_fallocate() function
1240   AC_MSG_CHECKING([for valid posix_fallocate() function])
1241   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1242 #ifdef HAVE_UNISTD_H
1243 # include <unistd.h>
1244 #endif
1245 #ifdef HAVE_SYS_TYPES_H
1246 # include <sys/types.h>
1247 #endif
1248 #ifdef HAVE_LINUX_FALLOC_H
1249 # include <linux/falloc.h>
1250 #endif
1251 #ifdef HAVE_FCNTL_H
1252 # include <fcntl.h>
1253 #endif
1254 ]],[[
1255    long ret;
1256    ret = posix_fallocate(0, 0xfffffffful, 0xfffffffful);
1257    if (ret != 0) {
1258       return 1;
1259    }
1260    ]])],[
1261   AC_MSG_RESULT([yes])
1262   AC_DEFINE([HAVE_POSIX_FALLOCATE], [1], [Have valid posix_fallocate() function])],[
1263   AC_MSG_RESULT([no])])
1264 ])
1265
1266
1267 AC_ARG_ENABLE([unshare],
1268   AS_HELP_STRING([--disable-unshare], [do not build unshare]),
1269   [], [UL_DEFAULT_ENABLE([unshare], [check])]
1270 )
1271 UL_BUILD_INIT([unshare])
1272 UL_REQUIRES_LINUX([unshare])
1273 UL_REQUIRES_SYSCALL_CHECK([unshare], [UL_CHECK_SYSCALL([unshare])])
1274 AM_CONDITIONAL([BUILD_UNSHARE], [test "x$build_unshare" = xyes])
1275 AC_CHECK_FUNCS([unshare])
1276
1277 AC_ARG_ENABLE([nsenter],
1278   AS_HELP_STRING([--disable-nsenter], [do not build nsenter]),
1279   [], [UL_DEFAULT_ENABLE([nsenter], [check])]
1280 )
1281 UL_BUILD_INIT([nsenter])
1282 UL_REQUIRES_LINUX([nsenter])
1283 UL_REQUIRES_SYSCALL_CHECK([nsenter], [UL_CHECK_SYSCALL([setns])], [setns])
1284 AM_CONDITIONAL([BUILD_NSENTER], [test "x$build_nsenter" = xyes])
1285 AC_CHECK_FUNCS([setns])
1286
1287
1288 AC_ARG_WITH([cap_ng],
1289   AS_HELP_STRING([--without-cap-ng], [compile without libcap-ng]),
1290   [], [with_cap_ng=auto]
1291 )
1292 AS_IF([test "x$with_cap_ng" = xno], [
1293   AM_CONDITIONAL([HAVE_CAP_NG], [false])
1294   have_cap_ng=no
1295 ],[
1296   UL_CHECK_LIB([cap-ng], [capng_apply], [cap_ng])
1297 ])
1298
1299
1300 AC_ARG_ENABLE([setpriv],
1301   AS_HELP_STRING([--disable-setpriv], [do not build setpriv]),
1302   [], [UL_DEFAULT_ENABLE([setpriv], [check])]
1303 )
1304 UL_BUILD_INIT([setpriv])
1305 UL_REQUIRES_LINUX([setpriv])
1306 UL_REQUIRES_HAVE([setpriv], [linux_securebits_h], [securebits.h header file])
1307 UL_REQUIRES_HAVE([setpriv], [cap_ng], [libcap-ng library])
1308 AM_CONDITIONAL([BUILD_SETPRIV], [test "x$build_setpriv" = xyes])
1309
1310
1311 AC_ARG_ENABLE([eject],
1312   AS_HELP_STRING([--disable-eject], [do not build eject]),
1313   [], [UL_DEFAULT_ENABLE([eject], [check])]
1314 )
1315 UL_BUILD_INIT([eject])
1316 UL_REQUIRES_LINUX([eject])
1317 UL_REQUIRES_BUILD([eject], [libmount])
1318 AM_CONDITIONAL([BUILD_EJECT], [test "x$build_eject" = xyes])
1319
1320
1321 AC_ARG_ENABLE([agetty],
1322   AS_HELP_STRING([--disable-agetty], [do not build agetty]),
1323   [], [UL_DEFAULT_ENABLE([agetty], [check])]
1324 )
1325 UL_BUILD_INIT([agetty])
1326 UL_REQUIRES_HAVE([agetty], [utmpx_h], [utmpx.h header])
1327 UL_REQUIRES_HAVE([agetty], [gnu_utmpx], [GNU utmpx fucntions])
1328 AM_CONDITIONAL([BUILD_AGETTY], [test "x$build_agetty" = xyes])
1329 AS_IF([test "x$have_futimens" = xyes -a "x$have_inotify_init1" = xyes ], [
1330   AC_DEFINE([AGETTY_RELOAD], [1], [Enable agetty --reload feature])
1331 ],[
1332   AC_MSG_WARN([futimens or inotify_init1 not found; agetty(8) will not provide ---reload functionality])
1333 ])
1334
1335
1336 AC_ARG_ENABLE([plymouth_support],
1337   AS_HELP_STRING([--disable-plymouth_support], [don not care about plymouth in sylogin(8) and agetty(8)]),
1338   [], [enable_plymouth_support=check]
1339 )
1340 UL_BUILD_INIT([plymouth_support])
1341 UL_REQUIRES_HAVE([plymouth_support], [tiocglcktrmios], [TIOCGLCKTRMIOS flag])
1342 UL_REQUIRES_HAVE([plymouth_support], [sock_cloexec], [SOCK_CLOEXEC flag])
1343 UL_REQUIRES_HAVE([plymouth_support], [sock_nonblock], [SOCK_NONBLOCK flag])
1344 UL_REQUIRES_HAVE([plymouth_support], [so_passcred], [SO_PASSCRED flag])
1345 AM_CONDITIONAL([USE_PLYMOUTH_SUPPORT], [test "x$build_plymouth_support" = xyes])
1346 AS_IF([test "x$build_plymouth_support" = xyes ], [
1347     AC_DEFINE([USE_PLYMOUTH_SUPPORT], [1], [Enable plymouth support feature for sulogin and aggety])
1348 ])
1349
1350
1351 AC_ARG_WITH([libz],
1352   AS_HELP_STRING([--without-libz], [compile without libz]),
1353   [], [with_libz=auto]
1354 )
1355 AS_IF([test "x$with_libz" = xno], [have_z=no], [
1356   AC_CHECK_LIB([z], [crc32], [have_z=yes], [have_z=no])
1357 ])
1358
1359
1360 AC_ARG_ENABLE([cramfs],
1361   AS_HELP_STRING([--disable-cramfs], [do not build fsck.cramfs, mkfs.cramfs]),
1362   [], [UL_DEFAULT_ENABLE([cramfs], [check])]
1363 )
1364 UL_BUILD_INIT([cramfs])
1365 UL_REQUIRES_HAVE([cramfs], [z], [z library])
1366 AM_CONDITIONAL([BUILD_CRAMFS], [test "x$build_cramfs" = xyes])
1367
1368
1369 AC_ARG_ENABLE([bfs],
1370   AS_HELP_STRING([--disable-bfs], [do not build mkfs.bfs]),
1371   [], [UL_DEFAULT_ENABLE([bfs], [yes])]
1372 )
1373 UL_BUILD_INIT([bfs])
1374 AM_CONDITIONAL([BUILD_BFS], [test "x$build_bfs" = xyes])
1375
1376
1377 AC_ARG_ENABLE([minix],
1378   AS_HELP_STRING([--disable-minix], [do not build fsck.minix, mkfs.minix]),
1379   [], [UL_DEFAULT_ENABLE([minix], [yes])]
1380 )
1381 UL_BUILD_INIT([minix])
1382 AM_CONDITIONAL([BUILD_MINIX], [test "x$build_minix" = xyes])
1383
1384
1385 AC_ARG_ENABLE([fdformat],
1386   AS_HELP_STRING([--disable-fdformat], [do not build fdformat]),
1387   [], [UL_DEFAULT_ENABLE([fdformat], [check])]
1388 )
1389 UL_BUILD_INIT([fdformat])
1390 UL_REQUIRES_LINUX([fdformat])
1391 AM_CONDITIONAL([BUILD_FDFORMAT], [test "x$build_fdformat" = xyes])
1392
1393
1394 AC_ARG_ENABLE([hwclock],
1395   AS_HELP_STRING([--disable-hwclock], [do not build hwclock]),
1396   [], [UL_DEFAULT_ENABLE([hwclock], [check])]
1397 )
1398 have_linuxdummy=$linux_os
1399
1400 UL_BUILD_INIT([hwclock])
1401 UL_REQUIRES_HAVE([hwclock], [io, linuxdummy], [ioperm iopl function or Linux])
1402 AM_CONDITIONAL([BUILD_HWCLOCK], [test "x$build_hwclock" = xyes])
1403
1404
1405 UL_BUILD_INIT([mkfs], [yes])
1406 AM_CONDITIONAL([BUILD_MKFS], [test "x$build_mkfs" = xyes])
1407
1408 UL_BUILD_INIT([isosize], [yes])
1409 AM_CONDITIONAL([BUILD_ISOSIZE], [test "x$build_isosize" = xyes])
1410
1411
1412 UL_BUILD_INIT([fstrim], [check])
1413 UL_REQUIRES_LINUX([fstrim])
1414 UL_REQUIRES_BUILD([fstrim], [libmount])
1415 AM_CONDITIONAL([BUILD_FSTRIM], [test "x$build_fstrim" = xyes])
1416
1417
1418 UL_BUILD_INIT([swapon], [check])
1419 UL_REQUIRES_LINUX([swapon])
1420 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapon])], [swapon])
1421 UL_REQUIRES_SYSCALL_CHECK([swapon], [UL_CHECK_SYSCALL([swapoff])], [swapoff])
1422 UL_REQUIRES_BUILD([swapon], [libblkid])
1423 UL_REQUIRES_BUILD([swapon], [libmount])
1424 UL_REQUIRES_BUILD([swapon], [libsmartcols])
1425 AM_CONDITIONAL([BUILD_SWAPON], [test "x$build_swapon" = xyes])
1426 AC_CHECK_FUNCS([swapon])
1427 AC_CHECK_FUNCS([swapoff])
1428
1429
1430 UL_BUILD_INIT([lsblk], [check])
1431 UL_REQUIRES_LINUX([lsblk])
1432 UL_REQUIRES_BUILD([lsblk], [libblkid])
1433 UL_REQUIRES_BUILD([lsblk], [libmount])
1434 UL_REQUIRES_BUILD([lsblk], [libsmartcols])
1435 AM_CONDITIONAL([BUILD_LSBLK], [test "x$build_lsblk" = xyes])
1436
1437
1438 UL_BUILD_INIT([lscpu], [check])
1439 UL_REQUIRES_LINUX([lscpu])
1440 UL_REQUIRES_BUILD([lscpu], [libsmartcols])
1441 UL_REQUIRES_HAVE([lscpu], [cpu_set_t], [cpu_set_t type])
1442 AM_CONDITIONAL([BUILD_LSCPU], [test "x$build_lscpu" = xyes])
1443
1444
1445 AC_ARG_ENABLE([lslogins],
1446   AS_HELP_STRING([--disable-lslogins], [do not build lslogins]),
1447   [], [UL_DEFAULT_ENABLE([lslogins], [check])]
1448 )
1449 UL_BUILD_INIT([lslogins])
1450 UL_REQUIRES_BUILD([lslogins], [libsmartcols])
1451 UL_REQUIRES_HAVE([lslogins], [shadow_h], [shadow.h header])
1452 UL_REQUIRES_HAVE([lslogins], [utmpx_h], [utmpx.h header])
1453 UL_REQUIRES_HAVE([lslogins], [gnu_utmpx], [GNU utmpx fucntions])
1454 AM_CONDITIONAL([BUILD_LSLOGINS], [test "x$build_lslogins" = xyes])
1455
1456
1457 UL_BUILD_INIT([chcpu], [check])
1458 UL_REQUIRES_LINUX([chcpu])
1459 UL_REQUIRES_HAVE([chcpu], [cpu_set_t], [cpu_set_t type])
1460 AM_CONDITIONAL([BUILD_CHCPU], [test "x$build_chcpu" = xyes])
1461
1462
1463 AC_ARG_ENABLE([wdctl],
1464   AS_HELP_STRING([--disable-wdctl], [do not build wdctl]),
1465   [], [UL_DEFAULT_ENABLE([wdctl], [check])]
1466 )
1467 UL_BUILD_INIT([wdctl])
1468 UL_REQUIRES_LINUX([wdctl])
1469 UL_REQUIRES_BUILD([wdctl], [libsmartcols])
1470 UL_REQUIRES_HAVE([wdctl], [linux_watchdog_h], [linux/watchdog.h header file])
1471 AM_CONDITIONAL([BUILD_WDCTL], [test "x$build_wdctl" = xyes])
1472
1473
1474 UL_BUILD_INIT([swaplabel], [check])
1475 UL_REQUIRES_BUILD([swaplabel], [libblkid])
1476 AM_CONDITIONAL([BUILD_SWAPLABEL], [test "x$build_swaplabel" = xyes])
1477
1478
1479 UL_BUILD_INIT([mkswap], [yes])
1480 AM_CONDITIONAL([BUILD_MKSWAP], [test "x$build_mkswap" = xyes])
1481 AS_IF([test "x$build_mkswap" = xyes -a "x$build_libuuid" != xyes], [
1482   AC_MSG_WARN([uuid library is not found; mkswap(8) will not generate UUIDs])
1483 ])
1484
1485
1486 AC_ARG_ENABLE([cal],
1487   AS_HELP_STRING([--disable-cal], [do not build cal]),
1488   [], [UL_DEFAULT_ENABLE([cal], [check])]
1489 )
1490 UL_BUILD_INIT([cal])
1491 AM_CONDITIONAL([BUILD_CAL], [test "x$build_cal" = xyes])
1492
1493 AC_ARG_ENABLE([logger],
1494   AS_HELP_STRING([--disable-logger], [do not build logger]),
1495   [], [UL_DEFAULT_ENABLE([logger], [check])]
1496 )
1497 UL_BUILD_INIT([logger])
1498 AM_CONDITIONAL([BUILD_LOGGER], [test "x$build_logger" = xyes])
1499
1500 UL_BUILD_INIT([look], [yes])
1501 AM_CONDITIONAL([BUILD_LOOK], [test "x$build_look" = xyes])
1502
1503 UL_BUILD_INIT([mcookie], [yes])
1504 AM_CONDITIONAL([BUILD_MCOOKIE], [test "x$build_mcookie" = xyes])
1505
1506 UL_BUILD_INIT([namei], [yes])
1507 AM_CONDITIONAL([BUILD_NAMEI], [test "x$build_namei" = xyes])
1508
1509 matriplet="$($CC -print-multiarch 2>/dev/null || true)"
1510 if test "x$matriplet" != "x"; then
1511   AC_DEFINE_UNQUOTED([MULTIARCHTRIPLET], ["$matriplet"],
1512   ["Multi-arch triplet for whereis library search path"])
1513 fi
1514 UL_BUILD_INIT([whereis], [yes])
1515 AM_CONDITIONAL([BUILD_WHEREIS], [test "x$build_whereis" = xyes])
1516
1517 UL_BUILD_INIT([getopt], [yes])
1518 AM_CONDITIONAL([BUILD_GETOPT], [test "x$build_getopt" = xyes])
1519
1520
1521 UL_BUILD_INIT([blockdev], [check])
1522 UL_REQUIRES_LINUX([blockdev])
1523 AM_CONDITIONAL([BUILD_BLOCKDEV], [test "x$build_blockdev" = xyes])
1524
1525
1526 UL_BUILD_INIT([prlimit], [check])
1527 UL_REQUIRES_LINUX([prlimit])
1528 UL_REQUIRES_BUILD([prlimit], [libsmartcols])
1529 UL_REQUIRES_SYSCALL_CHECK([prlimit], [UL_CHECK_SYSCALL([prlimit64])], [prlimit64])
1530 AM_CONDITIONAL([BUILD_PRLIMIT], [test "x$build_prlimit" = xyes])
1531 AS_IF([test "x$build_prlimit" = xyes], [
1532   AC_CHECK_FUNCS([prlimit])
1533 ])
1534
1535
1536 UL_BUILD_INIT([lslocks], [check])
1537 UL_REQUIRES_LINUX([lslocks])
1538 UL_REQUIRES_BUILD([lslocks], [libmount])
1539 UL_REQUIRES_BUILD([lslocks], [libsmartcols])
1540 AM_CONDITIONAL([BUILD_LSLOCKS], [test "x$build_lslocks" = xyes])
1541
1542
1543 AC_ARG_ENABLE([switch_root],
1544   AS_HELP_STRING([--disable-switch_root], [do not build switch_root]),
1545   [], [UL_DEFAULT_ENABLE([switch_root], [check])]
1546 )
1547 UL_BUILD_INIT([switch_root])
1548 UL_REQUIRES_LINUX([switch_root])
1549 UL_REQUIRES_HAVE([switch_root], [openat], [openat function])
1550 AM_CONDITIONAL([BUILD_SWITCH_ROOT], [test "x$build_switch_root" = xyes])
1551
1552
1553 AC_ARG_ENABLE([pivot_root],
1554   AS_HELP_STRING([--disable-pivot_root], [do not build pivot_root]),
1555   [], [UL_DEFAULT_ENABLE([pivot_root], [check])]
1556 )
1557 UL_BUILD_INIT([pivot_root])
1558 UL_REQUIRES_LINUX([pivot_root])
1559 UL_REQUIRES_SYSCALL_CHECK([pivot_root], [UL_CHECK_SYSCALL([pivot_root])])
1560 AM_CONDITIONAL([BUILD_PIVOT_ROOT], [test "x$build_pivot_root" = xyes])
1561
1562
1563 UL_BUILD_INIT([flock], [check])
1564 UL_REQUIRES_HAVE([flock], [timer], [timer_create function])
1565 AM_CONDITIONAL([BUILD_FLOCK], [test "x$build_flock" = xyes])
1566
1567
1568 AC_ARG_ENABLE([lsmem],
1569   AS_HELP_STRING([--disable-lsmem], [do not build lsmem]),
1570   [], [UL_DEFAULT_ENABLE([lsmem], [check])]
1571 )
1572 UL_BUILD_INIT([lsmem])
1573 UL_REQUIRES_LINUX([lsmem])
1574 UL_REQUIRES_BUILD([lsmem], [libsmartcols])
1575 AM_CONDITIONAL([BUILD_LSMEM], [test "x$build_lsmem" = xyes])
1576
1577
1578 AC_ARG_ENABLE([chmem],
1579   AS_HELP_STRING([--disable-chmem], [do not build chmem]),
1580   [], [UL_DEFAULT_ENABLE([chmem], [check])]
1581 )
1582 UL_BUILD_INIT([chmem])
1583 UL_REQUIRES_LINUX([chmem])
1584 AM_CONDITIONAL([BUILD_CHMEM], [test "x$build_chmem" = xyes])
1585
1586 UL_BUILD_INIT([ipcmk], [yes])
1587 AM_CONDITIONAL([BUILD_IPCMK], [test "x$build_ipcmk" = xyes])
1588
1589
1590 AC_ARG_ENABLE([ipcrm],
1591   AS_HELP_STRING([--disable-ipcrm], [do not build ipcrm]),
1592   [], [UL_DEFAULT_ENABLE([ipcrm], [yes])]
1593 )
1594 UL_BUILD_INIT([ipcrm])
1595 AM_CONDITIONAL([BUILD_IPCRM], [test "x$build_ipcrm" = xyes])
1596
1597 AC_ARG_ENABLE([ipcs],
1598   AS_HELP_STRING([--disable-ipcs], [do not build ipcs]),
1599   [], [UL_DEFAULT_ENABLE([ipcs], [yes])]
1600 )
1601 UL_BUILD_INIT([ipcs])
1602 AM_CONDITIONAL([BUILD_IPCS], [test "x$build_ipcs" = xyes])
1603
1604 UL_BUILD_INIT([lsipc], [check])
1605 UL_REQUIRES_LINUX([lsipc])
1606 UL_REQUIRES_BUILD([lsipc], [libsmartcols])
1607 AM_CONDITIONAL([BUILD_LSIPC], [test "x$build_lsipc" = xyes])
1608
1609 UL_BUILD_INIT([lsns], [check])
1610 UL_REQUIRES_LINUX([lsns])
1611 UL_REQUIRES_BUILD([lsns], [libsmartcols])
1612 UL_REQUIRES_BUILD([lsns], [libmount])
1613 AM_CONDITIONAL([BUILD_LSNS], [test "x$build_lsns" = xyes])
1614
1615 UL_BUILD_INIT([renice], [yes])
1616 AM_CONDITIONAL([BUILD_RENICE], [test "x$build_renice" = xyes])
1617
1618
1619 AC_ARG_ENABLE([rfkill],
1620   AS_HELP_STRING([--disable-rfkill], [do not build rfkill]),
1621   [], [UL_DEFAULT_ENABLE([rfkill], [check])]
1622 )
1623 UL_BUILD_INIT([rfkill])
1624 UL_REQUIRES_LINUX([rfkill])
1625 UL_REQUIRES_BUILD([rfkill], [libsmartcols])
1626 AM_CONDITIONAL([BUILD_RFKILL], [test "x$build_rfkill" = xyes])
1627
1628
1629 UL_BUILD_INIT([setsid], [yes])
1630 AM_CONDITIONAL([BUILD_SETSID], [test "x$build_setsid" = xyes])
1631
1632 UL_BUILD_INIT([readprofile], [check])
1633 UL_REQUIRES_LINUX([readprofile])
1634 AM_CONDITIONAL([BUILD_READPROFILE], [test "x$build_readprofile" = xyes])
1635
1636 UL_BUILD_INIT([dmesg], [check])
1637 UL_REQUIRES_LINUX([dmesg])
1638 AM_CONDITIONAL([BUILD_DMESG], [test "x$build_dmesg" = xyes])
1639
1640 UL_BUILD_INIT([ctrlaltdel], [check])
1641 UL_REQUIRES_LINUX([ctrlaltdel])
1642 dnl we assume reboot() to be the 1-argument variant, because even considering
1643 dnl widely used alternative C libraries like uclibc, dietlibc and musl,
1644 dnl reboot() with multiple arguments is yet only found in glibc versions
1645 dnl earlier than 2.x.
1646 UL_REQUIRES_HAVE([ctrlaltdel], [reboot], [reboot function])
1647 AM_CONDITIONAL([BUILD_CTRLALTDEL], [test "x$build_ctrlaltdel" = xyes])
1648
1649 UL_BUILD_INIT([fincore], [check])
1650 UL_REQUIRES_LINUX([fincore])
1651 UL_REQUIRES_BUILD([fincore], [libsmartcols])
1652 AM_CONDITIONAL([BUILD_FINCORE], [test "x$build_fincore" = xyes])
1653
1654 UL_BUILD_INIT([fsfreeze], [check])
1655 UL_REQUIRES_LINUX([fsfreeze])
1656 AM_CONDITIONAL([BUILD_FSFREEZE], [test "x$build_fsfreeze" = xyes])
1657
1658 UL_BUILD_INIT([blkdiscard], [check])
1659 UL_REQUIRES_LINUX([blkdiscard])
1660 AM_CONDITIONAL([BUILD_BLKDISCARD], [test "x$build_blkdiscard" = xyes])
1661
1662 UL_BUILD_INIT([blkzone], [check])
1663 UL_REQUIRES_LINUX([blkzone])
1664 UL_REQUIRES_HAVE([blkzone], [linux_blkzoned_h], [linux/blkzoned.h header])
1665 AM_CONDITIONAL([BUILD_BLKZONE], [test "x$build_blkzone" = xyes])
1666
1667 UL_BUILD_INIT([ldattach], [check])
1668 UL_REQUIRES_LINUX([ldattach])
1669 AM_CONDITIONAL([BUILD_LDATTACH], [test "x$build_ldattach" = xyes])
1670
1671 UL_BUILD_INIT([rtcwake], [check])
1672 UL_REQUIRES_LINUX([rtcwake])
1673 AM_CONDITIONAL([BUILD_RTCWAKE], [test "x$build_rtcwake" = xyes])
1674
1675 UL_BUILD_INIT([setarch], [check])
1676 UL_REQUIRES_LINUX([setarch])
1677 AM_CONDITIONAL([BUILD_SETARCH], [test "x$build_setarch" = xyes])
1678
1679 UL_BUILD_INIT([script], [check])
1680 UL_REQUIRES_HAVE([script], [sys_signalfd_h], [sys/signalfd.h header])
1681 AM_CONDITIONAL([BUILD_SCRIPT], [test "x$build_script" = xyes])
1682
1683 UL_BUILD_INIT([scriptreplay], [yes])
1684 AM_CONDITIONAL([BUILD_SCRIPTREPLAY], [test "x$build_scriptreplay" = xyes])
1685
1686 UL_BUILD_INIT([col], [yes])
1687 AM_CONDITIONAL([BUILD_COL], [test "x$build_col" = xyes])
1688
1689 UL_BUILD_INIT([colcrt], [yes])
1690 AM_CONDITIONAL([BUILD_COLCRT], [test "x$build_colcrt" = xyes])
1691
1692 UL_BUILD_INIT([colrm], [yes])
1693 AM_CONDITIONAL([BUILD_COLRM], [test "x$build_colrm" = xyes])
1694
1695 UL_BUILD_INIT([column], [check])
1696 UL_REQUIRES_BUILD([column], [libsmartcols])
1697 AM_CONDITIONAL([BUILD_COLUMN], [test "x$build_column" = xyes])
1698
1699 UL_BUILD_INIT([hexdump], [yes])
1700 AM_CONDITIONAL([BUILD_HEXDUMP], [test "x$build_hexdump" = xyes])
1701
1702 UL_BUILD_INIT([rev], [yes])
1703 AM_CONDITIONAL([BUILD_REV], [test "x$build_rev" = xyes])
1704
1705
1706 AC_ARG_ENABLE([tunelp],
1707   AS_HELP_STRING([--enable-tunelp], [build tunelp]),
1708   [], [UL_DEFAULT_ENABLE([tunelp], [no])]
1709 )
1710 UL_BUILD_INIT([tunelp])
1711 UL_REQUIRES_LINUX([tunelp])
1712 AM_CONDITIONAL([BUILD_TUNELP], [test "x$build_tunelp" = xyes])
1713
1714
1715 AC_ARG_ENABLE([kill],
1716   AS_HELP_STRING([--disable-kill], [do not build kill]),
1717   [], [UL_DEFAULT_ENABLE([kill], [check])]
1718 )
1719 UL_BUILD_INIT([kill])
1720 UL_REQUIRES_LINUX([kill])
1721 AM_CONDITIONAL([BUILD_KILL], [test "x$build_kill" = xyes])
1722
1723
1724 AC_ARG_ENABLE([last],
1725   AS_HELP_STRING([--disable-last], [do not build last]),
1726   [], [UL_DEFAULT_ENABLE([last], [check])]
1727 )
1728 UL_BUILD_INIT([last])
1729 UL_REQUIRES_HAVE([last], [utmpx_h], [utmpx.h header])
1730 UL_REQUIRES_HAVE([last], [gnu_utmpx], [GNU utmpx fucntions])
1731 AM_CONDITIONAL([BUILD_LAST], [test "x$build_last" = xyes])
1732
1733
1734 AC_ARG_ENABLE([utmpdump],
1735   AS_HELP_STRING([--disable-utmpdump], [do not build utmpdump]),
1736   [], [UL_DEFAULT_ENABLE([utmpdump], [check])]
1737 )
1738 UL_BUILD_INIT([utmpdump])
1739 UL_REQUIRES_HAVE([utmpdump], [utmpx_h], [utmpx.h header])
1740 UL_REQUIRES_HAVE([utmpdump], [gnu_utmpx], [GNU utmpx fucntions])
1741 AM_CONDITIONAL([BUILD_UTMPDUMP], [test "x$build_utmpdump" = xyes])
1742
1743
1744 AC_ARG_ENABLE([line],
1745   AS_HELP_STRING([--enable-line], [build line]),
1746   [], [UL_DEFAULT_ENABLE([line], [no])]
1747 )
1748 UL_BUILD_INIT([line])
1749 AM_CONDITIONAL([BUILD_LINE], [test "x$build_line" = xyes])
1750
1751
1752 AC_ARG_ENABLE([mesg],
1753   AS_HELP_STRING([--disable-mesg], [do not build mesg]),
1754   [], [UL_DEFAULT_ENABLE([mesg], [yes])]
1755 )
1756 UL_BUILD_INIT([mesg])
1757 AM_CONDITIONAL([BUILD_MESG], [test "x$build_mesg" = xyes])
1758
1759
1760 AC_ARG_ENABLE([raw],
1761   AS_HELP_STRING([--disable-raw], [do not build raw]),
1762   [], [UL_DEFAULT_ENABLE([raw], [check])]
1763 )
1764 UL_BUILD_INIT([raw])
1765 UL_REQUIRES_LINUX([raw])
1766 UL_REQUIRES_HAVE([raw], [linux_raw_h], [raw.h header file])
1767 AM_CONDITIONAL([BUILD_RAW], [test "x$build_raw" = xyes])
1768
1769
1770 AC_ARG_ENABLE([rename],
1771   AS_HELP_STRING([--disable-rename], [do not build rename]),
1772   [], [UL_DEFAULT_ENABLE([rename], [yes])]
1773 )
1774 UL_BUILD_INIT([rename])
1775 AM_CONDITIONAL([BUILD_RENAME], [test "x$build_rename" = xyes])
1776
1777
1778 AC_ARG_ENABLE([vipw],
1779   AS_HELP_STRING([--enable-vipw], [build vipw]),
1780   [], [UL_DEFAULT_ENABLE([vipw], [no])]
1781 )
1782 UL_BUILD_INIT([vipw])
1783 UL_REQUIRES_HAVE([vipw], [shadow_h], [shadow.h header])
1784 AM_CONDITIONAL([BUILD_VIPW], [test "x$build_vipw" = xyes])
1785
1786
1787 AC_ARG_ENABLE([newgrp],
1788   AS_HELP_STRING([--enable-newgrp], [build newgrp]),
1789   [], [UL_DEFAULT_ENABLE([newgrp], [no])]
1790 )
1791 UL_BUILD_INIT([newgrp])
1792 AM_CONDITIONAL([BUILD_NEWGRP], [test "x$build_newgrp" = xyes])
1793
1794
1795 AC_ARG_WITH([user], AS_HELP_STRING([--without-user], [compile without libuser (remote chsh)]),
1796   [], [with_user=check]
1797 )
1798 have_user=no
1799 AS_IF([test "x$with_user" != xno], [
1800   PKG_CHECK_MODULES(LIBUSER,[libuser >= 0.58], [have_user=yes], [have_user=no])
1801   AS_CASE([$with_user:$have_user],
1802     [yes:no],
1803       [AC_MSG_ERROR([user selected but libuser not found])],
1804     [*:yes],
1805       [AC_DEFINE([HAVE_LIBUSER], [1], [Define if libuser is available])]
1806   )
1807   # temporary solution, libuser has stupid .pc where are exported all
1808   # private dependencies to Requires: instead of Requires.private:
1809   AS_IF([test "x$have_user" = xyes], [
1810     LIBUSER_LIBS=-luser
1811   ])
1812 ])
1813 AM_CONDITIONAL([HAVE_USER], [test "x$have_user" = xyes])
1814
1815 AC_ARG_ENABLE([chfn-chsh-password],
1816   AS_HELP_STRING([--disable-chfn-chsh-password], [do not require the user to enter the password in chfn and chsh]),
1817   [], [enable_chfn_chsh_password=yes]
1818 )
1819
1820 AC_ARG_ENABLE([chfn-chsh],
1821   AS_HELP_STRING([--enable-chfn-chsh], [build chfn and chsh]),
1822   [], [UL_DEFAULT_ENABLE([chfn_chsh], [check])]
1823 )
1824 UL_BUILD_INIT([chfn_chsh])
1825 UL_REQUIRES_HAVE([chfn_chsh], [shadow_h], [shadow.h header])
1826 UL_REQUIRES_HAVE([chfn_chsh], [getusershell], [getusershell function])
1827
1828 AS_IF([test "x$enable_chfn_chsh_password" = xyes -o "x$have_user" = xyes], [
1829   UL_REQUIRES_HAVE([chfn_chsh], [security_pam_appl_h], [PAM header file])
1830   AC_DEFINE([CHFN_CHSH_PASSWORD], [1], [Should chfn and chsh require the user to enter the password?])
1831 ])
1832 AM_CONDITIONAL([BUILD_CHFN_CHSH], [test "x$build_chfn_chsh" = xyes])
1833 AM_CONDITIONAL([CHFN_CHSH_PASSWORD], [test "x$enable_chfn_chsh_password" = xyes])
1834
1835 AC_ARG_ENABLE([chsh-only-listed],
1836   AS_HELP_STRING([--disable-chsh-only-listed], [chsh: allow shells not in /etc/shells]),
1837   [], enable_chsh_only_listed=yes
1838 )
1839
1840 AS_IF([test "x$enable_chsh_only_listed" = xyes], [
1841   AC_DEFINE([ONLY_LISTED_SHELLS], [1], [Should chsh allow only shells in /etc/shells?])
1842 ])
1843
1844
1845 AC_ARG_ENABLE([login],
1846   AS_HELP_STRING([--disable-login], [do not build login]),
1847   [], [UL_DEFAULT_ENABLE([login], [check])]
1848 )
1849 UL_BUILD_INIT([login])
1850 UL_REQUIRES_HAVE([login], [security_pam_appl_h], [PAM header file])
1851 UL_REQUIRES_HAVE([login], [security_pam_misc_h, security_openpam_h], [PAM conversation functions])
1852 UL_REQUIRES_HAVE([login], [utmpx_h], [utmpx.h header])
1853 UL_REQUIRES_HAVE([login], [gnu_utmpx], [GNU utmpx fucntions])
1854 AM_CONDITIONAL([BUILD_LOGIN], [test "x$build_login" = xyes])
1855
1856 AC_ARG_ENABLE([login-chown-vcs],
1857   AS_HELP_STRING([--enable-login-chown-vcs], [let login chown /dev/vcsN]),
1858   [], [enable_login_chown_vcs=no]
1859 )
1860
1861 AS_IF([test "x$enable_login_chown_vcs" = xyes], [
1862   AC_DEFINE([LOGIN_CHOWN_VCS], [1], [Should login chown /dev/vcsN?])
1863 ])
1864
1865 AC_ARG_ENABLE([login-stat-mail],
1866   AS_HELP_STRING([--enable-login-stat-mail], [let login stat() the mailbox]),
1867   [], [enable_login_stat_mail=no]
1868 )
1869
1870 AS_IF([test "x$enable_login_stat_mail" = xyes], [
1871   AC_DEFINE([LOGIN_STAT_MAIL], [1], [Should login stat() the mailbox?])
1872 ])
1873
1874
1875 AC_ARG_ENABLE([nologin],
1876   AS_HELP_STRING([--disable-nologin], [do not build nologin]),
1877   [], [UL_DEFAULT_ENABLE([nologin], [yes])]
1878 )
1879 UL_BUILD_INIT([nologin])
1880 AM_CONDITIONAL([BUILD_NOLOGIN], [test "x$build_nologin" = xyes])
1881
1882
1883 AC_ARG_ENABLE([sulogin],
1884   AS_HELP_STRING([--disable-sulogin], [do not build sulogin]),
1885   [], [UL_DEFAULT_ENABLE([sulogin], [check])]
1886 )
1887 UL_BUILD_INIT([sulogin])
1888 UL_REQUIRES_HAVE([sulogin], [shadow_h], [shadow.h header])
1889 AM_CONDITIONAL([BUILD_SULOGIN], [test "x$build_sulogin" = xyes])
1890
1891
1892 AC_ARG_ENABLE([su],
1893   AS_HELP_STRING([--disable-su], [do not build su]),
1894   [], [UL_DEFAULT_ENABLE([su], [check])]
1895 )
1896 UL_BUILD_INIT([su])
1897 UL_REQUIRES_HAVE([su], [security_pam_appl_h], [PAM header file])
1898 UL_REQUIRES_HAVE([su], [utmpx_h], [utmpx.h header])
1899 UL_REQUIRES_HAVE([su], [gnu_utmpx], [GNU utmpx fucntions])
1900 AM_CONDITIONAL([BUILD_SU], [test "x$build_su" = xyes])
1901
1902
1903 AC_ARG_ENABLE([runuser],
1904   AS_HELP_STRING([--disable-runuser], [do not build runuser]),
1905   [], [UL_DEFAULT_ENABLE([runuser], [check])]
1906 )
1907 UL_BUILD_INIT([runuser])
1908 UL_REQUIRES_HAVE([runuser], [security_pam_appl_h], [PAM header file])
1909 UL_REQUIRES_HAVE([runuser], [utmpx_h], [utmpx.h header])
1910 UL_REQUIRES_HAVE([runuser], [gnu_utmpx], [GNU utmpx fucntions])
1911 AM_CONDITIONAL([BUILD_RUNUSER], [test "x$build_runuser" = xyes])
1912
1913
1914 AC_ARG_ENABLE([ul],
1915   AS_HELP_STRING([--disable-ul], [do not build ul]),
1916   [], [UL_DEFAULT_ENABLE([ul], [check])]
1917 )
1918 UL_BUILD_INIT([ul])
1919 UL_REQUIRES_HAVE([ul], [ncursesw, ncurses], [ncursesw or ncurses libraries])
1920 AM_CONDITIONAL([BUILD_UL], [test "x$build_ul" = xyes])
1921
1922
1923 AC_ARG_ENABLE([more],
1924   AS_HELP_STRING([--disable-more], [do not build more]),
1925   [], [UL_DEFAULT_ENABLE([more], [check])]
1926 )
1927 UL_BUILD_INIT([more])
1928 UL_REQUIRES_HAVE([more], [ncursesw, ncurses], [ncursesw or ncurses libraries])
1929 AM_CONDITIONAL([BUILD_MORE], [test "x$build_more" = xyes])
1930
1931
1932 AC_ARG_ENABLE([pg],
1933   AS_HELP_STRING([--enable-pg], [build pg]),
1934   [], [UL_DEFAULT_ENABLE([pg], [no])]
1935 )
1936 UL_BUILD_INIT([pg])
1937 UL_REQUIRES_HAVE([pg], [ncursesw, ncurses], [ncursesw or ncurses library])
1938 AM_CONDITIONAL([BUILD_PG], [test "x$build_pg" = xyes])
1939
1940
1941 AC_ARG_ENABLE([setterm],
1942   AS_HELP_STRING([--disable-setterm], [do not build setterm]),
1943   [], [UL_DEFAULT_ENABLE([setterm], [check])]
1944 )
1945 UL_BUILD_INIT([setterm])
1946 UL_REQUIRES_LINUX([setterm])
1947 UL_REQUIRES_HAVE([setterm], [ncursesw, ncurses], [ncursesw or ncurses library])
1948 AM_CONDITIONAL([BUILD_SETTERM], [test "x$build_setterm" = xyes])
1949
1950 # build_schedutils= is just configure-only variable to control
1951 # ionice, taskset and chrt
1952 AC_ARG_ENABLE([schedutils],
1953   AS_HELP_STRING([--disable-schedutils], [do not build chrt, ionice, taskset]),
1954   [], [UL_DEFAULT_ENABLE([schedutils], [check])]
1955 )
1956
1957
1958 UL_ENABLE_ALIAS([ionice], [schedutils])
1959 UL_BUILD_INIT([ionice])
1960 UL_REQUIRES_SYSCALL_CHECK([ionice],
1961         [UL_CHECK_SYSCALL([ioprio_set],
1962           [alpha],      [442],
1963           [i*86],       [289],
1964           [ia64*],      [1274],
1965           [powerpc*],   [273],
1966           [s390*],      [282],
1967           [sparc*],     [196],
1968           [sh*],        [288],
1969           [x86_64*],    [251])],
1970         [ioprio_set])
1971
1972 UL_REQUIRES_SYSCALL_CHECK([ionice],
1973         [UL_CHECK_SYSCALL([ioprio_get],
1974           [alpha],      [443],
1975           [i*86],       [290],
1976           [ia64*],      [1275],
1977           [powerpc*],   [274],
1978           [s390*],      [283],
1979           [sparc*],     [218],
1980           [sh*],        [289],
1981           [x86_64*],    [252])],
1982         [ioprio_get])
1983
1984 AM_CONDITIONAL([BUILD_IONICE], [test "x$build_ionice" = xyes])
1985
1986
1987 UL_ENABLE_ALIAS([taskset], [schedutils])
1988 UL_BUILD_INIT([taskset])
1989 UL_REQUIRES_HAVE([taskset], [cpu_set_t], [cpu_set_t type])
1990 UL_REQUIRES_SYSCALL_CHECK([taskset],
1991         [UL_CHECK_SYSCALL([sched_getaffinity])],
1992         [sched_getaffinity])
1993 AM_CONDITIONAL([BUILD_TASKSET], [test "x$build_taskset" = xyes])
1994
1995
1996 have_schedsetter=no
1997 AS_IF([test "x$ac_cv_func_sched_setscheduler" = xyes], [have_schedsetter=yes],
1998       [test "x$ac_cv_func_sched_setattr" = xyes], [have_schedsetter=yes])
1999
2000 UL_ENABLE_ALIAS([chrt], [schedutils])
2001 UL_BUILD_INIT([chrt])
2002 UL_REQUIRES_HAVE([chrt], [schedsetter], [sched_set functions])
2003 AM_CONDITIONAL([BUILD_CHRT], [test "x$build_chrt" = xyes])
2004
2005 AS_IF([test "x$build_chrt" = xyes], [
2006         UL_CHECK_SYSCALL([sched_setattr])
2007 ])
2008
2009
2010 AC_ARG_ENABLE([wall],
2011   AS_HELP_STRING([--disable-wall], [do not build wall]),
2012   [], [UL_DEFAULT_ENABLE([wall], [check])]
2013 )
2014 UL_BUILD_INIT([wall])
2015 UL_REQUIRES_HAVE([wall], [utmpx_h], [utmpx.h header])
2016 AM_CONDITIONAL([BUILD_WALL], [test "x$build_wall" = xyes])
2017
2018
2019 AC_ARG_ENABLE([write],
2020   AS_HELP_STRING([--enable-write], [build write]),
2021   [], [UL_DEFAULT_ENABLE([write], [no])]
2022 )
2023 UL_BUILD_INIT([write])
2024 UL_REQUIRES_HAVE([write], [utmpx_h], [utmpx.h header])
2025 UL_REQUIRES_HAVE([write], [gnu_utmpx], [GNU utmpx fucntions])
2026 AM_CONDITIONAL([BUILD_WRITE], [test "x$build_write" = xyes])
2027
2028
2029 AC_ARG_WITH([btrfs],
2030   AS_HELP_STRING([--with-btrfs], [build with support for btrfs]),
2031   [], [with_btrfs=check]
2032 )
2033 have_btrfs=no
2034 AS_IF([test "x$with_btrfs" != xno], [
2035   AS_CASE([$with_btrfs:$have_linux_btrfs_h],
2036     [yes:no],
2037     [AC_MSG_ERROR([btrfs selected but linux/btrfs.h not found])],
2038     [check:no],
2039        [AC_MSG_WARN([linux/btrfs.h not found, do not build with btrfs support])],
2040     [*:yes],
2041        [have_btrfs=yes
2042         AC_DEFINE([HAVE_BTRFS_SUPPORT], [1], [Define if btrfs stuff is available])]
2043   )
2044 ])
2045 AM_CONDITIONAL([HAVE_BTRFS], [test "x$have_btrfs" = xyes])
2046
2047
2048 AC_ARG_WITH([systemd],
2049   AS_HELP_STRING([--with-systemd], [build with support for systemd]),
2050   [], [with_systemd=check]
2051 )
2052
2053 have_systemd=no
2054 AS_IF([test "x$with_systemd" != xno], [
2055   # new version -- all libsystemd-* libs merged into libsystemd
2056   PKG_CHECK_MODULES([SYSTEMD], [libsystemd], [have_systemd=yes], [have_systemd=no])
2057   # old versions
2058   AS_IF([test "x$have_systemd" != "xyes"], [
2059     PKG_CHECK_MODULES([SYSTEMD_DAEMON], [libsystemd-daemon],
2060                       [have_systemd_daemon=yes], [have_systemd_daemon=no])
2061     PKG_CHECK_MODULES([SYSTEMD_JOURNAL], [libsystemd-journal],
2062                       [have_systemd_journal=yes], [have_systemd_journal=no])
2063     AS_IF([test "x$have_systemd_daemon" = "xyes" -a "x$have_systemd_journal" = "xyes" ],[
2064            have_systemd=yes])
2065   ])
2066   AS_CASE([$with_systemd:$have_systemd],
2067     [yes:no],
2068       [AC_MSG_ERROR([systemd expected but libsystemd not found])],
2069     [*:yes],
2070        AC_DEFINE([HAVE_LIBSYSTEMD], [1], [Define if libsystemd is available])
2071   )
2072 ])
2073 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$have_systemd" = xyes])
2074
2075
2076 AC_ARG_WITH([systemdsystemunitdir],
2077   AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [directory for systemd service files]),
2078   [], [with_systemdsystemunitdir=`$PKG_CONFIG --variable=systemdsystemunitdir systemd`])
2079
2080 AS_IF([test "x$with_systemdsystemunitdir" != "xno"], [
2081   AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
2082 ])
2083
2084
2085 AC_ARG_WITH([smack],
2086   AS_HELP_STRING([--with-smack], [build with SMACK support]),
2087   [], [with_smack=no]
2088 )
2089 AS_IF([test "x$with_smack" = xyes], [
2090   AC_DEFINE([HAVE_SMACK], [1], [Add SMACK support])
2091 ])
2092
2093
2094 AC_ARG_WITH([bashcompletiondir],
2095   AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
2096   [],
2097   [AS_IF([`$PKG_CONFIG --exists bash-completion`], [
2098     with_bashcompletiondir=`$PKG_CONFIG --variable=completionsdir bash-completion`
2099   ], [
2100     with_bashcompletiondir=${datadir}/bash-completion/completions
2101   ])
2102 ])
2103 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
2104
2105 AC_ARG_ENABLE([bash-completion],
2106   AS_HELP_STRING([--disable-bash-completion], [do not install bash completion files]),
2107   [], [enable_bash_completion=yes]
2108 )
2109
2110 AM_CONDITIONAL([BUILD_BASH_COMPLETION], [test "x$enable_bash_completion" = xyes])
2111
2112
2113 AC_ARG_WITH([python],
2114   AS_HELP_STRING([--without-python], [do not build python bindings, use --with-python={2,3} to force version]),
2115   [], [with_python=check withval=check]
2116 )
2117
2118 have_python=no
2119 have_libpython=no
2120 AS_IF([test "x$with_python" != xno], [
2121   # We follow distributions default and look for PKG module name "python"
2122   # (minimal version is 2) but if major version is explicitly specified by
2123   # --with-python=2 or --with-python=3 then we look for PKG module "python2" or
2124   # "python3".
2125   AS_IF([test "x$withval" != xno -a "x$withval" != xyes -a "x$withval" != xcheck],
2126         [pymajor="$withval"; PYTHON=python${pymajor}], [pymajor="2"])
2127
2128   # check for python interpreter
2129   AM_PATH_PYTHON([$pymajor], [have_python=yes], [have_python=no])
2130   AS_CASE([$with_python:$have_python],
2131     [yes:no],
2132       [AC_MSG_ERROR([python selected but python interpreter not found])],
2133     [check:no],
2134        [AC_MSG_WARN([python interpreter not found, do not build python bindings])],
2135     [*:yes],
2136        # check for python development stuff
2137        [PKG_CHECK_MODULES([PYTHON], [python-$PYTHON_VERSION],
2138                           [have_libpython=yes], [have_libpython=no])]
2139   )
2140 ])
2141
2142
2143 AC_ARG_ENABLE([pylibmount],
2144   AS_HELP_STRING([--disable-pylibmount], [do not build pylibmount]),
2145   [], [UL_DEFAULT_ENABLE([pylibmount], [check])]
2146 )
2147 UL_BUILD_INIT([pylibmount])
2148 UL_REQUIRES_HAVE([pylibmount], [libpython], [libpython])
2149 UL_REQUIRES_BUILD([pylibmount], [libmount])
2150 AM_CONDITIONAL([BUILD_PYLIBMOUNT], [test "x$build_pylibmount" = "xyes"])
2151
2152 # We need to introduce a verbatim dependency into the Makefile, without automake
2153 # trying to interpret it, so push it as a AM_SUBST_NOTMAKE variable.
2154 verbatim_pylibmount_dependency='
2155
2156 # pylibmountexec module must be installed after usrlib_exec libraries,
2157 # otherwise the libtool relink step will fail to find libmount.la and
2158 # will try -lmount which is possibly not available.
2159 install-pylibmountexecLTLIBRARIES: install-usrlib_execLTLIBRARIES
2160
2161 '
2162 AC_SUBST([verbatim_pylibmount_dependency])
2163 AM_SUBST_NOTMAKE([verbatim_pylibmount_dependency])
2164
2165 AC_ARG_ENABLE([pg-bell],
2166   AS_HELP_STRING([--disable-pg-bell], [let pg not ring the bell on invalid keys]),
2167   [], [enable_pg_bell=yes]
2168 )
2169
2170 AS_IF([test "x$enable_pg_bell" = xyes], [
2171   AC_DEFINE([PG_BELL], [1], [Should pg ring the bell on invalid keys?])
2172 ])
2173
2174
2175 AC_DEFUN([FS_PATHS_DEFAULT], [/sbin:/sbin/fs.d:/sbin/fs])
2176 AC_ARG_ENABLE([fs-paths-default],
2177   AS_HELP_STRING([--enable-fs-paths-default=paths], [default search path for fs helpers @<:@FS_PATHS_DEFAULT@:>@]),
2178   [AS_CASE([$enableval],
2179     [yes], [fs_paths_defaults="FS_PATHS_DEFAULT"],
2180     [no],  [fs_paths_defaults=""],
2181     [fs_paths_defaults="$enableval"]
2182   )],
2183   [fs_paths_defaults="FS_PATHS_DEFAULT"]
2184 )
2185 AC_ARG_ENABLE([fs-paths-extra],
2186   AS_HELP_STRING([--enable-fs-paths-extra=paths], [additional search paths for fs helpers]),
2187   [AS_CASE([$enableval],
2188      [yes|no], [fs_paths_extra=""],
2189      [fs_paths_extra="$enableval"]
2190   )],
2191   [fs_paths_extra=""]
2192 )
2193 fs_paths="$fs_paths_defaults"
2194 AS_IF([test "x$fs_paths_extra" != "x"], [
2195   AS_IF([test "x$fs_paths" != "x"], [
2196     fs_paths="${fs_paths}:"
2197   ])
2198   fs_paths="${fs_paths}${fs_paths_extra}"
2199 ])
2200 AC_DEFINE_UNQUOTED([FS_SEARCH_PATH], "$fs_paths", [search path for fs helpers])
2201
2202
2203 AC_ARG_ENABLE([use-tty-group],
2204   AS_HELP_STRING([--disable-use-tty-group], [do not install wall and write setgid tty]),
2205   [], [enable_use_tty_group=yes]
2206 )
2207 AM_CONDITIONAL([USE_TTY_GROUP], [test "x$enable_use_tty_group" = xyes])
2208
2209 AS_IF([test "x$enable_use_tty_group" = xyes], [
2210   AC_DEFINE([USE_TTY_GROUP], [1], [Should wall and write be installed setgid tty?])
2211 ])
2212
2213
2214 AC_ARG_ENABLE([sulogin-emergency-mount],
2215   AS_HELP_STRING([--enable-sulogin-emergency-mount],
2216                  [use emergency mount of /dev and /proc for sulogin]),
2217   [], [enable_sulogin_emergency_mount=no]
2218 )
2219
2220 AS_IF([test "x$enable_sulogin_emergency_mount" = xyes], [
2221   AC_DEFINE([USE_SULOGIN_EMERGENCY_MOUNT], [1],
2222             [Should sulogin use a emergency mount of /dev and /proc?])
2223 ])
2224
2225
2226 AC_ARG_ENABLE([usrdir-path],
2227   AS_HELP_STRING([--enable-usrdir-path], [use only /usr paths in PATH env. variable (recommended on systems with /bin -> /usr/bin symlinks)]),
2228   [], [enable_usrdir_path=no]
2229 )
2230
2231 AS_IF([test "x$enable_usrdir_path" == xyes], [
2232   AC_DEFINE([USE_USRDIR_PATHS_ONLY], [1], [Define to 1 to remove /bin and /sbin from PATH env.variable])
2233 ])
2234
2235
2236 AC_ARG_ENABLE([makeinstall-chown],
2237   AS_HELP_STRING([--disable-makeinstall-chown], [do not do chown-like operations during "make install"]),
2238   [], [enable_makeinstall_chown=yes]
2239 )
2240 AM_CONDITIONAL([MAKEINSTALL_DO_CHOWN], [test "x$enable_makeinstall_chown" = xyes])
2241
2242
2243 AC_ARG_ENABLE([makeinstall-setuid],
2244   AS_HELP_STRING([--disable-makeinstall-setuid], [do not do setuid chmod operations during "make install"]),
2245   [], [enable_makeinstall_setuid=yes]
2246 )
2247 AM_CONDITIONAL([MAKEINSTALL_DO_SETUID], [test "x$enable_makeinstall_setuid" = xyes])
2248
2249
2250 AC_ARG_ENABLE([colors-default],
2251   AS_HELP_STRING([--disable-colors-default], [do not colorize output from utils by default]),
2252   [], [enable_colors_default=yes]
2253 )
2254 AS_IF([test "x$enable_colors_default" = xyes], [
2255   AC_DEFINE([USE_COLORS_BY_DEFAULT], [1], [Enables colorized output from utils by default])
2256 ])
2257
2258
2259 AC_ARG_VAR([SUID_CFLAGS],
2260            [CFLAGS used for binaries which are usually with the suid bit])
2261 AC_ARG_VAR([SUID_LDFLAGS],
2262            [LDFLAGS used for binaries which are usually with the suid bit])
2263
2264 AC_ARG_VAR([DAEMON_CFLAGS],
2265            [CFLAGS used for binaries which are usually executed as daemons])
2266 AC_ARG_VAR([DAEMON_LDFLAGS],
2267            [LDFLAGS used for binaries which are usually executed as daemons])
2268
2269 AC_ARG_VAR([SOLIB_CFLAGS],
2270            [CFLAGS used for shared libraries])
2271 AC_ARG_VAR([SOLIB_LDFLAGS],
2272            [LDFLAGS used for shared libraries])
2273
2274 AC_ARG_VAR([ADJTIME_PATH],
2275            [Path to hwclock adjtime file, default /etc/adjtime])
2276 AS_IF([test "x$ADJTIME_PATH" = x], [ADJTIME_PATH="/etc/adjtime"])
2277 AC_DEFINE_UNQUOTED([CONFIG_ADJTIME_PATH], "$ADJTIME_PATH", [Path to hwclock adjtime file])
2278
2279
2280 LIBS=""
2281
2282
2283 AC_CONFIG_HEADERS([config.h])
2284
2285 #
2286 # Don't use configure.ac to replace install paths! See Makefile PATHFILES for
2287 # more details.
2288 #
2289 AC_CONFIG_FILES([
2290 Makefile
2291 libblkid/docs/Makefile
2292 libblkid/docs/version.xml
2293 libblkid/src/blkid.h
2294 libfdisk/docs/Makefile
2295 libfdisk/docs/version.xml
2296 libfdisk/src/libfdisk.h
2297 libmount/docs/Makefile
2298 libmount/docs/version.xml
2299 libmount/src/libmount.h
2300 libsmartcols/docs/Makefile
2301 libsmartcols/docs/version.xml
2302 libsmartcols/src/libsmartcols.h
2303 po/Makefile.in
2304 ])
2305
2306 AC_OUTPUT
2307
2308 AC_MSG_RESULT([
2309         ${PACKAGE}  ${VERSION}
2310
2311         prefix:            ${prefix}
2312         exec prefix:       ${exec_prefix}
2313
2314         runstatedir:       ${runstatedir}
2315         bindir:            ${bindir}
2316         sbindir:           ${sbindir}
2317         libdir:            ${libdir}
2318         includedir:        ${includedir}
2319         usrbin_execdir:    ${usrbin_execdir}
2320         usrsbin_execdir:   ${usrsbin_execdir}
2321         usrlib_execdir:    ${usrlib_execdir}
2322
2323         compiler:          ${CC}
2324         cflags:            ${CFLAGS}
2325         suid cflags:       ${SUID_CFLAGS}
2326         ldflags:           ${LDFLAGS}
2327         suid ldflags:      ${SUID_LDFLAGS}
2328
2329         Python:            ${PYTHON}
2330         Python version:    ${PYTHON_VERSION}
2331         Python libs:       ${pyexecdir}
2332
2333         Bash completions:  ${with_bashcompletiondir}
2334         Systemd support:   ${have_systemd}
2335         Btrfs support:     ${have_btrfs}
2336         Wide-char support: ${build_widechar}
2337
2338         warnings:
2339
2340 ${WARN_CFLAGS}
2341
2342         Type 'make' or 'make <utilname>' to compile.
2343 ])