configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 239 dnl -fstack-protector-strong.
 240 AC_ARG_ENABLE([stack-protector],
 241               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 242                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 243               [enable_stack_protector=$enableval],
 244               [enable_stack_protector=no])
 245 case "$enable_stack_protector" in
 246 all|yes|no|strong) ;;
 247 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 248 esac
 249
 250 dnl On some platforms we cannot use dynamic loading.  We must provide
 251 dnl static NSS modules.
 252 AC_ARG_ENABLE([static-nss],
 253               AC_HELP_STRING([--enable-static-nss],
 254                              [build static NSS modules @<:@default=no@:>@]),
 255               [static_nss=$enableval],
 256               [static_nss=no])
 257 dnl Enable static NSS also if we build no shared objects.
 258 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 259   static_nss=yes
 260   AC_DEFINE(DO_STATIC_NSS)
 261 fi
 262
 263 AC_ARG_ENABLE([force-install],
 264               AC_HELP_STRING([--disable-force-install],
 265                              [don't force installation of files from this package, even if they are older than the installed files]),
 266               [force_install=$enableval],
 267               [force_install=yes])
 268 AC_SUBST(force_install)
 269
 270 AC_ARG_ENABLE([maintainer-mode],
 271               AC_HELP_STRING([--enable-maintainer-mode],
 272                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 273               [maintainer=$enableval],
 274               [maintainer=no])
 275
 276 dnl On some platforms we allow dropping compatibility with all kernel
 277 dnl versions.
 278 AC_ARG_ENABLE([kernel],
 279               AC_HELP_STRING([--enable-kernel=VERSION],
 280                              [compile for compatibility with kernel not older than VERSION]),
 281               [minimum_kernel=$enableval],
 282               [])
 283 dnl Prevent unreasonable values.
 284 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 285   # Better nothing than this.
 286   minimum_kernel=""
 287 else
 288   if test "$minimum_kernel" = current; then
 289     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 290   fi
 291 fi
 292
 293 dnl For the development we sometimes want gcc to issue even more warnings.
 294 dnl This is not the default since many of the extra warnings are not
 295 dnl appropriate.
 296 AC_ARG_ENABLE([all-warnings],
 297               AC_HELP_STRING([--enable-all-warnings],
 298                              [enable all useful warnings gcc can issue]),
 299               [all_warnings=$enableval],
 300               [])
 301 AC_SUBST(all_warnings)
 302
 303 AC_ARG_ENABLE([werror],
 304               AC_HELP_STRING([--disable-werror],
 305                              [do not build with -Werror]),
 306               [enable_werror=$enableval],
 307               [enable_werror=yes])
 308 AC_SUBST(enable_werror)
 309
 310 AC_ARG_ENABLE([multi-arch],
 311               AC_HELP_STRING([--enable-multi-arch],
 312                              [enable single DSO with optimizations for multiple architectures]),
 313               [multi_arch=$enableval],
 314               [multi_arch=default])
 315
 316 AC_ARG_ENABLE([experimental-malloc],
 317               AC_HELP_STRING([--disable-experimental-malloc],
 318                              [disable experimental malloc features]),
 319               [experimental_malloc=$enableval],
 320               [experimental_malloc=yes])
 321 AC_SUBST(experimental_malloc)
 322
 323 AC_ARG_ENABLE([nss-crypt],
 324               AC_HELP_STRING([--enable-nss-crypt],
 325                              [enable libcrypt to use nss]),
 326               [nss_crypt=$enableval],
 327               [nss_crypt=no])
 328 if test x$nss_crypt = xyes; then
 329   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 330   if test $? -ne 0; then
 331     AC_MSG_ERROR([cannot find include directory with nss-config])
 332   fi
 333   old_CFLAGS="$CFLAGS"
 334   CFLAGS="$CFLAGS $nss_includes"
 335   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 336 #include <hasht.h>
 337 #include <nsslowhash.h>
 338 void f (void) { NSSLOW_Init (); }])],
 339              libc_cv_nss_crypt=yes,
 340              AC_MSG_ERROR([
 341 cannot find NSS headers with lowlevel hash function interfaces]))
 342   old_LIBS="$LIBS"
 343   old_LDFLAGS="$LDFLAGS"
 344   LIBS="$LIBS -lfreebl3"
 345   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 346 #include <hasht.h>
 347 #include <nsslowhash.h>],
 348                                   [NSSLOW_Init();])],
 349                  libc_cv_nss_crypt=yes,
 350                  AC_MSG_ERROR([
 351 cannot link program using lowlevel NSS hash functions]))
 352   # Check to see if there is a static NSS cryptographic library.
 353   # If there isn't then we can't link anything with libcrypt.a,
 354   # and that might mean disabling some static tests.
 355   LDFLAGS="$LDFLAGS -static"
 356   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 357 #include <hasht.h>
 358 #include <nsslowhash.h>],
 359                                   [NSSLOW_Init();])],
 360                  libc_cv_static_nss_crypt=yes,
 361                  libc_cv_static_nss_crypt=no)
 362   LDFLAGS="$old_LDFLAGS"
 363   CFLAGS="$old_CFLAGS"
 364   LIBS="$old_LIBS"
 365 else
 366   libc_cv_nss_crypt=no
 367   libc_cv_static_nss_crypt=no
 368 fi
 369 AC_SUBST(libc_cv_nss_crypt)
 370 AC_SUBST(libc_cv_static_nss_crypt)
 371
 372
 373 AC_ARG_ENABLE([obsolete-rpc],
 374               AC_HELP_STRING([--enable-obsolete-rpc],
 375                              [build and install the obsolete RPC code for link-time usage]),
 376               [link_obsolete_rpc=$enableval],
 377               [link_obsolete_rpc=no])
 378 AC_SUBST(link_obsolete_rpc)
 379
 380 if test "$link_obsolete_rpc" = yes; then
 381   AC_DEFINE(LINK_OBSOLETE_RPC)
 382 fi
 383
 384 AC_ARG_ENABLE([obsolete-nsl],
 385               AC_HELP_STRING([--enable-obsolete-nsl],
 386                              [build and install the obsolete libnsl library and depending NSS modules]),
 387               [build_obsolete_nsl=$enableval],
 388               [build_obsolete_nsl=no])
 389 AC_SUBST(build_obsolete_nsl)
 390
 391 if test "$build_obsolete_nsl" = yes; then
 392   AC_DEFINE(LINK_OBSOLETE_NSL)
 393 fi
 394
 395 AC_ARG_ENABLE([systemtap],
 396               [AS_HELP_STRING([--enable-systemtap],
 397                [enable systemtap static probe points @<:@default=no@:>@])],
 398               [systemtap=$enableval],
 399               [systemtap=no])
 400 if test "x$systemtap" != xno; then
 401   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 402   old_CFLAGS="$CFLAGS"
 403   CFLAGS="-std=gnu11 $CFLAGS"
 404   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 405 void foo (int i, void *p)
 406 {
 407   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 408        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 409 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 410   CFLAGS="$old_CFLAGS"])
 411   if test $libc_cv_sdt = yes; then
 412     AC_DEFINE([USE_STAP_PROBE])
 413   elif test "x$systemtap" != xauto; then
 414     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 415   fi
 416 fi
 417
 418 AC_ARG_ENABLE([build-nscd],
 419               [AS_HELP_STRING([--disable-build-nscd],
 420                [disable building and installing the nscd daemon])],
 421               [build_nscd=$enableval],
 422               [build_nscd=default])
 423 AC_SUBST(build_nscd)
 424
 425 # Note the use of $use_nscd is near the bottom of the file.
 426 AC_ARG_ENABLE([nscd],
 427               [AS_HELP_STRING([--disable-nscd],
 428                [library functions will not contact the nscd daemon])],
 429               [use_nscd=$enableval],
 430               [use_nscd=yes])
 431
 432 AC_ARG_ENABLE([pt_chown],
 433               [AS_HELP_STRING([--enable-pt_chown],
 434                [Enable building and installing pt_chown])],
 435               [build_pt_chown=$enableval],
 436               [build_pt_chown=no])
 437 AC_SUBST(build_pt_chown)
 438 if test "$build_pt_chown" = yes; then
 439   AC_DEFINE(HAVE_PT_CHOWN)
 440 fi
 441
 442 AC_ARG_ENABLE([tunables],
 443               [AS_HELP_STRING([--enable-tunables],
 444                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 445               [have_tunables=$enableval],
 446               [have_tunables=yes])
 447 AC_SUBST(have_tunables)
 448 if test "$have_tunables" = yes; then
 449   AC_DEFINE(HAVE_TUNABLES)
 450 fi
 451
 452 # The abi-tags file uses a fairly simplistic model for name recognition that
 453 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 454 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 455 # This doesn't get used much beyond that, so it's fairly safe.
 456 case "$host_os" in
 457 linux*)
 458   ;;
 459 gnu*)
 460   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 461   ;;
 462 esac
 463
 464 AC_ARG_ENABLE([mathvec],
 465               [AS_HELP_STRING([--enable-mathvec],
 466               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 467               [build_mathvec=$enableval],
 468               [build_mathvec=notset])
 469
 470 # We keep the original values in `$config_*' and never modify them, so we
 471 # can write them unchanged into config.make.  Everything else uses
 472 # $machine, $vendor, and $os, and changes them whenever convenient.
 473 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 474
 475 # Don't allow vendor == "unknown"
 476 test "$config_vendor" = unknown && config_vendor=
 477 config_os="`echo $config_os | sed 's/^unknown-//'`"
 478
 479 # Some configurations imply other options.
 480 elf=yes
 481
 482 # The configure fragment of an add-on port can modify these to supplement
 483 # or override the table in the case statement below.  No fragment should
 484 # ever change the config_* variables, however.
 485 machine=$config_machine
 486 vendor=$config_vendor
 487 os=$config_os
 488 base_os=''
 489
 490 submachine=
 491 AC_ARG_WITH([cpu],
 492             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 493             [dnl
 494   case "$withval" in
 495   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 496   no) ;;
 497   *) submachine="$withval" ;;
 498   esac
 499 ])
 500
 501 # An preconfigure script can set this when it wants to disable the sanity
 502 # check below.
 503 libc_config_ok=no
 504
 505 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 506 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 507
 508 dnl Having this here, though empty, makes sure that if add-ons' fragments
 509 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 510 dnl our AC_OUTPUT will actually use it.
 511 AC_CONFIG_SUBDIRS()
 512
 513 case "$enable_add_ons" in
 514 ''|no) add_ons= ;;
 515 yes|'*')
 516  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 517           sed 's@/[[^/]]*$@@' | sort | uniq`
 518          add_ons_automatic=yes
 519          ;;
 520 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 521        add_ons_automatic=no ;;
 522 esac
 523
 524 configured_add_ons=
 525 add_ons_sfx=
 526 add_ons_pfx=
 527 if test x"$add_ons" != x; then
 528   for f in $add_ons; do
 529     # Some sanity checks
 530     case "$f" in
 531     crypt)
 532       AC_MSG_ERROR([
 533 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 534 *** part of glibc and using the old add-on will not work with this
 535 *** release.  Start again with fresh sources and without the old
 536 *** \`crypt' add-on.])
 537     ;;
 538     localedata)
 539       AC_MSG_ERROR([
 540 *** It seems that you're using an old \`localedata' add-on.  localedata
 541 *** is now part of glibc and using the old add-on will not work with
 542 *** this release.  Start again with fresh sources and without the old
 543 *** \`localedata' add-on.])
 544     ;;
 545     esac
 546   done
 547
 548   # Now source each add-on's configure fragment.
 549   # The fragments can use $srcdir/$libc_add_on to find themselves,
 550   # and test $add_ons_automatic to see if they were explicitly requested.
 551   # A fragment can clear (or even change) $libc_add_on to affect
 552   # whether it goes into the list to be actually used in the build.
 553   use_add_ons=
 554   for libc_add_on in $add_ons; do
 555     # Test whether such a directory really exists.
 556     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 557     case "$libc_add_on" in
 558     /*)
 559       libc_add_on_srcdir=$libc_add_on
 560       ;;
 561     *)
 562       test -d "$srcdir/$libc_add_on" || {
 563         if test -d "$libc_add_on"; then
 564           libc_add_on="`pwd`/$libc_add_on"
 565         else
 566           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 567         fi
 568       }
 569       libc_add_on_srcdir=$srcdir/$libc_add_on
 570       ;;
 571     esac
 572
 573     libc_add_on_frag=$libc_add_on_srcdir/configure
 574     libc_add_on_canonical=
 575     libc_add_on_config_subdirs=
 576     if test -r "$libc_add_on_frag"; then
 577       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 578       libc_add_on_canonical=unknown
 579       libc_add_on_subdirs=
 580       . "$libc_add_on_frag"
 581       test -z "$libc_add_on" || {
 582         configured_add_ons="$configured_add_ons $libc_add_on"
 583         if test "x$libc_add_on_canonical" = xunknown; then
 584           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 585         fi
 586         for d in $libc_add_on_subdirs; do
 587           case "$libc_add_on" in
 588           /*) subdir_srcdir="$libc_add_on" ;;
 589           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 590           esac
 591           case "$d" in
 592           .)
 593             d="${libc_add_on_canonical:-$libc_add_on}"
 594             ;;
 595           /*)
 596             subdir_srcdir="$d"
 597             ;;
 598           *)
 599             subdir_srcdir="$subdir_srcdir/$d"
 600             ;;
 601           esac
 602           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 603           add_on_subdirs="$add_on_subdirs $d"
 604           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 605 $d-srcdir = $subdir_srcdir"
 606         done
 607         for d in $libc_add_on_config_subdirs; do
 608           case "$d" in
 609           /*) AC_MSG_ERROR(dnl
 610 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 611           esac
 612           if test ! -d "$libc_add_on_srcdir/$d"; then
 613             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 614           fi
 615           case "$libc_add_on" in
 616           /*) AC_MSG_ERROR(dnl
 617 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 618           esac
 619           subdirs="$subdirs $libc_add_on/$d"
 620         done
 621       }
 622     fi
 623     if test -n "$libc_add_on"; then
 624       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 625       use_add_ons="$use_add_ons $libc_add_on"
 626       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 627       test -z "$libc_add_on_canonical" ||
 628       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 629     fi
 630   done
 631   # Use echo to strip excess whitespace.
 632   add_ons="`echo $use_add_ons`"
 633 fi
 634 AC_SUBST(add_ons)
 635 AC_SUBST(add_on_subdirs)
 636
 637
 638 ###
 639 ### By using the undocumented --enable-hacker-mode option for configure
 640 ### one can skip this test to make the configuration not fail for unsupported
 641 ### platforms.
 642 ###
 643 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 644   case "$machine-$host_os" in
 645   *-linux* | *-gnu*)
 646     ;;
 647   *)
 648     AC_MSG_ERROR([
 649 *** The GNU C library is currently unavailable for this platform.
 650 *** If you are interested in seeing glibc on this platform visit
 651 *** the "How to submit a new port" in the wiki:
 652 ***   https://sourceware.org/glibc/wiki/#Development
 653 *** and join the community!])
 654     ;;
 655   esac
 656 fi
 657
 658 # Set base_machine if not set by a preconfigure fragment.
 659 test -n "$base_machine" || base_machine=$machine
 660 AC_SUBST(base_machine)
 661
 662 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 663 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 664                    [libc_cv_ssp=yes],
 665                    [libc_cv_ssp=no])
 666 ])
 667
 668 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 669 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 670                    [libc_cv_ssp_strong=yes],
 671                    [libc_cv_ssp_strong=no])
 672 ])
 673
 674 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 675 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 676                    [libc_cv_ssp_all=yes],
 677                    [libc_cv_ssp_all=no])
 678 ])
 679
 680 stack_protector=
 681 no_stack_protector=
 682 if test "$libc_cv_ssp" = yes; then
 683   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 684   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 685 fi
 686
 687 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 688   stack_protector="-fstack-protector"
 689   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 690 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 691   stack_protector="-fstack-protector-all"
 692   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 693 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 694   stack_protector="-fstack-protector-strong"
 695   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 696 else
 697   stack_protector="-fno-stack-protector"
 698   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 699 fi
 700 AC_SUBST(libc_cv_ssp)
 701 AC_SUBST(stack_protector)
 702 AC_SUBST(no_stack_protector)
 703
 704 if test -n "$stack_protector"; then
 705   dnl Don't run configure tests with stack-protection on, to avoid problems with
 706   dnl bootstrapping.
 707   no_ssp=-fno-stack-protector
 708 else
 709   no_ssp=
 710
 711   if test "$enable_stack_protector" != no; then
 712     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 713   fi
 714 fi
 715
 716 # For the multi-arch option we need support in the assembler & linker.
 717 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 718                libc_cv_ld_gnu_indirect_function, [dnl
 719 cat > conftest.S <<EOF
 720 .type foo,%gnu_indirect_function
 721 foo:
 722 .globl _start
 723 _start:
 724 .globl __start
 725 __start:
 726 .data
 727 #ifdef _LP64
 728 .quad foo
 729 #else
 730 .long foo
 731 #endif
 732 EOF
 733 libc_cv_ld_gnu_indirect_function=no
 734 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 735             -nostartfiles -nostdlib $no_ssp \
 736             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 737   # Do a link to see if the backend supports IFUNC relocs.
 738   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 739   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 740     libc_cv_ld_gnu_indirect_function=yes
 741   }
 742 fi
 743 rm -f conftest*])
 744
 745 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 746 AC_CACHE_CHECK([for gcc attribute ifunc support],
 747                libc_cv_gcc_indirect_function, [dnl
 748 cat > conftest.c <<EOF
 749 extern int func (int);
 750 int used_func (int a)
 751 {
 752   return a;
 753 }
 754 static void *resolver ()
 755 {
 756   return &used_func;
 757 }
 758 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 759 EOF
 760 libc_cv_gcc_indirect_function=no
 761 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 762    2>&AS_MESSAGE_LOG_FD ; then
 763   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 764     libc_cv_gcc_indirect_function=yes
 765   fi
 766 fi
 767 rm -f conftest*])
 768
 769 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 770   if test x"$multi_arch" = xyes; then
 771     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 772   else
 773     multi_arch=no
 774   fi
 775 fi
 776 if test x"$libc_cv_gcc_indirect_function" != xyes &&
 777    test x"$multi_arch" = xyes; then
 778   AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 779 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 780 fi
 781 multi_arch_d=
 782 if test x"$multi_arch" != xno; then
 783   multi_arch_d=/multiarch
 784 fi
 785
 786 # Compute the list of sysdep directories for this configuration.
 787 # This can take a while to compute.
 788 sysdep_dir=$srcdir/sysdeps
 789 AC_MSG_CHECKING(sysdep dirs)
 790 dnl We need to use [ and ] for other purposes for a while now.
 791 changequote(,)dnl
 792 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 793 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 794
 795 test "x$base_os" != x || case "$os" in
 796 gnu*)
 797   base_os=mach/hurd ;;
 798 linux*)
 799   base_os=unix/sysv ;;
 800 esac
 801
 802 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 803 tail=$os
 804 ostry=$os
 805 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 806   ostry="$ostry /$o"
 807   tail=$o
 808 done
 809 o=`echo $tail | sed 's/[0-9]*$//'`
 810 if test $o != $tail; then
 811   ostry="$ostry /$o"
 812 fi
 813 # For linux-gnu, try linux-gnu, then linux.
 814 o=`echo $tail | sed 's/-.*$//'`
 815 if test $o != $tail; then
 816   ostry="$ostry /$o"
 817 fi
 818
 819 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 820 base=
 821 tail=$base_os
 822 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 823   set $b
 824   base="$base /$1"
 825   tail="$2"
 826 done
 827
 828 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 829 mach=
 830 tail=$machine${submachine:+/$submachine}
 831 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 832   set $m
 833   # Prepend the machine's FPU directory unless --without-fp.
 834   if test "$with_fp" = yes; then
 835     maybe_fpu=/fpu
 836   else
 837     maybe_fpu=/nofpu
 838   fi
 839   # For each machine term, try it with and then without /multiarch.
 840   for try_fpu in $maybe_fpu ''; do
 841     for try_multi in $multi_arch_d ''; do
 842       mach="$mach /$1$try_fpu$try_multi"
 843     done
 844   done
 845   tail="$2"
 846 done
 847
 848 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 849 changequote([,])dnl
 850
 851 # Find what sysdep directories exist.
 852 sysnames_add_ons=
 853 sysnames=
 854 for b in $base ''; do
 855   for m0 in $mach ''; do
 856     for v in /$vendor ''; do
 857       test "$v" = / && continue
 858       for o in /$ostry ''; do
 859         test "$o" = / && continue
 860         for m in $mach ''; do
 861           for d in $add_ons_pfx ''; do
 862             for a in $add_ons_sfx ''; do
 863               try_suffix="$m0$b$v$o$m"
 864               if test -n "$try_suffix"; then
 865                 try_srcdir="${srcdir}/"
 866                 case "$d" in
 867                 /*) try_srcdir= ;;
 868                 esac
 869                 try="${d}sysdeps$try_suffix$a"
 870                 test -n "$enable_debug_configure" &&
 871                 echo "$0 [DEBUG]: try $try" >&2
 872                 if test -d "$try_srcdir$try"; then
 873                   sysnames="$sysnames $try"
 874                   { test -n "$o" || test -n "$b"; } && os_used=t
 875                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 876                   case x${m0:-$m} in
 877                   x*/$submachine) submachine_used=t ;;
 878                   esac
 879                   if test -n "$d"; then
 880                     case "$sysnames_add_ons" in
 881                     *" $d "*) ;;
 882                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 883                     esac
 884                   fi
 885                 fi
 886               fi
 887             done
 888           done
 889         done
 890       done
 891     done
 892   done
 893 done
 894
 895 # If the assembler supports gnu_indirect_function symbol type and the
 896 # architecture supports multi-arch, we enable multi-arch by default.
 897 case $sysnames_add_ons$sysnames in
 898 *"$multi_arch_d"*)
 899   ;;
 900 *)
 901   test x"$multi_arch" = xdefault && multi_arch=no
 902   ;;
 903 esac
 904 if test x"$multi_arch" != xno; then
 905   AC_DEFINE(USE_MULTIARCH)
 906 fi
 907 AC_SUBST(multi_arch)
 908
 909 if test -z "$os_used" && test "$os" != none; then
 910   AC_MSG_ERROR(Operating system $os is not supported.)
 911 fi
 912 if test -z "$machine_used" && test "$machine" != none; then
 913   AC_MSG_ERROR(The $machine is not supported.)
 914 fi
 915 if test -z "$submachine_used" && test -n "$submachine"; then
 916   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 917 fi
 918 AC_SUBST(submachine)
 919
 920 # We have now validated the configuration.
 921
 922 # Expand the list of system names into a full list of directories
 923 # from each element's parent name and Implies file (if present).
 924 set $sysnames
 925 names=
 926 while test $# -gt 0; do
 927   name=$1
 928   shift
 929
 930   case " $names " in *" $name "*)
 931     # Already in the list.
 932     continue
 933   esac
 934
 935   # Report each name as we discover it, so there is no long pause in output.
 936   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 937
 938   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 939
 940   case $name in
 941     /*) xsrcdir= ;;
 942     *)  xsrcdir=$srcdir/ ;;
 943   esac
 944   test -n "$enable_debug_configure" &&
 945   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 946
 947   for implies_file in Implies Implies-before Implies-after; do
 948     implies_type=`echo $implies_file | sed s/-/_/`
 949     eval ${implies_type}=
 950     if test -f $xsrcdir$name/$implies_file; then
 951       # Collect more names from the `Implies' file (removing comments).
 952       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 953       for x in $implied_candidate; do
 954         found=no
 955         if test -d $xsrcdir$name_base/$x; then
 956           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 957           found=yes
 958         fi
 959         for d in $add_ons_pfx ''; do
 960           try="${d}sysdeps/$x"
 961           case $d in
 962            /*) try_srcdir= ;;
 963            *) try_srcdir=$srcdir/ ;;
 964           esac
 965           test -n "$enable_debug_configure" &&
 966            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 967           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 968           then
 969             eval "${implies_type}=\"\$${implies_type} \$try\""
 970             found=yes
 971             case "$sysnames_add_ons" in
 972             *" $d "*) ;;
 973             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 974             esac
 975           fi
 976         done
 977         if test $found = no; then
 978           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 979         fi
 980       done
 981     fi
 982   done
 983
 984   # Add NAME to the list of names.
 985   names="$names $name"
 986
 987   # Find the parent of NAME, using the empty string if it has none.
 988 changequote(,)dnl
 989   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 990 changequote([,])dnl
 991
 992   test -n "$enable_debug_configure" &&
 993     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 994 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 995
 996   # Add the names implied by NAME, and NAME's parent (if it has one), to
 997   # the list of names to be processed (the argument list).  We prepend the
 998   # implied names to the list and append the parent.  We want implied
 999   # directories to come before further directories inferred from the
1000   # configuration components; this ensures that for sysv4, unix/common
1001   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
1002   # after sysv4).
1003   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
1004   test -n "$sysnames" && set $sysnames
1005 done
1006
1007 # Add the default directories.
1008 default_sysnames="sysdeps/generic"
1009 sysnames="$names $default_sysnames"
1010 AC_SUBST(sysnames)
1011 # The other names were emitted during the scan.
1012 AC_MSG_RESULT($default_sysnames)
1013
1014 # Collect the list of add-ons that supply partial sysdeps trees.
1015 sysdeps_add_ons=
1016 for add_on in $add_ons; do
1017   case "$add_on" in
1018   /*) xsrcdir= ;;
1019   *) xsrcdir="$srcdir/" ;;
1020   esac
1021
1022   test -d "$xsrcdir$add_on/sysdeps" || {
1023     case "$configured_add_ons " in
1024     *" $add_on "*) ;;
1025     *|'')
1026       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
1027       ;;
1028     esac
1029     continue
1030   }
1031
1032   sysdeps_add_ons="$sysdeps_add_ons $add_on"
1033   case "$sysnames_add_ons" in
1034   *" $add_on/ "*) ;;
1035   *|'')
1036     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
1037     continue ;;
1038   esac
1039
1040   found=no
1041   for d in $sysnames; do
1042     case "$d" in
1043     $add_on/sysdeps/*) ;;
1044     *) continue ;;
1045     esac
1046     (cd "$xsrcdir$d" && for f in *[[!~]]; do
1047        case "$f" in
1048        sys|bits)
1049          for ff in $f/*.h; do
1050            test -d "$ff" || { test -e "$ff" && exit 88; }
1051          done
1052          ;;
1053        *)
1054          test -d "$f" || { test -e "$f" && exit 88; }
1055          ;;
1056        esac
1057      done)
1058     if test $? -eq 88; then
1059       found=yes
1060       break
1061     fi
1062   done
1063   if test $found = no; then
1064     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
1065   fi
1066 done
1067 AC_SUBST(sysdeps_add_ons)
1068
1069
1070 ### Locate tools.
1071
1072 AC_PROG_INSTALL
1073 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
1074   # The makefiles need to use a different form to find it in $srcdir.
1075   INSTALL='\$(..)./scripts/install-sh -c'
1076 fi
1077 AC_PROG_LN_S
1078
1079 LIBC_PROG_BINUTILS
1080
1081 # Accept binutils 2.22 or newer.
1082 AC_CHECK_PROG_VER(AS, $AS, --version,
1083                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
1084                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1085                   AS=: critic_missing="$critic_missing as")
1086
1087 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
1088   # Accept gold 1.14 or higher
1089   AC_CHECK_PROG_VER(LD, $LD, --version,
1090                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
1091                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
1092                     LD=: critic_missing="$critic_missing GNU gold")
1093 else
1094   AC_CHECK_PROG_VER(LD, $LD, --version,
1095                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1096                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1097                     LD=: critic_missing="$critic_missing GNU ld")
1098 fi
1099
1100 # These programs are version sensitive.
1101 AC_CHECK_TOOL_PREFIX
1102 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1103   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1104   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1105
1106 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1107   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1108   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1109   MSGFMT=: aux_missing="$aux_missing msgfmt")
1110 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1111   [GNU texinfo.* \([0-9][0-9.]*\)],
1112   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1113   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1114 AC_CHECK_PROG_VER(SED, sed, --version,
1115   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1116   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1117   SED=: aux_missing="$aux_missing sed")
1118 AC_CHECK_PROG_VER(AWK, gawk, --version,
1119   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1120   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1121
1122 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1123 AC_TRY_COMPILE([], [
1124 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
1125 #error insufficient compiler
1126 #endif],
1127                [libc_cv_compiler_ok=yes],
1128                [libc_cv_compiler_ok=no])])
1129 AS_IF([test $libc_cv_compiler_ok != yes],
1130       [critic_missing="$critic_missing compiler"])
1131
1132 AC_CHECK_TOOL(NM, nm, false)
1133
1134 if test "x$maintainer" = "xyes"; then
1135   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1136   case "x$AUTOCONF" in
1137   xno|x|x:) AUTOCONF=no ;;
1138   *)
1139     AC_CACHE_CHECK(dnl
1140   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1141     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1142       libc_cv_autoconf_works=yes
1143     else
1144       libc_cv_autoconf_works=no
1145     fi])
1146     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1147     ;;
1148   esac
1149   if test "x$AUTOCONF" = xno; then
1150     aux_missing="$aux_missing autoconf"
1151   fi
1152 else
1153   AUTOCONF=no
1154 fi
1155
1156 # Check for python3 if available, or else python.
1157 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1158 case "x$PYTHON_PROG" in
1159 xno|x|x:) PYTHON_PROG=no ;;
1160 *) ;;
1161 esac
1162
1163 if test "x$PYTHON_PROG" = xno; then
1164   aux_missing="$aux_missing python"
1165 else
1166   PYTHON="$PYTHON_PROG -B"
1167   AC_SUBST(PYTHON)
1168 fi
1169
1170 test -n "$critic_missing" && AC_MSG_ERROR([
1171 *** These critical programs are missing or too old:$critic_missing
1172 *** Check the INSTALL file for required versions.])
1173
1174 test -n "$aux_missing" && AC_MSG_WARN([
1175 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1176 *** some features or tests will be disabled.
1177 *** Check the INSTALL file for required versions.])
1178
1179 # if using special system headers, find out the compiler's sekrit
1180 # header directory and add that to the list.  NOTE: Only does the right
1181 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1182 if test -n "$sysheaders"; then
1183   SYSINCLUDES=-nostdinc
1184   for d in include include-fixed; do
1185     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1186     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1187   done
1188   SYSINCLUDES="$SYSINCLUDES \
1189 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1190   if test -n "$CXX"; then
1191     CXX_SYSINCLUDES=
1192     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1193     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1194       test "x$cxxheaders" != x &&
1195       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1196     done
1197   fi
1198 fi
1199 AC_SUBST(SYSINCLUDES)
1200 AC_SUBST(CXX_SYSINCLUDES)
1201
1202 # Obtain some C++ header file paths.  This is used to make a local
1203 # copy of those headers in Makerules.
1204 if test -n "$CXX"; then
1205   find_cxx_header () {
1206     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1207          | sed -n "\,$1:,{s/:\$//;p}"
1208   }
1209   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1210   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1211   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1212 fi
1213 AC_SUBST(CXX_CSTDLIB_HEADER)
1214 AC_SUBST(CXX_CMATH_HEADER)
1215 AC_SUBST(CXX_BITS_STD_ABS_H)
1216
1217 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1218 # since this would lead to problems installing/building glibc.
1219 # LD_LIBRARY_PATH contains the current directory if one of the following
1220 # is true:
1221 # - one of the terminals (":" and ";") is the first or last sign
1222 # - two terminals occur directly after each other
1223 # - the path contains an element with a dot in it
1224 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1225 changequote(,)dnl
1226 case ${LD_LIBRARY_PATH} in
1227   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1228     ld_library_path_setting="contains current directory"
1229     ;;
1230   *)
1231     ld_library_path_setting="ok"
1232     ;;
1233 esac
1234 changequote([,])dnl
1235 AC_MSG_RESULT($ld_library_path_setting)
1236 if test "$ld_library_path_setting" != "ok"; then
1237 AC_MSG_ERROR([
1238 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1239 *** building glibc. Please change the environment variable
1240 *** and run configure again.])
1241 fi
1242
1243 AC_PATH_PROG(BASH_SHELL, bash, no)
1244
1245 AC_PATH_PROG(PERL, perl, no)
1246 if test "$PERL" != no &&
1247    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1248   PERL=no
1249 fi
1250 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1251              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1252 AC_CHECK_PROG_VER(BISON, bison, --version,
1253                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1254                   [2.7*|[3-9].*|[1-9][0-9]*],
1255                   BISON=no)
1256
1257 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1258 cat > conftest.s <<EOF
1259 .text
1260 foo:
1261 .set glibc_conftest_frobozz,foo
1262 .globl glibc_conftest_frobozz
1263 EOF
1264 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1265 # (but it doesn't work), so we must do a linking check to be sure.
1266 cat > conftest1.c <<\EOF
1267 extern int glibc_conftest_frobozz;
1268 void _start() { glibc_conftest_frobozz = 1; }
1269 EOF
1270 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1271             -nostartfiles -nostdlib $no_ssp \
1272             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1273   libc_cv_asm_set_directive=yes
1274 else
1275   libc_cv_asm_set_directive=no
1276 fi
1277 rm -f conftest*])
1278 if test $libc_cv_asm_set_directive = yes; then
1279   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1280 fi
1281
1282 AC_CACHE_CHECK(linker support for protected data symbol,
1283                libc_cv_protected_data,
1284                [cat > conftest.c <<EOF
1285                 int bar __attribute__ ((visibility ("protected"))) = 1;
1286 EOF
1287                 libc_cv_protected_data=no
1288                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1289                   cat > conftest.c <<EOF
1290                   extern int bar;
1291                   int main (void) { return bar; }
1292 EOF
1293                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1294                     libc_cv_protected_data=yes
1295                   fi
1296                 fi
1297                 rm -f conftest.*
1298                ])
1299 AC_SUBST(libc_cv_protected_data)
1300
1301 AC_CACHE_CHECK(for broken __attribute__((alias())),
1302                libc_cv_broken_alias_attribute,
1303                [cat > conftest.c <<EOF
1304                extern int foo (int x) __asm ("xyzzy");
1305                int bar (int x) { return x; }
1306                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1307                extern int dfoo;
1308                extern __typeof (dfoo) dfoo __asm ("abccb");
1309                int dfoo = 1;
1310 EOF
1311                libc_cv_broken_alias_attribute=yes
1312                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1313                  if grep 'xyzzy' conftest.s >/dev/null &&
1314                     grep 'abccb' conftest.s >/dev/null; then
1315                    libc_cv_broken_alias_attribute=no
1316                  fi
1317                fi
1318                rm -f conftest.c conftest.s
1319                ])
1320 if test $libc_cv_broken_alias_attribute = yes; then
1321   AC_MSG_ERROR(working alias attribute support required)
1322 fi
1323
1324 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1325                libc_cv_have_sdata_section,
1326                [echo "int i;" > conftest.c
1327                 libc_cv_have_sdata_section=no
1328                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1329                    | grep '\.sdata' >/dev/null; then
1330                   libc_cv_have_sdata_section=yes
1331                 fi
1332                 rm -f conftest.c conftest.so
1333                ])
1334 if test $libc_cv_have_sdata_section = yes; then
1335   AC_DEFINE(HAVE_SDATA_SECTION)
1336 fi
1337
1338 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1339                libc_cv_ctors_header, [dnl
1340   libc_cv_ctors_header=yes
1341   LIBC_TRY_LINK_STATIC([
1342 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1343 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1344 ],
1345               [dnl
1346       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1347         { gsub(/\@<:@ */, "@<:@") }
1348         $2 == ".ctors" || $2 == ".dtors" {
1349           size = strtonum("0x" $6)
1350           align = strtonum("0x" $NF)
1351           seen@<:@$2@:>@ = 1
1352           stub@<:@$2@:>@ = size == align * 2
1353         }
1354         END {
1355           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1356           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1357           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1358         }
1359       '], [libc_cv_ctors_header=no])
1360     ], [dnl
1361       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1362     ])
1363 ])
1364 if test $libc_cv_ctors_header = no; then
1365   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1366 fi
1367
1368 AC_CACHE_CHECK(for libunwind-support in compiler,
1369                libc_cv_cc_with_libunwind, [
1370   cat > conftest.c <<EOF
1371 int main (void) { return 0; }
1372 EOF
1373   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1374      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1375     libc_cv_cc_with_libunwind=yes
1376   else
1377     libc_cv_cc_with_libunwind=no
1378   fi
1379   rm -f conftest*])
1380 AC_SUBST(libc_cv_cc_with_libunwind)
1381 if test $libc_cv_cc_with_libunwind = yes; then
1382   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1383 fi
1384
1385 ASFLAGS_config=
1386 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1387                libc_cv_as_noexecstack, [dnl
1388 cat > conftest.c <<EOF
1389 void foo (void) { }
1390 EOF
1391 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1392                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1393    && grep .note.GNU-stack conftest.s >/dev/null \
1394    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1395                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1396 then
1397   libc_cv_as_noexecstack=yes
1398 else
1399   libc_cv_as_noexecstack=no
1400 fi
1401 rm -f conftest*])
1402 if test $libc_cv_as_noexecstack = yes; then
1403   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1404 fi
1405 AC_SUBST(ASFLAGS_config)
1406
1407 AC_CACHE_CHECK(for -z combreloc,
1408                libc_cv_z_combreloc, [dnl
1409 cat > conftest.c <<EOF
1410 extern int bar (int);
1411 extern int mumble;
1412 int foo (void) { return bar (mumble); }
1413 EOF
1414 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1415                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1416                         -nostdlib -nostartfiles
1417                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1418 then
1419 dnl The following test is a bit weak.  We must use a tool which can test
1420 dnl cross-platform since the gcc used can be a cross compiler.  Without
1421 dnl introducing new options this is not easily doable.  Instead use a tool
1422 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1423 dnl look for a section named .rel.dyn or .rela.dyn.
1424   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1425     libc_cv_z_combreloc=yes
1426   else
1427     libc_cv_z_combreloc=no
1428   fi
1429 else
1430   libc_cv_z_combreloc=no
1431 fi
1432 rm -f conftest*])
1433 if test "$libc_cv_z_combreloc" = yes; then
1434   AC_DEFINE(HAVE_Z_COMBRELOC)
1435 fi
1436 AC_SUBST(libc_cv_z_combreloc)
1437
1438 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1439                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1440 AC_SUBST(libc_cv_z_execstack)
1441
1442 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1443 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1444 ])
1445
1446 AC_SUBST(libc_cv_fpie)
1447
1448 AC_CACHE_CHECK(for --hash-style option,
1449                libc_cv_hashstyle, [dnl
1450 cat > conftest.c <<EOF
1451 int _start (void) { return 42; }
1452 EOF
1453 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1454                             -fPIC -shared -o conftest.so conftest.c
1455                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1456 then
1457   libc_cv_hashstyle=yes
1458 else
1459   libc_cv_hashstyle=no
1460 fi
1461 rm -f conftest*])
1462 AC_SUBST(libc_cv_hashstyle)
1463
1464 # The linker's default -shared behavior is good enough if it
1465 # does these things that our custom linker scripts ensure that
1466 # all allocated NOTE sections come first.
1467 if test "$use_default_link" = default; then
1468   AC_CACHE_CHECK([for sufficient default -shared layout],
1469                   libc_cv_use_default_link, [dnl
1470   libc_cv_use_default_link=no
1471   cat > conftest.s <<\EOF
1472           .section .note.a,"a",%note
1473           .balign 4
1474           .long 4,4,9
1475           .string "GNU"
1476           .string "foo"
1477           .section .note.b,"a",%note
1478           .balign 4
1479           .long 4,4,9
1480           .string "GNU"
1481           .string "bar"
1482 EOF
1483   if AC_TRY_COMMAND([dnl
1484   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1485        ac_try=`$READELF -S conftest.so | sed -n \
1486          ['${x;p;}
1487           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1488           t a
1489           b
1490           : a
1491           H']`
1492   then
1493     libc_seen_a=no libc_seen_b=no
1494     set -- $ac_try
1495     while test $# -ge 2 -a "$1" = NOTE; do
1496       case "$2" in
1497       .note.a) libc_seen_a=yes ;;
1498       .note.b) libc_seen_b=yes ;;
1499       esac
1500       shift 2
1501     done
1502     case "$libc_seen_a$libc_seen_b" in
1503     yesyes)
1504       libc_cv_use_default_link=yes
1505       ;;
1506     *)
1507       echo >&AS_MESSAGE_LOG_FD "\
1508 $libc_seen_a$libc_seen_b from:
1509 $ac_try"
1510       ;;
1511     esac
1512   fi
1513   rm -f conftest*])
1514   use_default_link=$libc_cv_use_default_link
1515 fi
1516
1517 AC_CACHE_CHECK(for GLOB_DAT reloc,
1518                libc_cv_has_glob_dat, [dnl
1519 cat > conftest.c <<EOF
1520 extern int mumble;
1521 int foo (void) { return mumble; }
1522 EOF
1523 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1524                         -fPIC -shared -o conftest.so conftest.c
1525                         -nostdlib -nostartfiles $no_ssp
1526                         1>&AS_MESSAGE_LOG_FD])
1527 then
1528 dnl look for GLOB_DAT relocation.
1529   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1530     libc_cv_has_glob_dat=yes
1531   else
1532     libc_cv_has_glob_dat=no
1533   fi
1534 else
1535   libc_cv_has_glob_dat=no
1536 fi
1537 rm -f conftest*])
1538 AC_SUBST(libc_cv_has_glob_dat)
1539
1540 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1541 if libc_cv_output_format=`
1542 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1543 then
1544   :
1545 else
1546   libc_cv_output_format=
1547 fi
1548 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1549 AC_SUBST(libc_cv_output_format)
1550
1551 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1552 cat > conftest.c <<EOF
1553 int foo;
1554 EOF
1555 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1556                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1557 then
1558   libc_cv_fno_toplevel_reorder=yes
1559 else
1560   libc_cv_fno_toplevel_reorder=no
1561 fi
1562 rm -f conftest*])
1563 if test $libc_cv_fno_toplevel_reorder = yes; then
1564   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1565 else
1566   fno_unit_at_a_time=-fno-unit-at-a-time
1567 fi
1568 AC_SUBST(fno_unit_at_a_time)
1569
1570 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1571 [dnl
1572 cat > conftest.c <<EOF
1573 __thread int i;
1574 void foo (void)
1575 {
1576   i = 10;
1577 }
1578 EOF
1579 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1580                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1581 then
1582   libc_cv_mtls_dialect_gnu2=yes
1583 else
1584   libc_cv_mtls_dialect_gnu2=no
1585 fi
1586 rm -f conftest*])
1587 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1588 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1589
1590 AC_CACHE_CHECK(whether cc puts quotes around section names,
1591                libc_cv_have_section_quotes,
1592                [cat > conftest.c <<EOF
1593                 static const int foo
1594                 __attribute__ ((section ("bar"))) = 1;
1595 EOF
1596                 if ${CC-cc} -S conftest.c -o conftest.s; then
1597                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1598                     libc_cv_have_section_quotes=yes
1599                   else
1600                     libc_cv_have_section_quotes=no
1601                   fi
1602                 else
1603                   libc_cv_have_section_quotes=unknown
1604                 fi
1605                 rm -f conftest.{c,s}
1606                 ])
1607 if test $libc_cv_have_section_quotes = yes; then
1608   AC_DEFINE(HAVE_SECTION_QUOTES)
1609 fi
1610
1611 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1612 cat > conftest.c <<\EOF
1613 void zero (void *x)
1614 {
1615   __builtin_memset (x, 0, 1000);
1616 }
1617 EOF
1618 dnl
1619 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1620 then
1621   libc_cv_gcc_builtin_memset=no
1622 else
1623   libc_cv_gcc_builtin_memset=yes
1624 fi
1625 rm -f conftest* ])
1626 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1627   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1628 fi
1629
1630 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1631 cat > conftest.c <<\EOF
1632 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1633 char *foo (const char *a, const char *b)
1634 {
1635   return __builtin_strstr (a, b);
1636 }
1637 EOF
1638 dnl
1639 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1640 then
1641   libc_cv_gcc_builtin_redirection=yes
1642 else
1643   libc_cv_gcc_builtin_redirection=no
1644 fi
1645 rm -f conftest* ])
1646 if test "$libc_cv_gcc_builtin_redirection" = no; then
1647   AC_MSG_ERROR([support for the symbol redirection needed])
1648 fi
1649
1650 dnl Determine how to disable generation of FMA instructions.
1651 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1652                libc_cv_cc_nofma, [dnl
1653 libc_cv_cc_nofma=
1654 for opt in -ffp-contract=off -mno-fused-madd; do
1655   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1656 done])
1657 AC_SUBST(libc_cv_cc_nofma)
1658
1659 if test -n "$submachine"; then
1660   AC_CACHE_CHECK([for compiler option for CPU variant],
1661                  libc_cv_cc_submachine, [dnl
1662   libc_cv_cc_submachine=no
1663   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1664     LIBC_TRY_CC_OPTION([$opt], [
1665       libc_cv_cc_submachine="$opt"
1666       break], [])
1667   done])
1668   if test "x$libc_cv_cc_submachine" = xno; then
1669     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1670   fi
1671 fi
1672 AC_SUBST(libc_cv_cc_submachine)
1673
1674 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1675 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1676 cat > conftest.c <<EOF
1677 void
1678 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1679 foo (void) {}
1680 EOF
1681 libc_cv_cc_loop_to_function=no
1682 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1683 then
1684   libc_cv_cc_loop_to_function=yes
1685 fi
1686 rm -f conftest*])
1687 if test $libc_cv_cc_loop_to_function = yes; then
1688   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1689 fi
1690 AC_SUBST(libc_cv_cc_loop_to_function)
1691
1692 dnl Check whether we have the gd library available.
1693 AC_MSG_CHECKING(for libgd)
1694 if test "$with_gd" != "no"; then
1695   old_CFLAGS="$CFLAGS"
1696   CFLAGS="$CFLAGS $libgd_include"
1697   old_LDFLAGS="$LDFLAGS"
1698   LDFLAGS="$LDFLAGS $libgd_ldflags"
1699   old_LIBS="$LIBS"
1700   LIBS="$LIBS -lgd -lpng -lz -lm"
1701   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1702   CFLAGS="$old_CFLAGS"
1703   LDFLAGS="$old_LDFLAGS"
1704   LIBS="$old_LIBS"
1705 else
1706   LIBGD=no
1707 fi
1708 AC_MSG_RESULT($LIBGD)
1709 AC_SUBST(LIBGD)
1710
1711 # SELinux detection
1712 if test x$with_selinux = xno ; then
1713   have_selinux=no;
1714 else
1715   # See if we have the SELinux library
1716   AC_CHECK_LIB(selinux, is_selinux_enabled,
1717                have_selinux=yes, have_selinux=no)
1718   if test x$with_selinux = xyes ; then
1719     if test x$have_selinux = xno ; then
1720       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1721     fi
1722   fi
1723 fi
1724 # Check if we're building with SELinux support.
1725 if test "x$have_selinux" = xyes; then
1726   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1727
1728   # See if we have the libaudit library
1729   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1730                have_libaudit=yes, have_libaudit=no)
1731   if test "x$have_libaudit" = xyes; then
1732     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1733   fi
1734   AC_SUBST(have_libaudit)
1735
1736   # See if we have the libcap library
1737   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1738   if test "x$have_libcap" = xyes; then
1739     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1740   fi
1741   AC_SUBST(have_libcap)
1742 fi
1743 AC_SUBST(have_selinux)
1744
1745 CPPUNDEFS=
1746 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1747 dnl Since we are building the implementations of the fortified functions here,
1748 dnl having the macro defined interacts very badly.
1749 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1750 [AC_TRY_COMPILE([], [
1751 #ifdef _FORTIFY_SOURCE
1752 # error bogon
1753 #endif],
1754                 [libc_cv_predef_fortify_source=no],
1755                 [libc_cv_predef_fortify_source=yes])])
1756 if test $libc_cv_predef_fortify_source = yes; then
1757   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1758 fi
1759 AC_SUBST(CPPUNDEFS)
1760
1761 # Some linkers on some architectures support __ehdr_start but with
1762 # bugs.  Make sure usage of it does not create relocations in the
1763 # output (as the linker should resolve them all for us).
1764 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1765                libc_cv_ehdr_start, [
1766 old_CFLAGS="$CFLAGS"
1767 old_LDFLAGS="$LDFLAGS"
1768 old_LIBS="$LIBS"
1769 CFLAGS="$CFLAGS -fPIC"
1770 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1771 LIBS=
1772 AC_LINK_IFELSE([AC_LANG_SOURCE([
1773 typedef struct {
1774   char foo;
1775   long val;
1776 } Ehdr;
1777 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1778 long ehdr (void) { return __ehdr_start.val; }
1779 ])],
1780                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1781                   libc_cv_ehdr_start=broken
1782                 else
1783                   libc_cv_ehdr_start=yes
1784                 fi], [libc_cv_ehdr_start=no])
1785 CFLAGS="$old_CFLAGS"
1786 LDFLAGS="$old_LDFLAGS"
1787 LIBS="$old_LIBS"
1788 ])
1789 if test "$libc_cv_ehdr_start" = yes; then
1790   AC_DEFINE([HAVE_EHDR_START])
1791 elif test "$libc_cv_ehdr_start" = broken; then
1792   AC_MSG_WARN([linker is broken -- you should upgrade])
1793 fi
1794
1795 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1796                libc_cv_builtin_trap, [dnl
1797 libc_cv_builtin_trap=no
1798 AC_TRY_COMPILE([], [__builtin_trap ()], [
1799 libc_undefs=`$NM -u conftest.o |
1800   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1801     2>&AS_MESSAGE_LOG_FD` || {
1802   AC_MSG_ERROR([confusing output from $NM -u])
1803 }
1804 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1805 if test -z "$libc_undefs"; then
1806   libc_cv_builtin_trap=yes
1807 fi])])
1808 if test $libc_cv_builtin_trap = yes; then
1809   AC_DEFINE([HAVE_BUILTIN_TRAP])
1810 fi
1811
1812 dnl C++ feature tests.
1813 AC_LANG_PUSH([C++])
1814
1815 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1816                libc_cv_cxx_thread_local, [
1817 old_CXXFLAGS="$CXXFLAGS"
1818 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1819 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1820 #include <thread>
1821
1822 // Compiler support.
1823 struct S
1824 {
1825   S ();
1826   ~S ();
1827 };
1828 thread_local S s;
1829 S * get () { return &s; }
1830
1831 // libstdc++ support.
1832 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1833 #error __cxa_thread_atexit_impl not supported
1834 #endif
1835 ])],
1836                [libc_cv_cxx_thread_local=yes],
1837                [libc_cv_cxx_thread_local=no])
1838 CXXFLAGS="$old_CXXFLAGS"
1839 ])
1840 AC_SUBST(libc_cv_cxx_thread_local)
1841
1842 AC_LANG_POP([C++])
1843 dnl End of C++ feature tests.
1844
1845 ### End of automated tests.
1846 ### Now run sysdeps configure fragments.
1847
1848 # They also can set these variables.
1849 use_ldconfig=no
1850 ldd_rewrite_script=no
1851 libc_cv_sysconfdir=$sysconfdir
1852 libc_cv_localstatedir=$localstatedir
1853 libc_cv_gcc_unwind_find_fde=no
1854 libc_cv_idn=no
1855
1856 # Iterate over all the sysdep directories we will use, running their
1857 # configure fragments.
1858 for dir in $sysnames; do
1859   case $dir in
1860     /*) dest=$dir ;;
1861     *)  dest=$srcdir/$dir ;;
1862   esac
1863   if test -r $dest/configure; then
1864     AC_MSG_RESULT(running configure fragment for $dir)
1865     . $dest/configure
1866   fi
1867 done
1868
1869 if test x"$build_mathvec" = xnotset; then
1870   build_mathvec=no
1871 fi
1872 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1873
1874 AC_SUBST(libc_extra_cflags)
1875 AC_SUBST(libc_extra_cppflags)
1876
1877 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1878   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1879 fi
1880 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1881
1882 # A sysdeps configure fragment can reset this if IFUNC is not actually
1883 # usable even though the assembler knows how to generate the symbol type.
1884 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1885   AC_DEFINE(HAVE_IFUNC)
1886 fi
1887
1888 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1889   AC_DEFINE(HAVE_GCC_IFUNC)
1890 fi
1891
1892 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1893 # configure fragment can override the value to prevent this AC_DEFINE.
1894 AC_SUBST(use_nscd)
1895 if test "x$use_nscd" != xno; then
1896   AC_DEFINE([USE_NSCD])
1897 fi
1898 if test "x$build_nscd" = xdefault; then
1899   build_nscd=$use_nscd
1900 fi
1901
1902 AC_SUBST(libc_cv_slibdir)
1903 AC_SUBST(libc_cv_rtlddir)
1904 AC_SUBST(libc_cv_complocaledir)
1905 AC_SUBST(libc_cv_sysconfdir)
1906 AC_SUBST(libc_cv_localstatedir)
1907 AC_SUBST(libc_cv_rootsbindir)
1908
1909 if test x$use_ldconfig = xyes; then
1910   AC_DEFINE(USE_LDCONFIG)
1911 fi
1912 AC_SUBST(use_ldconfig)
1913 AC_SUBST(ldd_rewrite_script)
1914
1915 AC_SUBST(static)
1916 AC_SUBST(shared)
1917
1918 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1919 [libc_cv_pic_default=yes
1920 cat > conftest.c <<EOF
1921 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1922 # error PIC is default.
1923 #endif
1924 EOF
1925 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1926   libc_cv_pic_default=no
1927 fi
1928 rm -f conftest.*])
1929 AC_SUBST(libc_cv_pic_default)
1930
1931 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1932 [libc_cv_pie_default=yes
1933 cat > conftest.c <<EOF
1934 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1935 # error PIE is default.
1936 #endif
1937 EOF
1938 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1939   libc_cv_pie_default=no
1940 fi
1941 rm -f conftest.*])
1942 AC_SUBST(libc_cv_pie_default)
1943
1944 AC_SUBST(profile)
1945 AC_SUBST(static_nss)
1946
1947 AC_SUBST(DEFINES)
1948
1949 dnl See sysdeps/mach/configure.ac for this variable.
1950 AC_SUBST(mach_interface_list)
1951
1952 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1953 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1954 AC_SUBST(VERSION)
1955 AC_SUBST(RELEASE)
1956
1957 AC_CONFIG_FILES([config.make Makefile])
1958 AC_CONFIG_COMMANDS([default],[[
1959 case $CONFIG_FILES in *config.make*)
1960 echo "$config_vars" >> config.make;;
1961 esac
1962 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1963 AC_OUTPUT