gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997-2022 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 3, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 # --------------------------------
  23 # Initialization and sanity checks
  24 # --------------------------------
  25
  26 AC_INIT
  27 AC_CONFIG_SRCDIR(tree.cc)
  28 AC_CONFIG_HEADER(auto-host.h:config.in)
  29
  30 gcc_version=`cat $srcdir/BASE-VER`
  31
  32 # Determine the host, build, and target systems
  33 AC_CANONICAL_BUILD
  34 AC_CANONICAL_HOST
  35 AC_CANONICAL_TARGET
  36
  37 # Determine the noncanonical host name, for Ada.
  38 ACX_NONCANONICAL_HOST
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Used for constructing correct paths for offload compilers.
  44 real_target_noncanonical=${target_noncanonical}
  45 accel_dir_suffix=
  46
  47 # Determine the target- and build-specific subdirectories
  48 GCC_TOPLEV_SUBDIRS
  49
  50 # Set program_transform_name
  51 AC_ARG_PROGRAM
  52
  53 # Check for bogus environment variables.
  54 # Test if LIBRARY_PATH contains the notation for the current directory
  55 # since this would lead to problems installing/building glibc.
  56 # LIBRARY_PATH contains the current directory if one of the following
  57 # is true:
  58 # - one of the terminals (":" and ";") is the first or last sign
  59 # - two terminals occur directly after each other
  60 # - the path contains an element with a dot in it
  61 AC_MSG_CHECKING(LIBRARY_PATH variable)
  62 changequote(,)dnl
  63 case ${LIBRARY_PATH} in
  64   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  65     library_path_setting="contains current directory"
  66     ;;
  67   *)
  68     library_path_setting="ok"
  69     ;;
  70 esac
  71 changequote([,])dnl
  72 AC_MSG_RESULT($library_path_setting)
  73 if test "$library_path_setting" != "ok"; then
  74 AC_MSG_ERROR([
  75 *** LIBRARY_PATH shouldn't contain the current directory when
  76 *** building gcc. Please change the environment variable
  77 *** and run configure again.])
  78 fi
  79
  80 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  81 # since this would lead to problems installing/building glibc.
  82 # GCC_EXEC_PREFIX contains the current directory if one of the following
  83 # is true:
  84 # - one of the terminals (":" and ";") is the first or last sign
  85 # - two terminals occur directly after each other
  86 # - the path contains an element with a dot in it
  87 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  88 changequote(,)dnl
  89 case ${GCC_EXEC_PREFIX} in
  90   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  91     gcc_exec_prefix_setting="contains current directory"
  92     ;;
  93   *)
  94     gcc_exec_prefix_setting="ok"
  95     ;;
  96 esac
  97 changequote([,])dnl
  98 AC_MSG_RESULT($gcc_exec_prefix_setting)
  99 if test "$gcc_exec_prefix_setting" != "ok"; then
 100 AC_MSG_ERROR([
 101 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
 102 *** building gcc. Please change the environment variable
 103 *** and run configure again.])
 104 fi
 105
 106 # -----------
 107 # Directories
 108 # -----------
 109
 110 # Specify the local prefix
 111 local_prefix=
 112 AC_ARG_WITH(local-prefix,
 113 [AS_HELP_STRING([--with-local-prefix=DIR],
 114                 [specifies directory to put local include])],
 115 [case "${withval}" in
 116 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 117 no)     ;;
 118 *)      local_prefix=$with_local_prefix ;;
 119 esac])
 120
 121 # Default local prefix if it is empty
 122 if test x$local_prefix = x; then
 123         local_prefix=/usr/local
 124 fi
 125
 126 AC_ARG_WITH([native-system-header-dir],
 127   [  --with-native-system-header-dir=dir
 128                           use dir as the directory to look for standard
 129                           system header files in.  Defaults to /usr/include.],
 130 [
 131  case ${with_native_system_header_dir} in
 132  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 133  /* | [[A-Za-z]]:[[\\/]]*) ;;
 134  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 135  esac
 136  configured_native_system_header_dir="${withval}"
 137 ], [configured_native_system_header_dir=])
 138
 139 AC_ARG_WITH(build-sysroot,
 140   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 141                   [use sysroot as the system root during the build])],
 142   [if test x"$withval" != x ; then
 143      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 144    fi],
 145   [SYSROOT_CFLAGS_FOR_TARGET=])
 146 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 147
 148 if test "x$prefix" = xNONE; then
 149  test_prefix=/usr/local
 150 else
 151  test_prefix=$prefix
 152 fi
 153 if test "x$exec_prefix" = xNONE; then
 154  test_exec_prefix=$test_prefix
 155 else
 156  test_exec_prefix=$exec_prefix
 157 fi
 158
 159 AC_ARG_WITH(sysroot,
 160 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 161                 [search for usr/lib, usr/include, et al, within DIR])],
 162 [
 163  case ${with_sysroot} in
 164  /) ;;
 165  */) with_sysroot=`echo $with_sysroot | sed 's,/$,,'` ;;
 166  esac
 167  case ${with_sysroot} in
 168  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 169  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 170  esac
 171
 172  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 173  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 174
 175  case ${TARGET_SYSTEM_ROOT} in
 176  "${test_prefix}"|"${test_prefix}/"*|\
 177  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 178  '${prefix}'|'${prefix}/'*|\
 179  '${exec_prefix}'|'${exec_prefix}/'*)
 180    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 181    TARGET_SYSTEM_ROOT_DEFINE="$t"
 182    ;;
 183  esac
 184 ], [
 185  TARGET_SYSTEM_ROOT=
 186  TARGET_SYSTEM_ROOT_DEFINE=
 187  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 188 ])
 189 AC_SUBST(TARGET_SYSTEM_ROOT)
 190 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 191 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 192
 193 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 194 # passed in by the toplevel make and thus we'd get different behavior
 195 # depending on where we built the sources.
 196 gcc_gxx_include_dir=
 197 # Specify the g++ header file directory
 198 AC_ARG_WITH(gxx-include-dir,
 199 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 200                 [specifies directory to put g++ header files])],
 201 [case "${withval}" in
 202 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 203 no)     ;;
 204 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 205 esac])
 206
 207 # If both --with-sysroot and --with-gxx-include-dir are passed, we interpolate
 208 # the former in the latter and, upon success, compute gcc_gxx_include_dir as
 209 # relative to the sysroot.
 210 gcc_gxx_include_dir_add_sysroot=0
 211
 212 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 213 if test x${gcc_gxx_include_dir} = x; then
 214   if test x${enable_version_specific_runtime_libs} = xyes; then
 215     gcc_gxx_include_dir='${libsubdir}/include/c++'
 216   else
 217     libstdcxx_incdir='include/c++/$(version)'
 218     if test x$host != x$target; then
 219        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 220     fi
 221     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 222   fi
 223 elif test "${with_sysroot+set}" = set; then
 224   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 225   if test "${gcc_gxx_without_sysroot}"; then
 226     gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 227     gcc_gxx_include_dir_add_sysroot=1
 228   fi
 229 fi
 230
 231 # Configuration for an alternate set of C++ headers.
 232 gcc_gxx_libcxx_include_dir=
 233 # Specify the alternate g++ header file directory
 234 AC_ARG_WITH(gxx-libcxx-include-dir,
 235 [AS_HELP_STRING([--with-gxx-libcxx-include-dir=DIR],
 236                 [specifies directory to find libc++ header files])],
 237 [case "${withval}" in
 238 yes)    AC_MSG_ERROR(bad value ${withval} given for libc++ include directory) ;;
 239 no)     ;;
 240 *)      gcc_gxx_libcxx_include_dir=$with_gxx_libcxx_include_dir ;;
 241 esac])
 242
 243 # If both --with-sysroot and --with-gxx-libcxx-include-dir are passed, we
 244 # check to see if the latter starts with the former and, upon success, compute
 245 # gcc_gxx_libcxx_include_dir as relative to the sysroot.
 246 gcc_gxx_libcxx_include_dir_add_sysroot=0
 247
 248 if test x${gcc_gxx_libcxx_include_dir} != x; then
 249   AC_DEFINE(ENABLE_STDLIB_OPTION, 1,
 250             [Define if the -stdlib= option should be enabled.])
 251 else
 252   AC_DEFINE(ENABLE_STDLIB_OPTION, 0)
 253 fi
 254 # ??? This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 255 if test x${gcc_gxx_libcxx_include_dir} = x; then
 256   if test x${enable_version_specific_runtime_libs} = xyes; then
 257     gcc_gxx_libcxx_include_dir='${libsubdir}/libc++_include/c++/v1'
 258   else
 259     libcxx_incdir='libc++_include/c++/$(version)/v1'
 260     if test x$host != x$target; then
 261        libcxx_incdir="$target_alias/$libcxx_incdir"
 262     fi
 263     gcc_gxx_libcxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libcxx_incdir"
 264   fi
 265 elif test "${with_sysroot+set}" = set; then
 266   gcc_gxx_libcxx_without_sysroot=`expr "${gcc_gxx_libcxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 267   if test "${gcc_gxx_libcxx_without_sysroot}"; then
 268     gcc_gxx_libcxx_include_dir="${gcc_gxx_libcxx_without_sysroot}"
 269     gcc_gxx_libcxx_include_dir_add_sysroot=1
 270   fi
 271 fi
 272
 273 AC_ARG_WITH(cpp_install_dir,
 274 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 275                 [install the user visible C preprocessor in DIR
 276                  (relative to PREFIX) as well as PREFIX/bin])],
 277 [if test x$withval = xyes; then
 278   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 279 elif test x$withval != xno; then
 280   cpp_install_dir=$withval
 281 fi])
 282
 283 # We would like to our source tree to be readonly.  However when releases or
 284 # pre-releases are generated, the flex/bison generated files as well as the
 285 # various formats of manuals need to be included along with the rest of the
 286 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 287 # just that.
 288
 289 AC_MSG_CHECKING([whether to place generated files in the source directory])
 290   dnl generated-files-in-srcdir is disabled by default
 291   AC_ARG_ENABLE(generated-files-in-srcdir,
 292     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 293                     [put copies of generated files in source dir
 294                      intended for creating source tarballs for users
 295                      without texinfo bison or flex])],
 296       generated_files_in_srcdir=$enableval,
 297       generated_files_in_srcdir=no)
 298
 299 AC_MSG_RESULT($generated_files_in_srcdir)
 300
 301 if test "$generated_files_in_srcdir" = "yes"; then
 302   GENINSRC=''
 303 else
 304   GENINSRC='#'
 305 fi
 306 AC_SUBST(GENINSRC)
 307
 308 # -------------------
 309 # Find default linker
 310 # -------------------
 311
 312 # With GNU ld
 313 AC_ARG_WITH(gnu-ld,
 314 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 315 gnu_ld_flag="$with_gnu_ld",
 316 gnu_ld_flag=no)
 317
 318 case $target in
 319     *darwin*)
 320         ld64_flag=yes # Darwin can only use a ld64-compatible linker.
 321         dsymutil_flag=yes # Darwin uses dsymutil to link debug.
 322         ;;
 323     *)
 324         ld64_flag=no
 325         dsymutil_flag=no
 326         ;;
 327 esac
 328
 329 # With pre-defined ld
 330 AC_ARG_WITH(ld,
 331 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 332 DEFAULT_LINKER="$with_ld")
 333 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 334   if test ! -x "$DEFAULT_LINKER"; then
 335     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 336   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 337     gnu_ld_flag=yes
 338   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep ld64- > /dev/null; then
 339     ld64_flag=yes
 340   fi
 341   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 342         [Define to enable the use of a default linker.])
 343 fi
 344
 345 AC_MSG_CHECKING([whether a default linker was specified])
 346 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 347   if test x"$gnu_ld_flag" = x"no"; then
 348     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 349   else
 350     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 351   fi
 352 else
 353   AC_MSG_RESULT(no)
 354 fi
 355
 356 # With demangler in GNU ld
 357 AC_ARG_WITH(demangler-in-ld,
 358 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 359 demangler_in_ld="$with_demangler_in_ld",
 360 demangler_in_ld=yes)
 361
 362 # Allow the user to specify a dsymutil executable (used on Darwin only, so far)
 363 AC_ARG_WITH(dsymutil,
 364 [AS_HELP_STRING([--with-dsymutil], [arrange to use the specified dsymutil (full pathname)])],
 365 DEFAULT_DSYMUTIL="$with_dsymutil")
 366
 367 dsymutil_vers=
 368 if test x"${DEFAULT_DSYMUTIL+set}" = x"set"; then
 369   if test ! -x "$DEFAULT_DSYMUTIL"; then
 370     AC_MSG_ERROR([cannot execute: $DEFAULT_DSYMUTIL: check --with-dsymutil or env. var. DEFAULT_DSYMUTIL])
 371   else
 372     if dsymutil_vers=`$DEFAULT_DSYMUTIL -v /dev/null 2>&1`; then
 373       dsymutil_flag=yes
 374     fi
 375   fi
 376   AC_DEFINE_UNQUOTED(DEFAULT_DSYMUTIL,"$DEFAULT_DSYMUTIL",
 377         [Define to enable the use of a default debug linker.])
 378 fi
 379
 380 AC_MSG_CHECKING([whether a default dsymutil was specified])
 381 if test x"${DEFAULT_DSYMUTIL+set}" = x"set"; then
 382   AC_MSG_RESULT([yes ($DEFAULT_DSYMUTIL)])
 383 else
 384   AC_MSG_RESULT(no)
 385 fi
 386
 387 # ----------------------
 388 # Find default assembler
 389 # ----------------------
 390
 391 # With GNU as
 392 AC_ARG_WITH(gnu-as,
 393 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 394 gas_flag="$with_gnu_as",
 395 gas_flag=no)
 396
 397 AC_ARG_WITH(as,
 398 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 399 DEFAULT_ASSEMBLER="$with_as")
 400 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 401   if test ! -x "$DEFAULT_ASSEMBLER"; then
 402     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 403   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 404     gas_flag=yes
 405   fi
 406   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 407         [Define to enable the use of a default assembler.])
 408 fi
 409
 410 AC_MSG_CHECKING([whether a default assembler was specified])
 411 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 412   if test x"$gas_flag" = x"no"; then
 413     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 414   else
 415     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 416   fi
 417 else
 418   AC_MSG_RESULT(no)
 419 fi
 420
 421 # ---------------
 422 # Find C compiler
 423 # ---------------
 424
 425 # If a non-executable a.out is present (e.g. created by GNU as above even if
 426 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 427 # file, even when creating an executable, so an execution test fails.
 428 # Remove possible default executable files to avoid this.
 429 #
 430 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 431 # Autoconf includes it.
 432 rm -f a.out a.exe b.out
 433
 434 # Find the native compiler
 435 AC_PROG_CC
 436 AC_PROG_CXX
 437 ACX_PROG_GNAT([-I"$srcdir"/ada/libgnat])
 438 ACX_PROG_GDC([-I"$srcdir"/d])
 439
 440 # Do configure tests with the C++ compiler, since that's what we build with.
 441 AC_LANG(C++)
 442
 443 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 444 # optimizations to be activated explicitly by the toplevel.
 445 case "$CC" in
 446   */prev-gcc/xgcc*) ;;
 447   *) CFLAGS=`echo "$CFLAGS " | sed -e "s/-Ofast[[       ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" `
 448      CXXFLAGS=`echo "$CXXFLAGS " | sed -e "s/-Ofast[[   ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" ` ;;
 449 esac
 450 AC_SUBST(CFLAGS)
 451 AC_SUBST(CXXFLAGS)
 452 AC_SUBST(GDCFLAGS)
 453
 454 # Determine PICFLAG for target gnatlib.
 455 GCC_PICFLAG_FOR_TARGET
 456 AC_SUBST(PICFLAG_FOR_TARGET)
 457
 458 # -------------------------
 459 # Check C compiler features
 460 # -------------------------
 461
 462 AC_USE_SYSTEM_EXTENSIONS
 463
 464 AC_PROG_CPP
 465 AC_C_INLINE
 466
 467 AC_SYS_LARGEFILE
 468 AC_CHECK_SIZEOF(ino_t)
 469 AC_CHECK_SIZEOF(dev_t)
 470
 471 # Select the right stat being able to handle 64bit inodes, if needed.
 472 if test "$enable_largefile" != no; then
 473   case "$host, $build" in
 474     *-*-aix*,*|*,*-*-aix*)
 475       if test "$ac_cv_sizeof_ino_t" == "4" -a "$ac_cv_sizeof_dev_t" == 4; then
 476         AC_DEFINE(HOST_STAT_FOR_64BIT_INODES, stat64x,
 477           [Define which stat syscall is able to handle 64bit indodes.])
 478       fi;;
 479   esac
 480 fi
 481
 482
 483 # sizeof(char) is 1 by definition.
 484 AC_CHECK_SIZEOF(void *)
 485 AC_CHECK_SIZEOF(short)
 486 AC_CHECK_SIZEOF(int)
 487 AC_CHECK_SIZEOF(long)
 488 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 489 GCC_STDINT_TYPES
 490 if test x"$ac_cv_c_uint64_t" = x"no" -o x"$ac_cv_c_int64_t" = x"no"; then
 491   AC_MSG_ERROR([uint64_t or int64_t not found])
 492 fi
 493
 494 # check what underlying integer type int64_t uses
 495 AC_CACHE_CHECK(for int64_t underlying type, ac_cv_int64_t_type, [
 496 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 497 #ifdef HAVE_STDINT_H
 498 #include <stdint.h>
 499 #endif
 500 template <typename T> struct X { };
 501 template <>
 502 struct X<long> { typedef long t; };
 503 ]], [[X<int64_t>::t x;]])],[ac_cv_int64_t_type=long],[ac_cv_int64_t_type="long long"])])
 504 if test "$ac_cv_int64_t_type" = "long"; then
 505   AC_DEFINE(INT64_T_IS_LONG, 1,
 506   [Define if int64_t uses long as underlying type.])
 507 else
 508 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 509 #ifdef HAVE_STDINT_H
 510 #include <stdint.h>
 511 #endif
 512 template <typename T> struct X { };
 513 template <>
 514 struct X<long long> { typedef long long t; };
 515 ]], [[X<int64_t>::t x;]])],[],[AC_MSG_ERROR([error verifying int64_t uses long long])])
 516 fi
 517
 518 AC_CACHE_CHECK(for std::swap in <utility>, ac_cv_std_swap_in_utility, [
 519 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 520 #include <utility>
 521 ]], [[int a, b; std::swap(a,b);]])],[ac_cv_std_swap_in_utility=yes],[ac_cv_std_swap_in_utility=no])])
 522 if test $ac_cv_std_swap_in_utility = yes; then
 523   AC_DEFINE(HAVE_SWAP_IN_UTILITY, 1,
 524   [Define if <utility> defines std::swap.])
 525 fi
 526
 527 # Check whether compiler is affected by placement new aliasing bug (PR 29286).
 528 # If the host compiler is affected by the bug, and we build with optimization
 529 # enabled (which happens e.g. when cross-compiling), the pool allocator may
 530 # get miscompiled.  Use -fno-strict-aliasing to work around this problem.
 531 # Since there is no reliable feature check for the presence of this bug,
 532 # we simply use a GCC version number check.  (This should never trigger for
 533 # stages 2 or 3 of a native bootstrap.)
 534 aliasing_flags=
 535 if test "$GCC" = yes; then
 536   saved_CXXFLAGS="$CXXFLAGS"
 537
 538   # The following test compilation will succeed if and only if $CXX accepts
 539   # -fno-strict-aliasing *and* is older than GCC 4.3.
 540   CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 541   AC_MSG_CHECKING([whether $CXX is affected by placement new aliasing bug])
 542   AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 543 #if (__GNUC__ > 4) || (__GNUC__ == 4 && __GNUC_MINOR__ >= 3)
 544 #error compiler not affected by placement new aliasing bug
 545 #endif
 546 ])],
 547     [AC_MSG_RESULT([yes]); aliasing_flags='-fno-strict-aliasing'],
 548     [AC_MSG_RESULT([no])])
 549
 550   CXXFLAGS="$saved_CXXFLAGS"
 551 fi
 552 AC_SUBST(aliasing_flags)
 553
 554
 555
 556 # ---------------------
 557 # Warnings and checking
 558 # ---------------------
 559
 560 # Check $CC warning features (if it's GCC).
 561 # We want to use -pedantic, but we don't want warnings about
 562 # * 'long long'
 563 # * variadic macros
 564 # * overlong strings
 565 # * C++11 narrowing conversions in { }
 566 # So, we only use -pedantic if we can disable those warnings.
 567
 568 # In stage 1, disable -Wformat warnings from old GCCs about new % codes
 569 AC_ARG_ENABLE(build-format-warnings,
 570   AS_HELP_STRING([--disable-build-format-warnings],[don't use -Wformat while building GCC]),
 571   [],[enable_build_format_warnings=yes])
 572 AS_IF([test $enable_build_format_warnings = no],
 573       [wf_opt=-Wno-format],[wf_opt=])
 574 ACX_PROG_CXX_WARNING_OPTS(
 575         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings ],
 576                        [-Wcast-qual $wf_opt])),
 577                        [loose_warn])
 578 ACX_PROG_CC_WARNING_OPTS(
 579         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes ],
 580                        [])), [c_loose_warn])
 581 ACX_PROG_CXX_WARNING_OPTS(
 582         m4_quote(m4_do([-Wmissing-format-attribute ],
 583                        [-Woverloaded-virtual])), [strict_warn])
 584 ACX_PROG_CC_WARNING_OPTS(
 585         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 586 ACX_PROG_CXX_WARNING_ALMOST_PEDANTIC(
 587         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 588                        [-Wno-overlength-strings])), [strict_warn])
 589 ACX_PROG_CXX_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 590
 591 # The above macros do nothing if the compiler is not GCC.  However, the
 592 # Makefile has more goo to add other flags, so these variables are used
 593 # to enable warnings only for GCC.
 594 warn_cflags=
 595 warn_cxxflags=
 596 if test "x$GCC" = "xyes"; then
 597   warn_cflags='$(GCC_WARN_CFLAGS)'
 598   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 599 fi
 600 AC_SUBST(warn_cflags)
 601 AC_SUBST(warn_cxxflags)
 602
 603 # Disable exceptions and RTTI if building with g++
 604 ACX_PROG_CC_WARNING_OPTS(
 605         m4_quote(m4_do([-fno-exceptions -fno-rtti -fasynchronous-unwind-tables])),
 606                        [noexception_flags])
 607
 608 # Enable expensive internal checks
 609 is_release=
 610 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 611   is_release=yes
 612 fi
 613
 614 AC_ARG_ENABLE(checking,
 615 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 616                 [enable expensive run-time checks.  With LIST,
 617                  enable only specific categories of checks.
 618                  Categories are: yes,no,all,none,release.
 619                  Flags are: assert,df,extra,fold,gc,gcac,gimple,misc,
 620                  rtlflag,rtl,runtime,tree,valgrind,types])],
 621 [ac_checking_flags="${enableval}"],[
 622 # Determine the default checks.
 623 if test x$is_release = x ; then
 624   ac_checking_flags=yes,extra
 625 else
 626   ac_checking_flags=release
 627 fi])
 628 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 629 for check in release $ac_checking_flags
 630 do
 631         case $check in
 632         # these set all the flags to specific states
 633         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 634                         ac_fold_checking= ; ac_gc_checking=1 ; ac_extra_checking= ;
 635                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 636                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 637                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 638                         ac_types_checking=1 ;;
 639         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 640                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 641                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 642                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 643                         ac_tree_checking= ; ac_valgrind_checking= ;
 644                         ac_types_checking= ;;
 645         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 646                         ac_fold_checking=1 ; ac_gc_checking=1 ; ac_extra_checking=1 ;
 647                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 648                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 649                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 650                         ac_types_checking=1 ;;
 651         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 652                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 653                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 654                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 655                         ac_tree_checking= ; ac_valgrind_checking= ;
 656                         ac_types_checking= ;;
 657         # these enable particular checks
 658         assert)         ac_assert_checking=1 ;;
 659         df)             ac_df_checking=1 ;;
 660         extra)          ac_extra_checking=1 ;;
 661         fold)           ac_fold_checking=1 ;;
 662         gc)             ac_gc_checking=1 ;;
 663         gcac)           ac_gc_always_collect=1 ;;
 664         gimple)         ac_gimple_checking=1 ;;
 665         misc)           ac_checking=1 ;;
 666         rtl)            ac_rtl_checking=1 ;;
 667         rtlflag)        ac_rtlflag_checking=1 ;;
 668         runtime)        ac_runtime_checking=1 ;;
 669         tree)           ac_tree_checking=1 ;;
 670         types)          ac_types_checking=1 ;;
 671         valgrind)       ac_valgrind_checking=1 ;;
 672         *)      AC_MSG_ERROR(unknown check category $check) ;;
 673         esac
 674 done
 675 IFS="$ac_save_IFS"
 676
 677 nocommon_flag=""
 678 if test x$ac_checking != x ; then
 679   AC_DEFINE(CHECKING_P, 1,
 680 [Define to 0/1 if you want more run-time sanity checks.  This one gets a grab
 681 bag of miscellaneous but relatively cheap checks.])
 682   nocommon_flag=-fno-common
 683 else
 684   AC_DEFINE(CHECKING_P, 0)
 685 fi
 686 AC_SUBST(nocommon_flag)
 687 if test x$ac_extra_checking != x ; then
 688   AC_DEFINE(ENABLE_EXTRA_CHECKING, 1,
 689 [Define to 0/1 if you want extra run-time checking that might affect code
 690 generation.])
 691 else
 692   AC_DEFINE(ENABLE_EXTRA_CHECKING, 0)
 693 fi
 694 if test x$ac_df_checking != x ; then
 695   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 696 [Define if you want more run-time sanity checks for dataflow.])
 697 fi
 698 if test x$ac_assert_checking != x ; then
 699   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 700 [Define if you want assertions enabled.  This is a cheap check.])
 701 fi
 702 if test x$ac_gimple_checking != x ; then
 703   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 704 [Define if you want operations on GIMPLE (the basic data structure of
 705 the high-level optimizers) to be checked for dynamic type safety at
 706 runtime.  This is moderately expensive.])
 707 fi
 708 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 709 if test x$ac_runtime_checking != x ; then
 710   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 711 [Define if you want runtime assertions enabled.  This is a cheap check.])
 712 fi
 713 if test x$ac_tree_checking != x ; then
 714   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 715 [Define if you want all operations on trees (the basic data
 716    structure of the front ends) to be checked for dynamic type safety
 717    at runtime.  This is moderately expensive.
 718    ])
 719   TREECHECKING=yes
 720 fi
 721 if test x$ac_types_checking != x ; then
 722   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 723 [Define if you want all gimple types to be verified after gimplifiation.
 724    This is cheap.
 725    ])
 726 fi
 727 AC_SUBST(TREECHECKING)
 728 if test x$ac_rtl_checking != x ; then
 729   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 730 [Define if you want all operations on RTL (the basic data structure
 731    of the optimizer and back end) to be checked for dynamic type safety
 732    at runtime.  This is quite expensive.])
 733 fi
 734 if test x$ac_rtlflag_checking != x ; then
 735   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 736 [Define if you want RTL flag accesses to be checked against the RTL
 737    codes that are supported for each access macro.  This is relatively
 738    cheap.])
 739 fi
 740 if test x$ac_gc_checking != x ; then
 741   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 742 [Define if you want the garbage collector to do object poisoning and
 743    other memory allocation checks.  This is quite expensive.])
 744 fi
 745 if test x$ac_gc_always_collect != x ; then
 746   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 747 [Define if you want the garbage collector to operate in maximally
 748    paranoid mode, validating the entire heap and collecting garbage at
 749    every opportunity.  This is extremely expensive.])
 750 fi
 751 if test x$ac_fold_checking != x ; then
 752   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 753 [Define if you want fold checked that it never destructs its argument.
 754    This is quite expensive.])
 755 fi
 756 valgrind_path_defines=
 757 valgrind_command=
 758
 759 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 760 dnl # an if statement.  This was the source of very frustrating bugs
 761 dnl # in converting to autoconf 2.5x!
 762 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 763
 764 # It is certainly possible that there's valgrind but no valgrind.h.
 765 # GCC relies on making annotations so we must have both.
 766 AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 767 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 768   [[#include <valgrind/memcheck.h>
 769 #ifndef VALGRIND_DISCARD
 770 #error VALGRIND_DISCARD not defined
 771 #endif]])],
 772   [gcc_cv_header_valgrind_memcheck_h=yes],
 773   [gcc_cv_header_valgrind_memcheck_h=no])
 774 AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 775 AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 776 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 777   [[#include <memcheck.h>
 778 #ifndef VALGRIND_DISCARD
 779 #error VALGRIND_DISCARD not defined
 780 #endif]])],
 781   [gcc_cv_header_memcheck_h=yes],
 782   [gcc_cv_header_memcheck_h=no])
 783 AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 784 if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 785   AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 786         [Define if valgrind's valgrind/memcheck.h header is installed.])
 787 fi
 788 if test $gcc_cv_header_memcheck_h = yes; then
 789   AC_DEFINE(HAVE_MEMCHECK_H, 1,
 790         [Define if valgrind's memcheck.h header is installed.])
 791 fi
 792
 793 if test x$ac_valgrind_checking != x ; then
 794   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 795         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 796   if test "x$valgrind_path" = "x" \
 797     || (test $have_valgrind_h = no \
 798         && test $gcc_cv_header_memcheck_h = no \
 799         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 800         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 801   fi
 802   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 803   valgrind_command="$valgrind_path -q"
 804   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 805 [Define if you want to run subprograms and generated programs
 806    through valgrind (a memory checker).  This is extremely expensive.])
 807 fi
 808 AC_SUBST(valgrind_path_defines)
 809 AC_SUBST(valgrind_command)
 810
 811 # Enable code coverage collection
 812 AC_ARG_ENABLE(coverage,
 813 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 814                 [enable compiler's code coverage collection.
 815                  Use to measure compiler performance and locate
 816                  unused parts of the compiler. With LEVEL, specify
 817                  optimization. Values are opt, noopt,
 818                  default is noopt])],
 819 [case "${enableval}" in
 820   yes|noopt)
 821     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0 -fkeep-static-functions"
 822     ;;
 823   opt)
 824     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2 -fkeep-static-functions"
 825     ;;
 826   no)
 827     # a.k.a. --disable-coverage
 828     coverage_flags=""
 829     ;;
 830   *)
 831     AC_MSG_ERROR(unknown coverage setting $enableval)
 832     ;;
 833 esac],
 834 [coverage_flags=""])
 835 AC_SUBST(coverage_flags)
 836
 837 AC_ARG_ENABLE(gather-detailed-mem-stats,
 838 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 839                 [enable detailed memory allocation stats gathering])], [],
 840 [enable_gather_detailed_mem_stats=no])
 841 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 842 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 843 [Define to enable detailed memory allocation stats gathering.])
 844
 845 AC_ARG_ENABLE(valgrind-annotations,
 846 [AS_HELP_STRING([--enable-valgrind-annotations],
 847                 [enable valgrind runtime interaction])], [],
 848 [enable_valgrind_annotations=no])
 849 if test x$enable_valgrind_annotations != xno \
 850     || test x$ac_valgrind_checking != x; then
 851   if (test $have_valgrind_h = no \
 852       && test $gcc_cv_header_memcheck_h = no \
 853       && test $gcc_cv_header_valgrind_memcheck_h = no); then
 854     AC_MSG_ERROR([*** Can't find valgrind/memcheck.h, memcheck.h or valgrind.h])
 855   fi
 856   AC_DEFINE(ENABLE_VALGRIND_ANNOTATIONS, 1,
 857 [Define to get calls to the valgrind runtime enabled.])
 858 fi
 859
 860 # -------------------------------
 861 # Miscenalleous configure options
 862 # -------------------------------
 863
 864 # Determine whether or not multilibs are enabled.
 865 AC_ARG_ENABLE(multilib,
 866 [AS_HELP_STRING([--enable-multilib],
 867                 [enable library support for multiple ABIs])],
 868 [], [enable_multilib=yes])
 869 AC_SUBST(enable_multilib)
 870
 871 # Determine whether or not multiarch is enabled.
 872 AC_ARG_ENABLE(multiarch,
 873 [AS_HELP_STRING([--enable-multiarch],
 874                 [enable support for multiarch paths])],
 875 [case "${enableval}" in
 876 yes|no|auto) enable_multiarch=$enableval;;
 877 *) AC_MSG_ERROR(bad value ${enableval} given for --enable-multiarch option) ;;
 878 esac], [enable_multiarch=auto])
 879 if test x${enable_multiarch} = xauto; then
 880   if test x${with_native_system_header_dir} != x; then
 881     ma_msg_suffix=", disabled auto check (configured with --native-system-header-dir)"
 882     enable_multiarch=no
 883   fi
 884   if test x$host != x$target && test "x$with_sysroot" = x; then
 885     ma_msg_suffix=", disabled auto check (cross build configured without --with-sysroot)"
 886     enable_multiarch=no
 887   fi
 888 fi
 889 AC_MSG_CHECKING(for multiarch configuration)
 890 AC_SUBST(enable_multiarch)
 891 AC_MSG_RESULT($enable_multiarch$ma_msg_suffix)
 892
 893 # needed for setting the multiarch name for soft-float/hard-float ABIs
 894 AC_SUBST(with_cpu)
 895 AC_SUBST(with_float)
 896
 897 # default stack clash protection guard size as power of twos in bytes.
 898 # Please keep these in sync with params.def.
 899 stk_clash_min=12
 900 stk_clash_max=30
 901
 902 # Keep the default value when the option is not used to 0, this allows us to
 903 # distinguish between the cases where the user specifially set a value via
 904 # configure and when the normal default value is used.
 905 AC_ARG_WITH(stack-clash-protection-guard-size,
 906 [AS_HELP_STRING([--with-stack-clash-protection-guard-size=size],
 907 [Set the default stack clash protection guard size for specific targets as a power of two in bytes.])],
 908 [DEFAULT_STK_CLASH_GUARD_SIZE="$with_stack_clash_protection_guard_size"], [DEFAULT_STK_CLASH_GUARD_SIZE=0])
 909 if test $DEFAULT_STK_CLASH_GUARD_SIZE -ne 0 \
 910      && (test $DEFAULT_STK_CLASH_GUARD_SIZE -lt $stk_clash_min \
 911          || test $DEFAULT_STK_CLASH_GUARD_SIZE -gt $stk_clash_max); then
 912   AC_MSG_ERROR(m4_normalize([
 913                 Invalid value $DEFAULT_STK_CLASH_GUARD_SIZE for --with-stack-clash-protection-guard-size. \
 914                 Must be between $stk_clash_min and $stk_clash_max.]))
 915 fi
 916
 917 AC_DEFINE_UNQUOTED(DEFAULT_STK_CLASH_GUARD_SIZE, $DEFAULT_STK_CLASH_GUARD_SIZE,
 918         [Define to larger than zero set the default stack clash protector size.])
 919
 920 # Enable __cxa_atexit for C++.
 921 AC_ARG_ENABLE(__cxa_atexit,
 922 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 923 [], [])
 924
 925 # Enable C extension for decimal float if target supports it.
 926 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 927
 928 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 929 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 930 [Define to 1 to enable decimal float extension to C.])
 931
 932 # Use default_decimal_float for dependency.
 933 enable_decimal_float=$default_decimal_float
 934
 935 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 936 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 937 [Define to 1 to specify that we are using the BID decimal floating
 938 point format instead of DPD])
 939
 940 # Enable C extension for fixed-point arithmetic.
 941 AC_ARG_ENABLE(fixed-point,
 942 [AS_HELP_STRING([--enable-fixed-point],
 943                 [enable fixed-point arithmetic extension to C])],
 944 [],
 945 [
 946   case $target in
 947     arm*)
 948       enable_fixed_point=yes
 949       ;;
 950
 951     mips*-*-*)
 952       enable_fixed_point=yes
 953       ;;
 954     loongarch*-*-*)
 955       enable_fixed_point=yes
 956       ;;
 957     *)
 958       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 959       enable_fixed_point=no
 960       ;;
 961   esac
 962 ])
 963 AC_SUBST(enable_fixed_point)
 964
 965 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 966 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 967 [Define to 1 to enable fixed-point arithmetic extension to C.])
 968
 969 # Enable threads
 970 # Pass with no value to take the default
 971 # Pass with a value to specify a thread package
 972 AC_ARG_ENABLE(threads,
 973 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 974                 [enable thread usage for target GCC,
 975                  using LIB thread package])],,
 976 [enable_threads=''])
 977
 978 AC_ARG_ENABLE(tls,
 979 [AS_HELP_STRING([--enable-tls],
 980                 [enable or disable generation of tls code
 981                  overriding the assembler check for tls support])],
 982 [
 983   case $enable_tls in
 984     yes | no) ;;
 985     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 986 Valid choices are 'yes' and 'no'.]) ;;
 987   esac
 988 ], [enable_tls=''])
 989
 990 AC_ARG_ENABLE(vtable-verify,
 991 [AS_HELP_STRING([--enable-vtable-verify],
 992                 [enable vtable verification feature])],,
 993 [enable_vtable_verify=no])
 994 vtable_verify=`if test x$enable_vtable_verify = xyes; then echo 1; else echo 0; fi`
 995 AC_DEFINE_UNQUOTED(ENABLE_VTABLE_VERIFY, $vtable_verify,
 996 [Define 0/1 if vtable verification feature is enabled.])
 997
 998 AC_ARG_ENABLE(analyzer,
 999 [AS_HELP_STRING([--disable-analyzer],
1000                 [disable -fanalyzer static analyzer])],
1001 if test x$enable_analyzer = xno; then
1002         analyzer=0
1003 else
1004         analyzer=1
1005 fi,
1006 analyzer=1)
1007 AC_DEFINE_UNQUOTED(ENABLE_ANALYZER, $analyzer,
1008 [Define 0/1 if static analyzer feature is enabled.])
1009
1010 AC_ARG_ENABLE(objc-gc,
1011 [AS_HELP_STRING([--enable-objc-gc],
1012                 [enable the use of Boehm's garbage collector with
1013                  the GNU Objective-C runtime])],
1014 if test x$enable_objc_gc = xno; then
1015         objc_boehm_gc=''
1016 else
1017         objc_boehm_gc=1
1018 fi,
1019 objc_boehm_gc='')
1020
1021 AC_ARG_WITH(dwarf2,
1022 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
1023 dwarf2="$with_dwarf2",
1024 dwarf2=no)
1025
1026 AC_ARG_ENABLE(shared,
1027 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
1028 [
1029   case $enable_shared in
1030   yes | no) ;;
1031   *)
1032     enable_shared=no
1033     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
1034     for pkg in $enableval; do
1035       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
1036         enable_shared=yes
1037       fi
1038     done
1039     IFS="$ac_save_ifs"
1040     ;;
1041   esac
1042 ], [enable_shared=yes])
1043 AC_SUBST(enable_shared)
1044
1045 AC_ARG_ENABLE(gcov,
1046 [  --disable-gcov          don't provide libgcov and related host tools],
1047 [], [case $target in
1048        bpf-*-*)
1049          enable_gcov=no
1050        ;;
1051        *)
1052          enable_gcov=yes
1053        ;;
1054      esac])
1055
1056 AC_SUBST(enable_gcov)
1057
1058 AC_ARG_WITH(specs,
1059   [AS_HELP_STRING([--with-specs=SPECS],
1060                   [add SPECS to driver command-line processing])],
1061   [CONFIGURE_SPECS=$withval],
1062   [CONFIGURE_SPECS=]
1063 )
1064 AC_SUBST(CONFIGURE_SPECS)
1065
1066 ACX_PKGVERSION([GCC])
1067 ACX_BUGURL([https://gcc.gnu.org/bugs/])
1068
1069 # Allow overriding the default URL for documentation
1070 AC_ARG_WITH(documentation-root-url,
1071     AS_HELP_STRING([--with-documentation-root-url=URL],
1072                    [Root for documentation URLs]),
1073     [case "$withval" in
1074       yes) AC_MSG_ERROR([documentation root URL not specified]) ;;
1075       no)  AC_MSG_ERROR([documentation root URL not specified]) ;;
1076       */)  DOCUMENTATION_ROOT_URL="$withval" ;;
1077       *)   AC_MSG_ERROR([documentation root URL does not end with /]) ;;
1078      esac],
1079      DOCUMENTATION_ROOT_URL="https://gcc.gnu.org/onlinedocs/"
1080 )
1081 AC_DEFINE_UNQUOTED(DOCUMENTATION_ROOT_URL,"$DOCUMENTATION_ROOT_URL",
1082         [Define to the root for documentation URLs.])
1083
1084 # Allow overriding the default URL for GCC changes
1085 AC_ARG_WITH(changes-root-url,
1086     AS_HELP_STRING([--with-changes-root-url=URL],
1087                    [Root for GCC changes URLs]),
1088     [case "$withval" in
1089       yes) AC_MSG_ERROR([changes root URL not specified]) ;;
1090       no)  AC_MSG_ERROR([changes root URL not specified]) ;;
1091       */)  CHANGES_ROOT_URL="$withval" ;;
1092       *)   AC_MSG_ERROR([changes root URL does not end with /]) ;;
1093      esac],
1094      CHANGES_ROOT_URL="https://gcc.gnu.org/"
1095 )
1096 AC_DEFINE_UNQUOTED(CHANGES_ROOT_URL,"$CHANGES_ROOT_URL",
1097         [Define to the root for URLs about GCC changes.])
1098
1099 # Sanity check enable_languages in case someone does not run the toplevel
1100 # configure # script.
1101 AC_ARG_ENABLE(languages,
1102 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
1103 [case ,${enable_languages}, in
1104        ,,|,yes,)
1105                 # go safe -- we cannot be much sure without the toplevel
1106                 # configure's
1107                 # analysis of which target libs are present and usable
1108                 enable_languages=c
1109                 ;;
1110          *,all,*)
1111                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
1112                 ;;
1113         *,c,*)
1114                 ;;
1115         *)
1116                 enable_languages=c,${enable_languages}
1117                 ;;
1118 esac],
1119 [enable_languages=c])
1120
1121 # If top-level libada has been disabled, then wire in install-gnatlib
1122 # invocation with `make install', so that one can build and install
1123 # the library manually with `make -C gcc all gnatlib gnattools install'.
1124 if test x"$enable_libada" = xno; then
1125   gnat_install_lib=gnat-install-lib
1126 else
1127   gnat_install_lib=
1128 fi
1129 AC_SUBST(gnat_install_lib)
1130
1131 if test x"$enable_as_accelerator_for" != x; then
1132   AC_DEFINE(ACCEL_COMPILER, 1,
1133     [Define if this compiler should be built as the offload target compiler.])
1134   enable_as_accelerator=yes
1135   case "${target}" in
1136     *-intelmicemul-*)
1137       # In this case we expect offload compiler to be built as native, so we
1138       # need to rename the driver to avoid clashes with host's drivers.
1139       program_transform_name="s&^&${target}-&" ;;
1140   esac
1141   sedscript="s#${target_noncanonical}#${enable_as_accelerator_for}-accel-${target_noncanonical}#"
1142   program_transform_name=`echo $program_transform_name | sed $sedscript`
1143   accel_dir_suffix=/accel/${target_noncanonical}
1144   real_target_noncanonical=${enable_as_accelerator_for}
1145 fi
1146 AC_SUBST(enable_as_accelerator)
1147 AC_SUBST(real_target_noncanonical)
1148 AC_SUBST(accel_dir_suffix)
1149
1150 for tgt in `echo $enable_offload_targets | sed 's/,/ /g'`; do
1151   tgt=`echo $tgt | sed 's/=.*//'`
1152
1153   enable_offloading=1
1154   case "$tgt" in
1155     *-intelmic-* | *-intelmicemul-*)
1156         omp_device_property=omp-device-properties-i386
1157         omp_device_property_tmake_file="${omp_device_property_tmake_file} \$(srcdir)/config/i386/t-omp-device"
1158         ;;
1159     amdgcn*)
1160         omp_device_property=omp-device-properties-gcn
1161         omp_device_property_tmake_file="${omp_device_property_tmake_file} \$(srcdir)/config/gcn/t-omp-device"
1162         ;;
1163     nvptx*)
1164         omp_device_property=omp-device-properties-nvptx
1165         omp_device_property_tmake_file="${omp_device_property_tmake_file} \$(srcdir)/config/nvptx/t-omp-device"
1166         ;;
1167     *)
1168         AC_MSG_ERROR([unknown offload target specified])
1169         ;;
1170   esac
1171   omp_device_properties="${omp_device_properties} ${tgt}=${omp_device_property}"
1172   omp_device_property_deps="${omp_device_property_deps} ${omp_device_property}"
1173
1174   if test x"$offload_targets" = x; then
1175     offload_targets=$tgt
1176   else
1177     offload_targets="$offload_targets,$tgt"
1178   fi
1179 done
1180 AC_SUBST(omp_device_properties)
1181 AC_SUBST(omp_device_property_deps)
1182
1183 AC_DEFINE_UNQUOTED(OFFLOAD_TARGETS, "$offload_targets",
1184   [Define to offload targets, separated by commas.])
1185 if test x"$enable_offloading" != x; then
1186   AC_DEFINE(ENABLE_OFFLOADING, 1,
1187     [Define this to enable support for offloading.])
1188 else
1189   AC_DEFINE(ENABLE_OFFLOADING, 0,
1190     [Define this to enable support for offloading.])
1191 fi
1192
1193 if test "x$enable_offload_defaulted" = xyes; then
1194   AC_DEFINE(OFFLOAD_DEFAULTED, 1,
1195     [Define to 1 to if -foffload is defaulted])
1196 fi
1197
1198 AC_ARG_WITH(multilib-list,
1199 [AS_HELP_STRING([--with-multilib-list], [select multilibs (AArch64, ARM, AVR, OR1K, RISC-V, SH and x86-64 only)])],
1200 :,
1201 with_multilib_list=default)
1202
1203 AC_ARG_WITH(multilib-generator,
1204 [AS_HELP_STRING([--with-multilib-generator], [Multi-libs configuration string (RISC-V only)])],
1205 :,
1206 with_multilib_generator=default)
1207
1208 # -------------------------
1209 # Checks for other programs
1210 # -------------------------
1211
1212 AC_PROG_MAKE_SET
1213
1214 # Find some useful tools
1215 AC_PROG_AWK
1216 # We need awk to create options.cc and options.h.
1217 # Bail out if it's missing.
1218 case ${AWK} in
1219   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
1220 esac
1221
1222 gcc_AC_PROG_LN_S
1223 ACX_PROG_LN($LN_S)
1224 AC_PROG_RANLIB
1225 ranlib_flags=""
1226 AC_SUBST(ranlib_flags)
1227
1228 gcc_AC_PROG_INSTALL
1229
1230 # See if cmp has --ignore-initial.
1231 gcc_AC_PROG_CMP_IGNORE_INITIAL
1232
1233 # See if we have the mktemp command.
1234 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
1235
1236 # See if makeinfo has been installed and is modern enough
1237 # that we can use it.
1238 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1239   [GNU texinfo.* \([0-9][0-9.]*\)],
1240   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
1241 if test $gcc_cv_prog_makeinfo_modern = no; then
1242   AC_MSG_WARN([
1243 *** Makeinfo is missing or too old.
1244 *** Info documentation will not be built.])
1245   BUILD_INFO=
1246 else
1247   BUILD_INFO=info
1248 fi
1249 AC_SUBST(BUILD_INFO)
1250
1251 # Is pod2man recent enough to regenerate manpages?
1252 AC_MSG_CHECKING([for recent Pod::Man])
1253 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
1254   AC_MSG_RESULT(yes)
1255   GENERATED_MANPAGES=generated-manpages
1256 else
1257   AC_MSG_RESULT(no)
1258   GENERATED_MANPAGES=
1259 fi
1260 AC_SUBST(GENERATED_MANPAGES)
1261
1262 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
1263
1264 # How about lex?
1265 dnl Don't use AC_PROG_LEX; we insist on flex.
1266 dnl LEXLIB is not useful in gcc.
1267 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
1268
1269 # Bison?
1270 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
1271
1272 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
1273 # check for build == host before using them.
1274
1275 # NM
1276 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
1277   && test -d ../binutils ; then
1278   NM='${objdir}/../binutils/nm-new'
1279 else
1280   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
1281 fi
1282
1283 # AR
1284 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
1285   && test -d ../binutils ; then
1286   AR='${objdir}/../binutils/ar'
1287 else
1288   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
1289 fi
1290
1291 # The jit documentation looks better if built with sphinx, but can be
1292 # built with texinfo if sphinx is not available.
1293 # Set "doc_build_sys" to "sphinx" or "texinfo" accordingly.
1294 AC_CHECK_PROG(doc_build_sys, sphinx-build, sphinx, texinfo)
1295
1296 # --------------------
1297 # Checks for C headers
1298 # --------------------
1299
1300 # Need to reject headers which give warnings, so that the -Werror bootstrap
1301 # works later. *sigh*  This needs to come before all header checks.
1302 AC_PROG_CPP_WERROR
1303
1304 AC_HEADER_STDC
1305 AC_HEADER_TIME
1306 ACX_HEADER_STRING
1307 AC_HEADER_SYS_WAIT
1308 AC_HEADER_TIOCGWINSZ
1309 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
1310                  fcntl.h ftw.h unistd.h sys/file.h sys/time.h sys/mman.h \
1311                  sys/resource.h sys/param.h sys/times.h sys/stat.h sys/locking.h \
1312                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
1313
1314 # Check for thread headers.
1315 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
1316 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
1317
1318 # These tests can't be done till we know if we have limits.h.
1319 gcc_AC_C_CHAR_BIT
1320 AC_C_BIGENDIAN
1321
1322 # ----------------------
1323 # Checks for C++ headers
1324 # ----------------------
1325
1326 dnl Autoconf will give an error in the configure script if there is no
1327 dnl C++ preprocessor.  Hack to prevent that.
1328 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
1329 AC_PROG_CXXCPP
1330 m4_popdef([AC_MSG_ERROR])[]dnl
1331
1332 AC_CHECK_HEADERS(unordered_map)
1333 AC_CHECK_HEADERS(tr1/unordered_map)
1334 AC_CHECK_HEADERS(ext/hash_map)
1335
1336 # --------
1337 # Dependency checking.
1338 # --------
1339
1340 ZW_CREATE_DEPDIR
1341 AC_CONFIG_COMMANDS([gccdepdir],[
1342   ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs build/$DEPDIR
1343   for lang in $subdirs c-family common analyzer rtl-ssa
1344   do
1345       ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs $lang/$DEPDIR
1346   done], [subdirs="$subdirs" ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR])
1347
1348 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
1349
1350 # --------
1351 # UNSORTED
1352 # --------
1353
1354
1355 # These libraries may be used by collect2.
1356 # We may need a special search path to get them linked.
1357 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
1358 [save_LIBS="$LIBS"
1359 for libs in '' -lld -lmld \
1360                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1361                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1362 do
1363         LIBS="$libs"
1364         AC_TRY_LINK_FUNC(ldopen,
1365                 [gcc_cv_collect2_libs="$libs"; break])
1366 done
1367 LIBS="$save_LIBS"
1368 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1369 case $gcc_cv_collect2_libs in
1370         "none required")        ;;
1371         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1372 esac
1373 AC_SUBST(COLLECT2_LIBS)
1374
1375 # When building Ada code on Alpha, we need exc_resume which is usually in
1376 # -lexc.  So test for it.
1377 save_LIBS="$LIBS"
1378 LIBS=
1379 AC_SEARCH_LIBS(exc_resume, exc)
1380 GNAT_LIBEXC="$LIBS"
1381 LIBS="$save_LIBS"
1382 AC_SUBST(GNAT_LIBEXC)
1383
1384 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
1385 save_LIBS="$LIBS"
1386 LIBS=
1387 AC_SEARCH_LIBS(kstat_open, kstat)
1388 EXTRA_GCC_LIBS="$LIBS"
1389 LIBS="$save_LIBS"
1390 AC_SUBST(EXTRA_GCC_LIBS)
1391
1392 # Solaris needs libsocket and libnsl for socket functions before 11.4.
1393 # C++ needs those for libcody.
1394 save_LIBS="$LIBS"
1395 LIBS=
1396 AX_LIB_SOCKET_NSL
1397 NETLIBS="$LIBS"
1398 LIBS="$save_LIBS"
1399 AC_SUBST(NETLIBS)
1400
1401 # Some systems put ldexp and frexp in libm instead of libc; assume
1402 # they're both in the same place.  jcf-dump needs them.
1403 save_LIBS="$LIBS"
1404 LIBS=
1405 AC_SEARCH_LIBS(ldexp, m)
1406 LDEXP_LIB="$LIBS"
1407 LIBS="$save_LIBS"
1408 AC_SUBST(LDEXP_LIB)
1409
1410 # Some systems need dlopen
1411 save_LIBS="$LIBS"
1412 LIBS=
1413 AC_SEARCH_LIBS(dlopen, dl)
1414 DL_LIB="$LIBS"
1415 LIBS="$save_LIBS"
1416 AC_SUBST(DL_LIB)
1417
1418 # Use <inttypes.h> only if it exists,
1419 # doesn't clash with <sys/types.h>, declares intmax_t and defines
1420 # PRId64
1421 AC_MSG_CHECKING(for inttypes.h)
1422 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1423 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1424 [[#define __STDC_FORMAT_MACROS
1425 #include <sys/types.h>
1426 #include <inttypes.h>]],
1427   [[intmax_t i = -1;
1428 #ifndef PRId64
1429 choke me
1430 #endif]])],
1431   [gcc_cv_header_inttypes_h=yes],
1432   [gcc_cv_header_inttypes_h=no])])
1433 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1434 if test $gcc_cv_header_inttypes_h = yes; then
1435   AC_DEFINE(HAVE_INTTYPES_H, 1,
1436         [Define if you have a working <inttypes.h> header file.])
1437 fi
1438
1439 # Look for the ZSTD package.
1440 ZSTD_INCLUDE=
1441 ZSTD_LIB=
1442 AC_SUBST(ZSTD_INCLUDE)
1443 AC_SUBST(ZSTD_LIB)
1444 ZSTD_CPPFLAGS=
1445 ZSTD_LDFLAGS=
1446 AC_SUBST(ZSTD_CPPFLAGS)
1447 AC_SUBST(ZSTD_LDFLAGS)
1448 AC_ARG_WITH(zstd,
1449         [AS_HELP_STRING([--with-zstd=PATH],
1450                 [specify prefix directory for installed zstd library.
1451                  Equivalent to --with-zstd-include=PATH/include
1452                  plus --with-zstd-lib=PATH/lib])])
1453 AC_ARG_WITH(zstd-include,
1454         [AS_HELP_STRING([--with-zstd-include=PATH],
1455                 [specify directory for installed zstd include files])])
1456 AC_ARG_WITH(zstd-lib,
1457         [AS_HELP_STRING([--with-zstd-lib=PATH],
1458                 [specify directory for the installed zstd library])])
1459 case "x$with_zstd" in
1460   x) ;;
1461   xno)
1462     ZSTD_INCLUDE=
1463     ZSTD_LIB=
1464     ;;
1465   *) ZSTD_INCLUDE=$with_zstd/include
1466      ZSTD_LIB=$with_zstd/lib
1467      ;;
1468 esac
1469
1470 if test "x$with_zstd" != xno; then
1471 if test "x$with_zstd_include" != x; then
1472   ZSTD_INCLUDE=$with_zstd_include
1473 fi
1474 if test "x$with_zstd_lib" != x; then
1475   ZSTD_LIB=$with_zstd_lib
1476 fi
1477 if test "x$ZSTD_INCLUDE" != x \
1478    && test "x$ZSTD_INCLUDE" != xno; then
1479   ZSTD_CPPFLAGS=-I$ZSTD_INCLUDE
1480 fi
1481 if test "x$ZSTD_LIB" != x \
1482    && test "x$ZSTD_LIB" != xno; then
1483   ZSTD_LDFLAGS=-L$ZSTD_LIB
1484 fi
1485
1486 CXXFLAGS="$CXXFLAGS $ZSTD_CPPFLAGS"
1487 LDFLAGS="$LDFLAGS $ZSTD_LDFLAGS"
1488
1489 AC_MSG_CHECKING(for zstd.h)
1490 AC_CACHE_VAL(gcc_cv_header_zstd_h,
1491 # We require version 1.3.0 or later.  This is the first version that has
1492 # ZSTD_getFrameContentSize.
1493 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1494 [[#include <zstd.h>
1495 #if ZSTD_VERSION_NUMBER < 10300
1496 #error "need zstd 1.3.0 or better"
1497 #endif]])],
1498   [gcc_cv_header_zstd_h=yes],
1499   [gcc_cv_header_zstd_h=no])])
1500 AC_MSG_RESULT($gcc_cv_header_zstd_h)
1501 if test $gcc_cv_header_zstd_h = yes; then
1502   AC_DEFINE(HAVE_ZSTD_H, 1,
1503         [Define if you have a working <zstd.h> header file.])
1504 elif test "x$with_zstd" != x; then
1505     as_fn_error $? "Unable to find zstd.h.  See config.log for details." "$LINENO" 5
1506 fi
1507
1508 # LTO can use zstd compression algorithm
1509 save_LIBS="$LIBS"
1510 LIBS=
1511 AC_SEARCH_LIBS(ZSTD_compress, zstd)
1512 ZSTD_LIB="$LIBS"
1513 LIBS="$save_LIBS"
1514 AC_SUBST(ZSTD_LIB)
1515 fi
1516
1517 dnl Disabled until we have a complete test for buggy enum bitfields.
1518 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1519
1520 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1521   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1522   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1523   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1524   putchar_unlocked putc_unlocked)
1525 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoq \
1526         popen sysconf strsignal getrusage nl_langinfo \
1527         gettimeofday mbstowcs wcswidth mmap posix_fallocate setlocale \
1528         gcc_UNLOCKED_FUNCS madvise mallinfo mallinfo2 fstatat)
1529
1530 if test x$ac_cv_func_mbstowcs = xyes; then
1531   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1532 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1533 int main()
1534 {
1535   mbstowcs(0, "", 0);
1536   return 0;
1537 }]])],
1538     [gcc_cv_func_mbstowcs_works=yes],
1539     [gcc_cv_func_mbstowcs_works=no],
1540     [gcc_cv_func_mbstowcs_works=yes])])
1541   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1542     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1543   [Define this macro if mbstowcs does not crash when its
1544    first argument is NULL.])
1545   fi
1546 fi
1547
1548 AC_CHECK_TYPE(ssize_t, int)
1549 AC_CHECK_TYPE(caddr_t, char *)
1550 AC_CHECK_TYPE(sighander_t,
1551   AC_DEFINE(HAVE_SIGHANDLER_T, 1,
1552     [Define if <sys/signal.h> defines sighandler_t]),
1553     ,signal.h)
1554
1555 GCC_AC_FUNC_MMAP_BLACKLIST
1556
1557 case "${host}" in
1558 *-*-*vms*)
1559   # Under VMS, vfork works very differently than on Unix. The standard test
1560   # won't work, and it isn't easily adaptable. It makes more sense to
1561   # just force it.
1562   ac_cv_func_vfork_works=yes
1563   ;;
1564 esac
1565 AC_FUNC_FORK
1566
1567 AM_ICONV
1568
1569 # Until we have in-tree GNU iconv:
1570 LIBICONV_DEP=
1571 if test -f "$LTLIBICONV"; then
1572   LIBICONV_DEP=$LTLIBICONV
1573 fi
1574 AC_SUBST(LIBICONV_DEP)
1575
1576 AM_LC_MESSAGES
1577
1578 AM_LANGINFO_CODESET
1579
1580 # We will need to find libiberty.h and ansidecl.h
1581 saved_CFLAGS="$CFLAGS"
1582 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1583 saved_CXXFLAGS="$CXXFLAGS"
1584 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1585
1586 # gcc_AC_CHECK_DECLS doesn't support overloaded functions, so use the
1587 # normal autoconf function for these.  But force definition of
1588 # HAVE_DECL_BASENAME like gcc_AC_CHECK_DECLS does, to suppress the bizarre
1589 # basename handling in libiberty.h.
1590 AC_CHECK_DECLS([basename(const char*), strstr(const char*,const char*)], , ,[
1591 #undef HAVE_DECL_BASENAME
1592 #define HAVE_DECL_BASENAME 1
1593 #include "ansidecl.h"
1594 #include "system.h"])
1595
1596 gcc_AC_CHECK_DECLS(getenv atol atoll asprintf sbrk abort atof getcwd getwd \
1597         madvise stpcpy strnlen strsignal strverscmp \
1598         strtol strtoul strtoll strtoull setenv unsetenv \
1599         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1600         free getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1601 #include "ansidecl.h"
1602 #include "system.h"])
1603
1604 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1605 #include "ansidecl.h"
1606 #include "system.h"
1607 #ifdef HAVE_SYS_RESOURCE_H
1608 #include <sys/resource.h>
1609 #endif
1610 ])
1611
1612 gcc_AC_CHECK_DECLS(mallinfo mallinfo2, , ,[
1613 #include "ansidecl.h"
1614 #include "system.h"
1615 #ifdef HAVE_MALLOC_H
1616 #include <malloc.h>
1617 #endif
1618 ])
1619
1620 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1621 #include "ansidecl.h"
1622 #include "system.h"
1623 #ifdef HAVE_SYS_RESOURCE_H
1624 #include <sys/resource.h>
1625 #endif
1626 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1627 [Define to `long' if <sys/resource.h> doesn't define.])])
1628
1629 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1630 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1631 # in collect2.cc, <fcntl.h> isn't visible, but the configure test below needs
1632 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1633 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1634 #include "ansidecl.h"
1635 #include "system.h"
1636 #ifdef HAVE_LDFCN_H
1637 #undef FREAD
1638 #undef FWRITE
1639 #include <ldfcn.h>
1640 #endif
1641 ])
1642
1643 gcc_AC_CHECK_DECLS(times, , ,[
1644 #include "ansidecl.h"
1645 #include "system.h"
1646 #ifdef HAVE_SYS_TIMES_H
1647 #include <sys/times.h>
1648 #endif
1649 ])
1650
1651 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1652 #include "ansidecl.h"
1653 #include "system.h"
1654 #include <signal.h>
1655 ])
1656
1657 # More time-related stuff.
1658 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1659 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1660 #include "ansidecl.h"
1661 #include "system.h"
1662 #ifdef HAVE_SYS_TIMES_H
1663 #include <sys/times.h>
1664 #endif
1665 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1666 if test $ac_cv_struct_tms = yes; then
1667   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1668   [Define if <sys/times.h> defines struct tms.])
1669 fi
1670
1671 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1672 # revisit after autoconf 2.50.
1673 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1674 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1675 #include "ansidecl.h"
1676 #include "system.h"
1677 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1678 if test $gcc_cv_type_clock_t = yes; then
1679   AC_DEFINE(HAVE_CLOCK_T, 1,
1680   [Define if <time.h> defines clock_t.])
1681 fi
1682
1683 # Check if F_SETLKW is supported by fcntl.
1684 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1685 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1686 #include <fcntl.h>]], [[
1687 struct flock fl;
1688 fl.l_whence = 0;
1689 fl.l_start = 0;
1690 fl.l_len = 0;
1691 fl.l_pid = 0;
1692 return fcntl (1, F_SETLKW, &fl);]])],
1693 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1694 if test $ac_cv_f_setlkw = yes; then
1695   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1696   [Define if F_SETLKW supported by fcntl.])
1697 fi
1698
1699 # Check if O_CLOEXEC is defined by fcntl
1700 AC_CACHE_CHECK(for O_CLOEXEC, ac_cv_o_cloexec, [
1701 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1702 #include <fcntl.h>]], [[
1703 return open ("/dev/null", O_RDONLY | O_CLOEXEC);]])],
1704 [ac_cv_o_cloexec=yes],[ac_cv_o_cloexec=no])])
1705 if test $ac_cv_o_cloexec = yes; then
1706   AC_DEFINE(HOST_HAS_O_CLOEXEC, 1,
1707   [Define if O_CLOEXEC supported by fcntl.])
1708 fi
1709
1710 # Check if O_NONBLOCK is defined by fcntl
1711 AC_CHECK_HEADERS([fcntl.h])
1712 AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
1713 if test $ac_cv_have_decl_O_NONBLOCK = yes; then
1714   AC_DEFINE(HOST_HAS_O_NONBLOCK, 1,
1715   [Define if O_NONBLOCK supported by fcntl.])
1716 fi
1717
1718
1719 # C++ Modules would like some networking features to provide the mapping
1720 # server.  You can still use modules without them though.
1721 # The following network-related checks could probably do with some
1722 # Windows and other non-linux defenses and checking.
1723
1724 # Local socket connectivity wants AF_UNIX networking
1725 # Check for AF_UNIX networking
1726 AC_CACHE_CHECK(for AF_UNIX, ac_cv_af_unix, [
1727 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1728 #include <sys/types.h>
1729 #include <sys/socket.h>
1730 #include <sys/un.h>
1731 #include <netinet/in.h>]],[[
1732 sockaddr_un un;
1733 un.sun_family = AF_UNSPEC;
1734 int fd = socket (AF_UNIX, SOCK_STREAM, 0);
1735 connect (fd, (sockaddr *)&un, sizeof (un));]])],
1736 [ac_cv_af_unix=yes],
1737 [ac_cv_af_unix=no])])
1738 if test $ac_cv_af_unix = yes; then
1739   AC_DEFINE(HAVE_AF_UNIX, 1,
1740   [Define if AF_UNIX supported.])
1741 fi
1742
1743 # Remote socket connectivity wants AF_INET6 networking
1744 # Check for AF_INET6 networking
1745 AC_CACHE_CHECK(for AF_INET6, ac_cv_af_inet6, [
1746 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1747 #include <sys/types.h>
1748 #include <sys/socket.h>
1749 #include <netinet/in.h>
1750 #include <netdb.h>]],[[
1751 sockaddr_in6 in6;
1752 in6.sin6_family = AF_UNSPEC;
1753 struct addrinfo *addrs = 0;
1754 struct addrinfo hints;
1755 hints.ai_flags = 0;
1756 hints.ai_family = AF_INET6;
1757 hints.ai_socktype = SOCK_STREAM;
1758 hints.ai_protocol = 0;
1759 hints.ai_canonname = 0;
1760 hints.ai_addr = 0;
1761 hints.ai_next = 0;
1762 int e = getaddrinfo ("localhost", 0, &hints, &addrs);
1763 const char *str = gai_strerror (e);
1764 freeaddrinfo (addrs);
1765 int fd = socket (AF_INET6, SOCK_STREAM, 0);
1766 connect (fd, (sockaddr *)&in6, sizeof (in6));]])],
1767 [ac_cv_af_inet6=yes],
1768 [ac_cv_af_inet6=no])])
1769 if test $ac_cv_af_inet6 = yes; then
1770   AC_DEFINE(HAVE_AF_INET6, 1,
1771   [Define if AF_INET6 supported.])
1772 fi
1773
1774 # Check if _LK_LOCK is supported by _locking
1775 AC_CACHE_CHECK(for _LK_LOCK, ac_cv_lk_lock, [
1776 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1777 #include <io.h>
1778 #include <sys/locking.h>]], [[
1779   int fd;
1780   return _locking (fd, _LK_LOCK, 0);]])],
1781 [ac_cv_lk_lock=yes],[ac_cv_lk_lock=no])])
1782 if test $ac_cv_lk_lock = yes; then
1783   AC_DEFINE(HOST_HAS_LK_LOCK, 1,
1784   [Define if _LK_LOC supported by _locking.])
1785 fi
1786
1787 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1788 CFLAGS="$saved_CFLAGS"
1789 CXXFLAGS="$saved_CXXFLAGS"
1790
1791 # mkdir takes a single argument on some systems.
1792 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1793
1794 # File extensions
1795 manext='.1'
1796 objext='.o'
1797 AC_SUBST(manext)
1798 AC_SUBST(objext)
1799
1800 # With Setjmp/Longjmp based exception handling.
1801 AC_ARG_ENABLE(sjlj-exceptions,
1802 [AS_HELP_STRING([--enable-sjlj-exceptions],
1803                 [arrange to use setjmp/longjmp exception handling])],
1804 [case $target in
1805   lm32*-*-*)
1806      force_sjlj_exceptions=yes
1807      enableval=yes
1808      ;;
1809   *)
1810     force_sjlj_exceptions=no
1811     ;;
1812 esac])
1813 if test $force_sjlj_exceptions = yes; then
1814   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1815   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1816     [Define 0/1 to force the choice for exception handling model.])
1817 fi
1818
1819 # --------------------------------------------------------
1820 # Build, host, and target specific configuration fragments
1821 # --------------------------------------------------------
1822
1823 # Collect build-machine-specific information.
1824 . ${srcdir}/config.build || exit 1
1825
1826 # Collect host-machine-specific information.
1827 . ${srcdir}/config.host || exit 1
1828
1829 target_gtfiles=
1830
1831 # Collect target-machine-specific information.
1832 . ${srcdir}/config.gcc || exit 1
1833
1834 extra_objs="${host_extra_objs} ${extra_objs}"
1835 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1836
1837 # Default the target-machine variables that were not explicitly set.
1838 if test x"$tm_file" = x
1839 then tm_file=$cpu_type/$cpu_type.h; fi
1840
1841 if test x"$extra_headers" = x
1842 then extra_headers=; fi
1843
1844 if test x$md_file = x
1845 then md_file=$cpu_type/$cpu_type.md; fi
1846
1847 if test x$out_file = x
1848 then out_file=$cpu_type/$cpu_type.cc; fi
1849
1850 if test x"$tmake_file" = x
1851 then tmake_file=$cpu_type/t-$cpu_type
1852 fi
1853
1854 # Support --enable-initfini-array.
1855 if test x$enable_initfini_array != xno; then
1856   tm_file="${tm_file} initfini-array.h"
1857 fi
1858
1859 if test x"$dwarf2" = xyes
1860 then tm_file="$tm_file tm-dwarf2.h"
1861 fi
1862
1863 # Say what files are being used for the output code and MD file.
1864 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1865 echo "Using \`$srcdir/config/$md_file' as machine description file."
1866
1867 # If any of the xm_file variables contain nonexistent files, warn
1868 # about them and drop them.
1869
1870 bx=
1871 for x in $build_xm_file; do
1872   if    test -f $srcdir/config/$x
1873   then      bx="$bx $x"
1874   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1875   fi
1876 done
1877 build_xm_file="$bx"
1878
1879 hx=
1880 for x in $host_xm_file; do
1881   if    test -f $srcdir/config/$x
1882   then      hx="$hx $x"
1883   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1884   fi
1885 done
1886 host_xm_file="$hx"
1887
1888 tx=
1889 for x in $xm_file; do
1890   if    test -f $srcdir/config/$x
1891   then      tx="$tx $x"
1892   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1893   fi
1894 done
1895 xm_file="$tx"
1896
1897 count=a
1898 for f in $tm_file; do
1899         count=${count}x
1900 done
1901 if test $count = ax; then
1902         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1903 else
1904         echo "Using the following target machine macro files:"
1905         for f in $tm_file; do
1906                 echo "  $srcdir/config/$f"
1907         done
1908 fi
1909
1910 if test x$use_long_long_for_widest_fast_int = xyes; then
1911         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1912 [Define to 1 if the 'long long' type is wider than 'long' but still
1913 efficiently supported by the host hardware.])
1914 fi
1915
1916 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1917 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1918
1919 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1920 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1921
1922 count=a
1923 for f in $host_xm_file; do
1924         count=${count}x
1925 done
1926 if test $count = a; then
1927         :
1928 elif test $count = ax; then
1929         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1930 else
1931         echo "Using the following host machine macro files:"
1932         for f in $host_xm_file; do
1933                 echo "  $srcdir/config/$f"
1934         done
1935 fi
1936 echo "Using ${out_host_hook_obj} for host machine hooks."
1937
1938 if test "$host_xm_file" != "$build_xm_file"; then
1939         count=a
1940         for f in $build_xm_file; do
1941                 count=${count}x
1942         done
1943         if test $count = a; then
1944                 :
1945         elif test $count = ax; then
1946                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1947         else
1948                 echo "Using the following build machine macro files:"
1949                 for f in $build_xm_file; do
1950                         echo "  $srcdir/config/$f"
1951                 done
1952         fi
1953 fi
1954
1955 if test -n "$configured_native_system_header_dir"; then
1956   native_system_header_dir=$configured_native_system_header_dir
1957 fi
1958 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1959 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1960
1961 case ${host} in
1962   powerpc*-*-darwin*)
1963     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1964       gcc_cv_mcontext_underscores,
1965       AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1966 #include <sys/cdefs.h>
1967 #include <sys/signal.h>
1968 #include <ucontext.h>
1969 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1970 ])],
1971         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1972       if test $gcc_cv_mcontext_underscores = yes; then
1973         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1974           [mcontext_t fields start with __])
1975       fi
1976     ;;
1977 esac
1978
1979 # ---------
1980 # Threading
1981 # ---------
1982
1983 # Check if a valid thread package
1984 case ${enable_threads} in
1985   "" | no)
1986     # No threads
1987     target_thread_file='single'
1988     ;;
1989   yes)
1990     # default
1991     target_thread_file='single'
1992     ;;
1993   aix | dce | lynx | mipssde | posix | rtems | \
1994   single | tpf | vxworks | win32)
1995     target_thread_file=${enable_threads}
1996     ;;
1997   *)
1998     echo "${enable_threads} is an unknown thread package" 1>&2
1999     exit 1
2000     ;;
2001 esac
2002
2003 if test x${thread_file} = x; then
2004   # No thread file set by target-specific clauses in config.gcc,
2005   # so use file chosen by default logic above
2006   thread_file=${target_thread_file}
2007 fi
2008
2009 # --------
2010 # UNSORTED
2011 # --------
2012
2013 use_cxa_atexit=no
2014 if test x$enable___cxa_atexit = xyes || \
2015    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
2016   if test x$host = x$target; then
2017     case $host in
2018       # mingw32 doesn't have __cxa_atexit but uses atexit registration
2019       # keyed to flag_use_cxa_atexit
2020       *-*-mingw32*)
2021         use_cxa_atexit=yes
2022         ;;
2023       powerpc-ibm-aix*)
2024         use_cxa_atexit=yes
2025         ;;
2026       *)
2027         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
2028           [echo "__cxa_atexit can't be enabled on this target"])
2029         ;;
2030     esac
2031   else
2032     # We can't check for __cxa_atexit when building a cross, so assume
2033     # it is available
2034     use_cxa_atexit=yes
2035   fi
2036   if test x$use_cxa_atexit = xyes; then
2037     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
2038       [Define if you want to use __cxa_atexit, rather than atexit, to
2039       register C++ destructors for local statics and global objects.
2040       This is essential for fully standards-compliant handling of
2041       destructors, but requires __cxa_atexit in libc.])
2042   fi
2043 fi
2044
2045 # Look for a file containing extra machine modes.
2046 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
2047   extra_modes_file='$(srcdir)'/config/${extra_modes}
2048   AC_SUBST(extra_modes_file)
2049   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
2050   [Define to the name of a file containing a list of extra machine modes
2051    for this architecture.])
2052 fi
2053
2054 # Convert extra_options into a form suitable for Makefile use.
2055 extra_opt_files=
2056 all_opt_files=
2057 for f in $extra_options; do
2058   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
2059   all_opt_files="$all_opt_files $srcdir/config/$f"
2060 done
2061 AC_SUBST(extra_opt_files)
2062
2063 # auto-host.h is the file containing items generated by autoconf and is
2064 # the first file included by config.h.
2065 # If host=build, it is correct to have bconfig include auto-host.h
2066 # as well.  If host!=build, we are in error and need to do more
2067 # work to find out the build config parameters.
2068 if test x$host = x$build
2069 then
2070         build_auto=auto-host.h
2071         HAVE_AUTO_BUILD='# '
2072 else
2073         # We create a subdir, then run autoconf in the subdir.
2074         # To prevent recursion we set host and build for the new
2075         # invocation of configure to the build for this invocation
2076         # of configure.
2077         tempdir=build.$$
2078         rm -rf $tempdir
2079         mkdir $tempdir
2080         cd $tempdir
2081         case ${srcdir} in
2082         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
2083         *) realsrcdir=../${srcdir};;
2084         esac
2085         # Clearing GMPINC is necessary to prevent host headers being
2086         # used by the build compiler.  Defining GENERATOR_FILE stops
2087         # system.h from including gmp.h.
2088         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
2089         CXX="${CXX_FOR_BUILD}" CXXFLAGS="${CXXFLAGS_FOR_BUILD}" \
2090         LD="${LD_FOR_BUILD}" LDFLAGS="${LDFLAGS_FOR_BUILD}" \
2091         GMPINC="" CPPFLAGS="${CPPFLAGS_FOR_BUILD} -DGENERATOR_FILE" \
2092         ${realsrcdir}/configure \
2093                 --enable-languages=${enable_languages-all} \
2094                 ${enable_obsolete+--enable-obsolete="$enable_obsolete"} \
2095                 ${enable_option_checking+--enable-option-checking="$enable_option_checking"} \
2096                 --target=$target_alias --host=$build_alias \
2097                 --build=$build_alias || exit # retaining $tempdir
2098
2099         # We just finished tests for the build machine, so rename
2100         # the file auto-build.h in the gcc directory.
2101         mv auto-host.h ../auto-build.h
2102         cd ..
2103         rm -rf $tempdir
2104         build_auto=auto-build.h
2105         HAVE_AUTO_BUILD=
2106 fi
2107 AC_SUBST(build_subdir)
2108 AC_SUBST(HAVE_AUTO_BUILD)
2109
2110 tm_file="${tm_file} defaults.h"
2111 tm_p_file="${tm_p_file} tm-preds.h"
2112 tm_d_file="${tm_d_file} defaults.h"
2113 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
2114 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
2115 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
2116 # put this back in temporarily.
2117 xm_file="auto-host.h ansidecl.h ${xm_file}"
2118
2119 # --------
2120 # UNSORTED
2121 # --------
2122
2123 changequote(,)dnl
2124 # Compile in configure arguments.
2125 if test -f configargs.h ; then
2126         # Being re-configured.
2127         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
2128         gcc_reconf_arguments=`echo "$gcc_config_arguments" | sed -e 's/^.*\( : (reconfigured) .*$\)/\1/'`
2129         if [ "$gcc_reconf_arguments" != " : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS" ]; then
2130                 gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
2131         fi
2132 else
2133         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
2134 fi
2135
2136 # Double all backslashes and backslash all quotes to turn
2137 # gcc_config_arguments into a C string.
2138 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
2139 $gcc_config_arguments
2140 EOF
2141 gcc_config_arguments_str=`cat conftest.out`
2142 rm -f conftest.out
2143
2144 cat > configargs.h <<EOF
2145 /* Generated automatically. */
2146 static const char configuration_arguments[] = "$gcc_config_arguments_str";
2147 static const char thread_model[] = "$thread_file";
2148
2149 static const struct {
2150   const char *name, *value;
2151 } configure_default_options[] = $configure_default_options;
2152 EOF
2153 changequote([,])dnl
2154
2155 changequote(,)dnl
2156 gcc_BASEVER=`cat $srcdir/BASE-VER`
2157 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
2158 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
2159 if test -f $srcdir/REVISION ; then
2160         gcc_REVISION=`cat $srcdir/REVISION`
2161 else
2162         gcc_REVISION=""
2163 fi
2164 cat > plugin-version.h <<EOF
2165 #include "configargs.h"
2166
2167 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
2168 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
2169 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
2170 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
2171
2172 static char basever[] = "$gcc_BASEVER";
2173 static char datestamp[] = "$gcc_DATESTAMP";
2174 static char devphase[] = "$gcc_DEVPHASE";
2175 static char revision[] = "$gcc_REVISION";
2176
2177 /* FIXME plugins: We should make the version information more precise.
2178    One way to do is to add a checksum. */
2179
2180 static struct plugin_gcc_version gcc_version = {basever, datestamp,
2181                                                 devphase, revision,
2182                                                 configuration_arguments};
2183 EOF
2184 changequote([,])dnl
2185
2186 # Determine what GCC version number to use in filesystem paths.
2187 GCC_BASE_VER
2188
2189 # Internationalization
2190 ZW_GNU_GETTEXT_SISTER_DIR
2191
2192 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
2193 # -liconv on the link line twice.
2194 case "$LIBINTL" in *$LIBICONV*)
2195         LIBICONV= ;;
2196 esac
2197
2198 AC_ARG_ENABLE(secureplt,
2199 [AS_HELP_STRING([--enable-secureplt],
2200                 [enable -msecure-plt by default for PowerPC])],
2201 [], [])
2202
2203 AC_ARG_ENABLE(mingw-wildcard,
2204 [AS_HELP_STRING([--enable-mingw-wildcard],
2205                 [Set whether to expand wildcard on command-line.
2206                  Default to platform configuration])],
2207 [],[enable_mingw_wildcard=platform])
2208 AS_IF([test x"$enable_mingw_wildcard" != xplatform ],
2209       [AC_DEFINE_UNQUOTED(MINGW_DOWILDCARD,
2210                  $(test x"$enable_mingw_wildcard" = xno; echo $?),
2211                  [Value to set mingw's _dowildcard to.])])
2212
2213 AC_ARG_ENABLE(large-address-aware,
2214 [AS_HELP_STRING([--enable-large-address-aware],
2215                 [Link mingw executables with --large-address-aware])])
2216 AS_IF([test x"$enable_large_address_aware" = xyes],
2217   [AC_DEFINE([MINGW_DEFAULT_LARGE_ADDR_AWARE], 1,
2218     [Define if we should link mingw executables with --large-address-aware])])
2219
2220 AC_ARG_ENABLE(leading-mingw64-underscores,
2221   AS_HELP_STRING([--enable-leading-mingw64-underscores],
2222                  [enable leading underscores on 64 bit mingw targets]),
2223   [],[])
2224 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
2225   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
2226     [Define if we should use leading underscore on 64 bit mingw targets])])
2227
2228 AC_ARG_ENABLE(cld,
2229 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
2230 [enable_cld=no])
2231
2232 AC_ARG_ENABLE(frame-pointer,
2233 [AS_HELP_STRING([--enable-frame-pointer],
2234                 [enable -fno-omit-frame-pointer by default for x86])], [],
2235 [
2236 case $target_os in
2237 linux* | gnu* | darwin[[8912]]* | cygwin* | mingw*)
2238   # Enable -fomit-frame-pointer by default for these systems with DWARF2.
2239   enable_frame_pointer=no
2240   ;;
2241 *)
2242   enable_frame_pointer=yes
2243   ;;
2244 esac
2245 ])
2246
2247 case $target in
2248 i[[34567]]86-*-* | x86_64-*-*)
2249         if test "x$enable_cld" = xyes; then
2250                 tm_defines="${tm_defines} USE_IX86_CLD=1"
2251         fi
2252         if test "x$enable_frame_pointer" = xyes; then
2253                 tm_defines="${tm_defines} USE_IX86_FRAME_POINTER=1"
2254         fi
2255         ;;
2256 esac
2257
2258 # Windows32 Registry support for specifying GCC installation paths.
2259 AC_ARG_ENABLE(win32-registry,
2260 [AS_HELP_STRING([--disable-win32-registry],
2261                 [disable lookup of installation paths in the
2262                  Registry on Windows hosts])
2263 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
2264 AS_HELP_STRING([--enable-win32-registry=KEY],
2265                [use KEY instead of GCC version as the last portion
2266                 of the registry key])],,)
2267
2268 case $host_os in
2269   win32 | pe | cygwin* | mingw32*)
2270     if test "x$enable_win32_registry" != xno; then
2271       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
2272     fi
2273
2274     if test "x$enable_win32_registry" != xno; then
2275       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
2276   [Define to 1 if installation paths should be looked up in the Windows
2277    Registry. Ignored on non-Windows hosts.])
2278
2279       if test "x$enable_win32_registry" != xyes \
2280          && test "x$enable_win32_registry" != x; then
2281         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
2282   [Define to be the last component of the Windows registry key under which
2283    to look for installation paths.  The full key used will be
2284    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
2285    The default is the GCC version number.])
2286       fi
2287     fi
2288   ;;
2289 esac
2290
2291 # Get an absolute path to the GCC top-level source directory
2292 holddir=`${PWDCMD-pwd}`
2293 cd $srcdir
2294 topdir=`${PWDCMD-pwd}`
2295 cd $holddir
2296
2297 # Conditionalize the makefile for this host machine.
2298 xmake_file=
2299 for f in ${host_xmake_file}
2300 do
2301         if test -f ${srcdir}/config/$f
2302         then
2303                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
2304         fi
2305 done
2306
2307 # Conditionalize the makefile for this target machine.
2308 tmake_file_=
2309 for f in ${tmake_file}
2310 do
2311         if test -f ${srcdir}/config/$f
2312         then
2313                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
2314         fi
2315 done
2316 tmake_file="${tmake_file_}${omp_device_property_tmake_file}"
2317
2318 out_object_file=`basename $out_file .cc`.o
2319 common_out_object_file=`basename $common_out_file .cc`.o
2320
2321 tm_file_list="options.h"
2322 tm_include_list="options.h insn-constants.h"
2323 for f in $tm_file; do
2324   case $f in
2325     ./* )
2326        f=`echo $f | sed 's/^..//'`
2327        tm_file_list="${tm_file_list} $f"
2328        tm_include_list="${tm_include_list} $f"
2329        ;;
2330     defaults.h )
2331        tm_file_list="${tm_file_list} \$(srcdir)/$f"
2332        tm_include_list="${tm_include_list} $f"
2333        ;;
2334     * )
2335        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
2336        tm_include_list="${tm_include_list} config/$f"
2337        ;;
2338   esac
2339 done
2340
2341 tm_p_file_list=
2342 tm_p_include_list=
2343 for f in $tm_p_file; do
2344   case $f in
2345     tm-preds.h )
2346        tm_p_file_list="${tm_p_file_list} $f"
2347        tm_p_include_list="${tm_p_include_list} $f"
2348        ;;
2349     * )
2350        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
2351        tm_p_include_list="${tm_p_include_list} config/$f"
2352   esac
2353 done
2354
2355 tm_d_file_list=
2356 tm_d_include_list="options.h insn-constants.h"
2357 for f in $tm_d_file; do
2358   case $f in
2359     defaults.h )
2360        tm_d_file_list="${tm_d_file_list} \$(srcdir)/$f"
2361        tm_d_include_list="${tm_d_include_list} $f"
2362        ;;
2363     * )
2364        tm_d_file_list="${tm_d_file_list} \$(srcdir)/config/$f"
2365        tm_d_include_list="${tm_d_include_list} config/$f"
2366        ;;
2367   esac
2368 done
2369
2370 xm_file_list=
2371 xm_include_list=
2372 for f in $xm_file; do
2373   case $f in
2374     ansidecl.h )
2375        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
2376        xm_include_list="${xm_include_list} $f"
2377        ;;
2378     auto-host.h )
2379        xm_file_list="${xm_file_list} $f"
2380        xm_include_list="${xm_include_list} $f"
2381        ;;
2382     * )
2383        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
2384        xm_include_list="${xm_include_list} config/$f"
2385        ;;
2386   esac
2387 done
2388
2389 host_xm_file_list=
2390 host_xm_include_list=
2391 for f in $host_xm_file; do
2392   case $f in
2393     ansidecl.h )
2394        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
2395        host_xm_include_list="${host_xm_include_list} $f"
2396        ;;
2397     auto-host.h )
2398        host_xm_file_list="${host_xm_file_list} $f"
2399        host_xm_include_list="${host_xm_include_list} $f"
2400        ;;
2401     * )
2402        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
2403        host_xm_include_list="${host_xm_include_list} config/$f"
2404        ;;
2405   esac
2406 done
2407
2408 build_xm_file_list=
2409 for f in $build_xm_file; do
2410   case $f in
2411     ansidecl.h )
2412        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
2413        build_xm_include_list="${build_xm_include_list} $f"
2414        ;;
2415     auto-build.h | auto-host.h )
2416        build_xm_file_list="${build_xm_file_list} $f"
2417        build_xm_include_list="${build_xm_include_list} $f"
2418        ;;
2419     * )
2420        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
2421        build_xm_include_list="${build_xm_include_list} config/$f"
2422        ;;
2423   esac
2424 done
2425
2426 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
2427 # cross-compiler which does not use the native headers and libraries.
2428 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
2429 CROSS=                                          AC_SUBST(CROSS)
2430 ALL=all.internal                                AC_SUBST(ALL)
2431 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
2432 BUILD_SYSTEM_HEADER_DIR=$SYSTEM_HEADER_DIR      AC_SUBST(BUILD_SYSTEM_HEADER_DIR)
2433
2434 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x ||
2435    test x$build != x$host || test "x$with_build_sysroot" != x; then
2436   if test "x$with_build_sysroot" != x; then
2437     BUILD_SYSTEM_HEADER_DIR=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
2438   else
2439     BUILD_SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
2440   fi
2441
2442   if test x$host != x$target
2443   then
2444     CROSS="-DCROSS_DIRECTORY_STRUCTURE"
2445     ALL=all.cross
2446     SYSTEM_HEADER_DIR=$BUILD_SYSTEM_HEADER_DIR
2447   elif test "x$TARGET_SYSTEM_ROOT" != x; then
2448     SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
2449   fi
2450
2451   if test "x$with_build_sysroot" != "x"; then
2452     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
2453   elif test "x$with_sysroot" = x; then
2454     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
2455   elif test "x$with_sysroot" = xyes; then
2456     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
2457   else
2458     target_header_dir="${with_sysroot}${native_system_header_dir}"
2459   fi
2460 else
2461   target_header_dir=${native_system_header_dir}
2462 fi
2463
2464 # If this is a cross-compiler that does not
2465 # have its own set of headers then define
2466 # inhibit_libc
2467
2468 # If this is using newlib, without having the headers available now,
2469 # then define inhibit_libc in LIBGCC2_CFLAGS.
2470 # This prevents libgcc2 from containing any code which requires libc
2471 # support.
2472 : ${inhibit_libc=false}
2473 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
2474        test x$with_newlib = xyes ; } &&
2475      { test "x$with_headers" = xno || test ! -f "$target_header_dir/stdio.h"; } ; then
2476        inhibit_libc=true
2477 fi
2478 AC_SUBST(inhibit_libc)
2479
2480 # When building gcc with a cross-compiler, we need to adjust things so
2481 # that the generator programs are still built with the native compiler.
2482 # Also, we cannot run fixincludes.
2483
2484 # These are the normal (build=host) settings:
2485 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
2486 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
2487 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
2488 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
2489 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
2490 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
2491
2492 # And these apply if build != host, or we are generating coverage data
2493 if test x$build != x$host || test "x$coverage_flags" != x
2494 then
2495     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS-$@) $(CFLAGS_FOR_BUILD)'
2496     BUILD_CXXFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS-$@) $(CXXFLAGS_FOR_BUILD)'
2497     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
2498 fi
2499
2500
2501 if test x$enable_fixincludes = xno;
2502 then
2503     STMP_FIXINC=''
2504 fi
2505
2506 # Expand extra_headers to include complete path.
2507 # This substitutes for lots of t-* files.
2508 extra_headers_list=
2509 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
2510 for file in ${extra_headers} ; do
2511   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
2512 done
2513
2514 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
2515 if test x"$use_gcc_tgmath" = xyes
2516 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
2517 fi
2518
2519 # Define collect2 in Makefile.
2520 case $host_can_use_collect2 in
2521   no) collect2= ;;
2522   *) collect2='collect2$(exeext)' ;;
2523 esac
2524 AC_SUBST([collect2])
2525
2526 # Add a definition of USE_COLLECT2 if system wants one.
2527 case $use_collect2 in
2528   no) use_collect2= ;;
2529   "") ;;
2530   *)
2531     host_xm_defines="${host_xm_defines} USE_COLLECT2"
2532     xm_defines="${xm_defines} USE_COLLECT2"
2533     case $host_can_use_collect2 in
2534       no)
2535         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
2536         ;;
2537     esac
2538     ;;
2539 esac
2540
2541 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
2542 [Define to the name of the LTO plugin DSO that must be
2543   passed to the linker's -plugin=LIB option.])
2544
2545 # ---------------------------
2546 # Assembler & linker features
2547 # ---------------------------
2548
2549 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
2550 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
2551 # However when ld-new is first executed from the build tree, libtool will
2552 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
2553 # to the build tree.  While doing this we need to use the previous-stage
2554 # linker, or we have an infinite loop.  The presence of a shell script as
2555 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
2556 # the gcc/collect-ld script.  So we need to know how libtool works, or
2557 # exec-tool will fail.
2558
2559 m4_defun([_LT_CONFIG_COMMANDS], [])
2560 AC_PROG_LIBTOOL
2561 AC_SUBST(objdir)
2562 AC_SUBST(enable_fast_install)
2563
2564 # Identify the assembler which will work hand-in-glove with the newly
2565 # built GCC, so that we can examine its features.  This is the assembler
2566 # which will be driven by the driver program.
2567 #
2568 # If build != host, and we aren't building gas in-tree, we identify a
2569 # build->target assembler and hope that it will have the same features
2570 # as the host->target assembler we'll be using.
2571 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
2572
2573 m4_pattern_allow([AS_FOR_TARGET])dnl
2574 AS_VAR_SET_IF(gcc_cv_as,, [
2575 if test -x "$DEFAULT_ASSEMBLER"; then
2576         gcc_cv_as="$DEFAULT_ASSEMBLER"
2577 elif test -f $gcc_cv_as_gas_srcdir/configure.ac \
2578      && test -f ../gas/Makefile \
2579      && test x$build = x$host; then
2580         gcc_cv_as=../gas/as-new$build_exeext
2581 elif test -x as$build_exeext; then
2582         # Build using assembler in the current directory.
2583         gcc_cv_as=./as$build_exeext
2584 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
2585         gcc_cv_as="$AS_FOR_TARGET"
2586 else
2587         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
2588 fi])
2589
2590 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
2591 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
2592 case "$ORIGINAL_AS_FOR_TARGET" in
2593   ./as | ./as$build_exeext) ;;
2594   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
2595 esac
2596
2597 default_ld=
2598 AC_ARG_ENABLE(ld,
2599 [[  --enable-ld[=ARG]       build ld [ARG={default,yes,no}]]],
2600 [case "${enableval}" in
2601  no)
2602    default_ld=ld.gold
2603    ;;
2604  esac])
2605
2606 install_gold_as_default=no
2607 AC_ARG_ENABLE(gold,
2608 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
2609 [case "${enableval}" in
2610  default)
2611    install_gold_as_default=yes
2612    ;;
2613  yes)
2614    if test x${default_ld} != x; then
2615      install_gold_as_default=yes
2616    fi
2617    ;;
2618  no)
2619    ;;
2620  *)
2621    AC_MSG_ERROR([invalid --enable-gold argument])
2622    ;;
2623  esac])
2624
2625 # Identify the linker which will work hand-in-glove with the newly
2626 # built GCC, so that we can examine its features.  This is the linker
2627 # which will be driven by the driver program.
2628 #
2629 # If build != host, and we aren't building gas in-tree, we identify a
2630 # build->target linker and hope that it will have the same features
2631 # as the host->target linker we'll be using.
2632 gcc_cv_gld_major_version=
2633 gcc_cv_gld_minor_version=
2634 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
2635 gcc_cv_ld_gold_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gold
2636 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
2637
2638 AS_VAR_SET_IF(gcc_cv_ld,, [
2639 if test -x "$DEFAULT_LINKER"; then
2640         gcc_cv_ld="$DEFAULT_LINKER"
2641 elif test $install_gold_as_default = yes \
2642      && test -f $gcc_cv_ld_gold_srcdir/configure.ac \
2643      && test -f ../gold/Makefile \
2644      && test x$build = x$host; then
2645         gcc_cv_ld=../gold/ld-new$build_exeext
2646 elif test -f $gcc_cv_ld_gld_srcdir/configure.ac \
2647      && test -f ../ld/Makefile \
2648      && test x$build = x$host; then
2649         gcc_cv_ld=../ld/ld-new$build_exeext
2650 elif test -x collect-ld$build_exeext; then
2651         # Build using linker in the current directory.
2652         gcc_cv_ld=./collect-ld$build_exeext
2653 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
2654         gcc_cv_ld="$LD_FOR_TARGET"
2655 else
2656         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2657 fi])
2658
2659 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2660 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2661 # if the PLUGIN_LD is set ld-new, just have it as ld
2662 # as that is the installed named.
2663 if test x$PLUGIN_LD_SUFFIX = xld-new \
2664    || test x$PLUGIN_LD_SUFFIX = xcollect-ld ; then
2665   PLUGIN_LD_SUFFIX=ld
2666 fi
2667 AC_ARG_WITH(plugin-ld,
2668 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2669 [if test x"$withval" != x; then
2670    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2671    PLUGIN_LD_SUFFIX="$withval"
2672  fi])
2673 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2674 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2675
2676 # Check to see if we are using gold instead of ld
2677 AC_MSG_CHECKING(whether we are using gold)
2678 ld_is_gold=no
2679 if test x$gcc_cv_ld != x; then
2680   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2681      | grep "GNU gold" > /dev/null; then
2682     ld_is_gold=yes
2683   fi
2684 fi
2685 AC_MSG_RESULT($ld_is_gold)
2686
2687 # Check to see if we are using mold instead of ld
2688 AC_MSG_CHECKING(whether we are using mold)
2689 ld_is_mold=no
2690 if test x$gcc_cv_ld != x; then
2691   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2692      | grep "mold" > /dev/null; then
2693     ld_is_mold=yes
2694   fi
2695 fi
2696 AC_MSG_RESULT($ld_is_mold)
2697
2698
2699 AC_MSG_CHECKING(gold linker with split stack support as non default)
2700 # Check to see if default ld is not gold, but gold is
2701 # available and has support for split stack.  If gcc was configured
2702 # with gold then no checking is done.
2703 #
2704 if test x$ld_is_gold = xno && which ${gcc_cv_ld}.gold >/dev/null 2>&1; then
2705
2706 # For platforms other than powerpc64*, enable as appropriate.
2707
2708   gold_non_default=no
2709   ld_gold=`which ${gcc_cv_ld}.gold`
2710 # Make sure this gold has minimal split stack support
2711   if $ld_gold --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
2712     ld_vers=`$ld_gold --version | sed 1q`
2713     gold_vers=`echo $ld_vers | sed -n \
2714           -e 's,^[[^)]]*[[  ]]\([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*[[^)]]*\)) .*$,\1,p'`
2715     case $target in
2716 # check that the gold version contains the complete split stack support
2717 # on powerpc64 big and little endian
2718       powerpc64*-*-*)
2719         case "$gold_vers" in
2720           2.25.[[1-9]]*|2.2[[6-9]][[.0-9]]*|2.[[3-9]][[.0-9]]*|[[3-9]].[[.0-9]]*) gold_non_default=yes
2721           ;;
2722           *) gold_non_default=no
2723           ;;
2724         esac
2725         ;;
2726     esac
2727   fi
2728   if test $gold_non_default = yes; then
2729     AC_DEFINE(HAVE_GOLD_NON_DEFAULT_SPLIT_STACK, 1,
2730             [Define if the gold linker supports split stack and is available as a non-default])
2731   fi
2732 fi
2733 AC_MSG_RESULT($gold_non_default)
2734
2735 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2736 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2737 case "$ORIGINAL_LD_FOR_TARGET" in
2738   ./collect-ld | ./collect-ld$build_exeext) ;;
2739   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2740 esac
2741
2742 AC_MSG_CHECKING(what linker to use)
2743 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2744    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2745         # Single tree build which includes ld.  We want to prefer it
2746         # over whatever linker top-level may have detected, since
2747         # we'll use what we're building after installation anyway.
2748         AC_MSG_RESULT(newly built ld)
2749         in_tree_ld=yes
2750         in_tree_ld_is_elf=no
2751         if (grep 'EMUL = .*elf' ../ld/Makefile \
2752             || grep 'EMUL = .*linux' ../ld/Makefile \
2753             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2754           in_tree_ld_is_elf=yes
2755         elif test "$ld_is_gold" = yes; then
2756           in_tree_ld_is_elf=yes
2757         fi
2758         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.ac $gcc_cv_ld_gld_srcdir/Makefile.in
2759         do
2760 changequote(,)dnl
2761                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*VERSION=[^0-9A-Za-z_]*\([0-9]*\.[0-9]*.*\)/VERSION=\1/p' < $f`
2762                 if test x$gcc_cv_gld_version != x; then
2763                         break
2764                 fi
2765         done
2766         case $gcc_cv_gld_version in
2767           VERSION=[0-9]*) ;;
2768 changequote([,])dnl
2769           *) AC_MSG_ERROR([[cannot find version of in-tree linker]]) ;;
2770 changequote(,)dnl
2771         esac
2772         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2773         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2774 changequote([,])dnl
2775         ORIGINAL_LD_BFD_FOR_TARGET=../ld/ld-new$build_exeext
2776         ORIGINAL_LD_GOLD_FOR_TARGET=../gold/ld-new$build_exeext
2777 else
2778         AC_MSG_RESULT($gcc_cv_ld)
2779         in_tree_ld=no
2780         gcc_cvs_ld_program=`dirname $gcc_cv_ld`/`basename $gcc_cv_ld $host_exeext`
2781         ORIGINAL_LD_BFD_FOR_TARGET=${gcc_cvs_ld_program}.bfd$host_exeext
2782         ORIGINAL_LD_GOLD_FOR_TARGET=${gcc_cvs_ld_program}.gold$host_exeext
2783 fi
2784
2785 AC_SUBST(ORIGINAL_LD_BFD_FOR_TARGET)
2786 AC_SUBST(ORIGINAL_LD_GOLD_FOR_TARGET)
2787
2788 # Figure out what nm we will be using.
2789 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2790 AS_VAR_SET_IF(gcc_cv_nm,, [
2791 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2792      && test -f ../binutils/Makefile \
2793      && test x$build = x$host; then
2794         gcc_cv_nm=../binutils/nm-new$build_exeext
2795 elif test -x nm$build_exeext; then
2796         gcc_cv_nm=./nm$build_exeext
2797 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2798         gcc_cv_nm="$NM_FOR_TARGET"
2799 else
2800         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2801 fi])
2802
2803 AC_MSG_CHECKING(what nm to use)
2804 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2805         # Single tree build which includes binutils.
2806         AC_MSG_RESULT(newly built nm)
2807         in_tree_nm=yes
2808 else
2809         AC_MSG_RESULT($gcc_cv_nm)
2810         in_tree_nm=no
2811 fi
2812
2813 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2814 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2815 case "$ORIGINAL_NM_FOR_TARGET" in
2816   ./nm | ./nm$build_exeext) ;;
2817   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2818 esac
2819
2820
2821 # Figure out what objdump we will be using.
2822 AS_VAR_SET_IF(gcc_cv_objdump,, [
2823 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2824      && test -f ../binutils/Makefile \
2825      && test x$build = x$host; then
2826         # Single tree build which includes binutils.
2827         gcc_cv_objdump=../binutils/objdump$build_exeext
2828 elif test -x objdump$build_exeext; then
2829         gcc_cv_objdump=./objdump$build_exeext
2830 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2831         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2832 else
2833         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2834 fi])
2835
2836 AC_MSG_CHECKING(what objdump to use)
2837 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2838         # Single tree build which includes binutils.
2839         AC_MSG_RESULT(newly built objdump)
2840 elif test x$gcc_cv_objdump = x; then
2841         AC_MSG_RESULT(not found)
2842 else
2843         AC_MSG_RESULT($gcc_cv_objdump)
2844 fi
2845
2846 # Figure out what readelf we will be using.
2847 AS_VAR_SET_IF(gcc_cv_readelf,, [
2848 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2849      && test -f ../binutils/Makefile \
2850      && test x$build = x$host; then
2851         # Single tree build which includes binutils.
2852         gcc_cv_readelf=../binutils/readelf$build_exeext
2853 elif test -x readelf$build_exeext; then
2854         gcc_cv_readelf=./readelf$build_exeext
2855 elif ( set dummy $READELF_FOR_TARGET; test -x $[2] ); then
2856         gcc_cv_readelf="$READELF_FOR_TARGET"
2857 else
2858         AC_PATH_PROG(gcc_cv_readelf, $READELF_FOR_TARGET)
2859 fi])
2860
2861 AC_MSG_CHECKING(what readelf to use)
2862 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2863         # Single tree build which includes binutils.
2864         AC_MSG_RESULT(newly built readelf)
2865 elif test x$gcc_cv_readelf = x; then
2866         AC_MSG_RESULT(not found)
2867 else
2868         AC_MSG_RESULT($gcc_cv_readelf)
2869 fi
2870
2871 # Figure out what otool we will be using.
2872 AS_VAR_SET_IF(gcc_cv_otool,, [
2873 if test -x otool$build_exeext; then
2874         gcc_cv_otool=./otool$build_exeext
2875 elif ( set dummy $OTOOL_FOR_TARGET; test -x $[2] ); then
2876         gcc_cv_otool="$OTOOL_FOR_TARGET"
2877 else
2878         AC_PATH_PROG(gcc_cv_otool, $OTOOL_FOR_TARGET)
2879 fi])
2880
2881 AC_MSG_CHECKING(what otool to use)
2882 if test x$gcc_cv_otool = x; then
2883         AC_MSG_RESULT(not found)
2884 else
2885         AC_MSG_RESULT($gcc_cv_otool)
2886 fi
2887
2888 # Figure out the dsymutil we will use.
2889 AS_VAR_SET_IF(gcc_cv_dsymutil,, [
2890 if test -x "$DEFAULT_DSYMUTIL"; then
2891     gcc_cv_dsymutil="$DEFAULT_DSYMUTIL"
2892 elif test -x dsymutil$build_exeext; then
2893     gcc_cv_dsymutil=./dsymutil$build_exeext
2894 elif ( set dummy $DSYMUTIL_FOR_TARGET; test -x $[2] ); then
2895     gcc_cv_dsymutil=$DSYMUTIL_FOR_TARGET
2896 elif ( set dummy $DSYMUTIL; test -x $[2] ); then
2897     gcc_cv_dsymutil=$DSYMUTIL
2898 else
2899     AC_PATH_PROG(gcc_cv_dsymutil, $DSYMUTIL_FOR_TARGET)
2900 fi])
2901
2902 ORIGINAL_DSYMUTIL_FOR_TARGET=$gcc_cv_dsymutil
2903 AC_SUBST(ORIGINAL_DSYMUTIL_FOR_TARGET)
2904 case "$ORIGINAL_DSYMUTIL_FOR_TARGET" in
2905   ./dsymutil | ./dsymutil$build_exeext) ;;
2906   *) AC_CONFIG_FILES(dsymutil:exec-tool.in, [chmod +x dsymutil]) ;;
2907 esac
2908
2909 # Figure out what assembler alignment features are present.
2910 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,,
2911 [.balign 4
2912 .p2align 2],,
2913 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2914   [Define if your assembler supports .balign and .p2align.])])
2915
2916 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,,
2917  [.p2align 4,,7],,
2918 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2919   [Define if your assembler supports specifying the maximum number
2920    of bytes to skip when using the GAS .p2align command.])])
2921
2922 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,,
2923  [.literal16],,
2924 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2925   [Define if your assembler supports .literal16.])])
2926
2927 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,,
2928  [conftest_label1: .word 0
2929 .subsection -1
2930 conftest_label2: .word 0
2931 .previous],
2932  [if test x$gcc_cv_nm != x; then
2933     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2934     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2935     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2936     then :
2937     else gcc_cv_as_subsection_m1=yes
2938     fi
2939     rm -f conftest.nm1 conftest.nm2
2940   fi],
2941  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2942   [Define if your assembler supports .subsection and .subsection -1 starts
2943    emitting at the beginning of your section.])])
2944
2945 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,,
2946  [      .weak foobar],,
2947 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2948
2949 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,,
2950  [      .weakref foobar, barfnot],,
2951 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2952
2953 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,,
2954  [      .SPACE $TEXT$
2955         .NSUBSPA $CODE$,COMDAT],,
2956 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2957
2958 # .hidden needs to be supported in both the assembler and the linker,
2959 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2960 # This is irritatingly difficult to feature test for; we have to check the
2961 # date string after the version number.  If we've got an in-tree
2962 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2963 # to be safe.
2964 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2965 case "${target}" in
2966   *-*-aix*)
2967     conftest_s='        .globl foobar,hidden'
2968     ;;
2969   *)
2970     conftest_s='        .hidden foobar
2971 foobar:'
2972     ;;
2973 esac
2974 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,, [$conftest_s])
2975 case "${target}" in
2976   *-*-darwin*)
2977     # Darwin as has some visibility support, though with a different syntax.
2978     gcc_cv_as_hidden=yes
2979     ;;
2980 esac
2981
2982 # gnu_indirect_function type is an extension proposed at
2983 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2984 # selection of function implementation
2985 AC_ARG_ENABLE(gnu-indirect-function,
2986  [AS_HELP_STRING([--enable-gnu-indirect-function],
2987                  [enable the use of the @gnu_indirect_function to glibc systems])],
2988  [case $enable_gnu_indirect_function in
2989     yes | no) ;;
2990     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2991 Valid choices are 'yes' and 'no'.]) ;;
2992   esac],
2993  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2994
2995 case "${target}" in
2996   riscv*-*-linux*)
2997     AC_MSG_CHECKING(linker ifunc IRELATIVE support)
2998     cat > conftest.s <<EOF
2999         .text
3000         .type   foo_resolver, @function
3001 foo_resolver:
3002         ret
3003         .size   foo_resolver, .-foo_resolver
3004
3005         .globl  foo
3006         .type   foo, %gnu_indirect_function
3007         .set    foo, foo_resolver
3008
3009         .globl  bar
3010         .type   bar, @function
3011 bar:
3012         call    foo
3013         ret
3014         .size   bar, .-bar
3015 EOF
3016     if test x$gcc_cv_as != x \
3017        && test x$gcc_cv_ld != x \
3018        && test x$gcc_cv_readelf != x \
3019        && $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
3020        && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1 \
3021        && $gcc_cv_readelf --relocs --wide conftest \
3022           | grep R_RISCV_IRELATIVE > /dev/null 2>&1; then
3023       enable_gnu_indirect_function=yes
3024     fi
3025     rm -f conftest conftest.o conftest.s
3026     AC_MSG_RESULT($enable_gnu_indirect_function)
3027     ;;
3028 esac
3029
3030 gif=`if test x$enable_gnu_indirect_function = xyes; then echo 1; else echo 0; fi`
3031 AC_DEFINE_UNQUOTED(HAVE_GNU_INDIRECT_FUNCTION, $gif,
3032 [Define if your system supports gnu indirect functions.])
3033
3034
3035 changequote(,)dnl
3036 if test $in_tree_ld != yes ; then
3037   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
3038   if echo "$ld_ver" | grep GNU > /dev/null; then
3039     if test x"$ld_is_gold" = xyes; then
3040       # GNU gold --version looks like this:
3041       #
3042       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
3043       #
3044       # We extract the binutils version which is more familiar and specific
3045       # than the gold version.
3046       ld_vers=`echo $ld_ver | sed -n \
3047           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3048     else
3049       # GNU ld --version looks like this:
3050       #
3051       # GNU ld (GNU Binutils) 2.21.51.20110225
3052       ld_vers=`echo $ld_ver | sed -n \
3053           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3054     fi
3055     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)\(-*\)\([01][0-9]\)\2\([0-3][0-9]\).*$,\1\3\4,p'`
3056     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3057     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3058     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
3059   else
3060     case "${target}" in
3061       *-*-solaris2*)
3062         # Solaris 2 ld -V output looks like this for a regular version:
3063         #
3064         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
3065         #
3066         # but test versions add stuff at the end:
3067         #
3068         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
3069         #
3070         # ld and ld.so.1 are guaranteed to be updated in lockstep, so ld version
3071         # numbers can be used in ld.so.1 feature checks even if a different
3072         # linker is configured.
3073         ld_ver=`$gcc_cv_ld -V 2>&1`
3074         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
3075           ld_vers=`echo $ld_ver | sed -n \
3076             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
3077           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3078           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3079         fi
3080         ;;
3081     esac
3082   fi
3083 fi
3084 changequote([,])dnl
3085
3086 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
3087 [[if test $in_tree_ld = yes ; then
3088   gcc_cv_ld_hidden=no
3089   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
3090      && test $in_tree_ld_is_elf = yes; then
3091      gcc_cv_ld_hidden=yes
3092   fi
3093 else
3094   gcc_cv_ld_hidden=yes
3095   if test x"$ld_is_gold" = xyes; then
3096     :
3097   elif test x"$ld_is_mold" = xyes; then
3098     :
3099   elif echo "$ld_ver" | grep GNU > /dev/null; then
3100     if test 0"$ld_date" -lt 20020404; then
3101       if test -n "$ld_date"; then
3102         # If there was date string, but was earlier than 2002-04-04, fail
3103         gcc_cv_ld_hidden=no
3104       elif test -z "$ld_vers"; then
3105         # If there was no date string nor ld version number, something is wrong
3106         gcc_cv_ld_hidden=no
3107       else
3108         test -z "$ld_vers_patch" && ld_vers_patch=0
3109         if test "$ld_vers_major" -lt 2; then
3110           gcc_cv_ld_hidden=no
3111         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
3112           gcc_cv_ld_hidden="no"
3113         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
3114           gcc_cv_ld_hidden=no
3115         fi
3116       fi
3117     fi
3118   else
3119     case "${target}" in
3120       *-*-aix[789]*)
3121         gcc_cv_ld_hidden=yes
3122         ;;
3123       *-*-darwin*)
3124         # Darwin ld has some visibility support.
3125         gcc_cv_ld_hidden=yes
3126         ;;
3127       hppa64*-*-hpux* | ia64*-*-hpux*)
3128         gcc_cv_ld_hidden=yes
3129         ;;
3130       *-*-solaris2*)
3131         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
3132         # .symbolic was only added in Solaris 9 12/02.
3133         gcc_cv_ld_hidden=yes
3134         ;;
3135       *)
3136         gcc_cv_ld_hidden=no
3137         ;;
3138     esac
3139   fi
3140 fi]])
3141 libgcc_visibility=no
3142 AC_SUBST(libgcc_visibility)
3143 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
3144 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
3145   libgcc_visibility=yes
3146   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
3147   [Define if your assembler and linker support .hidden.])
3148 fi
3149
3150 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3151 gcc_cv_ld_ro_rw_mix=unknown
3152 if test $in_tree_ld = yes ; then
3153   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3154      && test $in_tree_ld_is_elf = yes; then
3155     gcc_cv_ld_ro_rw_mix=read-write
3156   fi
3157 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3158   echo '.section myfoosect, "a"' > conftest1.s
3159   echo '.section myfoosect, "aw"' > conftest2.s
3160   echo '.byte 1' >> conftest2.s
3161   echo '.section myfoosect, "a"' > conftest3.s
3162   echo '.byte 0' >> conftest3.s
3163   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3164      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3165      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3166      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3167         conftest2.o conftest3.o > /dev/null 2>&1; then
3168     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3169                          | sed -e '/myfoosect/!d' -e N`
3170     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3171       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3172         gcc_cv_ld_ro_rw_mix=read-only
3173       else
3174         gcc_cv_ld_ro_rw_mix=read-write
3175       fi
3176     fi
3177   fi
3178 changequote(,)dnl
3179   rm -f conftest.* conftest[123].*
3180 changequote([,])dnl
3181 fi
3182 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3183         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3184   [Define if your linker links a mix of read-only
3185    and read-write sections into a read-write section.])
3186 fi
3187 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3188
3189 gcc_AC_INITFINI_ARRAY
3190
3191 # Check if we have .[us]leb128, and support symbol arithmetic with it.
3192 # Older versions of GAS and some non-GNU assemblers, have a bugs handling
3193 # these directives, even when they appear to accept them.
3194 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,,
3195 [       .data
3196         .uleb128 L2 - L1
3197 L1:
3198         .uleb128 1280
3199         .sleb128 -1010
3200 L2:
3201         .uleb128 0x8000000000000000
3202 ],
3203 [[
3204 if test "x$gcc_cv_objdump" != x; then
3205   if $gcc_cv_objdump -s conftest.o 2>/dev/null \
3206      | grep '04800a8e 78808080 80808080 808001' >/dev/null; then
3207     gcc_cv_as_leb128=yes
3208   fi
3209 elif test "x$gcc_cv_otool" != x; then
3210   if $gcc_cv_otool -d conftest.o 2>/dev/null \
3211      | grep '04 80 0a 8e 78 80 80 80 80 80 80 80 80 80 01' >/dev/null; then
3212     gcc_cv_as_leb128=yes
3213   fi
3214 else
3215   # play safe, assume the assembler is broken.
3216   :
3217 fi
3218 ]],
3219  [AC_DEFINE(HAVE_AS_LEB128, 1,
3220    [Define if your assembler supports .sleb128 and .uleb128.])],
3221  [AC_DEFINE(HAVE_AS_LEB128, 0,
3222    [Define if your assembler supports .sleb128 and .uleb128.])])
3223
3224 # Determine if an .eh_frame section is read-only.
3225 gcc_fn_eh_frame_ro () {
3226   $gcc_cv_as $1 -o conftest.o conftest.s > /dev/null 2>&1 && \
3227     $gcc_cv_objdump -h conftest.o 2>/dev/null | \
3228     sed -e '/.eh_frame/!d' -e N | grep READONLY > /dev/null
3229 }
3230
3231 # Check if we have assembler support for unwind directives.
3232 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,,
3233 [       .text
3234         .cfi_startproc
3235         .cfi_offset 0, 0
3236         .cfi_same_value 1
3237         .cfi_def_cfa 1, 2
3238         .cfi_escape 1, 2, 3, 4, 5
3239         .cfi_endproc],
3240 [case "$target" in
3241   *-*-solaris*)
3242     # If the linker used on Solaris (like Sun ld) isn't capable of merging
3243     # read-only and read-write sections, we need to make sure that the
3244     # assembler used emits read-write .eh_frame sections.
3245     if test "x$gcc_cv_ld_ro_rw_mix" = xread-write; then
3246       gcc_cv_as_cfi_directive=yes
3247     elif test "x$gcc_cv_objdump" = x; then
3248       # No objdump, err on the side of caution.
3249       gcc_cv_as_cfi_directive=no
3250     else
3251       if test x$gas = xyes; then
3252         as_32_opt="--32"
3253         as_64_opt="--64"
3254       else
3255         as_32_opt="-m32"
3256         as_64_opt="-m64"
3257       fi
3258       case "$target" in
3259         sparc*-*-solaris2.*)
3260           # On Solaris/SPARC, .eh_frame sections should always be read-write.
3261           if gcc_fn_eh_frame_ro $as_32_opt \
3262              || gcc_fn_eh_frame_ro $as_64_opt; then
3263             gcc_cv_as_cfi_directive=no
3264           else
3265             gcc_cv_as_cfi_directive=yes
3266           fi
3267           ;;
3268         i?86-*-solaris2.* | x86_64-*-solaris2.*)
3269           # On Solaris/x86, make sure that GCC and assembler agree on using
3270           # read-only .eh_frame sections for 64-bit.
3271           if gcc_fn_eh_frame_ro $as_32_opt; then
3272             gcc_cv_as_cfi_directive=no
3273           elif gcc_fn_eh_frame_ro $as_64_opt; then
3274             gcc_cv_as_cfi_directive=yes
3275           else
3276             gcc_cv_as_cfi_directive=no
3277           fi
3278           ;;
3279       esac
3280     fi
3281     ;;
3282   *-*-*)
3283     gcc_cv_as_cfi_directive=yes
3284     ;;
3285 esac])
3286 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
3287 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,,
3288 [       .text
3289         .cfi_startproc
3290         .cfi_adjust_cfa_offset 64
3291         .skip 75040, 0
3292         .cfi_adjust_cfa_offset 128
3293         .cfi_endproc],
3294 [[
3295 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
3296     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
3297    gcc_cv_as_cfi_advance_working=yes
3298 fi
3299 ]])
3300 else
3301   # no objdump, err on the side of caution
3302   gcc_cv_as_cfi_advance_working=no
3303 fi
3304 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
3305 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
3306   [`if test $gcc_cv_as_cfi_directive = yes \
3307        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
3308   [Define 0/1 if your assembler supports CFI directives.])
3309
3310 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
3311 gcc_GAS_CHECK_FEATURE([cfi personality directive],
3312   gcc_cv_as_cfi_personality_directive,,
3313 [       .text
3314         .cfi_startproc
3315         .cfi_personality 0, symbol
3316         .cfi_endproc])
3317 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
3318   [`if test $gcc_cv_as_cfi_personality_directive = yes; then echo 1; else echo 0; fi`],
3319   [Define 0/1 if your assembler supports .cfi_personality.])
3320
3321 gcc_GAS_CHECK_FEATURE([cfi sections directive],
3322   gcc_cv_as_cfi_sections_directive,,
3323 [       .text
3324         .cfi_sections .debug_frame, .eh_frame
3325         .cfi_startproc
3326         .cfi_endproc],
3327 [case $target_os in
3328   win32 | pe | cygwin* | mingw32*)
3329     # Need to check that we generated the correct relocation for the
3330     # .debug_frame section.  This was fixed for binutils 2.21.
3331     gcc_cv_as_cfi_sections_directive=no
3332     if test "x$gcc_cv_objdump" != x; then
3333      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
3334         grep secrel > /dev/null; then
3335       gcc_cv_as_cfi_sections_directive=yes
3336      fi
3337     fi
3338     ;;
3339   *)
3340     gcc_cv_as_cfi_sections_directive=yes
3341     ;;
3342 esac])
3343 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
3344 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
3345   [`if test $gcc_cv_as_cfi_sections_directive = yes; then echo 1; else echo 0; fi`],
3346   [Define 0/1 if your assembler supports .cfi_sections.])
3347
3348 # GAS versions up to and including 2.11.0 may mis-optimize
3349 # .eh_frame data.
3350 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,,
3351 [       .text
3352 .LFB1:
3353         .4byte  0
3354 .L1:
3355         .4byte  0
3356 .LFE1:
3357         .section        .eh_frame,"aw",@progbits
3358 __FRAME_BEGIN__:
3359         .4byte  .LECIE1-.LSCIE1
3360 .LSCIE1:
3361         .4byte  0x0
3362         .byte   0x1
3363         .ascii "z\0"
3364         .byte   0x1
3365         .byte   0x78
3366         .byte   0x1a
3367         .byte   0x0
3368         .byte   0x4
3369         .4byte  1
3370         .p2align 1
3371 .LECIE1:
3372 .LSFDE1:
3373         .4byte  .LEFDE1-.LASFDE1
3374 .LASFDE1:
3375         .4byte  .LASFDE1-__FRAME_BEGIN__
3376         .4byte  .LFB1
3377         .4byte  .LFE1-.LFB1
3378         .byte   0x4
3379         .4byte  .LFE1-.LFB1
3380         .byte   0x4
3381         .4byte  .L1-.LFB1
3382 .LEFDE1:],
3383 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
3384 cat > conftest.lit <<EOF
3385  0000 10000000 00000000 017a0001 781a0004  .........z..x...
3386  0010 01000000 12000000 18000000 00000000  ................
3387  0020 08000000 04080000 0044               .........D      @&t@
3388 EOF
3389 cat > conftest.big <<EOF
3390  0000 00000010 00000000 017a0001 781a0004  .........z..x...
3391  0010 00000001 00000012 00000018 00000000  ................
3392  0020 00000008 04000000 0844               .........D      @&t@
3393 EOF
3394   # If the assembler didn't choke, and we can objdump,
3395   # and we got the correct data, then succeed.
3396   # The text in the here-document typically retains its unix-style line
3397   # endings, while the output of objdump will use host line endings.
3398   # Therefore, use diff -b for the comparisons.
3399   if test x$gcc_cv_objdump != x \
3400   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
3401      | tail -3 > conftest.got \
3402   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
3403     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
3404   then
3405     gcc_cv_as_eh_frame=yes
3406   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
3407     gcc_cv_as_eh_frame=buggy
3408   else
3409     # Uh oh, what do we do now?
3410     gcc_cv_as_eh_frame=no
3411   fi])
3412
3413 if test $gcc_cv_as_eh_frame = buggy; then
3414   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
3415   [Define if your assembler mis-optimizes .eh_frame data.])
3416 fi
3417
3418 # Test if the assembler supports the section flag 'e' or #exclude for
3419 # specifying an excluded section.
3420 gcc_GAS_CHECK_FEATURE([section exclude flag], gcc_cv_as_section_exclude_e,
3421  [--fatal-warnings],
3422  [.section foo1,"e"
3423   .byte 0,0,0,0])
3424 if test $gcc_cv_as_section_exclude_e = no; then
3425   case "${target}" in
3426     # Solaris as uses #exclude instead.
3427     *-*-solaris2*)
3428       case "${target}" in
3429         sparc*-*-solaris2*)
3430           conftest_s='.section "foo1", #exclude'
3431           ;;
3432         i?86-*-solaris2* | x86_64-*-solaris2*)
3433           conftest_s='.section foo1, #exclude'
3434           ;;
3435       esac
3436       ;;
3437     esac
3438   gcc_GAS_CHECK_FEATURE([section exclude flag], gcc_cv_as_section_exclude_hash,,
3439     [$conftest_s
3440      .byte 0,0,0,0])
3441 fi
3442 AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
3443   [`if test $gcc_cv_as_section_exclude_e = yes || test $gcc_cv_as_section_exclude_hash = yes; then echo 1; else echo 0; fi`],
3444 [Define if your assembler supports specifying the exclude section flag.])
3445
3446 # Test if the assembler supports the section flag 'R' for specifying
3447 # section with SHF_GNU_RETAIN.
3448 case "${target}" in
3449   # Solaris may use GNU assembler with Solairs ld.  Even if GNU
3450   # assembler supports the section flag 'R', it doesn't mean that
3451   # Solairs ld supports it.
3452   *-*-solaris2*)
3453     gcc_cv_as_shf_gnu_retain=no
3454     ;;
3455   *)
3456     gcc_GAS_CHECK_FEATURE([section 'R' flag], gcc_cv_as_shf_gnu_retain,
3457       [--fatal-warnings],
3458       [.section .foo,"awR",%progbits
3459 .byte 0])
3460     ;;
3461 esac
3462 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_GNU_RETAIN,
3463   [`if test $gcc_cv_as_shf_gnu_retain = yes; then echo 1; else echo 0; fi`],
3464   [Define 0/1 if your assembler supports marking sections with SHF_GNU_RETAIN flag.])
3465
3466 # Test if the assembler supports the section flag 'o' for specifying
3467 # section with link-order.
3468 case "${target}" in
3469   # Solaris may use GNU assembler with Solairs ld.  Even if GNU
3470   # assembler supports the section flag 'o', it doesn't mean that
3471   # Solairs ld supports it.
3472   *-*-solaris2*)
3473     gcc_cv_as_section_link_order=no
3474     ;;
3475   *)
3476     gcc_GAS_CHECK_FEATURE([section 'o' flag], gcc_cv_as_section_link_order,
3477       [--fatal-warnings],
3478       [.section .foo,"a"
3479 .byte 0
3480 .section __patchable_function_entries,"awo",%progbits,.foo
3481 .byte 0])
3482     ;;
3483 esac
3484 AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_LINK_ORDER,
3485   [`if test $gcc_cv_as_section_link_order = yes; then echo 1; else echo 0; fi`],
3486   [Define 0/1 if your assembler supports 'o' flag in .section directive.])
3487
3488 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
3489  [--fatal-warnings],
3490  [.section .rodata.str, "aMS", @progbits, 1])
3491 if test $gcc_cv_as_shf_merge = no; then
3492   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
3493     [--fatal-warnings],
3494     [.section .rodata.str, "aMS", %progbits, 1])
3495 fi
3496 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
3497   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
3498 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
3499
3500 gcc_cv_ld_aligned_shf_merge=yes
3501 case "$target" in
3502   # SHF_MERGE support is broken in Solaris ld up to Solaris 11.3/SPARC for
3503   # alignment > 1.
3504   sparc*-*-solaris2.11*)
3505     if test x"$gnu_ld" = xno \
3506        && test "$ld_vers_major" -lt 2 && test "$ld_vers_minor" -lt 3159; then
3507       gcc_cv_ld_aligned_shf_merge=no
3508     fi
3509     ;;
3510 esac
3511 AC_DEFINE_UNQUOTED(HAVE_LD_ALIGNED_SHF_MERGE,
3512   [`if test $gcc_cv_ld_aligned_shf_merge = yes; then echo 1; else echo 0; fi`],
3513 [Define 0/1 if your linker supports the SHF_MERGE flag with section alignment > 1.])
3514
3515 gcc_GAS_CHECK_FEATURE([stabs directive], gcc_cv_as_stabs_directive,,
3516 [.stabs "gcc2_compiled.",60,0,0,0],,
3517 [AC_DEFINE(HAVE_AS_STABS_DIRECTIVE, 1,
3518   [Define if your assembler supports .stabs.])])
3519
3520 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
3521  gcc_cv_as_comdat_group,
3522  [--fatal-warnings],
3523  [.section .text,"axG",@progbits,.foo,comdat])
3524 if test $gcc_cv_as_comdat_group = yes; then
3525   gcc_cv_as_comdat_group_percent=no
3526   gcc_cv_as_comdat_group_group=no
3527 else
3528  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
3529    gcc_cv_as_comdat_group_percent,
3530    [--fatal-warnings],
3531    [.section .text,"axG",%progbits,.foo,comdat])
3532  if test $gcc_cv_as_comdat_group_percent = yes; then
3533    gcc_cv_as_comdat_group_group=no
3534  else
3535    case "${target}" in
3536      # Sun as uses a completely different syntax.
3537      *-*-solaris2*)
3538        case "${target}" in
3539          sparc*-*-solaris2*)
3540            conftest_s='
3541                .group foo,".text%foo",#comdat
3542                .section ".text%foo", #alloc,#execinstr,#progbits
3543                .globl foo
3544              foo:
3545              '
3546            ;;
3547          i?86-*-solaris2* | x86_64-*-solaris2*)
3548            conftest_s='
3549                .group foo,.text%foo,#comdat
3550                .section .text%foo, "ax", @progbits
3551                .globl  foo
3552              foo:
3553              '
3554            ;;
3555        esac
3556        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
3557          gcc_cv_as_comdat_group_group,
3558          , [$conftest_s])
3559        ;;
3560    esac
3561    if test -z "${gcc_cv_as_comdat_group_group+set}"; then
3562      gcc_cv_as_comdat_group_group=no
3563    fi
3564  fi
3565 fi
3566 if test x"$ld_is_gold" = xyes; then
3567   comdat_group=yes
3568 elif test x"$ld_is_mold" = xyes; then
3569   comdat_group=yes
3570 elif test $in_tree_ld = yes ; then
3571   comdat_group=no
3572   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3573      && test $in_tree_ld_is_elf = yes; then
3574      comdat_group=yes
3575   fi
3576 elif echo "$ld_ver" | grep GNU > /dev/null; then
3577   comdat_group=yes
3578   if test 0"$ld_date" -lt 20050308; then
3579     if test -n "$ld_date"; then
3580       # If there was date string, but was earlier than 2005-03-08, fail
3581       comdat_group=no
3582     elif test "$ld_vers_major" -lt 2; then
3583       comdat_group=no
3584     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
3585       comdat_group=no
3586     fi
3587   fi
3588 else
3589 changequote(,)dnl
3590   case "${target}" in
3591     *-*-solaris2.1[1-9]*)
3592       comdat_group=no
3593       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
3594       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
3595       # version 1.688.
3596       #
3597       # If using Sun as for COMDAT group as emitted by GCC, one needs at
3598       # least ld version 1.2267.
3599       if test "$ld_vers_major" -gt 1; then
3600         comdat_group=yes
3601       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
3602         comdat_group=yes
3603       elif test "$ld_vers_minor" -ge 2267; then
3604         comdat_group=yes
3605       fi
3606       ;;
3607     *)
3608       # Assume linkers other than GNU ld don't support COMDAT group.
3609       comdat_group=no
3610       ;;
3611   esac
3612 changequote([,])dnl
3613 fi
3614 # Allow overriding the automatic COMDAT group tests above.
3615 AC_ARG_ENABLE(comdat,
3616   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
3617   [comdat_group="$enable_comdat"])
3618 if test $comdat_group = no; then
3619   gcc_cv_as_comdat_group=no
3620   gcc_cv_as_comdat_group_percent=no
3621   gcc_cv_as_comdat_group_group=no
3622 fi
3623 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
3624   [`if test $gcc_cv_as_comdat_group = yes \
3625     || test $gcc_cv_as_comdat_group_percent = yes \
3626     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
3627 [Define 0/1 if your assembler and linker support COMDAT groups.])
3628
3629 # Restrict this test to Solaris/x86: other targets define this statically.
3630 case "${target}" in
3631   i?86-*-solaris2* | x86_64-*-solaris2*)
3632     AC_MSG_CHECKING(support for hidden thunks in linkonce sections)
3633     if test $in_tree_ld = yes || echo "$ld_ver" | grep GNU > /dev/null; then
3634       hidden_linkonce=yes
3635     else
3636       case "${target}" in
3637         # Full support for hidden thunks in linkonce sections only appeared in
3638         # Solaris 11/OpenSolaris.
3639         *-*-solaris2.1[[1-9]]*)
3640           hidden_linkonce=yes
3641           ;;
3642         *)
3643           hidden_linkonce=no
3644           ;;
3645       esac
3646     fi
3647     AC_MSG_RESULT($hidden_linkonce)
3648     AC_DEFINE_UNQUOTED(USE_HIDDEN_LINKONCE,
3649       [`if test $hidden_linkonce = yes; then echo 1; else echo 0; fi`],
3650     [Define 0/1 if your linker supports hidden thunks in linkonce sections.])
3651   ;;
3652 esac
3653
3654 gcc_GAS_CHECK_FEATURE([line table is_stmt support],
3655  gcc_cv_as_is_stmt,,
3656 [       .text
3657         .file 1 "conf.c"
3658         .loc 1 1 0 is_stmt 1],,
3659 [AC_DEFINE(HAVE_GAS_LOC_STMT, 1,
3660   [Define if your assembler supports the .loc is_stmt sub-directive.])])
3661
3662 gcc_GAS_CHECK_FEATURE([line table discriminator support],
3663  gcc_cv_as_discriminator,,
3664 [       .text
3665         .file 1 "conf.c"
3666         .loc 1 1 0 discriminator 1],,
3667 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
3668   [Define if your assembler supports the .loc discriminator sub-directive.])])
3669
3670 # Catch the newlib flag of the same name so we can gate GCC features on it.
3671 AC_ARG_ENABLE(newlib-nano-formatted-io,
3672 [AS_HELP_STRING([--enable-newlib-nano-formatted-io], [Use nano version
3673  formatted IO])],
3674 [case "${enableval}" in
3675   yes|no)
3676     ;;
3677   *)
3678     AC_MSG_ERROR([unknown newlib-nano-formatted-io setting $enableval])
3679     ;;
3680 esac], [])
3681
3682 # Thread-local storage - the check is heavily parameterized.
3683 conftest_s=
3684 tls_as_opt=
3685 case "$target" in
3686 changequote(,)dnl
3687   alpha*-*-*)
3688     conftest_s='
3689         .section ".tdata","awT",@progbits
3690 foo:    .long   25
3691         .text
3692         ldq     $27,__tls_get_addr($29)         !literal!1
3693         lda     $16,foo($29)                    !tlsgd!1
3694         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
3695         ldq     $27,__tls_get_addr($29)         !literal!2
3696         lda     $16,foo($29)                    !tlsldm!2
3697         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
3698         ldq     $1,foo($29)                     !gotdtprel
3699         ldah    $2,foo($29)                     !dtprelhi
3700         lda     $3,foo($2)                      !dtprello
3701         lda     $4,foo($29)                     !dtprel
3702         ldq     $1,foo($29)                     !gottprel
3703         ldah    $2,foo($29)                     !tprelhi
3704         lda     $3,foo($2)                      !tprello
3705         lda     $4,foo($29)                     !tprel'
3706         tls_as_opt=--fatal-warnings
3707         ;;
3708   arc*-*-*)
3709     conftest_s='
3710         add_s r0,r0, @foo@tpoff'
3711         ;;
3712   cris-*-*|crisv32-*-*)
3713     conftest_s='
3714         .section ".tdata","awT",@progbits
3715 x:      .long   25
3716         .text
3717         move.d x:IE,$r10
3718         nop'
3719         tls_as_opt=--fatal-warnings
3720         ;;
3721   frv*-*-*)
3722     conftest_s='
3723         .section ".tdata","awT",@progbits
3724 x:      .long   25
3725         .text
3726         call    #gettlsoff(x)'
3727         ;;
3728   hppa*-*-linux*)
3729     conftest_s='
3730 t1:     .reg    %r20
3731 t2:     .reg    %r21
3732 gp:     .reg    %r19
3733         .section ".tdata","awT",@progbits
3734 foo:    .long   25
3735         .text
3736         .align  4
3737         addil LT%foo-$tls_gdidx$,gp
3738         ldo RT%foo-$tls_gdidx$(%r1),%arg0
3739         b __tls_get_addr
3740         nop
3741         addil LT%foo-$tls_ldidx$,gp
3742         b __tls_get_addr
3743         ldo RT%foo-$tls_ldidx$(%r1),%arg0
3744         addil LR%foo-$tls_dtpoff$,%ret0
3745         ldo RR%foo-$tls_dtpoff$(%r1),%t1
3746         mfctl %cr27,%t1
3747         addil LT%foo-$tls_ieoff$,gp
3748         ldw RT%foo-$tls_ieoff$(%r1),%t2
3749         add %t1,%t2,%t3
3750         mfctl %cr27,%t1
3751         addil LR%foo-$tls_leoff$,%t1
3752         ldo RR%foo-$tls_leoff$(%r1),%t2'
3753         tls_as_opt=--fatal-warnings
3754         ;;
3755   arm*-*-*)
3756     conftest_s='
3757         .section ".tdata","awT",%progbits
3758 foo:    .long   25
3759         .text
3760 .word foo(gottpoff)
3761 .word foo(tpoff)
3762 .word foo(tlsgd)
3763 .word foo(tlsldm)
3764 .word foo(tlsldo)'
3765         ;;
3766   i[34567]86-*-* | x86_64-*-*)
3767     case "$target" in
3768       i[34567]86-*-solaris2.* | x86_64-*-solaris2.*)
3769         on_solaris=yes
3770         ;;
3771       *)
3772         on_solaris=no
3773         ;;
3774     esac
3775     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3776       conftest_s='
3777         .section .tdata,"awt",@progbits'
3778       tls_section_flag=t
3779 changequote([,])dnl
3780       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
3781 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
3782 changequote(,)dnl
3783     else
3784       conftest_s='
3785         .section ".tdata","awT",@progbits'
3786       tls_section_flag=T
3787       tls_as_opt="--fatal-warnings"
3788     fi
3789     case "$target" in
3790       i[34567]86-*-*)
3791         if test x$on_solaris = xyes; then
3792           case $gas_flag in
3793             yes) tls_as_opt="$tls_as_opt --32" ;;
3794           esac
3795         fi
3796         conftest_s="$conftest_s
3797 foo:    .long   25
3798         .text
3799         movl    %gs:0, %eax
3800         leal    foo@tlsgd(,%ebx,1), %eax
3801         leal    foo@tlsldm(%ebx), %eax
3802         leal    foo@dtpoff(%eax), %edx
3803         movl    foo@gottpoff(%ebx), %eax
3804         subl    foo@gottpoff(%ebx), %eax
3805         addl    foo@gotntpoff(%ebx), %eax
3806         movl    foo@indntpoff, %eax
3807         movl    \$foo@tpoff, %eax
3808         subl    \$foo@tpoff, %eax
3809         leal    foo@ntpoff(%ecx), %eax"
3810         ;;
3811       x86_64-*-*)
3812         if test x$on_solaris = xyes; then
3813           case $gas_flag in
3814             yes) tls_as_opt="$tls_as_opt --64" ;;
3815             no)  tls_as_opt="$tls_as_opt -xarch=amd64" ;;
3816           esac
3817         fi
3818         conftest_s="$conftest_s
3819 foo:    .long   25
3820         .text
3821         movq    %fs:0, %rax
3822         leaq    foo@tlsgd(%rip), %rdi
3823         leaq    foo@tlsld(%rip), %rdi
3824         leaq    foo@dtpoff(%rax), %rdx
3825         movq    foo@gottpoff(%rip), %rax
3826         movq    \$foo@tpoff, %rax"
3827         ;;
3828     esac
3829     ;;
3830   ia64-*-*)
3831     conftest_s='
3832         .section ".tdata","awT",@progbits
3833 foo:    data8   25
3834         .text
3835         addl    r16 = @ltoff(@dtpmod(foo#)), gp
3836         addl    r17 = @ltoff(@dtprel(foo#)), gp
3837         addl    r18 = @ltoff(@tprel(foo#)), gp
3838         addl    r19 = @dtprel(foo#), gp
3839         adds    r21 = @dtprel(foo#), r13
3840         movl    r23 = @dtprel(foo#)
3841         addl    r20 = @tprel(foo#), gp
3842         adds    r22 = @tprel(foo#), r13
3843         movl    r24 = @tprel(foo#)'
3844         tls_as_opt=--fatal-warnings
3845         ;;
3846   loongarch*-*-*)
3847     conftest_s='
3848         .section .tdata,"awT",@progbits
3849 x:      .word 2
3850         .text
3851         la.tls.gd $a0,x
3852         bl __tls_get_addr'
3853         tls_first_major=0
3854         tls_first_minor=0
3855         tls_as_opt='--fatal-warnings'
3856         ;;
3857   microblaze*-*-*)
3858     conftest_s='
3859         .section .tdata,"awT",@progbits
3860 x:
3861         .word 2
3862         .text
3863         addik r5,r20,x@TLSGD
3864         addik r5,r20,x@TLSLDM'
3865         tls_as_opt='--fatal-warnings'
3866         ;;
3867   mips*-*-*)
3868     conftest_s='
3869         .section .tdata,"awT",@progbits
3870 x:
3871         .word 2
3872         .text
3873         addiu $4, $28, %tlsgd(x)
3874         addiu $4, $28, %tlsldm(x)
3875         lui $4, %dtprel_hi(x)
3876         addiu $4, $4, %dtprel_lo(x)
3877         lw $4, %gottprel(x)($28)
3878         lui $4, %tprel_hi(x)
3879         addiu $4, $4, %tprel_lo(x)'
3880         tls_as_opt='-32 --fatal-warnings'
3881         ;;
3882   m68k-*-*)
3883     conftest_s='
3884         .section .tdata,"awT",@progbits
3885 x:
3886         .word 2
3887         .text
3888 foo:
3889         move.l x@TLSGD(%a5),%a0
3890         move.l x@TLSLDM(%a5),%a0
3891         move.l x@TLSLDO(%a5),%a0
3892         move.l x@TLSIE(%a5),%a0
3893         move.l x@TLSLE(%a5),%a0'
3894         tls_as_opt='--fatal-warnings'
3895         ;;
3896   nios2-*-*)
3897       conftest_s='
3898         .section ".tdata","awT",@progbits'
3899         tls_as_opt="--fatal-warnings"
3900         ;;
3901   aarch64*-*-*)
3902     conftest_s='
3903         .section ".tdata","awT",%progbits
3904 foo:    .long   25
3905         .text
3906         adrp  x0, :tlsgd:x
3907         add   x0, x0, #:tlsgd_lo12:x
3908         bl    __tls_get_addr
3909         nop'
3910         tls_as_opt='--fatal-warnings'
3911         ;;
3912   or1k*-*-*)
3913     conftest_s='
3914         .section ".tdata","awT",@progbits
3915 foo:    .long   25
3916         .text
3917         l.movhi r3, tpoffha(foo)
3918         l.add   r3, r3, r10
3919         l.lwz   r4, tpofflo(foo)(r3)'
3920     tls_as_opt=--fatal-warnings
3921     ;;
3922   powerpc-ibm-aix*)
3923     conftest_s='
3924         .extern __get_tpointer
3925         .toc
3926 LC..1:
3927         .tc a[TC],a[TL]@le
3928         .csect .text[PR]
3929 .tlstest:
3930         lwz 9,LC..1(2)
3931         bla __get_tpointer
3932         lwzx 3,9,3
3933         .globl a
3934         .csect a[TL],4
3935 a:
3936         .space 4'
3937         ;;
3938   powerpc64*-*-*)
3939     conftest_s='
3940         .section ".tdata","awT",@progbits
3941         .align 3
3942 ld0:    .space 8
3943 ld1:    .space 8
3944 x1:     .space 8
3945 x2:     .space 8
3946 x3:     .space 8
3947         .text
3948         addi 3,2,ld0@got@tlsgd
3949         bl .__tls_get_addr
3950         nop
3951         addi 3,2,ld1@toc
3952         bl .__tls_get_addr
3953         nop
3954         addi 3,2,x1@got@tlsld
3955         bl .__tls_get_addr
3956         nop
3957         addi 9,3,x1@dtprel
3958         bl .__tls_get_addr
3959         nop
3960         addis 9,3,x2@dtprel@ha
3961         addi 9,9,x2@dtprel@l
3962         bl .__tls_get_addr
3963         nop
3964         ld 9,x3@got@dtprel(2)
3965         add 9,9,3
3966         bl .__tls_get_addr
3967         nop'
3968         tls_as_opt="-a64 --fatal-warnings"
3969         ;;
3970   powerpc*-*-*)
3971     conftest_s='
3972         .section ".tdata","awT",@progbits
3973         .align 2
3974 ld0:    .space 4
3975 ld1:    .space 4
3976 x1:     .space 4
3977 x2:     .space 4
3978 x3:     .space 4
3979         .text
3980         addi 3,31,ld0@got@tlsgd
3981         bl __tls_get_addr
3982         addi 3,31,x1@got@tlsld
3983         bl __tls_get_addr
3984         addi 9,3,x1@dtprel
3985         addis 9,3,x2@dtprel@ha
3986         addi 9,9,x2@dtprel@l
3987         lwz 9,x3@got@tprel(31)
3988         add 9,9,x@tls
3989         addi 9,2,x1@tprel
3990         addis 9,2,x2@tprel@ha
3991         addi 9,9,x2@tprel@l'
3992         tls_as_opt="-a32 --fatal-warnings"
3993         ;;
3994   riscv*-*-*)
3995     conftest_s='
3996         .section .tdata,"awT",@progbits
3997 x:      .word 2
3998         .text
3999         la.tls.gd a0,x
4000         call __tls_get_addr'
4001         tls_as_opt='--fatal-warnings'
4002         ;;
4003   s390-*-*)
4004     conftest_s='
4005         .section ".tdata","awT",@progbits
4006 foo:    .long   25
4007         .text
4008         .long   foo@TLSGD
4009         .long   foo@TLSLDM
4010         .long   foo@DTPOFF
4011         .long   foo@NTPOFF
4012         .long   foo@GOTNTPOFF
4013         .long   foo@INDNTPOFF
4014         l       %r1,foo@GOTNTPOFF(%r12)
4015         l       %r1,0(%r1):tls_load:foo
4016         bas     %r14,0(%r1,%r13):tls_gdcall:foo
4017         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
4018         tls_as_opt="-m31 --fatal-warnings"
4019         ;;
4020   s390x-*-*)
4021     conftest_s='
4022         .section ".tdata","awT",@progbits
4023 foo:    .long   25
4024         .text
4025         .quad   foo@TLSGD
4026         .quad   foo@TLSLDM
4027         .quad   foo@DTPOFF
4028         .quad   foo@NTPOFF
4029         .quad   foo@GOTNTPOFF
4030         lg      %r1,foo@GOTNTPOFF(%r12)
4031         larl    %r1,foo@INDNTPOFF
4032         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
4033         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
4034         tls_as_opt="-m64 -Aesame --fatal-warnings"
4035         ;;
4036   sh-*-* | sh[123456789lbe]*-*-*)
4037     conftest_s='
4038         .section ".tdata","awT",@progbits
4039 foo:    .long   25
4040         .text
4041         .long   foo@TLSGD
4042         .long   foo@TLSLDM
4043         .long   foo@DTPOFF
4044         .long   foo@GOTTPOFF
4045         .long   foo@TPOFF'
4046         tls_as_opt=--fatal-warnings
4047         ;;
4048   sparc*-*-*)
4049     case "$target" in
4050       sparc*-sun-solaris2.*)
4051         on_solaris=yes
4052         ;;
4053       *)
4054         on_solaris=no
4055         ;;
4056     esac
4057     if test x$on_solaris = xyes && test x$gas_flag = xno; then
4058       conftest_s='
4059         .section ".tdata",#alloc,#write,#tls'
4060     else
4061       conftest_s='
4062         .section ".tdata","awT",@progbits'
4063         tls_as_opt="-32 --fatal-warnings"
4064     fi
4065     conftest_s="$conftest_s
4066 foo:    .long   25
4067         .text
4068         sethi   %tgd_hi22(foo), %o0
4069         add     %o0, %tgd_lo10(foo), %o1
4070         add     %l7, %o1, %o0, %tgd_add(foo)
4071         call    __tls_get_addr, %tgd_call(foo)
4072         sethi   %tldm_hi22(foo), %l1
4073         add     %l1, %tldm_lo10(foo), %l2
4074         add     %l7, %l2, %o0, %tldm_add(foo)
4075         call    __tls_get_addr, %tldm_call(foo)
4076         sethi   %tldo_hix22(foo), %l3
4077         xor     %l3, %tldo_lox10(foo), %l4
4078         add     %o0, %l4, %l5, %tldo_add(foo)
4079         sethi   %tie_hi22(foo), %o3
4080         add     %o3, %tie_lo10(foo), %o3
4081         ld      [%l7 + %o3], %o2, %tie_ld(foo)
4082         add     %g7, %o2, %o4, %tie_add(foo)
4083         sethi   %tle_hix22(foo), %l1
4084         xor     %l1, %tle_lox10(foo), %o5
4085         ld      [%g7 + %o5], %o1"
4086         ;;
4087   xtensa*-*-*)
4088     conftest_s='
4089         .section ".tdata","awT",@progbits
4090 foo:    .long   25
4091         .text
4092         movi    a8, foo@TLSFUNC
4093         movi    a10, foo@TLSARG
4094         callx8.tls a8, foo@TLSCALL'
4095         ;;
4096 changequote([,])dnl
4097 esac
4098 set_have_as_tls=no
4099 if test "x$enable_tls" = xno ; then
4100   : # TLS explicitly disabled.
4101 elif test "x$enable_tls" = xyes ; then
4102   set_have_as_tls=yes # TLS explicitly enabled.
4103 elif test -z "$conftest_s"; then
4104   : # If we don't have a check, assume no support.
4105 else
4106   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
4107   [$tls_as_opt], [$conftest_s],,
4108   [set_have_as_tls=yes])
4109 fi
4110 if test $set_have_as_tls = yes ; then
4111   AC_DEFINE(HAVE_AS_TLS, 1,
4112             [Define if your assembler and linker support thread-local storage.])
4113 fi
4114
4115 # Target-specific assembler checks.
4116
4117 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
4118 gcc_cv_ld_static_dynamic=no
4119 gcc_cv_ld_static_option='-Bstatic'
4120 gcc_cv_ld_dynamic_option='-Bdynamic'
4121 if test $in_tree_ld = yes ; then
4122   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
4123     gcc_cv_ld_static_dynamic=yes
4124   fi
4125 elif test x$gcc_cv_ld != x; then
4126   # Check if linker supports -Bstatic/-Bdynamic option
4127   if $gcc_cv_ld --help 2>&1 | grep -- -Bstatic > /dev/null \
4128      && $gcc_cv_ld --help 2>&1 | grep -- -Bdynamic > /dev/null; then
4129       gcc_cv_ld_static_dynamic=yes
4130   else
4131     case "$target" in
4132       # AIX ld uses -b flags
4133       *-*-aix4.[[23]]* | *-*-aix[[5-9]]*)
4134         gcc_cv_ld_static_dynamic=yes
4135         gcc_cv_ld_static_option="-bstatic"
4136         gcc_cv_ld_dynamic_option="-bdynamic"
4137         ;;
4138       # HP-UX ld uses -a flags to select between shared and archive.
4139       *-*-hpux*)
4140         if test x"$gnu_ld" = xno; then
4141           gcc_cv_ld_static_dynamic=yes
4142           gcc_cv_ld_static_option="-aarchive_shared"
4143           gcc_cv_ld_dynamic_option="-adefault"
4144         fi
4145         ;;
4146       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
4147       *-*-solaris2*)
4148         gcc_cv_ld_static_dynamic=yes
4149         ;;
4150     esac
4151   fi
4152 fi
4153 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
4154         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
4155 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
4156         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
4157 [Define to the linker option to disable use of shared objects.])
4158         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
4159 [Define to the linker option to enable use of shared objects.])
4160 fi
4161 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
4162
4163 AC_MSG_CHECKING(linker --version-script option)
4164 gcc_cv_ld_version_script=no
4165 ld_version_script_option=''
4166 if test $in_tree_ld = yes || test x"$gnu_ld" = xyes; then
4167   gcc_cv_ld_version_script=yes
4168   ld_version_script_option='--version-script'
4169 elif test x$gcc_cv_ld != x; then
4170   case "$target" in
4171     # Solaris 2 ld always supports -M.  It also supports a subset of
4172     # --version-script since Solaris 11.4, but requires
4173     # -z gnu-version-script-compat to activate.
4174     *-*-solaris2*)
4175       gcc_cv_ld_version_script=yes
4176       ld_version_script_option='-M'
4177       ;;
4178   esac
4179 fi
4180 # Don't AC_DEFINE result, only used in jit/Make-lang.in so far.
4181 AC_MSG_RESULT($gcc_cv_ld_version_script)
4182 AC_SUBST(ld_version_script_option)
4183
4184 AC_MSG_CHECKING(linker soname option)
4185 gcc_cv_ld_soname=no
4186 if test $in_tree_ld = yes || test x"$gnu_ld" = xyes; then
4187   gcc_cv_ld_soname=yes
4188   ld_soname_option='-soname'
4189 elif test x$gcc_cv_ld != x; then
4190   case "$target" in
4191     *-*-darwin*)
4192       gcc_cv_ld_soname=yes
4193       ld_soname_option='-install_name'
4194       ;;
4195     # Solaris 2 ld always supports -h.  It also supports --soname for GNU
4196     # ld compatiblity since some Solaris 10 update.
4197     *-*-solaris2*)
4198       gcc_cv_ld_soname=yes
4199       ld_soname_option='-h'
4200       ;;
4201   esac
4202 fi
4203 # Don't AC_DEFINE result, only used in jit/Make-lang.in so far.
4204 AC_MSG_RESULT($gcc_cv_ld_soname)
4205 AC_SUBST(ld_soname_option)
4206
4207 if test x"$demangler_in_ld" = xyes; then
4208   AC_MSG_CHECKING(linker --demangle support)
4209   gcc_cv_ld_demangle=no
4210   if test $in_tree_ld = yes; then
4211     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
4212       gcc_cv_ld_demangle=yes
4213     fi
4214   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
4215     # Check if the GNU linker supports --demangle option
4216     if $gcc_cv_ld --help 2>&1 | grep no-demangle > /dev/null; then
4217       gcc_cv_ld_demangle=yes
4218     fi
4219   fi
4220   if test x"$gcc_cv_ld_demangle" = xyes; then
4221     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
4222 [Define if your linker supports --demangle option.])
4223   fi
4224   AC_MSG_RESULT($gcc_cv_ld_demangle)
4225 fi
4226
4227 AC_MSG_CHECKING(linker plugin support)
4228 gcc_cv_lto_plugin=0
4229 if test -f liblto_plugin.la; then
4230   save_ld_ver="$ld_ver"
4231   save_ld_vers_major="$ld_vers_major"
4232   save_ld_vers_minor="$ld_vers_minor"
4233   save_ld_is_gold="$ld_is_gold"
4234
4235   ld_is_gold=no
4236
4237   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
4238     ld_ver="GNU ld"
4239     # FIXME: ld_is_gold?
4240     ld_vers_major="$gcc_cv_gld_major_version"
4241     ld_vers_minor="$gcc_cv_gld_minor_version"
4242   else
4243     # Determine plugin linker version.
4244     # FIXME: Partial duplicate from above, generalize.
4245 changequote(,)dnl
4246     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
4247     if echo "$ld_ver" | grep GNU > /dev/null; then
4248       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
4249         ld_is_gold=yes
4250         ld_vers=`echo $ld_ver | sed -n \
4251             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
4252       else
4253         ld_vers=`echo $ld_ver | sed -n \
4254             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
4255       fi
4256       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
4257       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
4258     fi
4259 changequote([,])dnl
4260   fi
4261
4262   # Determine plugin support.
4263   if echo "$ld_ver" | grep GNU > /dev/null; then
4264     # Require GNU ld or gold 2.21+ for plugin support by default.
4265     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
4266       gcc_cv_lto_plugin=2
4267     elif test "$ld_is_mold" = yes; then
4268       gcc_cv_lto_plugin=2
4269     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
4270     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
4271       gcc_cv_lto_plugin=1
4272     fi
4273   fi
4274
4275   ld_ver="$save_ld_ver"
4276   ld_vers_major="$save_ld_vers_major"
4277   ld_vers_minor="$save_ld_vers_minor"
4278   ld_is_gold="$save_ld_is_gold"
4279 fi
4280 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
4281   [Define to the level of your linker's plugin support.])
4282 AC_MSG_RESULT($gcc_cv_lto_plugin)
4283
4284 # Target OS-specific assembler checks.
4285
4286 case "$target_os" in
4287   darwin*)
4288     gcc_GAS_CHECK_FEATURE([-mmacosx-version-min option],
4289       gcc_cv_as_mmacosx_version_min,
4290       [-mmacosx-version-min=10.1], [.text],,
4291       [AC_DEFINE(HAVE_AS_MMACOSX_VERSION_MIN_OPTION, 1,
4292         [Define if your Mac OS X assembler supports the -mmacos-version-min option.])])
4293     ;;
4294 esac
4295
4296 # Target CPU-specific assembler checks.
4297
4298 case "$target" in
4299   aarch64*-*-*)
4300     gcc_GAS_CHECK_FEATURE([-mabi option], gcc_cv_as_aarch64_mabi,
4301                           [-mabi=lp64], [.text],,,)
4302     if test x$gcc_cv_as_aarch64_mabi = xyes; then
4303       AC_DEFINE(HAVE_AS_MABI_OPTION, 1,
4304                 [Define if your assembler supports the -mabi option.])
4305     else
4306       if test x$with_abi = xilp32; then
4307         AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
4308                      Upgrade the Assembler.])
4309       fi
4310       if test x"$with_multilib_list" = xdefault; then
4311         TM_MULTILIB_CONFIG=lp64
4312       else
4313         aarch64_multilibs=`echo $with_multilib_list | sed -e 's/,/ /g'`
4314         for aarch64_multilib in ${aarch64_multilibs}; do
4315           case ${aarch64_multilib} in
4316             ilp32)
4317               AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
4318                             Upgrade the Assembler.])
4319               ;;
4320             *)
4321               ;;
4322           esac
4323         done
4324       fi
4325     fi
4326     # Check if we have binutils support for relocations types needed by -fpic
4327     gcc_GAS_CHECK_FEATURE([-fpic relocs], gcc_cv_as_aarch64_picreloc,,
4328     [
4329         .text
4330         ldr     x0, [[x2, #:gotpage_lo15:globalsym]]
4331     ],,[AC_DEFINE(HAVE_AS_SMALL_PIC_RELOCS, 1,
4332         [Define if your assembler supports relocs needed by -fpic.])])
4333     # Enable Branch Target Identification Mechanism and Return Address
4334     # Signing by default.
4335     AC_ARG_ENABLE(standard-branch-protection,
4336     [
4337 AS_HELP_STRING([--enable-standard-branch-protection],
4338         [enable Branch Target Identification Mechanism and Return Address Signing by default for AArch64])
4339 AS_HELP_STRING([--disable-standard-branch-protection],
4340         [disable Branch Target Identification Mechanism and Return Address Signing by default for AArch64])
4341     ],
4342       [
4343         case $enableval in
4344           yes)
4345             tm_defines="${tm_defines} TARGET_ENABLE_BTI=1 TARGET_ENABLE_PAC_RET=1"
4346             ;;
4347           no)
4348             ;;
4349           *)
4350             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-standard-branch-protection.\
4351   Valid choices are 'yes' and 'no'.])
4352             ;;
4353         esac
4354       ],
4355     [])
4356     # Enable default workaround for AArch64 Cortex-A53 erratum 835769.
4357     AC_ARG_ENABLE(fix-cortex-a53-835769,
4358     [
4359 AS_HELP_STRING([--enable-fix-cortex-a53-835769],
4360         [enable workaround for AArch64 Cortex-A53 erratum 835769 by default])
4361 AS_HELP_STRING([--disable-fix-cortex-a53-835769],
4362         [disable workaround for AArch64 Cortex-A53 erratum 835769 by default])
4363     ],
4364       [
4365         case $enableval in
4366           yes)
4367             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_835769_DEFAULT=1"
4368             ;;
4369           no)
4370             ;;
4371           *)
4372             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-835769.\
4373   Valid choices are 'yes' and 'no'.])
4374             ;;
4375
4376         esac
4377       ],
4378     [])
4379     # Enable default workaround for AArch64 Cortex-A53 erratum 843419.
4380     AC_ARG_ENABLE(fix-cortex-a53-843419,
4381     [
4382 AS_HELP_STRING([--enable-fix-cortex-a53-843419],
4383         [enable workaround for AArch64 Cortex-A53 erratum 843419 by default])
4384 AS_HELP_STRING([--disable-fix-cortex-a53-843419],
4385         [disable workaround for AArch64 Cortex-A53 erratum 843419 by default])
4386     ],
4387       [
4388         case $enableval in
4389           yes)
4390             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_843419_DEFAULT=1"
4391             ;;
4392           no)
4393             ;;
4394           *)
4395             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-843419.\
4396   Valid choices are 'yes' and 'no'.])
4397             ;;
4398
4399         esac
4400       ],
4401     [])
4402     ;;
4403
4404   # All TARGET_ABI_OSF targets.
4405   alpha*-*-linux* | alpha*-*-*bsd*)
4406     gcc_GAS_CHECK_FEATURE([explicit relocation support],
4407         gcc_cv_as_alpha_explicit_relocs,,
4408 [       .set nomacro
4409         .text
4410         extbl   $3, $2, $3      !lituse_bytoff!1
4411         ldq     $2, a($29)      !literal!1
4412         ldq     $4, b($29)      !literal!2
4413         ldq_u   $3, 0($2)       !lituse_base!1
4414         ldq     $27, f($29)     !literal!5
4415         jsr     $26, ($27), f   !lituse_jsr!5
4416         ldah    $29, 0($26)     !gpdisp!3
4417         lda     $0, c($29)      !gprel
4418         ldah    $1, d($29)      !gprelhigh
4419         lda     $1, d($1)       !gprellow
4420         lda     $29, 0($29)     !gpdisp!3],,
4421     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
4422   [Define if your assembler supports explicit relocations.])])
4423     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
4424         gcc_cv_as_alpha_jsrdirect_relocs,,
4425 [       .set nomacro
4426         .text
4427         ldq     $27, a($29)     !literal!1
4428         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
4429     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
4430   [Define if your assembler supports the lituse_jsrdirect relocation.])])
4431     ;;
4432
4433   avr-*-*)
4434     gcc_GAS_CHECK_FEATURE([--mlink-relax option], gcc_cv_as_avr_mlink_relax,
4435       [--mlink-relax], [.text],,
4436       [AC_DEFINE(HAVE_AS_AVR_MLINK_RELAX_OPTION, 1,
4437                 [Define if your avr assembler supports --mlink-relax option.])])
4438
4439     gcc_GAS_CHECK_FEATURE([-mrmw option], gcc_cv_as_avr_mrmw,
4440       [-mrmw], [.text],,
4441       [AC_DEFINE(HAVE_AS_AVR_MRMW_OPTION, 1,
4442                 [Define if your avr assembler supports -mrmw option.])])
4443
4444     gcc_GAS_CHECK_FEATURE([__gcc_isr pseudo instruction],
4445       gcc_cv_as_avr_mgccisr,
4446       [-mgcc-isr], [.text
4447                     __gcc_isr 1
4448                     __gcc_isr 2
4449                     __gcc_isr 0,r24
4450                    ],,
4451       [AC_DEFINE(HAVE_AS_AVR_MGCCISR_OPTION, 1,
4452                 [Define if your avr assembler supports -mgcc-isr option.])])
4453
4454     # Check how default linker description file implements .rodata for
4455     # avrxmega3 (PR21472).  avr-gcc assumes .rodata is *not* loaded to
4456     # RAM so avr-gcc skips __do_copy_data for .rodata objects.
4457     AC_MSG_CHECKING(binutils for avrxmega3 .rodata support)
4458     cat > conftest.s <<EOF
4459         .section .rodata,"a",@progbits
4460         .global xxvaryy
4461     ;; avr-nm should print "... R xxvaryy", not "... D xxvaryy".
4462     xxvaryy:
4463         .word 1
4464 EOF
4465     rm -f conftest.nm
4466     AC_TRY_COMMAND([$gcc_cv_as -mmcu=avrxmega3 conftest.s -o conftest.o])
4467     AC_TRY_COMMAND([$gcc_cv_ld -mavrxmega3 conftest.o -o conftest.elf])
4468     AC_TRY_COMMAND([$gcc_cv_nm conftest.elf > conftest.nm])
4469     if test -s conftest.nm
4470     then
4471         if grep ' R xxvaryy' conftest.nm > /dev/null; then
4472             AC_MSG_RESULT(yes)
4473             AC_DEFINE(HAVE_LD_AVR_AVRXMEGA3_RODATA_IN_FLASH, 1,
4474                 [Define if your default avr linker script for avrxmega3 leaves .rodata in flash.])
4475         else
4476             AC_MSG_RESULT(no: avrxmega3 .rodata located in RAM)
4477             echo "$as_me: nm output was" >&AS_MESSAGE_LOG_FD
4478             cat conftest.nm >&AS_MESSAGE_LOG_FD
4479             avr_ld_ver="`$gcc_cv_ld -v | sed -e 's:^.* ::'`"
4480             AC_MSG_WARN([[support for avrxmega3 .rodata in flash needs Binutils 2.29 or higher (have $avr_ld_ver)]])
4481         fi
4482     else
4483         AC_MSG_RESULT(test failed)
4484         echo "$as_me: failed program was" >&AS_MESSAGE_LOG_FD
4485         cat conftest.s >&AS_MESSAGE_LOG_FD
4486         AC_MSG_WARN([[see `config.log' for details]])
4487     fi
4488     rm -f conftest.s conftest.o conftest.elf conftest.nm
4489     ;;
4490
4491   cris-*-*)
4492     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
4493       gcc_cv_as_cris_no_mul_bug,
4494       [-no-mul-bug-abort], [.text],,
4495       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
4496                 [Define if your assembler supports the -no-mul-bug-abort option.])])
4497     ;;
4498
4499   sparc*-*-*)
4500     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,
4501       [-relax], [.text],,
4502       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
4503                 [Define if your assembler supports -relax option.])])
4504
4505     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
4506       gcc_cv_as_sparc_gotdata_op,
4507       [-K PIC],
4508 [.text
4509 .align 4
4510 foo:
4511         nop
4512 bar:
4513         sethi %gdop_hix22(foo), %g1
4514         xor    %g1, %gdop_lox10(foo), %g1
4515         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
4516       [if test x$gcc_cv_ld != x \
4517        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
4518          if test x$gcc_cv_objdump != x; then
4519            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
4520               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
4521                gcc_cv_as_sparc_gotdata_op=no
4522            else
4523                gcc_cv_as_sparc_gotdata_op=yes
4524            fi
4525          fi
4526        fi
4527        rm -f conftest],
4528       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
4529                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
4530
4531     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
4532       gcc_cv_as_sparc_ua_pcrel,
4533       [-K PIC],
4534 [.text
4535 foo:
4536         nop
4537 .data
4538 .align 4
4539 .byte 0
4540 .uaword %r_disp32(foo)],
4541       [if test x$gcc_cv_ld != x \
4542        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
4543          gcc_cv_as_sparc_ua_pcrel=yes
4544        fi
4545        rm -f conftest],
4546       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
4547                 [Define if your assembler and linker support unaligned PC relative relocs.])
4548
4549       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
4550         gcc_cv_as_sparc_ua_pcrel_hidden,
4551         [-K PIC],
4552 [.data
4553 .align 4
4554 .byte 0x31
4555 .uaword %r_disp32(foo)
4556 .byte 0x32, 0x33, 0x34
4557 .global foo
4558 .hidden foo
4559 foo:
4560 .skip 4],
4561         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4562          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
4563          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
4564             | grep ' 31000000 07323334' > /dev/null 2>&1; then
4565             if $gcc_cv_objdump -R conftest 2> /dev/null \
4566                | grep 'DISP32' > /dev/null 2>&1; then
4567                 :
4568             else
4569                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
4570             fi
4571          fi
4572          rm -f conftest],
4573          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
4574                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
4575     ]) # unaligned pcrel relocs
4576
4577     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
4578       gcc_cv_as_sparc_offsetable_lo10,
4579       [-xarch=v9],
4580 [.text
4581         or %g1, %lo(ab) + 12, %g1
4582         or %g1, %lo(ab + 12), %g1],
4583       [if test x$gcc_cv_objdump != x \
4584        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
4585           | grep ' 82106000 82106000' > /dev/null 2>&1; then
4586          gcc_cv_as_sparc_offsetable_lo10=yes
4587        fi],
4588        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
4589                  [Define if your assembler supports offsetable %lo().])])
4590
4591     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
4592       gcc_cv_as_sparc_fmaf,
4593       [-xarch=v9d],
4594       [.text
4595        .register %g2, #scratch
4596        .register %g3, #scratch
4597        .align 4
4598        fmaddd %f0, %f2, %f4, %f6
4599        addxccc %g1, %g2, %g3
4600        fsrl32 %f2, %f4, %f8
4601        fnaddd %f10, %f12, %f14],,
4602       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
4603                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
4604
4605     gcc_GAS_CHECK_FEATURE([SPARC4 instructions],
4606       gcc_cv_as_sparc_sparc4,
4607       [-xarch=sparc4],
4608       [.text
4609        .register %g2, #scratch
4610        .register %g3, #scratch
4611        .align 4
4612        cxbe %g2, %g3, 1f
4613 1:     cwbneg %g2, %g3, 1f
4614 1:     sha1
4615        md5
4616        aes_kexpand0 %f4, %f6, %f8
4617        des_round %f38, %f40, %f42, %f44
4618        camellia_f %f54, %f56, %f58, %f60
4619        kasumi_fi_xor %f46, %f48, %f50, %f52],,
4620       [AC_DEFINE(HAVE_AS_SPARC4, 1,
4621                 [Define if your assembler supports SPARC4 instructions.])])
4622
4623     gcc_GAS_CHECK_FEATURE([SPARC5 and VIS 4.0 instructions],
4624       gcc_cv_as_sparc_sparc5,
4625       [-xarch=sparc5],
4626       [.text
4627        .register %g2, #scratch
4628        .register %g3, #scratch
4629        .align 4
4630        subxc %g1, %g2, %g3
4631        fpadd8 %f0, %f2, %f4],,
4632       [AC_DEFINE(HAVE_AS_SPARC5_VIS4, 1,
4633                 [Define if your assembler supports SPARC5 and VIS 4.0 instructions.])])
4634
4635     gcc_GAS_CHECK_FEATURE([SPARC6 instructions],
4636       gcc_cv_as_sparc_sparc6,
4637       [-xarch=sparc6],
4638       [.text
4639        .register %g2, #scratch
4640        .register %g3, #scratch
4641        .align 4
4642        rd %entropy, %g1
4643        fpsll64x %f0, %f2, %f4],,
4644       [AC_DEFINE(HAVE_AS_SPARC6, 1,
4645                 [Define if your assembler supports SPARC6 instructions.])])
4646
4647     gcc_GAS_CHECK_FEATURE([LEON instructions],
4648       gcc_cv_as_sparc_leon,
4649       [-Aleon],
4650       [.text
4651        .register %g2, #scratch
4652        .register %g3, #scratch
4653        .align 4
4654        smac %g2, %g3, %g1
4655        umac %g2, %g3, %g1
4656        casa [[%g2]] 0xb, %g3, %g1],,
4657       [AC_DEFINE(HAVE_AS_LEON, 1,
4658                 [Define if your assembler supports LEON instructions.])])
4659     ;;
4660
4661 changequote(,)dnl
4662   i[34567]86-*-* | x86_64-*-*)
4663 changequote([,])dnl
4664     case $target_os in
4665       cygwin*)
4666         # Full C++ conformance when using a shared libstdc++-v3 requires some
4667         # support from the Cygwin DLL, which in more recent versions exports
4668         # wrappers to aid in interposing and redirecting operators new, delete,
4669         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
4670         # are configuring for a version of Cygwin that exports the wrappers.
4671         if test x$host = x$target && test x$host_cpu = xi686; then
4672           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
4673         else
4674           # Can't check presence of libc functions during cross-compile, so
4675           # we just have to assume we're building for an up-to-date target.
4676           gcc_ac_cygwin_dll_wrappers=yes
4677         fi
4678         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
4679           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
4680           [Define if you want to generate code by default that assumes that the
4681            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
4682     esac
4683     case $target_os in
4684       cygwin* | pe | mingw32*)
4685         # Recent binutils allows the three-operand form of ".comm" on PE.  This
4686         # definition is used unconditionally to initialise the default state of
4687         # the target option variable that governs usage of the feature.
4688         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,,
4689           [.comm foo,1,32])
4690         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
4691           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
4692           [Define if your assembler supports specifying the alignment
4693            of objects allocated using the GAS .comm command.])
4694         # Used for DWARF 2 in PE
4695         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
4696           gcc_cv_as_ix86_pe_secrel32,,
4697 [.text
4698 foo:    nop
4699 .data
4700         .secrel32 foo],
4701           [if test x$gcc_cv_ld != x \
4702            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
4703              gcc_cv_as_ix86_pe_secrel32=yes
4704            fi
4705            rm -f conftest],
4706           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
4707             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
4708         # Test if the assembler supports the extended form of the .section
4709         # directive that specifies section alignment.  LTO support uses this,
4710         # but normally only after installation, so we warn but don't fail the
4711         # configure if LTO is enabled but the assembler does not support it.
4712         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
4713           -fatal-warnings,[.section lto_test,"dr0"])
4714         if test x$gcc_cv_as_section_has_align != xyes; then
4715           case ",$enable_languages," in
4716             *,lto,*)
4717               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
4718               ;;
4719           esac
4720         fi
4721         ;;
4722     esac
4723     case $target_os in
4724        darwin2* | darwin19*)
4725         gcc_GAS_CHECK_FEATURE([llvm assembler x86-pad-for-align option],
4726           gcc_cv_as_mllvm_x86_pad_for_align,
4727           [-mllvm -x86-pad-for-align=false], [.text],,
4728           [AC_DEFINE(HAVE_AS_MLLVM_X86_PAD_FOR_ALIGN, 1,
4729             [Define if your Mac OS X assembler supports -mllvm -x86-pad-for-align=false.])])
4730        ;;
4731     esac
4732
4733     gcc_GAS_CHECK_FEATURE([-xbrace_comment], gcc_cv_as_ix86_xbrace_comment,
4734       [-xbrace_comment=no], [.text],,
4735       [AC_DEFINE(HAVE_AS_XBRACE_COMMENT_OPTION, 1,
4736                 [Define if your assembler supports -xbrace_comment option.])])
4737
4738     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
4739        gcc_cv_as_ix86_filds,,
4740        [filds (%ebp); fists (%ebp)],,
4741        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
4742          [Define if your assembler uses filds and fists mnemonics.])])
4743
4744     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
4745        gcc_cv_as_ix86_fildq,,
4746        [fildq (%ebp); fistpq (%ebp)],,
4747        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
4748          [Define if your assembler uses fildq and fistq mnemonics.])])
4749
4750     gcc_GAS_CHECK_FEATURE([cmov syntax],
4751       gcc_cv_as_ix86_cmov_sun_syntax,,
4752       [cmovl.l %edx, %eax],,
4753       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
4754         [Define if your assembler supports the Sun syntax for cmov.])])
4755
4756     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
4757       gcc_cv_as_ix86_ffreep,,
4758       [ffreep %st(1)],,
4759       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
4760         [Define if your assembler supports the ffreep mnemonic.])])
4761
4762     gcc_GAS_CHECK_FEATURE([.quad directive],
4763       gcc_cv_as_ix86_quad,,
4764       [.quad 0],,
4765       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
4766         [Define if your assembler supports the .quad directive.])])
4767
4768     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
4769       gcc_cv_as_ix86_sahf,,
4770       [.code64
4771        sahf],,
4772       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
4773         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
4774
4775     gcc_GAS_CHECK_FEATURE([interunit movq mnemonic],
4776       gcc_cv_as_ix86_interunit_movq,,
4777       [.code64
4778        movq %mm0, %rax
4779        movq %rax, %xmm0])
4780     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_INTERUNIT_MOVQ,
4781       [`if test $gcc_cv_as_ix86_interunit_movq = yes; then echo 1; else echo 0; fi`],
4782       [Define if your assembler supports interunit movq mnemonic.])
4783
4784     gcc_GAS_CHECK_FEATURE([hle prefixes],
4785       gcc_cv_as_ix86_hle,,
4786       [lock xacquire cmpxchg %esi, (%ecx)],,
4787       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
4788         [Define if your assembler supports HLE prefixes.])])
4789
4790     gcc_GAS_CHECK_FEATURE([swap suffix],
4791       gcc_cv_as_ix86_swap,,
4792       [movl.s %esp, %ebp],,
4793       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
4794         [Define if your assembler supports the swap suffix.])])
4795
4796     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
4797       gcc_cv_as_ix86_diff_sect_delta,,
4798       [.section .rodata
4799 .L1:
4800         .long .L2-.L1
4801         .long .L3-.L1
4802         .text
4803 .L3:    nop
4804 .L2:    nop],,
4805       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
4806         [Define if your assembler supports the subtraction of symbols in different sections.])])
4807
4808     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
4809         gcc_cv_as_ix86_rep_lock_prefix,,
4810         [rep movsl
4811          rep ret
4812          rep nop
4813          rep bsf %ecx, %eax
4814          rep bsr %ecx, %eax
4815          lock addl %edi, (%eax,%esi)
4816          lock orl $0, (%esp)],,
4817         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
4818           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
4819
4820     gcc_GAS_CHECK_FEATURE([ud2 mnemonic],
4821         gcc_cv_as_ix86_ud2,,
4822         [ud2],,
4823       [AC_DEFINE(HAVE_AS_IX86_UD2, 1,
4824         [Define if your assembler supports the 'ud2' mnemonic.])])
4825
4826     # Enforce 32-bit output with gas and gld.
4827     if test x$gas = xyes; then
4828       as_ix86_gas_32_opt="--32"
4829     fi
4830     if echo "$ld_ver" | grep GNU > /dev/null; then
4831       if $gcc_cv_ld -V 2>/dev/null | grep elf_i386_sol2 > /dev/null; then
4832         ld_ix86_gld_32_opt="-melf_i386_sol2"
4833       else
4834         ld_ix86_gld_32_opt="-melf_i386"
4835       fi
4836     fi
4837
4838     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
4839         gcc_cv_as_ix86_tlsgdplt,
4840         [$as_ix86_gas_32_opt],
4841         [call    tls_gd@tlsgdplt],
4842         [if test x$gcc_cv_ld != x \
4843          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4844            gcc_cv_as_ix86_tlsgdplt=yes
4845          fi
4846          rm -f conftest],
4847       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
4848         [Define if your assembler and linker support @tlsgdplt.])])
4849
4850     conftest_s='
4851         .section .tdata,"aw'$tls_section_flag'",@progbits
4852 tls_ld:
4853         .section .text,"ax",@progbits
4854          call    tls_ld@tlsldmplt'
4855
4856     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
4857         gcc_cv_as_ix86_tlsldmplt,
4858         [$as_ix86_gas_32_opt],
4859         [$conftest_s],
4860         [if test x$gcc_cv_ld != x \
4861          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4862            gcc_cv_as_ix86_tlsldmplt=yes
4863          fi
4864          rm -f conftest])
4865     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDMPLT,
4866       [`if test $gcc_cv_as_ix86_tlsldmplt = yes; then echo 1; else echo 0; fi`],
4867       [Define to 1 if your assembler and linker support @tlsldmplt.])
4868
4869     conftest_s='
4870         .section .text,"ax",@progbits
4871         .globl  _start
4872         .type   _start, @function
4873 _start:
4874         leal    value@tlsldm(%ebx), %eax
4875         call    ___tls_get_addr@plt
4876
4877         .section .tdata,"aw'$tls_section_flag'",@progbits
4878         .type   value, @object
4879 value:'
4880     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM reloc],
4881         gcc_cv_as_ix86_tlsldm,
4882         [$as_ix86_gas_32_opt],
4883         [$conftest_s],
4884         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4885             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o $ld_tls_libs -lc > /dev/null 2>&1; then
4886            if $gcc_cv_objdump -d conftest 2>/dev/null | grep nop > /dev/null \
4887               || dis conftest 2>/dev/null | grep nop > /dev/null; then
4888              gcc_cv_as_ix86_tlsldm=yes
4889            fi
4890          fi
4891          rm -f conftest])
4892     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDM,
4893       [`if test $gcc_cv_as_ix86_tlsldm = yes; then echo 1; else echo 0; fi`],
4894       [Define to 1 if your assembler and linker support @tlsldm.])
4895
4896     conftest_s='
4897         .data
4898 bar:
4899         .byte 1
4900         .text
4901         .global _start
4902 _start:
4903          cmpl $0, bar@GOT
4904          jmp *_start@GOT'
4905     gcc_GAS_CHECK_FEATURE([R_386_GOT32X reloc],
4906         gcc_cv_as_ix86_got32x,
4907         [$as_ix86_gas_32_opt],
4908         [$conftest_s],
4909         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4910             && test x$gcc_cv_readelf != x \
4911             && $gcc_cv_readelf --relocs --wide conftest.o 2>&1 \
4912                | grep R_386_GOT32X > /dev/null 2>&1 \
4913             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4914            if $gcc_cv_objdump -dw conftest 2>&1 \
4915               | grep 0xffffff > /dev/null 2>&1; then
4916              gcc_cv_as_ix86_got32x=no
4917            else
4918              gcc_cv_as_ix86_got32x=yes
4919            fi
4920          fi
4921          rm -f conftest])
4922     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_GOT32X,
4923       [`if test x"$gcc_cv_as_ix86_got32x" = xyes; then echo 1; else echo 0; fi`],
4924       [Define 0/1 if your assembler and linker support @GOT.])
4925
4926     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
4927       gcc_cv_as_ix86_gotoff_in_data,
4928       [$as_ix86_gas_32_opt],
4929 [       .text
4930 .L0:
4931         nop
4932         .data
4933         .long .L0@GOTOFF])
4934     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
4935       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
4936       [Define true if the assembler supports '.long foo@GOTOFF'.])
4937
4938     conftest_s='
4939         .section .text,"ax",@progbits
4940         .globl  _start
4941         .type   _start, @function
4942 _start:
4943         leal    ld@tlsldm(%ecx), %eax
4944         call    *___tls_get_addr@GOT(%ecx)
4945         leal    gd@tlsgd(%ecx), %eax
4946         call    *___tls_get_addr@GOT(%ecx)
4947
4948         .section .tdata,"aw'$tls_section_flag'",@progbits
4949         .type   ld, @object
4950 ld:
4951         .byte 0
4952         .globl  gd
4953         .type   gd, @object
4954 gd:
4955         .byte 0'
4956     gcc_GAS_CHECK_FEATURE([calling ___tls_get_addr via GOT],
4957         gcc_cv_as_ix86_tls_get_addr_via_got,
4958         [$as_ix86_gas_32_opt],
4959         [$conftest_s],
4960         [if test x$gcc_cv_ld != x \
4961             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4962            gcc_cv_as_ix86_tls_get_addr_via_got=yes
4963          fi
4964          rm -f conftest])
4965     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLS_GET_ADDR_GOT,
4966       [`if test x"$gcc_cv_as_ix86_tls_get_addr_via_got" = xyes; then echo 1; else echo 0; fi`],
4967       [Define 0/1 if your assembler and linker support calling ___tls_get_addr via GOT.])
4968     ;;
4969
4970   ia64*-*-*)
4971     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
4972         gcc_cv_as_ia64_ltoffx_ldxmov_relocs,,
4973 [       .text
4974         addl r15 = @ltoffx(x#), gp
4975         ;;
4976         ld8.mov r16 = [[r15]], x#
4977 ],,
4978     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
4979           [Define if your assembler supports ltoffx and ldxmov relocations.])])
4980
4981     ;;
4982
4983   powerpc*-*-*)
4984
4985     case $target in
4986       *-*-darwin*)
4987         gcc_GAS_CHECK_FEATURE([.machine directive support],
4988           gcc_cv_as_machine_directive,,
4989           [     .machine ppc7400])
4990         if test x$gcc_cv_as_machine_directive != xyes; then
4991           echo "*** This target requires an assembler supporting \".machine\"" >&2
4992           echo you can get it from: https://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
4993           test x$build = x$target && exit 1
4994         fi
4995         ;;
4996     esac
4997
4998     case $target in
4999       *-*-aix*) conftest_s='    .machine "pwr5"
5000         .csect .text[[PR]]
5001         mfcr 3,128';;
5002       *-*-darwin*) conftest_s=' .text
5003         mfcr r3,128';;
5004       *) conftest_s='   .machine power4
5005         .text
5006         mfcr 3,128';;
5007     esac
5008
5009     gcc_GAS_CHECK_FEATURE([mfcr field support],
5010       gcc_cv_as_powerpc_mfcrf,,
5011       [$conftest_s],,
5012       [AC_DEFINE(HAVE_AS_MFCRF, 1,
5013           [Define if your assembler supports mfcr field.])])
5014
5015     case $target in
5016       *-*-aix*) conftest_s='    .csect .text[[PR]]
5017 LCF..0:
5018         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
5019       *-*-darwin*)
5020         conftest_s='    .text
5021 LCF0:
5022         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
5023       *) conftest_s='   .text
5024 .LCF0:
5025         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
5026     esac
5027
5028     gcc_GAS_CHECK_FEATURE([rel16 relocs],
5029       gcc_cv_as_powerpc_rel16, -a32,
5030       [$conftest_s],,
5031       [AC_DEFINE(HAVE_AS_REL16, 1,
5032           [Define if your assembler supports R_PPC_REL16 relocs.])])
5033
5034     case $target in
5035       *-*-aix*) conftest_s='    .machine "pwr7"
5036         .csect .text[[PR]]
5037         lxvd2x 1,2,3';;
5038       *) conftest_s='   .machine power7
5039         .text
5040         lxvd2x 1,2,3';;
5041     esac
5042
5043     gcc_GAS_CHECK_FEATURE([vector-scalar support],
5044       gcc_cv_as_powerpc_vsx, -a32,
5045       [$conftest_s],,
5046       [AC_DEFINE(HAVE_AS_VSX, 1,
5047           [Define if your assembler supports VSX instructions.])])
5048
5049     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
5050       gcc_cv_as_powerpc_gnu_attribute,,
5051       [.gnu_attribute 4,1],,
5052       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
5053           [Define if your assembler supports .gnu_attribute.])])
5054
5055     gcc_GAS_CHECK_FEATURE([prologue entry point marker support],
5056       gcc_cv_as_powerpc_entry_markers,-a64 --fatal-warnings,
5057       [ .reloc .,R_PPC64_ENTRY; nop],,
5058       [AC_DEFINE(HAVE_AS_ENTRY_MARKERS, 1,
5059           [Define if your assembler supports the R_PPC64_ENTRY relocation.])])
5060
5061     gcc_GAS_CHECK_FEATURE([plt sequence marker support],
5062       gcc_cv_as_powerpc_pltseq_markers,-a32 --fatal-warnings,
5063       [ .reloc .,R_PPC_PLTSEQ; nop],,
5064       [AC_DEFINE(HAVE_AS_PLTSEQ, 1,
5065           [Define if your assembler supports R_PPC*_PLTSEQ relocations.])])
5066
5067     case $target in
5068       *-*-aix*)
5069         gcc_GAS_CHECK_FEATURE([AIX .ref support],
5070           gcc_cv_as_aix_ref,,
5071           [     .csect stuff[[rw]]
5072              stuff:
5073                 .long 1
5074                 .extern sym
5075                 .ref sym
5076           ],,
5077           [AC_DEFINE(HAVE_AS_REF, 1,
5078             [Define if your assembler supports .ref])])
5079
5080         gcc_GAS_CHECK_FEATURE([AIX DWARF location lists section support],
5081           gcc_cv_as_aix_dwloc,,
5082           [     .dwsect 0xA0000
5083         Lframe..0:
5084                 .vbyte 4,Lframe..0
5085           ],,
5086           [AC_DEFINE(HAVE_XCOFF_DWARF_EXTRAS, 1,
5087             [Define if your assembler supports AIX debug frame section label reference.])])
5088         ;;
5089     esac
5090     ;;
5091
5092   mips*-*-*)
5093     gcc_GAS_CHECK_FEATURE([explicit relocation support],
5094       gcc_cv_as_mips_explicit_relocs,,
5095 [       lw $4,%gp_rel(foo)($4)],,
5096       [if test x$target_cpu_default = x
5097        then target_cpu_default=MASK_EXPLICIT_RELOCS
5098        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
5099        fi])
5100
5101     gcc_GAS_CHECK_FEATURE([-mno-shared support],
5102       gcc_cv_as_mips_no_shared,[-mno-shared], [nop],,
5103       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
5104                  [Define if the assembler understands -mno-shared.])])
5105
5106     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
5107       gcc_cv_as_mips_gnu_attribute,,
5108       [.gnu_attribute 4,1],,
5109       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
5110           [Define if your assembler supports .gnu_attribute.])])
5111
5112     gcc_GAS_CHECK_FEATURE([.module support],
5113       gcc_cv_as_mips_dot_module,[-32],
5114       [.module mips2
5115        .module fp=xx],,
5116       [AC_DEFINE(HAVE_AS_DOT_MODULE, 1,
5117           [Define if your assembler supports .module.])])
5118     if test x$gcc_cv_as_mips_dot_module = xno \
5119        && test x$with_fp_32 != x; then
5120       AC_MSG_ERROR(
5121         [Requesting --with-fp-32= requires assembler support for .module.])
5122     fi
5123
5124     gcc_GAS_CHECK_FEATURE([.micromips support],
5125       gcc_cv_as_micromips_support,[--fatal-warnings],
5126       [.set micromips],,
5127       [AC_DEFINE(HAVE_GAS_MICROMIPS, 1,
5128           [Define if your assembler supports the .set micromips directive])])
5129
5130     gcc_GAS_CHECK_FEATURE([.dtprelword support],
5131       gcc_cv_as_mips_dtprelword,,
5132       [.section .tdata,"awT",@progbits
5133 x:
5134         .word 2
5135         .text
5136         .dtprelword x+0x8000],,
5137       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
5138           [Define if your assembler supports .dtprelword.])])
5139
5140     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
5141       gcc_cv_as_mips_dspr1_mult,,
5142 [       .set    mips32r2
5143         .set    nodspr2
5144         .set    dsp
5145         madd    $ac3,$4,$5
5146         maddu   $ac3,$4,$5
5147         msub    $ac3,$4,$5
5148         msubu   $ac3,$4,$5
5149         mult    $ac3,$4,$5
5150         multu   $ac3,$4,$5],,
5151       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
5152           [Define if your assembler supports DSPR1 mult.])])
5153
5154     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
5155     gcc_cv_as_ld_jalr_reloc=no
5156     if test $gcc_cv_as_mips_explicit_relocs = yes; then
5157       if test $in_tree_ld = yes ; then
5158         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
5159            && test $in_tree_ld_is_elf = yes; then
5160           gcc_cv_as_ld_jalr_reloc=yes
5161         fi
5162       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
5163         echo '  .ent x' > conftest.s
5164         echo 'x:        lw $2,%got_disp(y)($3)' >> conftest.s
5165         echo '  lw $25,%call16(y)($28)' >> conftest.s
5166         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
5167         echo '1:        jalr $25' >> conftest.s
5168         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
5169         echo '1:        jalr $25' >> conftest.s
5170         echo '  .end x' >> conftest.s
5171         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
5172            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
5173           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
5174              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
5175             gcc_cv_as_ld_jalr_reloc=yes
5176           fi
5177         fi
5178         rm -f conftest.*
5179       fi
5180     fi
5181     if test $gcc_cv_as_ld_jalr_reloc = yes; then
5182       if test x$target_cpu_default = x; then
5183         target_cpu_default=MASK_RELAX_PIC_CALLS
5184       else
5185         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
5186       fi
5187     fi
5188     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
5189
5190     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
5191       [gcc_cv_ld_mips_personality_relaxation],
5192       [gcc_cv_ld_mips_personality_relaxation=no
5193        if test $in_tree_ld = yes ; then
5194          if test "$gcc_cv_gld_major_version" -eq 2 \
5195                  -a "$gcc_cv_gld_minor_version" -ge 21 \
5196                  -o "$gcc_cv_gld_major_version" -gt 2; then
5197            gcc_cv_ld_mips_personality_relaxation=yes
5198          fi
5199        elif test x$gcc_cv_as != x \
5200                  -a x$gcc_cv_ld != x \
5201                  -a x$gcc_cv_readelf != x ; then
5202          cat > conftest.s <<EOF
5203         .cfi_startproc
5204         .cfi_personality 0x80,indirect_ptr
5205         .ent test
5206 test:
5207         nop
5208         .end test
5209         .cfi_endproc
5210
5211         .section .data,"aw",@progbits
5212 indirect_ptr:
5213         .dc.a personality
5214 EOF
5215          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
5216             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
5217            if $gcc_cv_readelf -d conftest 2>&1 \
5218               | grep TEXTREL > /dev/null 2>&1; then
5219              :
5220            elif $gcc_cv_readelf --relocs conftest 2>&1 \
5221                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
5222              :
5223            else
5224              gcc_cv_ld_mips_personality_relaxation=yes
5225            fi
5226          fi
5227        fi
5228        rm -f conftest.s conftest.o conftest])
5229     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
5230             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
5231       [Define if your linker can relax absolute .eh_frame personality
5232 pointers into PC-relative form.])
5233     fi
5234
5235     gcc_GAS_CHECK_FEATURE([-mnan= support],
5236       gcc_cv_as_mips_nan,
5237       [-mnan=2008],,,
5238       [AC_DEFINE(HAVE_AS_NAN, 1,
5239                  [Define if the assembler understands -mnan=.])])
5240     if test x$gcc_cv_as_mips_nan = xno \
5241        && test x$with_nan != x; then
5242       AC_MSG_ERROR(
5243         [Requesting --with-nan= requires assembler support for -mnan=])
5244     fi
5245     ;;
5246     msp430-*-*)
5247     # Earlier GAS versions generically support .gnu_attribute, but the
5248     # msp430 assembler will not do anything with it.
5249     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
5250       gcc_cv_as_msp430_gnu_attribute,,
5251       [.gnu_attribute 4,1],,
5252       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
5253           [Define if your assembler supports .gnu_attribute.])])
5254     gcc_GAS_CHECK_FEATURE([.mspabi_attribute support],
5255       gcc_cv_as_msp430_mspabi_attribute,,
5256       [.mspabi_attribute 4,2],,
5257       [AC_DEFINE(HAVE_AS_MSPABI_ATTRIBUTE, 1,
5258           [Define if your assembler supports .mspabi_attribute.])])
5259     if test x$enable_newlib_nano_formatted_io = xyes; then
5260       AC_DEFINE(HAVE_NEWLIB_NANO_FORMATTED_IO, 1, [Define if GCC has been
5261 configured with --enable-newlib-nano-formatted-io.])
5262       fi
5263     ;;
5264     nios2-*-*)
5265     # Versions 2.33 and earlier lacked support for the %gotoff relocation
5266     # syntax that is documented in the ABI specification.
5267     gcc_GAS_CHECK_FEATURE([support for %gotoff relocations in constant data],
5268       gcc_cv_as_nios2_gotoff_relocation,,
5269 [       .extern foo
5270         .data
5271         .long %gotoff(foo)],,
5272       [AC_DEFINE(HAVE_AS_NIOS2_GOTOFF_RELOCATION, 1,
5273           [Define if your assembler supports %gotoff relocation syntax.])])
5274     ;;
5275     riscv*-*-*)
5276     gcc_GAS_CHECK_FEATURE([.attribute support],
5277       gcc_cv_as_riscv_attribute,,
5278       [.attribute stack_align,4],,
5279       [AC_DEFINE(HAVE_AS_RISCV_ATTRIBUTE, 1,
5280           [Define if your assembler supports .attribute.])])
5281     gcc_GAS_CHECK_FEATURE([-misa-spec= support],
5282       gcc_cv_as_riscv_isa_spec,
5283       [-misa-spec=2.2],,,
5284       [AC_DEFINE(HAVE_AS_MISA_SPEC, 1,
5285                  [Define if the assembler understands -misa-spec=.])])
5286     gcc_GAS_CHECK_FEATURE([-march=rv32i_zifencei support],
5287       gcc_cv_as_riscv_march_zifencei,
5288       [-march=rv32i_zifencei2p0],,,
5289       [AC_DEFINE(HAVE_AS_MARCH_ZIFENCEI, 1,
5290                  [Define if the assembler understands -march=rv*_zifencei.])])
5291     ;;
5292     loongarch*-*-*)
5293     gcc_GAS_CHECK_FEATURE([.dtprelword support],
5294       gcc_cv_as_loongarch_dtprelword, [2,18,0],,
5295       [.section .tdata,"awT",@progbits
5296 x:
5297         .word 2
5298         .text
5299         .dtprelword x+0x8000],,
5300       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
5301           [Define if your assembler supports .dtprelword.])])
5302     gcc_GAS_CHECK_FEATURE([explicit relocation support],
5303       gcc_cv_as_loongarch_explicit_relocs,,
5304       [a:pcalau12i $t0,%pc_hi20(a)],,
5305       [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
5306           [Define if your assembler supports explicit relocation.])])
5307     gcc_GAS_CHECK_FEATURE([eh_frame pcrel encoding support],
5308       gcc_cv_as_loongarch_eh_frame_pcrel_encoding_support,,
5309       [.cfi_startproc
5310        .cfi_personality 0x9b,a
5311        .cfi_lsda 0x1b,b
5312        .cfi_endproc],,
5313       [AC_DEFINE(HAVE_AS_EH_FRAME_PCREL_ENCODING_SUPPORT, 1,
5314           [Define if your assembler supports eh_frame pcrel encoding.])])
5315     ;;
5316     s390*-*-*)
5317     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
5318       gcc_cv_as_s390_gnu_attribute,,
5319       [.gnu_attribute 8,1],,
5320       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
5321           [Define if your assembler supports .gnu_attribute.])])
5322     gcc_GAS_CHECK_FEATURE([.machine and .machinemode support],
5323       gcc_cv_as_s390_machine_machinemode,,
5324       [ .machinemode push
5325         .machinemode pop
5326         .machine push
5327         .machine pop],,
5328       [AC_DEFINE(HAVE_AS_MACHINE_MACHINEMODE, 1,
5329           [Define if your assembler supports .machine and .machinemode.])])
5330     gcc_GAS_CHECK_FEATURE([architecture modifiers support],
5331       gcc_cv_as_s390_architecture_modifiers,,
5332       [ .machine z13+vx ],,
5333       [AC_DEFINE(HAVE_AS_ARCHITECTURE_MODIFIERS, 1,
5334           [Define if your assembler supports architecture modifiers.])])
5335     gcc_GAS_CHECK_FEATURE([vector load/store alignment hints],
5336       gcc_cv_as_s390_vector_loadstore_alignment_hints,,
5337       [ vl %v24,0(%r15),3 ],,
5338       [AC_DEFINE(HAVE_AS_VECTOR_LOADSTORE_ALIGNMENT_HINTS, 1,
5339           [Define if your assembler supports vl/vst/vlm/vstm with an optional alignment hint argument.])])
5340     gcc_GAS_CHECK_FEATURE([vector load/store alignment hints on z13],
5341       gcc_cv_as_s390_vector_loadstore_alignment_hints_on_z13, [-mzarch -march=z13],
5342       [ vl %v24,0(%r15),3 ],,
5343       [AC_DEFINE(HAVE_AS_VECTOR_LOADSTORE_ALIGNMENT_HINTS_ON_Z13, 1,
5344           [Define if your assembler supports vl/vst/vlm/vstm with an optional alignment hint argument on z13.])])
5345
5346     ;;
5347 esac
5348
5349 # Mips, LoongArch and HP-UX need the GNU assembler.
5350 # Linux on IA64 might be able to use the Intel assembler.
5351
5352 case "$target" in
5353   mips*-*-* | loongarch*-*-* | *-*-hpux* )
5354     if test x$gas_flag = xyes \
5355        || test x"$host" != x"$build" \
5356        || test ! -x "$gcc_cv_as" \
5357        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
5358       :
5359     else
5360       echo "*** This configuration requires the GNU assembler" >&2
5361       exit 1
5362     fi
5363     ;;
5364 esac
5365
5366 # AMD GCN needs the LLVM assembler and linker.
5367 # Test that LLVM is at least 13.0.1.
5368 case "$target" in
5369   amdgcn-* | gcn-*)
5370     AC_MSG_CHECKING(llvm assembler version)
5371     gcc_cv_as_version="unknown"
5372     if test x$gcc_cv_as != x; then
5373       gcc_cv_as_version=`$gcc_cv_as --version 2>&1 | sed -ne '/version/s/.* \([[0-9]]\)/\1/p' || echo error`
5374       case "$gcc_cv_as_version" in
5375         13.0.[[1-9]]*) ;;          # 13.0.1+
5376         13.[[1-9]]*) ;;            # 13.1+
5377         1[[4-9]]*) ;;              # 14..19
5378         [[2-9]][[0-9]]*) ;;        # 20..99
5379         [[1-9]][[0-9]][[0-9]]*) ;; # 100+
5380         error) AC_MSG_ERROR([cannot determine LLVM version]) ;;
5381         *) AC_MSG_ERROR([LLVM 13.0.1 or later is required (found LLVM $gcc_cv_as_version)]) ;;
5382       esac
5383     fi
5384     AC_MSG_RESULT([$gcc_cv_as_version, ok])
5385     ;;
5386 esac
5387
5388 case "$target" in
5389   arm*)
5390     gcc_GAS_CHECK_FEATURE([assembler for arm accepts context-specific architecture extensions],
5391       gcc_cv_as_arm_option_extensions,
5392       [-march=armv8.1-m.main+mve],
5393       [.text
5394         .thumb
5395         .syntax unified
5396         vmov.f32 s0, s1],,
5397       [AC_DEFINE(HAVE_GAS_ARM_EXTENDED_ARCH, 1,
5398        [Define if your Arm assembler permits context-specific feature extensions.])])
5399 esac
5400
5401 # ??? Not all targets support dwarf2 debug_line, even within a version
5402 # of gas.  Moreover, we need to emit a valid instruction to trigger any
5403 # info to the output file.  So, as supported targets are added to gas 2.11,
5404 # add some instruction here to (also) show we expect this might work.
5405 # ??? Once 2.11 is released, probably need to add first known working
5406 # version to the per-target configury.
5407 case "$cpu_type" in
5408   aarch64 | alpha | arc | arm | avr | bfin | cris | csky | i386 | loongarch | m32c \
5409   | m68k | microblaze | mips | nds32 | nios2 | pa | riscv | rs6000 | score | sparc \
5410   | visium | xstormy16 | xtensa)
5411     insn="nop"
5412     ;;
5413   ia64 | s390)
5414     insn="nop 0"
5415     ;;
5416   mmix)
5417     insn="swym 0"
5418     ;;
5419 esac
5420 if test x"$insn" != x; then
5421  conftest_s="\
5422         .file 1 \"conftest.s\"
5423         .loc 1 3 0
5424         $insn"
5425  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
5426   gcc_cv_as_dwarf2_debug_line,,
5427   [$conftest_s],
5428   [if test x$gcc_cv_objdump != x \
5429    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
5430       | grep debug_line > /dev/null 2>&1; then
5431      gcc_cv_as_dwarf2_debug_line=yes
5432    elif test x$gcc_cv_otool != x \
5433    && $gcc_cv_otool -l conftest.o 2> /dev/null \
5434       | grep debug_line > /dev/null 2>&1; then
5435      gcc_cv_as_dwarf2_debug_line=yes
5436    fi])
5437
5438 # The .debug_line file table must be in the exact order that
5439 # we specified the files, since these indices are also used
5440 # by DW_AT_decl_file.  Approximate this test by testing if
5441 # the assembler bitches if the same index is assigned twice.
5442  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
5443   gcc_cv_as_dwarf2_file_buggy,,
5444 [       .file 1 "foo.s"
5445         .file 1 "bar.s"])
5446
5447  if test $gcc_cv_as_dwarf2_debug_line = yes \
5448  && test $gcc_cv_as_dwarf2_file_buggy = no; then
5449     AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
5450   [Define if your assembler supports dwarf2 .file/.loc directives,
5451    and preserves file table indices exactly as given.])
5452
5453     if test $gcc_cv_as_leb128 = yes; then
5454         conftest_s="\
5455         .file 1 \"conftest.s\"
5456         .loc 1 3 0 view .LVU1
5457         $insn
5458         .data
5459         .uleb128 .LVU1
5460         .uleb128 .LVU1
5461 "
5462         gcc_GAS_CHECK_FEATURE([dwarf2 debug_view support],
5463           gcc_cv_as_dwarf2_debug_view,,
5464           [$conftest_s],,
5465           [AC_DEFINE(HAVE_AS_DWARF2_DEBUG_VIEW, 1,
5466   [Define if your assembler supports views in dwarf2 .loc directives.])])
5467     fi
5468  fi
5469
5470  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
5471   gcc_cv_as_gdwarf2_flag,
5472   [--gdwarf2], [$insn],,
5473   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
5474 [Define if your assembler supports the --gdwarf2 option.])])
5475
5476  gcc_GAS_CHECK_FEATURE([--gdwarf-5 option],
5477   gcc_cv_as_gdwarf_5_flag,
5478   [--gdwarf-5], [$insn],
5479   [if test x$gcc_cv_objdump != x \
5480       && $gcc_cv_objdump -Wi conftest.o 2>&1 \
5481          | grep DW_TAG_compile_unit > /dev/null 2>&1; then
5482      gcc_cv_as_gdwarf_5_flag=yes;
5483    fi],[AC_DEFINE(HAVE_AS_GDWARF_5_DEBUG_FLAG, 1,
5484 [Define if your assembler supports the --gdwarf-5 option.])])
5485
5486  case $target_os in
5487    win32 | pe | cygwin* | mingw32*)
5488      section_flags=\"dr\"
5489      function_type=".def foo; .scl 2; .type 32; .endef"
5490      function_size="";;
5491    *)
5492      section_flags=\"\",%progbits
5493      function_type=".type foo, %function"
5494      function_size=".size foo, .-foo";;
5495  esac
5496  dwarf4_debug_info_size=0x46
5497  dwarf4_high_pc_form=7
5498  dwarf4_debug_aranges_size=0x2c
5499  dwarf4_line_sz=9
5500  for dwarf4_addr_size in 8 4; do
5501    conftest_s="\
5502         .file   \"a.c\"
5503         .text
5504 .Ltext0:
5505         .p2align 4
5506         .globl  foo
5507         $function_type
5508 foo:
5509 .LFB0:
5510 .LM1:
5511         $insn
5512 .LM2:
5513 .LFE0:
5514         $function_size
5515 .Letext0:
5516         .section        .debug_info,$section_flags
5517 .Ldebug_info0:
5518         .4byte  $dwarf4_debug_info_size
5519         .2byte  0x4
5520         .4byte  .Ldebug_abbrev0
5521         .byte   0x$dwarf4_addr_size
5522         .byte   0x1
5523         .ascii \"GNU C17\\0\"
5524         .byte   0xc
5525         .ascii \"a.c\\0\"
5526         .ascii \"/\\0\"
5527         .${dwarf4_addr_size}byte        .Ltext0
5528         .${dwarf4_addr_size}byte        .Letext0-.Ltext0
5529         .4byte  .Ldebug_line0
5530         .byte   0x2
5531         .ascii \"foo\\0\"
5532         .byte   0x1
5533         .byte   0x2
5534         .byte   0x1
5535         .${dwarf4_addr_size}byte        .LFB0
5536         .${dwarf4_addr_size}byte        .LFE0-.LFB0
5537         .byte   0x1
5538         .byte   0x9c
5539         .byte   0
5540         .section        .debug_abbrev,$section_flags
5541 .Ldebug_abbrev0:
5542         .byte   0x1
5543         .byte   0x11
5544         .byte   0x1
5545         .byte   0x25
5546         .byte   0x8
5547         .byte   0x13
5548         .byte   0xb
5549         .byte   0x3
5550         .byte   0x8
5551         .byte   0x1b
5552         .byte   0x8
5553         .byte   0x11
5554         .byte   0x1
5555         .byte   0x12
5556         .byte   0x$dwarf4_high_pc_form
5557         .byte   0x10
5558         .byte   0x17
5559         .byte   0
5560         .byte   0
5561         .byte   0x2
5562         .byte   0x2e
5563         .byte   0
5564         .byte   0x3f
5565         .byte   0x19
5566         .byte   0x3
5567         .byte   0x8
5568         .byte   0x3a
5569         .byte   0xb
5570         .byte   0x3b
5571         .byte   0xb
5572         .byte   0x39
5573         .byte   0xb
5574         .byte   0x11
5575         .byte   0x1
5576         .byte   0x12
5577         .byte   0x$dwarf4_high_pc_form
5578         .byte   0x40
5579         .byte   0x18
5580         .byte   0
5581         .byte   0
5582         .byte   0
5583         .section        .debug_aranges,$section_flags
5584         .4byte  $dwarf4_debug_aranges_size
5585         .2byte  0x2
5586         .4byte  .Ldebug_info0
5587         .byte   0x8
5588         .byte   0
5589         .2byte  0
5590         .2byte  0
5591         .${dwarf4_addr_size}byte        .Ltext0
5592         .${dwarf4_addr_size}byte        .Letext0-.Ltext0
5593         .${dwarf4_addr_size}byte        0
5594         .${dwarf4_addr_size}byte        0
5595         .section        .debug_line,$section_flags
5596 .Ldebug_line0:
5597         .4byte  .LELT0-.LSLT0
5598 .LSLT0:
5599         .2byte  0x4
5600         .4byte  .LELTP0-.LASLTP0
5601 .LASLTP0:
5602         .byte   0x1
5603         .byte   0x1
5604         .byte   0x1
5605         .byte   0xf6
5606         .byte   0xf2
5607         .byte   0xd
5608         .byte   0
5609         .byte   0x1
5610         .byte   0x1
5611         .byte   0x1
5612         .byte   0x1
5613         .byte   0
5614         .byte   0
5615         .byte   0
5616         .byte   0x1
5617         .byte   0
5618         .byte   0
5619         .byte   0x1
5620         .byte   0
5621         .ascii \"a.c\\0\"
5622         .byte   0
5623         .byte   0
5624         .byte   0
5625         .byte   0
5626 .LELTP0:
5627         .byte   0
5628         .byte   0x$dwarf4_line_sz
5629         .byte   0x2
5630         .${dwarf4_addr_size}byte        .LM1
5631         .byte   0x18
5632         .byte   0x5
5633         .byte   0x1
5634         .byte   0
5635         .byte   0x$dwarf4_line_sz
5636         .byte   0x2
5637         .${dwarf4_addr_size}byte        .LM2
5638         .byte   0x1
5639         .byte   0x5
5640         .byte   0x1
5641         .byte   0
5642         .byte   0x$dwarf4_line_sz
5643         .byte   0x2
5644         .${dwarf4_addr_size}byte        .Letext0
5645         .byte   0
5646         .byte   0x1
5647         .byte   0x1
5648 .LELT0:
5649         .section        .debug_str,$section_flags
5650         .ident  \"GCC\"
5651 "
5652    dwarf4_success=no
5653    if test $dwarf4_addr_size = 4; then
5654      gcc_GAS_CHECK_FEATURE([assembly of compiler generated 32-bit .debug_line],
5655       gcc_cv_as_debug_line_32_flag,,
5656       [$conftest_s],,
5657       [dwarf4_success=yes])
5658    else
5659      gcc_GAS_CHECK_FEATURE([assembly of compiler generated 64-bit .debug_line],
5660       gcc_cv_as_debug_line_64_flag,,
5661       [$conftest_s],,
5662       [dwarf4_success=yes])
5663    fi
5664    if test $dwarf4_success = yes; then
5665      dwarf4_success=no
5666      gcc_GAS_CHECK_FEATURE([--gdwarf-4 not refusing compiler generated .debug_line],
5667       gcc_cv_as_dwarf_4_debug_line_flag,
5668       [--gdwarf-4], [$conftest_s],,
5669       [dwarf4_success=yes])
5670      break
5671    fi
5672    dwarf4_debug_info_size=0x36
5673    dwarf4_high_pc_form=6
5674    dwarf4_debug_aranges_size=0x1c
5675    dwarf4_line_sz=5
5676  done
5677
5678  if test $dwarf4_success = yes; then
5679    conftest_s="\
5680         .file   \"foo.c\"
5681         .text
5682 bar:
5683 #APP
5684 # 82 \"xxx.h\" 1
5685         $insn
5686 # 0 \"\" 2
5687 #NO_APP
5688         $insn
5689 foo:
5690         .file 1 \"foo.c\"
5691         $insn
5692         .file 2 \"foo.h\"
5693         ret
5694 "
5695    dwarf4_success=no
5696    gcc_GAS_CHECK_FEATURE([--gdwarf-4 with the APP marker],
5697      gcc_cv_as_dwarf_4_app_flag,
5698      [--gdwarf-4], [$conftest_s],, [dwarf4_success=yes])
5699  fi
5700
5701  if test $dwarf4_success = yes; then
5702    conftest_s="\
5703         .text
5704         .globl  foo
5705         $function_type
5706 foo:
5707         $insn
5708         $function_size
5709         .file   1 \"foo.c\"
5710 "
5711    gcc_GAS_CHECK_FEATURE([working --gdwarf-4/--gdwarf-5 for all sources],
5712      gcc_cv_as_working_gdwarf_n_flag,
5713      [--gdwarf-4],
5714      [$conftest_s],
5715      [changequote(,)dnl
5716       if test x$gcc_cv_objdump != x \
5717          && $gcc_cv_objdump -W conftest.o 2>&1 \
5718                 | grep conftest.s > /dev/null 2>&1; then
5719         gcc_cv_as_working_gdwarf_n_flag=no
5720       else
5721         gcc_cv_as_working_gdwarf_n_flag=yes
5722       fi
5723       changequote([,])dnl])
5724    if test $gcc_cv_as_working_gdwarf_n_flag = yes; then
5725      AC_DEFINE(HAVE_AS_WORKING_DWARF_N_FLAG, 1,
5726 [Define if your assembler supports --gdwarf-4/--gdwarf-5 even with
5727  compiler generated .debug_line.])
5728    fi
5729  fi
5730
5731  gcc_GAS_CHECK_FEATURE([--gstabs option],
5732   gcc_cv_as_gstabs_flag,
5733   [--gstabs], [$insn],,
5734   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
5735 [Define if your assembler supports the --gstabs option.])])
5736
5737  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
5738   gcc_cv_as_debug_prefix_map_flag,
5739   [--debug-prefix-map /a=/b], [$insn],,
5740   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
5741 [Define if your assembler supports the --debug-prefix-map option.])])
5742 fi
5743
5744 gcc_GAS_CHECK_FEATURE([compressed debug sections],
5745   gcc_cv_as_compress_debug,,,
5746   [# gas compiled without zlib cannot compress debug sections and warns
5747    # about it, but still exits successfully.  So check for this, too.
5748    if $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null
5749    then
5750      gcc_cv_as_compress_debug=0
5751    # Since binutils 2.26, gas supports --compress-debug-sections=type,
5752    # defaulting to the ELF gABI format.
5753    elif $gcc_cv_as --compress-debug-sections=zlib-gnu -o conftest.o conftest.s > /dev/null 2>&1
5754    then
5755      gcc_cv_as_compress_debug=2
5756      gcc_cv_as_compress_debug_option="--compress-debug-sections"
5757      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
5758    # Before binutils 2.26, gas only supported --compress-debug-options and
5759    # emitted the traditional GNU format.
5760    elif $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s > /dev/null 2>&1
5761    then
5762      gcc_cv_as_compress_debug=1
5763      gcc_cv_as_compress_debug_option="--compress-debug-sections"
5764      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
5765    else
5766      gcc_cv_as_compress_debug=0
5767    fi])
5768 AC_DEFINE_UNQUOTED(HAVE_AS_COMPRESS_DEBUG, $gcc_cv_as_compress_debug,
5769 [Define to the level of your assembler's compressed debug section support.])
5770 AC_DEFINE_UNQUOTED(AS_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_compress_debug_option",
5771 [Define to the assembler option to enable compressed debug sections.])
5772 AC_DEFINE_UNQUOTED(AS_NO_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_no_compress_debug_option",
5773 [Define to the assembler option to disable compressed debug sections.])
5774
5775 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,,
5776 [.lcomm bar,4,16],,
5777 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
5778   [Define if your assembler supports .lcomm with an alignment field.])])
5779
5780 if test x$with_sysroot = x && test x$host = x$target \
5781    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
5782    && test "$prefix" != "NONE"; then
5783   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
5784 [Define to PREFIX/include if cpp should also search that directory.])
5785 fi
5786
5787 # Determine the version of glibc, if any, used on the target.
5788 AC_MSG_CHECKING([for target glibc version])
5789 AC_ARG_WITH([glibc-version],
5790   [AS_HELP_STRING([--with-glibc-version=M.N],
5791     [assume GCC used with glibc version M.N or later])], [
5792 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
5793   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
5794   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
5795 else
5796   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
5797 fi], [
5798 glibc_version_major=0
5799 glibc_version_minor=0
5800 [if test -f $target_header_dir/features.h \
5801   && glibc_version_major_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC__[    ]+[0-9]' $target_header_dir/features.h` \
5802   && glibc_version_minor_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+[0-9]' $target_header_dir/features.h`; then
5803   glibc_version_major=`echo "$glibc_version_major_define" | sed -e 's/.*__GLIBC__[      ]*//'`
5804   glibc_version_minor=`echo "$glibc_version_minor_define" | sed -e 's/.*__GLIBC_MINOR__[        ]*//'`
5805 fi]])
5806 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
5807 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MAJOR], [$glibc_version_major],
5808 [GNU C Library major version number used on the target, or 0.])
5809 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MINOR], [$glibc_version_minor],
5810 [GNU C Library minor version number used on the target, or 0.])
5811
5812 AC_ARG_ENABLE(gnu-unique-object,
5813  [AS_HELP_STRING([--enable-gnu-unique-object],
5814    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
5815  [case $enable_gnu_unique_object in
5816     yes | no) ;;
5817     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
5818 Valid choices are 'yes' and 'no'.]) ;;
5819   esac],
5820  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,,
5821    [.type foo, '$target_type_format_char'gnu_unique_object],,
5822 # We need to unquote above to to use the definition from config.gcc.
5823 # Also check for ld.so support, i.e. glibc 2.11 or higher.
5824    [GCC_GLIBC_VERSION_GTE_IFELSE([2], [11], [enable_gnu_unique_object=yes], )]
5825    )])
5826 if test x$enable_gnu_unique_object = xyes; then
5827   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
5828    [Define if your assembler supports @gnu_unique_object.])
5829 fi
5830
5831 AC_CACHE_CHECK([assembler for tolerance to line number 0],
5832  [gcc_cv_as_line_zero],
5833  [gcc_cv_as_line_zero=no
5834   if test "x$gcc_cv_as" != x; then
5835     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
5836     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
5837        test "x`cat conftest.out`" = x
5838     then
5839       gcc_cv_as_line_zero=yes
5840     else
5841       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
5842       cat conftest.s >&AS_MESSAGE_LOG_FD
5843       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
5844       cat conftest.out >&AS_MESSAGE_LOG_FD
5845     fi
5846     rm -f conftest.o conftest.s conftest.out
5847   fi])
5848 if test "x$gcc_cv_as_line_zero" = xyes; then
5849   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
5850 [Define if the assembler won't complain about a line such as # 0 "" 2.])
5851 fi
5852
5853 AC_MSG_CHECKING(support for thin archives)
5854 thin_archive_support=no
5855 echo 'int main (void) { return 0; }' > conftest.c
5856 if ($AR --version | sed 1q | grep "GNU ar" \
5857     && $CC $CFLAGS -c conftest.c \
5858     && $AR rcT conftest.a conftest.o \
5859     && $CC $CFLAGS $LDFLAGS -o conftest conftest.a) >/dev/null 2>&1; then
5860   thin_archive_support=yes
5861 fi
5862 rm -f conftest.c conftest.o conftest.a conftest
5863 AC_MSG_RESULT($thin_archive_support)
5864 AC_SUBST(thin_archive_support)
5865
5866 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
5867 gcc_cv_ld_eh_frame_hdr=no
5868 if test $in_tree_ld = yes ; then
5869   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
5870      && test $in_tree_ld_is_elf = yes; then
5871     gcc_cv_ld_eh_frame_hdr=yes
5872   fi
5873 elif test x$gcc_cv_ld != x; then
5874   if echo "$ld_ver" | grep GNU > /dev/null; then
5875     # Check if linker supports --eh-frame-hdr option
5876     if $gcc_cv_ld --help 2>&1 | grep eh-frame-hdr > /dev/null; then
5877       gcc_cv_ld_eh_frame_hdr=yes
5878     fi
5879   else
5880     case "$target" in
5881       *-*-solaris2*)
5882         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
5883         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
5884           gcc_cv_ld_eh_frame_hdr=yes
5885         fi
5886         ;;
5887     esac
5888   fi
5889 fi
5890 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
5891 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
5892         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
5893 [Define if your linker supports .eh_frame_hdr.])
5894 fi
5895 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
5896
5897 AC_MSG_CHECKING(linker CIEv3 in .eh_frame support)
5898 gcc_cv_ld_eh_frame_ciev3=no
5899 if test $in_tree_ld = yes ; then
5900   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
5901      && test $in_tree_ld_is_elf = yes; then
5902     gcc_cv_ld_eh_frame_ciev3=yes
5903   fi
5904 elif test x$gcc_cv_ld != x; then
5905   if echo "$ld_ver" | grep GNU > /dev/null; then
5906     gcc_cv_ld_eh_frame_ciev3=yes
5907     if test 0"$ld_date" -lt 20040513; then
5908       if test -n "$ld_date"; then
5909         # If there was date string, but was earlier than 2004-05-13, fail
5910         gcc_cv_ld_eh_frame_ciev3=no
5911       elif test "$ld_vers_major" -lt 2; then
5912         gcc_cv_ld_eh_frame_ciev3=no
5913       elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
5914         gcc_cv_ld_eh_frame_ciev3=no
5915       fi
5916     fi
5917   else
5918     case "$target" in
5919       *-*-solaris2*)
5920         # Sun ld added support for CIE v3 in .eh_frame in Solaris 11.1.
5921         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2324; then
5922           gcc_cv_ld_eh_frame_ciev3=yes
5923         fi
5924         ;;
5925     esac
5926   fi
5927 fi
5928 AC_DEFINE_UNQUOTED(HAVE_LD_EH_FRAME_CIEV3,
5929   [`if test x"$gcc_cv_ld_eh_frame_ciev3" = xyes; then echo 1; else echo 0; fi`],
5930   [Define 0/1 if your linker supports CIE v3 in .eh_frame.])
5931 AC_MSG_RESULT($gcc_cv_ld_eh_frame_ciev3)
5932
5933 AC_MSG_CHECKING(linker position independent executable support)
5934 gcc_cv_ld_pie=no
5935 if test $in_tree_ld = yes ; then
5936   case "$target" in
5937     # Full PIE support on Solaris was only introduced in gld 2.26.
5938     *-*-solaris2*)  gcc_gld_pie_min_version=26 ;;
5939     *)              gcc_gld_pie_min_version=15 ;;
5940   esac
5941   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge "$gcc_gld_pie_min_version" -o "$gcc_cv_gld_major_version" -gt 2 \
5942      && test $in_tree_ld_is_elf = yes; then
5943     gcc_cv_ld_pie=yes
5944   fi
5945 elif test x$gcc_cv_ld != x; then
5946   # Check if linker supports -pie option
5947   if $gcc_cv_ld --help 2>&1 | grep -- -pie > /dev/null; then
5948     gcc_cv_ld_pie=yes
5949     case "$target" in
5950       *-*-solaris2*)
5951         if echo "$ld_ver" | grep GNU > /dev/null \
5952           && test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5953           gcc_cv_ld_pie=no
5954         fi
5955         ;;
5956     esac
5957   else
5958     case "$target" in
5959       *-*-solaris2.1[[1-9]]*)
5960         # Solaris 11.3 added PIE support.
5961         if $gcc_cv_ld -z help 2>&1 | grep -- type.*pie > /dev/null; then
5962           gcc_cv_ld_pie=yes
5963         fi
5964         ;;
5965     esac
5966   fi
5967 fi
5968 if test x"$gcc_cv_ld_pie" = xyes; then
5969         AC_DEFINE(HAVE_LD_PIE, 1,
5970 [Define if your linker supports PIE option.])
5971 fi
5972 AC_MSG_RESULT($gcc_cv_ld_pie)
5973
5974 AC_MSG_CHECKING(linker PIE support with copy reloc)
5975 gcc_cv_ld_pie_copyreloc=no
5976 if test $gcc_cv_ld_pie = yes ; then
5977   if test $in_tree_ld = yes ; then
5978     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
5979       gcc_cv_ld_pie_copyreloc=yes
5980     fi
5981   elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5982     # Check if linker supports -pie option with copy reloc
5983     case "$target" in
5984     i?86-*-linux* | x86_64-*-linux*)
5985       cat > conftest1.s <<EOF
5986         .globl  a_glob
5987         .data
5988         .type   a_glob, @object
5989         .size   a_glob, 4
5990 a_glob:
5991         .long   2
5992 EOF
5993       cat > conftest2.s <<EOF
5994         .text
5995         .globl  main
5996         .type   main, @function
5997 main:
5998         movl    %eax, a_glob(%rip)
5999         .size   main, .-main
6000         .globl  ptr
6001         .section        .data.rel,"aw",@progbits
6002         .type   ptr, @object
6003 ptr:
6004         .quad   a_glob
6005 EOF
6006       if $gcc_cv_as --64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
6007          && $gcc_cv_ld -shared -melf_x86_64 -o conftest1.so conftest1.o > /dev/null 2>&1 \
6008          && $gcc_cv_as --64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
6009          && $gcc_cv_ld -pie -melf_x86_64 -o conftest conftest2.o conftest1.so > /dev/null 2>&1; then
6010         gcc_cv_ld_pie_copyreloc=yes
6011       fi
6012       rm -f conftest conftest1.so conftest1.o conftest2.o conftest1.s conftest2.s
6013       ;;
6014     esac
6015   fi
6016 fi
6017 AC_DEFINE_UNQUOTED(HAVE_LD_PIE_COPYRELOC,
6018   [`if test x"$gcc_cv_ld_pie_copyreloc" = xyes; then echo 1; else echo 0; fi`],
6019   [Define 0/1 if your linker supports -pie option with copy reloc.])
6020 AC_MSG_RESULT($gcc_cv_ld_pie_copyreloc)
6021
6022 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
6023 gcc_cv_ld_eh_gc_sections=no
6024 if test $in_tree_ld = yes ; then
6025   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
6026      && test $in_tree_ld_is_elf = yes; then
6027     gcc_cv_ld_eh_gc_sections=yes
6028   fi
6029 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
6030   cat > conftest.s <<EOF
6031         .section        .text
6032 .globl _start
6033         .type _start, @function
6034 _start:
6035         .long foo
6036         .size _start, .-_start
6037         .section        .text.foo,"ax",@progbits
6038         .type foo, @function
6039 foo:
6040         .long 0
6041         .size foo, .-foo
6042         .section        .gcc_except_table.foo,"a",@progbits
6043 .L0:
6044         .long 0
6045         .section        .eh_frame,"a",@progbits
6046         .long .L0
6047 EOF
6048   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
6049     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
6050          | grep "gc-sections option ignored" > /dev/null; then
6051       gcc_cv_ld_eh_gc_sections=no
6052     elif $gcc_cv_objdump -h conftest 2> /dev/null \
6053          | grep gcc_except_table > /dev/null; then
6054       gcc_cv_ld_eh_gc_sections=yes
6055       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
6056       if test x$gcc_cv_as_comdat_group != xyes; then
6057         gcc_cv_ld_eh_gc_sections=no
6058         cat > conftest.s <<EOF
6059         .section        .text
6060 .globl _start
6061         .type _start, @function
6062 _start:
6063         .long foo
6064         .size _start, .-_start
6065         .section        .gnu.linkonce.t.foo,"ax",@progbits
6066         .type foo, @function
6067 foo:
6068         .long 0
6069         .size foo, .-foo
6070         .section        .gcc_except_table.foo,"a",@progbits
6071 .L0:
6072         .long 0
6073         .section        .eh_frame,"a",@progbits
6074         .long .L0
6075 EOF
6076         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
6077           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
6078                | grep "gc-sections option ignored" > /dev/null; then
6079             gcc_cv_ld_eh_gc_sections=no
6080           elif $gcc_cv_objdump -h conftest 2> /dev/null \
6081                | grep gcc_except_table > /dev/null; then
6082             gcc_cv_ld_eh_gc_sections=yes
6083           fi
6084         fi
6085       fi
6086     fi
6087   fi
6088   rm -f conftest.s conftest.o conftest
6089 fi
6090 case "$target" in
6091   hppa*-*-linux*)
6092     # ??? This apparently exposes a binutils bug with PC-relative relocations.
6093     gcc_cv_ld_eh_gc_sections=no
6094     ;;
6095 esac
6096 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
6097         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
6098   [Define if your linker supports garbage collection of
6099    sections in presence of EH frames.])
6100 fi
6101 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
6102
6103 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
6104 gcc_cv_ld_eh_gc_sections_bug=no
6105 if test $in_tree_ld = yes ; then
6106   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
6107      && test $in_tree_ld_is_elf = yes; then
6108     gcc_cv_ld_eh_gc_sections_bug=yes
6109   fi
6110 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
6111   gcc_cv_ld_eh_gc_sections_bug=yes
6112   cat > conftest.s <<EOF
6113         .section        .text
6114 .globl _start
6115         .type _start, @function
6116 _start:
6117         .long foo
6118         .size _start, .-_start
6119         .section        .text.startup.foo,"ax",@progbits
6120         .type foo, @function
6121 foo:
6122         .long 0
6123         .size foo, .-foo
6124         .section        .gcc_except_table.foo,"a",@progbits
6125 .L0:
6126         .long 0
6127         .section        .eh_frame,"a",@progbits
6128         .long .L0
6129 EOF
6130   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
6131     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
6132          | grep "gc-sections option ignored" > /dev/null; then
6133       :
6134     elif $gcc_cv_objdump -h conftest 2> /dev/null \
6135          | grep gcc_except_table > /dev/null; then
6136       gcc_cv_ld_eh_gc_sections_bug=no
6137     fi
6138   fi
6139   rm -f conftest.s conftest.o conftest
6140 fi
6141 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
6142         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
6143   [Define if your linker has buggy garbage collection of
6144    sections support when .text.startup.foo like sections are used.])
6145 fi
6146 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
6147
6148 AC_MSG_CHECKING(linker for compressed debug sections)
6149 # gold/gld support compressed debug sections since binutils 2.19/2.21
6150 # In binutils 2.26, gld gained support for the ELF gABI format.
6151 if test $in_tree_ld = yes ; then
6152   gcc_cv_ld_compress_debug=0
6153   if test $ld_is_mold = yes; then
6154     gcc_cv_ld_compress_debug=3
6155     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6156   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 19 -o "$gcc_cv_gld_major_version" -gt 2 \
6157      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = yes; then
6158     gcc_cv_ld_compress_debug=2
6159     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6160   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 26 -o "$gcc_cv_gld_major_version" -gt 2 \
6161      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = no; then
6162     gcc_cv_ld_compress_debug=3
6163     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6164   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2 \
6165      && test $in_tree_ld_is_elf = yes; then
6166     gcc_cv_ld_compress_debug=1
6167   fi
6168 elif echo "$ld_ver" | grep GNU > /dev/null; then
6169   if test $ld_is_mold = yes; then
6170     gcc_cv_ld_compress_debug=3
6171     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6172   elif test "$ld_vers_major" -lt 2 \
6173      || test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 21; then
6174     gcc_cv_ld_compress_debug=0
6175   elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
6176     gcc_cv_ld_compress_debug=1
6177   else
6178     gcc_cv_ld_compress_debug=3
6179     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6180   fi
6181   if test $ld_is_gold = yes; then
6182     gcc_cv_ld_compress_debug=2
6183     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
6184   fi
6185 else
6186 changequote(,)dnl
6187   case "${target}" in
6188     *-*-solaris2*)
6189       # Introduced in Solaris 11.2.
6190       if $gcc_cv_ld --help 2>&1 | grep -- '-z compress-sections' > /dev/null; then
6191         gcc_cv_ld_compress_debug=3
6192         gcc_cv_ld_compress_debug_option="-z compress-sections"
6193       else
6194         gcc_cv_ld_compress_debug=0
6195       fi
6196       ;;
6197     *)
6198       # Assume linkers other than GNU ld don't support compessed debug
6199       # sections.
6200       gcc_cv_ld_compress_debug=0
6201       ;;
6202   esac
6203 changequote([,])dnl
6204 fi
6205 AC_DEFINE_UNQUOTED(HAVE_LD_COMPRESS_DEBUG, $gcc_cv_ld_compress_debug,
6206 [Define to the level of your linker's compressed debug section support.])
6207 AC_DEFINE_UNQUOTED(LD_COMPRESS_DEBUG_OPTION, "$gcc_cv_ld_compress_debug_option",
6208 [Define to the linker option to enable compressed debug sections.])
6209 AC_MSG_RESULT($gcc_cv_ld_compress_debug)
6210
6211 if test x"$ld64_flag" = x"yes"; then
6212
6213   # Set defaults for possibly untestable items.
6214   gcc_cv_ld64_export_dynamic=0
6215   gcc_cv_ld64_platform_version=0
6216
6217   if test "$build" = "$host"; then
6218     darwin_try_test=1
6219   else
6220     darwin_try_test=0
6221   fi
6222
6223   # On Darwin, because of FAT library support, it is often possible to execute
6224   # exes from compatible archs even when the host differs from the build system.
6225   case "$build","$host" in
6226     x86_64-*-darwin*,i?86-*-darwin* | powerpc64*-*-darwin*,powerpc*-*-darwin*)
6227         darwin_try_test=1;;
6228     *) ;;
6229   esac
6230
6231   # If the configurer specified a minimum ld64 version to be supported, then use
6232   # that to determine feature support.
6233   if test x"${gcc_cv_ld64_version}" != x; then
6234     AC_MSG_CHECKING(ld64 specified version)
6235     gcc_cv_ld64_major=`echo "$gcc_cv_ld64_version" | sed -e 's/\..*//'`
6236     AC_MSG_RESULT($gcc_cv_ld64_major)
6237     if test "$gcc_cv_ld64_major" -ge 236; then
6238       gcc_cv_ld64_export_dynamic=1
6239     fi
6240     if test "$gcc_cv_ld64_major" -ge 512; then
6241       gcc_cv_ld64_platform_version=1
6242     fi
6243   elif test -x "$gcc_cv_ld" -a "$darwin_try_test" -eq 1; then
6244     # If the version was not specified, try to find it.
6245     AC_MSG_CHECKING(linker version)
6246     if test x"${gcc_cv_ld64_version}" = x; then
6247       gcc_cv_ld64_version=`$gcc_cv_ld -v 2>&1 | grep ld64 | sed s/.*ld64-// | awk '{print $1}'`
6248     fi
6249     AC_MSG_RESULT($gcc_cv_ld64_version)
6250
6251     AC_MSG_CHECKING(linker for -export_dynamic support)
6252     gcc_cv_ld64_export_dynamic=1
6253     if $gcc_cv_ld -export_dynamic < /dev/null 2>&1 | grep 'unknown option' > /dev/null; then
6254       gcc_cv_ld64_export_dynamic=0
6255     fi
6256     AC_MSG_RESULT($gcc_cv_ld64_export_dynamic)
6257
6258     AC_MSG_CHECKING(linker for -platform_version support)
6259     gcc_cv_ld64_platform_version=1
6260     if $gcc_cv_ld -platform_version macos 10.5 0.0 < /dev/null 2>&1 | grep 'unknown option' > /dev/null; then
6261       gcc_cv_ld64_platform_version=0
6262     fi
6263     AC_MSG_RESULT($gcc_cv_ld64_platform_version)
6264   fi
6265
6266   if test x"${gcc_cv_ld64_version}" != x; then
6267     AC_DEFINE_UNQUOTED(LD64_VERSION, "${gcc_cv_ld64_version}",
6268       [Define to ld64 version.])
6269   fi
6270
6271   AC_DEFINE_UNQUOTED(LD64_HAS_EXPORT_DYNAMIC, $gcc_cv_ld64_export_dynamic,
6272   [Define to 1 if ld64 supports '-export_dynamic'.])
6273
6274   AC_DEFINE_UNQUOTED(LD64_HAS_PLATFORM_VERSION, $gcc_cv_ld64_platform_version,
6275   [Define to 1 if ld64 supports '-platform_version'.])
6276 fi
6277
6278 if test x"$dsymutil_flag" = x"yes"; then
6279
6280     # If the user specified a dsymutil path, then we will already have the
6281     # version string, otherwise, pick it up.
6282     if test x"$gcc_cv_dsymutil" = x; then
6283         AC_MSG_WARN([dsymutil is a required tool for this system, but not found])
6284         dsymutil_vers="tool unspecified"
6285     elif test x"$dsymutil_vers" = x; then
6286         dsymutil_vers=`$gcc_cv_dsymutil -v /dev/null 2>&1`
6287     fi
6288
6289     dsymutil_temp=`echo $dsymutil_vers | sed 1q`
6290     AC_MSG_CHECKING(dsymutil version "$dsymutil_temp")
6291     if echo $dsymutil_temp | grep dwarfutils- > /dev/null; then
6292       dsymutil_kind=DWARFUTILS
6293       dsymutil_vers=`echo $dsymutil_temp | sed 's/.*dwarfutils-\([[0-9\.]]*\).*/\1/'`
6294     elif echo $dsymutil_temp | grep clang- > /dev/null; then
6295       dsymutil_kind=CLANG
6296       dsymutil_vers=`echo $dsymutil_temp | sed 's/.*clang-\([[0-9\.]]*\).*/\1/'`
6297     elif echo $dsymutil_temp | grep 'LLVM version ' > /dev/null; then
6298       dsymutil_kind=LLVM
6299       dsymutil_vers=`echo $dsymutil_temp | sed 's/.*LLVM\ version\ \([[0-9\.]]*\).*/\1/'`
6300     else
6301       dsymutil_kind=UNKNOWN
6302       dsymutil_vers="0.0"
6303     fi
6304     dsymutil_major=`expr "$dsymutil_vers" : '\([[0-9]]*\)'`
6305     dsymutil_minor=`expr "$dsymutil_vers" : '[[0-9]]*\.\([[0-9]]*\)'`
6306     dsymutil_tiny=`expr "$dsymutil_vers" : '[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)'`
6307     if test x"${dsymutil_minor}" = x; then
6308       dsymutil_minor=0
6309     fi
6310     if test x"${dsymutil_tiny}" = x; then
6311       dsymutil_tiny=0
6312     fi
6313     AC_DEFINE_UNQUOTED(DSYMUTIL_VERSION, [$dsymutil_kind,${dsymutil_major},${dsymutil_minor},${dsymutil_tiny}],
6314         [Define to the dsymutil version.])
6315     AC_MSG_RESULT($dsymutil_vers : $dsymutil_kind ${dsymutil_major} ${dsymutil_minor} ${dsymutil_tiny} )
6316 fi
6317
6318 case $target_os in
6319   win32 | pe | cygwin* | mingw32*)
6320     AC_MSG_CHECKING(broken PE linker dwarf5 support)
6321     gcc_cv_ld_broken_pe_dwarf5=yes
6322     if test $in_tree_ld = yes ; then
6323       if grep -q '\.debug_loclists.*BLOCK.*__section_alignment__.*NOLOAD.*:' \
6324            $gcc_cv_ld_gld_srcdir/scripttempl/pe*.sc \
6325          && grep -q '\.debug_rnglists.*BLOCK.*__section_alignment__.*NOLOAD.*:' \
6326               $gcc_cv_ld_gld_srcdir/scripttempl/pe*.sc; then
6327         gcc_cv_ld_broken_pe_dwarf5=no
6328       fi
6329     else
6330       if $gcc_cv_ld --verbose 2>&1 | grep -q '\.debug_loclists.*BLOCK.*__section_alignment__.*NOLOAD.*:' \
6331          && $gcc_cv_ld --verbose 2>&1 | grep -q '\.debug_rnglists.*BLOCK.*__section_alignment__.*NOLOAD.*:'; then
6332         gcc_cv_ld_broken_pe_dwarf5=no
6333       fi
6334     fi
6335     if test x$gcc_cv_ld_broken_pe_dwarf5 = xyes; then
6336       AC_DEFINE(HAVE_LD_BROKEN_PE_DWARF5, 1,
6337                 [Define if the PE linker has broken DWARF 5 support.])
6338     fi
6339     AC_MSG_RESULT($gcc_cv_ld_broken_pe_dwarf5)
6340
6341     AC_MSG_CHECKING(PE linker --disable-dynamicbase support)
6342     gcc_cv_ld_disable_dynamicbase=no
6343     if test $in_tree_ld = yes; then
6344       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 36 -o "$gcc_cv_gld_major_version" -gt 2; then \
6345         gcc_cv_ld_disable_dynamicbase=yes
6346       fi
6347     else
6348       if $gcc_cv_ld --help 2>&1 | grep -q 'disable\-]dynamicbase' > /dev/null; then
6349         gcc_cv_ld_disable_dynamicbase=yes
6350       fi
6351     fi
6352     if test x"$gcc_cv_ld_disable_dynamicbase" = xyes; then
6353       AC_DEFINE(HAVE_LD_PE_DISABLE_DYNAMICBASE, 1,
6354                 [Define if the PE linker supports --disable-dynamicbase option.])
6355     fi
6356     AC_MSG_RESULT($gcc_cv_ld_disable_dynamicbase)
6357     ;;
6358 esac
6359
6360 # --------
6361 # UNSORTED
6362 # --------
6363
6364 AC_CACHE_CHECK(linker --as-needed support,
6365 gcc_cv_ld_as_needed,
6366 [gcc_cv_ld_as_needed=no
6367 gcc_cv_ld_as_needed_option='--as-needed'
6368 gcc_cv_ld_no_as_needed_option='--no-as-needed'
6369 if test $in_tree_ld = yes ; then
6370   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
6371      && test $in_tree_ld_is_elf = yes; then
6372     gcc_cv_ld_as_needed=yes
6373     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 28; then
6374       gcc_cv_ld_as_needed_option='--push-state --as-needed'
6375       gcc_cv_ld_no_as_needed_option='--pop-state'
6376     fi
6377   fi
6378 elif test x$gcc_cv_ld != x; then
6379   # Check if linker supports --as-needed and --no-as-needed options
6380   if $gcc_cv_ld --help 2>&1 | grep as-needed > /dev/null; then
6381     gcc_cv_ld_as_needed=yes
6382     if $gcc_cv_ld --help 2>&1 | grep push-state > /dev/null \
6383        && $gcc_cv_ld --help 2>&1 | grep pop-state > /dev/null \
6384        && echo "$ld_ver" | grep GNU > /dev/null \
6385        && test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 28; then
6386       # Use these options only when both ld.bfd and ld.gold support
6387       # --push-state/--pop-state, which unfortunately wasn't added
6388       # at the same time.
6389       gcc_cv_ld_as_needed_option='--push-state --as-needed'
6390       gcc_cv_ld_no_as_needed_option='--pop-state'
6391     fi
6392   fi
6393   case "$target:$gnu_ld" in
6394     *-*-solaris2*:no)
6395       # Solaris 2 ld always supports -z ignore/-z record.  Prefer the native
6396       # forms.
6397       gcc_cv_ld_as_needed=yes
6398       gcc_cv_ld_as_needed_option="-z ignore"
6399       gcc_cv_ld_no_as_needed_option="-z record"
6400       ;;
6401   esac
6402 fi
6403 # --as-needed/-z ignore can only be used if libgcc_s.so.1 uses
6404 # dl_iterate_phdr, i.e. since Solaris 11.
6405 case "$target" in
6406   *-*-solaris2.1[[1-9]]*)
6407     case "$target" in
6408     i?86-*-* | x86_64-*-*)
6409       if echo "$ld_ver" | grep GNU > /dev/null; then
6410         # Doesn't work with gld on Solaris/x86 due to PR ld/12320.
6411         gcc_cv_ld_as_needed=no
6412       fi
6413       ;;
6414     esac
6415     ;;
6416   *-*-solaris2*)
6417     gcc_cv_ld_as_needed=no
6418     ;;
6419 esac
6420 ])
6421 if test x"$gcc_cv_ld_as_needed" = xyes; then
6422         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
6423 [Define if your linker supports --as-needed/--no-as-needed or equivalent options.])
6424         AC_DEFINE_UNQUOTED(LD_AS_NEEDED_OPTION, "$gcc_cv_ld_as_needed_option",
6425 [Define to the linker option to ignore unused dependencies.])
6426         AC_DEFINE_UNQUOTED(LD_NO_AS_NEEDED_OPTION, "$gcc_cv_ld_no_as_needed_option",
6427 [Define to the linker option to keep unused dependencies.])
6428 fi
6429
6430 AC_MSG_CHECKING(linker mapfile support for clearing hardware capabilities)
6431 saved_LDFLAGS="$LDFLAGS"
6432 for clearcap_map in sol2-clearcapv2.map sol2-clearcap.map; do
6433   LDFLAGS="$saved_LDFLAGS -Wl,-M,${srcdir}/config/$clearcap_map"
6434   AC_LINK_IFELSE([AC_LANG_SOURCE([int main(void) {return 0;}])],
6435     [gcc_cv_ld_clearcap=yes; break], [gcc_cv_ld_clearcap=no])
6436 done
6437 LDFLAGS="$saved_LDFLAGS"
6438 if test "x$gcc_cv_ld_clearcap" = xyes; then
6439   AC_DEFINE([HAVE_LD_CLEARCAP], 1,
6440 [Define if the linker supports clearing hardware capabilities via mapfile.])
6441   AC_CONFIG_LINKS([clearcap.map:${srcdir}/config/$clearcap_map])
6442 fi
6443 AC_MSG_RESULT($gcc_cv_ld_clearcap)
6444
6445 case "$target" in
6446   powerpc*-*-*)
6447     case "$target" in
6448       *le-*-linux*)
6449         emul_name="-melf32lppc"
6450         ;;
6451       *)
6452         emul_name="-melf32ppc"
6453         ;;
6454     esac
6455     AC_CACHE_CHECK(linker .gnu.attributes long double support,
6456     gcc_cv_ld_ppc_attr,
6457     [gcc_cv_ld_ppc_attr=no
6458     if test x"$ld_is_gold" = xyes; then
6459       gcc_cv_ld_ppc_attr=yes
6460     elif test $in_tree_ld = yes ; then
6461       if test "$gcc_cv_gld_major_version" -eq 2 \
6462                 -a "$gcc_cv_gld_minor_version" -ge 28 \
6463                 -o "$gcc_cv_gld_major_version" -gt 2; then
6464         gcc_cv_ld_ppc_attr=yes
6465       fi
6466     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
6467       # check that merging the long double .gnu_attribute doesn't warn
6468       cat > conftest1.s <<EOF
6469         .gnu_attribute 4,1
6470 EOF
6471       cat > conftest2.s <<EOF
6472         .gnu_attribute 4,9
6473 EOF
6474       if $gcc_cv_as -a32 -o conftest1.o conftest1.s > /dev/null 2>&1 \
6475          && $gcc_cv_as -a32 -o conftest2.o conftest2.s > /dev/null 2>&1 \
6476          && $gcc_cv_ld $emul_name -r -o conftest.o conftest1.o conftest2.o > /dev/null 2> conftest.err \
6477          && test ! -s conftest.err; then
6478         gcc_cv_ld_ppc_attr=yes
6479       fi
6480       rm -f conftest.err conftest.o conftest1.o conftest2.o conftest1.s conftest2.s
6481     fi
6482     ])
6483     if test x$gcc_cv_ld_ppc_attr = xyes; then
6484       AC_DEFINE(HAVE_LD_PPC_GNU_ATTR_LONG_DOUBLE, 1,
6485     [Define if your PowerPC linker has .gnu.attributes long double support.])
6486     fi
6487     ;;
6488 esac
6489
6490 case "$target:$tm_file" in
6491   powerpc64*-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
6492   case "$target" in
6493      *le-*-linux*)
6494      emul_name="-melf64lppc"
6495       ;;
6496      *-*-linux*)
6497      emul_name="-melf64ppc"
6498       ;;
6499      *le-*-freebsd*)
6500      emul_name="-melf64lppc_fbsd"
6501       ;;
6502      *-*-freebsd*)
6503      emul_name="-melf64ppc_fbsd"
6504       ;;
6505   esac
6506     AC_CACHE_CHECK(linker support for omitting dot symbols,
6507     gcc_cv_ld_no_dot_syms,
6508     [gcc_cv_ld_no_dot_syms=no
6509     if test x"$ld_is_gold" = xyes; then
6510       gcc_cv_ld_no_dot_syms=yes
6511     elif test $in_tree_ld = yes ; then
6512       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
6513         gcc_cv_ld_no_dot_syms=yes
6514       fi
6515     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
6516       cat > conftest1.s <<EOF
6517         .text
6518         bl .foo
6519 EOF
6520       cat > conftest2.s <<EOF
6521         .section ".opd","aw"
6522         .align 3
6523         .globl foo
6524         .type foo,@function
6525 foo:
6526         .quad .LEfoo,.TOC.@tocbase,0
6527         .text
6528 .LEfoo:
6529         blr
6530         .size foo,.-.LEfoo
6531 EOF
6532       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
6533          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
6534          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
6535         gcc_cv_ld_no_dot_syms=yes
6536       fi
6537       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
6538     fi
6539     ])
6540     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
6541       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
6542     [Define if your PowerPC64 linker only needs function descriptor syms.])
6543     fi
6544
6545     AC_CACHE_CHECK(linker large toc support,
6546     gcc_cv_ld_large_toc,
6547     [gcc_cv_ld_large_toc=no
6548     if test x"$ld_is_gold" = xyes; then
6549       gcc_cv_ld_large_toc=yes
6550     elif test $in_tree_ld = yes ; then
6551       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
6552         gcc_cv_ld_large_toc=yes
6553       fi
6554     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
6555       cat > conftest.s <<EOF
6556         .section ".tbss","awT",@nobits
6557         .align 3
6558 ie0:    .space 8
6559         .global _start
6560         .text
6561 _start:
6562         addis 9,13,ie0@got@tprel@ha
6563         ld 9,ie0@got@tprel@l(9)
6564 EOF
6565       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
6566          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
6567         gcc_cv_ld_large_toc=yes
6568       fi
6569       rm -f conftest conftest.o conftest.s
6570     fi
6571     ])
6572     if test x"$gcc_cv_ld_large_toc" = xyes; then
6573       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
6574     [Define if your PowerPC64 linker supports a large TOC.])
6575     fi
6576
6577     AC_CACHE_CHECK(linker toc pointer alignment,
6578     gcc_cv_ld_toc_align,
6579     [if test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_nm != x; then
6580       cat > conftest.s <<EOF
6581         .global _start
6582         .text
6583 _start:
6584         addis 9,2,x@got@ha
6585         .section .data.rel.ro,"aw",@progbits
6586         .p2align 16
6587         .space 32768
6588 x:      .quad .TOC.
6589 EOF
6590       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
6591          && $gcc_cv_ld $emul_name -z norelro -o conftest conftest.o > /dev/null 2>&1; then
6592         gcc_cv_ld_toc_align=`$gcc_cv_nm conftest | ${AWK} '/\.TOC\./ { match ($0, "0[[[:xdigit:]]]*", a); print strtonum ("0x" substr(a[[0]], length(a[[0]])-3)) }'`
6593       fi
6594       rm -f conftest conftest.o conftest.s
6595     fi
6596     ])
6597     if test -n "$gcc_cv_ld_toc_align" && test $gcc_cv_ld_toc_align -gt 8; then
6598       AC_DEFINE_UNQUOTED(POWERPC64_TOC_POINTER_ALIGNMENT, $gcc_cv_ld_toc_align,
6599     [Define to .TOC. alignment forced by your linker.])
6600     fi
6601     ;;
6602 esac
6603
6604 case "$target" in
6605   *-*-aix*)
6606     AC_CACHE_CHECK(linker large toc support,
6607     gcc_cv_ld_large_toc,
6608     [gcc_cv_ld_large_toc=no
6609     if test x$gcc_cv_as != x ; then
6610       cat > conftest.s <<EOF
6611         .toc
6612 LC..1:
6613         .tc a[[TC]],a[[RW]]
6614         .extern a[[RW]]
6615         .csect .text[[PR]]
6616 .largetoctest:
6617         addis 9,LC..1@u(2)
6618         ld 3,LC..1@l(9)
6619 EOF
6620       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1; then
6621         gcc_cv_ld_large_toc=yes
6622       fi
6623       rm -f conftest conftest.o conftest.s
6624     fi
6625     ])
6626     if test x"$gcc_cv_ld_large_toc" = xyes; then
6627       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
6628     [Define if your PowerPC64 linker supports a large TOC.])
6629     fi
6630     ;;
6631 esac
6632
6633 AC_CACHE_CHECK(linker --build-id support,
6634   gcc_cv_ld_buildid,
6635   [gcc_cv_ld_buildid=no
6636   if test $in_tree_ld = yes ; then
6637     if test "$gcc_cv_gld_major_version" -eq 2 -a \
6638        "$gcc_cv_gld_minor_version" -ge 18 -o \
6639        "$gcc_cv_gld_major_version" -gt 2 \
6640        && test $in_tree_ld_is_elf = yes; then
6641       gcc_cv_ld_buildid=yes
6642     fi
6643   elif test x$gcc_cv_ld != x; then
6644     if $gcc_cv_ld --help 2>&1 | grep build-id > /dev/null; then
6645       gcc_cv_ld_buildid=yes
6646     fi
6647   fi])
6648 if test x"$gcc_cv_ld_buildid" = xyes; then
6649   AC_DEFINE(HAVE_LD_BUILDID, 1,
6650   [Define if your linker supports --build-id.])
6651 fi
6652
6653 AC_ARG_ENABLE(linker-build-id,
6654 [AS_HELP_STRING([--enable-linker-build-id],
6655                 [compiler will always pass --build-id to linker])],
6656 [],
6657 enable_linker_build_id=no)
6658
6659 if test x"$enable_linker_build_id" = xyes; then
6660   if test x"$gcc_cv_ld_buildid" = xyes; then
6661     AC_DEFINE(ENABLE_LD_BUILDID, 1,
6662     [Define if gcc should always pass --build-id to linker.])
6663   else
6664     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
6665   fi
6666 fi
6667
6668 # In binutils 2.21, GNU ld gained support for new emulations fully
6669 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
6670 AC_CACHE_CHECK(linker *_sol2 emulation support,
6671   gcc_cv_ld_sol2_emulation,
6672   [gcc_cv_ld_sol2_emulation=no
6673   if test $in_tree_ld = yes ; then
6674     if test "$gcc_cv_gld_major_version" -eq 2 -a \
6675        "$gcc_cv_gld_minor_version" -ge 21 -o \
6676        "$gcc_cv_gld_major_version" -gt 2 \
6677        && test $in_tree_ld_is_elf = yes; then
6678       gcc_cv_ld_sol2_emulation=yes
6679     fi
6680   elif test x$gcc_cv_ld != x; then
6681     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
6682        grep _sol2 > /dev/null; then
6683       gcc_cv_ld_sol2_emulation=yes
6684     fi
6685   fi])
6686 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
6687   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
6688   [Define if your linker supports the *_sol2 emulations.])
6689 fi
6690
6691 AC_CACHE_CHECK(linker --sysroot support,
6692   gcc_cv_ld_sysroot,
6693   [gcc_cv_ld_sysroot=no
6694   if test $in_tree_ld = yes ; then
6695       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
6696         gcc_cv_ld_sysroot=yes
6697       fi
6698   elif test x$gcc_cv_ld != x; then
6699     if $gcc_cv_ld --help 2>&1 | grep sysroot > /dev/null; then
6700       gcc_cv_ld_sysroot=yes
6701     fi
6702   fi])
6703 if test x"$gcc_cv_ld_sysroot" = xyes; then
6704   AC_DEFINE(HAVE_LD_SYSROOT, 1,
6705   [Define if your linker supports --sysroot.])
6706 fi
6707
6708 case $target in
6709 *-*-solaris2*)
6710   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
6711   AC_CACHE_CHECK([system-provided CRTs on Solaris],
6712     gcc_cv_solaris_crts,
6713     [gcc_cv_solaris_crts=no
6714      if test x$host != x$target; then
6715        if test "x$with_sysroot" = xyes; then
6716          target_sysroot="${test_exec_prefix}/${target_noncanonical}/sys-root"
6717        else
6718          target_sysroot="${with_sysroot}"
6719        fi
6720      fi
6721      target_libdir="$target_sysroot/usr/lib"
6722      # At the time they were added, gcrt1.o became a symlink for backwards
6723      # compatibility on x86, while crt1.o was added on sparc, so check for that.
6724      case $target in
6725        i?86-*-solaris2* | x86_64-*-solaris2*)
6726          if test -h "$target_libdir/gcrt1.o"; then gcc_cv_solaris_crts=yes; fi
6727          ;;
6728        sparc*-*-solaris2*)
6729          if test -f "$target_libdir/crt1.o"; then gcc_cv_solaris_crts=yes; fi
6730          ;;
6731      esac])
6732   ;;
6733 esac
6734 if test x$gcc_cv_solaris_crts = xyes; then
6735   AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
6736             [Define if the system-provided CRTs are present on Solaris.])
6737 fi
6738
6739 AC_ARG_ENABLE(libssp,
6740 [AS_HELP_STRING([--enable-libssp], [enable linking against libssp])],
6741 [case "${enableval}" in
6742   yes|no)
6743     ;;
6744   *)
6745     AC_MSG_ERROR([unknown libssp setting $enableval])
6746     ;;
6747 esac], [])
6748
6749 # Test for stack protector support in target C library.
6750 AC_CACHE_CHECK(__stack_chk_fail in target C library,
6751   gcc_cv_libc_provides_ssp,
6752   [gcc_cv_libc_provides_ssp=no
6753   if test "x$enable_libssp" = "xno"; then
6754     gcc_cv_libc_provides_ssp=yes
6755   elif test "x$enable_libssp" = "xyes"; then
6756     gcc_cv_libc_provides_ssp=no
6757   else
6758     case "$target" in
6759        *-*-musl*)
6760          # All versions of musl provide stack protector
6761          gcc_cv_libc_provides_ssp=yes;;
6762        *-*-linux* | *-*-kfreebsd*-gnu)
6763       # glibc 2.4 and later provides __stack_chk_fail and
6764       # either __stack_chk_guard, or TLS access to stack guard canary.
6765       GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_libc_provides_ssp=yes], [
6766       [if test -f $target_header_dir/features.h \
6767          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
6768             $target_header_dir/features.h > /dev/null; then
6769         if $EGREP '^[   ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
6770              $target_header_dir/features.h > /dev/null && \
6771              test -f $target_header_dir/bits/uClibc_config.h && \
6772              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
6773              $target_header_dir/bits/uClibc_config.h > /dev/null; then
6774           gcc_cv_libc_provides_ssp=yes
6775         fi
6776       # all versions of Bionic support stack protector
6777       elif test -f $target_header_dir/sys/cdefs.h \
6778         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
6779            $target_header_dir/sys/cdefs.h > /dev/null; then
6780          gcc_cv_libc_provides_ssp=yes
6781       fi]])
6782         ;;
6783        *-*-gnu*)
6784          # Avoid complicated tests (see
6785          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
6786          # simply assert that glibc does provide this, which is true for all
6787          # realistically usable GNU/Hurd configurations.
6788          # All supported versions of musl provide it as well
6789          gcc_cv_libc_provides_ssp=yes;;
6790        *-*-darwin* | *-*-freebsd* | *-*-netbsd*)
6791          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
6792            [echo "no __stack_chk_fail on this target"])
6793         ;;
6794        *) gcc_cv_libc_provides_ssp=no ;;
6795     esac
6796   fi])
6797
6798 if test x$gcc_cv_libc_provides_ssp = xyes; then
6799   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
6800             [Define if your target C library provides stack protector support])
6801 fi
6802
6803 # Check whether --enable-default-ssp was given.
6804 AC_ARG_ENABLE(default-ssp,
6805 [AS_HELP_STRING([--enable-default-ssp],
6806   [enable Stack Smashing Protection as default])],[
6807 if test x$gcc_cv_libc_provides_ssp = xyes; then
6808   case "$target" in
6809     ia64*-*-*) enable_default_ssp=no ;;
6810     *) enable_default_ssp=$enableval ;;
6811   esac
6812 else
6813   enable_default_ssp=no
6814 fi],
6815 enable_default_ssp=no)
6816 if test x$enable_default_ssp = xyes ; then
6817   AC_DEFINE(ENABLE_DEFAULT_SSP, 1,
6818       [Define if your target supports default stack protector and it is enabled.])
6819 fi
6820 AC_SUBST([enable_default_ssp])
6821
6822 # Test for <sys/sdt.h> on the target.
6823 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
6824 AC_MSG_CHECKING(sys/sdt.h in the target C library)
6825 have_sys_sdt_h=no
6826 if test -f $target_header_dir/sys/sdt.h; then
6827   have_sys_sdt_h=yes
6828   AC_DEFINE(HAVE_SYS_SDT_H, 1,
6829             [Define if your target C library provides sys/sdt.h])
6830 fi
6831 AC_MSG_RESULT($have_sys_sdt_h)
6832
6833 # Check if TFmode long double should be used by default or not.
6834 # Some glibc targets used DFmode long double, but with glibc 2.4
6835 # and later they can use TFmode.
6836 case "$target" in
6837   powerpc*-*-linux* | \
6838   sparc*-*-linux* | \
6839   s390*-*-linux* | \
6840   alpha*-*-linux*)
6841     AC_ARG_WITH(long-double-128,
6842       [AS_HELP_STRING([--with-long-double-128],
6843                       [use 128-bit long double by default])],
6844       gcc_cv_target_ldbl128="$with_long_double_128", [
6845       case "$target" in
6846         s390*-*-linux-musl*)
6847           gcc_cv_target_ldbl128=yes
6848           ;;
6849         powerpc*-*-linux-musl*)
6850           gcc_cv_target_ldbl128=no
6851           ;;
6852         *)]
6853       [GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_target_ldbl128=yes], [
6854       [gcc_cv_target_ldbl128=no
6855       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
6856         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
6857       && gcc_cv_target_ldbl128=yes
6858       ]])]
6859       [
6860           ;;
6861       esac
6862       ])
6863     ;;
6864 esac
6865 if test x$gcc_cv_target_ldbl128 = xyes; then
6866   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
6867             [Define if TFmode long double should be the default])
6868 fi
6869
6870 # Check if TFmode long double target should use the IBM extended double or IEEE
6871 # 128-bit floating point formats if long doubles are 128-bits long.  The long
6872 # double type can only be switched on powerpc64 bit Linux systems where VSX is
6873 # supported.  Other PowerPC systems do not build the IEEE 128-bit emulator in
6874 # libgcc.
6875 AC_ARG_WITH([long-double-format],
6876   [AS_HELP_STRING([--with-long-double-format={ieee,ibm}]
6877                   [Specify whether PowerPC long double uses IEEE or IBM format])],[
6878 case "$target:$with_long_double_format" in
6879   powerpc64le-*-linux*:ieee | powerpc64le-*-linux*:ibm)
6880     :
6881     ;;
6882   powerpc64-*-linux*:ieee | powerpc64-*-linux*:ibm)
6883     # IEEE 128-bit emulation is only built on 64-bit VSX Linux systems
6884     case "$with_cpu" in
6885       power7 | power8 | power9 | power1*)
6886         :
6887         ;;
6888       *)
6889         AC_MSG_ERROR([Configuration option --with-long-double-format is only \
6890 supported if the default cpu is power7 or newer])
6891         with_long_double_format=""
6892         ;;
6893       esac
6894       ;;
6895   powerpc64*-*-linux*:*)
6896     AC_MSG_ERROR([--with-long-double-format argument should be ibm or ieee])
6897     with_long_double_format=""
6898     ;;
6899   *)
6900     AC_MSG_ERROR([Configure option --with-long-double-format is only supported \
6901 on 64-bit PowerPC VSX Linux systems])
6902     with_long_double_format=""
6903     ;;
6904 esac],
6905   [])
6906
6907 # Check if the target LIBC supports exporting the AT_PLATFORM and AT_HWCAP
6908 # values in the TCB.  Currently, only GLIBC 2.23 and later support this.
6909 gcc_cv_libc_provides_hwcap_in_tcb=no
6910 case "$target" in
6911   powerpc*-*-linux*)
6912     GCC_GLIBC_VERSION_GTE_IFELSE([2], [23], [gcc_cv_libc_provides_hwcap_in_tcb=yes], )
6913     ;;
6914 esac
6915 if test x$gcc_cv_libc_provides_hwcap_in_tcb = xyes; then
6916   AC_DEFINE(TARGET_LIBC_PROVIDES_HWCAP_IN_TCB, 1,
6917             [Define if your target C Library provides the AT_HWCAP value in the TCB])
6918 fi
6919
6920 # Check if the target LIBC handles PT_GNU_STACK.
6921 gcc_cv_libc_gnustack=unknown
6922 case "$target" in
6923   mips*-*-linux-musl*)
6924     gcc_cv_libc_gnustack=yes
6925     ;;
6926   mips*-*-linux*)
6927     GCC_GLIBC_VERSION_GTE_IFELSE([2], [31], [gcc_cv_libc_gnustack=yes], )
6928     ;;
6929 esac
6930 if test x$gcc_cv_libc_gnustack = xyes; then
6931   AC_DEFINE(TARGET_LIBC_GNUSTACK, 1,
6932             [Define if your target C Library properly handles PT_GNU_STACK])
6933 fi
6934
6935 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
6936 gcc_cv_target_dl_iterate_phdr=unknown
6937 case "$target" in
6938   *-*-solaris2*)
6939     # <link.h> needs both a dl_iterate_phdr declaration and support for
6940     # compilation with largefile support.
6941     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
6942       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
6943       gcc_cv_target_dl_iterate_phdr=yes
6944     else
6945       gcc_cv_target_dl_iterate_phdr=no
6946     fi
6947     ;;
6948   *-*-dragonfly* | *-*-freebsd*)
6949     if grep dl_iterate_phdr $target_header_dir/sys/link_elf.h > /dev/null 2>&1; then
6950       gcc_cv_target_dl_iterate_phdr=yes
6951     else
6952       gcc_cv_target_dl_iterate_phdr=no
6953     fi
6954     ;;
6955   *-linux-musl*)
6956     gcc_cv_target_dl_iterate_phdr=yes
6957     ;;
6958 esac
6959 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
6960 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
6961    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
6962 [Define if your target C library provides the `dl_iterate_phdr' function.])
6963 fi
6964 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
6965
6966 # We no longer support different GC mechanisms.  Emit an error if
6967 # the user configures with --with-gc.
6968 AC_ARG_WITH(gc,
6969 [AS_HELP_STRING([--with-gc={page,zone}],
6970                 [this option is not supported anymore.  It used to choose
6971                  the garbage collection mechanism to use with the compiler])],
6972 [AC_MSG_ERROR([Configure option --with-gc is only supported up to GCC 4.7.x])],
6973 [])
6974
6975 # Libraries to use on the host.  This will normally be set by the top
6976 # level Makefile.  Here we simply capture the value for our Makefile.
6977 if test -z "${HOST_LIBS+set}"; then
6978   HOST_LIBS=
6979 fi
6980 AC_SUBST(HOST_LIBS)
6981
6982 # Use the system's zlib library.
6983 AM_ZLIB
6984
6985 dnl Very limited version of automake's enable-maintainer-mode
6986
6987 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
6988   dnl maintainer-mode is disabled by default
6989   AC_ARG_ENABLE(maintainer-mode,
6990 [AS_HELP_STRING([--enable-maintainer-mode],
6991                 [enable make rules and dependencies not useful
6992                  (and sometimes confusing) to the casual installer])],
6993       maintainer_mode=$enableval,
6994       maintainer_mode=no)
6995
6996 AC_MSG_RESULT($maintainer_mode)
6997
6998 if test "$maintainer_mode" = "yes"; then
6999   MAINT=''
7000 else
7001   MAINT='#'
7002 fi
7003 AC_SUBST(MAINT)dnl
7004
7005 dnl Variables for tags utilities; copied from automake 1.16.4+'s init.m4
7006 if test -z "$CTAGS"; then
7007   CTAGS=ctags
7008 fi
7009 AC_SUBST([CTAGS])
7010 if test -z "$ETAGS"; then
7011   ETAGS=etags
7012 fi
7013 AC_SUBST([ETAGS])
7014 if test -z "$CSCOPE"; then
7015   CSCOPE=cscope
7016 fi
7017 AC_SUBST([CSCOPE])
7018
7019 dnl Whether to prevent multiple front-ends from linking at the same time
7020
7021 AC_MSG_CHECKING([whether to avoid linking multiple front-ends at once])
7022   AC_ARG_ENABLE(link-mutex,
7023 [AS_HELP_STRING([--enable-link-mutex],
7024                 [avoid linking multiple front-ends at once to avoid thrashing
7025                  on the build machine])],
7026       do_link_mutex=$enableval,
7027       do_link_mutex=no)
7028 AC_MSG_RESULT($do_link_mutex)
7029
7030 if test "$do_link_mutex" = "yes"; then
7031    DO_LINK_MUTEX=true
7032 else
7033    DO_LINK_MUTEX=false
7034 fi
7035 AC_SUBST(DO_LINK_MUTEX)
7036
7037 dnl Whether to prevent multiple GCC front-ends from linking at the same time
7038
7039 AC_MSG_CHECKING([whether to serialize linking of multiple front-ends])
7040   AC_ARG_ENABLE(link-serialization,
7041 [AS_HELP_STRING([--enable-link-serialization],
7042                 [avoid linking multiple GCC front-ends at once using make
7043                  dependencies to avoid thrashing on the build machine])],
7044       do_link_serialization=$enableval,
7045       do_link_serialization=no)
7046 AC_MSG_RESULT($do_link_serialization)
7047
7048 case "$do_link_serialization" in
7049   yes)
7050     DO_LINK_SERIALIZATION=1;;
7051   [[1-9]] | [[1-9]][[0-9]] | [[1-9]][[0-9]][[0-9]])
7052     DO_LINK_SERIALIZATION=$do_link_serialization;;
7053   no)
7054     DO_LINK_SERIALIZATION=;;
7055   *)
7056     AC_MSG_ERROR(bad value ${do_link_serialization} given for --enable-link-serialization) ;;
7057 esac
7058 AC_SUBST(DO_LINK_SERIALIZATION)
7059
7060 # --------------
7061 # Language hooks
7062 # --------------
7063
7064 # Make empty files to contain the specs and options for each language.
7065 # Then add #include lines to for a compiler that has specs and/or options.
7066
7067 subdirs=
7068 lang_opt_files=
7069 lang_specs_files=
7070 lang_tree_files=
7071 # These (without "all_") are set in each config-lang.in.
7072 # `language' must be a single word so is spelled singularly.
7073 all_languages=
7074 all_compilers=
7075 all_outputs='Makefile'
7076 # List of language configure and makefile fragments.
7077 all_lang_configurefrags=
7078 all_lang_makefrags=
7079 # Additional files for gengtype
7080 all_gtfiles="$target_gtfiles"
7081
7082 # These are the languages that are set in --enable-languages,
7083 # and are available in the GCC tree.
7084 all_selected_languages=
7085
7086 # Add the language fragments.
7087 # Languages are added via two mechanisms.  Some information must be
7088 # recorded in makefile variables, these are defined in config-lang.in.
7089 # We accumulate them and plug them into the main Makefile.
7090 # The other mechanism is a set of hooks for each of the main targets
7091 # like `clean', `install', etc.
7092
7093 language_hooks="Make-hooks"
7094
7095 for lang in ${srcdir}/*/config-lang.in
7096 do
7097 changequote(,)dnl
7098         test "$lang" = "${srcdir}/*/config-lang.in" && continue
7099
7100         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
7101         if test "x$lang_alias" = x
7102         then
7103               echo "$lang doesn't set \$language." 1>&2
7104               exit 1
7105         fi
7106         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
7107         subdirs="$subdirs $subdir"
7108
7109         # $gcc_subdir is where the gcc integration files are to be found
7110         # for a language, both for internal compiler purposes (compiler
7111         # sources implementing front-end to GCC tree converters), and for
7112         # build infrastructure purposes (Make-lang.in, etc.)
7113         #
7114         # This will be <subdir> (relative to $srcdir) if a line like
7115         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
7116         # is found in <langdir>/config-lang.in, and will remain <langdir>
7117         # otherwise.
7118         #
7119         # Except for the language alias (fetched above), the regular
7120         # "config-lang.in" contents are always retrieved from $gcc_subdir,
7121         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
7122         # only this and the language alias.
7123
7124         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
7125         if [ "$gcc_subdir" = "" ]; then
7126            gcc_subdir="$subdir"
7127         fi
7128
7129         case ",$enable_languages," in
7130         *,$lang_alias,*)
7131             all_selected_languages="$all_selected_languages $lang_alias"
7132             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
7133                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
7134             fi
7135             ;;
7136         esac
7137 changequote([,])dnl
7138
7139         language=
7140         boot_language=
7141         compilers=
7142         outputs=
7143         gtfiles=
7144         subdir_requires=
7145         . ${srcdir}/$gcc_subdir/config-lang.in
7146         if test "x$language" = x
7147         then
7148                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
7149                 exit 1
7150         fi
7151
7152         ok=:
7153         case ",$enable_languages," in
7154                 *,$lang_alias,*) ;;
7155                 *)
7156                         for i in $subdir_requires; do
7157                                 test -f "${srcdir}/$i/config-lang.in" && continue
7158                                 ok=false
7159                                 break
7160                         done
7161                 ;;
7162         esac
7163         $ok || continue
7164
7165         all_lang_configurefrags="$all_lang_configurefrags \$(srcdir)/$gcc_subdir/config-lang.in"
7166         if test "x$language" = xc && test -n "$all_lang_makefrags"; then
7167             # Put c/Make-lang.in fragment first to match serialization languages order.
7168             all_lang_makefrags="\$(srcdir)/$gcc_subdir/Make-lang.in $all_lang_makefrags"
7169         else
7170             all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
7171         fi
7172         if test -f $srcdir/$gcc_subdir/lang.opt; then
7173             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
7174             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
7175         fi
7176         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
7177             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
7178         fi
7179         all_languages="$all_languages $language"
7180         all_compilers="$all_compilers $compilers"
7181         all_outputs="$all_outputs $outputs"
7182         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
7183         case ",$enable_languages," in
7184                 *,lto,*)
7185                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
7186                     enable_lto=yes
7187                     AC_SUBST(enable_lto)
7188                     ;;
7189                 *) ;;
7190         esac
7191 done
7192
7193 check_languages=
7194 for language in $all_selected_languages
7195 do
7196         check_languages="$check_languages check-$language"
7197 done
7198
7199 selftest_languages=
7200 for language in $all_selected_languages
7201 do
7202         selftest_languages="$selftest_languages selftest-$language"
7203 done
7204
7205 # We link each language in with a set of hooks, reached indirectly via
7206 # lang.${target}.  Only do so for selected languages.
7207
7208 rm -f Make-hooks
7209 touch Make-hooks
7210 target_list="all.cross start.encap rest.encap tags \
7211         install-common install-man install-info install-dvi install-pdf \
7212         install-html dvi pdf html uninstall info man srcextra srcman srcinfo \
7213         mostlyclean clean distclean maintainer-clean install-plugin"
7214
7215 for t in $target_list
7216 do
7217         x=
7218         for lang in $all_selected_languages
7219         do
7220                 x="$x $lang.$t"
7221         done
7222         echo "lang.$t: $x" >> Make-hooks
7223 done
7224
7225 echo "ifeq (\$(DO_LINK_SERIALIZATION),)" >> Make-hooks
7226 echo "SERIAL_LIST =" >> Make-hooks
7227 echo else >> Make-hooks
7228 lang_cnt=0
7229 lang_list=
7230 prev=c
7231 serialization_languages=c
7232 for lang in $all_selected_languages
7233 do
7234         test $lang = c && continue
7235         if test $lang = lto; then
7236                 serialization_languages="$serialization_languages lto1 lto2"
7237         else
7238                 serialization_languages="$serialization_languages $lang"
7239         fi
7240 done
7241 for lang in $serialization_languages
7242 do
7243         test $lang = c && continue
7244         lang_cnt=`expr $lang_cnt + 1`
7245         lang_list=" $prev$lang_list"
7246         prev=${lang}
7247 done
7248 echo "SERIAL_LIST = \$(wordlist \$(DO_LINK_SERIALIZATION),$lang_cnt,$lang_list)" >> Make-hooks
7249 echo endif >> Make-hooks
7250 echo "SERIAL_COUNT = `expr $lang_cnt + 1`" >> Make-hooks
7251 echo "INDEX.c = 0" >> Make-hooks
7252 lang_idx=1
7253 for lang in $serialization_languages
7254 do
7255         test $lang = c && continue
7256         echo "$lang.prev = \$(if \$(word $lang_cnt,\$(SERIAL_LIST)),\$(\$(word $lang_cnt,\$(SERIAL_LIST)).serial))" >> Make-hooks
7257         echo "INDEX.$lang = $lang_idx" >> Make-hooks
7258         lang_cnt=`expr $lang_cnt - 1`
7259         lang_idx=`expr $lang_idx + 1`
7260 done
7261
7262 # --------
7263 # Option include files
7264 # --------
7265
7266 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
7267 option_includes="option-includes.mk"
7268 AC_SUBST_FILE(option_includes)
7269
7270 # --------
7271 # UNSORTED
7272 # --------
7273
7274 # Create .gdbinit.
7275
7276 echo "dir ." > .gdbinit
7277 echo "dir ${srcdir}" >> .gdbinit
7278 if test x$gdb_needs_out_file_path = xyes
7279 then
7280         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
7281 fi
7282 if test "x$subdirs" != x; then
7283         for s in $subdirs
7284         do
7285                 echo "dir ${srcdir}/$s" >> .gdbinit
7286         done
7287 fi
7288 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
7289 echo "python import sys; sys.path.append('${srcdir}'); import gdbhooks" >> .gdbinit
7290
7291 # Put a breakpoint on __asan_report_error to help with debugging buffer
7292 # overflow.
7293 case "$CFLAGS" in
7294 *-fsanitize=address*)
7295   echo "source ${srcdir}/gdbasan.in" >> .gdbinit
7296   ;;
7297 esac
7298
7299 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
7300 AC_SUBST(gcc_tooldir)
7301 AC_SUBST(dollar)
7302
7303 # Find a directory in which to install a shared libgcc.
7304
7305 AC_ARG_ENABLE(version-specific-runtime-libs,
7306 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
7307                 [specify that runtime libraries should be
7308                  installed in a compiler-specific directory])])
7309
7310 # Substitute configuration variables
7311 AC_SUBST(subdirs)
7312 AC_SUBST(srcdir)
7313 AC_SUBST(all_compilers)
7314 AC_SUBST(all_gtfiles)
7315 AC_SUBST(all_lang_configurefrags)
7316 AC_SUBST(all_lang_makefrags)
7317 AC_SUBST(all_languages)
7318 AC_SUBST(all_selected_languages)
7319 AC_SUBST(build_exeext)
7320 AC_SUBST(build_install_headers_dir)
7321 AC_SUBST(build_xm_file_list)
7322 AC_SUBST(build_xm_include_list)
7323 AC_SUBST(build_xm_defines)
7324 AC_SUBST(build_file_translate)
7325 AC_SUBST(check_languages)
7326 AC_SUBST(selftest_languages)
7327 AC_SUBST(cpp_install_dir)
7328 AC_SUBST(xmake_file)
7329 AC_SUBST(tmake_file)
7330 AC_SUBST(TM_ENDIAN_CONFIG)
7331 AC_SUBST(TM_MULTILIB_CONFIG)
7332 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
7333 AC_SUBST(extra_gcc_objs)
7334 AC_SUBST(user_headers_inc_next_pre)
7335 AC_SUBST(user_headers_inc_next_post)
7336 AC_SUBST(extra_headers_list)
7337 AC_SUBST(extra_objs)
7338 AC_SUBST(extra_programs)
7339 AC_SUBST(float_h_file)
7340 AC_SUBST(gcc_config_arguments)
7341 AC_SUBST(gcc_gxx_include_dir)
7342 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
7343 AC_SUBST(gcc_gxx_libcxx_include_dir)
7344 AC_SUBST(gcc_gxx_libcxx_include_dir_add_sysroot)
7345 AC_SUBST(host_exeext)
7346 AC_SUBST(host_xm_file_list)
7347 AC_SUBST(host_xm_include_list)
7348 AC_SUBST(host_xm_defines)
7349 AC_SUBST(out_host_hook_obj)
7350 AC_SUBST(install)
7351 AC_SUBST(lang_opt_files)
7352 AC_SUBST(lang_specs_files)
7353 AC_SUBST(lang_tree_files)
7354 AC_SUBST(local_prefix)
7355 AC_SUBST(md_file)
7356 AC_SUBST(objc_boehm_gc)
7357 AC_SUBST(out_file)
7358 AC_SUBST(out_object_file)
7359 AC_SUBST(common_out_file)
7360 AC_SUBST(common_out_object_file)
7361 AC_SUBST(tm_file_list)
7362 AC_SUBST(tm_include_list)
7363 AC_SUBST(tm_defines)
7364 AC_SUBST(tm_p_file_list)
7365 AC_SUBST(tm_p_include_list)
7366 AC_SUBST(tm_d_file_list)
7367 AC_SUBST(tm_d_include_list)
7368 AC_SUBST(xm_file_list)
7369 AC_SUBST(xm_include_list)
7370 AC_SUBST(xm_defines)
7371 AC_SUBST(use_gcc_stdint)
7372 AC_SUBST(c_target_objs)
7373 AC_SUBST(cxx_target_objs)
7374 AC_SUBST(fortran_target_objs)
7375 AC_SUBST(d_target_objs)
7376 AC_SUBST(target_cpu_default)
7377
7378 AC_SUBST_FILE(language_hooks)
7379
7380 # Echo link setup.
7381 if test x${build} = x${host} ; then
7382   if test x${host} = x${target} ; then
7383     echo "Links are now set up to build a native compiler for ${target}." 1>&2
7384   else
7385     echo "Links are now set up to build a cross-compiler" 1>&2
7386     echo " from ${host} to ${target}." 1>&2
7387   fi
7388 else
7389   if test x${host} = x${target} ; then
7390     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
7391     echo " for ${target}." 1>&2
7392   else
7393     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
7394     echo " from ${host} to ${target}." 1>&2
7395   fi
7396 fi
7397
7398 AC_ARG_VAR(GMPLIBS,[How to link GMP])
7399 AC_ARG_VAR(GMPINC,[How to find GMP include files])
7400
7401 AC_ARG_VAR(ISLLIBS,[How to link isl])
7402 AC_ARG_VAR(ISLINC,[How to find isl include files])
7403 if test "x${ISLLIBS}" != "x" ; then
7404    AC_DEFINE(HAVE_isl, 1, [Define if isl is in use.])
7405 fi
7406
7407 GCC_ENABLE_PLUGINS
7408 AC_SUBST(pluginlibs)
7409 AC_SUBST(enable_plugin)
7410 if test x"$enable_plugin" = x"yes"; then
7411   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
7412 fi
7413
7414
7415 # Enable --enable-host-shared
7416 AC_ARG_ENABLE(host-shared,
7417 [AS_HELP_STRING([--enable-host-shared],
7418                 [build host code as shared libraries])],
7419 [PICFLAG=-fPIC], [PICFLAG=])
7420 AC_SUBST(enable_host_shared)
7421 AC_SUBST(PICFLAG)
7422
7423
7424 AC_ARG_ENABLE(libquadmath-support,
7425 [AS_HELP_STRING([--disable-libquadmath-support],
7426   [disable libquadmath support for Fortran])],
7427 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
7428 ENABLE_LIBQUADMATH_SUPPORT=yes)
7429 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
7430   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
7431             [Define to 1 to enable libquadmath support])
7432 fi
7433
7434
7435 # Specify what hash style to use by default.
7436 AC_ARG_WITH([linker-hash-style],
7437 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
7438                 [specify the linker hash style])],
7439 [case x"$withval" in
7440    xsysv)
7441      LINKER_HASH_STYLE=sysv
7442      ;;
7443    xgnu)
7444      LINKER_HASH_STYLE=gnu
7445      ;;
7446    xboth)
7447      LINKER_HASH_STYLE=both
7448      ;;
7449    *)
7450      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
7451      ;;
7452  esac],
7453 [LINKER_HASH_STYLE=''])
7454 if test x"${LINKER_HASH_STYLE}" != x; then
7455   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
7456                                          [The linker hash style])
7457 fi
7458
7459 # Specify what should be the default of -fdiagnostics-color option.
7460 AC_ARG_WITH([diagnostics-color],
7461 [AC_HELP_STRING([--with-diagnostics-color={never,auto,auto-if-env,always}],
7462                 [specify the default of -fdiagnostics-color option
7463                  auto-if-env stands for -fdiagnostics-color=auto if
7464                  GCC_COLOR environment variable is present and
7465                  -fdiagnostics-color=never otherwise])],
7466 [case x"$withval" in
7467    xnever)
7468      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_NO
7469      ;;
7470    xauto)
7471      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO
7472      ;;
7473    xauto-if-env)
7474      DIAGNOSTICS_COLOR_DEFAULT=-1
7475      ;;
7476    xalways)
7477      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_YES
7478      ;;
7479    *)
7480      AC_MSG_ERROR([$withval is an invalid option to --with-diagnostics-color])
7481      ;;
7482  esac],
7483 [DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO])
7484 AC_DEFINE_UNQUOTED(DIAGNOSTICS_COLOR_DEFAULT, $DIAGNOSTICS_COLOR_DEFAULT,
7485                    [The default for -fdiagnostics-color option])
7486
7487 # Specify what should be the default of -fdiagnostics-urls option.
7488 AC_ARG_WITH([diagnostics-urls],
7489 [AC_HELP_STRING([--with-diagnostics-urls={never,auto,auto-if-env,always}],
7490                 [specify the default of -fdiagnostics-urls option
7491                  auto-if-env stands for -fdiagnostics-urls=auto if
7492                  GCC_URLS or TERM_URLS environment variable is present and
7493                  -fdiagnostics-urls=never otherwise])],
7494 [case x"$withval" in
7495    xnever)
7496      DIAGNOSTICS_URLS_DEFAULT=DIAGNOSTICS_URL_NO
7497      ;;
7498    xauto)
7499      DIAGNOSTICS_URLS_DEFAULT=DIAGNOSTICS_URL_AUTO
7500      ;;
7501    xauto-if-env)
7502      DIAGNOSTICS_URLS_DEFAULT=-1
7503      ;;
7504    xalways)
7505      DIAGNOSTICS_URLS_DEFAULT=DIAGNOSTICS_URL_YES
7506      ;;
7507    *)
7508      AC_MSG_ERROR([$withval is an invalid option to --with-diagnostics-urls])
7509      ;;
7510  esac],
7511 [DIAGNOSTICS_URLS_DEFAULT=DIAGNOSTICS_URL_AUTO])
7512 AC_DEFINE_UNQUOTED(DIAGNOSTICS_URLS_DEFAULT, $DIAGNOSTICS_URLS_DEFAULT,
7513                    [The default for -fdiagnostics-urls option])
7514
7515 # Generate gcc-driver-name.h containing GCC_DRIVER_NAME for the benefit
7516 # of jit/jit-playback.cc.
7517 gcc_driver_version=`eval "${get_gcc_base_ver} $srcdir/BASE-VER"`
7518 echo "gcc_driver_version: ${gcc_driver_version}"
7519 cat > gcc-driver-name.h <<EOF
7520 #define GCC_DRIVER_NAME "${target_noncanonical}-gcc-${gcc_driver_version}${exeext}"
7521 EOF
7522
7523 # Check whether --enable-default-pie was given.
7524 AC_ARG_ENABLE(default-pie,
7525 [AS_HELP_STRING([--enable-default-pie],
7526   [enable Position Independent Executable as default])],
7527 enable_default_pie=$enableval,
7528 enable_default_pie=no)
7529 if test x$enable_default_pie = xyes ; then
7530   AC_DEFINE(ENABLE_DEFAULT_PIE, 1,
7531       [Define if your target supports default PIE and it is enabled.])
7532 fi
7533 AC_SUBST([enable_default_pie])
7534
7535 # Check if -fno-PIE works.
7536 AC_CACHE_CHECK([for -fno-PIE option],
7537   [gcc_cv_c_no_fpie],
7538   [saved_CXXFLAGS="$CXXFLAGS"
7539    CXXFLAGS="$CXXFLAGS -fno-PIE"
7540    AC_COMPILE_IFELSE([AC_LANG_SOURCE([int main(void) {return 0;}])],
7541      [gcc_cv_c_no_fpie=yes],
7542      [gcc_cv_c_no_fpie=no])
7543    CXXFLAGS="$saved_CXXFLAGS"])
7544 if test "$gcc_cv_c_no_fpie" = "yes"; then
7545   NO_PIE_CFLAGS="-fno-PIE"
7546 fi
7547 AC_SUBST([NO_PIE_CFLAGS])
7548
7549 # Check if -no-pie works.
7550 AC_CACHE_CHECK([for -no-pie option],
7551   [gcc_cv_no_pie],
7552   [saved_LDFLAGS="$LDFLAGS"
7553    LDFLAGS="$LDFLAGS -no-pie"
7554    AC_LINK_IFELSE([AC_LANG_SOURCE([int main(void) {return 0;}])],
7555      [gcc_cv_no_pie=yes],
7556      [gcc_cv_no_pie=no])
7557    LDFLAGS="$saved_LDFLAGS"])
7558 if test "$gcc_cv_no_pie" = "yes"; then
7559   NO_PIE_FLAG="-no-pie"
7560 fi
7561 AC_SUBST([NO_PIE_FLAG])
7562
7563 # Enable Intel CET on Intel CET enabled host if jit is enabled.
7564 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
7565 case x$enable_languages in
7566 *jit*)
7567   ;;
7568 *)
7569   CET_HOST_FLAGS=
7570   ;;
7571 esac
7572 AC_SUBST(CET_HOST_FLAGS)
7573
7574 # Check linker supports '-z bndplt'
7575 ld_bndplt_support=no
7576 AC_MSG_CHECKING(linker -z bndplt option)
7577 if test x"$ld_is_gold" = xno; then
7578   if test $in_tree_ld = yes ; then
7579     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
7580       ld_bndplt_support=yes
7581     fi
7582   elif test x$gcc_cv_ld != x; then
7583     # Check if linker supports -a bndplt option
7584     if $gcc_cv_ld --help 2>&1 | grep -- '-z bndplt' > /dev/null; then
7585       ld_bndplt_support=yes
7586     fi
7587   fi
7588 fi
7589 if test x"$ld_bndplt_support" = xyes; then
7590   AC_DEFINE(HAVE_LD_BNDPLT_SUPPORT, 1,
7591         [Define if your linker supports -z bndplt])
7592 fi
7593 AC_MSG_RESULT($ld_bndplt_support)
7594
7595 # Check linker supports '--push-state'/'--pop-state'
7596 ld_pushpopstate_support=no
7597 AC_MSG_CHECKING(linker --push-state/--pop-state options)
7598 if test x"$ld_is_gold" = xno; then
7599   if test $in_tree_ld = yes ; then
7600     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
7601       ld_pushpopstate_support=yes
7602     fi
7603   elif test x$gcc_cv_ld != x; then
7604     # Check if linker supports --push-state/--pop-state options
7605     if $gcc_cv_ld --help 2>&1 | grep -- '--push-state' > /dev/null; then
7606       ld_pushpopstate_support=yes
7607     fi
7608   fi
7609 fi
7610 if test x"$ld_pushpopstate_support" = xyes; then
7611   AC_DEFINE(HAVE_LD_PUSHPOPSTATE_SUPPORT, 1,
7612         [Define if your linker supports --push-state/--pop-state])
7613 fi
7614 AC_MSG_RESULT($ld_pushpopstate_support)
7615
7616 # On s390, float_t has historically been statically defined as double for no
7617 # good reason. To comply with the C standard in the light of this definition,
7618 # gcc has evaluated float expressions in double precision when in
7619 # standards-compatible mode or when given -fexcess-precision=standard. To enable
7620 # a smooth transition towards the new model used by most architectures, where
7621 # gcc describes its behavior via the macro __FLT_EVAL_METHOD__ and glibc derives
7622 # float_t from that, this behavior can be configured with
7623 # --enable-s390-excess-float-precision. When given as enabled, that flag selects
7624 # the old model. When omitted, native builds and cross compiles that have target
7625 # libc headers will detect whether libc clamps float_t to double and in that
7626 # case maintain the old model. Otherwise, they will default to the new model.
7627 AC_ARG_ENABLE(s390-excess-float-precision,
7628   [AS_HELP_STRING([--enable-s390-excess-float-precision],
7629                   [on s390 targets, evaluate float with double precision
7630                    when in standards-conforming mode])],
7631   [],[enable_s390_excess_float_precision=auto])
7632
7633 case $target in
7634   s390*-linux*)
7635   if test x"$enable_s390_excess_float_precision" = xauto; then
7636     # Can we autodetect the behavior of the target libc?
7637     if test "$target" = "$host" -a "$host" = "$build"; then
7638       enable_s390_excess_float_precision=autodetect
7639     elif test "x$with_headers" != xno; then
7640       # cross build. are target headers available?
7641       # carefully coerce the build-system compiler to use target headers
7642       saved_CXXFLAGS="$CXXFLAGS"
7643       fixed_XGCC_FLAGS_FOR_TARGET=`echo "$XGCC_FLAGS_FOR_TARGET" | sed 's/-B/-idirafter/g'`
7644       CROSS_TEST_CXXFLAGS="-nostdinc $fixed_XGCC_FLAGS_FOR_TARGET"
7645       CXXFLAGS="$CROSS_TEST_CXXFLAGS"
7646       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
7647 #include <math.h>
7648 ]])], [enable_s390_excess_float_precision=autodetect], [])
7649       CXXFLAGS="$saved_CXXFLAGS"
7650     fi
7651
7652     if test x"$enable_s390_excess_float_precision" = xautodetect; then
7653       saved_CXXFLAGS="$CXXFLAGS"
7654       if ! test "$target" = "$host" -a "$host" = "$build"; then
7655         CXXFLAGS="$CROSS_TEST_CXXFLAGS"
7656         unset CROSS_TEST_CXXFLAGS
7657       fi
7658       AC_CACHE_CHECK([for glibc clamping float_t to double],
7659         gcc_cv_float_t_clamped_to_double, [
7660         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
7661 #define __FLT_EVAL_METHOD__ 0
7662 #include <math.h>
7663 int dummy[sizeof(float_t) == sizeof(double) ? 1 : -1];
7664 ]])],
7665           [gcc_cv_float_t_clamped_to_double=yes],
7666           [gcc_cv_float_t_clamped_to_double=no])])
7667       CXXFLAGS="$saved_CXXFLAGS"
7668       enable_s390_excess_float_precision="$gcc_cv_float_t_clamped_to_double"
7669     else
7670       # no way to detect behavior of target libc, default to new model
7671       enable_s390_excess_float_precision=no
7672     fi
7673   fi
7674
7675   GCC_TARGET_TEMPLATE(ENABLE_S390_EXCESS_FLOAT_PRECISION)
7676   if test x"$enable_s390_excess_float_precision" = xyes; then
7677     AC_DEFINE(ENABLE_S390_EXCESS_FLOAT_PRECISION, 1,
7678 [Define to enable evaluating float expressions with double precision in
7679 standards-compatible mode on s390 targets.])
7680   fi
7681   ;;
7682 esac
7683
7684 # Configure the subdirectories
7685 # AC_CONFIG_SUBDIRS($subdirs)
7686
7687 # Create the Makefile
7688 # and configure language subdirectories
7689 AC_CONFIG_FILES($all_outputs)
7690
7691 AC_CONFIG_COMMANDS([default],
7692 [
7693 case ${CONFIG_HEADERS} in
7694   *auto-host.h:config.in*)
7695   echo > cstamp-h ;;
7696 esac
7697 # Make sure all the subdirs exist.
7698 for d in $subdirs doc build common c-family
7699 do
7700     test -d $d || mkdir $d
7701 done
7702 ],
7703 [subdirs='$subdirs'])
7704 AC_OUTPUT
7705