configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
   4   [glibc], [https://www.gnu.org/software/glibc/])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 ACX_PKGVERSION([GNU libc])
  10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
  11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  12                    [Package description])
  13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  14                    [Bug reporting address])
  15
  16 # Glibc should not depend on any header files
  17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  18   [m4_divert_text([DEFAULTS],
  19     [ac_includes_default='/* none */'])])
  20
  21 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  22 # here to work around the Autoconf issue discussed in
  23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  24 AC_DEFUN([AC_PROG_CPP],
  25 [AC_REQUIRE([AC_PROG_CC])dnl
  26 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  27 _AC_ARG_VAR_CPPFLAGS()dnl
  28 # On Suns, sometimes $CPP names a directory.
  29 if test -n "$CPP" && test -d "$CPP"; then
  30   CPP=
  31 fi
  32 if test -z "$CPP"; then
  33   CPP="$CC -E"
  34 fi
  35 AC_SUBST(CPP)dnl
  36 ])# AC_PROG_CPP
  37
  38 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  39 # issue discussed in
  40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  42
  43 dnl This is here so we can set $subdirs directly based on configure fragments.
  44 AC_CONFIG_SUBDIRS()
  45
  46 AC_CANONICAL_HOST
  47
  48 AC_PROG_CC
  49 if test $host != $build; then
  50   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  51 fi
  52 AC_SUBST(cross_compiling)
  53 AC_PROG_CPP
  54 AC_CHECK_TOOL(READELF, readelf, false)
  55
  56 # We need the C++ compiler only for testing.
  57 AC_PROG_CXX
  58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  60 AC_LANG_PUSH([C++])
  61 # Default, dynamic case.
  62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  63                [libc_cv_cxx_link_ok=yes],
  64                [libc_cv_cxx_link_ok=no])
  65 # Static case.
  66 old_LDFLAGS="$LDFLAGS"
  67 LDFLAGS="$LDFLAGS -static"
  68 AC_LINK_IFELSE([AC_LANG_SOURCE([
  69 #include <iostream>
  70
  71 int
  72 main()
  73 {
  74   std::cout << "Hello, world!";
  75   return 0;
  76 }
  77 ])],
  78                [],
  79                [libc_cv_cxx_link_ok=no])
  80 LDFLAGS="$old_LDFLAGS"
  81 AC_LANG_POP([C++])])
  82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  83
  84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  85   AC_MSG_ERROR([you must configure in a separate build directory])
  86 fi
  87
  88 # This will get text that should go into config.make.
  89 config_vars=
  90
  91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  92 AC_ARG_WITH([gd],
  93             AC_HELP_STRING([--with-gd=DIR],
  94                            [find libgd include dir and library with prefix DIR]),
  95             [dnl
  96 case "$with_gd" in
  97 yes|''|no) ;;
  98 *) libgd_include="-I$withval/include"
  99    libgd_ldflags="-L$withval/lib" ;;
 100 esac
 101 ])
 102 AC_ARG_WITH([gd-include],
 103             AC_HELP_STRING([--with-gd-include=DIR],
 104                            [find libgd include files in DIR]),
 105             [dnl
 106 case "$with_gd_include" in
 107 ''|no) ;;
 108 *) libgd_include="-I$withval" ;;
 109 esac
 110 ])
 111 AC_ARG_WITH([gd-lib],
 112             AC_HELP_STRING([--with-gd-lib=DIR],
 113                            [find libgd library files in DIR]),
 114             [dnl
 115 case "$with_gd_lib" in
 116 ''|no) ;;
 117 *) libgd_ldflags="-L$withval" ;;
 118 esac
 119 ])
 120
 121 if test -n "$libgd_include"; then
 122   config_vars="$config_vars
 123 CFLAGS-memusagestat.c = $libgd_include"
 124 fi
 125 if test -n "$libgd_ldflags"; then
 126   config_vars="$config_vars
 127 libgd-LDFLAGS = $libgd_ldflags"
 128 fi
 129
 130 dnl Arguments to specify presence of other packages/features.
 131 AC_ARG_WITH([binutils],
 132             AC_HELP_STRING([--with-binutils=PATH],
 133                            [specify location of binutils (as and ld)]),
 134             [path_binutils=$withval],
 135             [path_binutils=''])
 136 AC_ARG_WITH([selinux],
 137             AC_HELP_STRING([--with-selinux],
 138                            [if building with SELinux support]),
 139             [with_selinux=$withval],
 140             [with_selinux=auto])
 141
 142 AC_ARG_WITH([headers],
 143             AC_HELP_STRING([--with-headers=PATH],
 144                            [location of system headers to use
 145                             (for example /usr/src/linux/include)
 146                             @<:@default=compiler default@:>@]),
 147             [sysheaders=$withval],
 148             [sysheaders=''])
 149 AC_SUBST(sysheaders)
 150
 151 AC_SUBST(use_default_link)
 152 AC_ARG_WITH([default-link],
 153             AC_HELP_STRING([--with-default-link],
 154                            [do not use explicit linker scripts]),
 155             [use_default_link=$withval],
 156             [use_default_link=default])
 157
 158 dnl Additional build flags injection.
 159 AC_ARG_WITH([nonshared-cflags],
 160             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 161                            [build nonshared libraries with additional CFLAGS]),
 162             [extra_nonshared_cflags=$withval],
 163             [extra_nonshared_cflags=])
 164 AC_SUBST(extra_nonshared_cflags)
 165
 166 AC_ARG_ENABLE([sanity-checks],
 167               AC_HELP_STRING([--disable-sanity-checks],
 168                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 169               [enable_sanity=$enableval],
 170               [enable_sanity=yes])
 171
 172 AC_ARG_ENABLE([shared],
 173               AC_HELP_STRING([--enable-shared],
 174                              [build shared library @<:@default=yes if GNU ld@:>@]),
 175               [shared=$enableval],
 176               [shared=yes])
 177 AC_ARG_ENABLE([profile],
 178               AC_HELP_STRING([--enable-profile],
 179                              [build profiled library @<:@default=no@:>@]),
 180               [profile=$enableval],
 181               [profile=no])
 182 AC_ARG_ENABLE([static-pie],
 183               AC_HELP_STRING([--enable-static-pie],
 184                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 185               [static_pie=$enableval],
 186               [static_pie=no])
 187 AC_ARG_ENABLE([timezone-tools],
 188               AC_HELP_STRING([--disable-timezone-tools],
 189                              [do not install timezone tools @<:@default=install@:>@]),
 190               [enable_timezone_tools=$enableval],
 191               [enable_timezone_tools=yes])
 192 AC_SUBST(enable_timezone_tools)
 193
 194 AC_ARG_ENABLE([hardcoded-path-in-tests],
 195               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 196                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 197               [hardcoded_path_in_tests=$enableval],
 198               [hardcoded_path_in_tests=no])
 199 AC_SUBST(hardcoded_path_in_tests)
 200
 201 AC_ARG_ENABLE([stackguard-randomization],
 202               AC_HELP_STRING([--enable-stackguard-randomization],
 203                              [initialize __stack_chk_guard canary with a random number at program start]),
 204               [enable_stackguard_randomize=$enableval],
 205               [enable_stackguard_randomize=no])
 206 if test "$enable_stackguard_randomize" = yes; then
 207   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 208 fi
 209
 210 AC_ARG_ENABLE([hidden-plt],
 211               AC_HELP_STRING([--disable-hidden-plt],
 212                              [do not hide internal function calls to avoid PLT]),
 213               [hidden=$enableval],
 214               [hidden=yes])
 215 if test "x$hidden" = xno; then
 216   AC_DEFINE(NO_HIDDEN)
 217 fi
 218
 219 AC_ARG_ENABLE([bind-now],
 220               AC_HELP_STRING([--enable-bind-now],
 221                              [disable lazy relocations in DSOs]),
 222               [bindnow=$enableval],
 223               [bindnow=no])
 224 AC_SUBST(bindnow)
 225 if test "x$bindnow" = xyes; then
 226   AC_DEFINE(BIND_NOW)
 227 fi
 228
 229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 230 dnl -fstack-protector-strong.
 231 AC_ARG_ENABLE([stack-protector],
 232               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 233                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 234               [enable_stack_protector=$enableval],
 235               [enable_stack_protector=no])
 236 case "$enable_stack_protector" in
 237 all|yes|no|strong) ;;
 238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 239 esac
 240
 241 dnl On some platforms we cannot use dynamic loading.  We must provide
 242 dnl static NSS modules.
 243 AC_ARG_ENABLE([static-nss],
 244               AC_HELP_STRING([--enable-static-nss],
 245                              [build static NSS modules @<:@default=no@:>@]),
 246               [static_nss=$enableval],
 247               [static_nss=no])
 248 dnl Enable static NSS also if we build no shared objects.
 249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 250   static_nss=yes
 251   AC_DEFINE(DO_STATIC_NSS)
 252 fi
 253
 254 AC_ARG_ENABLE([force-install],
 255               AC_HELP_STRING([--disable-force-install],
 256                              [don't force installation of files from this package, even if they are older than the installed files]),
 257               [force_install=$enableval],
 258               [force_install=yes])
 259 AC_SUBST(force_install)
 260
 261 AC_ARG_ENABLE([maintainer-mode],
 262               AC_HELP_STRING([--enable-maintainer-mode],
 263                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 264               [maintainer=$enableval],
 265               [maintainer=no])
 266
 267 dnl On some platforms we allow dropping compatibility with all kernel
 268 dnl versions.
 269 AC_ARG_ENABLE([kernel],
 270               AC_HELP_STRING([--enable-kernel=VERSION],
 271                              [compile for compatibility with kernel not older than VERSION]),
 272               [minimum_kernel=$enableval],
 273               [])
 274 dnl Prevent unreasonable values.
 275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 276   # Better nothing than this.
 277   minimum_kernel=""
 278 else
 279   if test "$minimum_kernel" = current; then
 280     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 281   fi
 282 fi
 283
 284 dnl For the development we sometimes want gcc to issue even more warnings.
 285 dnl This is not the default since many of the extra warnings are not
 286 dnl appropriate.
 287 AC_ARG_ENABLE([all-warnings],
 288               AC_HELP_STRING([--enable-all-warnings],
 289                              [enable all useful warnings gcc can issue]),
 290               [all_warnings=$enableval],
 291               [])
 292 AC_SUBST(all_warnings)
 293
 294 AC_ARG_ENABLE([werror],
 295               AC_HELP_STRING([--disable-werror],
 296                              [do not build with -Werror]),
 297               [enable_werror=$enableval],
 298               [enable_werror=yes])
 299 AC_SUBST(enable_werror)
 300
 301 AC_ARG_ENABLE([multi-arch],
 302               AC_HELP_STRING([--enable-multi-arch],
 303                              [enable single DSO with optimizations for multiple architectures]),
 304               [multi_arch=$enableval],
 305               [multi_arch=default])
 306
 307 AC_ARG_ENABLE([experimental-malloc],
 308               AC_HELP_STRING([--disable-experimental-malloc],
 309                              [disable experimental malloc features]),
 310               [experimental_malloc=$enableval],
 311               [experimental_malloc=yes])
 312 AC_SUBST(experimental_malloc)
 313
 314 AC_ARG_ENABLE([crypt],
 315               AC_HELP_STRING([--disable-crypt],
 316                              [do not build nor install the passphrase hashing library, libcrypt]),
 317               [build_crypt=$enableval],
 318               [build_crypt=yes])
 319 AC_SUBST(build_crypt)
 320
 321 AC_ARG_ENABLE([nss-crypt],
 322               AC_HELP_STRING([--enable-nss-crypt],
 323                              [enable libcrypt to use nss]),
 324               [nss_crypt=$enableval],
 325               [nss_crypt=no])
 326 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 327   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 328   nss_crypt=no
 329 fi
 330 if test x$nss_crypt = xyes; then
 331   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 332   if test $? -ne 0; then
 333     AC_MSG_ERROR([cannot find include directory with nss-config])
 334   fi
 335   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 336   if test $? -ne 0; then
 337     AC_MSG_ERROR([cannot find include directory with nspr-config])
 338   fi
 339   old_CFLAGS="$CFLAGS"
 340   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 341   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 342 #include <hasht.h>
 343 #include <nsslowhash.h>
 344 void f (void) { NSSLOW_Init (); }])],
 345              libc_cv_nss_crypt=yes,
 346              AC_MSG_ERROR([
 347 cannot find NSS headers with lowlevel hash function interfaces]))
 348   old_LIBS="$LIBS"
 349   old_LDFLAGS="$LDFLAGS"
 350   LIBS="$LIBS -lfreebl3"
 351   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 352 #include <hasht.h>
 353 #include <nsslowhash.h>],
 354                                   [NSSLOW_Init();])],
 355                  libc_cv_nss_crypt=yes,
 356                  AC_MSG_ERROR([
 357 cannot link program using lowlevel NSS hash functions]))
 358   # Check to see if there is a static NSS cryptographic library.
 359   # If there isn't then we can't link anything with libcrypt.a,
 360   # and that might mean disabling some static tests.
 361   LDFLAGS="$LDFLAGS -static"
 362   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 363 #include <hasht.h>
 364 #include <nsslowhash.h>],
 365                                   [NSSLOW_Init();])],
 366                  libc_cv_static_nss_crypt=yes,
 367                  libc_cv_static_nss_crypt=no)
 368   LDFLAGS="$old_LDFLAGS"
 369   CFLAGS="$old_CFLAGS"
 370   LIBS="$old_LIBS"
 371 else
 372   libc_cv_nss_crypt=no
 373   libc_cv_static_nss_crypt=no
 374 fi
 375 AC_SUBST(libc_cv_nss_crypt)
 376 AC_SUBST(libc_cv_static_nss_crypt)
 377
 378
 379 AC_ARG_ENABLE([systemtap],
 380               [AS_HELP_STRING([--enable-systemtap],
 381                [enable systemtap static probe points @<:@default=no@:>@])],
 382               [systemtap=$enableval],
 383               [systemtap=no])
 384 if test "x$systemtap" != xno; then
 385   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 386   old_CFLAGS="$CFLAGS"
 387   CFLAGS="-std=gnu11 $CFLAGS"
 388   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 389 void foo (int i, void *p)
 390 {
 391   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 392        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 393 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 394   CFLAGS="$old_CFLAGS"])
 395   if test $libc_cv_sdt = yes; then
 396     AC_DEFINE([USE_STAP_PROBE])
 397   elif test "x$systemtap" != xauto; then
 398     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 399   fi
 400 fi
 401
 402 AC_ARG_ENABLE([build-nscd],
 403               [AS_HELP_STRING([--disable-build-nscd],
 404                [disable building and installing the nscd daemon])],
 405               [build_nscd=$enableval],
 406               [build_nscd=default])
 407 AC_SUBST(build_nscd)
 408
 409 # Note the use of $use_nscd is near the bottom of the file.
 410 AC_ARG_ENABLE([nscd],
 411               [AS_HELP_STRING([--disable-nscd],
 412                [library functions will not contact the nscd daemon])],
 413               [use_nscd=$enableval],
 414               [use_nscd=yes])
 415
 416 AC_ARG_ENABLE([pt_chown],
 417               [AS_HELP_STRING([--enable-pt_chown],
 418                [Enable building and installing pt_chown])],
 419               [build_pt_chown=$enableval],
 420               [build_pt_chown=no])
 421 AC_SUBST(build_pt_chown)
 422 if test "$build_pt_chown" = yes; then
 423   AC_DEFINE(HAVE_PT_CHOWN)
 424 fi
 425
 426 AC_ARG_ENABLE([tunables],
 427               [AS_HELP_STRING([--enable-tunables],
 428                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 429               [have_tunables=$enableval],
 430               [have_tunables=yes])
 431 AC_SUBST(have_tunables)
 432 if test "$have_tunables" = yes; then
 433   AC_DEFINE(HAVE_TUNABLES)
 434 fi
 435
 436 # The abi-tags file uses a fairly simplistic model for name recognition that
 437 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 438 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 439 # This doesn't get used much beyond that, so it's fairly safe.
 440 case "$host_os" in
 441 linux*)
 442   ;;
 443 gnu*)
 444   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 445   ;;
 446 esac
 447
 448 AC_ARG_ENABLE([mathvec],
 449               [AS_HELP_STRING([--enable-mathvec],
 450               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 451               [build_mathvec=$enableval],
 452               [build_mathvec=notset])
 453
 454 AC_TRY_COMPILE([], [
 455 #ifndef __CET__
 456 # error no CET compiler support
 457 #endif],
 458                [libc_cv_compiler_default_cet=yes],
 459                [libc_cv_compiler_default_cet=no])
 460
 461 AC_ARG_ENABLE([cet],
 462               AC_HELP_STRING([--enable-cet],
 463                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 464               [enable_cet=$enableval],
 465               [enable_cet=$libc_cv_compiler_default_cet])
 466
 467 # We keep the original values in `$config_*' and never modify them, so we
 468 # can write them unchanged into config.make.  Everything else uses
 469 # $machine, $vendor, and $os, and changes them whenever convenient.
 470 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 471
 472 # Don't allow vendor == "unknown"
 473 test "$config_vendor" = unknown && config_vendor=
 474 config_os="`echo $config_os | sed 's/^unknown-//'`"
 475
 476 # Some configurations imply other options.
 477 elf=yes
 478
 479 # The configure fragment of a port can modify these to supplement
 480 # or override the table in the case statement below.  No fragment should
 481 # ever change the config_* variables, however.
 482 machine=$config_machine
 483 vendor=$config_vendor
 484 os=$config_os
 485 base_os=''
 486
 487 submachine=
 488 AC_ARG_WITH([cpu],
 489             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 490             [dnl
 491   case "$withval" in
 492   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 493   no) ;;
 494   *) submachine="$withval" ;;
 495   esac
 496 ])
 497
 498 # An preconfigure script can set this when it wants to disable the sanity
 499 # check below.
 500 libc_config_ok=no
 501
 502 # A preconfigure script for a system that may or may not use fpu
 503 # sysdeps directories sets this to a preprocessor conditional for
 504 # whether to use such directories.
 505 with_fp_cond=1
 506
 507 dnl Let sysdeps/*/preconfigure act here.
 508 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 509
 510
 511 ###
 512 ### By using the undocumented --enable-hacker-mode option for configure
 513 ### one can skip this test to make the configuration not fail for unsupported
 514 ### platforms.
 515 ###
 516 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 517   case "$machine-$host_os" in
 518   *-linux* | *-gnu*)
 519     ;;
 520   *)
 521     AC_MSG_ERROR([
 522 *** The GNU C library is currently unavailable for this platform.
 523 *** If you are interested in seeing glibc on this platform visit
 524 *** the "How to submit a new port" in the wiki:
 525 ***   https://sourceware.org/glibc/wiki/#Development
 526 *** and join the community!])
 527     ;;
 528   esac
 529 fi
 530
 531 # Set base_machine if not set by a preconfigure fragment.
 532 test -n "$base_machine" || base_machine=$machine
 533 AC_SUBST(base_machine)
 534
 535 # Determine whether to use fpu or nofpu sysdeps directories.
 536 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 537                libc_cv_with_fp, [dnl
 538 cat > conftest.c <<EOF
 539 #if $with_fp_cond
 540 int dummy;
 541 #else
 542 # error "no hardware floating point"
 543 #endif
 544 EOF
 545 libc_cv_with_fp=no
 546 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 547    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 548   libc_cv_with_fp=yes
 549 fi
 550 rm -f conftest*])
 551 AC_SUBST(libc_cv_with_fp)
 552
 553 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 554 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 555                    [libc_cv_ssp=yes],
 556                    [libc_cv_ssp=no])
 557 ])
 558
 559 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 560 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 561                    [libc_cv_ssp_strong=yes],
 562                    [libc_cv_ssp_strong=no])
 563 ])
 564
 565 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 566 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 567                    [libc_cv_ssp_all=yes],
 568                    [libc_cv_ssp_all=no])
 569 ])
 570
 571 stack_protector=
 572 no_stack_protector=
 573 if test "$libc_cv_ssp" = yes; then
 574   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 575   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 576 fi
 577
 578 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 579   stack_protector="-fstack-protector"
 580   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 581 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 582   stack_protector="-fstack-protector-all"
 583   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 584 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 585   stack_protector="-fstack-protector-strong"
 586   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 587 else
 588   stack_protector="-fno-stack-protector"
 589   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 590 fi
 591 AC_SUBST(libc_cv_ssp)
 592 AC_SUBST(stack_protector)
 593 AC_SUBST(no_stack_protector)
 594
 595 if test -n "$stack_protector"; then
 596   dnl Don't run configure tests with stack-protection on, to avoid problems with
 597   dnl bootstrapping.
 598   no_ssp=-fno-stack-protector
 599 else
 600   no_ssp=
 601
 602   if test "$enable_stack_protector" != no; then
 603     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 604   fi
 605 fi
 606
 607 # For the multi-arch option we need support in the assembler & linker.
 608 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 609                libc_cv_ld_gnu_indirect_function, [dnl
 610 cat > conftest.S <<EOF
 611 .type foo,%gnu_indirect_function
 612 foo:
 613 .globl _start
 614 _start:
 615 .globl __start
 616 __start:
 617 .data
 618 #ifdef _LP64
 619 .quad foo
 620 #else
 621 .long foo
 622 #endif
 623 EOF
 624 libc_cv_ld_gnu_indirect_function=no
 625 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 626             -nostartfiles -nostdlib $no_ssp \
 627             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 628   # Do a link to see if the backend supports IFUNC relocs.
 629   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 630   LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
 631     libc_cv_ld_gnu_indirect_function=yes
 632   }
 633 fi
 634 rm -f conftest*])
 635
 636 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 637 AC_CACHE_CHECK([for gcc attribute ifunc support],
 638                libc_cv_gcc_indirect_function, [dnl
 639 cat > conftest.c <<EOF
 640 extern int func (int);
 641 int used_func (int a)
 642 {
 643   return a;
 644 }
 645 static void *resolver ()
 646 {
 647   return &used_func;
 648 }
 649 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 650 EOF
 651 libc_cv_gcc_indirect_function=no
 652 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 653    2>&AS_MESSAGE_LOG_FD ; then
 654   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 655     libc_cv_gcc_indirect_function=yes
 656   fi
 657 fi
 658 rm -f conftest*])
 659
 660 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 661 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 662 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 663                libc_cv_textrel_ifunc, [dnl
 664 cat > conftest.S <<EOF
 665 .type foo,%gnu_indirect_function
 666 foo:
 667 .globl _start
 668 _start:
 669 .globl __start
 670 __start:
 671 .data
 672 #ifdef _LP64
 673 .quad foo
 674 #else
 675 .long foo
 676 #endif
 677 .text
 678 .globl address
 679 address:
 680 #ifdef _LP64
 681 .quad address
 682 #else
 683 .long address
 684 #endif
 685 EOF
 686 libc_cv_textrel_ifunc=no
 687 if test $libc_cv_ld_gnu_indirect_function = yes; then
 688    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 689      libc_cv_textrel_ifunc=yes
 690    fi
 691 fi
 692 rm -f conftest*])
 693 AC_SUBST(libc_cv_textrel_ifunc)
 694
 695 # Check if gcc warns about alias for function with incompatible types.
 696 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 697                libc_cv_gcc_incompatible_alias, [dnl
 698 cat > conftest.c <<EOF
 699 int __redirect_foo (const void *s, int c);
 700
 701 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 702 __typeof (__redirect_foo) *foo_impl (void)
 703 {
 704   return 0;
 705 }
 706
 707 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 708 EOF
 709 libc_cv_gcc_incompatible_alias=yes
 710 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 711   libc_cv_gcc_incompatible_alias=no
 712 fi
 713 rm -f conftest*])
 714
 715 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 716   if test x"$multi_arch" = xyes; then
 717     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 718   else
 719     multi_arch=no
 720   fi
 721 fi
 722 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 723   # GCC 8+ emits a warning for alias with incompatible types and it might
 724   # fail to build ifunc resolvers aliases to either weak or internal
 725   # symbols.  Disables multiarch build in this case.
 726   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 727     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 728     if test x"$multi_arch" = xyes; then
 729       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 730     fi
 731     AC_MSG_WARN([Multi-arch is disabled.])
 732     multi_arch=no
 733   elif test x"$multi_arch" = xyes; then
 734     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 735 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 736   fi
 737 fi
 738 multi_arch_d=
 739 if test x"$multi_arch" != xno; then
 740   multi_arch_d=/multiarch
 741 fi
 742
 743 # Compute the list of sysdep directories for this configuration.
 744 # This can take a while to compute.
 745 sysdep_dir=$srcdir/sysdeps
 746 AC_MSG_CHECKING(sysdep dirs)
 747 dnl We need to use [ and ] for other purposes for a while now.
 748 changequote(,)dnl
 749 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 750 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 751
 752 test "x$base_os" != x || case "$os" in
 753 gnu*)
 754   base_os=mach/hurd ;;
 755 linux*)
 756   base_os=unix/sysv ;;
 757 esac
 758
 759 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 760 tail=$os
 761 ostry=$os
 762 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 763   ostry="$ostry /$o"
 764   tail=$o
 765 done
 766 o=`echo $tail | sed 's/[0-9]*$//'`
 767 if test $o != $tail; then
 768   ostry="$ostry /$o"
 769 fi
 770 # For linux-gnu, try linux-gnu, then linux.
 771 o=`echo $tail | sed 's/-.*$//'`
 772 if test $o != $tail; then
 773   ostry="$ostry /$o"
 774 fi
 775
 776 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 777 base=
 778 tail=$base_os
 779 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 780   set $b
 781   base="$base /$1"
 782   tail="$2"
 783 done
 784
 785 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 786 mach=
 787 tail=$machine${submachine:+/$submachine}
 788 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 789   set $m
 790   # Prepend the machine's FPU directory unless the architecture specific
 791   # preconfigure disables it.
 792   if test "$libc_cv_with_fp" = yes; then
 793     maybe_fpu=/fpu
 794   else
 795     maybe_fpu=/nofpu
 796   fi
 797   # For each machine term, try it with and then without /multiarch.
 798   for try_fpu in $maybe_fpu ''; do
 799     for try_multi in $multi_arch_d ''; do
 800       mach="$mach /$1$try_fpu$try_multi"
 801     done
 802   done
 803   tail="$2"
 804 done
 805
 806 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 807 changequote([,])dnl
 808
 809 # Find what sysdep directories exist.
 810 sysnames=
 811 for b in $base ''; do
 812   for m0 in $mach ''; do
 813     for v in /$vendor ''; do
 814       test "$v" = / && continue
 815       for o in /$ostry ''; do
 816         test "$o" = / && continue
 817         for m in $mach ''; do
 818           try_suffix="$m0$b$v$o$m"
 819           if test -n "$try_suffix"; then
 820             try_srcdir="${srcdir}/"
 821             try="sysdeps$try_suffix"
 822             test -n "$enable_debug_configure" &&
 823             echo "$0 [DEBUG]: try $try" >&2
 824             if test -d "$try_srcdir$try"; then
 825               sysnames="$sysnames $try"
 826               { test -n "$o" || test -n "$b"; } && os_used=t
 827               { test -n "$m" || test -n "$m0"; } && machine_used=t
 828               case x${m0:-$m} in
 829               x*/$submachine) submachine_used=t ;;
 830               esac
 831             fi
 832           fi
 833         done
 834       done
 835     done
 836   done
 837 done
 838
 839 # If the assembler supports gnu_indirect_function symbol type and the
 840 # architecture supports multi-arch, we enable multi-arch by default.
 841 case $sysnames in
 842 *"$multi_arch_d"*)
 843   ;;
 844 *)
 845   test x"$multi_arch" = xdefault && multi_arch=no
 846   ;;
 847 esac
 848 if test x"$multi_arch" != xno; then
 849   AC_DEFINE(USE_MULTIARCH)
 850 fi
 851 AC_SUBST(multi_arch)
 852
 853 if test -z "$os_used" && test "$os" != none; then
 854   AC_MSG_ERROR(Operating system $os is not supported.)
 855 fi
 856 if test -z "$machine_used" && test "$machine" != none; then
 857   AC_MSG_ERROR(The $machine is not supported.)
 858 fi
 859 if test -z "$submachine_used" && test -n "$submachine"; then
 860   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 861 fi
 862 AC_SUBST(submachine)
 863
 864 # We have now validated the configuration.
 865
 866 # Expand the list of system names into a full list of directories
 867 # from each element's parent name and Implies file (if present).
 868 set $sysnames
 869 names=
 870 while test $# -gt 0; do
 871   name=$1
 872   shift
 873
 874   case " $names " in *" $name "*)
 875     # Already in the list.
 876     continue
 877   esac
 878
 879   # Report each name as we discover it, so there is no long pause in output.
 880   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 881
 882   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 883
 884   case $name in
 885     /*) xsrcdir= ;;
 886     *)  xsrcdir=$srcdir/ ;;
 887   esac
 888   test -n "$enable_debug_configure" &&
 889   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 890
 891   for implies_file in Implies Implies-before Implies-after; do
 892     implies_type=`echo $implies_file | sed s/-/_/`
 893     eval ${implies_type}=
 894     if test -f $xsrcdir$name/$implies_file; then
 895       # Collect more names from the `Implies' file (removing comments).
 896       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 897       for x in $implied_candidate; do
 898         found=no
 899         if test -d $xsrcdir$name_base/$x; then
 900           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 901           found=yes
 902         fi
 903         try="sysdeps/$x"
 904         try_srcdir=$srcdir/
 905         test -n "$enable_debug_configure" &&
 906          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 907         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 908         then
 909           eval "${implies_type}=\"\$${implies_type} \$try\""
 910           found=yes
 911         fi
 912         if test $found = no; then
 913           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 914         fi
 915       done
 916     fi
 917   done
 918
 919   # Add NAME to the list of names.
 920   names="$names $name"
 921
 922   # Find the parent of NAME, using the empty string if it has none.
 923 changequote(,)dnl
 924   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 925 changequote([,])dnl
 926
 927   test -n "$enable_debug_configure" &&
 928     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 929 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 930
 931   # Add the names implied by NAME, and NAME's parent (if it has one), to
 932   # the list of names to be processed (the argument list).  We prepend the
 933   # implied names to the list and append the parent.  We want implied
 934   # directories to come before further directories inferred from the
 935   # configuration components; this ensures that for sysv4, unix/common
 936   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 937   # after sysv4).
 938   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 939   test -n "$sysnames" && set $sysnames
 940 done
 941
 942 # Add the default directories.
 943 default_sysnames="sysdeps/generic"
 944 sysnames="$names $default_sysnames"
 945 AC_SUBST(sysnames)
 946 # The other names were emitted during the scan.
 947 AC_MSG_RESULT($default_sysnames)
 948
 949
 950 ### Locate tools.
 951
 952 AC_PROG_INSTALL
 953 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 954   # The makefiles need to use a different form to find it in $srcdir.
 955   INSTALL='\$(..)./scripts/install-sh -c'
 956 fi
 957 AC_PROG_LN_S
 958
 959 LIBC_PROG_BINUTILS
 960
 961 # Accept binutils 2.25 or newer.
 962 AC_CHECK_PROG_VER(AS, $AS, --version,
 963                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 964                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 965                   AS=: critic_missing="$critic_missing as")
 966
 967 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 968   # Accept gold 1.14 or higher
 969   AC_CHECK_PROG_VER(LD, $LD, --version,
 970                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 971                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 972                     LD=: critic_missing="$critic_missing GNU gold")
 973 else
 974   AC_CHECK_PROG_VER(LD, $LD, --version,
 975                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 976                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 977                     LD=: critic_missing="$critic_missing GNU ld")
 978 fi
 979
 980 # These programs are version sensitive.
 981 AC_CHECK_TOOL_PREFIX
 982 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 983   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 984   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 985
 986 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 987   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 988   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 989   MSGFMT=: aux_missing="$aux_missing msgfmt")
 990 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 991   [GNU texinfo.* \([0-9][0-9.]*\)],
 992   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 993   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 994 AC_CHECK_PROG_VER(SED, sed, --version,
 995   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 996   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 997   SED=: aux_missing="$aux_missing sed")
 998 AC_CHECK_PROG_VER(AWK, gawk, --version,
 999   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1000   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1001 AC_CHECK_PROG_VER(BISON, bison, --version,
1002   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1003   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1004
1005 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1006 AC_TRY_COMPILE([], [
1007 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1008 #error insufficient compiler
1009 #endif],
1010                [libc_cv_compiler_ok=yes],
1011                [libc_cv_compiler_ok=no])])
1012 AS_IF([test $libc_cv_compiler_ok != yes],
1013       [critic_missing="$critic_missing compiler"])
1014
1015 AC_CHECK_TOOL(NM, nm, false)
1016
1017 if test "x$maintainer" = "xyes"; then
1018   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1019   case "x$AUTOCONF" in
1020   xno|x|x:) AUTOCONF=no ;;
1021   *)
1022     AC_CACHE_CHECK(dnl
1023   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1024     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1025       libc_cv_autoconf_works=yes
1026     else
1027       libc_cv_autoconf_works=no
1028     fi])
1029     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1030     ;;
1031   esac
1032   if test "x$AUTOCONF" = xno; then
1033     aux_missing="$aux_missing autoconf"
1034   fi
1035 else
1036   AUTOCONF=no
1037 fi
1038
1039 # Check for python3 if available, or else python.
1040 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1041   [Python \([0-9][0-9.]*\)],
1042   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1043   critic_missing="$critic_missing python")
1044 PYTHON="$PYTHON_PROG -B"
1045 AC_SUBST(PYTHON)
1046
1047 test -n "$critic_missing" && AC_MSG_ERROR([
1048 *** These critical programs are missing or too old:$critic_missing
1049 *** Check the INSTALL file for required versions.])
1050
1051 test -n "$aux_missing" && AC_MSG_WARN([
1052 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1053 *** some features or tests will be disabled.
1054 *** Check the INSTALL file for required versions.])
1055
1056 # if using special system headers, find out the compiler's sekrit
1057 # header directory and add that to the list.  NOTE: Only does the right
1058 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1059 if test -n "$sysheaders"; then
1060   SYSINCLUDES=-nostdinc
1061   for d in include include-fixed; do
1062     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1063     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1064   done
1065   SYSINCLUDES="$SYSINCLUDES \
1066 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1067   if test -n "$CXX"; then
1068     CXX_SYSINCLUDES=
1069     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1070     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1071       test "x$cxxheaders" != x &&
1072       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1073     done
1074   fi
1075 fi
1076 AC_SUBST(SYSINCLUDES)
1077 AC_SUBST(CXX_SYSINCLUDES)
1078
1079 # Obtain some C++ header file paths.  This is used to make a local
1080 # copy of those headers in Makerules.
1081 if test -n "$CXX"; then
1082   find_cxx_header () {
1083     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1084          | sed -n "\,$1:,{s/:\$//;p}"
1085   }
1086   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1087   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1088   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1089 fi
1090 AC_SUBST(CXX_CSTDLIB_HEADER)
1091 AC_SUBST(CXX_CMATH_HEADER)
1092 AC_SUBST(CXX_BITS_STD_ABS_H)
1093
1094 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1095 # since this would lead to problems installing/building glibc.
1096 # LD_LIBRARY_PATH contains the current directory if one of the following
1097 # is true:
1098 # - one of the terminals (":" and ";") is the first or last sign
1099 # - two terminals occur directly after each other
1100 # - the path contains an element with a dot in it
1101 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1102 changequote(,)dnl
1103 case ${LD_LIBRARY_PATH} in
1104   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1105     ld_library_path_setting="contains current directory"
1106     ;;
1107   *)
1108     ld_library_path_setting="ok"
1109     ;;
1110 esac
1111 changequote([,])dnl
1112 AC_MSG_RESULT($ld_library_path_setting)
1113 if test "$ld_library_path_setting" != "ok"; then
1114 AC_MSG_ERROR([
1115 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1116 *** building glibc. Please change the environment variable
1117 *** and run configure again.])
1118 fi
1119
1120 AC_PATH_PROG(BASH_SHELL, bash, no)
1121
1122 AC_PATH_PROG(PERL, perl, no)
1123 if test "$PERL" != no &&
1124    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1125   PERL=no
1126 fi
1127 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1128              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1129
1130 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1131 cat > conftest.s <<EOF
1132 .text
1133 foo:
1134 .set glibc_conftest_frobozz,foo
1135 .globl glibc_conftest_frobozz
1136 EOF
1137 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1138 # (but it doesn't work), so we must do a linking check to be sure.
1139 cat > conftest1.c <<\EOF
1140 extern int glibc_conftest_frobozz;
1141 void _start() { glibc_conftest_frobozz = 1; }
1142 EOF
1143 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1144             -nostartfiles -nostdlib $no_ssp \
1145             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1146   libc_cv_asm_set_directive=yes
1147 else
1148   libc_cv_asm_set_directive=no
1149 fi
1150 rm -f conftest*])
1151 if test $libc_cv_asm_set_directive = yes; then
1152   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1153 fi
1154
1155 AC_CACHE_CHECK(linker support for protected data symbol,
1156                libc_cv_protected_data,
1157                [cat > conftest.c <<EOF
1158                 int bar __attribute__ ((visibility ("protected"))) = 1;
1159 EOF
1160                 libc_cv_protected_data=no
1161                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1162                   cat > conftest.c <<EOF
1163                   extern int bar;
1164                   int main (void) { return bar; }
1165 EOF
1166                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1167                     libc_cv_protected_data=yes
1168                   fi
1169                 fi
1170                 rm -f conftest.*
1171                ])
1172 AC_SUBST(libc_cv_protected_data)
1173
1174 AC_CACHE_CHECK(linker support for INSERT in linker script,
1175                libc_cv_insert,
1176                [cat > conftest.c <<EOF
1177                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1178                 int test (void) { return bar; }
1179 EOF
1180                 cat > conftest.t <<EOF
1181                 SECTIONS
1182                 {
1183                   .bar : { *(.bar) }
1184                 }
1185                 INSERT AFTER .rela.dyn;
1186 EOF
1187                 libc_cv_insert=no
1188                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1189                   libc_cv_insert=yes
1190                 fi
1191                 rm -f conftest.*
1192                ])
1193 AC_SUBST(libc_cv_insert)
1194
1195 AC_CACHE_CHECK(for broken __attribute__((alias())),
1196                libc_cv_broken_alias_attribute,
1197                [cat > conftest.c <<EOF
1198                extern int foo (int x) __asm ("xyzzy");
1199                int bar (int x) { return x; }
1200                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1201                extern int dfoo;
1202                extern __typeof (dfoo) dfoo __asm ("abccb");
1203                int dfoo = 1;
1204 EOF
1205                libc_cv_broken_alias_attribute=yes
1206                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1207                  if grep 'xyzzy' conftest.s >/dev/null &&
1208                     grep 'abccb' conftest.s >/dev/null; then
1209                    libc_cv_broken_alias_attribute=no
1210                  fi
1211                fi
1212                rm -f conftest.c conftest.s
1213                ])
1214 if test $libc_cv_broken_alias_attribute = yes; then
1215   AC_MSG_ERROR(working alias attribute support required)
1216 fi
1217
1218 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1219                libc_cv_have_sdata_section,
1220                [echo "int i;" > conftest.c
1221                 libc_cv_have_sdata_section=no
1222                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1223                    | grep '\.sdata' >/dev/null; then
1224                   libc_cv_have_sdata_section=yes
1225                 fi
1226                 rm -f conftest.c conftest.so
1227                ])
1228 if test $libc_cv_have_sdata_section = yes; then
1229   AC_DEFINE(HAVE_SDATA_SECTION)
1230 fi
1231
1232 AC_CACHE_CHECK(for libunwind-support in compiler,
1233                libc_cv_cc_with_libunwind, [
1234   cat > conftest.c <<EOF
1235 int main (void) { return 0; }
1236 EOF
1237   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1238      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1239     libc_cv_cc_with_libunwind=yes
1240   else
1241     libc_cv_cc_with_libunwind=no
1242   fi
1243   rm -f conftest*])
1244 AC_SUBST(libc_cv_cc_with_libunwind)
1245 if test $libc_cv_cc_with_libunwind = yes; then
1246   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1247 fi
1248
1249 ASFLAGS_config=
1250 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1251                libc_cv_as_noexecstack, [dnl
1252 cat > conftest.c <<EOF
1253 void foo (void) { }
1254 EOF
1255 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1256                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1257    && grep .note.GNU-stack conftest.s >/dev/null \
1258    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1259                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1260 then
1261   libc_cv_as_noexecstack=yes
1262 else
1263   libc_cv_as_noexecstack=no
1264 fi
1265 rm -f conftest*])
1266 if test $libc_cv_as_noexecstack = yes; then
1267   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1268 fi
1269 AC_SUBST(ASFLAGS_config)
1270
1271 AC_CACHE_CHECK(for -z combreloc,
1272                libc_cv_z_combreloc, [dnl
1273 cat > conftest.c <<EOF
1274 extern int bar (int);
1275 extern int mumble;
1276 int foo (void) { return bar (mumble); }
1277 EOF
1278 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1279                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1280                         -nostdlib -nostartfiles
1281                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1282 then
1283 dnl The following test is a bit weak.  We must use a tool which can test
1284 dnl cross-platform since the gcc used can be a cross compiler.  Without
1285 dnl introducing new options this is not easily doable.  Instead use a tool
1286 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1287 dnl look for a section named .rel.dyn or .rela.dyn.
1288   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1289     libc_cv_z_combreloc=yes
1290   else
1291     libc_cv_z_combreloc=no
1292   fi
1293 else
1294   libc_cv_z_combreloc=no
1295 fi
1296 rm -f conftest*])
1297 if test "$libc_cv_z_combreloc" = yes; then
1298   AC_DEFINE(HAVE_Z_COMBRELOC)
1299 fi
1300 AC_SUBST(libc_cv_z_combreloc)
1301
1302 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1303                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1304 AC_SUBST(libc_cv_z_execstack)
1305
1306 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1307                     [-Wl,--no-dynamic-linker],
1308                     [libc_cv_no_dynamic_linker=yes],
1309                     [libc_cv_no_dynamic_linker=no])
1310 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1311
1312 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1313 LIBC_TRY_CC_OPTION([-static-pie],
1314                    [libc_cv_static_pie=yes],
1315                    [libc_cv_static_pie=no])
1316 ])
1317 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1318
1319 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1320 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1321 ])
1322
1323 AC_SUBST(libc_cv_fpie)
1324
1325 AC_CACHE_CHECK(for --hash-style option,
1326                libc_cv_hashstyle, [dnl
1327 cat > conftest.c <<EOF
1328 int _start (void) { return 42; }
1329 EOF
1330 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1331                             -fPIC -shared -o conftest.so conftest.c
1332                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1333 then
1334   libc_cv_hashstyle=yes
1335 else
1336   libc_cv_hashstyle=no
1337 fi
1338 rm -f conftest*])
1339 AC_SUBST(libc_cv_hashstyle)
1340
1341 # The linker's default -shared behavior is good enough if it
1342 # does these things that our custom linker scripts ensure that
1343 # all allocated NOTE sections come first.
1344 if test "$use_default_link" = default; then
1345   AC_CACHE_CHECK([for sufficient default -shared layout],
1346                   libc_cv_use_default_link, [dnl
1347   libc_cv_use_default_link=no
1348   cat > conftest.s <<\EOF
1349           .section .note.a,"a",%note
1350           .balign 4
1351           .long 4,4,9
1352           .string "GNU"
1353           .string "foo"
1354           .section .note.b,"a",%note
1355           .balign 4
1356           .long 4,4,9
1357           .string "GNU"
1358           .string "bar"
1359 EOF
1360   if AC_TRY_COMMAND([dnl
1361   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1362        ac_try=`$READELF -S conftest.so | sed -n \
1363          ['${x;p;}
1364           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1365           t a
1366           b
1367           : a
1368           H']`
1369   then
1370     libc_seen_a=no libc_seen_b=no
1371     set -- $ac_try
1372     while test $# -ge 2 -a "$1" = NOTE; do
1373       case "$2" in
1374       .note.a) libc_seen_a=yes ;;
1375       .note.b) libc_seen_b=yes ;;
1376       esac
1377       shift 2
1378     done
1379     case "$libc_seen_a$libc_seen_b" in
1380     yesyes)
1381       libc_cv_use_default_link=yes
1382       ;;
1383     *)
1384       echo >&AS_MESSAGE_LOG_FD "\
1385 $libc_seen_a$libc_seen_b from:
1386 $ac_try"
1387       ;;
1388     esac
1389   fi
1390   rm -f conftest*])
1391   use_default_link=$libc_cv_use_default_link
1392 fi
1393
1394 AC_CACHE_CHECK(for GLOB_DAT reloc,
1395                libc_cv_has_glob_dat, [dnl
1396 cat > conftest.c <<EOF
1397 extern int mumble;
1398 int foo (void) { return mumble; }
1399 EOF
1400 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1401                         -fPIC -shared -o conftest.so conftest.c
1402                         -nostdlib -nostartfiles $no_ssp
1403                         1>&AS_MESSAGE_LOG_FD])
1404 then
1405 dnl look for GLOB_DAT relocation.
1406   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1407     libc_cv_has_glob_dat=yes
1408   else
1409     libc_cv_has_glob_dat=no
1410   fi
1411 else
1412   libc_cv_has_glob_dat=no
1413 fi
1414 rm -f conftest*])
1415 AC_SUBST(libc_cv_has_glob_dat)
1416
1417 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1418 if libc_cv_output_format=`
1419 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1420 then
1421   :
1422 else
1423   libc_cv_output_format=
1424 fi
1425 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1426 AC_SUBST(libc_cv_output_format)
1427
1428 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1429 cat > conftest.c <<EOF
1430 int foo;
1431 EOF
1432 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1433                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1434 then
1435   libc_cv_fno_toplevel_reorder=yes
1436 else
1437   libc_cv_fno_toplevel_reorder=no
1438 fi
1439 rm -f conftest*])
1440 if test $libc_cv_fno_toplevel_reorder = yes; then
1441   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1442 else
1443   fno_unit_at_a_time=-fno-unit-at-a-time
1444 fi
1445 AC_SUBST(fno_unit_at_a_time)
1446
1447 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1448 [dnl
1449 cat > conftest.c <<EOF
1450 __thread int i;
1451 void foo (void)
1452 {
1453   i = 10;
1454 }
1455 EOF
1456 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1457                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1458 then
1459   libc_cv_mtls_dialect_gnu2=yes
1460 else
1461   libc_cv_mtls_dialect_gnu2=no
1462 fi
1463 rm -f conftest*])
1464 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1465 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1466
1467 AC_CACHE_CHECK(whether cc puts quotes around section names,
1468                libc_cv_have_section_quotes,
1469                [cat > conftest.c <<EOF
1470                 static const int foo
1471                 __attribute__ ((section ("bar"))) = 1;
1472 EOF
1473                 if ${CC-cc} -S conftest.c -o conftest.s; then
1474                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1475                     libc_cv_have_section_quotes=yes
1476                   else
1477                     libc_cv_have_section_quotes=no
1478                   fi
1479                 else
1480                   libc_cv_have_section_quotes=unknown
1481                 fi
1482                 rm -f conftest.{c,s}
1483                 ])
1484 if test $libc_cv_have_section_quotes = yes; then
1485   AC_DEFINE(HAVE_SECTION_QUOTES)
1486 fi
1487
1488 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1489 cat > conftest.c <<\EOF
1490 void zero (void *x)
1491 {
1492   __builtin_memset (x, 0, 1000);
1493 }
1494 EOF
1495 dnl
1496 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1497 then
1498   libc_cv_gcc_builtin_memset=no
1499 else
1500   libc_cv_gcc_builtin_memset=yes
1501 fi
1502 rm -f conftest* ])
1503 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1504   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1505 fi
1506
1507 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1508 cat > conftest.c <<\EOF
1509 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1510 char *foo (const char *a, const char *b)
1511 {
1512   return __builtin_strstr (a, b);
1513 }
1514 EOF
1515 dnl
1516 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1517 then
1518   libc_cv_gcc_builtin_redirection=yes
1519 else
1520   libc_cv_gcc_builtin_redirection=no
1521 fi
1522 rm -f conftest* ])
1523 if test "$libc_cv_gcc_builtin_redirection" = no; then
1524   AC_MSG_ERROR([support for the symbol redirection needed])
1525 fi
1526
1527 dnl Determine how to disable generation of FMA instructions.
1528 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1529                libc_cv_cc_nofma, [dnl
1530 libc_cv_cc_nofma=
1531 for opt in -ffp-contract=off -mno-fused-madd; do
1532   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1533 done])
1534 AC_SUBST(libc_cv_cc_nofma)
1535
1536 if test -n "$submachine"; then
1537   AC_CACHE_CHECK([for compiler option for CPU variant],
1538                  libc_cv_cc_submachine, [dnl
1539   libc_cv_cc_submachine=no
1540   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1541     LIBC_TRY_CC_OPTION([$opt], [
1542       libc_cv_cc_submachine="$opt"
1543       break], [])
1544   done])
1545   if test "x$libc_cv_cc_submachine" = xno; then
1546     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1547   fi
1548 fi
1549 AC_SUBST(libc_cv_cc_submachine)
1550
1551 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1552 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1553 cat > conftest.c <<EOF
1554 void
1555 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1556 foo (void) {}
1557 EOF
1558 libc_cv_cc_loop_to_function=no
1559 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1560 then
1561   libc_cv_cc_loop_to_function=yes
1562 fi
1563 rm -f conftest*])
1564 if test $libc_cv_cc_loop_to_function = yes; then
1565   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1566 fi
1567 AC_SUBST(libc_cv_cc_loop_to_function)
1568
1569 dnl Check whether we have the gd library available.
1570 AC_MSG_CHECKING(for libgd)
1571 if test "$with_gd" != "no"; then
1572   old_CFLAGS="$CFLAGS"
1573   CFLAGS="$CFLAGS $libgd_include"
1574   old_LDFLAGS="$LDFLAGS"
1575   LDFLAGS="$LDFLAGS $libgd_ldflags"
1576   old_LIBS="$LIBS"
1577   LIBS="$LIBS -lgd -lpng -lz -lm"
1578   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1579   CFLAGS="$old_CFLAGS"
1580   LDFLAGS="$old_LDFLAGS"
1581   LIBS="$old_LIBS"
1582 else
1583   LIBGD=no
1584 fi
1585 AC_MSG_RESULT($LIBGD)
1586 AC_SUBST(LIBGD)
1587
1588 # SELinux detection
1589 if test x$with_selinux = xno ; then
1590   have_selinux=no;
1591 else
1592   # See if we have the SELinux library
1593   AC_CHECK_LIB(selinux, is_selinux_enabled,
1594                have_selinux=yes, have_selinux=no)
1595   if test x$with_selinux = xyes ; then
1596     if test x$have_selinux = xno ; then
1597       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1598     fi
1599   fi
1600 fi
1601 # Check if we're building with SELinux support.
1602 if test "x$have_selinux" = xyes; then
1603   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1604
1605   # See if we have the libaudit library
1606   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1607                have_libaudit=yes, have_libaudit=no)
1608   if test "x$have_libaudit" = xyes; then
1609     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1610   fi
1611   AC_SUBST(have_libaudit)
1612
1613   # See if we have the libcap library
1614   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1615   if test "x$have_libcap" = xyes; then
1616     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1617   fi
1618   AC_SUBST(have_libcap)
1619 fi
1620 AC_SUBST(have_selinux)
1621
1622 CPPUNDEFS=
1623 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1624 dnl Since we are building the implementations of the fortified functions here,
1625 dnl having the macro defined interacts very badly.
1626 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1627 [AC_TRY_COMPILE([], [
1628 #ifdef _FORTIFY_SOURCE
1629 # error bogon
1630 #endif],
1631                 [libc_cv_predef_fortify_source=no],
1632                 [libc_cv_predef_fortify_source=yes])])
1633 if test $libc_cv_predef_fortify_source = yes; then
1634   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1635 fi
1636 AC_SUBST(CPPUNDEFS)
1637
1638 # Some linkers on some architectures support __ehdr_start but with
1639 # bugs.  Make sure usage of it does not create relocations in the
1640 # output (as the linker should resolve them all for us).
1641 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1642                libc_cv_ehdr_start, [
1643 old_CFLAGS="$CFLAGS"
1644 old_LDFLAGS="$LDFLAGS"
1645 old_LIBS="$LIBS"
1646 CFLAGS="$CFLAGS -fPIC"
1647 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1648 LIBS=
1649 AC_LINK_IFELSE([AC_LANG_SOURCE([
1650 typedef struct {
1651   char foo;
1652   long val;
1653 } Ehdr;
1654 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1655 long ehdr (void) { return __ehdr_start.val; }
1656 ])],
1657                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1658                   libc_cv_ehdr_start=broken
1659                 else
1660                   libc_cv_ehdr_start=yes
1661                 fi], [libc_cv_ehdr_start=no])
1662 CFLAGS="$old_CFLAGS"
1663 LDFLAGS="$old_LDFLAGS"
1664 LIBS="$old_LIBS"
1665 ])
1666 if test "$libc_cv_ehdr_start" = yes; then
1667   AC_DEFINE([HAVE_EHDR_START])
1668 elif test "$libc_cv_ehdr_start" = broken; then
1669   AC_MSG_WARN([linker is broken -- you should upgrade])
1670 fi
1671
1672 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1673                libc_cv_builtin_trap, [dnl
1674 libc_cv_builtin_trap=no
1675 AC_TRY_COMPILE([], [__builtin_trap ()], [
1676 libc_undefs=`$NM -u conftest.o |
1677   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1678     2>&AS_MESSAGE_LOG_FD` || {
1679   AC_MSG_ERROR([confusing output from $NM -u])
1680 }
1681 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1682 if test -z "$libc_undefs"; then
1683   libc_cv_builtin_trap=yes
1684 fi])])
1685 if test $libc_cv_builtin_trap = yes; then
1686   AC_DEFINE([HAVE_BUILTIN_TRAP])
1687 fi
1688
1689 dnl C++ feature tests.
1690 AC_LANG_PUSH([C++])
1691
1692 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1693                libc_cv_cxx_thread_local, [
1694 old_CXXFLAGS="$CXXFLAGS"
1695 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1696 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1697 #include <thread>
1698
1699 // Compiler support.
1700 struct S
1701 {
1702   S ();
1703   ~S ();
1704 };
1705 thread_local S s;
1706 S * get () { return &s; }
1707
1708 // libstdc++ support.
1709 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1710 #error __cxa_thread_atexit_impl not supported
1711 #endif
1712 ])],
1713                [libc_cv_cxx_thread_local=yes],
1714                [libc_cv_cxx_thread_local=no])
1715 CXXFLAGS="$old_CXXFLAGS"
1716 ])
1717 AC_SUBST(libc_cv_cxx_thread_local)
1718
1719 AC_LANG_POP([C++])
1720 dnl End of C++ feature tests.
1721
1722 ### End of automated tests.
1723 ### Now run sysdeps configure fragments.
1724
1725 # They also can set these variables.
1726 use_ldconfig=no
1727 ldd_rewrite_script=no
1728 libc_cv_sysconfdir=$sysconfdir
1729 libc_cv_localstatedir=$localstatedir
1730 libc_cv_gcc_unwind_find_fde=no
1731 libc_cv_idn=no
1732
1733 # Iterate over all the sysdep directories we will use, running their
1734 # configure fragments.
1735 for dir in $sysnames; do
1736   case $dir in
1737     /*) dest=$dir ;;
1738     *)  dest=$srcdir/$dir ;;
1739   esac
1740   if test -r $dest/configure; then
1741     AC_MSG_RESULT(running configure fragment for $dir)
1742     . $dest/configure
1743   fi
1744 done
1745
1746 if test x"$build_mathvec" = xnotset; then
1747   build_mathvec=no
1748 fi
1749 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1750
1751 AC_SUBST(libc_extra_cflags)
1752 AC_SUBST(libc_extra_cppflags)
1753
1754 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1755   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1756 fi
1757 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1758
1759 # A sysdeps configure fragment can reset this if IFUNC is not actually
1760 # usable even though the assembler knows how to generate the symbol type.
1761 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1762   AC_DEFINE(HAVE_IFUNC)
1763 fi
1764 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1765
1766 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1767   AC_DEFINE(HAVE_GCC_IFUNC)
1768 fi
1769
1770 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1771 # configure fragment can override the value to prevent this AC_DEFINE.
1772 AC_SUBST(use_nscd)
1773 if test "x$use_nscd" != xno; then
1774   AC_DEFINE([USE_NSCD])
1775 fi
1776 if test "x$build_nscd" = xdefault; then
1777   build_nscd=$use_nscd
1778 fi
1779
1780 AC_SUBST(libc_cv_slibdir)
1781 AC_SUBST(libc_cv_rtlddir)
1782 AC_SUBST(libc_cv_complocaledir)
1783 AC_SUBST(libc_cv_sysconfdir)
1784 AC_SUBST(libc_cv_localstatedir)
1785 AC_SUBST(libc_cv_rootsbindir)
1786
1787 if test x$use_ldconfig = xyes; then
1788   AC_DEFINE(USE_LDCONFIG)
1789 fi
1790 AC_SUBST(use_ldconfig)
1791 AC_SUBST(ldd_rewrite_script)
1792
1793 AC_SUBST(static)
1794 AC_SUBST(shared)
1795
1796 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1797 [libc_cv_pic_default=yes
1798 cat > conftest.c <<EOF
1799 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1800 # error PIC is default.
1801 #endif
1802 EOF
1803 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1804   libc_cv_pic_default=no
1805 fi
1806 rm -f conftest.*])
1807 AC_SUBST(libc_cv_pic_default)
1808
1809 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1810 [libc_cv_cc_pie_default=yes
1811 cat > conftest.c <<EOF
1812 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1813 # error PIE is default.
1814 #endif
1815 EOF
1816 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1817   libc_cv_cc_pie_default=no
1818 fi
1819 rm -f conftest.*])
1820 libc_cv_pie_default=$libc_cv_cc_pie_default
1821 AC_SUBST(libc_cv_cc_pie_default)
1822 AC_SUBST(libc_cv_pie_default)
1823
1824 # Set the `multidir' variable by grabbing the variable from the compiler.
1825 # We do it once and save the result in a generated makefile.
1826 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1827 AC_SUBST(libc_cv_multidir)
1828
1829 if test "$static_pie" = yes; then
1830   # The linker must support --no-dynamic-linker.
1831   if test "$libc_cv_no_dynamic_linker" != yes; then
1832     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1833   fi
1834   # Default to PIE.
1835   libc_cv_pie_default=yes
1836   AC_DEFINE(ENABLE_STATIC_PIE)
1837 fi
1838 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1839
1840 AC_SUBST(profile)
1841 AC_SUBST(static_nss)
1842
1843 AC_SUBST(DEFINES)
1844
1845 dnl See sysdeps/mach/configure.ac for this variable.
1846 AC_SUBST(mach_interface_list)
1847
1848 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1849 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1850 AC_SUBST(VERSION)
1851 AC_SUBST(RELEASE)
1852
1853 AC_CONFIG_FILES([config.make Makefile])
1854 AC_CONFIG_COMMANDS([default],[[
1855 case $CONFIG_FILES in *config.make*)
1856 echo "$config_vars" >> config.make;;
1857 esac
1858 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1859 AC_OUTPUT