gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 326           -Wmissing-prototypes -Wcast-qual -Wc++-compat], [loose_warn])
 327 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 328                           -Wmissing-format-attribute], [strict_warn])
 329 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 330                                      -Wno-overlength-strings], [strict_warn])
 331 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 332
 333 # The above macros do nothing if the compiler is not GCC.  However, the
 334 # Makefile has more goo to add other flags, so this variabl is used to
 335 # enables warnings only for GCC.
 336 warn_cflags=
 337 if test "x$GCC" = "xyes"; then
 338   warn_cflags='$(GCC_WARN_CFLAGS)'
 339 fi
 340 AC_SUBST(warn_cflags)
 341
 342 # Enable expensive internal checks
 343 is_release=
 344 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 345   is_release=yes
 346 fi
 347
 348 AC_ARG_ENABLE(checking,
 349 [  --enable-checking[=LIST]
 350                           enable expensive run-time checks.  With LIST,
 351                           enable only specific categories of checks.
 352                           Categories are: yes,no,all,none,release.
 353                           Flags are: assert,df,fold,gc,gcac,misc,
 354                           rtlflag,rtl,runtime,tree,valgrind,types.],
 355 [ac_checking_flags="${enableval}"],[
 356 # Determine the default checks.
 357 if test x$is_release = x ; then
 358   ac_checking_flags=yes
 359 else
 360   ac_checking_flags=release
 361 fi])
 362 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 363 for check in release $ac_checking_flags
 364 do
 365         case $check in
 366         # these set all the flags to specific states
 367         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 368                         ac_fold_checking= ; ac_gc_checking=1 ;
 369                         ac_gc_always_collect= ; ac_rtl_checking= ;
 370                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 371                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 372                         ac_types_checking=1 ;;
 373         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 374                         ac_fold_checking= ; ac_gc_checking= ;
 375                         ac_gc_always_collect= ; ac_rtl_checking= ;
 376                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 377                         ac_tree_checking= ; ac_valgrind_checking= ;
 378                         ac_types_checking= ;;
 379         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 380                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 381                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 382                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 383                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 384                         ac_types_checking=1 ;;
 385         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 386                         ac_fold_checking= ; ac_gc_checking= ;
 387                         ac_gc_always_collect= ; ac_rtl_checking= ;
 388                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 389                         ac_tree_checking= ; ac_valgrind_checking= ;
 390                         ac_types_checking= ;;
 391         # these enable particular checks
 392         assert)         ac_assert_checking=1 ;;
 393         df)             ac_df_checking=1 ;;
 394         fold)           ac_fold_checking=1 ;;
 395         gc)             ac_gc_checking=1 ;;
 396         gcac)           ac_gc_always_collect=1 ;;
 397         misc)           ac_checking=1 ;;
 398         rtl)            ac_rtl_checking=1 ;;
 399         rtlflag)        ac_rtlflag_checking=1 ;;
 400         runtime)        ac_runtime_checking=1 ;;
 401         tree)           ac_tree_checking=1 ;;
 402         types)          ac_types_checking=1 ;;
 403         valgrind)       ac_valgrind_checking=1 ;;
 404         *)      AC_MSG_ERROR(unknown check category $check) ;;
 405         esac
 406 done
 407 IFS="$ac_save_IFS"
 408
 409 nocommon_flag=""
 410 if test x$ac_checking != x ; then
 411   AC_DEFINE(ENABLE_CHECKING, 1,
 412 [Define if you want more run-time sanity checks.  This one gets a grab
 413    bag of miscellaneous but relatively cheap checks.])
 414   nocommon_flag=-fno-common
 415 fi
 416 AC_SUBST(nocommon_flag)
 417 if test x$ac_df_checking != x ; then
 418   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 419 [Define if you want more run-time sanity checks for dataflow.])
 420 fi
 421 if test x$ac_assert_checking != x ; then
 422   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 423 [Define if you want assertions enabled.  This is a cheap check.])
 424 fi
 425 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 426 if test x$ac_runtime_checking != x ; then
 427   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 428 [Define if you want runtime assertions enabled.  This is a cheap check.])
 429 fi
 430 if test x$ac_tree_checking != x ; then
 431   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 432 [Define if you want all operations on trees (the basic data
 433    structure of the front ends) to be checked for dynamic type safety
 434    at runtime.  This is moderately expensive.  The tree browser debugging
 435    routines will also be enabled by this option.
 436    ])
 437   TREEBROWSER=tree-browser.o
 438 fi
 439 if test x$ac_types_checking != x ; then
 440   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 441 [Define if you want all gimple types to be verified after gimplifiation.
 442    This is cheap.
 443    ])
 444 fi
 445 AC_SUBST(TREEBROWSER)
 446 if test x$ac_rtl_checking != x ; then
 447   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 448 [Define if you want all operations on RTL (the basic data structure
 449    of the optimizer and back end) to be checked for dynamic type safety
 450    at runtime.  This is quite expensive.])
 451 fi
 452 if test x$ac_rtlflag_checking != x ; then
 453   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 454 [Define if you want RTL flag accesses to be checked against the RTL
 455    codes that are supported for each access macro.  This is relatively
 456    cheap.])
 457 fi
 458 if test x$ac_gc_checking != x ; then
 459   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 460 [Define if you want the garbage collector to do object poisoning and
 461    other memory allocation checks.  This is quite expensive.])
 462 fi
 463 if test x$ac_gc_always_collect != x ; then
 464   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 465 [Define if you want the garbage collector to operate in maximally
 466    paranoid mode, validating the entire heap and collecting garbage at
 467    every opportunity.  This is extremely expensive.])
 468 fi
 469 if test x$ac_fold_checking != x ; then
 470   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 471 [Define if you want fold checked that it never destructs its argument.
 472    This is quite expensive.])
 473 fi
 474 valgrind_path_defines=
 475 valgrind_command=
 476
 477 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 478 dnl # an if statement.  This was the source of very frustrating bugs
 479 dnl # in converting to autoconf 2.5x!
 480 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 481
 482 if test x$ac_valgrind_checking != x ; then
 483   # It is certainly possible that there's valgrind but no valgrind.h.
 484   # GCC relies on making annotations so we must have both.
 485   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 486   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 487     [[#include <valgrind/memcheck.h>
 488 #ifndef VALGRIND_DISCARD
 489 #error VALGRIND_DISCARD not defined
 490 #endif]])],
 491   [gcc_cv_header_valgrind_memcheck_h=yes],
 492   [gcc_cv_header_valgrind_memcheck_h=no])
 493   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 494   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 495   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 496     [[#include <memcheck.h>
 497 #ifndef VALGRIND_DISCARD
 498 #error VALGRIND_DISCARD not defined
 499 #endif]])],
 500   [gcc_cv_header_memcheck_h=yes],
 501   [gcc_cv_header_memcheck_h=no])
 502   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 503   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 504         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 505   if test "x$valgrind_path" = "x" \
 506     || (test $have_valgrind_h = no \
 507         && test $gcc_cv_header_memcheck_h = no \
 508         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 509         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 510   fi
 511   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 512   valgrind_command="$valgrind_path -q"
 513   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 514 [Define if you want to run subprograms and generated programs
 515    through valgrind (a memory checker).  This is extremely expensive.])
 516   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 517     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 518         [Define if valgrind's valgrind/memcheck.h header is installed.])
 519   fi
 520   if test $gcc_cv_header_memcheck_h = yes; then
 521     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 522         [Define if valgrind's memcheck.h header is installed.])
 523   fi
 524 fi
 525 AC_SUBST(valgrind_path_defines)
 526 AC_SUBST(valgrind_command)
 527
 528 # Enable code coverage collection
 529 AC_ARG_ENABLE(coverage,
 530 [  --enable-coverage[=LEVEL]
 531                           enable compiler's code coverage collection.
 532                           Use to measure compiler performance and locate
 533                           unused parts of the compiler. With LEVEL, specify
 534                           optimization. Values are opt, noopt,
 535                           default is noopt],
 536 [case "${enableval}" in
 537   yes|noopt)
 538     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 539     ;;
 540   opt)
 541     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 542     ;;
 543   no)
 544     # a.k.a. --disable-coverage
 545     coverage_flags=""
 546     ;;
 547   *)
 548     AC_MSG_ERROR(unknown coverage setting $enableval)
 549     ;;
 550 esac],
 551 [coverage_flags=""])
 552 AC_SUBST(coverage_flags)
 553
 554 AC_ARG_ENABLE(gather-detailed-mem-stats,
 555 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 556 [enable_gather_detailed_mem_stats=no])
 557 if test x$enable_gather_detailed_mem_stats = xyes ; then
 558   AC_DEFINE(GATHER_STATISTICS, 1,
 559         [Define to enable detailed memory allocation stats gathering.])
 560 fi
 561
 562 # -------------------------------
 563 # Miscenalleous configure options
 564 # -------------------------------
 565
 566 # With stabs
 567 AC_ARG_WITH(stabs,
 568 [  --with-stabs            arrange to use stabs instead of host debug format],
 569 stabs="$with_stabs",
 570 stabs=no)
 571
 572 # Determine whether or not multilibs are enabled.
 573 AC_ARG_ENABLE(multilib,
 574 [  --enable-multilib       enable library support for multiple ABIs],
 575 [], [enable_multilib=yes])
 576 AC_SUBST(enable_multilib)
 577
 578 # Enable __cxa_atexit for C++.
 579 AC_ARG_ENABLE(__cxa_atexit,
 580 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 581 [], [])
 582
 583 # Enable C extension for decimal float if target supports it.
 584 AC_ARG_ENABLE(decimal-float,
 585 [  --enable-decimal-float={no,yes,bid,dpd}
 586                         enable decimal float extension to C.  Selecting 'bid'
 587                         or 'dpd' choses which decimal floating point format
 588                         to use],
 589 [
 590   case $enable_decimal_float in
 591     yes | no | bid | dpd) ;;
 592     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 593 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 594   esac
 595 ],
 596 [
 597   case $target in
 598     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 599       enable_decimal_float=yes
 600       ;;
 601     *)
 602       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 603       enable_decimal_float=no
 604       ;;
 605   esac
 606 ])
 607
 608 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 609 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 610 [Define to 1 to enable decimal float extension to C.])
 611
 612 # x86's use BID format instead of DPD
 613 case x$enable_decimal_float in
 614   xyes)
 615     case $target in
 616       i?86*-*-linux* | x86_64*-*-linux*)
 617         enable_decimal_float=bid
 618         ;;
 619       *)
 620         enable_decimal_float=dpd
 621         ;;
 622     esac
 623     ;;
 624   xno)
 625     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 626     # dependency on libdecnumber.
 627     enable_decimal_float=dpd
 628     ;;
 629 esac
 630 AC_SUBST(enable_decimal_float)
 631
 632 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 633 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 634 [Define to 1 to specify that we are using the BID decimal floating
 635 point format instead of DPD])
 636
 637 # Enable C extension for fixed-point arithmetic.
 638 AC_ARG_ENABLE(fixed-point,
 639 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 640 [
 641 ],
 642 [
 643   case $target in
 644     mips*-*-*)
 645       case $host in
 646         mips*-sgi-irix*)
 647           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 648           enable_fixed_point=no
 649           ;;
 650         *)
 651           enable_fixed_point=yes
 652           ;;
 653       esac
 654       ;;
 655     *)
 656       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 657       enable_fixed_point=no
 658       ;;
 659   esac
 660 ])
 661 AC_SUBST(enable_fixed_point)
 662
 663 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 664 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 665 [Define to 1 to enable fixed-point arithmetic extension to C.])
 666
 667 # Enable threads
 668 # Pass with no value to take the default
 669 # Pass with a value to specify a thread package
 670 AC_ARG_ENABLE(threads,
 671 [  --enable-threads        enable thread usage for target GCC
 672   --enable-threads=LIB    use LIB thread package for target GCC],,
 673 [enable_threads=''])
 674
 675 AC_ARG_ENABLE(tls,
 676 [  --enable-tls            enable or disable generation of tls code
 677                           overriding the assembler check for tls support],
 678 [
 679   case $enable_tls in
 680     yes | no) ;;
 681     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 682 Valid choices are 'yes' and 'no'.]) ;;
 683   esac
 684 ], [enable_tls=''])
 685
 686 AC_ARG_ENABLE(objc-gc,
 687 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 688                           the GNU Objective-C runtime],
 689 if test x$enable_objc_gc = xno; then
 690         objc_boehm_gc=''
 691 else
 692         objc_boehm_gc=1
 693 fi,
 694 objc_boehm_gc='')
 695
 696 AC_ARG_WITH(dwarf2,
 697 [  --with-dwarf2           force the default debug format to be DWARF 2],
 698 dwarf2="$with_dwarf2",
 699 dwarf2=no)
 700
 701 AC_ARG_ENABLE(shared,
 702 [  --disable-shared        don't provide a shared libgcc],
 703 [
 704   case $enable_shared in
 705   yes | no) ;;
 706   *)
 707     enable_shared=no
 708     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 709     for pkg in $enableval; do
 710       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 711         enable_shared=yes
 712       fi
 713     done
 714     IFS="$ac_save_ifs"
 715     ;;
 716   esac
 717 ], [enable_shared=yes])
 718 AC_SUBST(enable_shared)
 719
 720 AC_ARG_WITH(build-sysroot,
 721   [  --with-build-sysroot=sysroot
 722                           use sysroot as the system root during the build])
 723
 724 AC_ARG_WITH(sysroot,
 725 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 726 [
 727  case ${with_sysroot} in
 728  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 729  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 730  esac
 731
 732  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 733  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 734
 735  if test "x$prefix" = xNONE; then
 736   test_prefix=/usr/local
 737  else
 738   test_prefix=$prefix
 739  fi
 740  if test "x$exec_prefix" = xNONE; then
 741   test_exec_prefix=$test_prefix
 742  else
 743   test_exec_prefix=$exec_prefix
 744  fi
 745  case ${TARGET_SYSTEM_ROOT} in
 746  "${test_prefix}"|"${test_prefix}/"*|\
 747  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 748  '${prefix}'|'${prefix}/'*|\
 749  '${exec_prefix}'|'${exec_prefix}/'*)
 750    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 751    TARGET_SYSTEM_ROOT_DEFINE="$t"
 752    ;;
 753  esac
 754 ], [
 755  TARGET_SYSTEM_ROOT=
 756  TARGET_SYSTEM_ROOT_DEFINE=
 757  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 758 ])
 759 AC_SUBST(TARGET_SYSTEM_ROOT)
 760 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 761 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 762
 763 # Build with intermodule optimisations
 764 AC_ARG_ENABLE(intermodule,
 765 [  --enable-intermodule    build the compiler in one step],
 766 [case ${enable_intermodule} in
 767   yes) onestep="-onestep";;
 768   *) onestep="";;
 769 esac],
 770 [onestep=""])
 771 AC_SUBST(onestep)
 772
 773 ACX_PKGVERSION([GCC])
 774 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 775
 776 # Sanity check enable_languages in case someone does not run the toplevel
 777 # configure # script.
 778 AC_ARG_ENABLE(languages,
 779 [  --enable-languages=LIST specify which front-ends to build],
 780 [case ,${enable_languages}, in
 781        ,,|,yes,)
 782                 # go safe -- we cannot be much sure without the toplevel
 783                 # configure's
 784                 # analysis of which target libs are present and usable
 785                 enable_languages=c
 786                 ;;
 787          *,all,*)
 788                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 789                 ;;
 790         *,c,*)
 791                 ;;
 792         *)
 793                 enable_languages=c,${enable_languages}
 794                 ;;
 795 esac],
 796 [enable_languages=c])
 797
 798 # Used by documentation targets
 799 AC_SUBST(datarootdir)
 800 AC_SUBST(docdir)
 801 AC_SUBST(htmldir)
 802
 803 # -------------------------
 804 # Checks for other programs
 805 # -------------------------
 806
 807 AC_PROG_MAKE_SET
 808
 809 # Find some useful tools
 810 AC_PROG_AWK
 811 # We need awk to create options.c and options.h.
 812 # Bail out if it's missing.
 813 case ${AWK} in
 814   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 815 esac
 816
 817 gcc_AC_PROG_LN_S
 818 ACX_PROG_LN($LN_S)
 819 AC_PROG_RANLIB
 820 case "${host}" in
 821 *-*-darwin*)
 822   # By default, the Darwin ranlib will not treat common symbols as
 823   # definitions when  building the archive table of contents.  Other
 824   # ranlibs do that; pass an option to the Darwin ranlib that makes
 825   # it behave similarly.
 826   ranlib_flags="-c"
 827   ;;
 828 *)
 829   ranlib_flags=""
 830 esac
 831 AC_SUBST(ranlib_flags)
 832
 833 gcc_AC_PROG_INSTALL
 834
 835 # See if cmp has --ignore-initial.
 836 gcc_AC_PROG_CMP_IGNORE_INITIAL
 837
 838 # See if we have the mktemp command.
 839 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 840
 841 # See if makeinfo has been installed and is modern enough
 842 # that we can use it.
 843 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 844   [GNU texinfo.* \([0-9][0-9.]*\)],
 845   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 846 if test $gcc_cv_prog_makeinfo_modern = no; then
 847   AC_MSG_WARN([
 848 *** Makeinfo is missing or too old.
 849 *** Info documentation will not be built.])
 850   BUILD_INFO=
 851 else
 852   BUILD_INFO=info
 853 fi
 854 AC_SUBST(BUILD_INFO)
 855
 856 # Is pod2man recent enough to regenerate manpages?
 857 AC_MSG_CHECKING([for recent Pod::Man])
 858 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 859   AC_MSG_RESULT(yes)
 860   GENERATED_MANPAGES=generated-manpages
 861 else
 862   AC_MSG_RESULT(no)
 863   GENERATED_MANPAGES=
 864 fi
 865 AC_SUBST(GENERATED_MANPAGES)
 866
 867 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 868
 869 # How about lex?
 870 dnl Don't use AC_PROG_LEX; we insist on flex.
 871 dnl LEXLIB is not useful in gcc.
 872 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 873
 874 # Bison?
 875 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 876
 877 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 878 # check for build == host before using them.
 879
 880 # NM
 881 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 882   && test -d ../binutils ; then
 883   NM='$(objdir)/../binutils/nm-new'
 884 else
 885   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 886 fi
 887
 888 # AR
 889 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 890   && test -d ../binutils ; then
 891   AR='$(objdir)/../binutils/ar'
 892 else
 893   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 894 fi
 895
 896
 897 # --------------------
 898 # Checks for C headers
 899 # --------------------
 900
 901 # Need to reject headers which give warnings, so that the -Werror bootstrap
 902 # works later. *sigh*  This needs to come before all header checks.
 903 AC_PROG_CPP_WERROR
 904
 905 AC_HEADER_STDC
 906 AC_HEADER_TIME
 907 ACX_HEADER_STRING
 908 AC_HEADER_SYS_WAIT
 909 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 910                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 911                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 912                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 913
 914 # Check for thread headers.
 915 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 916 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 917
 918 # These tests can't be done till we know if we have limits.h.
 919 gcc_AC_C_CHAR_BIT
 920 AC_C_BIGENDIAN
 921
 922 # --------
 923 # UNSORTED
 924 # --------
 925
 926
 927 # These libraries may be used by collect2.
 928 # We may need a special search path to get them linked.
 929 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 930 [save_LIBS="$LIBS"
 931 for libs in '' -lld -lmld \
 932                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 933                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 934 do
 935         LIBS="$libs"
 936         AC_TRY_LINK_FUNC(ldopen,
 937                 [gcc_cv_collect2_libs="$libs"; break])
 938 done
 939 LIBS="$save_LIBS"
 940 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 941 case $gcc_cv_collect2_libs in
 942         "none required")        ;;
 943         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 944 esac
 945 AC_SUBST(COLLECT2_LIBS)
 946
 947 # When building Ada code on Alpha, we need exc_resume which is usually in
 948 # -lexc.  So test for it.
 949 save_LIBS="$LIBS"
 950 LIBS=
 951 AC_SEARCH_LIBS(exc_resume, exc)
 952 GNAT_LIBEXC="$LIBS"
 953 LIBS="$save_LIBS"
 954 AC_SUBST(GNAT_LIBEXC)
 955
 956 # Some systems put ldexp and frexp in libm instead of libc; assume
 957 # they're both in the same place.  jcf-dump needs them.
 958 save_LIBS="$LIBS"
 959 LIBS=
 960 AC_SEARCH_LIBS(ldexp, m)
 961 LDEXP_LIB="$LIBS"
 962 LIBS="$save_LIBS"
 963 AC_SUBST(LDEXP_LIB)
 964
 965 # Use <inttypes.h> only if it exists,
 966 # doesn't clash with <sys/types.h>, and declares intmax_t.
 967 AC_MSG_CHECKING(for inttypes.h)
 968 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 969 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 970 [[#include <sys/types.h>
 971 #include <inttypes.h>]],
 972   [[intmax_t i = -1;]])],
 973   [gcc_cv_header_inttypes_h=yes],
 974   [gcc_cv_header_inttypes_h=no])])
 975 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 976 if test $gcc_cv_header_inttypes_h = yes; then
 977   AC_DEFINE(HAVE_INTTYPES_H, 1,
 978         [Define if you have a working <inttypes.h> header file.])
 979 fi
 980
 981 dnl Disabled until we have a complete test for buggy enum bitfields.
 982 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 983
 984 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 985   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 986   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 987   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 988   putchar_unlocked putc_unlocked)
 989 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 990         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 991         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 992         gcc_UNLOCKED_FUNCS)
 993
 994 if test x$ac_cv_func_mbstowcs = xyes; then
 995   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 996 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 997 int main()
 998 {
 999   mbstowcs(0, "", 0);
1000   return 0;
1001 }]])],
1002     [gcc_cv_func_mbstowcs_works=yes],
1003     [gcc_cv_func_mbstowcs_works=no],
1004     [gcc_cv_func_mbstowcs_works=yes])])
1005   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1006     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1007   [Define this macro if mbstowcs does not crash when its
1008    first argument is NULL.])
1009   fi
1010 fi
1011
1012 AC_CHECK_TYPE(ssize_t, int)
1013
1014 # Try to determine the array type of the second argument of getgroups
1015 # for the target system (int or gid_t).
1016 AC_TYPE_GETGROUPS
1017 if test "${target}" = "${build}"; then
1018   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1019 else
1020   case "${target}" in
1021         # This condition may need some tweaking.  It should include all
1022         # targets where the array type of the second argument of getgroups
1023         # is int and the type of gid_t is not equivalent to int.
1024         *-*-sunos* | *-*-ultrix*)
1025                 TARGET_GETGROUPS_T=int
1026                 ;;
1027         *)
1028                 TARGET_GETGROUPS_T=gid_t
1029                 ;;
1030   esac
1031 fi
1032 AC_SUBST(TARGET_GETGROUPS_T)
1033
1034 gcc_AC_FUNC_MMAP_BLACKLIST
1035
1036 case "${host}" in
1037 *-*-*vms*)
1038   # Under VMS, vfork works very differently than on Unix. The standard test
1039   # won't work, and it isn't easily adaptable. It makes more sense to
1040   # just force it.
1041   ac_cv_func_vfork_works=yes
1042   ;;
1043 esac
1044 AC_FUNC_FORK
1045
1046 AM_ICONV
1047 # Until we have in-tree GNU iconv:
1048 LIBICONV_DEP=
1049 AC_SUBST(LIBICONV_DEP)
1050
1051 AM_LC_MESSAGES
1052
1053 AM_LANGINFO_CODESET
1054
1055 # We will need to find libiberty.h and ansidecl.h
1056 saved_CFLAGS="$CFLAGS"
1057 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1058 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1059         strsignal strstr strverscmp \
1060         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1061         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"])
1064
1065 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1066 #include "ansidecl.h"
1067 #include "system.h"
1068 #ifdef HAVE_SYS_RESOURCE_H
1069 #include <sys/resource.h>
1070 #endif
1071 ])
1072
1073 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1074 #include "ansidecl.h"
1075 #include "system.h"
1076 #ifdef HAVE_SYS_RESOURCE_H
1077 #include <sys/resource.h>
1078 #endif
1079 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1080 [Define to `long' if <sys/resource.h> doesn't define.])])
1081
1082 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1083 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1084 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1085 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1086 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1087 #include "ansidecl.h"
1088 #include "system.h"
1089 #ifdef HAVE_LDFCN_H
1090 #undef FREAD
1091 #undef FWRITE
1092 #include <ldfcn.h>
1093 #endif
1094 ])
1095
1096 gcc_AC_CHECK_DECLS(times, , ,[
1097 #include "ansidecl.h"
1098 #include "system.h"
1099 #ifdef HAVE_SYS_TIMES_H
1100 #include <sys/times.h>
1101 #endif
1102 ])
1103
1104 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1105 #include "ansidecl.h"
1106 #include "system.h"
1107 #include <signal.h>
1108 ])
1109
1110 # More time-related stuff.
1111 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1112 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1113 #include "ansidecl.h"
1114 #include "system.h"
1115 #ifdef HAVE_SYS_TIMES_H
1116 #include <sys/times.h>
1117 #endif
1118 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1119 if test $ac_cv_struct_tms = yes; then
1120   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1121   [Define if <sys/times.h> defines struct tms.])
1122 fi
1123
1124 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1125 # revisit after autoconf 2.50.
1126 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1127 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1128 #include "ansidecl.h"
1129 #include "system.h"
1130 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1131 if test $gcc_cv_type_clock_t = yes; then
1132   AC_DEFINE(HAVE_CLOCK_T, 1,
1133   [Define if <time.h> defines clock_t.])
1134 fi
1135
1136 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1137 CFLAGS="$saved_CFLAGS"
1138
1139 gcc_AC_INITFINI_ARRAY
1140
1141 # mkdir takes a single argument on some systems.
1142 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1143
1144 # File extensions
1145 manext='.1'
1146 objext='.o'
1147 AC_SUBST(manext)
1148 AC_SUBST(objext)
1149
1150 # With Setjmp/Longjmp based exception handling.
1151 AC_ARG_ENABLE(sjlj-exceptions,
1152 [  --enable-sjlj-exceptions
1153                           arrange to use setjmp/longjmp exception handling],
1154 [case $target in
1155   *-*-hpux10*)
1156     if test $enableval != yes; then
1157       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1158       enableval=yes
1159     fi
1160     ;;
1161 esac
1162 force_sjlj_exceptions=yes],
1163 [case $target in
1164   *-*-hpux10*)
1165     force_sjlj_exceptions=yes
1166     enableval=yes
1167     ;;
1168   *)
1169     force_sjlj_exceptions=no
1170     ;;
1171 esac])
1172 if test $force_sjlj_exceptions = yes; then
1173   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1174   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1175     [Define 0/1 to force the choice for exception handling model.])
1176 fi
1177
1178 # For platforms with the unwind ABI which includes an unwind library,
1179 # libunwind, we can choose to use the system libunwind.
1180 AC_ARG_WITH(system-libunwind,
1181 [  --with-system-libunwind use installed libunwind])
1182
1183 # config.gcc also contains tests of with_system_libunwind.
1184 if test x$with_system_libunwind = xyes; then
1185         AC_DEFINE(HAVE_GETIPINFO, 1,
1186 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1187 fi
1188
1189 # --------------------------------------------------------
1190 # Build, host, and target specific configuration fragments
1191 # --------------------------------------------------------
1192
1193 # Collect build-machine-specific information.
1194 . ${srcdir}/config.build
1195
1196 # Collect host-machine-specific information.
1197 . ${srcdir}/config.host
1198
1199 target_gtfiles=
1200
1201 # Collect target-machine-specific information.
1202 . ${srcdir}/config.gcc
1203
1204 extra_objs="${host_extra_objs} ${extra_objs}"
1205 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1206
1207 # Default the target-machine variables that were not explicitly set.
1208 if test x"$tm_file" = x
1209 then tm_file=$cpu_type/$cpu_type.h; fi
1210
1211 if test x"$extra_headers" = x
1212 then extra_headers=; fi
1213
1214 if test x$md_file = x
1215 then md_file=$cpu_type/$cpu_type.md; fi
1216
1217 if test x$out_file = x
1218 then out_file=$cpu_type/$cpu_type.c; fi
1219
1220 if test x"$tmake_file" = x
1221 then tmake_file=$cpu_type/t-$cpu_type
1222 fi
1223
1224 if test x"$dwarf2" = xyes
1225 then tm_file="$tm_file tm-dwarf2.h"
1226 fi
1227
1228 # Say what files are being used for the output code and MD file.
1229 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1230 echo "Using \`$srcdir/config/$md_file' as machine description file."
1231
1232 # If any of the xm_file variables contain nonexistent files, warn
1233 # about them and drop them.
1234
1235 bx=
1236 for x in $build_xm_file; do
1237   if    test -f $srcdir/config/$x
1238   then      bx="$bx $x"
1239   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1240   fi
1241 done
1242 build_xm_file="$bx"
1243
1244 hx=
1245 for x in $host_xm_file; do
1246   if    test -f $srcdir/config/$x
1247   then      hx="$hx $x"
1248   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1249   fi
1250 done
1251 host_xm_file="$hx"
1252
1253 tx=
1254 for x in $xm_file; do
1255   if    test -f $srcdir/config/$x
1256   then      tx="$tx $x"
1257   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1258   fi
1259 done
1260 xm_file="$tx"
1261
1262 count=a
1263 for f in $tm_file; do
1264         count=${count}x
1265 done
1266 if test $count = ax; then
1267         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1268 else
1269         echo "Using the following target machine macro files:"
1270         for f in $tm_file; do
1271                 echo "  $srcdir/config/$f"
1272         done
1273 fi
1274
1275 if test x$need_64bit_hwint = xyes; then
1276         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1277 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1278 fi
1279
1280 if test x$use_long_long_for_widest_fast_int = xyes; then
1281         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1282 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1283 efficiently supported by the host hardware.])
1284 fi
1285
1286 count=a
1287 for f in $host_xm_file; do
1288         count=${count}x
1289 done
1290 if test $count = a; then
1291         :
1292 elif test $count = ax; then
1293         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1294 else
1295         echo "Using the following host machine macro files:"
1296         for f in $host_xm_file; do
1297                 echo "  $srcdir/config/$f"
1298         done
1299 fi
1300 echo "Using ${out_host_hook_obj} for host machine hooks."
1301
1302 if test "$host_xm_file" != "$build_xm_file"; then
1303         count=a
1304         for f in $build_xm_file; do
1305                 count=${count}x
1306         done
1307         if test $count = a; then
1308                 :
1309         elif test $count = ax; then
1310                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1311         else
1312                 echo "Using the following build machine macro files:"
1313                 for f in $build_xm_file; do
1314                         echo "  $srcdir/config/$f"
1315                 done
1316         fi
1317 fi
1318
1319 case ${host} in
1320   powerpc*-*-darwin*)
1321     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1322       gcc_cv_mcontext_underscores,
1323       AC_COMPILE_IFELSE([
1324 #include <sys/cdefs.h>
1325 #include <sys/signal.h>
1326 #include <ucontext.h>
1327 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1328 ],
1329         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1330       if test $gcc_cv_mcontext_underscores = yes; then
1331         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1332           [mcontext_t fields start with __])
1333       fi
1334     ;;
1335 esac
1336
1337 # ---------
1338 # Threading
1339 # ---------
1340
1341 # Check if a valid thread package
1342 case ${enable_threads} in
1343   "" | no)
1344     # No threads
1345     target_thread_file='single'
1346     ;;
1347   yes)
1348     # default
1349     target_thread_file='single'
1350     ;;
1351   aix | dce | gnat | irix | posix | posix95 | rtems | \
1352   single | solaris | vxworks | win32 | mipssde)
1353     target_thread_file=${enable_threads}
1354     ;;
1355   *)
1356     echo "${enable_threads} is an unknown thread package" 1>&2
1357     exit 1
1358     ;;
1359 esac
1360
1361 if test x${thread_file} = x; then
1362   # No thread file set by target-specific clauses in config.gcc,
1363   # so use file chosen by default logic above
1364   thread_file=${target_thread_file}
1365 fi
1366
1367 # Make gthr-default.h if we have a thread file.
1368 gthread_flags=
1369 if test $thread_file != single; then
1370   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1371   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1372     rm -f gthr-default.h-t
1373   else
1374     mv -f gthr-default.h-t gthr-default.h
1375   fi
1376   gthread_flags=-DHAVE_GTHR_DEFAULT
1377 fi
1378 AC_SUBST(gthread_flags)
1379
1380 # --------
1381 # UNSORTED
1382 # --------
1383
1384 use_cxa_atexit=no
1385 if test x$enable___cxa_atexit = xyes || \
1386    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1387   if test x$host = x$target; then
1388     case $host in
1389       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1390       # keyed to flag_use_cxa_atexit
1391       *-*-mingw32*)
1392         use_cxa_atexit=yes
1393         ;;
1394       *)
1395         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1396           [echo "__cxa_atexit can't be enabled on this target"])
1397         ;;
1398     esac
1399   else
1400     # We can't check for __cxa_atexit when building a cross, so assume
1401     # it is available
1402     use_cxa_atexit=yes
1403   fi
1404   if test x$use_cxa_atexit = xyes; then
1405     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1406       [Define if you want to use __cxa_atexit, rather than atexit, to
1407       register C++ destructors for local statics and global objects.
1408       This is essential for fully standards-compliant handling of
1409       destructors, but requires __cxa_atexit in libc.])
1410   fi
1411 fi
1412
1413 use_getipinfo=yes
1414 if test x$with_system_libunwind = xyes; then
1415    if test x$host = x$target; then
1416      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1417    fi
1418 fi
1419 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1420 if test x$use_getipinfo = xyes; then
1421    AC_DEFINE(HAVE_GETIPINFO, 1,
1422         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1423 else
1424    echo "The system unwind library does not support _Unwind_GetIPInfo."
1425 fi
1426
1427 # Look for a file containing extra machine modes.
1428 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1429   extra_modes_file='$(srcdir)'/config/${extra_modes}
1430   AC_SUBST(extra_modes_file)
1431   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1432   [Define to the name of a file containing a list of extra machine modes
1433    for this architecture.])
1434 fi
1435
1436 # Convert extra_options into a form suitable for Makefile use.
1437 extra_opt_files=
1438 for f in $extra_options; do
1439   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1440 done
1441 AC_SUBST(extra_opt_files)
1442
1443 # auto-host.h is the file containing items generated by autoconf and is
1444 # the first file included by config.h.
1445 # If host=build, it is correct to have bconfig include auto-host.h
1446 # as well.  If host!=build, we are in error and need to do more
1447 # work to find out the build config parameters.
1448 if test x$host = x$build
1449 then
1450         build_auto=auto-host.h
1451 else
1452         # We create a subdir, then run autoconf in the subdir.
1453         # To prevent recursion we set host and build for the new
1454         # invocation of configure to the build for this invocation
1455         # of configure.
1456         tempdir=build.$$
1457         rm -rf $tempdir
1458         mkdir $tempdir
1459         cd $tempdir
1460         case ${srcdir} in
1461         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1462         *) realsrcdir=../${srcdir};;
1463         esac
1464         saved_CFLAGS="${CFLAGS}"
1465         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1466         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1467         ${realsrcdir}/configure \
1468                 --enable-languages=${enable_languages-all} \
1469                 --target=$target_alias --host=$build_alias --build=$build_alias
1470         CFLAGS="${saved_CFLAGS}"
1471
1472         # We just finished tests for the build machine, so rename
1473         # the file auto-build.h in the gcc directory.
1474         mv auto-host.h ../auto-build.h
1475         cd ..
1476         rm -rf $tempdir
1477         build_auto=auto-build.h
1478 fi
1479 AC_SUBST(build_subdir)
1480
1481 tm_file="${tm_file} defaults.h"
1482 tm_p_file="${tm_p_file} tm-preds.h"
1483 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1484 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1485 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1486 # put this back in temporarily.
1487 xm_file="auto-host.h ansidecl.h ${xm_file}"
1488
1489 # --------
1490 # UNSORTED
1491 # --------
1492
1493 changequote(,)dnl
1494 # Compile in configure arguments.
1495 if test -f configargs.h ; then
1496         # Being re-configured.
1497         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1498         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1499 else
1500         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1501 fi
1502
1503 # Double all backslashes and backslash all quotes to turn
1504 # gcc_config_arguments into a C string.
1505 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1506 $gcc_config_arguments
1507 EOF
1508 gcc_config_arguments_str=`cat conftest.out`
1509 rm -f conftest.out
1510
1511 cat > configargs.h <<EOF
1512 /* Generated automatically. */
1513 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1514 static const char thread_model[] = "$thread_file";
1515
1516 static const struct {
1517   const char *name, *value;
1518 } configure_default_options[] = $configure_default_options;
1519 EOF
1520 changequote([,])dnl
1521
1522 # Internationalization
1523 ZW_GNU_GETTEXT_SISTER_DIR
1524
1525 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1526 # -liconv on the link line twice.
1527 case "$LIBINTL" in *$LIBICONV*)
1528         LIBICONV= ;;
1529 esac
1530
1531 AC_ARG_ENABLE(secureplt,
1532 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1533 [], [])
1534
1535 AC_ARG_ENABLE(cld,
1536 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1537 [enable_cld=no])
1538
1539 # Windows32 Registry support for specifying GCC installation paths.
1540 AC_ARG_ENABLE(win32-registry,
1541 [  --disable-win32-registry
1542                           disable lookup of installation paths in the
1543                           Registry on Windows hosts
1544   --enable-win32-registry enable registry lookup (default)
1545   --enable-win32-registry=KEY
1546                           use KEY instead of GCC version as the last portion
1547                           of the registry key],,)
1548
1549 case $host_os in
1550   win32 | pe | cygwin* | mingw32* | uwin*)
1551     if test "x$enable_win32_registry" != xno; then
1552       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1553     fi
1554
1555     if test "x$enable_win32_registry" != xno; then
1556       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1557   [Define to 1 if installation paths should be looked up in the Windows
1558    Registry. Ignored on non-Windows hosts.])
1559
1560       if test "x$enable_win32_registry" != xyes \
1561          && test "x$enable_win32_registry" != x; then
1562         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1563   [Define to be the last component of the Windows registry key under which
1564    to look for installation paths.  The full key used will be
1565    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1566    The default is the GCC version number.])
1567       fi
1568     fi
1569   ;;
1570 esac
1571
1572 # Get an absolute path to the GCC top-level source directory
1573 holddir=`${PWDCMD-pwd}`
1574 cd $srcdir
1575 topdir=`${PWDCMD-pwd}`
1576 cd $holddir
1577
1578 # Conditionalize the makefile for this host machine.
1579 xmake_file=
1580 for f in ${host_xmake_file}
1581 do
1582         if test -f ${srcdir}/config/$f
1583         then
1584                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1585         fi
1586 done
1587
1588 # Conditionalize the makefile for this target machine.
1589 tmake_file_=
1590 for f in ${tmake_file}
1591 do
1592         if test -f ${srcdir}/config/$f
1593         then
1594                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1595         fi
1596 done
1597 tmake_file="${tmake_file_}"
1598
1599 # This is a terrible hack which will go away some day.
1600 host_cc_for_libada=${CC}
1601 AC_SUBST(host_cc_for_libada)
1602
1603 out_object_file=`basename $out_file .c`.o
1604
1605 tm_file_list="options.h"
1606 tm_include_list="options.h"
1607 for f in $tm_file; do
1608   case $f in
1609     ./* )
1610        f=`echo $f | sed 's/^..//'`
1611        tm_file_list="${tm_file_list} $f"
1612        tm_include_list="${tm_include_list} $f"
1613        ;;
1614     defaults.h )
1615        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1616        tm_include_list="${tm_include_list} $f"
1617        ;;
1618     * )
1619        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1620        tm_include_list="${tm_include_list} config/$f"
1621        ;;
1622   esac
1623 done
1624
1625 tm_p_file_list=
1626 tm_p_include_list=
1627 for f in $tm_p_file; do
1628   case $f in
1629     tm-preds.h )
1630        tm_p_file_list="${tm_p_file_list} $f"
1631        tm_p_include_list="${tm_p_include_list} $f"
1632        ;;
1633     * )
1634        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1635        tm_p_include_list="${tm_p_include_list} config/$f"
1636   esac
1637 done
1638
1639 xm_file_list=
1640 xm_include_list=
1641 for f in $xm_file; do
1642   case $f in
1643     ansidecl.h )
1644        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1645        xm_include_list="${xm_include_list} $f"
1646        ;;
1647     auto-host.h )
1648        xm_file_list="${xm_file_list} $f"
1649        xm_include_list="${xm_include_list} $f"
1650        ;;
1651     * )
1652        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1653        xm_include_list="${xm_include_list} config/$f"
1654        ;;
1655   esac
1656 done
1657
1658 host_xm_file_list=
1659 host_xm_include_list=
1660 for f in $host_xm_file; do
1661   case $f in
1662     ansidecl.h )
1663        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1664        host_xm_include_list="${host_xm_include_list} $f"
1665        ;;
1666     auto-host.h )
1667        host_xm_file_list="${host_xm_file_list} $f"
1668        host_xm_include_list="${host_xm_include_list} $f"
1669        ;;
1670     * )
1671        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1672        host_xm_include_list="${host_xm_include_list} config/$f"
1673        ;;
1674   esac
1675 done
1676
1677 build_xm_file_list=
1678 for f in $build_xm_file; do
1679   case $f in
1680     ansidecl.h )
1681        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1682        build_xm_include_list="${build_xm_include_list} $f"
1683        ;;
1684     auto-build.h | auto-host.h )
1685        build_xm_file_list="${build_xm_file_list} $f"
1686        build_xm_include_list="${build_xm_include_list} $f"
1687        ;;
1688     * )
1689        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1690        build_xm_include_list="${build_xm_include_list} config/$f"
1691        ;;
1692   esac
1693 done
1694
1695 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1696 # cross-compiler which does not use the native headers and libraries.
1697 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1698 CROSS=                                          AC_SUBST(CROSS)
1699 ALL=all.internal                                AC_SUBST(ALL)
1700 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1701
1702 if test "x$with_build_sysroot" != x; then
1703   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1704 else
1705   # This value is used, even on a native system, because
1706   # CROSS_SYSTEM_HEADER_DIR is just
1707   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1708   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1709 fi
1710
1711 if test x$host != x$target
1712 then
1713         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1714         ALL=all.cross
1715         SYSTEM_HEADER_DIR=$build_system_header_dir
1716         case "$host","$target" in
1717         # Darwin crosses can use the host system's libraries and headers,
1718         # because of the fat library support.  Of course, it must be the
1719         # same version of Darwin on both sides.  Allow the user to
1720         # just say --target=foo-darwin without a version number to mean
1721         # "the version on this system".
1722             *-*-darwin*,*-*-darwin*)
1723                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1724                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1725                 if test $hostos = $targetos -o $targetos = darwin ; then
1726                     CROSS=
1727                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1728                     with_headers=yes
1729                 fi
1730                 ;;
1731
1732             i?86-*-*,x86_64-*-* \
1733             | powerpc*-*-*,powerpc64*-*-*)
1734                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1735         esac
1736 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1737         SYSTEM_HEADER_DIR=$build_system_header_dir
1738 fi
1739
1740 # If this is a cross-compiler that does not
1741 # have its own set of headers then define
1742 # inhibit_libc
1743
1744 # If this is using newlib, without having the headers available now,
1745 # then define inhibit_libc in LIBGCC2_CFLAGS.
1746 # This prevents libgcc2 from containing any code which requires libc
1747 # support.
1748 : ${inhibit_libc=false}
1749 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1750        test x$with_newlib = xyes ; } &&
1751      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1752        inhibit_libc=true
1753 fi
1754 AC_SUBST(inhibit_libc)
1755
1756 # When building gcc with a cross-compiler, we need to adjust things so
1757 # that the generator programs are still built with the native compiler.
1758 # Also, we cannot run fixincludes or fix-header.
1759
1760 # These are the normal (build=host) settings:
1761 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1762 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1763 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1764 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1765
1766 # Possibly disable fixproto, on a per-target basis.
1767 case ${use_fixproto} in
1768   no)
1769     STMP_FIXPROTO=
1770     ;;
1771   yes)
1772     STMP_FIXPROTO=stmp-fixproto
1773     ;;
1774 esac
1775 AC_SUBST(STMP_FIXPROTO)
1776
1777 # And these apply if build != host, or we are generating coverage data
1778 if test x$build != x$host || test "x$coverage_flags" != x
1779 then
1780     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1781     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1782
1783     if test "x$TARGET_SYSTEM_ROOT" = x; then
1784         if test "x$STMP_FIXPROTO" != x; then
1785           STMP_FIXPROTO=stmp-install-fixproto
1786         fi
1787     fi
1788 fi
1789
1790 # Expand extra_headers to include complete path.
1791 # This substitutes for lots of t-* files.
1792 extra_headers_list=
1793 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1794 for file in ${extra_headers} ; do
1795   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1796 done
1797
1798 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1799 if test x"$use_gcc_tgmath" = xyes
1800 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1801 fi
1802
1803 # Define collect2 in Makefile.
1804 case $host_can_use_collect2 in
1805   no) collect2= ;;
1806   *) collect2='collect2$(exeext)' ;;
1807 esac
1808 AC_SUBST([collect2])
1809
1810 # Add a definition of USE_COLLECT2 if system wants one.
1811 case $use_collect2 in
1812   no) use_collect2= ;;
1813   "") ;;
1814   *)
1815     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1816     xm_defines="${xm_defines} USE_COLLECT2"
1817     case $host_can_use_collect2 in
1818       no)
1819         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1820         ;;
1821     esac
1822     ;;
1823 esac
1824
1825 # ---------------------------
1826 # Assembler & linker features
1827 # ---------------------------
1828
1829 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1830 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1831 # However when ld-new is first executed from the build tree, libtool will
1832 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1833 # to the build tree.  While doing this we need to use the previous-stage
1834 # linker, or we have an infinite loop.  The presence of a shell script as
1835 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1836 # the gcc/collect-ld script.  So we need to know how libtool works, or
1837 # exec-tool will fail.
1838
1839 m4_defun([_LT_CONFIG_COMMANDS], [])
1840 AC_PROG_LIBTOOL
1841 AC_SUBST(objdir)
1842 AC_SUBST(enable_fast_install)
1843
1844 # Identify the assembler which will work hand-in-glove with the newly
1845 # built GCC, so that we can examine its features.  This is the assembler
1846 # which will be driven by the driver program.
1847 #
1848 # If build != host, and we aren't building gas in-tree, we identify a
1849 # build->target assembler and hope that it will have the same features
1850 # as the host->target assembler we'll be using.
1851 gcc_cv_gas_major_version=
1852 gcc_cv_gas_minor_version=
1853 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1854
1855 m4_pattern_allow([AS_FOR_TARGET])dnl
1856 AS_VAR_SET_IF(gcc_cv_as,, [
1857 if test -x "$DEFAULT_ASSEMBLER"; then
1858         gcc_cv_as="$DEFAULT_ASSEMBLER"
1859 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1860      && test -f ../gas/Makefile \
1861      && test x$build = x$host; then
1862         gcc_cv_as=../gas/as-new$build_exeext
1863 elif test -x as$build_exeext; then
1864         # Build using assembler in the current directory.
1865         gcc_cv_as=./as$build_exeext
1866 elif test -x $AS_FOR_TARGET; then
1867         gcc_cv_as="$AS_FOR_TARGET"
1868 else
1869         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1870 fi])
1871
1872 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1873 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1874 case "$ORIGINAL_AS_FOR_TARGET" in
1875   ./as | ./as$build_exeext) ;;
1876   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1877 esac
1878
1879 AC_MSG_CHECKING(what assembler to use)
1880 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1881   # Single tree build which includes gas.  We want to prefer it
1882   # over whatever linker top-level may have detected, since
1883   # we'll use what we're building after installation anyway.
1884   AC_MSG_RESULT(newly built gas)
1885   in_tree_gas=yes
1886   _gcc_COMPUTE_GAS_VERSION
1887   in_tree_gas_is_elf=no
1888   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1889      || (grep 'obj_format = multi' ../gas/Makefile \
1890          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1891   then
1892     in_tree_gas_is_elf=yes
1893   fi
1894 else
1895   AC_MSG_RESULT($gcc_cv_as)
1896   in_tree_gas=no
1897 fi
1898
1899 # Identify the linker which will work hand-in-glove with the newly
1900 # built GCC, so that we can examine its features.  This is the linker
1901 # which will be driven by the driver program.
1902 #
1903 # If build != host, and we aren't building gas in-tree, we identify a
1904 # build->target linker and hope that it will have the same features
1905 # as the host->target linker we'll be using.
1906 gcc_cv_gld_major_version=
1907 gcc_cv_gld_minor_version=
1908 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1909 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1910
1911 AS_VAR_SET_IF(gcc_cv_ld,, [
1912 if test -x "$DEFAULT_LINKER"; then
1913         gcc_cv_ld="$DEFAULT_LINKER"
1914 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1915      && test -f ../ld/Makefile \
1916      && test x$build = x$host; then
1917         gcc_cv_ld=../ld/ld-new$build_exeext
1918 elif test -x collect-ld$build_exeext; then
1919         # Build using linker in the current directory.
1920         gcc_cv_ld=./collect-ld$build_exeext
1921 elif test -x $LD_FOR_TARGET; then
1922         gcc_cv_ld="$LD_FOR_TARGET"
1923 else
1924         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1925 fi])
1926
1927 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1928 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1929 case "$ORIGINAL_LD_FOR_TARGET" in
1930   ./collect-ld | ./collect-ld$build_exeext) ;;
1931   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1932 esac
1933
1934 AC_MSG_CHECKING(what linker to use)
1935 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1936         # Single tree build which includes ld.  We want to prefer it
1937         # over whatever linker top-level may have detected, since
1938         # we'll use what we're building after installation anyway.
1939         AC_MSG_RESULT(newly built ld)
1940         in_tree_ld=yes
1941         in_tree_ld_is_elf=no
1942         if (grep 'EMUL = .*elf' ../ld/Makefile \
1943             || grep 'EMUL = .*linux' ../ld/Makefile \
1944             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1945           in_tree_ld_is_elf=yes
1946         fi
1947         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1948         do
1949 changequote(,)dnl
1950                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1951                 if test x$gcc_cv_gld_version != x; then
1952                         break
1953                 fi
1954         done
1955         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1956         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1957 changequote([,])dnl
1958 else
1959         AC_MSG_RESULT($gcc_cv_ld)
1960         in_tree_ld=no
1961 fi
1962
1963 # Figure out what nm we will be using.
1964 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1965 AS_VAR_SET_IF(gcc_cv_nm,, [
1966 if test -f $gcc_cv_binutils_srcdir/configure.in \
1967      && test -f ../binutils/Makefile \
1968      && test x$build = x$host; then
1969         gcc_cv_nm=../binutils/nm-new$build_exeext
1970 elif test -x nm$build_exeext; then
1971         gcc_cv_nm=./nm$build_exeext
1972 elif test -x $NM_FOR_TARGET; then
1973         gcc_cv_nm="$NM_FOR_TARGET"
1974 else
1975         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1976 fi])
1977
1978 AC_MSG_CHECKING(what nm to use)
1979 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1980         # Single tree build which includes binutils.
1981         AC_MSG_RESULT(newly built nm)
1982         in_tree_nm=yes
1983 else
1984         AC_MSG_RESULT($gcc_cv_nm)
1985         in_tree_nm=no
1986 fi
1987
1988 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1989 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1990 case "$ORIGINAL_NM_FOR_TARGET" in
1991   ./nm | ./nm$build_exeext) ;;
1992   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1993 esac
1994
1995
1996 # Figure out what objdump we will be using.
1997 AS_VAR_SET_IF(gcc_cv_objdump,, [
1998 if test -f $gcc_cv_binutils_srcdir/configure.in \
1999      && test -f ../binutils/Makefile \
2000      && test x$build = x$host; then
2001         # Single tree build which includes binutils.
2002         gcc_cv_objdump=../binutils/objdump$build_exeext
2003 elif test -x objdump$build_exeext; then
2004         gcc_cv_objdump=./objdump$build_exeext
2005 elif test -x $OBJDUMP_FOR_TARGET; then
2006         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2007 else
2008         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2009 fi])
2010
2011 AC_MSG_CHECKING(what objdump to use)
2012 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2013         # Single tree build which includes binutils.
2014         AC_MSG_RESULT(newly built objdump)
2015 elif test x$gcc_cv_objdump = x; then
2016         AC_MSG_RESULT(not found)
2017 else
2018         AC_MSG_RESULT($gcc_cv_objdump)
2019 fi
2020
2021 # Figure out what assembler alignment features are present.
2022 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2023  [2,6,0],,
2024 [.balign 4
2025 .p2align 2],,
2026 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2027   [Define if your assembler supports .balign and .p2align.])])
2028
2029 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2030  [2,8,0],,
2031  [.p2align 4,,7],,
2032 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2033   [Define if your assembler supports specifying the maximum number
2034    of bytes to skip when using the GAS .p2align command.])])
2035
2036 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2037  [2,8,0],,
2038  [.literal16],,
2039 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2040   [Define if your assembler supports .literal16.])])
2041
2042 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2043  [elf,2,9,0],,
2044  [conftest_label1: .word 0
2045 .subsection -1
2046 conftest_label2: .word 0
2047 .previous],
2048  [if test x$gcc_cv_nm != x; then
2049     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2050     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2051     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2052     then :
2053     else gcc_cv_as_subsection_m1=yes
2054     fi
2055     rm -f conftest.nm1 conftest.nm2
2056   fi],
2057  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2058   [Define if your assembler supports .subsection and .subsection -1 starts
2059    emitting at the beginning of your section.])])
2060
2061 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2062  [2,2,0],,
2063  [      .weak foobar],,
2064 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2065
2066 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2067  [2,17,0],,
2068  [      .weakref foobar, barfnot],,
2069 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2070
2071 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2072  [2,15,91],,
2073  [      .SPACE $TEXT$
2074         .NSUBSPA $CODE$,COMDAT],,
2075 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2076
2077 # .hidden needs to be supported in both the assembler and the linker,
2078 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2079 # This is irritatingly difficult to feature test for; we have to check the
2080 # date string after the version number.  If we've got an in-tree
2081 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2082 # to be safe.
2083 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2084 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2085  [elf,2,13,0],,
2086 [       .hidden foobar
2087 foobar:])
2088
2089 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2090 [if test $in_tree_ld = yes ; then
2091   gcc_cv_ld_hidden=no
2092   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2093      && test $in_tree_ld_is_elf = yes; then
2094      gcc_cv_ld_hidden=yes
2095   fi
2096 else
2097   gcc_cv_ld_hidden=yes
2098   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2099   if echo "$ld_ver" | grep GNU > /dev/null; then
2100 changequote(,)dnl
2101     ld_vers=`echo $ld_ver | sed -n \
2102         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2103     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2104     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2105     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2106     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2107     if test 0"$ld_date" -lt 20020404; then
2108       if test -n "$ld_date"; then
2109         # If there was date string, but was earlier than 2002-04-04, fail
2110         gcc_cv_ld_hidden=no
2111       elif test -z "$ld_vers"; then
2112         # If there was no date string nor ld version number, something is wrong
2113         gcc_cv_ld_hidden=no
2114       else
2115         test -z "$ld_vers_patch" && ld_vers_patch=0
2116         if test "$ld_vers_major" -lt 2; then
2117           gcc_cv_ld_hidden=no
2118         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2119           gcc_cv_ld_hidden="no"
2120         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2121           gcc_cv_ld_hidden=no
2122         fi
2123       fi
2124 changequote([,])dnl
2125     fi
2126   else
2127     case "${target}" in
2128       hppa64*-*-hpux* | ia64*-*-hpux*)
2129         gcc_cv_ld_hidden=yes
2130         ;;
2131       *)
2132         gcc_cv_ld_hidden=no
2133         ;;
2134     esac
2135   fi
2136 fi])
2137 libgcc_visibility=no
2138 AC_SUBST(libgcc_visibility)
2139 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2140 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2141   libgcc_visibility=yes
2142   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2143   [Define if your assembler and linker support .hidden.])
2144 fi
2145
2146 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2147 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2148   [elf,2,11,0],,
2149 [       .data
2150         .uleb128 L2 - L1
2151 L1:
2152         .uleb128 1280
2153         .sleb128 -1010
2154 L2:],
2155  [# GAS versions before 2.11 do not support uleb128,
2156   # despite appearing to.
2157   # ??? There exists an elf-specific test that will crash
2158   # the assembler.  Perhaps it's better to figure out whether
2159   # arbitrary sections are supported and try the test.
2160   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2161   if echo "$as_ver" | grep GNU > /dev/null; then
2162 changequote(,)dnl
2163     as_vers=`echo $as_ver | sed -n \
2164         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2165     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2166     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2167 changequote([,])dnl
2168     if test $as_major -eq 2 && test $as_minor -lt 11
2169     then :
2170     else gcc_cv_as_leb128=yes
2171     fi
2172   fi],
2173   [AC_DEFINE(HAVE_AS_LEB128, 1,
2174     [Define if your assembler supports .sleb128 and .uleb128.])])
2175
2176 # GAS versions up to and including 2.11.0 may mis-optimize
2177 # .eh_frame data.
2178 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2179   [elf,2,12,0],,
2180 [       .text
2181 .LFB1:
2182         .4byte  0
2183 .L1:
2184         .4byte  0
2185 .LFE1:
2186         .section        .eh_frame,"aw",@progbits
2187 __FRAME_BEGIN__:
2188         .4byte  .LECIE1-.LSCIE1
2189 .LSCIE1:
2190         .4byte  0x0
2191         .byte   0x1
2192         .ascii "z\0"
2193         .byte   0x1
2194         .byte   0x78
2195         .byte   0x1a
2196         .byte   0x0
2197         .byte   0x4
2198         .4byte  1
2199         .p2align 1
2200 .LECIE1:
2201 .LSFDE1:
2202         .4byte  .LEFDE1-.LASFDE1
2203 .LASFDE1:
2204         .4byte  .LASFDE1-__FRAME_BEGIN__
2205         .4byte  .LFB1
2206         .4byte  .LFE1-.LFB1
2207         .byte   0x4
2208         .4byte  .LFE1-.LFB1
2209         .byte   0x4
2210         .4byte  .L1-.LFB1
2211 .LEFDE1:],
2212 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2213 cat > conftest.lit <<EOF
2214  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2215  0010 01000000 12000000 18000000 00000000  ................
2216  0020 08000000 04080000 0044               .........D      @&t@
2217 EOF
2218 cat > conftest.big <<EOF
2219  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2220  0010 00000001 00000012 00000018 00000000  ................
2221  0020 00000008 04000000 0844               .........D      @&t@
2222 EOF
2223   # If the assembler didn't choke, and we can objdump,
2224   # and we got the correct data, then succeed.
2225   # The text in the here-document typically retains its unix-style line
2226   # endings, while the output of objdump will use host line endings.
2227   # Therefore, use diff -b for the comparisons.
2228   if test x$gcc_cv_objdump != x \
2229   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2230      | tail -3 > conftest.got \
2231   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2232     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2233   then
2234     gcc_cv_as_eh_frame=yes
2235   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2236     gcc_cv_as_eh_frame=buggy
2237   else
2238     # Uh oh, what do we do now?
2239     gcc_cv_as_eh_frame=no
2240   fi])
2241
2242 if test $gcc_cv_as_eh_frame = buggy; then
2243   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2244   [Define if your assembler mis-optimizes .eh_frame data.])
2245 fi
2246
2247 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2248  [elf,2,12,0], [--fatal-warnings],
2249  [.section .rodata.str, "aMS", @progbits, 1])
2250 if test $gcc_cv_as_shf_merge = no; then
2251   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2252     [elf,2,12,0], [--fatal-warnings],
2253     [.section .rodata.str, "aMS", %progbits, 1])
2254 fi
2255 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2256   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2257 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2258
2259 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2260  [elf,2,16,0], [--fatal-warnings],
2261  [.section .text,"axG",@progbits,.foo,comdat])
2262 if test $gcc_cv_as_comdat_group = yes; then
2263   gcc_cv_as_comdat_group_percent=no
2264 else
2265  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2266    [elf,2,16,0], [--fatal-warnings],
2267    [.section .text,"axG",%progbits,.foo,comdat])
2268 fi
2269 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2270   comdat_group=yes
2271   if test 0"$ld_date" -lt 20050308; then
2272     if test -n "$ld_date"; then
2273       # If there was date string, but was earlier than 2005-03-08, fail
2274       comdat_group=no
2275     elif test "$ld_vers_major" -lt 2; then
2276       comdat_group=no
2277     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2278       comdat_group=no
2279     fi
2280   fi
2281 else
2282   # assume linkers other than GNU ld don't support COMDAT group
2283   comdat_group=no
2284 fi
2285 if test $comdat_group = no; then
2286   gcc_cv_as_comdat_group=no
2287   gcc_cv_as_comdat_group_percent=no
2288 fi
2289 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2290   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2291 [Define 0/1 if your assembler and linker support COMDAT groups.])
2292
2293 # Thread-local storage - the check is heavily parametrized.
2294 conftest_s=
2295 tls_first_major=
2296 tls_first_minor=
2297 tls_as_opt=
2298 case "$target" in
2299 changequote(,)dnl
2300   alpha*-*-*)
2301     conftest_s='
2302         .section ".tdata","awT",@progbits
2303 foo:    .long   25
2304         .text
2305         ldq     $27,__tls_get_addr($29)         !literal!1
2306         lda     $16,foo($29)                    !tlsgd!1
2307         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2308         ldq     $27,__tls_get_addr($29)         !literal!2
2309         lda     $16,foo($29)                    !tlsldm!2
2310         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2311         ldq     $1,foo($29)                     !gotdtprel
2312         ldah    $2,foo($29)                     !dtprelhi
2313         lda     $3,foo($2)                      !dtprello
2314         lda     $4,foo($29)                     !dtprel
2315         ldq     $1,foo($29)                     !gottprel
2316         ldah    $2,foo($29)                     !tprelhi
2317         lda     $3,foo($2)                      !tprello
2318         lda     $4,foo($29)                     !tprel'
2319         tls_first_major=2
2320         tls_first_minor=13
2321         tls_as_opt=--fatal-warnings
2322         ;;
2323   frv*-*-*)
2324     conftest_s='
2325         .section ".tdata","awT",@progbits
2326 x:      .long   25
2327         .text
2328         call    #gettlsoff(x)'
2329         tls_first_major=2
2330         tls_first_minor=14
2331         ;;
2332   hppa*-*-linux*)
2333     conftest_s='
2334 t1:     .reg    %r20
2335 t2:     .reg    %r21
2336 gp:     .reg    %r19
2337         .section ".tdata","awT",@progbits
2338 foo:    .long   25
2339         .text
2340         .align  4
2341         addil LT%foo-$tls_gdidx$,gp
2342         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2343         b __tls_get_addr
2344         nop
2345         addil LT%foo-$tls_ldidx$,gp
2346         b __tls_get_addr
2347         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2348         addil LR%foo-$tls_dtpoff$,%ret0
2349         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2350         mfctl %cr27,%t1
2351         addil LT%foo-$tls_ieoff$,gp
2352         ldw RT%foo-$tls_ieoff$(%r1),%t2
2353         add %t1,%t2,%t3
2354         mfctl %cr27,%t1
2355         addil LR%foo-$tls_leoff$,%t1
2356         ldo RR%foo-$tls_leoff$(%r1),%t2'
2357         tls_first_major=2
2358         tls_first_minor=15
2359         tls_as_opt=--fatal-warnings
2360         ;;
2361   arm*-*-*)
2362     conftest_s='
2363         .section ".tdata","awT",%progbits
2364 foo:    .long   25
2365         .text
2366 .word foo(gottpoff)
2367 .word foo(tpoff)
2368 .word foo(tlsgd)
2369 .word foo(tlsldm)
2370 .word foo(tlsldo)'
2371         tls_first_major=2
2372         tls_first_minor=17
2373         ;;
2374   i[34567]86-*-*)
2375     conftest_s='
2376         .section ".tdata","awT",@progbits
2377 foo:    .long   25
2378         .text
2379         movl    %gs:0, %eax
2380         leal    foo@TLSGD(,%ebx,1), %eax
2381         leal    foo@TLSLDM(%ebx), %eax
2382         leal    foo@DTPOFF(%eax), %edx
2383         movl    foo@GOTTPOFF(%ebx), %eax
2384         subl    foo@GOTTPOFF(%ebx), %eax
2385         addl    foo@GOTNTPOFF(%ebx), %eax
2386         movl    foo@INDNTPOFF, %eax
2387         movl    $foo@TPOFF, %eax
2388         subl    $foo@TPOFF, %eax
2389         leal    foo@NTPOFF(%ecx), %eax'
2390         tls_first_major=2
2391         tls_first_minor=14
2392         tls_as_opt=--fatal-warnings
2393         ;;
2394   x86_64-*-*)
2395     conftest_s='
2396         .section ".tdata","awT",@progbits
2397 foo:    .long   25
2398         .text
2399         movq    %fs:0, %rax
2400         leaq    foo@TLSGD(%rip), %rdi
2401         leaq    foo@TLSLD(%rip), %rdi
2402         leaq    foo@DTPOFF(%rax), %rdx
2403         movq    foo@GOTTPOFF(%rip), %rax
2404         movq    $foo@TPOFF, %rax'
2405         tls_first_major=2
2406         tls_first_minor=14
2407         tls_as_opt=--fatal-warnings
2408         ;;
2409   ia64-*-*)
2410     conftest_s='
2411         .section ".tdata","awT",@progbits
2412 foo:    data8   25
2413         .text
2414         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2415         addl    r17 = @ltoff(@dtprel(foo#)), gp
2416         addl    r18 = @ltoff(@tprel(foo#)), gp
2417         addl    r19 = @dtprel(foo#), gp
2418         adds    r21 = @dtprel(foo#), r13
2419         movl    r23 = @dtprel(foo#)
2420         addl    r20 = @tprel(foo#), gp
2421         adds    r22 = @tprel(foo#), r13
2422         movl    r24 = @tprel(foo#)'
2423         tls_first_major=2
2424         tls_first_minor=13
2425         tls_as_opt=--fatal-warnings
2426         ;;
2427   mips*-*-*)
2428     conftest_s='
2429         .section .tdata,"awT",@progbits
2430 x:
2431         .word 2
2432         .text
2433         addiu $4, $28, %tlsgd(x)
2434         addiu $4, $28, %tlsldm(x)
2435         lui $4, %dtprel_hi(x)
2436         addiu $4, $4, %dtprel_lo(x)
2437         lw $4, %gottprel(x)($28)
2438         lui $4, %tprel_hi(x)
2439         addiu $4, $4, %tprel_lo(x)'
2440         tls_first_major=2
2441         tls_first_minor=16
2442         tls_as_opt='-32 --fatal-warnings'
2443         ;;
2444   powerpc-*-*)
2445     conftest_s='
2446         .section ".tdata","awT",@progbits
2447         .align 2
2448 ld0:    .space 4
2449 ld1:    .space 4
2450 x1:     .space 4
2451 x2:     .space 4
2452 x3:     .space 4
2453         .text
2454         addi 3,31,ld0@got@tlsgd
2455         bl __tls_get_addr
2456         addi 3,31,x1@got@tlsld
2457         bl __tls_get_addr
2458         addi 9,3,x1@dtprel
2459         addis 9,3,x2@dtprel@ha
2460         addi 9,9,x2@dtprel@l
2461         lwz 9,x3@got@tprel(31)
2462         add 9,9,x@tls
2463         addi 9,2,x1@tprel
2464         addis 9,2,x2@tprel@ha
2465         addi 9,9,x2@tprel@l'
2466         tls_first_major=2
2467         tls_first_minor=14
2468         tls_as_opt="-a32 --fatal-warnings"
2469         ;;
2470   powerpc64-*-*)
2471     conftest_s='
2472         .section ".tdata","awT",@progbits
2473         .align 3
2474 ld0:    .space 8
2475 ld1:    .space 8
2476 x1:     .space 8
2477 x2:     .space 8
2478 x3:     .space 8
2479         .text
2480         addi 3,2,ld0@got@tlsgd
2481         bl .__tls_get_addr
2482         nop
2483         addi 3,2,ld1@toc
2484         bl .__tls_get_addr
2485         nop
2486         addi 3,2,x1@got@tlsld
2487         bl .__tls_get_addr
2488         nop
2489         addi 9,3,x1@dtprel
2490         bl .__tls_get_addr
2491         nop
2492         addis 9,3,x2@dtprel@ha
2493         addi 9,9,x2@dtprel@l
2494         bl .__tls_get_addr
2495         nop
2496         ld 9,x3@got@dtprel(2)
2497         add 9,9,3
2498         bl .__tls_get_addr
2499         nop'
2500         tls_first_major=2
2501         tls_first_minor=14
2502         tls_as_opt="-a64 --fatal-warnings"
2503         ;;
2504   s390-*-*)
2505     conftest_s='
2506         .section ".tdata","awT",@progbits
2507 foo:    .long   25
2508         .text
2509         .long   foo@TLSGD
2510         .long   foo@TLSLDM
2511         .long   foo@DTPOFF
2512         .long   foo@NTPOFF
2513         .long   foo@GOTNTPOFF
2514         .long   foo@INDNTPOFF
2515         l       %r1,foo@GOTNTPOFF(%r12)
2516         l       %r1,0(%r1):tls_load:foo
2517         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2518         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2519         tls_first_major=2
2520         tls_first_minor=14
2521         tls_as_opt="-m31 --fatal-warnings"
2522         ;;
2523   s390x-*-*)
2524     conftest_s='
2525         .section ".tdata","awT",@progbits
2526 foo:    .long   25
2527         .text
2528         .quad   foo@TLSGD
2529         .quad   foo@TLSLDM
2530         .quad   foo@DTPOFF
2531         .quad   foo@NTPOFF
2532         .quad   foo@GOTNTPOFF
2533         lg      %r1,foo@GOTNTPOFF(%r12)
2534         larl    %r1,foo@INDNTPOFF
2535         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2536         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2537         tls_first_major=2
2538         tls_first_minor=14
2539         tls_as_opt="-m64 -Aesame --fatal-warnings"
2540         ;;
2541   sh-*-* | sh[34]-*-*)
2542     conftest_s='
2543         .section ".tdata","awT",@progbits
2544 foo:    .long   25
2545         .text
2546         .long   foo@TLSGD
2547         .long   foo@TLSLDM
2548         .long   foo@DTPOFF
2549         .long   foo@GOTTPOFF
2550         .long   foo@TPOFF'
2551         tls_first_major=2
2552         tls_first_minor=13
2553         tls_as_opt=--fatal-warnings
2554         ;;
2555   sparc*-*-*)
2556     case "$target" in
2557       sparc*-sun-solaris2.[56789]*)
2558         # TLS was introduced in the Solaris 9 4/04 release but
2559         # we do not enable it by default on Solaris 9 either.
2560         if test "x$enable_tls" = xyes ; then
2561           on_solaris=yes
2562         else
2563           enable_tls=no;
2564         fi
2565         ;;
2566       sparc*-sun-solaris2.*)
2567         on_solaris=yes
2568         ;;
2569       *)
2570         on_solaris=no
2571         ;;
2572     esac
2573     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2574       conftest_s='
2575         .section ".tdata",#alloc,#write,#tls
2576 foo:    .long   25
2577         .text
2578         sethi   %tgd_hi22(foo), %o0
2579         add     %o0, %tgd_lo10(foo), %o1
2580         add     %l7, %o1, %o0, %tgd_add(foo)
2581         call    __tls_get_addr, %tgd_call(foo)
2582         sethi   %tldm_hi22(foo), %l1
2583         add     %l1, %tldm_lo10(foo), %l2
2584         add     %l7, %l2, %o0, %tldm_add(foo)
2585         call    __tls_get_addr, %tldm_call(foo)
2586         sethi   %tldo_hix22(foo), %l3
2587         xor     %l3, %tldo_lox10(foo), %l4
2588         add     %o0, %l4, %l5, %tldo_add(foo)
2589         sethi   %tie_hi22(foo), %o3
2590         add     %o3, %tie_lo10(foo), %o3
2591         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2592         add     %g7, %o2, %o4, %tie_add(foo)
2593         sethi   %tle_hix22(foo), %l1
2594         xor     %l1, %tle_lox10(foo), %o5
2595         ld      [%g7 + %o5], %o1'
2596         tls_first_major=0
2597         tls_first_minor=0
2598     else
2599       conftest_s='
2600         .section ".tdata","awT",@progbits
2601 foo:    .long   25
2602         .text
2603         sethi   %tgd_hi22(foo), %o0
2604         add     %o0, %tgd_lo10(foo), %o1
2605         add     %l7, %o1, %o0, %tgd_add(foo)
2606         call    __tls_get_addr, %tgd_call(foo)
2607         sethi   %tldm_hi22(foo), %l1
2608         add     %l1, %tldm_lo10(foo), %l2
2609         add     %l7, %l2, %o0, %tldm_add(foo)
2610         call    __tls_get_addr, %tldm_call(foo)
2611         sethi   %tldo_hix22(foo), %l3
2612         xor     %l3, %tldo_lox10(foo), %l4
2613         add     %o0, %l4, %l5, %tldo_add(foo)
2614         sethi   %tie_hi22(foo), %o3
2615         add     %o3, %tie_lo10(foo), %o3
2616         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2617         add     %g7, %o2, %o4, %tie_add(foo)
2618         sethi   %tle_hix22(foo), %l1
2619         xor     %l1, %tle_lox10(foo), %o5
2620         ld      [%g7 + %o5], %o1'
2621         tls_first_major=2
2622         tls_first_minor=14
2623         tls_as_opt="-32 --fatal-warnings"
2624       fi
2625         ;;
2626 changequote([,])dnl
2627 esac
2628 set_have_as_tls=no
2629 if test "x$enable_tls" = xno ; then
2630   : # TLS explicitly disabled.
2631 elif test "x$enable_tls" = xyes ; then
2632   set_have_as_tls=yes # TLS explicitly enabled.
2633 elif test -z "$tls_first_major"; then
2634   : # If we don't have a check, assume no support.
2635 else
2636   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2637   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2638   [set_have_as_tls=yes])
2639 fi
2640 if test $set_have_as_tls = yes ; then
2641   AC_DEFINE(HAVE_AS_TLS, 1,
2642             [Define if your assembler supports thread-local storage.])
2643 fi
2644
2645 # Target-specific assembler checks.
2646
2647 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2648 gcc_cv_ld_static_dynamic=no
2649 if test $in_tree_ld = yes ; then
2650   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2651     gcc_cv_ld_static_dynamic=yes
2652   fi
2653 elif test x$gcc_cv_ld != x; then
2654         # Check if linker supports -Bstatic/-Bdynamic option
2655         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2656           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2657                 gcc_cv_ld_static_dynamic=yes
2658         fi
2659 fi
2660 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2661         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2662 [Define if your linker supports -Bstatic/-Bdynamic option.])
2663 fi
2664 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2665
2666 if test x"$demangler_in_ld" = xyes; then
2667   AC_MSG_CHECKING(linker --demangle support)
2668   gcc_cv_ld_demangle=no
2669   if test $in_tree_ld = yes; then
2670     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2671       gcc_cv_ld_demangle=yes
2672     fi
2673   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2674     # Check if the GNU linker supports --demangle option
2675     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2676       gcc_cv_ld_demangle=yes
2677     fi
2678   fi
2679   if test x"$gcc_cv_ld_demangle" = xyes; then
2680     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2681 [Define if your linker supports --demangle option.])
2682   fi
2683   AC_MSG_RESULT($gcc_cv_ld_demangle)
2684 fi
2685
2686 case "$target" in
2687   # All TARGET_ABI_OSF targets.
2688   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2689     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2690         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2691 [       .set nomacro
2692         .text
2693         extbl   $3, $2, $3      !lituse_bytoff!1
2694         ldq     $2, a($29)      !literal!1
2695         ldq     $4, b($29)      !literal!2
2696         ldq_u   $3, 0($2)       !lituse_base!1
2697         ldq     $27, f($29)     !literal!5
2698         jsr     $26, ($27), f   !lituse_jsr!5
2699         ldah    $29, 0($26)     !gpdisp!3
2700         lda     $0, c($29)      !gprel
2701         ldah    $1, d($29)      !gprelhigh
2702         lda     $1, d($1)       !gprellow
2703         lda     $29, 0($29)     !gpdisp!3],,
2704     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2705   [Define if your assembler supports explicit relocations.])])
2706     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2707         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2708 [       .set nomacro
2709         .text
2710         ldq     $27, a($29)     !literal!1
2711         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2712     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2713   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2714     ;;
2715
2716   cris-*-*)
2717     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2718       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2719       [-no-mul-bug-abort], [.text],,
2720       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2721                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2722     ;;
2723
2724   sparc*-*-*)
2725     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2726       [.register %g2, #scratch],,
2727       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2728                 [Define if your assembler supports .register.])])
2729
2730     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2731       [-relax], [.text],,
2732       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2733                 [Define if your assembler supports -relax option.])])
2734
2735     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2736       gcc_cv_as_sparc_ua_pcrel,,
2737       [-K PIC],
2738 [.text
2739 foo:
2740         nop
2741 .data
2742 .align 4
2743 .byte 0
2744 .uaword %r_disp32(foo)],
2745       [if test x$gcc_cv_ld != x \
2746        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2747          gcc_cv_as_sparc_ua_pcrel=yes
2748        fi
2749        rm -f conftest],
2750       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2751                 [Define if your assembler and linker support unaligned PC relative relocs.])
2752
2753       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2754         gcc_cv_as_sparc_ua_pcrel_hidden,,
2755         [-K PIC],
2756 [.data
2757 .align 4
2758 .byte 0x31
2759 .uaword %r_disp32(foo)
2760 .byte 0x32, 0x33, 0x34
2761 .global foo
2762 .hidden foo
2763 foo:
2764 .skip 4],
2765         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2766          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2767          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2768             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2769             if $gcc_cv_objdump -R conftest 2> /dev/null \
2770                | grep 'DISP32' > /dev/null 2>&1; then
2771                 :
2772             else
2773                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2774             fi
2775          fi
2776          rm -f conftest],
2777          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2778                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2779     ]) # unaligned pcrel relocs
2780
2781     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2782       gcc_cv_as_sparc_offsetable_lo10,,
2783       [-xarch=v9],
2784 [.text
2785         or %g1, %lo(ab) + 12, %g1
2786         or %g1, %lo(ab + 12), %g1],
2787       [if test x$gcc_cv_objdump != x \
2788        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2789           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2790          gcc_cv_as_sparc_offsetable_lo10=yes
2791        fi],
2792        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2793                  [Define if your assembler supports offsetable %lo().])])
2794     ;;
2795
2796 changequote(,)dnl
2797   i[34567]86-*-* | x86_64-*-*)
2798 changequote([,])dnl
2799     case $target_os in
2800       cygwin* | pe | mingw32*)
2801         # Used for DWARF 2 in PE
2802         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2803           gcc_cv_as_ix86_pe_secrel32,
2804           [2,15,91],,
2805 [.text
2806 foo:    nop
2807 .data
2808         .secrel32 foo],
2809           [if test x$gcc_cv_ld != x \
2810            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2811              gcc_cv_as_ix86_pe_secrel32=yes
2812            fi
2813            rm -f conftest],
2814           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2815             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2816         ;;
2817     esac
2818
2819     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2820        gcc_cv_as_ix86_filds_fists,
2821       [2,9,0],, [filds mem; fists mem],,
2822       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2823         [Define if your assembler uses the new HImode fild and fist notation.])])
2824
2825     gcc_GAS_CHECK_FEATURE([cmov syntax],
2826       gcc_cv_as_ix86_cmov_sun_syntax,,,
2827       [cmovl.l %edx, %eax],,
2828       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2829         [Define if your assembler supports the Sun syntax for cmov.])])
2830
2831     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2832       gcc_cv_as_ix86_ffreep,,,
2833       [ffreep %st(1)],,
2834       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2835         [Define if your assembler supports the ffreep mnemonic.])])
2836
2837     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2838       gcc_cv_as_ix86_sahf,,,
2839       [sahf],,
2840       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2841         [Define if your assembler supports the sahf mnemonic.])])
2842
2843     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2844       gcc_cv_as_ix86_diff_sect_delta,,,
2845       [.section .rodata
2846 .L1:
2847         .long .L2-.L1
2848         .long .L3-.L1
2849         .text
2850 .L3:    nop
2851 .L2:    nop],,
2852       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2853         [Define if your assembler supports the subtraction of symbols in different sections.])])
2854
2855     # This one is used unconditionally by i386.[ch]; it is to be defined
2856     # to 1 if the feature is present, 0 otherwise.
2857     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2858         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2859 [       .text
2860 .L0:
2861         nop
2862         .data
2863         .long .L0@GOTOFF])
2864     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2865       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2866       [Define true if the assembler supports '.long foo@GOTOFF'.])
2867     ;;
2868
2869   ia64*-*-*)
2870     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2871         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2872 [       .text
2873         addl r15 = @ltoffx(x#), gp
2874         ;;
2875         ld8.mov r16 = [[r15]], x#],,
2876     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2877           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2878
2879     ;;
2880
2881   powerpc*-*-*)
2882     case $target in
2883       *-*-aix*) conftest_s='    .machine "pwr5"
2884         .csect .text[[PR]]
2885         mfcr 3,128';;
2886       *-*-darwin*)
2887         gcc_GAS_CHECK_FEATURE([.machine directive support],
2888           gcc_cv_as_machine_directive,,,
2889           [     .machine ppc7400])
2890         if test x$gcc_cv_as_machine_directive != xyes; then
2891           echo "*** This target requires an assembler supporting \".machine\"" >&2
2892           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2893           test x$build = x$target && exit 1
2894         fi
2895         conftest_s='    .text
2896         mfcr r3,128';;
2897       *) conftest_s='   .machine power4
2898         .text
2899         mfcr 3,128';;
2900     esac
2901
2902     gcc_GAS_CHECK_FEATURE([mfcr field support],
2903       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2904       [$conftest_s],,
2905       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2906           [Define if your assembler supports mfcr field.])])
2907
2908     case $target in
2909       *-*-aix*) conftest_s='    .machine "pwr5"
2910         .csect .text[[PR]]
2911         popcntb 3,3';;
2912       *) conftest_s='   .machine power5
2913         .text
2914         popcntb 3,3';;
2915     esac
2916
2917     gcc_GAS_CHECK_FEATURE([popcntb support],
2918       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2919       [$conftest_s],,
2920       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2921           [Define if your assembler supports popcntb field.])])
2922
2923     case $target in
2924       *-*-aix*) conftest_s='    .machine "pwr5x"
2925         .csect .text[[PR]]
2926         frin 1,1';;
2927       *) conftest_s='   .machine power5
2928         .text
2929         frin 1,1';;
2930     esac
2931
2932     gcc_GAS_CHECK_FEATURE([fp round support],
2933       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2934       [$conftest_s],,
2935       [AC_DEFINE(HAVE_AS_FPRND, 1,
2936           [Define if your assembler supports fprnd.])])
2937
2938     case $target in
2939       *-*-aix*) conftest_s='    .machine "pwr6"
2940         .csect .text[[PR]]
2941         mffgpr 1,3';;
2942       *) conftest_s='   .machine power6
2943         .text
2944         mffgpr 1,3';;
2945     esac
2946
2947     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2948       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2949       [$conftest_s],,
2950       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2951           [Define if your assembler supports mffgpr and mftgpr.])])
2952
2953     case $target in
2954       *-*-aix*) conftest_s='    .csect .text[[PR]]
2955 LCF..0:
2956         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2957       *-*-darwin*)
2958         conftest_s='    .text
2959 LCF0:
2960         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2961       *) conftest_s='   .text
2962 .LCF0:
2963         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2964     esac
2965
2966     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2967       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2968       [$conftest_s],,
2969       [AC_DEFINE(HAVE_AS_REL16, 1,
2970           [Define if your assembler supports R_PPC_REL16 relocs.])])
2971
2972     case $target in
2973       *-*-aix*) conftest_s='    .machine "pwr6"
2974         .csect .text[[PR]]
2975         cmpb 3,4,5';;
2976       *) conftest_s='   .machine power6
2977         .text
2978         cmpb 3,4,5';;
2979     esac
2980
2981     gcc_GAS_CHECK_FEATURE([compare bytes support],
2982       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2983       [$conftest_s],,
2984       [AC_DEFINE(HAVE_AS_CMPB, 1,
2985           [Define if your assembler supports cmpb.])])
2986
2987     case $target in
2988       *-*-aix*) conftest_s='    .machine "pwr6"
2989         .csect .text[[PR]]
2990         dadd 1,2,3';;
2991       *) conftest_s='   .machine power6
2992         .text
2993         dadd 1,2,3';;
2994     esac
2995
2996     gcc_GAS_CHECK_FEATURE([decimal float support],
2997       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2998       [$conftest_s],,
2999       [AC_DEFINE(HAVE_AS_DFP, 1,
3000           [Define if your assembler supports DFP instructions.])])
3001
3002     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3003       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3004       [.gnu_attribute 4,1],,
3005       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3006           [Define if your assembler supports .gnu_attribute.])])
3007     ;;
3008
3009   mips*-*-*)
3010     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3011       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3012 [       lw $4,%gp_rel(foo)($4)],,
3013       [if test x$target_cpu_default = x
3014        then target_cpu_default=MASK_EXPLICIT_RELOCS
3015        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3016        fi])
3017     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3018       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3019       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3020                  [Define if the assembler understands -mno-shared.])])
3021
3022     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3023       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3024       [.gnu_attribute 4,1],,
3025       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3026           [Define if your assembler supports .gnu_attribute.])])
3027
3028     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3029       gcc_cv_as_mips_dtprelword, [2,18,0],,
3030       [.section .tdata,"awT",@progbits
3031 x:
3032         .word 2
3033         .text
3034         .dtprelword x+0x8000],,
3035       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3036           [Define if your assembler supports .dtprelword.])])
3037     ;;
3038 esac
3039
3040 # Mips and HP-UX need the GNU assembler.
3041 # Linux on IA64 might be able to use the Intel assembler.
3042
3043 case "$target" in
3044   mips*-*-* | *-*-hpux* )
3045     if test x$gas_flag = xyes \
3046        || test x"$host" != x"$build" \
3047        || test ! -x "$gcc_cv_as" \
3048        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3049       :
3050     else
3051       echo "*** This configuration requires the GNU assembler" >&2
3052       exit 1
3053     fi
3054     ;;
3055 esac
3056
3057 # ??? Not all targets support dwarf2 debug_line, even within a version
3058 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3059 # info to the output file.  So, as supported targets are added to gas 2.11,
3060 # add some instruction here to (also) show we expect this might work.
3061 # ??? Once 2.11 is released, probably need to add first known working
3062 # version to the per-target configury.
3063 case "$target" in
3064   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3065   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3066   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* \
3067   | spu-*-* | fido*-*-*)
3068     insn="nop"
3069     ;;
3070   ia64*-*-* | s390*-*-*)
3071     insn="nop 0"
3072     ;;
3073   mmix-*-*)
3074     insn="swym 0"
3075     ;;
3076 esac
3077 if test x"$insn" != x; then
3078  conftest_s="\
3079         .file 1 \"conftest.s\"
3080         .loc 1 3 0
3081         $insn"
3082  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3083   gcc_cv_as_dwarf2_debug_line,
3084   [elf,2,11,0],, [$conftest_s],
3085   [if test x$gcc_cv_objdump != x \
3086    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3087       | grep debug_line > /dev/null 2>&1; then
3088      gcc_cv_as_dwarf2_debug_line=yes
3089    fi])
3090
3091 # The .debug_line file table must be in the exact order that
3092 # we specified the files, since these indices are also used
3093 # by DW_AT_decl_file.  Approximate this test by testing if
3094 # the assembler bitches if the same index is assigned twice.
3095  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3096   gcc_cv_as_dwarf2_file_buggy,,,
3097 [       .file 1 "foo.s"
3098         .file 1 "bar.s"])
3099
3100  if test $gcc_cv_as_dwarf2_debug_line = yes \
3101  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3102         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3103   [Define if your assembler supports dwarf2 .file/.loc directives,
3104    and preserves file table indices exactly as given.])
3105  fi
3106
3107  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3108   gcc_cv_as_gdwarf2_flag,
3109   [elf,2,11,0], [--gdwarf2], [$insn],,
3110   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3111 [Define if your assembler supports the --gdwarf2 option.])])
3112
3113  gcc_GAS_CHECK_FEATURE([--gstabs option],
3114   gcc_cv_as_gstabs_flag,
3115   [elf,2,11,0], [--gstabs], [$insn],
3116   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3117    # and warns about it, but still exits successfully.  So check for
3118    # this.
3119    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3120    then :
3121    else gcc_cv_as_gstabs_flag=yes
3122    fi],
3123   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3124 [Define if your assembler supports the --gstabs option.])])
3125
3126  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3127   gcc_cv_as_debug_prefix_map_flag,
3128   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3129   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3130 [Define if your assembler supports the --debug-prefix-map option.])])
3131 fi
3132
3133 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3134  [gcc_cv_as_line_zero],
3135  [gcc_cv_as_line_zero=no
3136   if test $in_tree_gas = yes; then
3137     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3138   elif test "x$gcc_cv_as" != x; then
3139     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3140     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3141        test "x`cat conftest.out`" = x
3142     then
3143       gcc_cv_as_line_zero=yes
3144     else
3145       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3146       cat conftest.s >&AS_MESSAGE_LOG_FD
3147       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3148       cat conftest.out >&AS_MESSAGE_LOG_FD
3149     fi
3150     rm -f conftest.o conftest.s conftest.out
3151   fi])
3152 if test "x$gcc_cv_as_line_zero" = xyes; then
3153   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3154 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3155 fi
3156
3157 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3158 gcc_cv_ld_ro_rw_mix=unknown
3159 if test $in_tree_ld = yes ; then
3160   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3161      && test $in_tree_ld_is_elf = yes; then
3162     gcc_cv_ld_ro_rw_mix=read-write
3163   fi
3164 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3165   echo '.section myfoosect, "a"' > conftest1.s
3166   echo '.section myfoosect, "aw"' > conftest2.s
3167   echo '.byte 1' >> conftest2.s
3168   echo '.section myfoosect, "a"' > conftest3.s
3169   echo '.byte 0' >> conftest3.s
3170   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3171      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3172      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3173      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3174         conftest2.o conftest3.o > /dev/null 2>&1; then
3175     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3176                          | sed -e '/myfoosect/!d' -e N`
3177     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3178       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3179         gcc_cv_ld_ro_rw_mix=read-only
3180       else
3181         gcc_cv_ld_ro_rw_mix=read-write
3182       fi
3183     fi
3184   fi
3185 changequote(,)dnl
3186   rm -f conftest.* conftest[123].*
3187 changequote([,])dnl
3188 fi
3189 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3190         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3191   [Define if your linker links a mix of read-only
3192    and read-write sections into a read-write section.])
3193 fi
3194 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3195
3196 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3197 gcc_cv_ld_eh_frame_hdr=no
3198 if test $in_tree_ld = yes ; then
3199   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3200      && test $in_tree_ld_is_elf = yes; then
3201     gcc_cv_ld_eh_frame_hdr=yes
3202   fi
3203 elif test x$gcc_cv_ld != x; then
3204         # Check if linker supports --eh-frame-hdr option
3205         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3206                 gcc_cv_ld_eh_frame_hdr=yes
3207         fi
3208 fi
3209 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3210 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3211         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3212 [Define if your linker supports --eh-frame-hdr option.])
3213 fi
3214 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3215
3216 AC_MSG_CHECKING(linker position independent executable support)
3217 gcc_cv_ld_pie=no
3218 if test $in_tree_ld = yes ; then
3219   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3220      && test $in_tree_ld_is_elf = yes; then
3221     gcc_cv_ld_pie=yes
3222   fi
3223 elif test x$gcc_cv_ld != x; then
3224         # Check if linker supports -pie option
3225         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3226                 gcc_cv_ld_pie=yes
3227         fi
3228 fi
3229 if test x"$gcc_cv_ld_pie" = xyes; then
3230         AC_DEFINE(HAVE_LD_PIE, 1,
3231 [Define if your linker supports -pie option.])
3232 fi
3233 AC_MSG_RESULT($gcc_cv_ld_pie)
3234
3235 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3236 gcc_cv_ld_eh_gc_sections=no
3237 if test $in_tree_ld = yes ; then
3238   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3239      && test $in_tree_ld_is_elf = yes; then
3240     gcc_cv_ld_eh_gc_sections=yes
3241   fi
3242 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3243   cat > conftest.s <<EOF
3244         .section        .text
3245 .globl _start
3246         .type _start, @function
3247 _start:
3248         .long foo
3249         .size _start, .-_start
3250         .section        .text.foo,"ax",@progbits
3251         .type foo, @function
3252 foo:
3253         .long 0
3254         .size foo, .-foo
3255         .section        .gcc_except_table.foo,"a",@progbits
3256 .L0:
3257         .long 0
3258         .section        .eh_frame,"a",@progbits
3259         .long .L0
3260 EOF
3261   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3262     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3263          | grep "gc-sections option ignored" > /dev/null; then
3264       gcc_cv_ld_eh_gc_sections=no
3265     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3266       gcc_cv_ld_eh_gc_sections=yes
3267       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3268       if test x$gcc_cv_as_comdat_group != xyes; then
3269         gcc_cv_ld_eh_gc_sections=no
3270         cat > conftest.s <<EOF
3271         .section        .text
3272 .globl _start
3273         .type _start, @function
3274 _start:
3275         .long foo
3276         .size _start, .-_start
3277         .section        .gnu.linkonce.t.foo,"ax",@progbits
3278         .type foo, @function
3279 foo:
3280         .long 0
3281         .size foo, .-foo
3282         .section        .gcc_except_table.foo,"a",@progbits
3283 .L0:
3284         .long 0
3285         .section        .eh_frame,"a",@progbits
3286         .long .L0
3287 EOF
3288         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3289           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3290                | grep "gc-sections option ignored" > /dev/null; then
3291             gcc_cv_ld_eh_gc_sections=no
3292           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3293             gcc_cv_ld_eh_gc_sections=yes
3294           fi
3295         fi
3296       fi
3297     fi
3298   fi
3299   rm -f conftest.s conftest.o conftest
3300 fi
3301 case "$target" in
3302   hppa*-*-linux*)
3303     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3304     gcc_cv_ld_eh_gc_sections=no
3305     ;;
3306 esac
3307 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3308         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3309   [Define if your linker supports garbage collection of
3310    sections in presence of EH frames.])
3311 fi
3312 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3313
3314 # --------
3315 # UNSORTED
3316 # --------
3317
3318 AC_CACHE_CHECK(linker --as-needed support,
3319 gcc_cv_ld_as_needed,
3320 [gcc_cv_ld_as_needed=no
3321 if test $in_tree_ld = yes ; then
3322   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3323      && test $in_tree_ld_is_elf = yes; then
3324     gcc_cv_ld_as_needed=yes
3325   fi
3326 elif test x$gcc_cv_ld != x; then
3327         # Check if linker supports --as-needed and --no-as-needed options
3328         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3329                 gcc_cv_ld_as_needed=yes
3330         fi
3331 fi
3332 ])
3333 if test x"$gcc_cv_ld_as_needed" = xyes; then
3334         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3335 [Define if your linker supports --as-needed and --no-as-needed options.])
3336 fi
3337
3338 case "$target:$tm_file" in
3339   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3340     AC_CACHE_CHECK(linker support for omitting dot symbols,
3341     gcc_cv_ld_no_dot_syms,
3342     [gcc_cv_ld_no_dot_syms=no
3343     if test $in_tree_ld = yes ; then
3344       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3345         gcc_cv_ld_no_dot_syms=yes
3346       fi
3347     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3348       cat > conftest1.s <<EOF
3349         .text
3350         bl .foo
3351 EOF
3352       cat > conftest2.s <<EOF
3353         .section ".opd","aw"
3354         .align 3
3355         .globl foo
3356         .type foo,@function
3357 foo:
3358         .quad .LEfoo,.TOC.@tocbase,0
3359         .text
3360 .LEfoo:
3361         blr
3362         .size foo,.-.LEfoo
3363 EOF
3364       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3365          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3366          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3367         gcc_cv_ld_no_dot_syms=yes
3368       fi
3369       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3370     fi
3371     ])
3372     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3373       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3374     [Define if your PowerPC64 linker only needs function descriptor syms.])
3375     fi
3376     ;;
3377 esac
3378
3379 AC_CACHE_CHECK(linker --sysroot support,
3380   gcc_cv_ld_sysroot,
3381   [gcc_cv_ld_sysroot=no
3382   if test $in_tree_ld = yes ; then
3383       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3384         gcc_cv_ld_sysroot=yes
3385       fi
3386   elif test x$gcc_cv_ld != x; then
3387     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3388       gcc_cv_ld_sysroot=yes
3389     fi
3390   fi])
3391 if test x"$gcc_cv_ld_sysroot" = xyes; then
3392   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3393   [Define if your linker supports --sysroot.])
3394 fi
3395
3396 if test x$with_sysroot = x && test x$host = x$target \
3397    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3398    && test "$prefix" != "NONE"; then
3399   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3400 [Define to PREFIX/include if cpp should also search that directory.])
3401 fi
3402
3403 # Test for stack protector support in target C library.
3404 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3405       gcc_cv_libc_provides_ssp,
3406       [gcc_cv_libc_provides_ssp=no
3407     case "$target" in
3408        *-*-linux*)
3409       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3410         if test "x$with_sysroot" = x; then
3411           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3412         elif test "x$with_build_sysroot" != "x"; then
3413           glibc_header_dir="${with_build_sysroot}/usr/include"
3414         elif test "x$with_sysroot" = xyes; then
3415           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3416         else
3417           glibc_header_dir="${with_sysroot}/usr/include"
3418         fi
3419       else
3420         glibc_header_dir=/usr/include
3421       fi
3422       # glibc 2.4 and later provides __stack_chk_fail and
3423       # either __stack_chk_guard, or TLS access to stack guard canary.
3424       if test -f $glibc_header_dir/features.h \
3425          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3426             $glibc_header_dir/features.h > /dev/null; then
3427         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3428            $glibc_header_dir/features.h > /dev/null; then
3429           gcc_cv_libc_provides_ssp=yes
3430         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3431              $glibc_header_dir/features.h > /dev/null \
3432              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3433              $glibc_header_dir/features.h > /dev/null; then
3434           gcc_cv_libc_provides_ssp=yes
3435         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3436              $glibc_header_dir/features.h > /dev/null && \
3437              test -f $glibc_header_dir/bits/uClibc_config.h && \
3438              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3439              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3440           gcc_cv_libc_provides_ssp=yes
3441         fi
3442       fi
3443         ;;
3444        *-*-darwin*)
3445          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3446            [echo "no __stack_chk_fail on this target"])
3447         ;;
3448   *) gcc_cv_libc_provides_ssp=no ;;
3449     esac])
3450
3451 if test x$gcc_cv_libc_provides_ssp = xyes; then
3452   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3453             [Define if your target C library provides stack protector support])
3454 fi
3455
3456 # Check if TFmode long double should be used by default or not.
3457 # Some glibc targets used DFmode long double, but with glibc 2.4
3458 # and later they can use TFmode.
3459 case "$target" in
3460   powerpc*-*-linux* | \
3461   powerpc*-*-gnu* | \
3462   sparc*-*-linux* | \
3463   s390*-*-linux* | \
3464   alpha*-*-linux*)
3465     AC_ARG_WITH(long-double-128,
3466 [  --with-long-double-128  Use 128-bit long double by default.],
3467       gcc_cv_target_ldbl128="$with_long_double_128",
3468       [gcc_cv_target_ldbl128=no
3469       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3470         if test "x$with_sysroot" = x; then
3471           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3472         elif test "x$with_build_sysroot" != "x"; then
3473           glibc_header_dir="${with_build_sysroot}/usr/include"
3474         elif test "x$with_sysroot" = xyes; then
3475           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3476         else
3477           glibc_header_dir="${with_sysroot}/usr/include"
3478         fi
3479       else
3480         glibc_header_dir=/usr/include
3481       fi
3482 changequote(,)dnl
3483       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3484         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3485       && gcc_cv_target_ldbl128=yes
3486 changequote([,])dnl
3487       ])
3488     ;;
3489 esac
3490 if test x$gcc_cv_target_ldbl128 = xyes; then
3491   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3492             [Define if TFmode long double should be the default])
3493 fi
3494
3495 # Find out what GC implementation we want, or may, use.
3496 AC_ARG_WITH(gc,
3497 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3498                           with the compiler],
3499 [case "$withval" in
3500   page)
3501     GGC=ggc-$withval
3502     ;;
3503   zone)
3504     GGC=ggc-$withval
3505     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3506     ;;
3507   *)
3508     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3509     ;;
3510 esac],
3511 [GGC=ggc-page])
3512 AC_SUBST(GGC)
3513 echo "Using $GGC for garbage collection."
3514
3515 # Use the system's zlib library.
3516 zlibdir=-L../zlib
3517 zlibinc="-I\$(srcdir)/../zlib"
3518 AC_ARG_WITH(system-zlib,
3519 [  --with-system-zlib      use installed libz],
3520 zlibdir=
3521 zlibinc=
3522 )
3523 AC_SUBST(zlibdir)
3524 AC_SUBST(zlibinc)
3525
3526 dnl Very limited version of automake's enable-maintainer-mode
3527
3528 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3529   dnl maintainer-mode is disabled by default
3530   AC_ARG_ENABLE(maintainer-mode,
3531 [  --enable-maintainer-mode
3532                           enable make rules and dependencies not useful
3533                           (and sometimes confusing) to the casual installer],
3534       maintainer_mode=$enableval,
3535       maintainer_mode=no)
3536
3537 AC_MSG_RESULT($maintainer_mode)
3538
3539 if test "$maintainer_mode" = "yes"; then
3540   MAINT=''
3541 else
3542   MAINT='#'
3543 fi
3544 AC_SUBST(MAINT)dnl
3545
3546 # --------------
3547 # Language hooks
3548 # --------------
3549
3550 # Make empty files to contain the specs and options for each language.
3551 # Then add #include lines to for a compiler that has specs and/or options.
3552
3553 subdirs=
3554 lang_opt_files=
3555 lang_specs_files=
3556 lang_tree_files=
3557 # These (without "all_") are set in each config-lang.in.
3558 # `language' must be a single word so is spelled singularly.
3559 all_languages=
3560 all_compilers=
3561 all_outputs='Makefile gccbug libada-mk'
3562 # List of language makefile fragments.
3563 all_lang_makefrags=
3564 # List of language subdirectory makefiles.  Deprecated.
3565 all_lang_makefiles=
3566 # Additional files for gengtype
3567 all_gtfiles="$target_gtfiles"
3568
3569 # These are the languages that are set in --enable-languages,
3570 # and are available in the GCC tree.
3571 all_selected_languages=
3572
3573 # Add the language fragments.
3574 # Languages are added via two mechanisms.  Some information must be
3575 # recorded in makefile variables, these are defined in config-lang.in.
3576 # We accumulate them and plug them into the main Makefile.
3577 # The other mechanism is a set of hooks for each of the main targets
3578 # like `clean', `install', etc.
3579
3580 language_hooks="Make-hooks"
3581
3582 for lang in ${srcdir}/*/config-lang.in
3583 do
3584 changequote(,)dnl
3585         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3586
3587         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3588         if test "x$lang_alias" = x
3589         then
3590               echo "$lang doesn't set \$language." 1>&2
3591               exit 1
3592         fi
3593         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3594         subdirs="$subdirs $subdir"
3595
3596         # $gcc_subdir is where the gcc integration files are to be found
3597         # for a language, both for internal compiler purposes (compiler
3598         # sources implementing front-end to GCC tree converters), and for
3599         # build infrastructure purposes (Make-lang.in, etc.)
3600         #
3601         # This will be <subdir> (relative to $srcdir) if a line like
3602         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3603         # is found in <langdir>/config-lang.in, and will remain <langdir>
3604         # otherwise.
3605         #
3606         # Except for the language alias (fetched above), the regular
3607         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3608         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3609         # only this and the language alias.
3610
3611         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3612         if [ "$gcc_subdir" = "" ]; then
3613            gcc_subdir="$subdir"
3614         fi
3615
3616         case ",$enable_languages," in
3617         *,$lang_alias,*)
3618             all_selected_languages="$all_selected_languages $lang_alias"
3619             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3620                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3621             fi
3622             ;;
3623         esac
3624 changequote([,])dnl
3625
3626         language=
3627         boot_language=
3628         compilers=
3629         outputs=
3630         gtfiles=
3631         subdir_requires=
3632         . ${srcdir}/$gcc_subdir/config-lang.in
3633         if test "x$language" = x
3634         then
3635                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3636                 exit 1
3637         fi
3638
3639         ok=:
3640         case ",$enable_languages," in
3641                 *,$lang_alias,*) ;;
3642                 *)
3643                         for i in $subdir_requires; do
3644                                 test -f "${srcdir}/$i/config-lang.in" && continue
3645                                 ok=false
3646                                 break
3647                         done
3648                 ;;
3649         esac
3650         $ok || continue
3651
3652         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3653         if test -f $srcdir/$gcc_subdir/lang.opt; then
3654             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3655         fi
3656         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3657             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3658         fi
3659         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3660                 then all_lang_makefiles="$gcc_subdir/Makefile"
3661         fi
3662         all_languages="$all_languages $language"
3663         all_compilers="$all_compilers $compilers"
3664         all_outputs="$all_outputs $outputs"
3665         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3666 done
3667
3668 # Pick up gtfiles for c
3669 gtfiles=
3670 . ${srcdir}/c-config-lang.in
3671 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3672
3673 check_languages=
3674 for language in $all_selected_languages
3675 do
3676         check_languages="$check_languages check-$language"
3677 done
3678
3679 # We link each language in with a set of hooks, reached indirectly via
3680 # lang.${target}.  Only do so for selected languages.
3681
3682 rm -f Make-hooks
3683 touch Make-hooks
3684 target_list="all.cross start.encap rest.encap tags \
3685         install-common install-man install-info install-pdf dvi pdf \
3686         html uninstall info man srcextra srcman srcinfo \
3687         mostlyclean clean distclean maintainer-clean"
3688
3689 for t in $target_list
3690 do
3691         x=
3692         for lang in $all_selected_languages
3693         do
3694                 x="$x $lang.$t"
3695         done
3696         echo "lang.$t: $x" >> Make-hooks
3697 done
3698
3699 # --------
3700 # UNSORTED
3701 # --------
3702
3703 # Create .gdbinit.
3704
3705 echo "dir ." > .gdbinit
3706 echo "dir ${srcdir}" >> .gdbinit
3707 if test x$gdb_needs_out_file_path = xyes
3708 then
3709         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3710 fi
3711 if test "x$subdirs" != x; then
3712         for s in $subdirs
3713         do
3714                 echo "dir ${srcdir}/$s" >> .gdbinit
3715         done
3716 fi
3717 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3718
3719 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3720 AC_SUBST(gcc_tooldir)
3721 AC_SUBST(dollar)
3722
3723 # Find a directory in which to install a shared libgcc.
3724
3725 AC_ARG_ENABLE(version-specific-runtime-libs,
3726 [  --enable-version-specific-runtime-libs
3727                           specify that runtime libraries should be
3728                           installed in a compiler-specific directory])
3729
3730 AC_ARG_WITH(slibdir,
3731 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3732 slibdir="$with_slibdir",
3733 if test "${enable_version_specific_runtime_libs+set}" = set; then
3734   slibdir='$(libsubdir)'
3735 elif test "$host" != "$target"; then
3736   slibdir='$(build_tooldir)/lib'
3737 else
3738   slibdir='$(libdir)'
3739 fi)
3740 AC_SUBST(slibdir)
3741
3742 AC_ARG_WITH(datarootdir,
3743 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3744 datarootdir="\${prefix}/$with_datarootdir",
3745 datarootdir='$(prefix)/share')
3746 AC_SUBST(datarootdir)
3747
3748 AC_ARG_WITH(docdir,
3749 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3750 docdir="\${prefix}/$with_docdir",
3751 docdir='$(datarootdir)')
3752 AC_SUBST(docdir)
3753
3754 AC_ARG_WITH(htmldir,
3755 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3756 htmldir="\${prefix}/$with_htmldir",
3757 htmldir='$(docdir)')
3758 AC_SUBST(htmldir)
3759
3760 # Substitute configuration variables
3761 AC_SUBST(subdirs)
3762 AC_SUBST(srcdir)
3763 AC_SUBST(all_compilers)
3764 AC_SUBST(all_gtfiles)
3765 AC_SUBST(all_lang_makefrags)
3766 AC_SUBST(all_lang_makefiles)
3767 AC_SUBST(all_languages)
3768 AC_SUBST(all_selected_languages)
3769 AC_SUBST(build_exeext)
3770 AC_SUBST(build_install_headers_dir)
3771 AC_SUBST(build_xm_file_list)
3772 AC_SUBST(build_xm_include_list)
3773 AC_SUBST(build_xm_defines)
3774 AC_SUBST(build_file_translate)
3775 AC_SUBST(check_languages)
3776 AC_SUBST(cpp_install_dir)
3777 AC_SUBST(xmake_file)
3778 AC_SUBST(tmake_file)
3779 AC_SUBST(extra_gcc_objs)
3780 AC_SUBST(extra_headers_list)
3781 AC_SUBST(extra_objs)
3782 AC_SUBST(extra_parts)
3783 AC_SUBST(extra_passes)
3784 AC_SUBST(extra_programs)
3785 AC_SUBST(float_h_file)
3786 AC_SUBST(gcc_config_arguments)
3787 AC_SUBST(gcc_gxx_include_dir)
3788 AC_SUBST(host_exeext)
3789 AC_SUBST(host_xm_file_list)
3790 AC_SUBST(host_xm_include_list)
3791 AC_SUBST(host_xm_defines)
3792 AC_SUBST(out_host_hook_obj)
3793 AC_SUBST(install)
3794 AC_SUBST(lang_opt_files)
3795 AC_SUBST(lang_specs_files)
3796 AC_SUBST(lang_tree_files)
3797 AC_SUBST(local_prefix)
3798 AC_SUBST(md_file)
3799 AC_SUBST(objc_boehm_gc)
3800 AC_SUBST(out_file)
3801 AC_SUBST(out_object_file)
3802 AC_SUBST(thread_file)
3803 AC_SUBST(tm_file_list)
3804 AC_SUBST(tm_include_list)
3805 AC_SUBST(tm_defines)
3806 AC_SUBST(tm_p_file_list)
3807 AC_SUBST(tm_p_include_list)
3808 AC_SUBST(xm_file_list)
3809 AC_SUBST(xm_include_list)
3810 AC_SUBST(xm_defines)
3811 AC_SUBST(c_target_objs)
3812 AC_SUBST(cxx_target_objs)
3813 AC_SUBST(fortran_target_objs)
3814 AC_SUBST(target_cpu_default)
3815
3816 AC_SUBST_FILE(language_hooks)
3817
3818 # Echo link setup.
3819 if test x${build} = x${host} ; then
3820   if test x${host} = x${target} ; then
3821     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3822   else
3823     echo "Links are now set up to build a cross-compiler" 1>&2
3824     echo " from ${host} to ${target}." 1>&2
3825   fi
3826 else
3827   if test x${host} = x${target} ; then
3828     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3829     echo " for ${target}." 1>&2
3830   else
3831     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3832     echo " from ${host} to ${target}." 1>&2
3833   fi
3834 fi
3835
3836 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3837 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3838
3839 # Configure the subdirectories
3840 # AC_CONFIG_SUBDIRS($subdirs)
3841
3842 # Create the Makefile
3843 # and configure language subdirectories
3844 AC_CONFIG_FILES($all_outputs)
3845
3846 AC_CONFIG_COMMANDS([default],
3847 [
3848 case ${CONFIG_HEADERS} in
3849   *auto-host.h:config.in*)
3850   echo > cstamp-h ;;
3851 esac
3852 # Make sure all the subdirs exist.
3853 for d in $subdirs doc build
3854 do
3855     test -d $d || mkdir $d
3856 done
3857 ],
3858 [subdirs='$subdirs'])
3859 AC_OUTPUT