configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([binutils],
 131             AC_HELP_STRING([--with-binutils=PATH],
 132                            [specify location of binutils (as and ld)]),
 133             [path_binutils=$withval],
 134             [path_binutils=''])
 135 AC_ARG_WITH([selinux],
 136             AC_HELP_STRING([--with-selinux],
 137                            [if building with SELinux support]),
 138             [with_selinux=$withval],
 139             [with_selinux=auto])
 140
 141 AC_ARG_WITH([headers],
 142             AC_HELP_STRING([--with-headers=PATH],
 143                            [location of system headers to use
 144                             (for example /usr/src/linux/include)
 145                             @<:@default=compiler default@:>@]),
 146             [sysheaders=$withval],
 147             [sysheaders=''])
 148 AC_SUBST(sysheaders)
 149
 150 AC_SUBST(use_default_link)
 151 AC_ARG_WITH([default-link],
 152             AC_HELP_STRING([--with-default-link],
 153                            [do not use explicit linker scripts]),
 154             [use_default_link=$withval],
 155             [use_default_link=default])
 156
 157 dnl Additional build flags injection.
 158 AC_ARG_WITH([nonshared-cflags],
 159             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 160                            [build nonshared libraries with additional CFLAGS]),
 161             [extra_nonshared_cflags=$withval],
 162             [extra_nonshared_cflags=])
 163 AC_SUBST(extra_nonshared_cflags)
 164
 165 AC_ARG_ENABLE([sanity-checks],
 166               AC_HELP_STRING([--disable-sanity-checks],
 167                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 168               [enable_sanity=$enableval],
 169               [enable_sanity=yes])
 170
 171 AC_ARG_ENABLE([shared],
 172               AC_HELP_STRING([--enable-shared],
 173                              [build shared library @<:@default=yes if GNU ld@:>@]),
 174               [shared=$enableval],
 175               [shared=yes])
 176 AC_ARG_ENABLE([profile],
 177               AC_HELP_STRING([--enable-profile],
 178                              [build profiled library @<:@default=no@:>@]),
 179               [profile=$enableval],
 180               [profile=no])
 181 AC_ARG_ENABLE([static-pie],
 182               AC_HELP_STRING([--enable-static-pie],
 183                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 184               [static_pie=$enableval],
 185               [static_pie=no])
 186 AC_ARG_ENABLE([timezone-tools],
 187               AC_HELP_STRING([--disable-timezone-tools],
 188                              [do not install timezone tools @<:@default=install@:>@]),
 189               [enable_timezone_tools=$enableval],
 190               [enable_timezone_tools=yes])
 191 AC_SUBST(enable_timezone_tools)
 192
 193 AC_ARG_ENABLE([hardcoded-path-in-tests],
 194               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 195                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 196               [hardcoded_path_in_tests=$enableval],
 197               [hardcoded_path_in_tests=no])
 198 AC_SUBST(hardcoded_path_in_tests)
 199
 200 AC_ARG_ENABLE([stackguard-randomization],
 201               AC_HELP_STRING([--enable-stackguard-randomization],
 202                              [initialize __stack_chk_guard canary with a random number at program start]),
 203               [enable_stackguard_randomize=$enableval],
 204               [enable_stackguard_randomize=no])
 205 if test "$enable_stackguard_randomize" = yes; then
 206   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 207 fi
 208
 209 AC_ARG_ENABLE([hidden-plt],
 210               AC_HELP_STRING([--disable-hidden-plt],
 211                              [do not hide internal function calls to avoid PLT]),
 212               [hidden=$enableval],
 213               [hidden=yes])
 214 if test "x$hidden" = xno; then
 215   AC_DEFINE(NO_HIDDEN)
 216 fi
 217
 218 AC_ARG_ENABLE([bind-now],
 219               AC_HELP_STRING([--enable-bind-now],
 220                              [disable lazy relocations in DSOs]),
 221               [bindnow=$enableval],
 222               [bindnow=no])
 223 AC_SUBST(bindnow)
 224 if test "x$bindnow" = xyes; then
 225   AC_DEFINE(BIND_NOW)
 226 fi
 227
 228 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 229 dnl -fstack-protector-strong.
 230 AC_ARG_ENABLE([stack-protector],
 231               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 232                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 233               [enable_stack_protector=$enableval],
 234               [enable_stack_protector=no])
 235 case "$enable_stack_protector" in
 236 all|yes|no|strong) ;;
 237 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 238 esac
 239
 240 dnl On some platforms we cannot use dynamic loading.  We must provide
 241 dnl static NSS modules.
 242 AC_ARG_ENABLE([static-nss],
 243               AC_HELP_STRING([--enable-static-nss],
 244                              [build static NSS modules @<:@default=no@:>@]),
 245               [static_nss=$enableval],
 246               [static_nss=no])
 247 dnl Enable static NSS also if we build no shared objects.
 248 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 249   static_nss=yes
 250   AC_DEFINE(DO_STATIC_NSS)
 251 fi
 252
 253 AC_ARG_ENABLE([force-install],
 254               AC_HELP_STRING([--disable-force-install],
 255                              [don't force installation of files from this package, even if they are older than the installed files]),
 256               [force_install=$enableval],
 257               [force_install=yes])
 258 AC_SUBST(force_install)
 259
 260 AC_ARG_ENABLE([maintainer-mode],
 261               AC_HELP_STRING([--enable-maintainer-mode],
 262                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 263               [maintainer=$enableval],
 264               [maintainer=no])
 265
 266 dnl On some platforms we allow dropping compatibility with all kernel
 267 dnl versions.
 268 AC_ARG_ENABLE([kernel],
 269               AC_HELP_STRING([--enable-kernel=VERSION],
 270                              [compile for compatibility with kernel not older than VERSION]),
 271               [minimum_kernel=$enableval],
 272               [])
 273 dnl Prevent unreasonable values.
 274 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 275   # Better nothing than this.
 276   minimum_kernel=""
 277 else
 278   if test "$minimum_kernel" = current; then
 279     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 280   fi
 281 fi
 282
 283 dnl For the development we sometimes want gcc to issue even more warnings.
 284 dnl This is not the default since many of the extra warnings are not
 285 dnl appropriate.
 286 AC_ARG_ENABLE([all-warnings],
 287               AC_HELP_STRING([--enable-all-warnings],
 288                              [enable all useful warnings gcc can issue]),
 289               [all_warnings=$enableval],
 290               [])
 291 AC_SUBST(all_warnings)
 292
 293 AC_ARG_ENABLE([werror],
 294               AC_HELP_STRING([--disable-werror],
 295                              [do not build with -Werror]),
 296               [enable_werror=$enableval],
 297               [enable_werror=yes])
 298 AC_SUBST(enable_werror)
 299
 300 AC_ARG_ENABLE([multi-arch],
 301               AC_HELP_STRING([--enable-multi-arch],
 302                              [enable single DSO with optimizations for multiple architectures]),
 303               [multi_arch=$enableval],
 304               [multi_arch=default])
 305
 306 AC_ARG_ENABLE([experimental-malloc],
 307               AC_HELP_STRING([--disable-experimental-malloc],
 308                              [disable experimental malloc features]),
 309               [experimental_malloc=$enableval],
 310               [experimental_malloc=yes])
 311 AC_SUBST(experimental_malloc)
 312
 313 AC_ARG_ENABLE([crypt],
 314               AC_HELP_STRING([--disable-crypt],
 315                              [do not build nor install the passphrase hashing library, libcrypt]),
 316               [build_crypt=$enableval],
 317               [build_crypt=yes])
 318 AC_SUBST(build_crypt)
 319
 320 AC_ARG_ENABLE([nss-crypt],
 321               AC_HELP_STRING([--enable-nss-crypt],
 322                              [enable libcrypt to use nss]),
 323               [nss_crypt=$enableval],
 324               [nss_crypt=no])
 325 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 326   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 327   nss_crypt=no
 328 fi
 329 if test x$nss_crypt = xyes; then
 330   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 331   if test $? -ne 0; then
 332     AC_MSG_ERROR([cannot find include directory with nss-config])
 333   fi
 334   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 335   if test $? -ne 0; then
 336     AC_MSG_ERROR([cannot find include directory with nspr-config])
 337   fi
 338   old_CFLAGS="$CFLAGS"
 339   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 340   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 341 #include <hasht.h>
 342 #include <nsslowhash.h>
 343 void f (void) { NSSLOW_Init (); }])],
 344              libc_cv_nss_crypt=yes,
 345              AC_MSG_ERROR([
 346 cannot find NSS headers with lowlevel hash function interfaces]))
 347   old_LIBS="$LIBS"
 348   old_LDFLAGS="$LDFLAGS"
 349   LIBS="$LIBS -lfreebl3"
 350   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 351 #include <hasht.h>
 352 #include <nsslowhash.h>],
 353                                   [NSSLOW_Init();])],
 354                  libc_cv_nss_crypt=yes,
 355                  AC_MSG_ERROR([
 356 cannot link program using lowlevel NSS hash functions]))
 357   # Check to see if there is a static NSS cryptographic library.
 358   # If there isn't then we can't link anything with libcrypt.a,
 359   # and that might mean disabling some static tests.
 360   LDFLAGS="$LDFLAGS -static"
 361   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 362 #include <hasht.h>
 363 #include <nsslowhash.h>],
 364                                   [NSSLOW_Init();])],
 365                  libc_cv_static_nss_crypt=yes,
 366                  libc_cv_static_nss_crypt=no)
 367   LDFLAGS="$old_LDFLAGS"
 368   CFLAGS="$old_CFLAGS"
 369   LIBS="$old_LIBS"
 370 else
 371   libc_cv_nss_crypt=no
 372   libc_cv_static_nss_crypt=no
 373 fi
 374 AC_SUBST(libc_cv_nss_crypt)
 375 AC_SUBST(libc_cv_static_nss_crypt)
 376
 377
 378 AC_ARG_ENABLE([obsolete-rpc],
 379               AC_HELP_STRING([--enable-obsolete-rpc],
 380                              [build and install the obsolete RPC code for link-time usage]),
 381               [link_obsolete_rpc=$enableval],
 382               [link_obsolete_rpc=no])
 383 AC_SUBST(link_obsolete_rpc)
 384
 385 if test "$link_obsolete_rpc" = yes; then
 386   AC_DEFINE(LINK_OBSOLETE_RPC)
 387 fi
 388
 389 AC_ARG_ENABLE([obsolete-nsl],
 390               AC_HELP_STRING([--enable-obsolete-nsl],
 391                              [build and install the obsolete libnsl library and depending NSS modules]),
 392               [build_obsolete_nsl=$enableval],
 393               [build_obsolete_nsl=no])
 394 AC_SUBST(build_obsolete_nsl)
 395
 396 if test "$build_obsolete_nsl" = yes; then
 397   AC_DEFINE(LINK_OBSOLETE_NSL)
 398 fi
 399
 400 AC_ARG_ENABLE([systemtap],
 401               [AS_HELP_STRING([--enable-systemtap],
 402                [enable systemtap static probe points @<:@default=no@:>@])],
 403               [systemtap=$enableval],
 404               [systemtap=no])
 405 if test "x$systemtap" != xno; then
 406   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 407   old_CFLAGS="$CFLAGS"
 408   CFLAGS="-std=gnu11 $CFLAGS"
 409   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 410 void foo (int i, void *p)
 411 {
 412   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 413        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 414 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 415   CFLAGS="$old_CFLAGS"])
 416   if test $libc_cv_sdt = yes; then
 417     AC_DEFINE([USE_STAP_PROBE])
 418   elif test "x$systemtap" != xauto; then
 419     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 420   fi
 421 fi
 422
 423 AC_ARG_ENABLE([build-nscd],
 424               [AS_HELP_STRING([--disable-build-nscd],
 425                [disable building and installing the nscd daemon])],
 426               [build_nscd=$enableval],
 427               [build_nscd=default])
 428 AC_SUBST(build_nscd)
 429
 430 # Note the use of $use_nscd is near the bottom of the file.
 431 AC_ARG_ENABLE([nscd],
 432               [AS_HELP_STRING([--disable-nscd],
 433                [library functions will not contact the nscd daemon])],
 434               [use_nscd=$enableval],
 435               [use_nscd=yes])
 436
 437 AC_ARG_ENABLE([pt_chown],
 438               [AS_HELP_STRING([--enable-pt_chown],
 439                [Enable building and installing pt_chown])],
 440               [build_pt_chown=$enableval],
 441               [build_pt_chown=no])
 442 AC_SUBST(build_pt_chown)
 443 if test "$build_pt_chown" = yes; then
 444   AC_DEFINE(HAVE_PT_CHOWN)
 445 fi
 446
 447 AC_ARG_ENABLE([tunables],
 448               [AS_HELP_STRING([--enable-tunables],
 449                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 450               [have_tunables=$enableval],
 451               [have_tunables=yes])
 452 AC_SUBST(have_tunables)
 453 if test "$have_tunables" = yes; then
 454   AC_DEFINE(HAVE_TUNABLES)
 455 fi
 456
 457 # The abi-tags file uses a fairly simplistic model for name recognition that
 458 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 459 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 460 # This doesn't get used much beyond that, so it's fairly safe.
 461 case "$host_os" in
 462 linux*)
 463   ;;
 464 gnu*)
 465   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 466   ;;
 467 esac
 468
 469 AC_ARG_ENABLE([mathvec],
 470               [AS_HELP_STRING([--enable-mathvec],
 471               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 472               [build_mathvec=$enableval],
 473               [build_mathvec=notset])
 474
 475 AC_ARG_ENABLE([cet],
 476               AC_HELP_STRING([--enable-cet],
 477                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 478               [enable_cet=$enableval],
 479               [enable_cet=no])
 480
 481 # We keep the original values in `$config_*' and never modify them, so we
 482 # can write them unchanged into config.make.  Everything else uses
 483 # $machine, $vendor, and $os, and changes them whenever convenient.
 484 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 485
 486 # Don't allow vendor == "unknown"
 487 test "$config_vendor" = unknown && config_vendor=
 488 config_os="`echo $config_os | sed 's/^unknown-//'`"
 489
 490 # Some configurations imply other options.
 491 elf=yes
 492
 493 # The configure fragment of a port can modify these to supplement
 494 # or override the table in the case statement below.  No fragment should
 495 # ever change the config_* variables, however.
 496 machine=$config_machine
 497 vendor=$config_vendor
 498 os=$config_os
 499 base_os=''
 500
 501 submachine=
 502 AC_ARG_WITH([cpu],
 503             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 504             [dnl
 505   case "$withval" in
 506   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 507   no) ;;
 508   *) submachine="$withval" ;;
 509   esac
 510 ])
 511
 512 # An preconfigure script can set this when it wants to disable the sanity
 513 # check below.
 514 libc_config_ok=no
 515
 516 # A preconfigure script for a system that may or may not use fpu
 517 # sysdeps directories sets this to a preprocessor conditional for
 518 # whether to use such directories.
 519 with_fp_cond=1
 520
 521 dnl Let sysdeps/*/preconfigure act here.
 522 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 523
 524
 525 ###
 526 ### By using the undocumented --enable-hacker-mode option for configure
 527 ### one can skip this test to make the configuration not fail for unsupported
 528 ### platforms.
 529 ###
 530 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 531   case "$machine-$host_os" in
 532   *-linux* | *-gnu*)
 533     ;;
 534   *)
 535     AC_MSG_ERROR([
 536 *** The GNU C library is currently unavailable for this platform.
 537 *** If you are interested in seeing glibc on this platform visit
 538 *** the "How to submit a new port" in the wiki:
 539 ***   https://sourceware.org/glibc/wiki/#Development
 540 *** and join the community!])
 541     ;;
 542   esac
 543 fi
 544
 545 # Set base_machine if not set by a preconfigure fragment.
 546 test -n "$base_machine" || base_machine=$machine
 547 AC_SUBST(base_machine)
 548
 549 # Determine whether to use fpu or nofpu sysdeps directories.
 550 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 551                libc_cv_with_fp, [dnl
 552 cat > conftest.c <<EOF
 553 #if $with_fp_cond
 554 int dummy;
 555 #else
 556 # error "no hardware floating point"
 557 #endif
 558 EOF
 559 libc_cv_with_fp=no
 560 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 561    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 562   libc_cv_with_fp=yes
 563 fi
 564 rm -f conftest*])
 565 AC_SUBST(libc_cv_with_fp)
 566
 567 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 568 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 569                    [libc_cv_ssp=yes],
 570                    [libc_cv_ssp=no])
 571 ])
 572
 573 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 574 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 575                    [libc_cv_ssp_strong=yes],
 576                    [libc_cv_ssp_strong=no])
 577 ])
 578
 579 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 580 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 581                    [libc_cv_ssp_all=yes],
 582                    [libc_cv_ssp_all=no])
 583 ])
 584
 585 stack_protector=
 586 no_stack_protector=
 587 if test "$libc_cv_ssp" = yes; then
 588   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 589   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 590 fi
 591
 592 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 593   stack_protector="-fstack-protector"
 594   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 595 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 596   stack_protector="-fstack-protector-all"
 597   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 598 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 599   stack_protector="-fstack-protector-strong"
 600   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 601 else
 602   stack_protector="-fno-stack-protector"
 603   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 604 fi
 605 AC_SUBST(libc_cv_ssp)
 606 AC_SUBST(stack_protector)
 607 AC_SUBST(no_stack_protector)
 608
 609 if test -n "$stack_protector"; then
 610   dnl Don't run configure tests with stack-protection on, to avoid problems with
 611   dnl bootstrapping.
 612   no_ssp=-fno-stack-protector
 613 else
 614   no_ssp=
 615
 616   if test "$enable_stack_protector" != no; then
 617     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 618   fi
 619 fi
 620
 621 # For the multi-arch option we need support in the assembler & linker.
 622 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 623                libc_cv_ld_gnu_indirect_function, [dnl
 624 cat > conftest.S <<EOF
 625 .type foo,%gnu_indirect_function
 626 foo:
 627 .globl _start
 628 _start:
 629 .globl __start
 630 __start:
 631 .data
 632 #ifdef _LP64
 633 .quad foo
 634 #else
 635 .long foo
 636 #endif
 637 EOF
 638 libc_cv_ld_gnu_indirect_function=no
 639 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 640             -nostartfiles -nostdlib $no_ssp \
 641             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 642   # Do a link to see if the backend supports IFUNC relocs.
 643   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 644   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 645     libc_cv_ld_gnu_indirect_function=yes
 646   }
 647 fi
 648 rm -f conftest*])
 649
 650 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 651 AC_CACHE_CHECK([for gcc attribute ifunc support],
 652                libc_cv_gcc_indirect_function, [dnl
 653 cat > conftest.c <<EOF
 654 extern int func (int);
 655 int used_func (int a)
 656 {
 657   return a;
 658 }
 659 static void *resolver ()
 660 {
 661   return &used_func;
 662 }
 663 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 664 EOF
 665 libc_cv_gcc_indirect_function=no
 666 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 667    2>&AS_MESSAGE_LOG_FD ; then
 668   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 669     libc_cv_gcc_indirect_function=yes
 670   fi
 671 fi
 672 rm -f conftest*])
 673
 674 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 675 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 676 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 677                libc_cv_textrel_ifunc, [dnl
 678 cat > conftest.S <<EOF
 679 .type foo,%gnu_indirect_function
 680 foo:
 681 .globl _start
 682 _start:
 683 .globl __start
 684 __start:
 685 .data
 686 #ifdef _LP64
 687 .quad foo
 688 #else
 689 .long foo
 690 #endif
 691 .text
 692 .globl address
 693 address:
 694 #ifdef _LP64
 695 .quad address
 696 #else
 697 .long address
 698 #endif
 699 EOF
 700 libc_cv_textrel_ifunc=no
 701 if test $libc_cv_ld_gnu_indirect_function = yes; then
 702    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 703      libc_cv_textrel_ifunc=yes
 704    fi
 705 fi
 706 rm -f conftest*])
 707 AC_SUBST(libc_cv_textrel_ifunc)
 708
 709 # Check if gcc warns about alias for function with incompatible types.
 710 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 711                libc_cv_gcc_incompatible_alias, [dnl
 712 cat > conftest.c <<EOF
 713 int __redirect_foo (const void *s, int c);
 714
 715 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 716 __typeof (__redirect_foo) *foo_impl (void)
 717 {
 718   return 0;
 719 }
 720
 721 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 722 EOF
 723 libc_cv_gcc_incompatible_alias=yes
 724 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 725   libc_cv_gcc_incompatible_alias=no
 726 fi
 727 rm -f conftest*])
 728
 729 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 730   if test x"$multi_arch" = xyes; then
 731     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 732   else
 733     multi_arch=no
 734   fi
 735 fi
 736 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 737   # GCC 8+ emits a warning for alias with incompatible types and it might
 738   # fail to build ifunc resolvers aliases to either weak or internal
 739   # symbols.  Disables multiarch build in this case.
 740   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 741     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 742     if test x"$multi_arch" = xyes; then
 743       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 744     fi
 745     AC_MSG_WARN([Multi-arch is disabled.])
 746     multi_arch=no
 747   elif test x"$multi_arch" = xyes; then
 748     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 749 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 750   fi
 751 fi
 752 multi_arch_d=
 753 if test x"$multi_arch" != xno; then
 754   multi_arch_d=/multiarch
 755 fi
 756
 757 # Compute the list of sysdep directories for this configuration.
 758 # This can take a while to compute.
 759 sysdep_dir=$srcdir/sysdeps
 760 AC_MSG_CHECKING(sysdep dirs)
 761 dnl We need to use [ and ] for other purposes for a while now.
 762 changequote(,)dnl
 763 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 764 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 765
 766 test "x$base_os" != x || case "$os" in
 767 gnu*)
 768   base_os=mach/hurd ;;
 769 linux*)
 770   base_os=unix/sysv ;;
 771 esac
 772
 773 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 774 tail=$os
 775 ostry=$os
 776 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 777   ostry="$ostry /$o"
 778   tail=$o
 779 done
 780 o=`echo $tail | sed 's/[0-9]*$//'`
 781 if test $o != $tail; then
 782   ostry="$ostry /$o"
 783 fi
 784 # For linux-gnu, try linux-gnu, then linux.
 785 o=`echo $tail | sed 's/-.*$//'`
 786 if test $o != $tail; then
 787   ostry="$ostry /$o"
 788 fi
 789
 790 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 791 base=
 792 tail=$base_os
 793 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 794   set $b
 795   base="$base /$1"
 796   tail="$2"
 797 done
 798
 799 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 800 mach=
 801 tail=$machine${submachine:+/$submachine}
 802 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 803   set $m
 804   # Prepend the machine's FPU directory unless --without-fp.
 805   if test "$libc_cv_with_fp" = yes; then
 806     maybe_fpu=/fpu
 807   else
 808     maybe_fpu=/nofpu
 809   fi
 810   # For each machine term, try it with and then without /multiarch.
 811   for try_fpu in $maybe_fpu ''; do
 812     for try_multi in $multi_arch_d ''; do
 813       mach="$mach /$1$try_fpu$try_multi"
 814     done
 815   done
 816   tail="$2"
 817 done
 818
 819 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 820 changequote([,])dnl
 821
 822 # Find what sysdep directories exist.
 823 sysnames=
 824 for b in $base ''; do
 825   for m0 in $mach ''; do
 826     for v in /$vendor ''; do
 827       test "$v" = / && continue
 828       for o in /$ostry ''; do
 829         test "$o" = / && continue
 830         for m in $mach ''; do
 831           try_suffix="$m0$b$v$o$m"
 832           if test -n "$try_suffix"; then
 833             try_srcdir="${srcdir}/"
 834             try="sysdeps$try_suffix"
 835             test -n "$enable_debug_configure" &&
 836             echo "$0 [DEBUG]: try $try" >&2
 837             if test -d "$try_srcdir$try"; then
 838               sysnames="$sysnames $try"
 839               { test -n "$o" || test -n "$b"; } && os_used=t
 840               { test -n "$m" || test -n "$m0"; } && machine_used=t
 841               case x${m0:-$m} in
 842               x*/$submachine) submachine_used=t ;;
 843               esac
 844             fi
 845           fi
 846         done
 847       done
 848     done
 849   done
 850 done
 851
 852 # If the assembler supports gnu_indirect_function symbol type and the
 853 # architecture supports multi-arch, we enable multi-arch by default.
 854 case $sysnames in
 855 *"$multi_arch_d"*)
 856   ;;
 857 *)
 858   test x"$multi_arch" = xdefault && multi_arch=no
 859   ;;
 860 esac
 861 if test x"$multi_arch" != xno; then
 862   AC_DEFINE(USE_MULTIARCH)
 863 fi
 864 AC_SUBST(multi_arch)
 865
 866 if test -z "$os_used" && test "$os" != none; then
 867   AC_MSG_ERROR(Operating system $os is not supported.)
 868 fi
 869 if test -z "$machine_used" && test "$machine" != none; then
 870   AC_MSG_ERROR(The $machine is not supported.)
 871 fi
 872 if test -z "$submachine_used" && test -n "$submachine"; then
 873   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 874 fi
 875 AC_SUBST(submachine)
 876
 877 # We have now validated the configuration.
 878
 879 # Expand the list of system names into a full list of directories
 880 # from each element's parent name and Implies file (if present).
 881 set $sysnames
 882 names=
 883 while test $# -gt 0; do
 884   name=$1
 885   shift
 886
 887   case " $names " in *" $name "*)
 888     # Already in the list.
 889     continue
 890   esac
 891
 892   # Report each name as we discover it, so there is no long pause in output.
 893   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 894
 895   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 896
 897   case $name in
 898     /*) xsrcdir= ;;
 899     *)  xsrcdir=$srcdir/ ;;
 900   esac
 901   test -n "$enable_debug_configure" &&
 902   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 903
 904   for implies_file in Implies Implies-before Implies-after; do
 905     implies_type=`echo $implies_file | sed s/-/_/`
 906     eval ${implies_type}=
 907     if test -f $xsrcdir$name/$implies_file; then
 908       # Collect more names from the `Implies' file (removing comments).
 909       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 910       for x in $implied_candidate; do
 911         found=no
 912         if test -d $xsrcdir$name_base/$x; then
 913           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 914           found=yes
 915         fi
 916         try="sysdeps/$x"
 917         try_srcdir=$srcdir/
 918         test -n "$enable_debug_configure" &&
 919          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 920         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 921         then
 922           eval "${implies_type}=\"\$${implies_type} \$try\""
 923           found=yes
 924         fi
 925         if test $found = no; then
 926           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 927         fi
 928       done
 929     fi
 930   done
 931
 932   # Add NAME to the list of names.
 933   names="$names $name"
 934
 935   # Find the parent of NAME, using the empty string if it has none.
 936 changequote(,)dnl
 937   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 938 changequote([,])dnl
 939
 940   test -n "$enable_debug_configure" &&
 941     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 942 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 943
 944   # Add the names implied by NAME, and NAME's parent (if it has one), to
 945   # the list of names to be processed (the argument list).  We prepend the
 946   # implied names to the list and append the parent.  We want implied
 947   # directories to come before further directories inferred from the
 948   # configuration components; this ensures that for sysv4, unix/common
 949   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 950   # after sysv4).
 951   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 952   test -n "$sysnames" && set $sysnames
 953 done
 954
 955 # Add the default directories.
 956 default_sysnames="sysdeps/generic"
 957 sysnames="$names $default_sysnames"
 958 AC_SUBST(sysnames)
 959 # The other names were emitted during the scan.
 960 AC_MSG_RESULT($default_sysnames)
 961
 962
 963 ### Locate tools.
 964
 965 AC_PROG_INSTALL
 966 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 967   # The makefiles need to use a different form to find it in $srcdir.
 968   INSTALL='\$(..)./scripts/install-sh -c'
 969 fi
 970 AC_PROG_LN_S
 971
 972 LIBC_PROG_BINUTILS
 973
 974 # Accept binutils 2.25 or newer.
 975 AC_CHECK_PROG_VER(AS, $AS, --version,
 976                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 977                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 978                   AS=: critic_missing="$critic_missing as")
 979
 980 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 981   # Accept gold 1.14 or higher
 982   AC_CHECK_PROG_VER(LD, $LD, --version,
 983                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 984                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 985                     LD=: critic_missing="$critic_missing GNU gold")
 986 else
 987   AC_CHECK_PROG_VER(LD, $LD, --version,
 988                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 989                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 990                     LD=: critic_missing="$critic_missing GNU ld")
 991 fi
 992
 993 # These programs are version sensitive.
 994 AC_CHECK_TOOL_PREFIX
 995 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 996   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 997   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 998
 999 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1000   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1001   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1002   MSGFMT=: aux_missing="$aux_missing msgfmt")
1003 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1004   [GNU texinfo.* \([0-9][0-9.]*\)],
1005   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1006   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1007 AC_CHECK_PROG_VER(SED, sed, --version,
1008   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1009   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1010   SED=: aux_missing="$aux_missing sed")
1011 AC_CHECK_PROG_VER(AWK, gawk, --version,
1012   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1013   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1014 AC_CHECK_PROG_VER(BISON, bison, --version,
1015   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1016   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1017
1018 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1019 AC_TRY_COMPILE([], [
1020 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
1021 #error insufficient compiler
1022 #endif],
1023                [libc_cv_compiler_ok=yes],
1024                [libc_cv_compiler_ok=no])])
1025 AS_IF([test $libc_cv_compiler_ok != yes],
1026       [critic_missing="$critic_missing compiler"])
1027
1028 AC_CHECK_TOOL(NM, nm, false)
1029
1030 if test "x$maintainer" = "xyes"; then
1031   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1032   case "x$AUTOCONF" in
1033   xno|x|x:) AUTOCONF=no ;;
1034   *)
1035     AC_CACHE_CHECK(dnl
1036   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1037     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1038       libc_cv_autoconf_works=yes
1039     else
1040       libc_cv_autoconf_works=no
1041     fi])
1042     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1043     ;;
1044   esac
1045   if test "x$AUTOCONF" = xno; then
1046     aux_missing="$aux_missing autoconf"
1047   fi
1048 else
1049   AUTOCONF=no
1050 fi
1051
1052 # Check for python3 if available, or else python.
1053 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1054 case "x$PYTHON_PROG" in
1055 xno|x|x:) PYTHON_PROG=no ;;
1056 *) ;;
1057 esac
1058
1059 if test "x$PYTHON_PROG" = xno; then
1060   aux_missing="$aux_missing python"
1061 else
1062   PYTHON="$PYTHON_PROG -B"
1063   AC_SUBST(PYTHON)
1064 fi
1065
1066 test -n "$critic_missing" && AC_MSG_ERROR([
1067 *** These critical programs are missing or too old:$critic_missing
1068 *** Check the INSTALL file for required versions.])
1069
1070 test -n "$aux_missing" && AC_MSG_WARN([
1071 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1072 *** some features or tests will be disabled.
1073 *** Check the INSTALL file for required versions.])
1074
1075 # if using special system headers, find out the compiler's sekrit
1076 # header directory and add that to the list.  NOTE: Only does the right
1077 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1078 if test -n "$sysheaders"; then
1079   SYSINCLUDES=-nostdinc
1080   for d in include include-fixed; do
1081     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1082     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1083   done
1084   SYSINCLUDES="$SYSINCLUDES \
1085 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1086   if test -n "$CXX"; then
1087     CXX_SYSINCLUDES=
1088     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1089     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1090       test "x$cxxheaders" != x &&
1091       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1092     done
1093   fi
1094 fi
1095 AC_SUBST(SYSINCLUDES)
1096 AC_SUBST(CXX_SYSINCLUDES)
1097
1098 # Obtain some C++ header file paths.  This is used to make a local
1099 # copy of those headers in Makerules.
1100 if test -n "$CXX"; then
1101   find_cxx_header () {
1102     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1103          | sed -n "\,$1:,{s/:\$//;p}"
1104   }
1105   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1106   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1107   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1108 fi
1109 AC_SUBST(CXX_CSTDLIB_HEADER)
1110 AC_SUBST(CXX_CMATH_HEADER)
1111 AC_SUBST(CXX_BITS_STD_ABS_H)
1112
1113 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1114 # since this would lead to problems installing/building glibc.
1115 # LD_LIBRARY_PATH contains the current directory if one of the following
1116 # is true:
1117 # - one of the terminals (":" and ";") is the first or last sign
1118 # - two terminals occur directly after each other
1119 # - the path contains an element with a dot in it
1120 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1121 changequote(,)dnl
1122 case ${LD_LIBRARY_PATH} in
1123   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1124     ld_library_path_setting="contains current directory"
1125     ;;
1126   *)
1127     ld_library_path_setting="ok"
1128     ;;
1129 esac
1130 changequote([,])dnl
1131 AC_MSG_RESULT($ld_library_path_setting)
1132 if test "$ld_library_path_setting" != "ok"; then
1133 AC_MSG_ERROR([
1134 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1135 *** building glibc. Please change the environment variable
1136 *** and run configure again.])
1137 fi
1138
1139 AC_PATH_PROG(BASH_SHELL, bash, no)
1140
1141 AC_PATH_PROG(PERL, perl, no)
1142 if test "$PERL" != no &&
1143    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1144   PERL=no
1145 fi
1146 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1147              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1148
1149 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1150 cat > conftest.s <<EOF
1151 .text
1152 foo:
1153 .set glibc_conftest_frobozz,foo
1154 .globl glibc_conftest_frobozz
1155 EOF
1156 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1157 # (but it doesn't work), so we must do a linking check to be sure.
1158 cat > conftest1.c <<\EOF
1159 extern int glibc_conftest_frobozz;
1160 void _start() { glibc_conftest_frobozz = 1; }
1161 EOF
1162 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1163             -nostartfiles -nostdlib $no_ssp \
1164             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1165   libc_cv_asm_set_directive=yes
1166 else
1167   libc_cv_asm_set_directive=no
1168 fi
1169 rm -f conftest*])
1170 if test $libc_cv_asm_set_directive = yes; then
1171   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1172 fi
1173
1174 AC_CACHE_CHECK(linker support for protected data symbol,
1175                libc_cv_protected_data,
1176                [cat > conftest.c <<EOF
1177                 int bar __attribute__ ((visibility ("protected"))) = 1;
1178 EOF
1179                 libc_cv_protected_data=no
1180                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1181                   cat > conftest.c <<EOF
1182                   extern int bar;
1183                   int main (void) { return bar; }
1184 EOF
1185                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1186                     libc_cv_protected_data=yes
1187                   fi
1188                 fi
1189                 rm -f conftest.*
1190                ])
1191 AC_SUBST(libc_cv_protected_data)
1192
1193 AC_CACHE_CHECK(linker support for INSERT in linker script,
1194                libc_cv_insert,
1195                [cat > conftest.c <<EOF
1196                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1197                 int test (void) { return bar; }
1198 EOF
1199                 cat > conftest.t <<EOF
1200                 SECTIONS
1201                 {
1202                   .bar : { *(.bar) }
1203                 }
1204                 INSERT AFTER .rela.dyn;
1205 EOF
1206                 libc_cv_insert=no
1207                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1208                   libc_cv_insert=yes
1209                 fi
1210                 rm -f conftest.*
1211                ])
1212 AC_SUBST(libc_cv_insert)
1213
1214 AC_CACHE_CHECK(for broken __attribute__((alias())),
1215                libc_cv_broken_alias_attribute,
1216                [cat > conftest.c <<EOF
1217                extern int foo (int x) __asm ("xyzzy");
1218                int bar (int x) { return x; }
1219                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1220                extern int dfoo;
1221                extern __typeof (dfoo) dfoo __asm ("abccb");
1222                int dfoo = 1;
1223 EOF
1224                libc_cv_broken_alias_attribute=yes
1225                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1226                  if grep 'xyzzy' conftest.s >/dev/null &&
1227                     grep 'abccb' conftest.s >/dev/null; then
1228                    libc_cv_broken_alias_attribute=no
1229                  fi
1230                fi
1231                rm -f conftest.c conftest.s
1232                ])
1233 if test $libc_cv_broken_alias_attribute = yes; then
1234   AC_MSG_ERROR(working alias attribute support required)
1235 fi
1236
1237 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1238                libc_cv_have_sdata_section,
1239                [echo "int i;" > conftest.c
1240                 libc_cv_have_sdata_section=no
1241                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1242                    | grep '\.sdata' >/dev/null; then
1243                   libc_cv_have_sdata_section=yes
1244                 fi
1245                 rm -f conftest.c conftest.so
1246                ])
1247 if test $libc_cv_have_sdata_section = yes; then
1248   AC_DEFINE(HAVE_SDATA_SECTION)
1249 fi
1250
1251 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1252                libc_cv_ctors_header, [dnl
1253   libc_cv_ctors_header=yes
1254   LIBC_TRY_LINK_STATIC([
1255 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1256 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1257 ],
1258               [dnl
1259       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1260         { gsub(/\@<:@ */, "@<:@") }
1261         $2 == ".ctors" || $2 == ".dtors" {
1262           size = strtonum("0x" $6)
1263           align = strtonum("0x" $NF)
1264           seen@<:@$2@:>@ = 1
1265           stub@<:@$2@:>@ = size == align * 2
1266         }
1267         END {
1268           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1269           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1270           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1271         }
1272       '], [libc_cv_ctors_header=no])
1273     ], [dnl
1274       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1275     ])
1276 ])
1277 if test $libc_cv_ctors_header = no; then
1278   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1279 fi
1280
1281 AC_CACHE_CHECK(for libunwind-support in compiler,
1282                libc_cv_cc_with_libunwind, [
1283   cat > conftest.c <<EOF
1284 int main (void) { return 0; }
1285 EOF
1286   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1287      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1288     libc_cv_cc_with_libunwind=yes
1289   else
1290     libc_cv_cc_with_libunwind=no
1291   fi
1292   rm -f conftest*])
1293 AC_SUBST(libc_cv_cc_with_libunwind)
1294 if test $libc_cv_cc_with_libunwind = yes; then
1295   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1296 fi
1297
1298 ASFLAGS_config=
1299 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1300                libc_cv_as_noexecstack, [dnl
1301 cat > conftest.c <<EOF
1302 void foo (void) { }
1303 EOF
1304 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1305                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1306    && grep .note.GNU-stack conftest.s >/dev/null \
1307    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1308                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1309 then
1310   libc_cv_as_noexecstack=yes
1311 else
1312   libc_cv_as_noexecstack=no
1313 fi
1314 rm -f conftest*])
1315 if test $libc_cv_as_noexecstack = yes; then
1316   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1317 fi
1318 AC_SUBST(ASFLAGS_config)
1319
1320 AC_CACHE_CHECK(for -z combreloc,
1321                libc_cv_z_combreloc, [dnl
1322 cat > conftest.c <<EOF
1323 extern int bar (int);
1324 extern int mumble;
1325 int foo (void) { return bar (mumble); }
1326 EOF
1327 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1328                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1329                         -nostdlib -nostartfiles
1330                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1331 then
1332 dnl The following test is a bit weak.  We must use a tool which can test
1333 dnl cross-platform since the gcc used can be a cross compiler.  Without
1334 dnl introducing new options this is not easily doable.  Instead use a tool
1335 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1336 dnl look for a section named .rel.dyn or .rela.dyn.
1337   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1338     libc_cv_z_combreloc=yes
1339   else
1340     libc_cv_z_combreloc=no
1341   fi
1342 else
1343   libc_cv_z_combreloc=no
1344 fi
1345 rm -f conftest*])
1346 if test "$libc_cv_z_combreloc" = yes; then
1347   AC_DEFINE(HAVE_Z_COMBRELOC)
1348 fi
1349 AC_SUBST(libc_cv_z_combreloc)
1350
1351 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1352                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1353 AC_SUBST(libc_cv_z_execstack)
1354
1355 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1356                     [-Wl,--no-dynamic-linker],
1357                     [libc_cv_no_dynamic_linker=yes],
1358                     [libc_cv_no_dynamic_linker=no])
1359 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1360
1361 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1362 LIBC_TRY_CC_OPTION([-static-pie],
1363                    [libc_cv_static_pie=yes],
1364                    [libc_cv_static_pie=no])
1365 ])
1366 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1367
1368 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1369 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1370 ])
1371
1372 AC_SUBST(libc_cv_fpie)
1373
1374 AC_CACHE_CHECK(for --hash-style option,
1375                libc_cv_hashstyle, [dnl
1376 cat > conftest.c <<EOF
1377 int _start (void) { return 42; }
1378 EOF
1379 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1380                             -fPIC -shared -o conftest.so conftest.c
1381                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1382 then
1383   libc_cv_hashstyle=yes
1384 else
1385   libc_cv_hashstyle=no
1386 fi
1387 rm -f conftest*])
1388 AC_SUBST(libc_cv_hashstyle)
1389
1390 # The linker's default -shared behavior is good enough if it
1391 # does these things that our custom linker scripts ensure that
1392 # all allocated NOTE sections come first.
1393 if test "$use_default_link" = default; then
1394   AC_CACHE_CHECK([for sufficient default -shared layout],
1395                   libc_cv_use_default_link, [dnl
1396   libc_cv_use_default_link=no
1397   cat > conftest.s <<\EOF
1398           .section .note.a,"a",%note
1399           .balign 4
1400           .long 4,4,9
1401           .string "GNU"
1402           .string "foo"
1403           .section .note.b,"a",%note
1404           .balign 4
1405           .long 4,4,9
1406           .string "GNU"
1407           .string "bar"
1408 EOF
1409   if AC_TRY_COMMAND([dnl
1410   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1411        ac_try=`$READELF -S conftest.so | sed -n \
1412          ['${x;p;}
1413           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1414           t a
1415           b
1416           : a
1417           H']`
1418   then
1419     libc_seen_a=no libc_seen_b=no
1420     set -- $ac_try
1421     while test $# -ge 2 -a "$1" = NOTE; do
1422       case "$2" in
1423       .note.a) libc_seen_a=yes ;;
1424       .note.b) libc_seen_b=yes ;;
1425       esac
1426       shift 2
1427     done
1428     case "$libc_seen_a$libc_seen_b" in
1429     yesyes)
1430       libc_cv_use_default_link=yes
1431       ;;
1432     *)
1433       echo >&AS_MESSAGE_LOG_FD "\
1434 $libc_seen_a$libc_seen_b from:
1435 $ac_try"
1436       ;;
1437     esac
1438   fi
1439   rm -f conftest*])
1440   use_default_link=$libc_cv_use_default_link
1441 fi
1442
1443 AC_CACHE_CHECK(for GLOB_DAT reloc,
1444                libc_cv_has_glob_dat, [dnl
1445 cat > conftest.c <<EOF
1446 extern int mumble;
1447 int foo (void) { return mumble; }
1448 EOF
1449 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1450                         -fPIC -shared -o conftest.so conftest.c
1451                         -nostdlib -nostartfiles $no_ssp
1452                         1>&AS_MESSAGE_LOG_FD])
1453 then
1454 dnl look for GLOB_DAT relocation.
1455   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1456     libc_cv_has_glob_dat=yes
1457   else
1458     libc_cv_has_glob_dat=no
1459   fi
1460 else
1461   libc_cv_has_glob_dat=no
1462 fi
1463 rm -f conftest*])
1464 AC_SUBST(libc_cv_has_glob_dat)
1465
1466 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1467 if libc_cv_output_format=`
1468 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1469 then
1470   :
1471 else
1472   libc_cv_output_format=
1473 fi
1474 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1475 AC_SUBST(libc_cv_output_format)
1476
1477 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1478 cat > conftest.c <<EOF
1479 int foo;
1480 EOF
1481 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1482                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1483 then
1484   libc_cv_fno_toplevel_reorder=yes
1485 else
1486   libc_cv_fno_toplevel_reorder=no
1487 fi
1488 rm -f conftest*])
1489 if test $libc_cv_fno_toplevel_reorder = yes; then
1490   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1491 else
1492   fno_unit_at_a_time=-fno-unit-at-a-time
1493 fi
1494 AC_SUBST(fno_unit_at_a_time)
1495
1496 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1497 [dnl
1498 cat > conftest.c <<EOF
1499 __thread int i;
1500 void foo (void)
1501 {
1502   i = 10;
1503 }
1504 EOF
1505 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1506                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1507 then
1508   libc_cv_mtls_dialect_gnu2=yes
1509 else
1510   libc_cv_mtls_dialect_gnu2=no
1511 fi
1512 rm -f conftest*])
1513 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1514 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1515
1516 AC_CACHE_CHECK(whether cc puts quotes around section names,
1517                libc_cv_have_section_quotes,
1518                [cat > conftest.c <<EOF
1519                 static const int foo
1520                 __attribute__ ((section ("bar"))) = 1;
1521 EOF
1522                 if ${CC-cc} -S conftest.c -o conftest.s; then
1523                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1524                     libc_cv_have_section_quotes=yes
1525                   else
1526                     libc_cv_have_section_quotes=no
1527                   fi
1528                 else
1529                   libc_cv_have_section_quotes=unknown
1530                 fi
1531                 rm -f conftest.{c,s}
1532                 ])
1533 if test $libc_cv_have_section_quotes = yes; then
1534   AC_DEFINE(HAVE_SECTION_QUOTES)
1535 fi
1536
1537 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1538 cat > conftest.c <<\EOF
1539 void zero (void *x)
1540 {
1541   __builtin_memset (x, 0, 1000);
1542 }
1543 EOF
1544 dnl
1545 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1546 then
1547   libc_cv_gcc_builtin_memset=no
1548 else
1549   libc_cv_gcc_builtin_memset=yes
1550 fi
1551 rm -f conftest* ])
1552 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1553   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1554 fi
1555
1556 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1557 cat > conftest.c <<\EOF
1558 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1559 char *foo (const char *a, const char *b)
1560 {
1561   return __builtin_strstr (a, b);
1562 }
1563 EOF
1564 dnl
1565 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1566 then
1567   libc_cv_gcc_builtin_redirection=yes
1568 else
1569   libc_cv_gcc_builtin_redirection=no
1570 fi
1571 rm -f conftest* ])
1572 if test "$libc_cv_gcc_builtin_redirection" = no; then
1573   AC_MSG_ERROR([support for the symbol redirection needed])
1574 fi
1575
1576 dnl Determine how to disable generation of FMA instructions.
1577 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1578                libc_cv_cc_nofma, [dnl
1579 libc_cv_cc_nofma=
1580 for opt in -ffp-contract=off -mno-fused-madd; do
1581   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1582 done])
1583 AC_SUBST(libc_cv_cc_nofma)
1584
1585 if test -n "$submachine"; then
1586   AC_CACHE_CHECK([for compiler option for CPU variant],
1587                  libc_cv_cc_submachine, [dnl
1588   libc_cv_cc_submachine=no
1589   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1590     LIBC_TRY_CC_OPTION([$opt], [
1591       libc_cv_cc_submachine="$opt"
1592       break], [])
1593   done])
1594   if test "x$libc_cv_cc_submachine" = xno; then
1595     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1596   fi
1597 fi
1598 AC_SUBST(libc_cv_cc_submachine)
1599
1600 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1601 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1602 cat > conftest.c <<EOF
1603 void
1604 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1605 foo (void) {}
1606 EOF
1607 libc_cv_cc_loop_to_function=no
1608 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1609 then
1610   libc_cv_cc_loop_to_function=yes
1611 fi
1612 rm -f conftest*])
1613 if test $libc_cv_cc_loop_to_function = yes; then
1614   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1615 fi
1616 AC_SUBST(libc_cv_cc_loop_to_function)
1617
1618 dnl Check whether we have the gd library available.
1619 AC_MSG_CHECKING(for libgd)
1620 if test "$with_gd" != "no"; then
1621   old_CFLAGS="$CFLAGS"
1622   CFLAGS="$CFLAGS $libgd_include"
1623   old_LDFLAGS="$LDFLAGS"
1624   LDFLAGS="$LDFLAGS $libgd_ldflags"
1625   old_LIBS="$LIBS"
1626   LIBS="$LIBS -lgd -lpng -lz -lm"
1627   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1628   CFLAGS="$old_CFLAGS"
1629   LDFLAGS="$old_LDFLAGS"
1630   LIBS="$old_LIBS"
1631 else
1632   LIBGD=no
1633 fi
1634 AC_MSG_RESULT($LIBGD)
1635 AC_SUBST(LIBGD)
1636
1637 # SELinux detection
1638 if test x$with_selinux = xno ; then
1639   have_selinux=no;
1640 else
1641   # See if we have the SELinux library
1642   AC_CHECK_LIB(selinux, is_selinux_enabled,
1643                have_selinux=yes, have_selinux=no)
1644   if test x$with_selinux = xyes ; then
1645     if test x$have_selinux = xno ; then
1646       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1647     fi
1648   fi
1649 fi
1650 # Check if we're building with SELinux support.
1651 if test "x$have_selinux" = xyes; then
1652   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1653
1654   # See if we have the libaudit library
1655   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1656                have_libaudit=yes, have_libaudit=no)
1657   if test "x$have_libaudit" = xyes; then
1658     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1659   fi
1660   AC_SUBST(have_libaudit)
1661
1662   # See if we have the libcap library
1663   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1664   if test "x$have_libcap" = xyes; then
1665     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1666   fi
1667   AC_SUBST(have_libcap)
1668 fi
1669 AC_SUBST(have_selinux)
1670
1671 CPPUNDEFS=
1672 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1673 dnl Since we are building the implementations of the fortified functions here,
1674 dnl having the macro defined interacts very badly.
1675 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1676 [AC_TRY_COMPILE([], [
1677 #ifdef _FORTIFY_SOURCE
1678 # error bogon
1679 #endif],
1680                 [libc_cv_predef_fortify_source=no],
1681                 [libc_cv_predef_fortify_source=yes])])
1682 if test $libc_cv_predef_fortify_source = yes; then
1683   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1684 fi
1685 AC_SUBST(CPPUNDEFS)
1686
1687 # Some linkers on some architectures support __ehdr_start but with
1688 # bugs.  Make sure usage of it does not create relocations in the
1689 # output (as the linker should resolve them all for us).
1690 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1691                libc_cv_ehdr_start, [
1692 old_CFLAGS="$CFLAGS"
1693 old_LDFLAGS="$LDFLAGS"
1694 old_LIBS="$LIBS"
1695 CFLAGS="$CFLAGS -fPIC"
1696 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1697 LIBS=
1698 AC_LINK_IFELSE([AC_LANG_SOURCE([
1699 typedef struct {
1700   char foo;
1701   long val;
1702 } Ehdr;
1703 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1704 long ehdr (void) { return __ehdr_start.val; }
1705 ])],
1706                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1707                   libc_cv_ehdr_start=broken
1708                 else
1709                   libc_cv_ehdr_start=yes
1710                 fi], [libc_cv_ehdr_start=no])
1711 CFLAGS="$old_CFLAGS"
1712 LDFLAGS="$old_LDFLAGS"
1713 LIBS="$old_LIBS"
1714 ])
1715 if test "$libc_cv_ehdr_start" = yes; then
1716   AC_DEFINE([HAVE_EHDR_START])
1717 elif test "$libc_cv_ehdr_start" = broken; then
1718   AC_MSG_WARN([linker is broken -- you should upgrade])
1719 fi
1720
1721 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1722                libc_cv_builtin_trap, [dnl
1723 libc_cv_builtin_trap=no
1724 AC_TRY_COMPILE([], [__builtin_trap ()], [
1725 libc_undefs=`$NM -u conftest.o |
1726   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1727     2>&AS_MESSAGE_LOG_FD` || {
1728   AC_MSG_ERROR([confusing output from $NM -u])
1729 }
1730 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1731 if test -z "$libc_undefs"; then
1732   libc_cv_builtin_trap=yes
1733 fi])])
1734 if test $libc_cv_builtin_trap = yes; then
1735   AC_DEFINE([HAVE_BUILTIN_TRAP])
1736 fi
1737
1738 dnl C++ feature tests.
1739 AC_LANG_PUSH([C++])
1740
1741 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1742                libc_cv_cxx_thread_local, [
1743 old_CXXFLAGS="$CXXFLAGS"
1744 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1745 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1746 #include <thread>
1747
1748 // Compiler support.
1749 struct S
1750 {
1751   S ();
1752   ~S ();
1753 };
1754 thread_local S s;
1755 S * get () { return &s; }
1756
1757 // libstdc++ support.
1758 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1759 #error __cxa_thread_atexit_impl not supported
1760 #endif
1761 ])],
1762                [libc_cv_cxx_thread_local=yes],
1763                [libc_cv_cxx_thread_local=no])
1764 CXXFLAGS="$old_CXXFLAGS"
1765 ])
1766 AC_SUBST(libc_cv_cxx_thread_local)
1767
1768 AC_LANG_POP([C++])
1769 dnl End of C++ feature tests.
1770
1771 ### End of automated tests.
1772 ### Now run sysdeps configure fragments.
1773
1774 # They also can set these variables.
1775 use_ldconfig=no
1776 ldd_rewrite_script=no
1777 libc_cv_sysconfdir=$sysconfdir
1778 libc_cv_localstatedir=$localstatedir
1779 libc_cv_gcc_unwind_find_fde=no
1780 libc_cv_idn=no
1781
1782 # Iterate over all the sysdep directories we will use, running their
1783 # configure fragments.
1784 for dir in $sysnames; do
1785   case $dir in
1786     /*) dest=$dir ;;
1787     *)  dest=$srcdir/$dir ;;
1788   esac
1789   if test -r $dest/configure; then
1790     AC_MSG_RESULT(running configure fragment for $dir)
1791     . $dest/configure
1792   fi
1793 done
1794
1795 if test x"$build_mathvec" = xnotset; then
1796   build_mathvec=no
1797 fi
1798 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1799
1800 AC_SUBST(libc_extra_cflags)
1801 AC_SUBST(libc_extra_cppflags)
1802
1803 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1804   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1805 fi
1806 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1807
1808 # A sysdeps configure fragment can reset this if IFUNC is not actually
1809 # usable even though the assembler knows how to generate the symbol type.
1810 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1811   AC_DEFINE(HAVE_IFUNC)
1812 fi
1813
1814 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1815   AC_DEFINE(HAVE_GCC_IFUNC)
1816 fi
1817
1818 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1819 # configure fragment can override the value to prevent this AC_DEFINE.
1820 AC_SUBST(use_nscd)
1821 if test "x$use_nscd" != xno; then
1822   AC_DEFINE([USE_NSCD])
1823 fi
1824 if test "x$build_nscd" = xdefault; then
1825   build_nscd=$use_nscd
1826 fi
1827
1828 AC_SUBST(libc_cv_slibdir)
1829 AC_SUBST(libc_cv_rtlddir)
1830 AC_SUBST(libc_cv_complocaledir)
1831 AC_SUBST(libc_cv_sysconfdir)
1832 AC_SUBST(libc_cv_localstatedir)
1833 AC_SUBST(libc_cv_rootsbindir)
1834
1835 if test x$use_ldconfig = xyes; then
1836   AC_DEFINE(USE_LDCONFIG)
1837 fi
1838 AC_SUBST(use_ldconfig)
1839 AC_SUBST(ldd_rewrite_script)
1840
1841 AC_SUBST(static)
1842 AC_SUBST(shared)
1843
1844 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1845 [libc_cv_pic_default=yes
1846 cat > conftest.c <<EOF
1847 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1848 # error PIC is default.
1849 #endif
1850 EOF
1851 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1852   libc_cv_pic_default=no
1853 fi
1854 rm -f conftest.*])
1855 AC_SUBST(libc_cv_pic_default)
1856
1857 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1858 [libc_cv_cc_pie_default=yes
1859 cat > conftest.c <<EOF
1860 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1861 # error PIE is default.
1862 #endif
1863 EOF
1864 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1865   libc_cv_cc_pie_default=no
1866 fi
1867 rm -f conftest.*])
1868 libc_cv_pie_default=$libc_cv_cc_pie_default
1869 AC_SUBST(libc_cv_cc_pie_default)
1870 AC_SUBST(libc_cv_pie_default)
1871
1872 # Set the `multidir' variable by grabbing the variable from the compiler.
1873 # We do it once and save the result in a generated makefile.
1874 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1875 AC_SUBST(libc_cv_multidir)
1876
1877 if test "$static_pie" = yes; then
1878   # The linker must support --no-dynamic-linker.
1879   if test "$libc_cv_no_dynamic_linker" != yes; then
1880     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1881   fi
1882   # Default to PIE.
1883   libc_cv_pie_default=yes
1884   AC_DEFINE(ENABLE_STATIC_PIE)
1885 fi
1886 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1887
1888 AC_SUBST(profile)
1889 AC_SUBST(static_nss)
1890
1891 AC_SUBST(DEFINES)
1892
1893 dnl See sysdeps/mach/configure.ac for this variable.
1894 AC_SUBST(mach_interface_list)
1895
1896 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1897 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1898 AC_SUBST(VERSION)
1899 AC_SUBST(RELEASE)
1900
1901 AC_CONFIG_FILES([config.make Makefile])
1902 AC_CONFIG_COMMANDS([default],[[
1903 case $CONFIG_FILES in *config.make*)
1904 echo "$config_vars" >> config.make;;
1905 esac
1906 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1907 AC_OUTPUT