gcc/aclocal.m4

   1 dnl See whether we can include both string.h and strings.h.
   2 AC_DEFUN(gcc_AC_HEADER_STRING,
   3 [AC_CACHE_CHECK([whether string.h and strings.h may both be included],
   4   gcc_cv_header_string,
   5 [AC_TRY_COMPILE([#include <string.h>
   6 #include <strings.h>], , gcc_cv_header_string=yes, gcc_cv_header_string=no)])
   7 if test $gcc_cv_header_string = yes; then
   8   AC_DEFINE(STRING_WITH_STRINGS, 1, [Define if you can safely include both <string.h> and <strings.h>.])
   9 fi
  10 ])
  11
  12 dnl See whether we need a declaration for a function.
  13 dnl The result is highly dependent on the INCLUDES passed in, so make sure
  14 dnl to use a different cache variable name in this macro if it is invoked
  15 dnl in a different context somewhere else.
  16 dnl gcc_AC_CHECK_DECL(SYMBOL,
  17 dnl     [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]])
  18 AC_DEFUN(gcc_AC_CHECK_DECL,
  19 [AC_MSG_CHECKING([whether $1 is declared])
  20 AC_CACHE_VAL(gcc_cv_have_decl_$1,
  21 [AC_TRY_COMPILE([$4],
  22 [#ifndef $1
  23 char *(*pfn) = (char *(*)) $1 ;
  24 #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")])
  25 if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then
  26   AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2])
  27 else
  28   AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3])
  29 fi
  30 ])dnl
  31
  32 dnl Check multiple functions to see whether each needs a declaration.
  33 dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate.
  34 dnl gcc_AC_CHECK_DECLS(SYMBOLS,
  35 dnl     [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]])
  36 AC_DEFUN(gcc_AC_CHECK_DECLS,
  37 [for ac_func in $1
  38 do
  39 changequote(, )dnl
  40   ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
  41 changequote([, ])dnl
  42 gcc_AC_CHECK_DECL($ac_func,
  43   [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2],
  44   [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3],
  45   $4
  46 )
  47 done
  48 dnl Automatically generate config.h entries via autoheader.
  49 if test x = y ; then
  50   patsubst(translit([$1], [a-z], [A-Z]), [\w+],
  51     AC_DEFINE([HAVE_DECL_\&], 1,
  52       [Define to 1 if we found this declaration otherwise define to 0.]))dnl
  53 fi
  54 ])
  55
  56 dnl Check if we have vprintf and possibly _doprnt.
  57 dnl Note autoconf checks for vprintf even though we care about vfprintf.
  58 AC_DEFUN(gcc_AC_FUNC_VFPRINTF_DOPRNT,
  59 [AC_FUNC_VPRINTF
  60 vfprintf=
  61 doprint=
  62 if test $ac_cv_func_vprintf != yes ; then
  63   vfprintf=vfprintf.o
  64   if test $ac_cv_func__doprnt != yes ; then
  65     doprint=doprint.o
  66   fi
  67 fi
  68 AC_SUBST(vfprintf)
  69 AC_SUBST(doprint)
  70 ])
  71
  72 dnl See if the printf functions in libc support %p in format strings.
  73 AC_DEFUN(gcc_AC_FUNC_PRINTF_PTR,
  74 [AC_CACHE_CHECK(whether the printf functions support %p,
  75   gcc_cv_func_printf_ptr,
  76 [AC_TRY_RUN([#include <stdio.h>
  77
  78 int main()
  79 {
  80   char buf[64];
  81   char *p = buf, *q = NULL;
  82   sprintf(buf, "%p", p);
  83   sscanf(buf, "%p", &q);
  84   return (p != q);
  85 }], gcc_cv_func_printf_ptr=yes, gcc_cv_func_printf_ptr=no,
  86         gcc_cv_func_printf_ptr=no)
  87 rm -f core core.* *.core])
  88 if test $gcc_cv_func_printf_ptr = yes ; then
  89   AC_DEFINE(HAVE_PRINTF_PTR, 1, [Define if printf supports "%p".])
  90 fi
  91 ])
  92
  93 dnl See if symbolic links work and if not, try to substitute either hard links or simple copy.
  94 AC_DEFUN(gcc_AC_PROG_LN_S,
  95 [AC_MSG_CHECKING(whether ln -s works)
  96 AC_CACHE_VAL(gcc_cv_prog_LN_S,
  97 [rm -f conftestdata_t
  98 echo >conftestdata_f
  99 if ln -s conftestdata_f conftestdata_t 2>/dev/null
 100 then
 101   gcc_cv_prog_LN_S="ln -s"
 102 else
 103   if ln conftestdata_f conftestdata_t 2>/dev/null
 104   then
 105     gcc_cv_prog_LN_S=ln
 106   else
 107     gcc_cv_prog_LN_S=cp
 108   fi
 109 fi
 110 rm -f conftestdata_f conftestdata_t
 111 ])dnl
 112 LN_S="$gcc_cv_prog_LN_S"
 113 if test "$gcc_cv_prog_LN_S" = "ln -s"; then
 114   AC_MSG_RESULT(yes)
 115 else
 116   if test "$gcc_cv_prog_LN_S" = "ln"; then
 117     AC_MSG_RESULT([no, using ln])
 118   else
 119     AC_MSG_RESULT([no, and neither does ln, so using cp])
 120   fi
 121 fi
 122 AC_SUBST(LN_S)dnl
 123 ])
 124
 125 dnl See if hard links work and if not, try to substitute either symbolic links or simple copy.
 126 AC_DEFUN(gcc_AC_PROG_LN,
 127 [AC_MSG_CHECKING(whether ln works)
 128 AC_CACHE_VAL(gcc_cv_prog_LN,
 129 [rm -f conftestdata_t
 130 echo >conftestdata_f
 131 if ln conftestdata_f conftestdata_t 2>/dev/null
 132 then
 133   gcc_cv_prog_LN="ln"
 134 else
 135   if ln -s conftestdata_f conftestdata_t 2>/dev/null
 136   then
 137     gcc_cv_prog_LN="ln -s"
 138   else
 139     gcc_cv_prog_LN=cp
 140   fi
 141 fi
 142 rm -f conftestdata_f conftestdata_t
 143 ])dnl
 144 LN="$gcc_cv_prog_LN"
 145 if test "$gcc_cv_prog_LN" = "ln"; then
 146   AC_MSG_RESULT(yes)
 147 else
 148   if test "$gcc_cv_prog_LN" = "ln -s"; then
 149     AC_MSG_RESULT([no, using ln -s])
 150   else
 151     AC_MSG_RESULT([no, and neither does ln -s, so using cp])
 152   fi
 153 fi
 154 AC_SUBST(LN)dnl
 155 ])
 156
 157 dnl See whether the stage1 host compiler accepts the volatile keyword.
 158 AC_DEFUN(gcc_AC_C_VOLATILE,
 159 [AC_CACHE_CHECK([for volatile], gcc_cv_c_volatile,
 160 [AC_TRY_COMPILE(, [volatile int foo;],
 161         gcc_cv_c_volatile=yes, gcc_cv_c_volatile=no)])
 162 if test $gcc_cv_c_volatile = yes ; then
 163   AC_DEFINE(HAVE_VOLATILE, 1, [Define if your compiler understands volatile.])
 164 fi
 165 ])
 166
 167 dnl Check whether long double is supported.  This differs from the
 168 dnl built-in autoconf test in that it works for cross compiles.
 169 AC_DEFUN(gcc_AC_C_LONG_DOUBLE,
 170 [AC_CACHE_CHECK(for long double, gcc_cv_c_long_double,
 171 [if test "$GCC" = yes; then
 172   gcc_cv_c_long_double=yes
 173 else
 174 AC_TRY_COMPILE(,
 175 [/* The Stardent Vistra knows sizeof(long double), but does not support it.  */
 176 long double foo = 0.0;
 177 /* On Ultrix 4.3 cc, long double is 4 and double is 8.  */
 178 switch (0) case 0: case (sizeof(long double) >= sizeof(double)):;],
 179 gcc_cv_c_long_double=yes, gcc_cv_c_long_double=no)
 180 fi])
 181 if test $gcc_cv_c_long_double = yes; then
 182   AC_DEFINE(HAVE_LONG_DOUBLE)
 183 fi
 184 ])
 185
 186 dnl Define MKDIR_TAKES_ONE_ARG if mkdir accepts only one argument instead
 187 dnl of the usual 2.
 188 AC_DEFUN(gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG,
 189 [AC_CACHE_CHECK([if mkdir takes one argument], gcc_cv_mkdir_takes_one_arg,
 190 [AC_TRY_COMPILE([
 191 #include <sys/types.h>
 192 #ifdef HAVE_SYS_STAT_H
 193 # include <sys/stat.h>
 194 #endif
 195 #ifdef HAVE_UNISTD_H
 196 # include <unistd.h>
 197 #endif
 198 #ifdef HAVE_DIRECT_H
 199 # include <direct.h>
 200 #endif], [mkdir ("foo", 0);],
 201         gcc_cv_mkdir_takes_one_arg=no, gcc_cv_mkdir_takes_one_arg=yes)])
 202 if test $gcc_cv_mkdir_takes_one_arg = yes ; then
 203   AC_DEFINE(MKDIR_TAKES_ONE_ARG, 1, [Define if host mkdir takes a single argument.])
 204 fi
 205 ])
 206
 207 AC_DEFUN(gcc_AC_PROG_INSTALL,
 208 [AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT])dnl
 209 # Find a good install program.  We prefer a C program (faster),
 210 # so one script is as good as another.  But avoid the broken or
 211 # incompatible versions:
 212 # SysV /etc/install, /usr/sbin/install
 213 # SunOS /usr/etc/install
 214 # IRIX /sbin/install
 215 # AIX /bin/install
 216 # AFS /usr/afsws/bin/install, which mishandles nonexistent args
 217 # SVR4 /usr/ucb/install, which tries to use the nonexistent group "staff"
 218 # ./install, which can be erroneously created by make from ./install.sh.
 219 AC_MSG_CHECKING(for a BSD compatible install)
 220 if test -z "$INSTALL"; then
 221 AC_CACHE_VAL(ac_cv_path_install,
 222 [  IFS="${IFS=  }"; ac_save_IFS="$IFS"; IFS="${IFS}:"
 223   for ac_dir in $PATH; do
 224     # Account for people who put trailing slashes in PATH elements.
 225     case "$ac_dir/" in
 226     /|./|.//|/etc/*|/usr/sbin/*|/usr/etc/*|/sbin/*|/usr/afsws/bin/*|/usr/ucb/*) ;;
 227     *)
 228       # OSF1 and SCO ODT 3.0 have their own names for install.
 229       for ac_prog in ginstall scoinst install; do
 230         if test -f $ac_dir/$ac_prog; then
 231           if test $ac_prog = install &&
 232             grep dspmsg $ac_dir/$ac_prog >/dev/null 2>&1; then
 233             # AIX install.  It has an incompatible calling convention.
 234             # OSF/1 installbsd also uses dspmsg, but is usable.
 235             :
 236           else
 237             ac_cv_path_install="$ac_dir/$ac_prog -c"
 238             break 2
 239           fi
 240         fi
 241       done
 242       ;;
 243     esac
 244   done
 245   IFS="$ac_save_IFS"
 246 ])dnl
 247   if test "${ac_cv_path_install+set}" = set; then
 248     INSTALL="$ac_cv_path_install"
 249   else
 250     # As a last resort, use the slow shell script.  We don't cache a
 251     # path for INSTALL within a source directory, because that will
 252     # break other packages using the cache if that directory is
 253     # removed, or if the path is relative.
 254     INSTALL="$ac_install_sh"
 255   fi
 256 fi
 257 dnl We do special magic for INSTALL instead of AC_SUBST, to get
 258 dnl relative paths right.
 259 AC_MSG_RESULT($INSTALL)
 260 AC_SUBST(INSTALL)dnl
 261
 262 # Use test -z because SunOS4 sh mishandles braces in ${var-val}.
 263 # It thinks the first close brace ends the variable substitution.
 264 test -z "$INSTALL_PROGRAM" && INSTALL_PROGRAM='${INSTALL}'
 265 AC_SUBST(INSTALL_PROGRAM)dnl
 266
 267 test -z "$INSTALL_DATA" && INSTALL_DATA='${INSTALL} -m 644'
 268 AC_SUBST(INSTALL_DATA)dnl
 269 ])
 270
 271 #serial 1
 272 dnl This test replaces the one in autoconf.
 273 dnl Currently this macro should have the same name as the autoconf macro
 274 dnl because gettext's gettext.m4 (distributed in the automake package)
 275 dnl still uses it.  Otherwise, the use in gettext.m4 makes autoheader
 276 dnl give these diagnostics:
 277 dnl   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
 278 dnl   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
 279
 280 undefine([AC_ISC_POSIX])
 281 AC_DEFUN(AC_ISC_POSIX,
 282   [
 283     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
 284     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
 285   ]
 286 )
 287
 288 # Macro to add for using GNU gettext.
 289 # Ulrich Drepper <drepper@cygnus.com>, 1995.
 290 #
 291 # This file can be copied and used freely without restrictions.  It can
 292 # be used in projects which are not available under the GNU Public License
 293 # but which still want to provide support for the GNU gettext functionality.
 294 # Please note that the actual code is *not* freely available.
 295
 296 # serial 5
 297
 298 AC_DEFUN(AM_WITH_NLS,
 299   [AC_MSG_CHECKING([whether NLS is requested])
 300     dnl Default is enabled NLS
 301     AC_ARG_ENABLE(nls,
 302       [  --disable-nls           do not use Native Language Support],
 303       USE_NLS=$enableval, USE_NLS=yes)
 304     AC_MSG_RESULT($USE_NLS)
 305     AC_SUBST(USE_NLS)
 306
 307     USE_INCLUDED_LIBINTL=no
 308
 309     dnl If we use NLS figure out what method
 310     if test "$USE_NLS" = "yes"; then
 311       AC_DEFINE(ENABLE_NLS)
 312       AC_MSG_CHECKING([whether included gettext is requested])
 313       AC_ARG_WITH(included-gettext,
 314         [  --with-included-gettext use the GNU gettext library included here],
 315         nls_cv_force_use_gnu_gettext=$withval,
 316         nls_cv_force_use_gnu_gettext=yes)
 317       AC_MSG_RESULT($nls_cv_force_use_gnu_gettext)
 318
 319       nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext"
 320       if test "$nls_cv_force_use_gnu_gettext" != "yes"; then
 321         dnl User does not insist on using GNU NLS library.  Figure out what
 322         dnl to use.  If gettext or catgets are available (in this order) we
 323         dnl use this.  Else we have to fall back to GNU NLS library.
 324         dnl catgets is only used if permitted by option --with-catgets.
 325         nls_cv_header_intl=
 326         nls_cv_header_libgt=
 327         CATOBJEXT=NONE
 328
 329         AC_CHECK_HEADER(libintl.h,
 330           [AC_CACHE_CHECK([for gettext in libc], gt_cv_func_gettext_libc,
 331             [AC_TRY_LINK([#include <libintl.h>], [return (int) gettext ("")],
 332                gt_cv_func_gettext_libc=yes, gt_cv_func_gettext_libc=no)])
 333
 334            if test "$gt_cv_func_gettext_libc" != "yes"; then
 335              AC_CHECK_LIB(intl, bindtextdomain,
 336                [AC_CACHE_CHECK([for gettext in libintl],
 337                  gt_cv_func_gettext_libintl,
 338                  [AC_CHECK_LIB(intl, gettext,
 339                   gt_cv_func_gettext_libintl=yes,
 340                   gt_cv_func_gettext_libintl=no)],
 341                  gt_cv_func_gettext_libintl=no)])
 342            fi
 343
 344            if test "$gt_cv_func_gettext_libc" = "yes" \
 345               || test "$gt_cv_func_gettext_libintl" = "yes"; then
 346               AC_DEFINE(HAVE_GETTEXT)
 347               AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
 348                 [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)dnl
 349               if test "$MSGFMT" != "no"; then
 350                 AC_CHECK_FUNCS(dcgettext)
 351                 AC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)
 352                 AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
 353                   [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
 354                 AC_TRY_LINK(, [extern int _nl_msg_cat_cntr;
 355                                return _nl_msg_cat_cntr],
 356                   [CATOBJEXT=.gmo
 357                    DATADIRNAME=share],
 358                   [CATOBJEXT=.mo
 359                    DATADIRNAME=lib])
 360                 INSTOBJEXT=.mo
 361               fi
 362             fi
 363         ])
 364
 365         if test "$CATOBJEXT" = "NONE"; then
 366           AC_MSG_CHECKING([whether catgets can be used])
 367           AC_ARG_WITH(catgets,
 368             [  --with-catgets          use catgets functions if available],
 369             nls_cv_use_catgets=$withval, nls_cv_use_catgets=no)
 370           AC_MSG_RESULT($nls_cv_use_catgets)
 371
 372           if test "$nls_cv_use_catgets" = "yes"; then
 373             dnl No gettext in C library.  Try catgets next.
 374             AC_CHECK_LIB(i, main)
 375             AC_CHECK_FUNC(catgets,
 376               [AC_DEFINE(HAVE_CATGETS)
 377                INTLOBJS="\$(CATOBJS)"
 378                AC_PATH_PROG(GENCAT, gencat, no)dnl
 379                if test "$GENCAT" != "no"; then
 380                  AC_PATH_PROG(GMSGFMT, gmsgfmt, no)
 381                  if test "$GMSGFMT" = "no"; then
 382                    AM_PATH_PROG_WITH_TEST(GMSGFMT, msgfmt,
 383                     [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)
 384                    if test "$GMSGFMT" = "no"; then
 385                      AC_MSG_WARN(No program for catalog building found, so disabling building them)
 386                      create_catalogs="no"
 387                    fi
 388                  fi
 389                  AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
 390                    [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
 391                  USE_INCLUDED_LIBINTL=yes
 392                  CATOBJEXT=.cat
 393                  INSTOBJEXT=.cat
 394                  DATADIRNAME=lib
 395                  INTLDEPS='$(top_builddir)/intl/libintl.a'
 396                  INTLLIBS=$INTLDEPS
 397                  LIBS=`echo $LIBS | sed -e 's/-lintl//'`
 398                  nls_cv_header_intl=intl/libintl.h
 399                  nls_cv_header_libgt=intl/libgettext.h
 400                fi])
 401           fi
 402         fi
 403
 404         if test "$CATOBJEXT" = "NONE"; then
 405           dnl Neither gettext nor catgets in included in the C library.
 406           dnl Fall back on GNU gettext library.
 407           nls_cv_use_gnu_gettext=yes
 408         fi
 409       fi
 410
 411       if test "$nls_cv_use_gnu_gettext" = "yes"; then
 412         dnl Mark actions used to generate GNU NLS library.
 413         INTLOBJS="\$(GETTOBJS)"
 414         AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt,
 415           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep 'dv '`"], no)
 416         AC_PATH_PROG(GMSGFMT, gmsgfmt, no)
 417
 418         dnl If we didn't find either msgfmt or gmsgfmt, don't try to
 419         dnl create a catalog.
 420         if test "$MSGFMT" = "no" && test "$GMSGFMT" = "no"; then
 421           AC_MSG_WARN(Neither msgfmt nor gmsgfmt found. No catalogs will be built)
 422           create_catalogs="no"
 423           MSGFMT=msgfmt
 424           GMSGFMT=msgfmt
 425         fi
 426         AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext,
 427           [test -z "`$ac_dir/$ac_word -h 2>&1 | grep '(HELP)'`"], :)
 428         AC_SUBST(MSGFMT)
 429         USE_INCLUDED_LIBINTL=yes
 430         CATOBJEXT=.gmo
 431         INSTOBJEXT=.mo
 432         DATADIRNAME=share
 433         INTLDEPS='$(top_builddir)/intl/libintl.a'
 434         INTLLIBS=$INTLDEPS
 435         LIBS=`echo $LIBS | sed -e 's/-lintl//'`
 436         nls_cv_header_intl=intl/libintl.h
 437         nls_cv_header_libgt=intl/libgettext.h
 438       fi
 439
 440       dnl Test whether we really found GNU xgettext.
 441       if test "$XGETTEXT" != ":"; then
 442         dnl If it is no GNU xgettext we define it as : so that the
 443         dnl Makefiles still can work.
 444         if $XGETTEXT --omit-header /dev/null 2> /dev/null; then
 445           : ;
 446         else
 447           AC_MSG_RESULT(
 448             [found xgettext program is not GNU xgettext; ignore it])
 449           XGETTEXT=":"
 450         fi
 451       fi
 452
 453
 454
 455       # We need to process the po/ directory.
 456       POSUB=po
 457     else
 458       DATADIRNAME=share
 459       nls_cv_header_intl=intl/libintl.h
 460       nls_cv_header_libgt=intl/libgettext.h
 461     fi
 462     AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
 463     AC_OUTPUT_COMMANDS(
 464      [case "$CONFIG_FILES" in *po/Makefile.in*)
 465         sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile
 466       esac])
 467
 468
 469     # If this is used in GNU gettext we have to set USE_NLS to `yes'
 470     # because some of the sources are only built for this goal.
 471     if test "$PACKAGE" = gettext; then
 472       USE_NLS=yes
 473       USE_INCLUDED_LIBINTL=yes
 474     fi
 475
 476     dnl These rules are solely for the distribution goal.  While doing this
 477     dnl we only have to keep exactly one list of the available catalogs
 478     dnl in configure.in.
 479     for lang in $ALL_LINGUAS; do
 480       GMOFILES="$GMOFILES $lang.gmo"
 481       POFILES="$POFILES $lang.po"
 482     done
 483
 484     dnl Make all variables we use known to autoconf.
 485     AC_SUBST(USE_INCLUDED_LIBINTL)
 486     AC_SUBST(CATALOGS)
 487     AC_SUBST(CATOBJEXT)
 488     AC_SUBST(DATADIRNAME)
 489     AC_SUBST(GMOFILES)
 490     AC_SUBST(INSTOBJEXT)
 491     AC_SUBST(INTLDEPS)
 492     AC_SUBST(INTLLIBS)
 493     AC_SUBST(INTLOBJS)
 494     AC_SUBST(POFILES)
 495     AC_SUBST(POSUB)
 496   ])
 497
 498 AC_DEFUN(AM_GNU_GETTEXT,
 499   [AC_REQUIRE([AC_PROG_MAKE_SET])dnl
 500    AC_REQUIRE([AC_PROG_CC])dnl
 501    AC_REQUIRE([AC_PROG_RANLIB])dnl
 502    AC_REQUIRE([AC_ISC_POSIX])dnl
 503    AC_REQUIRE([AC_HEADER_STDC])dnl
 504    AC_REQUIRE([AC_C_CONST])dnl
 505    AC_REQUIRE([AC_C_INLINE])dnl
 506    AC_REQUIRE([AC_TYPE_OFF_T])dnl
 507    AC_REQUIRE([AC_TYPE_SIZE_T])dnl
 508    AC_REQUIRE([AC_FUNC_ALLOCA])dnl
 509
 510    AC_CHECK_HEADERS([argz.h limits.h locale.h nl_types.h malloc.h string.h \
 511 unistd.h sys/param.h])
 512    AC_CHECK_FUNCS([getcwd munmap putenv setenv setlocale strchr strcasecmp \
 513 strdup __argz_count __argz_stringify __argz_next])
 514
 515    if test "${ac_cv_func_stpcpy+set}" != "set"; then
 516      AC_CHECK_FUNCS(stpcpy)
 517    fi
 518    if test "${ac_cv_func_stpcpy}" = "yes"; then
 519      AC_DEFINE(HAVE_STPCPY)
 520    fi
 521
 522    AM_LC_MESSAGES
 523    AM_WITH_NLS
 524
 525    if test "x$CATOBJEXT" != "x" && test "x$create_catalogs" != "xno" ; then
 526      if test "x$ALL_LINGUAS" = "x"; then
 527        LINGUAS=
 528      else
 529        AC_MSG_CHECKING(for catalogs to be installed)
 530        if test "x$LINGUAS" = "x"; then
 531          LINGUAS=$ALL_LINGUAS
 532        else
 533          NEW_LINGUAS=
 534          for lang in $ALL_LINGUAS; do
 535            case " $LINGUAS " in
 536              *" $lang "*) NEW_LINGUAS="$NEW_LINGUAS $lang" ;;
 537            esac
 538          done
 539          LINGUAS=$NEW_LINGUAS
 540        fi
 541        AC_MSG_RESULT($LINGUAS)
 542      fi
 543
 544      dnl Construct list of names of catalog files to be constructed.
 545      if test -n "$LINGUAS"; then
 546        for lang in $LINGUAS; do CATALOGS="$CATALOGS $lang$CATOBJEXT"; done
 547      fi
 548    fi
 549
 550    dnl The reference to <locale.h> in the installed <libintl.h> file
 551    dnl must be resolved because we cannot expect the users of this
 552    dnl to define HAVE_LOCALE_H.
 553    if test $ac_cv_header_locale_h = yes; then
 554      INCLUDE_LOCALE_H="#include <locale.h>"
 555    else
 556      INCLUDE_LOCALE_H="\
 557 /* The system does not provide the header <locale.h>.  Take care yourself.  */"
 558    fi
 559    AC_SUBST(INCLUDE_LOCALE_H)
 560
 561    dnl Determine which catalog format we have (if any is needed)
 562    dnl For now we know about two different formats:
 563    dnl   Linux libc-5 and the normal X/Open format
 564    test -d intl || mkdir intl
 565    if test "$CATOBJEXT" = ".cat"; then
 566      AC_CHECK_HEADER(linux/version.h, msgformat=linux, msgformat=xopen)
 567
 568      dnl Transform the SED scripts while copying because some dumb SEDs
 569      dnl cannot handle comments.
 570      sed -e '/^#/d' $srcdir/intl/$msgformat-msg.sed > intl/po2msg.sed
 571    fi
 572    dnl po2tbl.sed is always needed.
 573    sed -e '/^#.*[^\\]$/d' -e '/^#$/d' \
 574      $srcdir/intl/po2tbl.sed.in > intl/po2tbl.sed
 575
 576    dnl In the intl/Makefile.in we have a special dependency which makes
 577    dnl only sense for gettext.  We comment this out for non-gettext
 578    dnl packages.
 579    if test "$PACKAGE" = "gettext"; then
 580      GT_NO="#NO#"
 581      GT_YES=
 582    else
 583      GT_NO=
 584      GT_YES="#YES#"
 585    fi
 586    AC_SUBST(GT_NO)
 587    AC_SUBST(GT_YES)
 588
 589    dnl If the AC_CONFIG_AUX_DIR macro for autoconf is used we possibly
 590    dnl find the mkinstalldirs script in another subdir but ($top_srcdir).
 591    dnl Try to locate is.
 592    MKINSTALLDIRS=
 593    if test -n "$ac_aux_dir"; then
 594      MKINSTALLDIRS="$ac_aux_dir/mkinstalldirs"
 595    fi
 596    if test -z "$MKINSTALLDIRS"; then
 597      MKINSTALLDIRS="\$(top_srcdir)/mkinstalldirs"
 598    fi
 599    AC_SUBST(MKINSTALLDIRS)
 600
 601    dnl *** For now the libtool support in intl/Makefile is not for real.
 602    l=
 603    AC_SUBST(l)
 604
 605    dnl Generate list of files to be processed by xgettext which will
 606    dnl be included in po/Makefile.
 607    test -d po || mkdir po
 608    if test "x$srcdir" != "x."; then
 609      if test "x`echo $srcdir | sed 's@/.*@@'`" = "x"; then
 610        posrcprefix="$srcdir/"
 611      else
 612        posrcprefix="../$srcdir/"
 613      fi
 614    else
 615      posrcprefix="../"
 616    fi
 617    rm -f po/POTFILES
 618    sed -e "/^#/d" -e "/^\$/d" -e "s,.*, $posrcprefix& \\\\," -e "\$s/\(.*\) \\\\/\1/" \
 619         < $srcdir/po/POTFILES.in > po/POTFILES
 620   ])
 621
 622 # Check whether LC_MESSAGES is available in <locale.h>.
 623 # Ulrich Drepper <drepper@cygnus.com>, 1995.
 624 #
 625 # This file can be copied and used freely without restrictions.  It can
 626 # be used in projects which are not available under the GNU Public License
 627 # but which still want to provide support for the GNU gettext functionality.
 628 # Please note that the actual code is *not* freely available.
 629
 630 # serial 1
 631
 632 AC_DEFUN(AM_LC_MESSAGES,
 633   [if test $ac_cv_header_locale_h = yes; then
 634     AC_CACHE_CHECK([for LC_MESSAGES], am_cv_val_LC_MESSAGES,
 635       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
 636        am_cv_val_LC_MESSAGES=yes, am_cv_val_LC_MESSAGES=no)])
 637     if test $am_cv_val_LC_MESSAGES = yes; then
 638       AC_DEFINE(HAVE_LC_MESSAGES)
 639     fi
 640   fi])
 641
 642 # Search path for a program which passes the given test.
 643 # Ulrich Drepper <drepper@cygnus.com>, 1996.
 644 #
 645 # This file can be copied and used freely without restrictions.  It can
 646 # be used in projects which are not available under the GNU Public License
 647 # but which still want to provide support for the GNU gettext functionality.
 648 # Please note that the actual code is *not* freely available.
 649
 650 # serial 1
 651
 652 dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR,
 653 dnl   TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]])
 654 AC_DEFUN(AM_PATH_PROG_WITH_TEST,
 655 [# Extract the first word of "$2", so it can be a program name with args.
 656 set dummy $2; ac_word=[$]2
 657 AC_MSG_CHECKING([for $ac_word])
 658 AC_CACHE_VAL(ac_cv_path_$1,
 659 [case "[$]$1" in
 660   /*)
 661   ac_cv_path_$1="[$]$1" # Let the user override the test with a path.
 662   ;;
 663   *)
 664   IFS="${IFS=   }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 665   for ac_dir in ifelse([$5], , $PATH, [$5]); do
 666     test -z "$ac_dir" && ac_dir=.
 667     if test -f $ac_dir/$ac_word; then
 668       if [$3]; then
 669         ac_cv_path_$1="$ac_dir/$ac_word"
 670         break
 671       fi
 672     fi
 673   done
 674   IFS="$ac_save_ifs"
 675 dnl If no 4th arg is given, leave the cache variable unset,
 676 dnl so AC_PATH_PROGS will keep looking.
 677 ifelse([$4], , , [  test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4"
 678 ])dnl
 679   ;;
 680 esac])dnl
 681 $1="$ac_cv_path_$1"
 682 if test -n "[$]$1"; then
 683   AC_MSG_RESULT([$]$1)
 684 else
 685   AC_MSG_RESULT(no)
 686 fi
 687 AC_SUBST($1)dnl
 688 ])
 689
 690 # Check whether mmap can map an arbitrary page from /dev/zero, without
 691 # MAP_FIXED.
 692 AC_DEFUN([AC_FUNC_MMAP_ANYWHERE],
 693 [AC_CHECK_HEADERS(unistd.h)
 694 AC_CHECK_FUNCS(getpagesize)
 695 AC_CACHE_CHECK(for working mmap from /dev/zero, ac_cv_func_mmap_anywhere,
 696 [AC_TRY_RUN([
 697 /* Test by Richard Henderson and Alexandre Oliva.
 698    Check whether mmap from /dev/zero works. */
 699 #include <sys/types.h>
 700 #include <fcntl.h>
 701 #include <sys/mman.h>
 702
 703 /* This mess was copied from the GNU getpagesize.h.  */
 704 #ifndef HAVE_GETPAGESIZE
 705 # ifdef HAVE_UNISTD_H
 706 #  include <unistd.h>
 707 # endif
 708
 709 /* Assume that all systems that can run configure have sys/param.h.  */
 710 # ifndef HAVE_SYS_PARAM_H
 711 #  define HAVE_SYS_PARAM_H 1
 712 # endif
 713
 714 # ifdef _SC_PAGESIZE
 715 #  define getpagesize() sysconf(_SC_PAGESIZE)
 716 # else /* no _SC_PAGESIZE */
 717 #  ifdef HAVE_SYS_PARAM_H
 718 #   include <sys/param.h>
 719 #   ifdef EXEC_PAGESIZE
 720 #    define getpagesize() EXEC_PAGESIZE
 721 #   else /* no EXEC_PAGESIZE */
 722 #    ifdef NBPG
 723 #     define getpagesize() NBPG * CLSIZE
 724 #     ifndef CLSIZE
 725 #      define CLSIZE 1
 726 #     endif /* no CLSIZE */
 727 #    else /* no NBPG */
 728 #     ifdef NBPC
 729 #      define getpagesize() NBPC
 730 #     else /* no NBPC */
 731 #      ifdef PAGESIZE
 732 #       define getpagesize() PAGESIZE
 733 #      endif /* PAGESIZE */
 734 #     endif /* no NBPC */
 735 #    endif /* no NBPG */
 736 #   endif /* no EXEC_PAGESIZE */
 737 #  else /* no HAVE_SYS_PARAM_H */
 738 #   define getpagesize() 8192   /* punt totally */
 739 #  endif /* no HAVE_SYS_PARAM_H */
 740 # endif /* no _SC_PAGESIZE */
 741
 742 #endif /* no HAVE_GETPAGESIZE */
 743
 744 int main()
 745 {
 746   char *x;
 747   int fd, pg;
 748
 749   fd = open("/dev/zero", O_RDWR);
 750   if (fd < 0)
 751     exit(1);
 752
 753   pg = getpagesize();
 754   x = (char*)mmap(0, pg, PROT_READ|PROT_WRITE, MAP_PRIVATE, fd, 0);
 755   if (x == (char *) -1)
 756     exit(2);
 757
 758   *(int *)x += 1;
 759
 760   if (munmap(x, pg) < 0)
 761     exit(3);
 762
 763   exit(0);
 764 }], ac_cv_func_mmap_anywhere=yes, ac_cv_func_mmap_anywhere=no,
 765 ac_cv_func_mmap_anywhere=no)])
 766 if test $ac_cv_func_mmap_anywhere = yes; then
 767   AC_DEFINE(HAVE_MMAP_ANYWHERE, 1,
 768             [Define if mmap can get us zeroed pages from /dev/zero.])
 769 fi
 770 ])
 771
 772 # Check whether mmap can map a plain file, without MAP_FIXED.
 773 AC_DEFUN([AC_FUNC_MMAP_FILE],
 774 [AC_REQUIRE([AC_FUNC_MMAP_ANYWHERE])dnl
 775 AC_CACHE_CHECK(for working mmap of a file, ac_cv_func_mmap_file,
 776 [# Create a file one thousand bytes long.
 777 for i in 1 2 3 4 5 6 7 8 9 0
 778 do for j in 1 2 3 4 5 6 7 8 9 0
 779 do echo $i $j xxxxx
 780 done
 781 done > conftestdata$$
 782
 783 AC_TRY_RUN([
 784 /* Test by Zack Weinberg.  Modified from MMAP_ANYWHERE test by
 785    Richard Henderson and Alexandre Oliva.
 786    Check whether read-only mmap of a plain file works. */
 787 #include <sys/types.h>
 788 #include <sys/stat.h>
 789 #include <fcntl.h>
 790 #include <sys/mman.h>
 791
 792 int main()
 793 {
 794   char *x;
 795   int fd;
 796   struct stat st;
 797
 798   fd = open("conftestdata$$", O_RDONLY);
 799   if (fd < 0)
 800     exit(1);
 801
 802   if (fstat (fd, &st))
 803     exit(2);
 804
 805   x = (char*)mmap(0, st.st_size, PROT_READ, MAP_PRIVATE, fd, 0);
 806   if (x == (char *) -1)
 807     exit(3);
 808
 809   if (x[0] != '1' || x[1] != ' ' || x[2] != '1' || x[3] != ' ')
 810     exit(4);
 811
 812   if (munmap(x, st.st_size) < 0)
 813     exit(5);
 814
 815   exit(0);
 816 }], ac_cv_func_mmap_file=yes, ac_cv_func_mmap_file=no,
 817 ac_cv_func_mmap_file=no)])
 818 if test $ac_cv_func_mmap_file = yes; then
 819   AC_DEFINE(HAVE_MMAP_FILE, 1,
 820             [Define if read-only mmap of a plain file works.])
 821 fi
 822 ])
 823
 824 dnl Locate a program and check that its version is acceptable.
 825 dnl AC_PROG_CHECK_VER(var, name, version-switch,
 826 dnl                  version-extract-regexp, version-glob)
 827 AC_DEFUN(gcc_AC_CHECK_PROG_VER,
 828 [AC_CHECK_PROG([$1], [$2], [$2])
 829 if test -n "[$]$1"; then
 830   # Found it, now check the version.
 831   AC_CACHE_CHECK(for modern $2, gcc_cv_prog_$2_modern,
 832 [changequote(<<,>>)dnl
 833   ac_prog_version=`<<$>>$1 $3 2>&1 |
 834                    sed -n 's/^.*patsubst(<<$4>>,/,\/).*$/\1/p'`
 835   echo "configure:__oline__: version of $2 is $ac_prog_version" >&AC_FD_CC
 836   case $ac_prog_version in
 837     '')     gcc_cv_prog_$2_modern=no;;
 838     <<$5>>)
 839             gcc_cv_prog_$2_modern=yes;;
 840     *)      gcc_cv_prog_$2_modern=no;;
 841   esac
 842 changequote([,])dnl
 843 ])
 844 else
 845   gcc_cv_prog_$2_modern=no
 846 fi
 847 ])