gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.57)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 278 ac_cv_prog_cc_no_long_long,
 279 [save_CFLAGS="$CFLAGS"
 280 CFLAGS="-Wno-long-long"
 281 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 282                ac_cv_prog_cc_no_long_long=no)
 283 CFLAGS="$save_CFLAGS"])
 284
 285 AC_PROG_CPP
 286 AC_C_INLINE
 287
 288 gcc_AC_C_LONG_LONG
 289 gcc_AC_C__BOOL
 290
 291 # sizeof(char) is 1 by definition.
 292 AC_COMPILE_CHECK_SIZEOF(void *)
 293 AC_COMPILE_CHECK_SIZEOF(short)
 294 AC_COMPILE_CHECK_SIZEOF(int)
 295 AC_COMPILE_CHECK_SIZEOF(long)
 296 if test $ac_cv_c_long_long = yes; then
 297   AC_COMPILE_CHECK_SIZEOF(long long)
 298 fi
 299 if test $ac_cv_c___int64 = yes; then
 300   AC_COMPILE_CHECK_SIZEOF(__int64)
 301 fi
 302
 303 # -----------------
 304 # Find Ada compiler
 305 # -----------------
 306
 307 # See if GNAT has been installed
 308 gcc_AC_PROG_GNAT
 309
 310 # ---------------------
 311 # Warnings and checking
 312 # ---------------------
 313
 314 strict1_warn=
 315 if test $ac_cv_prog_cc_no_long_long = yes ; then
 316   strict1_warn="-pedantic -Wno-long-long"
 317 fi
 318 AC_SUBST(strict1_warn)
 319
 320 # If the native compiler is GCC, we can enable warnings even in stage1.
 321 # That's useful for people building cross-compilers, or just running a
 322 # quick `make'.
 323 warn_cflags=
 324 if test "x$GCC" = "xyes"; then
 325   warn_cflags='$(GCC_WARN_CFLAGS)'
 326 fi
 327 AC_SUBST(warn_cflags)
 328
 329 # Enable -Werror in bootstrap stage2 and later.
 330 # Change the default to "no" on release branches.
 331 AC_ARG_ENABLE(werror,
 332 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 333 [enable_werror=yes])
 334 if test x$enable_werror = xyes ; then
 335   WERROR=-Werror
 336 fi
 337 AC_SUBST(WERROR)
 338
 339 # Enable expensive internal checks
 340 AC_ARG_ENABLE(checking,
 341 [  --enable-checking[=LIST]
 342                           enable expensive run-time checks.  With LIST,
 343                           enable only specific categories of checks.
 344                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 345                           default is misc,tree,gc,rtlflag],
 346 [ac_checking=
 347 ac_tree_checking=
 348 ac_rtl_checking=
 349 ac_rtlflag_checking=
 350 ac_gc_checking=
 351 ac_gc_always_collect=
 352 ac_fold_checking=
 353 case "${enableval}" in
 354 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 355         ac_rtlflag_checking=1 ;;
 356 no)     ;;
 357 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 358         set fnord $enableval; shift
 359         IFS="$ac_save_IFS"
 360         for check
 361         do
 362                 case $check in
 363                 misc)   ac_checking=1 ;;
 364                 tree)   ac_tree_checking=1 ;;
 365                 rtlflag)        ac_rtlflag_checking=1 ;;
 366                 rtl)    ac_rtl_checking=1 ;;
 367                 gc)     ac_gc_checking=1 ;;
 368                 gcac)   ac_gc_always_collect=1 ;;
 369                 fold)   ac_fold_checking=1 ;;
 370                 valgrind)       ac_checking_valgrind=1 ;;
 371                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 372                 esac
 373         done
 374         ;;
 375 esac
 376 ],
 377 # Enable some checks by default for development versions of GCC
 378 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 379 nocommon_flag=""
 380 if test x$ac_checking != x ; then
 381   AC_DEFINE(ENABLE_CHECKING, 1,
 382 [Define if you want more run-time sanity checks.  This one gets a grab
 383    bag of miscellaneous but relatively cheap checks.])
 384   nocommon_flag=-fno-common
 385 fi
 386 AC_SUBST(nocommon_flag)
 387 if test x$ac_tree_checking != x ; then
 388   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 389 [Define if you want all operations on trees (the basic data
 390    structure of the front ends) to be checked for dynamic type safety
 391    at runtime.  This is moderately expensive.])
 392 fi
 393 if test x$ac_rtl_checking != x ; then
 394   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 395 [Define if you want all operations on RTL (the basic data structure
 396    of the optimizer and back end) to be checked for dynamic type safety
 397    at runtime.  This is quite expensive.])
 398 fi
 399 if test x$ac_rtlflag_checking != x ; then
 400   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 401 [Define if you want RTL flag accesses to be checked against the RTL
 402    codes that are supported for each access macro.  This is relatively
 403    cheap.])
 404 fi
 405 if test x$ac_gc_checking != x ; then
 406   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 407 [Define if you want the garbage collector to do object poisoning and
 408    other memory allocation checks.  This is quite expensive.])
 409 fi
 410 if test x$ac_gc_always_collect != x ; then
 411   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 412 [Define if you want the garbage collector to operate in maximally
 413    paranoid mode, validating the entire heap and collecting garbage at
 414    every opportunity.  This is extremely expensive.])
 415 fi
 416 if test x$ac_fold_checking != x ; then
 417   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 418 [Define if you want fold checked that it never destructs its argument.
 419    This is quite expensive.])
 420 fi
 421 valgrind_path_defines=
 422 valgrind_command=
 423
 424 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 425 dnl # an if statement.  This was the source of very frustrating bugs
 426 dnl # in converting to autoconf 2.5x!
 427 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 428
 429 if test x$ac_checking_valgrind != x ; then
 430   # It is certainly possible that there's valgrind but no valgrind.h.
 431   # GCC relies on making annotations so we must have both.
 432   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 433   AC_TRY_CPP(
 434     [#include <valgrind/memcheck.h>
 435 #ifndef VALGRIND_DISCARD
 436 #error VALGRIND_DISCARD not defined
 437 #endif],
 438   [gcc_cv_header_valgrind_memcheck_h=yes],
 439   [gcc_cv_header_valgrind_memcheck_h=no])
 440   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 441   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 442   AC_TRY_CPP(
 443     [#include <memcheck.h>
 444 #ifndef VALGRIND_DISCARD
 445 #error VALGRIND_DISCARD not defined
 446 #endif],
 447   [gcc_cv_header_memcheck_h=yes],
 448   gcc_cv_header_memcheck_h=no)
 449   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 450   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 451         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 452   if test "x$valgrind_path" = "x" \
 453     || (test $have_valgrind_h = no \
 454         && test $gcc_cv_header_memcheck_h = no \
 455         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 456         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 457   fi
 458   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 459   valgrind_command="$valgrind_path -q"
 460   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 461 [Define if you want to run subprograms and generated programs
 462    through valgrind (a memory checker).  This is extremely expensive.])
 463   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 464     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 465         [Define if valgrind's valgrind/memcheck.h header is installed.])
 466   fi
 467   if test $gcc_cv_header_memcheck_h = yes; then
 468     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 469         [Define if valgrind's memcheck.h header is installed.])
 470   fi
 471 fi
 472 AC_SUBST(valgrind_path_defines)
 473 AC_SUBST(valgrind_command)
 474
 475 # Enable code coverage collection
 476 AC_ARG_ENABLE(coverage,
 477 [  --enable-coverage[=LEVEL]
 478                           enable compiler\'s code coverage collection.
 479                           Use to measure compiler performance and locate
 480                           unused parts of the compiler. With LEVEL, specify
 481                           optimization. Values are opt, noopt,
 482                           default is noopt],
 483 [case "${enableval}" in
 484 yes|noopt)
 485         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 486         ;;
 487 opt)
 488         coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 489         ;;
 490 *)
 491         AC_MSG_ERROR(unknown coverage setting $enableval)
 492         ;;
 493 esac],
 494 [coverage_flags=""])
 495 AC_SUBST(coverage_flags)
 496
 497 AC_ARG_ENABLE(gather-detailed-mem-stats,
 498 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 499 [enable_gather_detailed_mem_stats=no])
 500 if test x$enable_gather_detailed_mem_stats = xyes ; then
 501   AC_DEFINE(GATHER_STATISTICS, 1,
 502         [Define to enable detailed memory allocation stats gathering.])
 503 fi
 504
 505 # -------------------------------
 506 # Miscenalleous configure options
 507 # -------------------------------
 508
 509 # With stabs
 510 AC_ARG_WITH(stabs,
 511 [  --with-stabs            arrange to use stabs instead of host debug format],
 512 stabs="$with_stabs",
 513 stabs=no)
 514
 515 # Determine whether or not multilibs are enabled.
 516 AC_ARG_ENABLE(multilib,
 517 [  --enable-multilib       enable library support for multiple ABIs],
 518 [], [enable_multilib=yes])
 519 AC_SUBST(enable_multilib)
 520
 521 # Enable __cxa_atexit for C++.
 522 AC_ARG_ENABLE(__cxa_atexit,
 523 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 524 [], [])
 525
 526 # Enable threads
 527 # Pass with no value to take the default
 528 # Pass with a value to specify a thread package
 529 AC_ARG_ENABLE(threads,
 530 [  --enable-threads        enable thread usage for target GCC
 531   --enable-threads=LIB    use LIB thread package for target GCC],,
 532 enable_threads='')
 533 # Save in case it gets overwritten in config.gcc
 534 enable_threads_flag=$enable_threads
 535
 536 AC_ARG_ENABLE(objc-gc,
 537 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 538                           the GNU Objective-C runtime],
 539 if test x$enable_objc_gc = xno; then
 540         objc_boehm_gc=''
 541 else
 542         objc_boehm_gc=1
 543 fi,
 544 objc_boehm_gc='')
 545
 546 AC_ARG_WITH(dwarf2,
 547 [  --with-dwarf2           force the default debug format to be DWARF 2],
 548 dwarf2="$with_dwarf2",
 549 dwarf2=no)
 550
 551 AC_ARG_ENABLE(shared,
 552 [  --disable-shared        don't provide a shared libgcc],
 553 [
 554   case $enable_shared in
 555   yes | no) ;;
 556   *)
 557     enable_shared=no
 558     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 559     for pkg in $enableval; do
 560       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 561         enable_shared=yes
 562       fi
 563     done
 564     IFS="$ac_save_ifs"
 565     ;;
 566   esac
 567 ], [enable_shared=yes])
 568 AC_SUBST(enable_shared)
 569
 570 AC_ARG_WITH(sysroot,
 571 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 572 [
 573  case ${with_sysroot} in
 574  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 575  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 576  esac
 577
 578  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 579  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 580
 581  if test "x$exec_prefix" = xNONE; then
 582   if test "x$prefix" = xNONE; then
 583    test_prefix=/usr/local
 584   else
 585    test_prefix=$prefix
 586   fi
 587  else
 588   test_prefix=$exec_prefix
 589  fi
 590  case ${TARGET_SYSTEM_ROOT} in
 591  "${test_prefix}"|"${test_prefix}/"*|\
 592  '${exec_prefix}'|'${exec_prefix}/'*)
 593    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 594    TARGET_SYSTEM_ROOT_DEFINE="$t"
 595    ;;
 596  esac
 597 ], [
 598  TARGET_SYSTEM_ROOT=
 599  TARGET_SYSTEM_ROOT_DEFINE=
 600  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 601 ])
 602 AC_SUBST(TARGET_SYSTEM_ROOT)
 603 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 604 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 605
 606 # Build with intermodule optimisations
 607 AC_ARG_ENABLE(intermodule,
 608 [  --enable-intermodule    build the compiler in one step],
 609 [case ${enable_intermodule} in
 610   yes) onestep="-onestep";;
 611   *) onestep="";;
 612 esac],
 613 [onestep=""])
 614 AC_SUBST(onestep)
 615
 616 # -------------------------
 617 # Checks for other programs
 618 # -------------------------
 619
 620 AC_PROG_MAKE_SET
 621
 622 # Find some useful tools
 623 AC_PROG_AWK
 624 # We need awk to run opts.sh (to create options.c and options.h).
 625 # Bail out if it's missing.
 626 case ${AWK} in
 627   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 628 esac
 629
 630 gcc_AC_PROG_LN
 631 gcc_AC_PROG_LN_S
 632 AC_PROG_RANLIB
 633 gcc_AC_PROG_INSTALL
 634
 635 # See if cmp has --ignore-initial.
 636 gcc_AC_PROG_CMP_IGNORE_INITIAL
 637
 638 # See if we have the mktemp command.
 639 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 640
 641 # Do we have a single-tree copy of texinfo?
 642 if test -f $srcdir/../texinfo/Makefile.in; then
 643   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 644   gcc_cv_prog_makeinfo_modern=yes
 645   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 646 else
 647   # See if makeinfo has been installed and is modern enough
 648   # that we can use it.
 649   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 650   [GNU texinfo.* \([0-9][0-9.]*\)],
 651   [4.[2-9]*])
 652 fi
 653
 654 if test $gcc_cv_prog_makeinfo_modern = no; then
 655   AC_MSG_WARN([
 656 *** Makeinfo is missing or too old.
 657 *** Info documentation will not be built.])
 658   BUILD_INFO=
 659 else
 660   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 661 fi
 662
 663 # Is pod2man recent enough to regenerate manpages?
 664 AC_MSG_CHECKING([for recent Pod::Man])
 665 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 666   AC_MSG_RESULT(yes)
 667   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 668 else
 669   AC_MSG_RESULT(no)
 670   GENERATED_MANPAGES=
 671 fi
 672
 673 # How about lex?
 674 dnl Don't use AC_PROG_LEX; we insist on flex.
 675 dnl LEXLIB is not useful in gcc.
 676 if test -f $srcdir/../flex/skel.c; then
 677   FLEX='$(objdir)/../flex/flex'
 678 else
 679   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 680 fi
 681
 682 # Bison?
 683 # The -L switch is so bison can find its skeleton file.
 684 if test -f $srcdir/../bison/bison.simple; then
 685   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 686 else
 687   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 688 fi
 689
 690 # --------------------
 691 # Checks for C headers
 692 # --------------------
 693
 694 AC_MSG_CHECKING(for GNU C library)
 695 AC_CACHE_VAL(gcc_cv_glibc,
 696 [AC_TRY_COMPILE(
 697   [#include <features.h>],[
 698 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 699 #error Not a GNU C library system
 700 #endif],
 701   [gcc_cv_glibc=yes],
 702   gcc_cv_glibc=no)])
 703 AC_MSG_RESULT($gcc_cv_glibc)
 704 if test $gcc_cv_glibc = yes; then
 705   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 706 fi
 707
 708 # Need to reject headers which give warnings, so that the -Werror bootstrap
 709 # works later. *sigh*  This needs to come before all header checks.
 710 AC_PROG_CPP_WERROR
 711
 712 AC_HEADER_STDC
 713 AC_HEADER_TIME
 714 gcc_AC_HEADER_STDBOOL
 715 gcc_AC_HEADER_STRING
 716 AC_HEADER_SYS_WAIT
 717 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 718                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 719                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 720                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 721
 722 # Check for thread headers.
 723 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 724 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 725
 726 # These tests can't be done till we know if we have limits.h.
 727 gcc_AC_C_CHAR_BIT
 728 AC_C_BIGENDIAN_CROSS
 729
 730 # --------
 731 # UNSORTED
 732 # --------
 733
 734 # Stage specific cflags for build.
 735 stage1_cflags=
 736 case $build in
 737 vax-*-*)
 738   if test x$GCC = xyes
 739   then
 740     stage1_cflags="-Wa,-J"
 741   else
 742     stage1_cflags="-J"
 743   fi
 744   ;;
 745 powerpc-*-darwin*)
 746   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 747   # sources; use -no-cpp-precomp to get to GNU cpp.
 748   # Apple's GCC has bugs in designated initializer handling, so disable
 749   # that too.
 750   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 751   ;;
 752 esac
 753 AC_SUBST(stage1_cflags)
 754
 755 # These libraries may be used by collect2.
 756 # We may need a special search path to get them linked.
 757 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 758 [save_LIBS="$LIBS"
 759 for libs in '' -lld -lmld \
 760                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 761                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 762 do
 763         LIBS="$libs"
 764         AC_TRY_LINK_FUNC(ldopen,
 765                 [gcc_cv_collect2_libs="$libs"; break])
 766 done
 767 LIBS="$save_LIBS"
 768 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 769 case $gcc_cv_collect2_libs in
 770         "none required")        ;;
 771         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 772 esac
 773 AC_SUBST(COLLECT2_LIBS)
 774
 775 # When building Ada code on Alpha, we need exc_resume which is usually in
 776 # -lexc.  So test for it.
 777 save_LIBS="$LIBS"
 778 LIBS=
 779 AC_SEARCH_LIBS(exc_resume, exc)
 780 GNAT_LIBEXC="$LIBS"
 781 LIBS="$save_LIBS"
 782 AC_SUBST(GNAT_LIBEXC)
 783
 784 # Some systems put ldexp and frexp in libm instead of libc; assume
 785 # they're both in the same place.  jcf-dump needs them.
 786 save_LIBS="$LIBS"
 787 LIBS=
 788 AC_SEARCH_LIBS(ldexp, m)
 789 LDEXP_LIB="$LIBS"
 790 LIBS="$save_LIBS"
 791 AC_SUBST(LDEXP_LIB)
 792
 793 # Use <inttypes.h> only if it exists,
 794 # doesn't clash with <sys/types.h>, and declares intmax_t.
 795 AC_MSG_CHECKING(for inttypes.h)
 796 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 797 [AC_TRY_COMPILE(
 798   [#include <sys/types.h>
 799 #include <inttypes.h>],
 800   [intmax_t i = -1;],
 801   [gcc_cv_header_inttypes_h=yes],
 802   gcc_cv_header_inttypes_h=no)])
 803 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 804 if test $gcc_cv_header_inttypes_h = yes; then
 805   AC_DEFINE(HAVE_INTTYPES_H, 1,
 806         [Define if you have a working <inttypes.h> header file.])
 807 fi
 808
 809 dnl Disabled until we have a complete test for buggy enum bitfields.
 810 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 811
 812 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 813         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 814         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 815         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 816         setlocale)
 817
 818 if test x$ac_cv_func_mbstowcs = xyes; then
 819   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 820 [    AC_TRY_RUN([#include <stdlib.h>
 821 int main()
 822 {
 823   mbstowcs(0, "", 0);
 824   return 0;
 825 }],
 826     gcc_cv_func_mbstowcs_works=yes,
 827     gcc_cv_func_mbstowcs_works=no,
 828     gcc_cv_func_mbstowcs_works=yes)])
 829   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 830     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 831   [Define this macro if mbstowcs does not crash when its
 832    first argument is NULL.])
 833   fi
 834 fi
 835
 836 AC_CHECK_TYPE(ssize_t, int)
 837
 838 # Try to determine the array type of the second argument of getgroups
 839 # for the target system (int or gid_t).
 840 AC_TYPE_GETGROUPS
 841 if test "${target}" = "${build}"; then
 842   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 843 else
 844   case "${target}" in
 845         # This condition may need some tweaking.  It should include all
 846         # targets where the array type of the second argument of getgroups
 847         # is int and the type of gid_t is not equivalent to int.
 848         *-*-sunos* | *-*-ultrix*)
 849                 TARGET_GETGROUPS_T=int
 850                 ;;
 851         *)
 852                 TARGET_GETGROUPS_T=gid_t
 853                 ;;
 854   esac
 855 fi
 856 AC_SUBST(TARGET_GETGROUPS_T)
 857
 858 gcc_AC_FUNC_PRINTF_PTR
 859 gcc_AC_FUNC_MMAP_BLACKLIST
 860
 861 case "${host}" in
 862 *-*-*vms*)
 863   # Under VMS, vfork works very differently than on Unix. The standard test
 864   # won't work, and it isn't easily adaptable. It makes more sense to
 865   # just force it.
 866   ac_cv_func_vfork_works=yes
 867   ;;
 868 esac
 869 AC_FUNC_VFORK
 870
 871 AM_ICONV
 872 # Until we have in-tree GNU iconv:
 873 LIBICONV_DEP=
 874 AC_SUBST(LIBICONV_DEP)
 875
 876 AM_LC_MESSAGES
 877
 878 # We will need to find libiberty.h and ansidecl.h
 879 saved_CFLAGS="$CFLAGS"
 880 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 881 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 882         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 883         fprintf_unlocked strstr errno snprintf vasprintf \
 884         malloc realloc calloc free basename getopt clock, , ,[
 885 #include "ansidecl.h"
 886 #include "system.h"])
 887
 888 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 889 #include "ansidecl.h"
 890 #include "system.h"
 891 #ifdef HAVE_SYS_RESOURCE_H
 892 #include <sys/resource.h>
 893 #endif
 894 ])
 895
 896 AC_TRY_COMPILE([
 897 #include "ansidecl.h"
 898 #include "system.h"
 899 #ifdef HAVE_SYS_RESOURCE_H
 900 #include <sys/resource.h>
 901 #endif
 902 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 903 [Define to \`long' if <sys/resource.h> doesn't define.])])
 904
 905 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 906 #include "ansidecl.h"
 907 #include "system.h"
 908 #ifdef HAVE_LDFCN_H
 909 #include <ldfcn.h>
 910 #endif
 911 ])
 912
 913 gcc_AC_CHECK_DECLS(times, , ,[
 914 #include "ansidecl.h"
 915 #include "system.h"
 916 #ifdef HAVE_SYS_TIMES_H
 917 #include <sys/times.h>
 918 #endif
 919 ])
 920
 921 # More time-related stuff.
 922 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 923 AC_TRY_COMPILE([
 924 #include "ansidecl.h"
 925 #include "system.h"
 926 #ifdef HAVE_SYS_TIMES_H
 927 #include <sys/times.h>
 928 #endif
 929 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 930 if test $ac_cv_struct_tms = yes; then
 931   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 932   [Define if <sys/times.h> defines struct tms.])
 933 fi
 934
 935 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 936 # revisit after autoconf 2.50.
 937 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 938 AC_TRY_COMPILE([
 939 #include "ansidecl.h"
 940 #include "system.h"
 941 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 942 if test $gcc_cv_type_clock_t = yes; then
 943   AC_DEFINE(HAVE_CLOCK_T, 1,
 944   [Define if <time.h> defines clock_t.])
 945 fi
 946
 947 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
 948 [AC_TRY_COMPILE([
 949 #include "ansidecl.h"
 950 #include "system.h"
 951 ],
 952 [if ((uchar *)0) return 0;
 953  if (sizeof(uchar)) return 0;],
 954 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
 955 if test $ac_cv_type_uchar = yes; then
 956   AC_DEFINE(HAVE_UCHAR, 1,
 957   [Define if <sys/types.h> defines \`uchar'.])
 958 fi
 959
 960 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 961 CFLAGS="$saved_CFLAGS"
 962
 963 gcc_AC_INITFINI_ARRAY
 964
 965 # mkdir takes a single argument on some systems.
 966 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 967
 968 # File extensions
 969 manext='.1'
 970 objext='.o'
 971 AC_SUBST(manext)
 972 AC_SUBST(objext)
 973
 974 # With Setjmp/Longjmp based exception handling.
 975 AC_ARG_ENABLE(sjlj-exceptions,
 976 [  --enable-sjlj-exceptions
 977                           arrange to use setjmp/longjmp exception handling],
 978 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
 979 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
 980   [Define 0/1 to force the choice for exception handling model.])])
 981
 982 if test x$host = x$target; then
 983    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
 984 else
 985    use_libunwind_default=no
 986 fi
 987 # Use libunwind based exception handling.
 988 AC_ARG_ENABLE(libunwind-exceptions,
 989 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
 990 use_libunwind_exceptions=$enableval,
 991 use_libunwind_exceptions=$use_libunwind_default)
 992 if test x"$use_libunwind_exceptions" = xyes; then
 993    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
 994         [Define if gcc should use -lunwind.])
 995 fi
 996
 997 # --------------------------------------------------------
 998 # Build, host, and target specific configuration fragments
 999 # --------------------------------------------------------
1000
1001 # Collect build-machine-specific information.
1002 . ${srcdir}/config.build
1003
1004 # Collect host-machine-specific information.
1005 . ${srcdir}/config.host
1006
1007 target_gtfiles=
1008
1009 # Collect target-machine-specific information.
1010 . ${srcdir}/config.gcc
1011
1012 extra_objs="${host_extra_objs} ${extra_objs}"
1013 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1014
1015 # Default the target-machine variables that were not explicitly set.
1016 if test x"$tm_file" = x
1017 then tm_file=$cpu_type/$cpu_type.h; fi
1018
1019 if test x"$extra_headers" = x
1020 then extra_headers=; fi
1021
1022 if test x$md_file = x
1023 then md_file=$cpu_type/$cpu_type.md; fi
1024
1025 if test x$out_file = x
1026 then out_file=$cpu_type/$cpu_type.c; fi
1027
1028 if test x"$tmake_file" = x
1029 then tmake_file=$cpu_type/t-$cpu_type
1030 fi
1031
1032 if test x"$dwarf2" = xyes
1033 then tm_file="$tm_file tm-dwarf2.h"
1034 fi
1035
1036 # Say what files are being used for the output code and MD file.
1037 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1038 echo "Using \`$srcdir/config/$md_file' as machine description file."
1039
1040 # If any of the xm_file variables contain nonexistent files, warn
1041 # about them and drop them.
1042
1043 bx=
1044 for x in $build_xm_file; do
1045   if    test -f $srcdir/config/$x
1046   then      bx="$bx $x"
1047   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1048   fi
1049 done
1050 build_xm_file="$bx"
1051
1052 hx=
1053 for x in $host_xm_file; do
1054   if    test -f $srcdir/config/$x
1055   then      hx="$hx $x"
1056   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1057   fi
1058 done
1059 host_xm_file="$hx"
1060
1061 tx=
1062 for x in $xm_file; do
1063   if    test -f $srcdir/config/$x
1064   then      tx="$tx $x"
1065   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1066   fi
1067 done
1068 xm_file="$tx"
1069
1070 count=a
1071 for f in $tm_file; do
1072         count=${count}x
1073 done
1074 if test $count = ax; then
1075         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1076 else
1077         echo "Using the following target machine macro files:"
1078         for f in $tm_file; do
1079                 echo "  $srcdir/config/$f"
1080         done
1081 fi
1082
1083 if test x$need_64bit_hwint = xyes; then
1084         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1085 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1086 fi
1087
1088 count=a
1089 for f in $host_xm_file; do
1090         count=${count}x
1091 done
1092 if test $count = a; then
1093         :
1094 elif test $count = ax; then
1095         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1096 else
1097         echo "Using the following host machine macro files:"
1098         for f in $host_xm_file; do
1099                 echo "  $srcdir/config/$f"
1100         done
1101 fi
1102 echo "Using ${out_host_hook_obj} for host machine hooks."
1103
1104 if test "$host_xm_file" != "$build_xm_file"; then
1105         count=a
1106         for f in $build_xm_file; do
1107                 count=${count}x
1108         done
1109         if test $count = a; then
1110                 :
1111         elif test $count = ax; then
1112                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1113         else
1114                 echo "Using the following build machine macro files:"
1115                 for f in $build_xm_file; do
1116                         echo "  $srcdir/config/$f"
1117                 done
1118         fi
1119 fi
1120
1121 # Check if a valid thread package
1122 case ${enable_threads_flag} in
1123   "" | no)
1124     # No threads
1125     target_thread_file='single'
1126     ;;
1127   yes)
1128     # default
1129     target_thread_file='single'
1130     ;;
1131   aix | dce | gnat | irix | posix | rtems | \
1132   single | solaris | vxworks | win32 )
1133     target_thread_file=${enable_threads_flag}
1134     ;;
1135   *)
1136     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1137     exit 1
1138     ;;
1139 esac
1140
1141 if test x${thread_file} = x; then
1142   # No thread file set by target-specific clauses in config.gcc,
1143   # so use file chosen by default logic above
1144   thread_file=${target_thread_file}
1145 fi
1146
1147 if test x$enable___cxa_atexit = xyes || \
1148    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1149    AC_CHECK_FUNC(__cxa_atexit,
1150         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1151         [Define if you want to use __cxa_atexit, rather than atexit, to
1152         register C++ destructors for local statics and global objects.
1153         This is essential for fully standards-compliant handling of
1154         destructors, but requires __cxa_atexit in libc.])],
1155         echo "__cxa_atexit can't be enabled on this target")
1156 fi
1157
1158 # Look for a file containing extra machine modes.
1159 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1160   extra_modes_file='$(srcdir)'/config/${extra_modes}
1161   AC_SUBST(extra_modes_file)
1162   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1163   [Define to the name of a file containing a list of extra machine modes
1164    for this architecture.])
1165 fi
1166
1167 # auto-host.h is the file containing items generated by autoconf and is
1168 # the first file included by config.h.
1169 # If host=build, it is correct to have bconfig include auto-host.h
1170 # as well.  If host!=build, we are in error and need to do more
1171 # work to find out the build config parameters.
1172 if test x$host = x$build
1173 then
1174         build_auto=auto-host.h
1175         FORBUILD=..
1176 else
1177         # We create a subdir, then run autoconf in the subdir.
1178         # To prevent recursion we set host and build for the new
1179         # invocation of configure to the build for this invocation
1180         # of configure.
1181         tempdir=build.$$
1182         rm -rf $tempdir
1183         mkdir $tempdir
1184         cd $tempdir
1185         case ${srcdir} in
1186         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1187         *) realsrcdir=../${srcdir};;
1188         esac
1189         saved_CFLAGS="${CFLAGS}"
1190         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1191         ${realsrcdir}/configure \
1192                 --enable-languages=${enable_languages} \
1193                 --target=$target_alias --host=$build_alias --build=$build_alias
1194         CFLAGS="${saved_CFLAGS}"
1195
1196         # We just finished tests for the build machine, so rename
1197         # the file auto-build.h in the gcc directory.
1198         mv auto-host.h ../auto-build.h
1199         cd ..
1200         rm -rf $tempdir
1201         build_auto=auto-build.h
1202         FORBUILD=../${build_subdir}
1203 fi
1204 AC_SUBST(FORBUILD)
1205
1206 tm_file="${tm_file} defaults.h"
1207 tm_p_file="${tm_p_file} tm-preds.h"
1208 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1209 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1210 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1211 # put this back in temporarily.
1212 xm_file="ansidecl.h ${xm_file}"
1213
1214 # --------
1215 # UNSORTED
1216 # --------
1217
1218 # Get the version trigger filename from the toplevel
1219 if test "${with_gcc_version_trigger+set}" = set; then
1220         gcc_version_trigger=$with_gcc_version_trigger
1221 else
1222         gcc_version_trigger=${srcdir}/version.c
1223 fi
1224 changequote(,)dnl
1225 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1226 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1227
1228 # Compile in configure arguments.
1229 if test -f configargs.h ; then
1230         # Being re-configured.
1231         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1232         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1233 else
1234         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1235 fi
1236
1237 # Double all backslashes and backslash all quotes to turn
1238 # gcc_config_arguments into a C string.
1239 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1240 $gcc_config_arguments
1241 EOF
1242 gcc_config_arguments_str=`cat conftest.out`
1243 rm -f conftest.out
1244
1245 cat > configargs.h <<EOF
1246 /* Generated automatically. */
1247 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1248 static const char thread_model[] = "$thread_file";
1249
1250 static const struct {
1251   const char *name, *value;
1252 } configure_default_options[] = $configure_default_options;
1253 EOF
1254 changequote([,])dnl
1255
1256 # Internationalization
1257 PACKAGE=gcc
1258 VERSION="$gcc_version"
1259 AC_SUBST(PACKAGE)
1260 AC_SUBST(VERSION)
1261
1262 ZW_GNU_GETTEXT_SISTER_DIR
1263
1264 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1265 # -liconv on the link line twice.
1266 case "$LIBINTL" in *$LIBICONV*)
1267         LIBICONV= ;;
1268 esac
1269
1270 # Windows32 Registry support for specifying GCC installation paths.
1271 AC_ARG_ENABLE(win32-registry,
1272 [  --disable-win32-registry
1273                           disable lookup of installation paths in the
1274                           Registry on Windows hosts
1275   --enable-win32-registry enable registry lookup (default)
1276   --enable-win32-registry=KEY
1277                           use KEY instead of GCC version as the last portion
1278                           of the registry key],,)
1279 case $host_os in
1280         win32 | pe | cygwin* | mingw32* | uwin*)
1281 AC_MSG_CHECKING(whether windows registry support is requested)
1282 if test "x$enable_win32_registry" != xno; then
1283   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1284 [Define to 1 if installation paths should be looked up in Windows32
1285    Registry. Ignored on non windows32 hosts.])
1286   AC_MSG_RESULT(yes)
1287   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1288 else
1289   AC_MSG_RESULT(no)
1290 fi
1291
1292 # Check if user specified a different registry key.
1293 case "x${enable_win32_registry}" in
1294 x | xyes)
1295   # default.
1296   gcc_cv_win32_registry_key="$VERSION"
1297   ;;
1298 xno)
1299   # no registry lookup.
1300   gcc_cv_win32_registry_key=''
1301   ;;
1302 *)
1303   # user-specified key.
1304   gcc_cv_win32_registry_key="$enable_win32_registry"
1305   ;;
1306 esac
1307
1308 if test "x$enable_win32_registry" != xno; then
1309   AC_MSG_CHECKING(registry key on windows hosts)
1310   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1311         [Define to be the last portion of registry key on windows hosts.])
1312   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1313 fi
1314 ;;
1315 esac
1316
1317 # Get an absolute path to the GCC top-level source directory
1318 holddir=`${PWDCMD-pwd}`
1319 cd $srcdir
1320 topdir=`${PWDCMD-pwd}`
1321 cd $holddir
1322
1323 # Conditionalize the makefile for this host machine.
1324 xmake_file=
1325 for f in ${host_xmake_file}
1326 do
1327         if test -f ${srcdir}/config/$f
1328         then
1329                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1330         fi
1331 done
1332
1333 # Conditionalize the makefile for this target machine.
1334 tmake_file_=
1335 for f in ${tmake_file}
1336 do
1337         if test -f ${srcdir}/config/$f
1338         then
1339                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1340         fi
1341 done
1342 tmake_file="${tmake_file_}"
1343
1344 symbolic_link='ln -s'
1345
1346 # If the host doesn't support symlinks, modify CC in
1347 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1348 # Otherwise, we can use "CC=$(CC)".
1349 rm -f symtest.tem
1350 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1351 then
1352         cc_set_by_configure="\$(CC)"
1353         quoted_cc_set_by_configure="\$(CC)"
1354         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1355         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1356 else
1357         rm -f symtest.tem
1358         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1359         then
1360                 symbolic_link="cp -p"
1361         else
1362                 symbolic_link="cp"
1363         fi
1364         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1365         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1366         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1367         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1368 fi
1369 rm -f symtest.tem
1370
1371 out_object_file=`basename $out_file .c`.o
1372
1373 tm_file_list=
1374 tm_include_list=
1375 for f in $tm_file; do
1376   case $f in
1377     defaults.h )
1378        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1379        tm_include_list="${tm_include_list} $f"
1380        ;;
1381     * )
1382        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1383        tm_include_list="${tm_include_list} config/$f"
1384        ;;
1385   esac
1386 done
1387
1388 tm_p_file_list=
1389 tm_p_include_list=
1390 for f in $tm_p_file; do
1391   case $f in
1392     tm-preds.h )
1393        tm_p_file_list="${tm_p_file_list} $f"
1394        tm_p_include_list="${tm_p_include_list} $f"
1395        ;;
1396     * )
1397        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1398        tm_p_include_list="${tm_p_include_list} config/$f"
1399   esac
1400 done
1401
1402 xm_file_list=
1403 xm_include_list=
1404 for f in $xm_file; do
1405   case $f in
1406     ansidecl.h )
1407        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1408        xm_include_list="${xm_include_list} $f"
1409        ;;
1410     auto-host.h )
1411        xm_file_list="${xm_file_list} $f"
1412        xm_include_list="${xm_include_list} $f"
1413        ;;
1414     * )
1415        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1416        xm_include_list="${xm_include_list} config/$f"
1417        ;;
1418   esac
1419 done
1420
1421 host_xm_file_list=
1422 host_xm_include_list=
1423 for f in $host_xm_file; do
1424   case $f in
1425     ansidecl.h )
1426        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1427        host_xm_include_list="${host_xm_include_list} $f"
1428        ;;
1429     auto-host.h )
1430        host_xm_file_list="${host_xm_file_list} $f"
1431        host_xm_include_list="${host_xm_include_list} $f"
1432        ;;
1433     * )
1434        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1435        host_xm_include_list="${host_xm_include_list} config/$f"
1436        ;;
1437   esac
1438 done
1439
1440 build_xm_file_list=
1441 for f in $build_xm_file; do
1442   case $f in
1443     ansidecl.h )
1444        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1445        build_xm_include_list="${build_xm_include_list} $f"
1446        ;;
1447     auto-build.h | auto-host.h )
1448        build_xm_file_list="${build_xm_file_list} $f"
1449        build_xm_include_list="${build_xm_include_list} $f"
1450        ;;
1451     * )
1452        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1453        build_xm_include_list="${build_xm_include_list} config/$f"
1454        ;;
1455   esac
1456 done
1457
1458 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1459 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1460 CROSS=                                          AC_SUBST(CROSS)
1461 ALL=all.internal                                AC_SUBST(ALL)
1462 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1463 if test x$host != x$target
1464 then
1465         CROSS="-DCROSS_COMPILE"
1466         ALL=all.cross
1467         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1468         case "$host","$target" in
1469         # Darwin crosses can use the host system's libraries and headers,
1470         # because of the fat library support.  Of course, it must be the
1471         # same version of Darwin on both sides.  Allow the user to
1472         # just say --target=foo-darwin without a version number to mean
1473         # "the version on this system".
1474             *-*-darwin*,*-*-darwin*)
1475                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1476                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1477                 if test $hostos = $targetos -o $targetos = darwin ; then
1478                     CROSS=
1479                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1480                     with_headers=yes
1481                 fi
1482                 ;;
1483
1484             i?86-*-*,x86_64-*-* \
1485             | powerpc*-*-*,powerpc64*-*-*)
1486                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1487         esac
1488 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1489         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1490         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1491 fi
1492
1493 # If this is a cross-compiler that does not
1494 # have its own set of headers then define
1495 # inhibit_libc
1496
1497 # If this is using newlib, without having the headers available now,
1498 # then define inhibit_libc in LIBGCC2_CFLAGS.
1499 # This prevents libgcc2 from containing any code which requires libc
1500 # support.
1501 inhibit_libc=
1502 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1503        test x$with_newlib = xyes ; } &&
1504      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1505        inhibit_libc=-Dinhibit_libc
1506 fi
1507 AC_SUBST(inhibit_libc)
1508
1509 # When building gcc with a cross-compiler, we need to adjust things so
1510 # that the generator programs are still built with the native compiler.
1511 # Also, we cannot run fixincludes or fix-header.
1512
1513 # These are the normal (build=host) settings:
1514 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1515 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1516 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1517 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1518
1519 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1520
1521 # Possibly disable fixproto, on a per-target basis.
1522 case ${use_fixproto} in
1523   no)
1524     STMP_FIXPROTO=
1525     ;;
1526   yes)
1527     STMP_FIXPROTO=stmp-fixproto
1528     ;;
1529 esac
1530 AC_SUBST(STMP_FIXPROTO)
1531
1532 # And these apply if build != host, or we are generating coverage data
1533 if test x$build != x$host || test "x$coverage_flags" != x
1534 then
1535     BUILD_PREFIX=build-
1536     BUILD_PREFIX_1=build-
1537     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1538
1539     if test "x$TARGET_SYSTEM_ROOT" = x; then
1540         STMP_FIXINC=
1541         STMP_FIXPROTO=
1542     fi
1543 fi
1544
1545 # Expand extra_headers to include complete path.
1546 # This substitutes for lots of t-* files.
1547 extra_headers_list=
1548 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1549 for file in ${extra_headers} ; do
1550   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1551 done
1552
1553 # Add a definition of USE_COLLECT2 if system wants one.
1554 case $use_collect2 in
1555   no) use_collect2= ;;
1556   "") ;;
1557   *)
1558     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1559     xm_defines="${xm_defines} USE_COLLECT2"
1560     ;;
1561 esac
1562
1563 # Identify the assembler which will work hand-in-glove with the newly
1564 # built GCC, so that we can examine its features.  This is the assembler
1565 # which will be driven by the driver program.
1566 #
1567 # If build != host, and we aren't building gas in-tree, we identify a
1568 # build->target assembler and hope that it will have the same features
1569 # as the host->target assembler we'll be using.
1570 AC_MSG_CHECKING(what assembler to use)
1571 in_tree_gas=no
1572 gcc_cv_as=
1573 gcc_cv_gas_major_version=
1574 gcc_cv_gas_minor_version=
1575 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1576 if test -x "$DEFAULT_ASSEMBLER"; then
1577         gcc_cv_as="$DEFAULT_ASSEMBLER"
1578 elif test -x "$AS"; then
1579         gcc_cv_as="$AS"
1580 elif test -x as$host_exeext; then
1581         # Build using assembler in the current directory.
1582         gcc_cv_as=./as$host_exeext
1583 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1584      && test -f ../gas/Makefile; then
1585   # Single tree build which includes gas.
1586   in_tree_gas=yes
1587   _gcc_COMPUTE_GAS_VERSION
1588   rm -f as$host_exeext
1589   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1590   in_tree_gas_is_elf=no
1591   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1592      || (grep 'obj_format = multi' ../gas/Makefile \
1593          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1594   then
1595     in_tree_gas_is_elf=yes
1596   fi
1597 fi
1598
1599 if test "x$gcc_cv_as" = x; then
1600         # Search the same directories that the installed compiler will
1601         # search.  Else we may find the wrong assembler and lose.  If we
1602         # do not find a suitable assembler binary, then try the user's
1603         # path.
1604         #
1605         # Also note we have to check MD_EXEC_PREFIX before checking the
1606         # user's path.  Unfortunately, there is no good way to get at the
1607         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1608         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1609         # to be fixed as part of the make/configure rewrite too.
1610
1611         if test "x$exec_prefix" = xNONE; then
1612                 if test "x$prefix" = xNONE; then
1613                         test_prefix=/usr/local
1614                 else
1615                         test_prefix=$prefix
1616                 fi
1617         else
1618                 test_prefix=$exec_prefix
1619         fi
1620
1621         # If the loop below does not find an assembler, then use whatever
1622         # one we can find in the users's path.
1623         # user's path.
1624         if test "x$program_prefix" != xNONE; then
1625                 gcc_cv_as=${program_prefix}as$host_exeext
1626         else
1627                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1628         fi
1629
1630         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1631                    $test_prefix/libexec/gcc/$target_noncanonical \
1632                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1633                    /usr/lib/gcc/$target_noncanonical \
1634                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1635                    $test_prefix/$target_noncanonical/bin"
1636
1637         if test x$host = x$target; then
1638             test_dirs="$test_dirs \
1639                    /usr/libexec \
1640                    /usr/ccs/gcc \
1641                    /usr/ccs/bin \
1642                    /udk/usr/ccs/bin \
1643                    /bsd43/usr/lib/cmplrs/cc \
1644                    /usr/cross64/usr/bin \
1645                    /usr/lib/cmplrs/cc \
1646                    /sysv/usr/lib/cmplrs/cc \
1647                    /svr4/usr/lib/cmplrs/cc \
1648                    /usr/bin"
1649         fi
1650
1651         for dir in $test_dirs; do
1652                 if test -x $dir/as$host_exeext; then
1653                         gcc_cv_as=$dir/as$host_exeext
1654                         break;
1655                 fi
1656         done
1657 fi
1658 case $in_tree_gas in
1659   yes)
1660     AC_MSG_RESULT("newly built gas")
1661     ;;
1662   no)
1663     AC_MSG_RESULT($gcc_cv_as)
1664     ;;
1665 esac
1666
1667 # Identify the linker which will work hand-in-glove with the newly
1668 # built GCC, so that we can examine its features.  This is the linker
1669 # which will be driven by the driver program.
1670 #
1671 # If build != host, and we aren't building gas in-tree, we identify a
1672 # build->target linker and hope that it will have the same features
1673 # as the host->target linker we'll be using.
1674 AC_MSG_CHECKING(what linker to use)
1675 in_tree_ld=no
1676 gcc_cv_ld=
1677 gcc_cv_gld_major_version=
1678 gcc_cv_gld_minor_version=
1679 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1680 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1681 if test -x "$DEFAULT_LINKER"; then
1682         gcc_cv_ld="$DEFAULT_LINKER"
1683 elif test -x "$LD_FOR_TARGET"; then
1684         gcc_cv_ld="$LD_FOR_TARGET"
1685 elif test -x "$LD" && test x$host = x$target; then
1686         gcc_cv_ld="$LD"
1687 elif test -x collect-ld$host_exeext; then
1688         # Build using linker in the current directory.
1689         gcc_cv_ld=./collect-ld$host_exeext
1690 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1691      && test -f ../ld/Makefile; then
1692         # Single tree build which includes ld.
1693         in_tree_ld=yes
1694         in_tree_ld_is_elf=no
1695         if (grep 'EMUL = .*elf' ../ld/Makefile \
1696             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1697           in_tree_ld_is_elf=yes
1698         fi
1699         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1700         do
1701 changequote(,)dnl
1702                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1703 changequote([,])dnl
1704                 if test x$gcc_cv_gld_version != x; then
1705                         break
1706                 fi
1707         done
1708 changequote(,)dnl
1709         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1710         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1711 changequote([,])dnl
1712         rm -f collect-ld$host_exeext
1713         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1714                 2>/dev/null
1715 fi
1716
1717 if test "x$gcc_cv_ld" = x; then
1718         # Search the same directories that the installed compiler will
1719         # search.  Else we may find the wrong linker and lose.  If we
1720         # do not find a suitable linker binary, then try the user's
1721         # path.
1722         #
1723         # Also note we have to check MD_EXEC_PREFIX before checking the
1724         # user's path.  Unfortunately, there is no good way to get at the
1725         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1726         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1727         # to be fixed as part of the make/configure rewrite too.
1728
1729         if test "x$exec_prefix" = xNONE; then
1730                 if test "x$prefix" = xNONE; then
1731                         test_prefix=/usr/local
1732                 else
1733                         test_prefix=$prefix
1734                 fi
1735         else
1736                 test_prefix=$exec_prefix
1737         fi
1738
1739         # If the loop below does not find an linker, then use whatever
1740         # one we can find in the users's path.
1741         # user's path.
1742         if test "x$program_prefix" != xNONE; then
1743                 gcc_cv_ld=${program_prefix}ld$host_exeext
1744         else
1745                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1746         fi
1747
1748         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1749                    $test_prefix/libexec/gcc/$target_noncanonical \
1750                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1751                    /usr/lib/gcc/$target_noncanonical \
1752                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1753                    $test_prefix/$target_noncanonical/bin"
1754
1755         if test x$host = x$target; then
1756             test_dirs="$test_dirs \
1757                    /usr/libexec \
1758                    /usr/ccs/gcc \
1759                    /usr/ccs/bin \
1760                    /udk/usr/ccs/bin \
1761                    /bsd43/usr/lib/cmplrs/cc \
1762                    /usr/cross64/usr/bin \
1763                    /usr/lib/cmplrs/cc \
1764                    /sysv/usr/lib/cmplrs/cc \
1765                    /svr4/usr/lib/cmplrs/cc \
1766                    /usr/bin"
1767         fi
1768
1769         for dir in $test_dirs; do
1770                 if test -x $dir/ld$host_exeext; then
1771                         gcc_cv_ld=$dir/ld$host_exeext
1772                         break;
1773                 fi
1774         done
1775 fi
1776 case $in_tree_ld in
1777   yes)
1778     AC_MSG_RESULT("newly built ld")
1779     ;;
1780   no)
1781     AC_MSG_RESULT($gcc_cv_ld)
1782     ;;
1783 esac
1784
1785 # Figure out what nm we will be using.
1786 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1787 AC_MSG_CHECKING(what nm to use)
1788 in_tree_nm=no
1789 if test -x nm$host_exeext; then
1790         gcc_cv_nm=./nm$host_exeext
1791 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1792      && test -f ../binutils/Makefile; then
1793         # Single tree build which includes binutils.
1794         in_tree_nm=yes
1795         gcc_cv_nm=./nm$host_exeext
1796         rm -f nm$host_exeext
1797         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1798 elif test "x$program_prefix" != xNONE; then
1799         gcc_cv_nm=${program_prefix}nm$host_exeext
1800 else
1801         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1802 fi
1803 case $in_tree_nm in
1804   yes) AC_MSG_RESULT("newly built nm") ;;
1805   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1806 esac
1807
1808 # Figure out what objdump we will be using.
1809 AC_MSG_CHECKING(what objdump to use)
1810 in_tree_objdump=no
1811 if test -x objdump$host_exeext; then
1812         gcc_cv_objdump=./objdump$host_exeext
1813 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1814      && test -f ../binutils/Makefile; then
1815         # Single tree build which includes binutils.
1816         in_tree_objdump=yes
1817         gcc_cv_objdump=./objdump$host_exeext
1818         rm -f objdump$host_exeext
1819         $symbolic_link ../binutils/objdump$host_exeext \
1820                 objdump$host_exeext 2>/dev/null
1821 elif test "x$program_prefix" != xNONE; then
1822         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1823 else
1824         gcc_cv_objdump=`echo objdump | \
1825                 sed "${program_transform_name}"`$host_exeext
1826 fi
1827 case $in_tree_objdump in
1828   yes) AC_MSG_RESULT("newly built objdump") ;;
1829   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1830 esac
1831
1832 # Figure out what assembler alignment features are present.
1833 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1834  [2,6,0],,
1835 [.balign 4
1836 .p2align 2],,
1837 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1838   [Define if your assembler supports .balign and .p2align.])])
1839
1840 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1841  [2,8,0],,
1842  [.p2align 4,,7],,
1843 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1844   [Define if your assembler supports specifying the maximum number
1845    of bytes to skip when using the GAS .p2align command.])])
1846
1847 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1848  [elf,2,9,0],,
1849  [conftest_label1: .word 0
1850 .subsection -1
1851 conftest_label2: .word 0
1852 .previous],
1853  [if test x$gcc_cv_nm != x; then
1854     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1855     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1856     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1857     then :
1858     else gcc_cv_as_subsection_m1=yes
1859     fi
1860     rm -f conftest.nm1 conftest.nm2
1861   fi],
1862  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1863   [Define if your assembler supports .subsection and .subsection -1 starts
1864    emitting at the beginning of your section.])])
1865
1866 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1867  [2,2,0],,
1868  [      .weak foobar],,
1869 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1870
1871 # .hidden needs to be supported in both the assembler and the linker,
1872 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1873 # This is irritatingly difficult to feature test for; we have to check the
1874 # date string after the version number.  If we've got an in-tree
1875 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1876 # to be safe.
1877 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
1878 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
1879  [elf,2,13,0],,
1880 [       .hidden foobar
1881 foobar:])
1882
1883 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
1884 [if test $in_tree_ld = yes ; then
1885   gcc_cv_ld_hidden=no
1886   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
1887      && test $in_tree_ld_is_elf = yes; then
1888      gcc_cv_ld_hidden=yes
1889   fi
1890 else
1891   gcc_cv_ld_hidden=yes
1892   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
1893   if echo "$ld_ver" | grep GNU > /dev/null; then
1894 changequote(,)dnl
1895     ld_vers=`echo $ld_ver | sed -n \
1896         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1897         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1898         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
1899         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
1900         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
1901         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
1902     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
1903     if test 0"$ld_date" -lt 20020404; then
1904       if test -n "$ld_date"; then
1905         # If there was date string, but was earlier than 2002-04-04, fail
1906         gcc_cv_ld_hidden=no
1907       elif test -z "$ld_vers"; then
1908         # If there was no date string nor ld version number, something is wrong
1909         gcc_cv_ld_hidden=no
1910       else
1911         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
1912         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
1913         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
1914         test -z "$ld_vers_patch" && ld_vers_patch=0
1915         if test "$ld_vers_major" -lt 2; then
1916           gcc_cv_ld_hidden=no
1917         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
1918           gcc_cv_ld_hidden="no"
1919         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
1920           gcc_cv_ld_hidden=no
1921         fi
1922       fi
1923 changequote([,])dnl
1924     fi
1925   else
1926     case "${target}" in
1927       hppa64*-*-hpux* | ia64*-*-hpux*)
1928         gcc_cv_ld_hidden=yes
1929         ;;
1930       *)
1931         gcc_cv_ld_hidden=no
1932         ;;
1933     esac
1934   fi
1935 fi])
1936 libgcc_visibility=no
1937 AC_SUBST(libgcc_visibility)
1938 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
1939   libgcc_visibility=yes
1940   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1941   [Define if your assembler and linker support .hidden.])
1942 fi
1943
1944 # Check if we have .[us]leb128, and support symbol arithmetic with it.
1945 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
1946   [elf,2,11,0],,
1947 [       .data
1948         .uleb128 L2 - L1
1949 L1:
1950         .uleb128 1280
1951         .sleb128 -1010
1952 L2:],
1953  [# GAS versions before 2.11 do not support uleb128,
1954   # despite appearing to.
1955   # ??? There exists an elf-specific test that will crash
1956   # the assembler.  Perhaps it's better to figure out whether
1957   # arbitrary sections are supported and try the test.
1958   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
1959   if echo "$as_ver" | grep GNU > /dev/null; then
1960 changequote(,)dnl
1961     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1962     as_major=`echo $as_ver | sed 's/\..*//'`
1963     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1964 changequote([,])dnl
1965     if test $as_major -eq 2 && test $as_minor -lt 11
1966     then :
1967     else gcc_cv_as_leb128=yes
1968     fi
1969   fi],
1970   [AC_DEFINE(HAVE_AS_LEB128, 1,
1971     [Define if your assembler supports .sleb128 and .uleb128.])])
1972
1973 # GAS versions up to and including 2.11.0 may mis-optimize
1974 # .eh_frame data.
1975 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
1976   [elf,2,12,0],,
1977 [       .text
1978 .LFB1:
1979         .4byte  0
1980 .L1:
1981         .4byte  0
1982 .LFE1:
1983         .section        .eh_frame,"aw",@progbits
1984 __FRAME_BEGIN__:
1985         .4byte  .LECIE1-.LSCIE1
1986 .LSCIE1:
1987         .4byte  0x0
1988         .byte   0x1
1989         .ascii "z\0"
1990         .byte   0x1
1991         .byte   0x78
1992         .byte   0x1a
1993         .byte   0x0
1994         .byte   0x4
1995         .4byte  1
1996         .p2align 1
1997 .LECIE1:
1998 .LSFDE1:
1999         .4byte  .LEFDE1-.LASFDE1
2000 .LASFDE1:
2001         .4byte  .LASFDE1-__FRAME_BEGIN__
2002         .4byte  .LFB1
2003         .4byte  .LFE1-.LFB1
2004         .byte   0x4
2005         .4byte  .LFE1-.LFB1
2006         .byte   0x4
2007         .4byte  .L1-.LFB1
2008 .LEFDE1:],
2009 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2010 cat > conftest.lit <<EOF
2011  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2012  0010 01000000 12000000 18000000 00000000  ................
2013  0020 08000000 04080000 0044               .........D      @&t@
2014 EOF
2015 cat > conftest.big <<EOF
2016  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2017  0010 00000001 00000012 00000018 00000000  ................
2018  0020 00000008 04000000 0844               .........D      @&t@
2019 EOF
2020   # If the assembler didn't choke, and we can objdump,
2021   # and we got the correct data, then succeed.
2022   if test x$gcc_cv_objdump != x \
2023   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2024      | tail -3 > conftest.got \
2025   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2026     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2027   then
2028     gcc_cv_as_eh_frame=yes
2029   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2030     gcc_cv_as_eh_frame=buggy
2031   else
2032     # Uh oh, what do we do now?
2033     gcc_cv_as_eh_frame=no
2034   fi])
2035
2036 if test $gcc_cv_as_eh_frame = buggy; then
2037   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2038   [Define if your assembler mis-optimizes .eh_frame data.])
2039 fi
2040
2041 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2042  [elf,2,12,0], [--fatal-warnings],
2043  [.section .rodata.str, "aMS", @progbits, 1])
2044 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2045   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2046 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2047
2048 # Thread-local storage - the check is heavily parametrized.
2049 conftest_s=
2050 tls_first_major=
2051 tls_first_minor=
2052 tls_as_opt=
2053 case "$target" in
2054 changequote(,)dnl
2055   alpha*-*-*)
2056     conftest_s='
2057         .section ".tdata","awT",@progbits
2058 foo:    .long   25
2059         .text
2060         ldq     $27,__tls_get_addr($29)         !literal!1
2061         lda     $16,foo($29)                    !tlsgd!1
2062         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2063         ldq     $27,__tls_get_addr($29)         !literal!2
2064         lda     $16,foo($29)                    !tlsldm!2
2065         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2066         ldq     $1,foo($29)                     !gotdtprel
2067         ldah    $2,foo($29)                     !dtprelhi
2068         lda     $3,foo($2)                      !dtprello
2069         lda     $4,foo($29)                     !dtprel
2070         ldq     $1,foo($29)                     !gottprel
2071         ldah    $2,foo($29)                     !tprelhi
2072         lda     $3,foo($2)                      !tprello
2073         lda     $4,foo($29)                     !tprel'
2074         tls_first_major=2
2075         tls_first_minor=13
2076         tls_as_opt=--fatal-warnings
2077         ;;
2078   i[34567]86-*-*)
2079     conftest_s='
2080         .section ".tdata","awT",@progbits
2081 foo:    .long   25
2082         .text
2083         movl    %gs:0, %eax
2084         leal    foo@TLSGD(,%ebx,1), %eax
2085         leal    foo@TLSLDM(%ebx), %eax
2086         leal    foo@DTPOFF(%eax), %edx
2087         movl    foo@GOTTPOFF(%ebx), %eax
2088         subl    foo@GOTTPOFF(%ebx), %eax
2089         addl    foo@GOTNTPOFF(%ebx), %eax
2090         movl    foo@INDNTPOFF, %eax
2091         movl    $foo@TPOFF, %eax
2092         subl    $foo@TPOFF, %eax
2093         leal    foo@NTPOFF(%ecx), %eax'
2094         tls_first_major=2
2095         tls_first_minor=14
2096         tls_as_opt=--fatal-warnings
2097         ;;
2098   x86_64-*-*)
2099     conftest_s='
2100         .section ".tdata","awT",@progbits
2101 foo:    .long   25
2102         .text
2103         movq    %fs:0, %rax
2104         leaq    foo@TLSGD(%rip), %rdi
2105         leaq    foo@TLSLD(%rip), %rdi
2106         leaq    foo@DTPOFF(%rax), %rdx
2107         movq    foo@GOTTPOFF(%rip), %rax
2108         movq    $foo@TPOFF, %rax'
2109         tls_first_major=2
2110         tls_first_minor=14
2111         tls_as_opt=--fatal-warnings
2112         ;;
2113   ia64-*-*)
2114     conftest_s='
2115         .section ".tdata","awT",@progbits
2116 foo:    data8   25
2117         .text
2118         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2119         addl    r17 = @ltoff(@dtprel(foo#)), gp
2120         addl    r18 = @ltoff(@tprel(foo#)), gp
2121         addl    r19 = @dtprel(foo#), gp
2122         adds    r21 = @dtprel(foo#), r13
2123         movl    r23 = @dtprel(foo#)
2124         addl    r20 = @tprel(foo#), gp
2125         adds    r22 = @tprel(foo#), r13
2126         movl    r24 = @tprel(foo#)'
2127         tls_first_major=2
2128         tls_first_minor=13
2129         tls_as_opt=--fatal-warnings
2130         ;;
2131   powerpc-*-*)
2132     conftest_s='
2133         .section ".tdata","awT",@progbits
2134         .align 2
2135 ld0:    .space 4
2136 ld1:    .space 4
2137 x1:     .space 4
2138 x2:     .space 4
2139 x3:     .space 4
2140         .text
2141         addi 3,31,ld0@got@tlsgd
2142         bl __tls_get_addr
2143         addi 3,31,x1@got@tlsld
2144         bl __tls_get_addr
2145         addi 9,3,x1@dtprel
2146         addis 9,3,x2@dtprel@ha
2147         addi 9,9,x2@dtprel@l
2148         lwz 9,x3@got@tprel(31)
2149         add 9,9,x@tls
2150         addi 9,2,x1@tprel
2151         addis 9,2,x2@tprel@ha
2152         addi 9,9,x2@tprel@l'
2153         tls_first_major=2
2154         tls_first_minor=14
2155         tls_as_opt="-a32 --fatal-warnings"
2156         ;;
2157   powerpc64-*-*)
2158     conftest_s='
2159         .section ".tdata","awT",@progbits
2160         .align 3
2161 ld0:    .space 8
2162 ld1:    .space 8
2163 x1:     .space 8
2164 x2:     .space 8
2165 x3:     .space 8
2166         .text
2167         addi 3,2,ld0@got@tlsgd
2168         bl .__tls_get_addr
2169         nop
2170         addi 3,2,ld1@toc
2171         bl .__tls_get_addr
2172         nop
2173         addi 3,2,x1@got@tlsld
2174         bl .__tls_get_addr
2175         nop
2176         addi 9,3,x1@dtprel
2177         bl .__tls_get_addr
2178         nop
2179         addis 9,3,x2@dtprel@ha
2180         addi 9,9,x2@dtprel@l
2181         bl .__tls_get_addr
2182         nop
2183         ld 9,x3@got@dtprel(2)
2184         add 9,9,3
2185         bl .__tls_get_addr
2186         nop'
2187         tls_first_major=2
2188         tls_first_minor=14
2189         tls_as_opt="-a64 --fatal-warnings"
2190         ;;
2191   s390-*-*)
2192     conftest_s='
2193         .section ".tdata","awT",@progbits
2194 foo:    .long   25
2195         .text
2196         .long   foo@TLSGD
2197         .long   foo@TLSLDM
2198         .long   foo@DTPOFF
2199         .long   foo@NTPOFF
2200         .long   foo@GOTNTPOFF
2201         .long   foo@INDNTPOFF
2202         l       %r1,foo@GOTNTPOFF(%r12)
2203         l       %r1,0(%r1):tls_load:foo
2204         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2205         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2206         tls_first_major=2
2207         tls_first_minor=14
2208         tls_as_opt="-m31 --fatal-warnings"
2209         ;;
2210   s390x-*-*)
2211     conftest_s='
2212         .section ".tdata","awT",@progbits
2213 foo:    .long   25
2214         .text
2215         .quad   foo@TLSGD
2216         .quad   foo@TLSLDM
2217         .quad   foo@DTPOFF
2218         .quad   foo@NTPOFF
2219         .quad   foo@GOTNTPOFF
2220         lg      %r1,foo@GOTNTPOFF(%r12)
2221         larl    %r1,foo@INDNTPOFF
2222         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2223         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2224         tls_first_major=2
2225         tls_first_minor=14
2226         tls_as_opt="-m64 -Aesame --fatal-warnings"
2227         ;;
2228   sh-*-* | sh[34]-*-*)
2229     conftest_s='
2230         .section ".tdata","awT",@progbits
2231 foo:    .long   25
2232         .text
2233         .long   foo@TLSGD
2234         .long   foo@TLSLDM
2235         .long   foo@DTPOFF
2236         .long   foo@GOTTPOFF
2237         .long   foo@TPOFF'
2238         tls_first_major=2
2239         tls_first_minor=13
2240         tls_as_opt=--fatal-warnings
2241         ;;
2242   sparc*-*-*)
2243     case "$target" in
2244       sparc*-sun-solaris2.*)
2245         on_solaris=yes
2246         ;;
2247       *)
2248         on_solaris=no
2249         ;;
2250     esac
2251     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2252       conftest_s='
2253         .section ".tdata",#alloc,#write,#tls
2254 foo:    .long   25
2255         .text
2256         sethi   %tgd_hi22(foo), %o0
2257         add     %o0, %tgd_lo10(foo), %o1
2258         add     %l7, %o1, %o0, %tgd_add(foo)
2259         call    __tls_get_addr, %tgd_call(foo)
2260         sethi   %tldm_hi22(foo), %l1
2261         add     %l1, %tldm_lo10(foo), %l2
2262         add     %l7, %l2, %o0, %tldm_add(foo)
2263         call    __tls_get_addr, %tldm_call(foo)
2264         sethi   %tldo_hix22(foo), %l3
2265         xor     %l3, %tldo_lox10(foo), %l4
2266         add     %o0, %l4, %l5, %tldo_add(foo)
2267         sethi   %tie_hi22(foo), %o3
2268         add     %o3, %tie_lo10(foo), %o3
2269         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2270         add     %g7, %o2, %o4, %tie_add(foo)
2271         sethi   %tle_hix22(foo), %l1
2272         xor     %l1, %tle_lox10(foo), %o5
2273         ld      [%g7 + %o5], %o1'
2274         tls_first_major=0
2275         tls_first_minor=0
2276     else
2277       conftest_s='
2278         .section ".tdata","awT",@progbits
2279 foo:    .long   25
2280         .text
2281         sethi   %tgd_hi22(foo), %o0
2282         add     %o0, %tgd_lo10(foo), %o1
2283         add     %l7, %o1, %o0, %tgd_add(foo)
2284         call    __tls_get_addr, %tgd_call(foo)
2285         sethi   %tldm_hi22(foo), %l1
2286         add     %l1, %tldm_lo10(foo), %l2
2287         add     %l7, %l2, %o0, %tldm_add(foo)
2288         call    __tls_get_addr, %tldm_call(foo)
2289         sethi   %tldo_hix22(foo), %l3
2290         xor     %l3, %tldo_lox10(foo), %l4
2291         add     %o0, %l4, %l5, %tldo_add(foo)
2292         sethi   %tie_hi22(foo), %o3
2293         add     %o3, %tie_lo10(foo), %o3
2294         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2295         add     %g7, %o2, %o4, %tie_add(foo)
2296         sethi   %tle_hix22(foo), %l1
2297         xor     %l1, %tle_lox10(foo), %o5
2298         ld      [%g7 + %o5], %o1'
2299         tls_first_major=2
2300         tls_first_minor=14
2301         tls_as_opt="-32 --fatal-warnings"
2302       fi
2303         ;;
2304 changequote([,])dnl
2305 esac
2306 if test -z "$tls_first_major"; then
2307   : # If we don't have a check, assume no support.
2308 else
2309   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2310   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2311   [AC_DEFINE(HAVE_AS_TLS, 1,
2312             [Define if your assembler supports thread-local storage.])])
2313 fi
2314
2315 # Target-specific assembler checks.
2316
2317 case "$target" in
2318   # All TARGET_ABI_OSF targets.
2319   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2320     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2321         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2322 [       .set nomacro
2323         .text
2324         extbl   $3, $2, $3      !lituse_bytoff!1
2325         ldq     $2, a($29)      !literal!1
2326         ldq     $4, b($29)      !literal!2
2327         ldq_u   $3, 0($2)       !lituse_base!1
2328         ldq     $27, f($29)     !literal!5
2329         jsr     $26, ($27), f   !lituse_jsr!5
2330         ldah    $29, 0($26)     !gpdisp!3
2331         lda     $0, c($29)      !gprel
2332         ldah    $1, d($29)      !gprelhigh
2333         lda     $1, d($1)       !gprellow
2334         lda     $29, 0($29)     !gpdisp!3],,
2335     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2336   [Define if your assembler supports explicit relocations.])])
2337     ;;
2338
2339   sparc*-*-*)
2340     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2341       [.register %g2, #scratch],,
2342       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2343                 [Define if your assembler supports .register.])])
2344
2345     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2346       [-relax], [.text],,
2347       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2348                 [Define if your assembler supports -relax option.])])
2349
2350     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2351       gcc_cv_as_sparc_ua_pcrel,,
2352       [-K PIC],
2353 [.text
2354 foo:
2355         nop
2356 .data
2357 .align 4
2358 .byte 0
2359 .uaword %r_disp32(foo)],
2360       [if test x$gcc_cv_ld != x \
2361        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2362          gcc_cv_as_sparc_ua_pcrel=yes
2363        fi
2364        rm -f conftest],
2365       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2366                 [Define if your assembler and linker support unaligned PC relative relocs.])
2367
2368       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2369         gcc_cv_as_sparc_ua_pcrel_hidden,,
2370         [-K PIC],
2371 [.data
2372 .align 4
2373 .byte 0x31
2374 .uaword %r_disp32(foo)
2375 .byte 0x32, 0x33, 0x34
2376 .global foo
2377 .hidden foo
2378 foo:
2379 .skip 4],
2380         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2381          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2382          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2383             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2384             if $gcc_cv_objdump -R conftest 2> /dev/null \
2385                | grep 'DISP32' > /dev/null 2>&1; then
2386                 :
2387             else
2388                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2389             fi
2390          fi
2391          rm -f conftest],
2392          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2393                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2394     ]) # unaligned pcrel relocs
2395
2396     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2397       gcc_cv_as_sparc_offsetable_lo10,,
2398       [-xarch=v9],
2399 [.text
2400         or %g1, %lo(ab) + 12, %g1
2401         or %g1, %lo(ab + 12), %g1],
2402       [if test x$gcc_cv_objdump != x \
2403        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2404           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2405          gcc_cv_as_offsetable_lo10=yes
2406        fi],
2407        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2408                  [Define if your assembler supports offsetable %lo().])])
2409     ;;
2410
2411 changequote(,)dnl
2412   i[34567]86-*-* | x86_64-*-*)
2413 changequote([,])dnl
2414     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2415        gcc_cv_as_ix86_filds_fists,
2416       [2,9,0],, [filds mem; fists mem],,
2417       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2418         [Define if your assembler uses the new HImode fild and fist notation.])])
2419
2420     gcc_GAS_CHECK_FEATURE([cmov syntax],
2421       gcc_cv_as_ix86_cmov_sun_syntax,,,
2422       [cmovl.l %edx, %eax],,
2423       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2424         [Define if your assembler supports the Sun syntax for cmov.])])
2425
2426     # This one is used unconditionally by i386.[ch]; it is to be defined
2427     # to 1 if the feature is present, 0 otherwise.
2428     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2429         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2430 [       .text
2431 .L0:
2432         nop
2433         .data
2434         .long .L0@GOTOFF])
2435     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2436       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2437       [Define true if the assembler supports '.long foo@GOTOFF'.])
2438     ;;
2439
2440   ia64*-*-*)
2441     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2442         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2443 [       .text
2444         addl r15 = @ltoffx(x#), gp
2445         ;;
2446         ld8.mov r16 = [[r15]], x#],,
2447     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2448           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2449
2450     ;;
2451
2452   powerpc*-*-*)
2453     case $target in
2454       *-*-aix*) conftest_s='    .csect .text[[PR]]
2455         mfcr 3,128';;
2456       *-*-darwin*) conftest_s=' .text
2457         mfcr r3,128';;
2458       *)       conftest_s='     .text
2459         mfcr 3,128';;
2460     esac
2461
2462     gcc_GAS_CHECK_FEATURE([mfcr field support],
2463       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2464       [$conftest_s],,
2465       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2466           [Define if your assembler supports mfcr field.])])
2467     ;;
2468
2469   mips*-*-*)
2470     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2471       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2472 [       lw $4,%gp_rel(foo)($4)],,
2473       [if test x$target_cpu_default = x
2474        then target_cpu_default=MASK_EXPLICIT_RELOCS
2475        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2476        fi])
2477
2478     ;;
2479 esac
2480 # ??? Not all targets support dwarf2 debug_line, even within a version
2481 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2482 # info to the output file.  So, as supported targets are added to gas 2.11,
2483 # add some instruction here to (also) show we expect this might work.
2484 # ??? Once 2.11 is released, probably need to add first known working
2485 # version to the per-target configury.
2486 case "$target" in
2487   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2488   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2489   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2490     insn="nop"
2491     ;;
2492   ia64*-*-* | s390*-*-*)
2493     insn="nop 0"
2494     ;;
2495   mmix-*-*)
2496     insn="swym 0"
2497     ;;
2498 esac
2499 if test x"$insn" != x; then
2500  conftest_s="\
2501         .file 1 \"conftest.s\"
2502         .loc 1 3 0
2503         $insn"
2504  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2505   gcc_cv_as_dwarf2_debug_line,
2506   [elf,2,11,0],, [$conftest_s],
2507   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2508    if grep debug_line conftest.o > /dev/null 2>&1; then
2509      gcc_cv_as_dwarf2_debug_line=yes
2510    fi])
2511
2512 # The .debug_line file table must be in the exact order that
2513 # we specified the files, since these indices are also used
2514 # by DW_AT_decl_file.  Approximate this test by testing if
2515 # the assembler bitches if the same index is assigned twice.
2516  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2517   gcc_cv_as_dwarf2_file_buggy,,,
2518 [       .file 1 "foo.s"
2519         .file 1 "bar.s"])
2520
2521  if test $gcc_cv_as_dwarf2_debug_line = yes \
2522  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2523         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2524   [Define if your assembler supports dwarf2 .file/.loc directives,
2525    and preserves file table indices exactly as given.])
2526  fi
2527
2528  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2529   gcc_cv_as_gdwarf2_flag,
2530   [elf,2,11,0], [--gdwarf2], [$insn],,
2531   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2532 [Define if your assembler supports the --gdwarf2 option.])])
2533
2534  gcc_GAS_CHECK_FEATURE([--gstabs option],
2535   gcc_cv_as_gstabs_flag,
2536   [elf,2,11,0], [--gstabs], [$insn],
2537   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2538    # and warns about it, but still exits successfully.  So check for
2539    # this.
2540    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2541    then :
2542    else gcc_cv_as_gstabs_flag=yes
2543    fi],
2544   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2545 [Define if your assembler supports the --gstabs option.])])
2546 fi
2547
2548 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2549 gcc_cv_ld_ro_rw_mix=unknown
2550 if test $in_tree_ld = yes ; then
2551   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2552      && test $in_tree_ld_is_elf = yes; then
2553     gcc_cv_ld_ro_rw_mix=read-write
2554   fi
2555 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2556   echo '.section myfoosect, "a"' > conftest1.s
2557   echo '.section myfoosect, "aw"' > conftest2.s
2558   echo '.byte 1' >> conftest2.s
2559   echo '.section myfoosect, "a"' > conftest3.s
2560   echo '.byte 0' >> conftest3.s
2561   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2562      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2563      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2564      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2565         conftest2.o conftest3.o > /dev/null 2>&1; then
2566     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2567                          | sed -e '/myfoosect/!d' -e N`
2568     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2569       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2570         gcc_cv_ld_ro_rw_mix=read-only
2571       else
2572         gcc_cv_ld_ro_rw_mix=read-write
2573       fi
2574     fi
2575   fi
2576 changequote(,)dnl
2577   rm -f conftest.* conftest[123].*
2578 changequote([,])dnl
2579 fi
2580 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2581         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2582   [Define if your linker links a mix of read-only
2583    and read-write sections into a read-write section.])
2584 fi
2585 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2586
2587 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2588 gcc_cv_ld_eh_frame_hdr=no
2589 if test $in_tree_ld = yes ; then
2590   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2591      && test $in_tree_ld_is_elf = yes; then
2592     gcc_cv_ld_eh_frame_hdr=yes
2593   fi
2594 elif test x$gcc_cv_ld != x; then
2595         # Check if linker supports --eh-frame-hdr option
2596         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2597                 gcc_cv_ld_eh_frame_hdr=yes
2598         fi
2599 fi
2600 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2601         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2602 [Define if your linker supports --eh-frame-hdr option.])
2603 fi
2604 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2605
2606 AC_MSG_CHECKING(linker position independent executable support)
2607 gcc_cv_ld_pie=no
2608 if test $in_tree_ld = yes ; then
2609   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2610      && test $in_tree_ld_is_elf = yes; then
2611     gcc_cv_ld_pie=yes
2612   fi
2613 elif test x$gcc_cv_ld != x; then
2614         # Check if linker supports -pie option
2615         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2616                 gcc_cv_ld_pie=yes
2617         fi
2618 fi
2619 if test x"$gcc_cv_ld_pie" = xyes; then
2620         AC_DEFINE(HAVE_LD_PIE, 1,
2621 [Define if your linker supports -pie option.])
2622 fi
2623 AC_MSG_RESULT($gcc_cv_ld_pie)
2624
2625 if test x$with_sysroot = x && test x$host = x$target \
2626    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2627   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2628 [Define to PREFIX/include if cpp should also search that directory.])
2629 fi
2630
2631 # Figure out what language subdirectories are present.
2632 # Look if the user specified --enable-languages="..."; if not, use
2633 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2634 # go away some day.
2635 # NB:  embedded tabs in this IF block -- do not untabify
2636 if test x"${enable_languages+set}" != xset; then
2637         if test x"${LANGUAGES+set}" = xset; then
2638                 enable_languages="${LANGUAGES}"
2639                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
2640
2641         else
2642                 enable_languages=all
2643         fi
2644 else
2645         if test x"${enable_languages}" = x \
2646         || test x"${enable_languages}" = xyes;
2647         then
2648                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
2649         fi
2650 fi
2651 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
2652
2653 # First scan to see if an enabled language requires some other language.
2654 # We assume that a given config-lang.in will list all the language
2655 # front ends it requires, even if some are required indirectly.
2656 for lang in ${srcdir}/*/config-lang.in
2657 do
2658    case $lang in
2659     # The odd quoting in the next line works around
2660     # an apparent bug in bash 1.12 on linux.
2661 changequote(,)dnl
2662     ${srcdir}/[*]/config-lang.in)
2663        ;;
2664     *)
2665        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
2666        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
2667        for other in $this_lang_requires
2668        do
2669           case ,${enable_languages}, in
2670            *,$other,*)
2671               ;;
2672            *,all,*)
2673               ;;
2674            *,$lang_alias,*)
2675               enable_languages="$enable_languages,$other"
2676               ;;
2677           esac
2678        done
2679        ;;
2680 changequote([,])dnl
2681    esac
2682 done
2683
2684 expected_languages=`echo ,${enable_languages}, | sed -e 's:,: :g' -e 's:  *: :g' -e 's:  *: :g' -e 's:^ ::' -e 's: $::'`
2685 found_languages=
2686 subdirs=
2687 for lang in ${srcdir}/*/config-lang.in
2688 do
2689         case $lang in
2690         # The odd quoting in the next line works around
2691         # an apparent bug in bash 1.12 on linux.
2692 changequote(,)dnl
2693         ${srcdir}/[*]/config-lang.in) ;;
2694         *)
2695           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
2696           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
2697           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
2698           if test "x$lang_alias" = x
2699           then
2700                 echo "$lang doesn't set \$language." 1>&2
2701                 exit 1
2702           fi
2703           case ${build_by_default},${enable_languages}, in
2704           *,$lang_alias,*) add_this_lang=yes ;;
2705           no,*) add_this_lang=no ;;
2706           *,all,*) add_this_lang=yes ;;
2707           *) add_this_lang=no ;;
2708           esac
2709           found_languages="${found_languages} ${lang_alias}"
2710           if test x"${add_this_lang}" = xyes; then
2711                 case $lang in
2712                     ${srcdir}/ada/config-lang.in)
2713                         if test x$have_gnat = xyes ; then
2714                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2715                         fi
2716                         ;;
2717                     *)
2718                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
2719                         ;;
2720                 esac
2721           fi
2722           ;;
2723 changequote([,])dnl
2724         esac
2725 done
2726
2727 missing_languages=
2728 for expected_language in ${expected_languages} ..
2729 do
2730     if test "${expected_language}" != ..; then
2731         missing_language="${expected_language}"
2732         if test "${expected_language}" = "c" \
2733            || test "${expected_language}" = "all"; then
2734                 missing_language=
2735         fi
2736         for found_language in ${found_languages} ..
2737         do
2738             if test "${found_language}" != ..; then
2739                 if test "${expected_language}" = "${found_language}"; then
2740                     missing_language=
2741                 fi
2742             fi
2743         done
2744         if test "x${missing_language}" != x; then
2745            missing_languages="${missing_languages} ${missing_language}"
2746         fi
2747     fi
2748 done
2749
2750 if test "x$missing_languages" != x; then
2751   AC_MSG_ERROR([
2752 The following requested languages were not found:${missing_languages}
2753 The following languages were available: c${found_languages}])
2754 fi
2755
2756 # Make gthr-default.h if we have a thread file.
2757 gthread_flags=
2758 if test $thread_file != single; then
2759     rm -f gthr-default.h
2760     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
2761     gthread_flags=-DHAVE_GTHR_DEFAULT
2762 fi
2763 AC_SUBST(gthread_flags)
2764
2765 # Find out what GC implementation we want, or may, use.
2766 AC_ARG_WITH(gc,
2767 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2768                           with the compiler],
2769 [case "$withval" in
2770   page | zone)
2771     GGC=ggc-$withval
2772     ;;
2773   *)
2774     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2775     ;;
2776 esac],
2777 [GGC=ggc-page])
2778 AC_SUBST(GGC)
2779 echo "Using $GGC for garbage collection."
2780
2781 # Use the system's zlib library.
2782 zlibdir=-L../zlib
2783 zlibinc="-I\$(srcdir)/../zlib"
2784 AC_ARG_WITH(system-zlib,
2785 [  --with-system-zlib      use installed libz],
2786 zlibdir=
2787 zlibinc=
2788 )
2789 AC_SUBST(zlibdir)
2790 AC_SUBST(zlibinc)
2791
2792 dnl Very limited version of automake's enable-maintainer-mode
2793
2794 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2795   dnl maintainer-mode is disabled by default
2796   AC_ARG_ENABLE(maintainer-mode,
2797 [  --enable-maintainer-mode
2798                           enable make rules and dependencies not useful
2799                           (and sometimes confusing) to the casual installer],
2800       maintainer_mode=$enableval,
2801       maintainer_mode=no)
2802
2803 AC_MSG_RESULT($maintainer_mode)
2804
2805 if test "$maintainer_mode" = "yes"; then
2806   MAINT=''
2807 else
2808   MAINT='#'
2809 fi
2810 AC_SUBST(MAINT)dnl
2811
2812 # Make empty files to contain the specs and options for each language.
2813 # Then add #include lines to for a compiler that has specs and/or options.
2814
2815 lang_opt_files=
2816 lang_specs_files=
2817 lang_tree_files=
2818 for subdir in . $subdirs
2819 do
2820         if test -f $srcdir/$subdir/lang.opt; then
2821             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2822         fi
2823         if test -f $srcdir/$subdir/lang-specs.h; then
2824             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2825         fi
2826         if test -f $srcdir/$subdir/$subdir-tree.def; then
2827             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2828         fi
2829 done
2830
2831 # These (without "all_") are set in each config-lang.in.
2832 # `language' must be a single word so is spelled singularly.
2833 all_languages=
2834 all_boot_languages=
2835 all_compilers=
2836 all_stagestuff=
2837 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2838 # List of language makefile fragments.
2839 all_lang_makefrags=
2840 # List of language subdirectory makefiles.  Deprecated.
2841 all_lang_makefiles=
2842 # Files for gengtype
2843 all_gtfiles="$target_gtfiles"
2844 # Files for gengtype with language
2845 all_gtfiles_files_langs=
2846 all_gtfiles_files_files=
2847
2848 # Add the language fragments.
2849 # Languages are added via two mechanisms.  Some information must be
2850 # recorded in makefile variables, these are defined in config-lang.in.
2851 # We accumulate them and plug them into the main Makefile.
2852 # The other mechanism is a set of hooks for each of the main targets
2853 # like `clean', `install', etc.
2854
2855 language_hooks="Make-hooks"
2856
2857 for s in $subdirs
2858 do
2859                 language=
2860                 boot_language=
2861                 compilers=
2862                 stagestuff=
2863                 outputs=
2864                 gtfiles=
2865                 . ${srcdir}/$s/config-lang.in
2866                 if test "x$language" = x
2867                 then
2868                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2869                         exit 1
2870                 fi
2871                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2872                 if test -f ${srcdir}/$s/Makefile.in
2873                 then all_lang_makefiles="$s/Makefile"
2874                 fi
2875                 all_languages="$all_languages $language"
2876                 if test "x$boot_language" = xyes
2877                 then
2878                         all_boot_languages="$all_boot_languages $language"
2879                 fi
2880                 all_compilers="$all_compilers $compilers"
2881                 all_stagestuff="$all_stagestuff $stagestuff"
2882                 all_outputs="$all_outputs $outputs"
2883                 all_gtfiles="$all_gtfiles $gtfiles"
2884                 for f in $gtfiles
2885                 do
2886                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2887                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2888                 done
2889 done
2890
2891 # Pick up gtfiles for c
2892 gtfiles=
2893 s="c"
2894 . ${srcdir}/c-config-lang.in
2895 all_gtfiles="$all_gtfiles $gtfiles"
2896 for f in $gtfiles
2897 do
2898         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2899         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2900 done
2901
2902 check_languages=
2903 for language in $all_languages
2904 do
2905                 check_languages="$check_languages check-$language"
2906 done
2907
2908 # We link each language in with a set of hooks, reached indirectly via
2909 # lang.${target}.
2910
2911 rm -f Make-hooks
2912 touch Make-hooks
2913 target_list="all.build all.cross start.encap rest.encap tags \
2914         install-normal install-common install-man \
2915         uninstall info man srcextra srcman srcinfo \
2916         mostlyclean clean distclean maintainer-clean \
2917         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2918 for t in $target_list
2919 do
2920         x=
2921         for lang in $all_languages
2922         do
2923                         x="$x $lang.$t"
2924         done
2925         echo "lang.$t: $x" >> Make-hooks
2926 done
2927
2928 # Create .gdbinit.
2929
2930 echo "dir ." > .gdbinit
2931 echo "dir ${srcdir}" >> .gdbinit
2932 if test x$gdb_needs_out_file_path = xyes
2933 then
2934         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2935 fi
2936 if test "x$subdirs" != x; then
2937         for s in $subdirs
2938         do
2939                 echo "dir ${srcdir}/$s" >> .gdbinit
2940         done
2941 fi
2942 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2943
2944 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2945 # absolute path for gcc_tooldir based on inserting the number of up-directory
2946 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2947 # $(libsubdir)/@(unlibsubdir) based path.
2948 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2949 # make and thus we'd get different behavior depending on where we built the
2950 # sources.
2951 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2952     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
2953 else
2954 changequote(<<, >>)dnl
2955 # An explanation of the sed strings:
2956 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2957 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2958 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2959 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2960 #
2961 # (*) Note this pattern overwrites the first character of the string
2962 # with a forward slash if one is not already present.  This is not a
2963 # problem because the exact names of the sub-directories concerned is
2964 # unimportant, just the number of them matters.
2965 #
2966 # The practical upshot of these patterns is like this:
2967 #
2968 #  prefix     exec_prefix        result
2969 #  ------     -----------        ------
2970 #   /foo        /foo/bar          ../
2971 #   /foo/       /foo/bar          ../
2972 #   /foo        /foo/bar/         ../
2973 #   /foo/       /foo/bar/         ../
2974 #   /foo        /foo/bar/ugg      ../../
2975 #
2976     dollar='$$'
2977     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
2978 changequote([, ])dnl
2979 fi
2980 AC_SUBST(gcc_tooldir)
2981 AC_SUBST(dollar)
2982
2983 # Find a directory in which to install a shared libgcc.
2984
2985 AC_ARG_ENABLE(version-specific-runtime-libs,
2986 [  --enable-version-specific-runtime-libs
2987                           specify that runtime libraries should be
2988                           installed in a compiler-specific directory])
2989
2990 AC_ARG_WITH(slibdir,
2991 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2992 slibdir="$with_slibdir",
2993 if test "${enable_version_specific_runtime_libs+set}" = set; then
2994   slibdir='$(libsubdir)'
2995 elif test "$host" != "$target"; then
2996   slibdir='$(build_tooldir)/lib'
2997 else
2998   slibdir='$(libdir)'
2999 fi)
3000 AC_SUBST(slibdir)
3001
3002 objdir=`${PWDCMD-pwd}`
3003 AC_SUBST(objdir)
3004
3005 # Substitute configuration variables
3006 AC_SUBST(subdirs)
3007 AC_SUBST(srcdir)
3008 AC_SUBST(all_boot_languages)
3009 AC_SUBST(all_compilers)
3010 AC_SUBST(all_gtfiles)
3011 AC_SUBST(all_gtfiles_files_langs)
3012 AC_SUBST(all_gtfiles_files_files)
3013 AC_SUBST(all_lang_makefrags)
3014 AC_SUBST(all_lang_makefiles)
3015 AC_SUBST(all_languages)
3016 AC_SUBST(all_stagestuff)
3017 AC_SUBST(build_exeext)
3018 AC_SUBST(build_install_headers_dir)
3019 AC_SUBST(build_xm_file_list)
3020 AC_SUBST(build_xm_include_list)
3021 AC_SUBST(build_xm_defines)
3022 AC_SUBST(check_languages)
3023 AC_SUBST(cc_set_by_configure)
3024 AC_SUBST(quoted_cc_set_by_configure)
3025 AC_SUBST(cpp_install_dir)
3026 AC_SUBST(xmake_file)
3027 AC_SUBST(tmake_file)
3028 AC_SUBST(extra_gcc_objs)
3029 AC_SUBST(extra_headers_list)
3030 AC_SUBST(extra_objs)
3031 AC_SUBST(extra_parts)
3032 AC_SUBST(extra_passes)
3033 AC_SUBST(extra_programs)
3034 AC_SUBST(float_h_file)
3035 AC_SUBST(gcc_config_arguments)
3036 AC_SUBST(gcc_gxx_include_dir)
3037 AC_SUBST(libstdcxx_incdir)
3038 AC_SUBST(gcc_version)
3039 AC_SUBST(gcc_version_full)
3040 AC_SUBST(gcc_version_trigger)
3041 AC_SUBST(host_exeext)
3042 AC_SUBST(host_xm_file_list)
3043 AC_SUBST(host_xm_include_list)
3044 AC_SUBST(host_xm_defines)
3045 AC_SUBST(out_host_hook_obj)
3046 AC_SUBST(install)
3047 AC_SUBST(lang_opt_files)
3048 AC_SUBST(lang_specs_files)
3049 AC_SUBST(lang_tree_files)
3050 AC_SUBST(local_prefix)
3051 AC_SUBST(md_file)
3052 AC_SUBST(objc_boehm_gc)
3053 AC_SUBST(out_file)
3054 AC_SUBST(out_object_file)
3055 AC_SUBST(stage_prefix_set_by_configure)
3056 AC_SUBST(quoted_stage_prefix_set_by_configure)
3057 AC_SUBST(symbolic_link)
3058 AC_SUBST(thread_file)
3059 AC_SUBST(tm_file_list)
3060 AC_SUBST(tm_include_list)
3061 AC_SUBST(tm_defines)
3062 AC_SUBST(tm_p_file_list)
3063 AC_SUBST(tm_p_include_list)
3064 AC_SUBST(xm_file_list)
3065 AC_SUBST(xm_include_list)
3066 AC_SUBST(xm_defines)
3067 AC_SUBST(target_noncanonical)
3068 AC_SUBST(c_target_objs)
3069 AC_SUBST(cxx_target_objs)
3070 AC_SUBST(target_cpu_default)
3071
3072 AC_SUBST_FILE(language_hooks)
3073
3074 # If it doesn't already exist, create document directory
3075 echo "checking for the document directory." 1>&2
3076 if test -d doc ; then
3077   true
3078 else
3079   mkdir doc
3080 fi
3081
3082 # Echo link setup.
3083 if test x${build} = x${host} ; then
3084   if test x${host} = x${target} ; then
3085     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3086   else
3087     echo "Links are now set up to build a cross-compiler" 1>&2
3088     echo " from ${host} to ${target}." 1>&2
3089   fi
3090 else
3091   if test x${host} = x${target} ; then
3092     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3093     echo " for ${target}." 1>&2
3094   else
3095     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3096     echo " from ${host} to ${target}." 1>&2
3097   fi
3098 fi
3099
3100 # Configure the subdirectories
3101 # AC_CONFIG_SUBDIRS($subdirs)
3102
3103 # Create the Makefile
3104 # and configure language subdirectories
3105 AC_CONFIG_FILES($all_outputs)
3106
3107 AC_CONFIG_COMMANDS([default],
3108 [
3109 case ${CONFIG_HEADERS} in
3110   *auto-host.h:config.in*)
3111   echo > cstamp-h ;;
3112 esac
3113 # Make sure all the subdirs exist.
3114 for d in $subdirs
3115 do
3116     test -d $d || mkdir $d
3117 done
3118 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3119 # bootstrapping and the installation procedure can still use
3120 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3121 # FLAGS_TO_PASS has been modified to solve the problem there.
3122 # This is virtually a duplicate of what happens in configure.lang; we do
3123 # an extra check to make sure this only happens if ln -s can be used.
3124 if test "$symbolic_link" = "ln -s"; then
3125  for d in ${subdirs} fixinc ; do
3126         STARTDIR=`${PWDCMD-pwd}`
3127         cd $d
3128         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3129         do
3130                 rm -f $t
3131                 $symbolic_link ../$t $t 2>/dev/null
3132         done
3133         cd $STARTDIR
3134  done
3135 else true ; fi
3136 ],
3137 [subdirs='$subdirs'
3138 symbolic_link='$symbolic_link'
3139 ])
3140 AC_OUTPUT