configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234 if test "x$bindnow" = xyes; then
 235   AC_DEFINE(BIND_NOW)
 236 fi
 237
 238 dnl On some platforms we cannot use dynamic loading.  We must provide
 239 dnl static NSS modules.
 240 AC_ARG_ENABLE([static-nss],
 241               AC_HELP_STRING([--enable-static-nss],
 242                              [build static NSS modules @<:@default=no@:>@]),
 243               [static_nss=$enableval],
 244               [static_nss=no])
 245 dnl Enable static NSS also if we build no shared objects.
 246 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 247   static_nss=yes
 248   AC_DEFINE(DO_STATIC_NSS)
 249 fi
 250
 251 AC_ARG_ENABLE([force-install],
 252               AC_HELP_STRING([--disable-force-install],
 253                              [don't force installation of files from this package, even if they are older than the installed files]),
 254               [force_install=$enableval],
 255               [force_install=yes])
 256 AC_SUBST(force_install)
 257
 258 AC_ARG_ENABLE([maintainer-mode],
 259               AC_HELP_STRING([--enable-maintainer-mode],
 260                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 261               [maintainer=$enableval],
 262               [maintainer=no])
 263
 264 dnl On some platforms we allow dropping compatibility with all kernel
 265 dnl versions.
 266 AC_ARG_ENABLE([kernel],
 267               AC_HELP_STRING([--enable-kernel=VERSION],
 268                              [compile for compatibility with kernel not older than VERSION]),
 269               [minimum_kernel=$enableval],
 270               [])
 271 dnl Prevent unreasonable values.
 272 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 273   # Better nothing than this.
 274   minimum_kernel=""
 275 else
 276   if test "$minimum_kernel" = current; then
 277     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 278   fi
 279 fi
 280
 281 dnl For the development we sometimes want gcc to issue even more warnings.
 282 dnl This is not the default since many of the extra warnings are not
 283 dnl appropriate.
 284 AC_ARG_ENABLE([all-warnings],
 285               AC_HELP_STRING([--enable-all-warnings],
 286                              [enable all useful warnings gcc can issue]),
 287               [all_warnings=$enableval],
 288               [])
 289 AC_SUBST(all_warnings)
 290
 291 AC_ARG_ENABLE([werror],
 292               AC_HELP_STRING([--disable-werror],
 293                              [do not build with -Werror]),
 294               [enable_werror=$enableval],
 295               [enable_werror=yes])
 296 AC_SUBST(enable_werror)
 297
 298 AC_ARG_ENABLE([multi-arch],
 299               AC_HELP_STRING([--enable-multi-arch],
 300                              [enable single DSO with optimizations for multiple architectures]),
 301               [multi_arch=$enableval],
 302               [multi_arch=default])
 303
 304 AC_ARG_ENABLE([nss-crypt],
 305               AC_HELP_STRING([--enable-nss-crypt],
 306                              [enable libcrypt to use nss]),
 307               [nss_crypt=$enableval],
 308               [nss_crypt=no])
 309 if test x$nss_crypt = xyes; then
 310   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 311   if test $? -ne 0; then
 312     AC_MSG_ERROR([cannot find include directory with nss-config])
 313   fi
 314   old_CFLAGS="$CFLAGS"
 315   CFLAGS="$CFLAGS $nss_includes"
 316   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 317 #include <hasht.h>
 318 #include <nsslowhash.h>
 319 void f (void) { NSSLOW_Init (); }])],
 320              libc_cv_nss_crypt=yes,
 321              AC_MSG_ERROR([
 322 cannot find NSS headers with lowlevel hash function interfaces]))
 323   old_LIBS="$LIBS"
 324   old_LDFLAGS="$LDFLAGS"
 325   LIBS="$LIBS -lfreebl3"
 326   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 327 #include <hasht.h>
 328 #include <nsslowhash.h>],
 329                                   [NSSLOW_Init();])],
 330                  libc_cv_nss_crypt=yes,
 331                  AC_MSG_ERROR([
 332 cannot link program using lowlevel NSS hash functions]))
 333   # Check to see if there is a static NSS cryptographic library.
 334   # If there isn't then we can't link anything with libcrypt.a,
 335   # and that might mean disabling some static tests.
 336   LDFLAGS="$LDFLAGS -static"
 337   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 338 #include <hasht.h>
 339 #include <nsslowhash.h>],
 340                                   [NSSLOW_Init();])],
 341                  libc_cv_static_nss_crypt=yes,
 342                  libc_cv_static_nss_crypt=no)
 343   LDFLAGS="$old_LDFLAGS"
 344   CFLAGS="$old_CFLAGS"
 345   LIBS="$old_LIBS"
 346 else
 347   libc_cv_nss_crypt=no
 348   libc_cv_static_nss_crypt=no
 349 fi
 350 AC_SUBST(libc_cv_nss_crypt)
 351 AC_SUBST(libc_cv_static_nss_crypt)
 352
 353
 354 AC_ARG_ENABLE([obsolete-rpc],
 355               AC_HELP_STRING([--enable-obsolete-rpc],
 356                              [build and install the obsolete RPC code for link-time usage]),
 357               [link_obsolete_rpc=$enableval],
 358               [link_obsolete_rpc=no])
 359 AC_SUBST(link_obsolete_rpc)
 360
 361 if test "$link_obsolete_rpc" = yes; then
 362   AC_DEFINE(LINK_OBSOLETE_RPC)
 363 fi
 364
 365 AC_ARG_ENABLE([systemtap],
 366               [AS_HELP_STRING([--enable-systemtap],
 367                [enable systemtap static probe points @<:@default=no@:>@])],
 368               [systemtap=$enableval],
 369               [systemtap=no])
 370 if test "x$systemtap" != xno; then
 371   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 372   old_CFLAGS="$CFLAGS"
 373   CFLAGS="-std=gnu11 $CFLAGS"
 374   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 375 void foo (int i, void *p)
 376 {
 377   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 378        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 379 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 380   CFLAGS="$old_CFLAGS"])
 381   if test $libc_cv_sdt = yes; then
 382     AC_DEFINE([USE_STAP_PROBE])
 383   elif test "x$systemtap" != xauto; then
 384     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 385   fi
 386 fi
 387
 388 AC_ARG_ENABLE([build-nscd],
 389               [AS_HELP_STRING([--disable-build-nscd],
 390                [disable building and installing the nscd daemon])],
 391               [build_nscd=$enableval],
 392               [build_nscd=default])
 393 AC_SUBST(build_nscd)
 394
 395 # Note the use of $use_nscd is near the bottom of the file.
 396 AC_ARG_ENABLE([nscd],
 397               [AS_HELP_STRING([--disable-nscd],
 398                [library functions will not contact the nscd daemon])],
 399               [use_nscd=$enableval],
 400               [use_nscd=yes])
 401
 402 AC_ARG_ENABLE([pt_chown],
 403               [AS_HELP_STRING([--enable-pt_chown],
 404                [Enable building and installing pt_chown])],
 405               [build_pt_chown=$enableval],
 406               [build_pt_chown=no])
 407 AC_SUBST(build_pt_chown)
 408 if test "$build_pt_chown" = yes; then
 409   AC_DEFINE(HAVE_PT_CHOWN)
 410 fi
 411
 412 # The abi-tags file uses a fairly simplistic model for name recognition that
 413 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 414 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 415 # This doesn't get used much beyond that, so it's fairly safe.
 416 case "$host_os" in
 417 linux*)
 418   ;;
 419 gnu*)
 420   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 421   ;;
 422 esac
 423
 424 AC_ARG_ENABLE([mathvec],
 425               [AS_HELP_STRING([--enable-mathvec],
 426               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 427               [build_mathvec=$enableval],
 428               [build_mathvec=notset])
 429
 430 # We keep the original values in `$config_*' and never modify them, so we
 431 # can write them unchanged into config.make.  Everything else uses
 432 # $machine, $vendor, and $os, and changes them whenever convenient.
 433 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 434
 435 # Don't allow vendor == "unknown"
 436 test "$config_vendor" = unknown && config_vendor=
 437 config_os="`echo $config_os | sed 's/^unknown-//'`"
 438
 439 # Some configurations imply other options.
 440 elf=yes
 441
 442 # The configure fragment of an add-on port can modify these to supplement
 443 # or override the table in the case statement below.  No fragment should
 444 # ever change the config_* variables, however.
 445 machine=$config_machine
 446 vendor=$config_vendor
 447 os=$config_os
 448 base_os=''
 449
 450 submachine=
 451 AC_ARG_WITH([cpu],
 452             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 453             [dnl
 454   case "$withval" in
 455   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 456   no) ;;
 457   *) submachine="$withval" ;;
 458   esac
 459 ])
 460
 461 # An preconfigure script can set this when it wants to disable the sanity
 462 # check below.
 463 libc_config_ok=no
 464
 465 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 466 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 467
 468 dnl Having this here, though empty, makes sure that if add-ons' fragments
 469 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 470 dnl our AC_OUTPUT will actually use it.
 471 AC_CONFIG_SUBDIRS()
 472
 473 case "$enable_add_ons" in
 474 ''|no) add_ons= ;;
 475 yes|'*')
 476  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 477           sed 's@/[[^/]]*$@@' | sort | uniq`
 478          add_ons_automatic=yes
 479          ;;
 480 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 481        add_ons_automatic=no ;;
 482 esac
 483
 484 configured_add_ons=
 485 add_ons_sfx=
 486 add_ons_pfx=
 487 if test x"$add_ons" != x; then
 488   for f in $add_ons; do
 489     # Some sanity checks
 490     case "$f" in
 491     crypt)
 492       AC_MSG_ERROR([
 493 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 494 *** part of glibc and using the old add-on will not work with this
 495 *** release.  Start again with fresh sources and without the old
 496 *** \`crypt' add-on.])
 497     ;;
 498     localedata)
 499       AC_MSG_ERROR([
 500 *** It seems that you're using an old \`localedata' add-on.  localedata
 501 *** is now part of glibc and using the old add-on will not work with
 502 *** this release.  Start again with fresh sources and without the old
 503 *** \`localedata' add-on.])
 504     ;;
 505     esac
 506   done
 507
 508   # Now source each add-on's configure fragment.
 509   # The fragments can use $srcdir/$libc_add_on to find themselves,
 510   # and test $add_ons_automatic to see if they were explicitly requested.
 511   # A fragment can clear (or even change) $libc_add_on to affect
 512   # whether it goes into the list to be actually used in the build.
 513   use_add_ons=
 514   for libc_add_on in $add_ons; do
 515     # Test whether such a directory really exists.
 516     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 517     case "$libc_add_on" in
 518     /*)
 519       libc_add_on_srcdir=$libc_add_on
 520       ;;
 521     *)
 522       test -d "$srcdir/$libc_add_on" || {
 523         if test -d "$libc_add_on"; then
 524           libc_add_on="`pwd`/$libc_add_on"
 525         else
 526           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 527         fi
 528       }
 529       libc_add_on_srcdir=$srcdir/$libc_add_on
 530       ;;
 531     esac
 532
 533     libc_add_on_frag=$libc_add_on_srcdir/configure
 534     libc_add_on_canonical=
 535     libc_add_on_config_subdirs=
 536     if test -r "$libc_add_on_frag"; then
 537       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 538       libc_add_on_canonical=unknown
 539       libc_add_on_subdirs=
 540       . "$libc_add_on_frag"
 541       test -z "$libc_add_on" || {
 542         configured_add_ons="$configured_add_ons $libc_add_on"
 543         if test "x$libc_add_on_canonical" = xunknown; then
 544           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 545         fi
 546         for d in $libc_add_on_subdirs; do
 547           case "$libc_add_on" in
 548           /*) subdir_srcdir="$libc_add_on" ;;
 549           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 550           esac
 551           case "$d" in
 552           .)
 553             d="${libc_add_on_canonical:-$libc_add_on}"
 554             ;;
 555           /*)
 556             subdir_srcdir="$d"
 557             ;;
 558           *)
 559             subdir_srcdir="$subdir_srcdir/$d"
 560             ;;
 561           esac
 562           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 563           add_on_subdirs="$add_on_subdirs $d"
 564           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 565 $d-srcdir = $subdir_srcdir"
 566         done
 567         for d in $libc_add_on_config_subdirs; do
 568           case "$d" in
 569           /*) AC_MSG_ERROR(dnl
 570 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 571           esac
 572           if test ! -d "$libc_add_on_srcdir/$d"; then
 573             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 574           fi
 575           case "$libc_add_on" in
 576           /*) AC_MSG_ERROR(dnl
 577 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 578           esac
 579           subdirs="$subdirs $libc_add_on/$d"
 580         done
 581       }
 582     fi
 583     if test -n "$libc_add_on"; then
 584       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 585       use_add_ons="$use_add_ons $libc_add_on"
 586       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 587       test -z "$libc_add_on_canonical" ||
 588       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 589     fi
 590   done
 591   # Use echo to strip excess whitespace.
 592   add_ons="`echo $use_add_ons`"
 593 fi
 594 AC_SUBST(add_ons)
 595 AC_SUBST(add_on_subdirs)
 596
 597
 598 ###
 599 ### By using the undocumented --enable-hacker-mode option for configure
 600 ### one can skip this test to make the configuration not fail for unsupported
 601 ### platforms.
 602 ###
 603 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 604   case "$machine-$host_os" in
 605   *-linux* | *-gnu*)
 606     ;;
 607   *)
 608     AC_MSG_ERROR([
 609 *** The GNU C library is currently unavailable for this platform.
 610 *** If you are interested in seeing glibc on this platform visit
 611 *** the "How to submit a new port" in the wiki:
 612 ***   https://sourceware.org/glibc/wiki/#Development
 613 *** and join the community!])
 614     ;;
 615   esac
 616 fi
 617
 618 # Set base_machine if not set by a preconfigure fragment.
 619 test -n "$base_machine" || base_machine=$machine
 620 AC_SUBST(base_machine)
 621
 622 # For the multi-arch option we need support in the assembler & linker.
 623 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 624                libc_cv_ld_gnu_indirect_function, [dnl
 625 cat > conftest.S <<EOF
 626 .type foo,%gnu_indirect_function
 627 foo:
 628 .globl _start
 629 _start:
 630 .globl __start
 631 __start:
 632 .data
 633 #ifdef _LP64
 634 .quad foo
 635 #else
 636 .long foo
 637 #endif
 638 EOF
 639 libc_cv_ld_gnu_indirect_function=no
 640 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 641             -nostartfiles -nostdlib \
 642             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 643   # Do a link to see if the backend supports IFUNC relocs.
 644   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 645   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 646     libc_cv_ld_gnu_indirect_function=yes
 647   }
 648 fi
 649 rm -f conftest*])
 650
 651 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 652 AC_CACHE_CHECK([for gcc attribute ifunc support],
 653                libc_cv_gcc_indirect_function, [dnl
 654 cat > conftest.c <<EOF
 655 extern int func (int);
 656 int used_func (int a)
 657 {
 658   return a;
 659 }
 660 static void *resolver ()
 661 {
 662   return &used_func;
 663 }
 664 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 665 EOF
 666 libc_cv_gcc_indirect_function=no
 667 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 668    2>&AS_MESSAGE_LOG_FD ; then
 669   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 670     libc_cv_gcc_indirect_function=yes
 671   fi
 672 fi
 673 rm -f conftest*])
 674
 675 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 676   if test x"$multi_arch" = xyes; then
 677     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 678   else
 679     multi_arch=no
 680   fi
 681 fi
 682 if test x"$libc_cv_gcc_indirect_function" != xyes &&
 683    test x"$multi_arch" = xyes; then
 684   AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 685 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 686 fi
 687 multi_arch_d=
 688 if test x"$multi_arch" != xno; then
 689   multi_arch_d=/multiarch
 690 fi
 691
 692 # Compute the list of sysdep directories for this configuration.
 693 # This can take a while to compute.
 694 sysdep_dir=$srcdir/sysdeps
 695 AC_MSG_CHECKING(sysdep dirs)
 696 dnl We need to use [ and ] for other purposes for a while now.
 697 changequote(,)dnl
 698 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 699 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 700
 701 test "x$base_os" != x || case "$os" in
 702 gnu*)
 703   base_os=mach/hurd ;;
 704 linux*)
 705   base_os=unix/sysv ;;
 706 esac
 707
 708 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 709 tail=$os
 710 ostry=$os
 711 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 712   ostry="$ostry /$o"
 713   tail=$o
 714 done
 715 o=`echo $tail | sed 's/[0-9]*$//'`
 716 if test $o != $tail; then
 717   ostry="$ostry /$o"
 718 fi
 719 # For linux-gnu, try linux-gnu, then linux.
 720 o=`echo $tail | sed 's/-.*$//'`
 721 if test $o != $tail; then
 722   ostry="$ostry /$o"
 723 fi
 724
 725 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 726 base=
 727 tail=$base_os
 728 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 729   set $b
 730   base="$base /$1"
 731   tail="$2"
 732 done
 733
 734 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 735 mach=
 736 tail=$machine${submachine:+/$submachine}
 737 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 738   set $m
 739   # Prepend the machine's FPU directory unless --without-fp.
 740   if test "$with_fp" = yes; then
 741     maybe_fpu=/fpu
 742   else
 743     maybe_fpu=/nofpu
 744   fi
 745   # For each machine term, try it with and then without /multiarch.
 746   for try_fpu in $maybe_fpu ''; do
 747     for try_multi in $multi_arch_d ''; do
 748       mach="$mach /$1$try_fpu$try_multi"
 749     done
 750   done
 751   tail="$2"
 752 done
 753
 754 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 755 changequote([,])dnl
 756
 757 # Find what sysdep directories exist.
 758 sysnames_add_ons=
 759 sysnames=
 760 for b in $base ''; do
 761   for m0 in $mach ''; do
 762     for v in /$vendor ''; do
 763       test "$v" = / && continue
 764       for o in /$ostry ''; do
 765         test "$o" = / && continue
 766         for m in $mach ''; do
 767           for d in $add_ons_pfx ''; do
 768             for a in $add_ons_sfx ''; do
 769               try_suffix="$m0$b$v$o$m"
 770               if test -n "$try_suffix"; then
 771                 try_srcdir="${srcdir}/"
 772                 case "$d" in
 773                 /*) try_srcdir= ;;
 774                 esac
 775                 try="${d}sysdeps$try_suffix$a"
 776                 test -n "$enable_debug_configure" &&
 777                 echo "$0 [DEBUG]: try $try" >&2
 778                 if test -d "$try_srcdir$try"; then
 779                   sysnames="$sysnames $try"
 780                   { test -n "$o" || test -n "$b"; } && os_used=t
 781                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 782                   case x${m0:-$m} in
 783                   x*/$submachine) submachine_used=t ;;
 784                   esac
 785                   if test -n "$d"; then
 786                     case "$sysnames_add_ons" in
 787                     *" $d "*) ;;
 788                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 789                     esac
 790                   fi
 791                 fi
 792               fi
 793             done
 794           done
 795         done
 796       done
 797     done
 798   done
 799 done
 800
 801 # If the assembler supports gnu_indirect_function symbol type and the
 802 # architecture supports multi-arch, we enable multi-arch by default.
 803 case $sysnames_add_ons$sysnames in
 804 *"$multi_arch_d"*)
 805   ;;
 806 *)
 807   test x"$multi_arch" = xdefault && multi_arch=no
 808   ;;
 809 esac
 810 if test x"$multi_arch" != xno; then
 811   AC_DEFINE(USE_MULTIARCH)
 812 fi
 813 AC_SUBST(multi_arch)
 814
 815 if test -z "$os_used" && test "$os" != none; then
 816   AC_MSG_ERROR(Operating system $os is not supported.)
 817 fi
 818 if test -z "$machine_used" && test "$machine" != none; then
 819   AC_MSG_ERROR(The $machine is not supported.)
 820 fi
 821 if test -z "$submachine_used" && test -n "$submachine"; then
 822   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 823 fi
 824 AC_SUBST(submachine)
 825
 826 # We have now validated the configuration.
 827
 828 # Expand the list of system names into a full list of directories
 829 # from each element's parent name and Implies file (if present).
 830 set $sysnames
 831 names=
 832 while test $# -gt 0; do
 833   name=$1
 834   shift
 835
 836   case " $names " in *" $name "*)
 837     # Already in the list.
 838     continue
 839   esac
 840
 841   # Report each name as we discover it, so there is no long pause in output.
 842   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 843
 844   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 845
 846   case $name in
 847     /*) xsrcdir= ;;
 848     *)  xsrcdir=$srcdir/ ;;
 849   esac
 850   test -n "$enable_debug_configure" &&
 851   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 852
 853   for implies_file in Implies Implies-before Implies-after; do
 854     implies_type=`echo $implies_file | sed s/-/_/`
 855     eval ${implies_type}=
 856     if test -f $xsrcdir$name/$implies_file; then
 857       # Collect more names from the `Implies' file (removing comments).
 858       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 859       for x in $implied_candidate; do
 860         found=no
 861         if test -d $xsrcdir$name_base/$x; then
 862           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 863           found=yes
 864         fi
 865         for d in $add_ons_pfx ''; do
 866           try="${d}sysdeps/$x"
 867           case $d in
 868            /*) try_srcdir= ;;
 869            *) try_srcdir=$srcdir/ ;;
 870           esac
 871           test -n "$enable_debug_configure" &&
 872            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 873           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 874           then
 875             eval "${implies_type}=\"\$${implies_type} \$try\""
 876             found=yes
 877             case "$sysnames_add_ons" in
 878             *" $d "*) ;;
 879             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 880             esac
 881           fi
 882         done
 883         if test $found = no; then
 884           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 885         fi
 886       done
 887     fi
 888   done
 889
 890   # Add NAME to the list of names.
 891   names="$names $name"
 892
 893   # Find the parent of NAME, using the empty string if it has none.
 894 changequote(,)dnl
 895   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 896 changequote([,])dnl
 897
 898   test -n "$enable_debug_configure" &&
 899     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 900 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 901
 902   # Add the names implied by NAME, and NAME's parent (if it has one), to
 903   # the list of names to be processed (the argument list).  We prepend the
 904   # implied names to the list and append the parent.  We want implied
 905   # directories to come before further directories inferred from the
 906   # configuration components; this ensures that for sysv4, unix/common
 907   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 908   # after sysv4).
 909   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 910   test -n "$sysnames" && set $sysnames
 911 done
 912
 913 # Add the default directories.
 914 default_sysnames="sysdeps/generic"
 915 sysnames="$names $default_sysnames"
 916 AC_SUBST(sysnames)
 917 # The other names were emitted during the scan.
 918 AC_MSG_RESULT($default_sysnames)
 919
 920 # Collect the list of add-ons that supply partial sysdeps trees.
 921 sysdeps_add_ons=
 922 for add_on in $add_ons; do
 923   case "$add_on" in
 924   /*) xsrcdir= ;;
 925   *) xsrcdir="$srcdir/" ;;
 926   esac
 927
 928   test -d "$xsrcdir$add_on/sysdeps" || {
 929     case "$configured_add_ons " in
 930     *" $add_on "*) ;;
 931     *|'')
 932       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 933       ;;
 934     esac
 935     continue
 936   }
 937
 938   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 939   case "$sysnames_add_ons" in
 940   *" $add_on/ "*) ;;
 941   *|'')
 942     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 943     continue ;;
 944   esac
 945
 946   found=no
 947   for d in $sysnames; do
 948     case "$d" in
 949     $add_on/sysdeps/*) ;;
 950     *) continue ;;
 951     esac
 952     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 953        case "$f" in
 954        sys|bits)
 955          for ff in $f/*.h; do
 956            test -d "$ff" || { test -e "$ff" && exit 88; }
 957          done
 958          ;;
 959        *)
 960          test -d "$f" || { test -e "$f" && exit 88; }
 961          ;;
 962        esac
 963      done)
 964     if test $? -eq 88; then
 965       found=yes
 966       break
 967     fi
 968   done
 969   if test $found = no; then
 970     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 971   fi
 972 done
 973 AC_SUBST(sysdeps_add_ons)
 974
 975
 976 ### Locate tools.
 977
 978 AC_PROG_INSTALL
 979 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 980   # The makefiles need to use a different form to find it in $srcdir.
 981   INSTALL='\$(..)./scripts/install-sh -c'
 982 fi
 983 AC_PROG_LN_S
 984
 985 LIBC_PROG_BINUTILS
 986
 987 # Accept binutils 2.22 or newer.
 988 AC_CHECK_PROG_VER(AS, $AS, --version,
 989                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 990                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 991                   AS=: critic_missing="$critic_missing as")
 992 AC_CHECK_PROG_VER(LD, $LD, --version,
 993                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 994                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 995                   LD=: critic_missing="$critic_missing ld")
 996
 997 # These programs are version sensitive.
 998 AC_CHECK_TOOL_PREFIX
 999 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1000   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1001   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1002
1003 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1004   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1005   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1006   MSGFMT=: aux_missing="$aux_missing msgfmt")
1007 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1008   [GNU texinfo.* \([0-9][0-9.]*\)],
1009   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1010   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1011 AC_CHECK_PROG_VER(SED, sed, --version,
1012   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1013   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1014   SED=: aux_missing="$aux_missing sed")
1015 AC_CHECK_PROG_VER(AWK, gawk, --version,
1016   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1017   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1018
1019 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1020 AC_TRY_COMPILE([], [
1021 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
1022 #error insufficient compiler
1023 #endif],
1024                [libc_cv_compiler_ok=yes],
1025                [libc_cv_compiler_ok=no])])
1026 AS_IF([test $libc_cv_compiler_ok != yes],
1027       [critic_missing="$critic_missing compiler"])
1028
1029 AC_CHECK_TOOL(NM, nm, false)
1030
1031 if test "x$maintainer" = "xyes"; then
1032   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1033   case "x$AUTOCONF" in
1034   xno|x|x:) AUTOCONF=no ;;
1035   *)
1036     AC_CACHE_CHECK(dnl
1037   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1038     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1039       libc_cv_autoconf_works=yes
1040     else
1041       libc_cv_autoconf_works=no
1042     fi])
1043     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1044     ;;
1045   esac
1046   if test "x$AUTOCONF" = xno; then
1047     aux_missing="$aux_missing autoconf"
1048   fi
1049 else
1050   AUTOCONF=no
1051 fi
1052
1053 test -n "$critic_missing" && AC_MSG_ERROR([
1054 *** These critical programs are missing or too old:$critic_missing
1055 *** Check the INSTALL file for required versions.])
1056
1057 test -n "$aux_missing" && AC_MSG_WARN([
1058 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1059 *** some features will be disabled.
1060 *** Check the INSTALL file for required versions.])
1061
1062 # if using special system headers, find out the compiler's sekrit
1063 # header directory and add that to the list.  NOTE: Only does the right
1064 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1065 if test -n "$sysheaders"; then
1066   SYSINCLUDES=-nostdinc
1067   for d in include include-fixed; do
1068     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1069     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1070   done
1071   SYSINCLUDES="$SYSINCLUDES \
1072 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1073   if test -n "$CXX"; then
1074     CXX_SYSINCLUDES=
1075     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1076     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1077       test "x$cxxheaders" != x &&
1078       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1079     done
1080   fi
1081 fi
1082 AC_SUBST(SYSINCLUDES)
1083 AC_SUBST(CXX_SYSINCLUDES)
1084
1085 # Obtain some C++ header file paths.  This is used to make a local
1086 # copy of those headers in Makerules.
1087 if test -n "$CXX"; then
1088   find_cxx_header () {
1089     echo "#include <$1>" | $CXX -M -MP -x c++ - | sed -n "/$1:/{s/:\$//;p}"
1090   }
1091   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1092   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1093 fi
1094 AC_SUBST(CXX_CSTDLIB_HEADER)
1095 AC_SUBST(CXX_CMATH_HEADER)
1096
1097 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1098 # since this would lead to problems installing/building glibc.
1099 # LD_LIBRARY_PATH contains the current directory if one of the following
1100 # is true:
1101 # - one of the terminals (":" and ";") is the first or last sign
1102 # - two terminals occur directly after each other
1103 # - the path contains an element with a dot in it
1104 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1105 changequote(,)dnl
1106 case ${LD_LIBRARY_PATH} in
1107   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1108     ld_library_path_setting="contains current directory"
1109     ;;
1110   *)
1111     ld_library_path_setting="ok"
1112     ;;
1113 esac
1114 changequote([,])dnl
1115 AC_MSG_RESULT($ld_library_path_setting)
1116 if test "$ld_library_path_setting" != "ok"; then
1117 AC_MSG_ERROR([
1118 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1119 *** building glibc. Please change the environment variable
1120 *** and run configure again.])
1121 fi
1122
1123 AC_PATH_PROG(BASH_SHELL, bash, no)
1124
1125 AC_PATH_PROG(PERL, perl, no)
1126 if test "$PERL" != no &&
1127    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1128   PERL=no
1129 fi
1130 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1131              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1132 AC_CHECK_PROG_VER(BISON, bison, --version,
1133                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1134                   [2.7*|[3-9].*|[1-9][0-9]*],
1135                   BISON=no)
1136
1137 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1138 cat > conftest.s <<EOF
1139 .text
1140 foo:
1141 .set glibc_conftest_frobozz,foo
1142 .globl glibc_conftest_frobozz
1143 EOF
1144 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1145 # (but it doesn't work), so we must do a linking check to be sure.
1146 cat > conftest1.c <<\EOF
1147 extern int glibc_conftest_frobozz;
1148 void _start() { glibc_conftest_frobozz = 1; }
1149 EOF
1150 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1151             -nostartfiles -nostdlib \
1152             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1153   libc_cv_asm_set_directive=yes
1154 else
1155   libc_cv_asm_set_directive=no
1156 fi
1157 rm -f conftest*])
1158 if test $libc_cv_asm_set_directive = yes; then
1159   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1160 fi
1161
1162 AC_CACHE_CHECK(linker support for protected data symbol,
1163                libc_cv_protected_data,
1164                [cat > conftest.c <<EOF
1165                 int bar __attribute__ ((visibility ("protected"))) = 1;
1166 EOF
1167                 libc_cv_protected_data=no
1168                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1169                   cat > conftest.c <<EOF
1170                   extern int bar;
1171                   int main (void) { return bar; }
1172 EOF
1173                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1174                     libc_cv_protected_data=yes
1175                   fi
1176                 fi
1177                 rm -f conftest.*
1178                ])
1179 AC_SUBST(libc_cv_protected_data)
1180
1181 AC_CACHE_CHECK(for broken __attribute__((alias())),
1182                libc_cv_broken_alias_attribute,
1183                [cat > conftest.c <<EOF
1184                extern int foo (int x) __asm ("xyzzy");
1185                int bar (int x) { return x; }
1186                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1187                extern int dfoo;
1188                extern __typeof (dfoo) dfoo __asm ("abccb");
1189                int dfoo = 1;
1190 EOF
1191                libc_cv_broken_alias_attribute=yes
1192                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1193                  if grep 'xyzzy' conftest.s >/dev/null &&
1194                     grep 'abccb' conftest.s >/dev/null; then
1195                    libc_cv_broken_alias_attribute=no
1196                  fi
1197                fi
1198                rm -f conftest.c conftest.s
1199                ])
1200 if test $libc_cv_broken_alias_attribute = yes; then
1201   AC_MSG_ERROR(working alias attribute support required)
1202 fi
1203
1204 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1205                libc_cv_have_sdata_section,
1206                [echo "int i;" > conftest.c
1207                 libc_cv_have_sdata_section=no
1208                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1209                    | grep '\.sdata' >/dev/null; then
1210                   libc_cv_have_sdata_section=yes
1211                 fi
1212                 rm -f conftest.c conftest.so
1213                ])
1214 if test $libc_cv_have_sdata_section = yes; then
1215   AC_DEFINE(HAVE_SDATA_SECTION)
1216 fi
1217
1218 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1219                libc_cv_ctors_header, [dnl
1220   libc_cv_ctors_header=yes
1221   LIBC_TRY_LINK_STATIC([
1222 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1223 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1224 ],
1225               [dnl
1226       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1227         { gsub(/\@<:@ */, "@<:@") }
1228         $2 == ".ctors" || $2 == ".dtors" {
1229           size = strtonum("0x" $6)
1230           align = strtonum("0x" $NF)
1231           seen@<:@$2@:>@ = 1
1232           stub@<:@$2@:>@ = size == align * 2
1233         }
1234         END {
1235           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1236           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1237           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1238         }
1239       '], [libc_cv_ctors_header=no])
1240     ], [dnl
1241       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1242     ])
1243 ])
1244 if test $libc_cv_ctors_header = no; then
1245   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1246 fi
1247
1248 AC_CACHE_CHECK(for libunwind-support in compiler,
1249                libc_cv_cc_with_libunwind, [
1250   cat > conftest.c <<EOF
1251 int main (void) { return 0; }
1252 EOF
1253   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1254      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1255     libc_cv_cc_with_libunwind=yes
1256   else
1257     libc_cv_cc_with_libunwind=no
1258   fi
1259   rm -f conftest*])
1260 AC_SUBST(libc_cv_cc_with_libunwind)
1261 if test $libc_cv_cc_with_libunwind = yes; then
1262   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1263 fi
1264
1265 ASFLAGS_config=
1266 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1267                libc_cv_as_noexecstack, [dnl
1268 cat > conftest.c <<EOF
1269 void foo (void) { }
1270 EOF
1271 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1272                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1273    && grep .note.GNU-stack conftest.s >/dev/null \
1274    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1275                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1276 then
1277   libc_cv_as_noexecstack=yes
1278 else
1279   libc_cv_as_noexecstack=no
1280 fi
1281 rm -f conftest*])
1282 if test $libc_cv_as_noexecstack = yes; then
1283   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1284 fi
1285 AC_SUBST(ASFLAGS_config)
1286
1287 AC_CACHE_CHECK(for -z combreloc,
1288                libc_cv_z_combreloc, [dnl
1289 cat > conftest.c <<EOF
1290 extern int bar (int);
1291 extern int mumble;
1292 int foo (void) { return bar (mumble); }
1293 EOF
1294 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1295                         -fPIC -shared -o conftest.so conftest.c
1296                         -nostdlib -nostartfiles
1297                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1298 then
1299 dnl The following test is a bit weak.  We must use a tool which can test
1300 dnl cross-platform since the gcc used can be a cross compiler.  Without
1301 dnl introducing new options this is not easily doable.  Instead use a tool
1302 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1303 dnl look for a section named .rel.dyn.
1304   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1305     libc_cv_z_combreloc=yes
1306   else
1307     libc_cv_z_combreloc=no
1308   fi
1309 else
1310   libc_cv_z_combreloc=no
1311 fi
1312 rm -f conftest*])
1313 if test "$libc_cv_z_combreloc" = yes; then
1314   AC_DEFINE(HAVE_Z_COMBRELOC)
1315 fi
1316 AC_SUBST(libc_cv_z_combreloc)
1317
1318 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1319                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1320 AC_SUBST(libc_cv_z_execstack)
1321
1322 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1323 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1324 ])
1325
1326 AC_SUBST(libc_cv_fpie)
1327
1328 AC_CACHE_CHECK(for --hash-style option,
1329                libc_cv_hashstyle, [dnl
1330 cat > conftest.c <<EOF
1331 int _start (void) { return 42; }
1332 EOF
1333 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1334                             -fPIC -shared -o conftest.so conftest.c
1335                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1336 then
1337   libc_cv_hashstyle=yes
1338 else
1339   libc_cv_hashstyle=no
1340 fi
1341 rm -f conftest*])
1342 AC_SUBST(libc_cv_hashstyle)
1343
1344 # The linker's default -shared behavior is good enough if it
1345 # does these things that our custom linker scripts ensure that
1346 # all allocated NOTE sections come first.
1347 if test "$use_default_link" = default; then
1348   AC_CACHE_CHECK([for sufficient default -shared layout],
1349                   libc_cv_use_default_link, [dnl
1350   libc_cv_use_default_link=no
1351   cat > conftest.s <<\EOF
1352           .section .note.a,"a",%note
1353           .balign 4
1354           .long 4,4,9
1355           .string "GNU"
1356           .string "foo"
1357           .section .note.b,"a",%note
1358           .balign 4
1359           .long 4,4,9
1360           .string "GNU"
1361           .string "bar"
1362 EOF
1363   if AC_TRY_COMMAND([dnl
1364   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1365        ac_try=`$READELF -S conftest.so | sed -n \
1366          ['${x;p;}
1367           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1368           t a
1369           b
1370           : a
1371           H']`
1372   then
1373     libc_seen_a=no libc_seen_b=no
1374     set -- $ac_try
1375     while test $# -ge 2 -a "$1" = NOTE; do
1376       case "$2" in
1377       .note.a) libc_seen_a=yes ;;
1378       .note.b) libc_seen_b=yes ;;
1379       esac
1380       shift 2
1381     done
1382     case "$libc_seen_a$libc_seen_b" in
1383     yesyes)
1384       libc_cv_use_default_link=yes
1385       ;;
1386     *)
1387       echo >&AS_MESSAGE_LOG_FD "\
1388 $libc_seen_a$libc_seen_b from:
1389 $ac_try"
1390       ;;
1391     esac
1392   fi
1393   rm -f conftest*])
1394   use_default_link=$libc_cv_use_default_link
1395 fi
1396
1397 AC_CACHE_CHECK(for GLOB_DAT reloc,
1398                libc_cv_has_glob_dat, [dnl
1399 cat > conftest.c <<EOF
1400 extern int mumble;
1401 int foo (void) { return mumble; }
1402 EOF
1403 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1404                         -fPIC -shared -o conftest.so conftest.c
1405                         -nostdlib -nostartfiles
1406                         1>&AS_MESSAGE_LOG_FD])
1407 then
1408 dnl look for GLOB_DAT relocation.
1409   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1410     libc_cv_has_glob_dat=yes
1411   else
1412     libc_cv_has_glob_dat=no
1413   fi
1414 else
1415   libc_cv_has_glob_dat=no
1416 fi
1417 rm -f conftest*])
1418 AC_SUBST(libc_cv_has_glob_dat)
1419
1420 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1421 if libc_cv_output_format=`
1422 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1423 then
1424   :
1425 else
1426   libc_cv_output_format=
1427 fi
1428 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1429 AC_SUBST(libc_cv_output_format)
1430
1431 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1432 cat > conftest.c <<EOF
1433 int foo;
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1436                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1437 then
1438   libc_cv_fno_toplevel_reorder=yes
1439 else
1440   libc_cv_fno_toplevel_reorder=no
1441 fi
1442 rm -f conftest*])
1443 if test $libc_cv_fno_toplevel_reorder = yes; then
1444   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1445 else
1446   fno_unit_at_a_time=-fno-unit-at-a-time
1447 fi
1448 AC_SUBST(fno_unit_at_a_time)
1449
1450 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1451 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1452                    [libc_cv_ssp=yes],
1453                    [libc_cv_ssp=no])
1454 ])
1455
1456 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1457 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1458                    [libc_cv_ssp_strong=yes],
1459                    [libc_cv_ssp_strong=no])
1460 ])
1461
1462 stack_protector=
1463 if test "$libc_cv_ssp_strong" = "yes"; then
1464   stack_protector="-fstack-protector-strong"
1465 elif test "$libc_cv_ssp" = "yes"; then
1466   stack_protector="-fstack-protector"
1467 fi
1468 AC_SUBST(stack_protector)
1469
1470 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1471 [dnl
1472 cat > conftest.c <<EOF
1473 __thread int i;
1474 void foo (void)
1475 {
1476   i = 10;
1477 }
1478 EOF
1479 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1480                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1481 then
1482   libc_cv_mtls_dialect_gnu2=yes
1483 else
1484   libc_cv_mtls_dialect_gnu2=no
1485 fi
1486 rm -f conftest*])
1487 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1488 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1489
1490 AC_CACHE_CHECK(whether cc puts quotes around section names,
1491                libc_cv_have_section_quotes,
1492                [cat > conftest.c <<EOF
1493                 static const int foo
1494                 __attribute__ ((section ("bar"))) = 1;
1495 EOF
1496                 if ${CC-cc} -S conftest.c -o conftest.s; then
1497                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1498                     libc_cv_have_section_quotes=yes
1499                   else
1500                     libc_cv_have_section_quotes=no
1501                   fi
1502                 else
1503                   libc_cv_have_section_quotes=unknown
1504                 fi
1505                 rm -f conftest.{c,s}
1506                 ])
1507 if test $libc_cv_have_section_quotes = yes; then
1508   AC_DEFINE(HAVE_SECTION_QUOTES)
1509 fi
1510
1511 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1512 cat > conftest.c <<\EOF
1513 void zero (void *x)
1514 {
1515   __builtin_memset (x, 0, 1000);
1516 }
1517 EOF
1518 dnl
1519 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1520 then
1521   libc_cv_gcc_builtin_memset=no
1522 else
1523   libc_cv_gcc_builtin_memset=yes
1524 fi
1525 rm -f conftest* ])
1526 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1527   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1528 fi
1529
1530 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1531 cat > conftest.c <<\EOF
1532 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1533 char *foo (const char *a, const char *b)
1534 {
1535   return __builtin_strstr (a, b);
1536 }
1537 EOF
1538 dnl
1539 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1540 then
1541   libc_cv_gcc_builtin_redirection=yes
1542 else
1543   libc_cv_gcc_builtin_redirection=no
1544 fi
1545 rm -f conftest* ])
1546 if test "$libc_cv_gcc_builtin_redirection" = no; then
1547   AC_MSG_ERROR([support for the symbol redirection needed])
1548 fi
1549
1550 dnl Determine how to disable generation of FMA instructions.
1551 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1552                libc_cv_cc_nofma, [dnl
1553 libc_cv_cc_nofma=
1554 for opt in -ffp-contract=off -mno-fused-madd; do
1555   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1556 done])
1557 AC_SUBST(libc_cv_cc_nofma)
1558
1559 if test -n "$submachine"; then
1560   AC_CACHE_CHECK([for compiler option for CPU variant],
1561                  libc_cv_cc_submachine, [dnl
1562   libc_cv_cc_submachine=no
1563   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1564     LIBC_TRY_CC_OPTION([$opt], [
1565       libc_cv_cc_submachine="$opt"
1566       break], [])
1567   done])
1568   if test "x$libc_cv_cc_submachine" = xno; then
1569     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1570   fi
1571 fi
1572 AC_SUBST(libc_cv_cc_submachine)
1573
1574 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1575 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1576 cat > conftest.c <<EOF
1577 void
1578 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1579 foo (void) {}
1580 EOF
1581 libc_cv_cc_loop_to_function=no
1582 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1583 then
1584   libc_cv_cc_loop_to_function=yes
1585 fi
1586 rm -f conftest*])
1587 if test $libc_cv_cc_loop_to_function = yes; then
1588   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1589 fi
1590 AC_SUBST(libc_cv_cc_loop_to_function)
1591
1592 dnl Check whether we have the gd library available.
1593 AC_MSG_CHECKING(for libgd)
1594 if test "$with_gd" != "no"; then
1595   old_CFLAGS="$CFLAGS"
1596   CFLAGS="$CFLAGS $libgd_include"
1597   old_LDFLAGS="$LDFLAGS"
1598   LDFLAGS="$LDFLAGS $libgd_ldflags"
1599   old_LIBS="$LIBS"
1600   LIBS="$LIBS -lgd -lpng -lz -lm"
1601   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1602   CFLAGS="$old_CFLAGS"
1603   LDFLAGS="$old_LDFLAGS"
1604   LIBS="$old_LIBS"
1605 else
1606   LIBGD=no
1607 fi
1608 AC_MSG_RESULT($LIBGD)
1609 AC_SUBST(LIBGD)
1610
1611 # SELinux detection
1612 if test x$with_selinux = xno ; then
1613   have_selinux=no;
1614 else
1615   # See if we have the SELinux library
1616   AC_CHECK_LIB(selinux, is_selinux_enabled,
1617                have_selinux=yes, have_selinux=no)
1618   if test x$with_selinux = xyes ; then
1619     if test x$have_selinux = xno ; then
1620       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1621     fi
1622   fi
1623 fi
1624 # Check if we're building with SELinux support.
1625 if test "x$have_selinux" = xyes; then
1626   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1627
1628   # See if we have the libaudit library
1629   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1630                have_libaudit=yes, have_libaudit=no)
1631   if test "x$have_libaudit" = xyes; then
1632     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1633   fi
1634   AC_SUBST(have_libaudit)
1635
1636   # See if we have the libcap library
1637   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1638   if test "x$have_libcap" = xyes; then
1639     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1640   fi
1641   AC_SUBST(have_libcap)
1642 fi
1643 AC_SUBST(have_selinux)
1644
1645 CPPUNDEFS=
1646 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1647 dnl Since we are building the implementations of the fortified functions here,
1648 dnl having the macro defined interacts very badly.
1649 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1650 [AC_TRY_COMPILE([], [
1651 #ifdef _FORTIFY_SOURCE
1652 # error bogon
1653 #endif],
1654                 [libc_cv_predef_fortify_source=no],
1655                 [libc_cv_predef_fortify_source=yes])])
1656 if test $libc_cv_predef_fortify_source = yes; then
1657   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1658 fi
1659 AC_SUBST(CPPUNDEFS)
1660
1661 dnl Check for silly hacked compilers inserting -fstack-protector.
1662 dnl This breaks badly for the early startup code we compile, since
1663 dnl the compiled code can refer to a magic machine-dependent location
1664 dnl for the canary value before we have sufficient setup for that to
1665 dnl work.  It's also questionable to build all of libc with this flag
1666 dnl even when you're doing that for most applications you build, since
1667 dnl libc's code is so heavily-used and performance-sensitive.  If we
1668 dnl ever really want to make that work, it should be enabled explicitly
1669 dnl in the libc build, not inherited from implicit compiler settings.
1670 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1671                libc_cv_predef_stack_protector, [
1672 AC_TRY_COMPILE([extern void foobar (char *);],
1673                [char large_array[2048]; foobar (large_array);], [
1674 libc_undefs=`$NM -u conftest.o |
1675   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1676     2>&AS_MESSAGE_LOG_FD` || {
1677   AC_MSG_ERROR([confusing output from $NM -u])
1678 }
1679 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1680 # On some architectures, there are architecture-specific undefined
1681 # symbols (resolved by the linker), so filter out unknown symbols.
1682 # This will fail to produce the correct result if the compiler
1683 # defaults to -fstack-protector but this produces an undefined symbol
1684 # other than __stack_chk_fail or __stack_chk_fail_local. However,
1685 # compilers like that have not been encountered in practice.
1686 libc_undefs=`echo "$libc_undefs" | \
1687   egrep '^(foobar|__stack_chk_fail|__stack_chk_fail_local)$'`
1688 case "$libc_undefs" in
1689 foobar) libc_cv_predef_stack_protector=no ;;
1690 '__stack_chk_fail
1691 foobar'|'__stack_chk_fail_local
1692 foobar') libc_cv_predef_stack_protector=yes ;;
1693 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1694 esac],
1695                [AC_MSG_ERROR([test compilation failed])])
1696 ])
1697 libc_extra_cflags=
1698 if test $libc_cv_predef_stack_protector = yes; then
1699   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1700 fi
1701 libc_extra_cppflags=
1702
1703 # Some linkers on some architectures support __ehdr_start but with
1704 # bugs.  Make sure usage of it does not create relocations in the
1705 # output (as the linker should resolve them all for us).
1706 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1707                libc_cv_ehdr_start, [
1708 old_CFLAGS="$CFLAGS"
1709 old_LDFLAGS="$LDFLAGS"
1710 old_LIBS="$LIBS"
1711 CFLAGS="$CFLAGS -fPIC"
1712 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1713 LIBS=
1714 AC_LINK_IFELSE([AC_LANG_SOURCE([
1715 typedef struct {
1716   char foo;
1717   long val;
1718 } Ehdr;
1719 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1720 long ehdr (void) { return __ehdr_start.val; }
1721 ])],
1722                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1723                   libc_cv_ehdr_start=broken
1724                 else
1725                   libc_cv_ehdr_start=yes
1726                 fi], [libc_cv_ehdr_start=no])
1727 CFLAGS="$old_CFLAGS"
1728 LDFLAGS="$old_LDFLAGS"
1729 LIBS="$old_LIBS"
1730 ])
1731 if test "$libc_cv_ehdr_start" = yes; then
1732   AC_DEFINE([HAVE_EHDR_START])
1733 elif test "$libc_cv_ehdr_start" = broken; then
1734   AC_MSG_WARN([linker is broken -- you should upgrade])
1735 fi
1736
1737 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1738                libc_cv_builtin_trap, [dnl
1739 libc_cv_builtin_trap=no
1740 AC_TRY_COMPILE([], [__builtin_trap ()], [
1741 libc_undefs=`$NM -u conftest.o |
1742   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1743     2>&AS_MESSAGE_LOG_FD` || {
1744   AC_MSG_ERROR([confusing output from $NM -u])
1745 }
1746 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1747 if test -z "$libc_undefs"; then
1748   libc_cv_builtin_trap=yes
1749 fi])])
1750 if test $libc_cv_builtin_trap = yes; then
1751   AC_DEFINE([HAVE_BUILTIN_TRAP])
1752 fi
1753
1754 dnl C++ feature tests.
1755 AC_LANG_PUSH([C++])
1756
1757 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1758                libc_cv_cxx_thread_local, [
1759 old_CXXFLAGS="$CXXFLAGS"
1760 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1761 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1762 #include <thread>
1763
1764 // Compiler support.
1765 struct S
1766 {
1767   S ();
1768   ~S ();
1769 };
1770 thread_local S s;
1771 S * get () { return &s; }
1772
1773 // libstdc++ support.
1774 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1775 #error __cxa_thread_atexit_impl not supported
1776 #endif
1777 ])],
1778                [libc_cv_cxx_thread_local=yes],
1779                [libc_cv_cxx_thread_local=no])
1780 CXXFLAGS="$old_CXXFLAGS"
1781 ])
1782 AC_SUBST(libc_cv_cxx_thread_local)
1783
1784 AC_LANG_POP([C++])
1785 dnl End of C++ feature tests.
1786
1787 ### End of automated tests.
1788 ### Now run sysdeps configure fragments.
1789
1790 # They also can set these variables.
1791 use_ldconfig=no
1792 ldd_rewrite_script=no
1793 libc_cv_sysconfdir=$sysconfdir
1794 libc_cv_localstatedir=$localstatedir
1795 libc_cv_gcc_unwind_find_fde=no
1796 libc_cv_idn=no
1797
1798 # Iterate over all the sysdep directories we will use, running their
1799 # configure fragments.
1800 for dir in $sysnames; do
1801   case $dir in
1802     /*) dest=$dir ;;
1803     *)  dest=$srcdir/$dir ;;
1804   esac
1805   if test -r $dest/configure; then
1806     AC_MSG_RESULT(running configure fragment for $dir)
1807     . $dest/configure
1808   fi
1809 done
1810
1811 if test x"$build_mathvec" = xnotset; then
1812   build_mathvec=no
1813 fi
1814 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1815
1816 AC_SUBST(libc_extra_cflags)
1817 AC_SUBST(libc_extra_cppflags)
1818
1819 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1820   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1821 fi
1822 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1823
1824 # A sysdeps configure fragment can reset this if IFUNC is not actually
1825 # usable even though the assembler knows how to generate the symbol type.
1826 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1827   AC_DEFINE(HAVE_IFUNC)
1828 fi
1829
1830 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1831   AC_DEFINE(HAVE_GCC_IFUNC)
1832 fi
1833
1834 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1835 # configure fragment can override the value to prevent this AC_DEFINE.
1836 AC_SUBST(use_nscd)
1837 if test "x$use_nscd" != xno; then
1838   AC_DEFINE([USE_NSCD])
1839 fi
1840 if test "x$build_nscd" = xdefault; then
1841   build_nscd=$use_nscd
1842 fi
1843
1844 AC_SUBST(libc_cv_slibdir)
1845 AC_SUBST(libc_cv_rtlddir)
1846 AC_SUBST(libc_cv_complocaledir)
1847 AC_SUBST(libc_cv_sysconfdir)
1848 AC_SUBST(libc_cv_localstatedir)
1849 AC_SUBST(libc_cv_rootsbindir)
1850
1851 if test x$use_ldconfig = xyes; then
1852   AC_DEFINE(USE_LDCONFIG)
1853 fi
1854 AC_SUBST(use_ldconfig)
1855 AC_SUBST(ldd_rewrite_script)
1856
1857 AC_SUBST(static)
1858 AC_SUBST(shared)
1859
1860 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1861 [libc_cv_pic_default=yes
1862 cat > conftest.c <<EOF
1863 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1864 # error PIC is default.
1865 #endif
1866 EOF
1867 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1868   libc_cv_pic_default=no
1869 fi
1870 rm -f conftest.*])
1871 AC_SUBST(libc_cv_pic_default)
1872
1873 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1874 [libc_cv_pie_default=yes
1875 cat > conftest.c <<EOF
1876 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1877 # error PIE is default.
1878 #endif
1879 EOF
1880 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1881   libc_cv_pie_default=no
1882 fi
1883 rm -f conftest.*])
1884 AC_SUBST(libc_cv_pie_default)
1885
1886 AC_SUBST(profile)
1887 AC_SUBST(static_nss)
1888
1889 AC_SUBST(DEFINES)
1890
1891 dnl See sysdeps/mach/configure.ac for this variable.
1892 AC_SUBST(mach_interface_list)
1893
1894 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1895 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1896 AC_SUBST(VERSION)
1897 AC_SUBST(RELEASE)
1898
1899 AC_CONFIG_FILES([config.make Makefile])
1900 AC_CONFIG_COMMANDS([default],[[
1901 case $CONFIG_FILES in *config.make*)
1902 echo "$config_vars" >> config.make;;
1903 esac
1904 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1905 AC_OUTPUT