gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997-2016 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 3, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 # --------------------------------
  23 # Initialization and sanity checks
  24 # --------------------------------
  25
  26 AC_PREREQ(2.64)
  27 AC_INIT
  28 AC_CONFIG_SRCDIR(tree.c)
  29 AC_CONFIG_HEADER(auto-host.h:config.in)
  30
  31 gcc_version=`cat $srcdir/BASE-VER`
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical host name, for Ada.
  39 ACX_NONCANONICAL_HOST
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Used for constructing correct paths for offload compilers.
  45 real_target_noncanonical=${target_noncanonical}
  46 accel_dir_suffix=
  47
  48 # Determine the target- and build-specific subdirectories
  49 GCC_TOPLEV_SUBDIRS
  50
  51 # Set program_transform_name
  52 AC_ARG_PROGRAM
  53
  54 # Check for bogus environment variables.
  55 # Test if LIBRARY_PATH contains the notation for the current directory
  56 # since this would lead to problems installing/building glibc.
  57 # LIBRARY_PATH contains the current directory if one of the following
  58 # is true:
  59 # - one of the terminals (":" and ";") is the first or last sign
  60 # - two terminals occur directly after each other
  61 # - the path contains an element with a dot in it
  62 AC_MSG_CHECKING(LIBRARY_PATH variable)
  63 changequote(,)dnl
  64 case ${LIBRARY_PATH} in
  65   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  66     library_path_setting="contains current directory"
  67     ;;
  68   *)
  69     library_path_setting="ok"
  70     ;;
  71 esac
  72 changequote([,])dnl
  73 AC_MSG_RESULT($library_path_setting)
  74 if test "$library_path_setting" != "ok"; then
  75 AC_MSG_ERROR([
  76 *** LIBRARY_PATH shouldn't contain the current directory when
  77 *** building gcc. Please change the environment variable
  78 *** and run configure again.])
  79 fi
  80
  81 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  82 # since this would lead to problems installing/building glibc.
  83 # GCC_EXEC_PREFIX contains the current directory if one of the following
  84 # is true:
  85 # - one of the terminals (":" and ";") is the first or last sign
  86 # - two terminals occur directly after each other
  87 # - the path contains an element with a dot in it
  88 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  89 changequote(,)dnl
  90 case ${GCC_EXEC_PREFIX} in
  91   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  92     gcc_exec_prefix_setting="contains current directory"
  93     ;;
  94   *)
  95     gcc_exec_prefix_setting="ok"
  96     ;;
  97 esac
  98 changequote([,])dnl
  99 AC_MSG_RESULT($gcc_exec_prefix_setting)
 100 if test "$gcc_exec_prefix_setting" != "ok"; then
 101 AC_MSG_ERROR([
 102 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
 103 *** building gcc. Please change the environment variable
 104 *** and run configure again.])
 105 fi
 106
 107 # -----------
 108 # Directories
 109 # -----------
 110
 111 # Specify the local prefix
 112 local_prefix=
 113 AC_ARG_WITH(local-prefix,
 114 [AS_HELP_STRING([--with-local-prefix=DIR],
 115                 [specifies directory to put local include])],
 116 [case "${withval}" in
 117 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 118 no)     ;;
 119 *)      local_prefix=$with_local_prefix ;;
 120 esac])
 121
 122 # Default local prefix if it is empty
 123 if test x$local_prefix = x; then
 124         local_prefix=/usr/local
 125 fi
 126
 127 AC_ARG_WITH([native-system-header-dir],
 128   [  --with-native-system-header-dir=dir
 129                           use dir as the directory to look for standard
 130                           system header files in.  Defaults to /usr/include.],
 131 [
 132  case ${with_native_system_header_dir} in
 133  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 134  /* | [[A-Za-z]]:[[\\/]]*) ;;
 135  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 136  esac
 137  configured_native_system_header_dir="${withval}"
 138 ], [configured_native_system_header_dir=])
 139
 140 AC_ARG_WITH(build-sysroot,
 141   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 142                   [use sysroot as the system root during the build])],
 143   [if test x"$withval" != x ; then
 144      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 145    fi],
 146   [SYSROOT_CFLAGS_FOR_TARGET=])
 147 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 148
 149 if test "x$prefix" = xNONE; then
 150  test_prefix=/usr/local
 151 else
 152  test_prefix=$prefix
 153 fi
 154 if test "x$exec_prefix" = xNONE; then
 155  test_exec_prefix=$test_prefix
 156 else
 157  test_exec_prefix=$exec_prefix
 158 fi
 159
 160 AC_ARG_WITH(sysroot,
 161 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 162                 [search for usr/lib, usr/include, et al, within DIR])],
 163 [
 164  case ${with_sysroot} in
 165  /) ;;
 166  */) with_sysroot=`echo $with_sysroot | sed 's,/$,,'` ;;
 167  esac
 168  case ${with_sysroot} in
 169  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 170  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 171  esac
 172
 173  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 174  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 175
 176  case ${TARGET_SYSTEM_ROOT} in
 177  "${test_prefix}"|"${test_prefix}/"*|\
 178  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 179  '${prefix}'|'${prefix}/'*|\
 180  '${exec_prefix}'|'${exec_prefix}/'*)
 181    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 182    TARGET_SYSTEM_ROOT_DEFINE="$t"
 183    ;;
 184  esac
 185 ], [
 186  TARGET_SYSTEM_ROOT=
 187  TARGET_SYSTEM_ROOT_DEFINE=
 188  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 189 ])
 190 AC_SUBST(TARGET_SYSTEM_ROOT)
 191 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 192 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 193
 194 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 195 # passed in by the toplevel make and thus we'd get different behavior
 196 # depending on where we built the sources.
 197 gcc_gxx_include_dir=
 198 # Specify the g++ header file directory
 199 AC_ARG_WITH(gxx-include-dir,
 200 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 201                 [specifies directory to put g++ header files])],
 202 [case "${withval}" in
 203 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 204 no)     ;;
 205 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 206 esac])
 207
 208 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 209 if test x${gcc_gxx_include_dir} = x; then
 210   if test x${enable_version_specific_runtime_libs} = xyes; then
 211     gcc_gxx_include_dir='${libsubdir}/include/c++'
 212   else
 213     libstdcxx_incdir='include/c++/$(version)'
 214     if test x$host != x$target; then
 215        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 216     fi
 217     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 218   fi
 219 fi
 220
 221 gcc_gxx_include_dir_add_sysroot=0
 222 if test "${with_sysroot+set}" = set; then
 223   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 224   if test "${gcc_gxx_without_sysroot}"; then
 225     if test x${with_sysroot} != x/; then
 226       gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 227     fi
 228     gcc_gxx_include_dir_add_sysroot=1
 229   fi
 230 fi
 231
 232 AC_ARG_WITH(cpp_install_dir,
 233 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 234                 [install the user visible C preprocessor in DIR
 235                  (relative to PREFIX) as well as PREFIX/bin])],
 236 [if test x$withval = xyes; then
 237   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 238 elif test x$withval != xno; then
 239   cpp_install_dir=$withval
 240 fi])
 241
 242 # We would like to our source tree to be readonly.  However when releases or
 243 # pre-releases are generated, the flex/bison generated files as well as the
 244 # various formats of manuals need to be included along with the rest of the
 245 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 246 # just that.
 247
 248 AC_MSG_CHECKING([whether to place generated files in the source directory])
 249   dnl generated-files-in-srcdir is disabled by default
 250   AC_ARG_ENABLE(generated-files-in-srcdir,
 251     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 252                     [put copies of generated files in source dir
 253                      intended for creating source tarballs for users
 254                      without texinfo bison or flex])],
 255       generated_files_in_srcdir=$enableval,
 256       generated_files_in_srcdir=no)
 257
 258 AC_MSG_RESULT($generated_files_in_srcdir)
 259
 260 if test "$generated_files_in_srcdir" = "yes"; then
 261   GENINSRC=''
 262 else
 263   GENINSRC='#'
 264 fi
 265 AC_SUBST(GENINSRC)
 266
 267 # -------------------
 268 # Find default linker
 269 # -------------------
 270
 271 # With GNU ld
 272 AC_ARG_WITH(gnu-ld,
 273 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 274 gnu_ld_flag="$with_gnu_ld",
 275 gnu_ld_flag=no)
 276
 277 case $target in
 278     *darwin*) ld64_flag=yes;; # Darwin can only use a ld64-compatible linker.
 279     *) ld64_flag=no;;
 280 esac
 281
 282 # With pre-defined ld
 283 AC_ARG_WITH(ld,
 284 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 285 DEFAULT_LINKER="$with_ld")
 286 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 287   if test ! -x "$DEFAULT_LINKER"; then
 288     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 289   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 290     gnu_ld_flag=yes
 291   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep ld64- > /dev/null; then
 292     ld64_flag=yes
 293   fi
 294   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 295         [Define to enable the use of a default linker.])
 296 fi
 297
 298 AC_MSG_CHECKING([whether a default linker was specified])
 299 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 300   if test x"$gnu_ld_flag" = x"no"; then
 301     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 302   else
 303     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 304   fi
 305 else
 306   AC_MSG_RESULT(no)
 307 fi
 308
 309 # With demangler in GNU ld
 310 AC_ARG_WITH(demangler-in-ld,
 311 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 312 demangler_in_ld="$with_demangler_in_ld",
 313 demangler_in_ld=yes)
 314
 315 # ----------------------
 316 # Find default assembler
 317 # ----------------------
 318
 319 # With GNU as
 320 AC_ARG_WITH(gnu-as,
 321 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 322 gas_flag="$with_gnu_as",
 323 gas_flag=no)
 324
 325 AC_ARG_WITH(as,
 326 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 327 DEFAULT_ASSEMBLER="$with_as")
 328 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 329   if test ! -x "$DEFAULT_ASSEMBLER"; then
 330     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 331   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 332     gas_flag=yes
 333   fi
 334   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 335         [Define to enable the use of a default assembler.])
 336 fi
 337
 338 AC_MSG_CHECKING([whether a default assembler was specified])
 339 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 340   if test x"$gas_flag" = x"no"; then
 341     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 342   else
 343     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 344   fi
 345 else
 346   AC_MSG_RESULT(no)
 347 fi
 348
 349 # ---------------
 350 # Find C compiler
 351 # ---------------
 352
 353 # If a non-executable a.out is present (e.g. created by GNU as above even if
 354 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 355 # file, even when creating an executable, so an execution test fails.
 356 # Remove possible default executable files to avoid this.
 357 #
 358 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 359 # Autoconf includes it.
 360 rm -f a.out a.exe b.out
 361
 362 # Find the native compiler
 363 AC_PROG_CC
 364 AC_PROG_CXX
 365 ACX_PROG_GNAT([-I"$srcdir"/ada])
 366
 367 # Do configure tests with the C++ compiler, since that's what we build with.
 368 AC_LANG(C++)
 369
 370 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 371 # optimizations to be activated explicitly by the toplevel.
 372 case "$CC" in
 373   */prev-gcc/xgcc*) ;;
 374   *) CFLAGS=`echo "$CFLAGS " | sed -e "s/-Ofast[[       ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" `
 375      CXXFLAGS=`echo "$CXXFLAGS " | sed -e "s/-Ofast[[   ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" ` ;;
 376 esac
 377 AC_SUBST(CFLAGS)
 378 AC_SUBST(CXXFLAGS)
 379
 380 # Determine PICFLAG for target gnatlib.
 381 GCC_PICFLAG_FOR_TARGET
 382 AC_SUBST(PICFLAG_FOR_TARGET)
 383
 384 # -------------------------
 385 # Check C compiler features
 386 # -------------------------
 387
 388 AC_USE_SYSTEM_EXTENSIONS
 389 AC_PROG_CPP
 390 AC_C_INLINE
 391
 392 AC_SYS_LARGEFILE
 393
 394 # sizeof(char) is 1 by definition.
 395 AC_CHECK_SIZEOF(void *)
 396 AC_CHECK_SIZEOF(short)
 397 AC_CHECK_SIZEOF(int)
 398 AC_CHECK_SIZEOF(long)
 399 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 400 GCC_STDINT_TYPES
 401 if test x"$ac_cv_c_uint64_t" = x"no" -o x"$ac_cv_c_int64_t" = x"no"; then
 402   AC_MSG_ERROR([uint64_t or int64_t not found])
 403 fi
 404
 405 # check what underlying integer type int64_t uses
 406 AC_CACHE_CHECK(for int64_t underlying type, ac_cv_int64_t_type, [
 407 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 408 #ifdef HAVE_STDINT_H
 409 #include <stdint.h>
 410 #endif
 411 template <typename T> struct X { };
 412 template <>
 413 struct X<long> { typedef long t; };
 414 ]], [[X<int64_t>::t x;]])],[ac_cv_int64_t_type=long],[ac_cv_int64_t_type="long long"])])
 415 if test "$ac_cv_int64_t_type" = "long"; then
 416   AC_DEFINE(INT64_T_IS_LONG, 1,
 417   [Define if int64_t uses long as underlying type.])
 418 else
 419 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 420 #ifdef HAVE_STDINT_H
 421 #include <stdint.h>
 422 #endif
 423 template <typename T> struct X { };
 424 template <>
 425 struct X<long long> { typedef long long t; };
 426 ]], [[X<int64_t>::t x;]])],[],[AC_MSG_ERROR([error verifying int64_t uses long long])])
 427 fi
 428
 429 AC_CACHE_CHECK(for std::swap in <utility>, ac_cv_std_swap_in_utility, [
 430 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 431 #include <utility>
 432 ]], [[int a, b; std::swap(a,b);]])],[ac_cv_std_swap_in_utility=yes],[ac_cv_std_swap_in_utility=no])])
 433 if test $ac_cv_std_swap_in_utility = yes; then
 434   AC_DEFINE(HAVE_SWAP_IN_UTILITY, 1,
 435   [Define if <utility> defines std::swap.])
 436 fi
 437
 438 # Check whether compiler is affected by placement new aliasing bug (PR 29286).
 439 # If the host compiler is affected by the bug, and we build with optimization
 440 # enabled (which happens e.g. when cross-compiling), the pool allocator may
 441 # get miscompiled.  Use -fno-strict-aliasing to work around this problem.
 442 # Since there is no reliable feature check for the presence of this bug,
 443 # we simply use a GCC version number check.  (This should never trigger for
 444 # stages 2 or 3 of a native bootstrap.)
 445 aliasing_flags=
 446 if test "$GCC" = yes; then
 447   saved_CXXFLAGS="$CXXFLAGS"
 448
 449   # The following test compilation will succeed if and only if $CXX accepts
 450   # -fno-strict-aliasing *and* is older than GCC 4.3.
 451   CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 452   AC_MSG_CHECKING([whether $CXX is affected by placement new aliasing bug])
 453   AC_COMPILE_IFELSE([
 454 #if (__GNUC__ > 4) || (__GNUC__ == 4 && __GNUC_MINOR__ >= 3)
 455 #error compiler not affected by placement new aliasing bug
 456 #endif
 457 ],
 458     [AC_MSG_RESULT([yes]); aliasing_flags='-fno-strict-aliasing'],
 459     [AC_MSG_RESULT([no])])
 460
 461   CXXFLAGS="$saved_CXXFLAGS"
 462 fi
 463 AC_SUBST(aliasing_flags)
 464
 465
 466
 467 # ---------------------
 468 # Warnings and checking
 469 # ---------------------
 470
 471 # Check $CC warning features (if it's GCC).
 472 # We want to use -pedantic, but we don't want warnings about
 473 # * 'long long'
 474 # * variadic macros
 475 # * overlong strings
 476 # * C++11 narrowing conversions in { }
 477 # So, we only use -pedantic if we can disable those warnings.
 478
 479 # In stage 1, disable -Wformat warnings from old GCCs about new % codes
 480 AC_ARG_ENABLE(build-format-warnings,
 481   AS_HELP_STRING([--disable-build-format-warnings],[don't use -Wformat while building GCC]),
 482   [],[enable_build_format_warnings=yes])
 483 AS_IF([test $enable_build_format_warnings = no],
 484       [wf_opt=-Wno-format],[wf_opt=])
 485 ACX_PROG_CXX_WARNING_OPTS(
 486         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings ],
 487                        [-Wcast-qual $wf_opt])), [loose_warn])
 488 ACX_PROG_CC_WARNING_OPTS(
 489         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 490         [c_loose_warn])
 491 ACX_PROG_CXX_WARNING_OPTS(
 492         m4_quote(m4_do([-Wmissing-format-attribute ],
 493                        [-Woverloaded-virtual])), [strict_warn])
 494 ACX_PROG_CC_WARNING_OPTS(
 495         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 496 ACX_PROG_CXX_WARNING_ALMOST_PEDANTIC(
 497         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 498                        [-Wno-overlength-strings])), [strict_warn])
 499 ACX_PROG_CXX_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 500
 501 # The above macros do nothing if the compiler is not GCC.  However, the
 502 # Makefile has more goo to add other flags, so these variables are used
 503 # to enable warnings only for GCC.
 504 warn_cflags=
 505 warn_cxxflags=
 506 if test "x$GCC" = "xyes"; then
 507   warn_cflags='$(GCC_WARN_CFLAGS)'
 508   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 509 fi
 510 AC_SUBST(warn_cflags)
 511 AC_SUBST(warn_cxxflags)
 512
 513 # Disable exceptions and RTTI if building with g++
 514 ACX_PROG_CC_WARNING_OPTS(
 515         m4_quote(m4_do([-fno-exceptions -fno-rtti -fasynchronous-unwind-tables])),
 516                        [noexception_flags])
 517
 518 # Enable expensive internal checks
 519 is_release=
 520 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 521   is_release=yes
 522 fi
 523
 524 AC_ARG_ENABLE(checking,
 525 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 526                 [enable expensive run-time checks.  With LIST,
 527                  enable only specific categories of checks.
 528                  Categories are: yes,no,all,none,release.
 529                  Flags are: assert,df,extra,fold,gc,gcac,gimple,misc,
 530                  rtlflag,rtl,runtime,tree,valgrind,types])],
 531 [ac_checking_flags="${enableval}"],[
 532 # Determine the default checks.
 533 if test x$is_release = x ; then
 534   ac_checking_flags=yes,extra
 535 else
 536   ac_checking_flags=release
 537 fi])
 538 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 539 for check in release $ac_checking_flags
 540 do
 541         case $check in
 542         # these set all the flags to specific states
 543         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 544                         ac_fold_checking= ; ac_gc_checking=1 ; ac_extra_checking= ;
 545                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 546                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 547                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 548                         ac_types_checking=1 ;;
 549         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 550                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 551                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 552                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 553                         ac_tree_checking= ; ac_valgrind_checking= ;
 554                         ac_types_checking= ;;
 555         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 556                         ac_fold_checking=1 ; ac_gc_checking=1 ; ac_extra_checking=1 ;
 557                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 558                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 559                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 560                         ac_types_checking=1 ;;
 561         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 562                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 563                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 564                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 565                         ac_tree_checking= ; ac_valgrind_checking= ;
 566                         ac_types_checking= ;;
 567         # these enable particular checks
 568         assert)         ac_assert_checking=1 ;;
 569         df)             ac_df_checking=1 ;;
 570         extra)          ac_extra_checking=1 ;;
 571         fold)           ac_fold_checking=1 ;;
 572         gc)             ac_gc_checking=1 ;;
 573         gcac)           ac_gc_always_collect=1 ;;
 574         gimple)         ac_gimple_checking=1 ;;
 575         misc)           ac_checking=1 ;;
 576         rtl)            ac_rtl_checking=1 ;;
 577         rtlflag)        ac_rtlflag_checking=1 ;;
 578         runtime)        ac_runtime_checking=1 ;;
 579         tree)           ac_tree_checking=1 ;;
 580         types)          ac_types_checking=1 ;;
 581         valgrind)       ac_valgrind_checking=1 ;;
 582         *)      AC_MSG_ERROR(unknown check category $check) ;;
 583         esac
 584 done
 585 IFS="$ac_save_IFS"
 586
 587 nocommon_flag=""
 588 if test x$ac_checking != x ; then
 589   AC_DEFINE(CHECKING_P, 1,
 590 [Define to 0/1 if you want more run-time sanity checks.  This one gets a grab
 591 bag of miscellaneous but relatively cheap checks.])
 592   nocommon_flag=-fno-common
 593 else
 594   AC_DEFINE(CHECKING_P, 0)
 595 fi
 596 AC_SUBST(nocommon_flag)
 597 if test x$ac_extra_checking != x ; then
 598   AC_DEFINE(ENABLE_EXTRA_CHECKING, 1,
 599 [Define to 0/1 if you want extra run-time checking that might affect code
 600 generation.])
 601 else
 602   AC_DEFINE(ENABLE_EXTRA_CHECKING, 0)
 603 fi
 604 if test x$ac_df_checking != x ; then
 605   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 606 [Define if you want more run-time sanity checks for dataflow.])
 607 fi
 608 if test x$ac_assert_checking != x ; then
 609   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 610 [Define if you want assertions enabled.  This is a cheap check.])
 611 fi
 612 if test x$ac_gimple_checking != x ; then
 613   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 614 [Define if you want operations on GIMPLE (the basic data structure of
 615 the high-level optimizers) to be checked for dynamic type safety at
 616 runtime.  This is moderately expensive.])
 617 fi
 618 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 619 if test x$ac_runtime_checking != x ; then
 620   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 621 [Define if you want runtime assertions enabled.  This is a cheap check.])
 622 fi
 623 if test x$ac_tree_checking != x ; then
 624   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 625 [Define if you want all operations on trees (the basic data
 626    structure of the front ends) to be checked for dynamic type safety
 627    at runtime.  This is moderately expensive.
 628    ])
 629   TREECHECKING=yes
 630 fi
 631 if test x$ac_types_checking != x ; then
 632   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 633 [Define if you want all gimple types to be verified after gimplifiation.
 634    This is cheap.
 635    ])
 636 fi
 637 AC_SUBST(TREECHECKING)
 638 if test x$ac_rtl_checking != x ; then
 639   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 640 [Define if you want all operations on RTL (the basic data structure
 641    of the optimizer and back end) to be checked for dynamic type safety
 642    at runtime.  This is quite expensive.])
 643 fi
 644 if test x$ac_rtlflag_checking != x ; then
 645   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 646 [Define if you want RTL flag accesses to be checked against the RTL
 647    codes that are supported for each access macro.  This is relatively
 648    cheap.])
 649 fi
 650 if test x$ac_gc_checking != x ; then
 651   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 652 [Define if you want the garbage collector to do object poisoning and
 653    other memory allocation checks.  This is quite expensive.])
 654 fi
 655 if test x$ac_gc_always_collect != x ; then
 656   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 657 [Define if you want the garbage collector to operate in maximally
 658    paranoid mode, validating the entire heap and collecting garbage at
 659    every opportunity.  This is extremely expensive.])
 660 fi
 661 if test x$ac_fold_checking != x ; then
 662   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 663 [Define if you want fold checked that it never destructs its argument.
 664    This is quite expensive.])
 665 fi
 666 valgrind_path_defines=
 667 valgrind_command=
 668
 669 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 670 dnl # an if statement.  This was the source of very frustrating bugs
 671 dnl # in converting to autoconf 2.5x!
 672 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 673
 674 # It is certainly possible that there's valgrind but no valgrind.h.
 675 # GCC relies on making annotations so we must have both.
 676 AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 677 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 678   [[#include <valgrind/memcheck.h>
 679 #ifndef VALGRIND_DISCARD
 680 #error VALGRIND_DISCARD not defined
 681 #endif]])],
 682   [gcc_cv_header_valgrind_memcheck_h=yes],
 683   [gcc_cv_header_valgrind_memcheck_h=no])
 684 AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 685 AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 686 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 687   [[#include <memcheck.h>
 688 #ifndef VALGRIND_DISCARD
 689 #error VALGRIND_DISCARD not defined
 690 #endif]])],
 691   [gcc_cv_header_memcheck_h=yes],
 692   [gcc_cv_header_memcheck_h=no])
 693 AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 694 if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 695   AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 696         [Define if valgrind's valgrind/memcheck.h header is installed.])
 697 fi
 698 if test $gcc_cv_header_memcheck_h = yes; then
 699   AC_DEFINE(HAVE_MEMCHECK_H, 1,
 700         [Define if valgrind's memcheck.h header is installed.])
 701 fi
 702
 703 if test x$ac_valgrind_checking != x ; then
 704   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 705         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 706   if test "x$valgrind_path" = "x" \
 707     || (test $have_valgrind_h = no \
 708         && test $gcc_cv_header_memcheck_h = no \
 709         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 710         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 711   fi
 712   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 713   valgrind_command="$valgrind_path -q"
 714   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 715 [Define if you want to run subprograms and generated programs
 716    through valgrind (a memory checker).  This is extremely expensive.])
 717 fi
 718 AC_SUBST(valgrind_path_defines)
 719 AC_SUBST(valgrind_command)
 720
 721 # Enable code coverage collection
 722 AC_ARG_ENABLE(coverage,
 723 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 724                 [enable compiler's code coverage collection.
 725                  Use to measure compiler performance and locate
 726                  unused parts of the compiler. With LEVEL, specify
 727                  optimization. Values are opt, noopt,
 728                  default is noopt])],
 729 [case "${enableval}" in
 730   yes|noopt)
 731     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 732     ;;
 733   opt)
 734     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 735     ;;
 736   no)
 737     # a.k.a. --disable-coverage
 738     coverage_flags=""
 739     ;;
 740   *)
 741     AC_MSG_ERROR(unknown coverage setting $enableval)
 742     ;;
 743 esac],
 744 [coverage_flags=""])
 745 AC_SUBST(coverage_flags)
 746
 747 AC_ARG_ENABLE(gather-detailed-mem-stats,
 748 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 749                 [enable detailed memory allocation stats gathering])], [],
 750 [enable_gather_detailed_mem_stats=no])
 751 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 752 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 753 [Define to enable detailed memory allocation stats gathering.])
 754
 755 AC_ARG_ENABLE(valgrind-annotations,
 756 [AS_HELP_STRING([--enable-valgrind-annotations],
 757                 [enable valgrind runtime interaction])], [],
 758 [enable_valgrind_annotations=no])
 759 if test x$enable_valgrind_annotations != xno \
 760     || test x$ac_valgrind_checking != x; then
 761   if (test $have_valgrind_h = no \
 762       && test $gcc_cv_header_memcheck_h = no \
 763       && test $gcc_cv_header_valgrind_memcheck_h = no); then
 764     AC_MSG_ERROR([*** Can't find valgrind/memcheck.h, memcheck.h or valgrind.h])
 765   fi
 766   AC_DEFINE(ENABLE_VALGRIND_ANNOTATIONS, 1,
 767 [Define to get calls to the valgrind runtime enabled.])
 768 fi
 769
 770 # -------------------------------
 771 # Miscenalleous configure options
 772 # -------------------------------
 773
 774 # With stabs
 775 AC_ARG_WITH(stabs,
 776 [AS_HELP_STRING([--with-stabs],
 777                 [arrange to use stabs instead of host debug format])],
 778 stabs="$with_stabs",
 779 stabs=no)
 780
 781 # Determine whether or not multilibs are enabled.
 782 AC_ARG_ENABLE(multilib,
 783 [AS_HELP_STRING([--enable-multilib],
 784                 [enable library support for multiple ABIs])],
 785 [], [enable_multilib=yes])
 786 AC_SUBST(enable_multilib)
 787
 788 # Determine whether or not multiarch is enabled.
 789 AC_ARG_ENABLE(multiarch,
 790 [AS_HELP_STRING([--enable-multiarch],
 791                 [enable support for multiarch paths])],
 792 [case "${enableval}" in
 793 yes|no|auto) enable_multiarch=$enableval;;
 794 *) AC_MSG_ERROR(bad value ${enableval} given for --enable-multiarch option) ;;
 795 esac], [enable_multiarch=auto])
 796 if test x${enable_multiarch} = xauto; then
 797   if test x${with_native_system_header_dir} != x; then
 798     ma_msg_suffix=", disabled auto check (configured with --native-system-header-dir)"
 799     enable_multiarch=no
 800   fi
 801   if test x$host != x$target && test "x$with_sysroot" = x; then
 802     ma_msg_suffix=", disabled auto check (cross build configured without --with-sysroot)"
 803     enable_multiarch=no
 804   fi
 805 fi
 806 AC_MSG_CHECKING(for multiarch configuration)
 807 AC_SUBST(enable_multiarch)
 808 AC_MSG_RESULT($enable_multiarch$ma_msg_suffix)
 809
 810 # needed for setting the multiarch name for soft-float/hard-float ABIs
 811 AC_SUBST(with_cpu)
 812 AC_SUBST(with_float)
 813
 814 # Enable __cxa_atexit for C++.
 815 AC_ARG_ENABLE(__cxa_atexit,
 816 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 817 [], [])
 818
 819 # Enable C extension for decimal float if target supports it.
 820 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 821
 822 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 823 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 824 [Define to 1 to enable decimal float extension to C.])
 825
 826 # Use default_decimal_float for dependency.
 827 enable_decimal_float=$default_decimal_float
 828
 829 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 830 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 831 [Define to 1 to specify that we are using the BID decimal floating
 832 point format instead of DPD])
 833
 834 # Enable C extension for fixed-point arithmetic.
 835 AC_ARG_ENABLE(fixed-point,
 836 [AS_HELP_STRING([--enable-fixed-point],
 837                 [enable fixed-point arithmetic extension to C])],
 838 [],
 839 [
 840   case $target in
 841     arm*)
 842       enable_fixed_point=yes
 843       ;;
 844
 845     mips*-*-*)
 846       enable_fixed_point=yes
 847       ;;
 848     *)
 849       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 850       enable_fixed_point=no
 851       ;;
 852   esac
 853 ])
 854 AC_SUBST(enable_fixed_point)
 855
 856 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 857 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 858 [Define to 1 to enable fixed-point arithmetic extension to C.])
 859
 860 # Enable threads
 861 # Pass with no value to take the default
 862 # Pass with a value to specify a thread package
 863 AC_ARG_ENABLE(threads,
 864 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 865                 [enable thread usage for target GCC,
 866                  using LIB thread package])],,
 867 [enable_threads=''])
 868
 869 AC_ARG_ENABLE(tls,
 870 [AS_HELP_STRING([--enable-tls],
 871                 [enable or disable generation of tls code
 872                  overriding the assembler check for tls support])],
 873 [
 874   case $enable_tls in
 875     yes | no) ;;
 876     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 877 Valid choices are 'yes' and 'no'.]) ;;
 878   esac
 879 ], [enable_tls=''])
 880
 881 AC_ARG_ENABLE(vtable-verify,
 882 [AS_HELP_STRING([--enable-vtable-verify],
 883                 [enable vtable verification feature])],,
 884 [enable_vtable_verify=no])
 885 vtable_verify=`if test x$enable_vtable_verify = xyes; then echo 1; else echo 0; fi`
 886 AC_DEFINE_UNQUOTED(ENABLE_VTABLE_VERIFY, $vtable_verify,
 887 [Define 0/1 if vtable verification feature is enabled.])
 888
 889 AC_ARG_ENABLE(objc-gc,
 890 [AS_HELP_STRING([--enable-objc-gc],
 891                 [enable the use of Boehm's garbage collector with
 892                  the GNU Objective-C runtime])],
 893 if test x$enable_objc_gc = xno; then
 894         objc_boehm_gc=''
 895 else
 896         objc_boehm_gc=1
 897 fi,
 898 objc_boehm_gc='')
 899
 900 AC_ARG_WITH(dwarf2,
 901 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 902 dwarf2="$with_dwarf2",
 903 dwarf2=no)
 904
 905 AC_ARG_ENABLE(shared,
 906 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 907 [
 908   case $enable_shared in
 909   yes | no) ;;
 910   *)
 911     enable_shared=no
 912     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 913     for pkg in $enableval; do
 914       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 915         enable_shared=yes
 916       fi
 917     done
 918     IFS="$ac_save_ifs"
 919     ;;
 920   esac
 921 ], [enable_shared=yes])
 922 AC_SUBST(enable_shared)
 923
 924 AC_ARG_WITH(specs,
 925   [AS_HELP_STRING([--with-specs=SPECS],
 926                   [add SPECS to driver command-line processing])],
 927   [CONFIGURE_SPECS=$withval],
 928   [CONFIGURE_SPECS=]
 929 )
 930 AC_SUBST(CONFIGURE_SPECS)
 931
 932 ACX_PKGVERSION([GCC])
 933 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 934
 935 # Sanity check enable_languages in case someone does not run the toplevel
 936 # configure # script.
 937 AC_ARG_ENABLE(languages,
 938 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 939 [case ,${enable_languages}, in
 940        ,,|,yes,)
 941                 # go safe -- we cannot be much sure without the toplevel
 942                 # configure's
 943                 # analysis of which target libs are present and usable
 944                 enable_languages=c
 945                 ;;
 946          *,all,*)
 947                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 948                 ;;
 949         *,c,*)
 950                 ;;
 951         *)
 952                 enable_languages=c,${enable_languages}
 953                 ;;
 954 esac],
 955 [enable_languages=c])
 956
 957 if test x"$enable_as_accelerator_for" != x; then
 958   AC_DEFINE(ACCEL_COMPILER, 1,
 959     [Define if this compiler should be built as the offload target compiler.])
 960   enable_as_accelerator=yes
 961   case "${target}" in
 962     *-intelmicemul-*)
 963       # In this case we expect offload compiler to be built as native, so we
 964       # need to rename the driver to avoid clashes with host's drivers.
 965       program_transform_name="s&^&${target}-&" ;;
 966   esac
 967   sedscript="s#${target_noncanonical}#${enable_as_accelerator_for}-accel-${target_noncanonical}#"
 968   program_transform_name=`echo $program_transform_name | sed $sedscript`
 969   accel_dir_suffix=/accel/${target_noncanonical}
 970   real_target_noncanonical=${enable_as_accelerator_for}
 971 fi
 972 AC_SUBST(enable_as_accelerator)
 973 AC_SUBST(real_target_noncanonical)
 974 AC_SUBST(accel_dir_suffix)
 975
 976 for tgt in `echo $enable_offload_targets | sed 's/,/ /g'`; do
 977   tgt=`echo $tgt | sed 's/=.*//'`
 978
 979   if echo "$tgt" | grep "^hsa" > /dev/null ; then
 980     enable_hsa=1
 981   else
 982     enable_offloading=1
 983   fi
 984
 985   if test x"$offload_targets" = x; then
 986     offload_targets=$tgt
 987   else
 988     offload_targets="$offload_targets,$tgt"
 989   fi
 990 done
 991 AC_DEFINE_UNQUOTED(OFFLOAD_TARGETS, "$offload_targets",
 992   [Define to offload targets, separated by commas.])
 993 if test x"$enable_offloading" != x; then
 994   AC_DEFINE(ENABLE_OFFLOADING, 1,
 995     [Define this to enable support for offloading.])
 996 else
 997   AC_DEFINE(ENABLE_OFFLOADING, 0,
 998     [Define this to enable support for offloading.])
 999 fi
1000
1001 if test x"$enable_hsa" = x1 ; then
1002   AC_DEFINE(ENABLE_HSA, 1,
1003     [Define this to enable support for generating HSAIL.])
1004 fi
1005
1006 AC_ARG_WITH(multilib-list,
1007 [AS_HELP_STRING([--with-multilib-list], [select multilibs (AArch64, SH and x86-64 only)])],
1008 :,
1009 with_multilib_list=default)
1010
1011 # -------------------------
1012 # Checks for other programs
1013 # -------------------------
1014
1015 AC_PROG_MAKE_SET
1016
1017 # Find some useful tools
1018 AC_PROG_AWK
1019 # We need awk to create options.c and options.h.
1020 # Bail out if it's missing.
1021 case ${AWK} in
1022   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
1023 esac
1024
1025 gcc_AC_PROG_LN_S
1026 ACX_PROG_LN($LN_S)
1027 AC_PROG_RANLIB
1028 ranlib_flags=""
1029 AC_SUBST(ranlib_flags)
1030
1031 gcc_AC_PROG_INSTALL
1032
1033 # See if cmp has --ignore-initial.
1034 gcc_AC_PROG_CMP_IGNORE_INITIAL
1035
1036 # See if we have the mktemp command.
1037 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
1038
1039 # See if makeinfo has been installed and is modern enough
1040 # that we can use it.
1041 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1042   [GNU texinfo.* \([0-9][0-9.]*\)],
1043   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
1044 if test $gcc_cv_prog_makeinfo_modern = no; then
1045   AC_MSG_WARN([
1046 *** Makeinfo is missing or too old.
1047 *** Info documentation will not be built.])
1048   BUILD_INFO=
1049 else
1050   BUILD_INFO=info
1051 fi
1052 AC_SUBST(BUILD_INFO)
1053
1054 # Is pod2man recent enough to regenerate manpages?
1055 AC_MSG_CHECKING([for recent Pod::Man])
1056 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
1057   AC_MSG_RESULT(yes)
1058   GENERATED_MANPAGES=generated-manpages
1059 else
1060   AC_MSG_RESULT(no)
1061   GENERATED_MANPAGES=
1062 fi
1063 AC_SUBST(GENERATED_MANPAGES)
1064
1065 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
1066
1067 # How about lex?
1068 dnl Don't use AC_PROG_LEX; we insist on flex.
1069 dnl LEXLIB is not useful in gcc.
1070 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
1071
1072 # Bison?
1073 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
1074
1075 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
1076 # check for build == host before using them.
1077
1078 # NM
1079 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
1080   && test -d ../binutils ; then
1081   NM='${objdir}/../binutils/nm-new'
1082 else
1083   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
1084 fi
1085
1086 # AR
1087 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
1088   && test -d ../binutils ; then
1089   AR='${objdir}/../binutils/ar'
1090 else
1091   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
1092 fi
1093
1094 # The jit documentation looks better if built with sphinx, but can be
1095 # built with texinfo if sphinx is not available.
1096 # Set "doc_build_sys" to "sphinx" or "texinfo" accordingly.
1097 AC_CHECK_PROG(doc_build_sys, sphinx-build, sphinx, texinfo)
1098
1099 # --------------------
1100 # Checks for C headers
1101 # --------------------
1102
1103 # Need to reject headers which give warnings, so that the -Werror bootstrap
1104 # works later. *sigh*  This needs to come before all header checks.
1105 AC_PROG_CPP_WERROR
1106
1107 AC_HEADER_STDC
1108 AC_HEADER_TIME
1109 ACX_HEADER_STRING
1110 AC_HEADER_SYS_WAIT
1111 AC_HEADER_TIOCGWINSZ
1112 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
1113                  fcntl.h ftw.h unistd.h sys/file.h sys/time.h sys/mman.h \
1114                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
1115                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
1116
1117 # Check for thread headers.
1118 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
1119 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
1120
1121 # These tests can't be done till we know if we have limits.h.
1122 gcc_AC_C_CHAR_BIT
1123 AC_C_BIGENDIAN
1124
1125 # ----------------------
1126 # Checks for C++ headers
1127 # ----------------------
1128
1129 dnl Autoconf will give an error in the configure script if there is no
1130 dnl C++ preprocessor.  Hack to prevent that.
1131 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
1132 AC_PROG_CXXCPP
1133 m4_popdef([AC_MSG_ERROR])[]dnl
1134
1135 AC_CHECK_HEADERS(unordered_map)
1136 AC_CHECK_HEADERS(tr1/unordered_map)
1137 AC_CHECK_HEADERS(ext/hash_map)
1138
1139 # --------
1140 # Dependency checking.
1141 # --------
1142
1143 ZW_CREATE_DEPDIR
1144 AC_CONFIG_COMMANDS([gccdepdir],[
1145   ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs build/$DEPDIR
1146   for lang in $subdirs c-family common
1147   do
1148       ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs $lang/$DEPDIR
1149   done], [subdirs="$subdirs" ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR])
1150
1151 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
1152
1153 # --------
1154 # UNSORTED
1155 # --------
1156
1157
1158 # These libraries may be used by collect2.
1159 # We may need a special search path to get them linked.
1160 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
1161 [save_LIBS="$LIBS"
1162 for libs in '' -lld -lmld \
1163                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1164                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1165 do
1166         LIBS="$libs"
1167         AC_TRY_LINK_FUNC(ldopen,
1168                 [gcc_cv_collect2_libs="$libs"; break])
1169 done
1170 LIBS="$save_LIBS"
1171 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1172 case $gcc_cv_collect2_libs in
1173         "none required")        ;;
1174         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1175 esac
1176 AC_SUBST(COLLECT2_LIBS)
1177
1178 # When building Ada code on Alpha, we need exc_resume which is usually in
1179 # -lexc.  So test for it.
1180 save_LIBS="$LIBS"
1181 LIBS=
1182 AC_SEARCH_LIBS(exc_resume, exc)
1183 GNAT_LIBEXC="$LIBS"
1184 LIBS="$save_LIBS"
1185 AC_SUBST(GNAT_LIBEXC)
1186
1187 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
1188 save_LIBS="$LIBS"
1189 LIBS=
1190 AC_SEARCH_LIBS(kstat_open, kstat)
1191 EXTRA_GCC_LIBS="$LIBS"
1192 LIBS="$save_LIBS"
1193 AC_SUBST(EXTRA_GCC_LIBS)
1194
1195 # Some systems put ldexp and frexp in libm instead of libc; assume
1196 # they're both in the same place.  jcf-dump needs them.
1197 save_LIBS="$LIBS"
1198 LIBS=
1199 AC_SEARCH_LIBS(ldexp, m)
1200 LDEXP_LIB="$LIBS"
1201 LIBS="$save_LIBS"
1202 AC_SUBST(LDEXP_LIB)
1203
1204 # Use <inttypes.h> only if it exists,
1205 # doesn't clash with <sys/types.h>, declares intmax_t and defines
1206 # PRId64
1207 AC_MSG_CHECKING(for inttypes.h)
1208 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1209 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1210 [[#define __STDC_FORMAT_MACROS
1211 #include <sys/types.h>
1212 #include <inttypes.h>]],
1213   [[intmax_t i = -1;
1214 #ifndef PRId64
1215 choke me
1216 #endif]])],
1217   [gcc_cv_header_inttypes_h=yes],
1218   [gcc_cv_header_inttypes_h=no])])
1219 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1220 if test $gcc_cv_header_inttypes_h = yes; then
1221   AC_DEFINE(HAVE_INTTYPES_H, 1,
1222         [Define if you have a working <inttypes.h> header file.])
1223 fi
1224
1225 dnl Disabled until we have a complete test for buggy enum bitfields.
1226 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1227
1228 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1229   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1230   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1231   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1232   putchar_unlocked putc_unlocked)
1233 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoq \
1234         popen sysconf strsignal getrusage nl_langinfo \
1235         gettimeofday mbstowcs wcswidth mmap setlocale \
1236         gcc_UNLOCKED_FUNCS madvise)
1237
1238 if test x$ac_cv_func_mbstowcs = xyes; then
1239   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1240 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1241 int main()
1242 {
1243   mbstowcs(0, "", 0);
1244   return 0;
1245 }]])],
1246     [gcc_cv_func_mbstowcs_works=yes],
1247     [gcc_cv_func_mbstowcs_works=no],
1248     [gcc_cv_func_mbstowcs_works=yes])])
1249   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1250     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1251   [Define this macro if mbstowcs does not crash when its
1252    first argument is NULL.])
1253   fi
1254 fi
1255
1256 AC_CHECK_TYPE(ssize_t, int)
1257 AC_CHECK_TYPE(caddr_t, char *)
1258
1259 GCC_AC_FUNC_MMAP_BLACKLIST
1260
1261 case "${host}" in
1262 *-*-*vms*)
1263   # Under VMS, vfork works very differently than on Unix. The standard test
1264   # won't work, and it isn't easily adaptable. It makes more sense to
1265   # just force it.
1266   ac_cv_func_vfork_works=yes
1267   ;;
1268 esac
1269 AC_FUNC_FORK
1270
1271 AM_ICONV
1272
1273 # Until we have in-tree GNU iconv:
1274 LIBICONV_DEP=
1275 if test -f "$LTLIBICONV"; then
1276   LIBICONV_DEP=$LTLIBICONV
1277 fi
1278 AC_SUBST(LIBICONV_DEP)
1279
1280 AM_LC_MESSAGES
1281
1282 AM_LANGINFO_CODESET
1283
1284 # We will need to find libiberty.h and ansidecl.h
1285 saved_CFLAGS="$CFLAGS"
1286 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1287 saved_CXXFLAGS="$CXXFLAGS"
1288 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1289
1290 # gcc_AC_CHECK_DECLS doesn't support overloaded functions, so use the
1291 # normal autoconf function for these.  But force definition of
1292 # HAVE_DECL_BASENAME like gcc_AC_CHECK_DECLS does, to suppress the bizarre
1293 # basename handling in libiberty.h.
1294 AC_CHECK_DECLS([basename(const char*), strstr(const char*,const char*)], , ,[
1295 #undef HAVE_DECL_BASENAME
1296 #define HAVE_DECL_BASENAME 1
1297 #include "ansidecl.h"
1298 #include "system.h"])
1299
1300 gcc_AC_CHECK_DECLS(getenv atol atoll asprintf sbrk abort atof getcwd getwd \
1301         madvise stpcpy strnlen strsignal strverscmp \
1302         strtol strtoul strtoll strtoull setenv unsetenv \
1303         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1304         free getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1305 #include "ansidecl.h"
1306 #include "system.h"])
1307
1308 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1309 #include "ansidecl.h"
1310 #include "system.h"
1311 #ifdef HAVE_SYS_RESOURCE_H
1312 #include <sys/resource.h>
1313 #endif
1314 ])
1315
1316 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1317 #include "ansidecl.h"
1318 #include "system.h"
1319 #ifdef HAVE_SYS_RESOURCE_H
1320 #include <sys/resource.h>
1321 #endif
1322 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1323 [Define to `long' if <sys/resource.h> doesn't define.])])
1324
1325 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1326 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1327 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1328 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1329 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1330 #include "ansidecl.h"
1331 #include "system.h"
1332 #ifdef HAVE_LDFCN_H
1333 #undef FREAD
1334 #undef FWRITE
1335 #include <ldfcn.h>
1336 #endif
1337 ])
1338
1339 gcc_AC_CHECK_DECLS(times, , ,[
1340 #include "ansidecl.h"
1341 #include "system.h"
1342 #ifdef HAVE_SYS_TIMES_H
1343 #include <sys/times.h>
1344 #endif
1345 ])
1346
1347 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1348 #include "ansidecl.h"
1349 #include "system.h"
1350 #include <signal.h>
1351 ])
1352
1353 # More time-related stuff.
1354 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1355 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1356 #include "ansidecl.h"
1357 #include "system.h"
1358 #ifdef HAVE_SYS_TIMES_H
1359 #include <sys/times.h>
1360 #endif
1361 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1362 if test $ac_cv_struct_tms = yes; then
1363   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1364   [Define if <sys/times.h> defines struct tms.])
1365 fi
1366
1367 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1368 # revisit after autoconf 2.50.
1369 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1370 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1371 #include "ansidecl.h"
1372 #include "system.h"
1373 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1374 if test $gcc_cv_type_clock_t = yes; then
1375   AC_DEFINE(HAVE_CLOCK_T, 1,
1376   [Define if <time.h> defines clock_t.])
1377 fi
1378
1379 # Check if F_SETLKW is supported by fcntl.
1380 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1381 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1382 #include <fcntl.h>]], [[
1383 struct flock fl;
1384 fl.l_whence = 0;
1385 fl.l_start = 0;
1386 fl.l_len = 0;
1387 fl.l_pid = 0;
1388 return fcntl (1, F_SETLKW, &fl);]])],
1389 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1390 if test $ac_cv_f_setlkw = yes; then
1391   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1392   [Define if F_SETLKW supported by fcntl.])
1393 fi
1394
1395 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1396 CFLAGS="$saved_CFLAGS"
1397 CXXFLAGS="$saved_CXXFLAGS"
1398
1399 # mkdir takes a single argument on some systems.
1400 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1401
1402 # File extensions
1403 manext='.1'
1404 objext='.o'
1405 AC_SUBST(manext)
1406 AC_SUBST(objext)
1407
1408 # With Setjmp/Longjmp based exception handling.
1409 AC_ARG_ENABLE(sjlj-exceptions,
1410 [AS_HELP_STRING([--enable-sjlj-exceptions],
1411                 [arrange to use setjmp/longjmp exception handling])],
1412 [case $target in
1413   *-*-hpux10*)
1414     if test $enableval != yes; then
1415       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1416       enableval=yes
1417     fi
1418     ;;
1419 esac
1420 force_sjlj_exceptions=yes],
1421 [case $target in
1422   *-*-hpux10*)
1423     force_sjlj_exceptions=yes
1424     enableval=yes
1425     ;;
1426   lm32*-*-*)
1427      force_sjlj_exceptions=yes
1428      enableval=yes
1429      ;;
1430   *)
1431     force_sjlj_exceptions=no
1432     ;;
1433 esac])
1434 if test $force_sjlj_exceptions = yes; then
1435   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1436   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1437     [Define 0/1 to force the choice for exception handling model.])
1438 fi
1439
1440 # --------------------------------------------------------
1441 # Build, host, and target specific configuration fragments
1442 # --------------------------------------------------------
1443
1444 # Collect build-machine-specific information.
1445 . ${srcdir}/config.build
1446
1447 # Collect host-machine-specific information.
1448 . ${srcdir}/config.host
1449
1450 target_gtfiles=
1451
1452 # Collect target-machine-specific information.
1453 . ${srcdir}/config.gcc
1454
1455 extra_objs="${host_extra_objs} ${extra_objs}"
1456 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1457
1458 # Default the target-machine variables that were not explicitly set.
1459 if test x"$tm_file" = x
1460 then tm_file=$cpu_type/$cpu_type.h; fi
1461
1462 if test x"$extra_headers" = x
1463 then extra_headers=; fi
1464
1465 if test x$md_file = x
1466 then md_file=$cpu_type/$cpu_type.md; fi
1467
1468 if test x$out_file = x
1469 then out_file=$cpu_type/$cpu_type.c; fi
1470
1471 if test x"$tmake_file" = x
1472 then tmake_file=$cpu_type/t-$cpu_type
1473 fi
1474
1475 # Support --enable-initfini-array.
1476 if test x$enable_initfini_array != xno; then
1477   tm_file="${tm_file} initfini-array.h"
1478 fi
1479
1480 if test x"$dwarf2" = xyes
1481 then tm_file="$tm_file tm-dwarf2.h"
1482 fi
1483
1484 # Say what files are being used for the output code and MD file.
1485 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1486 echo "Using \`$srcdir/config/$md_file' as machine description file."
1487
1488 # If any of the xm_file variables contain nonexistent files, warn
1489 # about them and drop them.
1490
1491 bx=
1492 for x in $build_xm_file; do
1493   if    test -f $srcdir/config/$x
1494   then      bx="$bx $x"
1495   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1496   fi
1497 done
1498 build_xm_file="$bx"
1499
1500 hx=
1501 for x in $host_xm_file; do
1502   if    test -f $srcdir/config/$x
1503   then      hx="$hx $x"
1504   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1505   fi
1506 done
1507 host_xm_file="$hx"
1508
1509 tx=
1510 for x in $xm_file; do
1511   if    test -f $srcdir/config/$x
1512   then      tx="$tx $x"
1513   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1514   fi
1515 done
1516 xm_file="$tx"
1517
1518 count=a
1519 for f in $tm_file; do
1520         count=${count}x
1521 done
1522 if test $count = ax; then
1523         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1524 else
1525         echo "Using the following target machine macro files:"
1526         for f in $tm_file; do
1527                 echo "  $srcdir/config/$f"
1528         done
1529 fi
1530
1531 if test x$use_long_long_for_widest_fast_int = xyes; then
1532         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1533 [Define to 1 if the 'long long' type is wider than 'long' but still
1534 efficiently supported by the host hardware.])
1535 fi
1536
1537 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1538 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1539
1540 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1541 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1542
1543 count=a
1544 for f in $host_xm_file; do
1545         count=${count}x
1546 done
1547 if test $count = a; then
1548         :
1549 elif test $count = ax; then
1550         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1551 else
1552         echo "Using the following host machine macro files:"
1553         for f in $host_xm_file; do
1554                 echo "  $srcdir/config/$f"
1555         done
1556 fi
1557 echo "Using ${out_host_hook_obj} for host machine hooks."
1558
1559 if test "$host_xm_file" != "$build_xm_file"; then
1560         count=a
1561         for f in $build_xm_file; do
1562                 count=${count}x
1563         done
1564         if test $count = a; then
1565                 :
1566         elif test $count = ax; then
1567                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1568         else
1569                 echo "Using the following build machine macro files:"
1570                 for f in $build_xm_file; do
1571                         echo "  $srcdir/config/$f"
1572                 done
1573         fi
1574 fi
1575
1576 if test -n "$configured_native_system_header_dir"; then
1577   native_system_header_dir=$configured_native_system_header_dir
1578 fi
1579 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1580 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1581
1582 case ${host} in
1583   powerpc*-*-darwin*)
1584     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1585       gcc_cv_mcontext_underscores,
1586       AC_COMPILE_IFELSE([
1587 #include <sys/cdefs.h>
1588 #include <sys/signal.h>
1589 #include <ucontext.h>
1590 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1591 ],
1592         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1593       if test $gcc_cv_mcontext_underscores = yes; then
1594         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1595           [mcontext_t fields start with __])
1596       fi
1597     ;;
1598 esac
1599
1600 # ---------
1601 # Threading
1602 # ---------
1603
1604 # Check if a valid thread package
1605 case ${enable_threads} in
1606   "" | no)
1607     # No threads
1608     target_thread_file='single'
1609     ;;
1610   yes)
1611     # default
1612     target_thread_file='single'
1613     ;;
1614   aix | dce | lynx | mipssde | posix | rtems | \
1615   single | tpf | vxworks | win32)
1616     target_thread_file=${enable_threads}
1617     ;;
1618   *)
1619     echo "${enable_threads} is an unknown thread package" 1>&2
1620     exit 1
1621     ;;
1622 esac
1623
1624 if test x${thread_file} = x; then
1625   # No thread file set by target-specific clauses in config.gcc,
1626   # so use file chosen by default logic above
1627   thread_file=${target_thread_file}
1628 fi
1629
1630 # --------
1631 # UNSORTED
1632 # --------
1633
1634 use_cxa_atexit=no
1635 if test x$enable___cxa_atexit = xyes || \
1636    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1637   if test x$host = x$target; then
1638     case $host in
1639       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1640       # keyed to flag_use_cxa_atexit
1641       *-*-mingw32*)
1642         use_cxa_atexit=yes
1643         ;;
1644       powerpc-ibm-aix*)
1645         use_cxa_atexit=yes
1646         ;;
1647       *)
1648         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1649           [echo "__cxa_atexit can't be enabled on this target"])
1650         ;;
1651     esac
1652   else
1653     # We can't check for __cxa_atexit when building a cross, so assume
1654     # it is available
1655     use_cxa_atexit=yes
1656   fi
1657   if test x$use_cxa_atexit = xyes; then
1658     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1659       [Define if you want to use __cxa_atexit, rather than atexit, to
1660       register C++ destructors for local statics and global objects.
1661       This is essential for fully standards-compliant handling of
1662       destructors, but requires __cxa_atexit in libc.])
1663   fi
1664 fi
1665
1666 # Look for a file containing extra machine modes.
1667 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1668   extra_modes_file='$(srcdir)'/config/${extra_modes}
1669   AC_SUBST(extra_modes_file)
1670   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1671   [Define to the name of a file containing a list of extra machine modes
1672    for this architecture.])
1673 fi
1674
1675 # Convert extra_options into a form suitable for Makefile use.
1676 extra_opt_files=
1677 all_opt_files=
1678 for f in $extra_options; do
1679   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1680   all_opt_files="$all_opt_files $srcdir/config/$f"
1681 done
1682 AC_SUBST(extra_opt_files)
1683
1684 # auto-host.h is the file containing items generated by autoconf and is
1685 # the first file included by config.h.
1686 # If host=build, it is correct to have bconfig include auto-host.h
1687 # as well.  If host!=build, we are in error and need to do more
1688 # work to find out the build config parameters.
1689 if test x$host = x$build
1690 then
1691         build_auto=auto-host.h
1692 else
1693         # We create a subdir, then run autoconf in the subdir.
1694         # To prevent recursion we set host and build for the new
1695         # invocation of configure to the build for this invocation
1696         # of configure.
1697         tempdir=build.$$
1698         rm -rf $tempdir
1699         mkdir $tempdir
1700         cd $tempdir
1701         case ${srcdir} in
1702         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1703         *) realsrcdir=../${srcdir};;
1704         esac
1705         # Clearing GMPINC is necessary to prevent host headers being
1706         # used by the build compiler.  Defining GENERATOR_FILE stops
1707         # system.h from including gmp.h.
1708         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1709         CXX="${CXX_FOR_BUILD}" CXXFLAGS="${CXXFLAGS_FOR_BUILD}" \
1710         LD="${LD_FOR_BUILD}" LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1711         GMPINC="" CPPFLAGS="${CPPFLAGS} -DGENERATOR_FILE" \
1712         ${realsrcdir}/configure \
1713                 --enable-languages=${enable_languages-all} \
1714                 --target=$target_alias --host=$build_alias --build=$build_alias
1715
1716         # We just finished tests for the build machine, so rename
1717         # the file auto-build.h in the gcc directory.
1718         mv auto-host.h ../auto-build.h
1719         cd ..
1720         rm -rf $tempdir
1721         build_auto=auto-build.h
1722 fi
1723 AC_SUBST(build_subdir)
1724
1725 tm_file="${tm_file} defaults.h"
1726 tm_p_file="${tm_p_file} tm-preds.h"
1727 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1728 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1729 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1730 # put this back in temporarily.
1731 xm_file="auto-host.h ansidecl.h ${xm_file}"
1732
1733 # --------
1734 # UNSORTED
1735 # --------
1736
1737 changequote(,)dnl
1738 # Compile in configure arguments.
1739 if test -f configargs.h ; then
1740         # Being re-configured.
1741         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1742         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1743 else
1744         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1745 fi
1746
1747 # Double all backslashes and backslash all quotes to turn
1748 # gcc_config_arguments into a C string.
1749 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1750 $gcc_config_arguments
1751 EOF
1752 gcc_config_arguments_str=`cat conftest.out`
1753 rm -f conftest.out
1754
1755 cat > configargs.h <<EOF
1756 /* Generated automatically. */
1757 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1758 static const char thread_model[] = "$thread_file";
1759
1760 static const struct {
1761   const char *name, *value;
1762 } configure_default_options[] = $configure_default_options;
1763 EOF
1764 changequote([,])dnl
1765
1766 changequote(,)dnl
1767 gcc_BASEVER=`cat $srcdir/BASE-VER`
1768 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1769 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1770 if test -f $srcdir/REVISION ; then
1771         gcc_REVISION=`cat $srcdir/REVISION`
1772 else
1773         gcc_REVISION=""
1774 fi
1775 cat > plugin-version.h <<EOF
1776 #include "configargs.h"
1777
1778 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1779 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1780 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1781 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1782
1783 static char basever[] = "$gcc_BASEVER";
1784 static char datestamp[] = "$gcc_DATESTAMP";
1785 static char devphase[] = "$gcc_DEVPHASE";
1786 static char revision[] = "$gcc_REVISION";
1787
1788 /* FIXME plugins: We should make the version information more precise.
1789    One way to do is to add a checksum. */
1790
1791 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1792                                                 devphase, revision,
1793                                                 configuration_arguments};
1794 EOF
1795 changequote([,])dnl
1796
1797 # Internationalization
1798 ZW_GNU_GETTEXT_SISTER_DIR
1799
1800 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1801 # -liconv on the link line twice.
1802 case "$LIBINTL" in *$LIBICONV*)
1803         LIBICONV= ;;
1804 esac
1805
1806 AC_ARG_ENABLE(secureplt,
1807 [AS_HELP_STRING([--enable-secureplt],
1808                 [enable -msecure-plt by default for PowerPC])],
1809 [], [])
1810
1811 AC_ARG_ENABLE(leading-mingw64-underscores,
1812   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1813                  [enable leading underscores on 64 bit mingw targets]),
1814   [],[])
1815 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1816   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1817     [Define if we should use leading underscore on 64 bit mingw targets])])
1818
1819 AC_ARG_ENABLE(cld,
1820 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1821 [enable_cld=no])
1822
1823 AC_ARG_ENABLE(frame-pointer,
1824 [AS_HELP_STRING([--enable-frame-pointer],
1825                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1826 [
1827 case $target_os in
1828 linux* | darwin[[8912]]*)
1829   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1830   # DWARF2.
1831   enable_frame_pointer=no
1832   ;;
1833 *)
1834   enable_frame_pointer=yes
1835   ;;
1836 esac
1837 ])
1838
1839 # Windows32 Registry support for specifying GCC installation paths.
1840 AC_ARG_ENABLE(win32-registry,
1841 [AS_HELP_STRING([--disable-win32-registry],
1842                 [disable lookup of installation paths in the
1843                  Registry on Windows hosts])
1844 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1845 AS_HELP_STRING([--enable-win32-registry=KEY],
1846                [use KEY instead of GCC version as the last portion
1847                 of the registry key])],,)
1848
1849 case $host_os in
1850   win32 | pe | cygwin* | mingw32*)
1851     if test "x$enable_win32_registry" != xno; then
1852       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1853     fi
1854
1855     if test "x$enable_win32_registry" != xno; then
1856       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1857   [Define to 1 if installation paths should be looked up in the Windows
1858    Registry. Ignored on non-Windows hosts.])
1859
1860       if test "x$enable_win32_registry" != xyes \
1861          && test "x$enable_win32_registry" != x; then
1862         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1863   [Define to be the last component of the Windows registry key under which
1864    to look for installation paths.  The full key used will be
1865    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1866    The default is the GCC version number.])
1867       fi
1868     fi
1869   ;;
1870 esac
1871
1872 # Get an absolute path to the GCC top-level source directory
1873 holddir=`${PWDCMD-pwd}`
1874 cd $srcdir
1875 topdir=`${PWDCMD-pwd}`
1876 cd $holddir
1877
1878 # Conditionalize the makefile for this host machine.
1879 xmake_file=
1880 for f in ${host_xmake_file}
1881 do
1882         if test -f ${srcdir}/config/$f
1883         then
1884                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1885         fi
1886 done
1887
1888 # Conditionalize the makefile for this target machine.
1889 tmake_file_=
1890 for f in ${tmake_file}
1891 do
1892         if test -f ${srcdir}/config/$f
1893         then
1894                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1895         fi
1896 done
1897 tmake_file="${tmake_file_}"
1898
1899 out_object_file=`basename $out_file .c`.o
1900 common_out_object_file=`basename $common_out_file .c`.o
1901
1902 tm_file_list="options.h"
1903 tm_include_list="options.h insn-constants.h"
1904 for f in $tm_file; do
1905   case $f in
1906     ./* )
1907        f=`echo $f | sed 's/^..//'`
1908        tm_file_list="${tm_file_list} $f"
1909        tm_include_list="${tm_include_list} $f"
1910        ;;
1911     defaults.h )
1912        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1913        tm_include_list="${tm_include_list} $f"
1914        ;;
1915     * )
1916        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1917        tm_include_list="${tm_include_list} config/$f"
1918        ;;
1919   esac
1920 done
1921
1922 tm_p_file_list=
1923 tm_p_include_list=
1924 for f in $tm_p_file; do
1925   case $f in
1926     tm-preds.h )
1927        tm_p_file_list="${tm_p_file_list} $f"
1928        tm_p_include_list="${tm_p_include_list} $f"
1929        ;;
1930     * )
1931        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1932        tm_p_include_list="${tm_p_include_list} config/$f"
1933   esac
1934 done
1935
1936 xm_file_list=
1937 xm_include_list=
1938 for f in $xm_file; do
1939   case $f in
1940     ansidecl.h )
1941        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1942        xm_include_list="${xm_include_list} $f"
1943        ;;
1944     auto-host.h )
1945        xm_file_list="${xm_file_list} $f"
1946        xm_include_list="${xm_include_list} $f"
1947        ;;
1948     * )
1949        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1950        xm_include_list="${xm_include_list} config/$f"
1951        ;;
1952   esac
1953 done
1954
1955 host_xm_file_list=
1956 host_xm_include_list=
1957 for f in $host_xm_file; do
1958   case $f in
1959     ansidecl.h )
1960        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1961        host_xm_include_list="${host_xm_include_list} $f"
1962        ;;
1963     auto-host.h )
1964        host_xm_file_list="${host_xm_file_list} $f"
1965        host_xm_include_list="${host_xm_include_list} $f"
1966        ;;
1967     * )
1968        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1969        host_xm_include_list="${host_xm_include_list} config/$f"
1970        ;;
1971   esac
1972 done
1973
1974 build_xm_file_list=
1975 for f in $build_xm_file; do
1976   case $f in
1977     ansidecl.h )
1978        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1979        build_xm_include_list="${build_xm_include_list} $f"
1980        ;;
1981     auto-build.h | auto-host.h )
1982        build_xm_file_list="${build_xm_file_list} $f"
1983        build_xm_include_list="${build_xm_include_list} $f"
1984        ;;
1985     * )
1986        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1987        build_xm_include_list="${build_xm_include_list} config/$f"
1988        ;;
1989   esac
1990 done
1991
1992 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1993 # cross-compiler which does not use the native headers and libraries.
1994 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1995 CROSS=                                          AC_SUBST(CROSS)
1996 ALL=all.internal                                AC_SUBST(ALL)
1997 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1998
1999 if test "x$with_build_sysroot" != x; then
2000   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
2001 else
2002   # This value is used, even on a native system, because
2003   # CROSS_SYSTEM_HEADER_DIR is just
2004   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
2005   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
2006 fi
2007
2008 if test x$host != x$target
2009 then
2010         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
2011         ALL=all.cross
2012         SYSTEM_HEADER_DIR=$build_system_header_dir
2013         case "$host","$target" in
2014         # Darwin crosses can use the host system's libraries and headers,
2015         # because of the fat library support.  Of course, it must be the
2016         # same version of Darwin on both sides.  Allow the user to
2017         # just say --target=foo-darwin without a version number to mean
2018         # "the version on this system".
2019             *-*-darwin*,*-*-darwin*)
2020                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
2021                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
2022                 if test $hostos = $targetos -o $targetos = darwin ; then
2023                     CROSS=
2024                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
2025                     with_headers=yes
2026                 fi
2027                 ;;
2028
2029             i?86-*-*,x86_64-*-* \
2030             | powerpc*-*-*,powerpc64*-*-*)
2031                 CROSS="$CROSS -DNATIVE_CROSS" ;;
2032         esac
2033
2034         case $target in
2035                 *-*-mingw*)
2036                         if test "x$with_headers" = x; then
2037                                 with_headers=yes
2038                         fi
2039                         ;;
2040                 *)
2041                         ;;
2042         esac
2043 elif test "x$TARGET_SYSTEM_ROOT" != x; then
2044         SYSTEM_HEADER_DIR=$build_system_header_dir
2045 fi
2046
2047 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
2048   if test "x$with_headers" != x && test "x$with_headers" != xyes; then
2049     target_header_dir=$with_headers
2050   elif test "x$with_sysroot" = x; then
2051     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
2052   elif test "x$with_build_sysroot" != "x"; then
2053     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
2054   elif test "x$with_sysroot" = xyes; then
2055     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
2056   else
2057     target_header_dir="${with_sysroot}${native_system_header_dir}"
2058   fi
2059 else
2060   target_header_dir=${native_system_header_dir}
2061 fi
2062
2063 # If this is a cross-compiler that does not
2064 # have its own set of headers then define
2065 # inhibit_libc
2066
2067 # If this is using newlib, without having the headers available now,
2068 # then define inhibit_libc in LIBGCC2_CFLAGS.
2069 # This prevents libgcc2 from containing any code which requires libc
2070 # support.
2071 : ${inhibit_libc=false}
2072 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
2073        test x$with_newlib = xyes ; } &&
2074      { test "x$with_headers" = xno || test ! -f "$target_header_dir/stdio.h"; } ; then
2075        inhibit_libc=true
2076 fi
2077 AC_SUBST(inhibit_libc)
2078
2079 # When building gcc with a cross-compiler, we need to adjust things so
2080 # that the generator programs are still built with the native compiler.
2081 # Also, we cannot run fixincludes.
2082
2083 # These are the normal (build=host) settings:
2084 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
2085 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
2086 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
2087 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
2088 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
2089 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
2090
2091 BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS)' AC_SUBST(BUILD_NO_PIE_CFLAGS)
2092 BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG)' AC_SUBST(BUILD_NO_PIE_FLAG)
2093
2094 # And these apply if build != host, or we are generating coverage data
2095 if test x$build != x$host || test "x$coverage_flags" != x
2096 then
2097     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
2098     BUILD_CXXFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CXXFLAGS_FOR_BUILD)'
2099     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
2100
2101     NO_PIE_CFLAGS_FOR_BUILD=${NO_PIE_CFLAGS_FOR_BUILD-${NO_PIE_CFLAGS}}
2102     NO_PIE_FLAG_FOR_BUILD=${NO_PIE_FLAG_FOR_BUILD-${NO_PIE_FLAG}}
2103     BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS_FOR_BUILD)'
2104     BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG_FOR_BUILD)'
2105 fi
2106 AC_SUBST(NO_PIE_CFLAGS_FOR_BUILD)
2107 AC_SUBST(NO_PIE_FLAG_FOR_BUILD)
2108
2109 # Expand extra_headers to include complete path.
2110 # This substitutes for lots of t-* files.
2111 extra_headers_list=
2112 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
2113 for file in ${extra_headers} ; do
2114   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
2115 done
2116
2117 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
2118 if test x"$use_gcc_tgmath" = xyes
2119 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
2120 fi
2121
2122 # Define collect2 in Makefile.
2123 case $host_can_use_collect2 in
2124   no) collect2= ;;
2125   *) collect2='collect2$(exeext)' ;;
2126 esac
2127 AC_SUBST([collect2])
2128
2129 # Add a definition of USE_COLLECT2 if system wants one.
2130 case $use_collect2 in
2131   no) use_collect2= ;;
2132   "") ;;
2133   *)
2134     host_xm_defines="${host_xm_defines} USE_COLLECT2"
2135     xm_defines="${xm_defines} USE_COLLECT2"
2136     case $host_can_use_collect2 in
2137       no)
2138         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
2139         ;;
2140     esac
2141     ;;
2142 esac
2143
2144 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
2145 [Define to the name of the LTO plugin DSO that must be
2146   passed to the linker's -plugin=LIB option.])
2147
2148 # ---------------------------
2149 # Assembler & linker features
2150 # ---------------------------
2151
2152 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
2153 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
2154 # However when ld-new is first executed from the build tree, libtool will
2155 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
2156 # to the build tree.  While doing this we need to use the previous-stage
2157 # linker, or we have an infinite loop.  The presence of a shell script as
2158 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
2159 # the gcc/collect-ld script.  So we need to know how libtool works, or
2160 # exec-tool will fail.
2161
2162 m4_defun([_LT_CONFIG_COMMANDS], [])
2163 AC_PROG_LIBTOOL
2164 AC_SUBST(objdir)
2165 AC_SUBST(enable_fast_install)
2166
2167 # Identify the assembler which will work hand-in-glove with the newly
2168 # built GCC, so that we can examine its features.  This is the assembler
2169 # which will be driven by the driver program.
2170 #
2171 # If build != host, and we aren't building gas in-tree, we identify a
2172 # build->target assembler and hope that it will have the same features
2173 # as the host->target assembler we'll be using.
2174 gcc_cv_gas_major_version=
2175 gcc_cv_gas_minor_version=
2176 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
2177
2178 m4_pattern_allow([AS_FOR_TARGET])dnl
2179 AS_VAR_SET_IF(gcc_cv_as,, [
2180 if test -x "$DEFAULT_ASSEMBLER"; then
2181         gcc_cv_as="$DEFAULT_ASSEMBLER"
2182 elif test -f $gcc_cv_as_gas_srcdir/configure.ac \
2183      && test -f ../gas/Makefile \
2184      && test x$build = x$host; then
2185         gcc_cv_as=../gas/as-new$build_exeext
2186 elif test -x as$build_exeext; then
2187         # Build using assembler in the current directory.
2188         gcc_cv_as=./as$build_exeext
2189 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
2190         gcc_cv_as="$AS_FOR_TARGET"
2191 else
2192         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
2193 fi])
2194
2195 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
2196 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
2197 case "$ORIGINAL_AS_FOR_TARGET" in
2198   ./as | ./as$build_exeext) ;;
2199   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
2200 esac
2201
2202 AC_MSG_CHECKING(what assembler to use)
2203 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
2204   # Single tree build which includes gas.  We want to prefer it
2205   # over whatever linker top-level may have detected, since
2206   # we'll use what we're building after installation anyway.
2207   AC_MSG_RESULT(newly built gas)
2208   in_tree_gas=yes
2209   _gcc_COMPUTE_GAS_VERSION
2210   in_tree_gas_is_elf=no
2211   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2212      || (grep 'obj_format = multi' ../gas/Makefile \
2213          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
2214   then
2215     in_tree_gas_is_elf=yes
2216   fi
2217 else
2218   AC_MSG_RESULT($gcc_cv_as)
2219   in_tree_gas=no
2220 fi
2221
2222 default_ld=
2223 AC_ARG_ENABLE(ld,
2224 [[  --enable-ld[=ARG]       build ld [ARG={default,yes,no}]]],
2225 [case "${enableval}" in
2226  no)
2227    default_ld=ld.gold
2228    ;;
2229  esac])
2230
2231 install_gold_as_default=no
2232 AC_ARG_ENABLE(gold,
2233 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
2234 [case "${enableval}" in
2235  default)
2236    install_gold_as_default=yes
2237    ;;
2238  yes)
2239    if test x${default_ld} != x; then
2240      install_gold_as_default=yes
2241    fi
2242    ;;
2243  no)
2244    ;;
2245  *)
2246    AC_MSG_ERROR([invalid --enable-gold argument])
2247    ;;
2248  esac])
2249
2250 # Identify the linker which will work hand-in-glove with the newly
2251 # built GCC, so that we can examine its features.  This is the linker
2252 # which will be driven by the driver program.
2253 #
2254 # If build != host, and we aren't building gas in-tree, we identify a
2255 # build->target linker and hope that it will have the same features
2256 # as the host->target linker we'll be using.
2257 gcc_cv_gld_major_version=
2258 gcc_cv_gld_minor_version=
2259 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
2260 gcc_cv_ld_gold_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gold
2261 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
2262
2263 AS_VAR_SET_IF(gcc_cv_ld,, [
2264 if test -x "$DEFAULT_LINKER"; then
2265         gcc_cv_ld="$DEFAULT_LINKER"
2266 elif test $install_gold_as_default = yes \
2267      && test -f $gcc_cv_ld_gold_srcdir/configure.ac \
2268      && test -f ../gold/Makefile \
2269      && test x$build = x$host; then
2270         gcc_cv_ld=../gold/ld-new$build_exeext
2271 elif test -f $gcc_cv_ld_gld_srcdir/configure.ac \
2272      && test -f ../ld/Makefile \
2273      && test x$build = x$host; then
2274         gcc_cv_ld=../ld/ld-new$build_exeext
2275 elif test -x collect-ld$build_exeext; then
2276         # Build using linker in the current directory.
2277         gcc_cv_ld=./collect-ld$build_exeext
2278 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
2279         gcc_cv_ld="$LD_FOR_TARGET"
2280 else
2281         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2282 fi])
2283
2284 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2285 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2286 # if the PLUGIN_LD is set ld-new, just have it as ld
2287 # as that is the installed named.
2288 if test x$PLUGIN_LD_SUFFIX = xld-new \
2289    || test x$PLUGIN_LD_SUFFIX = xcollect-ld ; then
2290   PLUGIN_LD_SUFFIX=ld
2291 fi
2292 AC_ARG_WITH(plugin-ld,
2293 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2294 [if test x"$withval" != x; then
2295    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2296    PLUGIN_LD_SUFFIX="$withval"
2297  fi])
2298 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2299 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2300
2301 # Check to see if we are using gold instead of ld
2302 AC_MSG_CHECKING(whether we are using gold)
2303 ld_is_gold=no
2304 if test x$gcc_cv_ld != x; then
2305   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2306      | grep "GNU gold" > /dev/null; then
2307     ld_is_gold=yes
2308   fi
2309 fi
2310 AC_MSG_RESULT($ld_is_gold)
2311
2312 AC_MSG_CHECKING(gold linker with split stack support as non default)
2313 # Check to see if default ld is not gold, but gold is
2314 # available and has support for split stack.  If gcc was configured
2315 # with gold then no checking is done.
2316 #
2317 if test x$ld_is_gold = xno && which ${gcc_cv_ld}.gold >/dev/null 2>&1; then
2318
2319 # For platforms other than powerpc64*, enable as appropriate.
2320
2321   gold_non_default=no
2322   ld_gold=`which ${gcc_cv_ld}.gold`
2323 # Make sure this gold has minimal split stack support
2324   if $ld_gold --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
2325     ld_vers=`$ld_gold --version | sed 1q`
2326     gold_vers=`echo $ld_vers | sed -n \
2327           -e 's,^[[^)]]*[[  ]]\([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*[[^)]]*\)) .*$,\1,p'`
2328     case $target in
2329 # check that the gold version contains the complete split stack support
2330 # on powerpc64 big and little endian
2331       powerpc64*-*-*)
2332         case "$gold_vers" in
2333           2.25.[[1-9]]*|2.2[[6-9]][[.0-9]]*|2.[[3-9]][[.0-9]]*|[[3-9]].[[.0-9]]*) gold_non_default=yes
2334           ;;
2335           *) gold_non_default=no
2336           ;;
2337         esac
2338         ;;
2339     esac
2340   fi
2341   if test $gold_non_default = yes; then
2342     AC_DEFINE(HAVE_GOLD_NON_DEFAULT_SPLIT_STACK, 1,
2343             [Define if the gold linker supports split stack and is available as a non-default])
2344   fi
2345 fi
2346 AC_MSG_RESULT($gold_non_default)
2347
2348 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2349 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2350 case "$ORIGINAL_LD_FOR_TARGET" in
2351   ./collect-ld | ./collect-ld$build_exeext) ;;
2352   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2353 esac
2354
2355 AC_MSG_CHECKING(what linker to use)
2356 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2357    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2358         # Single tree build which includes ld.  We want to prefer it
2359         # over whatever linker top-level may have detected, since
2360         # we'll use what we're building after installation anyway.
2361         AC_MSG_RESULT(newly built ld)
2362         in_tree_ld=yes
2363         in_tree_ld_is_elf=no
2364         if (grep 'EMUL = .*elf' ../ld/Makefile \
2365             || grep 'EMUL = .*linux' ../ld/Makefile \
2366             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2367           in_tree_ld_is_elf=yes
2368         elif test "$ld_is_gold" = yes; then
2369           in_tree_ld_is_elf=yes
2370         fi
2371         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.ac $gcc_cv_ld_gld_srcdir/Makefile.in
2372         do
2373 changequote(,)dnl
2374                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*VERSION=[^0-9A-Za-z_]*\([0-9]*\.[0-9]*.*\)/VERSION=\1/p' < $f`
2375                 if test x$gcc_cv_gld_version != x; then
2376                         break
2377                 fi
2378         done
2379         case $gcc_cv_gld_version in
2380           VERSION=[0-9]*) ;;
2381 changequote([,])dnl
2382           *) AC_MSG_ERROR([[cannot find version of in-tree linker]]) ;;
2383 changequote(,)dnl
2384         esac
2385         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2386         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2387 changequote([,])dnl
2388         ORIGINAL_LD_BFD_FOR_TARGET=../ld/ld-new$build_exeext
2389         ORIGINAL_LD_GOLD_FOR_TARGET=../gold/ld-new$build_exeext
2390 else
2391         AC_MSG_RESULT($gcc_cv_ld)
2392         in_tree_ld=no
2393         gcc_cvs_ld_program=`dirname $gcc_cv_ld`/`basename $gcc_cv_ld $host_exeext`
2394         ORIGINAL_LD_BFD_FOR_TARGET=${gcc_cvs_ld_program}.bfd$host_exeext
2395         ORIGINAL_LD_GOLD_FOR_TARGET=${gcc_cvs_ld_program}.gold$host_exeext
2396 fi
2397
2398 AC_SUBST(ORIGINAL_LD_BFD_FOR_TARGET)
2399 AC_SUBST(ORIGINAL_LD_GOLD_FOR_TARGET)
2400
2401 # Figure out what nm we will be using.
2402 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2403 AS_VAR_SET_IF(gcc_cv_nm,, [
2404 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2405      && test -f ../binutils/Makefile \
2406      && test x$build = x$host; then
2407         gcc_cv_nm=../binutils/nm-new$build_exeext
2408 elif test -x nm$build_exeext; then
2409         gcc_cv_nm=./nm$build_exeext
2410 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2411         gcc_cv_nm="$NM_FOR_TARGET"
2412 else
2413         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2414 fi])
2415
2416 AC_MSG_CHECKING(what nm to use)
2417 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2418         # Single tree build which includes binutils.
2419         AC_MSG_RESULT(newly built nm)
2420         in_tree_nm=yes
2421 else
2422         AC_MSG_RESULT($gcc_cv_nm)
2423         in_tree_nm=no
2424 fi
2425
2426 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2427 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2428 case "$ORIGINAL_NM_FOR_TARGET" in
2429   ./nm | ./nm$build_exeext) ;;
2430   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2431 esac
2432
2433
2434 # Figure out what objdump we will be using.
2435 AS_VAR_SET_IF(gcc_cv_objdump,, [
2436 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2437      && test -f ../binutils/Makefile \
2438      && test x$build = x$host; then
2439         # Single tree build which includes binutils.
2440         gcc_cv_objdump=../binutils/objdump$build_exeext
2441 elif test -x objdump$build_exeext; then
2442         gcc_cv_objdump=./objdump$build_exeext
2443 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2444         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2445 else
2446         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2447 fi])
2448
2449 AC_MSG_CHECKING(what objdump to use)
2450 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2451         # Single tree build which includes binutils.
2452         AC_MSG_RESULT(newly built objdump)
2453 elif test x$gcc_cv_objdump = x; then
2454         AC_MSG_RESULT(not found)
2455 else
2456         AC_MSG_RESULT($gcc_cv_objdump)
2457 fi
2458
2459 # Figure out what readelf we will be using.
2460 AS_VAR_SET_IF(gcc_cv_readelf,, [
2461 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2462      && test -f ../binutils/Makefile \
2463      && test x$build = x$host; then
2464         # Single tree build which includes binutils.
2465         gcc_cv_readelf=../binutils/readelf$build_exeext
2466 elif test -x readelf$build_exeext; then
2467         gcc_cv_readelf=./readelf$build_exeext
2468 elif ( set dummy $READELF_FOR_TARGET; test -x $[2] ); then
2469         gcc_cv_readelf="$READELF_FOR_TARGET"
2470 else
2471         AC_PATH_PROG(gcc_cv_readelf, $READELF_FOR_TARGET)
2472 fi])
2473
2474 AC_MSG_CHECKING(what readelf to use)
2475 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2476         # Single tree build which includes binutils.
2477         AC_MSG_RESULT(newly built readelf)
2478 elif test x$gcc_cv_readelf = x; then
2479         AC_MSG_RESULT(not found)
2480 else
2481         AC_MSG_RESULT($gcc_cv_readelf)
2482 fi
2483
2484 # Figure out what assembler alignment features are present.
2485 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2486  [2,6,0],,
2487 [.balign 4
2488 .p2align 2],,
2489 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2490   [Define if your assembler supports .balign and .p2align.])])
2491
2492 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2493  [2,8,0],,
2494  [.p2align 4,,7],,
2495 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2496   [Define if your assembler supports specifying the maximum number
2497    of bytes to skip when using the GAS .p2align command.])])
2498
2499 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2500  [2,8,0],,
2501  [.literal16],,
2502 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2503   [Define if your assembler supports .literal16.])])
2504
2505 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2506  [elf,2,9,0],,
2507  [conftest_label1: .word 0
2508 .subsection -1
2509 conftest_label2: .word 0
2510 .previous],
2511  [if test x$gcc_cv_nm != x; then
2512     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2513     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2514     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2515     then :
2516     else gcc_cv_as_subsection_m1=yes
2517     fi
2518     rm -f conftest.nm1 conftest.nm2
2519   fi],
2520  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2521   [Define if your assembler supports .subsection and .subsection -1 starts
2522    emitting at the beginning of your section.])])
2523
2524 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2525  [2,2,0],,
2526  [      .weak foobar],,
2527 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2528
2529 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2530  [2,17,0],,
2531  [      .weakref foobar, barfnot],,
2532 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2533
2534 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2535  [2,15,91],,
2536  [      .SPACE $TEXT$
2537         .NSUBSPA $CODE$,COMDAT],,
2538 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2539
2540 # .hidden needs to be supported in both the assembler and the linker,
2541 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2542 # This is irritatingly difficult to feature test for; we have to check the
2543 # date string after the version number.  If we've got an in-tree
2544 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2545 # to be safe.
2546 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2547 case "${target}" in
2548   *-*-aix*)
2549     conftest_s='        .globl foobar,hidden'
2550     ;;
2551   *)
2552     conftest_s='        .hidden foobar
2553 foobar:'
2554     ;;
2555 esac
2556 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2557  [elf,2,13,0],, [$conftest_s])
2558 case "${target}" in
2559   *-*-darwin*)
2560     # Darwin as has some visibility support, though with a different syntax.
2561     gcc_cv_as_hidden=yes
2562     ;;
2563 esac
2564
2565 # gnu_indirect_function type is an extension proposed at
2566 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2567 # selection of function implementation
2568 AC_ARG_ENABLE(gnu-indirect-function,
2569  [AS_HELP_STRING([--enable-gnu-indirect-function],
2570                  [enable the use of the @gnu_indirect_function to glibc systems])],
2571  [case $enable_gnu_indirect_function in
2572     yes | no) ;;
2573     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2574 Valid choices are 'yes' and 'no'.]) ;;
2575   esac],
2576  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2577
2578 gif=`if test x$enable_gnu_indirect_function = xyes; then echo 1; else echo 0; fi`
2579 AC_DEFINE_UNQUOTED(HAVE_GNU_INDIRECT_FUNCTION, $gif,
2580 [Define if your system supports gnu indirect functions.])
2581
2582
2583 changequote(,)dnl
2584 if test $in_tree_ld != yes ; then
2585   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2586   if echo "$ld_ver" | grep GNU > /dev/null; then
2587     if test x"$ld_is_gold" = xyes; then
2588       # GNU gold --version looks like this:
2589       #
2590       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2591       #
2592       # We extract the binutils version which is more familiar and specific
2593       # than the gold version.
2594       ld_vers=`echo $ld_ver | sed -n \
2595           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2596     else
2597       # GNU ld --version looks like this:
2598       #
2599       # GNU ld (GNU Binutils) 2.21.51.20110225
2600       ld_vers=`echo $ld_ver | sed -n \
2601           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2602     fi
2603     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2604     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2605     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2606     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2607   else
2608     case "${target}" in
2609       *-*-solaris2*)
2610         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2611         # format.
2612         #
2613         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2614         # /usr/ccs/bin/ld has been configured.
2615         ld_ver=`$gcc_cv_ld -V 2>&1`
2616         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2617           ld_vers=`echo $ld_ver | sed -n \
2618             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2619           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2620           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2621         fi
2622         ;;
2623     esac
2624   fi
2625 fi
2626 changequote([,])dnl
2627
2628 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2629 [[if test $in_tree_ld = yes ; then
2630   gcc_cv_ld_hidden=no
2631   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2632      && test $in_tree_ld_is_elf = yes; then
2633      gcc_cv_ld_hidden=yes
2634   fi
2635 else
2636   gcc_cv_ld_hidden=yes
2637   if test x"$ld_is_gold" = xyes; then
2638     :
2639   elif echo "$ld_ver" | grep GNU > /dev/null; then
2640     case "${target}" in
2641       mmix-knuth-mmixware)
2642         # The linker emits by default mmo, not ELF, so "no" is appropriate.
2643         gcc_cv_ld_hidden=no
2644         ;;
2645     esac
2646     if test 0"$ld_date" -lt 20020404; then
2647       if test -n "$ld_date"; then
2648         # If there was date string, but was earlier than 2002-04-04, fail
2649         gcc_cv_ld_hidden=no
2650       elif test -z "$ld_vers"; then
2651         # If there was no date string nor ld version number, something is wrong
2652         gcc_cv_ld_hidden=no
2653       else
2654         test -z "$ld_vers_patch" && ld_vers_patch=0
2655         if test "$ld_vers_major" -lt 2; then
2656           gcc_cv_ld_hidden=no
2657         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2658           gcc_cv_ld_hidden="no"
2659         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2660           gcc_cv_ld_hidden=no
2661         fi
2662       fi
2663     fi
2664   else
2665     case "${target}" in
2666       *-*-aix[789]*)
2667         gcc_cv_ld_hidden=yes
2668         ;;
2669       *-*-darwin*)
2670         # Darwin ld has some visibility support.
2671         gcc_cv_ld_hidden=yes
2672         ;;
2673       hppa64*-*-hpux* | ia64*-*-hpux*)
2674         gcc_cv_ld_hidden=yes
2675         ;;
2676       *-*-solaris2.1[0-9]*)
2677         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2678         # .symbolic was only added in Solaris 9 12/02.
2679         gcc_cv_ld_hidden=yes
2680         ;;
2681       *)
2682         gcc_cv_ld_hidden=no
2683         ;;
2684     esac
2685   fi
2686 fi]])
2687 libgcc_visibility=no
2688 AC_SUBST(libgcc_visibility)
2689 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2690 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2691   libgcc_visibility=yes
2692   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2693   [Define if your assembler and linker support .hidden.])
2694 fi
2695
2696 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2697 gcc_cv_ld_ro_rw_mix=unknown
2698 if test $in_tree_ld = yes ; then
2699   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2700      && test $in_tree_ld_is_elf = yes; then
2701     gcc_cv_ld_ro_rw_mix=read-write
2702   fi
2703 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2704   echo '.section myfoosect, "a"' > conftest1.s
2705   echo '.section myfoosect, "aw"' > conftest2.s
2706   echo '.byte 1' >> conftest2.s
2707   echo '.section myfoosect, "a"' > conftest3.s
2708   echo '.byte 0' >> conftest3.s
2709   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2710      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2711      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2712      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2713         conftest2.o conftest3.o > /dev/null 2>&1; then
2714     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2715                          | sed -e '/myfoosect/!d' -e N`
2716     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2717       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2718         gcc_cv_ld_ro_rw_mix=read-only
2719       else
2720         gcc_cv_ld_ro_rw_mix=read-write
2721       fi
2722     fi
2723   fi
2724 changequote(,)dnl
2725   rm -f conftest.* conftest[123].*
2726 changequote([,])dnl
2727 fi
2728 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2729         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2730   [Define if your linker links a mix of read-only
2731    and read-write sections into a read-write section.])
2732 fi
2733 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2734
2735 gcc_AC_INITFINI_ARRAY
2736
2737 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2738 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2739   [elf,2,11,0],,
2740 [       .data
2741         .uleb128 L2 - L1
2742 L1:
2743         .uleb128 1280
2744         .sleb128 -1010
2745 L2:],
2746 [[# GAS versions before 2.11 do not support uleb128,
2747   # despite appearing to.
2748   # ??? There exists an elf-specific test that will crash
2749   # the assembler.  Perhaps it's better to figure out whether
2750   # arbitrary sections are supported and try the test.
2751   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2752   if echo "$as_ver" | grep GNU > /dev/null; then
2753     as_vers=`echo $as_ver | sed -n \
2754         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2755     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2756     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2757     if test $as_major -eq 2 && test $as_minor -lt 11
2758     then :
2759     else gcc_cv_as_leb128=yes
2760     fi
2761   fi]],
2762   [AC_DEFINE(HAVE_AS_LEB128, 1,
2763     [Define if your assembler supports .sleb128 and .uleb128.])],
2764   [AC_DEFINE(HAVE_AS_LEB128, 0,
2765     [Define if your assembler supports .sleb128 and .uleb128.])])
2766
2767 # Check if we have assembler support for unwind directives.
2768 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2769   ,,
2770 [       .text
2771         .cfi_startproc
2772         .cfi_offset 0, 0
2773         .cfi_same_value 1
2774         .cfi_def_cfa 1, 2
2775         .cfi_escape 1, 2, 3, 4, 5
2776         .cfi_endproc],
2777 [case "$target" in
2778   *-*-solaris*)
2779     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2780     # read-only and read-write sections, we need to make sure that the
2781     # assembler used emits read-write .eh_frame sections.
2782     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2783       if test "x$gcc_cv_objdump" != x; then
2784         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2785                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2786           gcc_cv_as_cfi_directive=no
2787         else
2788           case "$target" in
2789             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2790               # On Solaris/x86, make sure that GCC and assembler agree on using
2791               # read-only .eh_frame sections for 64-bit.
2792               if test x$gas = xyes; then
2793                  as_ix86_64_opt="--64"
2794               else
2795                  as_ix86_64_opt="-xarch=amd64"
2796               fi
2797               if $gcc_cv_as $as_ix86_64_opt -o conftest.o conftest.s > /dev/null 2>&1 && \
2798                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2799                         sed -e /.eh_frame/!d -e N | \
2800                         grep READONLY > /dev/null; then
2801                 gcc_cv_as_cfi_directive=yes
2802               else
2803                 gcc_cv_as_cfi_directive=no
2804               fi
2805               ;;
2806             *)
2807               gcc_cv_as_cfi_directive=yes
2808               ;;
2809           esac
2810         fi
2811       else
2812         # no objdump, err on the side of caution
2813         gcc_cv_as_cfi_directive=no
2814       fi
2815     else
2816       gcc_cv_as_cfi_directive=yes
2817     fi
2818     ;;
2819   *-*-*)
2820     gcc_cv_as_cfi_directive=yes
2821     ;;
2822 esac])
2823 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2824 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2825   ,,
2826 [       .text
2827         .cfi_startproc
2828         .cfi_adjust_cfa_offset 64
2829         .skip 75040, 0
2830         .cfi_adjust_cfa_offset 128
2831         .cfi_endproc],
2832 [[
2833 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2834     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2835    gcc_cv_as_cfi_advance_working=yes
2836 fi
2837 ]])
2838 else
2839   # no objdump, err on the side of caution
2840   gcc_cv_as_cfi_advance_working=no
2841 fi
2842 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2843 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2844   [`if test $gcc_cv_as_cfi_directive = yes \
2845        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2846   [Define 0/1 if your assembler supports CFI directives.])
2847
2848 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2849 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2850   gcc_cv_as_cfi_personality_directive, ,,
2851 [       .text
2852         .cfi_startproc
2853         .cfi_personality 0, symbol
2854         .cfi_endproc])
2855 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2856   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2857     then echo 1; else echo 0; fi`],
2858   [Define 0/1 if your assembler supports .cfi_personality.])
2859
2860 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2861   gcc_cv_as_cfi_sections_directive, ,,
2862 [       .text
2863         .cfi_sections .debug_frame, .eh_frame
2864         .cfi_startproc
2865         .cfi_endproc],
2866 [case $target_os in
2867   win32 | pe | cygwin* | mingw32*)
2868     # Need to check that we generated the correct relocation for the
2869     # .debug_frame section.  This was fixed for binutils 2.21.
2870     gcc_cv_as_cfi_sections_directive=no
2871     if test "x$gcc_cv_objdump" != x; then
2872      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2873         grep secrel > /dev/null; then
2874       gcc_cv_as_cfi_sections_directive=yes
2875      fi
2876     fi
2877     ;;
2878   *)
2879     gcc_cv_as_cfi_sections_directive=yes
2880     ;;
2881 esac])
2882 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2883 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2884   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2885     then echo 1; else echo 0; fi`],
2886   [Define 0/1 if your assembler supports .cfi_sections.])
2887
2888 # GAS versions up to and including 2.11.0 may mis-optimize
2889 # .eh_frame data.
2890 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2891   [elf,2,12,0],,
2892 [       .text
2893 .LFB1:
2894         .4byte  0
2895 .L1:
2896         .4byte  0
2897 .LFE1:
2898         .section        .eh_frame,"aw",@progbits
2899 __FRAME_BEGIN__:
2900         .4byte  .LECIE1-.LSCIE1
2901 .LSCIE1:
2902         .4byte  0x0
2903         .byte   0x1
2904         .ascii "z\0"
2905         .byte   0x1
2906         .byte   0x78
2907         .byte   0x1a
2908         .byte   0x0
2909         .byte   0x4
2910         .4byte  1
2911         .p2align 1
2912 .LECIE1:
2913 .LSFDE1:
2914         .4byte  .LEFDE1-.LASFDE1
2915 .LASFDE1:
2916         .4byte  .LASFDE1-__FRAME_BEGIN__
2917         .4byte  .LFB1
2918         .4byte  .LFE1-.LFB1
2919         .byte   0x4
2920         .4byte  .LFE1-.LFB1
2921         .byte   0x4
2922         .4byte  .L1-.LFB1
2923 .LEFDE1:],
2924 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2925 cat > conftest.lit <<EOF
2926  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2927  0010 01000000 12000000 18000000 00000000  ................
2928  0020 08000000 04080000 0044               .........D      @&t@
2929 EOF
2930 cat > conftest.big <<EOF
2931  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2932  0010 00000001 00000012 00000018 00000000  ................
2933  0020 00000008 04000000 0844               .........D      @&t@
2934 EOF
2935   # If the assembler didn't choke, and we can objdump,
2936   # and we got the correct data, then succeed.
2937   # The text in the here-document typically retains its unix-style line
2938   # endings, while the output of objdump will use host line endings.
2939   # Therefore, use diff -b for the comparisons.
2940   if test x$gcc_cv_objdump != x \
2941   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2942      | tail -3 > conftest.got \
2943   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2944     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2945   then
2946     gcc_cv_as_eh_frame=yes
2947   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2948     gcc_cv_as_eh_frame=buggy
2949   else
2950     # Uh oh, what do we do now?
2951     gcc_cv_as_eh_frame=no
2952   fi])
2953
2954 if test $gcc_cv_as_eh_frame = buggy; then
2955   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2956   [Define if your assembler mis-optimizes .eh_frame data.])
2957 fi
2958
2959 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2960  [elf,2,12,0], [--fatal-warnings],
2961  [.section .rodata.str, "aMS", @progbits, 1])
2962 if test $gcc_cv_as_shf_merge = no; then
2963   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2964     [elf,2,12,0], [--fatal-warnings],
2965     [.section .rodata.str, "aMS", %progbits, 1])
2966 fi
2967 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2968   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2969 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2970
2971 gcc_GAS_CHECK_FEATURE([stabs directive], gcc_cv_as_stabs_directive, ,,
2972 [.stabs "gcc2_compiled.",60,0,0,0],,
2973 [AC_DEFINE(HAVE_AS_STABS_DIRECTIVE, 1,
2974   [Define if your assembler supports .stabs.])])
2975
2976 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2977  gcc_cv_as_comdat_group,
2978  [elf,2,16,0], [--fatal-warnings],
2979  [.section .text,"axG",@progbits,.foo,comdat])
2980 if test $gcc_cv_as_comdat_group = yes; then
2981   gcc_cv_as_comdat_group_percent=no
2982   gcc_cv_as_comdat_group_group=no
2983 else
2984  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2985    gcc_cv_as_comdat_group_percent,
2986    [elf,2,16,0], [--fatal-warnings],
2987    [.section .text,"axG",%progbits,.foo,comdat])
2988  if test $gcc_cv_as_comdat_group_percent = yes; then
2989    gcc_cv_as_comdat_group_group=no
2990  else
2991    case "${target}" in
2992      # Sun as uses a completely different syntax.
2993      *-*-solaris2*)
2994        case "${target}" in
2995          sparc*-*-solaris2*)
2996            conftest_s='
2997                .group foo,".text%foo",#comdat
2998                .section ".text%foo", #alloc,#execinstr,#progbits
2999                .globl foo
3000              foo:
3001              '
3002            ;;
3003          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
3004            conftest_s='
3005                .group foo,.text%foo,#comdat
3006                .section .text%foo, "ax", @progbits
3007                .globl  foo
3008              foo:
3009              '
3010            ;;
3011        esac
3012        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
3013          gcc_cv_as_comdat_group_group,
3014          ,, [$conftest_s])
3015        ;;
3016    esac
3017    if test -z "${gcc_cv_as_comdat_group_group+set}"; then
3018      gcc_cv_as_comdat_group_group=no
3019    fi
3020  fi
3021 fi
3022 if test x"$ld_is_gold" = xyes; then
3023   comdat_group=yes
3024 elif test $in_tree_ld = yes ; then
3025   comdat_group=no
3026   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3027      && test $in_tree_ld_is_elf = yes; then
3028      comdat_group=yes
3029   fi
3030 elif echo "$ld_ver" | grep GNU > /dev/null; then
3031   comdat_group=yes
3032   if test 0"$ld_date" -lt 20050308; then
3033     if test -n "$ld_date"; then
3034       # If there was date string, but was earlier than 2005-03-08, fail
3035       comdat_group=no
3036     elif test "$ld_vers_major" -lt 2; then
3037       comdat_group=no
3038     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
3039       comdat_group=no
3040     fi
3041   fi
3042 else
3043 changequote(,)dnl
3044   case "${target}" in
3045     *-*-solaris2.1[1-9]*)
3046       comdat_group=no
3047       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
3048       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
3049       # version 1.688.
3050       #
3051       # If using Sun as for COMDAT group as emitted by GCC, one needs at
3052       # least ld version 1.2267.
3053       if test "$ld_vers_major" -gt 1; then
3054         comdat_group=yes
3055       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
3056         comdat_group=yes
3057       elif test "$ld_vers_minor" -ge 2267; then
3058         comdat_group=yes
3059       fi
3060       ;;
3061     *)
3062       # Assume linkers other than GNU ld don't support COMDAT group.
3063       comdat_group=no
3064       ;;
3065   esac
3066 changequote([,])dnl
3067 fi
3068 # Allow overriding the automatic COMDAT group tests above.
3069 AC_ARG_ENABLE(comdat,
3070   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
3071   [comdat_group="$enable_comdat"])
3072 if test $comdat_group = no; then
3073   gcc_cv_as_comdat_group=no
3074   gcc_cv_as_comdat_group_percent=no
3075   gcc_cv_as_comdat_group_group=no
3076 fi
3077 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
3078   [`if test $gcc_cv_as_comdat_group = yes \
3079     || test $gcc_cv_as_comdat_group_percent = yes \
3080     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
3081 [Define 0/1 if your assembler and linker support COMDAT groups.])
3082
3083 gcc_GAS_CHECK_FEATURE([line table discriminator support],
3084  gcc_cv_as_discriminator,
3085  [2,19,51],,
3086 [       .text
3087         .file 1 "conf.c"
3088         .loc 1 1 0 discriminator 1],,
3089 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
3090   [Define if your assembler supports the .loc discriminator sub-directive.])])
3091
3092 # Thread-local storage - the check is heavily parameterized.
3093 conftest_s=
3094 tls_first_major=
3095 tls_first_minor=
3096 tls_as_opt=
3097 case "$target" in
3098 changequote(,)dnl
3099   alpha*-*-*)
3100     conftest_s='
3101         .section ".tdata","awT",@progbits
3102 foo:    .long   25
3103         .text
3104         ldq     $27,__tls_get_addr($29)         !literal!1
3105         lda     $16,foo($29)                    !tlsgd!1
3106         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
3107         ldq     $27,__tls_get_addr($29)         !literal!2
3108         lda     $16,foo($29)                    !tlsldm!2
3109         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
3110         ldq     $1,foo($29)                     !gotdtprel
3111         ldah    $2,foo($29)                     !dtprelhi
3112         lda     $3,foo($2)                      !dtprello
3113         lda     $4,foo($29)                     !dtprel
3114         ldq     $1,foo($29)                     !gottprel
3115         ldah    $2,foo($29)                     !tprelhi
3116         lda     $3,foo($2)                      !tprello
3117         lda     $4,foo($29)                     !tprel'
3118         tls_first_major=2
3119         tls_first_minor=13
3120         tls_as_opt=--fatal-warnings
3121         ;;
3122   arc*-*-*)
3123     conftest_s='
3124         add_s r0,r0, @foo@tpoff'
3125         tls_first_major=2
3126         tls_first_minor=23
3127         ;;
3128   cris-*-*|crisv32-*-*)
3129     conftest_s='
3130         .section ".tdata","awT",@progbits
3131 x:      .long   25
3132         .text
3133         move.d x:IE,$r10
3134         nop'
3135         tls_first_major=2
3136         tls_first_minor=20
3137         tls_as_opt=--fatal-warnings
3138         ;;
3139   frv*-*-*)
3140     conftest_s='
3141         .section ".tdata","awT",@progbits
3142 x:      .long   25
3143         .text
3144         call    #gettlsoff(x)'
3145         tls_first_major=2
3146         tls_first_minor=14
3147         ;;
3148   hppa*-*-linux*)
3149     conftest_s='
3150 t1:     .reg    %r20
3151 t2:     .reg    %r21
3152 gp:     .reg    %r19
3153         .section ".tdata","awT",@progbits
3154 foo:    .long   25
3155         .text
3156         .align  4
3157         addil LT%foo-$tls_gdidx$,gp
3158         ldo RT%foo-$tls_gdidx$(%r1),%arg0
3159         b __tls_get_addr
3160         nop
3161         addil LT%foo-$tls_ldidx$,gp
3162         b __tls_get_addr
3163         ldo RT%foo-$tls_ldidx$(%r1),%arg0
3164         addil LR%foo-$tls_dtpoff$,%ret0
3165         ldo RR%foo-$tls_dtpoff$(%r1),%t1
3166         mfctl %cr27,%t1
3167         addil LT%foo-$tls_ieoff$,gp
3168         ldw RT%foo-$tls_ieoff$(%r1),%t2
3169         add %t1,%t2,%t3
3170         mfctl %cr27,%t1
3171         addil LR%foo-$tls_leoff$,%t1
3172         ldo RR%foo-$tls_leoff$(%r1),%t2'
3173         tls_first_major=2
3174         tls_first_minor=15
3175         tls_as_opt=--fatal-warnings
3176         ;;
3177   arm*-*-*)
3178     conftest_s='
3179         .section ".tdata","awT",%progbits
3180 foo:    .long   25
3181         .text
3182 .word foo(gottpoff)
3183 .word foo(tpoff)
3184 .word foo(tlsgd)
3185 .word foo(tlsldm)
3186 .word foo(tlsldo)'
3187         tls_first_major=2
3188         tls_first_minor=17
3189         ;;
3190   i[34567]86-*-* | x86_64-*-*)
3191     case "$target" in
3192       i[34567]86-*-solaris2.* | x86_64-*-solaris2.1[0-9]*)
3193         on_solaris=yes
3194         ;;
3195       *)
3196         on_solaris=no
3197         ;;
3198     esac
3199     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3200       conftest_s='
3201         .section .tdata,"awt",@progbits'
3202       tls_first_major=0
3203       tls_first_minor=0
3204       tls_section_flag=t
3205 changequote([,])dnl
3206       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
3207 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
3208 changequote(,)dnl
3209     else
3210       conftest_s='
3211         .section ".tdata","awT",@progbits'
3212       tls_first_major=2
3213       tls_first_minor=14
3214       tls_section_flag=T
3215       tls_as_opt="--fatal-warnings"
3216     fi
3217     case "$target" in
3218       i[34567]86-*-*)
3219         conftest_s="$conftest_s
3220 foo:    .long   25
3221         .text
3222         movl    %gs:0, %eax
3223         leal    foo@tlsgd(,%ebx,1), %eax
3224         leal    foo@tlsldm(%ebx), %eax
3225         leal    foo@dtpoff(%eax), %edx
3226         movl    foo@gottpoff(%ebx), %eax
3227         subl    foo@gottpoff(%ebx), %eax
3228         addl    foo@gotntpoff(%ebx), %eax
3229         movl    foo@indntpoff, %eax
3230         movl    \$foo@tpoff, %eax
3231         subl    \$foo@tpoff, %eax
3232         leal    foo@ntpoff(%ecx), %eax"
3233         ;;
3234       x86_64-*-*)
3235         if test x$on_solaris = xyes; then
3236           case $gas_flag in
3237             yes) tls_as_opt="$tls_as_opt --64" ;;
3238             no)  tls_as_opt="$tls_as_opt -xarch=amd64" ;;
3239           esac
3240         fi
3241         conftest_s="$conftest_s
3242 foo:    .long   25
3243         .text
3244         movq    %fs:0, %rax
3245         leaq    foo@tlsgd(%rip), %rdi
3246         leaq    foo@tlsld(%rip), %rdi
3247         leaq    foo@dtpoff(%rax), %rdx
3248         movq    foo@gottpoff(%rip), %rax
3249         movq    \$foo@tpoff, %rax"
3250         ;;
3251     esac
3252     ;;
3253   ia64-*-*)
3254     conftest_s='
3255         .section ".tdata","awT",@progbits
3256 foo:    data8   25
3257         .text
3258         addl    r16 = @ltoff(@dtpmod(foo#)), gp
3259         addl    r17 = @ltoff(@dtprel(foo#)), gp
3260         addl    r18 = @ltoff(@tprel(foo#)), gp
3261         addl    r19 = @dtprel(foo#), gp
3262         adds    r21 = @dtprel(foo#), r13
3263         movl    r23 = @dtprel(foo#)
3264         addl    r20 = @tprel(foo#), gp
3265         adds    r22 = @tprel(foo#), r13
3266         movl    r24 = @tprel(foo#)'
3267         tls_first_major=2
3268         tls_first_minor=13
3269         tls_as_opt=--fatal-warnings
3270         ;;
3271   microblaze*-*-*)
3272     conftest_s='
3273         .section .tdata,"awT",@progbits
3274 x:
3275         .word 2
3276         .text
3277         addik r5,r20,x@TLSGD
3278         addik r5,r20,x@TLSLDM'
3279         tls_first_major=2
3280         tls_first_minor=20
3281         tls_as_opt='--fatal-warnings'
3282         ;;
3283   mips*-*-*)
3284     conftest_s='
3285         .section .tdata,"awT",@progbits
3286 x:
3287         .word 2
3288         .text
3289         addiu $4, $28, %tlsgd(x)
3290         addiu $4, $28, %tlsldm(x)
3291         lui $4, %dtprel_hi(x)
3292         addiu $4, $4, %dtprel_lo(x)
3293         lw $4, %gottprel(x)($28)
3294         lui $4, %tprel_hi(x)
3295         addiu $4, $4, %tprel_lo(x)'
3296         tls_first_major=2
3297         tls_first_minor=16
3298         tls_as_opt='-32 --fatal-warnings'
3299         ;;
3300   m68k-*-*)
3301     conftest_s='
3302         .section .tdata,"awT",@progbits
3303 x:
3304         .word 2
3305         .text
3306 foo:
3307         move.l x@TLSGD(%a5),%a0
3308         move.l x@TLSLDM(%a5),%a0
3309         move.l x@TLSLDO(%a5),%a0
3310         move.l x@TLSIE(%a5),%a0
3311         move.l x@TLSLE(%a5),%a0'
3312         tls_first_major=2
3313         tls_first_minor=19
3314         tls_as_opt='--fatal-warnings'
3315         ;;
3316   nios2-*-*)
3317       conftest_s='
3318         .section ".tdata","awT",@progbits'
3319         tls_first_major=2
3320         tls_first_minor=23
3321         tls_as_opt="--fatal-warnings"
3322         ;;
3323   aarch64*-*-*)
3324     conftest_s='
3325         .section ".tdata","awT",%progbits
3326 foo:    .long   25
3327         .text
3328         adrp  x0, :tlsgd:x
3329         add   x0, x0, #:tlsgd_lo12:x
3330         bl    __tls_get_addr
3331         nop'
3332         tls_first_major=2
3333         tls_first_minor=20
3334         tls_as_opt='--fatal-warnings'
3335         ;;
3336   powerpc-ibm-aix*)
3337     conftest_s='
3338         .extern __get_tpointer
3339         .toc
3340 LC..1:
3341         .tc a[TC],a[TL]@le
3342         .csect .text[PR]
3343 .tlstest:
3344         lwz 9,LC..1(2)
3345         bla __get_tpointer
3346         lwzx 3,9,3
3347         .globl a
3348         .csect a[TL],4
3349 a:
3350         .space 4'
3351         tls_first_major=0
3352         tls_first_minor=0
3353         ;;
3354   powerpc64*-*-*)
3355     conftest_s='
3356         .section ".tdata","awT",@progbits
3357         .align 3
3358 ld0:    .space 8
3359 ld1:    .space 8
3360 x1:     .space 8
3361 x2:     .space 8
3362 x3:     .space 8
3363         .text
3364         addi 3,2,ld0@got@tlsgd
3365         bl .__tls_get_addr
3366         nop
3367         addi 3,2,ld1@toc
3368         bl .__tls_get_addr
3369         nop
3370         addi 3,2,x1@got@tlsld
3371         bl .__tls_get_addr
3372         nop
3373         addi 9,3,x1@dtprel
3374         bl .__tls_get_addr
3375         nop
3376         addis 9,3,x2@dtprel@ha
3377         addi 9,9,x2@dtprel@l
3378         bl .__tls_get_addr
3379         nop
3380         ld 9,x3@got@dtprel(2)
3381         add 9,9,3
3382         bl .__tls_get_addr
3383         nop'
3384         tls_first_major=2
3385         tls_first_minor=14
3386         tls_as_opt="-a64 --fatal-warnings"
3387         ;;
3388   powerpc*-*-*)
3389     conftest_s='
3390         .section ".tdata","awT",@progbits
3391         .align 2
3392 ld0:    .space 4
3393 ld1:    .space 4
3394 x1:     .space 4
3395 x2:     .space 4
3396 x3:     .space 4
3397         .text
3398         addi 3,31,ld0@got@tlsgd
3399         bl __tls_get_addr
3400         addi 3,31,x1@got@tlsld
3401         bl __tls_get_addr
3402         addi 9,3,x1@dtprel
3403         addis 9,3,x2@dtprel@ha
3404         addi 9,9,x2@dtprel@l
3405         lwz 9,x3@got@tprel(31)
3406         add 9,9,x@tls
3407         addi 9,2,x1@tprel
3408         addis 9,2,x2@tprel@ha
3409         addi 9,9,x2@tprel@l'
3410         tls_first_major=2
3411         tls_first_minor=14
3412         tls_as_opt="-a32 --fatal-warnings"
3413         ;;
3414   s390-*-*)
3415     conftest_s='
3416         .section ".tdata","awT",@progbits
3417 foo:    .long   25
3418         .text
3419         .long   foo@TLSGD
3420         .long   foo@TLSLDM
3421         .long   foo@DTPOFF
3422         .long   foo@NTPOFF
3423         .long   foo@GOTNTPOFF
3424         .long   foo@INDNTPOFF
3425         l       %r1,foo@GOTNTPOFF(%r12)
3426         l       %r1,0(%r1):tls_load:foo
3427         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3428         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3429         tls_first_major=2
3430         tls_first_minor=14
3431         tls_as_opt="-m31 --fatal-warnings"
3432         ;;
3433   s390x-*-*)
3434     conftest_s='
3435         .section ".tdata","awT",@progbits
3436 foo:    .long   25
3437         .text
3438         .quad   foo@TLSGD
3439         .quad   foo@TLSLDM
3440         .quad   foo@DTPOFF
3441         .quad   foo@NTPOFF
3442         .quad   foo@GOTNTPOFF
3443         lg      %r1,foo@GOTNTPOFF(%r12)
3444         larl    %r1,foo@INDNTPOFF
3445         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3446         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3447         tls_first_major=2
3448         tls_first_minor=14
3449         tls_as_opt="-m64 -Aesame --fatal-warnings"
3450         ;;
3451   sh-*-* | sh[123456789lbe]*-*-*)
3452     conftest_s='
3453         .section ".tdata","awT",@progbits
3454 foo:    .long   25
3455         .text
3456         .long   foo@TLSGD
3457         .long   foo@TLSLDM
3458         .long   foo@DTPOFF
3459         .long   foo@GOTTPOFF
3460         .long   foo@TPOFF'
3461         tls_first_major=2
3462         tls_first_minor=13
3463         tls_as_opt=--fatal-warnings
3464         ;;
3465   sparc*-*-*)
3466     case "$target" in
3467       sparc*-sun-solaris2.*)
3468         on_solaris=yes
3469         ;;
3470       *)
3471         on_solaris=no
3472         ;;
3473     esac
3474     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3475       conftest_s='
3476         .section ".tdata",#alloc,#write,#tls'
3477         tls_first_major=0
3478         tls_first_minor=0
3479     else
3480       conftest_s='
3481         .section ".tdata","awT",@progbits'
3482         tls_first_major=2
3483         tls_first_minor=14
3484         tls_as_opt="-32 --fatal-warnings"
3485     fi
3486     conftest_s="$conftest_s
3487 foo:    .long   25
3488         .text
3489         sethi   %tgd_hi22(foo), %o0
3490         add     %o0, %tgd_lo10(foo), %o1
3491         add     %l7, %o1, %o0, %tgd_add(foo)
3492         call    __tls_get_addr, %tgd_call(foo)
3493         sethi   %tldm_hi22(foo), %l1
3494         add     %l1, %tldm_lo10(foo), %l2
3495         add     %l7, %l2, %o0, %tldm_add(foo)
3496         call    __tls_get_addr, %tldm_call(foo)
3497         sethi   %tldo_hix22(foo), %l3
3498         xor     %l3, %tldo_lox10(foo), %l4
3499         add     %o0, %l4, %l5, %tldo_add(foo)
3500         sethi   %tie_hi22(foo), %o3
3501         add     %o3, %tie_lo10(foo), %o3
3502         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3503         add     %g7, %o2, %o4, %tie_add(foo)
3504         sethi   %tle_hix22(foo), %l1
3505         xor     %l1, %tle_lox10(foo), %o5
3506         ld      [%g7 + %o5], %o1"
3507         ;;
3508   tilepro*-*-*)
3509       conftest_s='
3510         .section ".tdata","awT",@progbits
3511 foo:    .long   25
3512         .text
3513         addli   r0, zero, tls_gd(foo)
3514         auli    r0, zero, tls_gd_ha16(foo)
3515         addli   r0, r0, tls_gd_lo16(foo)
3516         jal     __tls_get_addr
3517         addli   r0, zero, tls_ie(foo)
3518         auli    r0, r0, tls_ie_ha16(foo)
3519         addli   r0, r0, tls_ie_lo16(foo)'
3520         tls_first_major=2
3521         tls_first_minor=22
3522         tls_as_opt="--fatal-warnings"
3523         ;;
3524   tilegx*-*-*)
3525       conftest_s='
3526         .section ".tdata","awT",@progbits
3527 foo:    .long   25
3528         .text
3529         shl16insli r0, zero, hw0_last_tls_gd(foo)
3530         shl16insli r0, zero, hw1_last_tls_gd(foo)
3531         shl16insli r0, r0,   hw0_tls_gd(foo)
3532         jal        __tls_get_addr
3533         shl16insli r0, zero, hw1_last_tls_ie(foo)
3534         shl16insli r0, r0,   hw0_tls_ie(foo)'
3535         tls_first_major=2
3536         tls_first_minor=22
3537         tls_as_opt="--fatal-warnings"
3538         ;;
3539   xtensa*-*-*)
3540     conftest_s='
3541         .section ".tdata","awT",@progbits
3542 foo:    .long   25
3543         .text
3544         movi    a8, foo@TLSFUNC
3545         movi    a10, foo@TLSARG
3546         callx8.tls a8, foo@TLSCALL'
3547         tls_first_major=2
3548         tls_first_minor=19
3549         ;;
3550 changequote([,])dnl
3551 esac
3552 set_have_as_tls=no
3553 if test "x$enable_tls" = xno ; then
3554   : # TLS explicitly disabled.
3555 elif test "x$enable_tls" = xyes ; then
3556   set_have_as_tls=yes # TLS explicitly enabled.
3557 elif test -z "$tls_first_major"; then
3558   : # If we don't have a check, assume no support.
3559 else
3560   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3561   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3562   [set_have_as_tls=yes])
3563 fi
3564 if test $set_have_as_tls = yes ; then
3565   AC_DEFINE(HAVE_AS_TLS, 1,
3566             [Define if your assembler and linker support thread-local storage.])
3567 fi
3568
3569 # Target-specific assembler checks.
3570
3571 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3572 gcc_cv_ld_static_dynamic=no
3573 gcc_cv_ld_static_option='-Bstatic'
3574 gcc_cv_ld_dynamic_option='-Bdynamic'
3575 if test $in_tree_ld = yes ; then
3576   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3577     gcc_cv_ld_static_dynamic=yes
3578   fi
3579 elif test x$gcc_cv_ld != x; then
3580   # Check if linker supports -Bstatic/-Bdynamic option
3581   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3582      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3583       gcc_cv_ld_static_dynamic=yes
3584   else
3585     case "$target" in
3586       # AIX ld uses -b flags
3587       *-*-aix4.[[23]]* | *-*-aix[[5-9]]*)
3588         gcc_cv_ld_static_dynamic=yes
3589         gcc_cv_ld_static_option="-bstatic"
3590         gcc_cv_ld_dynamic_option="-bdynamic"
3591         ;;
3592       # HP-UX ld uses -a flags to select between shared and archive.
3593       *-*-hpux*)
3594         if test x"$gnu_ld" = xno; then
3595           gcc_cv_ld_static_dynamic=yes
3596           gcc_cv_ld_static_option="-aarchive_shared"
3597           gcc_cv_ld_dynamic_option="-adefault"
3598         fi
3599         ;;
3600       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3601       *-*-solaris2*)
3602         gcc_cv_ld_static_dynamic=yes
3603         ;;
3604     esac
3605   fi
3606 fi
3607 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3608         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3609 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3610         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3611 [Define to the linker option to disable use of shared objects.])
3612         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3613 [Define to the linker option to enable use of shared objects.])
3614 fi
3615 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3616
3617 if test x"$demangler_in_ld" = xyes; then
3618   AC_MSG_CHECKING(linker --demangle support)
3619   gcc_cv_ld_demangle=no
3620   if test $in_tree_ld = yes; then
3621     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3622       gcc_cv_ld_demangle=yes
3623     fi
3624   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3625     # Check if the GNU linker supports --demangle option
3626     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3627       gcc_cv_ld_demangle=yes
3628     fi
3629   fi
3630   if test x"$gcc_cv_ld_demangle" = xyes; then
3631     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3632 [Define if your linker supports --demangle option.])
3633   fi
3634   AC_MSG_RESULT($gcc_cv_ld_demangle)
3635 fi
3636
3637 AC_MSG_CHECKING(linker plugin support)
3638 gcc_cv_lto_plugin=0
3639 if test -f liblto_plugin.la; then
3640   save_ld_ver="$ld_ver"
3641   save_ld_vers_major="$ld_vers_major"
3642   save_ld_vers_minor="$ld_vers_minor"
3643   save_ld_is_gold="$ld_is_gold"
3644
3645   ld_is_gold=no
3646
3647   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3648     ld_ver="GNU ld"
3649     # FIXME: ld_is_gold?
3650     ld_vers_major="$gcc_cv_gld_major_version"
3651     ld_vers_minor="$gcc_cv_gld_minor_version"
3652   else
3653     # Determine plugin linker version.
3654     # FIXME: Partial duplicate from above, generalize.
3655 changequote(,)dnl
3656     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3657     if echo "$ld_ver" | grep GNU > /dev/null; then
3658       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3659         ld_is_gold=yes
3660         ld_vers=`echo $ld_ver | sed -n \
3661             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3662       else
3663         ld_vers=`echo $ld_ver | sed -n \
3664             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3665       fi
3666       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3667       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3668     fi
3669 changequote([,])dnl
3670   fi
3671
3672   # Determine plugin support.
3673   if echo "$ld_ver" | grep GNU > /dev/null; then
3674     # Require GNU ld or gold 2.21+ for plugin support by default.
3675     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3676       gcc_cv_lto_plugin=2
3677     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3678     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3679       gcc_cv_lto_plugin=1
3680     fi
3681   fi
3682
3683   ld_ver="$save_ld_ver"
3684   ld_vers_major="$save_ld_vers_major"
3685   ld_vers_minor="$save_ld_vers_minor"
3686   ld_is_gold="$save_ld_is_gold"
3687 fi
3688 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3689   [Define to the level of your linker's plugin support.])
3690 AC_MSG_RESULT($gcc_cv_lto_plugin)
3691
3692 # Target OS-specific assembler checks.
3693
3694 case "$target_os" in
3695   darwin*)
3696     gcc_GAS_CHECK_FEATURE([-mmacosx-version-min option],
3697       gcc_cv_as_mmacosx_version_min,,
3698       [-mmacosx-version-min=10.1], [.text],,
3699       [AC_DEFINE(HAVE_AS_MMACOSX_VERSION_MIN_OPTION, 1,
3700         [Define if your Mac OS X assembler supports the -mmacos-version-min option.])])
3701     ;;
3702 esac
3703
3704 # Target CPU-specific assembler checks.
3705
3706 case "$target" in
3707   aarch64*-*-*)
3708     gcc_GAS_CHECK_FEATURE([-mabi option], gcc_cv_as_aarch64_mabi,,
3709                           [-mabi=lp64], [.text],,,)
3710     if test x$gcc_cv_as_aarch64_mabi = xyes; then
3711       AC_DEFINE(HAVE_AS_MABI_OPTION, 1,
3712                 [Define if your assembler supports the -mabi option.])
3713     else
3714       if test x$with_abi = xilp32; then
3715         AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3716                      Upgrade the Assembler.])
3717       fi
3718       if test x"$with_multilib_list" = xdefault; then
3719         TM_MULTILIB_CONFIG=lp64
3720       else
3721         aarch64_multilibs=`echo $with_multilib_list | sed -e 's/,/ /g'`
3722         for aarch64_multilib in ${aarch64_multilibs}; do
3723           case ${aarch64_multilib} in
3724             ilp32)
3725               AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3726                             Upgrade the Assembler.])
3727               ;;
3728             *)
3729               ;;
3730           esac
3731         done
3732       fi
3733     fi
3734     # Check if we have binutils support for relocations types needed by -fpic
3735     gcc_GAS_CHECK_FEATURE([-fpic relocs], gcc_cv_as_aarch64_picreloc,,,
3736     [
3737         .text
3738         ldr     x0, [[x2, #:gotpage_lo15:globalsym]]
3739     ],,[AC_DEFINE(HAVE_AS_SMALL_PIC_RELOCS, 1,
3740         [Define if your assembler supports relocs needed by -fpic.])])
3741     # Enable default workaround for AArch64 Cortex-A53 erratum 835769.
3742     AC_ARG_ENABLE(fix-cortex-a53-835769,
3743     [
3744 AS_HELP_STRING([--enable-fix-cortex-a53-835769],
3745         [enable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3746 AS_HELP_STRING([--disable-fix-cortex-a53-835769],
3747         [disable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3748     ],
3749       [
3750         case $enableval in
3751           yes)
3752             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_835769_DEFAULT=1"
3753             ;;
3754           no)
3755             ;;
3756           *)
3757             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-835769.\
3758   Valid choices are 'yes' and 'no'.])
3759             ;;
3760
3761         esac
3762       ],
3763     [])
3764     # Enable default workaround for AArch64 Cortex-A53 erratum 843419.
3765     AC_ARG_ENABLE(fix-cortex-a53-843419,
3766     [
3767 AS_HELP_STRING([--enable-fix-cortex-a53-843419],
3768         [enable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3769 AS_HELP_STRING([--disable-fix-cortex-a53-843419],
3770         [disable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3771     ],
3772       [
3773         case $enableval in
3774           yes)
3775             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_843419_DEFAULT=1"
3776             ;;
3777           no)
3778             ;;
3779           *)
3780             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-843419.\
3781   Valid choices are 'yes' and 'no'.])
3782             ;;
3783
3784         esac
3785       ],
3786     [])
3787     ;;
3788
3789   # All TARGET_ABI_OSF targets.
3790   alpha*-*-linux* | alpha*-*-*bsd*)
3791     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3792         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3793 [       .set nomacro
3794         .text
3795         extbl   $3, $2, $3      !lituse_bytoff!1
3796         ldq     $2, a($29)      !literal!1
3797         ldq     $4, b($29)      !literal!2
3798         ldq_u   $3, 0($2)       !lituse_base!1
3799         ldq     $27, f($29)     !literal!5
3800         jsr     $26, ($27), f   !lituse_jsr!5
3801         ldah    $29, 0($26)     !gpdisp!3
3802         lda     $0, c($29)      !gprel
3803         ldah    $1, d($29)      !gprelhigh
3804         lda     $1, d($1)       !gprellow
3805         lda     $29, 0($29)     !gpdisp!3],,
3806     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3807   [Define if your assembler supports explicit relocations.])])
3808     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3809         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3810 [       .set nomacro
3811         .text
3812         ldq     $27, a($29)     !literal!1
3813         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3814     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3815   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3816     ;;
3817
3818   avr-*-*)
3819     gcc_GAS_CHECK_FEATURE([--mlink-relax option], gcc_cv_as_avr_mlink_relax,,
3820       [--mlink-relax], [.text],,
3821       [AC_DEFINE(HAVE_AS_AVR_MLINK_RELAX_OPTION, 1,
3822                 [Define if your avr assembler supports --mlink-relax option.])])
3823
3824     gcc_GAS_CHECK_FEATURE([-mrmw option], gcc_cv_as_avr_mrmw,,
3825       [-mrmw], [.text],,
3826       [AC_DEFINE(HAVE_AS_AVR_MRMW_OPTION, 1,
3827                 [Define if your avr assembler supports -mrmw option.])])
3828     ;;
3829
3830   cris-*-*)
3831     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3832       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3833       [-no-mul-bug-abort], [.text],,
3834       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3835                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3836     ;;
3837
3838   sparc*-*-*)
3839     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3840       [.register %g2, #scratch],,
3841       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3842                 [Define if your assembler supports .register.])])
3843
3844     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3845       [-relax], [.text],,
3846       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3847                 [Define if your assembler supports -relax option.])])
3848
3849     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3850       gcc_cv_as_sparc_gotdata_op,,
3851       [-K PIC],
3852 [.text
3853 .align 4
3854 foo:
3855         nop
3856 bar:
3857         sethi %gdop_hix22(foo), %g1
3858         xor    %g1, %gdop_lox10(foo), %g1
3859         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3860       [if test x$gcc_cv_ld != x \
3861        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3862          if test x$gcc_cv_objdump != x; then
3863            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3864               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3865                gcc_cv_as_sparc_gotdata_op=no
3866            else
3867                gcc_cv_as_sparc_gotdata_op=yes
3868            fi
3869          fi
3870        fi
3871        rm -f conftest],
3872       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3873                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3874
3875     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3876       gcc_cv_as_sparc_ua_pcrel,,
3877       [-K PIC],
3878 [.text
3879 foo:
3880         nop
3881 .data
3882 .align 4
3883 .byte 0
3884 .uaword %r_disp32(foo)],
3885       [if test x$gcc_cv_ld != x \
3886        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3887          gcc_cv_as_sparc_ua_pcrel=yes
3888        fi
3889        rm -f conftest],
3890       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3891                 [Define if your assembler and linker support unaligned PC relative relocs.])
3892
3893       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3894         gcc_cv_as_sparc_ua_pcrel_hidden,,
3895         [-K PIC],
3896 [.data
3897 .align 4
3898 .byte 0x31
3899 .uaword %r_disp32(foo)
3900 .byte 0x32, 0x33, 0x34
3901 .global foo
3902 .hidden foo
3903 foo:
3904 .skip 4],
3905         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3906          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3907          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3908             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3909             if $gcc_cv_objdump -R conftest 2> /dev/null \
3910                | grep 'DISP32' > /dev/null 2>&1; then
3911                 :
3912             else
3913                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3914             fi
3915          fi
3916          rm -f conftest],
3917          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3918                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3919     ]) # unaligned pcrel relocs
3920
3921     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3922       gcc_cv_as_sparc_offsetable_lo10,,
3923       [-xarch=v9],
3924 [.text
3925         or %g1, %lo(ab) + 12, %g1
3926         or %g1, %lo(ab + 12), %g1],
3927       [if test x$gcc_cv_objdump != x \
3928        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3929           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3930          gcc_cv_as_sparc_offsetable_lo10=yes
3931        fi],
3932        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3933                  [Define if your assembler supports offsetable %lo().])])
3934
3935     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3936       gcc_cv_as_sparc_fmaf,,
3937       [-xarch=v9d],
3938       [.text
3939        .register %g2, #scratch
3940        .register %g3, #scratch
3941        .align 4
3942        fmaddd %f0, %f2, %f4, %f6
3943        addxccc %g1, %g2, %g3
3944        fsrl32 %f2, %f4, %f8
3945        fnaddd %f10, %f12, %f14],,
3946       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3947                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3948
3949     gcc_GAS_CHECK_FEATURE([SPARC4 instructions],
3950       gcc_cv_as_sparc_sparc4,,
3951       [-xarch=sparc4],
3952       [.text
3953        .register %g2, #scratch
3954        .register %g3, #scratch
3955        .align 4
3956        cxbe %g2, %g3, 1f
3957 1:     cwbneg %g2, %g3, 1f
3958 1:     sha1
3959        md5
3960        aes_kexpand0 %f4, %f6, %f8
3961        des_round %f38, %f40, %f42, %f44
3962        camellia_f %f54, %f56, %f58, %f60
3963        kasumi_fi_xor %f46, %f48, %f50, %f52],,
3964       [AC_DEFINE(HAVE_AS_SPARC4, 1,
3965                 [Define if your assembler supports SPARC4 instructions.])])
3966
3967     gcc_GAS_CHECK_FEATURE([SPARC5 and VIS 4.0 instructions],
3968       gcc_cv_as_sparc_sparc5,,
3969       [-xarch=sparc5],
3970       [.text
3971        .register %g2, #scratch
3972        .register %g3, #scratch
3973        .align 4
3974        subxc %g1, %g2, %g3
3975        fpadd8 %f0, %f2, %f4],,
3976       [AC_DEFINE(HAVE_AS_SPARC5_VIS4, 1,
3977                 [Define if your assembler supports SPARC5 and VIS 4.0 instructions.])])
3978
3979     gcc_GAS_CHECK_FEATURE([LEON instructions],
3980       gcc_cv_as_sparc_leon,,
3981       [-Aleon],
3982       [.text
3983        .register %g2, #scratch
3984        .register %g3, #scratch
3985        .align 4
3986        smac %g2, %g3, %g1
3987        umac %g2, %g3, %g1
3988        casa [[%g2]] 0xb, %g3, %g1],,
3989       [AC_DEFINE(HAVE_AS_LEON, 1,
3990                 [Define if your assembler supports LEON instructions.])])
3991     ;;
3992
3993 changequote(,)dnl
3994   i[34567]86-*-* | x86_64-*-*)
3995 changequote([,])dnl
3996     case $target_os in
3997       cygwin*)
3998         # Full C++ conformance when using a shared libstdc++-v3 requires some
3999         # support from the Cygwin DLL, which in more recent versions exports
4000         # wrappers to aid in interposing and redirecting operators new, delete,
4001         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
4002         # are configuring for a version of Cygwin that exports the wrappers.
4003         if test x$host = x$target && test x$host_cpu = xi686; then
4004           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
4005         else
4006           # Can't check presence of libc functions during cross-compile, so
4007           # we just have to assume we're building for an up-to-date target.
4008           gcc_ac_cygwin_dll_wrappers=yes
4009         fi
4010         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
4011           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
4012           [Define if you want to generate code by default that assumes that the
4013            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
4014     esac
4015     case $target_os in
4016       cygwin* | pe | mingw32*)
4017         # Recent binutils allows the three-operand form of ".comm" on PE.  This
4018         # definition is used unconditionally to initialise the default state of
4019         # the target option variable that governs usage of the feature.
4020         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
4021          [2,19,52],,[.comm foo,1,32])
4022         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
4023           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
4024           [Define if your assembler supports specifying the alignment
4025            of objects allocated using the GAS .comm command.])
4026         # Used for DWARF 2 in PE
4027         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
4028           gcc_cv_as_ix86_pe_secrel32,
4029           [2,15,91],,
4030 [.text
4031 foo:    nop
4032 .data
4033         .secrel32 foo],
4034           [if test x$gcc_cv_ld != x \
4035            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
4036              gcc_cv_as_ix86_pe_secrel32=yes
4037            fi
4038            rm -f conftest],
4039           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
4040             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
4041         # Test if the assembler supports the extended form of the .section
4042         # directive that specifies section alignment.  LTO support uses this,
4043         # but normally only after installation, so we warn but don't fail the
4044         # configure if LTO is enabled but the assembler does not support it.
4045         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
4046           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
4047         if test x$gcc_cv_as_section_has_align != xyes; then
4048           case ",$enable_languages," in
4049             *,lto,*)
4050               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
4051               ;;
4052           esac
4053         fi
4054         ;;
4055     esac
4056
4057     # Test if the assembler supports the section flag 'e' for specifying
4058     # an excluded section.
4059     gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
4060       [2,22,51], [--fatal-warnings],
4061 [.section foo1,"e"
4062 .byte 0,0,0,0])
4063     AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
4064       [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
4065       [Define if your assembler supports specifying the section flag e.])
4066
4067     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
4068        gcc_cv_as_ix86_filds,,,
4069        [filds (%ebp); fists (%ebp)],,
4070        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
4071          [Define if your assembler uses filds and fists mnemonics.])])
4072
4073     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
4074        gcc_cv_as_ix86_fildq,,,
4075        [fildq (%ebp); fistpq (%ebp)],,
4076        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
4077          [Define if your assembler uses fildq and fistq mnemonics.])])
4078
4079     gcc_GAS_CHECK_FEATURE([cmov syntax],
4080       gcc_cv_as_ix86_cmov_sun_syntax,,,
4081       [cmovl.l %edx, %eax],,
4082       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
4083         [Define if your assembler supports the Sun syntax for cmov.])])
4084
4085     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
4086       gcc_cv_as_ix86_ffreep,,,
4087       [ffreep %st(1)],,
4088       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
4089         [Define if your assembler supports the ffreep mnemonic.])])
4090
4091     gcc_GAS_CHECK_FEATURE([.quad directive],
4092       gcc_cv_as_ix86_quad,,,
4093       [.quad 0],,
4094       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
4095         [Define if your assembler supports the .quad directive.])])
4096
4097     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
4098       gcc_cv_as_ix86_sahf,,,
4099       [.code64
4100        sahf],,
4101       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
4102         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
4103
4104     gcc_GAS_CHECK_FEATURE([interunit movq mnemonic],
4105       gcc_cv_as_ix86_interunit_movq,,,
4106       [.code64
4107        movq %mm0, %rax
4108        movq %rax, %xmm0])
4109     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_INTERUNIT_MOVQ,
4110       [`if test $gcc_cv_as_ix86_interunit_movq = yes; then echo 1; else echo 0; fi`],
4111       [Define if your assembler supports interunit movq mnemonic.])
4112
4113     gcc_GAS_CHECK_FEATURE([hle prefixes],
4114       gcc_cv_as_ix86_hle,,,
4115       [lock xacquire cmpxchg %esi, (%ecx)],,
4116       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
4117         [Define if your assembler supports HLE prefixes.])])
4118
4119     gcc_GAS_CHECK_FEATURE([swap suffix],
4120       gcc_cv_as_ix86_swap,,,
4121       [movl.s %esp, %ebp],,
4122       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
4123         [Define if your assembler supports the swap suffix.])])
4124
4125     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
4126       gcc_cv_as_ix86_diff_sect_delta,,,
4127       [.section .rodata
4128 .L1:
4129         .long .L2-.L1
4130         .long .L3-.L1
4131         .text
4132 .L3:    nop
4133 .L2:    nop],,
4134       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
4135         [Define if your assembler supports the subtraction of symbols in different sections.])])
4136
4137     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
4138         gcc_cv_as_ix86_rep_lock_prefix,,,
4139         [rep movsl
4140          rep ret
4141          rep nop
4142          rep bsf %ecx, %eax
4143          rep bsr %ecx, %eax
4144          lock addl %edi, (%eax,%esi)
4145          lock orl $0, (%esp)],,
4146         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
4147           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
4148
4149     gcc_GAS_CHECK_FEATURE([ud2 mnemonic],
4150         gcc_cv_as_ix86_ud2,,,
4151         [ud2],,
4152       [AC_DEFINE(HAVE_AS_IX86_UD2, 1,
4153         [Define if your assembler supports the 'ud2' mnemonic.])])
4154
4155     # Enforce 32-bit output with gas and gld.
4156     if test x$gas = xyes; then
4157       as_ix86_gas_32_opt="--32"
4158     fi
4159     if echo "$ld_ver" | grep GNU > /dev/null; then
4160       if $gcc_cv_ld -V 2>/dev/null | grep elf_i386_sol2 > /dev/null; then
4161         ld_ix86_gld_32_opt="-melf_i386_sol2"
4162       else
4163         ld_ix86_gld_32_opt="-melf_i386"
4164       fi
4165     fi
4166
4167     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
4168         gcc_cv_as_ix86_tlsgdplt,,
4169         [$as_ix86_gas_32_opt],
4170         [call    tls_gd@tlsgdplt],
4171         [if test x$gcc_cv_ld != x \
4172          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4173            gcc_cv_as_ix86_tlsgdplt=yes
4174          fi
4175          rm -f conftest],
4176       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
4177         [Define if your assembler and linker support @tlsgdplt.])])
4178
4179     conftest_s='
4180         .section .tdata,"aw'$tls_section_flag'",@progbits
4181 tls_ld:
4182         .section .text,"ax",@progbits
4183          call    tls_ld@tlsldmplt'
4184
4185     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
4186         gcc_cv_as_ix86_tlsldmplt,,
4187         [$as_ix86_gas_32_opt],
4188         [$conftest_s],
4189         [if test x$gcc_cv_ld != x \
4190          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4191            gcc_cv_as_ix86_tlsldmplt=yes
4192          fi
4193          rm -f conftest])
4194     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDMPLT,
4195       [`if test $gcc_cv_as_ix86_tlsldmplt = yes; then echo 1; else echo 0; fi`],
4196       [Define to 1 if your assembler and linker support @tlsldmplt.])
4197
4198     conftest_s='
4199         .section .text,"ax",@progbits
4200         .globl  _start
4201         .type   _start, @function
4202 _start:
4203         leal    value@tlsldm(%ebx), %eax
4204         call    ___tls_get_addr@plt
4205
4206         .section .tdata,"aw'$tls_section_flag'",@progbits
4207         .type   value, @object
4208 value:'
4209     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM reloc],
4210         gcc_cv_as_ix86_tlsldm,,
4211         [$as_ix86_gas_32_opt],
4212         [$conftest_s],
4213         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4214             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o $ld_tls_libs -lc > /dev/null 2>&1; then
4215            if $gcc_cv_objdump -d conftest 2>/dev/null | grep nop > /dev/null \
4216               || dis conftest 2>/dev/null | grep nop > /dev/null; then
4217              gcc_cv_as_ix86_tlsldm=yes
4218            fi
4219          fi
4220          rm -f conftest])
4221     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDM,
4222       [`if test $gcc_cv_as_ix86_tlsldm = yes; then echo 1; else echo 0; fi`],
4223       [Define to 1 if your assembler and linker support @tlsldm.])
4224
4225     conftest_s='
4226         .data
4227 bar:
4228         .byte 1
4229         .text
4230         .global _start
4231 _start:
4232          cmpl $0, bar@GOT
4233          jmp *_start@GOT'
4234     gcc_GAS_CHECK_FEATURE([R_386_GOT32X reloc],
4235         gcc_cv_as_ix86_got32x,,
4236         [$as_ix86_gas_32_opt],
4237         [$conftest_s],
4238         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4239             && test x$gcc_cv_readelf != x \
4240             && $gcc_cv_readelf --relocs --wide conftest.o 2>&1 \
4241                | grep R_386_GOT32X > /dev/null 2>&1 \
4242             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4243            if $gcc_cv_objdump -dw conftest 2>&1 \
4244               | grep 0xffffff > /dev/null 2>&1; then
4245              gcc_cv_as_ix86_got32x=no
4246            else
4247              gcc_cv_as_ix86_got32x=yes
4248            fi
4249          fi
4250          rm -f conftest])
4251     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_GOT32X,
4252       [`if test x"$gcc_cv_as_ix86_got32x" = xyes; then echo 1; else echo 0; fi`],
4253       [Define 0/1 if your assembler and linker support @GOT.])
4254
4255     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
4256       gcc_cv_as_ix86_gotoff_in_data, [2,11,0],
4257       [$as_ix86_gas_32_opt],
4258 [       .text
4259 .L0:
4260         nop
4261         .data
4262         .long .L0@GOTOFF])
4263     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
4264       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
4265       [Define true if the assembler supports '.long foo@GOTOFF'.])
4266
4267     conftest_s='
4268         .section .text,"ax",@progbits
4269         .globl  _start
4270         .type   _start, @function
4271 _start:
4272         leal    ld@tlsldm(%ecx), %eax
4273         call    *___tls_get_addr@GOT(%ecx)
4274         leal    gd@tlsgd(%ecx), %eax
4275         call    *___tls_get_addr@GOT(%ecx)
4276
4277         .section .tdata,"aw'$tls_section_flag'",@progbits
4278         .type   ld, @object
4279 ld:
4280         .byte 0
4281         .globl  gd
4282         .type   gd, @object
4283 gd:
4284         .byte 0'
4285     gcc_GAS_CHECK_FEATURE([calling ___tls_get_addr via GOT],
4286         gcc_cv_as_ix86_tls_get_addr_via_got,,
4287         [$as_ix86_gas_32_opt],
4288         [$conftest_s],
4289         [if test x$gcc_cv_ld != x \
4290             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4291            gcc_cv_as_ix86_tls_get_addr_via_got=yes
4292          fi
4293          rm -f conftest])
4294     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLS_GET_ADDR_GOT,
4295       [`if test x"$gcc_cv_as_ix86_tls_get_addr_via_got" = xyes; then echo 1; else echo 0; fi`],
4296       [Define 0/1 if your assembler and linker support calling ___tls_get_addr via GOT.])
4297     ;;
4298
4299   ia64*-*-*)
4300     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
4301         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
4302 [       .text
4303         addl r15 = @ltoffx(x#), gp
4304         ;;
4305         ld8.mov r16 = [[r15]], x#],,
4306     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
4307           [Define if your assembler supports ltoffx and ldxmov relocations.])])
4308
4309     ;;
4310
4311   powerpc*-*-*)
4312
4313     case $target in
4314       *-*-darwin*)
4315         gcc_GAS_CHECK_FEATURE([.machine directive support],
4316           gcc_cv_as_machine_directive,,,
4317           [     .machine ppc7400])
4318         if test x$gcc_cv_as_machine_directive != xyes; then
4319           echo "*** This target requires an assembler supporting \".machine\"" >&2
4320           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
4321           test x$build = x$target && exit 1
4322         fi
4323         ;;
4324     esac
4325
4326     case $target in
4327       *-*-aix*) conftest_s='    .machine "pwr5"
4328         .csect .text[[PR]]
4329         mfcr 3,128';;
4330       *-*-darwin*) conftest_s=' .text
4331         mfcr r3,128';;
4332       *) conftest_s='   .machine power4
4333         .text
4334         mfcr 3,128';;
4335     esac
4336
4337     gcc_GAS_CHECK_FEATURE([mfcr field support],
4338       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
4339       [$conftest_s],,
4340       [AC_DEFINE(HAVE_AS_MFCRF, 1,
4341           [Define if your assembler supports mfcr field.])])
4342
4343     case $target in
4344       *-*-aix*) conftest_s='    .machine "pwr5"
4345         .csect .text[[PR]]
4346         popcntb 3,3';;
4347       *) conftest_s='   .machine power5
4348         .text
4349         popcntb 3,3';;
4350     esac
4351
4352     gcc_GAS_CHECK_FEATURE([popcntb support],
4353       gcc_cv_as_powerpc_popcntb, [2,17,0],,
4354       [$conftest_s],,
4355       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
4356           [Define if your assembler supports popcntb field.])])
4357
4358     case $target in
4359       *-*-aix*) conftest_s='    .machine "pwr5x"
4360         .csect .text[[PR]]
4361         frin 1,1';;
4362       *) conftest_s='   .machine power5
4363         .text
4364         frin 1,1';;
4365     esac
4366
4367     gcc_GAS_CHECK_FEATURE([fp round support],
4368       gcc_cv_as_powerpc_fprnd, [2,17,0],,
4369       [$conftest_s],,
4370       [AC_DEFINE(HAVE_AS_FPRND, 1,
4371           [Define if your assembler supports fprnd.])])
4372
4373     case $target in
4374       *-*-aix*) conftest_s='    .machine "pwr6"
4375         .csect .text[[PR]]
4376         mffgpr 1,3';;
4377       *) conftest_s='   .machine power6
4378         .text
4379         mffgpr 1,3';;
4380     esac
4381
4382     gcc_GAS_CHECK_FEATURE([move fp gpr support],
4383       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
4384       [$conftest_s],,
4385       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
4386           [Define if your assembler supports mffgpr and mftgpr.])])
4387
4388     case $target in
4389       *-*-aix*) conftest_s='    .csect .text[[PR]]
4390 LCF..0:
4391         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
4392       *-*-darwin*)
4393         conftest_s='    .text
4394 LCF0:
4395         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
4396       *) conftest_s='   .text
4397 .LCF0:
4398         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
4399     esac
4400
4401     gcc_GAS_CHECK_FEATURE([rel16 relocs],
4402       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
4403       [$conftest_s],,
4404       [AC_DEFINE(HAVE_AS_REL16, 1,
4405           [Define if your assembler supports R_PPC_REL16 relocs.])])
4406
4407     case $target in
4408       *-*-aix*) conftest_s='    .machine "pwr6"
4409         .csect .text[[PR]]
4410         cmpb 3,4,5';;
4411       *) conftest_s='   .machine power6
4412         .text
4413         cmpb 3,4,5';;
4414     esac
4415
4416     gcc_GAS_CHECK_FEATURE([compare bytes support],
4417       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
4418       [$conftest_s],,
4419       [AC_DEFINE(HAVE_AS_CMPB, 1,
4420           [Define if your assembler supports cmpb.])])
4421
4422     case $target in
4423       *-*-aix*) conftest_s='    .machine "pwr6"
4424         .csect .text[[PR]]
4425         dadd 1,2,3';;
4426       *) conftest_s='   .machine power6
4427         .text
4428         dadd 1,2,3';;
4429     esac
4430
4431     gcc_GAS_CHECK_FEATURE([decimal float support],
4432       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
4433       [$conftest_s],,
4434       [AC_DEFINE(HAVE_AS_DFP, 1,
4435           [Define if your assembler supports DFP instructions.])])
4436
4437     case $target in
4438       *-*-aix*) conftest_s='    .machine "pwr7"
4439         .csect .text[[PR]]
4440         lxvd2x 1,2,3';;
4441       *) conftest_s='   .machine power7
4442         .text
4443         lxvd2x 1,2,3';;
4444     esac
4445
4446     gcc_GAS_CHECK_FEATURE([vector-scalar support],
4447       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
4448       [$conftest_s],,
4449       [AC_DEFINE(HAVE_AS_VSX, 1,
4450           [Define if your assembler supports VSX instructions.])])
4451
4452     case $target in
4453       *-*-aix*) conftest_s='    .machine "pwr7"
4454         .csect .text[[PR]]
4455         popcntd 3,3';;
4456       *) conftest_s='   .machine power7
4457         .text
4458         popcntd 3,3';;
4459     esac
4460
4461     gcc_GAS_CHECK_FEATURE([popcntd support],
4462       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
4463       [$conftest_s],,
4464       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
4465           [Define if your assembler supports POPCNTD instructions.])])
4466
4467     case $target in
4468       *-*-aix*) conftest_s='    .machine "pwr8"
4469         .csect .text[[PR]]';;
4470       *) conftest_s='   .machine power8
4471         .text';;
4472     esac
4473
4474     gcc_GAS_CHECK_FEATURE([power8 support],
4475       gcc_cv_as_powerpc_power8, [2,19,2], -a32,
4476       [$conftest_s],,
4477       [AC_DEFINE(HAVE_AS_POWER8, 1,
4478           [Define if your assembler supports POWER8 instructions.])])
4479
4480     case $target in
4481       *-*-aix*) conftest_s='    .machine "pwr9"
4482         .csect .text[[PR]]';;
4483       *) conftest_s='   .machine power9
4484         .text';;
4485     esac
4486
4487     gcc_GAS_CHECK_FEATURE([power9 support],
4488       gcc_cv_as_powerpc_power9, [2,19,2], -a32,
4489       [$conftest_s],,
4490       [AC_DEFINE(HAVE_AS_POWER9, 1,
4491           [Define if your assembler supports POWER9 instructions.])])
4492
4493     case $target in
4494       *-*-aix*) conftest_s='    .csect .text[[PR]]
4495         lwsync';;
4496       *) conftest_s='   .text
4497         lwsync';;
4498     esac
4499
4500     gcc_GAS_CHECK_FEATURE([lwsync support],
4501       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
4502       [$conftest_s],,
4503       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
4504           [Define if your assembler supports LWSYNC instructions.])])
4505
4506     case $target in
4507       *-*-aix*) conftest_s='    .machine "476"
4508         .csect .text[[PR]]
4509         dci 0';;
4510       *) conftest_s='   .machine "476"
4511         .text
4512         dci 0';;
4513     esac
4514
4515     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
4516       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
4517       [$conftest_s],,
4518       [AC_DEFINE(HAVE_AS_DCI, 1,
4519           [Define if your assembler supports the DCI/ICI instructions.])])
4520
4521     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4522       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
4523       [.gnu_attribute 4,1],,
4524       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4525           [Define if your assembler supports .gnu_attribute.])])
4526
4527     gcc_GAS_CHECK_FEATURE([tls marker support],
4528       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
4529       [ bl __tls_get_addr(x@tlsgd)],,
4530       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
4531           [Define if your assembler supports arg info for __tls_get_addr.])])
4532
4533     gcc_GAS_CHECK_FEATURE([prologue entry point marker support],
4534       gcc_cv_as_powerpc_entry_markers, [2,26,0],-a64 --fatal-warnings,
4535       [ .reloc .,R_PPC64_ENTRY; nop],,
4536       [AC_DEFINE(HAVE_AS_ENTRY_MARKERS, 1,
4537           [Define if your assembler supports the R_PPC64_ENTRY relocation.])])
4538
4539     case $target in
4540       *-*-aix*)
4541         gcc_GAS_CHECK_FEATURE([AIX .ref support],
4542           gcc_cv_as_aix_ref, [2,21,0],,
4543           [     .csect stuff[[rw]]
4544              stuff:
4545                 .long 1
4546                 .extern sym
4547                 .ref sym
4548           ],,
4549           [AC_DEFINE(HAVE_AS_REF, 1,
4550             [Define if your assembler supports .ref])])
4551
4552         gcc_GAS_CHECK_FEATURE([AIX DWARF location lists section support],
4553           gcc_cv_as_aix_dwloc, [2,21,0],,
4554           [     .dwsect 0xA0000
4555         Lframe..0:
4556                 .vbyte 4,Lframe..0
4557           ],,
4558           [AC_DEFINE(HAVE_XCOFF_DWARF_EXTRAS, 1,
4559             [Define if your assembler supports AIX debug frame section label reference.])])
4560         ;;
4561     esac
4562     ;;
4563
4564   mips*-*-*)
4565     gcc_GAS_CHECK_FEATURE([explicit relocation support],
4566       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
4567 [       lw $4,%gp_rel(foo)($4)],,
4568       [if test x$target_cpu_default = x
4569        then target_cpu_default=MASK_EXPLICIT_RELOCS
4570        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
4571        fi])
4572
4573     gcc_GAS_CHECK_FEATURE([-mno-shared support],
4574       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
4575       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
4576                  [Define if the assembler understands -mno-shared.])])
4577
4578     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4579       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
4580       [.gnu_attribute 4,1],,
4581       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4582           [Define if your assembler supports .gnu_attribute.])])
4583
4584     gcc_GAS_CHECK_FEATURE([.module support],
4585       gcc_cv_as_mips_dot_module,,[-32],
4586       [.module mips2
4587        .module fp=xx],,
4588       [AC_DEFINE(HAVE_AS_DOT_MODULE, 1,
4589           [Define if your assembler supports .module.])])
4590     if test x$gcc_cv_as_mips_dot_module = xno \
4591        && test x$with_fp_32 != x; then
4592       AC_MSG_ERROR(
4593         [Requesting --with-fp-32= requires assembler support for .module.])
4594     fi
4595
4596     gcc_GAS_CHECK_FEATURE([.micromips support],
4597       gcc_cv_as_micromips_support,,[--fatal-warnings],
4598       [.set micromips],,
4599       [AC_DEFINE(HAVE_GAS_MICROMIPS, 1,
4600           [Define if your assembler supports the .set micromips directive])])
4601
4602     gcc_GAS_CHECK_FEATURE([.dtprelword support],
4603       gcc_cv_as_mips_dtprelword, [2,18,0],,
4604       [.section .tdata,"awT",@progbits
4605 x:
4606         .word 2
4607         .text
4608         .dtprelword x+0x8000],,
4609       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
4610           [Define if your assembler supports .dtprelword.])])
4611
4612     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
4613       gcc_cv_as_mips_dspr1_mult,,,
4614 [       .set    mips32r2
4615         .set    nodspr2
4616         .set    dsp
4617         madd    $ac3,$4,$5
4618         maddu   $ac3,$4,$5
4619         msub    $ac3,$4,$5
4620         msubu   $ac3,$4,$5
4621         mult    $ac3,$4,$5
4622         multu   $ac3,$4,$5],,
4623       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
4624           [Define if your assembler supports DSPR1 mult.])])
4625
4626     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
4627     gcc_cv_as_ld_jalr_reloc=no
4628     if test $gcc_cv_as_mips_explicit_relocs = yes; then
4629       if test $in_tree_ld = yes ; then
4630         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
4631            && test $in_tree_ld_is_elf = yes; then
4632           gcc_cv_as_ld_jalr_reloc=yes
4633         fi
4634       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
4635         echo '  .ent x' > conftest.s
4636         echo 'x:        lw $2,%got_disp(y)($3)' >> conftest.s
4637         echo '  lw $25,%call16(y)($28)' >> conftest.s
4638         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
4639         echo '1:        jalr $25' >> conftest.s
4640         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
4641         echo '1:        jalr $25' >> conftest.s
4642         echo '  .end x' >> conftest.s
4643         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
4644            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
4645           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
4646              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
4647             gcc_cv_as_ld_jalr_reloc=yes
4648           fi
4649         fi
4650         rm -f conftest.*
4651       fi
4652     fi
4653     if test $gcc_cv_as_ld_jalr_reloc = yes; then
4654       if test x$target_cpu_default = x; then
4655         target_cpu_default=MASK_RELAX_PIC_CALLS
4656       else
4657         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
4658       fi
4659     fi
4660     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
4661
4662     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
4663       [gcc_cv_ld_mips_personality_relaxation],
4664       [gcc_cv_ld_mips_personality_relaxation=no
4665        if test $in_tree_ld = yes ; then
4666          if test "$gcc_cv_gld_major_version" -eq 2 \
4667                  -a "$gcc_cv_gld_minor_version" -ge 21 \
4668                  -o "$gcc_cv_gld_major_version" -gt 2; then
4669            gcc_cv_ld_mips_personality_relaxation=yes
4670          fi
4671        elif test x$gcc_cv_as != x \
4672                  -a x$gcc_cv_ld != x \
4673                  -a x$gcc_cv_readelf != x ; then
4674          cat > conftest.s <<EOF
4675         .cfi_startproc
4676         .cfi_personality 0x80,indirect_ptr
4677         .ent test
4678 test:
4679         nop
4680         .end test
4681         .cfi_endproc
4682
4683         .section .data,"aw",@progbits
4684 indirect_ptr:
4685         .dc.a personality
4686 EOF
4687          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
4688             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
4689            if $gcc_cv_readelf -d conftest 2>&1 \
4690               | grep TEXTREL > /dev/null 2>&1; then
4691              :
4692            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4693                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4694              :
4695            else
4696              gcc_cv_ld_mips_personality_relaxation=yes
4697            fi
4698          fi
4699        fi
4700        rm -f conftest.s conftest.o conftest])
4701     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4702             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4703       [Define if your linker can relax absolute .eh_frame personality
4704 pointers into PC-relative form.])
4705     fi
4706
4707     gcc_GAS_CHECK_FEATURE([-mnan= support],
4708       gcc_cv_as_mips_nan,,
4709       [-mnan=2008],,,
4710       [AC_DEFINE(HAVE_AS_NAN, 1,
4711                  [Define if the assembler understands -mnan=.])])
4712     if test x$gcc_cv_as_mips_nan = xno \
4713        && test x$with_nan != x; then
4714       AC_MSG_ERROR(
4715         [Requesting --with-nan= requires assembler support for -mnan=])
4716     fi
4717     ;;
4718     s390*-*-*)
4719     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4720       gcc_cv_as_s390_gnu_attribute, [2,18,0],,
4721       [.gnu_attribute 8,1],,
4722       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4723           [Define if your assembler supports .gnu_attribute.])])
4724     gcc_GAS_CHECK_FEATURE([.machine and .machinemode support],
4725       gcc_cv_as_s390_machine_machinemode, [2,24,0],,
4726       [ .machinemode push
4727         .machinemode pop
4728         .machine push
4729         .machine pop],,
4730       [AC_DEFINE(HAVE_AS_MACHINE_MACHINEMODE, 1,
4731           [Define if your assembler supports .machine and .machinemode.])])
4732     gcc_GAS_CHECK_FEATURE([architecture modifiers support],
4733       gcc_cv_as_s390_architecture_modifiers, [2,26,0],,
4734       [ .machine z13+vx ],,
4735       [AC_DEFINE(HAVE_AS_ARCHITECTURE_MODIFIERS, 1,
4736           [Define if your assembler supports architecture modifiers.])])
4737     ;;
4738 esac
4739
4740 # Mips and HP-UX need the GNU assembler.
4741 # Linux on IA64 might be able to use the Intel assembler.
4742
4743 case "$target" in
4744   mips*-*-* | *-*-hpux* )
4745     if test x$gas_flag = xyes \
4746        || test x"$host" != x"$build" \
4747        || test ! -x "$gcc_cv_as" \
4748        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4749       :
4750     else
4751       echo "*** This configuration requires the GNU assembler" >&2
4752       exit 1
4753     fi
4754     ;;
4755 esac
4756
4757 # ??? Not all targets support dwarf2 debug_line, even within a version
4758 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4759 # info to the output file.  So, as supported targets are added to gas 2.11,
4760 # add some instruction here to (also) show we expect this might work.
4761 # ??? Once 2.11 is released, probably need to add first known working
4762 # version to the per-target configury.
4763 case "$cpu_type" in
4764   aarch64 | alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze \
4765   | mips | nios2 | pa | rs6000 | score | sparc | spu | tilegx | tilepro \
4766   | visium | xstormy16 | xtensa)
4767     insn="nop"
4768     ;;
4769   ia64 | s390)
4770     insn="nop 0"
4771     ;;
4772   mmix)
4773     insn="swym 0"
4774     ;;
4775 esac
4776 if test x"$insn" != x; then
4777  conftest_s="\
4778         .file 1 \"conftest.s\"
4779         .loc 1 3 0
4780         $insn"
4781  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4782   gcc_cv_as_dwarf2_debug_line,
4783   [elf,2,11,0],, [$conftest_s],
4784   [if test x$gcc_cv_objdump != x \
4785    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4786       | grep debug_line > /dev/null 2>&1; then
4787      gcc_cv_as_dwarf2_debug_line=yes
4788    fi])
4789
4790 # The .debug_line file table must be in the exact order that
4791 # we specified the files, since these indices are also used
4792 # by DW_AT_decl_file.  Approximate this test by testing if
4793 # the assembler bitches if the same index is assigned twice.
4794  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4795   gcc_cv_as_dwarf2_file_buggy,,,
4796 [       .file 1 "foo.s"
4797         .file 1 "bar.s"])
4798
4799  if test $gcc_cv_as_dwarf2_debug_line = yes \
4800  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4801         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4802   [Define if your assembler supports dwarf2 .file/.loc directives,
4803    and preserves file table indices exactly as given.])
4804  fi
4805
4806  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4807   gcc_cv_as_gdwarf2_flag,
4808   [elf,2,11,0], [--gdwarf2], [$insn],,
4809   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4810 [Define if your assembler supports the --gdwarf2 option.])])
4811
4812  gcc_GAS_CHECK_FEATURE([--gstabs option],
4813   gcc_cv_as_gstabs_flag,
4814   [elf,2,11,0], [--gstabs], [$insn],,
4815   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4816 [Define if your assembler supports the --gstabs option.])])
4817
4818  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4819   gcc_cv_as_debug_prefix_map_flag,
4820   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4821   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4822 [Define if your assembler supports the --debug-prefix-map option.])])
4823 fi
4824
4825 gcc_GAS_CHECK_FEATURE([compressed debug sections],
4826   gcc_cv_as_compress_debug,,,,
4827   [# gas compiled without zlib cannot compress debug sections and warns
4828    # about it, but still exits successfully.  So check for this, too.
4829    if $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null
4830    then
4831      gcc_cv_as_compress_debug=0
4832    # Since binutils 2.26, gas supports --compress-debug-sections=type,
4833    # defaulting to the ELF gABI format.
4834    elif $gcc_cv_as --compress-debug-sections=zlib-gnu -o conftest.o conftest.s > /dev/null 2>&1
4835    then
4836      gcc_cv_as_compress_debug=2
4837      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4838      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4839    # Before binutils 2.26, gas only supported --compress-debug-options and
4840    # emitted the traditional GNU format.
4841    elif $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s > /dev/null 2>&1
4842    then
4843      gcc_cv_as_compress_debug=1
4844      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4845      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4846    else
4847      gcc_cv_as_compress_debug=0
4848    fi])
4849 AC_DEFINE_UNQUOTED(HAVE_AS_COMPRESS_DEBUG, $gcc_cv_as_compress_debug,
4850 [Define to the level of your assembler's compressed debug section support.])
4851 AC_DEFINE_UNQUOTED(AS_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_compress_debug_option",
4852 [Define to the assembler option to enable compressed debug sections.])
4853 AC_DEFINE_UNQUOTED(AS_NO_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_no_compress_debug_option",
4854 [Define to the assembler option to disable compressed debug sections.])
4855
4856 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4857  ,,
4858 [.lcomm bar,4,16],,
4859 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4860   [Define if your assembler supports .lcomm with an alignment field.])])
4861
4862 if test x$with_sysroot = x && test x$host = x$target \
4863    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4864    && test "$prefix" != "NONE"; then
4865   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4866 [Define to PREFIX/include if cpp should also search that directory.])
4867 fi
4868
4869 # Determine the version of glibc, if any, used on the target.
4870 AC_MSG_CHECKING([for target glibc version])
4871 AC_ARG_WITH([glibc-version],
4872   [AS_HELP_STRING([--with-glibc-version=M.N],
4873     [assume GCC used with glibc version M.N or later])], [
4874 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
4875   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
4876   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
4877 else
4878   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
4879 fi], [
4880 glibc_version_major=0
4881 glibc_version_minor=0
4882 [if test -f $target_header_dir/features.h \
4883   && glibc_version_major_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC__[    ]+[0-9]' $target_header_dir/features.h` \
4884   && glibc_version_minor_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+[0-9]' $target_header_dir/features.h`; then
4885   glibc_version_major=`echo "$glibc_version_major_define" | sed -e 's/.*__GLIBC__[      ]*//'`
4886   glibc_version_minor=`echo "$glibc_version_minor_define" | sed -e 's/.*__GLIBC_MINOR__[        ]*//'`
4887 fi]])
4888 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
4889 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MAJOR], [$glibc_version_major],
4890 [GNU C Library major version number used on the target, or 0.])
4891 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MINOR], [$glibc_version_minor],
4892 [GNU C Library minor version number used on the target, or 0.])
4893
4894 AC_ARG_ENABLE(gnu-unique-object,
4895  [AS_HELP_STRING([--enable-gnu-unique-object],
4896    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4897  [case $enable_gnu_unique_object in
4898     yes | no) ;;
4899     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4900 Valid choices are 'yes' and 'no'.]) ;;
4901   esac],
4902  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4903    [elf,2,19,52],,
4904    [.type foo, '$target_type_format_char'gnu_unique_object],,
4905 # We need to unquote above to to use the definition from config.gcc.
4906 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4907    [GCC_GLIBC_VERSION_GTE_IFELSE([2], [11], [enable_gnu_unique_object=yes], )]
4908    )])
4909 if test x$enable_gnu_unique_object = xyes; then
4910   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4911    [Define if your assembler supports @gnu_unique_object.])
4912 fi
4913
4914 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4915  [gcc_cv_as_line_zero],
4916  [gcc_cv_as_line_zero=no
4917   if test $in_tree_gas = yes; then
4918     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4919   elif test "x$gcc_cv_as" != x; then
4920     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4921     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4922        test "x`cat conftest.out`" = x
4923     then
4924       gcc_cv_as_line_zero=yes
4925     else
4926       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4927       cat conftest.s >&AS_MESSAGE_LOG_FD
4928       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4929       cat conftest.out >&AS_MESSAGE_LOG_FD
4930     fi
4931     rm -f conftest.o conftest.s conftest.out
4932   fi])
4933 if test "x$gcc_cv_as_line_zero" = xyes; then
4934   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4935 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4936 fi
4937
4938 AC_MSG_CHECKING(support for thin archives)
4939 thin_archive_support=no
4940 echo 'int main (void) { return 0; }' > conftest.c
4941 if ($AR --version | sed 1q | grep "GNU ar" \
4942     && $CC $CFLAGS -c conftest.c \
4943     && $AR rcT conftest.a conftest.o \
4944     && $CC $CFLAGS $LDFLAGS -o conftest conftest.a) >/dev/null 2>&1; then
4945   thin_archive_support=yes
4946 fi
4947 rm -f conftest.c conftest.o conftest.a conftest
4948 AC_MSG_RESULT($thin_archive_support)
4949 AC_SUBST(thin_archive_support)
4950
4951 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4952 gcc_cv_ld_eh_frame_hdr=no
4953 if test $in_tree_ld = yes ; then
4954   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4955      && test $in_tree_ld_is_elf = yes; then
4956     gcc_cv_ld_eh_frame_hdr=yes
4957   fi
4958 elif test x$gcc_cv_ld != x; then
4959   if echo "$ld_ver" | grep GNU > /dev/null; then
4960     # Check if linker supports --eh-frame-hdr option
4961     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4962       gcc_cv_ld_eh_frame_hdr=yes
4963     fi
4964   else
4965     case "$target" in
4966       *-*-solaris2*)
4967         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4968         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4969           gcc_cv_ld_eh_frame_hdr=yes
4970         fi
4971         ;;
4972     esac
4973   fi
4974 fi
4975 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4976 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4977         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4978 [Define if your linker supports .eh_frame_hdr.])
4979 fi
4980 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4981
4982 AC_MSG_CHECKING(linker CIEv3 in .eh_frame support)
4983 gcc_cv_ld_eh_frame_ciev3=no
4984 if test $in_tree_ld = yes ; then
4985   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4986      && test $in_tree_ld_is_elf = yes; then
4987     gcc_cv_ld_eh_frame_ciev3=yes
4988   fi
4989 elif test x$gcc_cv_ld != x; then
4990   if echo "$ld_ver" | grep GNU > /dev/null; then
4991     gcc_cv_ld_eh_frame_ciev3=yes
4992     if test 0"$ld_date" -lt 20040513; then
4993       if test -n "$ld_date"; then
4994         # If there was date string, but was earlier than 2004-05-13, fail
4995         gcc_cv_ld_eh_frame_ciev3=no
4996       elif test "$ld_vers_major" -lt 2; then
4997         gcc_cv_ld_eh_frame_ciev3=no
4998       elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
4999         gcc_cv_ld_eh_frame_ciev3=no
5000       fi
5001     fi
5002   else
5003     case "$target" in
5004       *-*-solaris2*)
5005         # Sun ld added support for CIE v3 in .eh_frame in Solaris 11.1.
5006         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2324; then
5007           gcc_cv_ld_eh_frame_ciev3=yes
5008         fi
5009         ;;
5010     esac
5011   fi
5012 fi
5013 AC_DEFINE_UNQUOTED(HAVE_LD_EH_FRAME_CIEV3,
5014   [`if test x"$gcc_cv_ld_eh_frame_ciev3" = xyes; then echo 1; else echo 0; fi`],
5015   [Define 0/1 if your linker supports CIE v3 in .eh_frame.])
5016 AC_MSG_RESULT($gcc_cv_ld_eh_frame_ciev3)
5017
5018 AC_MSG_CHECKING(linker position independent executable support)
5019 gcc_cv_ld_pie=no
5020 if test $in_tree_ld = yes ; then
5021   case "$target" in
5022     # Full PIE support on Solaris was only introduced in gld 2.26.
5023     *-*-solaris2*)  gcc_gld_pie_min_version=26 ;;
5024     *)              gcc_gld_pie_min_version=15 ;;
5025   esac
5026   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge "$gcc_gld_pie_min_version" -o "$gcc_cv_gld_major_version" -gt 2 \
5027      && test $in_tree_ld_is_elf = yes; then
5028     gcc_cv_ld_pie=yes
5029   fi
5030 elif test x$gcc_cv_ld != x; then
5031   # Check if linker supports -pie option
5032   if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
5033     gcc_cv_ld_pie=yes
5034     case "$target" in
5035       *-*-solaris2*)
5036         if echo "$ld_ver" | grep GNU > /dev/null \
5037           && test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5038           gcc_cv_ld_pie=no
5039         fi
5040         ;;
5041     esac
5042   else
5043     case "$target" in
5044       *-*-solaris2.1[[1-9]]*)
5045         # Solaris 11.x and Solaris 12 added PIE support.
5046         if $gcc_cv_ld -z help 2>&1 | grep -- type.*pie > /dev/null; then
5047           gcc_cv_ld_pie=yes
5048         fi
5049         ;;
5050     esac
5051   fi
5052 fi
5053 if test x"$gcc_cv_ld_pie" = xyes; then
5054         AC_DEFINE(HAVE_LD_PIE, 1,
5055 [Define if your linker supports PIE option.])
5056 fi
5057 AC_MSG_RESULT($gcc_cv_ld_pie)
5058
5059 AC_MSG_CHECKING(linker PIE support with copy reloc)
5060 gcc_cv_ld_pie_copyreloc=no
5061 if test $gcc_cv_ld_pie = yes ; then
5062   if test $in_tree_ld = yes ; then
5063     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
5064       gcc_cv_ld_pie_copyreloc=yes
5065     fi
5066   elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5067     # Check if linker supports -pie option with copy reloc
5068     case "$target" in
5069     i?86-*-linux* | x86_64-*-linux*)
5070       cat > conftest1.s <<EOF
5071         .globl  a_glob
5072         .data
5073         .type   a_glob, @object
5074         .size   a_glob, 4
5075 a_glob:
5076         .long   2
5077 EOF
5078       cat > conftest2.s <<EOF
5079         .text
5080         .globl  main
5081         .type   main, @function
5082 main:
5083         movl    %eax, a_glob(%rip)
5084         .size   main, .-main
5085         .globl  ptr
5086         .section        .data.rel,"aw",@progbits
5087         .type   ptr, @object
5088 ptr:
5089         .quad   a_glob
5090 EOF
5091       if $gcc_cv_as --64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5092          && $gcc_cv_ld -shared -melf_x86_64 -o conftest1.so conftest1.o > /dev/null 2>&1 \
5093          && $gcc_cv_as --64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5094          && $gcc_cv_ld -pie -melf_x86_64 -o conftest conftest2.o conftest1.so > /dev/null 2>&1; then
5095         gcc_cv_ld_pie_copyreloc=yes
5096       fi
5097       rm -f conftest conftest1.so conftest1.o conftest2.o conftest1.s conftest2.s
5098       ;;
5099     esac
5100   fi
5101 fi
5102 AC_DEFINE_UNQUOTED(HAVE_LD_PIE_COPYRELOC,
5103   [`if test x"$gcc_cv_ld_pie_copyreloc" = xyes; then echo 1; else echo 0; fi`],
5104   [Define 0/1 if your linker supports -pie option with copy reloc.])
5105 AC_MSG_RESULT($gcc_cv_ld_pie_copyreloc)
5106
5107 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
5108 gcc_cv_ld_eh_gc_sections=no
5109 if test $in_tree_ld = yes ; then
5110   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
5111      && test $in_tree_ld_is_elf = yes; then
5112     gcc_cv_ld_eh_gc_sections=yes
5113   fi
5114 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
5115   cat > conftest.s <<EOF
5116         .section        .text
5117 .globl _start
5118         .type _start, @function
5119 _start:
5120         .long foo
5121         .size _start, .-_start
5122         .section        .text.foo,"ax",@progbits
5123         .type foo, @function
5124 foo:
5125         .long 0
5126         .size foo, .-foo
5127         .section        .gcc_except_table.foo,"a",@progbits
5128 .L0:
5129         .long 0
5130         .section        .eh_frame,"a",@progbits
5131         .long .L0
5132 EOF
5133   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5134     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5135          | grep "gc-sections option ignored" > /dev/null; then
5136       gcc_cv_ld_eh_gc_sections=no
5137     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5138          | grep gcc_except_table > /dev/null; then
5139       gcc_cv_ld_eh_gc_sections=yes
5140       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
5141       if test x$gcc_cv_as_comdat_group != xyes; then
5142         gcc_cv_ld_eh_gc_sections=no
5143         cat > conftest.s <<EOF
5144         .section        .text
5145 .globl _start
5146         .type _start, @function
5147 _start:
5148         .long foo
5149         .size _start, .-_start
5150         .section        .gnu.linkonce.t.foo,"ax",@progbits
5151         .type foo, @function
5152 foo:
5153         .long 0
5154         .size foo, .-foo
5155         .section        .gcc_except_table.foo,"a",@progbits
5156 .L0:
5157         .long 0
5158         .section        .eh_frame,"a",@progbits
5159         .long .L0
5160 EOF
5161         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5162           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5163                | grep "gc-sections option ignored" > /dev/null; then
5164             gcc_cv_ld_eh_gc_sections=no
5165           elif $gcc_cv_objdump -h conftest 2> /dev/null \
5166                | grep gcc_except_table > /dev/null; then
5167             gcc_cv_ld_eh_gc_sections=yes
5168           fi
5169         fi
5170       fi
5171     fi
5172   fi
5173   rm -f conftest.s conftest.o conftest
5174 fi
5175 case "$target" in
5176   hppa*-*-linux*)
5177     # ??? This apparently exposes a binutils bug with PC-relative relocations.
5178     gcc_cv_ld_eh_gc_sections=no
5179     ;;
5180 esac
5181 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
5182         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
5183   [Define if your linker supports garbage collection of
5184    sections in presence of EH frames.])
5185 fi
5186 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
5187
5188 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
5189 gcc_cv_ld_eh_gc_sections_bug=no
5190 if test $in_tree_ld = yes ; then
5191   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
5192      && test $in_tree_ld_is_elf = yes; then
5193     gcc_cv_ld_eh_gc_sections_bug=yes
5194   fi
5195 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
5196   gcc_cv_ld_eh_gc_sections_bug=yes
5197   cat > conftest.s <<EOF
5198         .section        .text
5199 .globl _start
5200         .type _start, @function
5201 _start:
5202         .long foo
5203         .size _start, .-_start
5204         .section        .text.startup.foo,"ax",@progbits
5205         .type foo, @function
5206 foo:
5207         .long 0
5208         .size foo, .-foo
5209         .section        .gcc_except_table.foo,"a",@progbits
5210 .L0:
5211         .long 0
5212         .section        .eh_frame,"a",@progbits
5213         .long .L0
5214 EOF
5215   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5216     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5217          | grep "gc-sections option ignored" > /dev/null; then
5218       :
5219     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5220          | grep gcc_except_table > /dev/null; then
5221       gcc_cv_ld_eh_gc_sections_bug=no
5222     fi
5223   fi
5224   rm -f conftest.s conftest.o conftest
5225 fi
5226 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
5227         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
5228   [Define if your linker has buggy garbage collection of
5229    sections support when .text.startup.foo like sections are used.])
5230 fi
5231 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
5232
5233 AC_MSG_CHECKING(linker for compressed debug sections)
5234 # gold/gld support compressed debug sections since binutils 2.19/2.21
5235 # In binutils 2.26, gld gained support for the ELF gABI format.
5236 if test $in_tree_ld = yes ; then
5237   gcc_cv_ld_compress_debug=0
5238   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 19 -o "$gcc_cv_gld_major_version" -gt 2 \
5239      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = yes; then
5240     gcc_cv_ld_compress_debug=2
5241     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5242   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 26 -o "$gcc_cv_gld_major_version" -gt 2 \
5243      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = no; then
5244     gcc_cv_ld_compress_debug=3
5245     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5246   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2 \
5247      && test $in_tree_ld_is_elf = yes; then
5248     gcc_cv_ld_compress_debug=1
5249   fi
5250 elif echo "$ld_ver" | grep GNU > /dev/null; then
5251   if test "$ld_vers_major" -lt 2 \
5252      || test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 21; then
5253     gcc_cv_ld_compress_debug=0
5254   elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5255     gcc_cv_ld_compress_debug=1
5256   else
5257     gcc_cv_ld_compress_debug=3
5258     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5259   fi
5260   if test $ld_is_gold = yes; then
5261     gcc_cv_ld_compress_debug=2
5262     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5263   fi
5264 else
5265 changequote(,)dnl
5266   case "${target}" in
5267     *-*-solaris2*)
5268       # Introduced in Solaris 11.2.
5269       if $gcc_cv_ld --help 2>&1 | grep -- '-z compress-sections' > /dev/null; then
5270         gcc_cv_ld_compress_debug=3
5271         gcc_cv_ld_compress_debug_option="-z compress-sections"
5272       else
5273         gcc_cv_ld_compress_debug=0
5274       fi
5275       ;;
5276     *)
5277       # Assume linkers other than GNU ld don't support compessed debug
5278       # sections.
5279       gcc_cv_ld_compress_debug=0
5280       ;;
5281   esac
5282 changequote([,])dnl
5283 fi
5284 AC_DEFINE_UNQUOTED(HAVE_LD_COMPRESS_DEBUG, $gcc_cv_ld_compress_debug,
5285 [Define to the level of your linker's compressed debug section support.])
5286 AC_DEFINE_UNQUOTED(LD_COMPRESS_DEBUG_OPTION, "$gcc_cv_ld_compress_debug_option",
5287 [Define to the linker option to enable compressed debug sections.])
5288 AC_MSG_RESULT($gcc_cv_ld_compress_debug)
5289
5290 if test x"$ld64_flag" = x"yes"; then
5291
5292   # Set defaults for possibly untestable items.
5293   gcc_cv_ld64_export_dynamic=0
5294
5295   if test "$build" = "$host"; then
5296     darwin_try_test=1
5297   else
5298     darwin_try_test=0
5299   fi
5300
5301   # On Darwin, because of FAT library support, it is often possible to execute
5302   # exes from compatible archs even when the host differs from the build system.
5303   case "$build","$host" in
5304     x86_64-*-darwin*,i?86-*-darwin* | powerpc64*-*-darwin*,powerpc*-*-darwin*)
5305         darwin_try_test=1;;
5306     *) ;;
5307   esac
5308
5309   # If the configurer specified a minimum ld64 version to be supported, then use
5310   # that to determine feature support.
5311   if test x"${gcc_cv_ld64_version}" != x; then
5312     AC_MSG_CHECKING(ld64 major version)
5313     IFS=. read gcc_cv_ld64_major gcc_cv_ld64_minor <<< "${gcc_cv_ld64_version}"
5314     AC_MSG_RESULT($gcc_cv_ld64_major)
5315    if test "$gcc_cv_ld64_major" -ge 236; then
5316       gcc_cv_ld64_export_dynamic=1
5317     fi
5318   elif test -x "$gcc_cv_ld" -a "$darwin_try_test" -eq 1; then
5319     # If the version was not specified, try to find it.
5320     AC_MSG_CHECKING(linker version)
5321     if test x"${gcc_cv_ld64_version}" = x; then
5322       gcc_cv_ld64_version=`$gcc_cv_ld -v 2>&1 | grep ld64 | sed s/.*ld64-// | awk '{print $1}'`
5323     fi
5324     AC_MSG_RESULT($gcc_cv_ld64_version)
5325
5326     AC_MSG_CHECKING(linker for -export_dynamic support)
5327     gcc_cv_ld64_export_dynamic=1
5328     if $gcc_cv_ld -export_dynamic < /dev/null 2>&1 | grep 'unknown option' > /dev/null; then
5329       gcc_cv_ld64_export_dynamic=0
5330     fi
5331     AC_MSG_RESULT($gcc_cv_ld64_export_dynamic)
5332   fi
5333
5334   if test x"${gcc_cv_ld64_version}" != x; then
5335     AC_DEFINE_UNQUOTED(LD64_VERSION, "${gcc_cv_ld64_version}",
5336       [Define to ld64 version.])
5337   fi
5338
5339   AC_DEFINE_UNQUOTED(LD64_HAS_EXPORT_DYNAMIC, $gcc_cv_ld64_export_dynamic,
5340   [Define to 1 if ld64 supports '-export_dynamic'.])
5341 fi
5342
5343 # --------
5344 # UNSORTED
5345 # --------
5346
5347 AC_CACHE_CHECK(linker --as-needed support,
5348 gcc_cv_ld_as_needed,
5349 [gcc_cv_ld_as_needed=no
5350 gcc_cv_ld_as_needed_option='--as-needed'
5351 gcc_cv_ld_no_as_needed_option='--no-as-needed'
5352 if test $in_tree_ld = yes ; then
5353   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
5354      && test $in_tree_ld_is_elf = yes; then
5355     gcc_cv_ld_as_needed=yes
5356   fi
5357 elif test x$gcc_cv_ld != x; then
5358         # Check if linker supports --as-needed and --no-as-needed options
5359         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
5360                 gcc_cv_ld_as_needed=yes
5361         else
5362           case "$target" in
5363             # Solaris 2 ld always supports -z ignore/-z record.
5364             *-*-solaris2*)
5365               gcc_cv_ld_as_needed=yes
5366               gcc_cv_ld_as_needed_option="-z ignore"
5367               gcc_cv_ld_no_as_needed_option="-z record"
5368               ;;
5369           esac
5370         fi
5371 fi
5372 # --as-needed/-z ignore can only be used if libgcc_s.so.1 uses
5373 # dl_iterate_phdr, i.e. since Solaris 11.
5374 case "$target" in
5375   *-*-solaris2.1[[1-9]]*)
5376     case "$target" in
5377     i?86-*-* | x86_64-*-*)
5378       if echo "$ld_ver" | grep GNU > /dev/null; then
5379         # Doesn't work with gld on Solaris/x86 due to PR ld/12320.
5380         gcc_cv_ld_as_needed=no
5381       fi
5382       ;;
5383     esac
5384     ;;
5385   *-*-solaris2*)
5386     gcc_cv_ld_as_needed=no
5387     ;;
5388 esac
5389 ])
5390 if test x"$gcc_cv_ld_as_needed" = xyes; then
5391         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
5392 [Define if your linker supports --as-needed/--no-as-needed or equivalent options.])
5393         AC_DEFINE_UNQUOTED(LD_AS_NEEDED_OPTION, "$gcc_cv_ld_as_needed_option",
5394 [Define to the linker option to ignore unused dependencies.])
5395         AC_DEFINE_UNQUOTED(LD_NO_AS_NEEDED_OPTION, "$gcc_cv_ld_no_as_needed_option",
5396 [Define to the linker option to keep unused dependencies.])
5397 fi
5398
5399 AC_MSG_CHECKING(linker mapfile support for clearing hardware capabilities)
5400 saved_LDFLAGS="$LDFLAGS"
5401 for clearcap_map in sol2-clearcapv2.map sol2-clearcap.map; do
5402   LDFLAGS="$saved_LDFLAGS -Wl,-M,${srcdir}/config/$clearcap_map"
5403   AC_LINK_IFELSE([int main(void) {return 0;}],
5404     [gcc_cv_ld_clearcap=yes; break], [gcc_cv_ld_clearcap=no])
5405 done
5406 LDFLAGS="$saved_LDFLAGS"
5407 if test "x$gcc_cv_ld_clearcap" = xyes; then
5408   AC_DEFINE([HAVE_LD_CLEARCAP], 1,
5409 [Define if the linker supports clearing hardware capabilities via mapfile.])
5410   AC_CONFIG_LINKS([clearcap.map:${srcdir}/config/$clearcap_map])
5411 fi
5412 AC_MSG_RESULT($gcc_cv_ld_clearcap)
5413
5414 case "$target" in
5415   powerpc*-*-*)
5416     case "$target" in
5417       *le-*-linux*)
5418         emul_name="-melf32lppc"
5419         ;;
5420       *)
5421         emul_name="-melf32ppc"
5422         ;;
5423     esac
5424     AC_CACHE_CHECK(linker .gnu.attributes long double support,
5425     gcc_cv_ld_ppc_attr,
5426     [gcc_cv_ld_ppc_attr=no
5427     if test x"$ld_is_gold" = xyes; then
5428       gcc_cv_ld_ppc_attr=yes
5429     elif test $in_tree_ld = yes ; then
5430       if test "$gcc_cv_gld_major_version" -eq 2 \
5431                 -a "$gcc_cv_gld_minor_version" -ge 28 \
5432                 -o "$gcc_cv_gld_major_version" -gt 2; then
5433         gcc_cv_ld_ppc_attr=yes
5434       fi
5435     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5436       # check that merging the long double .gnu_attribute doesn't warn
5437       cat > conftest1.s <<EOF
5438         .gnu_attribute 4,1
5439 EOF
5440       cat > conftest2.s <<EOF
5441         .gnu_attribute 4,9
5442 EOF
5443       if $gcc_cv_as -a32 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5444          && $gcc_cv_as -a32 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5445          && $gcc_cv_ld $emul_name -r -o conftest.o conftest1.o conftest2.o > /dev/null 2> conftest.err \
5446          && test ! -s conftest.err; then
5447         gcc_cv_ld_ppc_attr=yes
5448       fi
5449       rm -f conftest.err conftest.o conftest1.o conftest2.o conftest1.s conftest2.s
5450     fi
5451     ])
5452     if test x$gcc_cv_ld_ppc_attr = xyes; then
5453       AC_DEFINE(HAVE_LD_PPC_GNU_ATTR_LONG_DOUBLE, 1,
5454     [Define if your PowerPC linker has .gnu.attributes long double support.])
5455     fi
5456     ;;
5457 esac
5458
5459 case "$target:$tm_file" in
5460   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
5461   case "$target" in
5462      *le-*-linux*)
5463      emul_name="-melf64lppc"
5464       ;;
5465      *-*-linux*)
5466      emul_name="-melf64ppc"
5467       ;;
5468      *-*-freebsd*)
5469      emul_name="-melf64ppc_fbsd"
5470       ;;
5471   esac
5472     AC_CACHE_CHECK(linker support for omitting dot symbols,
5473     gcc_cv_ld_no_dot_syms,
5474     [gcc_cv_ld_no_dot_syms=no
5475     if test x"$ld_is_gold" = xyes; then
5476       gcc_cv_ld_no_dot_syms=yes
5477     elif test $in_tree_ld = yes ; then
5478       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
5479         gcc_cv_ld_no_dot_syms=yes
5480       fi
5481     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5482       cat > conftest1.s <<EOF
5483         .text
5484         bl .foo
5485 EOF
5486       cat > conftest2.s <<EOF
5487         .section ".opd","aw"
5488         .align 3
5489         .globl foo
5490         .type foo,@function
5491 foo:
5492         .quad .LEfoo,.TOC.@tocbase,0
5493         .text
5494 .LEfoo:
5495         blr
5496         .size foo,.-.LEfoo
5497 EOF
5498       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5499          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5500          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
5501         gcc_cv_ld_no_dot_syms=yes
5502       fi
5503       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
5504     fi
5505     ])
5506     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
5507       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
5508     [Define if your PowerPC64 linker only needs function descriptor syms.])
5509     fi
5510
5511     AC_CACHE_CHECK(linker large toc support,
5512     gcc_cv_ld_large_toc,
5513     [gcc_cv_ld_large_toc=no
5514     if test x"$ld_is_gold" = xyes; then
5515       gcc_cv_ld_large_toc=yes
5516     elif test $in_tree_ld = yes ; then
5517       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
5518         gcc_cv_ld_large_toc=yes
5519       fi
5520     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5521       cat > conftest.s <<EOF
5522         .section ".tbss","awT",@nobits
5523         .align 3
5524 ie0:    .space 8
5525         .global _start
5526         .text
5527 _start:
5528         addis 9,13,ie0@got@tprel@ha
5529         ld 9,ie0@got@tprel@l(9)
5530 EOF
5531       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5532          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
5533         gcc_cv_ld_large_toc=yes
5534       fi
5535       rm -f conftest conftest.o conftest.s
5536     fi
5537     ])
5538     if test x"$gcc_cv_ld_large_toc" = xyes; then
5539       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5540     [Define if your PowerPC64 linker supports a large TOC.])
5541     fi
5542
5543     AC_CACHE_CHECK(linker toc pointer alignment,
5544     gcc_cv_ld_toc_align,
5545     [if test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_nm != x; then
5546       cat > conftest.s <<EOF
5547         .global _start
5548         .text
5549 _start:
5550         addis 9,2,x@got@ha
5551         .section .data.rel.ro,"aw",@progbits
5552         .p2align 16
5553         .space 32768
5554 x:      .quad .TOC.
5555 EOF
5556       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5557          && $gcc_cv_ld $emul_name -z norelro -o conftest conftest.o > /dev/null 2>&1; then
5558         gcc_cv_ld_toc_align=`$gcc_cv_nm conftest | ${AWK} '/\.TOC\./ { match ($0, "0[[[:xdigit:]]]*", a); print strtonum ("0x" substr(a[[0]], length(a[[0]])-3)) }'`
5559       fi
5560       rm -f conftest conftest.o conftest.s
5561     fi
5562     ])
5563     if test -n "$gcc_cv_ld_toc_align" && test $gcc_cv_ld_toc_align -gt 8; then
5564       AC_DEFINE_UNQUOTED(POWERPC64_TOC_POINTER_ALIGNMENT, $gcc_cv_ld_toc_align,
5565     [Define to .TOC. alignment forced by your linker.])
5566     fi
5567     ;;
5568 esac
5569
5570 case "$target" in
5571   *-*-aix*)
5572     AC_CACHE_CHECK(linker large toc support,
5573     gcc_cv_ld_large_toc,
5574     [gcc_cv_ld_large_toc=no
5575     if test x$gcc_cv_as != x ; then
5576       cat > conftest.s <<EOF
5577         .toc
5578 LC..1:
5579         .tc a[[TC]],a[[RW]]
5580         .extern a[[RW]]
5581         .csect .text[[PR]]
5582 .largetoctest:
5583         addis 9,LC..1@u(2)
5584         ld 3,LC..1@l(9)
5585 EOF
5586       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1; then
5587         gcc_cv_ld_large_toc=yes
5588       fi
5589       rm -f conftest conftest.o conftest.s
5590     fi
5591     ])
5592     if test x"$gcc_cv_ld_large_toc" = xyes; then
5593       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5594     [Define if your PowerPC64 linker supports a large TOC.])
5595     fi
5596     ;;
5597 esac
5598
5599 AC_CACHE_CHECK(linker --build-id support,
5600   gcc_cv_ld_buildid,
5601   [gcc_cv_ld_buildid=no
5602   if test $in_tree_ld = yes ; then
5603     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5604        "$gcc_cv_gld_minor_version" -ge 18 -o \
5605        "$gcc_cv_gld_major_version" -gt 2 \
5606        && test $in_tree_ld_is_elf = yes; then
5607       gcc_cv_ld_buildid=yes
5608     fi
5609   elif test x$gcc_cv_ld != x; then
5610     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
5611       gcc_cv_ld_buildid=yes
5612     fi
5613   fi])
5614 if test x"$gcc_cv_ld_buildid" = xyes; then
5615   AC_DEFINE(HAVE_LD_BUILDID, 1,
5616   [Define if your linker supports --build-id.])
5617 fi
5618
5619 AC_ARG_ENABLE(linker-build-id,
5620 [AS_HELP_STRING([--enable-linker-build-id],
5621                 [compiler will always pass --build-id to linker])],
5622 [],
5623 enable_linker_build_id=no)
5624
5625 if test x"$enable_linker_build_id" = xyes; then
5626   if test x"$gcc_cv_ld_buildid" = xyes; then
5627     AC_DEFINE(ENABLE_LD_BUILDID, 1,
5628     [Define if gcc should always pass --build-id to linker.])
5629   else
5630     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
5631   fi
5632 fi
5633
5634 # In binutils 2.21, GNU ld gained support for new emulations fully
5635 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
5636 AC_CACHE_CHECK(linker *_sol2 emulation support,
5637   gcc_cv_ld_sol2_emulation,
5638   [gcc_cv_ld_sol2_emulation=no
5639   if test $in_tree_ld = yes ; then
5640     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5641        "$gcc_cv_gld_minor_version" -ge 21 -o \
5642        "$gcc_cv_gld_major_version" -gt 2 \
5643        && test $in_tree_ld_is_elf = yes; then
5644       gcc_cv_ld_sol2_emulation=yes
5645     fi
5646   elif test x$gcc_cv_ld != x; then
5647     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
5648        grep _sol2 > /dev/null; then
5649       gcc_cv_ld_sol2_emulation=yes
5650     fi
5651   fi])
5652 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
5653   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
5654   [Define if your linker supports the *_sol2 emulations.])
5655 fi
5656
5657 AC_CACHE_CHECK(linker --sysroot support,
5658   gcc_cv_ld_sysroot,
5659   [gcc_cv_ld_sysroot=no
5660   if test $in_tree_ld = yes ; then
5661       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
5662         gcc_cv_ld_sysroot=yes
5663       fi
5664   elif test x$gcc_cv_ld != x; then
5665     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
5666       gcc_cv_ld_sysroot=yes
5667     fi
5668   fi])
5669 if test x"$gcc_cv_ld_sysroot" = xyes; then
5670   AC_DEFINE(HAVE_LD_SYSROOT, 1,
5671   [Define if your linker supports --sysroot.])
5672 fi
5673
5674 case $target in
5675 *-*-solaris2*)
5676   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
5677   AC_CACHE_CHECK([system-provided CRTs on Solaris],
5678     gcc_cv_solaris_crts,
5679     [gcc_cv_solaris_crts=no
5680      if test x$host != x$target; then
5681        if test "x$with_sysroot" = xyes; then
5682          target_sysroot="${test_exec_prefix}/${target_noncanonical}/sys-root"
5683        else
5684          target_sysroot="${with_sysroot}"
5685        fi
5686      fi
5687      target_libdir="$target_sysroot/usr/lib"
5688      # At the time they were added, gcrt1.o became a symlink for backwards
5689      # compatibility on x86, while crt1.o was added on sparc, so check for that.
5690      case $target in
5691        i?86-*-solaris2* | x86_64-*-solaris2*)
5692          if test -h "$target_libdir/gcrt1.o"; then gcc_cv_solaris_crts=yes; fi
5693          ;;
5694        sparc*-*-solaris2*)
5695          if test -f "$target_libdir/crt1.o"; then gcc_cv_solaris_crts=yes; fi
5696          ;;
5697      esac])
5698   ;;
5699 esac
5700 if test x$gcc_cv_solaris_crts = xyes; then
5701   AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
5702             [Define if the system-provided CRTs are present on Solaris.])
5703 fi
5704
5705 # Test for stack protector support in target C library.
5706 AC_CACHE_CHECK(__stack_chk_fail in target C library,
5707       gcc_cv_libc_provides_ssp,
5708       [gcc_cv_libc_provides_ssp=no
5709     case "$target" in
5710        *-*-musl*)
5711          # All versions of musl provide stack protector
5712          gcc_cv_libc_provides_ssp=yes;;
5713        *-*-linux* | *-*-kfreebsd*-gnu)
5714       # glibc 2.4 and later provides __stack_chk_fail and
5715       # either __stack_chk_guard, or TLS access to stack guard canary.
5716       GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_libc_provides_ssp=yes], [
5717       [if test -f $target_header_dir/features.h \
5718          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
5719             $target_header_dir/features.h > /dev/null; then
5720         if $EGREP '^[   ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
5721              $target_header_dir/features.h > /dev/null && \
5722              test -f $target_header_dir/bits/uClibc_config.h && \
5723              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
5724              $target_header_dir/bits/uClibc_config.h > /dev/null; then
5725           gcc_cv_libc_provides_ssp=yes
5726         fi
5727       # all versions of Bionic support stack protector
5728       elif test -f $target_header_dir/sys/cdefs.h \
5729         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
5730            $target_header_dir/sys/cdefs.h > /dev/null; then
5731          gcc_cv_libc_provides_ssp=yes
5732       fi]])
5733         ;;
5734        *-*-gnu*)
5735          # Avoid complicated tests (see
5736          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
5737          # simply assert that glibc does provide this, which is true for all
5738          # realistically usable GNU/Hurd configurations.
5739          # All supported versions of musl provide it as well
5740          gcc_cv_libc_provides_ssp=yes;;
5741        *-*-darwin* | *-*-freebsd* | *-*-netbsd*)
5742          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
5743            [echo "no __stack_chk_fail on this target"])
5744         ;;
5745   *) gcc_cv_libc_provides_ssp=no ;;
5746     esac])
5747
5748 if test x$gcc_cv_libc_provides_ssp = xyes; then
5749   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
5750             [Define if your target C library provides stack protector support])
5751 fi
5752
5753 # Check whether --enable-default-ssp was given.
5754 AC_ARG_ENABLE(default-ssp,
5755 [AS_HELP_STRING([--enable-default-ssp],
5756   [enable Stack Smashing Protection as default])],[
5757 if test x$gcc_cv_libc_provides_ssp = xyes; then
5758   case "$target" in
5759     ia64*-*-*) enable_default_ssp=no ;;
5760     *) enable_default_ssp=$enableval ;;
5761   esac
5762 else
5763   enable_default_ssp=no
5764 fi],
5765 enable_default_ssp=no)
5766 if test x$enable_default_ssp = xyes ; then
5767   AC_DEFINE(ENABLE_DEFAULT_SSP, 1,
5768       [Define if your target supports default stack protector and it is enabled.])
5769 fi
5770 AC_SUBST([enable_default_ssp])
5771
5772 # Test for <sys/sdt.h> on the target.
5773 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
5774 AC_MSG_CHECKING(sys/sdt.h in the target C library)
5775 have_sys_sdt_h=no
5776 if test -f $target_header_dir/sys/sdt.h; then
5777   have_sys_sdt_h=yes
5778   AC_DEFINE(HAVE_SYS_SDT_H, 1,
5779             [Define if your target C library provides sys/sdt.h])
5780 fi
5781 AC_MSG_RESULT($have_sys_sdt_h)
5782
5783 # Check if TFmode long double should be used by default or not.
5784 # Some glibc targets used DFmode long double, but with glibc 2.4
5785 # and later they can use TFmode.
5786 case "$target" in
5787   powerpc*-*-linux* | \
5788   sparc*-*-linux* | \
5789   s390*-*-linux* | \
5790   alpha*-*-linux*)
5791     AC_ARG_WITH(long-double-128,
5792       [AS_HELP_STRING([--with-long-double-128],
5793                       [use 128-bit long double by default])],
5794       gcc_cv_target_ldbl128="$with_long_double_128",
5795       [GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_target_ldbl128=yes], [
5796       [gcc_cv_target_ldbl128=no
5797       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
5798         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
5799       && gcc_cv_target_ldbl128=yes
5800       ]])])
5801     ;;
5802 esac
5803 if test x$gcc_cv_target_ldbl128 = xyes; then
5804   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
5805             [Define if TFmode long double should be the default])
5806 fi
5807
5808 # Check if the target LIBC supports exporting the AT_PLATFORM and AT_HWCAP
5809 # values in the TCB.  Currently, only GLIBC 2.23 and later support this.
5810 gcc_cv_libc_provides_hwcap_in_tcb=no
5811 case "$target" in
5812   powerpc*-*-linux*)
5813     GCC_GLIBC_VERSION_GTE_IFELSE([2], [23], [gcc_cv_libc_provides_hwcap_in_tcb=yes], )
5814     ;;
5815 esac
5816 if test x$gcc_cv_libc_provides_hwcap_in_tcb = xyes; then
5817   AC_DEFINE(TARGET_LIBC_PROVIDES_HWCAP_IN_TCB, 1,
5818             [Define if your target C Library provides the AT_HWCAP value in the TCB])
5819 fi
5820
5821 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
5822 gcc_cv_target_dl_iterate_phdr=unknown
5823 case "$target" in
5824   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
5825   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
5826   # libdl there, both complicating its use and breaking compatibility
5827   # between Solaris 10 updates.
5828   *-*-solaris2.1[[1-9]]*)
5829     # <link.h> needs both a dl_iterate_phdr declaration and support for
5830     # compilation with largefile support.
5831     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
5832       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
5833       gcc_cv_target_dl_iterate_phdr=yes
5834     else
5835       gcc_cv_target_dl_iterate_phdr=no
5836     fi
5837     ;;
5838   *-*-dragonfly* | *-*-freebsd*)
5839     if grep dl_iterate_phdr $target_header_dir/sys/link_elf.h > /dev/null 2>&1; then
5840       gcc_cv_target_dl_iterate_phdr=yes
5841     else
5842       gcc_cv_target_dl_iterate_phdr=no
5843     fi
5844     ;;
5845   *-linux-musl*)
5846     gcc_cv_target_dl_iterate_phdr=yes
5847     ;;
5848 esac
5849 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
5850 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
5851    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
5852 [Define if your target C library provides the `dl_iterate_phdr' function.])
5853 fi
5854 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
5855
5856 # We no longer support different GC mechanisms.  Emit an error if
5857 # the user configures with --with-gc.
5858 AC_ARG_WITH(gc,
5859 [AS_HELP_STRING([--with-gc={page,zone}],
5860                 [this option is not supported anymore.  It used to choose
5861                  the garbage collection mechanism to use with the compiler])],
5862 [AC_MSG_ERROR([Configure option --with-gc is only supported up to GCC 4.7.x])],
5863 [])
5864
5865 # Libraries to use on the host.  This will normally be set by the top
5866 # level Makefile.  Here we simply capture the value for our Makefile.
5867 if test -z "${HOST_LIBS+set}"; then
5868   HOST_LIBS=
5869 fi
5870 AC_SUBST(HOST_LIBS)
5871
5872 # Use the system's zlib library.
5873 AM_ZLIB
5874
5875 dnl Very limited version of automake's enable-maintainer-mode
5876
5877 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
5878   dnl maintainer-mode is disabled by default
5879   AC_ARG_ENABLE(maintainer-mode,
5880 [AS_HELP_STRING([--enable-maintainer-mode],
5881                 [enable make rules and dependencies not useful
5882                  (and sometimes confusing) to the casual installer])],
5883       maintainer_mode=$enableval,
5884       maintainer_mode=no)
5885
5886 AC_MSG_RESULT($maintainer_mode)
5887
5888 if test "$maintainer_mode" = "yes"; then
5889   MAINT=''
5890 else
5891   MAINT='#'
5892 fi
5893 AC_SUBST(MAINT)dnl
5894
5895 dnl Whether to prevent multiple front-ends from linking at the same time
5896
5897 AC_MSG_CHECKING([whether to avoid linking multiple front-ends at once])
5898   AC_ARG_ENABLE(link-mutex,
5899 [AS_HELP_STRING([--enable-link-mutex],
5900                 [avoid linking multiple front-ends at once to avoid thrashing
5901                  on the build machine])],
5902       do_link_mutex=$enableval,
5903       do_link_mutex=no)
5904 AC_MSG_RESULT($do_link_mutex)
5905
5906 if test "$do_link_mutex" = "yes"; then
5907    DO_LINK_MUTEX=true
5908 else
5909    DO_LINK_MUTEX=false
5910 fi
5911 AC_SUBST(DO_LINK_MUTEX)
5912
5913 # --------------
5914 # Language hooks
5915 # --------------
5916
5917 # Make empty files to contain the specs and options for each language.
5918 # Then add #include lines to for a compiler that has specs and/or options.
5919
5920 subdirs=
5921 lang_opt_files=
5922 lang_specs_files=
5923 lang_tree_files=
5924 # These (without "all_") are set in each config-lang.in.
5925 # `language' must be a single word so is spelled singularly.
5926 all_languages=
5927 all_compilers=
5928 all_outputs='Makefile'
5929 # List of language makefile fragments.
5930 all_lang_makefrags=
5931 # Additional files for gengtype
5932 all_gtfiles="$target_gtfiles"
5933
5934 # These are the languages that are set in --enable-languages,
5935 # and are available in the GCC tree.
5936 all_selected_languages=
5937
5938 # Add the language fragments.
5939 # Languages are added via two mechanisms.  Some information must be
5940 # recorded in makefile variables, these are defined in config-lang.in.
5941 # We accumulate them and plug them into the main Makefile.
5942 # The other mechanism is a set of hooks for each of the main targets
5943 # like `clean', `install', etc.
5944
5945 language_hooks="Make-hooks"
5946
5947 for lang in ${srcdir}/*/config-lang.in
5948 do
5949 changequote(,)dnl
5950         test "$lang" = "${srcdir}/*/config-lang.in" && continue
5951
5952         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
5953         if test "x$lang_alias" = x
5954         then
5955               echo "$lang doesn't set \$language." 1>&2
5956               exit 1
5957         fi
5958         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
5959         subdirs="$subdirs $subdir"
5960
5961         # $gcc_subdir is where the gcc integration files are to be found
5962         # for a language, both for internal compiler purposes (compiler
5963         # sources implementing front-end to GCC tree converters), and for
5964         # build infrastructure purposes (Make-lang.in, etc.)
5965         #
5966         # This will be <subdir> (relative to $srcdir) if a line like
5967         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
5968         # is found in <langdir>/config-lang.in, and will remain <langdir>
5969         # otherwise.
5970         #
5971         # Except for the language alias (fetched above), the regular
5972         # "config-lang.in" contents are always retrieved from $gcc_subdir,
5973         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
5974         # only this and the language alias.
5975
5976         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
5977         if [ "$gcc_subdir" = "" ]; then
5978            gcc_subdir="$subdir"
5979         fi
5980
5981         case ",$enable_languages," in
5982         *,$lang_alias,*)
5983             all_selected_languages="$all_selected_languages $lang_alias"
5984             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
5985                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
5986             fi
5987             ;;
5988         esac
5989 changequote([,])dnl
5990
5991         language=
5992         boot_language=
5993         compilers=
5994         outputs=
5995         gtfiles=
5996         subdir_requires=
5997         . ${srcdir}/$gcc_subdir/config-lang.in
5998         if test "x$language" = x
5999         then
6000                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
6001                 exit 1
6002         fi
6003
6004         ok=:
6005         case ",$enable_languages," in
6006                 *,$lang_alias,*) ;;
6007                 *)
6008                         for i in $subdir_requires; do
6009                                 test -f "${srcdir}/$i/config-lang.in" && continue
6010                                 ok=false
6011                                 break
6012                         done
6013                 ;;
6014         esac
6015         $ok || continue
6016
6017         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
6018         if test -f $srcdir/$gcc_subdir/lang.opt; then
6019             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
6020             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
6021         fi
6022         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
6023             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
6024         fi
6025         all_languages="$all_languages $language"
6026         all_compilers="$all_compilers $compilers"
6027         all_outputs="$all_outputs $outputs"
6028         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
6029         case ",$enable_languages," in
6030                 *,lto,*)
6031                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
6032                     enable_lto=yes
6033                     AC_SUBST(enable_lto)
6034                     ;;
6035                 *) ;;
6036         esac
6037 done
6038
6039 check_languages=
6040 for language in $all_selected_languages
6041 do
6042         check_languages="$check_languages check-$language"
6043 done
6044
6045 # We link each language in with a set of hooks, reached indirectly via
6046 # lang.${target}.  Only do so for selected languages.
6047
6048 rm -f Make-hooks
6049 touch Make-hooks
6050 target_list="all.cross start.encap rest.encap tags \
6051         install-common install-man install-info install-pdf install-html dvi \
6052         pdf html uninstall info man srcextra srcman srcinfo \
6053         mostlyclean clean distclean maintainer-clean install-plugin"
6054
6055 for t in $target_list
6056 do
6057         x=
6058         for lang in $all_selected_languages
6059         do
6060                 x="$x $lang.$t"
6061         done
6062         echo "lang.$t: $x" >> Make-hooks
6063 done
6064
6065 # --------
6066 # Option include files
6067 # --------
6068
6069 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
6070 option_includes="option-includes.mk"
6071 AC_SUBST_FILE(option_includes)
6072
6073 # --------
6074 # UNSORTED
6075 # --------
6076
6077 # Create .gdbinit.
6078
6079 echo "dir ." > .gdbinit
6080 echo "dir ${srcdir}" >> .gdbinit
6081 if test x$gdb_needs_out_file_path = xyes
6082 then
6083         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
6084 fi
6085 if test "x$subdirs" != x; then
6086         for s in $subdirs
6087         do
6088                 echo "dir ${srcdir}/$s" >> .gdbinit
6089         done
6090 fi
6091 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
6092 echo "python import sys; sys.path.append('${srcdir}'); import gdbhooks" >> .gdbinit
6093
6094 # Put a breakpoint on __asan_report_error to help with debugging buffer
6095 # overflow.
6096 case "$CFLAGS" in
6097 *-fsanitize=address*)
6098   echo "source ${srcdir}/gdbasan.in" >> .gdbinit
6099   ;;
6100 esac
6101
6102 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
6103 AC_SUBST(gcc_tooldir)
6104 AC_SUBST(dollar)
6105
6106 # Find a directory in which to install a shared libgcc.
6107
6108 AC_ARG_ENABLE(version-specific-runtime-libs,
6109 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
6110                 [specify that runtime libraries should be
6111                  installed in a compiler-specific directory])])
6112
6113 # Substitute configuration variables
6114 AC_SUBST(subdirs)
6115 AC_SUBST(srcdir)
6116 AC_SUBST(all_compilers)
6117 AC_SUBST(all_gtfiles)
6118 AC_SUBST(all_lang_makefrags)
6119 AC_SUBST(all_languages)
6120 AC_SUBST(all_selected_languages)
6121 AC_SUBST(build_exeext)
6122 AC_SUBST(build_install_headers_dir)
6123 AC_SUBST(build_xm_file_list)
6124 AC_SUBST(build_xm_include_list)
6125 AC_SUBST(build_xm_defines)
6126 AC_SUBST(build_file_translate)
6127 AC_SUBST(check_languages)
6128 AC_SUBST(cpp_install_dir)
6129 AC_SUBST(xmake_file)
6130 AC_SUBST(tmake_file)
6131 AC_SUBST(TM_ENDIAN_CONFIG)
6132 AC_SUBST(TM_MULTILIB_CONFIG)
6133 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
6134 AC_SUBST(extra_gcc_objs)
6135 AC_SUBST(user_headers_inc_next_pre)
6136 AC_SUBST(user_headers_inc_next_post)
6137 AC_SUBST(extra_headers_list)
6138 AC_SUBST(extra_objs)
6139 AC_SUBST(extra_programs)
6140 AC_SUBST(float_h_file)
6141 AC_SUBST(gcc_config_arguments)
6142 AC_SUBST(gcc_gxx_include_dir)
6143 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
6144 AC_SUBST(host_exeext)
6145 AC_SUBST(host_xm_file_list)
6146 AC_SUBST(host_xm_include_list)
6147 AC_SUBST(host_xm_defines)
6148 AC_SUBST(out_host_hook_obj)
6149 AC_SUBST(install)
6150 AC_SUBST(lang_opt_files)
6151 AC_SUBST(lang_specs_files)
6152 AC_SUBST(lang_tree_files)
6153 AC_SUBST(local_prefix)
6154 AC_SUBST(md_file)
6155 AC_SUBST(objc_boehm_gc)
6156 AC_SUBST(out_file)
6157 AC_SUBST(out_object_file)
6158 AC_SUBST(common_out_file)
6159 AC_SUBST(common_out_object_file)
6160 AC_SUBST(tm_file_list)
6161 AC_SUBST(tm_include_list)
6162 AC_SUBST(tm_defines)
6163 AC_SUBST(tm_p_file_list)
6164 AC_SUBST(tm_p_include_list)
6165 AC_SUBST(xm_file_list)
6166 AC_SUBST(xm_include_list)
6167 AC_SUBST(xm_defines)
6168 AC_SUBST(use_gcc_stdint)
6169 AC_SUBST(c_target_objs)
6170 AC_SUBST(cxx_target_objs)
6171 AC_SUBST(fortran_target_objs)
6172 AC_SUBST(target_cpu_default)
6173
6174 AC_SUBST_FILE(language_hooks)
6175
6176 # Echo link setup.
6177 if test x${build} = x${host} ; then
6178   if test x${host} = x${target} ; then
6179     echo "Links are now set up to build a native compiler for ${target}." 1>&2
6180   else
6181     echo "Links are now set up to build a cross-compiler" 1>&2
6182     echo " from ${host} to ${target}." 1>&2
6183   fi
6184 else
6185   if test x${host} = x${target} ; then
6186     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
6187     echo " for ${target}." 1>&2
6188   else
6189     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
6190     echo " from ${host} to ${target}." 1>&2
6191   fi
6192 fi
6193
6194 AC_ARG_VAR(GMPLIBS,[How to link GMP])
6195 AC_ARG_VAR(GMPINC,[How to find GMP include files])
6196
6197 AC_ARG_VAR(ISLLIBS,[How to link isl])
6198 AC_ARG_VAR(ISLINC,[How to find isl include files])
6199 if test "x${ISLLIBS}" != "x" ; then
6200    AC_DEFINE(HAVE_isl, 1, [Define if isl is in use.])
6201 fi
6202
6203 # Check whether isl_options_set_schedule_serialize_sccs is available;
6204 # it's new in isl 0.15.
6205 if test "x${ISLLIBS}" != "x" ; then
6206   saved_CXXFLAGS="$CXXFLAGS"
6207   CXXFLAGS="$CXXFLAGS $ISLINC $GMPINC"
6208   saved_LIBS="$LIBS"
6209   LIBS="$LIBS $ISLLIBS $GMPLIBS"
6210
6211   AC_MSG_CHECKING([Checking for isl_options_set_schedule_serialize_sccs])
6212   AC_TRY_LINK([#include <isl/schedule.h>],
6213               [isl_options_set_schedule_serialize_sccs (NULL, 0);],
6214               [ac_has_isl_options_set_schedule_serialize_sccs=yes],
6215               [ac_has_isl_options_set_schedule_serialize_sccs=no])
6216   AC_MSG_RESULT($ac_has_isl_options_set_schedule_serialize_sccs)
6217
6218   LIBS="$saved_LIBS"
6219   CXXFLAGS="$saved_CXXFLAGS"
6220
6221   if test x"$ac_has_isl_options_set_schedule_serialize_sccs" = x"yes"; then
6222      AC_DEFINE(HAVE_ISL_OPTIONS_SET_SCHEDULE_SERIALIZE_SCCS, 1,
6223                [Define if isl_options_set_schedule_serialize_sccs exists.])
6224   fi
6225 fi
6226
6227 GCC_ENABLE_PLUGINS
6228 AC_SUBST(pluginlibs)
6229 AC_SUBST(enable_plugin)
6230 if test x"$enable_plugin" = x"yes"; then
6231   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
6232 fi
6233
6234
6235 # Enable --enable-host-shared
6236 AC_ARG_ENABLE(host-shared,
6237 [AS_HELP_STRING([--enable-host-shared],
6238                 [build host code as shared libraries])],
6239 [PICFLAG=-fPIC], [PICFLAG=])
6240 AC_SUBST(enable_host_shared)
6241 AC_SUBST(PICFLAG)
6242
6243
6244 AC_ARG_ENABLE(libquadmath-support,
6245 [AS_HELP_STRING([--disable-libquadmath-support],
6246   [disable libquadmath support for Fortran])],
6247 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
6248 ENABLE_LIBQUADMATH_SUPPORT=yes)
6249 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
6250   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
6251             [Define to 1 to enable libquadmath support])
6252 fi
6253
6254
6255 # Specify what hash style to use by default.
6256 AC_ARG_WITH([linker-hash-style],
6257 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
6258                 [specify the linker hash style])],
6259 [case x"$withval" in
6260    xsysv)
6261      LINKER_HASH_STYLE=sysv
6262      ;;
6263    xgnu)
6264      LINKER_HASH_STYLE=gnu
6265      ;;
6266    xboth)
6267      LINKER_HASH_STYLE=both
6268      ;;
6269    *)
6270      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
6271      ;;
6272  esac],
6273 [LINKER_HASH_STYLE=''])
6274 if test x"${LINKER_HASH_STYLE}" != x; then
6275   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
6276                                          [The linker hash style])
6277 fi
6278
6279 # Specify what should be the default of -fdiagnostics-color option.
6280 AC_ARG_WITH([diagnostics-color],
6281 [AC_HELP_STRING([--with-diagnostics-color={never,auto,auto-if-env,always}],
6282                 [specify the default of -fdiagnostics-color option
6283                  auto-if-env stands for -fdiagnostics-color=auto if
6284                  GCC_COLOR environment variable is present and
6285                  -fdiagnostics-color=never otherwise])],
6286 [case x"$withval" in
6287    xnever)
6288      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_NO
6289      ;;
6290    xauto)
6291      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO
6292      ;;
6293    xauto-if-env)
6294      DIAGNOSTICS_COLOR_DEFAULT=-1
6295      ;;
6296    xalways)
6297      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_YES
6298      ;;
6299    *)
6300      AC_MSG_ERROR([$withval is an invalid option to --with-diagnostics-color])
6301      ;;
6302  esac],
6303 [DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO])
6304 AC_DEFINE_UNQUOTED(DIAGNOSTICS_COLOR_DEFAULT, $DIAGNOSTICS_COLOR_DEFAULT,
6305                    [The default for -fdiagnostics-color option])
6306
6307 # Generate gcc-driver-name.h containing GCC_DRIVER_NAME for the benefit
6308 # of jit/jit-playback.c.
6309 cat > gcc-driver-name.h <<EOF
6310 #define GCC_DRIVER_NAME "${target_noncanonical}-gcc-${gcc_BASEVER}${exeext}"
6311 EOF
6312
6313 # Check whether --enable-default-pie was given.
6314 AC_ARG_ENABLE(default-pie,
6315 [AS_HELP_STRING([--enable-default-pie],
6316   [enable Position Independent Executable as default])],
6317 enable_default_pie=$enableval,
6318 enable_default_pie=no)
6319 if test x$enable_default_pie = xyes ; then
6320   AC_DEFINE(ENABLE_DEFAULT_PIE, 1,
6321       [Define if your target supports default PIE and it is enabled.])
6322 fi
6323 AC_SUBST([enable_default_pie])
6324
6325 # Check if -fno-PIE works.
6326 AC_CACHE_CHECK([for -fno-PIE option],
6327   [gcc_cv_c_no_fpie],
6328   [saved_CXXFLAGS="$CXXFLAGS"
6329    CXXFLAGS="$CXXFLAGS -fno-PIE"
6330    AC_COMPILE_IFELSE([int main(void) {return 0;}],
6331      [gcc_cv_c_no_fpie=yes],
6332      [gcc_cv_c_no_fpie=no])
6333    CXXFLAGS="$saved_CXXFLAGS"])
6334 if test "$gcc_cv_c_no_fpie" = "yes"; then
6335   NO_PIE_CFLAGS="-fno-PIE"
6336 fi
6337 AC_SUBST([NO_PIE_CFLAGS])
6338
6339 # Check if -no-pie works.
6340 AC_CACHE_CHECK([for -no-pie option],
6341   [gcc_cv_no_pie],
6342   [saved_LDFLAGS="$LDFLAGS"
6343    LDFLAGS="$LDFLAGS -no-pie"
6344    AC_LINK_IFELSE([int main(void) {return 0;}],
6345      [gcc_cv_no_pie=yes],
6346      [gcc_cv_no_pie=no])
6347    LDFLAGS="$saved_LDFLAGS"])
6348 if test "$gcc_cv_no_pie" = "yes"; then
6349   NO_PIE_FLAG="-no-pie"
6350 fi
6351 AC_SUBST([NO_PIE_FLAG])
6352
6353 # Check linker supports '-z bndplt'
6354 ld_bndplt_support=no
6355 AC_MSG_CHECKING(linker -z bndplt option)
6356 if test x"$ld_is_gold" = xno; then
6357   if test $in_tree_ld = yes ; then
6358     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
6359       ld_bndplt_support=yes
6360     fi
6361   elif test x$gcc_cv_ld != x; then
6362     # Check if linker supports -a bndplt option
6363     if $gcc_cv_ld --help 2>/dev/null | grep -- '-z bndplt' > /dev/null; then
6364       ld_bndplt_support=yes
6365     fi
6366   fi
6367 fi
6368 if test x"$ld_bndplt_support" = xyes; then
6369   AC_DEFINE(HAVE_LD_BNDPLT_SUPPORT, 1,
6370         [Define if your linker supports -z bndplt])
6371 fi
6372 AC_MSG_RESULT($ld_bndplt_support)
6373
6374 # Check linker supports '--push-state'/'--pop-state'
6375 ld_pushpopstate_support=no
6376 AC_MSG_CHECKING(linker --push-state/--pop-state options)
6377 if test x"$ld_is_gold" = xno; then
6378   if test $in_tree_ld = yes ; then
6379     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
6380       ld_pushpopstate_support=yes
6381     fi
6382   elif test x$gcc_cv_ld != x; then
6383     # Check if linker supports --push-state/--pop-state options
6384     if $gcc_cv_ld --help 2>/dev/null | grep -- '--push-state' > /dev/null; then
6385       ld_pushpopstate_support=yes
6386     fi
6387   fi
6388 fi
6389 if test x"$ld_pushpopstate_support" = xyes; then
6390   AC_DEFINE(HAVE_LD_PUSHPOPSTATE_SUPPORT, 1,
6391         [Define if your linker supports --push-state/--pop-state])
6392 fi
6393 AC_MSG_RESULT($ld_pushpopstate_support)
6394
6395 # Configure the subdirectories
6396 # AC_CONFIG_SUBDIRS($subdirs)
6397
6398 # Create the Makefile
6399 # and configure language subdirectories
6400 AC_CONFIG_FILES($all_outputs)
6401
6402 AC_CONFIG_COMMANDS([default],
6403 [
6404 case ${CONFIG_HEADERS} in
6405   *auto-host.h:config.in*)
6406   echo > cstamp-h ;;
6407 esac
6408 # Make sure all the subdirs exist.
6409 for d in $subdirs doc build common c-family
6410 do
6411     test -d $d || mkdir $d
6412 done
6413 ],
6414 [subdirs='$subdirs'])
6415 AC_OUTPUT
6416