gcc/ada/adabkend.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             A D A B K E N D                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 2001-2019, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 ------------------------------------------------------------------------------
  22
  23 --  This is the version of the Back_End package for back ends written in Ada
  24
  25 with Atree;    use Atree;
  26 with Debug;
  27 with Lib;
  28 with Opt;      use Opt;
  29 with Output;   use Output;
  30 with Osint;    use Osint;
  31 with Osint.C;  use Osint.C;
  32 with Switch.C; use Switch.C;
  33 with Types;    use Types;
  34
  35 with System.OS_Lib; use System.OS_Lib;
  36
  37 package body Adabkend is
  38
  39    use Switch;
  40
  41    -------------------
  42    -- Call_Back_End --
  43    -------------------
  44
  45    procedure Call_Back_End is
  46    begin
  47       if (Opt.Verbose_Mode or Opt.Full_List)
  48         and then not Debug.Debug_Flag_7
  49       then
  50          Write_Eol;
  51          Write_Str (Product_Name);
  52          Write_Str (", Copyright ");
  53          Write_Str (Copyright_Years);
  54          Write_Str (" Ada Core Technologies, Inc.");
  55          Write_Str (" (http://www.adacore.com)");
  56          Write_Eol;
  57          Write_Eol;
  58       end if;
  59
  60       --  The front end leaves the Current_Error_Node at a location that is
  61       --  meaningless and confusing when emitting bug boxes from the back end.
  62       --  Reset the global variable in order to emit "No source file position
  63       --  information available" messages on back end crashes.
  64
  65       Current_Error_Node := Empty;
  66
  67       Driver (Lib.Cunit (Types.Main_Unit));
  68    end Call_Back_End;
  69
  70    -----------------------------
  71    -- Scan_Compiler_Arguments --
  72    -----------------------------
  73
  74    procedure Scan_Compiler_Arguments is
  75       Output_File_Name_Seen : Boolean := False;
  76       --  Set to True after having scanned the file_name for switch
  77       --  "-gnatO file_name"
  78
  79       Argument_Count : constant Integer := Arg_Count - 1;
  80       --  Number of arguments (excluding program name)
  81
  82       Args     : Argument_List (1 .. Argument_Count);
  83       Next_Arg : Positive := 1;
  84
  85       procedure Scan_Back_End_Switches (Switch_Chars : String);
  86       --  Procedure to scan out switches stored in Switch_Chars. The first
  87       --  character is known to be a valid switch character, and there are no
  88       --  blanks or other switch terminator characters in the string, so the
  89       --  entire string should consist of valid switch characters, except that
  90       --  an optional terminating NUL character is allowed.
  91       --
  92       --  If the switch is not valid, control will not return. The switches
  93       --  must still be scanned to skip the "-o" arguments, or internal GCC
  94       --  switches, which may be safely ignored by other back ends.
  95
  96       ----------------------------
  97       -- Scan_Back_End_Switches --
  98       ----------------------------
  99
 100       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 101          First : constant Positive := Switch_Chars'First + 1;
 102          Last  : constant Natural  := Switch_Last (Switch_Chars);
 103
 104       begin
 105          --  Process any back end switches, returning if the switch does not
 106          --  affect code generation or falling through if it does, so the
 107          --  switch will get stored.
 108
 109          --  Skip -o, -G or internal GCC switches together with their argument.
 110
 111          if Switch_Chars (First .. Last) = "o"
 112            or else Switch_Chars (First .. Last) = "G"
 113            or else Is_Internal_GCC_Switch (Switch_Chars)
 114          then
 115             Next_Arg := Next_Arg + 1;
 116             return; -- ignore this switch
 117
 118          --  Set optimization indicators appropriately. In gcc-based GNAT this
 119          --  is picked up from imported variables set by the gcc driver, but
 120          --  for compilers with non-gcc back ends we do it here to allow use of
 121          --  these switches by the front end. Allowed optimization switches are
 122          --  -Os (optimize for size), -O[0123], -O (same as -O1), -Ofast
 123          --  (disregard strict standards compliance), and -Og (optimize
 124          --  debugging experience).
 125
 126          elsif Switch_Chars (First) = 'O' then
 127             if First = Last then
 128                Optimization_Level := 1;
 129
 130             elsif Last - First = 1 then
 131                if Switch_Chars (Last) = 's' then
 132                   Optimize_Size := 1;
 133                   Optimization_Level := 2;  -- Consistent with gcc setting
 134
 135                elsif Switch_Chars (Last) in '0' .. '3' then
 136                   Optimization_Level :=
 137                     Character'Pos (Switch_Chars (Last)) - Character'Pos ('0');
 138
 139                --  Switch -Og is between -O0 and -O1 in GCC. Consider it like
 140                --  -O0 for other back ends.
 141
 142                elsif Switch_Chars (Last) = 'g' then
 143                   Optimization_Level := 0;
 144
 145                else
 146                   Fail ("invalid switch: " & Switch_Chars);
 147                end if;
 148
 149             --  Switch -Ofast enables -O3
 150
 151             elsif Switch_Chars (First + 1 .. Last) = "fast" then
 152                Optimization_Level := 3;
 153
 154             else
 155                Fail ("invalid switch: " & Switch_Chars);
 156             end if;
 157
 158          elsif Switch_Chars (First .. Last) = "quiet" then
 159             return; -- ignore this switch
 160
 161          elsif Switch_Chars (First .. Last) = "c" then
 162             return; -- ignore this switch
 163
 164          --  The -x switch and its language name argument will generally be
 165          --  ignored by non-gcc back ends. In any case, we save the switch and
 166          --  argument in the compilation switches.
 167
 168          elsif Switch_Chars (First .. Last) = "x" then
 169             Lib.Store_Compilation_Switch (Switch_Chars);
 170             Next_Arg := Next_Arg + 1;
 171
 172             declare
 173                Argv : constant String := Args (Next_Arg).all;
 174
 175             begin
 176                if Is_Switch (Argv) then
 177                   Fail ("language name missing after -x");
 178                else
 179                   Lib.Store_Compilation_Switch (Argv);
 180                end if;
 181             end;
 182
 183             return;
 184
 185          --  Special check, the back-end switch -fno-inline also sets the
 186          --  front end flags to entirely inhibit all inlining. So we store it
 187          --  and set the appropriate flags.
 188
 189          elsif Switch_Chars (First .. Last) = "fno-inline" then
 190             Lib.Store_Compilation_Switch (Switch_Chars);
 191             Opt.Disable_FE_Inline := True;
 192             Opt.Disable_FE_Inline_Always := True;
 193             return;
 194
 195          --  Similar processing for -fpreserve-control-flow
 196
 197          elsif Switch_Chars (First .. Last) = "fpreserve-control-flow" then
 198             Lib.Store_Compilation_Switch (Switch_Chars);
 199             Opt.Suppress_Control_Flow_Optimizations := True;
 200             return;
 201
 202          --  Recognize -gxxx switches
 203
 204          elsif Switch_Chars (First) = 'g' then
 205             Debugger_Level := 2;
 206
 207             if First < Last then
 208                case Switch_Chars (First + 1) is
 209                   when '0' =>
 210                      Debugger_Level := 0;
 211                   when '1' =>
 212                      Debugger_Level := 1;
 213                   when '2' =>
 214                      Debugger_Level := 2;
 215                   when '3' =>
 216                      Debugger_Level := 3;
 217                   when others =>
 218                      null;
 219                end case;
 220             end if;
 221
 222          --  Ignore all other back-end switches
 223
 224          elsif Is_Back_End_Switch (Switch_Chars) then
 225             null;
 226
 227          --  Give error for junk switch
 228
 229          else
 230             Fail ("invalid switch: " & Switch_Chars);
 231          end if;
 232
 233          --  Store any other GCC switches
 234
 235          Lib.Store_Compilation_Switch (Switch_Chars);
 236       end Scan_Back_End_Switches;
 237
 238    --  Start of processing for Scan_Compiler_Args
 239
 240    begin
 241       --  Put all the arguments in argument list Args
 242
 243       for Arg in 1 .. Argument_Count loop
 244          declare
 245             Argv : String (1 .. Len_Arg (Arg));
 246          begin
 247             Fill_Arg (Argv'Address, Arg);
 248             Args (Arg) := new String'(Argv);
 249          end;
 250       end loop;
 251
 252       --  Loop through command line arguments, storing them for later access
 253
 254       while Next_Arg <= Argument_Count loop
 255          Look_At_Arg : declare
 256             Argv : constant String := Args (Next_Arg).all;
 257
 258          begin
 259             if Argv'Length = 0 then
 260                Fail ("Empty argument");
 261             end if;
 262
 263             --  If the previous switch has set the Output_File_Name_Present
 264             --  flag (that is we have seen a -gnatO), then the next argument
 265             --  is the name of the output object file.
 266
 267             if Opt.Output_File_Name_Present
 268               and then not Output_File_Name_Seen
 269             then
 270                if Is_Switch (Argv) then
 271                   Fail ("Object file name missing after -gnatO");
 272                else
 273                   Set_Output_Object_File_Name (Argv);
 274                   Output_File_Name_Seen := True;
 275                end if;
 276
 277                --  If the previous switch has set the Search_Directory_Present
 278                --  flag (that is if we have just seen -I), then the next
 279                --  argument is a search directory path.
 280
 281             elsif Search_Directory_Present then
 282                if Is_Switch (Argv) then
 283                   Fail ("search directory missing after -I");
 284                else
 285                   Add_Src_Search_Dir (Argv);
 286
 287                   --  Add directory to lib search so that back end can take as
 288                   --  input ALI files if needed. Otherwise this won't have any
 289                   --  impact on the compiler.
 290
 291                   Add_Lib_Search_Dir (Argv);
 292
 293                   Search_Directory_Present := False;
 294                end if;
 295
 296             --  If not a switch, must be a file name
 297
 298             elsif not Is_Switch (Argv) then
 299                Add_File (Argv);
 300
 301             --  We must recognize -nostdinc to suppress visibility on the
 302             --  standard GNAT RTL sources.
 303
 304             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 305                Opt.No_Stdinc := True;
 306
 307             --  Front end switch
 308
 309             elsif Is_Front_End_Switch (Argv) then
 310                Scan_Front_End_Switches (Argv, Args, Next_Arg);
 311
 312             --  All non-front-end switches are back-end switches
 313
 314             else
 315                Scan_Back_End_Switches (Argv);
 316             end if;
 317          end Look_At_Arg;
 318
 319          Next_Arg := Next_Arg + 1;
 320       end loop;
 321    end Scan_Compiler_Arguments;
 322
 323 end Adabkend;