gcc/ada/a-except.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                       A D A . E X C E P T I O N S                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This version of Ada.Exceptions is a full Ada 95 version. It omits Ada 2005
  37 --  features such as the additional definitions of Exception_Name returning
  38 --  Wide_[Wide_]String.
  39
  40 --  It is used for building the compiler and the basic tools, since these
  41 --  builds may be done with bootstrap compilers that cannot handle these
  42 --  additions. The full version of Ada.Exceptions can be found in the files
  43 --  a-except-2005.ads/adb, and is used for all other builds where full Ada
  44 --  2005 functionality is required. In particular, it is used for building
  45 --  run times on all targets.
  46
  47 pragma Polling (Off);
  48 --  We must turn polling off for this unit, because otherwise we get
  49 --  elaboration circularities with ourself.
  50
  51 pragma Warnings (Off);
  52 pragma Compiler_Unit;
  53 pragma Warnings (On);
  54
  55 with System;
  56 with System.Parameters;
  57 with System.Standard_Library;
  58 with System.Traceback_Entries;
  59
  60 package Ada.Exceptions is
  61    pragma Warnings (Off);
  62    pragma Preelaborate_05;
  63    pragma Warnings (On);
  64    --  We make this preelaborable in Ada 2005 mode. If we did not do this, then
  65    --  run time units used by the compiler (e.g. s-soflin.ads) would run
  66    --  into trouble. Conformance is not an issue, since this version is used
  67    --  only by the compiler.
  68
  69    type Exception_Id is private;
  70
  71    Null_Id : constant Exception_Id;
  72
  73    type Exception_Occurrence is limited private;
  74
  75    type Exception_Occurrence_Access is access all Exception_Occurrence;
  76
  77    Null_Occurrence : constant Exception_Occurrence;
  78
  79    function Exception_Name (X : Exception_Occurrence) return String;
  80    --  Same as Exception_Name (Exception_Identity (X))
  81
  82    function Exception_Name (Id : Exception_Id) return String;
  83
  84    procedure Raise_Exception (E : Exception_Id; Message : String := "");
  85    pragma No_Return (Raise_Exception);
  86    --  Note: In accordance with AI-466, CE is raised if E = Null_Id
  87
  88    function Exception_Message (X : Exception_Occurrence) return String;
  89
  90    procedure Reraise_Occurrence (X : Exception_Occurrence);
  91    --  Note: it would be really nice to give a pragma No_Return for this
  92    --  procedure, but it would be wrong, since Reraise_Occurrence does return
  93    --  if the argument is the null exception occurrence. See also procedure
  94    --  Reraise_Occurrence_Always in the private part of this package.
  95
  96    function Exception_Identity (X : Exception_Occurrence) return Exception_Id;
  97
  98    function Exception_Information (X : Exception_Occurrence) return String;
  99    --  The format of the exception information is as follows:
 100    --
 101    --    exception name (as in Exception_Name)
 102    --    message (or a null line if no message)
 103    --    PID=nnnn
 104    --    0xyyyyyyyy 0xyyyyyyyy ...
 105    --
 106    --  The lines are separated by a ASCII.LF character
 107    --  The nnnn is the partition Id given as decimal digits.
 108    --  The 0x... line represents traceback program counter locations,
 109    --  in order with the first one being the exception location.
 110
 111    --  Note on ordering: the compiler uses the Save_Occurrence procedure, but
 112    --  not the function from Rtsfind, so it is important that the procedure
 113    --  come first, since Rtsfind finds the first matching entity.
 114
 115    procedure Save_Occurrence
 116      (Target : out Exception_Occurrence;
 117       Source : Exception_Occurrence);
 118
 119    function Save_Occurrence
 120      (Source : Exception_Occurrence)
 121       return   Exception_Occurrence_Access;
 122
 123 private
 124    package SSL renames System.Standard_Library;
 125    package SP renames System.Parameters;
 126
 127    subtype EOA is Exception_Occurrence_Access;
 128
 129    Exception_Msg_Max_Length : constant := SP.Default_Exception_Msg_Max_Length;
 130
 131    ------------------
 132    -- Exception_Id --
 133    ------------------
 134
 135    subtype Code_Loc is System.Address;
 136    --  Code location used in building exception tables and for call addresses
 137    --  when propagating an exception. Values of this type are created by using
 138    --  Label'Address or extracted from machine states using Get_Code_Loc.
 139
 140    Null_Loc : constant Code_Loc := System.Null_Address;
 141    --  Null code location, used to flag outer level frame
 142
 143    type Exception_Id is new SSL.Exception_Data_Ptr;
 144
 145    function EId_To_String (X : Exception_Id) return String;
 146    function String_To_EId (S : String) return Exception_Id;
 147    pragma Stream_Convert (Exception_Id, String_To_EId, EId_To_String);
 148    --  Functions for implementing Exception_Id stream attributes
 149
 150    Null_Id : constant Exception_Id := null;
 151
 152    -------------------------
 153    -- Private Subprograms --
 154    -------------------------
 155
 156    function Current_Target_Exception return Exception_Occurrence;
 157    pragma Export
 158      (Ada, Current_Target_Exception,
 159       "__gnat_current_target_exception");
 160    --  This routine should return the current raised exception on targets
 161    --  which have built-in exception handling such as the Java Virtual
 162    --  Machine. For other targets this routine is simply ignored. Currently,
 163    --  only JGNAT uses this. See 4jexcept.ads for details. The pragma Export
 164    --  allows this routine to be accessed elsewhere in the run-time, even
 165    --  though it is in the private part of this package (it is not allowed
 166    --  to be in the visible part, since this is set by the reference manual).
 167
 168    function Exception_Name_Simple (X : Exception_Occurrence) return String;
 169    --  Like Exception_Name, but returns the simple non-qualified name of the
 170    --  exception. This is used to implement the Exception_Name function in
 171    --  Current_Exceptions (the DEC compatible unit). It is called from the
 172    --  compiler generated code (using Rtsfind, which does not respect the
 173    --  private barrier, so we can place this function in the private part
 174    --  where the compiler can find it, but the spec is unchanged.)
 175
 176    procedure Raise_Exception_Always (E : Exception_Id; Message : String := "");
 177    pragma No_Return (Raise_Exception_Always);
 178    pragma Export (Ada, Raise_Exception_Always, "__gnat_raise_exception");
 179    --  This differs from Raise_Exception only in that the caller has determined
 180    --  that for sure the parameter E is not null, and that therefore no check
 181    --  for Null_Id is required. The expander converts Raise_Exception calls to
 182    --  Raise_Exception_Always if it can determine this is the case. The Export
 183    --  allows this routine to be accessed from Pure units.
 184
 185    procedure Raise_From_Signal_Handler
 186      (E : Exception_Id;
 187       M : System.Address);
 188    pragma Export
 189      (Ada, Raise_From_Signal_Handler,
 190            "ada__exceptions__raise_from_signal_handler");
 191    pragma No_Return (Raise_From_Signal_Handler);
 192    --  This routine is used to raise an exception from a signal handler. The
 193    --  signal handler has already stored the machine state (i.e. the state that
 194    --  corresponds to the location at which the signal was raised). E is the
 195    --  Exception_Id specifying what exception is being raised, and M is a
 196    --  pointer to a null-terminated string which is the message to be raised.
 197    --  Note that this routine never returns, so it is permissible to simply
 198    --  jump to this routine, rather than call it. This may be appropriate for
 199    --  systems where the right way to get out of signal handler is to alter the
 200    --  PC value in the machine state or in some other way ask the operating
 201    --  system to return here rather than to the original location.
 202
 203    procedure Raise_From_Controlled_Operation
 204      (X : Ada.Exceptions.Exception_Occurrence);
 205    pragma No_Return (Raise_From_Controlled_Operation);
 206    --  Raise Program_Error, providing information about X (an exception
 207    --  raised during a controlled operation) in the exception message.
 208
 209    procedure Reraise_Occurrence_Always (X : Exception_Occurrence);
 210    pragma No_Return (Reraise_Occurrence_Always);
 211    --  This differs from Raise_Occurrence only in that the caller guarantees
 212    --  that for sure the parameter X is not the null occurrence, and that
 213    --  therefore this procedure cannot return. The expander uses this routine
 214    --  in the translation of a raise statement with no parameter (reraise).
 215
 216    procedure Reraise_Occurrence_No_Defer (X : Exception_Occurrence);
 217    pragma No_Return (Reraise_Occurrence_No_Defer);
 218    --  Exactly like Reraise_Occurrence, except that abort is not deferred
 219    --  before the call and the parameter X is known not to be the null
 220    --  occurrence. This is used in generated code when it is known that
 221    --  abort is already deferred.
 222
 223    -----------------------
 224    -- Polling Interface --
 225    -----------------------
 226
 227    --  The GNAT compiler has an option to generate polling calls to the Poll
 228    --  routine in this package. Specifying the -gnatP option for a compilation
 229    --  causes a call to Ada.Exceptions.Poll to be generated on every subprogram
 230    --  entry and on every iteration of a loop, thus avoiding the possibility of
 231    --  a case of unbounded time between calls.
 232
 233    --  This polling interface may be used for instrumentation or debugging
 234    --  purposes (e.g. implementing watchpoints in software or in the debugger).
 235
 236    --  In the GNAT technology itself, this interface is used to implement
 237    --  immediate asynchronous transfer of control and immediate abort on
 238    --  targets which do not provide for one thread interrupting another.
 239
 240    --  Note: this used to be in a separate unit called System.Poll, but that
 241    --  caused horrible circular elaboration problems between System.Poll and
 242    --  Ada.Exceptions. One way of solving such circularities is unification!
 243
 244    procedure Poll;
 245    --  Check for asynchronous abort. Note that we do not inline the body.
 246    --  This makes the interface more useful for debugging purposes.
 247
 248    --------------------------
 249    -- Exception_Occurrence --
 250    --------------------------
 251
 252    package TBE renames System.Traceback_Entries;
 253
 254    Max_Tracebacks : constant := 50;
 255    --  Maximum number of trace backs stored in exception occurrence
 256
 257    type Tracebacks_Array is array (1 .. Max_Tracebacks) of TBE.Traceback_Entry;
 258    --  Traceback array stored in exception occurrence
 259
 260    type Exception_Occurrence is record
 261       Id : Exception_Id;
 262       --  Exception_Identity for this exception occurrence
 263       --  WARNING System.System.Finalization_Implementation.Finalize_List
 264       --  relies on the fact that this field is always first in the exception
 265       --  occurrence
 266
 267       Msg_Length : Natural := 0;
 268       --  Length of message (zero = no message)
 269
 270       Msg : String (1 .. Exception_Msg_Max_Length);
 271       --  Characters of message
 272
 273       Cleanup_Flag : Boolean := False;
 274       --  The cleanup flag is normally False, it is set True for an exception
 275       --  occurrence passed to a cleanup routine, and will still be set True
 276       --  when the cleanup routine does a Reraise_Occurrence call using this
 277       --  exception occurrence. This is used to avoid recording a bogus trace
 278       --  back entry from this reraise call.
 279
 280       Exception_Raised : Boolean := False;
 281       --  Set to true to indicate that this exception occurrence has actually
 282       --  been raised. When an exception occurrence is first created, this is
 283       --  set to False, then when it is processed by Raise_Current_Exception,
 284       --  it is set to True. If Raise_Current_Exception is used to raise an
 285       --  exception for which this flag is already True, then it knows that
 286       --  it is dealing with the reraise case (which is useful to distinguish
 287       --  for exception tracing purposes).
 288
 289       Pid : Natural := 0;
 290       --  Partition_Id for partition raising exception
 291
 292       Num_Tracebacks : Natural range 0 .. Max_Tracebacks := 0;
 293       --  Number of traceback entries stored
 294
 295       Tracebacks : Tracebacks_Array;
 296       --  Stored tracebacks (in Tracebacks (1 .. Num_Tracebacks))
 297
 298       Private_Data : System.Address := System.Null_Address;
 299       --  Field used by low level exception mechanism to store specific data.
 300       --  Currently used by the GCC exception mechanism to store a pointer to
 301       --  a GNAT_GCC_Exception.
 302    end record;
 303
 304    function "=" (Left, Right : Exception_Occurrence) return Boolean
 305      is abstract;
 306    --  Don't allow comparison on exception occurrences, we should not need
 307    --  this, and it would not work right, because of the Msg and Tracebacks
 308    --  fields which have unused entries not copied by Save_Occurrence.
 309
 310    function EO_To_String (X : Exception_Occurrence) return String;
 311    function String_To_EO (S : String) return Exception_Occurrence;
 312    pragma Stream_Convert (Exception_Occurrence, String_To_EO, EO_To_String);
 313    --  Functions for implementing Exception_Occurrence stream attributes
 314
 315    Null_Occurrence : constant Exception_Occurrence := (
 316      Id               => null,
 317      Msg_Length       => 0,
 318      Msg              => (others => ' '),
 319      Cleanup_Flag     => False,
 320      Exception_Raised => False,
 321      Pid              => 0,
 322      Num_Tracebacks   => 0,
 323      Tracebacks       => (others => TBE.Null_TB_Entry),
 324      Private_Data     => System.Null_Address);
 325
 326 end Ada.Exceptions;