gcc/ada/comperr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              C O M P E R R                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 --  This package contains routines called when a fatal internal compiler
  28 --  error is detected. Calls to these routines cause termination of the
  29 --  current compilation with appropriate error output.
  30
  31 with Atree;    use Atree;
  32 with Debug;    use Debug;
  33 with Errout;   use Errout;
  34 with Fname;    use Fname;
  35 with Gnatvsn;  use Gnatvsn;
  36 with Lib;      use Lib;
  37 with Namet;    use Namet;
  38 with Osint;    use Osint;
  39 with Output;   use Output;
  40 with Sinput;   use Sinput;
  41 with Sprint;   use Sprint;
  42 with Sdefault; use Sdefault;
  43 with Treepr;   use Treepr;
  44 with Types;    use Types;
  45
  46 with Ada.Exceptions; use Ada.Exceptions;
  47
  48 with System.Soft_Links; use System.Soft_Links;
  49
  50 package body Comperr is
  51
  52    ----------------
  53    -- Local Data --
  54    ----------------
  55
  56    Abort_In_Progress : Boolean := False;
  57    --  Used to prevent runaway recursion if something segfaults
  58    --  while processing a previous abort.
  59
  60    -----------------------
  61    -- Local Subprograms --
  62    -----------------------
  63
  64    procedure Repeat_Char (Char : Character; Col : Nat; After : Character);
  65    --  Output Char until current column is at or past Col, and then output
  66    --  the character given by After (if column is already past Col on entry,
  67    --  then the effect is simply to output the After character).
  68
  69    --------------------
  70    -- Compiler_Abort --
  71    --------------------
  72
  73    procedure Compiler_Abort
  74      (X    : String;
  75       Code : Integer := 0)
  76    is
  77       --  The procedures below output a "bug box" with information about
  78       --  the cause of the compiler abort and about the preferred method
  79       --  of reporting bugs. The default is a bug box appropriate for
  80       --  the FSF version of GNAT, but there are specializations for
  81       --  the GNATPRO and Public releases by Ada Core Technologies.
  82
  83       procedure End_Line;
  84       --  Add blanks up to column 76, and then a final vertical bar
  85
  86       --------------
  87       -- End_Line --
  88       --------------
  89
  90       procedure End_Line is
  91       begin
  92          Repeat_Char (' ', 76, '|');
  93          Write_Eol;
  94       end End_Line;
  95
  96       Is_Public_Version : constant Boolean := Get_Gnat_Build_Type = Public;
  97       Is_FSF_Version    : constant Boolean := Get_Gnat_Build_Type = FSF;
  98
  99    --  Start of processing for Compiler_Abort
 100
 101    begin
 102       --  Prevent recursion through Compiler_Abort, e.g. via SIGSEGV.
 103
 104       if Abort_In_Progress then
 105          Exit_Program (E_Abort);
 106       end if;
 107
 108       Abort_In_Progress := True;
 109
 110       --  If any errors have already occurred, then we guess that the abort
 111       --  may well be caused by previous errors, and we don't make too much
 112       --  fuss about it, since we want to let programmer fix the errors first.
 113
 114       --  Debug flag K disables this behavior (useful for debugging)
 115
 116       if Serious_Errors_Detected /= 0 and then not Debug_Flag_K then
 117          Errout.Finalize;
 118
 119          Set_Standard_Error;
 120          Write_Str ("compilation abandoned due to previous error");
 121          Write_Eol;
 122
 123          Set_Standard_Output;
 124          Source_Dump;
 125          Tree_Dump;
 126          Exit_Program (E_Errors);
 127
 128       --  Otherwise give message with details of the abort
 129
 130       else
 131          Set_Standard_Error;
 132
 133          --  Generate header for bug box
 134
 135          Write_Char ('+');
 136          Repeat_Char ('=', 29, 'G');
 137          Write_Str ("NAT BUG DETECTED");
 138          Repeat_Char ('=', 76, '+');
 139          Write_Eol;
 140
 141          --  Output GNAT version identification
 142
 143          Write_Str ("| ");
 144          Write_Str (Gnat_Version_String);
 145          Write_Str (" (");
 146
 147          --  Output target name, deleting junk final reverse slash
 148
 149          if Target_Name.all (Target_Name.all'Last) = '\'
 150            or else Target_Name.all (Target_Name.all'Last) = '/'
 151          then
 152             Write_Str (Target_Name.all (1 .. Target_Name.all'Last - 1));
 153          else
 154             Write_Str (Target_Name.all);
 155          end if;
 156
 157          --  Output identification of error
 158
 159          Write_Str (") ");
 160
 161          if X'Length + Column > 76 then
 162             if Code < 0 then
 163                Write_Str ("GCC error:");
 164             end if;
 165
 166             End_Line;
 167
 168             Write_Str ("| ");
 169          end if;
 170
 171          if X'Length > 70 then
 172             declare
 173                Last_Blank : Integer := 70;
 174
 175             begin
 176                for P in 40 .. 69 loop
 177                   if X (P) = ' ' then
 178                      Last_Blank := P;
 179                   end if;
 180                end loop;
 181
 182                Write_Str (X (1 .. Last_Blank));
 183                End_Line;
 184                Write_Str ("|    ");
 185                Write_Str (X (Last_Blank + 1 .. X'Length));
 186             end;
 187          else
 188             Write_Str (X);
 189          end if;
 190
 191          if Code > 0 then
 192             Write_Str (", Code=");
 193             Write_Int (Int (Code));
 194
 195          elsif Code = 0 then
 196
 197             --  For exception case, get exception message from the TSD. Note
 198             --  that it would be neater and cleaner to pass the exception
 199             --  message (obtained from Exception_Message) as a parameter to
 200             --  Compiler_Abort, but we can't do this quite yet since it would
 201             --  cause bootstrap path problems for 3.10 to 3.11.
 202
 203             Write_Char (' ');
 204             Write_Str (Exception_Message (Get_Current_Excep.all.all));
 205          end if;
 206
 207          End_Line;
 208
 209          --  Output source location information
 210
 211          if Sloc (Current_Error_Node) <= Standard_Location
 212            or else Sloc (Current_Error_Node) = No_Location
 213          then
 214             Write_Str ("| No source file position information available");
 215             End_Line;
 216          else
 217             Write_Str ("| Error detected at ");
 218             Write_Location (Sloc (Current_Error_Node));
 219             End_Line;
 220          end if;
 221
 222          --  There are two cases now. If the file gnat_bug.box exists,
 223          --  we use the contents of this file at this point.
 224
 225          declare
 226             Lo  : Source_Ptr;
 227             Hi  : Source_Ptr;
 228             Src : Source_Buffer_Ptr;
 229
 230          begin
 231             Namet.Unlock;
 232             Name_Buffer (1 .. 12) := "gnat_bug.box";
 233             Name_Len := 12;
 234             Read_Source_File (Name_Enter, 0, Hi, Src);
 235
 236             --  If we get a Src file, we use it
 237
 238             if Src /= null then
 239                Lo := 0;
 240
 241                Outer : while Lo < Hi loop
 242                   Write_Str ("| ");
 243
 244                   Inner : loop
 245                      exit Inner when Src (Lo) = ASCII.CR
 246                        or else Src (Lo) = ASCII.LF;
 247                      Write_Char (Src (Lo));
 248                      Lo := Lo + 1;
 249                   end loop Inner;
 250
 251                   End_Line;
 252
 253                   while Lo <= Hi
 254                     and then (Src (Lo) = ASCII.CR
 255                                 or else Src (Lo) = ASCII.LF)
 256                   loop
 257                      Lo := Lo + 1;
 258                   end loop;
 259                end loop Outer;
 260
 261             --  Otherwise we use the standard fixed text
 262
 263             else
 264                if Is_FSF_Version then
 265                   Write_Str
 266                     ("| Please submit a bug report; see" &
 267                      " http://gcc.gnu.org/bugs.html.");
 268                   End_Line;
 269
 270                else
 271                   Write_Str
 272                     ("| Please submit bug report by email " &
 273                      "to report@gnat.com.");
 274                   End_Line;
 275
 276                   Write_Str
 277                     ("| Use a subject line meaningful to you" &
 278                      " and us to track the bug.");
 279                   End_Line;
 280                end if;
 281
 282                if not (Is_Public_Version or Is_FSF_Version) then
 283                   Write_Str
 284                     ("| (include your customer number #nnn " &
 285                      "in the subject line).");
 286                   End_Line;
 287                end if;
 288
 289                Write_Str
 290                  ("| Include the entire contents of this bug " &
 291                   "box in the report.");
 292                End_Line;
 293
 294                Write_Str
 295                  ("| Include the exact gcc or gnatmake command " &
 296                   "that you entered.");
 297                End_Line;
 298
 299                Write_Str
 300                  ("| Also include sources listed below in gnatchop format");
 301                End_Line;
 302
 303                Write_Str
 304                  ("| (concatenated together with no headers between files).");
 305                End_Line;
 306
 307                if Is_Public_Version then
 308                   Write_Str
 309                     ("| (use plain ASCII or MIME attachment).");
 310                   End_Line;
 311
 312                   Write_Str
 313                     ("| See gnatinfo.txt for full info on procedure " &
 314                      "for submitting bugs.");
 315                   End_Line;
 316
 317                elsif not Is_FSF_Version then
 318                   Write_Str
 319                     ("| (use plain ASCII or MIME attachment, or FTP "
 320                      & "to your customer directory).");
 321                   End_Line;
 322
 323                   Write_Str
 324                     ("| See README.GNATPRO for full info on procedure " &
 325                      "for submitting bugs.");
 326                   End_Line;
 327                end if;
 328             end if;
 329          end;
 330
 331          --  Complete output of bug box
 332
 333          Write_Char ('+');
 334          Repeat_Char ('=', 76, '+');
 335          Write_Eol;
 336
 337          if Debug_Flag_3 then
 338             Write_Eol;
 339             Write_Eol;
 340             Print_Tree_Node (Current_Error_Node);
 341             Write_Eol;
 342          end if;
 343
 344          Write_Eol;
 345
 346          Write_Line ("Please include these source files with error report");
 347          Write_Line ("Note that list may not be accurate in some cases, ");
 348          Write_Line ("so please double check that the problem can still ");
 349          Write_Line ("be reproduced with the set of files listed.");
 350          Write_Eol;
 351
 352          for U in Main_Unit .. Last_Unit loop
 353             begin
 354                if not Is_Internal_File_Name
 355                         (File_Name (Source_Index (U)))
 356                then
 357                   Write_Name (Full_File_Name (Source_Index (U)));
 358                   Write_Eol;
 359                end if;
 360
 361             --  No point in double bug box if we blow up trying to print
 362             --  the list of file names! Output informative msg and quit.
 363
 364             exception
 365                when others =>
 366                   Write_Str ("list may be incomplete");
 367                   exit;
 368             end;
 369          end loop;
 370
 371          Write_Eol;
 372          Set_Standard_Output;
 373
 374          Tree_Dump;
 375          Source_Dump;
 376          raise Unrecoverable_Error;
 377       end if;
 378
 379    end Compiler_Abort;
 380
 381    -----------------
 382    -- Repeat_Char --
 383    -----------------
 384
 385    procedure Repeat_Char (Char : Character; Col : Nat; After : Character) is
 386    begin
 387       while Column < Col loop
 388          Write_Char (Char);
 389       end loop;
 390
 391       Write_Char (After);
 392    end Repeat_Char;
 393
 394 end Comperr;