configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 AC_ARG_ENABLE(static, dnl
  74 [  --enable-static         build static library [default=yes]],
  75               static=$enableval, static=yes)
  76 AC_ARG_ENABLE(shared, dnl
  77 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  78               shared=$enableval, shared=default)
  79 AC_ARG_ENABLE(profile, dnl
  80 [  --enable-profile        build profiled library [default=yes]],
  81               profile=$enableval, profile=yes)
  82 AC_ARG_ENABLE(omitfp, dnl
  83 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  84               omitfp=$enableval, omitfp=no)
  85 AC_ARG_ENABLE(bounded, dnl
  86 [  --enable-bounded        build with runtime bounds checking [default=no]],
  87               bounded=$enableval, bounded=no)
  88 AC_ARG_ENABLE(versioning, dnl
  89 [  --disable-versioning    do not include versioning information in the
  90                           library objects [default=yes if supported]],
  91              enable_versioning=$enableval, enable_versioning=yes)
  92
  93 dnl Generic infrastructure for drop-in additions to libc.
  94 AC_ARG_ENABLE(add-ons, dnl
  95 [  --enable-add-ons[=DIR1,DIR2]...
  96                           configure and build add-ons in DIR1,DIR2,...
  97                           search for add-ons if no parameter given],
  98   [case "$enableval" in
  99     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 100          test "$add_ons" = "*" && add_ons= ;;
 101     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 102    esac],
 103   [add_ons=])
 104
 105 AC_CONFIG_SUBDIRS($add_ons)
 106 add_ons_pfx=
 107 if test x"$add_ons" != x; then
 108   for f in $add_ons; do
 109     # Test whether such a subdir really exists.
 110     if test -d $srcdir/$f; then
 111       add_ons_pfx="$add_ons_pfx $f/"
 112     else
 113       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 114     fi
 115   done
 116 fi
 117
 118 dnl On some platforms we cannot use dynamic loading.  We must provide
 119 dnl static NSS modules.
 120 AC_ARG_ENABLE(static-nss, dnl
 121 [  --enable-static-nss     build static NSS modules [default=no]],
 122               static_nss=$enableval, static_nss=no)
 123 if test x"$static_nss" = xyes; then
 124   AC_DEFINE(DO_STATIC_NSS)
 125 fi
 126
 127 AC_ARG_ENABLE(force-install,
 128 [  --disable-force-install don't force installation of files from this package,
 129                           even if they are older than the installed files],
 130               force_install=$enableval, force_install=yes)
 131 AC_SUBST(force_install)
 132
 133 AC_CANONICAL_HOST
 134
 135 # The way shlib-versions is used to generate soversions.mk uses a
 136 # fairly simplistic model for name recognition that can't distinguish
 137 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 138 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 139 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 140 case "$host_os" in
 141 linux*)
 142   ;;
 143 gnu*)
 144   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 145   ;;
 146 esac
 147
 148 # We keep the original values in `$config_*' and never modify them, so we
 149 # can write them unchanged into config.make.  Everything else uses
 150 # $machine, $vendor, and $os, and changes them whenever convenient.
 151 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 152
 153 # Some configurations imply other options.
 154 case "$host_os" in
 155 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 156   # These systems always use GNU tools.
 157   gnu_ld=yes gnu_as=yes ;;
 158 esac
 159 case "$host_os" in
 160 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 161 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 162   ;;
 163 gnu* | linux* | sysv4* | solaris2* | irix6*)
 164   # These systems (almost) always use the ELF format.
 165   elf=yes
 166   ;;
 167 esac
 168
 169 machine=$config_machine
 170 vendor=$config_vendor
 171 os=$config_os
 172
 173 ###
 174 ### I put this here to prevent those annoying emails from people who cannot
 175 ### read and try to compile glibc on unsupported platforms.  --drepper
 176 ###
 177 ### By using the undocumented --enable-hacker-mode option for configure
 178 ### one can skip this test to make the configuration not fail for unsupported
 179 ### platforms.
 180 ###
 181 if test -z "$enable_hacker_mode"; then
 182   case "$machine-$host_os" in
 183   *-linux* | *-gnu* | arm*-none*)
 184     ;;
 185   *)
 186     echo "*** The GNU C library is currently not available for this platform."
 187     echo "*** So far nobody cared to port it and if there is no volunteer it"
 188     echo "*** might never happen.  So, if you have interest to see glibc on"
 189     echo "*** this platform visit"
 190     echo "***   http://www.gnu.org/software/libc/porting.html"
 191     echo "*** and join the group of porters"
 192     exit 1
 193     ;;
 194   esac
 195 fi
 196
 197 dnl We need to use [ and ] for other purposes for a while now.
 198 changequote(,)dnl
 199 # Expand the configuration machine name into a subdirectory by architecture
 200 # type and particular chip.
 201 case "$machine" in
 202 a29k | am29000) base_machine=a29k machine=a29k ;;
 203 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 204 arm*)           base_machine=arm machine=arm/$machine ;;
 205 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 206 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 207 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 208 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 209 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 210 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 211 m88???)         base_machine=m88k machine=m88k/$machine ;;
 212 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 213 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 214 mips*)          base_machine=mips
 215                 case "`uname -m`" in
 216                 IP22) machine=mips/mips3 ;;
 217                 *)    machine=mips/$machine ,,
 218                 esac ;;
 219 sparc | sparcv[67])
 220                 base_machine=sparc machine=sparc/sparc32 ;;
 221 sparcv8 | supersparc | hypersparc)
 222                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 223 sparc64 | ultrasparc)
 224                 base_machine=sparc machine=sparc/sparc64 ;;
 225 esac
 226 changequote([,])dnl
 227 AC_SUBST(base_machine)
 228
 229 if test "$base_machine" = "i386"; then
 230   AC_DEFINE(USE_REGPARMS)
 231 fi
 232
 233 # Compute the list of sysdep directories for this configuration.
 234 # This can take a while to compute.
 235 sysdep_dir=$srcdir/sysdeps
 236 AC_MSG_CHECKING(sysdep dirs)
 237 dnl We need to use [ and ] for other purposes for a while now.
 238 changequote(,)dnl
 239 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 240 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 241
 242 case "$os" in
 243 gnu*)
 244   base_os=mach/hurd ;;
 245 netbsd* | 386bsd* | freebsd* | bsdi*)
 246   base_os=unix/bsd/bsd4.4 ;;
 247 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 248   base_os=unix/bsd ;;
 249 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 250   base_os=unix/sysv ;;
 251 irix6*)
 252   base_os=unix/sysv/irix6/$os ;;
 253 solaris[2-9]*)
 254   base_os=unix/sysv/sysv4 ;;
 255 none)
 256   base_os=standalone ;;
 257 *)
 258   base_os='' ;;
 259 esac
 260
 261 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 262 tail=$os
 263 ostry=$os
 264 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 265   ostry="$ostry /$o"
 266   tail=$o
 267 done
 268 o=`echo $tail | sed 's/[0-9]*$//'`
 269 if test $o != $tail; then
 270   ostry="$ostry /$o"
 271 fi
 272 # For linux-gnu, try linux-gnu, then linux.
 273 o=`echo $tail | sed 's/-.*$//'`
 274 if test $o != $tail; then
 275   ostry="$ostry /$o"
 276 fi
 277
 278 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 279 base=
 280 tail=$base_os
 281 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 282   set $b
 283   base="$base /$1"
 284   tail="$2"
 285 done
 286
 287 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 288 mach=
 289 tail=$machine
 290 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 291   set $m
 292   # Prepend the machine's FPU directory unless --without-fp.
 293   if test "$with_fp" = yes; then
 294     mach="$mach /$1/fpu"
 295   fi
 296   mach="$mach /$1"
 297   tail="$2"
 298 done
 299
 300 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 301 changequote([,])dnl
 302
 303 # Find what sysdep directories exist.
 304 sysnames=
 305 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 306 for d in $add_ons_pfx ''; do
 307   for b in $base ''; do
 308     for m0 in $mach ''; do
 309       for v in /$vendor ''; do
 310         test "$v" = / && continue
 311         for o in /$ostry ''; do
 312           test "$o" = / && continue
 313           for m in $mach ''; do
 314             if test "$m0$b$v$o$m"; then
 315               try="${d}sysdeps$m0$b$v$o$m"
 316               test -n "$enable_debug_configure" &&
 317               echo "$0 [DEBUG]: try $try" >&2
 318               if test -d $srcdir/$try; then
 319                 sysnames="$sysnames $try"
 320                 { test -n "$o" || test -n "$b"; } && os_used=t
 321                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 322               fi
 323             fi
 324           done
 325         done
 326       done
 327     done
 328   done
 329 done
 330 IFS="$ac_save_ifs"
 331
 332 if test -z "$os_used" && test "$os" != none; then
 333   AC_MSG_ERROR(Operating system $os is not supported.)
 334 fi
 335 if test -z "$machine_used" && test "$machine" != none; then
 336   AC_MSG_ERROR(The $machine is not supported.)
 337 fi
 338
 339 # We have now validated the configuration.
 340
 341
 342 # If using ELF, look for an `elf' subdirectory of each machine directory.
 343 # We prepend these rather than inserting them whereever the machine appears
 344 # because things specified by the machine's ELF ABI should override
 345 # OS-specific things, and should always be the same for any OS on the
 346 # machine (otherwise what's the point of an ABI?).
 347 if test "$elf" = yes; then
 348   elf_dirs=
 349   for d in $add_ons_pfx ''; do
 350     for m in $mach; do
 351       if test -d $srcdir/${d}sysdeps$m/elf; then
 352         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 353       fi
 354     done
 355   done
 356   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 357 fi
 358
 359
 360 # Expand the list of system names into a full list of directories
 361 # from each element's parent name and Implies file (if present).
 362 set $sysnames
 363 names=
 364 while test $# -gt 0; do
 365   name=$1
 366   shift
 367
 368   case " $names " in *" $name "*)
 369     # Already in the list.
 370     continue
 371   esac
 372
 373   # Report each name as we discover it, so there is no long pause in output.
 374   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 375
 376   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 377
 378   case $name in
 379     /*) xsrcdir= ;;
 380     *)  xsrcdir=$srcdir/ ;;
 381   esac
 382   test -n "$enable_debug_configure" &&
 383   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 384
 385   if test -f $xsrcdir$name/Implies; then
 386     # Collect more names from the `Implies' file (removing comments).
 387     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 388     implied=
 389     for x in $implied_candidate; do
 390       if test -d $xsrcdir$name_base/$x; then
 391         implied="$implied $name_base/$x";
 392       else
 393         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 394       fi
 395     done
 396   else
 397     implied=
 398   fi
 399
 400   # Add NAME to the list of names.
 401   names="$names $name"
 402
 403   # Find the parent of NAME, using the empty string if it has none.
 404 changequote(,)dnl
 405   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 406 changequote([,])dnl
 407
 408   # Add the names implied by NAME, and NAME's parent (if it has one), to
 409   # the list of names to be processed (the argument list).  We prepend the
 410   # implied names to the list and append the parent.  We want implied
 411   # directories to come before further directories inferred from the
 412   # configuration components; this ensures that for sysv4, unix/common
 413   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 414   # after sysv4).
 415   sysnames="`echo $implied $* $parent`"
 416   test -n "$sysnames" && set $sysnames
 417 done
 418
 419 # Add the default directories.
 420 default_sysnames=sysdeps/generic
 421 if test "$elf" = yes; then
 422   default_sysnames="sysdeps/generic/elf $default_sysnames"
 423 fi
 424 sysnames="$names $default_sysnames"
 425 AC_SUBST(sysnames)
 426 # The other names were emitted during the scan.
 427 AC_MSG_RESULT($default_sysnames)
 428
 429
 430 ### Locate tools.
 431
 432 AC_PROG_INSTALL
 433 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 434   # The makefiles need to use a different form to find it in $srcdir.
 435   INSTALL='\$(..)./install-sh -c'
 436 fi
 437 AC_PROG_LN_S
 438
 439 # These programs are version sensitive.
 440 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 441 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 442   [version \([egcygnustp-]*[0-9.]*\)],
 443   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|pgcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|cygnus-2.9[1-9].*],
 444   critic_missing=t)
 445 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 446   [version \([0-9][0-9.]*\), by],
 447   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 448
 449 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 450   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 451   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 452 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 453   [GNU texinfo.* \([0-9][0-9.]*\)],
 454   [3.1[1-9] | 3.[2-9][0-9] | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 455
 456 if test -n "$critic_missing"; then
 457 AC_MSG_ERROR([
 458 *** Some critical program is missing or too old.
 459 *** Check the INSTALL file for required versions.])
 460 fi
 461
 462 test -n "$aux_missing" && AC_MSG_WARN([
 463 *** An auxiliary program is missing or too old;
 464 *** some features will be disabled.
 465 *** Check the INSTALL file for required versions.])
 466
 467 AC_PROG_CC_LOCAL
 468 AC_CANONICAL_BUILD
 469 if test $host != $build; then
 470   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 471 fi
 472 AC_SUBST(cross_compiling)
 473 AC_PROG_CPP
 474 LIBC_PROG_BINUTILS
 475 AC_CHECK_TOOL(MIG, mig)
 476
 477 # if using special system headers, find out the compiler's sekrit
 478 # header directory and add that to the list.  NOTE: Only does the right
 479 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 480 if test -n "$sysheaders"; then
 481   ccheaders=`$CC -print-file-name=include`
 482   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 483 fi
 484 AC_SUBST(SYSINCLUDES)
 485
 486 # check if ranlib is necessary
 487 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 488 cat > conftest.c <<EOF
 489 int a;
 490 char b;
 491 void c(void) {}
 492 EOF
 493 $CC $CFLAGS -c conftest.c
 494 $AR cr conftest.a conftest.c
 495 cp conftest.a conftest2.a
 496 $RANLIB conftest.a
 497 if cmp -s conftest.a conftest2.a; then
 498   libc_cv_ranlib_necessary=no
 499 else
 500   libc_cv_ranlib_necessary=yes
 501 fi
 502 rm -rf conftest*])
 503 if test "$libc_cv_ranlib_necessary" = no; then
 504  RANLIB=:
 505 fi
 506
 507 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 508 # since this would lead to problems installing/building glibc.
 509 # LD_LIBRARY_PATH contains the current directory if one of the following
 510 # is true:
 511 # - one of the terminals (":" and ";") is the first or last sign
 512 # - two terminals occur directly after each other
 513 # - the path contains an element with a dot in it
 514 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 515 changequote(,)dnl
 516 case ${LD_LIBRARY_PATH} in
 517   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 518     ld_library_path_setting="contains current directory"
 519     ;;
 520   *)
 521     ld_library_path_setting="ok"
 522     ;;
 523 esac
 524 changequote([,])dnl
 525 AC_MSG_RESULT($ld_library_path_setting)
 526 if test "$ld_library_path_setting" != "ok"; then
 527 AC_MSG_ERROR([
 528 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 529 *** building glibc. Please change the environment variable
 530 *** and run configure again.])
 531 fi
 532
 533 AC_PATH_PROG(BASH, bash, no)
 534 if test "$BASH" != no &&
 535    $BASH -c 'test "$BASH_VERSINFO" \
 536              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 537   libc_cv_have_bash2=yes
 538 else
 539   libc_cv_have_bash2=no
 540 fi
 541 AC_SUBST(libc_cv_have_bash2)
 542
 543 dnl We need a ksh compatible shell for tzselect.
 544 if test "$BASH" = no; then
 545   AC_PATH_PROG(KSH, ksh, no)
 546   if test "$KSH" = no; then
 547     libc_cv_have_ksh=no
 548   else
 549     libc_cv_have_ksh=yes
 550   fi
 551 else
 552   KSH="$BASH"
 553   AC_SUBST(KSH)
 554   libc_cv_have_ksh=yes
 555 fi
 556 AC_SUBST(libc_cv_have_ksh)
 557
 558 AC_PROG_AWK
 559 AC_PATH_PROG(PERL, perl, no)
 560 AC_SUBST(PERL)
 561 dnl This works around a bug in autoconf.
 562 install_info_path=/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin
 563 AC_PATH_PROG(INSTALL_INFO, install-info, no, $install_info_path)
 564 AC_SUBST(INSTALL_INFO)
 565 if test "$INSTALL_INFO" != "no"; then
 566 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 567  [mkdir conftest.d
 568   # There is a hard ^_ on the next line.  I am open to better ideas.
 569   (echo '\1f'
 570   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 571   echo '* Menu:') >conftest.d/dir
 572   (echo 'INFO-DIR-SECTION i-d-s works'
 573   echo 'START-INFO-DIR-ENTRY'
 574   echo '* Prog: (prog).   Program.'
 575   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 576   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 577   then
 578     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 579     then libc_cv_old_debian_install_info=no
 580     else libc_cv_old_debian_install_info=yes
 581     fi
 582   else libc_cv_old_debian_install_info=no testfailed=t
 583   fi
 584   rm -fr conftest.d])
 585 if test -n "$testfailed"
 586 then AC_MSG_WARN([install-info errored out, check config.log])
 587 fi
 588 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 589 fi
 590 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 591
 592 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 593 echo '#include <stddef.h>
 594 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 595 if eval "$ac_cpp conftest.c 2>/dev/null" \
 596 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 597   libc_cv_signed_size_t=no
 598 else
 599   libc_cv_signed_size_t=yes
 600 fi
 601 rm -f conftest*])
 602 if test $libc_cv_signed_size_t = yes; then
 603   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 604   cat >> confdefs.h <<\EOF
 605 #undef __SIZE_TYPE__
 606 #define __SIZE_TYPE__ unsigned
 607 EOF
 608 fi
 609
 610 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 611 AC_TRY_COMPILE(dnl
 612 [#define __need_size_t
 613 #define __need_wchar_t
 614 #include <stddef.h>
 615 #define __need_NULL
 616 #include <stddef.h>], [size_t size; wchar_t wchar;
 617 #ifdef offsetof
 618 #error stddef.h ignored __need_*
 619 #endif
 620 if (&size == NULL || &wchar == NULL) abort ();],
 621                libc_cv_friendly_stddef=yes,
 622                libc_cv_friendly_stddef=no)])
 623 if test $libc_cv_friendly_stddef = yes; then
 624   config_vars="$config_vars
 625 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 626 fi
 627
 628 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 629                libc_cv_need_minus_P, [dnl
 630 cat > conftest.S <<EOF
 631 #include "confdefs.h"
 632 /* Nothing whatsoever.  */
 633 EOF
 634 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 635   libc_cv_need_minus_P=no
 636 else
 637   libc_cv_need_minus_P=yes
 638 fi
 639 rm -f conftest*])
 640 if test $libc_cv_need_minus_P = yes; then
 641   config_vars="$config_vars
 642 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 643 fi
 644
 645 AC_CACHE_CHECK(for assembler global-symbol directive,
 646                libc_cv_asm_global_directive, [dnl
 647 libc_cv_asm_global_directive=UNKNOWN
 648 for ac_globl in .globl .global; do
 649   cat > conftest.s <<EOF
 650 .text
 651 ${ac_globl} foo
 652 foo:
 653 EOF
 654   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 655     libc_cv_asm_global_directive=${ac_globl}
 656   fi
 657   rm -f conftest*
 658   test $libc_cv_asm_global_directive != UNKNOWN && break
 659 done])
 660 if test $libc_cv_asm_global_directive = UNKNOWN; then
 661   AC_MSG_ERROR(cannot determine asm global directive)
 662 else
 663   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 664 fi
 665
 666 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 667 cat > conftest.s <<EOF
 668 .text
 669 foo:
 670 .set glibc_conftest_frobozz,foo
 671 $libc_cv_asm_global_directive glibc_conftest_frobozz
 672 EOF
 673 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 674 # (but it doesn't work), so we must do a linking check to be sure.
 675 cat > conftest1.c <<\EOF
 676 extern int glibc_conftest_frobozz;
 677 main () { printf ("%d\n", glibc_conftest_frobozz); }
 678 EOF
 679 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 680             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 681   libc_cv_asm_set_directive=yes
 682 else
 683   libc_cv_asm_set_directive=no
 684 fi
 685 rm -f conftest*])
 686 if test $libc_cv_asm_set_directive = yes; then
 687   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 688 fi
 689
 690 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 691 [cat > conftest.s <<EOF
 692 .text
 693 _sym:
 694 .symver _sym,sym@VERS
 695 EOF
 696 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 697   libc_cv_asm_symver_directive=yes
 698 else
 699   libc_cv_asm_symver_directive=no
 700 fi
 701 rm -f conftest*])
 702 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 703 if test $libc_cv_asm_symver_directive = yes; then
 704   cat > conftest.s <<EOF
 705 .text
 706 _sym:
 707 .symver _sym,sym@VERS
 708 EOF
 709   cat > conftest.map <<EOF
 710 VERS_1 {
 711         global: sym;
 712 };
 713
 714 VERS_2 {
 715         global: sym;
 716 } VERS_1;
 717 EOF
 718   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 719     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 720                                         -nostartfiles -nostdlib
 721                                         -Wl,--version-script,conftest.map
 722                        1>&AC_FD_CC]);
 723     then
 724       libc_cv_ld_version_script_option=yes
 725     else
 726       libc_cv_ld_version_script_option=no
 727     fi
 728   else
 729     libc_cv_ld_version_script_option=no
 730   fi
 731 else
 732   libc_cv_ld_version_script_option=no
 733 fi
 734 rm -f conftest*])
 735 if test $libc_cv_asm_symver_directive = yes &&
 736    test $libc_cv_ld_version_script_option = yes &&
 737    test $enable_versioning = yes; then
 738   VERSIONING=yes
 739   AC_DEFINE(DO_VERSIONING)
 740 else
 741   VERSIONING=no
 742 fi
 743 AC_SUBST(VERSIONING)
 744
 745 if test $VERSIONING = no; then
 746   echo "\
 747 *** WARNING: You should not compile GNU libc without versioning. Not using
 748 *** versioning will introduce incompatibilities so that old binaries
 749 *** will not run anymore.
 750 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 751 fi
 752 if test $elf = yes; then
 753   AC_CACHE_CHECK(for .previous assembler directive,
 754                  libc_cv_asm_previous_directive, [dnl
 755   cat > conftest.s <<EOF
 756 .section foo_section
 757 .previous
 758 EOF
 759   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 760     libc_cv_asm_previous_directive=yes
 761   else
 762     libc_cv_asm_previous_directive=no
 763   fi
 764   rm -f conftest*])
 765   if test $libc_cv_asm_previous_directive = yes; then
 766     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 767   else
 768     AC_CACHE_CHECK(for .popsection assembler directive,
 769                    libc_cv_asm_popsection_directive, [dnl
 770     cat > conftest.s <<EOF
 771 .pushsection foo_section
 772 .popsection
 773 EOF
 774     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 775       libc_cv_asm_popsection_directive=yes
 776     else
 777       libc_cv_asm_popsection_directive=no
 778     fi
 779     rm -f conftest*])
 780     if test $libc_cv_asm_popsection_directive = yes; then
 781       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 782     fi
 783   fi
 784 fi
 785
 786 if test $elf != yes; then
 787   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 788                  [AC_TRY_COMPILE(, [asm (".section .init");
 789                                     asm (".section .fini");
 790                                     asm (".text");],
 791                                  libc_cv_have_initfini=yes,
 792                                  libc_cv_have_initfini=no)])
 793   AC_SUBST(libc_cv_have_initfini)dnl
 794   if test $libc_cv_have_initfini = yes; then
 795     AC_DEFINE(HAVE_INITFINI)
 796   fi
 797 fi
 798
 799 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 800 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 801 [cat > conftest.$ac_ext <<EOF
 802 dnl This sometimes fails to find confdefs.h, for some reason.
 803 dnl [#]line __oline__ "[$]0"
 804 [#]line __oline__ "configure"
 805 #include "confdefs.h"
 806 void underscore_test(void) {
 807 return; }
 808 EOF
 809 if AC_TRY_EVAL(ac_compile); then
 810   if grep _underscore_test conftest* >/dev/null; then
 811     ifelse([$1], , :, [rm -f conftest*
 812     $1])
 813   else
 814     ifelse([$2], , , [rm -f conftest*
 815     $2])
 816   fi
 817 else
 818   echo "configure: failed program was:" >&AC_FD_CC
 819   cat conftest.$ac_ext >&AC_FD_CC
 820   ifelse([$2], , , [rm -f conftest*
 821   $2])
 822 fi
 823 rm -f conftest*])
 824
 825 if test $elf = yes; then
 826   libc_cv_asm_underscores=no
 827 else
 828   if test $ac_cv_prog_cc_works = yes; then
 829     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 830                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 831                                 libc_cv_asm_underscores=yes,
 832                                 libc_cv_asm_underscores=no)])
 833   else
 834     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 835                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 836                                             libc_cv_asm_underscores=no)])
 837   fi
 838 fi
 839 if test $libc_cv_asm_underscores = no; then
 840   AC_DEFINE(NO_UNDERSCORES)
 841 fi
 842
 843 if test $elf = yes; then
 844   libc_cv_weak_symbols=yes
 845 fi
 846
 847 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 848                  [dnl
 849 cat > conftest.s <<EOF
 850 .text
 851 ${libc_cv_asm_global_directive} foo
 852 foo:
 853 .weak foo
 854 .weak bar; bar = foo
 855 EOF
 856 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 857   libc_cv_asm_weak_directive=yes
 858 else
 859   libc_cv_asm_weak_directive=no
 860 fi
 861 rm -f conftest*])
 862
 863 if test $libc_cv_asm_weak_directive = no; then
 864   AC_CACHE_CHECK(for assembler .weakext directive,
 865                  libc_cv_asm_weakext_directive,
 866                  [dnl
 867 cat > conftest.s <<EOF
 868 .text
 869 ${libc_cv_asm_global_directive} foo
 870 foo:
 871 .weakext bar foo
 872 .weakext baz
 873 ${libc_cv_asm_global_directive} baz
 874 baz:
 875 EOF
 876   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 877     libc_cv_asm_weakext_directive=yes
 878   else
 879     libc_cv_asm_weakext_directive=no
 880   fi
 881   rm -f conftest*])
 882
 883 fi # no .weak
 884
 885 if test $libc_cv_asm_weak_directive = yes; then
 886   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 887 elif test $libc_cv_asm_weakext_directive = yes; then
 888   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 889 fi
 890
 891 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 892 cat > conftest.c <<\EOF
 893 _start () {}
 894 int __eh_pc;
 895 __throw () {}
 896 EOF
 897 dnl No \ in command here because it ends up inside ''.
 898 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 899                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 900                             -o conftest conftest.c 1>&AC_FD_CC]); then
 901   libc_cv_ld_no_whole_archive=yes
 902 else
 903   libc_cv_ld_no_whole_archive=no
 904 fi
 905 rm -f conftest*])
 906 if test $libc_cv_ld_no_whole_archive = yes; then
 907   no_whole_archive=-Wl,--no-whole-archive
 908 fi
 909 AC_SUBST(no_whole_archive)dnl
 910
 911 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 912 cat > conftest.c <<\EOF
 913 _start () {}
 914 int __eh_pc;
 915 __throw () {}
 916 EOF
 917 dnl No \ in command here because it ends up inside ''.
 918 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 919                             -nostdlib -nostartfiles -fexceptions
 920                             -o conftest conftest.c 1>&AC_FD_CC]); then
 921   libc_cv_gcc_exceptions=yes
 922 else
 923   libc_cv_gcc_exceptions=no
 924 fi
 925 rm -f conftest*])
 926 if test $libc_cv_gcc_exceptions = yes; then
 927   exceptions=-fexceptions
 928 fi
 929 AC_SUBST(exceptions)dnl
 930
 931 if test "$base_machine" = alpha ; then
 932 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 933 cat > conftest.c <<\EOF
 934 foo () { }
 935 EOF
 936 dnl
 937 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 938 then
 939   libc_cv_gcc_alpha_ng_prefix=yes
 940 else
 941   libc_cv_gcc_alpha_ng_prefix=no
 942 fi
 943 rm -f conftest* ])
 944 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 945   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 946 else
 947   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 948 fi
 949 fi
 950
 951 if test "$host_cpu" = powerpc ; then
 952 # Check for a bug present in at least versions 2.8.x of GCC
 953 # and versions 1.0.x of EGCS.
 954 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 955 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 956                libc_cv_c_asmcr0_bug='no',
 957                libc_cv_c_asmcr0_bug='yes')])
 958 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 959   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 960 fi
 961 fi
 962
 963 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 964 [cat > conftest.c <<EOF
 965 #line __oline__ "configure"
 966 static char __EH_FRAME_BEGIN__[];
 967 _start ()
 968 {
 969 #ifdef CHECK__register_frame
 970   __register_frame (__EH_FRAME_BEGIN__);
 971   __deregister_frame (__EH_FRAME_BEGIN__);
 972 #endif
 973 #ifdef CHECK__register_frame_info
 974   __register_frame_info (__EH_FRAME_BEGIN__);
 975   __deregister_frame_info (__EH_FRAME_BEGIN__);
 976 #endif
 977 }
 978 int __eh_pc;
 979 __throw () {}
 980 /* FIXME: this is fragile.  */
 981 malloc () {}
 982 strcmp () {}
 983 strlen () {}
 984 memcpy () {}
 985 memset () {}
 986 free () {}
 987 abort () {}
 988 __bzero () {}
 989 EOF
 990 dnl No \ in command here because it ends up inside ''.
 991 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 992                             -nostdlib -nostartfiles
 993                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 994   libc_cv_gcc_dwarf2_unwind_info=static
 995 else
 996   libc_cv_gcc_dwarf2_unwind_info=no
 997 fi
 998 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 999   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1000                               -nostdlib -nostartfiles
1001                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1002     libc_cv_gcc_dwarf2_unwind_info=yes
1003   else
1004     libc_cv_gcc_dwarf2_unwind_info=no
1005   fi
1006 fi
1007 rm -f conftest*])
1008 case $libc_cv_gcc_dwarf2_unwind_info in
1009 yes)
1010   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1011   ;;
1012 static)
1013   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1014   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1015   ;;
1016 esac
1017
1018 dnl Check whether compiler understands __builtin_expect.
1019 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1020 [cat > conftest.c <<EOF
1021 #line __oline__ "configure"
1022 int foo (int a)
1023 {
1024   a = __builtin_expect (a, 10);
1025   return a == 10 ? 0 : 1;
1026 }
1027 EOF
1028 dnl No \ in command here because it ends up inside ''.
1029 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1030                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1031   libc_cv_gcc_builtin_expect=yes
1032 else
1033   libc_cv_gcc_builtin_expect=no
1034 fi
1035 rm -f conftest*])
1036 if test "$libc_cv_gcc_builtin_expect" = yes; then
1037   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1038 fi
1039
1040 ### End of automated tests.
1041 ### Now run sysdeps configure fragments.
1042
1043 # sysdeps configure fragments may set these with files to be linked below.
1044 libc_link_dests=
1045 libc_link_sources=
1046
1047 # They also can set these variables.
1048 ldd_rewrite_script=no
1049
1050 # Iterate over all the sysdep directories we will use, running their
1051 # configure fragments, and looking for a uname implementation.
1052 uname=
1053 for dir in $sysnames; do
1054   case $dir in
1055     /*) dest=$dir ;;
1056     *)  dest=$srcdir/$dir ;;
1057   esac
1058   if test -r $dest/configure; then
1059     AC_MSG_RESULT(running configure fragment for $dest)
1060     . $dest/configure
1061   fi
1062 [
1063   if test -z "$uname"; then
1064     if test -r $dest/uname.c ||
1065        test -r $dest/uname.S ||
1066        { test -r $dest/syscalls.list &&
1067          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1068       uname=$dir
1069     fi
1070   fi
1071 ]dnl
1072 done
1073
1074 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1075
1076 # If we will use the generic uname implementation, we must figure out what
1077 # it will say by examining the system, and write the results in config-name.h.
1078 if test "$uname" = "sysdeps/generic"; then
1079
1080 changequote(,)dnl
1081   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1082 changequote([,])dnl
1083   if test $uname_sysname != $config_os; then
1084     config_release=`echo $config_os | sed s/$uname_sysname//`
1085   fi
1086 dnl
1087 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1088     if test -r /vmunix; then
1089       kernel_id=`strings /vmunix | grep UNIX`
1090     elif test -r /dynix; then
1091       kernel_id=`strings /dynix | grep DYNIX`
1092     else
1093       kernel_id=
1094     fi
1095 ])dnl
1096
1097   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1098 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1099 changequote(,)dnl
1100   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1101 changequote([,])dnl
1102   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1103          != x$config_release; then
1104     # The configuration release is a substring of the kernel release.
1105     libc_cv_uname_release=$kernel_release
1106   elif test x$config_release != x; then
1107     libc_cv_uname_release=$config_release
1108   elif test x$kernel_release != x; then
1109     libc_cv_uname_release=$kernel_release
1110   else
1111     libc_cv_uname_release=unknown
1112   fi])
1113   uname_release="$libc_cv_uname_release"
1114
1115   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1116 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1117 changequote(,)dnl
1118   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1119 changequote([,])dnl
1120   if test -n "$kernel_version"; then
1121     libc_cv_uname_version="$kernel_version"
1122   else
1123     libc_cv_uname_version=unknown
1124   fi])
1125   uname_version="$libc_cv_uname_version"
1126
1127 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1128   config_uname=config-name.h:config-name.in
1129 else
1130   # For non-generic uname, we don't need to create config-name.h at all.
1131   config_uname=
1132 fi
1133
1134 AC_MSG_CHECKING(stdio selection)
1135 AC_SUBST(stdio)
1136 case $stdio in
1137 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1138 default) stdio=stdio ;;
1139 esac
1140 AC_MSG_RESULT($stdio)
1141
1142 # Test for old glibc 2.0.x headers so that they can be removed properly
1143 # Search only in includedir.
1144 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1145 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1146 then
1147   old_glibc_headers=yes
1148 else
1149   old_glibc_headers=no
1150 fi
1151 AC_MSG_RESULT($old_glibc_headers)
1152 if test ${old_glibc_headers} = yes; then
1153   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1154   AC_MSG_WARN(*** be removed.)
1155 fi
1156 AC_SUBST(old_glibc_headers)
1157
1158 AC_SUBST(libc_cv_slibdir)
1159 AC_SUBST(libc_cv_sysconfdir)
1160 AC_SUBST(libc_cv_rootsbindir)
1161
1162 AC_SUBST(has_ldconfig)
1163 AC_SUBST(ldd_rewrite_script)
1164
1165 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1166 if test $gnu_ld = yes; then
1167   AC_DEFINE(HAVE_GNU_LD)
1168 fi
1169 if test $gnu_as = yes; then
1170   AC_DEFINE(HAVE_GNU_AS)
1171 fi
1172 if test $elf = yes; then
1173   AC_DEFINE(HAVE_ELF)
1174 fi
1175
1176 AC_SUBST(static)
1177 AC_SUBST(shared)
1178 if test $shared = default; then
1179   if test $gnu_ld = yes; then
1180     shared=$elf
1181   else
1182     # For now we do not assume shared libs are available.  In future more
1183     # tests might become available.
1184     shared=no
1185   fi
1186 fi
1187
1188 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1189 [pic_default=yes
1190 cat > conftest.c <<EOF
1191 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1192 # error PIC is default.
1193 #endif
1194 EOF
1195 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1196   pic_default=no
1197 fi
1198 rm -f conftest.*])
1199 AC_SUBST(pic_default)
1200
1201 AC_SUBST(profile)
1202 AC_SUBST(omitfp)
1203 AC_SUBST(bounded)
1204 AC_SUBST(static_nss)
1205 AC_SUBST(nopic_initfini)
1206
1207 AC_SUBST(DEFINES)
1208
1209 case "$add_ons" in
1210   *door*) linux_doors=yes ;;
1211   *) linux_doors=no ;;
1212 esac
1213 AC_SUBST(linux_doors)
1214
1215 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1216   config_makefile=
1217 else
1218   config_makefile=Makefile
1219 fi
1220
1221 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1222 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1223 AC_SUBST(VERSION)
1224 AC_SUBST(RELEASE)
1225
1226 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1227 case $CONFIG_FILES in *config.make*)
1228 echo "$config_vars" >> config.make;;
1229 esac
1230 test -d bits || mkdir bits], [config_vars='$config_vars'])