gcc/ada/s-carsi8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --         S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 8        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --             Copyright (C) 2002 Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Signed_8 is
  37
  38    type Word is mod 2 ** 32;
  39    --  Used to process operands by words
  40
  41    type Big_Words is array (Natural) of Word;
  42    type Big_Words_Ptr is access Big_Words;
  43    --  Array type used to access by words
  44
  45    type Byte is range -128 .. +127;
  46    for Byte'Size use 8;
  47    --  Used to process operands by bytes
  48
  49    type Big_Bytes is array (Natural) of Byte;
  50    type Big_Bytes_Ptr is access Big_Bytes;
  51    --  Array type used to access by bytes
  52
  53    function To_Big_Words is new
  54      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  55
  56    function To_Big_Bytes is new
  57      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  58
  59    ----------------------
  60    -- Compare_Array_S8 --
  61    ----------------------
  62
  63    function Compare_Array_S8
  64      (Left      : System.Address;
  65       Right     : System.Address;
  66       Left_Len  : Natural;
  67       Right_Len : Natural)
  68       return      Integer
  69    is
  70       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  71
  72    begin
  73       --  If operands are non-aligned, or length is too short, go by bytes
  74
  75       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  76          return Compare_Array_S8_Unaligned (Left, Right, Left_Len, Right_Len);
  77       end if;
  78
  79       --  Here we can go by words
  80
  81       declare
  82          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  83          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  84          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  85          Clen4F : constant Natural       := Clen4 * 4;
  86
  87       begin
  88          for J in 0 .. Clen4 loop
  89             if LeftP (J) /= RightP (J) then
  90                return Compare_Array_S8_Unaligned
  91                         (Left  + Address (4 * J),
  92                          Right + Address (4 * J),
  93                          4, 4);
  94             end if;
  95          end loop;
  96
  97          return Compare_Array_S8_Unaligned
  98                   (Left      + Address (Clen4F),
  99                    Right     + Address (Clen4F),
 100                    Left_Len  - Clen4F,
 101                    Right_Len - Clen4F);
 102       end;
 103    end Compare_Array_S8;
 104
 105    --------------------------------
 106    -- Compare_Array_S8_Unaligned --
 107    --------------------------------
 108
 109    function Compare_Array_S8_Unaligned
 110      (Left      : System.Address;
 111       Right     : System.Address;
 112       Left_Len  : Natural;
 113       Right_Len : Natural)
 114       return      Integer
 115    is
 116       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 117
 118       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 119       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 120
 121    begin
 122       for J in 0 .. Compare_Len - 1 loop
 123          if LeftP (J) /= RightP (J) then
 124             if LeftP (J) > RightP (J) then
 125                return +1;
 126             else
 127                return -1;
 128             end if;
 129          end if;
 130       end loop;
 131
 132       if Left_Len = Right_Len then
 133          return 0;
 134       elsif Left_Len > Right_Len then
 135          return +1;
 136       else
 137          return -1;
 138       end if;
 139    end Compare_Array_S8_Unaligned;
 140
 141 end System.Compare_Array_Signed_8;