]> git.ipfire.org Git - thirdparty/gcc.git/blob - gcc/c-parse.in
projects / thirdparty / gcc.git / blob
? search:
summary | shortlog | log | commit | commitdiff | tree
blame | history | raw | HEAD
alias.c [...]: Remove unnecessary casts.
[thirdparty/gcc.git] / gcc / c-parse.in
1 /* YACC parser for C syntax and for Objective C. -*-c-*-
2 Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996,
3 1997, 1998, 1999, 2000, 2001, 2002, 2003 Free Software Foundation, Inc.
4
5 This file is part of GCC.
6
7 GCC is free software; you can redistribute it and/or modify it under
8 the terms of the GNU General Public License as published by the Free
9 Software Foundation; either version 2, or (at your option) any later
10 version.
11
12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
14 FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
15 for more details.
16
17 You should have received a copy of the GNU General Public License
18 along with GCC; see the file COPYING. If not, write to the Free
19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
20 02111-1307, USA. */
21
22 /* This file defines the grammar of C and that of Objective C.
23 ifobjc ... end ifobjc conditionals contain code for Objective C only.
24 ifc ... end ifc conditionals contain code for C only.
25 Sed commands in Makefile.in are used to convert this file into
26 c-parse.y and into objc-parse.y. */
27
28 /* To whomever it may concern: I have heard that such a thing was once
29 written by AT&T, but I have never seen it. */
30
31 ifc
32 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts. */
33 end ifc
34
35 %{
36 #include "config.h"
37 #include "system.h"
38 #include "coretypes.h"
39 #include "tm.h"
40 #include "tree.h"
41 #include "input.h"
42 #include "cpplib.h"
43 #include "intl.h"
44 #include "timevar.h"
45 #include "c-pragma.h" /* For YYDEBUG definition, and parse_in. */
46 #include "c-tree.h"
47 #include "flags.h"
48 #include "varray.h"
49 #include "output.h"
50 #include "toplev.h"
51 #include "ggc.h"
52
53 ifobjc
54 #include "objc-act.h"
55 end ifobjc
56
57 /* Like YYERROR but do call yyerror. */
58 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
59
60 /* Like the default stack expander, except (1) use realloc when possible,
61 (2) impose no hard maxiumum on stack size, (3) REALLY do not use alloca.
62
63 Irritatingly, YYSTYPE is defined after this %{ %} block, so we cannot
64 give malloced_yyvs its proper type. This is ok since all we need from
65 it is to be able to free it. */
66
67 static short *malloced_yyss;
68 static void *malloced_yyvs;
69
70 #define yyoverflow(MSG, SS, SSSIZE, VS, VSSIZE, YYSSZ) \
71 do { \
72 size_t newsize; \
73 short *newss; \
74 YYSTYPE *newvs; \
75 newsize = *(YYSSZ) *= 2; \
76 if (malloced_yyss) \
77 { \
78 newss = really_call_realloc (*(SS), newsize * sizeof (short)); \
79 newvs = really_call_realloc (*(VS), newsize * sizeof (YYSTYPE)); \
80 } \
81 else \
82 { \
83 newss = really_call_malloc (newsize * sizeof (short)); \
84 newvs = really_call_malloc (newsize * sizeof (YYSTYPE)); \
85 if (newss) \
86 memcpy (newss, *(SS), (SSSIZE)); \
87 if (newvs) \
88 memcpy (newvs, *(VS), (VSSIZE)); \
89 } \
90 if (!newss || !newvs) \
91 { \
92 yyerror (MSG); \
93 return 2; \
94 } \
95 *(SS) = newss; \
96 *(VS) = newvs; \
97 malloced_yyss = newss; \
98 malloced_yyvs = (void *) newvs; \
99 } while (0)
100 %}
101
102 %start program
103
104 %union {long itype; tree ttype; enum tree_code code;
105 location_t location; }
106
107 /* All identifiers that are not reserved words
108 and are not declared typedefs in the current block */
109 %token IDENTIFIER
110
111 /* All identifiers that are declared typedefs in the current block.
112 In some contexts, they are treated just like IDENTIFIER,
113 but they can also serve as typespecs in declarations. */
114 %token TYPENAME
115
116 /* Reserved words that specify storage class.
117 yylval contains an IDENTIFIER_NODE which indicates which one. */
118 %token SCSPEC /* Storage class other than static. */
119 %token STATIC /* Static storage class. */
120
121 /* Reserved words that specify type.
122 yylval contains an IDENTIFIER_NODE which indicates which one. */
123 %token TYPESPEC
124
125 /* Reserved words that qualify type: "const", "volatile", or "restrict".
126 yylval contains an IDENTIFIER_NODE which indicates which one. */
127 %token TYPE_QUAL
128
129 /* Character or numeric constants.
130 yylval is the node for the constant. */
131 %token CONSTANT
132
133 /* String constants in raw form.
134 yylval is a STRING_CST node. */
135
136 %token STRING
137
138 /* "...", used for functions with variable arglists. */
139 %token ELLIPSIS
140
141 /* the reserved words */
142 /* SCO include files test "ASM", so use something else. */
143 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
144 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
145 %token ATTRIBUTE EXTENSION LABEL
146 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
147 %token PTR_VALUE PTR_BASE PTR_EXTENT
148 %token FUNC_NAME
149
150 /* Add precedence rules to solve dangling else s/r conflict */
151 %nonassoc IF
152 %nonassoc ELSE
153
154 /* Define the operator tokens and their precedences.
155 The value is an integer because, if used, it is the tree code
156 to use in the expression made from the operator. */
157
158 %right <code> ASSIGN '='
159 %right <code> '?' ':'
160 %left <code> OROR
161 %left <code> ANDAND
162 %left <code> '|'
163 %left <code> '^'
164 %left <code> '&'
165 %left <code> EQCOMPARE
166 %left <code> ARITHCOMPARE
167 %left <code> LSHIFT RSHIFT
168 %left <code> '+' '-'
169 %left <code> '*' '/' '%'
170 %right <code> UNARY PLUSPLUS MINUSMINUS
171 %left HYPERUNARY
172 %left <code> POINTSAT '.' '(' '['
173
174 /* The Objective-C keywords. These are included in C and in
175 Objective C, so that the token codes are the same in both. */
176 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
177 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
178 %token OBJC_STRING
179
180 %type <code> unop
181 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
182 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
183
184 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
185 %type <ttype> expr_no_commas cast_expr unary_expr primary STRING
186 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
187 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
188 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
189 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
190 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
191 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
192 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
193 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
194 %type <ttype> declspecs_ts declspecs_nots
195 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
196 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
197 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
198 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
199 %type <ttype> typespec_nonreserved_nonattr
200
201 %type <ttype> scspec SCSPEC STATIC TYPESPEC TYPE_QUAL maybe_type_qual
202 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl
203 %type <ttype> init maybeasm
204 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
205 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
206 %type <ttype> any_word extension
207
208 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
209 %type <ttype> do_stmt_start poplevel stmt label
210
211 %type <ttype> c99_block_start c99_block_end
212 %type <ttype> declarator
213 %type <ttype> notype_declarator after_type_declarator
214 %type <ttype> parm_declarator
215 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
216 %type <ttype> array_declarator
217
218 %type <ttype> structsp_attr structsp_nonattr
219 %type <ttype> component_decl_list component_decl_list2
220 %type <ttype> component_decl components components_notype component_declarator
221 %type <ttype> component_notype_declarator
222 %type <ttype> enumlist enumerator
223 %type <ttype> struct_head union_head enum_head
224 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
225 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
226 %type <ttype> xexpr parms parm firstparm identifiers
227
228 %type <ttype> parmlist parmlist_1 parmlist_2
229 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
230 %type <ttype> identifiers_or_typenames
231
232 %type <itype> setspecs setspecs_fp
233
234 %type <location> save_location
235 \f
236 ifobjc
237 /* the Objective-C nonterminals */
238
239 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
240 %type <ttype> methoddecl unaryselector keywordselector selector
241 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
242 %type <ttype> keywordexpr keywordarglist keywordarg
243 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
244 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
245 %type <ttype> non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
246
247 %type <ttype> CLASSNAME OBJECTNAME OBJC_STRING
248 end ifobjc
249 \f
250 %{
251 /* Number of statements (loosely speaking) and compound statements
252 seen so far. */
253 static int stmt_count;
254 static int compstmt_count;
255
256 /* Input location of the end of the body of last simple_if;
257 used by the stmt-rule immediately after simple_if returns. */
258 static location_t if_stmt_locus;
259
260
261 /* List of types and structure classes of the current declaration. */
262 static GTY(()) tree current_declspecs;
263 static GTY(()) tree prefix_attributes;
264
265 /* List of all the attributes applying to the identifier currently being
266 declared; includes prefix_attributes and possibly some more attributes
267 just after a comma. */
268 static GTY(()) tree all_prefix_attributes;
269
270 /* Stack of saved values of current_declspecs, prefix_attributes and
271 all_prefix_attributes. */
272 static GTY(()) tree declspec_stack;
273
274 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
275 should be called from the productions making use of setspecs. */
276 #define PUSH_DECLSPEC_STACK \
277 do { \
278 declspec_stack = tree_cons (build_tree_list (prefix_attributes, \
279 all_prefix_attributes), \
280 current_declspecs, \
281 declspec_stack); \
282 } while (0)
283
284 #define POP_DECLSPEC_STACK \
285 do { \
286 current_declspecs = TREE_VALUE (declspec_stack); \
287 prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack)); \
288 all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
289 declspec_stack = TREE_CHAIN (declspec_stack); \
290 } while (0)
291
292 /* For __extension__, save/restore the warning flags which are
293 controlled by __extension__. */
294 #define SAVE_EXT_FLAGS() \
295 size_int (pedantic \
296 | (warn_pointer_arith << 1) \
297 | (warn_traditional << 2) \
298 | (flag_iso << 3))
299
300 #define RESTORE_EXT_FLAGS(tval) \
301 do { \
302 int val = tree_low_cst (tval, 0); \
303 pedantic = val & 1; \
304 warn_pointer_arith = (val >> 1) & 1; \
305 warn_traditional = (val >> 2) & 1; \
306 flag_iso = (val >> 3) & 1; \
307 } while (0)
308
309 ifobjc
310 /* Objective-C specific parser/lexer information */
311
312 static enum tree_code objc_inherit_code;
313 static int objc_pq_context = 0, objc_public_flag = 0;
314
315 /* The following flag is needed to contextualize ObjC lexical analysis.
316 In some cases (e.g., 'int NSObject;'), it is undesirable to bind
317 an identifier to an ObjC class, even if a class with that name
318 exists. */
319 static int objc_need_raw_identifier;
320 #define OBJC_NEED_RAW_IDENTIFIER(VAL) objc_need_raw_identifier = VAL
321 end ifobjc
322
323 ifc
324 #define OBJC_NEED_RAW_IDENTIFIER(VAL) /* nothing */
325 end ifc
326
327 static bool parsing_iso_function_signature;
328
329 /* Tell yyparse how to print a token's value, if yydebug is set. */
330
331 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
332
333 static void yyprint (FILE *, int, YYSTYPE);
334 static void yyerror (const char *);
335 static int yylexname (void);
336 static inline int _yylex (void);
337 static int yylex (void);
338 static void init_reswords (void);
339
340 /* Initialisation routine for this file. */
341 void
342 c_parse_init (void)
343 {
344 init_reswords ();
345 }
346
347 %}
348 \f
349 %%
350 program: /* empty */
351 { if (pedantic)
352 pedwarn ("ISO C forbids an empty source file");
353 }
354 | extdefs
355 ;
356
357 /* the reason for the strange actions in this rule
358 is so that notype_initdecls when reached via datadef
359 can find a valid list of type and sc specs in $0. */
360
361 extdefs:
362 {$<ttype>$ = NULL_TREE; } extdef
363 | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
364 ;
365
366 extdef:
367 extdef_1
368 { parsing_iso_function_signature = false; } /* Reset after any external definition. */
369 ;
370
371 extdef_1:
372 fndef
373 | datadef
374 ifobjc
375 | objcdef
376 end ifobjc
377 | ASM_KEYWORD '(' expr ')' ';'
378 { STRIP_NOPS ($3);
379 if ((TREE_CODE ($3) == ADDR_EXPR
380 && TREE_CODE (TREE_OPERAND ($3, 0)) == STRING_CST)
381 || TREE_CODE ($3) == STRING_CST)
382 assemble_asm ($3);
383 else
384 error ("argument of `asm' is not a constant string"); }
385 | extension extdef
386 { RESTORE_EXT_FLAGS ($1); }
387 ;
388
389 datadef:
390 setspecs notype_initdecls ';'
391 { if (pedantic)
392 error ("ISO C forbids data definition with no type or storage class");
393 else
394 warning ("data definition has no type or storage class");
395
396 POP_DECLSPEC_STACK; }
397 | declspecs_nots setspecs notype_initdecls ';'
398 { POP_DECLSPEC_STACK; }
399 | declspecs_ts setspecs initdecls ';'
400 { POP_DECLSPEC_STACK; }
401 | declspecs ';'
402 { shadow_tag ($1); }
403 | error ';'
404 | error '}'
405 | ';'
406 { if (pedantic)
407 pedwarn ("ISO C does not allow extra `;' outside of a function"); }
408 ;
409 \f
410 fndef:
411 declspecs_ts setspecs declarator
412 { if (! start_function (current_declspecs, $3,
413 all_prefix_attributes))
414 YYERROR1;
415 }
416 old_style_parm_decls save_location
417 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
418 store_parm_decls (); }
419 compstmt_or_error
420 { finish_function (0, 1);
421 POP_DECLSPEC_STACK; }
422 | declspecs_ts setspecs declarator error
423 { POP_DECLSPEC_STACK; }
424 | declspecs_nots setspecs notype_declarator
425 { if (! start_function (current_declspecs, $3,
426 all_prefix_attributes))
427 YYERROR1;
428 }
429 old_style_parm_decls save_location
430 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
431 store_parm_decls (); }
432 compstmt_or_error
433 { finish_function (0, 1);
434 POP_DECLSPEC_STACK; }
435 | declspecs_nots setspecs notype_declarator error
436 { POP_DECLSPEC_STACK; }
437 | setspecs notype_declarator
438 { if (! start_function (NULL_TREE, $2,
439 all_prefix_attributes))
440 YYERROR1;
441 }
442 old_style_parm_decls save_location
443 { DECL_SOURCE_LOCATION (current_function_decl) = $5;
444 store_parm_decls (); }
445 compstmt_or_error
446 { finish_function (0, 1);
447 POP_DECLSPEC_STACK; }
448 | setspecs notype_declarator error
449 { POP_DECLSPEC_STACK; }
450 ;
451
452 identifier:
453 IDENTIFIER
454 | TYPENAME
455 ifobjc
456 | OBJECTNAME
457 | CLASSNAME
458 end ifobjc
459 ;
460
461 unop: '&'
462 { $$ = ADDR_EXPR; }
463 | '-'
464 { $$ = NEGATE_EXPR; }
465 | '+'
466 { $$ = CONVERT_EXPR;
467 ifc
468 if (warn_traditional && !in_system_header)
469 warning ("traditional C rejects the unary plus operator");
470 end ifc
471 }
472 | PLUSPLUS
473 { $$ = PREINCREMENT_EXPR; }
474 | MINUSMINUS
475 { $$ = PREDECREMENT_EXPR; }
476 | '~'
477 { $$ = BIT_NOT_EXPR; }
478 | '!'
479 { $$ = TRUTH_NOT_EXPR; }
480 ;
481
482 expr: nonnull_exprlist
483 { $$ = build_compound_expr ($1); }
484 ;
485
486 exprlist:
487 /* empty */
488 { $$ = NULL_TREE; }
489 | nonnull_exprlist
490 ;
491
492 nonnull_exprlist:
493 expr_no_commas
494 { $$ = build_tree_list (NULL_TREE, $1); }
495 | nonnull_exprlist ',' expr_no_commas
496 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
497 ;
498
499 unary_expr:
500 primary
501 | '*' cast_expr %prec UNARY
502 { $$ = build_indirect_ref ($2, "unary *"); }
503 /* __extension__ turns off -pedantic for following primary. */
504 | extension cast_expr %prec UNARY
505 { $$ = $2;
506 RESTORE_EXT_FLAGS ($1); }
507 | unop cast_expr %prec UNARY
508 { $$ = build_unary_op ($1, $2, 0);
509 overflow_warning ($$); }
510 /* Refer to the address of a label as a pointer. */
511 | ANDAND identifier
512 { $$ = finish_label_address_expr ($2); }
513 | sizeof unary_expr %prec UNARY
514 { skip_evaluation--;
515 if (TREE_CODE ($2) == COMPONENT_REF
516 && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
517 error ("`sizeof' applied to a bit-field");
518 $$ = c_sizeof (TREE_TYPE ($2)); }
519 | sizeof '(' typename ')' %prec HYPERUNARY
520 { skip_evaluation--;
521 $$ = c_sizeof (groktypename ($3)); }
522 | alignof unary_expr %prec UNARY
523 { skip_evaluation--;
524 $$ = c_alignof_expr ($2); }
525 | alignof '(' typename ')' %prec HYPERUNARY
526 { skip_evaluation--;
527 $$ = c_alignof (groktypename ($3)); }
528 | REALPART cast_expr %prec UNARY
529 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
530 | IMAGPART cast_expr %prec UNARY
531 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
532 ;
533
534 sizeof:
535 SIZEOF { skip_evaluation++; }
536 ;
537
538 alignof:
539 ALIGNOF { skip_evaluation++; }
540 ;
541
542 typeof:
543 TYPEOF { skip_evaluation++; }
544 ;
545
546 cast_expr:
547 unary_expr
548 | '(' typename ')' cast_expr %prec UNARY
549 { $$ = c_cast_expr ($2, $4); }
550 ;
551
552 expr_no_commas:
553 cast_expr
554 | expr_no_commas '+' expr_no_commas
555 { $$ = parser_build_binary_op ($2, $1, $3); }
556 | expr_no_commas '-' expr_no_commas
557 { $$ = parser_build_binary_op ($2, $1, $3); }
558 | expr_no_commas '*' expr_no_commas
559 { $$ = parser_build_binary_op ($2, $1, $3); }
560 | expr_no_commas '/' expr_no_commas
561 { $$ = parser_build_binary_op ($2, $1, $3); }
562 | expr_no_commas '%' expr_no_commas
563 { $$ = parser_build_binary_op ($2, $1, $3); }
564 | expr_no_commas LSHIFT expr_no_commas
565 { $$ = parser_build_binary_op ($2, $1, $3); }
566 | expr_no_commas RSHIFT expr_no_commas
567 { $$ = parser_build_binary_op ($2, $1, $3); }
568 | expr_no_commas ARITHCOMPARE expr_no_commas
569 { $$ = parser_build_binary_op ($2, $1, $3); }
570 | expr_no_commas EQCOMPARE expr_no_commas
571 { $$ = parser_build_binary_op ($2, $1, $3); }
572 | expr_no_commas '&' expr_no_commas
573 { $$ = parser_build_binary_op ($2, $1, $3); }
574 | expr_no_commas '|' expr_no_commas
575 { $$ = parser_build_binary_op ($2, $1, $3); }
576 | expr_no_commas '^' expr_no_commas
577 { $$ = parser_build_binary_op ($2, $1, $3); }
578 | expr_no_commas ANDAND
579 { $1 = c_common_truthvalue_conversion
580 (default_conversion ($1));
581 skip_evaluation += $1 == boolean_false_node; }
582 expr_no_commas
583 { skip_evaluation -= $1 == boolean_false_node;
584 $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
585 | expr_no_commas OROR
586 { $1 = c_common_truthvalue_conversion
587 (default_conversion ($1));
588 skip_evaluation += $1 == boolean_true_node; }
589 expr_no_commas
590 { skip_evaluation -= $1 == boolean_true_node;
591 $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
592 | expr_no_commas '?'
593 { $1 = c_common_truthvalue_conversion
594 (default_conversion ($1));
595 skip_evaluation += $1 == boolean_false_node; }
596 expr ':'
597 { skip_evaluation += (($1 == boolean_true_node)
598 - ($1 == boolean_false_node)); }
599 expr_no_commas
600 { skip_evaluation -= $1 == boolean_true_node;
601 $$ = build_conditional_expr ($1, $4, $7); }
602 | expr_no_commas '?'
603 { if (pedantic)
604 pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
605 /* Make sure first operand is calculated only once. */
606 $<ttype>2 = save_expr ($1);
607 $1 = c_common_truthvalue_conversion
608 (default_conversion ($<ttype>2));
609 skip_evaluation += $1 == boolean_true_node; }
610 ':' expr_no_commas
611 { skip_evaluation -= $1 == boolean_true_node;
612 $$ = build_conditional_expr ($1, $<ttype>2, $5); }
613 | expr_no_commas '=' expr_no_commas
614 { char class;
615 $$ = build_modify_expr ($1, NOP_EXPR, $3);
616 class = TREE_CODE_CLASS (TREE_CODE ($$));
617 if (IS_EXPR_CODE_CLASS (class))
618 C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
619 }
620 | expr_no_commas ASSIGN expr_no_commas
621 { char class;
622 $$ = build_modify_expr ($1, $2, $3);
623 /* This inhibits warnings in
624 c_common_truthvalue_conversion. */
625 class = TREE_CODE_CLASS (TREE_CODE ($$));
626 if (IS_EXPR_CODE_CLASS (class))
627 C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
628 }
629 ;
630
631 primary:
632 IDENTIFIER
633 {
634 if (yychar == YYEMPTY)
635 yychar = YYLEX;
636 $$ = build_external_ref ($1, yychar == '(');
637 }
638 | CONSTANT
639 | STRING
640 | FUNC_NAME
641 { $$ = fname_decl (C_RID_CODE ($$), $$); }
642 | '(' typename ')' '{'
643 { start_init (NULL_TREE, NULL, 0);
644 $2 = groktypename ($2);
645 really_start_incremental_init ($2); }
646 initlist_maybe_comma '}' %prec UNARY
647 { tree constructor = pop_init_level (0);
648 tree type = $2;
649 finish_init ();
650
651 if (pedantic && ! flag_isoc99)
652 pedwarn ("ISO C89 forbids compound literals");
653 $$ = build_compound_literal (type, constructor);
654 }
655 | '(' expr ')'
656 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
657 if (IS_EXPR_CODE_CLASS (class))
658 C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
659 $$ = $2; }
660 | '(' error ')'
661 { $$ = error_mark_node; }
662 | compstmt_primary_start compstmt_nostart ')'
663 { tree saved_last_tree;
664
665 if (pedantic)
666 pedwarn ("ISO C forbids braced-groups within expressions");
667 pop_label_level ();
668
669 saved_last_tree = COMPOUND_BODY ($1);
670 RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
671 last_tree = saved_last_tree;
672 TREE_CHAIN (last_tree) = NULL_TREE;
673 if (!last_expr_type)
674 last_expr_type = void_type_node;
675 $$ = build1 (STMT_EXPR, last_expr_type, $1);
676 TREE_SIDE_EFFECTS ($$) = 1;
677 }
678 | compstmt_primary_start error ')'
679 {
680 pop_label_level ();
681 last_tree = COMPOUND_BODY ($1);
682 TREE_CHAIN (last_tree) = NULL_TREE;
683 $$ = error_mark_node;
684 }
685 | primary '(' exprlist ')' %prec '.'
686 { $$ = build_function_call ($1, $3); }
687 | VA_ARG '(' expr_no_commas ',' typename ')'
688 { $$ = build_va_arg ($3, groktypename ($5)); }
689
690 | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ',' expr_no_commas ')'
691 {
692 tree c;
693
694 c = fold ($3);
695 STRIP_NOPS (c);
696 if (TREE_CODE (c) != INTEGER_CST)
697 error ("first argument to __builtin_choose_expr not a constant");
698 $$ = integer_zerop (c) ? $7 : $5;
699 }
700 | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
701 {
702 tree e1, e2;
703
704 e1 = TYPE_MAIN_VARIANT (groktypename ($3));
705 e2 = TYPE_MAIN_VARIANT (groktypename ($5));
706
707 $$ = comptypes (e1, e2, COMPARE_STRICT)
708 ? build_int_2 (1, 0) : build_int_2 (0, 0);
709 }
710 | primary '[' expr ']' %prec '.'
711 { $$ = build_array_ref ($1, $3); }
712 | primary '.' identifier
713 {
714 ifobjc
715 if (!is_public ($1, $3))
716 $$ = error_mark_node;
717 else
718 end ifobjc
719 $$ = build_component_ref ($1, $3);
720 }
721 | primary POINTSAT identifier
722 {
723 tree expr = build_indirect_ref ($1, "->");
724
725 ifobjc
726 if (!is_public (expr, $3))
727 $$ = error_mark_node;
728 else
729 end ifobjc
730 $$ = build_component_ref (expr, $3);
731 }
732 | primary PLUSPLUS
733 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
734 | primary MINUSMINUS
735 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
736 ifobjc
737 | objcmessageexpr
738 { $$ = build_message_expr ($1); }
739 | objcselectorexpr
740 { $$ = build_selector_expr ($1); }
741 | objcprotocolexpr
742 { $$ = build_protocol_expr ($1); }
743 | objcencodeexpr
744 { $$ = build_encode_expr ($1); }
745 | OBJC_STRING
746 { $$ = build_objc_string_object ($1); }
747 end ifobjc
748 ;
749
750 old_style_parm_decls:
751 old_style_parm_decls_1
752 {
753 parsing_iso_function_signature = false; /* Reset after decls. */
754 }
755 ;
756
757 old_style_parm_decls_1:
758 /* empty */
759 {
760 if (warn_traditional && !in_system_header
761 && parsing_iso_function_signature)
762 warning ("traditional C rejects ISO C style function definitions");
763 parsing_iso_function_signature = false; /* Reset after warning. */
764 }
765 | datadecls
766 ;
767
768 /* The following are analogous to lineno_decl, decls and decl
769 except that they do not allow nested functions.
770 They are used for old-style parm decls. */
771 lineno_datadecl:
772 save_location datadecl
773 { }
774 ;
775
776 datadecls:
777 lineno_datadecl
778 | errstmt
779 | datadecls lineno_datadecl
780 | lineno_datadecl errstmt
781 ;
782
783 /* We don't allow prefix attributes here because they cause reduce/reduce
784 conflicts: we can't know whether we're parsing a function decl with
785 attribute suffix, or function defn with attribute prefix on first old
786 style parm. */
787 datadecl:
788 declspecs_ts_nosa setspecs initdecls ';'
789 { POP_DECLSPEC_STACK; }
790 | declspecs_nots_nosa setspecs notype_initdecls ';'
791 { POP_DECLSPEC_STACK; }
792 | declspecs_ts_nosa ';'
793 { shadow_tag_warned ($1, 1);
794 pedwarn ("empty declaration"); }
795 | declspecs_nots_nosa ';'
796 { pedwarn ("empty declaration"); }
797 ;
798
799 /* This combination which saves a lineno before a decl
800 is the normal thing to use, rather than decl itself.
801 This is to avoid shift/reduce conflicts in contexts
802 where statement labels are allowed. */
803 lineno_decl:
804 save_location decl
805 { }
806 ;
807
808 /* records the type and storage class specs to use for processing
809 the declarators that follow.
810 Maintains a stack of outer-level values of current_declspecs,
811 for the sake of parm declarations nested in function declarators. */
812 setspecs: /* empty */
813 { pending_xref_error ();
814 PUSH_DECLSPEC_STACK;
815 split_specs_attrs ($<ttype>0,
816 &current_declspecs, &prefix_attributes);
817 all_prefix_attributes = prefix_attributes; }
818 ;
819
820 /* Possibly attributes after a comma, which should reset all_prefix_attributes
821 to prefix_attributes with these ones chained on the front. */
822 maybe_resetattrs:
823 maybe_attribute
824 { all_prefix_attributes = chainon ($1, prefix_attributes); }
825 ;
826
827 decl:
828 declspecs_ts setspecs initdecls ';'
829 { POP_DECLSPEC_STACK; }
830 | declspecs_nots setspecs notype_initdecls ';'
831 { POP_DECLSPEC_STACK; }
832 | declspecs_ts setspecs nested_function
833 { POP_DECLSPEC_STACK; }
834 | declspecs_nots setspecs notype_nested_function
835 { POP_DECLSPEC_STACK; }
836 | declspecs ';'
837 { shadow_tag ($1); }
838 | extension decl
839 { RESTORE_EXT_FLAGS ($1); }
840 ;
841
842 /* A list of declaration specifiers. These are:
843
844 - Storage class specifiers (scspec), which for GCC currently includes
845 function specifiers ("inline").
846
847 - Type specifiers (typespec_*).
848
849 - Type qualifiers (TYPE_QUAL).
850
851 - Attribute specifier lists (attributes).
852
853 These are stored as a TREE_LIST; the head of the list is the last
854 item in the specifier list. Each entry in the list has either a
855 TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
856 is a single other specifier or qualifier; and a TREE_CHAIN that is the
857 rest of the list. TREE_STATIC is set on the list if something other
858 than a storage class specifier or attribute has been seen; this is used
859 to warn for the obsolescent usage of storage class specifiers other than
860 at the start of the list. (Doing this properly would require function
861 specifiers to be handled separately from storage class specifiers.)
862
863 The various cases below are classified according to:
864
865 (a) Whether a storage class specifier is included or not; some
866 places in the grammar disallow storage class specifiers (_sc or _nosc).
867
868 (b) Whether a type specifier has been seen; after a type specifier,
869 a typedef name is an identifier to redeclare (_ts or _nots).
870
871 (c) Whether the list starts with an attribute; in certain places,
872 the grammar requires specifiers that don't start with an attribute
873 (_sa or _nosa).
874
875 (d) Whether the list ends with an attribute (or a specifier such that
876 any following attribute would have been parsed as part of that specifier);
877 this avoids shift-reduce conflicts in the parsing of attributes
878 (_ea or _noea).
879
880 TODO:
881
882 (i) Distinguish between function specifiers and storage class specifiers,
883 at least for the purpose of warnings about obsolescent usage.
884
885 (ii) Halve the number of productions here by eliminating the _sc/_nosc
886 distinction and instead checking where required that storage class
887 specifiers aren't present. */
888
889 /* Declspecs which contain at least one type specifier or typedef name.
890 (Just `const' or `volatile' is not enough.)
891 A typedef'd name following these is taken as a name to be declared.
892 Declspecs have a non-NULL TREE_VALUE, attributes do not. */
893
894 declspecs_nosc_nots_nosa_noea:
895 TYPE_QUAL
896 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
897 TREE_STATIC ($$) = 1; }
898 | declspecs_nosc_nots_nosa_noea TYPE_QUAL
899 { $$ = tree_cons (NULL_TREE, $2, $1);
900 TREE_STATIC ($$) = 1; }
901 | declspecs_nosc_nots_nosa_ea TYPE_QUAL
902 { $$ = tree_cons (NULL_TREE, $2, $1);
903 TREE_STATIC ($$) = 1; }
904 ;
905
906 declspecs_nosc_nots_nosa_ea:
907 declspecs_nosc_nots_nosa_noea attributes
908 { $$ = tree_cons ($2, NULL_TREE, $1);
909 TREE_STATIC ($$) = TREE_STATIC ($1); }
910 ;
911
912 declspecs_nosc_nots_sa_noea:
913 declspecs_nosc_nots_sa_noea TYPE_QUAL
914 { $$ = tree_cons (NULL_TREE, $2, $1);
915 TREE_STATIC ($$) = 1; }
916 | declspecs_nosc_nots_sa_ea TYPE_QUAL
917 { $$ = tree_cons (NULL_TREE, $2, $1);
918 TREE_STATIC ($$) = 1; }
919 ;
920
921 declspecs_nosc_nots_sa_ea:
922 attributes
923 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
924 TREE_STATIC ($$) = 0; }
925 | declspecs_nosc_nots_sa_noea attributes
926 { $$ = tree_cons ($2, NULL_TREE, $1);
927 TREE_STATIC ($$) = TREE_STATIC ($1); }
928 ;
929
930 declspecs_nosc_ts_nosa_noea:
931 typespec_nonattr
932 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
933 TREE_STATIC ($$) = 1; }
934 | declspecs_nosc_ts_nosa_noea TYPE_QUAL
935 { $$ = tree_cons (NULL_TREE, $2, $1);
936 TREE_STATIC ($$) = 1; }
937 | declspecs_nosc_ts_nosa_ea TYPE_QUAL
938 { $$ = tree_cons (NULL_TREE, $2, $1);
939 TREE_STATIC ($$) = 1; }
940 | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
941 { $$ = tree_cons (NULL_TREE, $2, $1);
942 TREE_STATIC ($$) = 1; }
943 | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
944 { $$ = tree_cons (NULL_TREE, $2, $1);
945 TREE_STATIC ($$) = 1; }
946 | declspecs_nosc_nots_nosa_noea typespec_nonattr
947 { $$ = tree_cons (NULL_TREE, $2, $1);
948 TREE_STATIC ($$) = 1; }
949 | declspecs_nosc_nots_nosa_ea typespec_nonattr
950 { $$ = tree_cons (NULL_TREE, $2, $1);
951 TREE_STATIC ($$) = 1; }
952 ;
953
954 declspecs_nosc_ts_nosa_ea:
955 typespec_attr
956 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
957 TREE_STATIC ($$) = 1; }
958 | declspecs_nosc_ts_nosa_noea attributes
959 { $$ = tree_cons ($2, NULL_TREE, $1);
960 TREE_STATIC ($$) = TREE_STATIC ($1); }
961 | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
962 { $$ = tree_cons (NULL_TREE, $2, $1);
963 TREE_STATIC ($$) = 1; }
964 | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
965 { $$ = tree_cons (NULL_TREE, $2, $1);
966 TREE_STATIC ($$) = 1; }
967 | declspecs_nosc_nots_nosa_noea typespec_attr
968 { $$ = tree_cons (NULL_TREE, $2, $1);
969 TREE_STATIC ($$) = 1; }
970 | declspecs_nosc_nots_nosa_ea typespec_attr
971 { $$ = tree_cons (NULL_TREE, $2, $1);
972 TREE_STATIC ($$) = 1; }
973 ;
974
975 declspecs_nosc_ts_sa_noea:
976 declspecs_nosc_ts_sa_noea TYPE_QUAL
977 { $$ = tree_cons (NULL_TREE, $2, $1);
978 TREE_STATIC ($$) = 1; }
979 | declspecs_nosc_ts_sa_ea TYPE_QUAL
980 { $$ = tree_cons (NULL_TREE, $2, $1);
981 TREE_STATIC ($$) = 1; }
982 | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
983 { $$ = tree_cons (NULL_TREE, $2, $1);
984 TREE_STATIC ($$) = 1; }
985 | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
986 { $$ = tree_cons (NULL_TREE, $2, $1);
987 TREE_STATIC ($$) = 1; }
988 | declspecs_nosc_nots_sa_noea typespec_nonattr
989 { $$ = tree_cons (NULL_TREE, $2, $1);
990 TREE_STATIC ($$) = 1; }
991 | declspecs_nosc_nots_sa_ea typespec_nonattr
992 { $$ = tree_cons (NULL_TREE, $2, $1);
993 TREE_STATIC ($$) = 1; }
994 ;
995
996 declspecs_nosc_ts_sa_ea:
997 declspecs_nosc_ts_sa_noea attributes
998 { $$ = tree_cons ($2, NULL_TREE, $1);
999 TREE_STATIC ($$) = TREE_STATIC ($1); }
1000 | declspecs_nosc_ts_sa_noea typespec_reserved_attr
1001 { $$ = tree_cons (NULL_TREE, $2, $1);
1002 TREE_STATIC ($$) = 1; }
1003 | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1004 { $$ = tree_cons (NULL_TREE, $2, $1);
1005 TREE_STATIC ($$) = 1; }
1006 | declspecs_nosc_nots_sa_noea typespec_attr
1007 { $$ = tree_cons (NULL_TREE, $2, $1);
1008 TREE_STATIC ($$) = 1; }
1009 | declspecs_nosc_nots_sa_ea typespec_attr
1010 { $$ = tree_cons (NULL_TREE, $2, $1);
1011 TREE_STATIC ($$) = 1; }
1012 ;
1013
1014 declspecs_sc_nots_nosa_noea:
1015 scspec
1016 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1017 TREE_STATIC ($$) = 0; }
1018 | declspecs_sc_nots_nosa_noea TYPE_QUAL
1019 { $$ = tree_cons (NULL_TREE, $2, $1);
1020 TREE_STATIC ($$) = 1; }
1021 | declspecs_sc_nots_nosa_ea TYPE_QUAL
1022 { $$ = tree_cons (NULL_TREE, $2, $1);
1023 TREE_STATIC ($$) = 1; }
1024 | declspecs_nosc_nots_nosa_noea scspec
1025 { if (extra_warnings && TREE_STATIC ($1))
1026 warning ("`%s' is not at beginning of declaration",
1027 IDENTIFIER_POINTER ($2));
1028 $$ = tree_cons (NULL_TREE, $2, $1);
1029 TREE_STATIC ($$) = TREE_STATIC ($1); }
1030 | declspecs_nosc_nots_nosa_ea scspec
1031 { if (extra_warnings && TREE_STATIC ($1))
1032 warning ("`%s' is not at beginning of declaration",
1033 IDENTIFIER_POINTER ($2));
1034 $$ = tree_cons (NULL_TREE, $2, $1);
1035 TREE_STATIC ($$) = TREE_STATIC ($1); }
1036 | declspecs_sc_nots_nosa_noea scspec
1037 { if (extra_warnings && TREE_STATIC ($1))
1038 warning ("`%s' is not at beginning of declaration",
1039 IDENTIFIER_POINTER ($2));
1040 $$ = tree_cons (NULL_TREE, $2, $1);
1041 TREE_STATIC ($$) = TREE_STATIC ($1); }
1042 | declspecs_sc_nots_nosa_ea scspec
1043 { if (extra_warnings && TREE_STATIC ($1))
1044 warning ("`%s' is not at beginning of declaration",
1045 IDENTIFIER_POINTER ($2));
1046 $$ = tree_cons (NULL_TREE, $2, $1);
1047 TREE_STATIC ($$) = TREE_STATIC ($1); }
1048 ;
1049
1050 declspecs_sc_nots_nosa_ea:
1051 declspecs_sc_nots_nosa_noea attributes
1052 { $$ = tree_cons ($2, NULL_TREE, $1);
1053 TREE_STATIC ($$) = TREE_STATIC ($1); }
1054 ;
1055
1056 declspecs_sc_nots_sa_noea:
1057 declspecs_sc_nots_sa_noea TYPE_QUAL
1058 { $$ = tree_cons (NULL_TREE, $2, $1);
1059 TREE_STATIC ($$) = 1; }
1060 | declspecs_sc_nots_sa_ea TYPE_QUAL
1061 { $$ = tree_cons (NULL_TREE, $2, $1);
1062 TREE_STATIC ($$) = 1; }
1063 | declspecs_nosc_nots_sa_noea scspec
1064 { if (extra_warnings && TREE_STATIC ($1))
1065 warning ("`%s' is not at beginning of declaration",
1066 IDENTIFIER_POINTER ($2));
1067 $$ = tree_cons (NULL_TREE, $2, $1);
1068 TREE_STATIC ($$) = TREE_STATIC ($1); }
1069 | declspecs_nosc_nots_sa_ea scspec
1070 { if (extra_warnings && TREE_STATIC ($1))
1071 warning ("`%s' is not at beginning of declaration",
1072 IDENTIFIER_POINTER ($2));
1073 $$ = tree_cons (NULL_TREE, $2, $1);
1074 TREE_STATIC ($$) = TREE_STATIC ($1); }
1075 | declspecs_sc_nots_sa_noea scspec
1076 { if (extra_warnings && TREE_STATIC ($1))
1077 warning ("`%s' is not at beginning of declaration",
1078 IDENTIFIER_POINTER ($2));
1079 $$ = tree_cons (NULL_TREE, $2, $1);
1080 TREE_STATIC ($$) = TREE_STATIC ($1); }
1081 | declspecs_sc_nots_sa_ea scspec
1082 { if (extra_warnings && TREE_STATIC ($1))
1083 warning ("`%s' is not at beginning of declaration",
1084 IDENTIFIER_POINTER ($2));
1085 $$ = tree_cons (NULL_TREE, $2, $1);
1086 TREE_STATIC ($$) = TREE_STATIC ($1); }
1087 ;
1088
1089 declspecs_sc_nots_sa_ea:
1090 declspecs_sc_nots_sa_noea attributes
1091 { $$ = tree_cons ($2, NULL_TREE, $1);
1092 TREE_STATIC ($$) = TREE_STATIC ($1); }
1093 ;
1094
1095 declspecs_sc_ts_nosa_noea:
1096 declspecs_sc_ts_nosa_noea TYPE_QUAL
1097 { $$ = tree_cons (NULL_TREE, $2, $1);
1098 TREE_STATIC ($$) = 1; }
1099 | declspecs_sc_ts_nosa_ea TYPE_QUAL
1100 { $$ = tree_cons (NULL_TREE, $2, $1);
1101 TREE_STATIC ($$) = 1; }
1102 | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1103 { $$ = tree_cons (NULL_TREE, $2, $1);
1104 TREE_STATIC ($$) = 1; }
1105 | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1106 { $$ = tree_cons (NULL_TREE, $2, $1);
1107 TREE_STATIC ($$) = 1; }
1108 | declspecs_sc_nots_nosa_noea typespec_nonattr
1109 { $$ = tree_cons (NULL_TREE, $2, $1);
1110 TREE_STATIC ($$) = 1; }
1111 | declspecs_sc_nots_nosa_ea typespec_nonattr
1112 { $$ = tree_cons (NULL_TREE, $2, $1);
1113 TREE_STATIC ($$) = 1; }
1114 | declspecs_nosc_ts_nosa_noea scspec
1115 { if (extra_warnings && TREE_STATIC ($1))
1116 warning ("`%s' is not at beginning of declaration",
1117 IDENTIFIER_POINTER ($2));
1118 $$ = tree_cons (NULL_TREE, $2, $1);
1119 TREE_STATIC ($$) = TREE_STATIC ($1); }
1120 | declspecs_nosc_ts_nosa_ea scspec
1121 { if (extra_warnings && TREE_STATIC ($1))
1122 warning ("`%s' is not at beginning of declaration",
1123 IDENTIFIER_POINTER ($2));
1124 $$ = tree_cons (NULL_TREE, $2, $1);
1125 TREE_STATIC ($$) = TREE_STATIC ($1); }
1126 | declspecs_sc_ts_nosa_noea scspec
1127 { if (extra_warnings && TREE_STATIC ($1))
1128 warning ("`%s' is not at beginning of declaration",
1129 IDENTIFIER_POINTER ($2));
1130 $$ = tree_cons (NULL_TREE, $2, $1);
1131 TREE_STATIC ($$) = TREE_STATIC ($1); }
1132 | declspecs_sc_ts_nosa_ea scspec
1133 { if (extra_warnings && TREE_STATIC ($1))
1134 warning ("`%s' is not at beginning of declaration",
1135 IDENTIFIER_POINTER ($2));
1136 $$ = tree_cons (NULL_TREE, $2, $1);
1137 TREE_STATIC ($$) = TREE_STATIC ($1); }
1138 ;
1139
1140 declspecs_sc_ts_nosa_ea:
1141 declspecs_sc_ts_nosa_noea attributes
1142 { $$ = tree_cons ($2, NULL_TREE, $1);
1143 TREE_STATIC ($$) = TREE_STATIC ($1); }
1144 | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1145 { $$ = tree_cons (NULL_TREE, $2, $1);
1146 TREE_STATIC ($$) = 1; }
1147 | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1148 { $$ = tree_cons (NULL_TREE, $2, $1);
1149 TREE_STATIC ($$) = 1; }
1150 | declspecs_sc_nots_nosa_noea typespec_attr
1151 { $$ = tree_cons (NULL_TREE, $2, $1);
1152 TREE_STATIC ($$) = 1; }
1153 | declspecs_sc_nots_nosa_ea typespec_attr
1154 { $$ = tree_cons (NULL_TREE, $2, $1);
1155 TREE_STATIC ($$) = 1; }
1156 ;
1157
1158 declspecs_sc_ts_sa_noea:
1159 declspecs_sc_ts_sa_noea TYPE_QUAL
1160 { $$ = tree_cons (NULL_TREE, $2, $1);
1161 TREE_STATIC ($$) = 1; }
1162 | declspecs_sc_ts_sa_ea TYPE_QUAL
1163 { $$ = tree_cons (NULL_TREE, $2, $1);
1164 TREE_STATIC ($$) = 1; }
1165 | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1166 { $$ = tree_cons (NULL_TREE, $2, $1);
1167 TREE_STATIC ($$) = 1; }
1168 | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1169 { $$ = tree_cons (NULL_TREE, $2, $1);
1170 TREE_STATIC ($$) = 1; }
1171 | declspecs_sc_nots_sa_noea typespec_nonattr
1172 { $$ = tree_cons (NULL_TREE, $2, $1);
1173 TREE_STATIC ($$) = 1; }
1174 | declspecs_sc_nots_sa_ea typespec_nonattr
1175 { $$ = tree_cons (NULL_TREE, $2, $1);
1176 TREE_STATIC ($$) = 1; }
1177 | declspecs_nosc_ts_sa_noea scspec
1178 { if (extra_warnings && TREE_STATIC ($1))
1179 warning ("`%s' is not at beginning of declaration",
1180 IDENTIFIER_POINTER ($2));
1181 $$ = tree_cons (NULL_TREE, $2, $1);
1182 TREE_STATIC ($$) = TREE_STATIC ($1); }
1183 | declspecs_nosc_ts_sa_ea scspec
1184 { if (extra_warnings && TREE_STATIC ($1))
1185 warning ("`%s' is not at beginning of declaration",
1186 IDENTIFIER_POINTER ($2));
1187 $$ = tree_cons (NULL_TREE, $2, $1);
1188 TREE_STATIC ($$) = TREE_STATIC ($1); }
1189 | declspecs_sc_ts_sa_noea scspec
1190 { if (extra_warnings && TREE_STATIC ($1))
1191 warning ("`%s' is not at beginning of declaration",
1192 IDENTIFIER_POINTER ($2));
1193 $$ = tree_cons (NULL_TREE, $2, $1);
1194 TREE_STATIC ($$) = TREE_STATIC ($1); }
1195 | declspecs_sc_ts_sa_ea scspec
1196 { if (extra_warnings && TREE_STATIC ($1))
1197 warning ("`%s' is not at beginning of declaration",
1198 IDENTIFIER_POINTER ($2));
1199 $$ = tree_cons (NULL_TREE, $2, $1);
1200 TREE_STATIC ($$) = TREE_STATIC ($1); }
1201 ;
1202
1203 declspecs_sc_ts_sa_ea:
1204 declspecs_sc_ts_sa_noea attributes
1205 { $$ = tree_cons ($2, NULL_TREE, $1);
1206 TREE_STATIC ($$) = TREE_STATIC ($1); }
1207 | declspecs_sc_ts_sa_noea typespec_reserved_attr
1208 { $$ = tree_cons (NULL_TREE, $2, $1);
1209 TREE_STATIC ($$) = 1; }
1210 | declspecs_sc_ts_sa_ea typespec_reserved_attr
1211 { $$ = tree_cons (NULL_TREE, $2, $1);
1212 TREE_STATIC ($$) = 1; }
1213 | declspecs_sc_nots_sa_noea typespec_attr
1214 { $$ = tree_cons (NULL_TREE, $2, $1);
1215 TREE_STATIC ($$) = 1; }
1216 | declspecs_sc_nots_sa_ea typespec_attr
1217 { $$ = tree_cons (NULL_TREE, $2, $1);
1218 TREE_STATIC ($$) = 1; }
1219 ;
1220
1221 /* Particular useful classes of declspecs. */
1222 declspecs_ts:
1223 declspecs_nosc_ts_nosa_noea
1224 | declspecs_nosc_ts_nosa_ea
1225 | declspecs_nosc_ts_sa_noea
1226 | declspecs_nosc_ts_sa_ea
1227 | declspecs_sc_ts_nosa_noea
1228 | declspecs_sc_ts_nosa_ea
1229 | declspecs_sc_ts_sa_noea
1230 | declspecs_sc_ts_sa_ea
1231 ;
1232
1233 declspecs_nots:
1234 declspecs_nosc_nots_nosa_noea
1235 | declspecs_nosc_nots_nosa_ea
1236 | declspecs_nosc_nots_sa_noea
1237 | declspecs_nosc_nots_sa_ea
1238 | declspecs_sc_nots_nosa_noea
1239 | declspecs_sc_nots_nosa_ea
1240 | declspecs_sc_nots_sa_noea
1241 | declspecs_sc_nots_sa_ea
1242 ;
1243
1244 declspecs_ts_nosa:
1245 declspecs_nosc_ts_nosa_noea
1246 | declspecs_nosc_ts_nosa_ea
1247 | declspecs_sc_ts_nosa_noea
1248 | declspecs_sc_ts_nosa_ea
1249 ;
1250
1251 declspecs_nots_nosa:
1252 declspecs_nosc_nots_nosa_noea
1253 | declspecs_nosc_nots_nosa_ea
1254 | declspecs_sc_nots_nosa_noea
1255 | declspecs_sc_nots_nosa_ea
1256 ;
1257
1258 declspecs_nosc_ts:
1259 declspecs_nosc_ts_nosa_noea
1260 | declspecs_nosc_ts_nosa_ea
1261 | declspecs_nosc_ts_sa_noea
1262 | declspecs_nosc_ts_sa_ea
1263 ;
1264
1265 declspecs_nosc_nots:
1266 declspecs_nosc_nots_nosa_noea
1267 | declspecs_nosc_nots_nosa_ea
1268 | declspecs_nosc_nots_sa_noea
1269 | declspecs_nosc_nots_sa_ea
1270 ;
1271
1272 declspecs_nosc:
1273 declspecs_nosc_ts_nosa_noea
1274 | declspecs_nosc_ts_nosa_ea
1275 | declspecs_nosc_ts_sa_noea
1276 | declspecs_nosc_ts_sa_ea
1277 | declspecs_nosc_nots_nosa_noea
1278 | declspecs_nosc_nots_nosa_ea
1279 | declspecs_nosc_nots_sa_noea
1280 | declspecs_nosc_nots_sa_ea
1281 ;
1282
1283 declspecs:
1284 declspecs_nosc_nots_nosa_noea
1285 | declspecs_nosc_nots_nosa_ea
1286 | declspecs_nosc_nots_sa_noea
1287 | declspecs_nosc_nots_sa_ea
1288 | declspecs_nosc_ts_nosa_noea
1289 | declspecs_nosc_ts_nosa_ea
1290 | declspecs_nosc_ts_sa_noea
1291 | declspecs_nosc_ts_sa_ea
1292 | declspecs_sc_nots_nosa_noea
1293 | declspecs_sc_nots_nosa_ea
1294 | declspecs_sc_nots_sa_noea
1295 | declspecs_sc_nots_sa_ea
1296 | declspecs_sc_ts_nosa_noea
1297 | declspecs_sc_ts_nosa_ea
1298 | declspecs_sc_ts_sa_noea
1299 | declspecs_sc_ts_sa_ea
1300 ;
1301
1302 /* A (possibly empty) sequence of type qualifiers and attributes. */
1303 maybe_type_quals_attrs:
1304 /* empty */
1305 { $$ = NULL_TREE; }
1306 | declspecs_nosc_nots
1307 { $$ = $1; }
1308 ;
1309
1310 /* A type specifier (but not a type qualifier).
1311 Once we have seen one of these in a declaration,
1312 if a typedef name appears then it is being redeclared.
1313
1314 The _reserved versions start with a reserved word and may appear anywhere
1315 in the declaration specifiers; the _nonreserved versions may only
1316 appear before any other type specifiers, and after that are (if names)
1317 being redeclared.
1318
1319 FIXME: should the _nonreserved version be restricted to names being
1320 redeclared only? The other entries there relate only the GNU extensions
1321 and Objective C, and are historically parsed thus, and don't make sense
1322 after other type specifiers, but it might be cleaner to count them as
1323 _reserved.
1324
1325 _attr means: specifiers that either end with attributes,
1326 or are such that any following attributes would
1327 be parsed as part of the specifier.
1328
1329 _nonattr: specifiers. */
1330
1331 typespec_nonattr:
1332 typespec_reserved_nonattr
1333 | typespec_nonreserved_nonattr
1334 ;
1335
1336 typespec_attr:
1337 typespec_reserved_attr
1338 ;
1339
1340 typespec_reserved_nonattr:
1341 TYPESPEC
1342 { OBJC_NEED_RAW_IDENTIFIER (1); }
1343 | structsp_nonattr
1344 ;
1345
1346 typespec_reserved_attr:
1347 structsp_attr
1348 ;
1349
1350 typespec_nonreserved_nonattr:
1351 TYPENAME
1352 { /* For a typedef name, record the meaning, not the name.
1353 In case of `foo foo, bar;'. */
1354 $$ = lookup_name ($1); }
1355 ifobjc
1356 | CLASSNAME protocolrefs
1357 { $$ = get_static_reference ($1, $2); }
1358 | OBJECTNAME protocolrefs
1359 { $$ = get_object_reference ($2); }
1360
1361 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1362 - nisse@lysator.liu.se */
1363 | non_empty_protocolrefs
1364 { $$ = get_object_reference ($1); }
1365 end ifobjc
1366 | typeof '(' expr ')'
1367 { skip_evaluation--; $$ = TREE_TYPE ($3); }
1368 | typeof '(' typename ')'
1369 { skip_evaluation--; $$ = groktypename ($3); }
1370 ;
1371
1372 /* typespec_nonreserved_attr does not exist. */
1373
1374 initdecls:
1375 initdcl
1376 | initdecls ',' maybe_resetattrs initdcl
1377 ;
1378
1379 notype_initdecls:
1380 notype_initdcl
1381 | notype_initdecls ',' maybe_resetattrs notype_initdcl
1382 ;
1383
1384 maybeasm:
1385 /* empty */
1386 { $$ = NULL_TREE; }
1387 | ASM_KEYWORD '(' STRING ')'
1388 { $$ = $3; }
1389 ;
1390
1391 initdcl:
1392 declarator maybeasm maybe_attribute '='
1393 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1394 chainon ($3, all_prefix_attributes));
1395 start_init ($<ttype>$, $2, global_bindings_p ()); }
1396 init
1397 /* Note how the declaration of the variable is in effect while its init is parsed! */
1398 { finish_init ();
1399 finish_decl ($<ttype>5, $6, $2); }
1400 | declarator maybeasm maybe_attribute
1401 { tree d = start_decl ($1, current_declspecs, 0,
1402 chainon ($3, all_prefix_attributes));
1403 finish_decl (d, NULL_TREE, $2);
1404 }
1405 ;
1406
1407 notype_initdcl:
1408 notype_declarator maybeasm maybe_attribute '='
1409 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1410 chainon ($3, all_prefix_attributes));
1411 start_init ($<ttype>$, $2, global_bindings_p ()); }
1412 init
1413 /* Note how the declaration of the variable is in effect while its init is parsed! */
1414 { finish_init ();
1415 finish_decl ($<ttype>5, $6, $2); }
1416 | notype_declarator maybeasm maybe_attribute
1417 { tree d = start_decl ($1, current_declspecs, 0,
1418 chainon ($3, all_prefix_attributes));
1419 finish_decl (d, NULL_TREE, $2); }
1420 ;
1421 /* the * rules are dummies to accept the Apollo extended syntax
1422 so that the header files compile. */
1423 maybe_attribute:
1424 /* empty */
1425 { $$ = NULL_TREE; }
1426 | attributes
1427 { $$ = $1; }
1428 ;
1429
1430 attributes:
1431 attribute
1432 { $$ = $1; }
1433 | attributes attribute
1434 { $$ = chainon ($1, $2); }
1435 ;
1436
1437 attribute:
1438 ATTRIBUTE '(' '(' attribute_list ')' ')'
1439 { $$ = $4; }
1440 ;
1441
1442 attribute_list:
1443 attrib
1444 { $$ = $1; }
1445 | attribute_list ',' attrib
1446 { $$ = chainon ($1, $3); }
1447 ;
1448
1449 attrib:
1450 /* empty */
1451 { $$ = NULL_TREE; }
1452 | any_word
1453 { $$ = build_tree_list ($1, NULL_TREE); }
1454 | any_word '(' IDENTIFIER ')'
1455 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1456 | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1457 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1458 | any_word '(' exprlist ')'
1459 { $$ = build_tree_list ($1, $3); }
1460 ;
1461
1462 /* This still leaves out most reserved keywords,
1463 shouldn't we include them? */
1464
1465 any_word:
1466 identifier
1467 | scspec
1468 | TYPESPEC
1469 | TYPE_QUAL
1470 ;
1471
1472 scspec:
1473 STATIC
1474 | SCSPEC
1475 ;
1476 \f
1477 /* Initializers. `init' is the entry point. */
1478
1479 init:
1480 expr_no_commas
1481 | '{'
1482 { really_start_incremental_init (NULL_TREE); }
1483 initlist_maybe_comma '}'
1484 { $$ = pop_init_level (0); }
1485 | error
1486 { $$ = error_mark_node; }
1487 ;
1488
1489 /* `initlist_maybe_comma' is the guts of an initializer in braces. */
1490 initlist_maybe_comma:
1491 /* empty */
1492 { if (pedantic)
1493 pedwarn ("ISO C forbids empty initializer braces"); }
1494 | initlist1 maybecomma
1495 ;
1496
1497 initlist1:
1498 initelt
1499 | initlist1 ',' initelt
1500 ;
1501
1502 /* `initelt' is a single element of an initializer.
1503 It may use braces. */
1504 initelt:
1505 designator_list '=' initval
1506 { if (pedantic && ! flag_isoc99)
1507 pedwarn ("ISO C89 forbids specifying subobject to initialize"); }
1508 | designator initval
1509 { if (pedantic)
1510 pedwarn ("obsolete use of designated initializer without `='"); }
1511 | identifier ':'
1512 { set_init_label ($1);
1513 if (pedantic)
1514 pedwarn ("obsolete use of designated initializer with `:'"); }
1515 initval
1516 {}
1517 | initval
1518 ;
1519
1520 initval:
1521 '{'
1522 { push_init_level (0); }
1523 initlist_maybe_comma '}'
1524 { process_init_element (pop_init_level (0)); }
1525 | expr_no_commas
1526 { process_init_element ($1); }
1527 | error
1528 ;
1529
1530 designator_list:
1531 designator
1532 | designator_list designator
1533 ;
1534
1535 designator:
1536 '.' identifier
1537 { set_init_label ($2); }
1538 | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1539 { set_init_index ($2, $4);
1540 if (pedantic)
1541 pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1542 | '[' expr_no_commas ']'
1543 { set_init_index ($2, NULL_TREE); }
1544 ;
1545 \f
1546 nested_function:
1547 declarator
1548 { if (pedantic)
1549 pedwarn ("ISO C forbids nested functions");
1550
1551 push_function_context ();
1552 if (! start_function (current_declspecs, $1,
1553 all_prefix_attributes))
1554 {
1555 pop_function_context ();
1556 YYERROR1;
1557 }
1558 parsing_iso_function_signature = false; /* Don't warn about nested functions. */
1559 }
1560 old_style_parm_decls save_location
1561 { tree decl = current_function_decl;
1562 DECL_SOURCE_LOCATION (decl) = $4;
1563 store_parm_decls (); }
1564 /* This used to use compstmt_or_error.
1565 That caused a bug with input `f(g) int g {}',
1566 where the use of YYERROR1 above caused an error
1567 which then was handled by compstmt_or_error.
1568 There followed a repeated execution of that same rule,
1569 which called YYERROR1 again, and so on. */
1570 compstmt
1571 { tree decl = current_function_decl;
1572 finish_function (1, 1);
1573 pop_function_context ();
1574 add_decl_stmt (decl); }
1575 ;
1576
1577 notype_nested_function:
1578 notype_declarator
1579 { if (pedantic)
1580 pedwarn ("ISO C forbids nested functions");
1581
1582 push_function_context ();
1583 if (! start_function (current_declspecs, $1,
1584 all_prefix_attributes))
1585 {
1586 pop_function_context ();
1587 YYERROR1;
1588 }
1589 parsing_iso_function_signature = false; /* Don't warn about nested functions. */
1590 }
1591 old_style_parm_decls save_location
1592 { tree decl = current_function_decl;
1593 DECL_SOURCE_LOCATION (decl) = $4;
1594 store_parm_decls (); }
1595 /* This used to use compstmt_or_error.
1596 That caused a bug with input `f(g) int g {}',
1597 where the use of YYERROR1 above caused an error
1598 which then was handled by compstmt_or_error.
1599 There followed a repeated execution of that same rule,
1600 which called YYERROR1 again, and so on. */
1601 compstmt
1602 { tree decl = current_function_decl;
1603 finish_function (1, 1);
1604 pop_function_context ();
1605 add_decl_stmt (decl); }
1606 ;
1607
1608 /* Any kind of declarator (thus, all declarators allowed
1609 after an explicit typespec). */
1610
1611 declarator:
1612 after_type_declarator
1613 | notype_declarator
1614 ;
1615
1616 /* A declarator that is allowed only after an explicit typespec. */
1617
1618 after_type_declarator:
1619 '(' maybe_attribute after_type_declarator ')'
1620 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1621 | after_type_declarator '(' parmlist_or_identifiers %prec '.'
1622 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1623 /* | after_type_declarator '(' error ')' %prec '.'
1624 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1625 poplevel (0, 0, 0); } */
1626 | after_type_declarator array_declarator %prec '.'
1627 { $$ = set_array_declarator_type ($2, $1, 0); }
1628 | '*' maybe_type_quals_attrs after_type_declarator %prec UNARY
1629 { $$ = make_pointer_declarator ($2, $3); }
1630 | TYPENAME
1631 ifobjc
1632 | OBJECTNAME
1633 end ifobjc
1634 ;
1635
1636 /* Kinds of declarator that can appear in a parameter list
1637 in addition to notype_declarator. This is like after_type_declarator
1638 but does not allow a typedef name in parentheses as an identifier
1639 (because it would conflict with a function with that typedef as arg). */
1640 parm_declarator:
1641 parm_declarator_starttypename
1642 | parm_declarator_nostarttypename
1643 ;
1644
1645 parm_declarator_starttypename:
1646 parm_declarator_starttypename '(' parmlist_or_identifiers %prec '.'
1647 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1648 /* | parm_declarator_starttypename '(' error ')' %prec '.'
1649 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1650 poplevel (0, 0, 0); } */
1651 | parm_declarator_starttypename array_declarator %prec '.'
1652 { $$ = set_array_declarator_type ($2, $1, 0); }
1653 | TYPENAME
1654 ifobjc
1655 | OBJECTNAME
1656 end ifobjc
1657 ;
1658
1659 parm_declarator_nostarttypename:
1660 parm_declarator_nostarttypename '(' parmlist_or_identifiers %prec '.'
1661 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1662 /* | parm_declarator_nostarttypename '(' error ')' %prec '.'
1663 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1664 poplevel (0, 0, 0); } */
1665 | parm_declarator_nostarttypename array_declarator %prec '.'
1666 { $$ = set_array_declarator_type ($2, $1, 0); }
1667 | '*' maybe_type_quals_attrs parm_declarator_starttypename %prec UNARY
1668 { $$ = make_pointer_declarator ($2, $3); }
1669 | '*' maybe_type_quals_attrs parm_declarator_nostarttypename %prec UNARY
1670 { $$ = make_pointer_declarator ($2, $3); }
1671 | '(' maybe_attribute parm_declarator_nostarttypename ')'
1672 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1673 ;
1674
1675 /* A declarator allowed whether or not there has been
1676 an explicit typespec. These cannot redeclare a typedef-name. */
1677
1678 notype_declarator:
1679 notype_declarator '(' parmlist_or_identifiers %prec '.'
1680 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1681 /* | notype_declarator '(' error ')' %prec '.'
1682 { $$ = build_nt (CALL_EXPR, $1, NULL_TREE, NULL_TREE);
1683 poplevel (0, 0, 0); } */
1684 | '(' maybe_attribute notype_declarator ')'
1685 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1686 | '*' maybe_type_quals_attrs notype_declarator %prec UNARY
1687 { $$ = make_pointer_declarator ($2, $3); }
1688 | notype_declarator array_declarator %prec '.'
1689 { $$ = set_array_declarator_type ($2, $1, 0); }
1690 | IDENTIFIER
1691 ;
1692
1693 struct_head:
1694 STRUCT
1695 { $$ = NULL_TREE; }
1696 | STRUCT attributes
1697 { $$ = $2; }
1698 ;
1699
1700 union_head:
1701 UNION
1702 { $$ = NULL_TREE; }
1703 | UNION attributes
1704 { $$ = $2; }
1705 ;
1706
1707 enum_head:
1708 ENUM
1709 { $$ = NULL_TREE; }
1710 | ENUM attributes
1711 { $$ = $2; }
1712 ;
1713
1714 /* structsp_attr: struct/union/enum specifiers that either
1715 end with attributes, or are such that any following attributes would
1716 be parsed as part of the struct/union/enum specifier.
1717
1718 structsp_nonattr: other struct/union/enum specifiers. */
1719
1720 structsp_attr:
1721 struct_head identifier '{'
1722 { $$ = start_struct (RECORD_TYPE, $2);
1723 /* Start scope of tag before parsing components. */
1724 }
1725 component_decl_list '}' maybe_attribute
1726 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1727 chainon ($1, $7)); }
1728 | struct_head '{' component_decl_list '}' maybe_attribute
1729 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1730 nreverse ($3), chainon ($1, $5));
1731 }
1732 | union_head identifier '{'
1733 { $$ = start_struct (UNION_TYPE, $2); }
1734 component_decl_list '}' maybe_attribute
1735 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1736 chainon ($1, $7)); }
1737 | union_head '{' component_decl_list '}' maybe_attribute
1738 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1739 nreverse ($3), chainon ($1, $5));
1740 }
1741 | enum_head identifier '{'
1742 { $$ = start_enum ($2); }
1743 enumlist maybecomma_warn '}' maybe_attribute
1744 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1745 chainon ($1, $8)); }
1746 | enum_head '{'
1747 { $$ = start_enum (NULL_TREE); }
1748 enumlist maybecomma_warn '}' maybe_attribute
1749 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1750 chainon ($1, $7)); }
1751 ;
1752
1753 structsp_nonattr:
1754 struct_head identifier
1755 { $$ = xref_tag (RECORD_TYPE, $2); }
1756 | union_head identifier
1757 { $$ = xref_tag (UNION_TYPE, $2); }
1758 | enum_head identifier
1759 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1760 /* In ISO C, enumerated types can be referred to
1761 only if already defined. */
1762 if (pedantic && !COMPLETE_TYPE_P ($$))
1763 pedwarn ("ISO C forbids forward references to `enum' types"); }
1764 ;
1765
1766 maybecomma:
1767 /* empty */
1768 | ','
1769 ;
1770
1771 maybecomma_warn:
1772 /* empty */
1773 | ','
1774 { if (pedantic && ! flag_isoc99)
1775 pedwarn ("comma at end of enumerator list"); }
1776 ;
1777
1778 /* We chain the components in reverse order. They are put in forward
1779 order in structsp_attr.
1780
1781 Note that component_declarator returns single decls, so components
1782 and components_notype can use TREE_CHAIN directly, wheras components
1783 and components_notype return lists (of comma separated decls), so
1784 component_decl_list and component_decl_list2 must use chainon.
1785
1786 The theory behind all this is that there will be more semicolon
1787 separated fields than comma separated fields, and so we'll be
1788 minimizing the number of node traversals required by chainon. */
1789
1790 component_decl_list:
1791 component_decl_list2
1792 { $$ = $1; }
1793 | component_decl_list2 component_decl
1794 { $$ = chainon ($2, $1);
1795 pedwarn ("no semicolon at end of struct or union"); }
1796 ;
1797
1798 component_decl_list2: /* empty */
1799 { $$ = NULL_TREE; }
1800 | component_decl_list2 component_decl ';'
1801 { $$ = chainon ($2, $1); }
1802 | component_decl_list2 ';'
1803 { if (pedantic)
1804 pedwarn ("extra semicolon in struct or union specified"); }
1805 ifobjc
1806 /* foo(sizeof(struct{ @defs(ClassName)})); */
1807 | DEFS '(' CLASSNAME ')'
1808 {
1809 tree interface = lookup_interface ($3);
1810
1811 if (interface)
1812 $$ = nreverse (get_class_ivars (interface));
1813 else
1814 {
1815 error ("cannot find interface declaration for `%s'",
1816 IDENTIFIER_POINTER ($3));
1817 $$ = NULL_TREE;
1818 }
1819 }
1820 end ifobjc
1821 ;
1822
1823 component_decl:
1824 declspecs_nosc_ts setspecs components
1825 { $$ = $3;
1826 POP_DECLSPEC_STACK; }
1827 | declspecs_nosc_ts setspecs
1828 {
1829 /* Support for unnamed structs or unions as members of
1830 structs or unions (which is [a] useful and [b] supports
1831 MS P-SDK). */
1832 if (pedantic)
1833 pedwarn ("ISO C doesn't support unnamed structs/unions");
1834
1835 $$ = grokfield(NULL, current_declspecs, NULL_TREE);
1836 POP_DECLSPEC_STACK; }
1837 | declspecs_nosc_nots setspecs components_notype
1838 { $$ = $3;
1839 POP_DECLSPEC_STACK; }
1840 | declspecs_nosc_nots
1841 { if (pedantic)
1842 pedwarn ("ISO C forbids member declarations with no members");
1843 shadow_tag_warned ($1, pedantic);
1844 $$ = NULL_TREE; }
1845 | error
1846 { $$ = NULL_TREE; }
1847 | extension component_decl
1848 { $$ = $2;
1849 RESTORE_EXT_FLAGS ($1); }
1850 ;
1851
1852 components:
1853 component_declarator
1854 | components ',' maybe_resetattrs component_declarator
1855 { TREE_CHAIN ($4) = $1; $$ = $4; }
1856 ;
1857
1858 components_notype:
1859 component_notype_declarator
1860 | components_notype ',' maybe_resetattrs component_notype_declarator
1861 { TREE_CHAIN ($4) = $1; $$ = $4; }
1862 ;
1863
1864 component_declarator:
1865 declarator maybe_attribute
1866 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1867 decl_attributes (&$$,
1868 chainon ($2, all_prefix_attributes), 0); }
1869 | declarator ':' expr_no_commas maybe_attribute
1870 { $$ = grokfield ($1, current_declspecs, $3);
1871 decl_attributes (&$$,
1872 chainon ($4, all_prefix_attributes), 0); }
1873 | ':' expr_no_commas maybe_attribute
1874 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1875 decl_attributes (&$$,
1876 chainon ($3, all_prefix_attributes), 0); }
1877 ;
1878
1879 component_notype_declarator:
1880 notype_declarator maybe_attribute
1881 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1882 decl_attributes (&$$,
1883 chainon ($2, all_prefix_attributes), 0); }
1884 | notype_declarator ':' expr_no_commas maybe_attribute
1885 { $$ = grokfield ($1, current_declspecs, $3);
1886 decl_attributes (&$$,
1887 chainon ($4, all_prefix_attributes), 0); }
1888 | ':' expr_no_commas maybe_attribute
1889 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1890 decl_attributes (&$$,
1891 chainon ($3, all_prefix_attributes), 0); }
1892 ;
1893
1894 /* We chain the enumerators in reverse order.
1895 They are put in forward order in structsp_attr. */
1896
1897 enumlist:
1898 enumerator
1899 | enumlist ',' enumerator
1900 { if ($1 == error_mark_node)
1901 $$ = $1;
1902 else
1903 TREE_CHAIN ($3) = $1, $$ = $3; }
1904 | error
1905 { $$ = error_mark_node; }
1906 ;
1907
1908
1909 enumerator:
1910 identifier
1911 { $$ = build_enumerator ($1, NULL_TREE); }
1912 | identifier '=' expr_no_commas
1913 { $$ = build_enumerator ($1, $3); }
1914 ;
1915
1916 typename:
1917 declspecs_nosc
1918 { pending_xref_error ();
1919 $<ttype>$ = $1; }
1920 absdcl
1921 { $$ = build_tree_list ($<ttype>2, $3); }
1922 ;
1923
1924 absdcl: /* an absolute declarator */
1925 /* empty */
1926 { $$ = NULL_TREE; }
1927 | absdcl1
1928 ;
1929
1930 absdcl_maybe_attribute: /* absdcl maybe_attribute, but not just attributes */
1931 /* empty */
1932 { $$ = build_tree_list (build_tree_list (current_declspecs,
1933 NULL_TREE),
1934 all_prefix_attributes); }
1935 | absdcl1
1936 { $$ = build_tree_list (build_tree_list (current_declspecs,
1937 $1),
1938 all_prefix_attributes); }
1939 | absdcl1_noea attributes
1940 { $$ = build_tree_list (build_tree_list (current_declspecs,
1941 $1),
1942 chainon ($2, all_prefix_attributes)); }
1943 ;
1944
1945 absdcl1: /* a nonempty absolute declarator */
1946 absdcl1_ea
1947 | absdcl1_noea
1948 ;
1949
1950 absdcl1_noea:
1951 direct_absdcl1
1952 | '*' maybe_type_quals_attrs absdcl1_noea
1953 { $$ = make_pointer_declarator ($2, $3); }
1954 ;
1955
1956 absdcl1_ea:
1957 '*' maybe_type_quals_attrs
1958 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1959 | '*' maybe_type_quals_attrs absdcl1_ea
1960 { $$ = make_pointer_declarator ($2, $3); }
1961 ;
1962
1963 direct_absdcl1:
1964 '(' maybe_attribute absdcl1 ')'
1965 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1966 | direct_absdcl1 '(' parmlist
1967 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1968 | direct_absdcl1 array_declarator
1969 { $$ = set_array_declarator_type ($2, $1, 1); }
1970 | '(' parmlist
1971 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1972 | array_declarator
1973 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1974 ;
1975
1976 /* The [...] part of a declarator for an array type. */
1977
1978 array_declarator:
1979 '[' maybe_type_quals_attrs expr ']'
1980 { $$ = build_array_declarator ($3, $2, 0, 0); }
1981 | '[' maybe_type_quals_attrs ']'
1982 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1983 | '[' maybe_type_quals_attrs '*' ']'
1984 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1985 | '[' STATIC maybe_type_quals_attrs expr ']'
1986 { $$ = build_array_declarator ($4, $3, 1, 0); }
1987 /* declspecs_nosc_nots is a synonym for type_quals_attrs. */
1988 | '[' declspecs_nosc_nots STATIC expr ']'
1989 { $$ = build_array_declarator ($4, $2, 1, 0); }
1990 ;
1991
1992 /* A nonempty series of declarations and statements (possibly followed by
1993 some labels) that can form the body of a compound statement.
1994 NOTE: we don't allow labels on declarations; this might seem like a
1995 natural extension, but there would be a conflict between attributes
1996 on the label and prefix attributes on the declaration. */
1997
1998 stmts_and_decls:
1999 lineno_stmt_decl_or_labels_ending_stmt
2000 | lineno_stmt_decl_or_labels_ending_decl
2001 | lineno_stmt_decl_or_labels_ending_label
2002 {
2003 pedwarn ("deprecated use of label at end of compound statement");
2004 }
2005 | lineno_stmt_decl_or_labels_ending_error
2006 ;
2007
2008 lineno_stmt_decl_or_labels_ending_stmt:
2009 lineno_stmt
2010 | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
2011 | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
2012 | lineno_stmt_decl_or_labels_ending_label lineno_stmt
2013 | lineno_stmt_decl_or_labels_ending_error lineno_stmt
2014 ;
2015
2016 lineno_stmt_decl_or_labels_ending_decl:
2017 lineno_decl
2018 | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
2019 { if (pedantic && !flag_isoc99)
2020 pedwarn ("ISO C89 forbids mixed declarations and code"); }
2021 | lineno_stmt_decl_or_labels_ending_decl lineno_decl
2022 | lineno_stmt_decl_or_labels_ending_error lineno_decl
2023 ;
2024
2025 lineno_stmt_decl_or_labels_ending_label:
2026 lineno_label
2027 | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2028 | lineno_stmt_decl_or_labels_ending_decl lineno_label
2029 | lineno_stmt_decl_or_labels_ending_label lineno_label
2030 | lineno_stmt_decl_or_labels_ending_error lineno_label
2031 ;
2032
2033 lineno_stmt_decl_or_labels_ending_error:
2034 errstmt
2035 | lineno_stmt_decl_or_labels errstmt
2036 ;
2037
2038 lineno_stmt_decl_or_labels:
2039 lineno_stmt_decl_or_labels_ending_stmt
2040 | lineno_stmt_decl_or_labels_ending_decl
2041 | lineno_stmt_decl_or_labels_ending_label
2042 | lineno_stmt_decl_or_labels_ending_error
2043 ;
2044
2045 errstmt: error ';'
2046 ;
2047
2048 pushlevel: /* empty */
2049 { pushlevel (0);
2050 clear_last_expr ();
2051 add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2052 ifobjc
2053 if (objc_method_context)
2054 add_objc_decls ();
2055 end ifobjc
2056 }
2057 ;
2058
2059 poplevel: /* empty */
2060 { $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0); }
2061 ;
2062
2063 /* Start and end blocks created for the new scopes of C99. */
2064 c99_block_start: /* empty */
2065 { if (flag_isoc99)
2066 {
2067 $$ = c_begin_compound_stmt ();
2068 pushlevel (0);
2069 clear_last_expr ();
2070 add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2071 ifobjc
2072 if (objc_method_context)
2073 add_objc_decls ();
2074 end ifobjc
2075 }
2076 else
2077 $$ = NULL_TREE;
2078 }
2079 ;
2080
2081 /* Productions using c99_block_start and c99_block_end will need to do what's
2082 in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2083 $1 is the value of c99_block_start and $2 of c99_block_end. */
2084 c99_block_end: /* empty */
2085 { if (flag_isoc99)
2086 {
2087 tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2088 $$ = poplevel (KEEP_MAYBE, 0, 0);
2089 SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2090 = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2091 = $$;
2092 }
2093 else
2094 $$ = NULL_TREE; }
2095 ;
2096
2097 /* Read zero or more forward-declarations for labels
2098 that nested functions can jump to. */
2099 maybe_label_decls:
2100 /* empty */
2101 | label_decls
2102 { if (pedantic)
2103 pedwarn ("ISO C forbids label declarations"); }
2104 ;
2105
2106 label_decls:
2107 label_decl
2108 | label_decls label_decl
2109 ;
2110
2111 label_decl:
2112 LABEL identifiers_or_typenames ';'
2113 { tree link;
2114 for (link = $2; link; link = TREE_CHAIN (link))
2115 {
2116 tree label = shadow_label (TREE_VALUE (link));
2117 C_DECLARED_LABEL_FLAG (label) = 1;
2118 add_decl_stmt (label);
2119 }
2120 }
2121 ;
2122
2123 /* This is the body of a function definition.
2124 It causes syntax errors to ignore to the next openbrace. */
2125 compstmt_or_error:
2126 compstmt
2127 {}
2128 | error compstmt
2129 ;
2130
2131 compstmt_start: '{' { compstmt_count++;
2132 $$ = c_begin_compound_stmt (); }
2133 ;
2134
2135 compstmt_nostart: '}'
2136 { $$ = convert (void_type_node, integer_zero_node); }
2137 | pushlevel maybe_label_decls compstmt_contents_nonempty '}' poplevel
2138 { $$ = poplevel (KEEP_MAYBE, 1, 0);
2139 SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2140 = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2141 = $$; }
2142 ;
2143
2144 compstmt_contents_nonempty:
2145 stmts_and_decls
2146 | error
2147 ;
2148
2149 compstmt_primary_start:
2150 '(' '{'
2151 { if (current_function_decl == 0)
2152 {
2153 error ("braced-group within expression allowed only inside a function");
2154 YYERROR;
2155 }
2156 /* We must force a BLOCK for this level
2157 so that, if it is not expanded later,
2158 there is a way to turn off the entire subtree of blocks
2159 that are contained in it. */
2160 keep_next_level ();
2161 push_label_level ();
2162 compstmt_count++;
2163 $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2164 }
2165 ;
2166
2167 compstmt: compstmt_start compstmt_nostart
2168 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2169 last_expr_type = NULL_TREE;
2170 $$ = $1; }
2171 ;
2172
2173 /* Value is number of statements counted as of the closeparen. */
2174 simple_if:
2175 if_prefix c99_block_lineno_labeled_stmt
2176 { c_finish_then (); }
2177 /* Make sure c_expand_end_cond is run once
2178 for each call to c_expand_start_cond.
2179 Otherwise a crash is likely. */
2180 | if_prefix error
2181 ;
2182
2183 if_prefix:
2184 /* We must build the IF_STMT node before parsing its
2185 condition so that STMT_LINENO refers to the line
2186 containing the "if", and not the line containing
2187 the close-parenthesis.
2188
2189 c_begin_if_stmt returns the IF_STMT node, which
2190 we later pass to c_expand_start_cond to fill
2191 in the condition and other tidbits. */
2192 IF
2193 { $<ttype>$ = c_begin_if_stmt (); }
2194 '(' expr ')'
2195 { c_expand_start_cond (c_common_truthvalue_conversion ($4),
2196 compstmt_count,$<ttype>2);
2197 $<itype>$ = stmt_count;
2198 if_stmt_locus = $<location>-1; }
2199 ;
2200
2201 /* This is a subroutine of stmt.
2202 It is used twice, once for valid DO statements
2203 and once for catching errors in parsing the end test. */
2204 do_stmt_start:
2205 DO
2206 { stmt_count++;
2207 compstmt_count++;
2208 $<ttype>$
2209 = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2210 NULL_TREE));
2211 /* In the event that a parse error prevents
2212 parsing the complete do-statement, set the
2213 condition now. Otherwise, we can get crashes at
2214 RTL-generation time. */
2215 DO_COND ($<ttype>$) = error_mark_node; }
2216 c99_block_lineno_labeled_stmt WHILE
2217 { $$ = $<ttype>2;
2218 RECHAIN_STMTS ($$, DO_BODY ($$)); }
2219 ;
2220
2221 /* The forced readahead in here is because we might be at the end of a
2222 line, and the line and file won't be bumped until yylex absorbs the
2223 first token on the next line. */
2224
2225 save_location:
2226 { if (yychar == YYEMPTY)
2227 yychar = YYLEX;
2228 $$ = input_location; }
2229 ;
2230
2231 lineno_labeled_stmt:
2232 lineno_stmt
2233 | lineno_label lineno_labeled_stmt
2234 ;
2235
2236 /* Like lineno_labeled_stmt, but a block in C99. */
2237 c99_block_lineno_labeled_stmt:
2238 c99_block_start lineno_labeled_stmt c99_block_end
2239 { if (flag_isoc99)
2240 RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2241 ;
2242
2243 lineno_stmt:
2244 save_location stmt
2245 { if ($2)
2246 {
2247 STMT_LINENO ($2) = $1.line;
2248 /* ??? We currently have no way of recording
2249 the filename for a statement. This probably
2250 matters little in practice at the moment,
2251 but I suspect that problems will occur when
2252 doing inlining at the tree level. */
2253 }
2254 }
2255 ;
2256
2257 lineno_label:
2258 save_location label
2259 { if ($2)
2260 {
2261 STMT_LINENO ($2) = $1.line;
2262 }
2263 }
2264 ;
2265
2266 select_or_iter_stmt:
2267 simple_if ELSE
2268 { c_expand_start_else ();
2269 $<itype>1 = stmt_count; }
2270 c99_block_lineno_labeled_stmt
2271 { c_finish_else ();
2272 c_expand_end_cond ();
2273 if (extra_warnings && stmt_count == $<itype>1)
2274 warning ("empty body in an else-statement"); }
2275 | simple_if %prec IF
2276 { c_expand_end_cond ();
2277 /* This warning is here instead of in simple_if, because we
2278 do not want a warning if an empty if is followed by an
2279 else statement. Increment stmt_count so we don't
2280 give a second error if this is a nested `if'. */
2281 if (extra_warnings && stmt_count++ == $<itype>1)
2282 warning ("%Hempty body in an if-statement",
2283 &if_stmt_locus); }
2284 /* Make sure c_expand_end_cond is run once
2285 for each call to c_expand_start_cond.
2286 Otherwise a crash is likely. */
2287 | simple_if ELSE error
2288 { c_expand_end_cond (); }
2289 /* We must build the WHILE_STMT node before parsing its
2290 condition so that STMT_LINENO refers to the line
2291 containing the "while", and not the line containing
2292 the close-parenthesis.
2293
2294 c_begin_while_stmt returns the WHILE_STMT node, which
2295 we later pass to c_finish_while_stmt_cond to fill
2296 in the condition and other tidbits. */
2297 | WHILE
2298 { stmt_count++;
2299 $<ttype>$ = c_begin_while_stmt (); }
2300 '(' expr ')'
2301 { $4 = c_common_truthvalue_conversion ($4);
2302 c_finish_while_stmt_cond
2303 (c_common_truthvalue_conversion ($4), $<ttype>2);
2304 $<ttype>$ = add_stmt ($<ttype>2); }
2305 c99_block_lineno_labeled_stmt
2306 { RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2307 | do_stmt_start
2308 '(' expr ')' ';'
2309 { DO_COND ($1) = c_common_truthvalue_conversion ($3); }
2310 | do_stmt_start error
2311 { }
2312 | FOR
2313 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2314 NULL_TREE, NULL_TREE);
2315 add_stmt ($<ttype>$); }
2316 '(' for_init_stmt
2317 { stmt_count++;
2318 RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2319 xexpr ';'
2320 { if ($6)
2321 FOR_COND ($<ttype>2)
2322 = c_common_truthvalue_conversion ($6); }
2323 xexpr ')'
2324 { FOR_EXPR ($<ttype>2) = $9; }
2325 c99_block_lineno_labeled_stmt
2326 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2)); }
2327 | SWITCH '(' expr ')'
2328 { stmt_count++;
2329 $<ttype>$ = c_start_case ($3); }
2330 c99_block_lineno_labeled_stmt
2331 { c_finish_case (); }
2332 ;
2333
2334 for_init_stmt:
2335 xexpr ';'
2336 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2337 | decl
2338 { check_for_loop_decls (); }
2339 ;
2340
2341 /* Parse a single real statement, not including any labels. */
2342 stmt:
2343 compstmt
2344 { stmt_count++; $$ = $1; }
2345 | expr ';'
2346 { stmt_count++;
2347 $$ = c_expand_expr_stmt ($1); }
2348 | c99_block_start select_or_iter_stmt c99_block_end
2349 { if (flag_isoc99)
2350 RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2351 $$ = NULL_TREE; }
2352 | BREAK ';'
2353 { stmt_count++;
2354 $$ = add_stmt (build_break_stmt ()); }
2355 | CONTINUE ';'
2356 { stmt_count++;
2357 $$ = add_stmt (build_continue_stmt ()); }
2358 | RETURN ';'
2359 { stmt_count++;
2360 $$ = c_expand_return (NULL_TREE); }
2361 | RETURN expr ';'
2362 { stmt_count++;
2363 $$ = c_expand_return ($2); }
2364 | ASM_KEYWORD maybe_type_qual '(' expr ')' ';'
2365 { stmt_count++;
2366 $$ = simple_asm_stmt ($4); }
2367 /* This is the case with just output operands. */
2368 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ')' ';'
2369 { stmt_count++;
2370 $$ = build_asm_stmt ($2, $4, $6, NULL_TREE, NULL_TREE); }
2371 /* This is the case with input operands as well. */
2372 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2373 asm_operands ')' ';'
2374 { stmt_count++;
2375 $$ = build_asm_stmt ($2, $4, $6, $8, NULL_TREE); }
2376 /* This is the case with clobbered registers as well. */
2377 | ASM_KEYWORD maybe_type_qual '(' expr ':' asm_operands ':'
2378 asm_operands ':' asm_clobbers ')' ';'
2379 { stmt_count++;
2380 $$ = build_asm_stmt ($2, $4, $6, $8, $10); }
2381 | GOTO identifier ';'
2382 { tree decl;
2383 stmt_count++;
2384 decl = lookup_label ($2);
2385 if (decl != 0)
2386 {
2387 TREE_USED (decl) = 1;
2388 $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2389 }
2390 else
2391 $$ = NULL_TREE;
2392 }
2393 | GOTO '*' expr ';'
2394 { if (pedantic)
2395 pedwarn ("ISO C forbids `goto *expr;'");
2396 stmt_count++;
2397 $3 = convert (ptr_type_node, $3);
2398 $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2399 | ';'
2400 { $$ = NULL_TREE; }
2401 ;
2402
2403 /* Any kind of label, including jump labels and case labels.
2404 ANSI C accepts labels only before statements, but we allow them
2405 also at the end of a compound statement. */
2406
2407 label: CASE expr_no_commas ':'
2408 { stmt_count++;
2409 $$ = do_case ($2, NULL_TREE); }
2410 | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2411 { stmt_count++;
2412 $$ = do_case ($2, $4); }
2413 | DEFAULT ':'
2414 { stmt_count++;
2415 $$ = do_case (NULL_TREE, NULL_TREE); }
2416 | identifier save_location ':' maybe_attribute
2417 { tree label = define_label ($2, $1);
2418 stmt_count++;
2419 if (label)
2420 {
2421 decl_attributes (&label, $4, 0);
2422 $$ = add_stmt (build_stmt (LABEL_STMT, label));
2423 }
2424 else
2425 $$ = NULL_TREE;
2426 }
2427 ;
2428
2429 /* Either a type-qualifier or nothing. First thing in an `asm' statement. */
2430
2431 maybe_type_qual:
2432 /* empty */
2433 { emit_line_note (input_location);
2434 $$ = NULL_TREE; }
2435 | TYPE_QUAL
2436 { emit_line_note (input_location); }
2437 ;
2438
2439 xexpr:
2440 /* empty */
2441 { $$ = NULL_TREE; }
2442 | expr
2443 ;
2444
2445 /* These are the operands other than the first string and colon
2446 in asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x)) */
2447 asm_operands: /* empty */
2448 { $$ = NULL_TREE; }
2449 | nonnull_asm_operands
2450 ;
2451
2452 nonnull_asm_operands:
2453 asm_operand
2454 | nonnull_asm_operands ',' asm_operand
2455 { $$ = chainon ($1, $3); }
2456 ;
2457
2458 asm_operand:
2459 STRING '(' expr ')'
2460 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $3); }
2461 | '[' identifier ']' STRING '(' expr ')'
2462 { $2 = build_string (IDENTIFIER_LENGTH ($2),
2463 IDENTIFIER_POINTER ($2));
2464 $$ = build_tree_list (build_tree_list ($2, $4), $6); }
2465 ;
2466
2467 asm_clobbers:
2468 STRING
2469 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE); }
2470 | asm_clobbers ',' STRING
2471 { $$ = tree_cons (NULL_TREE, $3, $1); }
2472 ;
2473 \f
2474 /* This is what appears inside the parens in a function declarator.
2475 Its value is a list of ..._TYPE nodes. Attributes must appear here
2476 to avoid a conflict with their appearance after an open parenthesis
2477 in an abstract declarator, as in
2478 "void bar (int (__attribute__((__mode__(SI))) int foo));". */
2479 parmlist:
2480 maybe_attribute
2481 { pushlevel (0);
2482 clear_parm_order ();
2483 declare_parm_level (); }
2484 parmlist_1
2485 { $$ = $3;
2486 parmlist_tags_warning ();
2487 poplevel (0, 0, 0); }
2488 ;
2489
2490 parmlist_1:
2491 parmlist_2 ')'
2492 | parms ';'
2493 { tree parm;
2494 if (pedantic)
2495 pedwarn ("ISO C forbids forward parameter declarations");
2496 /* Mark the forward decls as such. */
2497 for (parm = getdecls (); parm; parm = TREE_CHAIN (parm))
2498 TREE_ASM_WRITTEN (parm) = 1;
2499 clear_parm_order (); }
2500 maybe_attribute
2501 { /* Dummy action so attributes are in known place
2502 on parser stack. */ }
2503 parmlist_1
2504 { $$ = $6; }
2505 | error ')'
2506 { $$ = tree_cons (NULL_TREE, NULL_TREE, NULL_TREE); }
2507 ;
2508
2509 /* This is what appears inside the parens in a function declarator.
2510 Is value is represented in the format that grokdeclarator expects. */
2511 parmlist_2: /* empty */
2512 { $$ = get_parm_info (0); }
2513 | ELLIPSIS
2514 { $$ = get_parm_info (0);
2515 /* Gcc used to allow this as an extension. However, it does
2516 not work for all targets, and thus has been disabled.
2517 Also, since func (...) and func () are indistinguishable,
2518 it caused problems with the code in expand_builtin which
2519 tries to verify that BUILT_IN_NEXT_ARG is being used
2520 correctly. */
2521 error ("ISO C requires a named argument before `...'");
2522 }
2523 | parms
2524 { $$ = get_parm_info (1);
2525 parsing_iso_function_signature = true;
2526 }
2527 | parms ',' ELLIPSIS
2528 { $$ = get_parm_info (0); }
2529 ;
2530
2531 parms:
2532 firstparm
2533 { push_parm_decl ($1); }
2534 | parms ',' parm
2535 { push_parm_decl ($3); }
2536 ;
2537
2538 /* A single parameter declaration or parameter type name,
2539 as found in a parmlist. */
2540 parm:
2541 declspecs_ts setspecs parm_declarator maybe_attribute
2542 { $$ = build_tree_list (build_tree_list (current_declspecs,
2543 $3),
2544 chainon ($4, all_prefix_attributes));
2545 POP_DECLSPEC_STACK; }
2546 | declspecs_ts setspecs notype_declarator maybe_attribute
2547 { $$ = build_tree_list (build_tree_list (current_declspecs,
2548 $3),
2549 chainon ($4, all_prefix_attributes));
2550 POP_DECLSPEC_STACK; }
2551 | declspecs_ts setspecs absdcl_maybe_attribute
2552 { $$ = $3;
2553 POP_DECLSPEC_STACK; }
2554 | declspecs_nots setspecs notype_declarator maybe_attribute
2555 { $$ = build_tree_list (build_tree_list (current_declspecs,
2556 $3),
2557 chainon ($4, all_prefix_attributes));
2558 POP_DECLSPEC_STACK; }
2559
2560 | declspecs_nots setspecs absdcl_maybe_attribute
2561 { $$ = $3;
2562 POP_DECLSPEC_STACK; }
2563 ;
2564
2565 /* The first parm, which must suck attributes from off the top of the parser
2566 stack. */
2567 firstparm:
2568 declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2569 { $$ = build_tree_list (build_tree_list (current_declspecs,
2570 $3),
2571 chainon ($4, all_prefix_attributes));
2572 POP_DECLSPEC_STACK; }
2573 | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2574 { $$ = build_tree_list (build_tree_list (current_declspecs,
2575 $3),
2576 chainon ($4, all_prefix_attributes));
2577 POP_DECLSPEC_STACK; }
2578 | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2579 { $$ = $3;
2580 POP_DECLSPEC_STACK; }
2581 | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2582 { $$ = build_tree_list (build_tree_list (current_declspecs,
2583 $3),
2584 chainon ($4, all_prefix_attributes));
2585 POP_DECLSPEC_STACK; }
2586
2587 | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2588 { $$ = $3;
2589 POP_DECLSPEC_STACK; }
2590 ;
2591
2592 setspecs_fp:
2593 setspecs
2594 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2595 all_prefix_attributes = prefix_attributes; }
2596 ;
2597
2598 /* This is used in a function definition
2599 where either a parmlist or an identifier list is ok.
2600 Its value is a list of ..._TYPE nodes or a list of identifiers. */
2601 parmlist_or_identifiers:
2602 maybe_attribute
2603 { pushlevel (0);
2604 clear_parm_order ();
2605 declare_parm_level (); }
2606 parmlist_or_identifiers_1
2607 { $$ = $3;
2608 parmlist_tags_warning ();
2609 poplevel (0, 0, 0); }
2610 ;
2611
2612 parmlist_or_identifiers_1:
2613 parmlist_1
2614 | identifiers ')'
2615 { tree t;
2616 for (t = $1; t; t = TREE_CHAIN (t))
2617 if (TREE_VALUE (t) == NULL_TREE)
2618 error ("`...' in old-style identifier list");
2619 $$ = tree_cons (NULL_TREE, NULL_TREE, $1);
2620
2621 /* Make sure we have a parmlist after attributes. */
2622 if ($<ttype>-1 != 0
2623 && (TREE_CODE ($$) != TREE_LIST
2624 || TREE_PURPOSE ($$) == 0
2625 || TREE_CODE (TREE_PURPOSE ($$)) != PARM_DECL))
2626 YYERROR1;
2627 }
2628 ;
2629
2630 /* A nonempty list of identifiers. */
2631 identifiers:
2632 IDENTIFIER
2633 { $$ = build_tree_list (NULL_TREE, $1); }
2634 | identifiers ',' IDENTIFIER
2635 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2636 ;
2637
2638 /* A nonempty list of identifiers, including typenames. */
2639 identifiers_or_typenames:
2640 identifier
2641 { $$ = build_tree_list (NULL_TREE, $1); }
2642 | identifiers_or_typenames ',' identifier
2643 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2644 ;
2645
2646 extension:
2647 EXTENSION
2648 { $$ = SAVE_EXT_FLAGS();
2649 pedantic = 0;
2650 warn_pointer_arith = 0;
2651 warn_traditional = 0;
2652 flag_iso = 0; }
2653 ;
2654 \f
2655 ifobjc
2656 /* Objective-C productions. */
2657
2658 objcdef:
2659 classdef
2660 | classdecl
2661 | aliasdecl
2662 | protocoldef
2663 | methoddef
2664 | END
2665 {
2666 if (objc_implementation_context)
2667 {
2668 finish_class (objc_implementation_context);
2669 objc_ivar_chain = NULL_TREE;
2670 objc_implementation_context = NULL_TREE;
2671 }
2672 else
2673 warning ("`@end' must appear in an implementation context");
2674 }
2675 ;
2676
2677 /* A nonempty list of identifiers. */
2678 identifier_list:
2679 identifier
2680 { $$ = build_tree_list (NULL_TREE, $1); }
2681 | identifier_list ',' identifier
2682 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2683 ;
2684
2685 classdecl:
2686 CLASS identifier_list ';'
2687 {
2688 objc_declare_class ($2);
2689 }
2690 ;
2691
2692 aliasdecl:
2693 ALIAS identifier identifier ';'
2694 {
2695 objc_declare_alias ($2, $3);
2696 }
2697 ;
2698
2699 classdef:
2700 INTERFACE identifier protocolrefs '{'
2701 {
2702 objc_interface_context = objc_ivar_context
2703 = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2704 objc_public_flag = 0;
2705 }
2706 ivar_decl_list '}'
2707 {
2708 continue_class (objc_interface_context);
2709 }
2710 methodprotolist
2711 END
2712 {
2713 finish_class (objc_interface_context);
2714 objc_interface_context = NULL_TREE;
2715 }
2716
2717 | INTERFACE identifier protocolrefs
2718 {
2719 objc_interface_context
2720 = start_class (CLASS_INTERFACE_TYPE, $2, NULL_TREE, $3);
2721 continue_class (objc_interface_context);
2722 }
2723 methodprotolist
2724 END
2725 {
2726 finish_class (objc_interface_context);
2727 objc_interface_context = NULL_TREE;
2728 }
2729
2730 | INTERFACE identifier ':' identifier protocolrefs '{'
2731 {
2732 objc_interface_context = objc_ivar_context
2733 = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2734 objc_public_flag = 0;
2735 }
2736 ivar_decl_list '}'
2737 {
2738 continue_class (objc_interface_context);
2739 }
2740 methodprotolist
2741 END
2742 {
2743 finish_class (objc_interface_context);
2744 objc_interface_context = NULL_TREE;
2745 }
2746
2747 | INTERFACE identifier ':' identifier protocolrefs
2748 {
2749 objc_interface_context
2750 = start_class (CLASS_INTERFACE_TYPE, $2, $4, $5);
2751 continue_class (objc_interface_context);
2752 }
2753 methodprotolist
2754 END
2755 {
2756 finish_class (objc_interface_context);
2757 objc_interface_context = NULL_TREE;
2758 }
2759
2760 | IMPLEMENTATION identifier '{'
2761 {
2762 objc_implementation_context = objc_ivar_context
2763 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2764 objc_public_flag = 0;
2765 }
2766 ivar_decl_list '}'
2767 {
2768 objc_ivar_chain
2769 = continue_class (objc_implementation_context);
2770 }
2771
2772 | IMPLEMENTATION identifier
2773 {
2774 objc_implementation_context
2775 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, NULL_TREE, NULL_TREE);
2776 objc_ivar_chain
2777 = continue_class (objc_implementation_context);
2778 }
2779
2780 | IMPLEMENTATION identifier ':' identifier '{'
2781 {
2782 objc_implementation_context = objc_ivar_context
2783 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2784 objc_public_flag = 0;
2785 }
2786 ivar_decl_list '}'
2787 {
2788 objc_ivar_chain
2789 = continue_class (objc_implementation_context);
2790 }
2791
2792 | IMPLEMENTATION identifier ':' identifier
2793 {
2794 objc_implementation_context
2795 = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2796 objc_ivar_chain
2797 = continue_class (objc_implementation_context);
2798 }
2799
2800 | INTERFACE identifier '(' identifier ')' protocolrefs
2801 {
2802 objc_interface_context
2803 = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2804 continue_class (objc_interface_context);
2805 }
2806 methodprotolist
2807 END
2808 {
2809 finish_class (objc_interface_context);
2810 objc_interface_context = NULL_TREE;
2811 }
2812
2813 | IMPLEMENTATION identifier '(' identifier ')'
2814 {
2815 objc_implementation_context
2816 = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2817 objc_ivar_chain
2818 = continue_class (objc_implementation_context);
2819 }
2820 ;
2821
2822 protocoldef:
2823 PROTOCOL identifier protocolrefs
2824 {
2825 objc_pq_context = 1;
2826 objc_interface_context
2827 = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2828 }
2829 methodprotolist END
2830 {
2831 objc_pq_context = 0;
2832 finish_protocol(objc_interface_context);
2833 objc_interface_context = NULL_TREE;
2834 }
2835 /* The @protocol forward-declaration production introduces a
2836 reduce/reduce conflict on ';', which should be resolved in
2837 favor of the production 'identifier_list -> identifier'. */
2838 | PROTOCOL identifier_list ';'
2839 {
2840 objc_declare_protocols ($2);
2841 }
2842 ;
2843
2844 protocolrefs:
2845 /* empty */
2846 {
2847 $$ = NULL_TREE;
2848 }
2849 | non_empty_protocolrefs
2850 ;
2851
2852 non_empty_protocolrefs:
2853 ARITHCOMPARE identifier_list ARITHCOMPARE
2854 {
2855 if ($1 == LT_EXPR && $3 == GT_EXPR)
2856 $$ = $2;
2857 else
2858 YYERROR1;
2859 }
2860 ;
2861
2862 ivar_decl_list:
2863 ivar_decl_list visibility_spec ivar_decls
2864 | ivar_decls
2865 ;
2866
2867 visibility_spec:
2868 PRIVATE { objc_public_flag = 2; }
2869 | PROTECTED { objc_public_flag = 0; }
2870 | PUBLIC { objc_public_flag = 1; }
2871 ;
2872
2873 ivar_decls:
2874 /* empty */
2875 {
2876 $$ = NULL_TREE;
2877 }
2878 | ivar_decls ivar_decl ';'
2879 | ivar_decls ';'
2880 {
2881 if (pedantic)
2882 pedwarn ("extra semicolon in struct or union specified");
2883 }
2884 ;
2885
2886
2887 /* There is a shift-reduce conflict here, because `components' may
2888 start with a `typename'. It happens that shifting (the default resolution)
2889 does the right thing, because it treats the `typename' as part of
2890 a `typed_typespecs'.
2891
2892 It is possible that this same technique would allow the distinction
2893 between `notype_initdecls' and `initdecls' to be eliminated.
2894 But I am being cautious and not trying it. */
2895
2896 ivar_decl:
2897 declspecs_nosc_ts setspecs ivars
2898 { $$ = $3;
2899 POP_DECLSPEC_STACK; }
2900 | declspecs_nosc_nots setspecs ivars
2901 { $$ = $3;
2902 POP_DECLSPEC_STACK; }
2903 | error
2904 { $$ = NULL_TREE; }
2905 ;
2906
2907 ivars:
2908 /* empty */
2909 { $$ = NULL_TREE; }
2910 | ivar_declarator
2911 | ivars ',' maybe_resetattrs ivar_declarator
2912 ;
2913
2914 ivar_declarator:
2915 declarator
2916 {
2917 $$ = add_instance_variable (objc_ivar_context,
2918 objc_public_flag,
2919 $1, current_declspecs,
2920 NULL_TREE);
2921 }
2922 | declarator ':' expr_no_commas
2923 {
2924 $$ = add_instance_variable (objc_ivar_context,
2925 objc_public_flag,
2926 $1, current_declspecs, $3);
2927 }
2928 | ':' expr_no_commas
2929 {
2930 $$ = add_instance_variable (objc_ivar_context,
2931 objc_public_flag,
2932 NULL_TREE,
2933 current_declspecs, $2);
2934 }
2935 ;
2936
2937 methodtype:
2938 '+'
2939 { objc_inherit_code = CLASS_METHOD_DECL; }
2940 | '-'
2941 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2942 ;
2943
2944 methoddef:
2945 methodtype
2946 {
2947 objc_pq_context = 1;
2948 if (!objc_implementation_context)
2949 fatal_error ("method definition not in class context");
2950 }
2951 methoddecl
2952 {
2953 objc_pq_context = 0;
2954 if (objc_inherit_code == CLASS_METHOD_DECL)
2955 add_class_method (objc_implementation_context, $3);
2956 else
2957 add_instance_method (objc_implementation_context, $3);
2958 start_method_def ($3);
2959 }
2960 optarglist
2961 {
2962 continue_method_def ();
2963 }
2964 compstmt_or_error
2965 {
2966 finish_method_def ();
2967 }
2968 ;
2969
2970 /* the reason for the strange actions in this rule
2971 is so that notype_initdecls when reached via datadef
2972 can find a valid list of type and sc specs in $0. */
2973
2974 methodprotolist:
2975 /* empty */
2976 | {$<ttype>$ = NULL_TREE; } methodprotolist2
2977 ;
2978
2979 methodprotolist2: /* eliminates a shift/reduce conflict */
2980 methodproto
2981 | datadef
2982 | methodprotolist2 methodproto
2983 | methodprotolist2 {$<ttype>$ = NULL_TREE; } datadef
2984 ;
2985
2986 semi_or_error:
2987 ';'
2988 | error
2989 ;
2990
2991 methodproto:
2992 methodtype
2993 {
2994 /* Remember protocol qualifiers in prototypes. */
2995 objc_pq_context = 1;
2996 }
2997 methoddecl
2998 {
2999 /* Forget protocol qualifiers here. */
3000 objc_pq_context = 0;
3001 if (objc_inherit_code == CLASS_METHOD_DECL)
3002 add_class_method (objc_interface_context, $3);
3003 else
3004 add_instance_method (objc_interface_context, $3);
3005 }
3006 semi_or_error
3007 ;
3008
3009 methoddecl:
3010 '(' typename ')' unaryselector
3011 {
3012 $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
3013 }
3014
3015 | unaryselector
3016 {
3017 $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
3018 }
3019
3020 | '(' typename ')' keywordselector optparmlist
3021 {
3022 $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
3023 }
3024
3025 | keywordselector optparmlist
3026 {
3027 $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3028 }
3029 ;
3030
3031 /* "optarglist" assumes that start_method_def has already been called...
3032 if it is not, the "xdecls" will not be placed in the proper scope */
3033
3034 optarglist:
3035 /* empty */
3036 | ';' myxdecls
3037 ;
3038
3039 /* to get around the following situation: "int foo (int a) int b; {}" that
3040 is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3041
3042 myxdecls:
3043 /* empty */
3044 | mydecls
3045 ;
3046
3047 mydecls:
3048 mydecl
3049 | errstmt
3050 | mydecls mydecl
3051 | mydecl errstmt
3052 ;
3053
3054 mydecl:
3055 declspecs_ts setspecs myparms ';'
3056 { POP_DECLSPEC_STACK; }
3057 | declspecs_ts ';'
3058 { shadow_tag ($1); }
3059 | declspecs_nots ';'
3060 { pedwarn ("empty declaration"); }
3061 ;
3062
3063 myparms:
3064 myparm
3065 { push_parm_decl ($1); }
3066 | myparms ',' myparm
3067 { push_parm_decl ($3); }
3068 ;
3069
3070 /* A single parameter declaration or parameter type name,
3071 as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3072
3073 myparm:
3074 parm_declarator maybe_attribute
3075 { $$ = build_tree_list (build_tree_list (current_declspecs,
3076 $1),
3077 chainon ($2, all_prefix_attributes)); }
3078 | notype_declarator maybe_attribute
3079 { $$ = build_tree_list (build_tree_list (current_declspecs,
3080 $1),
3081 chainon ($2, all_prefix_attributes)); }
3082 | absdcl_maybe_attribute
3083 { $$ = $1; }
3084 ;
3085
3086 optparmlist:
3087 /* empty */
3088 {
3089 $$ = NULL_TREE;
3090 }
3091 | ',' ELLIPSIS
3092 {
3093 /* oh what a kludge! */
3094 $$ = objc_ellipsis_node;
3095 }
3096 | ','
3097 {
3098 pushlevel (0);
3099 }
3100 parmlist_2
3101 {
3102 /* returns a tree list node generated by get_parm_info */
3103 $$ = $3;
3104 poplevel (0, 0, 0);
3105 }
3106 ;
3107
3108 unaryselector:
3109 selector
3110 ;
3111
3112 keywordselector:
3113 keyworddecl
3114
3115 | keywordselector keyworddecl
3116 {
3117 $$ = chainon ($1, $2);
3118 }
3119 ;
3120
3121 selector:
3122 IDENTIFIER
3123 | TYPENAME
3124 | CLASSNAME
3125 | OBJECTNAME
3126 | reservedwords
3127 ;
3128
3129 reservedwords:
3130 ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3131 | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3132 | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3133 | TYPESPEC | TYPE_QUAL
3134 ;
3135
3136 keyworddecl:
3137 selector ':' '(' typename ')' identifier
3138 {
3139 $$ = build_keyword_decl ($1, $4, $6);
3140 }
3141
3142 | selector ':' identifier
3143 {
3144 $$ = build_keyword_decl ($1, NULL_TREE, $3);
3145 }
3146
3147 | ':' '(' typename ')' identifier
3148 {
3149 $$ = build_keyword_decl (NULL_TREE, $3, $5);
3150 }
3151
3152 | ':' identifier
3153 {
3154 $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3155 }
3156 ;
3157
3158 messageargs:
3159 selector
3160 | keywordarglist
3161 ;
3162
3163 keywordarglist:
3164 keywordarg
3165 | keywordarglist keywordarg
3166 {
3167 $$ = chainon ($1, $2);
3168 }
3169 ;
3170
3171
3172 keywordexpr:
3173 nonnull_exprlist
3174 {
3175 if (TREE_CHAIN ($1) == NULL_TREE)
3176 /* just return the expr., remove a level of indirection */
3177 $$ = TREE_VALUE ($1);
3178 else
3179 /* we have a comma expr., we will collapse later */
3180 $$ = $1;
3181 }
3182 ;
3183
3184 keywordarg:
3185 selector ':' keywordexpr
3186 {
3187 $$ = build_tree_list ($1, $3);
3188 }
3189 | ':' keywordexpr
3190 {
3191 $$ = build_tree_list (NULL_TREE, $2);
3192 }
3193 ;
3194
3195 receiver:
3196 expr
3197 | CLASSNAME
3198 {
3199 $$ = get_class_reference ($1);
3200 }
3201 ;
3202
3203 objcmessageexpr:
3204 '[' receiver messageargs ']'
3205 { $$ = build_tree_list ($2, $3); }
3206 ;
3207
3208 selectorarg:
3209 selector
3210 | keywordnamelist
3211 ;
3212
3213 keywordnamelist:
3214 keywordname
3215 | keywordnamelist keywordname
3216 {
3217 $$ = chainon ($1, $2);
3218 }
3219 ;
3220
3221 keywordname:
3222 selector ':'
3223 {
3224 $$ = build_tree_list ($1, NULL_TREE);
3225 }
3226 | ':'
3227 {
3228 $$ = build_tree_list (NULL_TREE, NULL_TREE);
3229 }
3230 ;
3231
3232 objcselectorexpr:
3233 SELECTOR '(' selectorarg ')'
3234 {
3235 $$ = $3;
3236 }
3237 ;
3238
3239 objcprotocolexpr:
3240 PROTOCOL '(' identifier ')'
3241 {
3242 $$ = $3;
3243 }
3244 ;
3245
3246 /* extension to support C-structures in the archiver */
3247
3248 objcencodeexpr:
3249 ENCODE '(' typename ')'
3250 {
3251 $$ = groktypename ($3);
3252 }
3253 ;
3254
3255 end ifobjc
3256 %%
3257
3258 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3259 cpplib.h's token codes into yacc's token codes. */
3260
3261 static enum cpp_ttype last_token;
3262
3263 /* The reserved keyword table. */
3264 struct resword
3265 {
3266 const char *word;
3267 ENUM_BITFIELD(rid) rid : 16;
3268 unsigned int disable : 16;
3269 };
3270
3271 /* Disable mask. Keywords are disabled if (reswords[i].disable & mask) is
3272 _true_. */
3273 #define D_C89 0x01 /* not in C89 */
3274 #define D_EXT 0x02 /* GCC extension */
3275 #define D_EXT89 0x04 /* GCC extension incorporated in C99 */
3276 #define D_OBJC 0x08 /* Objective C only */
3277
3278 static const struct resword reswords[] =
3279 {
3280 { "_Bool", RID_BOOL, 0 },
3281 { "_Complex", RID_COMPLEX, 0 },
3282 { "__FUNCTION__", RID_FUNCTION_NAME, 0 },
3283 { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3284 { "__alignof", RID_ALIGNOF, 0 },
3285 { "__alignof__", RID_ALIGNOF, 0 },
3286 { "__asm", RID_ASM, 0 },
3287 { "__asm__", RID_ASM, 0 },
3288 { "__attribute", RID_ATTRIBUTE, 0 },
3289 { "__attribute__", RID_ATTRIBUTE, 0 },
3290 { "__builtin_choose_expr", RID_CHOOSE_EXPR, 0 },
3291 { "__builtin_types_compatible_p", RID_TYPES_COMPATIBLE_P, 0 },
3292 { "__builtin_va_arg", RID_VA_ARG, 0 },
3293 { "__complex", RID_COMPLEX, 0 },
3294 { "__complex__", RID_COMPLEX, 0 },
3295 { "__const", RID_CONST, 0 },
3296 { "__const__", RID_CONST, 0 },
3297 { "__extension__", RID_EXTENSION, 0 },
3298 { "__func__", RID_C99_FUNCTION_NAME, 0 },
3299 { "__imag", RID_IMAGPART, 0 },
3300 { "__imag__", RID_IMAGPART, 0 },
3301 { "__inline", RID_INLINE, 0 },
3302 { "__inline__", RID_INLINE, 0 },
3303 { "__label__", RID_LABEL, 0 },
3304 { "__ptrbase", RID_PTRBASE, 0 },
3305 { "__ptrbase__", RID_PTRBASE, 0 },
3306 { "__ptrextent", RID_PTREXTENT, 0 },
3307 { "__ptrextent__", RID_PTREXTENT, 0 },
3308 { "__ptrvalue", RID_PTRVALUE, 0 },
3309 { "__ptrvalue__", RID_PTRVALUE, 0 },
3310 { "__real", RID_REALPART, 0 },
3311 { "__real__", RID_REALPART, 0 },
3312 { "__restrict", RID_RESTRICT, 0 },
3313 { "__restrict__", RID_RESTRICT, 0 },
3314 { "__signed", RID_SIGNED, 0 },
3315 { "__signed__", RID_SIGNED, 0 },
3316 { "__thread", RID_THREAD, 0 },
3317 { "__typeof", RID_TYPEOF, 0 },
3318 { "__typeof__", RID_TYPEOF, 0 },
3319 { "__volatile", RID_VOLATILE, 0 },
3320 { "__volatile__", RID_VOLATILE, 0 },
3321 { "asm", RID_ASM, D_EXT },
3322 { "auto", RID_AUTO, 0 },
3323 { "break", RID_BREAK, 0 },
3324 { "case", RID_CASE, 0 },
3325 { "char", RID_CHAR, 0 },
3326 { "const", RID_CONST, 0 },
3327 { "continue", RID_CONTINUE, 0 },
3328 { "default", RID_DEFAULT, 0 },
3329 { "do", RID_DO, 0 },
3330 { "double", RID_DOUBLE, 0 },
3331 { "else", RID_ELSE, 0 },
3332 { "enum", RID_ENUM, 0 },
3333 { "extern", RID_EXTERN, 0 },
3334 { "float", RID_FLOAT, 0 },
3335 { "for", RID_FOR, 0 },
3336 { "goto", RID_GOTO, 0 },
3337 { "if", RID_IF, 0 },
3338 { "inline", RID_INLINE, D_EXT89 },
3339 { "int", RID_INT, 0 },
3340 { "long", RID_LONG, 0 },
3341 { "register", RID_REGISTER, 0 },
3342 { "restrict", RID_RESTRICT, D_C89 },
3343 { "return", RID_RETURN, 0 },
3344 { "short", RID_SHORT, 0 },
3345 { "signed", RID_SIGNED, 0 },
3346 { "sizeof", RID_SIZEOF, 0 },
3347 { "static", RID_STATIC, 0 },
3348 { "struct", RID_STRUCT, 0 },
3349 { "switch", RID_SWITCH, 0 },
3350 { "typedef", RID_TYPEDEF, 0 },
3351 { "typeof", RID_TYPEOF, D_EXT },
3352 { "union", RID_UNION, 0 },
3353 { "unsigned", RID_UNSIGNED, 0 },
3354 { "void", RID_VOID, 0 },
3355 { "volatile", RID_VOLATILE, 0 },
3356 { "while", RID_WHILE, 0 },
3357 ifobjc
3358 { "id", RID_ID, D_OBJC },
3359
3360 /* These objc keywords are recognized only immediately after
3361 an '@'. */
3362 { "class", RID_AT_CLASS, D_OBJC },
3363 { "compatibility_alias", RID_AT_ALIAS, D_OBJC },
3364 { "defs", RID_AT_DEFS, D_OBJC },
3365 { "encode", RID_AT_ENCODE, D_OBJC },
3366 { "end", RID_AT_END, D_OBJC },
3367 { "implementation", RID_AT_IMPLEMENTATION, D_OBJC },
3368 { "interface", RID_AT_INTERFACE, D_OBJC },
3369 { "private", RID_AT_PRIVATE, D_OBJC },
3370 { "protected", RID_AT_PROTECTED, D_OBJC },
3371 { "protocol", RID_AT_PROTOCOL, D_OBJC },
3372 { "public", RID_AT_PUBLIC, D_OBJC },
3373 { "selector", RID_AT_SELECTOR, D_OBJC },
3374
3375 /* These are recognized only in protocol-qualifier context
3376 (see above) */
3377 { "bycopy", RID_BYCOPY, D_OBJC },
3378 { "byref", RID_BYREF, D_OBJC },
3379 { "in", RID_IN, D_OBJC },
3380 { "inout", RID_INOUT, D_OBJC },
3381 { "oneway", RID_ONEWAY, D_OBJC },
3382 { "out", RID_OUT, D_OBJC },
3383 end ifobjc
3384 };
3385 #define N_reswords (sizeof reswords / sizeof (struct resword))
3386
3387 /* Table mapping from RID_* constants to yacc token numbers.
3388 Unfortunately we have to have entries for all the keywords in all
3389 three languages. */
3390 static const short rid_to_yy[RID_MAX] =
3391 {
3392 /* RID_STATIC */ STATIC,
3393 /* RID_UNSIGNED */ TYPESPEC,
3394 /* RID_LONG */ TYPESPEC,
3395 /* RID_CONST */ TYPE_QUAL,
3396 /* RID_EXTERN */ SCSPEC,
3397 /* RID_REGISTER */ SCSPEC,
3398 /* RID_TYPEDEF */ SCSPEC,
3399 /* RID_SHORT */ TYPESPEC,
3400 /* RID_INLINE */ SCSPEC,
3401 /* RID_VOLATILE */ TYPE_QUAL,
3402 /* RID_SIGNED */ TYPESPEC,
3403 /* RID_AUTO */ SCSPEC,
3404 /* RID_RESTRICT */ TYPE_QUAL,
3405
3406 /* C extensions */
3407 /* RID_COMPLEX */ TYPESPEC,
3408 /* RID_THREAD */ SCSPEC,
3409
3410 /* C++ */
3411 /* RID_FRIEND */ 0,
3412 /* RID_VIRTUAL */ 0,
3413 /* RID_EXPLICIT */ 0,
3414 /* RID_EXPORT */ 0,
3415 /* RID_MUTABLE */ 0,
3416
3417 /* ObjC */
3418 /* RID_IN */ TYPE_QUAL,
3419 /* RID_OUT */ TYPE_QUAL,
3420 /* RID_INOUT */ TYPE_QUAL,
3421 /* RID_BYCOPY */ TYPE_QUAL,
3422 /* RID_BYREF */ TYPE_QUAL,
3423 /* RID_ONEWAY */ TYPE_QUAL,
3424
3425 /* C */
3426 /* RID_INT */ TYPESPEC,
3427 /* RID_CHAR */ TYPESPEC,
3428 /* RID_FLOAT */ TYPESPEC,
3429 /* RID_DOUBLE */ TYPESPEC,
3430 /* RID_VOID */ TYPESPEC,
3431 /* RID_ENUM */ ENUM,
3432 /* RID_STRUCT */ STRUCT,
3433 /* RID_UNION */ UNION,
3434 /* RID_IF */ IF,
3435 /* RID_ELSE */ ELSE,
3436 /* RID_WHILE */ WHILE,
3437 /* RID_DO */ DO,
3438 /* RID_FOR */ FOR,
3439 /* RID_SWITCH */ SWITCH,
3440 /* RID_CASE */ CASE,
3441 /* RID_DEFAULT */ DEFAULT,
3442 /* RID_BREAK */ BREAK,
3443 /* RID_CONTINUE */ CONTINUE,
3444 /* RID_RETURN */ RETURN,
3445 /* RID_GOTO */ GOTO,
3446 /* RID_SIZEOF */ SIZEOF,
3447
3448 /* C extensions */
3449 /* RID_ASM */ ASM_KEYWORD,
3450 /* RID_TYPEOF */ TYPEOF,
3451 /* RID_ALIGNOF */ ALIGNOF,
3452 /* RID_ATTRIBUTE */ ATTRIBUTE,
3453 /* RID_VA_ARG */ VA_ARG,
3454 /* RID_EXTENSION */ EXTENSION,
3455 /* RID_IMAGPART */ IMAGPART,
3456 /* RID_REALPART */ REALPART,
3457 /* RID_LABEL */ LABEL,
3458 /* RID_PTRBASE */ PTR_BASE,
3459 /* RID_PTREXTENT */ PTR_EXTENT,
3460 /* RID_PTRVALUE */ PTR_VALUE,
3461
3462 /* RID_CHOOSE_EXPR */ CHOOSE_EXPR,
3463 /* RID_TYPES_COMPATIBLE_P */ TYPES_COMPATIBLE_P,
3464
3465 /* RID_FUNCTION_NAME */ FUNC_NAME,
3466 /* RID_PRETTY_FUNCTION_NAME */ FUNC_NAME,
3467 /* RID_C99_FUNCTION_NAME */ FUNC_NAME,
3468
3469 /* C++ */
3470 /* RID_BOOL */ TYPESPEC,
3471 /* RID_WCHAR */ 0,
3472 /* RID_CLASS */ 0,
3473 /* RID_PUBLIC */ 0,
3474 /* RID_PRIVATE */ 0,
3475 /* RID_PROTECTED */ 0,
3476 /* RID_TEMPLATE */ 0,
3477 /* RID_NULL */ 0,
3478 /* RID_CATCH */ 0,
3479 /* RID_DELETE */ 0,
3480 /* RID_FALSE */ 0,
3481 /* RID_NAMESPACE */ 0,
3482 /* RID_NEW */ 0,
3483 /* RID_OPERATOR */ 0,
3484 /* RID_THIS */ 0,
3485 /* RID_THROW */ 0,
3486 /* RID_TRUE */ 0,
3487 /* RID_TRY */ 0,
3488 /* RID_TYPENAME */ 0,
3489 /* RID_TYPEID */ 0,
3490 /* RID_USING */ 0,
3491
3492 /* casts */
3493 /* RID_CONSTCAST */ 0,
3494 /* RID_DYNCAST */ 0,
3495 /* RID_REINTCAST */ 0,
3496 /* RID_STATCAST */ 0,
3497
3498 /* Objective C */
3499 /* RID_ID */ OBJECTNAME,
3500 /* RID_AT_ENCODE */ ENCODE,
3501 /* RID_AT_END */ END,
3502 /* RID_AT_CLASS */ CLASS,
3503 /* RID_AT_ALIAS */ ALIAS,
3504 /* RID_AT_DEFS */ DEFS,
3505 /* RID_AT_PRIVATE */ PRIVATE,
3506 /* RID_AT_PROTECTED */ PROTECTED,
3507 /* RID_AT_PUBLIC */ PUBLIC,
3508 /* RID_AT_PROTOCOL */ PROTOCOL,
3509 /* RID_AT_SELECTOR */ SELECTOR,
3510 /* RID_AT_INTERFACE */ INTERFACE,
3511 /* RID_AT_IMPLEMENTATION */ IMPLEMENTATION
3512 };
3513
3514 static void
3515 init_reswords (void)
3516 {
3517 unsigned int i;
3518 tree id;
3519 int mask = (flag_isoc99 ? 0 : D_C89)
3520 | (flag_no_asm ? (flag_isoc99 ? D_EXT : D_EXT|D_EXT89) : 0);
3521
3522 if (!c_dialect_objc ())
3523 mask |= D_OBJC;
3524
3525 ridpointers = ggc_calloc ((int) RID_MAX, sizeof (tree));
3526 for (i = 0; i < N_reswords; i++)
3527 {
3528 /* If a keyword is disabled, do not enter it into the table
3529 and so create a canonical spelling that isn't a keyword. */
3530 if (reswords[i].disable & mask)
3531 continue;
3532
3533 id = get_identifier (reswords[i].word);
3534 C_RID_CODE (id) = reswords[i].rid;
3535 C_IS_RESERVED_WORD (id) = 1;
3536 ridpointers [(int) reswords[i].rid] = id;
3537 }
3538 }
3539
3540 #define NAME(type) cpp_type2name (type)
3541
3542 static void
3543 yyerror (const char *msgid)
3544 {
3545 const char *string = _(msgid);
3546
3547 if (last_token == CPP_EOF)
3548 error ("%s at end of input", string);
3549 else if (last_token == CPP_CHAR || last_token == CPP_WCHAR)
3550 {
3551 unsigned int val = TREE_INT_CST_LOW (yylval.ttype);
3552 const char *const ell = (last_token == CPP_CHAR) ? "" : "L";
3553 if (val <= UCHAR_MAX && ISGRAPH (val))
3554 error ("%s before %s'%c'", string, ell, val);
3555 else
3556 error ("%s before %s'\\x%x'", string, ell, val);
3557 }
3558 else if (last_token == CPP_STRING
3559 || last_token == CPP_WSTRING)
3560 error ("%s before string constant", string);
3561 else if (last_token == CPP_NUMBER)
3562 error ("%s before numeric constant", string);
3563 else if (last_token == CPP_NAME)
3564 error ("%s before \"%s\"", string, IDENTIFIER_POINTER (yylval.ttype));
3565 else
3566 error ("%s before '%s' token", string, NAME(last_token));
3567 }
3568
3569 static int
3570 yylexname (void)
3571 {
3572 tree decl;
3573
3574 ifobjc
3575 int objc_force_identifier = objc_need_raw_identifier;
3576 OBJC_NEED_RAW_IDENTIFIER (0);
3577 end ifobjc
3578
3579 if (C_IS_RESERVED_WORD (yylval.ttype))
3580 {
3581 enum rid rid_code = C_RID_CODE (yylval.ttype);
3582
3583 ifobjc
3584 /* Turn non-typedefed refs to "id" into plain identifiers; this
3585 allows constructs like "void foo(id id);" to work. */
3586 if (rid_code == RID_ID)
3587 {
3588 decl = lookup_name (yylval.ttype);
3589 if (decl == NULL_TREE || TREE_CODE (decl) != TYPE_DECL)
3590 return IDENTIFIER;
3591 }
3592
3593 if (!OBJC_IS_AT_KEYWORD (rid_code)
3594 && (!OBJC_IS_PQ_KEYWORD (rid_code) || objc_pq_context))
3595 end ifobjc
3596 {
3597 /* Return the canonical spelling for this keyword. */
3598 yylval.ttype = ridpointers[(int) rid_code];
3599 return rid_to_yy[(int) rid_code];
3600 }
3601 }
3602
3603 decl = lookup_name (yylval.ttype);
3604 if (decl)
3605 {
3606 if (TREE_CODE (decl) == TYPE_DECL)
3607 return TYPENAME;
3608 }
3609 ifobjc
3610 else
3611 {
3612 tree objc_interface_decl = is_class_name (yylval.ttype);
3613 /* ObjC class names are in the same namespace as variables and
3614 typedefs, and hence are shadowed by local declarations. */
3615 if (objc_interface_decl
3616 && (global_bindings_p ()
3617 || (!objc_force_identifier && !decl)))
3618 {
3619 yylval.ttype = objc_interface_decl;
3620 return CLASSNAME;
3621 }
3622 }
3623 end ifobjc
3624
3625 return IDENTIFIER;
3626 }
3627
3628 static inline int
3629 _yylex (void)
3630 {
3631 get_next:
3632 last_token = c_lex (&yylval.ttype);
3633 switch (last_token)
3634 {
3635 case CPP_EQ: return '=';
3636 case CPP_NOT: return '!';
3637 case CPP_GREATER: yylval.code = GT_EXPR; return ARITHCOMPARE;
3638 case CPP_LESS: yylval.code = LT_EXPR; return ARITHCOMPARE;
3639 case CPP_PLUS: yylval.code = PLUS_EXPR; return '+';
3640 case CPP_MINUS: yylval.code = MINUS_EXPR; return '-';
3641 case CPP_MULT: yylval.code = MULT_EXPR; return '*';
3642 case CPP_DIV: yylval.code = TRUNC_DIV_EXPR; return '/';
3643 case CPP_MOD: yylval.code = TRUNC_MOD_EXPR; return '%';
3644 case CPP_AND: yylval.code = BIT_AND_EXPR; return '&';
3645 case CPP_OR: yylval.code = BIT_IOR_EXPR; return '|';
3646 case CPP_XOR: yylval.code = BIT_XOR_EXPR; return '^';
3647 case CPP_RSHIFT: yylval.code = RSHIFT_EXPR; return RSHIFT;
3648 case CPP_LSHIFT: yylval.code = LSHIFT_EXPR; return LSHIFT;
3649
3650 case CPP_COMPL: return '~';
3651 case CPP_AND_AND: return ANDAND;
3652 case CPP_OR_OR: return OROR;
3653 case CPP_QUERY: return '?';
3654 case CPP_OPEN_PAREN: return '(';
3655 case CPP_EQ_EQ: yylval.code = EQ_EXPR; return EQCOMPARE;
3656 case CPP_NOT_EQ: yylval.code = NE_EXPR; return EQCOMPARE;
3657 case CPP_GREATER_EQ:yylval.code = GE_EXPR; return ARITHCOMPARE;
3658 case CPP_LESS_EQ: yylval.code = LE_EXPR; return ARITHCOMPARE;
3659
3660 case CPP_PLUS_EQ: yylval.code = PLUS_EXPR; return ASSIGN;
3661 case CPP_MINUS_EQ: yylval.code = MINUS_EXPR; return ASSIGN;
3662 case CPP_MULT_EQ: yylval.code = MULT_EXPR; return ASSIGN;
3663 case CPP_DIV_EQ: yylval.code = TRUNC_DIV_EXPR; return ASSIGN;
3664 case CPP_MOD_EQ: yylval.code = TRUNC_MOD_EXPR; return ASSIGN;
3665 case CPP_AND_EQ: yylval.code = BIT_AND_EXPR; return ASSIGN;
3666 case CPP_OR_EQ: yylval.code = BIT_IOR_EXPR; return ASSIGN;
3667 case CPP_XOR_EQ: yylval.code = BIT_XOR_EXPR; return ASSIGN;
3668 case CPP_RSHIFT_EQ: yylval.code = RSHIFT_EXPR; return ASSIGN;
3669 case CPP_LSHIFT_EQ: yylval.code = LSHIFT_EXPR; return ASSIGN;
3670
3671 case CPP_OPEN_SQUARE: return '[';
3672 case CPP_CLOSE_SQUARE: return ']';
3673 case CPP_OPEN_BRACE: return '{';
3674 case CPP_CLOSE_BRACE: return '}';
3675 case CPP_ELLIPSIS: return ELLIPSIS;
3676
3677 case CPP_PLUS_PLUS: return PLUSPLUS;
3678 case CPP_MINUS_MINUS: return MINUSMINUS;
3679 case CPP_DEREF: return POINTSAT;
3680 case CPP_DOT: return '.';
3681
3682 /* The following tokens may affect the interpretation of any
3683 identifiers following, if doing Objective-C. */
3684 case CPP_COLON: OBJC_NEED_RAW_IDENTIFIER (0); return ':';
3685 case CPP_COMMA: OBJC_NEED_RAW_IDENTIFIER (0); return ',';
3686 case CPP_CLOSE_PAREN: OBJC_NEED_RAW_IDENTIFIER (0); return ')';
3687 case CPP_SEMICOLON: OBJC_NEED_RAW_IDENTIFIER (0); return ';';
3688
3689 case CPP_EOF:
3690 return 0;
3691
3692 case CPP_NAME:
3693 return yylexname ();
3694
3695 case CPP_AT_NAME:
3696 /* This only happens in Objective-C; it must be a keyword. */
3697 return rid_to_yy [(int) C_RID_CODE (yylval.ttype)];
3698
3699 case CPP_NUMBER:
3700 case CPP_CHAR:
3701 case CPP_WCHAR:
3702 return CONSTANT;
3703
3704 case CPP_STRING:
3705 case CPP_WSTRING:
3706 return STRING;
3707
3708 case CPP_OBJC_STRING:
3709 return OBJC_STRING;
3710
3711 /* These tokens are C++ specific (and will not be generated
3712 in C mode, but let's be cautious). */
3713 case CPP_SCOPE:
3714 case CPP_DEREF_STAR:
3715 case CPP_DOT_STAR:
3716 case CPP_MIN_EQ:
3717 case CPP_MAX_EQ:
3718 case CPP_MIN:
3719 case CPP_MAX:
3720 /* These tokens should not survive translation phase 4. */
3721 case CPP_HASH:
3722 case CPP_PASTE:
3723 error ("syntax error at '%s' token", NAME(last_token));
3724 goto get_next;
3725
3726 default:
3727 abort ();
3728 }
3729 /* NOTREACHED */
3730 }
3731
3732 static int
3733 yylex (void)
3734 {
3735 int r;
3736 timevar_push (TV_LEX);
3737 r = _yylex();
3738 timevar_pop (TV_LEX);
3739 return r;
3740 }
3741
3742 /* Function used when yydebug is set, to print a token in more detail. */
3743
3744 static void
3745 yyprint (FILE *file, int yychar, YYSTYPE yyl)
3746 {
3747 tree t = yyl.ttype;
3748
3749 fprintf (file, " [%s]", NAME(last_token));
3750
3751 switch (yychar)
3752 {
3753 case IDENTIFIER:
3754 case TYPENAME:
3755 case OBJECTNAME:
3756 case TYPESPEC:
3757 case TYPE_QUAL:
3758 case SCSPEC:
3759 case STATIC:
3760 if (IDENTIFIER_POINTER (t))
3761 fprintf (file, " `%s'", IDENTIFIER_POINTER (t));
3762 break;
3763
3764 case CONSTANT:
3765 fprintf (file, " %s", GET_MODE_NAME (TYPE_MODE (TREE_TYPE (t))));
3766 if (TREE_CODE (t) == INTEGER_CST)
3767 {
3768 fputs (" ", file);
3769 fprintf (file, HOST_WIDE_INT_PRINT_DOUBLE_HEX,
3770 TREE_INT_CST_HIGH (t), TREE_INT_CST_LOW (t));
3771 }
3772 break;
3773 }
3774 }
3775 \f
3776 /* This is not the ideal place to put these, but we have to get them out
3777 of c-lex.c because cp/lex.c has its own versions. */
3778
3779 /* Free malloced parser stacks if necessary. */
3780
3781 void
3782 free_parser_stacks (void)
3783 {
3784 }
3785
3786 /* Parse the file. */
3787 void
3788 c_parse_file (void)
3789 {
3790 yyparse ();
3791 /* In case there were missing closebraces, get us back to the global
3792 binding level. */
3793 while (! global_bindings_p ())
3794 poplevel (0, 0, 0);
3795 /* __FUNCTION__ is defined at file scope (""). This
3796 call may not be necessary as my tests indicate it
3797 still works without it. */
3798 finish_fname_decls ();
3799
3800 if (malloced_yyss)
3801 {
3802 free (malloced_yyss);
3803 free (malloced_yyvs);
3804 malloced_yyss = 0;
3805 }
3806 }
3807
3808 #include "gt-c-parse.h"
Mirror of https://gcc.gnu.org/git/gcc.git