configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 dnl Use something like this if you need to patch autoconf files and
  11 dnl regenerate configure outside upstream git tree:
  12 dnl AC_INIT([lldpd], [0.5.7], [bernat@luffy.cx])
  13 AC_INIT([lldpd],
  14         [m4_esyscmd_s([./get-version])],
  15         [bernat@luffy.cx])
  16
  17 AC_CONFIG_SRCDIR([src/log.c])
  18 AC_CONFIG_HEADER([config.h])
  19 AC_CONFIG_FILES([Makefile src/Makefile src/compat/Makefile src/daemon/Makefile
  20                           src/lib/Makefile src/lib/lldpctl.pc src/client/Makefile
  21                           tests/Makefile])
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 # Configure automake
  25 AM_INIT_AUTOMAKE([foreign -Wall -Werror])
  26 AM_MAINTAINER_MODE
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  28
  29 # Automake 1.12...
  30 m4_pattern_allow([AM_PROG_AR])
  31 AM_PROG_AR
  32
  33 # Configure libtool
  34 LT_INIT
  35
  36 #######################
  37 ### Checks
  38
  39 # Checks for programs.
  40 AC_PROG_CC
  41 AC_PROG_CC_C99
  42 AC_PROG_CXX
  43 AM_PROG_CC_C_O
  44 AC_PROG_LIBTOOL
  45 AC_PROG_LN_S
  46 AC_PROG_EGREP
  47
  48 # Doxygen
  49 DX_HTML_FEATURE(ON)
  50 DX_DOT_FEATURE(OFF)
  51 DX_CHM_FEATURE(OFF)
  52 DX_CHI_FEATURE(OFF)
  53 DX_MAN_FEATURE(OFF)
  54 DX_RTF_FEATURE(OFF)
  55 DX_XML_FEATURE(OFF)
  56 DX_PDF_FEATURE(ON)
  57 DX_PS_FEATURE(OFF)
  58 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  59
  60 # Check some compiler flags
  61 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option])
  62 AX_CFLAGS_GCC_OPTION([-pipe])
  63 AX_CFLAGS_GCC_OPTION([-Wall])
  64 AX_CFLAGS_GCC_OPTION([-W])
  65 AX_CFLAGS_GCC_OPTION([-Wextra])
  66 AX_CFLAGS_GCC_OPTION([-Wformat])
  67 AX_CFLAGS_GCC_OPTION([-Wformat-security])
  68 AX_CFLAGS_GCC_OPTION([-Wfatal-errors])
  69 AX_CFLAGS_GCC_OPTION([-Wcast-align])
  70 AX_CFLAGS_GCC_OPTION([-Winline])
  71 AX_CFLAGS_GCC_OPTION([-fstack-protector])
  72 AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2])
  73 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter])
  74 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers])
  75 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare]) dnl Should be fixed later
  76 AX_LDFLAGS_OPTION([-Wl,-z,relro])
  77 AX_LDFLAGS_OPTION([-Wl,-z,now])
  78
  79 # OS
  80 lldp_CHECK_OS
  81
  82 AC_CACHE_SAVE
  83
  84 # Checks for header files.
  85 AC_HEADER_RESOLV
  86 AC_CHECK_HEADERS([valgrind/valgrind.h])
  87 lldp_CHECK_STDINT
  88
  89 AC_CACHE_SAVE
  90
  91 # Checks for typedefs, structures, and compiler characteristics.
  92 lldp_CHECK___PROGNAME
  93
  94 # Checks for library functions.
  95 AC_CONFIG_LIBOBJ_DIR([src/compat])
  96 AC_FUNC_MALLOC
  97 AC_FUNC_REALLOC
  98 AC_REPLACE_FUNCS([strlcpy strnlen fgetln])
  99 AC_CHECK_FUNCS([setresuid setresgid])
 100
 101 AC_SEARCH_LIBS([__res_init], resolv bind, AC_DEFINE([HAVE_RES_INIT], 1, [Define to indicate that res_init() exists]),
 102 AC_SEARCH_LIBS([res_9_init], resolv bind, AC_DEFINE([HAVE_RES_INIT], 1, [Define to indicate that res_init() exists]),
 103 AC_SEARCH_LIBS([res_init],   resolv bind, AC_DEFINE([HAVE_RES_INIT], 1, [Define to indicate that res_init() exists]))))
 104
 105 AC_CACHE_SAVE
 106
 107 ## Unit tests wich check
 108 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 109
 110 # Libevent
 111 lldp_CHECK_LIBEVENT
 112
 113 #######################
 114 ### Options
 115
 116 # Readline
 117 AC_ARG_WITH([readline],
 118   AS_HELP_STRING(
 119     [--with-readline],
 120     [Enable the use of readline-like library @<:@default=check@:>@]),
 121   [],
 122   [with_readline=check])
 123 if test x"$with_readline" != x"no"; then
 124    AX_LIB_READLINE
 125    if test x"$with_readline" != x"check"; then
 126      if test x"$ax_cv_lib_readline" = x"no"; then
 127        AC_MSG_FAILURE([*** no readline support found])
 128      fi
 129    fi
 130 else
 131    ax_cv_lib_readline="no"
 132 fi
 133
 134 # SNMP
 135 AC_ARG_WITH([snmp],
 136   AS_HELP_STRING(
 137     [--with-snmp],
 138     [Enable the use of SNMP @<:@default=no@:>@]
 139   ))
 140 if test x"$with_snmp" = x"yes"; then
 141    lldp_CHECK_SNMP
 142 fi
 143
 144 # XML
 145 AC_ARG_WITH([xml],
 146   AC_HELP_STRING(
 147     [--with-xml],
 148     [Enable XML output via libxml2 @<:@default=no@:>@]
 149   ))
 150 if test x"$with_xml" = x"yes"; then
 151    lldp_CHECK_XML2
 152 fi
 153
 154 # JSON
 155 AC_ARG_WITH([json],
 156   AC_HELP_STRING(
 157     [--with-json],
 158     [Enable JSON output via Jansson @<:@default=no@:>@]
 159   ))
 160 if test x"$with_json" = x"yes"; then
 161    lldp_CHECK_JANSSON
 162 fi
 163
 164 # Privsep settings
 165 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 166 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 167 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [/var/run/lldpd])
 168
 169 # CDP/FDP/EDP/SONMP
 170 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 171 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 172 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 173 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 174
 175 # LLDPMED/Dot1/Dot3
 176 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 177 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 178 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 179
 180 # Oldies
 181 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.18], [no])
 182
 183 #######################
 184 # Output results
 185 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 186 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 187 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 188 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"yes"])
 189 AC_OUTPUT
 190
 191 if test x"$LIBEVENT_EMBEDDED" = x; then
 192    libevent=system
 193 else
 194    libevent=embedded
 195 fi
 196
 197 cat <<EOF
 198
 199 ------------------ Summary ------------------
 200  $PACKAGE_NAME version $PACKAGE_VERSION
 201   OS.............: $os
 202   Prefix.........: $prefix
 203   C Compiler.....: $CC $CFLAGS $CPPFLAGS
 204   Linker.........: $LD $LDFLAGS $LIBS
 205   Libevent.......: $libevent
 206   Readline.......: ${ax_cv_lib_readline}
 207  Optional features:
 208   SNMP support...: ${with_snmp-no}
 209   CDP............: $enable_cdp
 210   FDP............: $enable_fdp
 211   EDP............: $enable_edp
 212   SONMP..........: $enable_sonmp
 213   LLDPMED........: $enable_lldpmed
 214   DOT1...........: $enable_dot1
 215   DOT3...........: $enable_dot3
 216   XML output.....: ${with_xml-no}
 217   JSON output....: ${with_json-no}
 218   Oldies support.: $enable_oldies
 219 ---------------------------------------------
 220
 221 Check the above options and compile with:
 222  ${MAKE-make}
 223
 224 EOF