configure.in

   1 dnl ** This is a configure script template for BIRD
   2 dnl ** Process it with autoconf to get ./configure
   3 dnl ** (c) 1999--2000 Martin Mares <mj@ucw.cz>
   4
   5 AC_REVISION($Id$)
   6 AC_INIT(conf/confbase.Y)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 AC_ARG_ENABLE(debug,    [  --enable-debug          enable internal debugging routines (default: disabled)],,enable_debug=no)
  10 AC_ARG_ENABLE(memcheck, [  --enable-memcheck       check memory allocations when debugging (default: enabled)],,enable_memcheck=yes)
  11 AC_ARG_ENABLE(client,   [  --enable-client         enable building of BIRD client (default: enabled)],,enable_client=yes)
  12 AC_ARG_ENABLE(ipv6,     [  --enable-ipv6           enable building of IPv6 version (default: disabled)],,enable_ipv6=no)
  13 AC_ARG_ENABLE(pthreads, [  --enable-pthreads       enable POSIX threads support (default: detect)],,enable_pthreads=try)
  14 AC_ARG_WITH(suffix,     [  --with-suffix=STRING    use specified suffix for BIRD files (default: 6 for IPv6 version)],[given_suffix="yes"])
  15 AC_ARG_WITH(sysconfig,  [  --with-sysconfig=FILE   use specified BIRD system configuration file])
  16 AC_ARG_WITH(protocols,  [  --with-protocols=LIST   include specified routing protocols (default: all)],,[with_protocols="all"])
  17 AC_ARG_WITH(sysinclude, [  --with-sysinclude=PATH  search for system includes on specified place])
  18 AC_ARG_WITH(runtimedir, [  --with-runtimedir=PATH  path for runtime files (default: $(localstatedir)/run)],[runtimedir="$with_runtimedir"],[runtimedir="\$(localstatedir)/run"])
  19 AC_ARG_WITH(iproutedir, [  --with-iproutedir=PATH  path to iproute2 config files (default: /etc/iproute2)],[given_iproutedir="yes"])
  20 AC_ARG_VAR([FLEX], [location of the Flex program])
  21 AC_ARG_VAR([BISON], [location of the Bison program])
  22 AC_ARG_VAR([M4], [location of the M4 program])
  23
  24
  25 if test "$srcdir" = . ; then
  26         # Building in current directory => create obj directory holding all objects
  27         objdir=obj
  28         mkdir -p obj
  29         srcdir_rel=..
  30         makefiles="Makefile:tools/Makefile-top.in obj/Makefile:tools/Makefile.in obj/Rules:tools/Rules.in"
  31         exedir=..
  32 else
  33         # Building in separate directory
  34         objdir=.
  35         srcdir_rel=$srcdir
  36         makefiles="Makefile:tools/Makefile.in Rules:tools/Rules.in"
  37         exedir=.
  38 fi
  39 case $srcdir_rel in
  40         /*)     srcdir_rel_mf=$srcdir_rel ;;
  41         *)      srcdir_rel_mf="\$(root-rel)$srcdir_rel" ;;
  42 esac
  43 AC_SUBST(objdir)
  44 AC_SUBST(exedir)
  45 AC_SUBST(srcdir_rel_mf)
  46 AC_SUBST(runtimedir)
  47
  48 if test "$enable_ipv6" = yes ; then
  49         ip=ipv6
  50         SUFFIX=6
  51         proto_radv=radv
  52 else
  53         ip=ipv4
  54         SUFFIX=""
  55 fi
  56
  57 if test "$given_suffix" = yes ; then
  58         SUFFIX="$with_suffix"
  59 fi
  60 AC_SUBST(SUFFIX)
  61
  62 if test "$enable_debug" = yes ; then
  63         CONFIG_FILE="bird$SUFFIX.conf"
  64         CONTROL_SOCKET="bird$SUFFIX.ctl"
  65 else
  66         CONFIG_FILE="\$(sysconfdir)/bird$SUFFIX.conf"
  67         CONTROL_SOCKET="$runtimedir/bird$SUFFIX.ctl"
  68 fi
  69 AC_SUBST(CONFIG_FILE)
  70 AC_SUBST(CONTROL_SOCKET)
  71
  72 AC_SEARCH_LIBS(clock_gettime,[c rt posix4])
  73
  74 AC_CANONICAL_HOST
  75
  76 # Store this value because ac_test_CFLAGS is overwritten by AC_PROG_CC
  77 if test "$ac_test_CFLAGS" != set ; then
  78         bird_cflags_default=yes
  79 fi
  80
  81 AC_PROG_CC
  82 if test -z "$GCC" ; then
  83         AC_MSG_ERROR([This program requires the GNU C Compiler.])
  84 fi
  85
  86 # Enable threads by default just in Linux and FreeBSD
  87 if test "$enable_pthreads" = try ; then
  88         case "$host_os" in
  89                 (linux* | freebsd*)     enable_pthreads=try ;;
  90                 (*)                     enable_pthreads=no ;;
  91         esac
  92 fi
  93
  94 if test "$enable_pthreads" != no ; then
  95         BIRD_CHECK_PTHREADS
  96
  97         if test "$bird_cv_lib_pthreads" = yes ; then
  98                 AC_DEFINE(USE_PTHREADS)
  99                 CFLAGS="$CFLAGS -pthread"
 100                 LDFLAGS="$LDFLAGS -pthread"
 101                 proto_bfd=bfd
 102         elif test "$enable_pthreads" = yes ; then
 103                 AC_MSG_ERROR([POSIX threads not available.])
 104         fi
 105
 106         if test "$enable_pthreads" = try ; then
 107                 enable_pthreads="$bird_cv_lib_pthreads"
 108         fi
 109 fi
 110
 111 if test "$bird_cflags_default" = yes ; then
 112         BIRD_CHECK_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign, -Wall)
 113         BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing)
 114         BIRD_CHECK_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow)
 115
 116         CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -Wno-parentheses"
 117         BIRD_ADD_GCC_OPTION(bird_cv_c_option_wno_pointer_sign, -Wno-pointer-sign)
 118         BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_aliasing, -fno-strict-aliasing)
 119         BIRD_ADD_GCC_OPTION(bird_cv_c_option_fno_strict_overflow, -fno-strict-overflow)
 120 fi
 121 AC_MSG_CHECKING([CFLAGS])
 122 AC_MSG_RESULT($CFLAGS)
 123
 124
 125 AC_PROG_CPP
 126 AC_PROG_INSTALL
 127 AC_PROG_RANLIB
 128 AC_CHECK_PROG(FLEX, flex, flex)
 129 AC_CHECK_PROG(BISON, bison, bison)
 130 AC_CHECK_PROGS(M4, gm4 m4)
 131
 132 test -z "$FLEX"  && AC_MSG_ERROR([Flex is missing.])
 133 test -z "$BISON" && AC_MSG_ERROR([Bison is missing.])
 134 test -z "$M4"    && AC_MSG_ERROR([M4 is missing.])
 135 BIRD_CHECK_PROG_FLAVOR_GNU([$M4], , [AC_MSG_ERROR([Provided M4 is not GNU M4.])])
 136
 137 if test -n "$with_sysconfig" -a "$with_sysconfig" != no ; then
 138         if test -f $with_sysconfig ; then
 139                 sysdesc=$with_sysconfig
 140         else
 141                 sysdesc=$srcdir/sysdep/cf/$with_sysconfig
 142                 if ! test -f $sysdesc ; then
 143                         sysdesc=$sysdesc.h
 144                 fi
 145         fi
 146 elif test -f sysconfig.h ; then
 147         sysdesc=sysconfig
 148 else
 149         case "$ip:$host_os" in
 150                 ipv6:linux*)    sysdesc=linux-v6
 151                                 default_iproutedir="/etc/iproute2"
 152                                 ;;
 153                 ipv4:linux*)    sysdesc=linux
 154                                 default_iproutedir="/etc/iproute2"
 155                                 ;;
 156                 ipv6:netbsd*)   sysdesc=bsd-v6
 157                                 CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 158                                 LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 159                                 ;;
 160                 ipv4:netbsd*)   sysdesc=bsd
 161                                 CPPFLAGS="$CPPFLAGS -I/usr/pkg/include"
 162                                 LDFLAGS="$LDFLAGS -L/usr/pkg/lib -R/usr/pkg/lib"
 163                                 ;;
 164                 ipv6:freebsd*)  sysdesc=bsd-v6
 165                                 ;;
 166                 ipv4:freebsd*)  sysdesc=bsd
 167                                 ;;
 168                 ipv6:dragonfly*)        sysdesc=bsd-v6
 169                                 ;;
 170                 ipv4:dragonfly*)        sysdesc=bsd
 171                                 ;;
 172                 ipv6:kfreebsd*) sysdesc=bsd-v6
 173                                 ;;
 174                 ipv4:kfreebsd*) sysdesc=bsd
 175                                 ;;
 176                 ipv6:openbsd*)  sysdesc=bsd-v6
 177                                 ;;
 178                 ipv4:openbsd*)  sysdesc=bsd
 179                                 ;;
 180                 *)              AC_MSG_ERROR([Cannot determine correct system configuration. Please use --with-sysconfig to set it manually.])
 181                                 ;;
 182                 esac
 183         sysdesc=$srcdir/sysdep/cf/$sysdesc.h
 184 fi
 185 AC_MSG_CHECKING([which OS configuration should we use])
 186 AC_MSG_RESULT($sysdesc)
 187 if ! test -f $sysdesc ; then
 188         AC_MSG_ERROR([The system configuration file is missing.])
 189 fi
 190 sysname=`echo $sysdesc | sed 's/\.h$//'`
 191 AC_DEFINE_UNQUOTED(SYSCONF_INCLUDE, "$sysdesc")
 192
 193 AC_MSG_CHECKING([system-dependent directories])
 194 sysdep_dirs="`sed <$sysdesc '/^Link: /!d;s/^Link: \(.*\)$/\1/' | tr '\012' ' '` lib"
 195 AC_MSG_RESULT($sysdep_dirs)
 196 AC_SUBST(sysdep_dirs)
 197
 198 if test "$with_iproutedir" = no ; then with_iproutedir= ; fi
 199
 200 if test -n "$given_iproutedir"
 201 then iproutedir=$with_iproutedir
 202 else iproutedir=$default_iproutedir
 203 fi
 204
 205 AC_SUBST(iproutedir)
 206
 207 all_protocols="$proto_bfd bgp ospf pipe $proto_radv rip static"
 208 all_protocols=`echo $all_protocols | sed 's/ /,/g'`
 209
 210 if test "$with_protocols" = all ; then
 211         with_protocols="$all_protocols"
 212 fi
 213
 214 AC_MSG_CHECKING([protocols])
 215 protocols=`echo "$with_protocols" | sed 's/,/ /g'`
 216 if test "$protocols" = no ; then protocols= ; fi
 217 for a in $protocols ; do
 218         if ! test -f $srcdir/proto/$a/Makefile ; then
 219                 AC_MSG_RESULT(failed)
 220                 AC_MSG_ERROR([Requested protocol $a not found.])
 221                 fi
 222         AC_DEFINE_UNQUOTED(CONFIG_`echo $a | tr 'a-z' 'A-Z'`)
 223         done
 224 AC_MSG_RESULT(ok)
 225 AC_SUBST(protocols)
 226
 227 case $sysdesc in
 228         */linux*|*/linux-v6*)
 229                 AC_CHECK_HEADER(linux/rtnetlink.h,,[AC_MSG_ERROR([Appropriate version of Linux kernel headers not found.])],[
 230 #include <asm/types.h>
 231 #include <sys/socket.h>
 232 ])
 233                 ;;
 234 esac
 235
 236 AC_CHECK_HEADER(syslog.h, [AC_DEFINE(HAVE_SYSLOG)])
 237 AC_CHECK_HEADER(alloca.h, [AC_DEFINE(HAVE_ALLOCA_H)])
 238 AC_MSG_CHECKING(whether 'struct sockaddr' has sa_len)
 239 AC_TRY_COMPILE([#include <sys/types.h>
 240   #include <sys/socket.h>
 241   ], [static struct sockaddr sa; int i = sizeof(sa.sa_len);],
 242   [AC_MSG_RESULT(yes)
 243   AC_DEFINE(HAVE_SIN_LEN,,sin_len)],
 244   AC_MSG_RESULT(no))
 245
 246 AC_C_BIGENDIAN([AC_DEFINE(CPU_BIG_ENDIAN)], [AC_DEFINE(CPU_LITTLE_ENDIAN)],
 247                  [AC_MSG_ERROR([Cannot determine CPU endianity.])])
 248
 249 BIRD_CHECK_INTEGERS
 250 BIRD_CHECK_STRUCT_ALIGN
 251 BIRD_CHECK_TIME_T
 252 BIRD_CHECK_STRUCT_IP_MREQN
 253
 254 if test "$enable_debug" = yes ; then
 255         AC_DEFINE(DEBUGGING)
 256         if test "$enable_memcheck" = yes ; then
 257                 AC_CHECK_LIB(dmalloc, dmalloc_debug)
 258                 if test $ac_cv_lib_dmalloc_dmalloc_debug != yes ; then
 259                         AC_CHECK_LIB(efence, malloc)
 260                 fi
 261         fi
 262 fi
 263
 264 CLIENT=
 265 CLIENT_LIBS=
 266 if test "$enable_client" = yes ; then
 267         CLIENT=birdc
 268         AC_CHECK_LIB(history, add_history, CLIENT_LIBS="-lhistory")
 269         AC_CHECK_LIB(ncurses, tgetent, USE_TERMCAP_LIB=-lncurses,
 270                 AC_CHECK_LIB(curses, tgetent, USE_TERMCAP_LIB=-lcurses,
 271                         AC_CHECK_LIB(tinfow, tgetent, USE_TERMCAP_LIB=-ltinfow,
 272                                 AC_CHECK_LIB(tinfo, tgetent, USE_TERMCAP_LIB=-ltinfo
 273                                         AC_CHECK_LIB(termcap, tgetent, USE_TERMCAP_LIB=-ltermcap)))))
 274         AC_CHECK_LIB(readline, rl_callback_read_char, CLIENT_LIBS="-lreadline $CLIENT_LIBS $USE_TERMCAP_LIB",
 275                 AC_MSG_ERROR([[The client requires GNU readline library 2.1 or newer. Either install the library or use --disable-client to compile without the client.]]), $USE_TERMCAP_LIB)
 276         AC_CHECK_LIB(readline, rl_crlf, AC_DEFINE(HAVE_RL_CRLF),,$USE_TERMCAP_LIB)
 277         AC_CHECK_LIB(readline, rl_ding, AC_DEFINE(HAVE_RL_DING),,$USE_TERMCAP_LIB)
 278 fi
 279 AC_SUBST(CLIENT)
 280 AC_SUBST(CLIENT_LIBS)
 281
 282 mkdir -p $objdir/sysdep
 283 AC_CONFIG_HEADERS([$objdir/sysdep/autoconf.h:sysdep/autoconf.h.in])
 284 AC_CONFIG_COMMANDS([merge],[[export CPP="$CPP"
 285 $srcdir/tools/mergedirs $srcdir $srcdir_rel $objdir $sysdep_dirs]],
 286         [[srcdir=$srcdir]
 287         [srcdir_rel=$srcdir_rel]
 288         [objdir=$objdir]
 289         [sysdep_dirs="$sysdep_dirs"]])
 290 AC_CONFIG_FILES($makefiles)
 291 AC_OUTPUT
 292
 293 rm -f $objdir/sysdep/paths.h
 294
 295 cat >&AC_FD_MSG <<EOF
 296
 297 BIRD was configured with the following options:
 298         Source directory:       $srcdir
 299         Object directory:       $objdir
 300         Iproute2 directory:     $iproutedir
 301         System configuration:   $sysdesc
 302         Debugging:              $enable_debug
 303         POSIX threads:          $enable_pthreads
 304         Routing protocols:      $protocols
 305         Client:                 $enable_client
 306 EOF
 307 rm -f $objdir/.*-stamp