configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 dnl This is here so we can set $subdirs directly based on configure fragments.
   9 AC_CONFIG_SUBDIRS()
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 if test $host != $build; then
  15   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  16 fi
  17 AC_SUBST(cross_compiling)
  18 AC_PROG_CPP
  19 # We need the C++ compiler only for testing.
  20 AC_PROG_CXX
  21
  22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  23   AC_MSG_ERROR([you must configure in a separate build directory])
  24 fi
  25
  26 # This will get text that should go into config.make.
  27 config_vars=
  28
  29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  30 AC_ARG_WITH([gd],
  31             AC_HELP_STRING([--with-gd=DIR],
  32                            [find libgd include dir and library with prefix DIR]),
  33             [dnl
  34 case "$with_gd" in
  35 yes|''|no) ;;
  36 *) libgd_include="-I$withval/include"
  37    libgd_ldflags="-L$withval/lib" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH([gd-include],
  41             AC_HELP_STRING([--with-gd-include=DIR],
  42                            [find libgd include files in DIR]),
  43             [dnl
  44 case "$with_gd_include" in
  45 ''|no) ;;
  46 *) libgd_include="-I$withval" ;;
  47 esac
  48 ])
  49 AC_ARG_WITH([gd-lib],
  50             AC_HELP_STRING([--with-gd-lib=DIR],
  51                            [find libgd library files in DIR]),
  52             [dnl
  53 case "$with_gd_lib" in
  54 ''|no) ;;
  55 *) libgd_ldflags="-L$withval" ;;
  56 esac
  57 ])
  58
  59 if test -n "$libgd_include"; then
  60   config_vars="$config_vars
  61 CFLAGS-memusagestat.c = $libgd_include"
  62 fi
  63 if test -n "$libgd_ldflags"; then
  64   config_vars="$config_vars
  65 libgd-LDFLAGS = $libgd_ldflags"
  66 fi
  67
  68 dnl Arguments to specify presence of other packages/features.
  69 AC_ARG_WITH([fp],
  70             AC_HELP_STRING([--with-fp],
  71                            [if using floating-point hardware @<:@default=yes@:>@]),
  72             [with_fp=$withval],
  73             [with_fp=yes])
  74 AC_SUBST(with_fp)
  75 AC_ARG_WITH([binutils],
  76             AC_HELP_STRING([--with-binutils=PATH],
  77                            [specify location of binutils (as and ld)]),
  78             [path_binutils=$withval],
  79             [path_binutils=''])
  80 AC_ARG_WITH([selinux],
  81             AC_HELP_STRING([--with-selinux],
  82                            [if building with SELinux support]),
  83             [with_selinux=$withval],
  84             [with_selinux=auto])
  85
  86 AC_ARG_WITH([headers],
  87             AC_HELP_STRING([--with-headers=PATH],
  88                            [location of system headers to use
  89                             (for example /usr/src/linux/include)
  90                             @<:@default=compiler default@:>@]),
  91             [sysheaders=$withval],
  92             [sysheaders=''])
  93
  94 AC_SUBST(use_default_link)
  95 AC_ARG_WITH([default-link],
  96             AC_HELP_STRING([--with-default-link],
  97                            [do not use explicit linker scripts]),
  98             [use_default_link=$withval],
  99             [use_default_link=default])
 100
 101 AC_ARG_ENABLE([sanity-checks],
 102               AC_HELP_STRING([--disable-sanity-checks],
 103                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 104               [enable_sanity=$enableval],
 105               [enable_sanity=yes])
 106
 107 AC_SUBST(enable_check_abi)
 108 AC_ARG_ENABLE([check-abi],
 109               AC_HELP_STRING([--enable-check-abi],
 110                              [do "make check-abi" in "make check" (no/warn/yes)
 111                               @<:@default=no@:>@]),
 112               [enable_check_abi=$enableval],
 113               [enable_check_abi=no])
 114
 115 AC_ARG_ENABLE([shared],
 116               AC_HELP_STRING([--enable-shared],
 117                              [build shared library @<:@default=yes if GNU ld@:>@]),
 118               [shared=$enableval],
 119               [shared=yes])
 120 AC_ARG_ENABLE([profile],
 121               AC_HELP_STRING([--enable-profile],
 122                              [build profiled library @<:@default=no@:>@]),
 123               [profile=$enableval],
 124               [profile=no])
 125 AC_ARG_ENABLE([versioning],
 126               AC_HELP_STRING([--disable-versioning],
 127                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 128               [enable_versioning=$enableval],
 129               [enable_versioning=yes])
 130
 131 AC_ARG_ENABLE([oldest-abi],
 132               AC_HELP_STRING([--enable-oldest-abi=ABI],
 133                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 134               [oldest_abi=$enableval],
 135               [oldest_abi=no])
 136 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 137   oldest_abi=default
 138 else
 139   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 140 fi
 141 AC_SUBST(oldest_abi)
 142
 143 AC_ARG_ENABLE([stackguard-randomization],
 144               AC_HELP_STRING([--enable-stackguard-randomization],
 145                              [initialize __stack_chk_guard canary with a random number at program start]),
 146               [enable_stackguard_randomize=$enableval],
 147               [enable_stackguard_randomize=no])
 148 if test "$enable_stackguard_randomize" = yes; then
 149   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 150 fi
 151
 152 dnl Generic infrastructure for drop-in additions to libc.
 153 AC_ARG_ENABLE([add-ons],
 154               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 155                              [configure and build add-ons in DIR1,DIR2,...
 156                               search for add-ons if no parameter given]),
 157                              , [enable_add_ons=yes])
 158
 159 AC_ARG_ENABLE([hidden-plt],
 160               AC_HELP_STRING([--disable-hidden-plt],
 161                              [do not hide internal function calls to avoid PLT]),
 162               [hidden=$enableval],
 163               [hidden=yes])
 164 if test "x$hidden" = xno; then
 165   AC_DEFINE(NO_HIDDEN)
 166 fi
 167
 168 AC_ARG_ENABLE([bind-now],
 169               AC_HELP_STRING([--enable-bind-now],
 170                              [disable lazy relocations in DSOs]),
 171               [bindnow=$enableval],
 172               [bindnow=no])
 173 AC_SUBST(bindnow)
 174
 175 dnl On some platforms we cannot use dynamic loading.  We must provide
 176 dnl static NSS modules.
 177 AC_ARG_ENABLE([static-nss],
 178               AC_HELP_STRING([--enable-static-nss],
 179                              [build static NSS modules @<:@default=no@:>@]),
 180               [static_nss=$enableval],
 181               [static_nss=no])
 182 dnl Enable static NSS also if we build no shared objects.
 183 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 184   static_nss=yes
 185   AC_DEFINE(DO_STATIC_NSS)
 186 fi
 187
 188 AC_ARG_ENABLE([force-install],
 189               AC_HELP_STRING([--disable-force-install],
 190                              [don't force installation of files from this package, even if they are older than the installed files]),
 191               [force_install=$enableval],
 192               [force_install=yes])
 193 AC_SUBST(force_install)
 194
 195 dnl On some platforms we allow dropping compatibility with all kernel
 196 dnl versions.
 197 AC_ARG_ENABLE([kernel],
 198               AC_HELP_STRING([--enable-kernel=VERSION],
 199                              [compile for compatibility with kernel not older than VERSION]),
 200               [minimum_kernel=$enableval],
 201               [])
 202 dnl Prevent unreasonable values.
 203 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 204   # Better nothing than this.
 205   minimum_kernel=""
 206 else
 207   if test "$minimum_kernel" = current; then
 208     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 209   fi
 210 fi
 211
 212 dnl For the development we sometimes want gcc to issue even more warnings.
 213 dnl This is not the default since many of the extra warnings are not
 214 dnl appropriate.
 215 AC_ARG_ENABLE([all-warnings],
 216               AC_HELP_STRING([--enable-all-warnings],
 217                              [enable all useful warnings gcc can issue]),
 218               [all_warnings=$enableval],
 219               [])
 220 AC_SUBST(all_warnings)
 221
 222 AC_ARG_ENABLE([multi-arch],
 223               AC_HELP_STRING([--enable-multi-arch],
 224                              [enable single DSO with optimizations for multiple architectures]),
 225               [multi_arch=$enableval],
 226               [multi_arch=default])
 227
 228 AC_ARG_ENABLE([nss-crypt],
 229               AC_HELP_STRING([--enable-nss-crypt],
 230                              [enable libcrypt to use nss]),
 231               [nss_crypt=$enableval],
 232               [nss_crypt=no])
 233 if test x$nss_crypt = xyes; then
 234   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 235   if test $? -ne 0; then
 236     AC_MSG_ERROR([cannot find include directory with nss-config])
 237   fi
 238   old_CFLAGS="$CFLAGS"
 239   CFLAGS="$CFLAGS $nss_includes"
 240   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 241 #include <hasht.h>
 242 #include <nsslowhash.h>
 243 void f (void) { NSSLOW_Init (); }])],
 244              libc_cv_nss_crypt=yes,
 245              AC_MSG_ERROR([
 246 cannot find NSS headers with lowlevel hash function interfaces]))
 247   old_LIBS="$LIBS"
 248   LIBS="$LIBS -lfreebl3"
 249   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 250 #include <hasht.h>
 251 #include <nsslowhash.h>],
 252                                   [NSSLOW_Init();])],
 253                  libc_cv_nss_crypt=yes,
 254                  AC_MSG_ERROR([
 255 cannot link program using lowlevel NSS hash functions]))
 256   CFLAGS="$old_CFLAGS"
 257   LIBS="$old_LIBS"
 258 else
 259   libc_cv_nss_crypt=no
 260 fi
 261 AC_SUBST(libc_cv_nss_crypt)
 262
 263 # The way shlib-versions is used to generate soversions.mk uses a
 264 # fairly simplistic model for name recognition that can't distinguish
 265 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 266 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 267 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 268 case "$host_os" in
 269 linux*)
 270   ;;
 271 gnu*)
 272   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 273   ;;
 274 esac
 275
 276 # We keep the original values in `$config_*' and never modify them, so we
 277 # can write them unchanged into config.make.  Everything else uses
 278 # $machine, $vendor, and $os, and changes them whenever convenient.
 279 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 280
 281 # Don't allow vendor == "unknown"
 282 test "$config_vendor" = unknown && config_vendor=
 283 config_os="`echo $config_os | sed 's/^unknown-//'`"
 284
 285 # Some configurations imply other options.
 286 elf=yes
 287
 288 # The configure fragment of an add-on port can modify these to supplement
 289 # or override the table in the case statement below.  No fragment should
 290 # ever change the config_* variables, however.
 291 machine=$config_machine
 292 vendor=$config_vendor
 293 os=$config_os
 294 base_os=''
 295
 296 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 297 # Unify this here.
 298 if test "$machine" = rs6000; then
 299   machine="powerpc"
 300 fi
 301
 302 # Braindead PowerPC box with absolutely no FPU.
 303 case "$machine-$host_os" in
 304   powerpc*-*soft)
 305     with_fp=no
 306     ;;
 307 esac
 308
 309 submachine=
 310 AC_ARG_WITH([cpu],
 311             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 312             [dnl
 313   case "$withval" in
 314   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 315   no) ;;
 316   *) submachine="$withval" ;;
 317   esac
 318 ])
 319
 320 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 321 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 322
 323 # An add-on can set this when it wants to disable the sanity check below.
 324 libc_config_ok=no
 325
 326 dnl Having this here, though empty, makes sure that if add-ons' fragments
 327 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 328 dnl our AC_OUTPUT will actually use it.
 329 AC_CONFIG_SUBDIRS()
 330
 331 case "$enable_add_ons" in
 332 ''|no) add_ons= ;;
 333 yes|'*')
 334  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 335           sed 's@/[[^/]]*$@@' | sort | uniq`
 336          add_ons_automatic=yes
 337          ;;
 338 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 339        add_ons_automatic=no ;;
 340 esac
 341
 342 configured_add_ons=
 343 add_ons_sfx=
 344 add_ons_pfx=
 345 if test x"$add_ons" != x; then
 346   for f in $add_ons; do
 347     # Some sanity checks
 348     case "$f" in
 349     crypt)
 350       AC_MSG_ERROR([
 351 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 352 *** part of glibc and using the old add-on will not work with this
 353 *** release.  Start again with fresh sources and without the old
 354 *** \`crypt' add-on.])
 355     ;;
 356     localedata)
 357       AC_MSG_ERROR([
 358 *** It seems that you're using an old \`localedata' add-on.  localedata
 359 *** is now part of glibc and using the old add-on will not work with
 360 *** this release.  Start again with fresh sources and without the old
 361 *** \`localedata' add-on.])
 362     ;;
 363     esac
 364   done
 365
 366   # Now source each add-on's configure fragment.
 367   # The fragments can use $srcdir/$libc_add_on to find themselves,
 368   # and test $add_ons_automatic to see if they were explicitly requested.
 369   # A fragment can clear (or even change) $libc_add_on to affect
 370   # whether it goes into the list to be actually used in the build.
 371   use_add_ons=
 372   for libc_add_on in $add_ons; do
 373     # Test whether such a directory really exists.
 374     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 375     case "$libc_add_on" in
 376     /*)
 377       libc_add_on_srcdir=$libc_add_on
 378       ;;
 379     *)
 380       test -d "$srcdir/$libc_add_on" || {
 381         if test -d "$libc_add_on"; then
 382           libc_add_on="`pwd`/$libc_add_on"
 383         else
 384           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 385         fi
 386       }
 387       libc_add_on_srcdir=$srcdir/$libc_add_on
 388       ;;
 389     esac
 390
 391     libc_add_on_frag=$libc_add_on_srcdir/configure
 392     libc_add_on_canonical=
 393     libc_add_on_config_subdirs=
 394     if test -r "$libc_add_on_frag"; then
 395       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 396       libc_add_on_canonical=unknown
 397       libc_add_on_subdirs=
 398       . "$libc_add_on_frag"
 399       test -z "$libc_add_on" || {
 400         configured_add_ons="$configured_add_ons $libc_add_on"
 401         if test "x$libc_add_on_canonical" = xunknown; then
 402           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 403         fi
 404         for d in $libc_add_on_subdirs; do
 405           case "$libc_add_on" in
 406           /*) subdir_srcdir="$libc_add_on" ;;
 407           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 408           esac
 409           case "$d" in
 410           .)
 411             d="${libc_add_on_canonical:-$libc_add_on}"
 412             ;;
 413           /*)
 414             subdir_srcdir="$d"
 415             ;;
 416           *)
 417             subdir_srcdir="$subdir_srcdir/$d"
 418             ;;
 419           esac
 420           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 421           add_on_subdirs="$add_on_subdirs $d"
 422           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 423 $d-srcdir = $subdir_srcdir"
 424         done
 425         for d in $libc_add_on_config_subdirs; do
 426           case "$d" in
 427           /*) AC_MSG_ERROR(dnl
 428 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 429           esac
 430           if test ! -d "$libc_add_on_srcdir/$d"; then
 431             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 432           fi
 433           case "$libc_add_on" in
 434           /*) AC_MSG_ERROR(dnl
 435 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 436           esac
 437           subdirs="$subdirs $libc_add_on/$d"
 438         done
 439       }
 440     fi
 441     if test -n "$libc_add_on"; then
 442       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 443       use_add_ons="$use_add_ons $libc_add_on"
 444       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 445       test -z "$libc_add_on_canonical" ||
 446       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 447     fi
 448   done
 449   # Use echo to strip excess whitespace.
 450   add_ons="`echo $use_add_ons`"
 451 fi
 452 AC_SUBST(add_ons)
 453 AC_SUBST(add_on_subdirs)
 454
 455
 456 ###
 457 ### I put this here to prevent those annoying emails from people who cannot
 458 ### read and try to compile glibc on unsupported platforms.  --drepper
 459 ###
 460 ### By using the undocumented --enable-hacker-mode option for configure
 461 ### one can skip this test to make the configuration not fail for unsupported
 462 ### platforms.
 463 ###
 464 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 465   case "$machine-$host_os" in
 466   *-linux* | *-gnu*)
 467     ;;
 468   *)
 469     echo "*** The GNU C library is currently not available for this platform."
 470     echo "*** So far nobody cared to port it and if there is no volunteer it"
 471     echo "*** might never happen.  So, if you have interest to see glibc on"
 472     echo "*** this platform visit"
 473     echo "***   http://www.gnu.org/software/libc/porting.html"
 474     echo "*** and join the group of porters"
 475     exit 1
 476     ;;
 477   esac
 478 fi
 479
 480 dnl We need to use [ and ] for other purposes for a while now.
 481 changequote(,)dnl
 482 # Expand the configuration machine name into a subdirectory by architecture
 483 # type and particular chip.  If an add-on configure fragment already set
 484 # base_machine, we don't change it.
 485 test -n "$base_machine" || case "$machine" in
 486 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 487 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 488 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 489 s390)           base_machine=s390 machine=s390/s390-32 ;;
 490 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 491 sh3*)           base_machine=sh machine=sh/sh3 ;;
 492 sh4*)           base_machine=sh machine=sh/sh4 ;;
 493 sparc | sparcv[67])
 494                 base_machine=sparc machine=sparc/sparc32 ;;
 495 sparcv8 | supersparc | hypersparc)
 496                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 497 sparcv8plus | sparcv8plusa | sparcv9)
 498                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 499 sparcv8plusb | sparcv9b)
 500                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 501 sparcv9v)
 502                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 503 sparcv9v2)
 504                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 505 sparc64)
 506                 base_machine=sparc machine=sparc/sparc64 ;;
 507 sparc64b)
 508                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 509 sparc64v)
 510                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 511 sparc64v2)
 512                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 513 *)              base_machine=$machine ;;
 514 esac
 515 changequote([,])dnl
 516 AC_SUBST(base_machine)
 517
 518 if test "$base_machine" = "i386"; then
 519   AC_DEFINE(USE_REGPARMS)
 520 fi
 521
 522 # For the multi-arch option we need support in the assembler.
 523 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 524                libc_cv_asm_gnu_indirect_function, [dnl
 525 cat > conftest.s <<EOF
 526 .type foo,%gnu_indirect_function
 527 EOF
 528 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 529 then
 530   libc_cv_asm_gnu_indirect_function=yes
 531 else
 532   libc_cv_asm_gnu_indirect_function=no
 533 fi
 534 rm -f conftest*])
 535
 536 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 537 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 538 cat > conftest.s <<EOF
 539 .text
 540 EOF
 541 libc_cv_dot_text=
 542 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 543   libc_cv_dot_text=.text
 544 fi
 545 rm -f conftest*])
 546 if test -z "$libc_cv_dot_text"; then
 547   AC_MSG_RESULT(no)
 548 else
 549   AC_MSG_RESULT(yes)
 550 fi
 551
 552 AC_CACHE_CHECK(for assembler global-symbol directive,
 553                libc_cv_asm_global_directive, [dnl
 554 libc_cv_asm_global_directive=UNKNOWN
 555 for ac_globl in .globl .global .EXPORT; do
 556   cat > conftest.s <<EOF
 557         ${libc_cv_dot_text}
 558         ${ac_globl} foo
 559 foo:
 560 EOF
 561   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 562     libc_cv_asm_global_directive=${ac_globl}
 563   fi
 564   rm -f conftest*
 565   test $libc_cv_asm_global_directive != UNKNOWN && break
 566 done])
 567 if test $libc_cv_asm_global_directive = UNKNOWN; then
 568   AC_MSG_ERROR(cannot determine asm global directive)
 569 else
 570   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 571 fi
 572
 573 AC_CACHE_CHECK(for assembler .type directive prefix,
 574                libc_cv_asm_type_prefix, [dnl
 575 libc_cv_asm_type_prefix=no
 576 for ac_try_prefix in '@' '%' '#'; do
 577   cat > conftest.s <<EOF
 578         ${libc_cv_dot_text}
 579         ${libc_cv_asm_global_directive} foo
 580         .type foo, ${ac_try_prefix}object
 581         .size foo, 1
 582 foo:
 583         .byte 1
 584 EOF
 585   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 586     libc_cv_asm_type_prefix=${ac_try_prefix}
 587   fi
 588   rm -f conftest*
 589   test "x$libc_cv_asm_type_prefix" != xno && break
 590 done])
 591 if test "x$libc_cv_asm_type_prefix" != xno; then
 592   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 593 fi
 594
 595 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
 596   if test x"$multi_arch" = xyes; then
 597     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 598   else
 599     multi_arch=no
 600   fi
 601 fi
 602 if test x"$multi_arch" != xno; then
 603   multi_arch_d=/multiarch
 604 fi
 605
 606 # Compute the list of sysdep directories for this configuration.
 607 # This can take a while to compute.
 608 sysdep_dir=$srcdir/sysdeps
 609 AC_MSG_CHECKING(sysdep dirs)
 610 dnl We need to use [ and ] for other purposes for a while now.
 611 changequote(,)dnl
 612 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 613 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 614
 615 test "x$base_os" != x || case "$os" in
 616 gnu*)
 617   base_os=mach/hurd ;;
 618 linux*)
 619   base_os=unix/sysv ;;
 620 esac
 621
 622 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 623 tail=$os
 624 ostry=$os
 625 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 626   ostry="$ostry /$o"
 627   tail=$o
 628 done
 629 o=`echo $tail | sed 's/[0-9]*$//'`
 630 if test $o != $tail; then
 631   ostry="$ostry /$o"
 632 fi
 633 # For linux-gnu, try linux-gnu, then linux.
 634 o=`echo $tail | sed 's/-.*$//'`
 635 if test $o != $tail; then
 636   ostry="$ostry /$o"
 637 fi
 638
 639 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 640 base=
 641 tail=$base_os
 642 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 643   set $b
 644   base="$base /$1"
 645   tail="$2"
 646 done
 647
 648 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 649 mach=
 650 tail=$machine${submachine:+/$submachine}
 651 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 652   set $m
 653   # Prepend the machine's FPU directory unless --without-fp.
 654   if test "$with_fp" = yes; then
 655     mach="$mach /$1/fpu"
 656   else
 657     mach="$mach /$1/nofpu"
 658   fi
 659   mach="$mach /$1"
 660   tail="$2"
 661 done
 662
 663 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 664 changequote([,])dnl
 665
 666 # Find what sysdep directories exist.
 667 sysnames_add_ons=
 668 sysnames=
 669 for b in $base ''; do
 670   for m0 in $mach ''; do
 671     for v in /$vendor ''; do
 672       test "$v" = / && continue
 673       for o in /$ostry ''; do
 674         test "$o" = / && continue
 675         for m in $multi_arch_d $mach ''; do
 676           for d in $add_ons_pfx ''; do
 677             for a in $add_ons_sfx ''; do
 678               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 679                 try_srcdir="${srcdir}/"
 680                 case "$d" in
 681                 /*) try_srcdir= ;;
 682                 esac
 683                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 684                 test -n "$enable_debug_configure" &&
 685                 echo "$0 [DEBUG]: try $try" >&2
 686                 if test -d "$try_srcdir$try"; then
 687                   sysnames="$sysnames $try"
 688                   { test -n "$o" || test -n "$b"; } && os_used=t
 689                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 690                   case x${m0:-$m} in
 691                   x*/$submachine) submachine_used=t ;;
 692                   esac
 693                   if test -n "$d"; then
 694                     case "$sysnames_add_ons" in
 695                     *" $d "*) ;;
 696                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 697                     esac
 698                   fi
 699                 fi
 700               fi
 701             done
 702           done
 703         done
 704       done
 705     done
 706   done
 707 done
 708
 709 # If the assembler supports gnu_indirect_function symbol type and the
 710 # architecture supports multi-arch, we enable multi-arch by default.
 711 case $sysnames_add_ons$sysnames in
 712 *"$multi_arch_d"*)
 713   ;;
 714 *)
 715   test x"$multi_arch" = xdefault && multi_arch=no
 716   ;;
 717 esac
 718 if test x"$multi_arch" != xno; then
 719   AC_DEFINE(USE_MULTIARCH)
 720 fi
 721 AC_SUBST(multi_arch)
 722
 723 if test -z "$os_used" && test "$os" != none; then
 724   AC_MSG_ERROR(Operating system $os is not supported.)
 725 fi
 726 if test -z "$machine_used" && test "$machine" != none; then
 727   AC_MSG_ERROR(The $machine is not supported.)
 728 fi
 729 if test -z "$submachine_used" && test -n "$submachine"; then
 730   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 731 fi
 732 AC_SUBST(submachine)
 733
 734 # We have now validated the configuration.
 735
 736 # Expand the list of system names into a full list of directories
 737 # from each element's parent name and Implies file (if present).
 738 set $sysnames
 739 names=
 740 while test $# -gt 0; do
 741   name=$1
 742   shift
 743
 744   case " $names " in *" $name "*)
 745     # Already in the list.
 746     continue
 747   esac
 748
 749   # Report each name as we discover it, so there is no long pause in output.
 750   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 751
 752   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 753
 754   case $name in
 755     /*) xsrcdir= ;;
 756     *)  xsrcdir=$srcdir/ ;;
 757   esac
 758   test -n "$enable_debug_configure" &&
 759   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 760
 761   if test -f $xsrcdir$name/Implies; then
 762     # Collect more names from the `Implies' file (removing comments).
 763     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 764     implied=
 765     for x in $implied_candidate; do
 766       found=no
 767       if test -d $xsrcdir$name_base/$x; then
 768         implied="$implied $name_base/$x";
 769         found=yes
 770       fi
 771       for d in $add_ons_pfx ''; do
 772         try="${d}sysdeps/$x"
 773         case $d in
 774          /*) try_srcdir= ;;
 775          *) try_srcdir=$srcdir/ ;;
 776         esac
 777         test -n "$enable_debug_configure" &&
 778          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 779         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 780         then
 781           implied="$implied $try"
 782           found=yes
 783           case "$sysnames_add_ons" in
 784           *" $d "*) ;;
 785           *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 786           esac
 787         fi
 788       done
 789       if test $found = no; then
 790         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 791       fi
 792     done
 793   else
 794     implied=
 795   fi
 796
 797   # Add NAME to the list of names.
 798   names="$names $name"
 799
 800   # Find the parent of NAME, using the empty string if it has none.
 801 changequote(,)dnl
 802   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 803 changequote([,])dnl
 804
 805   # Add the names implied by NAME, and NAME's parent (if it has one), to
 806   # the list of names to be processed (the argument list).  We prepend the
 807   # implied names to the list and append the parent.  We want implied
 808   # directories to come before further directories inferred from the
 809   # configuration components; this ensures that for sysv4, unix/common
 810   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 811   # after sysv4).
 812   sysnames="`echo $implied $* $parent`"
 813   test -n "$sysnames" && set $sysnames
 814 done
 815
 816 # Add the default directories.
 817 default_sysnames="sysdeps/generic"
 818 sysnames="$names $default_sysnames"
 819 AC_SUBST(sysnames)
 820 # The other names were emitted during the scan.
 821 AC_MSG_RESULT($default_sysnames)
 822
 823 # Collect the list of add-ons that supply partial sysdeps trees.
 824 sysdeps_add_ons=
 825 for add_on in $add_ons; do
 826   case "$add_on" in
 827   /*) xsrcdir= ;;
 828   *) xsrcdir="$srcdir/" ;;
 829   esac
 830
 831   test -d "$xsrcdir$add_on/sysdeps" || {
 832     case "$configured_add_ons " in
 833     *" $add_on "*) ;;
 834     *|'')
 835       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 836       ;;
 837     esac
 838     continue
 839   }
 840
 841   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 842   case "$sysnames_add_ons" in
 843   *" $add_on/ "*) ;;
 844   *|'')
 845     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 846     continue ;;
 847   esac
 848
 849   found=no
 850   for d in $sysnames; do
 851     case "$d" in
 852     $add_on/sysdeps/*) ;;
 853     *) continue ;;
 854     esac
 855     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 856        case "$f" in
 857        sys|bits)
 858          for ff in $f/*.h; do
 859            test -d "$ff" || { test -e "$ff" && exit 88; }
 860          done
 861          ;;
 862        *)
 863          test -d "$f" || { test -e "$f" && exit 88; }
 864          ;;
 865        esac
 866      done)
 867     if test $? -eq 88; then
 868       found=yes
 869       break
 870     fi
 871   done
 872   if test $found = no; then
 873     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 874   fi
 875 done
 876 AC_SUBST(sysdeps_add_ons)
 877
 878
 879 ### Locate tools.
 880
 881 AC_PROG_INSTALL
 882 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 883   # The makefiles need to use a different form to find it in $srcdir.
 884   INSTALL='\$(..)./scripts/install-sh -c'
 885 fi
 886 AC_PROG_LN_S
 887
 888 LIBC_PROG_BINUTILS
 889 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 890
 891 # Accept binutils 2.20 or newer.
 892 AC_CHECK_PROG_VER(AS, $AS, --version,
 893                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 894                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 895 AC_CHECK_PROG_VER(LD, $LD, --version,
 896                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 897                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 898
 899 # These programs are version sensitive.
 900 AC_CHECK_TOOL_PREFIX
 901 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 902   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 903   critic_missing="$critic_missing gcc")
 904 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 905   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 906   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 907
 908 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 909   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 910   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 911   MSGFMT=: aux_missing="$aux_missing msgfmt")
 912 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 913   [GNU texinfo.* \([0-9][0-9.]*\)],
 914   [4.*],
 915   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 916 AC_CHECK_PROG_VER(SED, sed, --version,
 917   [GNU sed version \([0-9]*\.[0-9.]*\)],
 918   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 919   SED=: aux_missing="$aux_missing sed")
 920
 921 AC_CHECK_TOOL(READELF, readelf, false)
 922
 923 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 924 case "x$AUTOCONF" in
 925 xno|x|x:) AUTOCONF=no ;;
 926 *)
 927   AC_CACHE_CHECK(dnl
 928 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 929   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 930     libc_cv_autoconf_works=yes
 931   else
 932     libc_cv_autoconf_works=no
 933   fi])
 934   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 935   ;;
 936 esac
 937 if test "x$AUTOCONF" = xno; then
 938   aux_missing="$aux_missing autoconf"
 939 fi
 940
 941 test -n "$critic_missing" && AC_MSG_ERROR([
 942 *** These critical programs are missing or too old:$critic_missing
 943 *** Check the INSTALL file for required versions.])
 944
 945 test -n "$aux_missing" && AC_MSG_WARN([
 946 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 947 *** some features will be disabled.
 948 *** Check the INSTALL file for required versions.])
 949
 950 # if using special system headers, find out the compiler's sekrit
 951 # header directory and add that to the list.  NOTE: Only does the right
 952 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 953 if test -n "$sysheaders"; then
 954   SYSINCLUDES=-nostdinc
 955   for d in include include-fixed; do
 956     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 957     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 958   done
 959   SYSINCLUDES="$SYSINCLUDES \
 960 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 961   if test -n "$CXX"; then
 962     CXX_SYSINCLUDES=
 963     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
 964     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
 965     for d in include "$cxxmachine/include"; do
 966       i=../../../../$d/c++/$cxxversion
 967       cxxheaders=`$CXX -print-file-name="$i"` &&
 968       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
 969       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
 970 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
 971     done
 972   fi
 973 fi
 974 AC_SUBST(SYSINCLUDES)
 975 AC_SUBST(CXX_SYSINCLUDES)
 976
 977 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 978 # since this would lead to problems installing/building glibc.
 979 # LD_LIBRARY_PATH contains the current directory if one of the following
 980 # is true:
 981 # - one of the terminals (":" and ";") is the first or last sign
 982 # - two terminals occur directly after each other
 983 # - the path contains an element with a dot in it
 984 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 985 changequote(,)dnl
 986 case ${LD_LIBRARY_PATH} in
 987   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 988     ld_library_path_setting="contains current directory"
 989     ;;
 990   *)
 991     ld_library_path_setting="ok"
 992     ;;
 993 esac
 994 changequote([,])dnl
 995 AC_MSG_RESULT($ld_library_path_setting)
 996 if test "$ld_library_path_setting" != "ok"; then
 997 AC_MSG_ERROR([
 998 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 999 *** building glibc. Please change the environment variable
1000 *** and run configure again.])
1001 fi
1002
1003 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1004 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1005   libc_cv_gcc_static_libgcc=
1006 else
1007   libc_cv_gcc_static_libgcc=-static-libgcc
1008 fi])
1009 AC_SUBST(libc_cv_gcc_static_libgcc)
1010
1011 AC_PATH_PROG(BASH_SHELL, bash, no)
1012 if test "$BASH_SHELL" != no &&
1013    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1014              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1015   libc_cv_have_bash2=yes
1016 else
1017   libc_cv_have_bash2=no
1018 fi
1019 AC_SUBST(libc_cv_have_bash2)
1020
1021 dnl We need a ksh compatible shell for tzselect.
1022 if test "$BASH_SHELL" = no; then
1023   AC_PATH_PROG(KSH, ksh, no)
1024   if test "$KSH" = no; then
1025     libc_cv_have_ksh=no
1026   else
1027     libc_cv_have_ksh=yes
1028   fi
1029 else
1030   KSH="$BASH_SHELL"
1031   AC_SUBST(KSH)
1032   libc_cv_have_ksh=yes
1033 fi
1034 AC_SUBST(libc_cv_have_ksh)
1035
1036 AC_PROG_AWK
1037 AC_PATH_PROG(PERL, perl, no)
1038 if test "$PERL" != no &&
1039    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1040   PERL=no
1041 fi
1042 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1043              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1044 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1045
1046 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1047 AC_TRY_COMPILE(dnl
1048 [#define __need_size_t
1049 #define __need_wchar_t
1050 #include <stddef.h>
1051 #define __need_NULL
1052 #include <stddef.h>], [size_t size; wchar_t wchar;
1053 #ifdef offsetof
1054 #error stddef.h ignored __need_*
1055 #endif
1056 if (&size == NULL || &wchar == NULL) abort ();],
1057                libc_cv_friendly_stddef=yes,
1058                libc_cv_friendly_stddef=no)])
1059 if test $libc_cv_friendly_stddef = yes; then
1060   config_vars="$config_vars
1061 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1062 fi
1063
1064 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1065                libc_cv_need_minus_P, [dnl
1066 cat > conftest.S <<EOF
1067 #include "confdefs.h"
1068 /* Nothing whatsoever.  */
1069 EOF
1070 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1071   libc_cv_need_minus_P=no
1072 else
1073   libc_cv_need_minus_P=yes
1074 fi
1075 rm -f conftest*])
1076 if test $libc_cv_need_minus_P = yes; then
1077   config_vars="$config_vars
1078 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1079 fi
1080
1081 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1082 cat > conftest.s <<EOF
1083 ${libc_cv_dot_text}
1084 foo:
1085 .set glibc_conftest_frobozz,foo
1086 $libc_cv_asm_global_directive glibc_conftest_frobozz
1087 EOF
1088 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1089 # (but it doesn't work), so we must do a linking check to be sure.
1090 cat > conftest1.c <<\EOF
1091 extern int glibc_conftest_frobozz;
1092 void _start() { glibc_conftest_frobozz = 1; }
1093 EOF
1094 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1095             -nostartfiles -nostdlib \
1096             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1097   libc_cv_asm_set_directive=yes
1098 else
1099   libc_cv_asm_set_directive=no
1100 fi
1101 rm -f conftest*])
1102 if test $libc_cv_asm_set_directive = yes; then
1103   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1104 fi
1105
1106 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1107                libc_cv_asm_unique_object, [dnl
1108 cat > conftest.s <<EOF
1109 ${libc_cv_dot_text}
1110 _sym:
1111 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1112 EOF
1113 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1114   libc_cv_asm_unique_object=yes
1115 else
1116   libc_cv_asm_unique_object=no
1117 fi
1118 rm -f conftest*])
1119 if test $libc_cv_asm_unique_object = yes; then
1120   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1121 fi
1122
1123 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1124 [cat > conftest.s <<EOF
1125 ${libc_cv_dot_text}
1126 _sym:
1127 .symver _sym,sym@VERS
1128 EOF
1129 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1130   libc_cv_asm_symver_directive=yes
1131 else
1132   libc_cv_asm_symver_directive=no
1133 fi
1134 rm -f conftest*])
1135 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1136 if test $libc_cv_asm_symver_directive = yes; then
1137   cat > conftest.s <<EOF
1138 ${libc_cv_dot_text}
1139 _sym:
1140 .symver _sym,sym@VERS
1141 EOF
1142   cat > conftest.map <<EOF
1143 VERS_1 {
1144         global: sym;
1145 };
1146
1147 VERS_2 {
1148         global: sym;
1149 } VERS_1;
1150 EOF
1151   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1152     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1153                                 -o conftest.so conftest.o
1154                                 -nostartfiles -nostdlib
1155                                 -Wl,--version-script,conftest.map
1156                        1>&AS_MESSAGE_LOG_FD]);
1157     then
1158       libc_cv_ld_version_script_option=yes
1159     else
1160       libc_cv_ld_version_script_option=no
1161     fi
1162   else
1163     libc_cv_ld_version_script_option=no
1164   fi
1165 else
1166   libc_cv_ld_version_script_option=no
1167 fi
1168 rm -f conftest*])
1169 if test $shared != no &&
1170    test $libc_cv_asm_symver_directive = yes &&
1171    test $libc_cv_ld_version_script_option = yes &&
1172    test $enable_versioning = yes; then
1173   VERSIONING=yes
1174   AC_DEFINE(DO_VERSIONING)
1175 else
1176   VERSIONING=no
1177 fi
1178 AC_SUBST(VERSIONING)
1179
1180 if test $shared != no && test $VERSIONING = no; then
1181   echo "\
1182 *** WARNING: You should not compile GNU libc without versioning. Not using
1183 *** versioning will introduce incompatibilities so that old binaries
1184 *** will not run anymore.
1185 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1186 fi
1187 AC_CACHE_CHECK(for .previous assembler directive,
1188                libc_cv_asm_previous_directive, [dnl
1189 cat > conftest.s <<EOF
1190 .section foo_section
1191 .previous
1192 EOF
1193 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1194   libc_cv_asm_previous_directive=yes
1195 else
1196   libc_cv_asm_previous_directive=no
1197 fi
1198 rm -f conftest*])
1199 if test $libc_cv_asm_previous_directive = yes; then
1200   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1201 else
1202   AC_CACHE_CHECK(for .popsection assembler directive,
1203                  libc_cv_asm_popsection_directive, [dnl
1204   cat > conftest.s <<EOF
1205 .pushsection foo_section
1206 .popsection
1207 EOF
1208   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1209     libc_cv_asm_popsection_directive=yes
1210   else
1211     libc_cv_asm_popsection_directive=no
1212   fi
1213   rm -f conftest*])
1214   if test $libc_cv_asm_popsection_directive = yes; then
1215     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1216   fi
1217 fi
1218 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1219                libc_cv_asm_protected_directive, [dnl
1220 cat > conftest.s <<EOF
1221 .protected foo
1222 foo:
1223 .hidden bar
1224 bar:
1225 EOF
1226 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1227   libc_cv_asm_protected_directive=yes
1228 else
1229   AC_MSG_ERROR(assembler support for symbol visibility is required)
1230 fi
1231 rm -f conftest*])
1232
1233 if test $libc_cv_asm_protected_directive = yes; then
1234   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1235                  libc_cv_visibility_attribute,
1236                  [cat > conftest.c <<EOF
1237                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1238                   int bar __attribute__ ((visibility ("protected"))) = 1;
1239 EOF
1240                   libc_cv_visibility_attribute=no
1241                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1242                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1243                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1244                         libc_cv_visibility_attribute=yes
1245                       fi
1246                     fi
1247                   fi
1248                   rm -f conftest.{c,s}
1249                  ])
1250   if test $libc_cv_visibility_attribute != yes; then
1251     AC_MSG_ERROR(compiler support for visibility attribute is required)
1252   fi
1253 fi
1254
1255 if test $libc_cv_visibility_attribute = yes; then
1256   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1257                  libc_cv_broken_visibility_attribute,
1258                  [cat > conftest.c <<EOF
1259                   int foo (int x);
1260                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1261                   int bar (int x) { return x; }
1262 EOF
1263                   libc_cv_broken_visibility_attribute=yes
1264                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1265 changequote(,)dnl
1266                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1267 changequote([,])dnl
1268                       libc_cv_broken_visibility_attribute=no
1269                     fi
1270                   fi
1271                   rm -f conftest.c conftest.s
1272                  ])
1273   if test $libc_cv_broken_visibility_attribute = yes; then
1274     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1275   fi
1276 fi
1277
1278 AC_CACHE_CHECK(for broken __attribute__((alias())),
1279                libc_cv_broken_alias_attribute,
1280                [cat > conftest.c <<EOF
1281                extern int foo (int x) __asm ("xyzzy");
1282                int bar (int x) { return x; }
1283                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1284                extern int dfoo;
1285                extern __typeof (dfoo) dfoo __asm ("abccb");
1286                int dfoo = 1;
1287 EOF
1288                libc_cv_broken_alias_attribute=yes
1289                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1290                  if grep 'xyzzy' conftest.s >/dev/null &&
1291                     grep 'abccb' conftest.s >/dev/null; then
1292                    libc_cv_broken_alias_attribute=no
1293                  fi
1294                fi
1295                rm -f conftest.c conftest.s
1296                ])
1297 if test $libc_cv_broken_alias_attribute = yes; then
1298   AC_MSG_ERROR(working alias attribute support required)
1299 fi
1300
1301 if test $libc_cv_visibility_attribute = yes; then
1302   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1303                  libc_cv_have_sdata_section,
1304                  [echo "int i;" > conftest.c
1305                   libc_cv_have_sdata_section=no
1306                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1307                      | grep '\.sdata' >/dev/null; then
1308                     libc_cv_have_sdata_section=yes
1309                   fi
1310                   rm -f conftest.c conftest.so
1311                  ])
1312   if test $libc_cv_have_sdata_section = yes; then
1313     AC_DEFINE(HAVE_SDATA_SECTION)
1314   fi
1315 fi
1316
1317 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1318                libc_cv_initfini_array, [dnl
1319 LIBC_TRY_LINK_STATIC([
1320 int foo (void) { return 1; }
1321 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1322 ],
1323   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1324     libc_cv_initfini_array=yes
1325   else
1326     libc_cv_initfini_array=no
1327   fi],
1328   [libc_cv_initfini_array=no])
1329 ])
1330 if test $libc_cv_initfini_array != yes; then
1331   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1332 fi
1333
1334 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1335                libc_cv_ctors_header, [dnl
1336   libc_cv_ctors_header=yes
1337   LIBC_TRY_LINK_STATIC([
1338 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1339 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1340 ],
1341               [dnl
1342       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1343         { gsub(/\@<:@ */, "@<:@") }
1344         $2 == ".ctors" || $2 == ".dtors" {
1345           size = strtonum("0x" $6)
1346           align = strtonum("0x" $NF)
1347           seen@<:@$2@:>@ = 1
1348           stub@<:@$2@:>@ = size == align * 2
1349         }
1350         END {
1351           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1352           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1353           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1354         }
1355       '], [libc_cv_ctors_header=no])
1356     ], [dnl
1357       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1358     ])
1359 ])
1360 if test $libc_cv_ctors_header = no; then
1361   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1362 fi
1363
1364 AC_CACHE_CHECK(for libunwind-support in compiler,
1365                libc_cv_cc_with_libunwind, [
1366   cat > conftest.c <<EOF
1367 int main (void) { return 0; }
1368 EOF
1369   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1370      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1371     libc_cv_cc_with_libunwind=yes
1372   else
1373     libc_cv_cc_with_libunwind=no
1374   fi
1375   rm -f conftest*])
1376 AC_SUBST(libc_cv_cc_with_libunwind)
1377 if test $libc_cv_cc_with_libunwind = yes; then
1378   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1379 fi
1380
1381 AC_CACHE_CHECK(for -z nodelete option,
1382                libc_cv_z_nodelete, [dnl
1383 cat > conftest.c <<EOF
1384 int _start (void) { return 42; }
1385 EOF
1386 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1387                    -fPIC -shared -o conftest.so conftest.c
1388                    -nostartfiles -nostdlib
1389                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1390 then
1391   libc_cv_z_nodelete=yes
1392 else
1393   AC_MSG_ERROR(linker with -z nodelete support required)
1394 fi
1395 rm -f conftest*])
1396
1397 AC_CACHE_CHECK(for -z nodlopen option,
1398                libc_cv_z_nodlopen, [dnl
1399 cat > conftest.c <<EOF
1400 int _start (void) { return 42; }
1401 EOF
1402 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1403                         -fPIC -shared -o conftest.so conftest.c
1404                         -nostartfiles -nostdlib
1405                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1406 then
1407   libc_cv_z_nodlopen=yes
1408 else
1409   AC_MSG_ERROR(linker with -z nodlopen support required)
1410 fi
1411 rm -f conftest*])
1412
1413 AC_CACHE_CHECK(for -z initfirst option,
1414                libc_cv_z_initfirst, [dnl
1415 cat > conftest.c <<EOF
1416 int _start (void) { return 42; }
1417 EOF
1418 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1419                         -fPIC -shared -o conftest.so conftest.c
1420                         -nostartfiles -nostdlib
1421                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1422 then
1423   libc_cv_z_initfirst=yes
1424 else
1425   AC_MSG_ERROR(linker with -z initfirst support required)
1426 fi
1427 rm -f conftest*])
1428
1429 # Add-on fragments can set these for other machines.
1430 libc_commonpagesize=${libc_commonpagesize:-no}
1431 libc_relro_required=${libc_relro_required:-no}
1432 case "$base_machine" in
1433   i[[34567]]86 | x86_64 | powerpc* | s390*)
1434     libc_commonpagesize=0x1000
1435     libc_relro_required=yes
1436     ;;
1437   sparc*)
1438     libc_commonpagesize=0x2000
1439     libc_relro_required=yes
1440     ;;
1441 esac
1442
1443 if test $libc_commonpagesize != no; then
1444   AC_CACHE_CHECK(for -z relro option,
1445                  libc_cv_z_relro, [dnl
1446   libc_cv_z_relro=no
1447   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1448 int _start (void) { return 42; }
1449 extern void _exit (int);
1450 /* Since these pointers are const, they should go in rodata.
1451    Since they refer to functions that have to be resolved by
1452    dynamic linking, they should instead go in RELRO data.  */
1453 const void *const relro[] = { &_start, &_exit, 0 };
1454 /* GNU ld fails to produce RELRO data when it's very small and there is no
1455    normal writable data following it, or if only uninitialized (.bss) data
1456    follows it, or only very small writable data.  */
1457 int data[0x10000] = { 1, };
1458 ]])])
1459   cat > conftest.awk <<\EOF
1460 BEGIN {
1461   result = "no"
1462   commonpagesize = strtonum(commonpagesize)
1463 }
1464 { print "LINE:", $0 > "/dev/stderr" }
1465 $1 == "GNU_RELRO" {
1466   vaddr = strtonum($3)
1467   memsz = strtonum($6)
1468   end = vaddr + memsz
1469   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1470     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1471   result = (end % commonpagesize == 0) ? "yes" : "broken"
1472 }
1473 END { print result }
1474 EOF
1475   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1476                     -fPIC -shared -o conftest.so conftest.c
1477                     -nostartfiles -nostdlib
1478                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1479   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1480   AC_TRY_COMMAND([
1481       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1482            conftest.ph > conftest.cps
1483     ]) &&
1484   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1485   rm -f conftest*])
1486   if { test "x$libc_relro_required" = xyes &&
1487        test "x$libc_cv_z_relro" != xyes
1488      }
1489   then
1490     AC_MSG_ERROR(linker with -z relro support required)
1491   fi
1492 else
1493   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1494 fi
1495
1496 AC_CACHE_CHECK(for -Bgroup option,
1497                libc_cv_Bgroup, [dnl
1498 cat > conftest.c <<EOF
1499 int _start (void) { return 42; }
1500 EOF
1501 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1502                             -fPIC -shared -o conftest.so conftest.c
1503                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1504 then
1505   libc_cv_Bgroup=yes
1506 else
1507   libc_cv_Bgroup=no
1508 fi
1509 rm -f conftest*])
1510 AC_SUBST(libc_cv_Bgroup)
1511
1512 ASFLAGS_config=
1513 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1514                libc_cv_as_noexecstack, [dnl
1515 cat > conftest.c <<EOF
1516 void foo (void) { }
1517 EOF
1518 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1519                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1520    && grep -q .note.GNU-stack conftest.s \
1521    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1522                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1523 then
1524   libc_cv_as_noexecstack=yes
1525 else
1526   libc_cv_as_noexecstack=no
1527 fi
1528 rm -f conftest*])
1529 if test $libc_cv_as_noexecstack = yes; then
1530   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1531 fi
1532 AC_SUBST(ASFLAGS_config)
1533
1534 AC_CACHE_CHECK(for -z combreloc,
1535                libc_cv_z_combreloc, [dnl
1536 cat > conftest.c <<EOF
1537 extern int bar (int);
1538 extern int mumble;
1539 int foo (void) { return bar (mumble); }
1540 EOF
1541 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1542                         -fPIC -shared -o conftest.so conftest.c
1543                         -nostdlib -nostartfiles
1544                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1545 then
1546 dnl The following test is a bit weak.  We must use a tool which can test
1547 dnl cross-platform since the gcc used can be a cross compiler.  Without
1548 dnl introducing new options this is not easily doable.  Instead use a tool
1549 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1550 dnl look for a section named .rel.dyn.
1551   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1552     libc_cv_z_combreloc=yes
1553   else
1554     libc_cv_z_combreloc=no
1555   fi
1556 else
1557   libc_cv_z_combreloc=no
1558 fi
1559 rm -f conftest*])
1560 if test "$libc_cv_z_combreloc" = yes; then
1561   AC_DEFINE(HAVE_Z_COMBRELOC)
1562 fi
1563 AC_SUBST(libc_cv_z_combreloc)
1564
1565 AC_CACHE_CHECK(for -z execstack,
1566                libc_cv_z_execstack, [dnl
1567 cat > conftest.c <<EOF
1568 int _start (void) { return 42; }
1569 EOF
1570 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1571                             -fPIC -shared -o conftest.so conftest.c
1572                             -Wl,-z,execstack -nostdlib
1573                             1>&AS_MESSAGE_LOG_FD])
1574 then
1575   libc_cv_z_execstack=yes
1576 else
1577   libc_cv_z_execstack=no
1578 fi
1579 rm -f conftest*])
1580 AC_SUBST(libc_cv_z_execstack)
1581
1582 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1583 cat > conftest.c <<EOF
1584 int foo;
1585 main () { return 0;}
1586 EOF
1587 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1588                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1589 then
1590   libc_cv_fpie=yes
1591 else
1592   libc_cv_fpie=no
1593 fi
1594 rm -f conftest*])
1595
1596 AC_SUBST(libc_cv_fpie)
1597
1598 AC_CACHE_CHECK(for --hash-style option,
1599                libc_cv_hashstyle, [dnl
1600 cat > conftest.c <<EOF
1601 int _start (void) { return 42; }
1602 EOF
1603 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1604                             -fPIC -shared -o conftest.so conftest.c
1605                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1606 then
1607   libc_cv_hashstyle=yes
1608 else
1609   libc_cv_hashstyle=no
1610 fi
1611 rm -f conftest*])
1612 AC_SUBST(libc_cv_hashstyle)
1613
1614 # The linker's default -shared behavior is good enough if it
1615 # does these things that our custom linker scripts ensure that
1616 # all allocated NOTE sections come first.
1617 if test "$use_default_link" = default; then
1618   AC_CACHE_CHECK([for sufficient default -shared layout],
1619                   libc_cv_use_default_link, [dnl
1620   libc_cv_use_default_link=no
1621   cat > conftest.s <<\EOF
1622           .section .note.a,"a",%note
1623           .balign 4
1624           .long 4,4,9
1625           .string "GNU"
1626           .string "foo"
1627           .section .note.b,"a",%note
1628           .balign 4
1629           .long 4,4,9
1630           .string "GNU"
1631           .string "bar"
1632 EOF
1633   if AC_TRY_COMMAND([dnl
1634   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1635        ac_try=`$READELF -S conftest.so | sed -n \
1636          ['${x;p;}
1637           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1638           t a
1639           b
1640           : a
1641           H']`
1642   then
1643     libc_seen_a=no libc_seen_b=no
1644     set -- $ac_try
1645     while test $# -ge 2 -a "$1" = NOTE; do
1646       case "$2" in
1647       .note.a) libc_seen_a=yes ;;
1648       .note.b) libc_seen_b=yes ;;
1649       esac
1650       shift 2
1651     done
1652     case "$libc_seen_a$libc_seen_b" in
1653     yesyes)
1654       libc_cv_use_default_link=yes
1655       ;;
1656     *)
1657       echo >&AS_MESSAGE_LOG_FD "\
1658 $libc_seen_a$libc_seen_b from:
1659 $ac_try"
1660       ;;
1661     esac
1662   fi
1663   rm -f conftest*])
1664   use_default_link=$libc_cv_use_default_link
1665 fi
1666
1667 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1668 if libc_cv_output_format=`
1669 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1670 then
1671   :
1672 else
1673   libc_cv_output_format=
1674 fi
1675 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1676 AC_SUBST(libc_cv_output_format)
1677
1678 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1679 cat > conftest.c <<EOF
1680 int foo;
1681 EOF
1682 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1683                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1684 then
1685   libc_cv_fno_toplevel_reorder=yes
1686 else
1687   libc_cv_fno_toplevel_reorder=no
1688 fi
1689 rm -f conftest*])
1690 if test $libc_cv_fno_toplevel_reorder = yes; then
1691   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1692 else
1693   fno_unit_at_a_time=-fno-unit-at-a-time
1694 fi
1695 AC_SUBST(fno_unit_at_a_time)
1696
1697 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1698 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1699                    [libc_cv_ssp=yes],
1700                    [libc_cv_ssp=no])
1701 ])
1702 AC_SUBST(libc_cv_ssp)
1703
1704 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1705 cat > conftest.c <<EOF
1706 int foo;
1707 #ifdef __GNUC_GNU_INLINE__
1708 main () { return 0;}
1709 #else
1710 #error
1711 #endif
1712 EOF
1713 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1714                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1715 then
1716   libc_cv_gnu89_inline=yes
1717 else
1718   libc_cv_gnu89_inline=no
1719 fi
1720 rm -f conftest*])
1721 if test $libc_cv_gnu89_inline = yes; then
1722   gnu89_inline=-fgnu89-inline
1723 else
1724   gnu89_inline=
1725 fi
1726 AC_SUBST(gnu89_inline)
1727
1728 AC_CACHE_CHECK(whether cc puts quotes around section names,
1729                libc_cv_have_section_quotes,
1730                [cat > conftest.c <<EOF
1731                 static const int foo
1732                 __attribute__ ((section ("bar"))) = 1;
1733 EOF
1734                 if ${CC-cc} -S conftest.c -o conftest.s; then
1735                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1736                     libc_cv_have_section_quotes=yes
1737                   else
1738                     libc_cv_have_section_quotes=no
1739                   fi
1740                 else
1741                   libc_cv_have_section_quotes=unknown
1742                 fi
1743                 rm -f conftest.{c,s}
1744                 ])
1745 if test $libc_cv_have_section_quotes = yes; then
1746   AC_DEFINE(HAVE_SECTION_QUOTES)
1747 fi
1748
1749 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1750                [dnl
1751 cat > conftest.s <<EOF
1752 ${libc_cv_dot_text}
1753 ${libc_cv_asm_global_directive} foo
1754 foo:
1755 .weak foo
1756 .weak bar; bar = foo
1757 EOF
1758 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1759   libc_cv_asm_weak_directive=yes
1760 else
1761   libc_cv_asm_weak_directive=no
1762 fi
1763 rm -f conftest*])
1764
1765 if test $libc_cv_asm_weak_directive = no; then
1766   AC_CACHE_CHECK(for assembler .weakext directive,
1767                  libc_cv_asm_weakext_directive,
1768                  [dnl
1769 cat > conftest.s <<EOF
1770 ${libc_cv_dot_text}
1771 ${libc_cv_asm_global_directive} foo
1772 foo:
1773 .weakext bar foo
1774 .weakext baz
1775 ${libc_cv_asm_global_directive} baz
1776 baz:
1777 EOF
1778   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1779     libc_cv_asm_weakext_directive=yes
1780   else
1781     libc_cv_asm_weakext_directive=no
1782   fi
1783   rm -f conftest*])
1784
1785 fi # no .weak
1786
1787 if test $libc_cv_asm_weak_directive = yes; then
1788   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1789 elif test $libc_cv_asm_weakext_directive = yes; then
1790   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1791 fi
1792
1793 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1794 case $machine in
1795   sparc/sparc64*) cfi_offset=2047;;
1796   *) cfi_offset=0;;
1797 esac
1798 cat > conftest.s <<EOF
1799         .text
1800         .type   func,%function
1801 func:
1802         .cfi_startproc
1803         .cfi_remember_state
1804         .cfi_rel_offset 1, $cfi_offset
1805         .cfi_endproc
1806 EOF
1807 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1808   libc_cv_asm_cfi_directives=yes
1809 else
1810   libc_cv_asm_cfi_directives=no
1811 fi
1812 rm -f conftest*])
1813 if test $libc_cv_asm_cfi_directives = yes; then
1814   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1815 fi
1816
1817 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1818 cat > conftest.c <<\EOF
1819 _start () {}
1820 int __eh_pc;
1821 __throw () {}
1822 EOF
1823 dnl No \ in command here because it ends up inside ''.
1824 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1825                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1826                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1827   libc_cv_ld_no_whole_archive=yes
1828 else
1829   libc_cv_ld_no_whole_archive=no
1830 fi
1831 rm -f conftest*])
1832 if test $libc_cv_ld_no_whole_archive = no; then
1833   AC_MSG_ERROR([support for --no-whole-archive is needed])
1834 fi
1835
1836 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1837 cat > conftest.c <<\EOF
1838 _start () {}
1839 int __eh_pc;
1840 __throw () {}
1841 EOF
1842 dnl No \ in command here because it ends up inside ''.
1843 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1844                             -nostdlib -nostartfiles -fexceptions
1845                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1846   libc_cv_gcc_exceptions=yes
1847 else
1848   libc_cv_gcc_exceptions=no
1849 fi
1850 rm -f conftest*])
1851 if test $libc_cv_gcc_exceptions = yes; then
1852   exceptions=-fexceptions
1853 fi
1854 AC_SUBST(exceptions)dnl
1855
1856 if test "$host_cpu" = powerpc ; then
1857 # Check for a bug present in at least versions 2.8.x of GCC
1858 # and versions 1.0.x of EGCS.
1859 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1860 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1861                libc_cv_c_asmcr0_bug='no',
1862                libc_cv_c_asmcr0_bug='yes')])
1863 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1864   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1865 fi
1866 fi
1867
1868 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1869 cat > conftest.c <<\EOF
1870 void zero (void *x)
1871 {
1872   __builtin_memset (x, 0, 1000);
1873 }
1874 EOF
1875 dnl
1876 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1877 then
1878   libc_cv_gcc_builtin_memset=no
1879 else
1880   libc_cv_gcc_builtin_memset=yes
1881 fi
1882 rm -f conftest* ])
1883 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1884   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1885 fi
1886
1887 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1888 cat > conftest.c <<\EOF
1889 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1890 char *foo (const char *a, const char *b)
1891 {
1892   return __builtin_strstr (a, b);
1893 }
1894 EOF
1895 dnl
1896 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1897 then
1898   libc_cv_gcc_builtin_redirection=yes
1899 else
1900   libc_cv_gcc_builtin_redirection=no
1901 fi
1902 rm -f conftest* ])
1903 if test "$libc_cv_gcc_builtin_redirection" = no; then
1904   AC_MSG_ERROR([support for the symbol redirection needed])
1905 fi
1906
1907 dnl Check whether the compiler supports the __thread keyword.
1908 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1909 [cat > conftest.c <<\EOF
1910 __thread int a = 42;
1911 EOF
1912 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1913   libc_cv_gcc___thread=yes
1914 else
1915   libc_cv_gcc___thread=no
1916 fi
1917 rm -f conftest*])
1918 if test "$libc_cv_gcc___thread" = no; then
1919   AC_MSG_ERROR([support for the __thread keyword is required])
1920 fi
1921
1922 dnl Check whether the compiler supports the tls_model attribute.
1923 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1924 cat > conftest.c <<\EOF
1925 extern __thread int a __attribute__((tls_model ("initial-exec")));
1926 EOF
1927 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1928   libc_cv_gcc_tls_model_attr=yes
1929 else
1930   libc_cv_gcc_tls_model_attr=no
1931 fi
1932 rm -f conftest*])
1933 if test "$libc_cv_gcc_tls_model_attr" = no; then
1934   AC_MSG_ERROR([support for the tls_model attribute is required])
1935 fi
1936
1937 dnl Determine how to disable generation of FMA instructions.
1938 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1939                libc_cv_cc_nofma, [dnl
1940 libc_cv_cc_nofma=
1941 for opt in -ffp-contract=off -mno-fused-madd; do
1942   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1943 done])
1944
1945 if test -n "$submachine"; then
1946   AC_CACHE_CHECK([for compiler option for CPU variant],
1947                  libc_cv_cc_submachine, [dnl
1948   libc_cv_cc_submachine=no
1949   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1950     LIBC_TRY_CC_OPTION([$opt], [
1951       libc_cv_cc_submachine="$opt"
1952       break], [])
1953   done])
1954   if test "x$libc_cv_cc_submachine" = xno; then
1955     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1956   fi
1957 fi
1958 AC_SUBST(libc_cv_cc_submachine)
1959
1960 dnl Check whether we have the gd library available.
1961 AC_MSG_CHECKING(for libgd)
1962 if test "$with_gd" != "no"; then
1963   old_CFLAGS="$CFLAGS"
1964   CFLAGS="$CFLAGS $libgd_include"
1965   old_LDFLAGS="$LDFLAGS"
1966   LDFLAGS="$LDFLAGS $libgd_ldflags"
1967   old_LIBS="$LIBS"
1968   LIBS="$LIBS -lgd -lpng -lz -lm"
1969   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1970   CFLAGS="$old_CFLAGS"
1971   LDFLAGS="$old_LDFLAGS"
1972   LIBS="$old_LIBS"
1973 else
1974   LIBGD=no
1975 fi
1976 AC_MSG_RESULT($LIBGD)
1977 AC_SUBST(LIBGD)
1978
1979 # SELinux detection
1980 if test x$with_selinux = xno ; then
1981   have_selinux=no;
1982 else
1983   # See if we have the SELinux library
1984   AC_CHECK_LIB(selinux, is_selinux_enabled,
1985                have_selinux=yes, have_selinux=no)
1986   # See if we have the SELinux header with the NSCD permissions in it.
1987   if test x$have_selinux = xyes ; then
1988     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1989     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1990                     [#ifdef NSCD__SHMEMHOST
1991                      return 0;
1992                      #else
1993                      #error NSCD__SHMEMHOST not defined
1994                      #endif],
1995                     have_selinux=yes, have_selinux=no)
1996     AC_MSG_RESULT($have_selinux)
1997   fi
1998
1999   if test x$with_selinux = xyes ; then
2000     if test x$have_selinux = xno ; then
2001       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2002     fi
2003   fi
2004 fi
2005 # Check if we're building with SELinux support.
2006 if test "x$have_selinux" = xyes; then
2007   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2008
2009   # See if we have the libaudit library
2010   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2011                have_libaudit=yes, have_libaudit=no)
2012   if test "x$have_libaudit" = xyes; then
2013     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2014   fi
2015   AC_SUBST(have_libaudit)
2016
2017   # See if we have the libcap library
2018   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2019   if test "x$have_libcap" = xyes; then
2020     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2021   fi
2022   AC_SUBST(have_libcap)
2023 fi
2024 AC_SUBST(have_selinux)
2025
2026 dnl check for the size of 'long double'.
2027 AC_CHECK_SIZEOF(long double, 0)
2028 sizeof_long_double=$ac_cv_sizeof_long_double
2029 AC_SUBST(sizeof_long_double)
2030
2031 ### End of automated tests.
2032 ### Now run sysdeps configure fragments.
2033
2034 # They also can set these variables.
2035 use_ldconfig=no
2036 ldd_rewrite_script=no
2037 libc_cv_sysconfdir=$sysconfdir
2038 libc_cv_gcc_unwind_find_fde=no
2039 libc_cv_idn=no
2040
2041 # Iterate over all the sysdep directories we will use, running their
2042 # configure fragments.
2043 for dir in $sysnames; do
2044   case $dir in
2045     /*) dest=$dir ;;
2046     *)  dest=$srcdir/$dir ;;
2047   esac
2048   if test -r $dest/configure; then
2049     AC_MSG_RESULT(running configure fragment for $dir)
2050     . $dest/configure
2051   fi
2052 done
2053
2054 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2055   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2056 fi
2057 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2058
2059 # Test for old glibc 2.0.x headers so that they can be removed properly
2060 # Search only in includedir.
2061 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2062 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2063 then
2064   old_glibc_headers=yes
2065 else
2066   old_glibc_headers=no
2067 fi
2068 AC_MSG_RESULT($old_glibc_headers)
2069 if test ${old_glibc_headers} = yes; then
2070   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2071   AC_MSG_WARN(*** be removed.)
2072 fi
2073 AC_SUBST(old_glibc_headers)
2074
2075 AC_SUBST(libc_cv_slibdir)
2076 AC_SUBST(libc_cv_localedir)
2077 AC_SUBST(libc_cv_sysconfdir)
2078 AC_SUBST(libc_cv_rootsbindir)
2079 AC_SUBST(libc_cv_forced_unwind)
2080
2081 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2082 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2083 AC_SUBST(libc_cv_cc_sse4)
2084 AC_SUBST(libc_cv_cc_avx)
2085 AC_SUBST(libc_cv_cc_sse2avx)
2086 AC_SUBST(libc_cv_cc_novzeroupper)
2087 AC_SUBST(libc_cv_cc_fma4)
2088 AC_SUBST(libc_cv_cc_nofma)
2089 AC_SUBST(libc_cv_as_i686)
2090 AC_SUBST(libc_cv_sparc_as_vis3)
2091
2092 AC_SUBST(use_ldconfig)
2093 AC_SUBST(ldd_rewrite_script)
2094
2095 AC_SUBST(static)
2096 AC_SUBST(shared)
2097
2098 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2099 [libc_cv_pic_default=yes
2100 cat > conftest.c <<EOF
2101 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2102 # error PIC is default.
2103 #endif
2104 EOF
2105 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2106   libc_cv_pic_default=no
2107 fi
2108 rm -f conftest.*])
2109 AC_SUBST(libc_cv_pic_default)
2110
2111 AC_SUBST(profile)
2112 AC_SUBST(static_nss)
2113
2114 AC_SUBST(DEFINES)
2115
2116 dnl See sysdeps/mach/configure.in for this variable.
2117 AC_SUBST(mach_interface_list)
2118
2119 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2120   config_makefile=
2121 else
2122   config_makefile=Makefile
2123 fi
2124
2125 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2126 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2127 AC_SUBST(VERSION)
2128 AC_SUBST(RELEASE)
2129
2130 AC_CONFIG_FILES([config.make ${config_makefile}])
2131 AC_CONFIG_COMMANDS([default],[[
2132 case $CONFIG_FILES in *config.make*)
2133 echo "$config_vars" >> config.make;;
2134 esac
2135 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2136 AC_OUTPUT