configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl On some platforms we cannot use dynamic loading.  We must provide
 239 dnl static NSS modules.
 240 AC_ARG_ENABLE([static-nss],
 241               AC_HELP_STRING([--enable-static-nss],
 242                              [build static NSS modules @<:@default=no@:>@]),
 243               [static_nss=$enableval],
 244               [static_nss=no])
 245 dnl Enable static NSS also if we build no shared objects.
 246 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 247   static_nss=yes
 248   AC_DEFINE(DO_STATIC_NSS)
 249 fi
 250
 251 AC_ARG_ENABLE([force-install],
 252               AC_HELP_STRING([--disable-force-install],
 253                              [don't force installation of files from this package, even if they are older than the installed files]),
 254               [force_install=$enableval],
 255               [force_install=yes])
 256 AC_SUBST(force_install)
 257
 258 AC_ARG_ENABLE([maintainer-mode],
 259               AC_HELP_STRING([--enable-maintainer-mode],
 260                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 261               [maintainer=$enableval],
 262               [maintainer=no])
 263
 264 dnl On some platforms we allow dropping compatibility with all kernel
 265 dnl versions.
 266 AC_ARG_ENABLE([kernel],
 267               AC_HELP_STRING([--enable-kernel=VERSION],
 268                              [compile for compatibility with kernel not older than VERSION]),
 269               [minimum_kernel=$enableval],
 270               [])
 271 dnl Prevent unreasonable values.
 272 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 273   # Better nothing than this.
 274   minimum_kernel=""
 275 else
 276   if test "$minimum_kernel" = current; then
 277     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 278   fi
 279 fi
 280
 281 dnl For the development we sometimes want gcc to issue even more warnings.
 282 dnl This is not the default since many of the extra warnings are not
 283 dnl appropriate.
 284 AC_ARG_ENABLE([all-warnings],
 285               AC_HELP_STRING([--enable-all-warnings],
 286                              [enable all useful warnings gcc can issue]),
 287               [all_warnings=$enableval],
 288               [])
 289 AC_SUBST(all_warnings)
 290
 291 AC_ARG_ENABLE([werror],
 292               AC_HELP_STRING([--disable-werror],
 293                              [do not build with -Werror]),
 294               [enable_werror=$enableval],
 295               [enable_werror=yes])
 296 AC_SUBST(enable_werror)
 297
 298 AC_ARG_ENABLE([multi-arch],
 299               AC_HELP_STRING([--enable-multi-arch],
 300                              [enable single DSO with optimizations for multiple architectures]),
 301               [multi_arch=$enableval],
 302               [multi_arch=default])
 303
 304 AC_ARG_ENABLE([nss-crypt],
 305               AC_HELP_STRING([--enable-nss-crypt],
 306                              [enable libcrypt to use nss]),
 307               [nss_crypt=$enableval],
 308               [nss_crypt=no])
 309 if test x$nss_crypt = xyes; then
 310   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 311   if test $? -ne 0; then
 312     AC_MSG_ERROR([cannot find include directory with nss-config])
 313   fi
 314   old_CFLAGS="$CFLAGS"
 315   CFLAGS="$CFLAGS $nss_includes"
 316   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 317 #include <hasht.h>
 318 #include <nsslowhash.h>
 319 void f (void) { NSSLOW_Init (); }])],
 320              libc_cv_nss_crypt=yes,
 321              AC_MSG_ERROR([
 322 cannot find NSS headers with lowlevel hash function interfaces]))
 323   old_LIBS="$LIBS"
 324   LIBS="$LIBS -lfreebl3"
 325   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 326 #include <hasht.h>
 327 #include <nsslowhash.h>],
 328                                   [NSSLOW_Init();])],
 329                  libc_cv_nss_crypt=yes,
 330                  AC_MSG_ERROR([
 331 cannot link program using lowlevel NSS hash functions]))
 332   CFLAGS="$old_CFLAGS"
 333   LIBS="$old_LIBS"
 334 else
 335   libc_cv_nss_crypt=no
 336 fi
 337 AC_SUBST(libc_cv_nss_crypt)
 338
 339
 340 AC_ARG_ENABLE([obsolete-rpc],
 341               AC_HELP_STRING([--enable-obsolete-rpc],
 342                              [build and install the obsolete RPC code for link-time usage]),
 343               [link_obsolete_rpc=$enableval],
 344               [link_obsolete_rpc=no])
 345 AC_SUBST(link_obsolete_rpc)
 346
 347 if test "$link_obsolete_rpc" = yes; then
 348   AC_DEFINE(LINK_OBSOLETE_RPC)
 349 fi
 350
 351 AC_ARG_ENABLE([systemtap],
 352               [AS_HELP_STRING([--enable-systemtap],
 353                [enable systemtap static probe points @<:@default=no@:>@])],
 354               [systemtap=$enableval],
 355               [systemtap=no])
 356 if test "x$systemtap" != xno; then
 357   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 358   old_CFLAGS="$CFLAGS"
 359   CFLAGS="-std=gnu11 $CFLAGS"
 360   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 361 void foo (int i, void *p)
 362 {
 363   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 364        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 365 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 366   CFLAGS="$old_CFLAGS"])
 367   if test $libc_cv_sdt = yes; then
 368     AC_DEFINE([USE_STAP_PROBE])
 369   elif test "x$systemtap" != xauto; then
 370     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 371   fi
 372 fi
 373
 374 AC_ARG_ENABLE([build-nscd],
 375               [AS_HELP_STRING([--disable-build-nscd],
 376                [disable building and installing the nscd daemon])],
 377               [build_nscd=$enableval],
 378               [build_nscd=default])
 379 AC_SUBST(build_nscd)
 380
 381 # Note the use of $use_nscd is near the bottom of the file.
 382 AC_ARG_ENABLE([nscd],
 383               [AS_HELP_STRING([--disable-nscd],
 384                [library functions will not contact the nscd daemon])],
 385               [use_nscd=$enableval],
 386               [use_nscd=yes])
 387
 388 AC_ARG_ENABLE([pt_chown],
 389               [AS_HELP_STRING([--enable-pt_chown],
 390                [Enable building and installing pt_chown])],
 391               [build_pt_chown=$enableval],
 392               [build_pt_chown=no])
 393 AC_SUBST(build_pt_chown)
 394 if test "$build_pt_chown" = yes; then
 395   AC_DEFINE(HAVE_PT_CHOWN)
 396 fi
 397
 398 # The abi-tags file uses a fairly simplistic model for name recognition that
 399 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 400 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 401 # This doesn't get used much beyond that, so it's fairly safe.
 402 case "$host_os" in
 403 linux*)
 404   ;;
 405 gnu*)
 406   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 407   ;;
 408 esac
 409
 410 AC_ARG_ENABLE([mathvec],
 411               [AS_HELP_STRING([--enable-mathvec],
 412               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 413               [build_mathvec=$enableval],
 414               [build_mathvec=notset])
 415
 416 # We keep the original values in `$config_*' and never modify them, so we
 417 # can write them unchanged into config.make.  Everything else uses
 418 # $machine, $vendor, and $os, and changes them whenever convenient.
 419 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 420
 421 # Don't allow vendor == "unknown"
 422 test "$config_vendor" = unknown && config_vendor=
 423 config_os="`echo $config_os | sed 's/^unknown-//'`"
 424
 425 # Some configurations imply other options.
 426 elf=yes
 427
 428 # The configure fragment of an add-on port can modify these to supplement
 429 # or override the table in the case statement below.  No fragment should
 430 # ever change the config_* variables, however.
 431 machine=$config_machine
 432 vendor=$config_vendor
 433 os=$config_os
 434 base_os=''
 435
 436 submachine=
 437 AC_ARG_WITH([cpu],
 438             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 439             [dnl
 440   case "$withval" in
 441   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 442   no) ;;
 443   *) submachine="$withval" ;;
 444   esac
 445 ])
 446
 447 # An preconfigure script can set this when it wants to disable the sanity
 448 # check below.
 449 libc_config_ok=no
 450
 451 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 452 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 453
 454 dnl Having this here, though empty, makes sure that if add-ons' fragments
 455 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 456 dnl our AC_OUTPUT will actually use it.
 457 AC_CONFIG_SUBDIRS()
 458
 459 case "$enable_add_ons" in
 460 ''|no) add_ons= ;;
 461 yes|'*')
 462  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 463           sed 's@/[[^/]]*$@@' | sort | uniq`
 464          add_ons_automatic=yes
 465          ;;
 466 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 467        add_ons_automatic=no ;;
 468 esac
 469
 470 configured_add_ons=
 471 add_ons_sfx=
 472 add_ons_pfx=
 473 if test x"$add_ons" != x; then
 474   for f in $add_ons; do
 475     # Some sanity checks
 476     case "$f" in
 477     crypt)
 478       AC_MSG_ERROR([
 479 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 480 *** part of glibc and using the old add-on will not work with this
 481 *** release.  Start again with fresh sources and without the old
 482 *** \`crypt' add-on.])
 483     ;;
 484     localedata)
 485       AC_MSG_ERROR([
 486 *** It seems that you're using an old \`localedata' add-on.  localedata
 487 *** is now part of glibc and using the old add-on will not work with
 488 *** this release.  Start again with fresh sources and without the old
 489 *** \`localedata' add-on.])
 490     ;;
 491     esac
 492   done
 493
 494   # Now source each add-on's configure fragment.
 495   # The fragments can use $srcdir/$libc_add_on to find themselves,
 496   # and test $add_ons_automatic to see if they were explicitly requested.
 497   # A fragment can clear (or even change) $libc_add_on to affect
 498   # whether it goes into the list to be actually used in the build.
 499   use_add_ons=
 500   for libc_add_on in $add_ons; do
 501     # Test whether such a directory really exists.
 502     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 503     case "$libc_add_on" in
 504     /*)
 505       libc_add_on_srcdir=$libc_add_on
 506       ;;
 507     *)
 508       test -d "$srcdir/$libc_add_on" || {
 509         if test -d "$libc_add_on"; then
 510           libc_add_on="`pwd`/$libc_add_on"
 511         else
 512           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 513         fi
 514       }
 515       libc_add_on_srcdir=$srcdir/$libc_add_on
 516       ;;
 517     esac
 518
 519     libc_add_on_frag=$libc_add_on_srcdir/configure
 520     libc_add_on_canonical=
 521     libc_add_on_config_subdirs=
 522     if test -r "$libc_add_on_frag"; then
 523       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 524       libc_add_on_canonical=unknown
 525       libc_add_on_subdirs=
 526       . "$libc_add_on_frag"
 527       test -z "$libc_add_on" || {
 528         configured_add_ons="$configured_add_ons $libc_add_on"
 529         if test "x$libc_add_on_canonical" = xunknown; then
 530           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 531         fi
 532         for d in $libc_add_on_subdirs; do
 533           case "$libc_add_on" in
 534           /*) subdir_srcdir="$libc_add_on" ;;
 535           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 536           esac
 537           case "$d" in
 538           .)
 539             d="${libc_add_on_canonical:-$libc_add_on}"
 540             ;;
 541           /*)
 542             subdir_srcdir="$d"
 543             ;;
 544           *)
 545             subdir_srcdir="$subdir_srcdir/$d"
 546             ;;
 547           esac
 548           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 549           add_on_subdirs="$add_on_subdirs $d"
 550           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 551 $d-srcdir = $subdir_srcdir"
 552         done
 553         for d in $libc_add_on_config_subdirs; do
 554           case "$d" in
 555           /*) AC_MSG_ERROR(dnl
 556 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 557           esac
 558           if test ! -d "$libc_add_on_srcdir/$d"; then
 559             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 560           fi
 561           case "$libc_add_on" in
 562           /*) AC_MSG_ERROR(dnl
 563 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 564           esac
 565           subdirs="$subdirs $libc_add_on/$d"
 566         done
 567       }
 568     fi
 569     if test -n "$libc_add_on"; then
 570       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 571       use_add_ons="$use_add_ons $libc_add_on"
 572       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 573       test -z "$libc_add_on_canonical" ||
 574       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 575     fi
 576   done
 577   # Use echo to strip excess whitespace.
 578   add_ons="`echo $use_add_ons`"
 579 fi
 580 AC_SUBST(add_ons)
 581 AC_SUBST(add_on_subdirs)
 582
 583
 584 ###
 585 ### By using the undocumented --enable-hacker-mode option for configure
 586 ### one can skip this test to make the configuration not fail for unsupported
 587 ### platforms.
 588 ###
 589 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 590   case "$machine-$host_os" in
 591   *-linux* | *-gnu*)
 592     ;;
 593   *)
 594     AC_MSG_ERROR([
 595 *** The GNU C library is currently unavailable for this platform.
 596 *** If you are interested in seeing glibc on this platform visit
 597 *** the "How to submit a new port" in the wiki:
 598 ***   https://sourceware.org/glibc/wiki/#Development
 599 *** and join the community!])
 600     ;;
 601   esac
 602 fi
 603
 604 # Set base_machine if not set by a preconfigure fragment.
 605 test -n "$base_machine" || base_machine=$machine
 606 AC_SUBST(base_machine)
 607
 608 # For the multi-arch option we need support in the assembler & linker.
 609 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 610                libc_cv_ld_gnu_indirect_function, [dnl
 611 cat > conftest.S <<EOF
 612 .type foo,%gnu_indirect_function
 613 foo:
 614 .globl _start
 615 _start:
 616 .globl __start
 617 __start:
 618 .data
 619 #ifdef _LP64
 620 .quad foo
 621 #else
 622 .long foo
 623 #endif
 624 EOF
 625 libc_cv_ld_gnu_indirect_function=no
 626 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 627             -nostartfiles -nostdlib \
 628             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 629   # Do a link to see if the backend supports IFUNC relocs.
 630   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 631   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 632     libc_cv_ld_gnu_indirect_function=yes
 633   }
 634 fi
 635 rm -f conftest*])
 636
 637 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 638   if test x"$multi_arch" = xyes; then
 639     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 640   else
 641     multi_arch=no
 642   fi
 643 fi
 644 multi_arch_d=
 645 if test x"$multi_arch" != xno; then
 646   multi_arch_d=/multiarch
 647 fi
 648
 649 # Compute the list of sysdep directories for this configuration.
 650 # This can take a while to compute.
 651 sysdep_dir=$srcdir/sysdeps
 652 AC_MSG_CHECKING(sysdep dirs)
 653 dnl We need to use [ and ] for other purposes for a while now.
 654 changequote(,)dnl
 655 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 656 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 657
 658 test "x$base_os" != x || case "$os" in
 659 gnu*)
 660   base_os=mach/hurd ;;
 661 linux*)
 662   base_os=unix/sysv ;;
 663 esac
 664
 665 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 666 tail=$os
 667 ostry=$os
 668 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 669   ostry="$ostry /$o"
 670   tail=$o
 671 done
 672 o=`echo $tail | sed 's/[0-9]*$//'`
 673 if test $o != $tail; then
 674   ostry="$ostry /$o"
 675 fi
 676 # For linux-gnu, try linux-gnu, then linux.
 677 o=`echo $tail | sed 's/-.*$//'`
 678 if test $o != $tail; then
 679   ostry="$ostry /$o"
 680 fi
 681
 682 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 683 base=
 684 tail=$base_os
 685 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 686   set $b
 687   base="$base /$1"
 688   tail="$2"
 689 done
 690
 691 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 692 mach=
 693 tail=$machine${submachine:+/$submachine}
 694 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 695   set $m
 696   # Prepend the machine's FPU directory unless --without-fp.
 697   if test "$with_fp" = yes; then
 698     maybe_fpu=/fpu
 699   else
 700     maybe_fpu=/nofpu
 701   fi
 702   # For each machine term, try it with and then without /multiarch.
 703   for try_fpu in $maybe_fpu ''; do
 704     for try_multi in $multi_arch_d ''; do
 705       mach="$mach /$1$try_fpu$try_multi"
 706     done
 707   done
 708   tail="$2"
 709 done
 710
 711 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 712 changequote([,])dnl
 713
 714 # Find what sysdep directories exist.
 715 sysnames_add_ons=
 716 sysnames=
 717 for b in $base ''; do
 718   for m0 in $mach ''; do
 719     for v in /$vendor ''; do
 720       test "$v" = / && continue
 721       for o in /$ostry ''; do
 722         test "$o" = / && continue
 723         for m in $mach ''; do
 724           for d in $add_ons_pfx ''; do
 725             for a in $add_ons_sfx ''; do
 726               try_suffix="$m0$b$v$o$m"
 727               if test -n "$try_suffix"; then
 728                 try_srcdir="${srcdir}/"
 729                 case "$d" in
 730                 /*) try_srcdir= ;;
 731                 esac
 732                 try="${d}sysdeps$try_suffix$a"
 733                 test -n "$enable_debug_configure" &&
 734                 echo "$0 [DEBUG]: try $try" >&2
 735                 if test -d "$try_srcdir$try"; then
 736                   sysnames="$sysnames $try"
 737                   { test -n "$o" || test -n "$b"; } && os_used=t
 738                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 739                   case x${m0:-$m} in
 740                   x*/$submachine) submachine_used=t ;;
 741                   esac
 742                   if test -n "$d"; then
 743                     case "$sysnames_add_ons" in
 744                     *" $d "*) ;;
 745                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 746                     esac
 747                   fi
 748                 fi
 749               fi
 750             done
 751           done
 752         done
 753       done
 754     done
 755   done
 756 done
 757
 758 # If the assembler supports gnu_indirect_function symbol type and the
 759 # architecture supports multi-arch, we enable multi-arch by default.
 760 case $sysnames_add_ons$sysnames in
 761 *"$multi_arch_d"*)
 762   ;;
 763 *)
 764   test x"$multi_arch" = xdefault && multi_arch=no
 765   ;;
 766 esac
 767 if test x"$multi_arch" != xno; then
 768   AC_DEFINE(USE_MULTIARCH)
 769 fi
 770 AC_SUBST(multi_arch)
 771
 772 if test -z "$os_used" && test "$os" != none; then
 773   AC_MSG_ERROR(Operating system $os is not supported.)
 774 fi
 775 if test -z "$machine_used" && test "$machine" != none; then
 776   AC_MSG_ERROR(The $machine is not supported.)
 777 fi
 778 if test -z "$submachine_used" && test -n "$submachine"; then
 779   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 780 fi
 781 AC_SUBST(submachine)
 782
 783 # We have now validated the configuration.
 784
 785 # Expand the list of system names into a full list of directories
 786 # from each element's parent name and Implies file (if present).
 787 set $sysnames
 788 names=
 789 while test $# -gt 0; do
 790   name=$1
 791   shift
 792
 793   case " $names " in *" $name "*)
 794     # Already in the list.
 795     continue
 796   esac
 797
 798   # Report each name as we discover it, so there is no long pause in output.
 799   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 800
 801   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 802
 803   case $name in
 804     /*) xsrcdir= ;;
 805     *)  xsrcdir=$srcdir/ ;;
 806   esac
 807   test -n "$enable_debug_configure" &&
 808   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 809
 810   for implies_file in Implies Implies-before Implies-after; do
 811     implies_type=`echo $implies_file | sed s/-/_/`
 812     eval ${implies_type}=
 813     if test -f $xsrcdir$name/$implies_file; then
 814       # Collect more names from the `Implies' file (removing comments).
 815       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 816       for x in $implied_candidate; do
 817         found=no
 818         if test -d $xsrcdir$name_base/$x; then
 819           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 820           found=yes
 821         fi
 822         for d in $add_ons_pfx ''; do
 823           try="${d}sysdeps/$x"
 824           case $d in
 825            /*) try_srcdir= ;;
 826            *) try_srcdir=$srcdir/ ;;
 827           esac
 828           test -n "$enable_debug_configure" &&
 829            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 830           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 831           then
 832             eval "${implies_type}=\"\$${implies_type} \$try\""
 833             found=yes
 834             case "$sysnames_add_ons" in
 835             *" $d "*) ;;
 836             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 837             esac
 838           fi
 839         done
 840         if test $found = no; then
 841           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 842         fi
 843       done
 844     fi
 845   done
 846
 847   # Add NAME to the list of names.
 848   names="$names $name"
 849
 850   # Find the parent of NAME, using the empty string if it has none.
 851 changequote(,)dnl
 852   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 853 changequote([,])dnl
 854
 855   test -n "$enable_debug_configure" &&
 856     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 857 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 858
 859   # Add the names implied by NAME, and NAME's parent (if it has one), to
 860   # the list of names to be processed (the argument list).  We prepend the
 861   # implied names to the list and append the parent.  We want implied
 862   # directories to come before further directories inferred from the
 863   # configuration components; this ensures that for sysv4, unix/common
 864   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 865   # after sysv4).
 866   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 867   test -n "$sysnames" && set $sysnames
 868 done
 869
 870 # Add the default directories.
 871 default_sysnames="sysdeps/generic"
 872 sysnames="$names $default_sysnames"
 873 AC_SUBST(sysnames)
 874 # The other names were emitted during the scan.
 875 AC_MSG_RESULT($default_sysnames)
 876
 877 # Collect the list of add-ons that supply partial sysdeps trees.
 878 sysdeps_add_ons=
 879 for add_on in $add_ons; do
 880   case "$add_on" in
 881   /*) xsrcdir= ;;
 882   *) xsrcdir="$srcdir/" ;;
 883   esac
 884
 885   test -d "$xsrcdir$add_on/sysdeps" || {
 886     case "$configured_add_ons " in
 887     *" $add_on "*) ;;
 888     *|'')
 889       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 890       ;;
 891     esac
 892     continue
 893   }
 894
 895   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 896   case "$sysnames_add_ons" in
 897   *" $add_on/ "*) ;;
 898   *|'')
 899     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 900     continue ;;
 901   esac
 902
 903   found=no
 904   for d in $sysnames; do
 905     case "$d" in
 906     $add_on/sysdeps/*) ;;
 907     *) continue ;;
 908     esac
 909     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 910        case "$f" in
 911        sys|bits)
 912          for ff in $f/*.h; do
 913            test -d "$ff" || { test -e "$ff" && exit 88; }
 914          done
 915          ;;
 916        *)
 917          test -d "$f" || { test -e "$f" && exit 88; }
 918          ;;
 919        esac
 920      done)
 921     if test $? -eq 88; then
 922       found=yes
 923       break
 924     fi
 925   done
 926   if test $found = no; then
 927     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 928   fi
 929 done
 930 AC_SUBST(sysdeps_add_ons)
 931
 932
 933 ### Locate tools.
 934
 935 AC_PROG_INSTALL
 936 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 937   # The makefiles need to use a different form to find it in $srcdir.
 938   INSTALL='\$(..)./scripts/install-sh -c'
 939 fi
 940 AC_PROG_LN_S
 941
 942 LIBC_PROG_BINUTILS
 943
 944 # Accept binutils 2.22 or newer.
 945 AC_CHECK_PROG_VER(AS, $AS, --version,
 946                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 947                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 948                   AS=: critic_missing="$critic_missing as")
 949 AC_CHECK_PROG_VER(LD, $LD, --version,
 950                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 951                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 952                   LD=: critic_missing="$critic_missing ld")
 953
 954 # These programs are version sensitive.
 955 AC_CHECK_TOOL_PREFIX
 956 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 957   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 958   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 959
 960 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 961   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 962   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 963   MSGFMT=: aux_missing="$aux_missing msgfmt")
 964 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 965   [GNU texinfo.* \([0-9][0-9.]*\)],
 966   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 967   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 968 AC_CHECK_PROG_VER(SED, sed, --version,
 969   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 970   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 971   SED=: aux_missing="$aux_missing sed")
 972 AC_CHECK_PROG_VER(AWK, gawk, --version,
 973   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 974   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 975
 976 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 977 AC_TRY_COMPILE([], [
 978 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 979 #error insufficient compiler
 980 #endif],
 981                [libc_cv_compiler_ok=yes],
 982                [libc_cv_compiler_ok=no])])
 983 AS_IF([test $libc_cv_compiler_ok != yes],
 984       [critic_missing="$critic_missing compiler"])
 985
 986 AC_CHECK_TOOL(NM, nm, false)
 987
 988 if test "x$maintainer" = "xyes"; then
 989   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 990   case "x$AUTOCONF" in
 991   xno|x|x:) AUTOCONF=no ;;
 992   *)
 993     AC_CACHE_CHECK(dnl
 994   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 995     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 996       libc_cv_autoconf_works=yes
 997     else
 998       libc_cv_autoconf_works=no
 999     fi])
1000     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1001     ;;
1002   esac
1003   if test "x$AUTOCONF" = xno; then
1004     aux_missing="$aux_missing autoconf"
1005   fi
1006 else
1007   AUTOCONF=no
1008 fi
1009
1010 test -n "$critic_missing" && AC_MSG_ERROR([
1011 *** These critical programs are missing or too old:$critic_missing
1012 *** Check the INSTALL file for required versions.])
1013
1014 test -n "$aux_missing" && AC_MSG_WARN([
1015 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1016 *** some features will be disabled.
1017 *** Check the INSTALL file for required versions.])
1018
1019 # if using special system headers, find out the compiler's sekrit
1020 # header directory and add that to the list.  NOTE: Only does the right
1021 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1022 if test -n "$sysheaders"; then
1023   SYSINCLUDES=-nostdinc
1024   for d in include include-fixed; do
1025     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1026     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1027   done
1028   SYSINCLUDES="$SYSINCLUDES \
1029 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1030   if test -n "$CXX"; then
1031     CXX_SYSINCLUDES=
1032     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1033     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1034       test "x$cxxheaders" != x &&
1035       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1036     done
1037   fi
1038 fi
1039 AC_SUBST(SYSINCLUDES)
1040 AC_SUBST(CXX_SYSINCLUDES)
1041
1042 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1043 # since this would lead to problems installing/building glibc.
1044 # LD_LIBRARY_PATH contains the current directory if one of the following
1045 # is true:
1046 # - one of the terminals (":" and ";") is the first or last sign
1047 # - two terminals occur directly after each other
1048 # - the path contains an element with a dot in it
1049 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1050 changequote(,)dnl
1051 case ${LD_LIBRARY_PATH} in
1052   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1053     ld_library_path_setting="contains current directory"
1054     ;;
1055   *)
1056     ld_library_path_setting="ok"
1057     ;;
1058 esac
1059 changequote([,])dnl
1060 AC_MSG_RESULT($ld_library_path_setting)
1061 if test "$ld_library_path_setting" != "ok"; then
1062 AC_MSG_ERROR([
1063 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1064 *** building glibc. Please change the environment variable
1065 *** and run configure again.])
1066 fi
1067
1068 AC_PATH_PROG(BASH_SHELL, bash, no)
1069
1070 AC_PATH_PROG(PERL, perl, no)
1071 if test "$PERL" != no &&
1072    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1073   PERL=no
1074 fi
1075 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1076              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1077 AC_CHECK_PROG_VER(BISON, bison, --version,
1078                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1079                   [2.7*|[3-9].*|[1-9][0-9]*],
1080                   BISON=no)
1081
1082 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1083 cat > conftest.s <<EOF
1084 .text
1085 foo:
1086 .set glibc_conftest_frobozz,foo
1087 .globl glibc_conftest_frobozz
1088 EOF
1089 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1090 # (but it doesn't work), so we must do a linking check to be sure.
1091 cat > conftest1.c <<\EOF
1092 extern int glibc_conftest_frobozz;
1093 void _start() { glibc_conftest_frobozz = 1; }
1094 EOF
1095 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1096             -nostartfiles -nostdlib \
1097             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1098   libc_cv_asm_set_directive=yes
1099 else
1100   libc_cv_asm_set_directive=no
1101 fi
1102 rm -f conftest*])
1103 if test $libc_cv_asm_set_directive = yes; then
1104   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1105 fi
1106
1107 AC_CACHE_CHECK(linker support for protected data symbol,
1108                libc_cv_protected_data,
1109                [cat > conftest.c <<EOF
1110                 int bar __attribute__ ((visibility ("protected"))) = 1;
1111 EOF
1112                 libc_cv_protected_data=no
1113                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1114                   cat > conftest.c <<EOF
1115                   extern int bar;
1116                   int main (void) { return bar; }
1117 EOF
1118                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1119                     libc_cv_protected_data=yes
1120                   fi
1121                 fi
1122                 rm -f conftest.*
1123                ])
1124 AC_SUBST(libc_cv_protected_data)
1125
1126 AC_CACHE_CHECK(for broken __attribute__((alias())),
1127                libc_cv_broken_alias_attribute,
1128                [cat > conftest.c <<EOF
1129                extern int foo (int x) __asm ("xyzzy");
1130                int bar (int x) { return x; }
1131                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1132                extern int dfoo;
1133                extern __typeof (dfoo) dfoo __asm ("abccb");
1134                int dfoo = 1;
1135 EOF
1136                libc_cv_broken_alias_attribute=yes
1137                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1138                  if grep 'xyzzy' conftest.s >/dev/null &&
1139                     grep 'abccb' conftest.s >/dev/null; then
1140                    libc_cv_broken_alias_attribute=no
1141                  fi
1142                fi
1143                rm -f conftest.c conftest.s
1144                ])
1145 if test $libc_cv_broken_alias_attribute = yes; then
1146   AC_MSG_ERROR(working alias attribute support required)
1147 fi
1148
1149 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1150                libc_cv_have_sdata_section,
1151                [echo "int i;" > conftest.c
1152                 libc_cv_have_sdata_section=no
1153                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1154                    | grep '\.sdata' >/dev/null; then
1155                   libc_cv_have_sdata_section=yes
1156                 fi
1157                 rm -f conftest.c conftest.so
1158                ])
1159 if test $libc_cv_have_sdata_section = yes; then
1160   AC_DEFINE(HAVE_SDATA_SECTION)
1161 fi
1162
1163 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1164                libc_cv_ctors_header, [dnl
1165   libc_cv_ctors_header=yes
1166   LIBC_TRY_LINK_STATIC([
1167 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1168 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1169 ],
1170               [dnl
1171       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1172         { gsub(/\@<:@ */, "@<:@") }
1173         $2 == ".ctors" || $2 == ".dtors" {
1174           size = strtonum("0x" $6)
1175           align = strtonum("0x" $NF)
1176           seen@<:@$2@:>@ = 1
1177           stub@<:@$2@:>@ = size == align * 2
1178         }
1179         END {
1180           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1181           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1182           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1183         }
1184       '], [libc_cv_ctors_header=no])
1185     ], [dnl
1186       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1187     ])
1188 ])
1189 if test $libc_cv_ctors_header = no; then
1190   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1191 fi
1192
1193 AC_CACHE_CHECK(for libunwind-support in compiler,
1194                libc_cv_cc_with_libunwind, [
1195   cat > conftest.c <<EOF
1196 int main (void) { return 0; }
1197 EOF
1198   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1199      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1200     libc_cv_cc_with_libunwind=yes
1201   else
1202     libc_cv_cc_with_libunwind=no
1203   fi
1204   rm -f conftest*])
1205 AC_SUBST(libc_cv_cc_with_libunwind)
1206 if test $libc_cv_cc_with_libunwind = yes; then
1207   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1208 fi
1209
1210 ASFLAGS_config=
1211 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1212                libc_cv_as_noexecstack, [dnl
1213 cat > conftest.c <<EOF
1214 void foo (void) { }
1215 EOF
1216 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1217                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1218    && grep .note.GNU-stack conftest.s >/dev/null \
1219    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1220                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1221 then
1222   libc_cv_as_noexecstack=yes
1223 else
1224   libc_cv_as_noexecstack=no
1225 fi
1226 rm -f conftest*])
1227 if test $libc_cv_as_noexecstack = yes; then
1228   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1229 fi
1230 AC_SUBST(ASFLAGS_config)
1231
1232 AC_CACHE_CHECK(for -z combreloc,
1233                libc_cv_z_combreloc, [dnl
1234 cat > conftest.c <<EOF
1235 extern int bar (int);
1236 extern int mumble;
1237 int foo (void) { return bar (mumble); }
1238 EOF
1239 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1240                         -fPIC -shared -o conftest.so conftest.c
1241                         -nostdlib -nostartfiles
1242                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1243 then
1244 dnl The following test is a bit weak.  We must use a tool which can test
1245 dnl cross-platform since the gcc used can be a cross compiler.  Without
1246 dnl introducing new options this is not easily doable.  Instead use a tool
1247 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1248 dnl look for a section named .rel.dyn.
1249   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1250     libc_cv_z_combreloc=yes
1251   else
1252     libc_cv_z_combreloc=no
1253   fi
1254 else
1255   libc_cv_z_combreloc=no
1256 fi
1257 rm -f conftest*])
1258 if test "$libc_cv_z_combreloc" = yes; then
1259   AC_DEFINE(HAVE_Z_COMBRELOC)
1260 fi
1261 AC_SUBST(libc_cv_z_combreloc)
1262
1263 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1264                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1265 AC_SUBST(libc_cv_z_execstack)
1266
1267 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1268 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1269 ])
1270
1271 AC_SUBST(libc_cv_fpie)
1272
1273 AC_CACHE_CHECK(for --hash-style option,
1274                libc_cv_hashstyle, [dnl
1275 cat > conftest.c <<EOF
1276 int _start (void) { return 42; }
1277 EOF
1278 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1279                             -fPIC -shared -o conftest.so conftest.c
1280                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1281 then
1282   libc_cv_hashstyle=yes
1283 else
1284   libc_cv_hashstyle=no
1285 fi
1286 rm -f conftest*])
1287 AC_SUBST(libc_cv_hashstyle)
1288
1289 # The linker's default -shared behavior is good enough if it
1290 # does these things that our custom linker scripts ensure that
1291 # all allocated NOTE sections come first.
1292 if test "$use_default_link" = default; then
1293   AC_CACHE_CHECK([for sufficient default -shared layout],
1294                   libc_cv_use_default_link, [dnl
1295   libc_cv_use_default_link=no
1296   cat > conftest.s <<\EOF
1297           .section .note.a,"a",%note
1298           .balign 4
1299           .long 4,4,9
1300           .string "GNU"
1301           .string "foo"
1302           .section .note.b,"a",%note
1303           .balign 4
1304           .long 4,4,9
1305           .string "GNU"
1306           .string "bar"
1307 EOF
1308   if AC_TRY_COMMAND([dnl
1309   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1310        ac_try=`$READELF -S conftest.so | sed -n \
1311          ['${x;p;}
1312           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1313           t a
1314           b
1315           : a
1316           H']`
1317   then
1318     libc_seen_a=no libc_seen_b=no
1319     set -- $ac_try
1320     while test $# -ge 2 -a "$1" = NOTE; do
1321       case "$2" in
1322       .note.a) libc_seen_a=yes ;;
1323       .note.b) libc_seen_b=yes ;;
1324       esac
1325       shift 2
1326     done
1327     case "$libc_seen_a$libc_seen_b" in
1328     yesyes)
1329       libc_cv_use_default_link=yes
1330       ;;
1331     *)
1332       echo >&AS_MESSAGE_LOG_FD "\
1333 $libc_seen_a$libc_seen_b from:
1334 $ac_try"
1335       ;;
1336     esac
1337   fi
1338   rm -f conftest*])
1339   use_default_link=$libc_cv_use_default_link
1340 fi
1341
1342 AC_CACHE_CHECK(for GLOB_DAT reloc,
1343                libc_cv_has_glob_dat, [dnl
1344 cat > conftest.c <<EOF
1345 extern int mumble;
1346 int foo (void) { return mumble; }
1347 EOF
1348 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1349                         -fPIC -shared -o conftest.so conftest.c
1350                         -nostdlib -nostartfiles
1351                         1>&AS_MESSAGE_LOG_FD])
1352 then
1353 dnl look for GLOB_DAT relocation.
1354   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1355     libc_cv_has_glob_dat=yes
1356   else
1357     libc_cv_has_glob_dat=no
1358   fi
1359 else
1360   libc_cv_has_glob_dat=no
1361 fi
1362 rm -f conftest*])
1363 AC_SUBST(libc_cv_has_glob_dat)
1364
1365 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1366 if libc_cv_output_format=`
1367 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1368 then
1369   :
1370 else
1371   libc_cv_output_format=
1372 fi
1373 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1374 AC_SUBST(libc_cv_output_format)
1375
1376 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1377 cat > conftest.c <<EOF
1378 int foo;
1379 EOF
1380 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1381                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1382 then
1383   libc_cv_fno_toplevel_reorder=yes
1384 else
1385   libc_cv_fno_toplevel_reorder=no
1386 fi
1387 rm -f conftest*])
1388 if test $libc_cv_fno_toplevel_reorder = yes; then
1389   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1390 else
1391   fno_unit_at_a_time=-fno-unit-at-a-time
1392 fi
1393 AC_SUBST(fno_unit_at_a_time)
1394
1395 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1396 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1397                    [libc_cv_ssp=yes],
1398                    [libc_cv_ssp=no])
1399 ])
1400
1401 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1402 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1403                    [libc_cv_ssp_strong=yes],
1404                    [libc_cv_ssp_strong=no])
1405 ])
1406
1407 stack_protector=
1408 if test "$libc_cv_ssp_strong" = "yes"; then
1409   stack_protector="-fstack-protector-strong"
1410 elif test "$libc_cv_ssp" = "yes"; then
1411   stack_protector="-fstack-protector"
1412 fi
1413 AC_SUBST(stack_protector)
1414
1415 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1416 [dnl
1417 cat > conftest.c <<EOF
1418 __thread int i;
1419 void foo (void)
1420 {
1421   i = 10;
1422 }
1423 EOF
1424 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1425                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1426 then
1427   libc_cv_mtls_dialect_gnu2=yes
1428 else
1429   libc_cv_mtls_dialect_gnu2=no
1430 fi
1431 rm -f conftest*])
1432 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1433 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1434
1435 AC_CACHE_CHECK(whether cc puts quotes around section names,
1436                libc_cv_have_section_quotes,
1437                [cat > conftest.c <<EOF
1438                 static const int foo
1439                 __attribute__ ((section ("bar"))) = 1;
1440 EOF
1441                 if ${CC-cc} -S conftest.c -o conftest.s; then
1442                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1443                     libc_cv_have_section_quotes=yes
1444                   else
1445                     libc_cv_have_section_quotes=no
1446                   fi
1447                 else
1448                   libc_cv_have_section_quotes=unknown
1449                 fi
1450                 rm -f conftest.{c,s}
1451                 ])
1452 if test $libc_cv_have_section_quotes = yes; then
1453   AC_DEFINE(HAVE_SECTION_QUOTES)
1454 fi
1455
1456 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1457 cat > conftest.c <<\EOF
1458 void zero (void *x)
1459 {
1460   __builtin_memset (x, 0, 1000);
1461 }
1462 EOF
1463 dnl
1464 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1465 then
1466   libc_cv_gcc_builtin_memset=no
1467 else
1468   libc_cv_gcc_builtin_memset=yes
1469 fi
1470 rm -f conftest* ])
1471 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1472   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1473 fi
1474
1475 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1476 cat > conftest.c <<\EOF
1477 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1478 char *foo (const char *a, const char *b)
1479 {
1480   return __builtin_strstr (a, b);
1481 }
1482 EOF
1483 dnl
1484 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1485 then
1486   libc_cv_gcc_builtin_redirection=yes
1487 else
1488   libc_cv_gcc_builtin_redirection=no
1489 fi
1490 rm -f conftest* ])
1491 if test "$libc_cv_gcc_builtin_redirection" = no; then
1492   AC_MSG_ERROR([support for the symbol redirection needed])
1493 fi
1494
1495 dnl Determine how to disable generation of FMA instructions.
1496 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1497                libc_cv_cc_nofma, [dnl
1498 libc_cv_cc_nofma=
1499 for opt in -ffp-contract=off -mno-fused-madd; do
1500   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1501 done])
1502 AC_SUBST(libc_cv_cc_nofma)
1503
1504 if test -n "$submachine"; then
1505   AC_CACHE_CHECK([for compiler option for CPU variant],
1506                  libc_cv_cc_submachine, [dnl
1507   libc_cv_cc_submachine=no
1508   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1509     LIBC_TRY_CC_OPTION([$opt], [
1510       libc_cv_cc_submachine="$opt"
1511       break], [])
1512   done])
1513   if test "x$libc_cv_cc_submachine" = xno; then
1514     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1515   fi
1516 fi
1517 AC_SUBST(libc_cv_cc_submachine)
1518
1519 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1520 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1521 cat > conftest.c <<EOF
1522 void
1523 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1524 foo (void) {}
1525 EOF
1526 libc_cv_cc_loop_to_function=no
1527 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1528 then
1529   libc_cv_cc_loop_to_function=yes
1530 fi
1531 rm -f conftest*])
1532 if test $libc_cv_cc_loop_to_function = yes; then
1533   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1534 fi
1535 AC_SUBST(libc_cv_cc_loop_to_function)
1536
1537 dnl Check whether we have the gd library available.
1538 AC_MSG_CHECKING(for libgd)
1539 if test "$with_gd" != "no"; then
1540   old_CFLAGS="$CFLAGS"
1541   CFLAGS="$CFLAGS $libgd_include"
1542   old_LDFLAGS="$LDFLAGS"
1543   LDFLAGS="$LDFLAGS $libgd_ldflags"
1544   old_LIBS="$LIBS"
1545   LIBS="$LIBS -lgd -lpng -lz -lm"
1546   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1547   CFLAGS="$old_CFLAGS"
1548   LDFLAGS="$old_LDFLAGS"
1549   LIBS="$old_LIBS"
1550 else
1551   LIBGD=no
1552 fi
1553 AC_MSG_RESULT($LIBGD)
1554 AC_SUBST(LIBGD)
1555
1556 # SELinux detection
1557 if test x$with_selinux = xno ; then
1558   have_selinux=no;
1559 else
1560   # See if we have the SELinux library
1561   AC_CHECK_LIB(selinux, is_selinux_enabled,
1562                have_selinux=yes, have_selinux=no)
1563   if test x$with_selinux = xyes ; then
1564     if test x$have_selinux = xno ; then
1565       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1566     fi
1567   fi
1568 fi
1569 # Check if we're building with SELinux support.
1570 if test "x$have_selinux" = xyes; then
1571   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1572
1573   # See if we have the libaudit library
1574   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1575                have_libaudit=yes, have_libaudit=no)
1576   if test "x$have_libaudit" = xyes; then
1577     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1578   fi
1579   AC_SUBST(have_libaudit)
1580
1581   # See if we have the libcap library
1582   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1583   if test "x$have_libcap" = xyes; then
1584     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1585   fi
1586   AC_SUBST(have_libcap)
1587 fi
1588 AC_SUBST(have_selinux)
1589
1590 CPPUNDEFS=
1591 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1592 dnl Since we are building the implementations of the fortified functions here,
1593 dnl having the macro defined interacts very badly.
1594 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1595 [AC_TRY_COMPILE([], [
1596 #ifdef _FORTIFY_SOURCE
1597 # error bogon
1598 #endif],
1599                 [libc_cv_predef_fortify_source=no],
1600                 [libc_cv_predef_fortify_source=yes])])
1601 if test $libc_cv_predef_fortify_source = yes; then
1602   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1603 fi
1604 AC_SUBST(CPPUNDEFS)
1605
1606 dnl Check for silly hacked compilers inserting -fstack-protector.
1607 dnl This breaks badly for the early startup code we compile, since
1608 dnl the compiled code can refer to a magic machine-dependent location
1609 dnl for the canary value before we have sufficient setup for that to
1610 dnl work.  It's also questionable to build all of libc with this flag
1611 dnl even when you're doing that for most applications you build, since
1612 dnl libc's code is so heavily-used and performance-sensitive.  If we
1613 dnl ever really want to make that work, it should be enabled explicitly
1614 dnl in the libc build, not inherited from implicit compiler settings.
1615 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1616                libc_cv_predef_stack_protector, [
1617 AC_TRY_COMPILE([extern void foobar (char *);],
1618                [char large_array[2048]; foobar (large_array);], [
1619 libc_undefs=`$NM -u conftest.o |
1620   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1621     2>&AS_MESSAGE_LOG_FD` || {
1622   AC_MSG_ERROR([confusing output from $NM -u])
1623 }
1624 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1625 # On some architectures, there are architecture-specific undefined
1626 # symbols (resolved by the linker), so filter out unknown symbols.
1627 # This will fail to produce the correct result if the compiler
1628 # defaults to -fstack-protector but this produces an undefined symbol
1629 # other than __stack_chk_fail or __stack_chk_fail_local. However,
1630 # compilers like that have not been encountered in practice.
1631 libc_undefs=`echo "$libc_undefs" | \
1632   egrep '^(foobar|__stack_chk_fail|__stack_chk_fail_local)$'`
1633 case "$libc_undefs" in
1634 foobar) libc_cv_predef_stack_protector=no ;;
1635 '__stack_chk_fail
1636 foobar'|'__stack_chk_fail_local
1637 foobar') libc_cv_predef_stack_protector=yes ;;
1638 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1639 esac],
1640                [AC_MSG_ERROR([test compilation failed])])
1641 ])
1642 libc_extra_cflags=
1643 if test $libc_cv_predef_stack_protector = yes; then
1644   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1645 fi
1646 libc_extra_cppflags=
1647
1648 # Some linkers on some architectures support __ehdr_start but with
1649 # bugs.  Make sure usage of it does not create relocations in the
1650 # output (as the linker should resolve them all for us).
1651 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1652                libc_cv_ehdr_start, [
1653 old_CFLAGS="$CFLAGS"
1654 old_LDFLAGS="$LDFLAGS"
1655 old_LIBS="$LIBS"
1656 CFLAGS="$CFLAGS -fPIC"
1657 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1658 LIBS=
1659 AC_LINK_IFELSE([AC_LANG_SOURCE([
1660 typedef struct {
1661   char foo;
1662   long val;
1663 } Ehdr;
1664 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1665 long ehdr (void) { return __ehdr_start.val; }
1666 ])],
1667                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1668                   libc_cv_ehdr_start=broken
1669                 else
1670                   libc_cv_ehdr_start=yes
1671                 fi], [libc_cv_ehdr_start=no])
1672 CFLAGS="$old_CFLAGS"
1673 LDFLAGS="$old_LDFLAGS"
1674 LIBS="$old_LIBS"
1675 ])
1676 if test "$libc_cv_ehdr_start" = yes; then
1677   AC_DEFINE([HAVE_EHDR_START])
1678 elif test "$libc_cv_ehdr_start" = broken; then
1679   AC_MSG_WARN([linker is broken -- you should upgrade])
1680 fi
1681
1682 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1683                libc_cv_builtin_trap, [dnl
1684 libc_cv_builtin_trap=no
1685 AC_TRY_COMPILE([], [__builtin_trap ()], [
1686 libc_undefs=`$NM -u conftest.o |
1687   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1688     2>&AS_MESSAGE_LOG_FD` || {
1689   AC_MSG_ERROR([confusing output from $NM -u])
1690 }
1691 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1692 if test -z "$libc_undefs"; then
1693   libc_cv_builtin_trap=yes
1694 fi])])
1695 if test $libc_cv_builtin_trap = yes; then
1696   AC_DEFINE([HAVE_BUILTIN_TRAP])
1697 fi
1698
1699 dnl C++ feature tests.
1700 AC_LANG_PUSH([C++])
1701
1702 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1703                libc_cv_cxx_thread_local, [
1704 old_CXXFLAGS="$CXXFLAGS"
1705 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1706 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1707 #include <thread>
1708
1709 // Compiler support.
1710 struct S
1711 {
1712   S ();
1713   ~S ();
1714 };
1715 thread_local S s;
1716 S * get () { return &s; }
1717
1718 // libstdc++ support.
1719 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1720 #error __cxa_thread_atexit_impl not supported
1721 #endif
1722 ])],
1723                [libc_cv_cxx_thread_local=yes],
1724                [libc_cv_cxx_thread_local=no])
1725 CXXFLAGS="$old_CXXFLAGS"
1726 ])
1727 AC_SUBST(libc_cv_cxx_thread_local)
1728
1729 AC_LANG_POP([C++])
1730 dnl End of C++ feature tests.
1731
1732 ### End of automated tests.
1733 ### Now run sysdeps configure fragments.
1734
1735 # They also can set these variables.
1736 use_ldconfig=no
1737 ldd_rewrite_script=no
1738 libc_cv_sysconfdir=$sysconfdir
1739 libc_cv_localstatedir=$localstatedir
1740 libc_cv_gcc_unwind_find_fde=no
1741 libc_cv_idn=no
1742
1743 # Iterate over all the sysdep directories we will use, running their
1744 # configure fragments.
1745 for dir in $sysnames; do
1746   case $dir in
1747     /*) dest=$dir ;;
1748     *)  dest=$srcdir/$dir ;;
1749   esac
1750   if test -r $dest/configure; then
1751     AC_MSG_RESULT(running configure fragment for $dir)
1752     . $dest/configure
1753   fi
1754 done
1755
1756 if test x"$build_mathvec" = xnotset; then
1757   build_mathvec=no
1758 fi
1759 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1760
1761 AC_SUBST(libc_extra_cflags)
1762 AC_SUBST(libc_extra_cppflags)
1763
1764 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1765   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1766 fi
1767 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1768
1769 # A sysdeps configure fragment can reset this if IFUNC is not actually
1770 # usable even though the assembler knows how to generate the symbol type.
1771 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1772   AC_DEFINE(HAVE_IFUNC)
1773 fi
1774
1775 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1776 # configure fragment can override the value to prevent this AC_DEFINE.
1777 AC_SUBST(use_nscd)
1778 if test "x$use_nscd" != xno; then
1779   AC_DEFINE([USE_NSCD])
1780 fi
1781 if test "x$build_nscd" = xdefault; then
1782   build_nscd=$use_nscd
1783 fi
1784
1785 AC_SUBST(libc_cv_slibdir)
1786 AC_SUBST(libc_cv_rtlddir)
1787 AC_SUBST(libc_cv_complocaledir)
1788 AC_SUBST(libc_cv_sysconfdir)
1789 AC_SUBST(libc_cv_localstatedir)
1790 AC_SUBST(libc_cv_rootsbindir)
1791
1792 if test x$use_ldconfig = xyes; then
1793   AC_DEFINE(USE_LDCONFIG)
1794 fi
1795 AC_SUBST(use_ldconfig)
1796 AC_SUBST(ldd_rewrite_script)
1797
1798 AC_SUBST(static)
1799 AC_SUBST(shared)
1800
1801 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1802 [libc_cv_pic_default=yes
1803 cat > conftest.c <<EOF
1804 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1805 # error PIC is default.
1806 #endif
1807 EOF
1808 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1809   libc_cv_pic_default=no
1810 fi
1811 rm -f conftest.*])
1812 AC_SUBST(libc_cv_pic_default)
1813
1814 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1815 [libc_cv_pie_default=yes
1816 cat > conftest.c <<EOF
1817 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1818 # error PIE is default.
1819 #endif
1820 EOF
1821 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1822   libc_cv_pie_default=no
1823 fi
1824 rm -f conftest.*])
1825 AC_SUBST(libc_cv_pie_default)
1826
1827 AC_SUBST(profile)
1828 AC_SUBST(static_nss)
1829
1830 AC_SUBST(DEFINES)
1831
1832 dnl See sysdeps/mach/configure.ac for this variable.
1833 AC_SUBST(mach_interface_list)
1834
1835 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1836 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1837 AC_SUBST(VERSION)
1838 AC_SUBST(RELEASE)
1839
1840 AC_CONFIG_FILES([config.make Makefile])
1841 AC_CONFIG_COMMANDS([default],[[
1842 case $CONFIG_FILES in *config.make*)
1843 echo "$config_vars" >> config.make;;
1844 esac
1845 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1846 AC_OUTPUT