gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 #Set to 1 on a release branch
  34 is_release=
  35
  36 # Determine the host, build, and target systems
  37 AC_CANONICAL_BUILD
  38 AC_CANONICAL_HOST
  39 AC_CANONICAL_TARGET
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Determine the target- and build-specific subdirectories
  45 GCC_TOPLEV_SUBDIRS
  46
  47 # Set program_transform_name
  48 AC_ARG_PROGRAM
  49
  50 # Check for bogus environment variables.
  51 # Test if LIBRARY_PATH contains the notation for the current directory
  52 # since this would lead to problems installing/building glibc.
  53 # LIBRARY_PATH contains the current directory if one of the following
  54 # is true:
  55 # - one of the terminals (":" and ";") is the first or last sign
  56 # - two terminals occur directly after each other
  57 # - the path contains an element with a dot in it
  58 AC_MSG_CHECKING(LIBRARY_PATH variable)
  59 changequote(,)dnl
  60 case ${LIBRARY_PATH} in
  61   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  62     library_path_setting="contains current directory"
  63     ;;
  64   *)
  65     library_path_setting="ok"
  66     ;;
  67 esac
  68 changequote([,])dnl
  69 AC_MSG_RESULT($library_path_setting)
  70 if test "$library_path_setting" != "ok"; then
  71 AC_MSG_ERROR([
  72 *** LIBRARY_PATH shouldn't contain the current directory when
  73 *** building gcc. Please change the environment variable
  74 *** and run configure again.])
  75 fi
  76
  77 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  78 # since this would lead to problems installing/building glibc.
  79 # GCC_EXEC_PREFIX contains the current directory if one of the following
  80 # is true:
  81 # - one of the terminals (":" and ";") is the first or last sign
  82 # - two terminals occur directly after each other
  83 # - the path contains an element with a dot in it
  84 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  85 changequote(,)dnl
  86 case ${GCC_EXEC_PREFIX} in
  87   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  88     gcc_exec_prefix_setting="contains current directory"
  89     ;;
  90   *)
  91     gcc_exec_prefix_setting="ok"
  92     ;;
  93 esac
  94 changequote([,])dnl
  95 AC_MSG_RESULT($gcc_exec_prefix_setting)
  96 if test "$gcc_exec_prefix_setting" != "ok"; then
  97 AC_MSG_ERROR([
  98 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  99 *** building gcc. Please change the environment variable
 100 *** and run configure again.])
 101 fi
 102
 103 TL_AC_GCC_VERSION([$srcdir/..])
 104
 105 # -----------
 106 # Directories
 107 # -----------
 108
 109 # Specify the local prefix
 110 local_prefix=
 111 AC_ARG_WITH(local-prefix,
 112 [  --with-local-prefix=DIR specifies directory to put local include],
 113 [case "${withval}" in
 114 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 115 no)     ;;
 116 *)      local_prefix=$with_local_prefix ;;
 117 esac])
 118
 119 # Default local prefix if it is empty
 120 if test x$local_prefix = x; then
 121         local_prefix=/usr/local
 122 fi
 123
 124 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 125 # passed in by the toplevel make and thus we'd get different behavior
 126 # depending on where we built the sources.
 127 gcc_gxx_include_dir=
 128 # Specify the g++ header file directory
 129 AC_ARG_WITH(gxx-include-dir,
 130 [  --with-gxx-include-dir=DIR
 131                           specifies directory to put g++ header files],
 132 [case "${withval}" in
 133 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 134 no)     ;;
 135 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 136 esac])
 137
 138 if test x${gcc_gxx_include_dir} = x; then
 139   if test x${enable_version_specific_runtime_libs} = xyes; then
 140     gcc_gxx_include_dir='${libsubdir}/include/c++'
 141   else
 142     libstdcxx_incdir=c++/${gcc_version}
 143 changequote(<<, >>)dnl
 144     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 145 changequote([, ])dnl
 146   fi
 147 fi
 148
 149 AC_ARG_WITH(cpp_install_dir,
 150 [  --with-cpp-install-dir=DIR
 151                           install the user visible C preprocessor in DIR
 152                           (relative to PREFIX) as well as PREFIX/bin],
 153 [if test x$withval = xyes; then
 154   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 155 elif test x$withval != xno; then
 156   cpp_install_dir=$withval
 157 fi])
 158
 159 # We would like to our source tree to be readonly.  However when releases or
 160 # pre-releases are generated, the flex/bison generated files as well as the
 161 # various formats of manuals need to be included along with the rest of the
 162 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 163 # just that.
 164
 165 AC_MSG_CHECKING([whether to place generated files in the source directory])
 166   dnl generated-files-in-srcdir is disabled by default
 167   AC_ARG_ENABLE(generated-files-in-srcdir,
 168 [  --enable-generated-files-in-srcdir
 169                           put copies of generated files in source dir
 170                           intended for creating source tarballs for users
 171                           without texinfo bison or flex.],
 172       generated_files_in_srcdir=$enableval,
 173       generated_files_in_srcdir=no)
 174
 175 AC_MSG_RESULT($generated_files_in_srcdir)
 176
 177 if test "$generated_files_in_srcdir" = "yes"; then
 178   GENINSRC=''
 179 else
 180   GENINSRC='#'
 181 fi
 182 AC_SUBST(GENINSRC)
 183
 184 # -------------------
 185 # Find default linker
 186 # -------------------
 187
 188 # With GNU ld
 189 AC_ARG_WITH(gnu-ld,
 190 [  --with-gnu-ld           arrange to work with GNU ld.],
 191 gnu_ld_flag="$with_gnu_ld",
 192 gnu_ld_flag=no)
 193
 194 # With pre-defined ld
 195 AC_ARG_WITH(ld,
 196 [  --with-ld               arrange to use the specified ld (full pathname)],
 197 DEFAULT_LINKER="$with_ld")
 198 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 199   if test ! -x "$DEFAULT_LINKER"; then
 200     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 201   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 202     gnu_ld_flag=yes
 203   fi
 204   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 205         [Define to enable the use of a default linker.])
 206 fi
 207
 208 AC_MSG_CHECKING([whether a default linker was specified])
 209 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 210   if test x"$gnu_ld_flag" = x"no"; then
 211     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 212   else
 213     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 214   fi
 215 else
 216   AC_MSG_RESULT(no)
 217 fi
 218
 219 # With demangler in GNU ld
 220 AC_ARG_WITH(demangler-in-ld,
 221 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 222 demangler_in_ld="$with_demangler_in_ld",
 223 demangler_in_ld=no)
 224
 225 # ----------------------
 226 # Find default assembler
 227 # ----------------------
 228
 229 # With GNU as
 230 AC_ARG_WITH(gnu-as,
 231 [  --with-gnu-as           arrange to work with GNU as],
 232 gas_flag="$with_gnu_as",
 233 gas_flag=no)
 234
 235 AC_ARG_WITH(as,
 236 [  --with-as               arrange to use the specified as (full pathname)],
 237 DEFAULT_ASSEMBLER="$with_as")
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test ! -x "$DEFAULT_ASSEMBLER"; then
 240     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 241   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 242     gas_flag=yes
 243   fi
 244   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 245         [Define to enable the use of a default assembler.])
 246 fi
 247
 248 AC_MSG_CHECKING([whether a default assembler was specified])
 249 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 250   if test x"$gas_flag" = x"no"; then
 251     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 252   else
 253     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 254   fi
 255 else
 256   AC_MSG_RESULT(no)
 257 fi
 258
 259 # ---------------
 260 # Find C compiler
 261 # ---------------
 262
 263 # If a non-executable a.out is present (e.g. created by GNU as above even if
 264 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 265 # file, even when creating an executable, so an execution test fails.
 266 # Remove possible default executable files to avoid this.
 267 #
 268 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 269 # Autoconf includes it.
 270 rm -f a.out a.exe b.out
 271
 272 # Find the native compiler
 273 AC_PROG_CC
 274 AM_PROG_CC_C_O
 275 # autoconf is lame and doesn't give us any substitution variable for this.
 276 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 277   NO_MINUS_C_MINUS_O=yes
 278 else
 279   OUTPUT_OPTION='-o $@'
 280 fi
 281 AC_SUBST(NO_MINUS_C_MINUS_O)
 282 AC_SUBST(OUTPUT_OPTION)
 283
 284 # -------------------------
 285 # Check C compiler features
 286 # -------------------------
 287
 288 AC_PROG_CPP
 289 AC_C_INLINE
 290
 291 gcc_AC_C_LONG_LONG
 292
 293 # sizeof(char) is 1 by definition.
 294 AC_CHECK_SIZEOF(void *)
 295 AC_CHECK_SIZEOF(short)
 296 AC_CHECK_SIZEOF(int)
 297 AC_CHECK_SIZEOF(long)
 298 if test $ac_cv_c_long_long = yes; then
 299   AC_CHECK_SIZEOF(long long)
 300 fi
 301 if test $ac_cv_c___int64 = yes; then
 302   AC_CHECK_SIZEOF(__int64)
 303 fi
 304
 305 # ---------------------
 306 # Warnings and checking
 307 # ---------------------
 308
 309 # Check $CC warning features (if it's GCC).
 310 # We want to use -pedantic, but we don't want warnings about
 311 # * 'long long'
 312 # * variadic macros
 313 # So, we only use -pedantic if we can disable those warnings.
 314
 315 AC_CACHE_CHECK(
 316   [whether ${CC} accepts -Wno-long-long],
 317   [ac_cv_prog_cc_w_no_long_long],
 318   [save_CFLAGS="$CFLAGS"
 319   CFLAGS="-Wno-long-long"
 320   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 321                     [ac_cv_prog_cc_w_no_long_long=yes],
 322                     [ac_cv_prog_cc_w_no_long_long=no])
 323   CFLAGS="$save_CFLAGS"
 324   ])
 325
 326 AC_CACHE_CHECK(
 327   [whether ${CC} accepts -Wno-variadic-macros],
 328   [ac_cv_prog_cc_w_no_variadic_macros],
 329   [save_CFLAGS="$CFLAGS"
 330   CFLAGS="-Wno-variadic-macros"
 331   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 332                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 333                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 334   CFLAGS="$save_CFLAGS"
 335   ])
 336
 337 strict1_warn=
 338 if test $ac_cv_prog_cc_w_no_long_long = yes \
 339    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 340   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 341 fi
 342 AC_SUBST(strict1_warn)
 343
 344 # Add -Wold-style-definition if it's accepted
 345 AC_CACHE_CHECK(
 346   [whether ${CC} accepts -Wold-style-definition],
 347   [ac_cv_prog_cc_w_old_style_definition],
 348   [save_CFLAGS="$CFLAGS"
 349   CFLAGS="-Wold-style-definition"
 350   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 351                     [ac_cv_prog_cc_w_old_style_definition=yes],
 352                     [ac_cv_prog_cc_w_old_style_definition=no])
 353   CFLAGS="$save_CFLAGS"
 354   ])
 355 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 356   strict1_warn="${strict1_warn} -Wold-style-definition"
 357 fi
 358
 359 # Enable -Werror, period.
 360 AC_ARG_ENABLE(werror_always,
 361 [  --enable-werror-always         enable -Werror always], [],
 362 [enable_werror_always=no])
 363 if test x${enable_werror_always} = xyes ; then
 364   strict1_warn="${strict1_warn} -Werror"
 365   WERROR=-Werror
 366 fi
 367
 368 # If the native compiler is GCC, we can enable warnings even in stage1.
 369 # That's useful for people building cross-compilers, or just running a
 370 # quick `make'.
 371 warn_cflags=
 372 if test "x$GCC" = "xyes"; then
 373   warn_cflags='$(GCC_WARN_CFLAGS)'
 374 fi
 375 AC_SUBST(warn_cflags)
 376
 377 # Enable -Werror in bootstrap stage2 and later.
 378 AC_ARG_ENABLE(werror,
 379 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 380 [if test x$is_release = x ; then
 381   # Default to "yes" on development branches.
 382   enable_werror=yes
 383 else
 384   # Default to "no" on release branches.
 385   enable_werror=no
 386 fi])
 387 if test x$enable_werror = xyes ; then
 388   WERROR=-Werror
 389 fi
 390 AC_SUBST(WERROR)
 391
 392 # Enable expensive internal checks
 393 AC_ARG_ENABLE(checking,
 394 [  --enable-checking[=LIST]
 395                           enable expensive run-time checks.  With LIST,
 396                           enable only specific categories of checks.
 397                           Categories are: assert,fold,gc,gcac,misc,
 398                           rtlflag,rtl,tree,valgrind,release,yes,all;],
 399 [ac_checking_flags="${enableval}"],[
 400 # Determine the default checks.
 401 if test x$is_release = x ; then
 402   ac_checking_flags=yes
 403 else
 404   ac_checking_flags=release
 405 fi])
 406 ac_assert_checking=1
 407 ac_checking=
 408 ac_tree_checking=
 409 ac_rtl_checking=
 410 ac_rtlflag_checking=
 411 ac_gc_checking=
 412 ac_gc_always_collect=
 413 ac_fold_checking=
 414 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 415 for check in $ac_checking_flags
 416 do
 417         case $check in
 418         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 419                         ac_tree_checking=1 ; ac_gc_checking=1 ;
 420                         ac_rtlflag_checking=1 ;;
 421         no)             ac_assert_checking= ; ac_checking= ;
 422                         ac_tree_checking= ; ac_rtl_checking= ;
 423                         ac_rtlflag_checking= ; ac_gc_checking= ;
 424                         ac_gc_always_collect= ; ac_fold_checking= ;;
 425         all)            ac_assert_checking=1 ; ac_checking=1 ;
 426                         ac_tree_checking=1 ; ac_rtl_checking=1 ;
 427                         ac_rtlflag_checking=1 ; ac_gc_checking=1 ;
 428                         ac_gc_always_collect=1 ; ac_fold_checking=1 ;;
 429         release)        ac_assert_checking=1 ;;
 430         assert)         ac_assert_checking=1 ;;
 431         fold)           ac_fold_checking=1 ;;
 432         gc)             ac_gc_checking=1 ;;
 433         gcac)           ac_gc_always_collect=1 ;;
 434         misc)           ac_checking=1 ;;
 435         rtlflag)        ac_rtlflag_checking=1 ;;
 436         rtl)            ac_rtl_checking=1 ;;
 437         tree)           ac_tree_checking=1 ;;
 438         valgrind)       ac_checking_valgrind=1 ;;
 439         *)      AC_MSG_ERROR(unknown check category $check) ;;
 440         esac
 441 done
 442 IFS="$ac_save_IFS"
 443
 444 nocommon_flag=""
 445 if test x$ac_checking != x ; then
 446   AC_DEFINE(ENABLE_CHECKING, 1,
 447 [Define if you want more run-time sanity checks.  This one gets a grab
 448    bag of miscellaneous but relatively cheap checks.])
 449   nocommon_flag=-fno-common
 450 fi
 451 AC_SUBST(nocommon_flag)
 452 if test x$ac_assert_checking != x ; then
 453   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 454 [Define if you want assertions enabled.  This is a cheap check.])
 455 fi
 456 if test x$ac_tree_checking != x ; then
 457   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 458 [Define if you want all operations on trees (the basic data
 459    structure of the front ends) to be checked for dynamic type safety
 460    at runtime.  This is moderately expensive.  The tree browser debugging
 461    routines will also be enabled by this option.
 462    ])
 463   TREEBROWSER=tree-browser.o
 464 fi
 465 AC_SUBST(TREEBROWSER)
 466 if test x$ac_rtl_checking != x ; then
 467   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 468 [Define if you want all operations on RTL (the basic data structure
 469    of the optimizer and back end) to be checked for dynamic type safety
 470    at runtime.  This is quite expensive.])
 471 fi
 472 if test x$ac_rtlflag_checking != x ; then
 473   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 474 [Define if you want RTL flag accesses to be checked against the RTL
 475    codes that are supported for each access macro.  This is relatively
 476    cheap.])
 477 fi
 478 if test x$ac_gc_checking != x ; then
 479   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 480 [Define if you want the garbage collector to do object poisoning and
 481    other memory allocation checks.  This is quite expensive.])
 482 fi
 483 if test x$ac_gc_always_collect != x ; then
 484   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 485 [Define if you want the garbage collector to operate in maximally
 486    paranoid mode, validating the entire heap and collecting garbage at
 487    every opportunity.  This is extremely expensive.])
 488 fi
 489 if test x$ac_fold_checking != x ; then
 490   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 491 [Define if you want fold checked that it never destructs its argument.
 492    This is quite expensive.])
 493 fi
 494 valgrind_path_defines=
 495 valgrind_command=
 496
 497 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 498 dnl # an if statement.  This was the source of very frustrating bugs
 499 dnl # in converting to autoconf 2.5x!
 500 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 501
 502 if test x$ac_checking_valgrind != x ; then
 503   # It is certainly possible that there's valgrind but no valgrind.h.
 504   # GCC relies on making annotations so we must have both.
 505   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 506   AC_TRY_CPP(
 507     [#include <valgrind/memcheck.h>
 508 #ifndef VALGRIND_DISCARD
 509 #error VALGRIND_DISCARD not defined
 510 #endif],
 511   [gcc_cv_header_valgrind_memcheck_h=yes],
 512   [gcc_cv_header_valgrind_memcheck_h=no])
 513   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 514   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 515   AC_TRY_CPP(
 516     [#include <memcheck.h>
 517 #ifndef VALGRIND_DISCARD
 518 #error VALGRIND_DISCARD not defined
 519 #endif],
 520   [gcc_cv_header_memcheck_h=yes],
 521   gcc_cv_header_memcheck_h=no)
 522   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 523   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 524         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 525   if test "x$valgrind_path" = "x" \
 526     || (test $have_valgrind_h = no \
 527         && test $gcc_cv_header_memcheck_h = no \
 528         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 529         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 530   fi
 531   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 532   valgrind_command="$valgrind_path -q"
 533   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 534 [Define if you want to run subprograms and generated programs
 535    through valgrind (a memory checker).  This is extremely expensive.])
 536   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 537     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 538         [Define if valgrind's valgrind/memcheck.h header is installed.])
 539   fi
 540   if test $gcc_cv_header_memcheck_h = yes; then
 541     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 542         [Define if valgrind's memcheck.h header is installed.])
 543   fi
 544 fi
 545 AC_SUBST(valgrind_path_defines)
 546 AC_SUBST(valgrind_command)
 547
 548 AC_ARG_ENABLE(mapped-location,
 549 [  --enable-mapped-location   location_t is fileline integer cookie],,
 550 enable_mapped_location=no)
 551
 552 if test "$enable_mapped_location" = yes ; then
 553   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 554 [Define if location_t is fileline integer cookie.])
 555 fi
 556
 557 # Enable code coverage collection
 558 AC_ARG_ENABLE(coverage,
 559 [  --enable-coverage[=LEVEL]
 560                           enable compiler's code coverage collection.
 561                           Use to measure compiler performance and locate
 562                           unused parts of the compiler. With LEVEL, specify
 563                           optimization. Values are opt, noopt,
 564                           default is noopt],
 565 [case "${enableval}" in
 566   yes|noopt)
 567     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 568     ;;
 569   opt)
 570     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 571     ;;
 572   no)
 573     # a.k.a. --disable-coverage
 574     coverage_flags=""
 575     ;;
 576   *)
 577     AC_MSG_ERROR(unknown coverage setting $enableval)
 578     ;;
 579 esac],
 580 [coverage_flags=""])
 581 AC_SUBST(coverage_flags)
 582
 583 AC_ARG_ENABLE(gather-detailed-mem-stats,
 584 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 585 [enable_gather_detailed_mem_stats=no])
 586 if test x$enable_gather_detailed_mem_stats = xyes ; then
 587   AC_DEFINE(GATHER_STATISTICS, 1,
 588         [Define to enable detailed memory allocation stats gathering.])
 589 fi
 590
 591 # -------------------------------
 592 # Miscenalleous configure options
 593 # -------------------------------
 594
 595 # With stabs
 596 AC_ARG_WITH(stabs,
 597 [  --with-stabs            arrange to use stabs instead of host debug format],
 598 stabs="$with_stabs",
 599 stabs=no)
 600
 601 # Determine whether or not multilibs are enabled.
 602 AC_ARG_ENABLE(multilib,
 603 [  --enable-multilib       enable library support for multiple ABIs],
 604 [], [enable_multilib=yes])
 605 AC_SUBST(enable_multilib)
 606
 607 # Enable __cxa_atexit for C++.
 608 AC_ARG_ENABLE(__cxa_atexit,
 609 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 610 [], [])
 611
 612 # Enable threads
 613 # Pass with no value to take the default
 614 # Pass with a value to specify a thread package
 615 AC_ARG_ENABLE(threads,
 616 [  --enable-threads        enable thread usage for target GCC
 617   --enable-threads=LIB    use LIB thread package for target GCC],,
 618 [enable_threads=''])
 619
 620 AC_ARG_ENABLE(objc-gc,
 621 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 622                           the GNU Objective-C runtime],
 623 if test x$enable_objc_gc = xno; then
 624         objc_boehm_gc=''
 625 else
 626         objc_boehm_gc=1
 627 fi,
 628 objc_boehm_gc='')
 629
 630 AC_ARG_WITH(dwarf2,
 631 [  --with-dwarf2           force the default debug format to be DWARF 2],
 632 dwarf2="$with_dwarf2",
 633 dwarf2=no)
 634
 635 AC_ARG_ENABLE(shared,
 636 [  --disable-shared        don't provide a shared libgcc],
 637 [
 638   case $enable_shared in
 639   yes | no) ;;
 640   *)
 641     enable_shared=no
 642     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 643     for pkg in $enableval; do
 644       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 645         enable_shared=yes
 646       fi
 647     done
 648     IFS="$ac_save_ifs"
 649     ;;
 650   esac
 651 ], [enable_shared=yes])
 652 AC_SUBST(enable_shared)
 653
 654 AC_ARG_WITH(sysroot,
 655 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 656 [
 657  case ${with_sysroot} in
 658  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 659  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 660  esac
 661
 662  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 663  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 664
 665  if test "x$exec_prefix" = xNONE; then
 666   if test "x$prefix" = xNONE; then
 667    test_prefix=/usr/local
 668   else
 669    test_prefix=$prefix
 670   fi
 671  else
 672   test_prefix=$exec_prefix
 673  fi
 674  case ${TARGET_SYSTEM_ROOT} in
 675  "${test_prefix}"|"${test_prefix}/"*|\
 676  '${exec_prefix}'|'${exec_prefix}/'*)
 677    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 678    TARGET_SYSTEM_ROOT_DEFINE="$t"
 679    ;;
 680  esac
 681 ], [
 682  TARGET_SYSTEM_ROOT=
 683  TARGET_SYSTEM_ROOT_DEFINE=
 684  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 685 ])
 686 AC_SUBST(TARGET_SYSTEM_ROOT)
 687 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 688 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 689
 690 # Build with intermodule optimisations
 691 AC_ARG_ENABLE(intermodule,
 692 [  --enable-intermodule    build the compiler in one step],
 693 [case ${enable_intermodule} in
 694   yes) onestep="-onestep";;
 695   *) onestep="";;
 696 esac],
 697 [onestep=""])
 698 AC_SUBST(onestep)
 699
 700 # Sanity check enable_languages in case someone does not run the toplevel
 701 # configure # script.
 702 AC_ARG_ENABLE(languages,
 703 [  --enable-languages=LIST specify which front-ends to build],
 704 [case ,${enable_languages}, in
 705        ,,|,yes,)
 706                 # go safe -- we cannot be much sure without the toplevel
 707                 # configure's
 708                 # analysis of which target libs are present and usable
 709                 enable_languages=c
 710                 ;;
 711          *,all,*)
 712                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 713                 ;;
 714         *,c,*)
 715                 ;;
 716         *)
 717                 enable_languages=c,${enable_languages}
 718                 ;;
 719 esac],
 720 [enable_languages=c])
 721
 722 subdirs=
 723 for lang in ${srcdir}/*/config-lang.in
 724 do
 725         case $lang in
 726         # The odd quoting in the next line works around
 727         # an apparent bug in bash 1.12 on linux.
 728 changequote(,)dnl
 729         ${srcdir}/[*]/config-lang.in) ;;
 730         *)
 731           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 732           if test "x$lang_alias" = x
 733           then
 734                 echo "$lang doesn't set \$language." 1>&2
 735                 exit 1
 736           fi
 737           case ",$enable_languages," in
 738           *,$lang_alias,*)
 739             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 740           esac
 741           ;;
 742 changequote([,])dnl
 743         esac
 744 done
 745
 746
 747 # -------------------------
 748 # Checks for other programs
 749 # -------------------------
 750
 751 AC_PROG_MAKE_SET
 752
 753 # Find some useful tools
 754 AC_PROG_AWK
 755 # We need awk to create options.c and options.h.
 756 # Bail out if it's missing.
 757 case ${AWK} in
 758   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 759 esac
 760
 761 gcc_AC_PROG_LN_S
 762 ACX_PROG_LN($LN_S)
 763 AC_PROG_RANLIB
 764 case "${host}" in
 765 *-*-darwin*)
 766   # By default, the Darwin ranlib will not treat common symbols as
 767   # definitions when  building the archive table of contents.  Other
 768   # ranlibs do that; pass an option to the Darwin ranlib that makes
 769   # it behave similarly.
 770   ranlib_flags="-c"
 771   ;;
 772 *)
 773   ranlib_flags=""
 774 esac
 775 AC_SUBST(ranlib_flags)
 776
 777 gcc_AC_PROG_INSTALL
 778
 779 # See if cmp has --ignore-initial.
 780 gcc_AC_PROG_CMP_IGNORE_INITIAL
 781
 782 # See if we have the mktemp command.
 783 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 784
 785 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 786
 787 # See if makeinfo has been installed and is modern enough
 788 # that we can use it.
 789 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 790   [GNU texinfo.* \([0-9][0-9.]*\)],
 791   [4.[2-9]*])
 792 if test $gcc_cv_prog_makeinfo_modern = no; then
 793   MAKEINFO="$MISSING makeinfo"
 794   AC_MSG_WARN([
 795 *** Makeinfo is missing or too old.
 796 *** Info documentation will not be built.])
 797   BUILD_INFO=
 798 else
 799   BUILD_INFO=info
 800 fi
 801 AC_SUBST(BUILD_INFO)
 802
 803 # Is pod2man recent enough to regenerate manpages?
 804 AC_MSG_CHECKING([for recent Pod::Man])
 805 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 806   AC_MSG_RESULT(yes)
 807   GENERATED_MANPAGES=generated-manpages
 808 else
 809   AC_MSG_RESULT(no)
 810   GENERATED_MANPAGES=
 811 fi
 812 AC_SUBST(GENERATED_MANPAGES)
 813
 814 # How about lex?
 815 dnl Don't use AC_PROG_LEX; we insist on flex.
 816 dnl LEXLIB is not useful in gcc.
 817 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 818
 819 # Bison?
 820 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 821
 822 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 823 # check for build == host before using them.
 824
 825 # NM
 826 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 827   && test -d ../binutils ; then
 828   NM='$(objdir)/../binutils/nm-new'
 829 else
 830   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 831 fi
 832
 833 # AR
 834 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 835   && test -d ../binutils ; then
 836   AR='$(objdir)/../binutils/ar'
 837 else
 838   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 839 fi
 840
 841
 842 # --------------------
 843 # Checks for C headers
 844 # --------------------
 845
 846 AC_MSG_CHECKING(for GNU C library)
 847 AC_CACHE_VAL(gcc_cv_glibc,
 848 [AC_TRY_COMPILE(
 849   [#include <features.h>],[
 850 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 851 #error Not a GNU C library system
 852 #endif],
 853   [gcc_cv_glibc=yes],
 854   gcc_cv_glibc=no)])
 855 AC_MSG_RESULT($gcc_cv_glibc)
 856 if test $gcc_cv_glibc = yes; then
 857   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 858 fi
 859
 860 # Need to reject headers which give warnings, so that the -Werror bootstrap
 861 # works later. *sigh*  This needs to come before all header checks.
 862 AC_PROG_CPP_WERROR
 863
 864 AC_HEADER_STDC
 865 AC_HEADER_TIME
 866 ACX_HEADER_STRING
 867 AC_HEADER_SYS_WAIT
 868 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 869                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 870                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 871                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 872
 873 # Check for thread headers.
 874 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 875 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 876
 877 # These tests can't be done till we know if we have limits.h.
 878 gcc_AC_C_CHAR_BIT
 879 AC_C_BIGENDIAN_CROSS
 880
 881 # --------
 882 # UNSORTED
 883 # --------
 884
 885 # Stage specific cflags for build.
 886 stage1_cflags=
 887 case $build in
 888 vax-*-*)
 889   if test x$GCC = xyes
 890   then
 891     stage1_cflags="-Wa,-J"
 892   else
 893     stage1_cflags="-J"
 894   fi
 895   ;;
 896 powerpc-*-darwin*)
 897   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 898   # sources; use -no-cpp-precomp to get to GNU cpp.
 899   # Apple's GCC has bugs in designated initializer handling, so disable
 900   # that too.
 901   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 902   ;;
 903 esac
 904 AC_SUBST(stage1_cflags)
 905
 906 # These libraries may be used by collect2.
 907 # We may need a special search path to get them linked.
 908 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 909 [save_LIBS="$LIBS"
 910 for libs in '' -lld -lmld \
 911                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 912                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 913 do
 914         LIBS="$libs"
 915         AC_TRY_LINK_FUNC(ldopen,
 916                 [gcc_cv_collect2_libs="$libs"; break])
 917 done
 918 LIBS="$save_LIBS"
 919 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 920 case $gcc_cv_collect2_libs in
 921         "none required")        ;;
 922         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 923 esac
 924 AC_SUBST(COLLECT2_LIBS)
 925
 926 # When building Ada code on Alpha, we need exc_resume which is usually in
 927 # -lexc.  So test for it.
 928 save_LIBS="$LIBS"
 929 LIBS=
 930 AC_SEARCH_LIBS(exc_resume, exc)
 931 GNAT_LIBEXC="$LIBS"
 932 LIBS="$save_LIBS"
 933 AC_SUBST(GNAT_LIBEXC)
 934
 935 # Some systems put ldexp and frexp in libm instead of libc; assume
 936 # they're both in the same place.  jcf-dump needs them.
 937 save_LIBS="$LIBS"
 938 LIBS=
 939 AC_SEARCH_LIBS(ldexp, m)
 940 LDEXP_LIB="$LIBS"
 941 LIBS="$save_LIBS"
 942 AC_SUBST(LDEXP_LIB)
 943
 944 # Use <inttypes.h> only if it exists,
 945 # doesn't clash with <sys/types.h>, and declares intmax_t.
 946 AC_MSG_CHECKING(for inttypes.h)
 947 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 948 [AC_TRY_COMPILE(
 949   [#include <sys/types.h>
 950 #include <inttypes.h>],
 951   [intmax_t i = -1;],
 952   [gcc_cv_header_inttypes_h=yes],
 953   gcc_cv_header_inttypes_h=no)])
 954 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 955 if test $gcc_cv_header_inttypes_h = yes; then
 956   AC_DEFINE(HAVE_INTTYPES_H, 1,
 957         [Define if you have a working <inttypes.h> header file.])
 958 fi
 959
 960 dnl Disabled until we have a complete test for buggy enum bitfields.
 961 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 962
 963 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 964         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 965         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 966         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 967         setlocale)
 968
 969 if test x$ac_cv_func_mbstowcs = xyes; then
 970   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 971 [    AC_TRY_RUN([#include <stdlib.h>
 972 int main()
 973 {
 974   mbstowcs(0, "", 0);
 975   return 0;
 976 }],
 977     gcc_cv_func_mbstowcs_works=yes,
 978     gcc_cv_func_mbstowcs_works=no,
 979     gcc_cv_func_mbstowcs_works=yes)])
 980   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 981     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 982   [Define this macro if mbstowcs does not crash when its
 983    first argument is NULL.])
 984   fi
 985 fi
 986
 987 AC_CHECK_TYPE(ssize_t, int)
 988
 989 # Try to determine the array type of the second argument of getgroups
 990 # for the target system (int or gid_t).
 991 AC_TYPE_GETGROUPS
 992 if test "${target}" = "${build}"; then
 993   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 994 else
 995   case "${target}" in
 996         # This condition may need some tweaking.  It should include all
 997         # targets where the array type of the second argument of getgroups
 998         # is int and the type of gid_t is not equivalent to int.
 999         *-*-sunos* | *-*-ultrix*)
1000                 TARGET_GETGROUPS_T=int
1001                 ;;
1002         *)
1003                 TARGET_GETGROUPS_T=gid_t
1004                 ;;
1005   esac
1006 fi
1007 AC_SUBST(TARGET_GETGROUPS_T)
1008
1009 gcc_AC_FUNC_PRINTF_PTR
1010 gcc_AC_FUNC_MMAP_BLACKLIST
1011
1012 case "${host}" in
1013 *-*-*vms*)
1014   # Under VMS, vfork works very differently than on Unix. The standard test
1015   # won't work, and it isn't easily adaptable. It makes more sense to
1016   # just force it.
1017   ac_cv_func_vfork_works=yes
1018   ;;
1019 esac
1020 AC_FUNC_VFORK
1021
1022 AM_ICONV
1023 # Until we have in-tree GNU iconv:
1024 LIBICONV_DEP=
1025 AC_SUBST(LIBICONV_DEP)
1026
1027 AM_LC_MESSAGES
1028
1029 AM_LANGINFO_CODESET
1030
1031 # We will need to find libiberty.h and ansidecl.h
1032 saved_CFLAGS="$CFLAGS"
1033 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1034 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1035         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1036         fprintf_unlocked strstr errno snprintf vasprintf \
1037         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1038 #include "ansidecl.h"
1039 #include "system.h"])
1040
1041 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1042 #include "ansidecl.h"
1043 #include "system.h"
1044 #ifdef HAVE_SYS_RESOURCE_H
1045 #include <sys/resource.h>
1046 #endif
1047 ])
1048
1049 AC_TRY_COMPILE([
1050 #include "ansidecl.h"
1051 #include "system.h"
1052 #ifdef HAVE_SYS_RESOURCE_H
1053 #include <sys/resource.h>
1054 #endif
1055 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1056 [Define to \`long' if <sys/resource.h> doesn't define.])])
1057
1058 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1059 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1060 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1061 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1062 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1063 #include "ansidecl.h"
1064 #include "system.h"
1065 #ifdef HAVE_LDFCN_H
1066 #undef FREAD
1067 #undef FWRITE
1068 #include <ldfcn.h>
1069 #endif
1070 ])
1071
1072 gcc_AC_CHECK_DECLS(times, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"
1075 #ifdef HAVE_SYS_TIMES_H
1076 #include <sys/times.h>
1077 #endif
1078 ])
1079
1080 # More time-related stuff.
1081 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1082 AC_TRY_COMPILE([
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_SYS_TIMES_H
1086 #include <sys/times.h>
1087 #endif
1088 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1089 if test $ac_cv_struct_tms = yes; then
1090   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1091   [Define if <sys/times.h> defines struct tms.])
1092 fi
1093
1094 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1095 # revisit after autoconf 2.50.
1096 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1097 AC_TRY_COMPILE([
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1101 if test $gcc_cv_type_clock_t = yes; then
1102   AC_DEFINE(HAVE_CLOCK_T, 1,
1103   [Define if <time.h> defines clock_t.])
1104 fi
1105
1106 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1107 CFLAGS="$saved_CFLAGS"
1108
1109 gcc_AC_INITFINI_ARRAY
1110
1111 # mkdir takes a single argument on some systems.
1112 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1113
1114 # File extensions
1115 manext='.1'
1116 objext='.o'
1117 AC_SUBST(manext)
1118 AC_SUBST(objext)
1119
1120 # With Setjmp/Longjmp based exception handling.
1121 AC_ARG_ENABLE(sjlj-exceptions,
1122 [  --enable-sjlj-exceptions
1123                           arrange to use setjmp/longjmp exception handling],
1124 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1125 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1126   [Define 0/1 to force the choice for exception handling model.])])
1127
1128 # For platforms with the unwind ABI which includes an unwind library,
1129 # libunwind, we can choose to use the system libunwind.
1130 AC_ARG_WITH(system-libunwind,
1131 [  --with-system-libunwind use installed libunwind])
1132
1133 # --------------------------------------------------------
1134 # Build, host, and target specific configuration fragments
1135 # --------------------------------------------------------
1136
1137 # Collect build-machine-specific information.
1138 . ${srcdir}/config.build
1139
1140 # Collect host-machine-specific information.
1141 . ${srcdir}/config.host
1142
1143 target_gtfiles=
1144
1145 # Collect target-machine-specific information.
1146 . ${srcdir}/config.gcc
1147
1148 extra_objs="${host_extra_objs} ${extra_objs}"
1149 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1150
1151 # Default the target-machine variables that were not explicitly set.
1152 if test x"$tm_file" = x
1153 then tm_file=$cpu_type/$cpu_type.h; fi
1154
1155 if test x"$extra_headers" = x
1156 then extra_headers=; fi
1157
1158 if test x$md_file = x
1159 then md_file=$cpu_type/$cpu_type.md; fi
1160
1161 if test x$out_file = x
1162 then out_file=$cpu_type/$cpu_type.c; fi
1163
1164 if test x"$tmake_file" = x
1165 then tmake_file=$cpu_type/t-$cpu_type
1166 fi
1167
1168 if test x"$dwarf2" = xyes
1169 then tm_file="$tm_file tm-dwarf2.h"
1170 fi
1171
1172 # Say what files are being used for the output code and MD file.
1173 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1174 echo "Using \`$srcdir/config/$md_file' as machine description file."
1175
1176 # If any of the xm_file variables contain nonexistent files, warn
1177 # about them and drop them.
1178
1179 bx=
1180 for x in $build_xm_file; do
1181   if    test -f $srcdir/config/$x
1182   then      bx="$bx $x"
1183   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1184   fi
1185 done
1186 build_xm_file="$bx"
1187
1188 hx=
1189 for x in $host_xm_file; do
1190   if    test -f $srcdir/config/$x
1191   then      hx="$hx $x"
1192   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1193   fi
1194 done
1195 host_xm_file="$hx"
1196
1197 tx=
1198 for x in $xm_file; do
1199   if    test -f $srcdir/config/$x
1200   then      tx="$tx $x"
1201   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1202   fi
1203 done
1204 xm_file="$tx"
1205
1206 count=a
1207 for f in $tm_file; do
1208         count=${count}x
1209 done
1210 if test $count = ax; then
1211         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1212 else
1213         echo "Using the following target machine macro files:"
1214         for f in $tm_file; do
1215                 echo "  $srcdir/config/$f"
1216         done
1217 fi
1218
1219 if test x$need_64bit_hwint = xyes; then
1220         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1221 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1222 fi
1223
1224 if test x$use_long_long_for_widest_fast_int = xyes; then
1225         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1226 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1227 efficiently supported by the host hardware.])
1228 fi
1229
1230 count=a
1231 for f in $host_xm_file; do
1232         count=${count}x
1233 done
1234 if test $count = a; then
1235         :
1236 elif test $count = ax; then
1237         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1238 else
1239         echo "Using the following host machine macro files:"
1240         for f in $host_xm_file; do
1241                 echo "  $srcdir/config/$f"
1242         done
1243 fi
1244 echo "Using ${out_host_hook_obj} for host machine hooks."
1245
1246 if test "$host_xm_file" != "$build_xm_file"; then
1247         count=a
1248         for f in $build_xm_file; do
1249                 count=${count}x
1250         done
1251         if test $count = a; then
1252                 :
1253         elif test $count = ax; then
1254                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1255         else
1256                 echo "Using the following build machine macro files:"
1257                 for f in $build_xm_file; do
1258                         echo "  $srcdir/config/$f"
1259                 done
1260         fi
1261 fi
1262
1263 # ---------
1264 # Threading
1265 # ---------
1266
1267 # Check if a valid thread package
1268 case ${enable_threads} in
1269   "" | no)
1270     # No threads
1271     target_thread_file='single'
1272     ;;
1273   yes)
1274     # default
1275     target_thread_file='single'
1276     ;;
1277   aix | dce | gnat | irix | posix | posix95 | rtems | \
1278   single | solaris | vxworks | win32 )
1279     target_thread_file=${enable_threads}
1280     ;;
1281   *)
1282     echo "${enable_threads} is an unknown thread package" 1>&2
1283     exit 1
1284     ;;
1285 esac
1286
1287 if test x${thread_file} = x; then
1288   # No thread file set by target-specific clauses in config.gcc,
1289   # so use file chosen by default logic above
1290   thread_file=${target_thread_file}
1291 fi
1292
1293 # Make gthr-default.h if we have a thread file.
1294 gthread_flags=
1295 if test $thread_file != single; then
1296   rm -f gthr-default.h
1297   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1298   gthread_flags=-DHAVE_GTHR_DEFAULT
1299 fi
1300 AC_SUBST(gthread_flags)
1301
1302 # --------
1303 # UNSORTED
1304 # --------
1305
1306 use_cxa_atexit=no
1307 if test x$enable___cxa_atexit = xyes || \
1308    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1309   if test x$host = x$target; then
1310     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1311         [echo "__cxa_atexit can't be enabled on this target"])
1312   else
1313     # We can't check for __cxa_atexit when building a cross, so assume
1314     # it is available
1315     use_cxa_atexit=yes
1316   fi
1317   if test x$use_cxa_atexit = xyes; then
1318     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1319       [Define if you want to use __cxa_atexit, rather than atexit, to
1320       register C++ destructors for local statics and global objects.
1321       This is essential for fully standards-compliant handling of
1322       destructors, but requires __cxa_atexit in libc.])
1323   fi
1324 fi
1325
1326 # Look for a file containing extra machine modes.
1327 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1328   extra_modes_file='$(srcdir)'/config/${extra_modes}
1329   AC_SUBST(extra_modes_file)
1330   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1331   [Define to the name of a file containing a list of extra machine modes
1332    for this architecture.])
1333 fi
1334
1335 # auto-host.h is the file containing items generated by autoconf and is
1336 # the first file included by config.h.
1337 # If host=build, it is correct to have bconfig include auto-host.h
1338 # as well.  If host!=build, we are in error and need to do more
1339 # work to find out the build config parameters.
1340 if test x$host = x$build
1341 then
1342         build_auto=auto-host.h
1343 else
1344         # We create a subdir, then run autoconf in the subdir.
1345         # To prevent recursion we set host and build for the new
1346         # invocation of configure to the build for this invocation
1347         # of configure.
1348         tempdir=build.$$
1349         rm -rf $tempdir
1350         mkdir $tempdir
1351         cd $tempdir
1352         case ${srcdir} in
1353         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1354         *) realsrcdir=../${srcdir};;
1355         esac
1356         saved_CFLAGS="${CFLAGS}"
1357         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1358         ${realsrcdir}/configure \
1359                 --enable-languages=${enable_languages-all} \
1360                 --target=$target_alias --host=$build_alias --build=$build_alias
1361         CFLAGS="${saved_CFLAGS}"
1362
1363         # We just finished tests for the build machine, so rename
1364         # the file auto-build.h in the gcc directory.
1365         mv auto-host.h ../auto-build.h
1366         cd ..
1367         rm -rf $tempdir
1368         build_auto=auto-build.h
1369 fi
1370 AC_SUBST(build_subdir)
1371
1372 tm_file="${tm_file} defaults.h"
1373 tm_p_file="${tm_p_file} tm-preds.h"
1374 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1375 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1376 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1377 # put this back in temporarily.
1378 xm_file="ansidecl.h ${xm_file}"
1379
1380 # --------
1381 # UNSORTED
1382 # --------
1383
1384 changequote(,)dnl
1385 # Compile in configure arguments.
1386 if test -f configargs.h ; then
1387         # Being re-configured.
1388         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1389         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1390 else
1391         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1392 fi
1393
1394 # Double all backslashes and backslash all quotes to turn
1395 # gcc_config_arguments into a C string.
1396 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1397 $gcc_config_arguments
1398 EOF
1399 gcc_config_arguments_str=`cat conftest.out`
1400 rm -f conftest.out
1401
1402 cat > configargs.h <<EOF
1403 /* Generated automatically. */
1404 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1405 static const char thread_model[] = "$thread_file";
1406
1407 static const struct {
1408   const char *name, *value;
1409 } configure_default_options[] = $configure_default_options;
1410 EOF
1411 changequote([,])dnl
1412
1413 # Internationalization
1414 PACKAGE=gcc
1415 VERSION="$gcc_version"
1416 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1417   [The name of this program for internationalization purposes.])
1418 AC_SUBST(PACKAGE)
1419 AC_SUBST(VERSION)
1420
1421 ZW_GNU_GETTEXT_SISTER_DIR
1422
1423 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1424 # -liconv on the link line twice.
1425 case "$LIBINTL" in *$LIBICONV*)
1426         LIBICONV= ;;
1427 esac
1428
1429 # Windows32 Registry support for specifying GCC installation paths.
1430 AC_ARG_ENABLE(win32-registry,
1431 [  --disable-win32-registry
1432                           disable lookup of installation paths in the
1433                           Registry on Windows hosts
1434   --enable-win32-registry enable registry lookup (default)
1435   --enable-win32-registry=KEY
1436                           use KEY instead of GCC version as the last portion
1437                           of the registry key],,)
1438 case $host_os in
1439         win32 | pe | cygwin* | mingw32* | uwin*)
1440 AC_MSG_CHECKING(whether windows registry support is requested)
1441 if test "x$enable_win32_registry" != xno; then
1442   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1443 [Define to 1 if installation paths should be looked up in Windows32
1444    Registry. Ignored on non windows32 hosts.])
1445   AC_MSG_RESULT(yes)
1446   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1447 else
1448   AC_MSG_RESULT(no)
1449 fi
1450
1451 # Check if user specified a different registry key.
1452 case "x${enable_win32_registry}" in
1453 x | xyes)
1454   # default.
1455   gcc_cv_win32_registry_key="$VERSION"
1456   ;;
1457 xno)
1458   # no registry lookup.
1459   gcc_cv_win32_registry_key=''
1460   ;;
1461 *)
1462   # user-specified key.
1463   gcc_cv_win32_registry_key="$enable_win32_registry"
1464   ;;
1465 esac
1466
1467 if test "x$enable_win32_registry" != xno; then
1468   AC_MSG_CHECKING(registry key on windows hosts)
1469   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1470         [Define to be the last portion of registry key on windows hosts.])
1471   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1472 fi
1473 ;;
1474 esac
1475
1476 # Get an absolute path to the GCC top-level source directory
1477 holddir=`${PWDCMD-pwd}`
1478 cd $srcdir
1479 topdir=`${PWDCMD-pwd}`
1480 cd $holddir
1481
1482 # Conditionalize the makefile for this host machine.
1483 xmake_file=
1484 for f in ${host_xmake_file}
1485 do
1486         if test -f ${srcdir}/config/$f
1487         then
1488                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1489         fi
1490 done
1491
1492 # Conditionalize the makefile for this target machine.
1493 tmake_file_=
1494 for f in ${tmake_file}
1495 do
1496         if test -f ${srcdir}/config/$f
1497         then
1498                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1499         fi
1500 done
1501 tmake_file="${tmake_file_}"
1502
1503 # If the host doesn't support symlinks, modify CC in
1504 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1505 # Otherwise, we can use "CC=$(CC)".
1506 rm -f symtest.tem
1507 case "$LN_S" in
1508         *-s*)
1509                 cc_set_by_configure="\$(CC)"
1510                 quoted_cc_set_by_configure="\$(CC)"
1511                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1512                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1513                 ;;
1514         *)
1515                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1516                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1517                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1518                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1519                 ;;
1520 esac
1521
1522 out_object_file=`basename $out_file .c`.o
1523
1524 tm_file_list=
1525 tm_include_list=
1526 for f in $tm_file; do
1527   case $f in
1528     defaults.h )
1529        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1530        tm_include_list="${tm_include_list} $f"
1531        ;;
1532     * )
1533        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1534        tm_include_list="${tm_include_list} config/$f"
1535        ;;
1536   esac
1537 done
1538
1539 tm_p_file_list=
1540 tm_p_include_list=
1541 for f in $tm_p_file; do
1542   case $f in
1543     tm-preds.h )
1544        tm_p_file_list="${tm_p_file_list} $f"
1545        tm_p_include_list="${tm_p_include_list} $f"
1546        ;;
1547     * )
1548        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1549        tm_p_include_list="${tm_p_include_list} config/$f"
1550   esac
1551 done
1552
1553 xm_file_list=
1554 xm_include_list=
1555 for f in $xm_file; do
1556   case $f in
1557     ansidecl.h )
1558        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1559        xm_include_list="${xm_include_list} $f"
1560        ;;
1561     auto-host.h )
1562        xm_file_list="${xm_file_list} $f"
1563        xm_include_list="${xm_include_list} $f"
1564        ;;
1565     * )
1566        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1567        xm_include_list="${xm_include_list} config/$f"
1568        ;;
1569   esac
1570 done
1571
1572 host_xm_file_list=
1573 host_xm_include_list=
1574 for f in $host_xm_file; do
1575   case $f in
1576     ansidecl.h )
1577        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1578        host_xm_include_list="${host_xm_include_list} $f"
1579        ;;
1580     auto-host.h )
1581        host_xm_file_list="${host_xm_file_list} $f"
1582        host_xm_include_list="${host_xm_include_list} $f"
1583        ;;
1584     * )
1585        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1586        host_xm_include_list="${host_xm_include_list} config/$f"
1587        ;;
1588   esac
1589 done
1590
1591 build_xm_file_list=
1592 for f in $build_xm_file; do
1593   case $f in
1594     ansidecl.h )
1595        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1596        build_xm_include_list="${build_xm_include_list} $f"
1597        ;;
1598     auto-build.h | auto-host.h )
1599        build_xm_file_list="${build_xm_file_list} $f"
1600        build_xm_include_list="${build_xm_include_list} $f"
1601        ;;
1602     * )
1603        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1604        build_xm_include_list="${build_xm_include_list} config/$f"
1605        ;;
1606   esac
1607 done
1608
1609 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1610 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1611 CROSS=                                          AC_SUBST(CROSS)
1612 ALL=all.internal                                AC_SUBST(ALL)
1613 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1614 if test x$host != x$target
1615 then
1616         CROSS="-DCROSS_COMPILE"
1617         ALL=all.cross
1618         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1619         case "$host","$target" in
1620         # Darwin crosses can use the host system's libraries and headers,
1621         # because of the fat library support.  Of course, it must be the
1622         # same version of Darwin on both sides.  Allow the user to
1623         # just say --target=foo-darwin without a version number to mean
1624         # "the version on this system".
1625             *-*-darwin*,*-*-darwin*)
1626                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1627                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1628                 if test $hostos = $targetos -o $targetos = darwin ; then
1629                     CROSS=
1630                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1631                     with_headers=yes
1632                 fi
1633                 ;;
1634
1635             i?86-*-*,x86_64-*-* \
1636             | powerpc*-*-*,powerpc64*-*-*)
1637                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1638         esac
1639 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1640         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1641         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1642 fi
1643
1644 # If this is a cross-compiler that does not
1645 # have its own set of headers then define
1646 # inhibit_libc
1647
1648 # If this is using newlib, without having the headers available now,
1649 # then define inhibit_libc in LIBGCC2_CFLAGS.
1650 # This prevents libgcc2 from containing any code which requires libc
1651 # support.
1652 inhibit_libc=
1653 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1654        test x$with_newlib = xyes ; } &&
1655      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1656        inhibit_libc=-Dinhibit_libc
1657 fi
1658 AC_SUBST(inhibit_libc)
1659
1660 # When building gcc with a cross-compiler, we need to adjust things so
1661 # that the generator programs are still built with the native compiler.
1662 # Also, we cannot run fixincludes or fix-header.
1663
1664 # These are the normal (build=host) settings:
1665 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1666 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1667 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1668
1669 # Possibly disable fixproto, on a per-target basis.
1670 case ${use_fixproto} in
1671   no)
1672     STMP_FIXPROTO=
1673     ;;
1674   yes)
1675     STMP_FIXPROTO=stmp-fixproto
1676     ;;
1677 esac
1678 AC_SUBST(STMP_FIXPROTO)
1679
1680 # And these apply if build != host, or we are generating coverage data
1681 if test x$build != x$host || test "x$coverage_flags" != x
1682 then
1683     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1684
1685     if test "x$TARGET_SYSTEM_ROOT" = x; then
1686         if [ "x$STMP_FIXPROTO" != x ] ; then
1687           STMP_FIXPROTO=stmp-install-fixproto
1688         fi
1689     fi
1690 fi
1691
1692 # Expand extra_headers to include complete path.
1693 # This substitutes for lots of t-* files.
1694 extra_headers_list=
1695 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1696 for file in ${extra_headers} ; do
1697   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1698 done
1699
1700 # Define collect2 in Makefile.
1701 case $host_can_use_collect2 in
1702   no) collect2= ;;
1703   *) collect2='collect2$(exeext)' ;;
1704 esac
1705 AC_SUBST([collect2])
1706
1707 # Add a definition of USE_COLLECT2 if system wants one.
1708 case $use_collect2 in
1709   no) use_collect2= ;;
1710   "") ;;
1711   *)
1712     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1713     xm_defines="${xm_defines} USE_COLLECT2"
1714     case $host_can_use_collect2 in
1715       no)
1716         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1717         ;;
1718     esac
1719     ;;
1720 esac
1721
1722 # ---------------------------
1723 # Assembler & linker features
1724 # ---------------------------
1725
1726 # Identify the assembler which will work hand-in-glove with the newly
1727 # built GCC, so that we can examine its features.  This is the assembler
1728 # which will be driven by the driver program.
1729 #
1730 # If build != host, and we aren't building gas in-tree, we identify a
1731 # build->target assembler and hope that it will have the same features
1732 # as the host->target assembler we'll be using.
1733 AC_MSG_CHECKING(what assembler to use)
1734 in_tree_gas=no
1735 gcc_cv_as=
1736 gcc_cv_gas_major_version=
1737 gcc_cv_gas_minor_version=
1738 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1739 if test -x "$DEFAULT_ASSEMBLER"; then
1740         gcc_cv_as="$DEFAULT_ASSEMBLER"
1741 elif test -x as$build_exeext; then
1742         # Build using assembler in the current directory.
1743         gcc_cv_as=./as$build_exeext
1744 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1745      && test -f ../gas/Makefile \
1746      && test x$build = x$host; then
1747   # Single tree build which includes gas.  We want to prefer it
1748   # over whatever linker top-level may have detected, since
1749   # we'll use what we're building after installation anyway.
1750   in_tree_gas=yes
1751   _gcc_COMPUTE_GAS_VERSION
1752   rm -f as$build_exeext
1753   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1754   in_tree_gas_is_elf=no
1755   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1756      || (grep 'obj_format = multi' ../gas/Makefile \
1757          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1758   then
1759     in_tree_gas_is_elf=yes
1760   fi
1761 m4_pattern_allow([AS_FOR_TARGET])dnl
1762 elif test -x "$AS_FOR_TARGET"; then
1763         gcc_cv_as="$AS_FOR_TARGET"
1764 elif test -x "$AS" && test x$host = x$target; then
1765         gcc_cv_as="$AS"
1766 fi
1767
1768 if test "x$gcc_cv_as" = x; then
1769         # Search the same directories that the installed compiler will
1770         # search.  Else we may find the wrong assembler and lose.  If we
1771         # do not find a suitable assembler binary, then try the user's
1772         # path.
1773         #
1774         # Also note we have to check MD_EXEC_PREFIX before checking the
1775         # user's path.  Unfortunately, there is no good way to get at the
1776         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1777         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1778         # to be fixed as part of the make/configure rewrite too.
1779
1780         if test "x$exec_prefix" = xNONE; then
1781                 if test "x$prefix" = xNONE; then
1782                         test_prefix=/usr/local
1783                 else
1784                         test_prefix=$prefix
1785                 fi
1786         else
1787                 test_prefix=$exec_prefix
1788         fi
1789
1790         # If the loop below does not find an assembler, then use whatever
1791         # one we can find in the users's path.
1792         # user's path.
1793         if test "x$program_prefix" != xNONE; then
1794                 gcc_cv_as=${program_prefix}as$build_exeext
1795         else
1796                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1797         fi
1798
1799         if test x$host = x$build; then
1800             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1801                        $test_prefix/libexec/gcc/$target_noncanonical \
1802                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1803                        /usr/lib/gcc/$target_noncanonical \
1804                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1805                        $test_prefix/$target_noncanonical/bin"
1806         else
1807             test_dirs=
1808         fi
1809
1810         if test x$host = x$target; then
1811             test_dirs="$test_dirs \
1812                    /usr/libexec \
1813                    /usr/ccs/gcc \
1814                    /usr/ccs/bin \
1815                    /udk/usr/ccs/bin \
1816                    /bsd43/usr/lib/cmplrs/cc \
1817                    /usr/cross64/usr/bin \
1818                    /usr/lib/cmplrs/cc \
1819                    /sysv/usr/lib/cmplrs/cc \
1820                    /svr4/usr/lib/cmplrs/cc \
1821                    /usr/bin"
1822         fi
1823
1824         for dir in $test_dirs; do
1825                 if test -x $dir/as$build_exeext; then
1826                         gcc_cv_as=$dir/as$build_exeext
1827                         break;
1828                 fi
1829         done
1830 fi
1831 case $in_tree_gas in
1832   yes)
1833     AC_MSG_RESULT("newly built gas")
1834     ;;
1835   no)
1836     AC_MSG_RESULT($gcc_cv_as)
1837     ;;
1838 esac
1839
1840 # Identify the linker which will work hand-in-glove with the newly
1841 # built GCC, so that we can examine its features.  This is the linker
1842 # which will be driven by the driver program.
1843 #
1844 # If build != host, and we aren't building gas in-tree, we identify a
1845 # build->target linker and hope that it will have the same features
1846 # as the host->target linker we'll be using.
1847 AC_MSG_CHECKING(what linker to use)
1848 in_tree_ld=no
1849 gcc_cv_ld=
1850 gcc_cv_gld_major_version=
1851 gcc_cv_gld_minor_version=
1852 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1853 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1854 if test -x "$DEFAULT_LINKER"; then
1855         gcc_cv_ld="$DEFAULT_LINKER"
1856 elif test -x collect-ld$build_exeext; then
1857         # Build using linker in the current directory.
1858         gcc_cv_ld=./collect-ld$build_exeext
1859 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1860      && test -f ../ld/Makefile \
1861      && test x$build = x$host; then
1862         # Single tree build which includes ld.  We want to prefer it
1863         # over whatever linker top-level may have detected, since
1864         # we'll use what we're building after installation anyway.
1865         in_tree_ld=yes
1866         in_tree_ld_is_elf=no
1867         if (grep 'EMUL = .*elf' ../ld/Makefile \
1868             || grep 'EMUL = .*linux' ../ld/Makefile \
1869             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1870           in_tree_ld_is_elf=yes
1871         fi
1872         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1873         do
1874 changequote(,)dnl
1875                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1876 changequote([,])dnl
1877                 if test x$gcc_cv_gld_version != x; then
1878                         break
1879                 fi
1880         done
1881 changequote(,)dnl
1882         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1883         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1884 changequote([,])dnl
1885         rm -f collect-ld$build_exeext
1886         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1887 elif test -x "$LD_FOR_TARGET"; then
1888         gcc_cv_ld="$LD_FOR_TARGET"
1889 elif test -x "$LD" && test x$host = x$target; then
1890         gcc_cv_ld="$LD"
1891 fi
1892
1893 if test "x$gcc_cv_ld" = x; then
1894         # Search the same directories that the installed compiler will
1895         # search.  Else we may find the wrong linker and lose.  If we
1896         # do not find a suitable linker binary, then try the user's
1897         # path.
1898         #
1899         # Also note we have to check MD_EXEC_PREFIX before checking the
1900         # user's path.  Unfortunately, there is no good way to get at the
1901         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1902         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1903         # to be fixed as part of the make/configure rewrite too.
1904
1905         if test "x$exec_prefix" = xNONE; then
1906                 if test "x$prefix" = xNONE; then
1907                         test_prefix=/usr/local
1908                 else
1909                         test_prefix=$prefix
1910                 fi
1911         else
1912                 test_prefix=$exec_prefix
1913         fi
1914
1915         # If the loop below does not find an linker, then use whatever
1916         # one we can find in the users's path.
1917         # user's path.
1918         if test "x$program_prefix" != xNONE; then
1919                 gcc_cv_ld=${program_prefix}ld$build_exeext
1920         else
1921                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1922         fi
1923
1924         if test x$host = x$build; then
1925             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1926                        $test_prefix/libexec/gcc/$target_noncanonical \
1927                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1928                        /usr/lib/gcc/$target_noncanonical \
1929                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1930                        $test_prefix/$target_noncanonical/bin"
1931         else
1932             test_dirs=
1933         fi
1934
1935         if test x$host = x$target; then
1936             test_dirs="$test_dirs \
1937                    /usr/libexec \
1938                    /usr/ccs/gcc \
1939                    /usr/ccs/bin \
1940                    /udk/usr/ccs/bin \
1941                    /bsd43/usr/lib/cmplrs/cc \
1942                    /usr/cross64/usr/bin \
1943                    /usr/lib/cmplrs/cc \
1944                    /sysv/usr/lib/cmplrs/cc \
1945                    /svr4/usr/lib/cmplrs/cc \
1946                    /usr/bin"
1947         fi
1948
1949         for dir in $test_dirs; do
1950                 if test -x $dir/ld$build_exeext; then
1951                         gcc_cv_ld=$dir/ld$build_exeext
1952                         break;
1953                 fi
1954         done
1955 fi
1956 case $in_tree_ld in
1957   yes)
1958     AC_MSG_RESULT("newly built ld")
1959     ;;
1960   no)
1961     AC_MSG_RESULT($gcc_cv_ld)
1962     ;;
1963 esac
1964
1965 # Figure out what nm we will be using.
1966 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1967 AC_MSG_CHECKING(what nm to use)
1968 in_tree_nm=no
1969 if test -x nm$build_exeext; then
1970         gcc_cv_nm=./nm$build_exeext
1971 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1972      && test -f ../binutils/Makefile; then
1973         # Single tree build which includes binutils.
1974         in_tree_nm=yes
1975         gcc_cv_nm=./nm$build_exeext
1976         rm -f nm$build_exeext
1977         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1978 elif test "x$program_prefix" != xNONE; then
1979         gcc_cv_nm=${program_prefix}nm$build_exeext
1980 else
1981         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1982 fi
1983 case $in_tree_nm in
1984   yes) AC_MSG_RESULT("newly built nm") ;;
1985   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1986 esac
1987
1988 # Figure out what objdump we will be using.
1989 AC_MSG_CHECKING(what objdump to use)
1990 in_tree_objdump=no
1991 if test -x objdump$build_exeext; then
1992         gcc_cv_objdump=./objdump$build_exeext
1993 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1994      && test -f ../binutils/Makefile; then
1995         # Single tree build which includes binutils.
1996         in_tree_objdump=yes
1997         gcc_cv_objdump=./objdump$build_exeext
1998         rm -f objdump$build_exeext
1999         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2000 elif test "x$program_prefix" != xNONE; then
2001         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2002 else
2003         gcc_cv_objdump=`echo objdump | \
2004                 sed "${program_transform_name}"`$build_exeext
2005 fi
2006 case $in_tree_objdump in
2007   yes) AC_MSG_RESULT("newly built objdump") ;;
2008   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2009 esac
2010
2011 # Figure out what assembler alignment features are present.
2012 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2013  [2,6,0],,
2014 [.balign 4
2015 .p2align 2],,
2016 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2017   [Define if your assembler supports .balign and .p2align.])])
2018
2019 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2020  [2,8,0],,
2021  [.p2align 4,,7],,
2022 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2023   [Define if your assembler supports specifying the maximum number
2024    of bytes to skip when using the GAS .p2align command.])])
2025
2026 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2027  [elf,2,9,0],,
2028  [conftest_label1: .word 0
2029 .subsection -1
2030 conftest_label2: .word 0
2031 .previous],
2032  [if test x$gcc_cv_nm != x; then
2033     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2034     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2035     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2036     then :
2037     else gcc_cv_as_subsection_m1=yes
2038     fi
2039     rm -f conftest.nm1 conftest.nm2
2040   fi],
2041  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2042   [Define if your assembler supports .subsection and .subsection -1 starts
2043    emitting at the beginning of your section.])])
2044
2045 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2046  [2,2,0],,
2047  [      .weak foobar],,
2048 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2049
2050 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2051  [2,15,91],,
2052  [      .SPACE $TEXT$
2053         .NSUBSPA $CODE$,COMDAT],,
2054 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2055
2056 # .hidden needs to be supported in both the assembler and the linker,
2057 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2058 # This is irritatingly difficult to feature test for; we have to check the
2059 # date string after the version number.  If we've got an in-tree
2060 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2061 # to be safe.
2062 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2063 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2064  [elf,2,13,0],,
2065 [       .hidden foobar
2066 foobar:])
2067
2068 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2069 [if test $in_tree_ld = yes ; then
2070   gcc_cv_ld_hidden=no
2071   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2072      && test $in_tree_ld_is_elf = yes; then
2073      gcc_cv_ld_hidden=yes
2074   fi
2075 else
2076   gcc_cv_ld_hidden=yes
2077   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2078   if echo "$ld_ver" | grep GNU > /dev/null; then
2079 changequote(,)dnl
2080     ld_vers=`echo $ld_ver | sed -n \
2081         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2082         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2083         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2084         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2085         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2086         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2087     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2088     if test 0"$ld_date" -lt 20020404; then
2089       if test -n "$ld_date"; then
2090         # If there was date string, but was earlier than 2002-04-04, fail
2091         gcc_cv_ld_hidden=no
2092       elif test -z "$ld_vers"; then
2093         # If there was no date string nor ld version number, something is wrong
2094         gcc_cv_ld_hidden=no
2095       else
2096         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2097         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2098         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2099         test -z "$ld_vers_patch" && ld_vers_patch=0
2100         if test "$ld_vers_major" -lt 2; then
2101           gcc_cv_ld_hidden=no
2102         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2103           gcc_cv_ld_hidden="no"
2104         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2105           gcc_cv_ld_hidden=no
2106         fi
2107       fi
2108 changequote([,])dnl
2109     fi
2110   else
2111     case "${target}" in
2112       hppa64*-*-hpux* | ia64*-*-hpux*)
2113         gcc_cv_ld_hidden=yes
2114         ;;
2115       *)
2116         gcc_cv_ld_hidden=no
2117         ;;
2118     esac
2119   fi
2120 fi])
2121 libgcc_visibility=no
2122 AC_SUBST(libgcc_visibility)
2123 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2124   libgcc_visibility=yes
2125   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2126   [Define if your assembler and linker support .hidden.])
2127 fi
2128
2129 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2130 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2131   [elf,2,11,0],,
2132 [       .data
2133         .uleb128 L2 - L1
2134 L1:
2135         .uleb128 1280
2136         .sleb128 -1010
2137 L2:],
2138  [# GAS versions before 2.11 do not support uleb128,
2139   # despite appearing to.
2140   # ??? There exists an elf-specific test that will crash
2141   # the assembler.  Perhaps it's better to figure out whether
2142   # arbitrary sections are supported and try the test.
2143   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2144   if echo "$as_ver" | grep GNU > /dev/null; then
2145 changequote(,)dnl
2146     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2147     as_major=`echo $as_ver | sed 's/\..*//'`
2148     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2149 changequote([,])dnl
2150     if test $as_major -eq 2 && test $as_minor -lt 11
2151     then :
2152     else gcc_cv_as_leb128=yes
2153     fi
2154   fi],
2155   [AC_DEFINE(HAVE_AS_LEB128, 1,
2156     [Define if your assembler supports .sleb128 and .uleb128.])])
2157
2158 # GAS versions up to and including 2.11.0 may mis-optimize
2159 # .eh_frame data.
2160 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2161   [elf,2,12,0],,
2162 [       .text
2163 .LFB1:
2164         .4byte  0
2165 .L1:
2166         .4byte  0
2167 .LFE1:
2168         .section        .eh_frame,"aw",@progbits
2169 __FRAME_BEGIN__:
2170         .4byte  .LECIE1-.LSCIE1
2171 .LSCIE1:
2172         .4byte  0x0
2173         .byte   0x1
2174         .ascii "z\0"
2175         .byte   0x1
2176         .byte   0x78
2177         .byte   0x1a
2178         .byte   0x0
2179         .byte   0x4
2180         .4byte  1
2181         .p2align 1
2182 .LECIE1:
2183 .LSFDE1:
2184         .4byte  .LEFDE1-.LASFDE1
2185 .LASFDE1:
2186         .4byte  .LASFDE1-__FRAME_BEGIN__
2187         .4byte  .LFB1
2188         .4byte  .LFE1-.LFB1
2189         .byte   0x4
2190         .4byte  .LFE1-.LFB1
2191         .byte   0x4
2192         .4byte  .L1-.LFB1
2193 .LEFDE1:],
2194 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2195 cat > conftest.lit <<EOF
2196  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2197  0010 01000000 12000000 18000000 00000000  ................
2198  0020 08000000 04080000 0044               .........D      @&t@
2199 EOF
2200 cat > conftest.big <<EOF
2201  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2202  0010 00000001 00000012 00000018 00000000  ................
2203  0020 00000008 04000000 0844               .........D      @&t@
2204 EOF
2205   # If the assembler didn't choke, and we can objdump,
2206   # and we got the correct data, then succeed.
2207   if test x$gcc_cv_objdump != x \
2208   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2209      | tail -3 > conftest.got \
2210   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2211     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2212   then
2213     gcc_cv_as_eh_frame=yes
2214   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2215     gcc_cv_as_eh_frame=buggy
2216   else
2217     # Uh oh, what do we do now?
2218     gcc_cv_as_eh_frame=no
2219   fi])
2220
2221 if test $gcc_cv_as_eh_frame = buggy; then
2222   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2223   [Define if your assembler mis-optimizes .eh_frame data.])
2224 fi
2225
2226 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2227  [elf,2,12,0], [--fatal-warnings],
2228  [.section .rodata.str, "aMS", @progbits, 1])
2229 if test $gcc_cv_as_shf_merge = no; then
2230   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2231     [elf,2,12,0], [--fatal-warnings],
2232     [.section .rodata.str, "aMS", %progbits, 1])
2233 fi
2234 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2235   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2236 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2237
2238 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2239  [elf,2,15,91], [--fatal-warnings],
2240  [.section .text,"axG",@progbits,.foo,comdat])
2241 if test $gcc_cv_as_comdat_group = yes; then
2242   gcc_cv_as_comdat_group_percent=no
2243 else
2244  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2245    [elf,2,15,91], [--fatal-warnings],
2246    [.section .text,"axG",%progbits,.foo,comdat])
2247 fi
2248 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2249   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2250 [Define 0/1 if your assembler supports COMDAT group.])
2251
2252 # Thread-local storage - the check is heavily parametrized.
2253 conftest_s=
2254 tls_first_major=
2255 tls_first_minor=
2256 tls_as_opt=
2257 case "$target" in
2258 changequote(,)dnl
2259   alpha*-*-*)
2260     conftest_s='
2261         .section ".tdata","awT",@progbits
2262 foo:    .long   25
2263         .text
2264         ldq     $27,__tls_get_addr($29)         !literal!1
2265         lda     $16,foo($29)                    !tlsgd!1
2266         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2267         ldq     $27,__tls_get_addr($29)         !literal!2
2268         lda     $16,foo($29)                    !tlsldm!2
2269         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2270         ldq     $1,foo($29)                     !gotdtprel
2271         ldah    $2,foo($29)                     !dtprelhi
2272         lda     $3,foo($2)                      !dtprello
2273         lda     $4,foo($29)                     !dtprel
2274         ldq     $1,foo($29)                     !gottprel
2275         ldah    $2,foo($29)                     !tprelhi
2276         lda     $3,foo($2)                      !tprello
2277         lda     $4,foo($29)                     !tprel'
2278         tls_first_major=2
2279         tls_first_minor=13
2280         tls_as_opt=--fatal-warnings
2281         ;;
2282   i[34567]86-*-*)
2283     conftest_s='
2284         .section ".tdata","awT",@progbits
2285 foo:    .long   25
2286         .text
2287         movl    %gs:0, %eax
2288         leal    foo@TLSGD(,%ebx,1), %eax
2289         leal    foo@TLSLDM(%ebx), %eax
2290         leal    foo@DTPOFF(%eax), %edx
2291         movl    foo@GOTTPOFF(%ebx), %eax
2292         subl    foo@GOTTPOFF(%ebx), %eax
2293         addl    foo@GOTNTPOFF(%ebx), %eax
2294         movl    foo@INDNTPOFF, %eax
2295         movl    $foo@TPOFF, %eax
2296         subl    $foo@TPOFF, %eax
2297         leal    foo@NTPOFF(%ecx), %eax'
2298         tls_first_major=2
2299         tls_first_minor=14
2300         tls_as_opt=--fatal-warnings
2301         ;;
2302   x86_64-*-*)
2303     conftest_s='
2304         .section ".tdata","awT",@progbits
2305 foo:    .long   25
2306         .text
2307         movq    %fs:0, %rax
2308         leaq    foo@TLSGD(%rip), %rdi
2309         leaq    foo@TLSLD(%rip), %rdi
2310         leaq    foo@DTPOFF(%rax), %rdx
2311         movq    foo@GOTTPOFF(%rip), %rax
2312         movq    $foo@TPOFF, %rax'
2313         tls_first_major=2
2314         tls_first_minor=14
2315         tls_as_opt=--fatal-warnings
2316         ;;
2317   ia64-*-*)
2318     conftest_s='
2319         .section ".tdata","awT",@progbits
2320 foo:    data8   25
2321         .text
2322         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2323         addl    r17 = @ltoff(@dtprel(foo#)), gp
2324         addl    r18 = @ltoff(@tprel(foo#)), gp
2325         addl    r19 = @dtprel(foo#), gp
2326         adds    r21 = @dtprel(foo#), r13
2327         movl    r23 = @dtprel(foo#)
2328         addl    r20 = @tprel(foo#), gp
2329         adds    r22 = @tprel(foo#), r13
2330         movl    r24 = @tprel(foo#)'
2331         tls_first_major=2
2332         tls_first_minor=13
2333         tls_as_opt=--fatal-warnings
2334         ;;
2335   powerpc-*-*)
2336     conftest_s='
2337         .section ".tdata","awT",@progbits
2338         .align 2
2339 ld0:    .space 4
2340 ld1:    .space 4
2341 x1:     .space 4
2342 x2:     .space 4
2343 x3:     .space 4
2344         .text
2345         addi 3,31,ld0@got@tlsgd
2346         bl __tls_get_addr
2347         addi 3,31,x1@got@tlsld
2348         bl __tls_get_addr
2349         addi 9,3,x1@dtprel
2350         addis 9,3,x2@dtprel@ha
2351         addi 9,9,x2@dtprel@l
2352         lwz 9,x3@got@tprel(31)
2353         add 9,9,x@tls
2354         addi 9,2,x1@tprel
2355         addis 9,2,x2@tprel@ha
2356         addi 9,9,x2@tprel@l'
2357         tls_first_major=2
2358         tls_first_minor=14
2359         tls_as_opt="-a32 --fatal-warnings"
2360         ;;
2361   powerpc64-*-*)
2362     conftest_s='
2363         .section ".tdata","awT",@progbits
2364         .align 3
2365 ld0:    .space 8
2366 ld1:    .space 8
2367 x1:     .space 8
2368 x2:     .space 8
2369 x3:     .space 8
2370         .text
2371         addi 3,2,ld0@got@tlsgd
2372         bl .__tls_get_addr
2373         nop
2374         addi 3,2,ld1@toc
2375         bl .__tls_get_addr
2376         nop
2377         addi 3,2,x1@got@tlsld
2378         bl .__tls_get_addr
2379         nop
2380         addi 9,3,x1@dtprel
2381         bl .__tls_get_addr
2382         nop
2383         addis 9,3,x2@dtprel@ha
2384         addi 9,9,x2@dtprel@l
2385         bl .__tls_get_addr
2386         nop
2387         ld 9,x3@got@dtprel(2)
2388         add 9,9,3
2389         bl .__tls_get_addr
2390         nop'
2391         tls_first_major=2
2392         tls_first_minor=14
2393         tls_as_opt="-a64 --fatal-warnings"
2394         ;;
2395   s390-*-*)
2396     conftest_s='
2397         .section ".tdata","awT",@progbits
2398 foo:    .long   25
2399         .text
2400         .long   foo@TLSGD
2401         .long   foo@TLSLDM
2402         .long   foo@DTPOFF
2403         .long   foo@NTPOFF
2404         .long   foo@GOTNTPOFF
2405         .long   foo@INDNTPOFF
2406         l       %r1,foo@GOTNTPOFF(%r12)
2407         l       %r1,0(%r1):tls_load:foo
2408         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2409         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2410         tls_first_major=2
2411         tls_first_minor=14
2412         tls_as_opt="-m31 --fatal-warnings"
2413         ;;
2414   s390x-*-*)
2415     conftest_s='
2416         .section ".tdata","awT",@progbits
2417 foo:    .long   25
2418         .text
2419         .quad   foo@TLSGD
2420         .quad   foo@TLSLDM
2421         .quad   foo@DTPOFF
2422         .quad   foo@NTPOFF
2423         .quad   foo@GOTNTPOFF
2424         lg      %r1,foo@GOTNTPOFF(%r12)
2425         larl    %r1,foo@INDNTPOFF
2426         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2427         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2428         tls_first_major=2
2429         tls_first_minor=14
2430         tls_as_opt="-m64 -Aesame --fatal-warnings"
2431         ;;
2432   sh-*-* | sh[34]-*-*)
2433     conftest_s='
2434         .section ".tdata","awT",@progbits
2435 foo:    .long   25
2436         .text
2437         .long   foo@TLSGD
2438         .long   foo@TLSLDM
2439         .long   foo@DTPOFF
2440         .long   foo@GOTTPOFF
2441         .long   foo@TPOFF'
2442         tls_first_major=2
2443         tls_first_minor=13
2444         tls_as_opt=--fatal-warnings
2445         ;;
2446   sparc*-*-*)
2447     case "$target" in
2448       sparc*-sun-solaris2.*)
2449         on_solaris=yes
2450         ;;
2451       *)
2452         on_solaris=no
2453         ;;
2454     esac
2455     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2456       conftest_s='
2457         .section ".tdata",#alloc,#write,#tls
2458 foo:    .long   25
2459         .text
2460         sethi   %tgd_hi22(foo), %o0
2461         add     %o0, %tgd_lo10(foo), %o1
2462         add     %l7, %o1, %o0, %tgd_add(foo)
2463         call    __tls_get_addr, %tgd_call(foo)
2464         sethi   %tldm_hi22(foo), %l1
2465         add     %l1, %tldm_lo10(foo), %l2
2466         add     %l7, %l2, %o0, %tldm_add(foo)
2467         call    __tls_get_addr, %tldm_call(foo)
2468         sethi   %tldo_hix22(foo), %l3
2469         xor     %l3, %tldo_lox10(foo), %l4
2470         add     %o0, %l4, %l5, %tldo_add(foo)
2471         sethi   %tie_hi22(foo), %o3
2472         add     %o3, %tie_lo10(foo), %o3
2473         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2474         add     %g7, %o2, %o4, %tie_add(foo)
2475         sethi   %tle_hix22(foo), %l1
2476         xor     %l1, %tle_lox10(foo), %o5
2477         ld      [%g7 + %o5], %o1'
2478         tls_first_major=0
2479         tls_first_minor=0
2480     else
2481       conftest_s='
2482         .section ".tdata","awT",@progbits
2483 foo:    .long   25
2484         .text
2485         sethi   %tgd_hi22(foo), %o0
2486         add     %o0, %tgd_lo10(foo), %o1
2487         add     %l7, %o1, %o0, %tgd_add(foo)
2488         call    __tls_get_addr, %tgd_call(foo)
2489         sethi   %tldm_hi22(foo), %l1
2490         add     %l1, %tldm_lo10(foo), %l2
2491         add     %l7, %l2, %o0, %tldm_add(foo)
2492         call    __tls_get_addr, %tldm_call(foo)
2493         sethi   %tldo_hix22(foo), %l3
2494         xor     %l3, %tldo_lox10(foo), %l4
2495         add     %o0, %l4, %l5, %tldo_add(foo)
2496         sethi   %tie_hi22(foo), %o3
2497         add     %o3, %tie_lo10(foo), %o3
2498         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2499         add     %g7, %o2, %o4, %tie_add(foo)
2500         sethi   %tle_hix22(foo), %l1
2501         xor     %l1, %tle_lox10(foo), %o5
2502         ld      [%g7 + %o5], %o1'
2503         tls_first_major=2
2504         tls_first_minor=14
2505         tls_as_opt="-32 --fatal-warnings"
2506       fi
2507         ;;
2508 changequote([,])dnl
2509 esac
2510 if test -z "$tls_first_major"; then
2511   : # If we don't have a check, assume no support.
2512 else
2513   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2514   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2515   [AC_DEFINE(HAVE_AS_TLS, 1,
2516             [Define if your assembler supports thread-local storage.])])
2517 fi
2518
2519 # Target-specific assembler checks.
2520
2521 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2522 gcc_cv_ld_static_dynamic=no
2523 if test $in_tree_ld = yes ; then
2524   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2525     gcc_cv_ld_static_dynamic=yes
2526   fi
2527 elif test x$gcc_cv_ld != x; then
2528         # Check if linker supports -Bstatic/-Bdynamic option
2529         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2530           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2531                 gcc_cv_ld_static_dynamic=yes
2532         fi
2533 fi
2534 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2535         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2536 [Define if your linker supports -Bstatic/-Bdynamic option.])
2537 fi
2538 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2539
2540 if test x"$demangler_in_ld" = xyes; then
2541   AC_MSG_CHECKING(linker --demangle support)
2542   gcc_cv_ld_demangle=no
2543   if test $in_tree_ld = yes; then
2544     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2545       gcc_cv_ld_demangle=yes
2546     fi
2547   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2548     # Check if the GNU linker supports --demangle option
2549     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2550       gcc_cv_ld_demangle=yes
2551     fi
2552   fi
2553   if test x"$gcc_cv_ld_demangle" = xyes; then
2554     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2555 [Define if your linker supports --demangle option.])
2556   fi
2557   AC_MSG_RESULT($gcc_cv_ld_demangle)
2558 fi
2559
2560 case "$target" in
2561   # All TARGET_ABI_OSF targets.
2562   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2563     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2564         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2565 [       .set nomacro
2566         .text
2567         extbl   $3, $2, $3      !lituse_bytoff!1
2568         ldq     $2, a($29)      !literal!1
2569         ldq     $4, b($29)      !literal!2
2570         ldq_u   $3, 0($2)       !lituse_base!1
2571         ldq     $27, f($29)     !literal!5
2572         jsr     $26, ($27), f   !lituse_jsr!5
2573         ldah    $29, 0($26)     !gpdisp!3
2574         lda     $0, c($29)      !gprel
2575         ldah    $1, d($29)      !gprelhigh
2576         lda     $1, d($1)       !gprellow
2577         lda     $29, 0($29)     !gpdisp!3],,
2578     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2579   [Define if your assembler supports explicit relocations.])])
2580     ;;
2581
2582   cris-*-*)
2583     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2584       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2585       [-no-mul-bug-abort], [.text],,
2586       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2587                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2588     ;;
2589
2590   sparc*-*-*)
2591     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2592       [.register %g2, #scratch],,
2593       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2594                 [Define if your assembler supports .register.])])
2595
2596     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2597       [-relax], [.text],,
2598       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2599                 [Define if your assembler supports -relax option.])])
2600
2601     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2602       gcc_cv_as_sparc_ua_pcrel,,
2603       [-K PIC],
2604 [.text
2605 foo:
2606         nop
2607 .data
2608 .align 4
2609 .byte 0
2610 .uaword %r_disp32(foo)],
2611       [if test x$gcc_cv_ld != x \
2612        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2613          gcc_cv_as_sparc_ua_pcrel=yes
2614        fi
2615        rm -f conftest],
2616       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2617                 [Define if your assembler and linker support unaligned PC relative relocs.])
2618
2619       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2620         gcc_cv_as_sparc_ua_pcrel_hidden,,
2621         [-K PIC],
2622 [.data
2623 .align 4
2624 .byte 0x31
2625 .uaword %r_disp32(foo)
2626 .byte 0x32, 0x33, 0x34
2627 .global foo
2628 .hidden foo
2629 foo:
2630 .skip 4],
2631         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2632          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2633          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2634             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2635             if $gcc_cv_objdump -R conftest 2> /dev/null \
2636                | grep 'DISP32' > /dev/null 2>&1; then
2637                 :
2638             else
2639                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2640             fi
2641          fi
2642          rm -f conftest],
2643          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2644                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2645     ]) # unaligned pcrel relocs
2646
2647     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2648       gcc_cv_as_sparc_offsetable_lo10,,
2649       [-xarch=v9],
2650 [.text
2651         or %g1, %lo(ab) + 12, %g1
2652         or %g1, %lo(ab + 12), %g1],
2653       [if test x$gcc_cv_objdump != x \
2654        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2655           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2656          gcc_cv_as_sparc_offsetable_lo10=yes
2657        fi],
2658        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2659                  [Define if your assembler supports offsetable %lo().])])
2660     ;;
2661
2662 changequote(,)dnl
2663   i[34567]86-*-* | x86_64-*-*)
2664 changequote([,])dnl
2665     case $target_os in
2666       cygwin* | pe | mingw32*)
2667         # Used for DWARF 2 in PE
2668         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2669           gcc_cv_as_ix86_pe_secrel32,
2670           [2,15,91],,
2671 [.text
2672 foo:    nop
2673 .data
2674         .secrel32 foo],
2675           [if test x$gcc_cv_ld != x \
2676            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2677              gcc_cv_as_ix86_pe_secrel32=yes
2678            fi
2679            rm -f conftest],
2680           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2681             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2682         ;;
2683     esac
2684
2685     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2686        gcc_cv_as_ix86_filds_fists,
2687       [2,9,0],, [filds mem; fists mem],,
2688       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2689         [Define if your assembler uses the new HImode fild and fist notation.])])
2690
2691     gcc_GAS_CHECK_FEATURE([cmov syntax],
2692       gcc_cv_as_ix86_cmov_sun_syntax,,,
2693       [cmovl.l %edx, %eax],,
2694       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2695         [Define if your assembler supports the Sun syntax for cmov.])])
2696
2697     # This one is used unconditionally by i386.[ch]; it is to be defined
2698     # to 1 if the feature is present, 0 otherwise.
2699     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2700         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2701 [       .text
2702 .L0:
2703         nop
2704         .data
2705         .long .L0@GOTOFF])
2706     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2707       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2708       [Define true if the assembler supports '.long foo@GOTOFF'.])
2709     ;;
2710
2711   ia64*-*-*)
2712     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2713         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2714 [       .text
2715         addl r15 = @ltoffx(x#), gp
2716         ;;
2717         ld8.mov r16 = [[r15]], x#],,
2718     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2719           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2720
2721     ;;
2722
2723   powerpc*-*-*)
2724     case $target in
2725       *-*-aix*) conftest_s='    .csect .text[[PR]]
2726         mfcr 3,128';;
2727       *-*-darwin*)
2728         gcc_GAS_CHECK_FEATURE([.machine directive support],
2729           gcc_cv_as_machine_directive,,,
2730           [     .machine ppc7400])
2731         if test x$gcc_cv_as_machine_directive != xyes; then
2732           echo "*** This target requires an assembler supporting \".machine\"" >&2
2733           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2734           test x$build = x$target && exit 1
2735         fi
2736         conftest_s='    .text
2737         mfcr r3,128';;
2738       *) conftest_s='   .machine power4
2739         .text
2740         mfcr 3,128';;
2741     esac
2742
2743     gcc_GAS_CHECK_FEATURE([mfcr field support],
2744       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2745       [$conftest_s],,
2746       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2747           [Define if your assembler supports mfcr field.])])
2748     ;;
2749
2750   mips*-*-*)
2751     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2752       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2753 [       lw $4,%gp_rel(foo)($4)],,
2754       [if test x$target_cpu_default = x
2755        then target_cpu_default=MASK_EXPLICIT_RELOCS
2756        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2757        fi])
2758
2759     if test x$gas_flag = xyes \
2760        || test x"$host" != x"$build" \
2761        || test ! -x "$gcc_cv_as" \
2762        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2763       :
2764     else
2765       echo "*** This configuration requires the GNU assembler" >&2
2766       exit 1
2767     fi
2768     ;;
2769 esac
2770 # ??? Not all targets support dwarf2 debug_line, even within a version
2771 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2772 # info to the output file.  So, as supported targets are added to gas 2.11,
2773 # add some instruction here to (also) show we expect this might work.
2774 # ??? Once 2.11 is released, probably need to add first known working
2775 # version to the per-target configury.
2776 case "$target" in
2777   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2778   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2779   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2780     insn="nop"
2781     ;;
2782   ia64*-*-* | s390*-*-*)
2783     insn="nop 0"
2784     ;;
2785   mmix-*-*)
2786     insn="swym 0"
2787     ;;
2788 esac
2789 if test x"$insn" != x; then
2790  conftest_s="\
2791         .file 1 \"conftest.s\"
2792         .loc 1 3 0
2793         $insn"
2794  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2795   gcc_cv_as_dwarf2_debug_line,
2796   [elf,2,11,0],, [$conftest_s],
2797   [if test x$gcc_cv_objdump != x \
2798    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2799       | grep debug_line > /dev/null 2>&1; then
2800      gcc_cv_as_dwarf2_debug_line=yes
2801    fi])
2802
2803 # The .debug_line file table must be in the exact order that
2804 # we specified the files, since these indices are also used
2805 # by DW_AT_decl_file.  Approximate this test by testing if
2806 # the assembler bitches if the same index is assigned twice.
2807  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2808   gcc_cv_as_dwarf2_file_buggy,,,
2809 [       .file 1 "foo.s"
2810         .file 1 "bar.s"])
2811
2812  if test $gcc_cv_as_dwarf2_debug_line = yes \
2813  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2814         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2815   [Define if your assembler supports dwarf2 .file/.loc directives,
2816    and preserves file table indices exactly as given.])
2817  fi
2818
2819  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2820   gcc_cv_as_gdwarf2_flag,
2821   [elf,2,11,0], [--gdwarf2], [$insn],,
2822   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2823 [Define if your assembler supports the --gdwarf2 option.])])
2824
2825  gcc_GAS_CHECK_FEATURE([--gstabs option],
2826   gcc_cv_as_gstabs_flag,
2827   [elf,2,11,0], [--gstabs], [$insn],
2828   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2829    # and warns about it, but still exits successfully.  So check for
2830    # this.
2831    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2832    then :
2833    else gcc_cv_as_gstabs_flag=yes
2834    fi],
2835   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2836 [Define if your assembler supports the --gstabs option.])])
2837 fi
2838
2839 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2840 gcc_cv_ld_ro_rw_mix=unknown
2841 if test $in_tree_ld = yes ; then
2842   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2843      && test $in_tree_ld_is_elf = yes; then
2844     gcc_cv_ld_ro_rw_mix=read-write
2845   fi
2846 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2847   echo '.section myfoosect, "a"' > conftest1.s
2848   echo '.section myfoosect, "aw"' > conftest2.s
2849   echo '.byte 1' >> conftest2.s
2850   echo '.section myfoosect, "a"' > conftest3.s
2851   echo '.byte 0' >> conftest3.s
2852   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2853      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2854      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2855      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2856         conftest2.o conftest3.o > /dev/null 2>&1; then
2857     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2858                          | sed -e '/myfoosect/!d' -e N`
2859     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2860       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2861         gcc_cv_ld_ro_rw_mix=read-only
2862       else
2863         gcc_cv_ld_ro_rw_mix=read-write
2864       fi
2865     fi
2866   fi
2867 changequote(,)dnl
2868   rm -f conftest.* conftest[123].*
2869 changequote([,])dnl
2870 fi
2871 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2872         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2873   [Define if your linker links a mix of read-only
2874    and read-write sections into a read-write section.])
2875 fi
2876 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2877
2878 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2879 gcc_cv_ld_eh_frame_hdr=no
2880 if test $in_tree_ld = yes ; then
2881   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2882      && test $in_tree_ld_is_elf = yes; then
2883     gcc_cv_ld_eh_frame_hdr=yes
2884   fi
2885 elif test x$gcc_cv_ld != x; then
2886         # Check if linker supports --eh-frame-hdr option
2887         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2888                 gcc_cv_ld_eh_frame_hdr=yes
2889         fi
2890 fi
2891 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2892         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2893 [Define if your linker supports --eh-frame-hdr option.])
2894 fi
2895 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2896
2897 AC_MSG_CHECKING(linker position independent executable support)
2898 gcc_cv_ld_pie=no
2899 if test $in_tree_ld = yes ; then
2900   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2901      && test $in_tree_ld_is_elf = yes; then
2902     gcc_cv_ld_pie=yes
2903   fi
2904 elif test x$gcc_cv_ld != x; then
2905         # Check if linker supports -pie option
2906         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2907                 gcc_cv_ld_pie=yes
2908         fi
2909 fi
2910 if test x"$gcc_cv_ld_pie" = xyes; then
2911         AC_DEFINE(HAVE_LD_PIE, 1,
2912 [Define if your linker supports -pie option.])
2913 fi
2914 AC_MSG_RESULT($gcc_cv_ld_pie)
2915
2916 # --------
2917 # UNSORTED
2918 # --------
2919
2920 AC_CACHE_CHECK(linker --as-needed support,
2921 gcc_cv_ld_as_needed,
2922 [gcc_cv_ld_as_needed=no
2923 if test $in_tree_ld = yes ; then
2924   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2925      && test $in_tree_ld_is_elf = yes; then
2926     gcc_cv_ld_as_needed=yes
2927   fi
2928 elif test x$gcc_cv_ld != x; then
2929         # Check if linker supports --as-needed and --no-as-needed options
2930         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2931                 gcc_cv_ld_as_needed=yes
2932         fi
2933 fi
2934 ])
2935 if test x"$gcc_cv_ld_as_needed" = xyes; then
2936         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2937 [Define if your linker supports --as-needed and --no-as-needed options.])
2938 fi
2939
2940 case "$target" in
2941   powerpc64*-*-linux*)
2942     AC_CACHE_CHECK(linker support for omitting dot symbols,
2943     gcc_cv_ld_no_dot_syms,
2944     [gcc_cv_ld_no_dot_syms=no
2945     if test $in_tree_ld = yes ; then
2946       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2947         gcc_cv_ld_no_dot_syms=yes
2948       fi
2949     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2950       cat > conftest1.s <<EOF
2951         .text
2952         bl .foo
2953 EOF
2954       cat > conftest2.s <<EOF
2955         .section ".opd","aw"
2956         .align 3
2957         .globl foo
2958         .type foo,@function
2959 foo:
2960         .quad .LEfoo,.TOC.@tocbase,0
2961         .text
2962 .LEfoo:
2963         blr
2964         .size foo,.-.LEfoo
2965 EOF
2966       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
2967          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
2968          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
2969         gcc_cv_ld_no_dot_syms=yes
2970       fi
2971       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
2972     fi
2973     ])
2974     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
2975       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
2976     [Define if your PowerPC64 linker only needs function descriptor syms.])
2977     fi
2978     ;;
2979 esac
2980
2981 if test x$with_sysroot = x && test x$host = x$target \
2982    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2983   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2984 [Define to PREFIX/include if cpp should also search that directory.])
2985 fi
2986
2987 # Find out what GC implementation we want, or may, use.
2988 AC_ARG_WITH(gc,
2989 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2990                           with the compiler],
2991 [case "$withval" in
2992   page | zone)
2993     GGC=ggc-$withval
2994     ;;
2995   *)
2996     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2997     ;;
2998 esac],
2999 [GGC=ggc-page])
3000 AC_SUBST(GGC)
3001 echo "Using $GGC for garbage collection."
3002
3003 # Use the system's zlib library.
3004 zlibdir=-L../zlib
3005 zlibinc="-I\$(srcdir)/../zlib"
3006 AC_ARG_WITH(system-zlib,
3007 [  --with-system-zlib      use installed libz],
3008 zlibdir=
3009 zlibinc=
3010 )
3011 AC_SUBST(zlibdir)
3012 AC_SUBST(zlibinc)
3013
3014 dnl Very limited version of automake's enable-maintainer-mode
3015
3016 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3017   dnl maintainer-mode is disabled by default
3018   AC_ARG_ENABLE(maintainer-mode,
3019 [  --enable-maintainer-mode
3020                           enable make rules and dependencies not useful
3021                           (and sometimes confusing) to the casual installer],
3022       maintainer_mode=$enableval,
3023       maintainer_mode=no)
3024
3025 AC_MSG_RESULT($maintainer_mode)
3026
3027 if test "$maintainer_mode" = "yes"; then
3028   MAINT=''
3029 else
3030   MAINT='#'
3031 fi
3032 AC_SUBST(MAINT)dnl
3033
3034 # --------------
3035 # Language hooks
3036 # --------------
3037
3038 # Make empty files to contain the specs and options for each language.
3039 # Then add #include lines to for a compiler that has specs and/or options.
3040
3041 lang_opt_files=
3042 lang_specs_files=
3043 lang_tree_files=
3044 for subdir in . $subdirs
3045 do
3046         if test -f $srcdir/$subdir/lang.opt; then
3047             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3048         fi
3049         if test -f $srcdir/$subdir/lang-specs.h; then
3050             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3051         fi
3052         if test -f $srcdir/$subdir/$subdir-tree.def; then
3053             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3054         fi
3055 done
3056
3057 # These (without "all_") are set in each config-lang.in.
3058 # `language' must be a single word so is spelled singularly.
3059 all_languages=
3060 all_boot_languages=
3061 all_compilers=
3062 all_stagestuff=
3063 all_outputs='Makefile gccbug mklibgcc libada-mk'
3064 # List of language makefile fragments.
3065 all_lang_makefrags=
3066 # List of language subdirectory makefiles.  Deprecated.
3067 all_lang_makefiles=
3068 # Files for gengtype
3069 all_gtfiles="$target_gtfiles"
3070 # Files for gengtype with language
3071 all_gtfiles_files_langs=
3072 all_gtfiles_files_files=
3073
3074 # Add the language fragments.
3075 # Languages are added via two mechanisms.  Some information must be
3076 # recorded in makefile variables, these are defined in config-lang.in.
3077 # We accumulate them and plug them into the main Makefile.
3078 # The other mechanism is a set of hooks for each of the main targets
3079 # like `clean', `install', etc.
3080
3081 language_hooks="Make-hooks"
3082
3083 for s in $subdirs
3084 do
3085                 language=
3086                 boot_language=
3087                 compilers=
3088                 stagestuff=
3089                 outputs=
3090                 gtfiles=
3091                 . ${srcdir}/$s/config-lang.in
3092                 if test "x$language" = x
3093                 then
3094                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3095                         exit 1
3096                 fi
3097                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3098                 if test -f ${srcdir}/$s/Makefile.in
3099                 then all_lang_makefiles="$s/Makefile"
3100                 fi
3101                 all_languages="$all_languages $language"
3102                 if test "x$boot_language" = xyes
3103                 then
3104                         all_boot_languages="$all_boot_languages $language"
3105                 fi
3106                 all_compilers="$all_compilers $compilers"
3107                 all_stagestuff="$all_stagestuff $stagestuff"
3108                 all_outputs="$all_outputs $outputs"
3109                 all_gtfiles="$all_gtfiles $gtfiles"
3110                 for f in $gtfiles
3111                 do
3112                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3113                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3114                 done
3115 done
3116
3117 # Pick up gtfiles for c
3118 gtfiles=
3119 s="c"
3120 . ${srcdir}/c-config-lang.in
3121 all_gtfiles="$all_gtfiles $gtfiles"
3122 for f in $gtfiles
3123 do
3124         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3125         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3126 done
3127
3128 check_languages=
3129 for language in $all_languages
3130 do
3131                 check_languages="$check_languages check-$language"
3132 done
3133
3134 # We link each language in with a set of hooks, reached indirectly via
3135 # lang.${target}.
3136
3137 rm -f Make-hooks
3138 touch Make-hooks
3139 target_list="all.build all.cross start.encap rest.encap tags \
3140         install-normal install-common install-man \
3141         uninstall info man srcextra srcman srcinfo \
3142         mostlyclean clean distclean maintainer-clean \
3143         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3144 for t in $target_list
3145 do
3146         x=
3147         for lang in $all_languages
3148         do
3149                         x="$x $lang.$t"
3150         done
3151         echo "lang.$t: $x" >> Make-hooks
3152 done
3153
3154 # --------
3155 # UNSORTED
3156 # --------
3157
3158 # Create .gdbinit.
3159
3160 echo "dir ." > .gdbinit
3161 echo "dir ${srcdir}" >> .gdbinit
3162 if test x$gdb_needs_out_file_path = xyes
3163 then
3164         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3165 fi
3166 if test "x$subdirs" != x; then
3167         for s in $subdirs
3168         do
3169                 echo "dir ${srcdir}/$s" >> .gdbinit
3170         done
3171 fi
3172 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3173
3174 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3175 # absolute path for gcc_tooldir based on inserting the number of up-directory
3176 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3177 # $(libsubdir)/@(unlibsubdir) based path.
3178 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3179 # make and thus we'd get different behavior depending on where we built the
3180 # sources.
3181 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3182     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3183 else
3184 changequote(<<, >>)dnl
3185 # An explanation of the sed strings:
3186 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3187 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3188 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3189 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3190 #
3191 # (*) Note this pattern overwrites the first character of the string
3192 # with a forward slash if one is not already present.  This is not a
3193 # problem because the exact names of the sub-directories concerned is
3194 # unimportant, just the number of them matters.
3195 #
3196 # The practical upshot of these patterns is like this:
3197 #
3198 #  prefix     exec_prefix        result
3199 #  ------     -----------        ------
3200 #   /foo        /foo/bar          ../
3201 #   /foo/       /foo/bar          ../
3202 #   /foo        /foo/bar/         ../
3203 #   /foo/       /foo/bar/         ../
3204 #   /foo        /foo/bar/ugg      ../../
3205 #
3206     dollar='$$'
3207     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3208 changequote([, ])dnl
3209 fi
3210 AC_SUBST(gcc_tooldir)
3211 AC_SUBST(dollar)
3212
3213 # Find a directory in which to install a shared libgcc.
3214
3215 AC_ARG_ENABLE(version-specific-runtime-libs,
3216 [  --enable-version-specific-runtime-libs
3217                           specify that runtime libraries should be
3218                           installed in a compiler-specific directory])
3219
3220 AC_ARG_WITH(slibdir,
3221 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3222 slibdir="$with_slibdir",
3223 if test "${enable_version_specific_runtime_libs+set}" = set; then
3224   slibdir='$(libsubdir)'
3225 elif test "$host" != "$target"; then
3226   slibdir='$(build_tooldir)/lib'
3227 else
3228   slibdir='$(libdir)'
3229 fi)
3230 AC_SUBST(slibdir)
3231
3232 objdir=`${PWDCMD-pwd}`
3233 AC_SUBST(objdir)
3234
3235 # Substitute configuration variables
3236 AC_SUBST(subdirs)
3237 AC_SUBST(srcdir)
3238 AC_SUBST(all_boot_languages)
3239 AC_SUBST(all_compilers)
3240 AC_SUBST(all_gtfiles)
3241 AC_SUBST(all_gtfiles_files_langs)
3242 AC_SUBST(all_gtfiles_files_files)
3243 AC_SUBST(all_lang_makefrags)
3244 AC_SUBST(all_lang_makefiles)
3245 AC_SUBST(all_languages)
3246 AC_SUBST(all_stagestuff)
3247 AC_SUBST(build_exeext)
3248 AC_SUBST(build_install_headers_dir)
3249 AC_SUBST(build_xm_file_list)
3250 AC_SUBST(build_xm_include_list)
3251 AC_SUBST(build_xm_defines)
3252 AC_SUBST(check_languages)
3253 AC_SUBST(cc_set_by_configure)
3254 AC_SUBST(quoted_cc_set_by_configure)
3255 AC_SUBST(cpp_install_dir)
3256 AC_SUBST(xmake_file)
3257 AC_SUBST(tmake_file)
3258 AC_SUBST(extra_gcc_objs)
3259 AC_SUBST(extra_headers_list)
3260 AC_SUBST(extra_objs)
3261 AC_SUBST(extra_parts)
3262 AC_SUBST(extra_passes)
3263 AC_SUBST(extra_programs)
3264 AC_SUBST(float_h_file)
3265 AC_SUBST(gcc_config_arguments)
3266 AC_SUBST(gcc_gxx_include_dir)
3267 AC_SUBST(libstdcxx_incdir)
3268 AC_SUBST(host_exeext)
3269 AC_SUBST(host_xm_file_list)
3270 AC_SUBST(host_xm_include_list)
3271 AC_SUBST(host_xm_defines)
3272 AC_SUBST(out_host_hook_obj)
3273 AC_SUBST(install)
3274 AC_SUBST(lang_opt_files)
3275 AC_SUBST(lang_specs_files)
3276 AC_SUBST(lang_tree_files)
3277 AC_SUBST(local_prefix)
3278 AC_SUBST(md_file)
3279 AC_SUBST(objc_boehm_gc)
3280 AC_SUBST(out_file)
3281 AC_SUBST(out_object_file)
3282 AC_SUBST(stage_prefix_set_by_configure)
3283 AC_SUBST(quoted_stage_prefix_set_by_configure)
3284 AC_SUBST(thread_file)
3285 AC_SUBST(tm_file_list)
3286 AC_SUBST(tm_include_list)
3287 AC_SUBST(tm_defines)
3288 AC_SUBST(tm_p_file_list)
3289 AC_SUBST(tm_p_include_list)
3290 AC_SUBST(xm_file_list)
3291 AC_SUBST(xm_include_list)
3292 AC_SUBST(xm_defines)
3293 AC_SUBST(c_target_objs)
3294 AC_SUBST(cxx_target_objs)
3295 AC_SUBST(target_cpu_default)
3296
3297 AC_SUBST_FILE(language_hooks)
3298
3299 TL_AC_GNU_MAKE_GCC_LIB_PATH
3300
3301 # Echo link setup.
3302 if test x${build} = x${host} ; then
3303   if test x${host} = x${target} ; then
3304     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3305   else
3306     echo "Links are now set up to build a cross-compiler" 1>&2
3307     echo " from ${host} to ${target}." 1>&2
3308   fi
3309 else
3310   if test x${host} = x${target} ; then
3311     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3312     echo " for ${target}." 1>&2
3313   else
3314     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3315     echo " from ${host} to ${target}." 1>&2
3316   fi
3317 fi
3318
3319 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3320 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3321
3322 # Configure the subdirectories
3323 # AC_CONFIG_SUBDIRS($subdirs)
3324
3325 # Create the Makefile
3326 # and configure language subdirectories
3327 AC_CONFIG_FILES($all_outputs)
3328
3329 AC_CONFIG_COMMANDS([default],
3330 [
3331 case ${CONFIG_HEADERS} in
3332   *auto-host.h:config.in*)
3333   echo > cstamp-h ;;
3334 esac
3335 # Make sure all the subdirs exist.
3336 for d in $subdirs doc build
3337 do
3338     test -d $d || mkdir $d
3339 done
3340 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3341 # bootstrapping and the installation procedure can still use
3342 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3343 # FLAGS_TO_PASS has been modified to solve the problem there.
3344 # This is virtually a duplicate of what happens in configure.lang; we do
3345 # an extra check to make sure this only happens if ln -s can be used.
3346 case "$LN_S" in
3347   *-s*)
3348     for d in ${subdirs} ; do
3349         STARTDIR=`${PWDCMD-pwd}`
3350         cd $d
3351         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3352         do
3353                 rm -f $t
3354                 $LN_S ../$t $t 2>/dev/null
3355         done
3356         cd $STARTDIR
3357     done
3358   ;;
3359 esac
3360 ],
3361 [subdirs='$subdirs'])
3362 AC_OUTPUT