gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 _GCC_TOPLEV_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # ----------------------
 215 # Find default assembler
 216 # ----------------------
 217
 218 # With GNU as
 219 AC_ARG_WITH(gnu-as,
 220 [  --with-gnu-as           arrange to work with GNU as],
 221 gas_flag="$with_gnu_as",
 222 gas_flag=no)
 223
 224 AC_ARG_WITH(as,
 225 [  --with-as               arrange to use the specified as (full pathname)],
 226 DEFAULT_ASSEMBLER="$with_as")
 227 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 228   if test ! -x "$DEFAULT_ASSEMBLER"; then
 229     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 230   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 231     gas_flag=yes
 232   fi
 233   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 234         [Define to enable the use of a default assembler.])
 235 fi
 236
 237 AC_MSG_CHECKING([whether a default assembler was specified])
 238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 239   if test x"$gas_flag" = x"no"; then
 240     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 241   else
 242     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 243   fi
 244 else
 245   AC_MSG_RESULT(no)
 246 fi
 247
 248 # ---------------
 249 # Find C compiler
 250 # ---------------
 251
 252 # If a non-executable a.out is present (e.g. created by GNU as above even if
 253 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 254 # file, even when creating an executable, so an execution test fails.
 255 # Remove possible default executable files to avoid this.
 256 #
 257 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 258 # Autoconf includes it.
 259 rm -f a.out a.exe b.out
 260
 261 # Find the native compiler
 262 AC_PROG_CC
 263 AC_PROG_CC_C_O
 264 # autoconf is lame and doesn't give us any substitution variable for this.
 265 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 266   NO_MINUS_C_MINUS_O=yes
 267 else
 268   OUTPUT_OPTION='-o $@'
 269 fi
 270 AC_SUBST(NO_MINUS_C_MINUS_O)
 271 AC_SUBST(OUTPUT_OPTION)
 272
 273 # -------------------------
 274 # Check C compiler features
 275 # -------------------------
 276
 277 AC_PROG_CPP
 278 AC_C_INLINE
 279
 280 gcc_AC_C_LONG_LONG
 281 gcc_AC_C__BOOL
 282
 283 # sizeof(char) is 1 by definition.
 284 AC_COMPILE_CHECK_SIZEOF(void *)
 285 AC_COMPILE_CHECK_SIZEOF(short)
 286 AC_COMPILE_CHECK_SIZEOF(int)
 287 AC_COMPILE_CHECK_SIZEOF(long)
 288 if test $ac_cv_c_long_long = yes; then
 289   AC_COMPILE_CHECK_SIZEOF(long long)
 290 fi
 291 if test $ac_cv_c___int64 = yes; then
 292   AC_COMPILE_CHECK_SIZEOF(__int64)
 293 fi
 294
 295 # ---------------------
 296 # Warnings and checking
 297 # ---------------------
 298
 299 # Check $CC warning features (if it's GCC).
 300 # We want to use -pedantic, but we don't want warnings about
 301 # * 'long long'
 302 # * variadic macros
 303 # So, we only use -pedantic if we can disable those warnings.
 304
 305 AC_CACHE_CHECK(
 306   [whether ${CC} accepts -Wno-long-long],
 307   [ac_cv_prog_cc_w_no_long_long],
 308   [save_CFLAGS="$CFLAGS"
 309   CFLAGS="-Wno-long-long"
 310   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 311                     [ac_cv_prog_cc_w_no_long_long=yes],
 312                     [ac_cv_prog_cc_w_no_long_long=no])
 313   CFLAGS="$save_CFLAGS"
 314   ])
 315
 316 AC_CACHE_CHECK(
 317   [whether ${CC} accepts -Wno-variadic-macros],
 318   [ac_cv_prog_cc_w_no_variadic_macros],
 319   [save_CFLAGS="$CFLAGS"
 320   CFLAGS="-Wno-variadic-macros"
 321   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 322                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 323                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 324   CFLAGS="$save_CFLAGS"
 325   ])
 326
 327 strict1_warn=
 328 if test $ac_cv_prog_cc_w_no_long_long = yes \
 329    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 330   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 331 fi
 332 AC_SUBST(strict1_warn)
 333
 334 # Add -Wold-style-definition if it's accepted
 335 AC_CACHE_CHECK(
 336   [whether ${CC} accepts -Wold-style-definition],
 337   [ac_cv_prog_cc_w_old_style_definition],
 338   [save_CFLAGS="$CFLAGS"
 339   CFLAGS="-Wold-style-definition"
 340   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 341                     [ac_cv_prog_cc_w_old_style_definition=yes],
 342                     [ac_cv_prog_cc_w_old_style_definition=no])
 343   CFLAGS="$save_CFLAGS"
 344   ])
 345 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 346   strict1_warn="${strict1_warn} -Wold-style-definition"
 347 fi
 348
 349 # Enable -Werror, period.
 350 AC_ARG_ENABLE(werror_always,
 351 [  --enable-werror-always         enable -Werror always], [],
 352 [enable_werror_always=no])
 353 if test x${enable_werror_always} = xyes ; then
 354   strict1_warn="${strict1_warn} -Werror"
 355   WERROR=-Werror
 356 fi
 357
 358 # If the native compiler is GCC, we can enable warnings even in stage1.
 359 # That's useful for people building cross-compilers, or just running a
 360 # quick `make'.
 361 warn_cflags=
 362 if test "x$GCC" = "xyes"; then
 363   warn_cflags='$(GCC_WARN_CFLAGS)'
 364 fi
 365 AC_SUBST(warn_cflags)
 366
 367 # Enable -Werror in bootstrap stage2 and later.
 368 # Change the default to "no" on release branches.
 369 AC_ARG_ENABLE(werror,
 370 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 371 [enable_werror=yes])
 372 if test x$enable_werror = xyes ; then
 373   WERROR=-Werror
 374 fi
 375 AC_SUBST(WERROR)
 376
 377 # Enable expensive internal checks
 378 AC_ARG_ENABLE(checking,
 379 [  --enable-checking[=LIST]
 380                           enable expensive run-time checks.  With LIST,
 381                           enable only specific categories of checks.
 382                           Categories are: misc,tree,rtl,rtlflag,gc,gcac,fold;
 383                           default is misc,tree,gc,rtlflag],
 384 [ac_checking=
 385 ac_tree_checking=
 386 ac_rtl_checking=
 387 ac_rtlflag_checking=
 388 ac_gc_checking=
 389 ac_gc_always_collect=
 390 ac_fold_checking=
 391 case "${enableval}" in
 392 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;
 393         ac_rtlflag_checking=1 ;;
 394 no)     ;;
 395 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 396         set fnord $enableval; shift
 397         IFS="$ac_save_IFS"
 398         for check
 399         do
 400                 case $check in
 401                 misc)   ac_checking=1 ;;
 402                 tree)   ac_tree_checking=1 ;;
 403                 rtlflag)        ac_rtlflag_checking=1 ;;
 404                 rtl)    ac_rtl_checking=1 ;;
 405                 gc)     ac_gc_checking=1 ;;
 406                 gcac)   ac_gc_always_collect=1 ;;
 407                 fold)   ac_fold_checking=1 ;;
 408                 valgrind)       ac_checking_valgrind=1 ;;
 409                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 410                 esac
 411         done
 412         ;;
 413 esac
 414 ],
 415 # Enable some checks by default for development versions of GCC
 416 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1; ac_rtlflag_checking=1;])
 417 nocommon_flag=""
 418 if test x$ac_checking != x ; then
 419   AC_DEFINE(ENABLE_CHECKING, 1,
 420 [Define if you want more run-time sanity checks.  This one gets a grab
 421    bag of miscellaneous but relatively cheap checks.])
 422   nocommon_flag=-fno-common
 423 fi
 424 AC_SUBST(nocommon_flag)
 425 if test x$ac_tree_checking != x ; then
 426   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 427 [Define if you want all operations on trees (the basic data
 428    structure of the front ends) to be checked for dynamic type safety
 429    at runtime.  This is moderately expensive.])
 430 fi
 431 if test x$ac_rtl_checking != x ; then
 432   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 433 [Define if you want all operations on RTL (the basic data structure
 434    of the optimizer and back end) to be checked for dynamic type safety
 435    at runtime.  This is quite expensive.])
 436 fi
 437 if test x$ac_rtlflag_checking != x ; then
 438   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 439 [Define if you want RTL flag accesses to be checked against the RTL
 440    codes that are supported for each access macro.  This is relatively
 441    cheap.])
 442 fi
 443 if test x$ac_gc_checking != x ; then
 444   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 445 [Define if you want the garbage collector to do object poisoning and
 446    other memory allocation checks.  This is quite expensive.])
 447 fi
 448 if test x$ac_gc_always_collect != x ; then
 449   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 450 [Define if you want the garbage collector to operate in maximally
 451    paranoid mode, validating the entire heap and collecting garbage at
 452    every opportunity.  This is extremely expensive.])
 453 fi
 454 if test x$ac_fold_checking != x ; then
 455   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 456 [Define if you want fold checked that it never destructs its argument.
 457    This is quite expensive.])
 458 fi
 459 valgrind_path_defines=
 460 valgrind_command=
 461
 462 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 463 dnl # an if statement.  This was the source of very frustrating bugs
 464 dnl # in converting to autoconf 2.5x!
 465 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 466
 467 if test x$ac_checking_valgrind != x ; then
 468   # It is certainly possible that there's valgrind but no valgrind.h.
 469   # GCC relies on making annotations so we must have both.
 470   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 471   AC_TRY_CPP(
 472     [#include <valgrind/memcheck.h>
 473 #ifndef VALGRIND_DISCARD
 474 #error VALGRIND_DISCARD not defined
 475 #endif],
 476   [gcc_cv_header_valgrind_memcheck_h=yes],
 477   [gcc_cv_header_valgrind_memcheck_h=no])
 478   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 479   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 480   AC_TRY_CPP(
 481     [#include <memcheck.h>
 482 #ifndef VALGRIND_DISCARD
 483 #error VALGRIND_DISCARD not defined
 484 #endif],
 485   [gcc_cv_header_memcheck_h=yes],
 486   gcc_cv_header_memcheck_h=no)
 487   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 488   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 489         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 490   if test "x$valgrind_path" = "x" \
 491     || (test $have_valgrind_h = no \
 492         && test $gcc_cv_header_memcheck_h = no \
 493         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 494         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 495   fi
 496   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 497   valgrind_command="$valgrind_path -q"
 498   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 499 [Define if you want to run subprograms and generated programs
 500    through valgrind (a memory checker).  This is extremely expensive.])
 501   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 502     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 503         [Define if valgrind's valgrind/memcheck.h header is installed.])
 504   fi
 505   if test $gcc_cv_header_memcheck_h = yes; then
 506     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 507         [Define if valgrind's memcheck.h header is installed.])
 508   fi
 509 fi
 510 AC_SUBST(valgrind_path_defines)
 511 AC_SUBST(valgrind_command)
 512
 513 # Enable code coverage collection
 514 AC_ARG_ENABLE(coverage,
 515 [  --enable-coverage[=LEVEL]
 516                           enable compiler\'s code coverage collection.
 517                           Use to measure compiler performance and locate
 518                           unused parts of the compiler. With LEVEL, specify
 519                           optimization. Values are opt, noopt,
 520                           default is noopt],
 521 [case "${enableval}" in
 522   yes|noopt)
 523     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 524     ;;
 525   opt)
 526     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 527     ;;
 528   no)
 529     # a.k.a. --disable-coverage
 530     coverage_flags=""
 531     ;;
 532   *)
 533     AC_MSG_ERROR(unknown coverage setting $enableval)
 534     ;;
 535 esac],
 536 [coverage_flags=""])
 537 AC_SUBST(coverage_flags)
 538
 539 AC_ARG_ENABLE(gather-detailed-mem-stats,
 540 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 541 [enable_gather_detailed_mem_stats=no])
 542 if test x$enable_gather_detailed_mem_stats = xyes ; then
 543   AC_DEFINE(GATHER_STATISTICS, 1,
 544         [Define to enable detailed memory allocation stats gathering.])
 545 fi
 546
 547 # -------------------------------
 548 # Miscenalleous configure options
 549 # -------------------------------
 550
 551 # With stabs
 552 AC_ARG_WITH(stabs,
 553 [  --with-stabs            arrange to use stabs instead of host debug format],
 554 stabs="$with_stabs",
 555 stabs=no)
 556
 557 # Determine whether or not multilibs are enabled.
 558 AC_ARG_ENABLE(multilib,
 559 [  --enable-multilib       enable library support for multiple ABIs],
 560 [], [enable_multilib=yes])
 561 AC_SUBST(enable_multilib)
 562
 563 # Enable __cxa_atexit for C++.
 564 AC_ARG_ENABLE(__cxa_atexit,
 565 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 566 [], [])
 567
 568 # Enable threads
 569 # Pass with no value to take the default
 570 # Pass with a value to specify a thread package
 571 AC_ARG_ENABLE(threads,
 572 [  --enable-threads        enable thread usage for target GCC
 573   --enable-threads=LIB    use LIB thread package for target GCC],,
 574 enable_threads='')
 575 # Save in case it gets overwritten in config.gcc
 576 enable_threads_flag=$enable_threads
 577
 578 AC_ARG_ENABLE(objc-gc,
 579 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 580                           the GNU Objective-C runtime],
 581 if test x$enable_objc_gc = xno; then
 582         objc_boehm_gc=''
 583 else
 584         objc_boehm_gc=1
 585 fi,
 586 objc_boehm_gc='')
 587
 588 AC_ARG_WITH(dwarf2,
 589 [  --with-dwarf2           force the default debug format to be DWARF 2],
 590 dwarf2="$with_dwarf2",
 591 dwarf2=no)
 592
 593 AC_ARG_ENABLE(shared,
 594 [  --disable-shared        don't provide a shared libgcc],
 595 [
 596   case $enable_shared in
 597   yes | no) ;;
 598   *)
 599     enable_shared=no
 600     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 601     for pkg in $enableval; do
 602       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 603         enable_shared=yes
 604       fi
 605     done
 606     IFS="$ac_save_ifs"
 607     ;;
 608   esac
 609 ], [enable_shared=yes])
 610 AC_SUBST(enable_shared)
 611
 612 AC_ARG_WITH(sysroot,
 613 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 614 [
 615  case ${with_sysroot} in
 616  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 617  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 618  esac
 619
 620  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 621  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 622
 623  if test "x$exec_prefix" = xNONE; then
 624   if test "x$prefix" = xNONE; then
 625    test_prefix=/usr/local
 626   else
 627    test_prefix=$prefix
 628   fi
 629  else
 630   test_prefix=$exec_prefix
 631  fi
 632  case ${TARGET_SYSTEM_ROOT} in
 633  "${test_prefix}"|"${test_prefix}/"*|\
 634  '${exec_prefix}'|'${exec_prefix}/'*)
 635    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 636    TARGET_SYSTEM_ROOT_DEFINE="$t"
 637    ;;
 638  esac
 639 ], [
 640  TARGET_SYSTEM_ROOT=
 641  TARGET_SYSTEM_ROOT_DEFINE=
 642  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 643 ])
 644 AC_SUBST(TARGET_SYSTEM_ROOT)
 645 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 646 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 647
 648 # Build with intermodule optimisations
 649 AC_ARG_ENABLE(intermodule,
 650 [  --enable-intermodule    build the compiler in one step],
 651 [case ${enable_intermodule} in
 652   yes) onestep="-onestep";;
 653   *) onestep="";;
 654 esac],
 655 [onestep=""])
 656 AC_SUBST(onestep)
 657
 658 # Sanity check enable_languages in case someone does not run the toplevel
 659 # configure # script.
 660 AC_ARG_ENABLE(languages,
 661 [  --enable-languages=LIST specify which front-ends to build],
 662 [case ,${enable_languages}, in
 663        ,,|,yes,)
 664                 # go safe -- we cannot be much sure without the toplevel
 665                 # configure's
 666                 # analysis of which target libs are present and usable
 667                 enable_languages=c
 668                 ;;
 669          *,all,*)
 670                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 671                 ;;
 672         *,c,*)
 673                 ;;
 674         *)
 675                 enable_languages=c,${enable_languages}
 676                 ;;
 677 esac],
 678 [enable_languages=c])
 679
 680 subdirs=
 681 for lang in ${srcdir}/*/config-lang.in
 682 do
 683         case $lang in
 684         # The odd quoting in the next line works around
 685         # an apparent bug in bash 1.12 on linux.
 686 changequote(,)dnl
 687         ${srcdir}/[*]/config-lang.in) ;;
 688         *)
 689           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 690           if test "x$lang_alias" = x
 691           then
 692                 echo "$lang doesn't set \$language." 1>&2
 693                 exit 1
 694           fi
 695           case ",$enable_languages," in
 696           *,$lang_alias,*)
 697             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 698           esac
 699           ;;
 700 changequote([,])dnl
 701         esac
 702 done
 703
 704
 705 # -------------------------
 706 # Checks for other programs
 707 # -------------------------
 708
 709 AC_PROG_MAKE_SET
 710
 711 # Find some useful tools
 712 AC_PROG_AWK
 713 # We need awk to run opts.sh (to create options.c and options.h).
 714 # Bail out if it's missing.
 715 case ${AWK} in
 716   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 717 esac
 718
 719 gcc_AC_PROG_LN
 720 gcc_AC_PROG_LN_S
 721 AC_PROG_RANLIB
 722 gcc_AC_PROG_INSTALL
 723
 724 # See if cmp has --ignore-initial.
 725 gcc_AC_PROG_CMP_IGNORE_INITIAL
 726
 727 # See if we have the mktemp command.
 728 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 729
 730 # Do we have a single-tree copy of texinfo?
 731 if test -f $srcdir/../texinfo/Makefile.in; then
 732   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 733   gcc_cv_prog_makeinfo_modern=yes
 734   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 735 else
 736   # See if makeinfo has been installed and is modern enough
 737   # that we can use it.
 738   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 739   [GNU texinfo.* \([0-9][0-9.]*\)],
 740   [4.[2-9]*])
 741 fi
 742
 743 if test $gcc_cv_prog_makeinfo_modern = no; then
 744   AC_MSG_WARN([
 745 *** Makeinfo is missing or too old.
 746 *** Info documentation will not be built.])
 747   BUILD_INFO=
 748 else
 749   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 750 fi
 751
 752 # Is pod2man recent enough to regenerate manpages?
 753 AC_MSG_CHECKING([for recent Pod::Man])
 754 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 755   AC_MSG_RESULT(yes)
 756   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 757 else
 758   AC_MSG_RESULT(no)
 759   GENERATED_MANPAGES=
 760 fi
 761
 762 # How about lex?
 763 dnl Don't use AC_PROG_LEX; we insist on flex.
 764 dnl LEXLIB is not useful in gcc.
 765 if test -f $srcdir/../flex/skel.c; then
 766   FLEX='$(objdir)/../flex/flex'
 767 else
 768   AC_CHECK_PROG(FLEX, flex, flex, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing flex)
 769 fi
 770
 771 # Bison?
 772 # The -L switch is so bison can find its skeleton file.
 773 if test -f $srcdir/../bison/bison.simple; then
 774   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 775 else
 776   AC_CHECK_PROG(BISON, bison, bison, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing bison)
 777 fi
 778
 779 # --------------------
 780 # Checks for C headers
 781 # --------------------
 782
 783 AC_MSG_CHECKING(for GNU C library)
 784 AC_CACHE_VAL(gcc_cv_glibc,
 785 [AC_TRY_COMPILE(
 786   [#include <features.h>],[
 787 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 788 #error Not a GNU C library system
 789 #endif],
 790   [gcc_cv_glibc=yes],
 791   gcc_cv_glibc=no)])
 792 AC_MSG_RESULT($gcc_cv_glibc)
 793 if test $gcc_cv_glibc = yes; then
 794   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 795 fi
 796
 797 # Need to reject headers which give warnings, so that the -Werror bootstrap
 798 # works later. *sigh*  This needs to come before all header checks.
 799 AC_PROG_CPP_WERROR
 800
 801 AC_HEADER_STDC
 802 AC_HEADER_TIME
 803 gcc_AC_HEADER_STDBOOL
 804 gcc_AC_HEADER_STRING
 805 AC_HEADER_SYS_WAIT
 806 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 807                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 808                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 809                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 810
 811 # Check for thread headers.
 812 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 813 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 814
 815 # These tests can't be done till we know if we have limits.h.
 816 gcc_AC_C_CHAR_BIT
 817 AC_C_BIGENDIAN_CROSS
 818
 819 # --------
 820 # UNSORTED
 821 # --------
 822
 823 # Stage specific cflags for build.
 824 stage1_cflags=
 825 case $build in
 826 vax-*-*)
 827   if test x$GCC = xyes
 828   then
 829     stage1_cflags="-Wa,-J"
 830   else
 831     stage1_cflags="-J"
 832   fi
 833   ;;
 834 powerpc-*-darwin*)
 835   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 836   # sources; use -no-cpp-precomp to get to GNU cpp.
 837   # Apple's GCC has bugs in designated initializer handling, so disable
 838   # that too.
 839   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 840   ;;
 841 esac
 842 AC_SUBST(stage1_cflags)
 843
 844 # These libraries may be used by collect2.
 845 # We may need a special search path to get them linked.
 846 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 847 [save_LIBS="$LIBS"
 848 for libs in '' -lld -lmld \
 849                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 850                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 851 do
 852         LIBS="$libs"
 853         AC_TRY_LINK_FUNC(ldopen,
 854                 [gcc_cv_collect2_libs="$libs"; break])
 855 done
 856 LIBS="$save_LIBS"
 857 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 858 case $gcc_cv_collect2_libs in
 859         "none required")        ;;
 860         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 861 esac
 862 AC_SUBST(COLLECT2_LIBS)
 863
 864 # When building Ada code on Alpha, we need exc_resume which is usually in
 865 # -lexc.  So test for it.
 866 save_LIBS="$LIBS"
 867 LIBS=
 868 AC_SEARCH_LIBS(exc_resume, exc)
 869 GNAT_LIBEXC="$LIBS"
 870 LIBS="$save_LIBS"
 871 AC_SUBST(GNAT_LIBEXC)
 872
 873 # Some systems put ldexp and frexp in libm instead of libc; assume
 874 # they're both in the same place.  jcf-dump needs them.
 875 save_LIBS="$LIBS"
 876 LIBS=
 877 AC_SEARCH_LIBS(ldexp, m)
 878 LDEXP_LIB="$LIBS"
 879 LIBS="$save_LIBS"
 880 AC_SUBST(LDEXP_LIB)
 881
 882 # Use <inttypes.h> only if it exists,
 883 # doesn't clash with <sys/types.h>, and declares intmax_t.
 884 AC_MSG_CHECKING(for inttypes.h)
 885 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 886 [AC_TRY_COMPILE(
 887   [#include <sys/types.h>
 888 #include <inttypes.h>],
 889   [intmax_t i = -1;],
 890   [gcc_cv_header_inttypes_h=yes],
 891   gcc_cv_header_inttypes_h=no)])
 892 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 893 if test $gcc_cv_header_inttypes_h = yes; then
 894   AC_DEFINE(HAVE_INTTYPES_H, 1,
 895         [Define if you have a working <inttypes.h> header file.])
 896 fi
 897
 898 dnl Disabled until we have a complete test for buggy enum bitfields.
 899 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 900
 901 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 902         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
 903         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 904         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
 905         setlocale)
 906
 907 if test x$ac_cv_func_mbstowcs = xyes; then
 908   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 909 [    AC_TRY_RUN([#include <stdlib.h>
 910 int main()
 911 {
 912   mbstowcs(0, "", 0);
 913   return 0;
 914 }],
 915     gcc_cv_func_mbstowcs_works=yes,
 916     gcc_cv_func_mbstowcs_works=no,
 917     gcc_cv_func_mbstowcs_works=yes)])
 918   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 919     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 920   [Define this macro if mbstowcs does not crash when its
 921    first argument is NULL.])
 922   fi
 923 fi
 924
 925 AC_CHECK_TYPE(ssize_t, int)
 926
 927 # Try to determine the array type of the second argument of getgroups
 928 # for the target system (int or gid_t).
 929 AC_TYPE_GETGROUPS
 930 if test "${target}" = "${build}"; then
 931   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 932 else
 933   case "${target}" in
 934         # This condition may need some tweaking.  It should include all
 935         # targets where the array type of the second argument of getgroups
 936         # is int and the type of gid_t is not equivalent to int.
 937         *-*-sunos* | *-*-ultrix*)
 938                 TARGET_GETGROUPS_T=int
 939                 ;;
 940         *)
 941                 TARGET_GETGROUPS_T=gid_t
 942                 ;;
 943   esac
 944 fi
 945 AC_SUBST(TARGET_GETGROUPS_T)
 946
 947 gcc_AC_FUNC_PRINTF_PTR
 948 gcc_AC_FUNC_MMAP_BLACKLIST
 949
 950 case "${host}" in
 951 *-*-*vms*)
 952   # Under VMS, vfork works very differently than on Unix. The standard test
 953   # won't work, and it isn't easily adaptable. It makes more sense to
 954   # just force it.
 955   ac_cv_func_vfork_works=yes
 956   ;;
 957 esac
 958 AC_FUNC_VFORK
 959
 960 AM_ICONV
 961 # Until we have in-tree GNU iconv:
 962 LIBICONV_DEP=
 963 AC_SUBST(LIBICONV_DEP)
 964
 965 AM_LC_MESSAGES
 966
 967 # We will need to find libiberty.h and ansidecl.h
 968 saved_CFLAGS="$CFLAGS"
 969 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 970 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 971         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 972         fprintf_unlocked strstr errno snprintf vasprintf \
 973         malloc realloc calloc free basename getopt clock, , ,[
 974 #include "ansidecl.h"
 975 #include "system.h"])
 976
 977 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 978 #include "ansidecl.h"
 979 #include "system.h"
 980 #ifdef HAVE_SYS_RESOURCE_H
 981 #include <sys/resource.h>
 982 #endif
 983 ])
 984
 985 AC_TRY_COMPILE([
 986 #include "ansidecl.h"
 987 #include "system.h"
 988 #ifdef HAVE_SYS_RESOURCE_H
 989 #include <sys/resource.h>
 990 #endif
 991 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
 992 [Define to \`long' if <sys/resource.h> doesn't define.])])
 993
 994 gcc_AC_CHECK_DECLS(ldgetname, , ,[
 995 #include "ansidecl.h"
 996 #include "system.h"
 997 #ifdef HAVE_LDFCN_H
 998 #include <ldfcn.h>
 999 #endif
1000 ])
1001
1002 gcc_AC_CHECK_DECLS(times, , ,[
1003 #include "ansidecl.h"
1004 #include "system.h"
1005 #ifdef HAVE_SYS_TIMES_H
1006 #include <sys/times.h>
1007 #endif
1008 ])
1009
1010 # More time-related stuff.
1011 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1012 AC_TRY_COMPILE([
1013 #include "ansidecl.h"
1014 #include "system.h"
1015 #ifdef HAVE_SYS_TIMES_H
1016 #include <sys/times.h>
1017 #endif
1018 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1019 if test $ac_cv_struct_tms = yes; then
1020   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1021   [Define if <sys/times.h> defines struct tms.])
1022 fi
1023
1024 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1025 # revisit after autoconf 2.50.
1026 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1027 AC_TRY_COMPILE([
1028 #include "ansidecl.h"
1029 #include "system.h"
1030 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1031 if test $gcc_cv_type_clock_t = yes; then
1032   AC_DEFINE(HAVE_CLOCK_T, 1,
1033   [Define if <time.h> defines clock_t.])
1034 fi
1035
1036 AC_CACHE_CHECK(for uchar, gcc_cv_type_uchar,
1037 [AC_TRY_COMPILE([
1038 #include "ansidecl.h"
1039 #include "system.h"
1040 ],
1041 [if ((uchar *)0) return 0;
1042  if (sizeof(uchar)) return 0;],
1043 ac_cv_type_uchar=yes, ac_cv_type_uchar=no)])
1044 if test $ac_cv_type_uchar = yes; then
1045   AC_DEFINE(HAVE_UCHAR, 1,
1046   [Define if <sys/types.h> defines \`uchar'.])
1047 fi
1048
1049 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1050 CFLAGS="$saved_CFLAGS"
1051
1052 gcc_AC_INITFINI_ARRAY
1053
1054 # mkdir takes a single argument on some systems.
1055 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1056
1057 # File extensions
1058 manext='.1'
1059 objext='.o'
1060 AC_SUBST(manext)
1061 AC_SUBST(objext)
1062
1063 # With Setjmp/Longjmp based exception handling.
1064 AC_ARG_ENABLE(sjlj-exceptions,
1065 [  --enable-sjlj-exceptions
1066                           arrange to use setjmp/longjmp exception handling],
1067 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1068 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1069   [Define 0/1 to force the choice for exception handling model.])])
1070
1071 if test x$host = x$target; then
1072    AC_CHECK_LIB(unwind, main, use_libunwind_default=yes, use_libunwind_default=no)
1073 else
1074    use_libunwind_default=no
1075 fi
1076 # Use libunwind based exception handling.
1077 AC_ARG_ENABLE(libunwind-exceptions,
1078 [  --enable-libunwind-exceptions  force use libunwind for exceptions],
1079 use_libunwind_exceptions=$enableval,
1080 use_libunwind_exceptions=$use_libunwind_default)
1081 if test x"$use_libunwind_exceptions" = xyes; then
1082    AC_DEFINE(USE_LIBUNWIND_EXCEPTIONS, 1,
1083         [Define if gcc should use -lunwind.])
1084 fi
1085
1086 # --------------------------------------------------------
1087 # Build, host, and target specific configuration fragments
1088 # --------------------------------------------------------
1089
1090 # Collect build-machine-specific information.
1091 . ${srcdir}/config.build
1092
1093 # Collect host-machine-specific information.
1094 . ${srcdir}/config.host
1095
1096 target_gtfiles=
1097
1098 # Collect target-machine-specific information.
1099 . ${srcdir}/config.gcc
1100
1101 extra_objs="${host_extra_objs} ${extra_objs}"
1102 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1103
1104 # Default the target-machine variables that were not explicitly set.
1105 if test x"$tm_file" = x
1106 then tm_file=$cpu_type/$cpu_type.h; fi
1107
1108 if test x"$extra_headers" = x
1109 then extra_headers=; fi
1110
1111 if test x$md_file = x
1112 then md_file=$cpu_type/$cpu_type.md; fi
1113
1114 if test x$out_file = x
1115 then out_file=$cpu_type/$cpu_type.c; fi
1116
1117 if test x"$tmake_file" = x
1118 then tmake_file=$cpu_type/t-$cpu_type
1119 fi
1120
1121 if test x"$dwarf2" = xyes
1122 then tm_file="$tm_file tm-dwarf2.h"
1123 fi
1124
1125 # Say what files are being used for the output code and MD file.
1126 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1127 echo "Using \`$srcdir/config/$md_file' as machine description file."
1128
1129 # If any of the xm_file variables contain nonexistent files, warn
1130 # about them and drop them.
1131
1132 bx=
1133 for x in $build_xm_file; do
1134   if    test -f $srcdir/config/$x
1135   then      bx="$bx $x"
1136   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1137   fi
1138 done
1139 build_xm_file="$bx"
1140
1141 hx=
1142 for x in $host_xm_file; do
1143   if    test -f $srcdir/config/$x
1144   then      hx="$hx $x"
1145   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1146   fi
1147 done
1148 host_xm_file="$hx"
1149
1150 tx=
1151 for x in $xm_file; do
1152   if    test -f $srcdir/config/$x
1153   then      tx="$tx $x"
1154   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1155   fi
1156 done
1157 xm_file="$tx"
1158
1159 count=a
1160 for f in $tm_file; do
1161         count=${count}x
1162 done
1163 if test $count = ax; then
1164         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1165 else
1166         echo "Using the following target machine macro files:"
1167         for f in $tm_file; do
1168                 echo "  $srcdir/config/$f"
1169         done
1170 fi
1171
1172 if test x$need_64bit_hwint = xyes; then
1173         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1174 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1175 fi
1176
1177 count=a
1178 for f in $host_xm_file; do
1179         count=${count}x
1180 done
1181 if test $count = a; then
1182         :
1183 elif test $count = ax; then
1184         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1185 else
1186         echo "Using the following host machine macro files:"
1187         for f in $host_xm_file; do
1188                 echo "  $srcdir/config/$f"
1189         done
1190 fi
1191 echo "Using ${out_host_hook_obj} for host machine hooks."
1192
1193 if test "$host_xm_file" != "$build_xm_file"; then
1194         count=a
1195         for f in $build_xm_file; do
1196                 count=${count}x
1197         done
1198         if test $count = a; then
1199                 :
1200         elif test $count = ax; then
1201                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1202         else
1203                 echo "Using the following build machine macro files:"
1204                 for f in $build_xm_file; do
1205                         echo "  $srcdir/config/$f"
1206                 done
1207         fi
1208 fi
1209
1210 # ---------
1211 # Threading
1212 # ---------
1213
1214 # Check if a valid thread package
1215 case ${enable_threads_flag} in
1216   "" | no)
1217     # No threads
1218     target_thread_file='single'
1219     ;;
1220   yes)
1221     # default
1222     target_thread_file='single'
1223     ;;
1224   aix | dce | gnat | irix | posix | rtems | \
1225   single | solaris | vxworks | win32 )
1226     target_thread_file=${enable_threads_flag}
1227     ;;
1228   *)
1229     echo "${enable_threads_flag} is an unknown thread package" 1>&2
1230     exit 1
1231     ;;
1232 esac
1233
1234 if test x${thread_file} = x; then
1235   # No thread file set by target-specific clauses in config.gcc,
1236   # so use file chosen by default logic above
1237   thread_file=${target_thread_file}
1238 fi
1239
1240 # Make gthr-default.h if we have a thread file.
1241 gthread_flags=
1242 if test $thread_file != single; then
1243   rm -f gthr-default.h
1244   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1245   gthread_flags=-DHAVE_GTHR_DEFAULT
1246 fi
1247 AC_SUBST(gthread_flags)
1248
1249 # --------
1250 # UNSORTED
1251 # --------
1252
1253 if test x$enable___cxa_atexit = xyes || \
1254    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1255    AC_CHECK_FUNC(__cxa_atexit,
1256         [AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1257         [Define if you want to use __cxa_atexit, rather than atexit, to
1258         register C++ destructors for local statics and global objects.
1259         This is essential for fully standards-compliant handling of
1260         destructors, but requires __cxa_atexit in libc.])],
1261         echo "__cxa_atexit can't be enabled on this target")
1262 fi
1263
1264 # Look for a file containing extra machine modes.
1265 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1266   extra_modes_file='$(srcdir)'/config/${extra_modes}
1267   AC_SUBST(extra_modes_file)
1268   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1269   [Define to the name of a file containing a list of extra machine modes
1270    for this architecture.])
1271 fi
1272
1273 # auto-host.h is the file containing items generated by autoconf and is
1274 # the first file included by config.h.
1275 # If host=build, it is correct to have bconfig include auto-host.h
1276 # as well.  If host!=build, we are in error and need to do more
1277 # work to find out the build config parameters.
1278 if test x$host = x$build
1279 then
1280         build_auto=auto-host.h
1281         FORBUILD=..
1282 else
1283         # We create a subdir, then run autoconf in the subdir.
1284         # To prevent recursion we set host and build for the new
1285         # invocation of configure to the build for this invocation
1286         # of configure.
1287         tempdir=build.$$
1288         rm -rf $tempdir
1289         mkdir $tempdir
1290         cd $tempdir
1291         case ${srcdir} in
1292         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1293         *) realsrcdir=../${srcdir};;
1294         esac
1295         saved_CFLAGS="${CFLAGS}"
1296         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1297         ${realsrcdir}/configure \
1298                 --enable-languages=${enable_languages-all} \
1299                 --target=$target_alias --host=$build_alias --build=$build_alias
1300         CFLAGS="${saved_CFLAGS}"
1301
1302         # We just finished tests for the build machine, so rename
1303         # the file auto-build.h in the gcc directory.
1304         mv auto-host.h ../auto-build.h
1305         cd ..
1306         rm -rf $tempdir
1307         build_auto=auto-build.h
1308         FORBUILD=../${build_subdir}
1309 fi
1310 AC_SUBST(FORBUILD)
1311
1312 tm_file="${tm_file} defaults.h"
1313 tm_p_file="${tm_p_file} tm-preds.h"
1314 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1315 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1316 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1317 # put this back in temporarily.
1318 xm_file="ansidecl.h ${xm_file}"
1319
1320 # --------
1321 # UNSORTED
1322 # --------
1323
1324 # Get the version trigger filename from the toplevel
1325 if test "${with_gcc_version_trigger+set}" = set; then
1326         gcc_version_trigger=$with_gcc_version_trigger
1327 else
1328         gcc_version_trigger=${srcdir}/version.c
1329 fi
1330 changequote(,)dnl
1331 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
1332 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1333
1334 # Compile in configure arguments.
1335 if test -f configargs.h ; then
1336         # Being re-configured.
1337         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1338         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1339 else
1340         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1341 fi
1342
1343 # Double all backslashes and backslash all quotes to turn
1344 # gcc_config_arguments into a C string.
1345 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1346 $gcc_config_arguments
1347 EOF
1348 gcc_config_arguments_str=`cat conftest.out`
1349 rm -f conftest.out
1350
1351 cat > configargs.h <<EOF
1352 /* Generated automatically. */
1353 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1354 static const char thread_model[] = "$thread_file";
1355
1356 static const struct {
1357   const char *name, *value;
1358 } configure_default_options[] = $configure_default_options;
1359 EOF
1360 changequote([,])dnl
1361
1362 # Internationalization
1363 PACKAGE=gcc
1364 VERSION="$gcc_version"
1365 AC_SUBST(PACKAGE)
1366 AC_SUBST(VERSION)
1367
1368 ZW_GNU_GETTEXT_SISTER_DIR
1369
1370 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1371 # -liconv on the link line twice.
1372 case "$LIBINTL" in *$LIBICONV*)
1373         LIBICONV= ;;
1374 esac
1375
1376 # Windows32 Registry support for specifying GCC installation paths.
1377 AC_ARG_ENABLE(win32-registry,
1378 [  --disable-win32-registry
1379                           disable lookup of installation paths in the
1380                           Registry on Windows hosts
1381   --enable-win32-registry enable registry lookup (default)
1382   --enable-win32-registry=KEY
1383                           use KEY instead of GCC version as the last portion
1384                           of the registry key],,)
1385 case $host_os in
1386         win32 | pe | cygwin* | mingw32* | uwin*)
1387 AC_MSG_CHECKING(whether windows registry support is requested)
1388 if test "x$enable_win32_registry" != xno; then
1389   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1390 [Define to 1 if installation paths should be looked up in Windows32
1391    Registry. Ignored on non windows32 hosts.])
1392   AC_MSG_RESULT(yes)
1393   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1394 else
1395   AC_MSG_RESULT(no)
1396 fi
1397
1398 # Check if user specified a different registry key.
1399 case "x${enable_win32_registry}" in
1400 x | xyes)
1401   # default.
1402   gcc_cv_win32_registry_key="$VERSION"
1403   ;;
1404 xno)
1405   # no registry lookup.
1406   gcc_cv_win32_registry_key=''
1407   ;;
1408 *)
1409   # user-specified key.
1410   gcc_cv_win32_registry_key="$enable_win32_registry"
1411   ;;
1412 esac
1413
1414 if test "x$enable_win32_registry" != xno; then
1415   AC_MSG_CHECKING(registry key on windows hosts)
1416   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1417         [Define to be the last portion of registry key on windows hosts.])
1418   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1419 fi
1420 ;;
1421 esac
1422
1423 # Get an absolute path to the GCC top-level source directory
1424 holddir=`${PWDCMD-pwd}`
1425 cd $srcdir
1426 topdir=`${PWDCMD-pwd}`
1427 cd $holddir
1428
1429 # Conditionalize the makefile for this host machine.
1430 xmake_file=
1431 for f in ${host_xmake_file}
1432 do
1433         if test -f ${srcdir}/config/$f
1434         then
1435                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1436         fi
1437 done
1438
1439 # Conditionalize the makefile for this target machine.
1440 tmake_file_=
1441 for f in ${tmake_file}
1442 do
1443         if test -f ${srcdir}/config/$f
1444         then
1445                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1446         fi
1447 done
1448 tmake_file="${tmake_file_}"
1449
1450 symbolic_link='ln -s'
1451
1452 # If the host doesn't support symlinks, modify CC in
1453 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1454 # Otherwise, we can use "CC=$(CC)".
1455 rm -f symtest.tem
1456 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1457 then
1458         cc_set_by_configure="\$(CC)"
1459         quoted_cc_set_by_configure="\$(CC)"
1460         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1461         quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1462 else
1463         rm -f symtest.tem
1464         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1465         then
1466                 symbolic_link="cp -p"
1467         else
1468                 symbolic_link="cp"
1469         fi
1470         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1471         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1472         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1473         quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1474 fi
1475 rm -f symtest.tem
1476
1477 out_object_file=`basename $out_file .c`.o
1478
1479 tm_file_list=
1480 tm_include_list=
1481 for f in $tm_file; do
1482   case $f in
1483     defaults.h )
1484        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1485        tm_include_list="${tm_include_list} $f"
1486        ;;
1487     * )
1488        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1489        tm_include_list="${tm_include_list} config/$f"
1490        ;;
1491   esac
1492 done
1493
1494 tm_p_file_list=
1495 tm_p_include_list=
1496 for f in $tm_p_file; do
1497   case $f in
1498     tm-preds.h )
1499        tm_p_file_list="${tm_p_file_list} $f"
1500        tm_p_include_list="${tm_p_include_list} $f"
1501        ;;
1502     * )
1503        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1504        tm_p_include_list="${tm_p_include_list} config/$f"
1505   esac
1506 done
1507
1508 xm_file_list=
1509 xm_include_list=
1510 for f in $xm_file; do
1511   case $f in
1512     ansidecl.h )
1513        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1514        xm_include_list="${xm_include_list} $f"
1515        ;;
1516     auto-host.h )
1517        xm_file_list="${xm_file_list} $f"
1518        xm_include_list="${xm_include_list} $f"
1519        ;;
1520     * )
1521        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1522        xm_include_list="${xm_include_list} config/$f"
1523        ;;
1524   esac
1525 done
1526
1527 host_xm_file_list=
1528 host_xm_include_list=
1529 for f in $host_xm_file; do
1530   case $f in
1531     ansidecl.h )
1532        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1533        host_xm_include_list="${host_xm_include_list} $f"
1534        ;;
1535     auto-host.h )
1536        host_xm_file_list="${host_xm_file_list} $f"
1537        host_xm_include_list="${host_xm_include_list} $f"
1538        ;;
1539     * )
1540        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1541        host_xm_include_list="${host_xm_include_list} config/$f"
1542        ;;
1543   esac
1544 done
1545
1546 build_xm_file_list=
1547 for f in $build_xm_file; do
1548   case $f in
1549     ansidecl.h )
1550        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1551        build_xm_include_list="${build_xm_include_list} $f"
1552        ;;
1553     auto-build.h | auto-host.h )
1554        build_xm_file_list="${build_xm_file_list} $f"
1555        build_xm_include_list="${build_xm_include_list} $f"
1556        ;;
1557     * )
1558        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1559        build_xm_include_list="${build_xm_include_list} config/$f"
1560        ;;
1561   esac
1562 done
1563
1564 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1565 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1566 CROSS=                                          AC_SUBST(CROSS)
1567 ALL=all.internal                                AC_SUBST(ALL)
1568 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1569 if test x$host != x$target
1570 then
1571         CROSS="-DCROSS_COMPILE"
1572         ALL=all.cross
1573         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1574         case "$host","$target" in
1575         # Darwin crosses can use the host system's libraries and headers,
1576         # because of the fat library support.  Of course, it must be the
1577         # same version of Darwin on both sides.  Allow the user to
1578         # just say --target=foo-darwin without a version number to mean
1579         # "the version on this system".
1580             *-*-darwin*,*-*-darwin*)
1581                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1582                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1583                 if test $hostos = $targetos -o $targetos = darwin ; then
1584                     CROSS=
1585                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1586                     with_headers=yes
1587                 fi
1588                 ;;
1589
1590             i?86-*-*,x86_64-*-* \
1591             | powerpc*-*-*,powerpc64*-*-*)
1592                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1593         esac
1594 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1595         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1596         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1597 fi
1598
1599 # If this is a cross-compiler that does not
1600 # have its own set of headers then define
1601 # inhibit_libc
1602
1603 # If this is using newlib, without having the headers available now,
1604 # then define inhibit_libc in LIBGCC2_CFLAGS.
1605 # This prevents libgcc2 from containing any code which requires libc
1606 # support.
1607 inhibit_libc=
1608 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1609        test x$with_newlib = xyes ; } &&
1610      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1611        inhibit_libc=-Dinhibit_libc
1612 fi
1613 AC_SUBST(inhibit_libc)
1614
1615 # When building gcc with a cross-compiler, we need to adjust things so
1616 # that the generator programs are still built with the native compiler.
1617 # Also, we cannot run fixincludes or fix-header.
1618
1619 # These are the normal (build=host) settings:
1620 BUILD_PREFIX=                   AC_SUBST(BUILD_PREFIX)
1621 BUILD_PREFIX_1=ignore-          AC_SUBST(BUILD_PREFIX_1)
1622 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1623 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1624
1625 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1626
1627 # Possibly disable fixproto, on a per-target basis.
1628 case ${use_fixproto} in
1629   no)
1630     STMP_FIXPROTO=
1631     ;;
1632   yes)
1633     STMP_FIXPROTO=stmp-fixproto
1634     ;;
1635 esac
1636 AC_SUBST(STMP_FIXPROTO)
1637
1638 # And these apply if build != host, or we are generating coverage data
1639 if test x$build != x$host || test "x$coverage_flags" != x
1640 then
1641     BUILD_PREFIX=build-
1642     BUILD_PREFIX_1=build-
1643     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1644
1645     if test "x$TARGET_SYSTEM_ROOT" = x; then
1646         STMP_FIXINC=
1647         STMP_FIXPROTO=
1648     fi
1649 fi
1650
1651 # Expand extra_headers to include complete path.
1652 # This substitutes for lots of t-* files.
1653 extra_headers_list=
1654 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1655 for file in ${extra_headers} ; do
1656   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1657 done
1658
1659 # Define collect2 in Makefile.
1660 case $host_can_use_collect2 in
1661   no) collect2= ;;
1662   *) collect2='collect2$(exeext)' ;;
1663 esac
1664 AC_SUBST([collect2])
1665
1666 # Add a definition of USE_COLLECT2 if system wants one.
1667 case $use_collect2 in
1668   no) use_collect2= ;;
1669   "") ;;
1670   *)
1671     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1672     xm_defines="${xm_defines} USE_COLLECT2"
1673     case $host_can_use_collect2 in
1674       no)
1675         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1676         ;;
1677     esac
1678     ;;
1679 esac
1680
1681 # ---------------------------
1682 # Assembler & linker features
1683 # ---------------------------
1684
1685 # Identify the assembler which will work hand-in-glove with the newly
1686 # built GCC, so that we can examine its features.  This is the assembler
1687 # which will be driven by the driver program.
1688 #
1689 # If build != host, and we aren't building gas in-tree, we identify a
1690 # build->target assembler and hope that it will have the same features
1691 # as the host->target assembler we'll be using.
1692 AC_MSG_CHECKING(what assembler to use)
1693 in_tree_gas=no
1694 gcc_cv_as=
1695 gcc_cv_gas_major_version=
1696 gcc_cv_gas_minor_version=
1697 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1698 if test -x "$DEFAULT_ASSEMBLER"; then
1699         gcc_cv_as="$DEFAULT_ASSEMBLER"
1700 elif test -x "$AS"; then
1701         gcc_cv_as="$AS"
1702 elif test -x as$host_exeext; then
1703         # Build using assembler in the current directory.
1704         gcc_cv_as=./as$host_exeext
1705 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1706      && test -f ../gas/Makefile; then
1707   # Single tree build which includes gas.
1708   in_tree_gas=yes
1709   _gcc_COMPUTE_GAS_VERSION
1710   rm -f as$host_exeext
1711   $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1712   in_tree_gas_is_elf=no
1713   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1714      || (grep 'obj_format = multi' ../gas/Makefile \
1715          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1716   then
1717     in_tree_gas_is_elf=yes
1718   fi
1719 fi
1720
1721 if test "x$gcc_cv_as" = x; then
1722         # Search the same directories that the installed compiler will
1723         # search.  Else we may find the wrong assembler and lose.  If we
1724         # do not find a suitable assembler binary, then try the user's
1725         # path.
1726         #
1727         # Also note we have to check MD_EXEC_PREFIX before checking the
1728         # user's path.  Unfortunately, there is no good way to get at the
1729         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1730         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1731         # to be fixed as part of the make/configure rewrite too.
1732
1733         if test "x$exec_prefix" = xNONE; then
1734                 if test "x$prefix" = xNONE; then
1735                         test_prefix=/usr/local
1736                 else
1737                         test_prefix=$prefix
1738                 fi
1739         else
1740                 test_prefix=$exec_prefix
1741         fi
1742
1743         # If the loop below does not find an assembler, then use whatever
1744         # one we can find in the users's path.
1745         # user's path.
1746         if test "x$program_prefix" != xNONE; then
1747                 gcc_cv_as=${program_prefix}as$host_exeext
1748         else
1749                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$host_exeext
1750         fi
1751
1752         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1753                    $test_prefix/libexec/gcc/$target_noncanonical \
1754                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1755                    /usr/lib/gcc/$target_noncanonical \
1756                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1757                    $test_prefix/$target_noncanonical/bin"
1758
1759         if test x$host = x$target; then
1760             test_dirs="$test_dirs \
1761                    /usr/libexec \
1762                    /usr/ccs/gcc \
1763                    /usr/ccs/bin \
1764                    /udk/usr/ccs/bin \
1765                    /bsd43/usr/lib/cmplrs/cc \
1766                    /usr/cross64/usr/bin \
1767                    /usr/lib/cmplrs/cc \
1768                    /sysv/usr/lib/cmplrs/cc \
1769                    /svr4/usr/lib/cmplrs/cc \
1770                    /usr/bin"
1771         fi
1772
1773         for dir in $test_dirs; do
1774                 if test -x $dir/as$host_exeext; then
1775                         gcc_cv_as=$dir/as$host_exeext
1776                         break;
1777                 fi
1778         done
1779 fi
1780 case $in_tree_gas in
1781   yes)
1782     AC_MSG_RESULT("newly built gas")
1783     ;;
1784   no)
1785     AC_MSG_RESULT($gcc_cv_as)
1786     ;;
1787 esac
1788
1789 # Identify the linker which will work hand-in-glove with the newly
1790 # built GCC, so that we can examine its features.  This is the linker
1791 # which will be driven by the driver program.
1792 #
1793 # If build != host, and we aren't building gas in-tree, we identify a
1794 # build->target linker and hope that it will have the same features
1795 # as the host->target linker we'll be using.
1796 AC_MSG_CHECKING(what linker to use)
1797 in_tree_ld=no
1798 gcc_cv_ld=
1799 gcc_cv_gld_major_version=
1800 gcc_cv_gld_minor_version=
1801 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1802 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1803 if test -x "$DEFAULT_LINKER"; then
1804         gcc_cv_ld="$DEFAULT_LINKER"
1805 elif test -x "$LD_FOR_TARGET"; then
1806         gcc_cv_ld="$LD_FOR_TARGET"
1807 elif test -x "$LD" && test x$host = x$target; then
1808         gcc_cv_ld="$LD"
1809 elif test -x collect-ld$host_exeext; then
1810         # Build using linker in the current directory.
1811         gcc_cv_ld=./collect-ld$host_exeext
1812 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1813      && test -f ../ld/Makefile; then
1814         # Single tree build which includes ld.
1815         in_tree_ld=yes
1816         in_tree_ld_is_elf=no
1817         if (grep 'EMUL = .*elf' ../ld/Makefile \
1818             || grep 'EMUL = .*linux' ../ld/Makefile) > /dev/null; then
1819           in_tree_ld_is_elf=yes
1820         fi
1821         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1822         do
1823 changequote(,)dnl
1824                 gcc_cv_gld_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1825 changequote([,])dnl
1826                 if test x$gcc_cv_gld_version != x; then
1827                         break
1828                 fi
1829         done
1830 changequote(,)dnl
1831         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1832         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1833 changequote([,])dnl
1834         rm -f collect-ld$host_exeext
1835         $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext \
1836                 2>/dev/null
1837 fi
1838
1839 if test "x$gcc_cv_ld" = x; then
1840         # Search the same directories that the installed compiler will
1841         # search.  Else we may find the wrong linker and lose.  If we
1842         # do not find a suitable linker binary, then try the user's
1843         # path.
1844         #
1845         # Also note we have to check MD_EXEC_PREFIX before checking the
1846         # user's path.  Unfortunately, there is no good way to get at the
1847         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1848         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1849         # to be fixed as part of the make/configure rewrite too.
1850
1851         if test "x$exec_prefix" = xNONE; then
1852                 if test "x$prefix" = xNONE; then
1853                         test_prefix=/usr/local
1854                 else
1855                         test_prefix=$prefix
1856                 fi
1857         else
1858                 test_prefix=$exec_prefix
1859         fi
1860
1861         # If the loop below does not find an linker, then use whatever
1862         # one we can find in the users's path.
1863         # user's path.
1864         if test "x$program_prefix" != xNONE; then
1865                 gcc_cv_ld=${program_prefix}ld$host_exeext
1866         else
1867                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$host_exeext
1868         fi
1869
1870         test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1871                    $test_prefix/libexec/gcc/$target_noncanonical \
1872                    /usr/lib/gcc/$target_noncanonical/$gcc_version \
1873                    /usr/lib/gcc/$target_noncanonical \
1874                    $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1875                    $test_prefix/$target_noncanonical/bin"
1876
1877         if test x$host = x$target; then
1878             test_dirs="$test_dirs \
1879                    /usr/libexec \
1880                    /usr/ccs/gcc \
1881                    /usr/ccs/bin \
1882                    /udk/usr/ccs/bin \
1883                    /bsd43/usr/lib/cmplrs/cc \
1884                    /usr/cross64/usr/bin \
1885                    /usr/lib/cmplrs/cc \
1886                    /sysv/usr/lib/cmplrs/cc \
1887                    /svr4/usr/lib/cmplrs/cc \
1888                    /usr/bin"
1889         fi
1890
1891         for dir in $test_dirs; do
1892                 if test -x $dir/ld$host_exeext; then
1893                         gcc_cv_ld=$dir/ld$host_exeext
1894                         break;
1895                 fi
1896         done
1897 fi
1898 case $in_tree_ld in
1899   yes)
1900     AC_MSG_RESULT("newly built ld")
1901     ;;
1902   no)
1903     AC_MSG_RESULT($gcc_cv_ld)
1904     ;;
1905 esac
1906
1907 # Figure out what nm we will be using.
1908 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1909 AC_MSG_CHECKING(what nm to use)
1910 in_tree_nm=no
1911 if test -x nm$host_exeext; then
1912         gcc_cv_nm=./nm$host_exeext
1913 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1914      && test -f ../binutils/Makefile; then
1915         # Single tree build which includes binutils.
1916         in_tree_nm=yes
1917         gcc_cv_nm=./nm$host_exeext
1918         rm -f nm$host_exeext
1919         $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1920 elif test "x$program_prefix" != xNONE; then
1921         gcc_cv_nm=${program_prefix}nm$host_exeext
1922 else
1923         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$host_exeext
1924 fi
1925 case $in_tree_nm in
1926   yes) AC_MSG_RESULT("newly built nm") ;;
1927   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1928 esac
1929
1930 # Figure out what objdump we will be using.
1931 AC_MSG_CHECKING(what objdump to use)
1932 in_tree_objdump=no
1933 if test -x objdump$host_exeext; then
1934         gcc_cv_objdump=./objdump$host_exeext
1935 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1936      && test -f ../binutils/Makefile; then
1937         # Single tree build which includes binutils.
1938         in_tree_objdump=yes
1939         gcc_cv_objdump=./objdump$host_exeext
1940         rm -f objdump$host_exeext
1941         $symbolic_link ../binutils/objdump$host_exeext \
1942                 objdump$host_exeext 2>/dev/null
1943 elif test "x$program_prefix" != xNONE; then
1944         gcc_cv_objdump=${program_prefix}objdump$host_exeext
1945 else
1946         gcc_cv_objdump=`echo objdump | \
1947                 sed "${program_transform_name}"`$host_exeext
1948 fi
1949 case $in_tree_objdump in
1950   yes) AC_MSG_RESULT("newly built objdump") ;;
1951   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
1952 esac
1953
1954 # Figure out what assembler alignment features are present.
1955 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1956  [2,6,0],,
1957 [.balign 4
1958 .p2align 2],,
1959 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1960   [Define if your assembler supports .balign and .p2align.])])
1961
1962 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1963  [2,8,0],,
1964  [.p2align 4,,7],,
1965 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1966   [Define if your assembler supports specifying the maximum number
1967    of bytes to skip when using the GAS .p2align command.])])
1968
1969 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1970  [elf,2,9,0],,
1971  [conftest_label1: .word 0
1972 .subsection -1
1973 conftest_label2: .word 0
1974 .previous],
1975  [if test x$gcc_cv_nm != x; then
1976     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1977     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1978     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1979     then :
1980     else gcc_cv_as_subsection_m1=yes
1981     fi
1982     rm -f conftest.nm1 conftest.nm2
1983   fi],
1984  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1985   [Define if your assembler supports .subsection and .subsection -1 starts
1986    emitting at the beginning of your section.])])
1987
1988 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1989  [2,2,0],,
1990  [      .weak foobar],,
1991 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1992
1993 # .hidden needs to be supported in both the assembler and the linker,
1994 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
1995 # This is irritatingly difficult to feature test for; we have to check the
1996 # date string after the version number.  If we've got an in-tree
1997 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
1998 # to be safe.
1999 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2000 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2001  [elf,2,13,0],,
2002 [       .hidden foobar
2003 foobar:])
2004
2005 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2006 [if test $in_tree_ld = yes ; then
2007   gcc_cv_ld_hidden=no
2008   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2009      && test $in_tree_ld_is_elf = yes; then
2010      gcc_cv_ld_hidden=yes
2011   fi
2012 else
2013   gcc_cv_ld_hidden=yes
2014   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2015   if echo "$ld_ver" | grep GNU > /dev/null; then
2016 changequote(,)dnl
2017     ld_vers=`echo $ld_ver | sed -n \
2018         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2019         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2020         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2021         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2022         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2023         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2024     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2025     if test 0"$ld_date" -lt 20020404; then
2026       if test -n "$ld_date"; then
2027         # If there was date string, but was earlier than 2002-04-04, fail
2028         gcc_cv_ld_hidden=no
2029       elif test -z "$ld_vers"; then
2030         # If there was no date string nor ld version number, something is wrong
2031         gcc_cv_ld_hidden=no
2032       else
2033         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2034         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2035         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2036         test -z "$ld_vers_patch" && ld_vers_patch=0
2037         if test "$ld_vers_major" -lt 2; then
2038           gcc_cv_ld_hidden=no
2039         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2040           gcc_cv_ld_hidden="no"
2041         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2042           gcc_cv_ld_hidden=no
2043         fi
2044       fi
2045 changequote([,])dnl
2046     fi
2047   else
2048     case "${target}" in
2049       hppa64*-*-hpux* | ia64*-*-hpux*)
2050         gcc_cv_ld_hidden=yes
2051         ;;
2052       *)
2053         gcc_cv_ld_hidden=no
2054         ;;
2055     esac
2056   fi
2057 fi])
2058 libgcc_visibility=no
2059 AC_SUBST(libgcc_visibility)
2060 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2061   libgcc_visibility=yes
2062   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2063   [Define if your assembler and linker support .hidden.])
2064 fi
2065
2066 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2067 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2068   [elf,2,11,0],,
2069 [       .data
2070         .uleb128 L2 - L1
2071 L1:
2072         .uleb128 1280
2073         .sleb128 -1010
2074 L2:],
2075  [# GAS versions before 2.11 do not support uleb128,
2076   # despite appearing to.
2077   # ??? There exists an elf-specific test that will crash
2078   # the assembler.  Perhaps it's better to figure out whether
2079   # arbitrary sections are supported and try the test.
2080   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2081   if echo "$as_ver" | grep GNU > /dev/null; then
2082 changequote(,)dnl
2083     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2084     as_major=`echo $as_ver | sed 's/\..*//'`
2085     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2086 changequote([,])dnl
2087     if test $as_major -eq 2 && test $as_minor -lt 11
2088     then :
2089     else gcc_cv_as_leb128=yes
2090     fi
2091   fi],
2092   [AC_DEFINE(HAVE_AS_LEB128, 1,
2093     [Define if your assembler supports .sleb128 and .uleb128.])])
2094
2095 # GAS versions up to and including 2.11.0 may mis-optimize
2096 # .eh_frame data.
2097 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2098   [elf,2,12,0],,
2099 [       .text
2100 .LFB1:
2101         .4byte  0
2102 .L1:
2103         .4byte  0
2104 .LFE1:
2105         .section        .eh_frame,"aw",@progbits
2106 __FRAME_BEGIN__:
2107         .4byte  .LECIE1-.LSCIE1
2108 .LSCIE1:
2109         .4byte  0x0
2110         .byte   0x1
2111         .ascii "z\0"
2112         .byte   0x1
2113         .byte   0x78
2114         .byte   0x1a
2115         .byte   0x0
2116         .byte   0x4
2117         .4byte  1
2118         .p2align 1
2119 .LECIE1:
2120 .LSFDE1:
2121         .4byte  .LEFDE1-.LASFDE1
2122 .LASFDE1:
2123         .4byte  .LASFDE1-__FRAME_BEGIN__
2124         .4byte  .LFB1
2125         .4byte  .LFE1-.LFB1
2126         .byte   0x4
2127         .4byte  .LFE1-.LFB1
2128         .byte   0x4
2129         .4byte  .L1-.LFB1
2130 .LEFDE1:],
2131 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2132 cat > conftest.lit <<EOF
2133  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2134  0010 01000000 12000000 18000000 00000000  ................
2135  0020 08000000 04080000 0044               .........D      @&t@
2136 EOF
2137 cat > conftest.big <<EOF
2138  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2139  0010 00000001 00000012 00000018 00000000  ................
2140  0020 00000008 04000000 0844               .........D      @&t@
2141 EOF
2142   # If the assembler didn't choke, and we can objdump,
2143   # and we got the correct data, then succeed.
2144   if test x$gcc_cv_objdump != x \
2145   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2146      | tail -3 > conftest.got \
2147   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2148     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2149   then
2150     gcc_cv_as_eh_frame=yes
2151   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2152     gcc_cv_as_eh_frame=buggy
2153   else
2154     # Uh oh, what do we do now?
2155     gcc_cv_as_eh_frame=no
2156   fi])
2157
2158 if test $gcc_cv_as_eh_frame = buggy; then
2159   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2160   [Define if your assembler mis-optimizes .eh_frame data.])
2161 fi
2162
2163 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2164  [elf,2,12,0], [--fatal-warnings],
2165  [.section .rodata.str, "aMS", @progbits, 1])
2166 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2167   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2168 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2169
2170 # Thread-local storage - the check is heavily parametrized.
2171 conftest_s=
2172 tls_first_major=
2173 tls_first_minor=
2174 tls_as_opt=
2175 case "$target" in
2176 changequote(,)dnl
2177   alpha*-*-*)
2178     conftest_s='
2179         .section ".tdata","awT",@progbits
2180 foo:    .long   25
2181         .text
2182         ldq     $27,__tls_get_addr($29)         !literal!1
2183         lda     $16,foo($29)                    !tlsgd!1
2184         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2185         ldq     $27,__tls_get_addr($29)         !literal!2
2186         lda     $16,foo($29)                    !tlsldm!2
2187         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2188         ldq     $1,foo($29)                     !gotdtprel
2189         ldah    $2,foo($29)                     !dtprelhi
2190         lda     $3,foo($2)                      !dtprello
2191         lda     $4,foo($29)                     !dtprel
2192         ldq     $1,foo($29)                     !gottprel
2193         ldah    $2,foo($29)                     !tprelhi
2194         lda     $3,foo($2)                      !tprello
2195         lda     $4,foo($29)                     !tprel'
2196         tls_first_major=2
2197         tls_first_minor=13
2198         tls_as_opt=--fatal-warnings
2199         ;;
2200   i[34567]86-*-*)
2201     conftest_s='
2202         .section ".tdata","awT",@progbits
2203 foo:    .long   25
2204         .text
2205         movl    %gs:0, %eax
2206         leal    foo@TLSGD(,%ebx,1), %eax
2207         leal    foo@TLSLDM(%ebx), %eax
2208         leal    foo@DTPOFF(%eax), %edx
2209         movl    foo@GOTTPOFF(%ebx), %eax
2210         subl    foo@GOTTPOFF(%ebx), %eax
2211         addl    foo@GOTNTPOFF(%ebx), %eax
2212         movl    foo@INDNTPOFF, %eax
2213         movl    $foo@TPOFF, %eax
2214         subl    $foo@TPOFF, %eax
2215         leal    foo@NTPOFF(%ecx), %eax'
2216         tls_first_major=2
2217         tls_first_minor=14
2218         tls_as_opt=--fatal-warnings
2219         ;;
2220   x86_64-*-*)
2221     conftest_s='
2222         .section ".tdata","awT",@progbits
2223 foo:    .long   25
2224         .text
2225         movq    %fs:0, %rax
2226         leaq    foo@TLSGD(%rip), %rdi
2227         leaq    foo@TLSLD(%rip), %rdi
2228         leaq    foo@DTPOFF(%rax), %rdx
2229         movq    foo@GOTTPOFF(%rip), %rax
2230         movq    $foo@TPOFF, %rax'
2231         tls_first_major=2
2232         tls_first_minor=14
2233         tls_as_opt=--fatal-warnings
2234         ;;
2235   ia64-*-*)
2236     conftest_s='
2237         .section ".tdata","awT",@progbits
2238 foo:    data8   25
2239         .text
2240         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2241         addl    r17 = @ltoff(@dtprel(foo#)), gp
2242         addl    r18 = @ltoff(@tprel(foo#)), gp
2243         addl    r19 = @dtprel(foo#), gp
2244         adds    r21 = @dtprel(foo#), r13
2245         movl    r23 = @dtprel(foo#)
2246         addl    r20 = @tprel(foo#), gp
2247         adds    r22 = @tprel(foo#), r13
2248         movl    r24 = @tprel(foo#)'
2249         tls_first_major=2
2250         tls_first_minor=13
2251         tls_as_opt=--fatal-warnings
2252         ;;
2253   powerpc-*-*)
2254     conftest_s='
2255         .section ".tdata","awT",@progbits
2256         .align 2
2257 ld0:    .space 4
2258 ld1:    .space 4
2259 x1:     .space 4
2260 x2:     .space 4
2261 x3:     .space 4
2262         .text
2263         addi 3,31,ld0@got@tlsgd
2264         bl __tls_get_addr
2265         addi 3,31,x1@got@tlsld
2266         bl __tls_get_addr
2267         addi 9,3,x1@dtprel
2268         addis 9,3,x2@dtprel@ha
2269         addi 9,9,x2@dtprel@l
2270         lwz 9,x3@got@tprel(31)
2271         add 9,9,x@tls
2272         addi 9,2,x1@tprel
2273         addis 9,2,x2@tprel@ha
2274         addi 9,9,x2@tprel@l'
2275         tls_first_major=2
2276         tls_first_minor=14
2277         tls_as_opt="-a32 --fatal-warnings"
2278         ;;
2279   powerpc64-*-*)
2280     conftest_s='
2281         .section ".tdata","awT",@progbits
2282         .align 3
2283 ld0:    .space 8
2284 ld1:    .space 8
2285 x1:     .space 8
2286 x2:     .space 8
2287 x3:     .space 8
2288         .text
2289         addi 3,2,ld0@got@tlsgd
2290         bl .__tls_get_addr
2291         nop
2292         addi 3,2,ld1@toc
2293         bl .__tls_get_addr
2294         nop
2295         addi 3,2,x1@got@tlsld
2296         bl .__tls_get_addr
2297         nop
2298         addi 9,3,x1@dtprel
2299         bl .__tls_get_addr
2300         nop
2301         addis 9,3,x2@dtprel@ha
2302         addi 9,9,x2@dtprel@l
2303         bl .__tls_get_addr
2304         nop
2305         ld 9,x3@got@dtprel(2)
2306         add 9,9,3
2307         bl .__tls_get_addr
2308         nop'
2309         tls_first_major=2
2310         tls_first_minor=14
2311         tls_as_opt="-a64 --fatal-warnings"
2312         ;;
2313   s390-*-*)
2314     conftest_s='
2315         .section ".tdata","awT",@progbits
2316 foo:    .long   25
2317         .text
2318         .long   foo@TLSGD
2319         .long   foo@TLSLDM
2320         .long   foo@DTPOFF
2321         .long   foo@NTPOFF
2322         .long   foo@GOTNTPOFF
2323         .long   foo@INDNTPOFF
2324         l       %r1,foo@GOTNTPOFF(%r12)
2325         l       %r1,0(%r1):tls_load:foo
2326         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2327         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2328         tls_first_major=2
2329         tls_first_minor=14
2330         tls_as_opt="-m31 --fatal-warnings"
2331         ;;
2332   s390x-*-*)
2333     conftest_s='
2334         .section ".tdata","awT",@progbits
2335 foo:    .long   25
2336         .text
2337         .quad   foo@TLSGD
2338         .quad   foo@TLSLDM
2339         .quad   foo@DTPOFF
2340         .quad   foo@NTPOFF
2341         .quad   foo@GOTNTPOFF
2342         lg      %r1,foo@GOTNTPOFF(%r12)
2343         larl    %r1,foo@INDNTPOFF
2344         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2345         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2346         tls_first_major=2
2347         tls_first_minor=14
2348         tls_as_opt="-m64 -Aesame --fatal-warnings"
2349         ;;
2350   sh-*-* | sh[34]-*-*)
2351     conftest_s='
2352         .section ".tdata","awT",@progbits
2353 foo:    .long   25
2354         .text
2355         .long   foo@TLSGD
2356         .long   foo@TLSLDM
2357         .long   foo@DTPOFF
2358         .long   foo@GOTTPOFF
2359         .long   foo@TPOFF'
2360         tls_first_major=2
2361         tls_first_minor=13
2362         tls_as_opt=--fatal-warnings
2363         ;;
2364   sparc*-*-*)
2365     case "$target" in
2366       sparc*-sun-solaris2.*)
2367         on_solaris=yes
2368         ;;
2369       *)
2370         on_solaris=no
2371         ;;
2372     esac
2373     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2374       conftest_s='
2375         .section ".tdata",#alloc,#write,#tls
2376 foo:    .long   25
2377         .text
2378         sethi   %tgd_hi22(foo), %o0
2379         add     %o0, %tgd_lo10(foo), %o1
2380         add     %l7, %o1, %o0, %tgd_add(foo)
2381         call    __tls_get_addr, %tgd_call(foo)
2382         sethi   %tldm_hi22(foo), %l1
2383         add     %l1, %tldm_lo10(foo), %l2
2384         add     %l7, %l2, %o0, %tldm_add(foo)
2385         call    __tls_get_addr, %tldm_call(foo)
2386         sethi   %tldo_hix22(foo), %l3
2387         xor     %l3, %tldo_lox10(foo), %l4
2388         add     %o0, %l4, %l5, %tldo_add(foo)
2389         sethi   %tie_hi22(foo), %o3
2390         add     %o3, %tie_lo10(foo), %o3
2391         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2392         add     %g7, %o2, %o4, %tie_add(foo)
2393         sethi   %tle_hix22(foo), %l1
2394         xor     %l1, %tle_lox10(foo), %o5
2395         ld      [%g7 + %o5], %o1'
2396         tls_first_major=0
2397         tls_first_minor=0
2398     else
2399       conftest_s='
2400         .section ".tdata","awT",@progbits
2401 foo:    .long   25
2402         .text
2403         sethi   %tgd_hi22(foo), %o0
2404         add     %o0, %tgd_lo10(foo), %o1
2405         add     %l7, %o1, %o0, %tgd_add(foo)
2406         call    __tls_get_addr, %tgd_call(foo)
2407         sethi   %tldm_hi22(foo), %l1
2408         add     %l1, %tldm_lo10(foo), %l2
2409         add     %l7, %l2, %o0, %tldm_add(foo)
2410         call    __tls_get_addr, %tldm_call(foo)
2411         sethi   %tldo_hix22(foo), %l3
2412         xor     %l3, %tldo_lox10(foo), %l4
2413         add     %o0, %l4, %l5, %tldo_add(foo)
2414         sethi   %tie_hi22(foo), %o3
2415         add     %o3, %tie_lo10(foo), %o3
2416         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2417         add     %g7, %o2, %o4, %tie_add(foo)
2418         sethi   %tle_hix22(foo), %l1
2419         xor     %l1, %tle_lox10(foo), %o5
2420         ld      [%g7 + %o5], %o1'
2421         tls_first_major=2
2422         tls_first_minor=14
2423         tls_as_opt="-32 --fatal-warnings"
2424       fi
2425         ;;
2426 changequote([,])dnl
2427 esac
2428 if test -z "$tls_first_major"; then
2429   : # If we don't have a check, assume no support.
2430 else
2431   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2432   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2433   [AC_DEFINE(HAVE_AS_TLS, 1,
2434             [Define if your assembler supports thread-local storage.])])
2435 fi
2436
2437 # Target-specific assembler checks.
2438
2439 case "$target" in
2440   # All TARGET_ABI_OSF targets.
2441   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2442     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2443         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2444 [       .set nomacro
2445         .text
2446         extbl   $3, $2, $3      !lituse_bytoff!1
2447         ldq     $2, a($29)      !literal!1
2448         ldq     $4, b($29)      !literal!2
2449         ldq_u   $3, 0($2)       !lituse_base!1
2450         ldq     $27, f($29)     !literal!5
2451         jsr     $26, ($27), f   !lituse_jsr!5
2452         ldah    $29, 0($26)     !gpdisp!3
2453         lda     $0, c($29)      !gprel
2454         ldah    $1, d($29)      !gprelhigh
2455         lda     $1, d($1)       !gprellow
2456         lda     $29, 0($29)     !gpdisp!3],,
2457     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2458   [Define if your assembler supports explicit relocations.])])
2459     ;;
2460
2461   cris-*-*)
2462     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2463       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2464       [-no-mul-bug-abort], [.text],,
2465       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2466                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2467     ;;
2468
2469   sparc*-*-*)
2470     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2471       [.register %g2, #scratch],,
2472       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2473                 [Define if your assembler supports .register.])])
2474
2475     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2476       [-relax], [.text],,
2477       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2478                 [Define if your assembler supports -relax option.])])
2479
2480     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2481       gcc_cv_as_sparc_ua_pcrel,,
2482       [-K PIC],
2483 [.text
2484 foo:
2485         nop
2486 .data
2487 .align 4
2488 .byte 0
2489 .uaword %r_disp32(foo)],
2490       [if test x$gcc_cv_ld != x \
2491        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2492          gcc_cv_as_sparc_ua_pcrel=yes
2493        fi
2494        rm -f conftest],
2495       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2496                 [Define if your assembler and linker support unaligned PC relative relocs.])
2497
2498       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2499         gcc_cv_as_sparc_ua_pcrel_hidden,,
2500         [-K PIC],
2501 [.data
2502 .align 4
2503 .byte 0x31
2504 .uaword %r_disp32(foo)
2505 .byte 0x32, 0x33, 0x34
2506 .global foo
2507 .hidden foo
2508 foo:
2509 .skip 4],
2510         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2511          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2512          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2513             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2514             if $gcc_cv_objdump -R conftest 2> /dev/null \
2515                | grep 'DISP32' > /dev/null 2>&1; then
2516                 :
2517             else
2518                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2519             fi
2520          fi
2521          rm -f conftest],
2522          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2523                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2524     ]) # unaligned pcrel relocs
2525
2526     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2527       gcc_cv_as_sparc_offsetable_lo10,,
2528       [-xarch=v9],
2529 [.text
2530         or %g1, %lo(ab) + 12, %g1
2531         or %g1, %lo(ab + 12), %g1],
2532       [if test x$gcc_cv_objdump != x \
2533        && %gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2534           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2535          gcc_cv_as_offsetable_lo10=yes
2536        fi],
2537        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2538                  [Define if your assembler supports offsetable %lo().])])
2539     ;;
2540
2541 changequote(,)dnl
2542   i[34567]86-*-* | x86_64-*-*)
2543 changequote([,])dnl
2544     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2545        gcc_cv_as_ix86_filds_fists,
2546       [2,9,0],, [filds mem; fists mem],,
2547       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2548         [Define if your assembler uses the new HImode fild and fist notation.])])
2549
2550     gcc_GAS_CHECK_FEATURE([cmov syntax],
2551       gcc_cv_as_ix86_cmov_sun_syntax,,,
2552       [cmovl.l %edx, %eax],,
2553       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2554         [Define if your assembler supports the Sun syntax for cmov.])])
2555
2556     # This one is used unconditionally by i386.[ch]; it is to be defined
2557     # to 1 if the feature is present, 0 otherwise.
2558     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2559         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2560 [       .text
2561 .L0:
2562         nop
2563         .data
2564         .long .L0@GOTOFF])
2565     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2566       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2567       [Define true if the assembler supports '.long foo@GOTOFF'.])
2568     ;;
2569
2570   ia64*-*-*)
2571     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2572         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2573 [       .text
2574         addl r15 = @ltoffx(x#), gp
2575         ;;
2576         ld8.mov r16 = [[r15]], x#],,
2577     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2578           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2579
2580     ;;
2581
2582   powerpc*-*-*)
2583     case $target in
2584       *-*-aix*) conftest_s='    .csect .text[[PR]]
2585         mfcr 3,128';;
2586       *-*-darwin*) conftest_s=' .text
2587         mfcr r3,128';;
2588       *)       conftest_s='     .text
2589         mfcr 3,128';;
2590     esac
2591
2592     gcc_GAS_CHECK_FEATURE([mfcr field support],
2593       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2594       [$conftest_s],,
2595       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2596           [Define if your assembler supports mfcr field.])])
2597     ;;
2598
2599   mips*-*-*)
2600     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2601       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2602 [       lw $4,%gp_rel(foo)($4)],,
2603       [if test x$target_cpu_default = x
2604        then target_cpu_default=MASK_EXPLICIT_RELOCS
2605        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2606        fi])
2607
2608     ;;
2609 esac
2610 # ??? Not all targets support dwarf2 debug_line, even within a version
2611 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2612 # info to the output file.  So, as supported targets are added to gas 2.11,
2613 # add some instruction here to (also) show we expect this might work.
2614 # ??? Once 2.11 is released, probably need to add first known working
2615 # version to the per-target configury.
2616 case "$target" in
2617   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2618   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2619   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2620     insn="nop"
2621     ;;
2622   ia64*-*-* | s390*-*-*)
2623     insn="nop 0"
2624     ;;
2625   mmix-*-*)
2626     insn="swym 0"
2627     ;;
2628 esac
2629 if test x"$insn" != x; then
2630  conftest_s="\
2631         .file 1 \"conftest.s\"
2632         .loc 1 3 0
2633         $insn"
2634  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2635   gcc_cv_as_dwarf2_debug_line,
2636   [elf,2,11,0],, [$conftest_s],
2637   [# ??? This fails with non-gnu grep.  Maybe use objdump?
2638    if grep debug_line conftest.o > /dev/null 2>&1; then
2639      gcc_cv_as_dwarf2_debug_line=yes
2640    fi])
2641
2642 # The .debug_line file table must be in the exact order that
2643 # we specified the files, since these indices are also used
2644 # by DW_AT_decl_file.  Approximate this test by testing if
2645 # the assembler bitches if the same index is assigned twice.
2646  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2647   gcc_cv_as_dwarf2_file_buggy,,,
2648 [       .file 1 "foo.s"
2649         .file 1 "bar.s"])
2650
2651  if test $gcc_cv_as_dwarf2_debug_line = yes \
2652  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2653         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2654   [Define if your assembler supports dwarf2 .file/.loc directives,
2655    and preserves file table indices exactly as given.])
2656  fi
2657
2658  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2659   gcc_cv_as_gdwarf2_flag,
2660   [elf,2,11,0], [--gdwarf2], [$insn],,
2661   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2662 [Define if your assembler supports the --gdwarf2 option.])])
2663
2664  gcc_GAS_CHECK_FEATURE([--gstabs option],
2665   gcc_cv_as_gstabs_flag,
2666   [elf,2,11,0], [--gstabs], [$insn],
2667   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2668    # and warns about it, but still exits successfully.  So check for
2669    # this.
2670    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2671    then :
2672    else gcc_cv_as_gstabs_flag=yes
2673    fi],
2674   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2675 [Define if your assembler supports the --gstabs option.])])
2676 fi
2677
2678 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2679 gcc_cv_ld_ro_rw_mix=unknown
2680 if test $in_tree_ld = yes ; then
2681   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2682      && test $in_tree_ld_is_elf = yes; then
2683     gcc_cv_ld_ro_rw_mix=read-write
2684   fi
2685 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2686   echo '.section myfoosect, "a"' > conftest1.s
2687   echo '.section myfoosect, "aw"' > conftest2.s
2688   echo '.byte 1' >> conftest2.s
2689   echo '.section myfoosect, "a"' > conftest3.s
2690   echo '.byte 0' >> conftest3.s
2691   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2692      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2693      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2694      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2695         conftest2.o conftest3.o > /dev/null 2>&1; then
2696     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2697                          | sed -e '/myfoosect/!d' -e N`
2698     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2699       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2700         gcc_cv_ld_ro_rw_mix=read-only
2701       else
2702         gcc_cv_ld_ro_rw_mix=read-write
2703       fi
2704     fi
2705   fi
2706 changequote(,)dnl
2707   rm -f conftest.* conftest[123].*
2708 changequote([,])dnl
2709 fi
2710 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2711         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2712   [Define if your linker links a mix of read-only
2713    and read-write sections into a read-write section.])
2714 fi
2715 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2716
2717 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2718 gcc_cv_ld_eh_frame_hdr=no
2719 if test $in_tree_ld = yes ; then
2720   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2721      && test $in_tree_ld_is_elf = yes; then
2722     gcc_cv_ld_eh_frame_hdr=yes
2723   fi
2724 elif test x$gcc_cv_ld != x; then
2725         # Check if linker supports --eh-frame-hdr option
2726         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2727                 gcc_cv_ld_eh_frame_hdr=yes
2728         fi
2729 fi
2730 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2731         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2732 [Define if your linker supports --eh-frame-hdr option.])
2733 fi
2734 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2735
2736 AC_MSG_CHECKING(linker position independent executable support)
2737 gcc_cv_ld_pie=no
2738 if test $in_tree_ld = yes ; then
2739   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2740      && test $in_tree_ld_is_elf = yes; then
2741     gcc_cv_ld_pie=yes
2742   fi
2743 elif test x$gcc_cv_ld != x; then
2744         # Check if linker supports -pie option
2745         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2746                 gcc_cv_ld_pie=yes
2747         fi
2748 fi
2749 if test x"$gcc_cv_ld_pie" = xyes; then
2750         AC_DEFINE(HAVE_LD_PIE, 1,
2751 [Define if your linker supports -pie option.])
2752 fi
2753 AC_MSG_RESULT($gcc_cv_ld_pie)
2754
2755 # --------
2756 # UNSORTED
2757 # --------
2758
2759 AC_MSG_CHECKING(linker --as-needed support)
2760 gcc_cv_ld_as_needed=no
2761 if test $in_tree_ld = yes ; then
2762   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2763      && test $in_tree_ld_is_elf = yes; then
2764     gcc_cv_ld_as_needed=yes
2765   fi
2766 elif test x$gcc_cv_ld != x; then
2767         # Check if linker supports --as-needed and --no-as-needed options
2768         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2769                 gcc_cv_ld_as_needed=yes
2770         fi
2771 fi
2772 if test x"$gcc_cv_ld_as_needed" = xyes; then
2773         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2774 [Define if your linker supports --as-needed and --no-as-needed options.])
2775 fi
2776 AC_MSG_RESULT($gcc_cv_ld_as_needed)
2777
2778 if test x$with_sysroot = x && test x$host = x$target \
2779    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
2780   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
2781 [Define to PREFIX/include if cpp should also search that directory.])
2782 fi
2783
2784 # Find out what GC implementation we want, or may, use.
2785 AC_ARG_WITH(gc,
2786 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
2787                           with the compiler],
2788 [case "$withval" in
2789   page | zone)
2790     GGC=ggc-$withval
2791     ;;
2792   *)
2793     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
2794     ;;
2795 esac],
2796 [GGC=ggc-page])
2797 AC_SUBST(GGC)
2798 echo "Using $GGC for garbage collection."
2799
2800 # Use the system's zlib library.
2801 zlibdir=-L../zlib
2802 zlibinc="-I\$(srcdir)/../zlib"
2803 AC_ARG_WITH(system-zlib,
2804 [  --with-system-zlib      use installed libz],
2805 zlibdir=
2806 zlibinc=
2807 )
2808 AC_SUBST(zlibdir)
2809 AC_SUBST(zlibinc)
2810
2811 dnl Very limited version of automake's enable-maintainer-mode
2812
2813 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2814   dnl maintainer-mode is disabled by default
2815   AC_ARG_ENABLE(maintainer-mode,
2816 [  --enable-maintainer-mode
2817                           enable make rules and dependencies not useful
2818                           (and sometimes confusing) to the casual installer],
2819       maintainer_mode=$enableval,
2820       maintainer_mode=no)
2821
2822 AC_MSG_RESULT($maintainer_mode)
2823
2824 if test "$maintainer_mode" = "yes"; then
2825   MAINT=''
2826 else
2827   MAINT='#'
2828 fi
2829 AC_SUBST(MAINT)dnl
2830
2831 # --------------
2832 # Language hooks
2833 # --------------
2834
2835 # Make empty files to contain the specs and options for each language.
2836 # Then add #include lines to for a compiler that has specs and/or options.
2837
2838 lang_opt_files=
2839 lang_specs_files=
2840 lang_tree_files=
2841 for subdir in . $subdirs
2842 do
2843         if test -f $srcdir/$subdir/lang.opt; then
2844             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
2845         fi
2846         if test -f $srcdir/$subdir/lang-specs.h; then
2847             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
2848         fi
2849         if test -f $srcdir/$subdir/$subdir-tree.def; then
2850             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
2851         fi
2852 done
2853
2854 # These (without "all_") are set in each config-lang.in.
2855 # `language' must be a single word so is spelled singularly.
2856 all_languages=
2857 all_boot_languages=
2858 all_compilers=
2859 all_stagestuff=
2860 all_outputs='Makefile fixinc/Makefile gccbug mklibgcc mkheaders'
2861 # List of language makefile fragments.
2862 all_lang_makefrags=
2863 # List of language subdirectory makefiles.  Deprecated.
2864 all_lang_makefiles=
2865 # Files for gengtype
2866 all_gtfiles="$target_gtfiles"
2867 # Files for gengtype with language
2868 all_gtfiles_files_langs=
2869 all_gtfiles_files_files=
2870
2871 # Add the language fragments.
2872 # Languages are added via two mechanisms.  Some information must be
2873 # recorded in makefile variables, these are defined in config-lang.in.
2874 # We accumulate them and plug them into the main Makefile.
2875 # The other mechanism is a set of hooks for each of the main targets
2876 # like `clean', `install', etc.
2877
2878 language_hooks="Make-hooks"
2879
2880 for s in $subdirs
2881 do
2882                 language=
2883                 boot_language=
2884                 compilers=
2885                 stagestuff=
2886                 outputs=
2887                 gtfiles=
2888                 . ${srcdir}/$s/config-lang.in
2889                 if test "x$language" = x
2890                 then
2891                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2892                         exit 1
2893                 fi
2894                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
2895                 if test -f ${srcdir}/$s/Makefile.in
2896                 then all_lang_makefiles="$s/Makefile"
2897                 fi
2898                 all_languages="$all_languages $language"
2899                 if test "x$boot_language" = xyes
2900                 then
2901                         all_boot_languages="$all_boot_languages $language"
2902                 fi
2903                 all_compilers="$all_compilers $compilers"
2904                 all_stagestuff="$all_stagestuff $stagestuff"
2905                 all_outputs="$all_outputs $outputs"
2906                 all_gtfiles="$all_gtfiles $gtfiles"
2907                 for f in $gtfiles
2908                 do
2909                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2910                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2911                 done
2912 done
2913
2914 # Pick up gtfiles for c
2915 gtfiles=
2916 s="c"
2917 . ${srcdir}/c-config-lang.in
2918 all_gtfiles="$all_gtfiles $gtfiles"
2919 for f in $gtfiles
2920 do
2921         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
2922         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
2923 done
2924
2925 check_languages=
2926 for language in $all_languages
2927 do
2928                 check_languages="$check_languages check-$language"
2929 done
2930
2931 # We link each language in with a set of hooks, reached indirectly via
2932 # lang.${target}.
2933
2934 rm -f Make-hooks
2935 touch Make-hooks
2936 target_list="all.build all.cross start.encap rest.encap tags \
2937         install-normal install-common install-man \
2938         uninstall info man srcextra srcman srcinfo \
2939         mostlyclean clean distclean maintainer-clean \
2940         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
2941 for t in $target_list
2942 do
2943         x=
2944         for lang in $all_languages
2945         do
2946                         x="$x $lang.$t"
2947         done
2948         echo "lang.$t: $x" >> Make-hooks
2949 done
2950
2951 # --------
2952 # UNSORTED
2953 # --------
2954
2955 # Create .gdbinit.
2956
2957 echo "dir ." > .gdbinit
2958 echo "dir ${srcdir}" >> .gdbinit
2959 if test x$gdb_needs_out_file_path = xyes
2960 then
2961         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2962 fi
2963 if test "x$subdirs" != x; then
2964         for s in $subdirs
2965         do
2966                 echo "dir ${srcdir}/$s" >> .gdbinit
2967         done
2968 fi
2969 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2970
2971 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2972 # absolute path for gcc_tooldir based on inserting the number of up-directory
2973 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2974 # $(libsubdir)/@(unlibsubdir) based path.
2975 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2976 # make and thus we'd get different behavior depending on where we built the
2977 # sources.
2978 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2979     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
2980 else
2981 changequote(<<, >>)dnl
2982 # An explanation of the sed strings:
2983 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2984 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2985 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2986 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2987 #
2988 # (*) Note this pattern overwrites the first character of the string
2989 # with a forward slash if one is not already present.  This is not a
2990 # problem because the exact names of the sub-directories concerned is
2991 # unimportant, just the number of them matters.
2992 #
2993 # The practical upshot of these patterns is like this:
2994 #
2995 #  prefix     exec_prefix        result
2996 #  ------     -----------        ------
2997 #   /foo        /foo/bar          ../
2998 #   /foo/       /foo/bar          ../
2999 #   /foo        /foo/bar/         ../
3000 #   /foo/       /foo/bar/         ../
3001 #   /foo        /foo/bar/ugg      ../../
3002 #
3003     dollar='$$'
3004     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3005 changequote([, ])dnl
3006 fi
3007 AC_SUBST(gcc_tooldir)
3008 AC_SUBST(dollar)
3009
3010 # Find a directory in which to install a shared libgcc.
3011
3012 AC_ARG_ENABLE(version-specific-runtime-libs,
3013 [  --enable-version-specific-runtime-libs
3014                           specify that runtime libraries should be
3015                           installed in a compiler-specific directory])
3016
3017 AC_ARG_WITH(slibdir,
3018 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3019 slibdir="$with_slibdir",
3020 if test "${enable_version_specific_runtime_libs+set}" = set; then
3021   slibdir='$(libsubdir)'
3022 elif test "$host" != "$target"; then
3023   slibdir='$(build_tooldir)/lib'
3024 else
3025   slibdir='$(libdir)'
3026 fi)
3027 AC_SUBST(slibdir)
3028
3029 objdir=`${PWDCMD-pwd}`
3030 AC_SUBST(objdir)
3031
3032 # Substitute configuration variables
3033 AC_SUBST(subdirs)
3034 AC_SUBST(srcdir)
3035 AC_SUBST(all_boot_languages)
3036 AC_SUBST(all_compilers)
3037 AC_SUBST(all_gtfiles)
3038 AC_SUBST(all_gtfiles_files_langs)
3039 AC_SUBST(all_gtfiles_files_files)
3040 AC_SUBST(all_lang_makefrags)
3041 AC_SUBST(all_lang_makefiles)
3042 AC_SUBST(all_languages)
3043 AC_SUBST(all_stagestuff)
3044 AC_SUBST(build_exeext)
3045 AC_SUBST(build_install_headers_dir)
3046 AC_SUBST(build_xm_file_list)
3047 AC_SUBST(build_xm_include_list)
3048 AC_SUBST(build_xm_defines)
3049 AC_SUBST(check_languages)
3050 AC_SUBST(cc_set_by_configure)
3051 AC_SUBST(quoted_cc_set_by_configure)
3052 AC_SUBST(cpp_install_dir)
3053 AC_SUBST(xmake_file)
3054 AC_SUBST(tmake_file)
3055 AC_SUBST(extra_gcc_objs)
3056 AC_SUBST(extra_headers_list)
3057 AC_SUBST(extra_objs)
3058 AC_SUBST(extra_parts)
3059 AC_SUBST(extra_passes)
3060 AC_SUBST(extra_programs)
3061 AC_SUBST(float_h_file)
3062 AC_SUBST(gcc_config_arguments)
3063 AC_SUBST(gcc_gxx_include_dir)
3064 AC_SUBST(libstdcxx_incdir)
3065 AC_SUBST(gcc_version)
3066 AC_SUBST(gcc_version_full)
3067 AC_SUBST(gcc_version_trigger)
3068 AC_SUBST(host_exeext)
3069 AC_SUBST(host_xm_file_list)
3070 AC_SUBST(host_xm_include_list)
3071 AC_SUBST(host_xm_defines)
3072 AC_SUBST(out_host_hook_obj)
3073 AC_SUBST(install)
3074 AC_SUBST(lang_opt_files)
3075 AC_SUBST(lang_specs_files)
3076 AC_SUBST(lang_tree_files)
3077 AC_SUBST(local_prefix)
3078 AC_SUBST(md_file)
3079 AC_SUBST(objc_boehm_gc)
3080 AC_SUBST(out_file)
3081 AC_SUBST(out_object_file)
3082 AC_SUBST(stage_prefix_set_by_configure)
3083 AC_SUBST(quoted_stage_prefix_set_by_configure)
3084 AC_SUBST(symbolic_link)
3085 AC_SUBST(thread_file)
3086 AC_SUBST(tm_file_list)
3087 AC_SUBST(tm_include_list)
3088 AC_SUBST(tm_defines)
3089 AC_SUBST(tm_p_file_list)
3090 AC_SUBST(tm_p_include_list)
3091 AC_SUBST(xm_file_list)
3092 AC_SUBST(xm_include_list)
3093 AC_SUBST(xm_defines)
3094 AC_SUBST(target_noncanonical)
3095 AC_SUBST(c_target_objs)
3096 AC_SUBST(cxx_target_objs)
3097 AC_SUBST(target_cpu_default)
3098
3099 AC_SUBST_FILE(language_hooks)
3100
3101 # If it doesn't already exist, create document directory
3102 echo "checking for the document directory." 1>&2
3103 if test -d doc ; then
3104   true
3105 else
3106   mkdir doc
3107 fi
3108
3109 # Echo link setup.
3110 if test x${build} = x${host} ; then
3111   if test x${host} = x${target} ; then
3112     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3113   else
3114     echo "Links are now set up to build a cross-compiler" 1>&2
3115     echo " from ${host} to ${target}." 1>&2
3116   fi
3117 else
3118   if test x${host} = x${target} ; then
3119     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3120     echo " for ${target}." 1>&2
3121   else
3122     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3123     echo " from ${host} to ${target}." 1>&2
3124   fi
3125 fi
3126
3127 # Configure the subdirectories
3128 # AC_CONFIG_SUBDIRS($subdirs)
3129
3130 # Create the Makefile
3131 # and configure language subdirectories
3132 AC_CONFIG_FILES($all_outputs)
3133
3134 AC_CONFIG_COMMANDS([default],
3135 [
3136 case ${CONFIG_HEADERS} in
3137   *auto-host.h:config.in*)
3138   echo > cstamp-h ;;
3139 esac
3140 # Make sure all the subdirs exist.
3141 for d in $subdirs
3142 do
3143     test -d $d || mkdir $d
3144 done
3145 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3146 # bootstrapping and the installation procedure can still use
3147 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3148 # FLAGS_TO_PASS has been modified to solve the problem there.
3149 # This is virtually a duplicate of what happens in configure.lang; we do
3150 # an extra check to make sure this only happens if ln -s can be used.
3151 if test "$symbolic_link" = "ln -s"; then
3152  for d in ${subdirs} fixinc ; do
3153         STARTDIR=`${PWDCMD-pwd}`
3154         cd $d
3155         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3156         do
3157                 rm -f $t
3158                 $symbolic_link ../$t $t 2>/dev/null
3159         done
3160         cd $STARTDIR
3161  done
3162 else true ; fi
3163 ],
3164 [subdirs='$subdirs'
3165 symbolic_link='$symbolic_link'
3166 ])
3167 AC_OUTPUT