gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997-2016 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 3, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING3.  If not see
  20 #<http://www.gnu.org/licenses/>.
  21
  22 # --------------------------------
  23 # Initialization and sanity checks
  24 # --------------------------------
  25
  26 AC_PREREQ(2.64)
  27 AC_INIT
  28 AC_CONFIG_SRCDIR(tree.c)
  29 AC_CONFIG_HEADER(auto-host.h:config.in)
  30
  31 gcc_version=`cat $srcdir/BASE-VER`
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical host name, for Ada.
  39 ACX_NONCANONICAL_HOST
  40
  41 # Determine the noncanonical target name, for directory use.
  42 ACX_NONCANONICAL_TARGET
  43
  44 # Used for constructing correct paths for offload compilers.
  45 real_target_noncanonical=${target_noncanonical}
  46 accel_dir_suffix=
  47
  48 # Determine the target- and build-specific subdirectories
  49 GCC_TOPLEV_SUBDIRS
  50
  51 # Set program_transform_name
  52 AC_ARG_PROGRAM
  53
  54 # Check for bogus environment variables.
  55 # Test if LIBRARY_PATH contains the notation for the current directory
  56 # since this would lead to problems installing/building glibc.
  57 # LIBRARY_PATH contains the current directory if one of the following
  58 # is true:
  59 # - one of the terminals (":" and ";") is the first or last sign
  60 # - two terminals occur directly after each other
  61 # - the path contains an element with a dot in it
  62 AC_MSG_CHECKING(LIBRARY_PATH variable)
  63 changequote(,)dnl
  64 case ${LIBRARY_PATH} in
  65   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  66     library_path_setting="contains current directory"
  67     ;;
  68   *)
  69     library_path_setting="ok"
  70     ;;
  71 esac
  72 changequote([,])dnl
  73 AC_MSG_RESULT($library_path_setting)
  74 if test "$library_path_setting" != "ok"; then
  75 AC_MSG_ERROR([
  76 *** LIBRARY_PATH shouldn't contain the current directory when
  77 *** building gcc. Please change the environment variable
  78 *** and run configure again.])
  79 fi
  80
  81 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  82 # since this would lead to problems installing/building glibc.
  83 # GCC_EXEC_PREFIX contains the current directory if one of the following
  84 # is true:
  85 # - one of the terminals (":" and ";") is the first or last sign
  86 # - two terminals occur directly after each other
  87 # - the path contains an element with a dot in it
  88 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  89 changequote(,)dnl
  90 case ${GCC_EXEC_PREFIX} in
  91   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  92     gcc_exec_prefix_setting="contains current directory"
  93     ;;
  94   *)
  95     gcc_exec_prefix_setting="ok"
  96     ;;
  97 esac
  98 changequote([,])dnl
  99 AC_MSG_RESULT($gcc_exec_prefix_setting)
 100 if test "$gcc_exec_prefix_setting" != "ok"; then
 101 AC_MSG_ERROR([
 102 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
 103 *** building gcc. Please change the environment variable
 104 *** and run configure again.])
 105 fi
 106
 107 # -----------
 108 # Directories
 109 # -----------
 110
 111 # Specify the local prefix
 112 local_prefix=
 113 AC_ARG_WITH(local-prefix,
 114 [AS_HELP_STRING([--with-local-prefix=DIR],
 115                 [specifies directory to put local include])],
 116 [case "${withval}" in
 117 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 118 no)     ;;
 119 *)      local_prefix=$with_local_prefix ;;
 120 esac])
 121
 122 # Default local prefix if it is empty
 123 if test x$local_prefix = x; then
 124         local_prefix=/usr/local
 125 fi
 126
 127 AC_ARG_WITH([native-system-header-dir],
 128   [  --with-native-system-header-dir=dir
 129                           use dir as the directory to look for standard
 130                           system header files in.  Defaults to /usr/include.],
 131 [
 132  case ${with_native_system_header_dir} in
 133  yes|no) AC_MSG_ERROR([bad value ${withval} given for --with-native-system-header-dir]) ;;
 134  /* | [[A-Za-z]]:[[\\/]]*) ;;
 135  *) AC_MSG_ERROR([--with-native-system-header-dir argument ${withval} must be an absolute directory]) ;;
 136  esac
 137  configured_native_system_header_dir="${withval}"
 138 ], [configured_native_system_header_dir=])
 139
 140 AC_ARG_WITH(build-sysroot,
 141   [AS_HELP_STRING([--with-build-sysroot=sysroot],
 142                   [use sysroot as the system root during the build])],
 143   [if test x"$withval" != x ; then
 144      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
 145    fi],
 146   [SYSROOT_CFLAGS_FOR_TARGET=])
 147 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 148
 149 if test "x$prefix" = xNONE; then
 150  test_prefix=/usr/local
 151 else
 152  test_prefix=$prefix
 153 fi
 154 if test "x$exec_prefix" = xNONE; then
 155  test_exec_prefix=$test_prefix
 156 else
 157  test_exec_prefix=$exec_prefix
 158 fi
 159
 160 AC_ARG_WITH(sysroot,
 161 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
 162                 [search for usr/lib, usr/include, et al, within DIR])],
 163 [
 164  case ${with_sysroot} in
 165  /) ;;
 166  */) with_sysroot=`echo $with_sysroot | sed 's,/$,,'` ;;
 167  esac
 168  case ${with_sysroot} in
 169  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 170  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 171  esac
 172
 173  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 174  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 175
 176  case ${TARGET_SYSTEM_ROOT} in
 177  "${test_prefix}"|"${test_prefix}/"*|\
 178  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 179  '${prefix}'|'${prefix}/'*|\
 180  '${exec_prefix}'|'${exec_prefix}/'*)
 181    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 182    TARGET_SYSTEM_ROOT_DEFINE="$t"
 183    ;;
 184  esac
 185 ], [
 186  TARGET_SYSTEM_ROOT=
 187  TARGET_SYSTEM_ROOT_DEFINE=
 188  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 189 ])
 190 AC_SUBST(TARGET_SYSTEM_ROOT)
 191 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 192 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 193
 194 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 195 # passed in by the toplevel make and thus we'd get different behavior
 196 # depending on where we built the sources.
 197 gcc_gxx_include_dir=
 198 # Specify the g++ header file directory
 199 AC_ARG_WITH(gxx-include-dir,
 200 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
 201                 [specifies directory to put g++ header files])],
 202 [case "${withval}" in
 203 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 204 no)     ;;
 205 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 206 esac])
 207
 208 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 209 if test x${gcc_gxx_include_dir} = x; then
 210   if test x${enable_version_specific_runtime_libs} = xyes; then
 211     gcc_gxx_include_dir='${libsubdir}/include/c++'
 212   else
 213     libstdcxx_incdir='include/c++/$(version)'
 214     if test x$host != x$target; then
 215        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 216     fi
 217     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 218   fi
 219 fi
 220
 221 gcc_gxx_include_dir_add_sysroot=0
 222 if test "${with_sysroot+set}" = set; then
 223   gcc_gxx_without_sysroot=`expr "${gcc_gxx_include_dir}" : "${with_sysroot}"'\(.*\)'`
 224   if test "${gcc_gxx_without_sysroot}"; then
 225     if test x${with_sysroot} != x/; then
 226       gcc_gxx_include_dir="${gcc_gxx_without_sysroot}"
 227     fi
 228     gcc_gxx_include_dir_add_sysroot=1
 229   fi
 230 fi
 231
 232 AC_ARG_WITH(cpp_install_dir,
 233 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
 234                 [install the user visible C preprocessor in DIR
 235                  (relative to PREFIX) as well as PREFIX/bin])],
 236 [if test x$withval = xyes; then
 237   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 238 elif test x$withval != xno; then
 239   cpp_install_dir=$withval
 240 fi])
 241
 242 # We would like to our source tree to be readonly.  However when releases or
 243 # pre-releases are generated, the flex/bison generated files as well as the
 244 # various formats of manuals need to be included along with the rest of the
 245 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 246 # just that.
 247
 248 AC_MSG_CHECKING([whether to place generated files in the source directory])
 249   dnl generated-files-in-srcdir is disabled by default
 250   AC_ARG_ENABLE(generated-files-in-srcdir,
 251     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
 252                     [put copies of generated files in source dir
 253                      intended for creating source tarballs for users
 254                      without texinfo bison or flex])],
 255       generated_files_in_srcdir=$enableval,
 256       generated_files_in_srcdir=no)
 257
 258 AC_MSG_RESULT($generated_files_in_srcdir)
 259
 260 if test "$generated_files_in_srcdir" = "yes"; then
 261   GENINSRC=''
 262 else
 263   GENINSRC='#'
 264 fi
 265 AC_SUBST(GENINSRC)
 266
 267 # -------------------
 268 # Find default linker
 269 # -------------------
 270
 271 # With GNU ld
 272 AC_ARG_WITH(gnu-ld,
 273 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
 274 gnu_ld_flag="$with_gnu_ld",
 275 gnu_ld_flag=no)
 276
 277 # With pre-defined ld
 278 AC_ARG_WITH(ld,
 279 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
 280 DEFAULT_LINKER="$with_ld")
 281 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 282   if test ! -x "$DEFAULT_LINKER"; then
 283     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 284   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 285     gnu_ld_flag=yes
 286   fi
 287   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 288         [Define to enable the use of a default linker.])
 289 fi
 290
 291 AC_MSG_CHECKING([whether a default linker was specified])
 292 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 293   if test x"$gnu_ld_flag" = x"no"; then
 294     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 295   else
 296     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 297   fi
 298 else
 299   AC_MSG_RESULT(no)
 300 fi
 301
 302 # With demangler in GNU ld
 303 AC_ARG_WITH(demangler-in-ld,
 304 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
 305 demangler_in_ld="$with_demangler_in_ld",
 306 demangler_in_ld=yes)
 307
 308 # ----------------------
 309 # Find default assembler
 310 # ----------------------
 311
 312 # With GNU as
 313 AC_ARG_WITH(gnu-as,
 314 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
 315 gas_flag="$with_gnu_as",
 316 gas_flag=no)
 317
 318 AC_ARG_WITH(as,
 319 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
 320 DEFAULT_ASSEMBLER="$with_as")
 321 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 322   if test ! -x "$DEFAULT_ASSEMBLER"; then
 323     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 324   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 325     gas_flag=yes
 326   fi
 327   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 328         [Define to enable the use of a default assembler.])
 329 fi
 330
 331 AC_MSG_CHECKING([whether a default assembler was specified])
 332 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 333   if test x"$gas_flag" = x"no"; then
 334     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 335   else
 336     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 337   fi
 338 else
 339   AC_MSG_RESULT(no)
 340 fi
 341
 342 # ---------------
 343 # Find C compiler
 344 # ---------------
 345
 346 # If a non-executable a.out is present (e.g. created by GNU as above even if
 347 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 348 # file, even when creating an executable, so an execution test fails.
 349 # Remove possible default executable files to avoid this.
 350 #
 351 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 352 # Autoconf includes it.
 353 rm -f a.out a.exe b.out
 354
 355 # Find the native compiler
 356 AC_PROG_CC
 357 AC_PROG_CXX
 358 ACX_PROG_GNAT([-I"$srcdir"/ada])
 359
 360 # Do configure tests with the C++ compiler, since that's what we build with.
 361 AC_LANG(C++)
 362
 363 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 364 # optimizations to be activated explicitly by the toplevel.
 365 case "$CC" in
 366   */prev-gcc/xgcc*) ;;
 367   *) CFLAGS=`echo "$CFLAGS " | sed -e "s/-Ofast[[       ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" `
 368      CXXFLAGS=`echo "$CXXFLAGS " | sed -e "s/-Ofast[[   ]]//" -e "s/-O[[gs]][[  ]]//" -e "s/-O[[0-9]]*[[        ]]//" ` ;;
 369 esac
 370 AC_SUBST(CFLAGS)
 371 AC_SUBST(CXXFLAGS)
 372
 373 # Determine PICFLAG for target gnatlib.
 374 GCC_PICFLAG_FOR_TARGET
 375 AC_SUBST(PICFLAG_FOR_TARGET)
 376
 377 # -------------------------
 378 # Check C compiler features
 379 # -------------------------
 380
 381 AC_USE_SYSTEM_EXTENSIONS
 382 AC_PROG_CPP
 383 AC_C_INLINE
 384
 385 AC_SYS_LARGEFILE
 386
 387 # sizeof(char) is 1 by definition.
 388 AC_CHECK_SIZEOF(void *)
 389 AC_CHECK_SIZEOF(short)
 390 AC_CHECK_SIZEOF(int)
 391 AC_CHECK_SIZEOF(long)
 392 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 393 GCC_STDINT_TYPES
 394 if test x"$ac_cv_c_uint64_t" = x"no" -o x"$ac_cv_c_int64_t" = x"no"; then
 395   AC_MSG_ERROR([uint64_t or int64_t not found])
 396 fi
 397
 398 # check what underlying integer type int64_t uses
 399 AC_CACHE_CHECK(for int64_t underlying type, ac_cv_int64_t_type, [
 400 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 401 #ifdef HAVE_STDINT_H
 402 #include <stdint.h>
 403 #endif
 404 template <typename T> struct X { };
 405 template <>
 406 struct X<long> { typedef long t; };
 407 ]], [[X<int64_t>::t x;]])],[ac_cv_int64_t_type=long],[ac_cv_int64_t_type="long long"])])
 408 if test "$ac_cv_int64_t_type" = "long"; then
 409   AC_DEFINE(INT64_T_IS_LONG, 1,
 410   [Define if int64_t uses long as underlying type.])
 411 else
 412 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 413 #ifdef HAVE_STDINT_H
 414 #include <stdint.h>
 415 #endif
 416 template <typename T> struct X { };
 417 template <>
 418 struct X<long long> { typedef long long t; };
 419 ]], [[X<int64_t>::t x;]])],[],[AC_MSG_ERROR([error verifying int64_t uses long long])])
 420 fi
 421
 422 AC_CACHE_CHECK(for std::swap in <utility>, ac_cv_std_swap_in_utility, [
 423 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 424 #include <utility>
 425 ]], [[int a, b; std::swap(a,b);]])],[ac_cv_std_swap_in_utility=yes],[ac_cv_std_swap_in_utility=no])])
 426 if test $ac_cv_std_swap_in_utility = yes; then
 427   AC_DEFINE(HAVE_SWAP_IN_UTILITY, 1,
 428   [Define if <utility> defines std::swap.])
 429 fi
 430
 431 # Check whether compiler is affected by placement new aliasing bug (PR 29286).
 432 # If the host compiler is affected by the bug, and we build with optimization
 433 # enabled (which happens e.g. when cross-compiling), the pool allocator may
 434 # get miscompiled.  Use -fno-strict-aliasing to work around this problem.
 435 # Since there is no reliable feature check for the presence of this bug,
 436 # we simply use a GCC version number check.  (This should never trigger for
 437 # stages 2 or 3 of a native bootstrap.)
 438 aliasing_flags=
 439 if test "$GCC" = yes; then
 440   saved_CXXFLAGS="$CXXFLAGS"
 441
 442   # The following test compilation will succeed if and only if $CXX accepts
 443   # -fno-strict-aliasing *and* is older than GCC 4.3.
 444   CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 445   AC_MSG_CHECKING([whether $CXX is affected by placement new aliasing bug])
 446   AC_COMPILE_IFELSE([
 447 #if (__GNUC__ > 4) || (__GNUC__ == 4 && __GNUC_MINOR__ >= 3)
 448 #error compiler not affected by placement new aliasing bug
 449 #endif
 450 ],
 451     [AC_MSG_RESULT([yes]); aliasing_flags='-fno-strict-aliasing'],
 452     [AC_MSG_RESULT([no])])
 453
 454   CXXFLAGS="$saved_CXXFLAGS"
 455 fi
 456 AC_SUBST(aliasing_flags)
 457
 458
 459
 460 # ---------------------
 461 # Warnings and checking
 462 # ---------------------
 463
 464 # Check $CC warning features (if it's GCC).
 465 # We want to use -pedantic, but we don't want warnings about
 466 # * 'long long'
 467 # * variadic macros
 468 # * overlong strings
 469 # * C++11 narrowing conversions in { }
 470 # So, we only use -pedantic if we can disable those warnings.
 471
 472 # In stage 1, disable -Wformat warnings from old GCCs about new % codes
 473 AC_ARG_ENABLE(build-format-warnings,
 474   AS_HELP_STRING([--disable-build-format-warnings],[don't use -Wformat while building GCC]),
 475   [],[enable_build_format_warnings=yes])
 476 AS_IF([test $enable_build_format_warnings = no],
 477       [wf_opt=-Wno-format],[wf_opt=])
 478 ACX_PROG_CXX_WARNING_OPTS(
 479         m4_quote(m4_do([-W -Wall -Wno-narrowing -Wwrite-strings -Wcast-qual $wf_opt])), [loose_warn])
 480 ACX_PROG_CC_WARNING_OPTS(
 481         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
 482         [c_loose_warn])
 483 ACX_PROG_CXX_WARNING_OPTS(
 484         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
 485 ACX_PROG_CXX_WARNING_OPTS(
 486         m4_quote(m4_do([-Woverloaded-virtual])), [strict_warn])
 487 ACX_PROG_CC_WARNING_OPTS(
 488         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
 489 ACX_PROG_CXX_WARNING_ALMOST_PEDANTIC(
 490         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 491                        [-Wno-overlength-strings])), [strict_warn])
 492 ACX_PROG_CXX_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 493
 494 # The above macros do nothing if the compiler is not GCC.  However, the
 495 # Makefile has more goo to add other flags, so these variables are used
 496 # to enable warnings only for GCC.
 497 warn_cflags=
 498 warn_cxxflags=
 499 if test "x$GCC" = "xyes"; then
 500   warn_cflags='$(GCC_WARN_CFLAGS)'
 501   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
 502 fi
 503 AC_SUBST(warn_cflags)
 504 AC_SUBST(warn_cxxflags)
 505
 506 # Disable exceptions and RTTI if building with g++
 507 ACX_PROG_CC_WARNING_OPTS(
 508         m4_quote(m4_do([-fno-exceptions -fno-rtti -fasynchronous-unwind-tables])),
 509                        [noexception_flags])
 510
 511 # Enable expensive internal checks
 512 is_release=
 513 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 514   is_release=yes
 515 fi
 516
 517 AC_ARG_ENABLE(checking,
 518 [AS_HELP_STRING([[--enable-checking[=LIST]]],
 519                 [enable expensive run-time checks.  With LIST,
 520                  enable only specific categories of checks.
 521                  Categories are: yes,no,all,none,release.
 522                  Flags are: assert,df,extra,fold,gc,gcac,gimple,misc,
 523                  rtlflag,rtl,runtime,tree,valgrind,types])],
 524 [ac_checking_flags="${enableval}"],[
 525 # Determine the default checks.
 526 if test x$is_release = x ; then
 527   ac_checking_flags=yes,extra
 528 else
 529   ac_checking_flags=release
 530 fi])
 531 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 532 for check in release $ac_checking_flags
 533 do
 534         case $check in
 535         # these set all the flags to specific states
 536         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 537                         ac_fold_checking= ; ac_gc_checking=1 ; ac_extra_checking= ;
 538                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 539                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 540                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 541                         ac_types_checking=1 ;;
 542         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 543                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 544                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 545                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 546                         ac_tree_checking= ; ac_valgrind_checking= ;
 547                         ac_types_checking= ;;
 548         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 549                         ac_fold_checking=1 ; ac_gc_checking=1 ; ac_extra_checking=1 ;
 550                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 551                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 552                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 553                         ac_types_checking=1 ;;
 554         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 555                         ac_fold_checking= ; ac_gc_checking= ; ac_extra_checking= ;
 556                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 557                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 558                         ac_tree_checking= ; ac_valgrind_checking= ;
 559                         ac_types_checking= ;;
 560         # these enable particular checks
 561         assert)         ac_assert_checking=1 ;;
 562         df)             ac_df_checking=1 ;;
 563         extra)          ac_extra_checking=1 ;;
 564         fold)           ac_fold_checking=1 ;;
 565         gc)             ac_gc_checking=1 ;;
 566         gcac)           ac_gc_always_collect=1 ;;
 567         gimple)         ac_gimple_checking=1 ;;
 568         misc)           ac_checking=1 ;;
 569         rtl)            ac_rtl_checking=1 ;;
 570         rtlflag)        ac_rtlflag_checking=1 ;;
 571         runtime)        ac_runtime_checking=1 ;;
 572         tree)           ac_tree_checking=1 ;;
 573         types)          ac_types_checking=1 ;;
 574         valgrind)       ac_valgrind_checking=1 ;;
 575         *)      AC_MSG_ERROR(unknown check category $check) ;;
 576         esac
 577 done
 578 IFS="$ac_save_IFS"
 579
 580 nocommon_flag=""
 581 if test x$ac_checking != x ; then
 582   if test x$ac_extra_checking != x ; then
 583     ac_checking=2
 584   fi
 585   AC_DEFINE_UNQUOTED(CHECKING_P, $ac_checking,
 586 [Define to 1 if you want more run-time sanity checks.  This one gets a grab
 587    bag of miscellaneous but relatively cheap checks.  Define to 2 if you want
 588    also extra run-time checking that might affect code generation.])
 589   nocommon_flag=-fno-common
 590 else
 591   AC_DEFINE(CHECKING_P, 0)
 592 fi
 593 AC_SUBST(nocommon_flag)
 594 if test x$ac_df_checking != x ; then
 595   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 596 [Define if you want more run-time sanity checks for dataflow.])
 597 fi
 598 if test x$ac_assert_checking != x ; then
 599   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 600 [Define if you want assertions enabled.  This is a cheap check.])
 601 fi
 602 if test x$ac_gimple_checking != x ; then
 603   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 604 [Define if you want operations on GIMPLE (the basic data structure of
 605 the high-level optimizers) to be checked for dynamic type safety at
 606 runtime.  This is moderately expensive.])
 607 fi
 608 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 609 if test x$ac_runtime_checking != x ; then
 610   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 611 [Define if you want runtime assertions enabled.  This is a cheap check.])
 612 fi
 613 if test x$ac_tree_checking != x ; then
 614   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 615 [Define if you want all operations on trees (the basic data
 616    structure of the front ends) to be checked for dynamic type safety
 617    at runtime.  This is moderately expensive.
 618    ])
 619   TREECHECKING=yes
 620 fi
 621 if test x$ac_types_checking != x ; then
 622   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 623 [Define if you want all gimple types to be verified after gimplifiation.
 624    This is cheap.
 625    ])
 626 fi
 627 AC_SUBST(TREECHECKING)
 628 if test x$ac_rtl_checking != x ; then
 629   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 630 [Define if you want all operations on RTL (the basic data structure
 631    of the optimizer and back end) to be checked for dynamic type safety
 632    at runtime.  This is quite expensive.])
 633 fi
 634 if test x$ac_rtlflag_checking != x ; then
 635   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 636 [Define if you want RTL flag accesses to be checked against the RTL
 637    codes that are supported for each access macro.  This is relatively
 638    cheap.])
 639 fi
 640 if test x$ac_gc_checking != x ; then
 641   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 642 [Define if you want the garbage collector to do object poisoning and
 643    other memory allocation checks.  This is quite expensive.])
 644 fi
 645 if test x$ac_gc_always_collect != x ; then
 646   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 647 [Define if you want the garbage collector to operate in maximally
 648    paranoid mode, validating the entire heap and collecting garbage at
 649    every opportunity.  This is extremely expensive.])
 650 fi
 651 if test x$ac_fold_checking != x ; then
 652   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 653 [Define if you want fold checked that it never destructs its argument.
 654    This is quite expensive.])
 655 fi
 656 valgrind_path_defines=
 657 valgrind_command=
 658
 659 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 660 dnl # an if statement.  This was the source of very frustrating bugs
 661 dnl # in converting to autoconf 2.5x!
 662 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 663
 664 # It is certainly possible that there's valgrind but no valgrind.h.
 665 # GCC relies on making annotations so we must have both.
 666 AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 667 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 668   [[#include <valgrind/memcheck.h>
 669 #ifndef VALGRIND_DISCARD
 670 #error VALGRIND_DISCARD not defined
 671 #endif]])],
 672   [gcc_cv_header_valgrind_memcheck_h=yes],
 673   [gcc_cv_header_valgrind_memcheck_h=no])
 674 AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 675 AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 676 AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 677   [[#include <memcheck.h>
 678 #ifndef VALGRIND_DISCARD
 679 #error VALGRIND_DISCARD not defined
 680 #endif]])],
 681   [gcc_cv_header_memcheck_h=yes],
 682   [gcc_cv_header_memcheck_h=no])
 683 AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 684 if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 685   AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 686         [Define if valgrind's valgrind/memcheck.h header is installed.])
 687 fi
 688 if test $gcc_cv_header_memcheck_h = yes; then
 689   AC_DEFINE(HAVE_MEMCHECK_H, 1,
 690         [Define if valgrind's memcheck.h header is installed.])
 691 fi
 692
 693 if test x$ac_valgrind_checking != x ; then
 694   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 695         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 696   if test "x$valgrind_path" = "x" \
 697     || (test $have_valgrind_h = no \
 698         && test $gcc_cv_header_memcheck_h = no \
 699         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 700         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 701   fi
 702   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 703   valgrind_command="$valgrind_path -q"
 704   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 705 [Define if you want to run subprograms and generated programs
 706    through valgrind (a memory checker).  This is extremely expensive.])
 707 fi
 708 AC_SUBST(valgrind_path_defines)
 709 AC_SUBST(valgrind_command)
 710
 711 # Enable code coverage collection
 712 AC_ARG_ENABLE(coverage,
 713 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
 714                 [enable compiler's code coverage collection.
 715                  Use to measure compiler performance and locate
 716                  unused parts of the compiler. With LEVEL, specify
 717                  optimization. Values are opt, noopt,
 718                  default is noopt])],
 719 [case "${enableval}" in
 720   yes|noopt)
 721     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 722     ;;
 723   opt)
 724     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 725     ;;
 726   no)
 727     # a.k.a. --disable-coverage
 728     coverage_flags=""
 729     ;;
 730   *)
 731     AC_MSG_ERROR(unknown coverage setting $enableval)
 732     ;;
 733 esac],
 734 [coverage_flags=""])
 735 AC_SUBST(coverage_flags)
 736
 737 AC_ARG_ENABLE(gather-detailed-mem-stats,
 738 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
 739                 [enable detailed memory allocation stats gathering])], [],
 740 [enable_gather_detailed_mem_stats=no])
 741 gather_stats=`if test $enable_gather_detailed_mem_stats != no; then echo 1; else echo 0; fi`
 742 AC_DEFINE_UNQUOTED(GATHER_STATISTICS, $gather_stats,
 743 [Define to enable detailed memory allocation stats gathering.])
 744
 745 AC_ARG_ENABLE(valgrind-annotations,
 746 [AS_HELP_STRING([--enable-valgrind-annotations],
 747                 [enable valgrind runtime interaction])], [],
 748 [enable_valgrind_annotations=no])
 749 if test x$enable_valgrind_annotations != xno \
 750     || test x$ac_valgrind_checking != x; then
 751   if (test $have_valgrind_h = no \
 752       && test $gcc_cv_header_memcheck_h = no \
 753       && test $gcc_cv_header_valgrind_memcheck_h = no); then
 754     AC_MSG_ERROR([*** Can't find valgrind/memcheck.h, memcheck.h or valgrind.h])
 755   fi
 756   AC_DEFINE(ENABLE_VALGRIND_ANNOTATIONS, 1,
 757 [Define to get calls to the valgrind runtime enabled.])
 758 fi
 759
 760 # -------------------------------
 761 # Miscenalleous configure options
 762 # -------------------------------
 763
 764 # With stabs
 765 AC_ARG_WITH(stabs,
 766 [AS_HELP_STRING([--with-stabs],
 767                 [arrange to use stabs instead of host debug format])],
 768 stabs="$with_stabs",
 769 stabs=no)
 770
 771 # Determine whether or not multilibs are enabled.
 772 AC_ARG_ENABLE(multilib,
 773 [AS_HELP_STRING([--enable-multilib],
 774                 [enable library support for multiple ABIs])],
 775 [], [enable_multilib=yes])
 776 AC_SUBST(enable_multilib)
 777
 778 # Determine whether or not multiarch is enabled.
 779 AC_ARG_ENABLE(multiarch,
 780 [AS_HELP_STRING([--enable-multiarch],
 781                 [enable support for multiarch paths])],
 782 [case "${enableval}" in
 783 yes|no|auto) enable_multiarch=$enableval;;
 784 *) AC_MSG_ERROR(bad value ${enableval} given for --enable-multiarch option) ;;
 785 esac], [enable_multiarch=auto])
 786 if test x${enable_multiarch} = xauto; then
 787   if test x${with_native_system_header_dir} != x; then
 788     ma_msg_suffix=", disabled auto check (configured with --native-system-header-dir)"
 789     enable_multiarch=no
 790   fi
 791   if test x$host != x$target && test "x$with_sysroot" = x; then
 792     ma_msg_suffix=", disabled auto check (cross build configured without --with-sysroot)"
 793     enable_multiarch=no
 794   fi
 795 fi
 796 AC_MSG_CHECKING(for multiarch configuration)
 797 AC_SUBST(enable_multiarch)
 798 AC_MSG_RESULT($enable_multiarch$ma_msg_suffix)
 799
 800 # needed for setting the multiarch name for soft-float/hard-float ABIs
 801 AC_SUBST(with_cpu)
 802 AC_SUBST(with_float)
 803
 804 # Enable __cxa_atexit for C++.
 805 AC_ARG_ENABLE(__cxa_atexit,
 806 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
 807 [], [])
 808
 809 # Enable C extension for decimal float if target supports it.
 810 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
 811
 812 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 813 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 814 [Define to 1 to enable decimal float extension to C.])
 815
 816 # Use default_decimal_float for dependency.
 817 enable_decimal_float=$default_decimal_float
 818
 819 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 820 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 821 [Define to 1 to specify that we are using the BID decimal floating
 822 point format instead of DPD])
 823
 824 # Enable C extension for fixed-point arithmetic.
 825 AC_ARG_ENABLE(fixed-point,
 826 [AS_HELP_STRING([--enable-fixed-point],
 827                 [enable fixed-point arithmetic extension to C])],
 828 [],
 829 [
 830   case $target in
 831     arm*)
 832       enable_fixed_point=yes
 833       ;;
 834
 835     mips*-*-*)
 836       enable_fixed_point=yes
 837       ;;
 838     *)
 839       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
 840       enable_fixed_point=no
 841       ;;
 842   esac
 843 ])
 844 AC_SUBST(enable_fixed_point)
 845
 846 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 847 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 848 [Define to 1 to enable fixed-point arithmetic extension to C.])
 849
 850 # Enable threads
 851 # Pass with no value to take the default
 852 # Pass with a value to specify a thread package
 853 AC_ARG_ENABLE(threads,
 854 [AS_HELP_STRING([[--enable-threads[=LIB]]],
 855                 [enable thread usage for target GCC,
 856                  using LIB thread package])],,
 857 [enable_threads=''])
 858
 859 AC_ARG_ENABLE(tls,
 860 [AS_HELP_STRING([--enable-tls],
 861                 [enable or disable generation of tls code
 862                  overriding the assembler check for tls support])],
 863 [
 864   case $enable_tls in
 865     yes | no) ;;
 866     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 867 Valid choices are 'yes' and 'no'.]) ;;
 868   esac
 869 ], [enable_tls=''])
 870
 871 AC_ARG_ENABLE(vtable-verify,
 872 [AS_HELP_STRING([--enable-vtable-verify],
 873                 [enable vtable verification feature])],,
 874 [enable_vtable_verify=no])
 875 vtable_verify=`if test x$enable_vtable_verify = xyes; then echo 1; else echo 0; fi`
 876 AC_DEFINE_UNQUOTED(ENABLE_VTABLE_VERIFY, $vtable_verify,
 877 [Define 0/1 if vtable verification feature is enabled.])
 878
 879 AC_ARG_ENABLE(objc-gc,
 880 [AS_HELP_STRING([--enable-objc-gc],
 881                 [enable the use of Boehm's garbage collector with
 882                  the GNU Objective-C runtime])],
 883 if test x$enable_objc_gc = xno; then
 884         objc_boehm_gc=''
 885 else
 886         objc_boehm_gc=1
 887 fi,
 888 objc_boehm_gc='')
 889
 890 AC_ARG_WITH(dwarf2,
 891 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
 892 dwarf2="$with_dwarf2",
 893 dwarf2=no)
 894
 895 AC_ARG_ENABLE(shared,
 896 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
 897 [
 898   case $enable_shared in
 899   yes | no) ;;
 900   *)
 901     enable_shared=no
 902     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 903     for pkg in $enableval; do
 904       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 905         enable_shared=yes
 906       fi
 907     done
 908     IFS="$ac_save_ifs"
 909     ;;
 910   esac
 911 ], [enable_shared=yes])
 912 AC_SUBST(enable_shared)
 913
 914 AC_ARG_WITH(specs,
 915   [AS_HELP_STRING([--with-specs=SPECS],
 916                   [add SPECS to driver command-line processing])],
 917   [CONFIGURE_SPECS=$withval],
 918   [CONFIGURE_SPECS=]
 919 )
 920 AC_SUBST(CONFIGURE_SPECS)
 921
 922 ACX_PKGVERSION([GCC])
 923 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 924
 925 # Sanity check enable_languages in case someone does not run the toplevel
 926 # configure # script.
 927 AC_ARG_ENABLE(languages,
 928 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
 929 [case ,${enable_languages}, in
 930        ,,|,yes,)
 931                 # go safe -- we cannot be much sure without the toplevel
 932                 # configure's
 933                 # analysis of which target libs are present and usable
 934                 enable_languages=c
 935                 ;;
 936          *,all,*)
 937                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 938                 ;;
 939         *,c,*)
 940                 ;;
 941         *)
 942                 enable_languages=c,${enable_languages}
 943                 ;;
 944 esac],
 945 [enable_languages=c])
 946
 947 if test x"$enable_as_accelerator_for" != x; then
 948   AC_DEFINE(ACCEL_COMPILER, 1,
 949     [Define if this compiler should be built as the offload target compiler.])
 950   enable_as_accelerator=yes
 951   case "${target}" in
 952     *-intelmicemul-*)
 953       # In this case we expect offload compiler to be built as native, so we
 954       # need to rename the driver to avoid clashes with host's drivers.
 955       program_transform_name="s&^&${target}-&" ;;
 956   esac
 957   sedscript="s#${target_noncanonical}#${enable_as_accelerator_for}-accel-${target_noncanonical}#"
 958   program_transform_name=`echo $program_transform_name | sed $sedscript`
 959   accel_dir_suffix=/accel/${target_noncanonical}
 960   real_target_noncanonical=${enable_as_accelerator_for}
 961 fi
 962 AC_SUBST(enable_as_accelerator)
 963 AC_SUBST(real_target_noncanonical)
 964 AC_SUBST(accel_dir_suffix)
 965
 966 for tgt in `echo $enable_offload_targets | sed 's/,/ /g'`; do
 967   tgt=`echo $tgt | sed 's/=.*//'`
 968
 969   if echo "$tgt" | grep "^hsa" > /dev/null ; then
 970     enable_hsa=1
 971   else
 972     enable_offloading=1
 973   fi
 974
 975   if test x"$offload_targets" = x; then
 976     offload_targets=$tgt
 977   else
 978     offload_targets="$offload_targets,$tgt"
 979   fi
 980 done
 981 AC_DEFINE_UNQUOTED(OFFLOAD_TARGETS, "$offload_targets",
 982   [Define to offload targets, separated by commas.])
 983 if test x"$enable_offloading" != x; then
 984   AC_DEFINE(ENABLE_OFFLOADING, 1,
 985     [Define this to enable support for offloading.])
 986 else
 987   AC_DEFINE(ENABLE_OFFLOADING, 0,
 988     [Define this to enable support for offloading.])
 989 fi
 990
 991 if test x"$enable_hsa" = x1 ; then
 992   AC_DEFINE(ENABLE_HSA, 1,
 993     [Define this to enable support for generating HSAIL.])
 994 fi
 995
 996 AC_ARG_WITH(multilib-list,
 997 [AS_HELP_STRING([--with-multilib-list], [select multilibs (AArch64, SH and x86-64 only)])],
 998 :,
 999 with_multilib_list=default)
1000
1001 # -------------------------
1002 # Checks for other programs
1003 # -------------------------
1004
1005 AC_PROG_MAKE_SET
1006
1007 # Find some useful tools
1008 AC_PROG_AWK
1009 # We need awk to create options.c and options.h.
1010 # Bail out if it's missing.
1011 case ${AWK} in
1012   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
1013 esac
1014
1015 gcc_AC_PROG_LN_S
1016 ACX_PROG_LN($LN_S)
1017 AC_PROG_RANLIB
1018 ranlib_flags=""
1019 AC_SUBST(ranlib_flags)
1020
1021 gcc_AC_PROG_INSTALL
1022
1023 # See if cmp has --ignore-initial.
1024 gcc_AC_PROG_CMP_IGNORE_INITIAL
1025
1026 # See if we have the mktemp command.
1027 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
1028
1029 # See if makeinfo has been installed and is modern enough
1030 # that we can use it.
1031 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1032   [GNU texinfo.* \([0-9][0-9.]*\)],
1033   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
1034 if test $gcc_cv_prog_makeinfo_modern = no; then
1035   AC_MSG_WARN([
1036 *** Makeinfo is missing or too old.
1037 *** Info documentation will not be built.])
1038   BUILD_INFO=
1039 else
1040   BUILD_INFO=info
1041 fi
1042 AC_SUBST(BUILD_INFO)
1043
1044 # Is pod2man recent enough to regenerate manpages?
1045 AC_MSG_CHECKING([for recent Pod::Man])
1046 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
1047   AC_MSG_RESULT(yes)
1048   GENERATED_MANPAGES=generated-manpages
1049 else
1050   AC_MSG_RESULT(no)
1051   GENERATED_MANPAGES=
1052 fi
1053 AC_SUBST(GENERATED_MANPAGES)
1054
1055 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
1056
1057 # How about lex?
1058 dnl Don't use AC_PROG_LEX; we insist on flex.
1059 dnl LEXLIB is not useful in gcc.
1060 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
1061
1062 # Bison?
1063 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
1064
1065 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
1066 # check for build == host before using them.
1067
1068 # NM
1069 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
1070   && test -d ../binutils ; then
1071   NM='${objdir}/../binutils/nm-new'
1072 else
1073   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
1074 fi
1075
1076 # AR
1077 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
1078   && test -d ../binutils ; then
1079   AR='${objdir}/../binutils/ar'
1080 else
1081   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
1082 fi
1083
1084 # The jit documentation looks better if built with sphinx, but can be
1085 # built with texinfo if sphinx is not available.
1086 # Set "doc_build_sys" to "sphinx" or "texinfo" accordingly.
1087 AC_CHECK_PROG(doc_build_sys, sphinx-build, sphinx, texinfo)
1088
1089 # --------------------
1090 # Checks for C headers
1091 # --------------------
1092
1093 # Need to reject headers which give warnings, so that the -Werror bootstrap
1094 # works later. *sigh*  This needs to come before all header checks.
1095 AC_PROG_CPP_WERROR
1096
1097 AC_HEADER_STDC
1098 AC_HEADER_TIME
1099 ACX_HEADER_STRING
1100 AC_HEADER_SYS_WAIT
1101 AC_HEADER_TIOCGWINSZ
1102 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
1103                  fcntl.h ftw.h unistd.h sys/file.h sys/time.h sys/mman.h \
1104                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
1105                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
1106
1107 # Check for thread headers.
1108 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
1109 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
1110
1111 # These tests can't be done till we know if we have limits.h.
1112 gcc_AC_C_CHAR_BIT
1113 AC_C_BIGENDIAN
1114
1115 # ----------------------
1116 # Checks for C++ headers
1117 # ----------------------
1118
1119 dnl Autoconf will give an error in the configure script if there is no
1120 dnl C++ preprocessor.  Hack to prevent that.
1121 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
1122 AC_PROG_CXXCPP
1123 m4_popdef([AC_MSG_ERROR])[]dnl
1124
1125 AC_CHECK_HEADERS(unordered_map)
1126 AC_CHECK_HEADERS(tr1/unordered_map)
1127 AC_CHECK_HEADERS(ext/hash_map)
1128
1129 # --------
1130 # Dependency checking.
1131 # --------
1132
1133 ZW_CREATE_DEPDIR
1134 AC_CONFIG_COMMANDS([gccdepdir],[
1135   ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs build/$DEPDIR
1136   for lang in $subdirs c-family common
1137   do
1138       ${CONFIG_SHELL-/bin/sh} $ac_aux_dir/mkinstalldirs $lang/$DEPDIR
1139   done], [subdirs="$subdirs" ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR])
1140
1141 ZW_PROG_COMPILER_DEPENDENCIES([CXX])
1142
1143 # --------
1144 # UNSORTED
1145 # --------
1146
1147
1148 # These libraries may be used by collect2.
1149 # We may need a special search path to get them linked.
1150 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
1151 [save_LIBS="$LIBS"
1152 for libs in '' -lld -lmld \
1153                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
1154                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
1155 do
1156         LIBS="$libs"
1157         AC_TRY_LINK_FUNC(ldopen,
1158                 [gcc_cv_collect2_libs="$libs"; break])
1159 done
1160 LIBS="$save_LIBS"
1161 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
1162 case $gcc_cv_collect2_libs in
1163         "none required")        ;;
1164         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
1165 esac
1166 AC_SUBST(COLLECT2_LIBS)
1167
1168 # When building Ada code on Alpha, we need exc_resume which is usually in
1169 # -lexc.  So test for it.
1170 save_LIBS="$LIBS"
1171 LIBS=
1172 AC_SEARCH_LIBS(exc_resume, exc)
1173 GNAT_LIBEXC="$LIBS"
1174 LIBS="$save_LIBS"
1175 AC_SUBST(GNAT_LIBEXC)
1176
1177 # To support -mcpu=native on Solaris/SPARC, we need libkstat.
1178 save_LIBS="$LIBS"
1179 LIBS=
1180 AC_SEARCH_LIBS(kstat_open, kstat)
1181 EXTRA_GCC_LIBS="$LIBS"
1182 LIBS="$save_LIBS"
1183 AC_SUBST(EXTRA_GCC_LIBS)
1184
1185 # Some systems put ldexp and frexp in libm instead of libc; assume
1186 # they're both in the same place.  jcf-dump needs them.
1187 save_LIBS="$LIBS"
1188 LIBS=
1189 AC_SEARCH_LIBS(ldexp, m)
1190 LDEXP_LIB="$LIBS"
1191 LIBS="$save_LIBS"
1192 AC_SUBST(LDEXP_LIB)
1193
1194 # Use <inttypes.h> only if it exists,
1195 # doesn't clash with <sys/types.h>, declares intmax_t and defines
1196 # PRId64
1197 AC_MSG_CHECKING(for inttypes.h)
1198 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1199 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1200 [[#define __STDC_FORMAT_MACROS
1201 #include <sys/types.h>
1202 #include <inttypes.h>]],
1203   [[intmax_t i = -1;
1204 #ifndef PRId64
1205 choke me
1206 #endif]])],
1207   [gcc_cv_header_inttypes_h=yes],
1208   [gcc_cv_header_inttypes_h=no])])
1209 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1210 if test $gcc_cv_header_inttypes_h = yes; then
1211   AC_DEFINE(HAVE_INTTYPES_H, 1,
1212         [Define if you have a working <inttypes.h> header file.])
1213 fi
1214
1215 dnl Disabled until we have a complete test for buggy enum bitfields.
1216 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1217
1218 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1219   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1220   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1221   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1222   putchar_unlocked putc_unlocked)
1223 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoq \
1224         popen sysconf strsignal getrusage nl_langinfo \
1225         gettimeofday mbstowcs wcswidth mmap setlocale \
1226         gcc_UNLOCKED_FUNCS madvise)
1227
1228 if test x$ac_cv_func_mbstowcs = xyes; then
1229   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1230 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1231 int main()
1232 {
1233   mbstowcs(0, "", 0);
1234   return 0;
1235 }]])],
1236     [gcc_cv_func_mbstowcs_works=yes],
1237     [gcc_cv_func_mbstowcs_works=no],
1238     [gcc_cv_func_mbstowcs_works=yes])])
1239   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1240     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1241   [Define this macro if mbstowcs does not crash when its
1242    first argument is NULL.])
1243   fi
1244 fi
1245
1246 AC_CHECK_TYPE(ssize_t, int)
1247 AC_CHECK_TYPE(caddr_t, char *)
1248
1249 GCC_AC_FUNC_MMAP_BLACKLIST
1250
1251 case "${host}" in
1252 *-*-*vms*)
1253   # Under VMS, vfork works very differently than on Unix. The standard test
1254   # won't work, and it isn't easily adaptable. It makes more sense to
1255   # just force it.
1256   ac_cv_func_vfork_works=yes
1257   ;;
1258 esac
1259 AC_FUNC_FORK
1260
1261 AM_ICONV
1262
1263 # Until we have in-tree GNU iconv:
1264 LIBICONV_DEP=
1265 if test -f "$LTLIBICONV"; then
1266   LIBICONV_DEP=$LTLIBICONV
1267 fi
1268 AC_SUBST(LIBICONV_DEP)
1269
1270 AM_LC_MESSAGES
1271
1272 AM_LANGINFO_CODESET
1273
1274 # We will need to find libiberty.h and ansidecl.h
1275 saved_CFLAGS="$CFLAGS"
1276 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1277 saved_CXXFLAGS="$CXXFLAGS"
1278 CXXFLAGS="$CXXFLAGS -I${srcdir} -I${srcdir}/../include $GMPINC"
1279
1280 # gcc_AC_CHECK_DECLS doesn't support overloaded functions, so use the
1281 # normal autoconf function for these.  But force definition of
1282 # HAVE_DECL_BASENAME like gcc_AC_CHECK_DECLS does, to suppress the bizarre
1283 # basename handling in libiberty.h.
1284 AC_CHECK_DECLS([basename(const char*), strstr(const char*,const char*)], , ,[
1285 #undef HAVE_DECL_BASENAME
1286 #define HAVE_DECL_BASENAME 1
1287 #include "ansidecl.h"
1288 #include "system.h"])
1289
1290 gcc_AC_CHECK_DECLS(getenv atol atoll asprintf sbrk abort atof getcwd getwd \
1291         madvise stpcpy strnlen strsignal strverscmp \
1292         strtol strtoul strtoll strtoull setenv unsetenv \
1293         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1294         free getopt clock getpagesize ffs gcc_UNLOCKED_FUNCS, , ,[
1295 #include "ansidecl.h"
1296 #include "system.h"])
1297
1298 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1299 #include "ansidecl.h"
1300 #include "system.h"
1301 #ifdef HAVE_SYS_RESOURCE_H
1302 #include <sys/resource.h>
1303 #endif
1304 ])
1305
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1307 #include "ansidecl.h"
1308 #include "system.h"
1309 #ifdef HAVE_SYS_RESOURCE_H
1310 #include <sys/resource.h>
1311 #endif
1312 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1313 [Define to `long' if <sys/resource.h> doesn't define.])])
1314
1315 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1316 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1317 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1318 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1319 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1320 #include "ansidecl.h"
1321 #include "system.h"
1322 #ifdef HAVE_LDFCN_H
1323 #undef FREAD
1324 #undef FWRITE
1325 #include <ldfcn.h>
1326 #endif
1327 ])
1328
1329 gcc_AC_CHECK_DECLS(times, , ,[
1330 #include "ansidecl.h"
1331 #include "system.h"
1332 #ifdef HAVE_SYS_TIMES_H
1333 #include <sys/times.h>
1334 #endif
1335 ])
1336
1337 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1338 #include "ansidecl.h"
1339 #include "system.h"
1340 #include <signal.h>
1341 ])
1342
1343 # More time-related stuff.
1344 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1345 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1346 #include "ansidecl.h"
1347 #include "system.h"
1348 #ifdef HAVE_SYS_TIMES_H
1349 #include <sys/times.h>
1350 #endif
1351 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1352 if test $ac_cv_struct_tms = yes; then
1353   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1354   [Define if <sys/times.h> defines struct tms.])
1355 fi
1356
1357 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1358 # revisit after autoconf 2.50.
1359 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1360 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1361 #include "ansidecl.h"
1362 #include "system.h"
1363 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1364 if test $gcc_cv_type_clock_t = yes; then
1365   AC_DEFINE(HAVE_CLOCK_T, 1,
1366   [Define if <time.h> defines clock_t.])
1367 fi
1368
1369 # Check if F_SETLKW is supported by fcntl.
1370 AC_CACHE_CHECK(for F_SETLKW, ac_cv_f_setlkw, [
1371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1372 #include <fcntl.h>]], [[
1373 struct flock fl;
1374 fl.l_whence = 0;
1375 fl.l_start = 0;
1376 fl.l_len = 0;
1377 fl.l_pid = 0;
1378 return fcntl (1, F_SETLKW, &fl);]])],
1379 [ac_cv_f_setlkw=yes],[ac_cv_f_setlkw=no])])
1380 if test $ac_cv_f_setlkw = yes; then
1381   AC_DEFINE(HOST_HAS_F_SETLKW, 1,
1382   [Define if F_SETLKW supported by fcntl.])
1383 fi
1384
1385 # Restore CFLAGS, CXXFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1386 CFLAGS="$saved_CFLAGS"
1387 CXXFLAGS="$saved_CXXFLAGS"
1388
1389 # mkdir takes a single argument on some systems.
1390 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1391
1392 # File extensions
1393 manext='.1'
1394 objext='.o'
1395 AC_SUBST(manext)
1396 AC_SUBST(objext)
1397
1398 # With Setjmp/Longjmp based exception handling.
1399 AC_ARG_ENABLE(sjlj-exceptions,
1400 [AS_HELP_STRING([--enable-sjlj-exceptions],
1401                 [arrange to use setjmp/longjmp exception handling])],
1402 [case $target in
1403   *-*-hpux10*)
1404     if test $enableval != yes; then
1405       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1406       enableval=yes
1407     fi
1408     ;;
1409 esac
1410 force_sjlj_exceptions=yes],
1411 [case $target in
1412   *-*-hpux10*)
1413     force_sjlj_exceptions=yes
1414     enableval=yes
1415     ;;
1416   lm32*-*-*)
1417      force_sjlj_exceptions=yes
1418      enableval=yes
1419      ;;
1420   *)
1421     force_sjlj_exceptions=no
1422     ;;
1423 esac])
1424 if test $force_sjlj_exceptions = yes; then
1425   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1426   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1427     [Define 0/1 to force the choice for exception handling model.])
1428 fi
1429
1430 # --------------------------------------------------------
1431 # Build, host, and target specific configuration fragments
1432 # --------------------------------------------------------
1433
1434 # Collect build-machine-specific information.
1435 . ${srcdir}/config.build
1436
1437 # Collect host-machine-specific information.
1438 . ${srcdir}/config.host
1439
1440 target_gtfiles=
1441
1442 # Collect target-machine-specific information.
1443 . ${srcdir}/config.gcc
1444
1445 extra_objs="${host_extra_objs} ${extra_objs}"
1446 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1447
1448 # Default the target-machine variables that were not explicitly set.
1449 if test x"$tm_file" = x
1450 then tm_file=$cpu_type/$cpu_type.h; fi
1451
1452 if test x"$extra_headers" = x
1453 then extra_headers=; fi
1454
1455 if test x$md_file = x
1456 then md_file=$cpu_type/$cpu_type.md; fi
1457
1458 if test x$out_file = x
1459 then out_file=$cpu_type/$cpu_type.c; fi
1460
1461 if test x"$tmake_file" = x
1462 then tmake_file=$cpu_type/t-$cpu_type
1463 fi
1464
1465 # Support --enable-initfini-array.
1466 if test x$enable_initfini_array != xno; then
1467   tm_file="${tm_file} initfini-array.h"
1468 fi
1469
1470 if test x"$dwarf2" = xyes
1471 then tm_file="$tm_file tm-dwarf2.h"
1472 fi
1473
1474 # Say what files are being used for the output code and MD file.
1475 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1476 echo "Using \`$srcdir/config/$md_file' as machine description file."
1477
1478 # If any of the xm_file variables contain nonexistent files, warn
1479 # about them and drop them.
1480
1481 bx=
1482 for x in $build_xm_file; do
1483   if    test -f $srcdir/config/$x
1484   then      bx="$bx $x"
1485   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1486   fi
1487 done
1488 build_xm_file="$bx"
1489
1490 hx=
1491 for x in $host_xm_file; do
1492   if    test -f $srcdir/config/$x
1493   then      hx="$hx $x"
1494   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1495   fi
1496 done
1497 host_xm_file="$hx"
1498
1499 tx=
1500 for x in $xm_file; do
1501   if    test -f $srcdir/config/$x
1502   then      tx="$tx $x"
1503   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1504   fi
1505 done
1506 xm_file="$tx"
1507
1508 count=a
1509 for f in $tm_file; do
1510         count=${count}x
1511 done
1512 if test $count = ax; then
1513         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1514 else
1515         echo "Using the following target machine macro files:"
1516         for f in $tm_file; do
1517                 echo "  $srcdir/config/$f"
1518         done
1519 fi
1520
1521 if test x$use_long_long_for_widest_fast_int = xyes; then
1522         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1523 [Define to 1 if the 'long long' type is wider than 'long' but still
1524 efficiently supported by the host hardware.])
1525 fi
1526
1527 gnu_ld_bool=`if test x"$gnu_ld" = x"yes"; then echo 1; else echo 0; fi`
1528 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld_bool, [Define to 1 if using GNU ld.])
1529
1530 gnu_as_bool=`if test x"$gas" = x"yes"; then echo 1; else echo 0; fi`
1531 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as_bool, [Define to 1 if using GNU as.])
1532
1533 count=a
1534 for f in $host_xm_file; do
1535         count=${count}x
1536 done
1537 if test $count = a; then
1538         :
1539 elif test $count = ax; then
1540         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1541 else
1542         echo "Using the following host machine macro files:"
1543         for f in $host_xm_file; do
1544                 echo "  $srcdir/config/$f"
1545         done
1546 fi
1547 echo "Using ${out_host_hook_obj} for host machine hooks."
1548
1549 if test "$host_xm_file" != "$build_xm_file"; then
1550         count=a
1551         for f in $build_xm_file; do
1552                 count=${count}x
1553         done
1554         if test $count = a; then
1555                 :
1556         elif test $count = ax; then
1557                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1558         else
1559                 echo "Using the following build machine macro files:"
1560                 for f in $build_xm_file; do
1561                         echo "  $srcdir/config/$f"
1562                 done
1563         fi
1564 fi
1565
1566 if test -n "$configured_native_system_header_dir"; then
1567   native_system_header_dir=$configured_native_system_header_dir
1568 fi
1569 NATIVE_SYSTEM_HEADER_DIR="$native_system_header_dir"
1570 AC_SUBST(NATIVE_SYSTEM_HEADER_DIR)
1571
1572 case ${host} in
1573   powerpc*-*-darwin*)
1574     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1575       gcc_cv_mcontext_underscores,
1576       AC_COMPILE_IFELSE([
1577 #include <sys/cdefs.h>
1578 #include <sys/signal.h>
1579 #include <ucontext.h>
1580 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1581 ],
1582         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1583       if test $gcc_cv_mcontext_underscores = yes; then
1584         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1585           [mcontext_t fields start with __])
1586       fi
1587     ;;
1588 esac
1589
1590 # ---------
1591 # Threading
1592 # ---------
1593
1594 # Check if a valid thread package
1595 case ${enable_threads} in
1596   "" | no)
1597     # No threads
1598     target_thread_file='single'
1599     ;;
1600   yes)
1601     # default
1602     target_thread_file='single'
1603     ;;
1604   aix | dce | lynx | mipssde | posix | rtems | \
1605   single | tpf | vxworks | win32)
1606     target_thread_file=${enable_threads}
1607     ;;
1608   *)
1609     echo "${enable_threads} is an unknown thread package" 1>&2
1610     exit 1
1611     ;;
1612 esac
1613
1614 if test x${thread_file} = x; then
1615   # No thread file set by target-specific clauses in config.gcc,
1616   # so use file chosen by default logic above
1617   thread_file=${target_thread_file}
1618 fi
1619
1620 # --------
1621 # UNSORTED
1622 # --------
1623
1624 use_cxa_atexit=no
1625 if test x$enable___cxa_atexit = xyes || \
1626    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1627   if test x$host = x$target; then
1628     case $host in
1629       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1630       # keyed to flag_use_cxa_atexit
1631       *-*-mingw32*)
1632         use_cxa_atexit=yes
1633         ;;
1634       powerpc-ibm-aix*)
1635         use_cxa_atexit=yes
1636         ;;
1637       *)
1638         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1639           [echo "__cxa_atexit can't be enabled on this target"])
1640         ;;
1641     esac
1642   else
1643     # We can't check for __cxa_atexit when building a cross, so assume
1644     # it is available
1645     use_cxa_atexit=yes
1646   fi
1647   if test x$use_cxa_atexit = xyes; then
1648     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1649       [Define if you want to use __cxa_atexit, rather than atexit, to
1650       register C++ destructors for local statics and global objects.
1651       This is essential for fully standards-compliant handling of
1652       destructors, but requires __cxa_atexit in libc.])
1653   fi
1654 fi
1655
1656 # Look for a file containing extra machine modes.
1657 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1658   extra_modes_file='$(srcdir)'/config/${extra_modes}
1659   AC_SUBST(extra_modes_file)
1660   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1661   [Define to the name of a file containing a list of extra machine modes
1662    for this architecture.])
1663 fi
1664
1665 # Convert extra_options into a form suitable for Makefile use.
1666 extra_opt_files=
1667 all_opt_files=
1668 for f in $extra_options; do
1669   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1670   all_opt_files="$all_opt_files $srcdir/config/$f"
1671 done
1672 AC_SUBST(extra_opt_files)
1673
1674 # auto-host.h is the file containing items generated by autoconf and is
1675 # the first file included by config.h.
1676 # If host=build, it is correct to have bconfig include auto-host.h
1677 # as well.  If host!=build, we are in error and need to do more
1678 # work to find out the build config parameters.
1679 if test x$host = x$build
1680 then
1681         build_auto=auto-host.h
1682 else
1683         # We create a subdir, then run autoconf in the subdir.
1684         # To prevent recursion we set host and build for the new
1685         # invocation of configure to the build for this invocation
1686         # of configure.
1687         tempdir=build.$$
1688         rm -rf $tempdir
1689         mkdir $tempdir
1690         cd $tempdir
1691         case ${srcdir} in
1692         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1693         *) realsrcdir=../${srcdir};;
1694         esac
1695         # Clearing GMPINC is necessary to prevent host headers being
1696         # used by the build compiler.  Defining GENERATOR_FILE stops
1697         # system.h from including gmp.h.
1698         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1699         CXX="${CXX_FOR_BUILD}" CXXFLAGS="${CXXFLAGS_FOR_BUILD}" \
1700         LD="${LD_FOR_BUILD}" LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1701         GMPINC="" CPPFLAGS="${CPPFLAGS} -DGENERATOR_FILE" \
1702         ${realsrcdir}/configure \
1703                 --enable-languages=${enable_languages-all} \
1704                 --target=$target_alias --host=$build_alias --build=$build_alias
1705
1706         # We just finished tests for the build machine, so rename
1707         # the file auto-build.h in the gcc directory.
1708         mv auto-host.h ../auto-build.h
1709         cd ..
1710         rm -rf $tempdir
1711         build_auto=auto-build.h
1712 fi
1713 AC_SUBST(build_subdir)
1714
1715 tm_file="${tm_file} defaults.h"
1716 tm_p_file="${tm_p_file} tm-preds.h"
1717 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1718 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1719 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1720 # put this back in temporarily.
1721 xm_file="auto-host.h ansidecl.h ${xm_file}"
1722
1723 # --------
1724 # UNSORTED
1725 # --------
1726
1727 changequote(,)dnl
1728 # Compile in configure arguments.
1729 if test -f configargs.h ; then
1730         # Being re-configured.
1731         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1732         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1733 else
1734         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1735 fi
1736
1737 # Double all backslashes and backslash all quotes to turn
1738 # gcc_config_arguments into a C string.
1739 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1740 $gcc_config_arguments
1741 EOF
1742 gcc_config_arguments_str=`cat conftest.out`
1743 rm -f conftest.out
1744
1745 cat > configargs.h <<EOF
1746 /* Generated automatically. */
1747 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1748 static const char thread_model[] = "$thread_file";
1749
1750 static const struct {
1751   const char *name, *value;
1752 } configure_default_options[] = $configure_default_options;
1753 EOF
1754 changequote([,])dnl
1755
1756 changequote(,)dnl
1757 gcc_BASEVER=`cat $srcdir/BASE-VER`
1758 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1759 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1760 if test -f $srcdir/REVISION ; then
1761         gcc_REVISION=`cat $srcdir/REVISION`
1762 else
1763         gcc_REVISION=""
1764 fi
1765 cat > plugin-version.h <<EOF
1766 #include "configargs.h"
1767
1768 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1769 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1770 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1771 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1772
1773 static char basever[] = "$gcc_BASEVER";
1774 static char datestamp[] = "$gcc_DATESTAMP";
1775 static char devphase[] = "$gcc_DEVPHASE";
1776 static char revision[] = "$gcc_REVISION";
1777
1778 /* FIXME plugins: We should make the version information more precise.
1779    One way to do is to add a checksum. */
1780
1781 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1782                                                 devphase, revision,
1783                                                 configuration_arguments};
1784 EOF
1785 changequote([,])dnl
1786
1787 # Internationalization
1788 ZW_GNU_GETTEXT_SISTER_DIR
1789
1790 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1791 # -liconv on the link line twice.
1792 case "$LIBINTL" in *$LIBICONV*)
1793         LIBICONV= ;;
1794 esac
1795
1796 AC_ARG_ENABLE(secureplt,
1797 [AS_HELP_STRING([--enable-secureplt],
1798                 [enable -msecure-plt by default for PowerPC])],
1799 [], [])
1800
1801 AC_ARG_ENABLE(leading-mingw64-underscores,
1802   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1803                  [enable leading underscores on 64 bit mingw targets]),
1804   [],[])
1805 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1806   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1807     [Define if we should use leading underscore on 64 bit mingw targets])])
1808
1809 AC_ARG_ENABLE(cld,
1810 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1811 [enable_cld=no])
1812
1813 AC_ARG_ENABLE(frame-pointer,
1814 [AS_HELP_STRING([--enable-frame-pointer],
1815                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1816 [
1817 case $target_os in
1818 linux* | darwin[[8912]]*)
1819   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1820   # DWARF2.
1821   enable_frame_pointer=no
1822   ;;
1823 *)
1824   enable_frame_pointer=yes
1825   ;;
1826 esac
1827 ])
1828
1829 # Windows32 Registry support for specifying GCC installation paths.
1830 AC_ARG_ENABLE(win32-registry,
1831 [AS_HELP_STRING([--disable-win32-registry],
1832                 [disable lookup of installation paths in the
1833                  Registry on Windows hosts])
1834 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1835 AS_HELP_STRING([--enable-win32-registry=KEY],
1836                [use KEY instead of GCC version as the last portion
1837                 of the registry key])],,)
1838
1839 case $host_os in
1840   win32 | pe | cygwin* | mingw32*)
1841     if test "x$enable_win32_registry" != xno; then
1842       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1843     fi
1844
1845     if test "x$enable_win32_registry" != xno; then
1846       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1847   [Define to 1 if installation paths should be looked up in the Windows
1848    Registry. Ignored on non-Windows hosts.])
1849
1850       if test "x$enable_win32_registry" != xyes \
1851          && test "x$enable_win32_registry" != x; then
1852         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1853   [Define to be the last component of the Windows registry key under which
1854    to look for installation paths.  The full key used will be
1855    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1856    The default is the GCC version number.])
1857       fi
1858     fi
1859   ;;
1860 esac
1861
1862 # Get an absolute path to the GCC top-level source directory
1863 holddir=`${PWDCMD-pwd}`
1864 cd $srcdir
1865 topdir=`${PWDCMD-pwd}`
1866 cd $holddir
1867
1868 # Conditionalize the makefile for this host machine.
1869 xmake_file=
1870 for f in ${host_xmake_file}
1871 do
1872         if test -f ${srcdir}/config/$f
1873         then
1874                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1875         fi
1876 done
1877
1878 # Conditionalize the makefile for this target machine.
1879 tmake_file_=
1880 for f in ${tmake_file}
1881 do
1882         if test -f ${srcdir}/config/$f
1883         then
1884                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1885         fi
1886 done
1887 tmake_file="${tmake_file_}"
1888
1889 out_object_file=`basename $out_file .c`.o
1890 common_out_object_file=`basename $common_out_file .c`.o
1891
1892 tm_file_list="options.h"
1893 tm_include_list="options.h insn-constants.h"
1894 for f in $tm_file; do
1895   case $f in
1896     ./* )
1897        f=`echo $f | sed 's/^..//'`
1898        tm_file_list="${tm_file_list} $f"
1899        tm_include_list="${tm_include_list} $f"
1900        ;;
1901     defaults.h )
1902        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1903        tm_include_list="${tm_include_list} $f"
1904        ;;
1905     * )
1906        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1907        tm_include_list="${tm_include_list} config/$f"
1908        ;;
1909   esac
1910 done
1911
1912 tm_p_file_list=
1913 tm_p_include_list=
1914 for f in $tm_p_file; do
1915   case $f in
1916     tm-preds.h )
1917        tm_p_file_list="${tm_p_file_list} $f"
1918        tm_p_include_list="${tm_p_include_list} $f"
1919        ;;
1920     * )
1921        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1922        tm_p_include_list="${tm_p_include_list} config/$f"
1923   esac
1924 done
1925
1926 xm_file_list=
1927 xm_include_list=
1928 for f in $xm_file; do
1929   case $f in
1930     ansidecl.h )
1931        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1932        xm_include_list="${xm_include_list} $f"
1933        ;;
1934     auto-host.h )
1935        xm_file_list="${xm_file_list} $f"
1936        xm_include_list="${xm_include_list} $f"
1937        ;;
1938     * )
1939        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1940        xm_include_list="${xm_include_list} config/$f"
1941        ;;
1942   esac
1943 done
1944
1945 host_xm_file_list=
1946 host_xm_include_list=
1947 for f in $host_xm_file; do
1948   case $f in
1949     ansidecl.h )
1950        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1951        host_xm_include_list="${host_xm_include_list} $f"
1952        ;;
1953     auto-host.h )
1954        host_xm_file_list="${host_xm_file_list} $f"
1955        host_xm_include_list="${host_xm_include_list} $f"
1956        ;;
1957     * )
1958        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1959        host_xm_include_list="${host_xm_include_list} config/$f"
1960        ;;
1961   esac
1962 done
1963
1964 build_xm_file_list=
1965 for f in $build_xm_file; do
1966   case $f in
1967     ansidecl.h )
1968        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1969        build_xm_include_list="${build_xm_include_list} $f"
1970        ;;
1971     auto-build.h | auto-host.h )
1972        build_xm_file_list="${build_xm_file_list} $f"
1973        build_xm_include_list="${build_xm_include_list} $f"
1974        ;;
1975     * )
1976        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1977        build_xm_include_list="${build_xm_include_list} config/$f"
1978        ;;
1979   esac
1980 done
1981
1982 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1983 # cross-compiler which does not use the native headers and libraries.
1984 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1985 CROSS=                                          AC_SUBST(CROSS)
1986 ALL=all.internal                                AC_SUBST(ALL)
1987 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1988
1989 if test "x$with_build_sysroot" != x; then
1990   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1991 else
1992   # This value is used, even on a native system, because
1993   # CROSS_SYSTEM_HEADER_DIR is just
1994   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1995   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1996 fi
1997
1998 if test x$host != x$target
1999 then
2000         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
2001         ALL=all.cross
2002         SYSTEM_HEADER_DIR=$build_system_header_dir
2003         case "$host","$target" in
2004         # Darwin crosses can use the host system's libraries and headers,
2005         # because of the fat library support.  Of course, it must be the
2006         # same version of Darwin on both sides.  Allow the user to
2007         # just say --target=foo-darwin without a version number to mean
2008         # "the version on this system".
2009             *-*-darwin*,*-*-darwin*)
2010                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
2011                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
2012                 if test $hostos = $targetos -o $targetos = darwin ; then
2013                     CROSS=
2014                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
2015                     with_headers=yes
2016                 fi
2017                 ;;
2018
2019             i?86-*-*,x86_64-*-* \
2020             | powerpc*-*-*,powerpc64*-*-*)
2021                 CROSS="$CROSS -DNATIVE_CROSS" ;;
2022         esac
2023
2024         case $target in
2025                 *-*-mingw*)
2026                         if test "x$with_headers" = x; then
2027                                 with_headers=yes
2028                         fi
2029                         ;;
2030                 *)
2031                         ;;
2032         esac
2033 elif test "x$TARGET_SYSTEM_ROOT" != x; then
2034         SYSTEM_HEADER_DIR=$build_system_header_dir
2035 fi
2036
2037 if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
2038   if test "x$with_headers" != x && test "x$with_headers" != xyes; then
2039     target_header_dir=$with_headers
2040   elif test "x$with_sysroot" = x; then
2041     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-include"
2042   elif test "x$with_build_sysroot" != "x"; then
2043     target_header_dir="${with_build_sysroot}${native_system_header_dir}"
2044   elif test "x$with_sysroot" = xyes; then
2045     target_header_dir="${test_exec_prefix}/${target_noncanonical}/sys-root${native_system_header_dir}"
2046   else
2047     target_header_dir="${with_sysroot}${native_system_header_dir}"
2048   fi
2049 else
2050   target_header_dir=${native_system_header_dir}
2051 fi
2052
2053 # If this is a cross-compiler that does not
2054 # have its own set of headers then define
2055 # inhibit_libc
2056
2057 # If this is using newlib, without having the headers available now,
2058 # then define inhibit_libc in LIBGCC2_CFLAGS.
2059 # This prevents libgcc2 from containing any code which requires libc
2060 # support.
2061 : ${inhibit_libc=false}
2062 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
2063        test x$with_newlib = xyes ; } &&
2064      { test "x$with_headers" = xno || test ! -f "$target_header_dir/stdio.h"; } ; then
2065        inhibit_libc=true
2066 fi
2067 AC_SUBST(inhibit_libc)
2068
2069 # When building gcc with a cross-compiler, we need to adjust things so
2070 # that the generator programs are still built with the native compiler.
2071 # Also, we cannot run fixincludes.
2072
2073 # These are the normal (build=host) settings:
2074 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
2075 CXX_FOR_BUILD='$(CXX)'          AC_SUBST(CXX_FOR_BUILD)
2076 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
2077 BUILD_CXXFLAGS='$(ALL_CXXFLAGS)' AC_SUBST(BUILD_CXXFLAGS)
2078 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
2079 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
2080
2081 BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS)' AC_SUBST(BUILD_NO_PIE_CFLAGS)
2082 BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG)' AC_SUBST(BUILD_NO_PIE_FLAG)
2083
2084 # And these apply if build != host, or we are generating coverage data
2085 if test x$build != x$host || test "x$coverage_flags" != x
2086 then
2087     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
2088     BUILD_CXXFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CXXFLAGS_FOR_BUILD)'
2089     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
2090
2091     NO_PIE_CFLAGS_FOR_BUILD=${NO_PIE_CFLAGS_FOR_BUILD-${NO_PIE_CFLAGS}}
2092     NO_PIE_FLAG_FOR_BUILD=${NO_PIE_FLAG_FOR_BUILD-${NO_PIE_FLAG}}
2093     BUILD_NO_PIE_CFLAGS='$(NO_PIE_CFLAGS_FOR_BUILD)'
2094     BUILD_NO_PIE_FLAG='$(NO_PIE_FLAG_FOR_BUILD)'
2095 fi
2096 AC_SUBST(NO_PIE_CFLAGS_FOR_BUILD)
2097 AC_SUBST(NO_PIE_FLAG_FOR_BUILD)
2098
2099 # Expand extra_headers to include complete path.
2100 # This substitutes for lots of t-* files.
2101 extra_headers_list=
2102 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
2103 for file in ${extra_headers} ; do
2104   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
2105 done
2106
2107 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
2108 if test x"$use_gcc_tgmath" = xyes
2109 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
2110 fi
2111
2112 # Define collect2 in Makefile.
2113 case $host_can_use_collect2 in
2114   no) collect2= ;;
2115   *) collect2='collect2$(exeext)' ;;
2116 esac
2117 AC_SUBST([collect2])
2118
2119 # Add a definition of USE_COLLECT2 if system wants one.
2120 case $use_collect2 in
2121   no) use_collect2= ;;
2122   "") ;;
2123   *)
2124     host_xm_defines="${host_xm_defines} USE_COLLECT2"
2125     xm_defines="${xm_defines} USE_COLLECT2"
2126     case $host_can_use_collect2 in
2127       no)
2128         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
2129         ;;
2130     esac
2131     ;;
2132 esac
2133
2134 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
2135 [Define to the name of the LTO plugin DSO that must be
2136   passed to the linker's -plugin=LIB option.])
2137
2138 # ---------------------------
2139 # Assembler & linker features
2140 # ---------------------------
2141
2142 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
2143 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
2144 # However when ld-new is first executed from the build tree, libtool will
2145 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
2146 # to the build tree.  While doing this we need to use the previous-stage
2147 # linker, or we have an infinite loop.  The presence of a shell script as
2148 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
2149 # the gcc/collect-ld script.  So we need to know how libtool works, or
2150 # exec-tool will fail.
2151
2152 m4_defun([_LT_CONFIG_COMMANDS], [])
2153 AC_PROG_LIBTOOL
2154 AC_SUBST(objdir)
2155 AC_SUBST(enable_fast_install)
2156
2157 # Identify the assembler which will work hand-in-glove with the newly
2158 # built GCC, so that we can examine its features.  This is the assembler
2159 # which will be driven by the driver program.
2160 #
2161 # If build != host, and we aren't building gas in-tree, we identify a
2162 # build->target assembler and hope that it will have the same features
2163 # as the host->target assembler we'll be using.
2164 gcc_cv_gas_major_version=
2165 gcc_cv_gas_minor_version=
2166 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
2167
2168 m4_pattern_allow([AS_FOR_TARGET])dnl
2169 AS_VAR_SET_IF(gcc_cv_as,, [
2170 if test -x "$DEFAULT_ASSEMBLER"; then
2171         gcc_cv_as="$DEFAULT_ASSEMBLER"
2172 elif test -f $gcc_cv_as_gas_srcdir/configure.ac \
2173      && test -f ../gas/Makefile \
2174      && test x$build = x$host; then
2175         gcc_cv_as=../gas/as-new$build_exeext
2176 elif test -x as$build_exeext; then
2177         # Build using assembler in the current directory.
2178         gcc_cv_as=./as$build_exeext
2179 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
2180         gcc_cv_as="$AS_FOR_TARGET"
2181 else
2182         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
2183 fi])
2184
2185 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
2186 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
2187 case "$ORIGINAL_AS_FOR_TARGET" in
2188   ./as | ./as$build_exeext) ;;
2189   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
2190 esac
2191
2192 AC_MSG_CHECKING(what assembler to use)
2193 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
2194   # Single tree build which includes gas.  We want to prefer it
2195   # over whatever linker top-level may have detected, since
2196   # we'll use what we're building after installation anyway.
2197   AC_MSG_RESULT(newly built gas)
2198   in_tree_gas=yes
2199   _gcc_COMPUTE_GAS_VERSION
2200   in_tree_gas_is_elf=no
2201   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
2202      || (grep 'obj_format = multi' ../gas/Makefile \
2203          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
2204   then
2205     in_tree_gas_is_elf=yes
2206   fi
2207 else
2208   AC_MSG_RESULT($gcc_cv_as)
2209   in_tree_gas=no
2210 fi
2211
2212 default_ld=
2213 AC_ARG_ENABLE(ld,
2214 [[  --enable-ld[=ARG]       build ld [ARG={default,yes,no}]]],
2215 [case "${enableval}" in
2216  no)
2217    default_ld=ld.gold
2218    ;;
2219  esac])
2220
2221 install_gold_as_default=no
2222 AC_ARG_ENABLE(gold,
2223 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
2224 [case "${enableval}" in
2225  default)
2226    install_gold_as_default=yes
2227    ;;
2228  yes)
2229    if test x${default_ld} != x; then
2230      install_gold_as_default=yes
2231    fi
2232    ;;
2233  no)
2234    ;;
2235  *)
2236    AC_MSG_ERROR([invalid --enable-gold argument])
2237    ;;
2238  esac])
2239
2240 # Identify the linker which will work hand-in-glove with the newly
2241 # built GCC, so that we can examine its features.  This is the linker
2242 # which will be driven by the driver program.
2243 #
2244 # If build != host, and we aren't building gas in-tree, we identify a
2245 # build->target linker and hope that it will have the same features
2246 # as the host->target linker we'll be using.
2247 gcc_cv_gld_major_version=
2248 gcc_cv_gld_minor_version=
2249 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
2250 gcc_cv_ld_gold_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gold
2251 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
2252
2253 AS_VAR_SET_IF(gcc_cv_ld,, [
2254 if test -x "$DEFAULT_LINKER"; then
2255         gcc_cv_ld="$DEFAULT_LINKER"
2256 elif test $install_gold_as_default = yes \
2257      && test -f $gcc_cv_ld_gold_srcdir/configure.ac \
2258      && test -f ../gold/Makefile \
2259      && test x$build = x$host; then
2260         gcc_cv_ld=../gold/ld-new$build_exeext
2261 elif test -f $gcc_cv_ld_gld_srcdir/configure.ac \
2262      && test -f ../ld/Makefile \
2263      && test x$build = x$host; then
2264         gcc_cv_ld=../ld/ld-new$build_exeext
2265 elif test -x collect-ld$build_exeext; then
2266         # Build using linker in the current directory.
2267         gcc_cv_ld=./collect-ld$build_exeext
2268 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
2269         gcc_cv_ld="$LD_FOR_TARGET"
2270 else
2271         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
2272 fi])
2273
2274 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
2275 PLUGIN_LD_SUFFIX=`basename $gcc_cv_ld | sed -e "s,$target_alias-,,"`
2276 # if the PLUGIN_LD is set ld-new, just have it as ld
2277 # as that is the installed named.
2278 if test x$PLUGIN_LD_SUFFIX = xld-new \
2279    || test x$PLUGIN_LD_SUFFIX = xcollect-ld ; then
2280   PLUGIN_LD_SUFFIX=ld
2281 fi
2282 AC_ARG_WITH(plugin-ld,
2283 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
2284 [if test x"$withval" != x; then
2285    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
2286    PLUGIN_LD_SUFFIX="$withval"
2287  fi])
2288 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
2289 AC_DEFINE_UNQUOTED(PLUGIN_LD_SUFFIX, "$PLUGIN_LD_SUFFIX", [Specify plugin linker])
2290
2291 # Check to see if we are using gold instead of ld
2292 AC_MSG_CHECKING(whether we are using gold)
2293 ld_is_gold=no
2294 if test x$gcc_cv_ld != x; then
2295   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
2296      | grep "GNU gold" > /dev/null; then
2297     ld_is_gold=yes
2298   fi
2299 fi
2300 AC_MSG_RESULT($ld_is_gold)
2301
2302 AC_MSG_CHECKING(gold linker with split stack support as non default)
2303 # Check to see if default ld is not gold, but gold is
2304 # available and has support for split stack.  If gcc was configured
2305 # with gold then no checking is done.
2306 #
2307 if test x$ld_is_gold = xno && which ${gcc_cv_ld}.gold >/dev/null 2>&1; then
2308
2309 # For platforms other than powerpc64*, enable as appropriate.
2310
2311   gold_non_default=no
2312   ld_gold=`which ${gcc_cv_ld}.gold`
2313 # Make sure this gold has minimal split stack support
2314   if $ld_gold --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
2315     ld_vers=`$ld_gold --version | sed 1q`
2316     gold_vers=`echo $ld_vers | sed -n \
2317           -e 's,^[[^)]]*[[  ]]\([[0-9]][[0-9]]*\.[[0-9]][[0-9]]*[[^)]]*\)) .*$,\1,p'`
2318     case $target in
2319 # check that the gold version contains the complete split stack support
2320 # on powerpc64 big and little endian
2321       powerpc64*-*-*)
2322         case "$gold_vers" in
2323           2.25.[[1-9]]*|2.2[[6-9]][[.0-9]]*|2.[[3-9]][[.0-9]]*|[[3-9]].[[.0-9]]*) gold_non_default=yes
2324           ;;
2325           *) gold_non_default=no
2326           ;;
2327         esac
2328         ;;
2329     esac
2330   fi
2331   if test $gold_non_default = yes; then
2332     AC_DEFINE(HAVE_GOLD_NON_DEFAULT_SPLIT_STACK, 1,
2333             [Define if the gold linker supports split stack and is available as a non-default])
2334   fi
2335 fi
2336 AC_MSG_RESULT($gold_non_default)
2337
2338 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
2339 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
2340 case "$ORIGINAL_LD_FOR_TARGET" in
2341   ./collect-ld | ./collect-ld$build_exeext) ;;
2342   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
2343 esac
2344
2345 AC_MSG_CHECKING(what linker to use)
2346 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
2347    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
2348         # Single tree build which includes ld.  We want to prefer it
2349         # over whatever linker top-level may have detected, since
2350         # we'll use what we're building after installation anyway.
2351         AC_MSG_RESULT(newly built ld)
2352         in_tree_ld=yes
2353         in_tree_ld_is_elf=no
2354         if (grep 'EMUL = .*elf' ../ld/Makefile \
2355             || grep 'EMUL = .*linux' ../ld/Makefile \
2356             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2357           in_tree_ld_is_elf=yes
2358         elif test "$ld_is_gold" = yes; then
2359           in_tree_ld_is_elf=yes
2360         fi
2361         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.ac $gcc_cv_ld_gld_srcdir/Makefile.in
2362         do
2363 changequote(,)dnl
2364                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*VERSION=[^0-9A-Za-z_]*\([0-9]*\.[0-9]*.*\)/VERSION=\1/p' < $f`
2365                 if test x$gcc_cv_gld_version != x; then
2366                         break
2367                 fi
2368         done
2369         case $gcc_cv_gld_version in
2370           VERSION=[0-9]*) ;;
2371 changequote([,])dnl
2372           *) AC_MSG_ERROR([[cannot find version of in-tree linker]]) ;;
2373 changequote(,)dnl
2374         esac
2375         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2376         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2377 changequote([,])dnl
2378         ORIGINAL_LD_BFD_FOR_TARGET=../ld/ld-new$build_exeext
2379         ORIGINAL_LD_GOLD_FOR_TARGET=../gold/ld-new$build_exeext
2380 else
2381         AC_MSG_RESULT($gcc_cv_ld)
2382         in_tree_ld=no
2383         gcc_cvs_ld_program=`dirname $gcc_cv_ld`/`basename $gcc_cv_ld $host_exeext`
2384         ORIGINAL_LD_BFD_FOR_TARGET=${gcc_cvs_ld_program}.bfd$host_exeext
2385         ORIGINAL_LD_GOLD_FOR_TARGET=${gcc_cvs_ld_program}.gold$host_exeext
2386 fi
2387
2388 AC_SUBST(ORIGINAL_LD_BFD_FOR_TARGET)
2389 AC_SUBST(ORIGINAL_LD_GOLD_FOR_TARGET)
2390
2391 # Figure out what nm we will be using.
2392 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2393 AS_VAR_SET_IF(gcc_cv_nm,, [
2394 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2395      && test -f ../binutils/Makefile \
2396      && test x$build = x$host; then
2397         gcc_cv_nm=../binutils/nm-new$build_exeext
2398 elif test -x nm$build_exeext; then
2399         gcc_cv_nm=./nm$build_exeext
2400 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2401         gcc_cv_nm="$NM_FOR_TARGET"
2402 else
2403         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2404 fi])
2405
2406 AC_MSG_CHECKING(what nm to use)
2407 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2408         # Single tree build which includes binutils.
2409         AC_MSG_RESULT(newly built nm)
2410         in_tree_nm=yes
2411 else
2412         AC_MSG_RESULT($gcc_cv_nm)
2413         in_tree_nm=no
2414 fi
2415
2416 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2417 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2418 case "$ORIGINAL_NM_FOR_TARGET" in
2419   ./nm | ./nm$build_exeext) ;;
2420   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2421 esac
2422
2423
2424 # Figure out what objdump we will be using.
2425 AS_VAR_SET_IF(gcc_cv_objdump,, [
2426 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2427      && test -f ../binutils/Makefile \
2428      && test x$build = x$host; then
2429         # Single tree build which includes binutils.
2430         gcc_cv_objdump=../binutils/objdump$build_exeext
2431 elif test -x objdump$build_exeext; then
2432         gcc_cv_objdump=./objdump$build_exeext
2433 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2434         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2435 else
2436         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2437 fi])
2438
2439 AC_MSG_CHECKING(what objdump to use)
2440 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2441         # Single tree build which includes binutils.
2442         AC_MSG_RESULT(newly built objdump)
2443 elif test x$gcc_cv_objdump = x; then
2444         AC_MSG_RESULT(not found)
2445 else
2446         AC_MSG_RESULT($gcc_cv_objdump)
2447 fi
2448
2449 # Figure out what readelf we will be using.
2450 AS_VAR_SET_IF(gcc_cv_readelf,, [
2451 if test -f $gcc_cv_binutils_srcdir/configure.ac \
2452      && test -f ../binutils/Makefile \
2453      && test x$build = x$host; then
2454         # Single tree build which includes binutils.
2455         gcc_cv_readelf=../binutils/readelf$build_exeext
2456 elif test -x readelf$build_exeext; then
2457         gcc_cv_readelf=./readelf$build_exeext
2458 elif ( set dummy $READELF_FOR_TARGET; test -x $[2] ); then
2459         gcc_cv_readelf="$READELF_FOR_TARGET"
2460 else
2461         AC_PATH_PROG(gcc_cv_readelf, $READELF_FOR_TARGET)
2462 fi])
2463
2464 AC_MSG_CHECKING(what readelf to use)
2465 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2466         # Single tree build which includes binutils.
2467         AC_MSG_RESULT(newly built readelf)
2468 elif test x$gcc_cv_readelf = x; then
2469         AC_MSG_RESULT(not found)
2470 else
2471         AC_MSG_RESULT($gcc_cv_readelf)
2472 fi
2473
2474 # Figure out what assembler alignment features are present.
2475 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2476  [2,6,0],,
2477 [.balign 4
2478 .p2align 2],,
2479 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2480   [Define if your assembler supports .balign and .p2align.])])
2481
2482 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2483  [2,8,0],,
2484  [.p2align 4,,7],,
2485 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2486   [Define if your assembler supports specifying the maximum number
2487    of bytes to skip when using the GAS .p2align command.])])
2488
2489 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2490  [2,8,0],,
2491  [.literal16],,
2492 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2493   [Define if your assembler supports .literal16.])])
2494
2495 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2496  [elf,2,9,0],,
2497  [conftest_label1: .word 0
2498 .subsection -1
2499 conftest_label2: .word 0
2500 .previous],
2501  [if test x$gcc_cv_nm != x; then
2502     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2503     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2504     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2505     then :
2506     else gcc_cv_as_subsection_m1=yes
2507     fi
2508     rm -f conftest.nm1 conftest.nm2
2509   fi],
2510  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2511   [Define if your assembler supports .subsection and .subsection -1 starts
2512    emitting at the beginning of your section.])])
2513
2514 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2515  [2,2,0],,
2516  [      .weak foobar],,
2517 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2518
2519 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2520  [2,17,0],,
2521  [      .weakref foobar, barfnot],,
2522 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2523
2524 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2525  [2,15,91],,
2526  [      .SPACE $TEXT$
2527         .NSUBSPA $CODE$,COMDAT],,
2528 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2529
2530 # .hidden needs to be supported in both the assembler and the linker,
2531 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2532 # This is irritatingly difficult to feature test for; we have to check the
2533 # date string after the version number.  If we've got an in-tree
2534 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2535 # to be safe.
2536 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2537 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2538  [elf,2,13,0],,
2539 [       .hidden foobar
2540 foobar:])
2541 case "${target}" in
2542   *-*-darwin*)
2543     # Darwin as has some visibility support, though with a different syntax.
2544     gcc_cv_as_hidden=yes
2545     ;;
2546 esac
2547
2548 # gnu_indirect_function type is an extension proposed at
2549 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2550 # selection of function implementation
2551 AC_ARG_ENABLE(gnu-indirect-function,
2552  [AS_HELP_STRING([--enable-gnu-indirect-function],
2553                  [enable the use of the @gnu_indirect_function to glibc systems])],
2554  [case $enable_gnu_indirect_function in
2555     yes | no) ;;
2556     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2557 Valid choices are 'yes' and 'no'.]) ;;
2558   esac],
2559  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2560
2561 gif=`if test x$enable_gnu_indirect_function = xyes; then echo 1; else echo 0; fi`
2562 AC_DEFINE_UNQUOTED(HAVE_GNU_INDIRECT_FUNCTION, $gif,
2563 [Define if your system supports gnu indirect functions.])
2564
2565
2566 changequote(,)dnl
2567 if test $in_tree_ld != yes ; then
2568   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2569   if echo "$ld_ver" | grep GNU > /dev/null; then
2570     if test x"$ld_is_gold" = xyes; then
2571       # GNU gold --version looks like this:
2572       #
2573       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2574       #
2575       # We extract the binutils version which is more familiar and specific
2576       # than the gold version.
2577       ld_vers=`echo $ld_ver | sed -n \
2578           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2579     else
2580       # GNU ld --version looks like this:
2581       #
2582       # GNU ld (GNU Binutils) 2.21.51.20110225
2583       ld_vers=`echo $ld_ver | sed -n \
2584           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2585     fi
2586     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2587     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2588     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2589     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2590   else
2591     case "${target}" in
2592       *-*-solaris2*)
2593         # See acinclude.m4 (gcc_SUN_LD_VERSION) for the version number
2594         # format.
2595         #
2596         # Don't reuse gcc_gv_sun_ld_vers_* in case a linker other than
2597         # /usr/ccs/bin/ld has been configured.
2598         ld_ver=`$gcc_cv_ld -V 2>&1`
2599         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2600           ld_vers=`echo $ld_ver | sed -n \
2601             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2602           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2603           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2604         fi
2605         ;;
2606     esac
2607   fi
2608 fi
2609 changequote([,])dnl
2610
2611 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2612 [[if test $in_tree_ld = yes ; then
2613   gcc_cv_ld_hidden=no
2614   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2615      && test $in_tree_ld_is_elf = yes; then
2616      gcc_cv_ld_hidden=yes
2617   fi
2618 else
2619   gcc_cv_ld_hidden=yes
2620   if test x"$ld_is_gold" = xyes; then
2621     :
2622   elif echo "$ld_ver" | grep GNU > /dev/null; then
2623     case "${target}" in
2624       mmix-knuth-mmixware)
2625         # The linker emits by default mmo, not ELF, so "no" is appropriate.
2626         gcc_cv_ld_hidden=no
2627         ;;
2628     esac
2629     if test 0"$ld_date" -lt 20020404; then
2630       if test -n "$ld_date"; then
2631         # If there was date string, but was earlier than 2002-04-04, fail
2632         gcc_cv_ld_hidden=no
2633       elif test -z "$ld_vers"; then
2634         # If there was no date string nor ld version number, something is wrong
2635         gcc_cv_ld_hidden=no
2636       else
2637         test -z "$ld_vers_patch" && ld_vers_patch=0
2638         if test "$ld_vers_major" -lt 2; then
2639           gcc_cv_ld_hidden=no
2640         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2641           gcc_cv_ld_hidden="no"
2642         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2643           gcc_cv_ld_hidden=no
2644         fi
2645       fi
2646     fi
2647   else
2648     case "${target}" in
2649       *-*-darwin*)
2650         # Darwin ld has some visibility support.
2651         gcc_cv_ld_hidden=yes
2652         ;;
2653       hppa64*-*-hpux* | ia64*-*-hpux*)
2654         gcc_cv_ld_hidden=yes
2655         ;;
2656       *-*-solaris2.1[0-9]*)
2657         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2658         # .symbolic was only added in Solaris 9 12/02.
2659         gcc_cv_ld_hidden=yes
2660         ;;
2661       *)
2662         gcc_cv_ld_hidden=no
2663         ;;
2664     esac
2665   fi
2666 fi]])
2667 libgcc_visibility=no
2668 AC_SUBST(libgcc_visibility)
2669 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2670 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2671   libgcc_visibility=yes
2672   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2673   [Define if your assembler and linker support .hidden.])
2674 fi
2675
2676 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2677 gcc_cv_ld_ro_rw_mix=unknown
2678 if test $in_tree_ld = yes ; then
2679   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2680      && test $in_tree_ld_is_elf = yes; then
2681     gcc_cv_ld_ro_rw_mix=read-write
2682   fi
2683 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2684   echo '.section myfoosect, "a"' > conftest1.s
2685   echo '.section myfoosect, "aw"' > conftest2.s
2686   echo '.byte 1' >> conftest2.s
2687   echo '.section myfoosect, "a"' > conftest3.s
2688   echo '.byte 0' >> conftest3.s
2689   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2690      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2691      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2692      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2693         conftest2.o conftest3.o > /dev/null 2>&1; then
2694     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2695                          | sed -e '/myfoosect/!d' -e N`
2696     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2697       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2698         gcc_cv_ld_ro_rw_mix=read-only
2699       else
2700         gcc_cv_ld_ro_rw_mix=read-write
2701       fi
2702     fi
2703   fi
2704 changequote(,)dnl
2705   rm -f conftest.* conftest[123].*
2706 changequote([,])dnl
2707 fi
2708 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2709         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2710   [Define if your linker links a mix of read-only
2711    and read-write sections into a read-write section.])
2712 fi
2713 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2714
2715 gcc_AC_INITFINI_ARRAY
2716
2717 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2718 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2719   [elf,2,11,0],,
2720 [       .data
2721         .uleb128 L2 - L1
2722 L1:
2723         .uleb128 1280
2724         .sleb128 -1010
2725 L2:],
2726 [[# GAS versions before 2.11 do not support uleb128,
2727   # despite appearing to.
2728   # ??? There exists an elf-specific test that will crash
2729   # the assembler.  Perhaps it's better to figure out whether
2730   # arbitrary sections are supported and try the test.
2731   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2732   if echo "$as_ver" | grep GNU > /dev/null; then
2733     as_vers=`echo $as_ver | sed -n \
2734         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2735     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2736     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2737     if test $as_major -eq 2 && test $as_minor -lt 11
2738     then :
2739     else gcc_cv_as_leb128=yes
2740     fi
2741   fi]],
2742   [AC_DEFINE(HAVE_AS_LEB128, 1,
2743     [Define if your assembler supports .sleb128 and .uleb128.])])
2744
2745 # Check if we have assembler support for unwind directives.
2746 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2747   ,,
2748 [       .text
2749         .cfi_startproc
2750         .cfi_offset 0, 0
2751         .cfi_same_value 1
2752         .cfi_def_cfa 1, 2
2753         .cfi_escape 1, 2, 3, 4, 5
2754         .cfi_endproc],
2755 [case "$target" in
2756   *-*-solaris*)
2757     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2758     # read-only and read-write sections, we need to make sure that the
2759     # assembler used emits read-write .eh_frame sections.
2760     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2761       if test "x$gcc_cv_objdump" != x; then
2762         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2763                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2764           gcc_cv_as_cfi_directive=no
2765         else
2766           case "$target" in
2767             i?86-*-solaris2.1[[0-9]]* | x86_64-*-solaris2.1[[0-9]]*)
2768               # On Solaris/x86, make sure that GCC and assembler agree on using
2769               # read-only .eh_frame sections for 64-bit.
2770               if test x$gas = xyes; then
2771                  as_ix86_64_opt="--64"
2772               else
2773                  as_ix86_64_opt="-xarch=amd64"
2774               fi
2775               if $gcc_cv_as $as_ix86_64_opt -o conftest.o conftest.s > /dev/null 2>&1 && \
2776                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2777                         sed -e /.eh_frame/!d -e N | \
2778                         grep READONLY > /dev/null; then
2779                 gcc_cv_as_cfi_directive=yes
2780               else
2781                 gcc_cv_as_cfi_directive=no
2782               fi
2783               ;;
2784             *)
2785               gcc_cv_as_cfi_directive=yes
2786               ;;
2787           esac
2788         fi
2789       else
2790         # no objdump, err on the side of caution
2791         gcc_cv_as_cfi_directive=no
2792       fi
2793     else
2794       gcc_cv_as_cfi_directive=yes
2795     fi
2796     ;;
2797   *-*-*)
2798     gcc_cv_as_cfi_directive=yes
2799     ;;
2800 esac])
2801 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2802 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2803   ,,
2804 [       .text
2805         .cfi_startproc
2806         .cfi_adjust_cfa_offset 64
2807         .skip 75040, 0
2808         .cfi_adjust_cfa_offset 128
2809         .cfi_endproc],
2810 [[
2811 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2812     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2813    gcc_cv_as_cfi_advance_working=yes
2814 fi
2815 ]])
2816 else
2817   # no objdump, err on the side of caution
2818   gcc_cv_as_cfi_advance_working=no
2819 fi
2820 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2821 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2822   [`if test $gcc_cv_as_cfi_directive = yes \
2823        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2824   [Define 0/1 if your assembler supports CFI directives.])
2825
2826 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2827 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2828   gcc_cv_as_cfi_personality_directive, ,,
2829 [       .text
2830         .cfi_startproc
2831         .cfi_personality 0, symbol
2832         .cfi_endproc])
2833 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2834   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2835     then echo 1; else echo 0; fi`],
2836   [Define 0/1 if your assembler supports .cfi_personality.])
2837
2838 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2839   gcc_cv_as_cfi_sections_directive, ,,
2840 [       .text
2841         .cfi_sections .debug_frame, .eh_frame
2842         .cfi_startproc
2843         .cfi_endproc],
2844 [case $target_os in
2845   win32 | pe | cygwin* | mingw32*)
2846     # Need to check that we generated the correct relocation for the
2847     # .debug_frame section.  This was fixed for binutils 2.21.
2848     gcc_cv_as_cfi_sections_directive=no
2849     if test "x$gcc_cv_objdump" != x; then
2850      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2851         grep secrel > /dev/null; then
2852       gcc_cv_as_cfi_sections_directive=yes
2853      fi
2854     fi
2855     ;;
2856   *)
2857     gcc_cv_as_cfi_sections_directive=yes
2858     ;;
2859 esac])
2860 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2861 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2862   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2863     then echo 1; else echo 0; fi`],
2864   [Define 0/1 if your assembler supports .cfi_sections.])
2865
2866 # GAS versions up to and including 2.11.0 may mis-optimize
2867 # .eh_frame data.
2868 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2869   [elf,2,12,0],,
2870 [       .text
2871 .LFB1:
2872         .4byte  0
2873 .L1:
2874         .4byte  0
2875 .LFE1:
2876         .section        .eh_frame,"aw",@progbits
2877 __FRAME_BEGIN__:
2878         .4byte  .LECIE1-.LSCIE1
2879 .LSCIE1:
2880         .4byte  0x0
2881         .byte   0x1
2882         .ascii "z\0"
2883         .byte   0x1
2884         .byte   0x78
2885         .byte   0x1a
2886         .byte   0x0
2887         .byte   0x4
2888         .4byte  1
2889         .p2align 1
2890 .LECIE1:
2891 .LSFDE1:
2892         .4byte  .LEFDE1-.LASFDE1
2893 .LASFDE1:
2894         .4byte  .LASFDE1-__FRAME_BEGIN__
2895         .4byte  .LFB1
2896         .4byte  .LFE1-.LFB1
2897         .byte   0x4
2898         .4byte  .LFE1-.LFB1
2899         .byte   0x4
2900         .4byte  .L1-.LFB1
2901 .LEFDE1:],
2902 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2903 cat > conftest.lit <<EOF
2904  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2905  0010 01000000 12000000 18000000 00000000  ................
2906  0020 08000000 04080000 0044               .........D      @&t@
2907 EOF
2908 cat > conftest.big <<EOF
2909  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2910  0010 00000001 00000012 00000018 00000000  ................
2911  0020 00000008 04000000 0844               .........D      @&t@
2912 EOF
2913   # If the assembler didn't choke, and we can objdump,
2914   # and we got the correct data, then succeed.
2915   # The text in the here-document typically retains its unix-style line
2916   # endings, while the output of objdump will use host line endings.
2917   # Therefore, use diff -b for the comparisons.
2918   if test x$gcc_cv_objdump != x \
2919   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2920      | tail -3 > conftest.got \
2921   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2922     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2923   then
2924     gcc_cv_as_eh_frame=yes
2925   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2926     gcc_cv_as_eh_frame=buggy
2927   else
2928     # Uh oh, what do we do now?
2929     gcc_cv_as_eh_frame=no
2930   fi])
2931
2932 if test $gcc_cv_as_eh_frame = buggy; then
2933   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2934   [Define if your assembler mis-optimizes .eh_frame data.])
2935 fi
2936
2937 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2938  [elf,2,12,0], [--fatal-warnings],
2939  [.section .rodata.str, "aMS", @progbits, 1])
2940 if test $gcc_cv_as_shf_merge = no; then
2941   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2942     [elf,2,12,0], [--fatal-warnings],
2943     [.section .rodata.str, "aMS", %progbits, 1])
2944 fi
2945 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2946   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2947 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2948
2949 gcc_GAS_CHECK_FEATURE([stabs directive], gcc_cv_as_stabs_directive, ,,
2950 [.stabs "gcc2_compiled.",60,0,0,0],,
2951 [AC_DEFINE(HAVE_AS_STABS_DIRECTIVE, 1,
2952   [Define if your assembler supports .stabs.])])
2953
2954 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2955  gcc_cv_as_comdat_group,
2956  [elf,2,16,0], [--fatal-warnings],
2957  [.section .text,"axG",@progbits,.foo,comdat])
2958 if test $gcc_cv_as_comdat_group = yes; then
2959   gcc_cv_as_comdat_group_percent=no
2960   gcc_cv_as_comdat_group_group=no
2961 else
2962  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2963    gcc_cv_as_comdat_group_percent,
2964    [elf,2,16,0], [--fatal-warnings],
2965    [.section .text,"axG",%progbits,.foo,comdat])
2966  if test $gcc_cv_as_comdat_group_percent = yes; then
2967    gcc_cv_as_comdat_group_group=no
2968  else
2969    case "${target}" in
2970      # Sun as uses a completely different syntax.
2971      *-*-solaris2*)
2972        case "${target}" in
2973          sparc*-*-solaris2*)
2974            conftest_s='
2975                .group foo,".text%foo",#comdat
2976                .section ".text%foo", #alloc,#execinstr,#progbits
2977                .globl foo
2978              foo:
2979              '
2980            ;;
2981          i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
2982            conftest_s='
2983                .group foo,.text%foo,#comdat
2984                .section .text%foo, "ax", @progbits
2985                .globl  foo
2986              foo:
2987              '
2988            ;;
2989        esac
2990        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2991          gcc_cv_as_comdat_group_group,
2992          ,, [$conftest_s])
2993        ;;
2994    esac
2995    if test -z "${gcc_cv_as_comdat_group_group+set}"; then
2996      gcc_cv_as_comdat_group_group=no
2997    fi
2998  fi
2999 fi
3000 if test x"$ld_is_gold" = xyes; then
3001   comdat_group=yes
3002 elif test $in_tree_ld = yes ; then
3003   comdat_group=no
3004   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3005      && test $in_tree_ld_is_elf = yes; then
3006      comdat_group=yes
3007   fi
3008 elif echo "$ld_ver" | grep GNU > /dev/null; then
3009   comdat_group=yes
3010   if test 0"$ld_date" -lt 20050308; then
3011     if test -n "$ld_date"; then
3012       # If there was date string, but was earlier than 2005-03-08, fail
3013       comdat_group=no
3014     elif test "$ld_vers_major" -lt 2; then
3015       comdat_group=no
3016     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
3017       comdat_group=no
3018     fi
3019   fi
3020 else
3021 changequote(,)dnl
3022   case "${target}" in
3023     *-*-solaris2.1[1-9]*)
3024       comdat_group=no
3025       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
3026       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
3027       # version 1.688.
3028       #
3029       # If using Sun as for COMDAT group as emitted by GCC, one needs at
3030       # least ld version 1.2267.
3031       if test "$ld_vers_major" -gt 1; then
3032         comdat_group=yes
3033       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
3034         comdat_group=yes
3035       elif test "$ld_vers_minor" -ge 2267; then
3036         comdat_group=yes
3037       fi
3038       ;;
3039     *)
3040       # Assume linkers other than GNU ld don't support COMDAT group.
3041       comdat_group=no
3042       ;;
3043   esac
3044 changequote([,])dnl
3045 fi
3046 # Allow overriding the automatic COMDAT group tests above.
3047 AC_ARG_ENABLE(comdat,
3048   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
3049   [comdat_group="$enable_comdat"])
3050 if test $comdat_group = no; then
3051   gcc_cv_as_comdat_group=no
3052   gcc_cv_as_comdat_group_percent=no
3053   gcc_cv_as_comdat_group_group=no
3054 fi
3055 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
3056   [`if test $gcc_cv_as_comdat_group = yes \
3057     || test $gcc_cv_as_comdat_group_percent = yes \
3058     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
3059 [Define 0/1 if your assembler and linker support COMDAT groups.])
3060
3061 gcc_GAS_CHECK_FEATURE([line table discriminator support],
3062  gcc_cv_as_discriminator,
3063  [2,19,51],,
3064 [       .text
3065         .file 1 "conf.c"
3066         .loc 1 1 0 discriminator 1],,
3067 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
3068   [Define if your assembler supports the .loc discriminator sub-directive.])])
3069
3070 # Thread-local storage - the check is heavily parameterized.
3071 conftest_s=
3072 tls_first_major=
3073 tls_first_minor=
3074 tls_as_opt=
3075 case "$target" in
3076 changequote(,)dnl
3077   alpha*-*-*)
3078     conftest_s='
3079         .section ".tdata","awT",@progbits
3080 foo:    .long   25
3081         .text
3082         ldq     $27,__tls_get_addr($29)         !literal!1
3083         lda     $16,foo($29)                    !tlsgd!1
3084         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
3085         ldq     $27,__tls_get_addr($29)         !literal!2
3086         lda     $16,foo($29)                    !tlsldm!2
3087         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
3088         ldq     $1,foo($29)                     !gotdtprel
3089         ldah    $2,foo($29)                     !dtprelhi
3090         lda     $3,foo($2)                      !dtprello
3091         lda     $4,foo($29)                     !dtprel
3092         ldq     $1,foo($29)                     !gottprel
3093         ldah    $2,foo($29)                     !tprelhi
3094         lda     $3,foo($2)                      !tprello
3095         lda     $4,foo($29)                     !tprel'
3096         tls_first_major=2
3097         tls_first_minor=13
3098         tls_as_opt=--fatal-warnings
3099         ;;
3100   arc*-*-*)
3101     conftest_s='
3102         add_s r0,r0, @foo@tpoff'
3103         tls_first_major=2
3104         tls_first_minor=23
3105         ;;
3106   cris-*-*|crisv32-*-*)
3107     conftest_s='
3108         .section ".tdata","awT",@progbits
3109 x:      .long   25
3110         .text
3111         move.d x:IE,$r10
3112         nop'
3113         tls_first_major=2
3114         tls_first_minor=20
3115         tls_as_opt=--fatal-warnings
3116         ;;
3117   frv*-*-*)
3118     conftest_s='
3119         .section ".tdata","awT",@progbits
3120 x:      .long   25
3121         .text
3122         call    #gettlsoff(x)'
3123         tls_first_major=2
3124         tls_first_minor=14
3125         ;;
3126   hppa*-*-linux*)
3127     conftest_s='
3128 t1:     .reg    %r20
3129 t2:     .reg    %r21
3130 gp:     .reg    %r19
3131         .section ".tdata","awT",@progbits
3132 foo:    .long   25
3133         .text
3134         .align  4
3135         addil LT%foo-$tls_gdidx$,gp
3136         ldo RT%foo-$tls_gdidx$(%r1),%arg0
3137         b __tls_get_addr
3138         nop
3139         addil LT%foo-$tls_ldidx$,gp
3140         b __tls_get_addr
3141         ldo RT%foo-$tls_ldidx$(%r1),%arg0
3142         addil LR%foo-$tls_dtpoff$,%ret0
3143         ldo RR%foo-$tls_dtpoff$(%r1),%t1
3144         mfctl %cr27,%t1
3145         addil LT%foo-$tls_ieoff$,gp
3146         ldw RT%foo-$tls_ieoff$(%r1),%t2
3147         add %t1,%t2,%t3
3148         mfctl %cr27,%t1
3149         addil LR%foo-$tls_leoff$,%t1
3150         ldo RR%foo-$tls_leoff$(%r1),%t2'
3151         tls_first_major=2
3152         tls_first_minor=15
3153         tls_as_opt=--fatal-warnings
3154         ;;
3155   arm*-*-*)
3156     conftest_s='
3157         .section ".tdata","awT",%progbits
3158 foo:    .long   25
3159         .text
3160 .word foo(gottpoff)
3161 .word foo(tpoff)
3162 .word foo(tlsgd)
3163 .word foo(tlsldm)
3164 .word foo(tlsldo)'
3165         tls_first_major=2
3166         tls_first_minor=17
3167         ;;
3168   i[34567]86-*-* | x86_64-*-*)
3169     case "$target" in
3170       i[34567]86-*-solaris2.* | x86_64-*-solaris2.1[0-9]*)
3171         on_solaris=yes
3172         ;;
3173       *)
3174         on_solaris=no
3175         ;;
3176     esac
3177     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3178       conftest_s='
3179         .section .tdata,"awt",@progbits'
3180       tls_first_major=0
3181       tls_first_minor=0
3182       tls_section_flag=t
3183 changequote([,])dnl
3184       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
3185 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
3186 changequote(,)dnl
3187     else
3188       conftest_s='
3189         .section ".tdata","awT",@progbits'
3190       tls_first_major=2
3191       tls_first_minor=14
3192       tls_section_flag=T
3193       tls_as_opt="--fatal-warnings"
3194     fi
3195     case "$target" in
3196       i[34567]86-*-*)
3197         conftest_s="$conftest_s
3198 foo:    .long   25
3199         .text
3200         movl    %gs:0, %eax
3201         leal    foo@tlsgd(,%ebx,1), %eax
3202         leal    foo@tlsldm(%ebx), %eax
3203         leal    foo@dtpoff(%eax), %edx
3204         movl    foo@gottpoff(%ebx), %eax
3205         subl    foo@gottpoff(%ebx), %eax
3206         addl    foo@gotntpoff(%ebx), %eax
3207         movl    foo@indntpoff, %eax
3208         movl    \$foo@tpoff, %eax
3209         subl    \$foo@tpoff, %eax
3210         leal    foo@ntpoff(%ecx), %eax"
3211         ;;
3212       x86_64-*-*)
3213         if test x$on_solaris = xyes; then
3214           case $gas_flag in
3215             yes) tls_as_opt="$tls_as_opt --64" ;;
3216             no)  tls_as_opt="$tls_as_opt -xarch=amd64" ;;
3217           esac
3218         fi
3219         conftest_s="$conftest_s
3220 foo:    .long   25
3221         .text
3222         movq    %fs:0, %rax
3223         leaq    foo@tlsgd(%rip), %rdi
3224         leaq    foo@tlsld(%rip), %rdi
3225         leaq    foo@dtpoff(%rax), %rdx
3226         movq    foo@gottpoff(%rip), %rax
3227         movq    \$foo@tpoff, %rax"
3228         ;;
3229     esac
3230     ;;
3231   ia64-*-*)
3232     conftest_s='
3233         .section ".tdata","awT",@progbits
3234 foo:    data8   25
3235         .text
3236         addl    r16 = @ltoff(@dtpmod(foo#)), gp
3237         addl    r17 = @ltoff(@dtprel(foo#)), gp
3238         addl    r18 = @ltoff(@tprel(foo#)), gp
3239         addl    r19 = @dtprel(foo#), gp
3240         adds    r21 = @dtprel(foo#), r13
3241         movl    r23 = @dtprel(foo#)
3242         addl    r20 = @tprel(foo#), gp
3243         adds    r22 = @tprel(foo#), r13
3244         movl    r24 = @tprel(foo#)'
3245         tls_first_major=2
3246         tls_first_minor=13
3247         tls_as_opt=--fatal-warnings
3248         ;;
3249   microblaze*-*-*)
3250     conftest_s='
3251         .section .tdata,"awT",@progbits
3252 x:
3253         .word 2
3254         .text
3255         addik r5,r20,x@TLSGD
3256         addik r5,r20,x@TLSLDM'
3257         tls_first_major=2
3258         tls_first_minor=20
3259         tls_as_opt='--fatal-warnings'
3260         ;;
3261   mips*-*-*)
3262     conftest_s='
3263         .section .tdata,"awT",@progbits
3264 x:
3265         .word 2
3266         .text
3267         addiu $4, $28, %tlsgd(x)
3268         addiu $4, $28, %tlsldm(x)
3269         lui $4, %dtprel_hi(x)
3270         addiu $4, $4, %dtprel_lo(x)
3271         lw $4, %gottprel(x)($28)
3272         lui $4, %tprel_hi(x)
3273         addiu $4, $4, %tprel_lo(x)'
3274         tls_first_major=2
3275         tls_first_minor=16
3276         tls_as_opt='-32 --fatal-warnings'
3277         ;;
3278   m68k-*-*)
3279     conftest_s='
3280         .section .tdata,"awT",@progbits
3281 x:
3282         .word 2
3283         .text
3284 foo:
3285         move.l x@TLSGD(%a5),%a0
3286         move.l x@TLSLDM(%a5),%a0
3287         move.l x@TLSLDO(%a5),%a0
3288         move.l x@TLSIE(%a5),%a0
3289         move.l x@TLSLE(%a5),%a0'
3290         tls_first_major=2
3291         tls_first_minor=19
3292         tls_as_opt='--fatal-warnings'
3293         ;;
3294   nios2-*-*)
3295       conftest_s='
3296         .section ".tdata","awT",@progbits'
3297         tls_first_major=2
3298         tls_first_minor=23
3299         tls_as_opt="--fatal-warnings"
3300         ;;
3301   aarch64*-*-*)
3302     conftest_s='
3303         .section ".tdata","awT",%progbits
3304 foo:    .long   25
3305         .text
3306         adrp  x0, :tlsgd:x
3307         add   x0, x0, #:tlsgd_lo12:x
3308         bl    __tls_get_addr
3309         nop'
3310         tls_first_major=2
3311         tls_first_minor=20
3312         tls_as_opt='--fatal-warnings'
3313         ;;
3314   powerpc-ibm-aix*)
3315     conftest_s='
3316         .extern __get_tpointer
3317         .toc
3318 LC..1:
3319         .tc a[TC],a[TL]@le
3320         .csect .text[PR]
3321 .tlstest:
3322         lwz 9,LC..1(2)
3323         bla __get_tpointer
3324         lwzx 3,9,3
3325         .globl a
3326         .csect a[TL],4
3327 a:
3328         .space 4'
3329         tls_first_major=0
3330         tls_first_minor=0
3331         ;;
3332   powerpc64*-*-*)
3333     conftest_s='
3334         .section ".tdata","awT",@progbits
3335         .align 3
3336 ld0:    .space 8
3337 ld1:    .space 8
3338 x1:     .space 8
3339 x2:     .space 8
3340 x3:     .space 8
3341         .text
3342         addi 3,2,ld0@got@tlsgd
3343         bl .__tls_get_addr
3344         nop
3345         addi 3,2,ld1@toc
3346         bl .__tls_get_addr
3347         nop
3348         addi 3,2,x1@got@tlsld
3349         bl .__tls_get_addr
3350         nop
3351         addi 9,3,x1@dtprel
3352         bl .__tls_get_addr
3353         nop
3354         addis 9,3,x2@dtprel@ha
3355         addi 9,9,x2@dtprel@l
3356         bl .__tls_get_addr
3357         nop
3358         ld 9,x3@got@dtprel(2)
3359         add 9,9,3
3360         bl .__tls_get_addr
3361         nop'
3362         tls_first_major=2
3363         tls_first_minor=14
3364         tls_as_opt="-a64 --fatal-warnings"
3365         ;;
3366   powerpc*-*-*)
3367     conftest_s='
3368         .section ".tdata","awT",@progbits
3369         .align 2
3370 ld0:    .space 4
3371 ld1:    .space 4
3372 x1:     .space 4
3373 x2:     .space 4
3374 x3:     .space 4
3375         .text
3376         addi 3,31,ld0@got@tlsgd
3377         bl __tls_get_addr
3378         addi 3,31,x1@got@tlsld
3379         bl __tls_get_addr
3380         addi 9,3,x1@dtprel
3381         addis 9,3,x2@dtprel@ha
3382         addi 9,9,x2@dtprel@l
3383         lwz 9,x3@got@tprel(31)
3384         add 9,9,x@tls
3385         addi 9,2,x1@tprel
3386         addis 9,2,x2@tprel@ha
3387         addi 9,9,x2@tprel@l'
3388         tls_first_major=2
3389         tls_first_minor=14
3390         tls_as_opt="-a32 --fatal-warnings"
3391         ;;
3392   s390-*-*)
3393     conftest_s='
3394         .section ".tdata","awT",@progbits
3395 foo:    .long   25
3396         .text
3397         .long   foo@TLSGD
3398         .long   foo@TLSLDM
3399         .long   foo@DTPOFF
3400         .long   foo@NTPOFF
3401         .long   foo@GOTNTPOFF
3402         .long   foo@INDNTPOFF
3403         l       %r1,foo@GOTNTPOFF(%r12)
3404         l       %r1,0(%r1):tls_load:foo
3405         bas     %r14,0(%r1,%r13):tls_gdcall:foo
3406         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
3407         tls_first_major=2
3408         tls_first_minor=14
3409         tls_as_opt="-m31 --fatal-warnings"
3410         ;;
3411   s390x-*-*)
3412     conftest_s='
3413         .section ".tdata","awT",@progbits
3414 foo:    .long   25
3415         .text
3416         .quad   foo@TLSGD
3417         .quad   foo@TLSLDM
3418         .quad   foo@DTPOFF
3419         .quad   foo@NTPOFF
3420         .quad   foo@GOTNTPOFF
3421         lg      %r1,foo@GOTNTPOFF(%r12)
3422         larl    %r1,foo@INDNTPOFF
3423         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3424         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3425         tls_first_major=2
3426         tls_first_minor=14
3427         tls_as_opt="-m64 -Aesame --fatal-warnings"
3428         ;;
3429   sh-*-* | sh[123456789lbe]*-*-*)
3430     conftest_s='
3431         .section ".tdata","awT",@progbits
3432 foo:    .long   25
3433         .text
3434         .long   foo@TLSGD
3435         .long   foo@TLSLDM
3436         .long   foo@DTPOFF
3437         .long   foo@GOTTPOFF
3438         .long   foo@TPOFF'
3439         tls_first_major=2
3440         tls_first_minor=13
3441         tls_as_opt=--fatal-warnings
3442         ;;
3443   sparc*-*-*)
3444     case "$target" in
3445       sparc*-sun-solaris2.*)
3446         on_solaris=yes
3447         ;;
3448       *)
3449         on_solaris=no
3450         ;;
3451     esac
3452     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3453       conftest_s='
3454         .section ".tdata",#alloc,#write,#tls'
3455         tls_first_major=0
3456         tls_first_minor=0
3457     else
3458       conftest_s='
3459         .section ".tdata","awT",@progbits'
3460         tls_first_major=2
3461         tls_first_minor=14
3462         tls_as_opt="-32 --fatal-warnings"
3463     fi
3464     conftest_s="$conftest_s
3465 foo:    .long   25
3466         .text
3467         sethi   %tgd_hi22(foo), %o0
3468         add     %o0, %tgd_lo10(foo), %o1
3469         add     %l7, %o1, %o0, %tgd_add(foo)
3470         call    __tls_get_addr, %tgd_call(foo)
3471         sethi   %tldm_hi22(foo), %l1
3472         add     %l1, %tldm_lo10(foo), %l2
3473         add     %l7, %l2, %o0, %tldm_add(foo)
3474         call    __tls_get_addr, %tldm_call(foo)
3475         sethi   %tldo_hix22(foo), %l3
3476         xor     %l3, %tldo_lox10(foo), %l4
3477         add     %o0, %l4, %l5, %tldo_add(foo)
3478         sethi   %tie_hi22(foo), %o3
3479         add     %o3, %tie_lo10(foo), %o3
3480         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3481         add     %g7, %o2, %o4, %tie_add(foo)
3482         sethi   %tle_hix22(foo), %l1
3483         xor     %l1, %tle_lox10(foo), %o5
3484         ld      [%g7 + %o5], %o1"
3485         ;;
3486   tilepro*-*-*)
3487       conftest_s='
3488         .section ".tdata","awT",@progbits
3489 foo:    .long   25
3490         .text
3491         addli   r0, zero, tls_gd(foo)
3492         auli    r0, zero, tls_gd_ha16(foo)
3493         addli   r0, r0, tls_gd_lo16(foo)
3494         jal     __tls_get_addr
3495         addli   r0, zero, tls_ie(foo)
3496         auli    r0, r0, tls_ie_ha16(foo)
3497         addli   r0, r0, tls_ie_lo16(foo)'
3498         tls_first_major=2
3499         tls_first_minor=22
3500         tls_as_opt="--fatal-warnings"
3501         ;;
3502   tilegx*-*-*)
3503       conftest_s='
3504         .section ".tdata","awT",@progbits
3505 foo:    .long   25
3506         .text
3507         shl16insli r0, zero, hw0_last_tls_gd(foo)
3508         shl16insli r0, zero, hw1_last_tls_gd(foo)
3509         shl16insli r0, r0,   hw0_tls_gd(foo)
3510         jal        __tls_get_addr
3511         shl16insli r0, zero, hw1_last_tls_ie(foo)
3512         shl16insli r0, r0,   hw0_tls_ie(foo)'
3513         tls_first_major=2
3514         tls_first_minor=22
3515         tls_as_opt="--fatal-warnings"
3516         ;;
3517   xtensa*-*-*)
3518     conftest_s='
3519         .section ".tdata","awT",@progbits
3520 foo:    .long   25
3521         .text
3522         movi    a8, foo@TLSFUNC
3523         movi    a10, foo@TLSARG
3524         callx8.tls a8, foo@TLSCALL'
3525         tls_first_major=2
3526         tls_first_minor=19
3527         ;;
3528 changequote([,])dnl
3529 esac
3530 set_have_as_tls=no
3531 if test "x$enable_tls" = xno ; then
3532   : # TLS explicitly disabled.
3533 elif test "x$enable_tls" = xyes ; then
3534   set_have_as_tls=yes # TLS explicitly enabled.
3535 elif test -z "$tls_first_major"; then
3536   : # If we don't have a check, assume no support.
3537 else
3538   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3539   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3540   [set_have_as_tls=yes])
3541 fi
3542 if test $set_have_as_tls = yes ; then
3543   AC_DEFINE(HAVE_AS_TLS, 1,
3544             [Define if your assembler and linker support thread-local storage.])
3545 fi
3546
3547 # Target-specific assembler checks.
3548
3549 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3550 gcc_cv_ld_static_dynamic=no
3551 gcc_cv_ld_static_option='-Bstatic'
3552 gcc_cv_ld_dynamic_option='-Bdynamic'
3553 if test $in_tree_ld = yes ; then
3554   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3555     gcc_cv_ld_static_dynamic=yes
3556   fi
3557 elif test x$gcc_cv_ld != x; then
3558   # Check if linker supports -Bstatic/-Bdynamic option
3559   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3560      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3561       gcc_cv_ld_static_dynamic=yes
3562   else
3563     case "$target" in
3564       # AIX ld uses -b flags
3565       *-*-aix4.[[23]]* | *-*-aix[[5-9]]*)
3566         gcc_cv_ld_static_dynamic=yes
3567         gcc_cv_ld_static_option="-bstatic"
3568         gcc_cv_ld_dynamic_option="-bdynamic"
3569         ;;
3570       # HP-UX ld uses -a flags to select between shared and archive.
3571       *-*-hpux*)
3572         if test x"$gnu_ld" = xno; then
3573           gcc_cv_ld_static_dynamic=yes
3574           gcc_cv_ld_static_option="-aarchive_shared"
3575           gcc_cv_ld_dynamic_option="-adefault"
3576         fi
3577         ;;
3578       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3579       *-*-solaris2*)
3580         gcc_cv_ld_static_dynamic=yes
3581         ;;
3582     esac
3583   fi
3584 fi
3585 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3586         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3587 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3588         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3589 [Define to the linker option to disable use of shared objects.])
3590         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3591 [Define to the linker option to enable use of shared objects.])
3592 fi
3593 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3594
3595 if test x"$demangler_in_ld" = xyes; then
3596   AC_MSG_CHECKING(linker --demangle support)
3597   gcc_cv_ld_demangle=no
3598   if test $in_tree_ld = yes; then
3599     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3600       gcc_cv_ld_demangle=yes
3601     fi
3602   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3603     # Check if the GNU linker supports --demangle option
3604     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3605       gcc_cv_ld_demangle=yes
3606     fi
3607   fi
3608   if test x"$gcc_cv_ld_demangle" = xyes; then
3609     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3610 [Define if your linker supports --demangle option.])
3611   fi
3612   AC_MSG_RESULT($gcc_cv_ld_demangle)
3613 fi
3614
3615 AC_MSG_CHECKING(linker plugin support)
3616 gcc_cv_lto_plugin=0
3617 if test -f liblto_plugin.la; then
3618   save_ld_ver="$ld_ver"
3619   save_ld_vers_major="$ld_vers_major"
3620   save_ld_vers_minor="$ld_vers_minor"
3621   save_ld_is_gold="$ld_is_gold"
3622
3623   ld_is_gold=no
3624
3625   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3626     ld_ver="GNU ld"
3627     # FIXME: ld_is_gold?
3628     ld_vers_major="$gcc_cv_gld_major_version"
3629     ld_vers_minor="$gcc_cv_gld_minor_version"
3630   else
3631     # Determine plugin linker version.
3632     # FIXME: Partial duplicate from above, generalize.
3633 changequote(,)dnl
3634     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3635     if echo "$ld_ver" | grep GNU > /dev/null; then
3636       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3637         ld_is_gold=yes
3638         ld_vers=`echo $ld_ver | sed -n \
3639             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3640       else
3641         ld_vers=`echo $ld_ver | sed -n \
3642             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3643       fi
3644       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3645       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3646     fi
3647 changequote([,])dnl
3648   fi
3649
3650   # Determine plugin support.
3651   if echo "$ld_ver" | grep GNU > /dev/null; then
3652     # Require GNU ld or gold 2.21+ for plugin support by default.
3653     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3654       gcc_cv_lto_plugin=2
3655     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3656     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3657       gcc_cv_lto_plugin=1
3658     fi
3659   fi
3660
3661   ld_ver="$save_ld_ver"
3662   ld_vers_major="$save_ld_vers_major"
3663   ld_vers_minor="$save_ld_vers_minor"
3664   ld_is_gold="$save_ld_is_gold"
3665 fi
3666 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3667   [Define to the level of your linker's plugin support.])
3668 AC_MSG_RESULT($gcc_cv_lto_plugin)
3669
3670 case "$target" in
3671   aarch64*-*-*)
3672     gcc_GAS_CHECK_FEATURE([-mabi option], gcc_cv_as_aarch64_mabi,,
3673                           [-mabi=lp64], [.text],,,)
3674     if test x$gcc_cv_as_aarch64_mabi = xyes; then
3675       AC_DEFINE(HAVE_AS_MABI_OPTION, 1,
3676                 [Define if your assembler supports the -mabi option.])
3677     else
3678       if test x$with_abi = xilp32; then
3679         AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3680                      Upgrade the Assembler.])
3681       fi
3682       if test x"$with_multilib_list" = xdefault; then
3683         TM_MULTILIB_CONFIG=lp64
3684       else
3685         aarch64_multilibs=`echo $with_multilib_list | sed -e 's/,/ /g'`
3686         for aarch64_multilib in ${aarch64_multilibs}; do
3687           case ${aarch64_multilib} in
3688             ilp32)
3689               AC_MSG_ERROR([Assembler does not support -mabi=ilp32.\
3690                             Upgrade the Assembler.])
3691               ;;
3692             *)
3693               ;;
3694           esac
3695         done
3696       fi
3697     fi
3698     # Check if we have binutils support for relocations types needed by -fpic
3699     gcc_GAS_CHECK_FEATURE([-fpic relocs], gcc_cv_as_aarch64_picreloc,,,
3700     [
3701         .text
3702         ldr     x0, [[x2, #:gotpage_lo15:globalsym]]
3703     ],,[AC_DEFINE(HAVE_AS_SMALL_PIC_RELOCS, 1,
3704         [Define if your assembler supports relocs needed by -fpic.])])
3705     # Enable default workaround for AArch64 Cortex-A53 erratum 835769.
3706     AC_ARG_ENABLE(fix-cortex-a53-835769,
3707     [
3708 AS_HELP_STRING([--enable-fix-cortex-a53-835769],
3709         [enable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3710 AS_HELP_STRING([--disable-fix-cortex-a53-835769],
3711         [disable workaround for AArch64 Cortex-A53 erratum 835769 by default])
3712     ],
3713       [
3714         case $enableval in
3715           yes)
3716             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_835769_DEFAULT=1"
3717             ;;
3718           no)
3719             ;;
3720           *)
3721             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-835769.\
3722   Valid choices are 'yes' and 'no'.])
3723             ;;
3724
3725         esac
3726       ],
3727     [])
3728     # Enable default workaround for AArch64 Cortex-A53 erratum 843419.
3729     AC_ARG_ENABLE(fix-cortex-a53-843419,
3730     [
3731 AS_HELP_STRING([--enable-fix-cortex-a53-843419],
3732         [enable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3733 AS_HELP_STRING([--disable-fix-cortex-a53-843419],
3734         [disable workaround for AArch64 Cortex-A53 erratum 843419 by default])
3735     ],
3736       [
3737         case $enableval in
3738           yes)
3739             tm_defines="${tm_defines} TARGET_FIX_ERR_A53_843419_DEFAULT=1"
3740             ;;
3741           no)
3742             ;;
3743           *)
3744             AC_MSG_ERROR(['$enableval' is an invalid value for --enable-fix-cortex-a53-843419.\
3745   Valid choices are 'yes' and 'no'.])
3746             ;;
3747
3748         esac
3749       ],
3750     [])
3751     ;;
3752
3753   # All TARGET_ABI_OSF targets.
3754   alpha*-*-linux* | alpha*-*-*bsd*)
3755     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3756         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3757 [       .set nomacro
3758         .text
3759         extbl   $3, $2, $3      !lituse_bytoff!1
3760         ldq     $2, a($29)      !literal!1
3761         ldq     $4, b($29)      !literal!2
3762         ldq_u   $3, 0($2)       !lituse_base!1
3763         ldq     $27, f($29)     !literal!5
3764         jsr     $26, ($27), f   !lituse_jsr!5
3765         ldah    $29, 0($26)     !gpdisp!3
3766         lda     $0, c($29)      !gprel
3767         ldah    $1, d($29)      !gprelhigh
3768         lda     $1, d($1)       !gprellow
3769         lda     $29, 0($29)     !gpdisp!3],,
3770     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3771   [Define if your assembler supports explicit relocations.])])
3772     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3773         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3774 [       .set nomacro
3775         .text
3776         ldq     $27, a($29)     !literal!1
3777         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3778     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3779   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3780     ;;
3781
3782   avr-*-*)
3783     gcc_GAS_CHECK_FEATURE([--mlink-relax option], gcc_cv_as_avr_mlink_relax,,
3784       [--mlink-relax], [.text],,
3785       [AC_DEFINE(HAVE_AS_AVR_MLINK_RELAX_OPTION, 1,
3786                 [Define if your avr assembler supports --mlink-relax option.])])
3787
3788     gcc_GAS_CHECK_FEATURE([-mrmw option], gcc_cv_as_avr_mrmw,,
3789       [-mrmw], [.text],,
3790       [AC_DEFINE(HAVE_AS_AVR_MRMW_OPTION, 1,
3791                 [Define if your avr assembler supports -mrmw option.])])
3792     ;;
3793
3794   cris-*-*)
3795     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3796       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3797       [-no-mul-bug-abort], [.text],,
3798       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3799                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3800     ;;
3801
3802   sparc*-*-*)
3803     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3804       [.register %g2, #scratch],,
3805       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3806                 [Define if your assembler supports .register.])])
3807
3808     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3809       [-relax], [.text],,
3810       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3811                 [Define if your assembler supports -relax option.])])
3812
3813     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3814       gcc_cv_as_sparc_gotdata_op,,
3815       [-K PIC],
3816 [.text
3817 .align 4
3818 foo:
3819         nop
3820 bar:
3821         sethi %gdop_hix22(foo), %g1
3822         xor    %g1, %gdop_lox10(foo), %g1
3823         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3824       [if test x$gcc_cv_ld != x \
3825        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3826          if test x$gcc_cv_objdump != x; then
3827            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3828               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3829                gcc_cv_as_sparc_gotdata_op=no
3830            else
3831                gcc_cv_as_sparc_gotdata_op=yes
3832            fi
3833          fi
3834        fi
3835        rm -f conftest],
3836       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3837                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3838
3839     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3840       gcc_cv_as_sparc_ua_pcrel,,
3841       [-K PIC],
3842 [.text
3843 foo:
3844         nop
3845 .data
3846 .align 4
3847 .byte 0
3848 .uaword %r_disp32(foo)],
3849       [if test x$gcc_cv_ld != x \
3850        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3851          gcc_cv_as_sparc_ua_pcrel=yes
3852        fi
3853        rm -f conftest],
3854       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3855                 [Define if your assembler and linker support unaligned PC relative relocs.])
3856
3857       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3858         gcc_cv_as_sparc_ua_pcrel_hidden,,
3859         [-K PIC],
3860 [.data
3861 .align 4
3862 .byte 0x31
3863 .uaword %r_disp32(foo)
3864 .byte 0x32, 0x33, 0x34
3865 .global foo
3866 .hidden foo
3867 foo:
3868 .skip 4],
3869         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3870          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3871          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3872             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3873             if $gcc_cv_objdump -R conftest 2> /dev/null \
3874                | grep 'DISP32' > /dev/null 2>&1; then
3875                 :
3876             else
3877                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3878             fi
3879          fi
3880          rm -f conftest],
3881          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3882                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3883     ]) # unaligned pcrel relocs
3884
3885     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3886       gcc_cv_as_sparc_offsetable_lo10,,
3887       [-xarch=v9],
3888 [.text
3889         or %g1, %lo(ab) + 12, %g1
3890         or %g1, %lo(ab + 12), %g1],
3891       [if test x$gcc_cv_objdump != x \
3892        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3893           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3894          gcc_cv_as_sparc_offsetable_lo10=yes
3895        fi],
3896        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3897                  [Define if your assembler supports offsetable %lo().])])
3898
3899     gcc_GAS_CHECK_FEATURE([FMAF, HPC, and VIS 3.0 instructions],
3900       gcc_cv_as_sparc_fmaf,,
3901       [-xarch=v9d],
3902       [.text
3903        .register %g2, #scratch
3904        .register %g3, #scratch
3905        .align 4
3906        fmaddd %f0, %f2, %f4, %f6
3907        addxccc %g1, %g2, %g3
3908        fsrl32 %f2, %f4, %f8
3909        fnaddd %f10, %f12, %f14],,
3910       [AC_DEFINE(HAVE_AS_FMAF_HPC_VIS3, 1,
3911                 [Define if your assembler supports FMAF, HPC, and VIS 3.0 instructions.])])
3912
3913     gcc_GAS_CHECK_FEATURE([SPARC4 instructions],
3914       gcc_cv_as_sparc_sparc4,,
3915       [-xarch=sparc4],
3916       [.text
3917        .register %g2, #scratch
3918        .register %g3, #scratch
3919        .align 4
3920        cxbe %g2, %g3, 1f
3921 1:     cwbneg %g2, %g3, 1f
3922 1:     sha1
3923        md5
3924        aes_kexpand0 %f4, %f6, %f8
3925        des_round %f38, %f40, %f42, %f44
3926        camellia_f %f54, %f56, %f58, %f60
3927        kasumi_fi_xor %f46, %f48, %f50, %f52],,
3928       [AC_DEFINE(HAVE_AS_SPARC4, 1,
3929                 [Define if your assembler supports SPARC4 instructions.])])
3930
3931     gcc_GAS_CHECK_FEATURE([SPARC5 and VIS 4.0 instructions],
3932       gcc_cv_as_sparc_sparc5,,
3933       [-xarch=sparc5],
3934       [.text
3935        .register %g2, #scratch
3936        .register %g3, #scratch
3937        .align 4
3938        subxc %g1, %g2, %g3
3939        fpadd8 %f0, %f2, %f4],,
3940       [AC_DEFINE(HAVE_AS_SPARC5_VIS4, 1,
3941                 [Define if your assembler supports SPARC5 and VIS 4.0 instructions.])])
3942
3943     gcc_GAS_CHECK_FEATURE([LEON instructions],
3944       gcc_cv_as_sparc_leon,,
3945       [-Aleon],
3946       [.text
3947        .register %g2, #scratch
3948        .register %g3, #scratch
3949        .align 4
3950        smac %g2, %g3, %g1
3951        umac %g2, %g3, %g1
3952        casa [[%g2]] 0xb, %g3, %g1],,
3953       [AC_DEFINE(HAVE_AS_LEON, 1,
3954                 [Define if your assembler supports LEON instructions.])])
3955     ;;
3956
3957 changequote(,)dnl
3958   i[34567]86-*-* | x86_64-*-*)
3959 changequote([,])dnl
3960     case $target_os in
3961       cygwin*)
3962         # Full C++ conformance when using a shared libstdc++-v3 requires some
3963         # support from the Cygwin DLL, which in more recent versions exports
3964         # wrappers to aid in interposing and redirecting operators new, delete,
3965         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3966         # are configuring for a version of Cygwin that exports the wrappers.
3967         if test x$host = x$target && test x$host_cpu = xi686; then
3968           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3969         else
3970           # Can't check presence of libc functions during cross-compile, so
3971           # we just have to assume we're building for an up-to-date target.
3972           gcc_ac_cygwin_dll_wrappers=yes
3973         fi
3974         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3975           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3976           [Define if you want to generate code by default that assumes that the
3977            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3978     esac
3979     case $target_os in
3980       cygwin* | pe | mingw32*)
3981         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3982         # definition is used unconditionally to initialise the default state of
3983         # the target option variable that governs usage of the feature.
3984         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3985          [2,19,52],,[.comm foo,1,32])
3986         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3987           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3988           [Define if your assembler supports specifying the alignment
3989            of objects allocated using the GAS .comm command.])
3990         # Used for DWARF 2 in PE
3991         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3992           gcc_cv_as_ix86_pe_secrel32,
3993           [2,15,91],,
3994 [.text
3995 foo:    nop
3996 .data
3997         .secrel32 foo],
3998           [if test x$gcc_cv_ld != x \
3999            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
4000              gcc_cv_as_ix86_pe_secrel32=yes
4001            fi
4002            rm -f conftest],
4003           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
4004             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
4005         # Test if the assembler supports the extended form of the .section
4006         # directive that specifies section alignment.  LTO support uses this,
4007         # but normally only after installation, so we warn but don't fail the
4008         # configure if LTO is enabled but the assembler does not support it.
4009         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
4010           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
4011         if test x$gcc_cv_as_section_has_align != xyes; then
4012           case ",$enable_languages," in
4013             *,lto,*)
4014               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
4015               ;;
4016           esac
4017         fi
4018         ;;
4019     esac
4020
4021     # Test if the assembler supports the section flag 'e' for specifying
4022     # an excluded section.
4023     gcc_GAS_CHECK_FEATURE([.section with e], gcc_cv_as_section_has_e,
4024       [2,22,51], [--fatal-warnings],
4025 [.section foo1,"e"
4026 .byte 0,0,0,0])
4027     AC_DEFINE_UNQUOTED(HAVE_GAS_SECTION_EXCLUDE,
4028       [`if test $gcc_cv_as_section_has_e = yes; then echo 1; else echo 0; fi`],
4029       [Define if your assembler supports specifying the section flag e.])
4030
4031     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
4032        gcc_cv_as_ix86_filds,,,
4033        [filds (%ebp); fists (%ebp)],,
4034        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
4035          [Define if your assembler uses filds and fists mnemonics.])])
4036
4037     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
4038        gcc_cv_as_ix86_fildq,,,
4039        [fildq (%ebp); fistpq (%ebp)],,
4040        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
4041          [Define if your assembler uses fildq and fistq mnemonics.])])
4042
4043     gcc_GAS_CHECK_FEATURE([cmov syntax],
4044       gcc_cv_as_ix86_cmov_sun_syntax,,,
4045       [cmovl.l %edx, %eax],,
4046       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
4047         [Define if your assembler supports the Sun syntax for cmov.])])
4048
4049     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
4050       gcc_cv_as_ix86_ffreep,,,
4051       [ffreep %st(1)],,
4052       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
4053         [Define if your assembler supports the ffreep mnemonic.])])
4054
4055     gcc_GAS_CHECK_FEATURE([.quad directive],
4056       gcc_cv_as_ix86_quad,,,
4057       [.quad 0],,
4058       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
4059         [Define if your assembler supports the .quad directive.])])
4060
4061     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
4062       gcc_cv_as_ix86_sahf,,,
4063       [.code64
4064        sahf],,
4065       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
4066         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
4067
4068     gcc_GAS_CHECK_FEATURE([interunit movq mnemonic],
4069       gcc_cv_as_ix86_interunit_movq,,,
4070       [.code64
4071        movq %mm0, %rax
4072        movq %rax, %xmm0])
4073     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_INTERUNIT_MOVQ,
4074       [`if test $gcc_cv_as_ix86_interunit_movq = yes; then echo 1; else echo 0; fi`],
4075       [Define if your assembler supports interunit movq mnemonic.])
4076
4077     gcc_GAS_CHECK_FEATURE([hle prefixes],
4078       gcc_cv_as_ix86_hle,,,
4079       [lock xacquire cmpxchg %esi, (%ecx)],,
4080       [AC_DEFINE(HAVE_AS_IX86_HLE, 1,
4081         [Define if your assembler supports HLE prefixes.])])
4082
4083     gcc_GAS_CHECK_FEATURE([swap suffix],
4084       gcc_cv_as_ix86_swap,,,
4085       [movl.s %esp, %ebp],,
4086       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
4087         [Define if your assembler supports the swap suffix.])])
4088
4089     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
4090       gcc_cv_as_ix86_diff_sect_delta,,,
4091       [.section .rodata
4092 .L1:
4093         .long .L2-.L1
4094         .long .L3-.L1
4095         .text
4096 .L3:    nop
4097 .L2:    nop],,
4098       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
4099         [Define if your assembler supports the subtraction of symbols in different sections.])])
4100
4101     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
4102         gcc_cv_as_ix86_rep_lock_prefix,,,
4103         [rep movsl
4104          rep ret
4105          rep nop
4106          rep bsf %ecx, %eax
4107          rep bsr %ecx, %eax
4108          lock addl %edi, (%eax,%esi)
4109          lock orl $0, (%esp)],,
4110         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
4111           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
4112
4113     gcc_GAS_CHECK_FEATURE([ud2 mnemonic],
4114         gcc_cv_as_ix86_ud2,,,
4115         [ud2],,
4116       [AC_DEFINE(HAVE_AS_IX86_UD2, 1,
4117         [Define if your assembler supports the 'ud2' mnemonic.])])
4118
4119     # Enforce 32-bit output with gas and gld.
4120     if test x$gas = xyes; then
4121       as_ix86_gas_32_opt="--32"
4122     fi
4123     if echo "$ld_ver" | grep GNU > /dev/null; then
4124       if $gcc_cv_ld -V 2>/dev/null | grep elf_i386_sol2 > /dev/null; then
4125         ld_ix86_gld_32_opt="-melf_i386_sol2"
4126       else
4127         ld_ix86_gld_32_opt="-melf_i386"
4128       fi
4129     fi
4130
4131     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
4132         gcc_cv_as_ix86_tlsgdplt,,
4133         [$as_ix86_gas_32_opt],
4134         [call    tls_gd@tlsgdplt],
4135         [if test x$gcc_cv_ld != x \
4136          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4137            gcc_cv_as_ix86_tlsgdplt=yes
4138          fi
4139          rm -f conftest],
4140       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
4141         [Define if your assembler and linker support @tlsgdplt.])])
4142
4143     conftest_s='
4144         .section .tdata,"aw'$tls_section_flag'",@progbits
4145 tls_ld:
4146         .section .text,"ax",@progbits
4147          call    tls_ld@tlsldmplt'
4148
4149     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
4150         gcc_cv_as_ix86_tlsldmplt,,
4151         [$as_ix86_gas_32_opt],
4152         [$conftest_s],
4153         [if test x$gcc_cv_ld != x \
4154          && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o -G > /dev/null 2>&1; then
4155            gcc_cv_as_ix86_tlsldmplt=yes
4156          fi
4157          rm -f conftest])
4158     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDMPLT,
4159       [`if test $gcc_cv_as_ix86_tlsldmplt = yes; then echo 1; else echo 0; fi`],
4160       [Define to 1 if your assembler and linker support @tlsldmplt.])
4161
4162     conftest_s='
4163         .section .text,"ax",@progbits
4164         .globl  _start
4165         .type   _start, @function
4166 _start:
4167         leal    value@tlsldm(%ebx), %eax
4168         call    ___tls_get_addr@plt
4169
4170         .section .tdata,"aw'$tls_section_flag'",@progbits
4171         .type   value, @object
4172 value:'
4173     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM reloc],
4174         gcc_cv_as_ix86_tlsldm,,
4175         [$as_ix86_gas_32_opt],
4176         [$conftest_s],
4177         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4178             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o $ld_tls_libs -lc > /dev/null 2>&1; then
4179            if $gcc_cv_objdump -d conftest 2>/dev/null | grep nop > /dev/null \
4180               || dis conftest 2>/dev/null | grep nop > /dev/null; then
4181              gcc_cv_as_ix86_tlsldm=yes
4182            fi
4183          fi
4184          rm -f conftest])
4185     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLSLDM,
4186       [`if test $gcc_cv_as_ix86_tlsldm = yes; then echo 1; else echo 0; fi`],
4187       [Define to 1 if your assembler and linker support @tlsldm.])
4188
4189     conftest_s='
4190         .data
4191 bar:
4192         .byte 1
4193         .text
4194         .global _start
4195 _start:
4196          cmpl $0, bar@GOT
4197          jmp *_start@GOT'
4198     gcc_GAS_CHECK_FEATURE([R_386_GOT32X reloc],
4199         gcc_cv_as_ix86_got32x,,
4200         [$as_ix86_gas_32_opt],
4201         [$conftest_s],
4202         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
4203             && test x$gcc_cv_readelf != x \
4204             && $gcc_cv_readelf --relocs --wide conftest.o 2>&1 \
4205                | grep R_386_GOT32X > /dev/null 2>&1 \
4206             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4207            if $gcc_cv_objdump -dw conftest 2>&1 \
4208               | grep 0xffffff > /dev/null 2>&1; then
4209              gcc_cv_as_ix86_got32x=no
4210            else
4211              gcc_cv_as_ix86_got32x=yes
4212            fi
4213          fi
4214          rm -f conftest])
4215     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_GOT32X,
4216       [`if test x"$gcc_cv_as_ix86_got32x" = xyes; then echo 1; else echo 0; fi`],
4217       [Define 0/1 if your assembler and linker support @GOT.])
4218
4219     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
4220       gcc_cv_as_ix86_gotoff_in_data, [2,11,0],
4221       [$as_ix86_gas_32_opt],
4222 [       .text
4223 .L0:
4224         nop
4225         .data
4226         .long .L0@GOTOFF])
4227     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
4228       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
4229       [Define true if the assembler supports '.long foo@GOTOFF'.])
4230
4231     conftest_s='
4232         .section .text,"ax",@progbits
4233         .globl  _start
4234         .type   _start, @function
4235 _start:
4236         leal    ld@tlsldm(%ecx), %eax
4237         call    *___tls_get_addr@GOT(%ecx)
4238         leal    gd@tlsgd(%ecx), %eax
4239         call    *___tls_get_addr@GOT(%ecx)
4240
4241         .section .tdata,"aw'$tls_section_flag'",@progbits
4242         .type   ld, @object
4243 ld:
4244         .byte 0
4245         .globl  gd
4246         .type   gd, @object
4247 gd:
4248         .byte 0'
4249     gcc_GAS_CHECK_FEATURE([calling ___tls_get_addr via GOT],
4250         gcc_cv_as_ix86_tls_get_addr_via_got,,
4251         [$as_ix86_gas_32_opt],
4252         [$conftest_s],
4253         [if test x$gcc_cv_ld != x \
4254             && $gcc_cv_ld $ld_ix86_gld_32_opt -o conftest conftest.o > /dev/null 2>&1; then
4255            gcc_cv_as_ix86_tls_get_addr_via_got=yes
4256          fi
4257          rm -f conftest])
4258     AC_DEFINE_UNQUOTED(HAVE_AS_IX86_TLS_GET_ADDR_GOT,
4259       [`if test x"$gcc_cv_as_ix86_tls_get_addr_via_got" = xyes; then echo 1; else echo 0; fi`],
4260       [Define 0/1 if your assembler and linker support calling ___tls_get_addr via GOT.])
4261     ;;
4262
4263   ia64*-*-*)
4264     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
4265         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
4266 [       .text
4267         addl r15 = @ltoffx(x#), gp
4268         ;;
4269         ld8.mov r16 = [[r15]], x#],,
4270     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
4271           [Define if your assembler supports ltoffx and ldxmov relocations.])])
4272
4273     ;;
4274
4275   powerpc*-*-*)
4276
4277     case $target in
4278       *-*-darwin*)
4279         gcc_GAS_CHECK_FEATURE([.machine directive support],
4280           gcc_cv_as_machine_directive,,,
4281           [     .machine ppc7400])
4282         if test x$gcc_cv_as_machine_directive != xyes; then
4283           echo "*** This target requires an assembler supporting \".machine\"" >&2
4284           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
4285           test x$build = x$target && exit 1
4286         fi
4287         ;;
4288     esac
4289
4290     case $target in
4291       *-*-aix*) conftest_s='    .machine "pwr5"
4292         .csect .text[[PR]]
4293         mfcr 3,128';;
4294       *-*-darwin*) conftest_s=' .text
4295         mfcr r3,128';;
4296       *) conftest_s='   .machine power4
4297         .text
4298         mfcr 3,128';;
4299     esac
4300
4301     gcc_GAS_CHECK_FEATURE([mfcr field support],
4302       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
4303       [$conftest_s],,
4304       [AC_DEFINE(HAVE_AS_MFCRF, 1,
4305           [Define if your assembler supports mfcr field.])])
4306
4307     case $target in
4308       *-*-aix*) conftest_s='    .machine "pwr5"
4309         .csect .text[[PR]]
4310         popcntb 3,3';;
4311       *) conftest_s='   .machine power5
4312         .text
4313         popcntb 3,3';;
4314     esac
4315
4316     gcc_GAS_CHECK_FEATURE([popcntb support],
4317       gcc_cv_as_powerpc_popcntb, [2,17,0],,
4318       [$conftest_s],,
4319       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
4320           [Define if your assembler supports popcntb field.])])
4321
4322     case $target in
4323       *-*-aix*) conftest_s='    .machine "pwr5x"
4324         .csect .text[[PR]]
4325         frin 1,1';;
4326       *) conftest_s='   .machine power5
4327         .text
4328         frin 1,1';;
4329     esac
4330
4331     gcc_GAS_CHECK_FEATURE([fp round support],
4332       gcc_cv_as_powerpc_fprnd, [2,17,0],,
4333       [$conftest_s],,
4334       [AC_DEFINE(HAVE_AS_FPRND, 1,
4335           [Define if your assembler supports fprnd.])])
4336
4337     case $target in
4338       *-*-aix*) conftest_s='    .machine "pwr6"
4339         .csect .text[[PR]]
4340         mffgpr 1,3';;
4341       *) conftest_s='   .machine power6
4342         .text
4343         mffgpr 1,3';;
4344     esac
4345
4346     gcc_GAS_CHECK_FEATURE([move fp gpr support],
4347       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
4348       [$conftest_s],,
4349       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
4350           [Define if your assembler supports mffgpr and mftgpr.])])
4351
4352     case $target in
4353       *-*-aix*) conftest_s='    .csect .text[[PR]]
4354 LCF..0:
4355         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
4356       *-*-darwin*)
4357         conftest_s='    .text
4358 LCF0:
4359         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
4360       *) conftest_s='   .text
4361 .LCF0:
4362         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
4363     esac
4364
4365     gcc_GAS_CHECK_FEATURE([rel16 relocs],
4366       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
4367       [$conftest_s],,
4368       [AC_DEFINE(HAVE_AS_REL16, 1,
4369           [Define if your assembler supports R_PPC_REL16 relocs.])])
4370
4371     case $target in
4372       *-*-aix*) conftest_s='    .machine "pwr6"
4373         .csect .text[[PR]]
4374         cmpb 3,4,5';;
4375       *) conftest_s='   .machine power6
4376         .text
4377         cmpb 3,4,5';;
4378     esac
4379
4380     gcc_GAS_CHECK_FEATURE([compare bytes support],
4381       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
4382       [$conftest_s],,
4383       [AC_DEFINE(HAVE_AS_CMPB, 1,
4384           [Define if your assembler supports cmpb.])])
4385
4386     case $target in
4387       *-*-aix*) conftest_s='    .machine "pwr6"
4388         .csect .text[[PR]]
4389         dadd 1,2,3';;
4390       *) conftest_s='   .machine power6
4391         .text
4392         dadd 1,2,3';;
4393     esac
4394
4395     gcc_GAS_CHECK_FEATURE([decimal float support],
4396       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
4397       [$conftest_s],,
4398       [AC_DEFINE(HAVE_AS_DFP, 1,
4399           [Define if your assembler supports DFP instructions.])])
4400
4401     case $target in
4402       *-*-aix*) conftest_s='    .machine "pwr7"
4403         .csect .text[[PR]]
4404         lxvd2x 1,2,3';;
4405       *) conftest_s='   .machine power7
4406         .text
4407         lxvd2x 1,2,3';;
4408     esac
4409
4410     gcc_GAS_CHECK_FEATURE([vector-scalar support],
4411       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
4412       [$conftest_s],,
4413       [AC_DEFINE(HAVE_AS_VSX, 1,
4414           [Define if your assembler supports VSX instructions.])])
4415
4416     case $target in
4417       *-*-aix*) conftest_s='    .machine "pwr7"
4418         .csect .text[[PR]]
4419         popcntd 3,3';;
4420       *) conftest_s='   .machine power7
4421         .text
4422         popcntd 3,3';;
4423     esac
4424
4425     gcc_GAS_CHECK_FEATURE([popcntd support],
4426       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
4427       [$conftest_s],,
4428       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
4429           [Define if your assembler supports POPCNTD instructions.])])
4430
4431     case $target in
4432       *-*-aix*) conftest_s='    .machine "pwr8"
4433         .csect .text[[PR]]';;
4434       *) conftest_s='   .machine power8
4435         .text';;
4436     esac
4437
4438     gcc_GAS_CHECK_FEATURE([power8 support],
4439       gcc_cv_as_powerpc_power8, [2,19,2], -a32,
4440       [$conftest_s],,
4441       [AC_DEFINE(HAVE_AS_POWER8, 1,
4442           [Define if your assembler supports POWER8 instructions.])])
4443
4444     case $target in
4445       *-*-aix*) conftest_s='    .machine "pwr9"
4446         .csect .text[[PR]]';;
4447       *) conftest_s='   .machine power9
4448         .text';;
4449     esac
4450
4451     gcc_GAS_CHECK_FEATURE([power9 support],
4452       gcc_cv_as_powerpc_power9, [2,19,2], -a32,
4453       [$conftest_s],,
4454       [AC_DEFINE(HAVE_AS_POWER9, 1,
4455           [Define if your assembler supports POWER9 instructions.])])
4456
4457     case $target in
4458       *-*-aix*) conftest_s='    .csect .text[[PR]]
4459         lwsync';;
4460       *) conftest_s='   .text
4461         lwsync';;
4462     esac
4463
4464     gcc_GAS_CHECK_FEATURE([lwsync support],
4465       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
4466       [$conftest_s],,
4467       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
4468           [Define if your assembler supports LWSYNC instructions.])])
4469
4470     case $target in
4471       *-*-aix*) conftest_s='    .machine "476"
4472         .csect .text[[PR]]
4473         dci 0';;
4474       *) conftest_s='   .machine "476"
4475         .text
4476         dci 0';;
4477     esac
4478
4479     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
4480       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
4481       [$conftest_s],,
4482       [AC_DEFINE(HAVE_AS_DCI, 1,
4483           [Define if your assembler supports the DCI/ICI instructions.])])
4484
4485     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4486       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
4487       [.gnu_attribute 4,1],,
4488       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4489           [Define if your assembler supports .gnu_attribute.])])
4490
4491     gcc_GAS_CHECK_FEATURE([tls marker support],
4492       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
4493       [ bl __tls_get_addr(x@tlsgd)],,
4494       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
4495           [Define if your assembler supports arg info for __tls_get_addr.])])
4496
4497     gcc_GAS_CHECK_FEATURE([prologue entry point marker support],
4498       gcc_cv_as_powerpc_entry_markers, [2,26,0],-a64 --fatal-warnings,
4499       [ .reloc .,R_PPC64_ENTRY; nop],,
4500       [AC_DEFINE(HAVE_AS_ENTRY_MARKERS, 1,
4501           [Define if your assembler supports the R_PPC64_ENTRY relocation.])])
4502
4503     case $target in
4504       *-*-aix*)
4505         gcc_GAS_CHECK_FEATURE([AIX .ref support],
4506           gcc_cv_as_aix_ref, [2,21,0],,
4507           [     .csect stuff[[rw]]
4508              stuff:
4509                 .long 1
4510                 .extern sym
4511                 .ref sym
4512           ],,
4513           [AC_DEFINE(HAVE_AS_REF, 1,
4514             [Define if your assembler supports .ref])])
4515
4516         gcc_GAS_CHECK_FEATURE([AIX DWARF location lists section support],
4517           gcc_cv_as_aix_dwloc, [2,21,0],,
4518           [     .dwsect 0xA0000
4519         Lframe..0:
4520                 .vbyte 4,Lframe..0:
4521           ],,
4522           [AC_DEFINE(HAVE_XCOFF_DWARF_EXTRAS, 1,
4523             [Define if your assembler supports AIX debug frame section label reference.])])
4524         ;;
4525     esac
4526     ;;
4527
4528   mips*-*-*)
4529     gcc_GAS_CHECK_FEATURE([explicit relocation support],
4530       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
4531 [       lw $4,%gp_rel(foo)($4)],,
4532       [if test x$target_cpu_default = x
4533        then target_cpu_default=MASK_EXPLICIT_RELOCS
4534        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
4535        fi])
4536
4537     gcc_GAS_CHECK_FEATURE([-mno-shared support],
4538       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
4539       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
4540                  [Define if the assembler understands -mno-shared.])])
4541
4542     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4543       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
4544       [.gnu_attribute 4,1],,
4545       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4546           [Define if your assembler supports .gnu_attribute.])])
4547
4548     gcc_GAS_CHECK_FEATURE([.module support],
4549       gcc_cv_as_mips_dot_module,,[-32],
4550       [.module mips2
4551        .module fp=xx],,
4552       [AC_DEFINE(HAVE_AS_DOT_MODULE, 1,
4553           [Define if your assembler supports .module.])])
4554     if test x$gcc_cv_as_mips_dot_module = xno \
4555        && test x$with_fp_32 != x; then
4556       AC_MSG_ERROR(
4557         [Requesting --with-fp-32= requires assembler support for .module.])
4558     fi
4559
4560     gcc_GAS_CHECK_FEATURE([.micromips support],
4561       gcc_cv_as_micromips_support,,[--fatal-warnings],
4562       [.set micromips],,
4563       [AC_DEFINE(HAVE_GAS_MICROMIPS, 1,
4564           [Define if your assembler supports the .set micromips directive])])
4565
4566     gcc_GAS_CHECK_FEATURE([.dtprelword support],
4567       gcc_cv_as_mips_dtprelword, [2,18,0],,
4568       [.section .tdata,"awT",@progbits
4569 x:
4570         .word 2
4571         .text
4572         .dtprelword x+0x8000],,
4573       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
4574           [Define if your assembler supports .dtprelword.])])
4575
4576     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
4577       gcc_cv_as_mips_dspr1_mult,,,
4578 [       .set    mips32r2
4579         .set    nodspr2
4580         .set    dsp
4581         madd    $ac3,$4,$5
4582         maddu   $ac3,$4,$5
4583         msub    $ac3,$4,$5
4584         msubu   $ac3,$4,$5
4585         mult    $ac3,$4,$5
4586         multu   $ac3,$4,$5],,
4587       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
4588           [Define if your assembler supports DSPR1 mult.])])
4589
4590     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
4591     gcc_cv_as_ld_jalr_reloc=no
4592     if test $gcc_cv_as_mips_explicit_relocs = yes; then
4593       if test $in_tree_ld = yes ; then
4594         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
4595            && test $in_tree_ld_is_elf = yes; then
4596           gcc_cv_as_ld_jalr_reloc=yes
4597         fi
4598       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
4599         echo '  .ent x' > conftest.s
4600         echo 'x:        lw $2,%got_disp(y)($3)' >> conftest.s
4601         echo '  lw $25,%call16(y)($28)' >> conftest.s
4602         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
4603         echo '1:        jalr $25' >> conftest.s
4604         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
4605         echo '1:        jalr $25' >> conftest.s
4606         echo '  .end x' >> conftest.s
4607         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
4608            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
4609           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
4610              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
4611             gcc_cv_as_ld_jalr_reloc=yes
4612           fi
4613         fi
4614         rm -f conftest.*
4615       fi
4616     fi
4617     if test $gcc_cv_as_ld_jalr_reloc = yes; then
4618       if test x$target_cpu_default = x; then
4619         target_cpu_default=MASK_RELAX_PIC_CALLS
4620       else
4621         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
4622       fi
4623     fi
4624     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
4625
4626     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
4627       [gcc_cv_ld_mips_personality_relaxation],
4628       [gcc_cv_ld_mips_personality_relaxation=no
4629        if test $in_tree_ld = yes ; then
4630          if test "$gcc_cv_gld_major_version" -eq 2 \
4631                  -a "$gcc_cv_gld_minor_version" -ge 21 \
4632                  -o "$gcc_cv_gld_major_version" -gt 2; then
4633            gcc_cv_ld_mips_personality_relaxation=yes
4634          fi
4635        elif test x$gcc_cv_as != x \
4636                  -a x$gcc_cv_ld != x \
4637                  -a x$gcc_cv_readelf != x ; then
4638          cat > conftest.s <<EOF
4639         .cfi_startproc
4640         .cfi_personality 0x80,indirect_ptr
4641         .ent test
4642 test:
4643         nop
4644         .end test
4645         .cfi_endproc
4646
4647         .section .data,"aw",@progbits
4648 indirect_ptr:
4649         .dc.a personality
4650 EOF
4651          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
4652             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
4653            if $gcc_cv_readelf -d conftest 2>&1 \
4654               | grep TEXTREL > /dev/null 2>&1; then
4655              :
4656            elif $gcc_cv_readelf --relocs conftest 2>&1 \
4657                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
4658              :
4659            else
4660              gcc_cv_ld_mips_personality_relaxation=yes
4661            fi
4662          fi
4663        fi
4664        rm -f conftest.s conftest.o conftest])
4665     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
4666             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
4667       [Define if your linker can relax absolute .eh_frame personality
4668 pointers into PC-relative form.])
4669     fi
4670
4671     gcc_GAS_CHECK_FEATURE([-mnan= support],
4672       gcc_cv_as_mips_nan,,
4673       [-mnan=2008],,,
4674       [AC_DEFINE(HAVE_AS_NAN, 1,
4675                  [Define if the assembler understands -mnan=.])])
4676     if test x$gcc_cv_as_mips_nan = xno \
4677        && test x$with_nan != x; then
4678       AC_MSG_ERROR(
4679         [Requesting --with-nan= requires assembler support for -mnan=])
4680     fi
4681     ;;
4682     s390*-*-*)
4683     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
4684       gcc_cv_as_s390_gnu_attribute, [2,18,0],,
4685       [.gnu_attribute 8,1],,
4686       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
4687           [Define if your assembler supports .gnu_attribute.])])
4688     gcc_GAS_CHECK_FEATURE([.machine and .machinemode support],
4689       gcc_cv_as_s390_machine_machinemode, [2,24,0],,
4690       [ .machinemode push
4691         .machinemode pop
4692         .machine push
4693         .machine pop],,
4694       [AC_DEFINE(HAVE_AS_MACHINE_MACHINEMODE, 1,
4695           [Define if your assembler supports .machine and .machinemode.])])
4696     gcc_GAS_CHECK_FEATURE([architecture modifiers support],
4697       gcc_cv_as_s390_architecture_modifiers, [2,26,0],,
4698       [ .machine z13+vx ],,
4699       [AC_DEFINE(HAVE_AS_ARCHITECTURE_MODIFIERS, 1,
4700           [Define if your assembler supports architecture modifiers.])])
4701     ;;
4702 esac
4703
4704 # Mips and HP-UX need the GNU assembler.
4705 # Linux on IA64 might be able to use the Intel assembler.
4706
4707 case "$target" in
4708   mips*-*-* | *-*-hpux* )
4709     if test x$gas_flag = xyes \
4710        || test x"$host" != x"$build" \
4711        || test ! -x "$gcc_cv_as" \
4712        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
4713       :
4714     else
4715       echo "*** This configuration requires the GNU assembler" >&2
4716       exit 1
4717     fi
4718     ;;
4719 esac
4720
4721 # ??? Not all targets support dwarf2 debug_line, even within a version
4722 # of gas.  Moreover, we need to emit a valid instruction to trigger any
4723 # info to the output file.  So, as supported targets are added to gas 2.11,
4724 # add some instruction here to (also) show we expect this might work.
4725 # ??? Once 2.11 is released, probably need to add first known working
4726 # version to the per-target configury.
4727 case "$cpu_type" in
4728   aarch64 | alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze \
4729   | mips | nios2 | pa | rs6000 | score | sparc | spu | tilegx | tilepro \
4730   | visium | xstormy16 | xtensa)
4731     insn="nop"
4732     ;;
4733   ia64 | s390)
4734     insn="nop 0"
4735     ;;
4736   mmix)
4737     insn="swym 0"
4738     ;;
4739 esac
4740 if test x"$insn" != x; then
4741  conftest_s="\
4742         .file 1 \"conftest.s\"
4743         .loc 1 3 0
4744         $insn"
4745  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
4746   gcc_cv_as_dwarf2_debug_line,
4747   [elf,2,11,0],, [$conftest_s],
4748   [if test x$gcc_cv_objdump != x \
4749    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4750       | grep debug_line > /dev/null 2>&1; then
4751      gcc_cv_as_dwarf2_debug_line=yes
4752    fi])
4753
4754 # The .debug_line file table must be in the exact order that
4755 # we specified the files, since these indices are also used
4756 # by DW_AT_decl_file.  Approximate this test by testing if
4757 # the assembler bitches if the same index is assigned twice.
4758  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4759   gcc_cv_as_dwarf2_file_buggy,,,
4760 [       .file 1 "foo.s"
4761         .file 1 "bar.s"])
4762
4763  if test $gcc_cv_as_dwarf2_debug_line = yes \
4764  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4765         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4766   [Define if your assembler supports dwarf2 .file/.loc directives,
4767    and preserves file table indices exactly as given.])
4768  fi
4769
4770  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4771   gcc_cv_as_gdwarf2_flag,
4772   [elf,2,11,0], [--gdwarf2], [$insn],,
4773   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4774 [Define if your assembler supports the --gdwarf2 option.])])
4775
4776  gcc_GAS_CHECK_FEATURE([--gstabs option],
4777   gcc_cv_as_gstabs_flag,
4778   [elf,2,11,0], [--gstabs], [$insn],,
4779   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4780 [Define if your assembler supports the --gstabs option.])])
4781
4782  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4783   gcc_cv_as_debug_prefix_map_flag,
4784   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4785   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4786 [Define if your assembler supports the --debug-prefix-map option.])])
4787 fi
4788
4789 gcc_GAS_CHECK_FEATURE([compressed debug sections],
4790   gcc_cv_as_compress_debug,,,,
4791   [# gas compiled without zlib cannot compress debug sections and warns
4792    # about it, but still exits successfully.  So check for this, too.
4793    if $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null
4794    then
4795      gcc_cv_as_compress_debug=0
4796    # Since binutils 2.26, gas supports --compress-debug-sections=type,
4797    # defaulting to the ELF gABI format.
4798    elif $gcc_cv_as --compress-debug-sections=zlib-gnu -o conftest.o conftest.s > /dev/null 2>&1
4799    then
4800      gcc_cv_as_compress_debug=2
4801      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4802      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4803    # Before binutils 2.26, gas only supported --compress-debug-options and
4804    # emitted the traditional GNU format.
4805    elif $gcc_cv_as --compress-debug-sections -o conftest.o conftest.s > /dev/null 2>&1
4806    then
4807      gcc_cv_as_compress_debug=1
4808      gcc_cv_as_compress_debug_option="--compress-debug-sections"
4809      gcc_cv_as_no_compress_debug_option="--nocompress-debug-sections"
4810    else
4811      gcc_cv_as_compress_debug=0
4812    fi])
4813 AC_DEFINE_UNQUOTED(HAVE_AS_COMPRESS_DEBUG, $gcc_cv_as_compress_debug,
4814 [Define to the level of your assembler's compressed debug section support.])
4815 AC_DEFINE_UNQUOTED(AS_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_compress_debug_option",
4816 [Define to the assembler option to enable compressed debug sections.])
4817 AC_DEFINE_UNQUOTED(AS_NO_COMPRESS_DEBUG_OPTION, "$gcc_cv_as_no_compress_debug_option",
4818 [Define to the assembler option to disable compressed debug sections.])
4819
4820 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4821  ,,
4822 [.lcomm bar,4,16],,
4823 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4824   [Define if your assembler supports .lcomm with an alignment field.])])
4825
4826 if test x$with_sysroot = x && test x$host = x$target \
4827    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
4828    && test "$prefix" != "NONE"; then
4829   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
4830 [Define to PREFIX/include if cpp should also search that directory.])
4831 fi
4832
4833 # Determine the version of glibc, if any, used on the target.
4834 AC_MSG_CHECKING([for target glibc version])
4835 AC_ARG_WITH([glibc-version],
4836   [AS_HELP_STRING([--with-glibc-version=M.N],
4837     [assume GCC used with glibc version M.N or later])], [
4838 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
4839   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
4840   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
4841 else
4842   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
4843 fi], [
4844 glibc_version_major=0
4845 glibc_version_minor=0
4846 [if test -f $target_header_dir/features.h \
4847   && glibc_version_major_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC__[    ]+[0-9]' $target_header_dir/features.h` \
4848   && glibc_version_minor_define=`$EGREP '^[     ]*#[    ]*define[       ]+__GLIBC_MINOR__[      ]+[0-9]' $target_header_dir/features.h`; then
4849   glibc_version_major=`echo "$glibc_version_major_define" | sed -e 's/.*__GLIBC__[      ]*//'`
4850   glibc_version_minor=`echo "$glibc_version_minor_define" | sed -e 's/.*__GLIBC_MINOR__[        ]*//'`
4851 fi]])
4852 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
4853 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MAJOR], [$glibc_version_major],
4854 [GNU C Library major version number used on the target, or 0.])
4855 AC_DEFINE_UNQUOTED([TARGET_GLIBC_MINOR], [$glibc_version_minor],
4856 [GNU C Library minor version number used on the target, or 0.])
4857
4858 AC_ARG_ENABLE(gnu-unique-object,
4859  [AS_HELP_STRING([--enable-gnu-unique-object],
4860    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4861  [case $enable_gnu_unique_object in
4862     yes | no) ;;
4863     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4864 Valid choices are 'yes' and 'no'.]) ;;
4865   esac],
4866  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4867    [elf,2,19,52],,
4868    [.type foo, '$target_type_format_char'gnu_unique_object],,
4869 # We need to unquote above to to use the definition from config.gcc.
4870 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4871    [GCC_GLIBC_VERSION_GTE_IFELSE([2], [11], [enable_gnu_unique_object=yes], )]
4872    )])
4873 if test x$enable_gnu_unique_object = xyes; then
4874   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4875    [Define if your assembler supports @gnu_unique_object.])
4876 fi
4877
4878 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4879  [gcc_cv_as_line_zero],
4880  [gcc_cv_as_line_zero=no
4881   if test $in_tree_gas = yes; then
4882     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4883   elif test "x$gcc_cv_as" != x; then
4884     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4885     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4886        test "x`cat conftest.out`" = x
4887     then
4888       gcc_cv_as_line_zero=yes
4889     else
4890       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4891       cat conftest.s >&AS_MESSAGE_LOG_FD
4892       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4893       cat conftest.out >&AS_MESSAGE_LOG_FD
4894     fi
4895     rm -f conftest.o conftest.s conftest.out
4896   fi])
4897 if test "x$gcc_cv_as_line_zero" = xyes; then
4898   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4899 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4900 fi
4901
4902 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4903 gcc_cv_ld_eh_frame_hdr=no
4904 if test $in_tree_ld = yes ; then
4905   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4906      && test $in_tree_ld_is_elf = yes; then
4907     gcc_cv_ld_eh_frame_hdr=yes
4908   fi
4909 elif test x$gcc_cv_ld != x; then
4910   if echo "$ld_ver" | grep GNU > /dev/null; then
4911     # Check if linker supports --eh-frame-hdr option
4912     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4913       gcc_cv_ld_eh_frame_hdr=yes
4914     fi
4915   else
4916     case "$target" in
4917       *-*-solaris2*)
4918         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4919         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4920           gcc_cv_ld_eh_frame_hdr=yes
4921         fi
4922         ;;
4923     esac
4924   fi
4925 fi
4926 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4927 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4928         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4929 [Define if your linker supports .eh_frame_hdr.])
4930 fi
4931 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4932
4933 AC_MSG_CHECKING(linker CIEv3 in .eh_frame support)
4934 gcc_cv_ld_eh_frame_ciev3=no
4935 if test $in_tree_ld = yes ; then
4936   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
4937      && test $in_tree_ld_is_elf = yes; then
4938     gcc_cv_ld_eh_frame_ciev3=yes
4939   fi
4940 elif test x$gcc_cv_ld != x; then
4941   if echo "$ld_ver" | grep GNU > /dev/null; then
4942     gcc_cv_ld_eh_frame_ciev3=yes
4943     if test 0"$ld_date" -lt 20040513; then
4944       if test -n "$ld_date"; then
4945         # If there was date string, but was earlier than 2004-05-13, fail
4946         gcc_cv_ld_eh_frame_ciev3=no
4947       elif test "$ld_vers_major" -lt 2; then
4948         gcc_cv_ld_eh_frame_ciev3=no
4949       elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
4950         gcc_cv_ld_eh_frame_ciev3=no
4951       fi
4952     fi
4953   else
4954     case "$target" in
4955       *-*-solaris2*)
4956         # Sun ld added support for CIE v3 in .eh_frame in Solaris 11.1.
4957         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2324; then
4958           gcc_cv_ld_eh_frame_ciev3=yes
4959         fi
4960         ;;
4961     esac
4962   fi
4963 fi
4964 AC_DEFINE_UNQUOTED(HAVE_LD_EH_FRAME_CIEV3,
4965   [`if test x"$gcc_cv_ld_eh_frame_ciev3" = xyes; then echo 1; else echo 0; fi`],
4966   [Define 0/1 if your linker supports CIE v3 in .eh_frame.])
4967 AC_MSG_RESULT($gcc_cv_ld_eh_frame_ciev3)
4968
4969 AC_MSG_CHECKING(linker position independent executable support)
4970 gcc_cv_ld_pie=no
4971 if test $in_tree_ld = yes ; then
4972   case "$target" in
4973     # Full PIE support on Solaris was only introduced in gld 2.26.
4974     *-*-solaris2*)  gcc_gld_pie_min_version=26 ;;
4975     *)              gcc_gld_pie_min_version=15 ;;
4976   esac
4977   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge "$gcc_gld_pie_min_version" -o "$gcc_cv_gld_major_version" -gt 2 \
4978      && test $in_tree_ld_is_elf = yes; then
4979     gcc_cv_ld_pie=yes
4980   fi
4981 elif test x$gcc_cv_ld != x; then
4982   # Check if linker supports -pie option
4983   if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4984     gcc_cv_ld_pie=yes
4985     case "$target" in
4986       *-*-solaris2*)
4987         if echo "$ld_ver" | grep GNU > /dev/null \
4988           && test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
4989           gcc_cv_ld_pie=no
4990         fi
4991         ;;
4992     esac
4993   else
4994     case "$target" in
4995       *-*-solaris2.1[[1-9]]*)
4996         # Solaris 11.x and Solaris 12 added PIE support.
4997         if $gcc_cv_ld -z help 2>&1 | grep -- type.*pie > /dev/null; then
4998           gcc_cv_ld_pie=yes
4999         fi
5000         ;;
5001     esac
5002   fi
5003 fi
5004 if test x"$gcc_cv_ld_pie" = xyes; then
5005         AC_DEFINE(HAVE_LD_PIE, 1,
5006 [Define if your linker supports PIE option.])
5007 fi
5008 AC_MSG_RESULT($gcc_cv_ld_pie)
5009
5010 AC_MSG_CHECKING(linker PIE support with copy reloc)
5011 gcc_cv_ld_pie_copyreloc=no
5012 if test $gcc_cv_ld_pie = yes ; then
5013   if test $in_tree_ld = yes ; then
5014     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
5015       gcc_cv_ld_pie_copyreloc=yes
5016     fi
5017   elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5018     # Check if linker supports -pie option with copy reloc
5019     case "$target" in
5020     i?86-*-linux* | x86_64-*-linux*)
5021       cat > conftest1.s <<EOF
5022         .globl  a_glob
5023         .data
5024         .type   a_glob, @object
5025         .size   a_glob, 4
5026 a_glob:
5027         .long   2
5028 EOF
5029       cat > conftest2.s <<EOF
5030         .text
5031         .globl  main
5032         .type   main, @function
5033 main:
5034         movl    %eax, a_glob(%rip)
5035         .size   main, .-main
5036         .globl  ptr
5037         .section        .data.rel,"aw",@progbits
5038         .type   ptr, @object
5039 ptr:
5040         .quad   a_glob
5041 EOF
5042       if $gcc_cv_as --64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5043          && $gcc_cv_ld -shared -melf_x86_64 -o conftest1.so conftest1.o > /dev/null 2>&1 \
5044          && $gcc_cv_as --64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5045          && $gcc_cv_ld -pie -melf_x86_64 -o conftest conftest2.o conftest1.so > /dev/null 2>&1; then
5046         gcc_cv_ld_pie_copyreloc=yes
5047       fi
5048       rm -f conftest conftest1.so conftest1.o conftest2.o conftest1.s conftest2.s
5049       ;;
5050     esac
5051   fi
5052 fi
5053 AC_DEFINE_UNQUOTED(HAVE_LD_PIE_COPYRELOC,
5054   [`if test x"$gcc_cv_ld_pie_copyreloc" = xyes; then echo 1; else echo 0; fi`],
5055   [Define 0/1 if your linker supports -pie option with copy reloc.])
5056 AC_MSG_RESULT($gcc_cv_ld_pie_copyreloc)
5057
5058 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
5059 gcc_cv_ld_eh_gc_sections=no
5060 if test $in_tree_ld = yes ; then
5061   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
5062      && test $in_tree_ld_is_elf = yes; then
5063     gcc_cv_ld_eh_gc_sections=yes
5064   fi
5065 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
5066   cat > conftest.s <<EOF
5067         .section        .text
5068 .globl _start
5069         .type _start, @function
5070 _start:
5071         .long foo
5072         .size _start, .-_start
5073         .section        .text.foo,"ax",@progbits
5074         .type foo, @function
5075 foo:
5076         .long 0
5077         .size foo, .-foo
5078         .section        .gcc_except_table.foo,"a",@progbits
5079 .L0:
5080         .long 0
5081         .section        .eh_frame,"a",@progbits
5082         .long .L0
5083 EOF
5084   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5085     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5086          | grep "gc-sections option ignored" > /dev/null; then
5087       gcc_cv_ld_eh_gc_sections=no
5088     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5089          | grep gcc_except_table > /dev/null; then
5090       gcc_cv_ld_eh_gc_sections=yes
5091       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
5092       if test x$gcc_cv_as_comdat_group != xyes; then
5093         gcc_cv_ld_eh_gc_sections=no
5094         cat > conftest.s <<EOF
5095         .section        .text
5096 .globl _start
5097         .type _start, @function
5098 _start:
5099         .long foo
5100         .size _start, .-_start
5101         .section        .gnu.linkonce.t.foo,"ax",@progbits
5102         .type foo, @function
5103 foo:
5104         .long 0
5105         .size foo, .-foo
5106         .section        .gcc_except_table.foo,"a",@progbits
5107 .L0:
5108         .long 0
5109         .section        .eh_frame,"a",@progbits
5110         .long .L0
5111 EOF
5112         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5113           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5114                | grep "gc-sections option ignored" > /dev/null; then
5115             gcc_cv_ld_eh_gc_sections=no
5116           elif $gcc_cv_objdump -h conftest 2> /dev/null \
5117                | grep gcc_except_table > /dev/null; then
5118             gcc_cv_ld_eh_gc_sections=yes
5119           fi
5120         fi
5121       fi
5122     fi
5123   fi
5124   rm -f conftest.s conftest.o conftest
5125 fi
5126 case "$target" in
5127   hppa*-*-linux*)
5128     # ??? This apparently exposes a binutils bug with PC-relative relocations.
5129     gcc_cv_ld_eh_gc_sections=no
5130     ;;
5131 esac
5132 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
5133         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
5134   [Define if your linker supports garbage collection of
5135    sections in presence of EH frames.])
5136 fi
5137 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
5138
5139 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
5140 gcc_cv_ld_eh_gc_sections_bug=no
5141 if test $in_tree_ld = yes ; then
5142   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
5143      && test $in_tree_ld_is_elf = yes; then
5144     gcc_cv_ld_eh_gc_sections_bug=yes
5145   fi
5146 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
5147   gcc_cv_ld_eh_gc_sections_bug=yes
5148   cat > conftest.s <<EOF
5149         .section        .text
5150 .globl _start
5151         .type _start, @function
5152 _start:
5153         .long foo
5154         .size _start, .-_start
5155         .section        .text.startup.foo,"ax",@progbits
5156         .type foo, @function
5157 foo:
5158         .long 0
5159         .size foo, .-foo
5160         .section        .gcc_except_table.foo,"a",@progbits
5161 .L0:
5162         .long 0
5163         .section        .eh_frame,"a",@progbits
5164         .long .L0
5165 EOF
5166   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
5167     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
5168          | grep "gc-sections option ignored" > /dev/null; then
5169       :
5170     elif $gcc_cv_objdump -h conftest 2> /dev/null \
5171          | grep gcc_except_table > /dev/null; then
5172       gcc_cv_ld_eh_gc_sections_bug=no
5173     fi
5174   fi
5175   rm -f conftest.s conftest.o conftest
5176 fi
5177 if test x$gcc_cv_ld_eh_gc_sections_bug = xyes; then
5178         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS_BUG, 1,
5179   [Define if your linker has buggy garbage collection of
5180    sections support when .text.startup.foo like sections are used.])
5181 fi
5182 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections_bug)
5183
5184 AC_MSG_CHECKING(linker for compressed debug sections)
5185 # gold/gld support compressed debug sections since binutils 2.19/2.21
5186 # In binutils 2.26, gld gained support for the ELF gABI format.
5187 if test $in_tree_ld = yes ; then
5188   gcc_cv_ld_compress_debug=0
5189   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 19 -o "$gcc_cv_gld_major_version" -gt 2 \
5190      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = yes; then
5191     gcc_cv_ld_compress_debug=2
5192     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5193   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 26 -o "$gcc_cv_gld_major_version" -gt 2 \
5194      && test $in_tree_ld_is_elf = yes && test $ld_is_gold = no; then
5195     gcc_cv_ld_compress_debug=3
5196     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5197   elif test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2 \
5198      && test $in_tree_ld_is_elf = yes; then
5199     gcc_cv_ld_compress_debug=1
5200   fi
5201 elif echo "$ld_ver" | grep GNU > /dev/null; then
5202   if test "$ld_vers_major" -lt 2 \
5203      || test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 21; then
5204     gcc_cv_ld_compress_debug=0
5205   elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 26; then
5206     gcc_cv_ld_compress_debug=1
5207   else
5208     gcc_cv_ld_compress_debug=3
5209     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5210   fi
5211   if test $ld_is_gold = yes; then
5212     gcc_cv_ld_compress_debug=2
5213     gcc_cv_ld_compress_debug_option="--compress-debug-sections"
5214   fi
5215 else
5216 changequote(,)dnl
5217   case "${target}" in
5218     *-*-solaris2*)
5219       # Introduced in Solaris 11.2.
5220       if $gcc_cv_ld --help 2>&1 | grep -- '-z compress-sections' > /dev/null; then
5221         gcc_cv_ld_compress_debug=3
5222         gcc_cv_ld_compress_debug_option="-z compress-sections"
5223       else
5224         gcc_cv_ld_compress_debug=0
5225       fi
5226       ;;
5227     *)
5228       # Assume linkers other than GNU ld don't support compessed debug
5229       # sections.
5230       gcc_cv_ld_compress_debug=0
5231       ;;
5232   esac
5233 changequote([,])dnl
5234 fi
5235 AC_DEFINE_UNQUOTED(HAVE_LD_COMPRESS_DEBUG, $gcc_cv_ld_compress_debug,
5236 [Define to the level of your linker's compressed debug section support.])
5237 AC_DEFINE_UNQUOTED(LD_COMPRESS_DEBUG_OPTION, "$gcc_cv_ld_compress_debug_option",
5238 [Define to the linker option to enable compressed debug sections.])
5239 AC_MSG_RESULT($gcc_cv_ld_compress_debug)
5240
5241 # --------
5242 # UNSORTED
5243 # --------
5244
5245 AC_CACHE_CHECK(linker --as-needed support,
5246 gcc_cv_ld_as_needed,
5247 [gcc_cv_ld_as_needed=no
5248 gcc_cv_ld_as_needed_option='--as-needed'
5249 gcc_cv_ld_no_as_needed_option='--no-as-needed'
5250 if test $in_tree_ld = yes ; then
5251   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
5252      && test $in_tree_ld_is_elf = yes; then
5253     gcc_cv_ld_as_needed=yes
5254   fi
5255 elif test x$gcc_cv_ld != x; then
5256         # Check if linker supports --as-needed and --no-as-needed options
5257         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
5258                 gcc_cv_ld_as_needed=yes
5259         else
5260           case "$target" in
5261             # Solaris 2 ld always supports -z ignore/-z record.
5262             *-*-solaris2*)
5263               gcc_cv_ld_as_needed=yes
5264               gcc_cv_ld_as_needed_option="-z ignore"
5265               gcc_cv_ld_no_as_needed_option="-z record"
5266               ;;
5267           esac
5268         fi
5269 fi
5270 # --as-needed/-z ignore can only be used if libgcc_s.so.1 uses
5271 # dl_iterate_phdr, i.e. since Solaris 11.
5272 case "$target" in
5273   *-*-solaris2.1[[1-9]]*)
5274     case "$target" in
5275     i?86-*-* | x86_64-*-*)
5276       if echo "$ld_ver" | grep GNU > /dev/null; then
5277         # Doesn't work with gld on Solaris/x86 due to PR ld/12320.
5278         gcc_cv_ld_as_needed=no
5279       fi
5280       ;;
5281     esac
5282     ;;
5283   *-*-solaris2*)
5284     gcc_cv_ld_as_needed=no
5285     ;;
5286 esac
5287 ])
5288 if test x"$gcc_cv_ld_as_needed" = xyes; then
5289         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
5290 [Define if your linker supports --as-needed/--no-as-needed or equivalent options.])
5291         AC_DEFINE_UNQUOTED(LD_AS_NEEDED_OPTION, "$gcc_cv_ld_as_needed_option",
5292 [Define to the linker option to ignore unused dependencies.])
5293         AC_DEFINE_UNQUOTED(LD_NO_AS_NEEDED_OPTION, "$gcc_cv_ld_no_as_needed_option",
5294 [Define to the linker option to keep unused dependencies.])
5295 fi
5296
5297 AC_MSG_CHECKING(linker mapfile support for clearing hardware capabilities)
5298 saved_LDFLAGS="$LDFLAGS"
5299 for clearcap_map in sol2-clearcapv2.map sol2-clearcap.map; do
5300   LDFLAGS="$saved_LDFLAGS -Wl,-M,${srcdir}/config/$clearcap_map"
5301   AC_LINK_IFELSE([int main(void) {return 0;}],
5302     [gcc_cv_ld_clearcap=yes; break], [gcc_cv_ld_clearcap=no])
5303 done
5304 LDFLAGS="$saved_LDFLAGS"
5305 if test "x$gcc_cv_ld_clearcap" = xyes; then
5306   AC_DEFINE([HAVE_LD_CLEARCAP], 1,
5307 [Define if the linker supports clearing hardware capabilities via mapfile.])
5308   AC_CONFIG_LINKS([clearcap.map:${srcdir}/config/$clearcap_map])
5309 fi
5310 AC_MSG_RESULT($gcc_cv_ld_clearcap)
5311
5312 case "$target:$tm_file" in
5313   powerpc64-*-freebsd* | powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
5314   case "$target" in
5315      *le-*-linux*)
5316      emul_name="-melf64lppc"
5317       ;;
5318      *-*-linux*)
5319      emul_name="-melf64ppc"
5320       ;;
5321      *-*-freebsd*)
5322      emul_name="-melf64ppc_fbsd"
5323       ;;
5324   esac
5325     AC_CACHE_CHECK(linker support for omitting dot symbols,
5326     gcc_cv_ld_no_dot_syms,
5327     [gcc_cv_ld_no_dot_syms=no
5328     if test x"$ld_is_gold" = xyes; then
5329       gcc_cv_ld_no_dot_syms=yes
5330     elif test $in_tree_ld = yes ; then
5331       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
5332         gcc_cv_ld_no_dot_syms=yes
5333       fi
5334     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5335       cat > conftest1.s <<EOF
5336         .text
5337         bl .foo
5338 EOF
5339       cat > conftest2.s <<EOF
5340         .section ".opd","aw"
5341         .align 3
5342         .globl foo
5343         .type foo,@function
5344 foo:
5345         .quad .LEfoo,.TOC.@tocbase,0
5346         .text
5347 .LEfoo:
5348         blr
5349         .size foo,.-.LEfoo
5350 EOF
5351       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
5352          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
5353          && $gcc_cv_ld $emul_name -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
5354         gcc_cv_ld_no_dot_syms=yes
5355       fi
5356       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
5357     fi
5358     ])
5359     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
5360       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
5361     [Define if your PowerPC64 linker only needs function descriptor syms.])
5362     fi
5363
5364     AC_CACHE_CHECK(linker large toc support,
5365     gcc_cv_ld_large_toc,
5366     [gcc_cv_ld_large_toc=no
5367     if test x"$ld_is_gold" = xyes; then
5368       gcc_cv_ld_large_toc=yes
5369     elif test $in_tree_ld = yes ; then
5370       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 21 -o "$gcc_cv_gld_major_version" -gt 2; then
5371         gcc_cv_ld_large_toc=yes
5372       fi
5373     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
5374       cat > conftest.s <<EOF
5375         .section ".tbss","awT",@nobits
5376         .align 3
5377 ie0:    .space 8
5378         .global _start
5379         .text
5380 _start:
5381         addis 9,13,ie0@got@tprel@ha
5382         ld 9,ie0@got@tprel@l(9)
5383 EOF
5384       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5385          && $gcc_cv_ld $emul_name --no-toc-sort -o conftest conftest.o > /dev/null 2>&1; then
5386         gcc_cv_ld_large_toc=yes
5387       fi
5388       rm -f conftest conftest.o conftest.s
5389     fi
5390     ])
5391     if test x"$gcc_cv_ld_large_toc" = xyes; then
5392       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5393     [Define if your PowerPC64 linker supports a large TOC.])
5394     fi
5395
5396     AC_CACHE_CHECK(linker toc pointer alignment,
5397     gcc_cv_ld_toc_align,
5398     [if test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_nm != x; then
5399       cat > conftest.s <<EOF
5400         .global _start
5401         .text
5402 _start:
5403         addis 9,2,x@got@ha
5404         .section .data.rel.ro,"aw",@progbits
5405         .p2align 16
5406         .space 32768
5407 x:      .quad .TOC.
5408 EOF
5409       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1 \
5410          && $gcc_cv_ld $emul_name -z norelro -o conftest conftest.o > /dev/null 2>&1; then
5411         gcc_cv_ld_toc_align=`$gcc_cv_nm conftest | ${AWK} '/\.TOC\./ { match ($0, "0[[[:xdigit:]]]*", a); print strtonum ("0x" substr(a[[0]], length(a[[0]])-3)) }'`
5412       fi
5413       rm -f conftest conftest.o conftest.s
5414     fi
5415     ])
5416     if test -n "$gcc_cv_ld_toc_align" && test $gcc_cv_ld_toc_align -gt 8; then
5417       AC_DEFINE_UNQUOTED(POWERPC64_TOC_POINTER_ALIGNMENT, $gcc_cv_ld_toc_align,
5418     [Define to .TOC. alignment forced by your linker.])
5419     fi
5420     ;;
5421 esac
5422
5423 case "$target" in
5424   *-*-aix*)
5425     AC_CACHE_CHECK(linker large toc support,
5426     gcc_cv_ld_large_toc,
5427     [gcc_cv_ld_large_toc=no
5428     if test x$gcc_cv_as != x ; then
5429       cat > conftest.s <<EOF
5430         .toc
5431 LC..1:
5432         .tc a[[TC]],a[[RW]]
5433         .extern a[[RW]]
5434         .csect .text[[PR]]
5435 .largetoctest:
5436         addis 9,LC..1@u(2)
5437         ld 3,LC..1@l(9)
5438 EOF
5439       if $gcc_cv_as -a64 -o conftest.o conftest.s > /dev/null 2>&1; then
5440         gcc_cv_ld_large_toc=yes
5441       fi
5442       rm -f conftest conftest.o conftest.s
5443     fi
5444     ])
5445     if test x"$gcc_cv_ld_large_toc" = xyes; then
5446       AC_DEFINE(HAVE_LD_LARGE_TOC, 1,
5447     [Define if your PowerPC64 linker supports a large TOC.])
5448     fi
5449     ;;
5450 esac
5451
5452 AC_CACHE_CHECK(linker --build-id support,
5453   gcc_cv_ld_buildid,
5454   [gcc_cv_ld_buildid=no
5455   if test $in_tree_ld = yes ; then
5456     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5457        "$gcc_cv_gld_minor_version" -ge 18 -o \
5458        "$gcc_cv_gld_major_version" -gt 2 \
5459        && test $in_tree_ld_is_elf = yes; then
5460       gcc_cv_ld_buildid=yes
5461     fi
5462   elif test x$gcc_cv_ld != x; then
5463     if $gcc_cv_ld --help 2>/dev/null | grep build-id > /dev/null; then
5464       gcc_cv_ld_buildid=yes
5465     fi
5466   fi])
5467 if test x"$gcc_cv_ld_buildid" = xyes; then
5468   AC_DEFINE(HAVE_LD_BUILDID, 1,
5469   [Define if your linker supports --build-id.])
5470 fi
5471
5472 AC_ARG_ENABLE(linker-build-id,
5473 [AS_HELP_STRING([--enable-linker-build-id],
5474                 [compiler will always pass --build-id to linker])],
5475 [],
5476 enable_linker_build_id=no)
5477
5478 if test x"$enable_linker_build_id" = xyes; then
5479   if test x"$gcc_cv_ld_buildid" = xyes; then
5480     AC_DEFINE(ENABLE_LD_BUILDID, 1,
5481     [Define if gcc should always pass --build-id to linker.])
5482   else
5483     AC_MSG_WARN(--build-id is not supported by your linker; --enable-linker-build-id ignored)
5484   fi
5485 fi
5486
5487 # In binutils 2.21, GNU ld gained support for new emulations fully
5488 # supporting the Solaris 2 ABI.  Detect their presence in the linker used.
5489 AC_CACHE_CHECK(linker *_sol2 emulation support,
5490   gcc_cv_ld_sol2_emulation,
5491   [gcc_cv_ld_sol2_emulation=no
5492   if test $in_tree_ld = yes ; then
5493     if test "$gcc_cv_gld_major_version" -eq 2 -a \
5494        "$gcc_cv_gld_minor_version" -ge 21 -o \
5495        "$gcc_cv_gld_major_version" -gt 2 \
5496        && test $in_tree_ld_is_elf = yes; then
5497       gcc_cv_ld_sol2_emulation=yes
5498     fi
5499   elif test x$gcc_cv_ld != x; then
5500     if $gcc_cv_ld -V 2>/dev/null | sed -e '1,/Supported emulations/d;q' | \
5501        grep _sol2 > /dev/null; then
5502       gcc_cv_ld_sol2_emulation=yes
5503     fi
5504   fi])
5505 if test x"$gcc_cv_ld_sol2_emulation" = xyes; then
5506   AC_DEFINE(HAVE_LD_SOL2_EMULATION, 1,
5507   [Define if your linker supports the *_sol2 emulations.])
5508 fi
5509
5510 AC_CACHE_CHECK(linker --sysroot support,
5511   gcc_cv_ld_sysroot,
5512   [gcc_cv_ld_sysroot=no
5513   if test $in_tree_ld = yes ; then
5514       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
5515         gcc_cv_ld_sysroot=yes
5516       fi
5517   elif test x$gcc_cv_ld != x; then
5518     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
5519       gcc_cv_ld_sysroot=yes
5520     fi
5521   fi])
5522 if test x"$gcc_cv_ld_sysroot" = xyes; then
5523   AC_DEFINE(HAVE_LD_SYSROOT, 1,
5524   [Define if your linker supports --sysroot.])
5525 fi
5526
5527 case $target in
5528 *-*-solaris2*)
5529   # Check for system-provided CRTs on Solaris 11.x and Solaris 12.
5530   AC_CACHE_CHECK([system-provided CRTs on Solaris],
5531     gcc_cv_solaris_crts,
5532     [gcc_cv_solaris_crts=no
5533      if test x$host != x$target; then
5534        if test "x$with_sysroot" = xyes; then
5535          target_sysroot="${test_exec_prefix}/${target_noncanonical}/sys-root"
5536        else
5537          target_sysroot="${with_sysroot}"
5538        fi
5539      fi
5540      target_libdir="$target_sysroot/usr/lib"
5541      # At the time they were added, gcrt1.o became a symlink for backwards
5542      # compatibility on x86, while crt1.o was added on sparc, so check for that.
5543      case $target in
5544        i?86-*-solaris2* | x86_64-*-solaris2*)
5545          if test -h "$target_libdir/gcrt1.o"; then gcc_cv_solaris_crts=yes; fi
5546          ;;
5547        sparc*-*-solaris2*)
5548          if test -f "$target_libdir/crt1.o"; then gcc_cv_solaris_crts=yes; fi
5549          ;;
5550      esac])
5551   ;;
5552 esac
5553 if test x$gcc_cv_solaris_crts = xyes; then
5554   AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
5555             [Define if the system-provided CRTs are present on Solaris.])
5556 fi
5557
5558 # Test for stack protector support in target C library.
5559 AC_CACHE_CHECK(__stack_chk_fail in target C library,
5560       gcc_cv_libc_provides_ssp,
5561       [gcc_cv_libc_provides_ssp=no
5562     case "$target" in
5563        *-*-musl*)
5564          # All versions of musl provide stack protector
5565          gcc_cv_libc_provides_ssp=yes;;
5566        *-*-linux* | *-*-kfreebsd*-gnu)
5567       # glibc 2.4 and later provides __stack_chk_fail and
5568       # either __stack_chk_guard, or TLS access to stack guard canary.
5569       GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_libc_provides_ssp=yes], [
5570       [if test -f $target_header_dir/features.h \
5571          && $EGREP '^[  ]*#[    ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
5572             $target_header_dir/features.h > /dev/null; then
5573         if $EGREP '^[   ]*#[    ]*define[       ]+__UCLIBC__[   ]+1' \
5574              $target_header_dir/features.h > /dev/null && \
5575              test -f $target_header_dir/bits/uClibc_config.h && \
5576              $EGREP '^[         ]*#[    ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
5577              $target_header_dir/bits/uClibc_config.h > /dev/null; then
5578           gcc_cv_libc_provides_ssp=yes
5579         fi
5580       # all versions of Bionic support stack protector
5581       elif test -f $target_header_dir/sys/cdefs.h \
5582         && $EGREP '^[  ]*#[    ]*define[       ]+__BIONIC__[   ]+1' \
5583            $target_header_dir/sys/cdefs.h > /dev/null; then
5584          gcc_cv_libc_provides_ssp=yes
5585       fi]])
5586         ;;
5587        *-*-gnu*)
5588          # Avoid complicated tests (see
5589          # <http://gcc.gnu.org/ml/gcc/2008-10/msg00130.html>) and for now
5590          # simply assert that glibc does provide this, which is true for all
5591          # realistically usable GNU/Hurd configurations.
5592          # All supported versions of musl provide it as well
5593          gcc_cv_libc_provides_ssp=yes;;
5594        *-*-darwin* | *-*-freebsd* | *-*-netbsd*)
5595          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
5596            [echo "no __stack_chk_fail on this target"])
5597         ;;
5598   *) gcc_cv_libc_provides_ssp=no ;;
5599     esac])
5600
5601 if test x$gcc_cv_libc_provides_ssp = xyes; then
5602   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
5603             [Define if your target C library provides stack protector support])
5604 fi
5605
5606 # Check whether --enable-default-ssp was given.
5607 AC_ARG_ENABLE(default-ssp,
5608 [AS_HELP_STRING([--enable-default-ssp],
5609   [enable Stack Smashing Protection as default])],[
5610 if test x$gcc_cv_libc_provides_ssp = xyes; then
5611   case "$target" in
5612     ia64*-*-*) enable_default_ssp=no ;;
5613     *) enable_default_ssp=$enableval ;;
5614   esac
5615 else
5616   enable_default_ssp=no
5617 fi],
5618 enable_default_ssp=no)
5619 if test x$enable_default_ssp = xyes ; then
5620   AC_DEFINE(ENABLE_DEFAULT_SSP, 1,
5621       [Define if your target supports default stack protector and it is enabled.])
5622 fi
5623 AC_SUBST([enable_default_ssp])
5624
5625 # Test for <sys/sdt.h> on the target.
5626 GCC_TARGET_TEMPLATE([HAVE_SYS_SDT_H])
5627 AC_MSG_CHECKING(sys/sdt.h in the target C library)
5628 have_sys_sdt_h=no
5629 if test -f $target_header_dir/sys/sdt.h; then
5630   have_sys_sdt_h=yes
5631   AC_DEFINE(HAVE_SYS_SDT_H, 1,
5632             [Define if your target C library provides sys/sdt.h])
5633 fi
5634 AC_MSG_RESULT($have_sys_sdt_h)
5635
5636 # Check if TFmode long double should be used by default or not.
5637 # Some glibc targets used DFmode long double, but with glibc 2.4
5638 # and later they can use TFmode.
5639 case "$target" in
5640   powerpc*-*-linux* | \
5641   sparc*-*-linux* | \
5642   s390*-*-linux* | \
5643   alpha*-*-linux*)
5644     AC_ARG_WITH(long-double-128,
5645       [AS_HELP_STRING([--with-long-double-128],
5646                       [use 128-bit long double by default])],
5647       gcc_cv_target_ldbl128="$with_long_double_128",
5648       [GCC_GLIBC_VERSION_GTE_IFELSE([2], [4], [gcc_cv_target_ldbl128=yes], [
5649       [gcc_cv_target_ldbl128=no
5650       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
5651         $target_header_dir/bits/wordsize.h > /dev/null 2>&1 \
5652       && gcc_cv_target_ldbl128=yes
5653       ]])])
5654     ;;
5655 esac
5656 if test x$gcc_cv_target_ldbl128 = xyes; then
5657   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
5658             [Define if TFmode long double should be the default])
5659 fi
5660
5661 # Check if the target LIBC supports exporting the AT_PLATFORM and AT_HWCAP
5662 # values in the TCB.  Currently, only GLIBC 2.23 and later support this.
5663 gcc_cv_libc_provides_hwcap_in_tcb=no
5664 case "$target" in
5665   powerpc*-*-linux*)
5666     GCC_GLIBC_VERSION_GTE_IFELSE([2], [23], [gcc_cv_libc_provides_hwcap_in_tcb=yes], )
5667     ;;
5668 esac
5669 if test x$gcc_cv_libc_provides_hwcap_in_tcb = xyes; then
5670   AC_DEFINE(TARGET_LIBC_PROVIDES_HWCAP_IN_TCB, 1,
5671             [Define if your target C Library provides the AT_HWCAP value in the TCB])
5672 fi
5673
5674 AC_MSG_CHECKING(dl_iterate_phdr in target C library)
5675 gcc_cv_target_dl_iterate_phdr=unknown
5676 case "$target" in
5677   # Restrict to Solaris 11+.  While most of the Solaris 11 linker changes
5678   # were backported to Solaris 10 Update 10, dl_iterate_phdr only lives in
5679   # libdl there, both complicating its use and breaking compatibility
5680   # between Solaris 10 updates.
5681   *-*-solaris2.1[[1-9]]*)
5682     # <link.h> needs both a dl_iterate_phdr declaration and support for
5683     # compilation with largefile support.
5684     if grep dl_iterate_phdr $target_header_dir/link.h > /dev/null 2>&1 \
5685       && grep 'large file capable' $target_header_dir/link.h > /dev/null 2>&1; then
5686       gcc_cv_target_dl_iterate_phdr=yes
5687     else
5688       gcc_cv_target_dl_iterate_phdr=no
5689     fi
5690     ;;
5691   *-*-dragonfly* | *-*-freebsd*)
5692     if grep dl_iterate_phdr $target_header_dir/sys/link_elf.h > /dev/null 2>&1; then
5693       gcc_cv_target_dl_iterate_phdr=yes
5694     else
5695       gcc_cv_target_dl_iterate_phdr=no
5696     fi
5697     ;;
5698   *-linux-musl*)
5699     gcc_cv_target_dl_iterate_phdr=yes
5700     ;;
5701 esac
5702 GCC_TARGET_TEMPLATE([TARGET_DL_ITERATE_PHDR])
5703 if test x$gcc_cv_target_dl_iterate_phdr = xyes; then
5704    AC_DEFINE(TARGET_DL_ITERATE_PHDR, 1,
5705 [Define if your target C library provides the `dl_iterate_phdr' function.])
5706 fi
5707 AC_MSG_RESULT($gcc_cv_target_dl_iterate_phdr)
5708
5709 # We no longer support different GC mechanisms.  Emit an error if
5710 # the user configures with --with-gc.
5711 AC_ARG_WITH(gc,
5712 [AS_HELP_STRING([--with-gc={page,zone}],
5713                 [this option is not supported anymore.  It used to choose
5714                  the garbage collection mechanism to use with the compiler])],
5715 [AC_MSG_ERROR([Configure option --with-gc is only supported up to GCC 4.7.x])],
5716 [])
5717
5718 # Libraries to use on the host.  This will normally be set by the top
5719 # level Makefile.  Here we simply capture the value for our Makefile.
5720 if test -z "${HOST_LIBS+set}"; then
5721   HOST_LIBS=
5722 fi
5723 AC_SUBST(HOST_LIBS)
5724
5725 # Use the system's zlib library.
5726 AM_ZLIB
5727
5728 dnl Very limited version of automake's enable-maintainer-mode
5729
5730 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
5731   dnl maintainer-mode is disabled by default
5732   AC_ARG_ENABLE(maintainer-mode,
5733 [AS_HELP_STRING([--enable-maintainer-mode],
5734                 [enable make rules and dependencies not useful
5735                  (and sometimes confusing) to the casual installer])],
5736       maintainer_mode=$enableval,
5737       maintainer_mode=no)
5738
5739 AC_MSG_RESULT($maintainer_mode)
5740
5741 if test "$maintainer_mode" = "yes"; then
5742   MAINT=''
5743 else
5744   MAINT='#'
5745 fi
5746 AC_SUBST(MAINT)dnl
5747
5748 dnl Whether to prevent multiple front-ends from linking at the same time
5749
5750 AC_MSG_CHECKING([whether to avoid linking multiple front-ends at once])
5751   AC_ARG_ENABLE(link-mutex,
5752 [AS_HELP_STRING([--enable-link-mutex],
5753                 [avoid linking multiple front-ends at once to avoid thrashing
5754                  on the build machine])],
5755       do_link_mutex=$enableval,
5756       do_link_mutex=no)
5757 AC_MSG_RESULT($do_link_mutex)
5758
5759 if test "$do_link_mutex" = "yes"; then
5760    DO_LINK_MUTEX=true
5761 else
5762    DO_LINK_MUTEX=false
5763 fi
5764 AC_SUBST(DO_LINK_MUTEX)
5765
5766 # --------------
5767 # Language hooks
5768 # --------------
5769
5770 # Make empty files to contain the specs and options for each language.
5771 # Then add #include lines to for a compiler that has specs and/or options.
5772
5773 subdirs=
5774 lang_opt_files=
5775 lang_specs_files=
5776 lang_tree_files=
5777 # These (without "all_") are set in each config-lang.in.
5778 # `language' must be a single word so is spelled singularly.
5779 all_languages=
5780 all_compilers=
5781 all_outputs='Makefile'
5782 # List of language makefile fragments.
5783 all_lang_makefrags=
5784 # Additional files for gengtype
5785 all_gtfiles="$target_gtfiles"
5786
5787 # These are the languages that are set in --enable-languages,
5788 # and are available in the GCC tree.
5789 all_selected_languages=
5790
5791 # Add the language fragments.
5792 # Languages are added via two mechanisms.  Some information must be
5793 # recorded in makefile variables, these are defined in config-lang.in.
5794 # We accumulate them and plug them into the main Makefile.
5795 # The other mechanism is a set of hooks for each of the main targets
5796 # like `clean', `install', etc.
5797
5798 language_hooks="Make-hooks"
5799
5800 for lang in ${srcdir}/*/config-lang.in
5801 do
5802 changequote(,)dnl
5803         test "$lang" = "${srcdir}/*/config-lang.in" && continue
5804
5805         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
5806         if test "x$lang_alias" = x
5807         then
5808               echo "$lang doesn't set \$language." 1>&2
5809               exit 1
5810         fi
5811         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
5812         subdirs="$subdirs $subdir"
5813
5814         # $gcc_subdir is where the gcc integration files are to be found
5815         # for a language, both for internal compiler purposes (compiler
5816         # sources implementing front-end to GCC tree converters), and for
5817         # build infrastructure purposes (Make-lang.in, etc.)
5818         #
5819         # This will be <subdir> (relative to $srcdir) if a line like
5820         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
5821         # is found in <langdir>/config-lang.in, and will remain <langdir>
5822         # otherwise.
5823         #
5824         # Except for the language alias (fetched above), the regular
5825         # "config-lang.in" contents are always retrieved from $gcc_subdir,
5826         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
5827         # only this and the language alias.
5828
5829         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
5830         if [ "$gcc_subdir" = "" ]; then
5831            gcc_subdir="$subdir"
5832         fi
5833
5834         case ",$enable_languages," in
5835         *,$lang_alias,*)
5836             all_selected_languages="$all_selected_languages $lang_alias"
5837             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
5838                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
5839             fi
5840             ;;
5841         esac
5842 changequote([,])dnl
5843
5844         language=
5845         boot_language=
5846         compilers=
5847         outputs=
5848         gtfiles=
5849         subdir_requires=
5850         . ${srcdir}/$gcc_subdir/config-lang.in
5851         if test "x$language" = x
5852         then
5853                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
5854                 exit 1
5855         fi
5856
5857         ok=:
5858         case ",$enable_languages," in
5859                 *,$lang_alias,*) ;;
5860                 *)
5861                         for i in $subdir_requires; do
5862                                 test -f "${srcdir}/$i/config-lang.in" && continue
5863                                 ok=false
5864                                 break
5865                         done
5866                 ;;
5867         esac
5868         $ok || continue
5869
5870         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
5871         if test -f $srcdir/$gcc_subdir/lang.opt; then
5872             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
5873             all_opt_files="$all_opt_files $srcdir/$gcc_subdir/lang.opt"
5874         fi
5875         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
5876             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
5877         fi
5878         all_languages="$all_languages $language"
5879         all_compilers="$all_compilers $compilers"
5880         all_outputs="$all_outputs $outputs"
5881         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
5882         case ",$enable_languages," in
5883                 *,lto,*)
5884                     AC_DEFINE(ENABLE_LTO, 1, [Define to enable LTO support.])
5885                     enable_lto=yes
5886                     AC_SUBST(enable_lto)
5887                     ;;
5888                 *) ;;
5889         esac
5890 done
5891
5892 check_languages=
5893 for language in $all_selected_languages
5894 do
5895         check_languages="$check_languages check-$language"
5896 done
5897
5898 # We link each language in with a set of hooks, reached indirectly via
5899 # lang.${target}.  Only do so for selected languages.
5900
5901 rm -f Make-hooks
5902 touch Make-hooks
5903 target_list="all.cross start.encap rest.encap tags \
5904         install-common install-man install-info install-pdf install-html dvi \
5905         pdf html uninstall info man srcextra srcman srcinfo \
5906         mostlyclean clean distclean maintainer-clean install-plugin"
5907
5908 for t in $target_list
5909 do
5910         x=
5911         for lang in $all_selected_languages
5912         do
5913                 x="$x $lang.$t"
5914         done
5915         echo "lang.$t: $x" >> Make-hooks
5916 done
5917
5918 # --------
5919 # Option include files
5920 # --------
5921
5922 ${AWK} -f $srcdir/opt-include.awk $all_opt_files > option-includes.mk
5923 option_includes="option-includes.mk"
5924 AC_SUBST_FILE(option_includes)
5925
5926 # --------
5927 # UNSORTED
5928 # --------
5929
5930 # Create .gdbinit.
5931
5932 echo "dir ." > .gdbinit
5933 echo "dir ${srcdir}" >> .gdbinit
5934 if test x$gdb_needs_out_file_path = xyes
5935 then
5936         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
5937 fi
5938 if test "x$subdirs" != x; then
5939         for s in $subdirs
5940         do
5941                 echo "dir ${srcdir}/$s" >> .gdbinit
5942         done
5943 fi
5944 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
5945 echo "python import sys; sys.path.append('${srcdir}'); import gdbhooks" >> .gdbinit
5946
5947 # Put a breakpoint on __asan_report_error to help with debugging buffer
5948 # overflow.
5949 case "$CFLAGS" in
5950 *-fsanitize=address*)
5951   echo "source ${srcdir}/gdbasan.in" >> .gdbinit
5952   ;;
5953 esac
5954
5955 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
5956 AC_SUBST(gcc_tooldir)
5957 AC_SUBST(dollar)
5958
5959 # Find a directory in which to install a shared libgcc.
5960
5961 AC_ARG_ENABLE(version-specific-runtime-libs,
5962 [AS_HELP_STRING([--enable-version-specific-runtime-libs],
5963                 [specify that runtime libraries should be
5964                  installed in a compiler-specific directory])])
5965
5966 # Substitute configuration variables
5967 AC_SUBST(subdirs)
5968 AC_SUBST(srcdir)
5969 AC_SUBST(all_compilers)
5970 AC_SUBST(all_gtfiles)
5971 AC_SUBST(all_lang_makefrags)
5972 AC_SUBST(all_languages)
5973 AC_SUBST(all_selected_languages)
5974 AC_SUBST(build_exeext)
5975 AC_SUBST(build_install_headers_dir)
5976 AC_SUBST(build_xm_file_list)
5977 AC_SUBST(build_xm_include_list)
5978 AC_SUBST(build_xm_defines)
5979 AC_SUBST(build_file_translate)
5980 AC_SUBST(check_languages)
5981 AC_SUBST(cpp_install_dir)
5982 AC_SUBST(xmake_file)
5983 AC_SUBST(tmake_file)
5984 AC_SUBST(TM_ENDIAN_CONFIG)
5985 AC_SUBST(TM_MULTILIB_CONFIG)
5986 AC_SUBST(TM_MULTILIB_EXCEPTIONS_CONFIG)
5987 AC_SUBST(extra_gcc_objs)
5988 AC_SUBST(user_headers_inc_next_pre)
5989 AC_SUBST(user_headers_inc_next_post)
5990 AC_SUBST(extra_headers_list)
5991 AC_SUBST(extra_objs)
5992 AC_SUBST(extra_programs)
5993 AC_SUBST(float_h_file)
5994 AC_SUBST(gcc_config_arguments)
5995 AC_SUBST(gcc_gxx_include_dir)
5996 AC_SUBST(gcc_gxx_include_dir_add_sysroot)
5997 AC_SUBST(host_exeext)
5998 AC_SUBST(host_xm_file_list)
5999 AC_SUBST(host_xm_include_list)
6000 AC_SUBST(host_xm_defines)
6001 AC_SUBST(out_host_hook_obj)
6002 AC_SUBST(install)
6003 AC_SUBST(lang_opt_files)
6004 AC_SUBST(lang_specs_files)
6005 AC_SUBST(lang_tree_files)
6006 AC_SUBST(local_prefix)
6007 AC_SUBST(md_file)
6008 AC_SUBST(objc_boehm_gc)
6009 AC_SUBST(out_file)
6010 AC_SUBST(out_object_file)
6011 AC_SUBST(common_out_file)
6012 AC_SUBST(common_out_object_file)
6013 AC_SUBST(tm_file_list)
6014 AC_SUBST(tm_include_list)
6015 AC_SUBST(tm_defines)
6016 AC_SUBST(tm_p_file_list)
6017 AC_SUBST(tm_p_include_list)
6018 AC_SUBST(xm_file_list)
6019 AC_SUBST(xm_include_list)
6020 AC_SUBST(xm_defines)
6021 AC_SUBST(use_gcc_stdint)
6022 AC_SUBST(c_target_objs)
6023 AC_SUBST(cxx_target_objs)
6024 AC_SUBST(fortran_target_objs)
6025 AC_SUBST(target_cpu_default)
6026
6027 AC_SUBST_FILE(language_hooks)
6028
6029 # Echo link setup.
6030 if test x${build} = x${host} ; then
6031   if test x${host} = x${target} ; then
6032     echo "Links are now set up to build a native compiler for ${target}." 1>&2
6033   else
6034     echo "Links are now set up to build a cross-compiler" 1>&2
6035     echo " from ${host} to ${target}." 1>&2
6036   fi
6037 else
6038   if test x${host} = x${target} ; then
6039     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
6040     echo " for ${target}." 1>&2
6041   else
6042     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
6043     echo " from ${host} to ${target}." 1>&2
6044   fi
6045 fi
6046
6047 AC_ARG_VAR(GMPLIBS,[How to link GMP])
6048 AC_ARG_VAR(GMPINC,[How to find GMP include files])
6049
6050 AC_ARG_VAR(ISLLIBS,[How to link isl])
6051 AC_ARG_VAR(ISLINC,[How to find isl include files])
6052 if test "x${ISLLIBS}" != "x" ; then
6053    AC_DEFINE(HAVE_isl, 1, [Define if isl is in use.])
6054 fi
6055
6056 # Check whether isl_options_set_schedule_serialize_sccs is available;
6057 # it's new in isl 0.15.
6058 if test "x${ISLLIBS}" != "x" ; then
6059   saved_CXXFLAGS="$CXXFLAGS"
6060   CXXFLAGS="$CXXFLAGS $ISLINC $GMPINC"
6061   saved_LIBS="$LIBS"
6062   LIBS="$LIBS $ISLLIBS $GMPLIBS"
6063
6064   AC_MSG_CHECKING([Checking for isl_options_set_schedule_serialize_sccs])
6065   AC_TRY_LINK([#include <isl/schedule.h>],
6066               [isl_options_set_schedule_serialize_sccs (NULL, 0);],
6067               [ac_has_isl_options_set_schedule_serialize_sccs=yes],
6068               [ac_has_isl_options_set_schedule_serialize_sccs=no])
6069   AC_MSG_RESULT($ac_has_isl_options_set_schedule_serialize_sccs)
6070
6071   LIBS="$saved_LIBS"
6072   CXXFLAGS="$saved_CXXFLAGS"
6073
6074   if test x"$ac_has_isl_options_set_schedule_serialize_sccs" = x"yes"; then
6075      AC_DEFINE(HAVE_ISL_OPTIONS_SET_SCHEDULE_SERIALIZE_SCCS, 1,
6076                [Define if isl_options_set_schedule_serialize_sccs exists.])
6077   fi
6078 fi
6079
6080 GCC_ENABLE_PLUGINS
6081 AC_SUBST(pluginlibs)
6082 AC_SUBST(enable_plugin)
6083 if test x"$enable_plugin" = x"yes"; then
6084   AC_DEFINE(ENABLE_PLUGIN, 1, [Define to enable plugin support.])
6085 fi
6086
6087
6088 # Enable --enable-host-shared
6089 AC_ARG_ENABLE(host-shared,
6090 [AS_HELP_STRING([--enable-host-shared],
6091                 [build host code as shared libraries])],
6092 [PICFLAG=-fPIC], [PICFLAG=])
6093 AC_SUBST(enable_host_shared)
6094 AC_SUBST(PICFLAG)
6095
6096
6097 AC_ARG_ENABLE(libquadmath-support,
6098 [AS_HELP_STRING([--disable-libquadmath-support],
6099   [disable libquadmath support for Fortran])],
6100 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
6101 ENABLE_LIBQUADMATH_SUPPORT=yes)
6102 if test "${ENABLE_LIBQUADMATH_SUPPORT}" != "no" ; then
6103   AC_DEFINE(ENABLE_LIBQUADMATH_SUPPORT, 1,
6104             [Define to 1 to enable libquadmath support])
6105 fi
6106
6107
6108 # Specify what hash style to use by default.
6109 AC_ARG_WITH([linker-hash-style],
6110 [AC_HELP_STRING([--with-linker-hash-style={sysv,gnu,both}],
6111                 [specify the linker hash style])],
6112 [case x"$withval" in
6113    xsysv)
6114      LINKER_HASH_STYLE=sysv
6115      ;;
6116    xgnu)
6117      LINKER_HASH_STYLE=gnu
6118      ;;
6119    xboth)
6120      LINKER_HASH_STYLE=both
6121      ;;
6122    *)
6123      AC_MSG_ERROR([$withval is an invalid option to --with-linker-hash-style])
6124      ;;
6125  esac],
6126 [LINKER_HASH_STYLE=''])
6127 if test x"${LINKER_HASH_STYLE}" != x; then
6128   AC_DEFINE_UNQUOTED(LINKER_HASH_STYLE, "$LINKER_HASH_STYLE",
6129                                          [The linker hash style])
6130 fi
6131
6132 # Specify what should be the default of -fdiagnostics-color option.
6133 AC_ARG_WITH([diagnostics-color],
6134 [AC_HELP_STRING([--with-diagnostics-color={never,auto,auto-if-env,always}],
6135                 [specify the default of -fdiagnostics-color option
6136                  auto-if-env stands for -fdiagnostics-color=auto if
6137                  GCC_COLOR environment variable is present and
6138                  -fdiagnostics-color=never otherwise])],
6139 [case x"$withval" in
6140    xnever)
6141      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_NO
6142      ;;
6143    xauto)
6144      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO
6145      ;;
6146    xauto-if-env)
6147      DIAGNOSTICS_COLOR_DEFAULT=-1
6148      ;;
6149    xalways)
6150      DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_YES
6151      ;;
6152    *)
6153      AC_MSG_ERROR([$withval is an invalid option to --with-diagnostics-color])
6154      ;;
6155  esac],
6156 [DIAGNOSTICS_COLOR_DEFAULT=DIAGNOSTICS_COLOR_AUTO])
6157 AC_DEFINE_UNQUOTED(DIAGNOSTICS_COLOR_DEFAULT, $DIAGNOSTICS_COLOR_DEFAULT,
6158                    [The default for -fdiagnostics-color option])
6159
6160 # Generate gcc-driver-name.h containing GCC_DRIVER_NAME for the benefit
6161 # of jit/jit-playback.c.
6162 cat > gcc-driver-name.h <<EOF
6163 #define GCC_DRIVER_NAME "${target_noncanonical}-gcc-${gcc_BASEVER}${exeext}"
6164 EOF
6165
6166 # Check whether --enable-default-pie was given.
6167 AC_ARG_ENABLE(default-pie,
6168 [AS_HELP_STRING([--enable-default-pie],
6169   [enable Position Independent Executable as default])],
6170 enable_default_pie=$enableval,
6171 enable_default_pie=no)
6172 if test x$enable_default_pie = xyes ; then
6173   AC_DEFINE(ENABLE_DEFAULT_PIE, 1,
6174       [Define if your target supports default PIE and it is enabled.])
6175 fi
6176 AC_SUBST([enable_default_pie])
6177
6178 # Check if -fno-PIE works.
6179 AC_CACHE_CHECK([for -fno-PIE option],
6180   [gcc_cv_c_no_fpie],
6181   [saved_CXXFLAGS="$CXXFLAGS"
6182    CXXFLAGS="$CXXFLAGS -fno-PIE"
6183    AC_COMPILE_IFELSE([int main(void) {return 0;}],
6184      [gcc_cv_c_no_fpie=yes],
6185      [gcc_cv_c_no_fpie=no])
6186    CXXFLAGS="$saved_CXXFLAGS"])
6187 if test "$gcc_cv_c_no_fpie" = "yes"; then
6188   NO_PIE_CFLAGS="-fno-PIE"
6189 fi
6190 AC_SUBST([NO_PIE_CFLAGS])
6191
6192 # Check if -no-pie works.
6193 AC_CACHE_CHECK([for -no-pie option],
6194   [gcc_cv_no_pie],
6195   [saved_LDFLAGS="$LDFLAGS"
6196    LDFLAGS="$LDFLAGS -no-pie"
6197    AC_LINK_IFELSE([int main(void) {return 0;}],
6198      [gcc_cv_no_pie=yes],
6199      [gcc_cv_no_pie=no])
6200    LDFLAGS="$saved_LDFLAGS"])
6201 if test "$gcc_cv_no_pie" = "yes"; then
6202   NO_PIE_FLAG="-no-pie"
6203 fi
6204 AC_SUBST([NO_PIE_FLAG])
6205
6206 # Check linker supports '-z bndplt'
6207 ld_bndplt_support=no
6208 AC_MSG_CHECKING(linker -z bndplt option)
6209 if test x"$ld_is_gold" = xno; then
6210   if test $in_tree_ld = yes ; then
6211     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 25 -o "$gcc_cv_gld_major_version" -gt 2; then
6212       ld_bndplt_support=yes
6213     fi
6214   elif test x$gcc_cv_ld != x; then
6215     # Check if linker supports -a bndplt option
6216     if $gcc_cv_ld --help 2>/dev/null | grep -- '-z bndplt' > /dev/null; then
6217       ld_bndplt_support=yes
6218     fi
6219   fi
6220 fi
6221 if test x"$ld_bndplt_support" = xyes; then
6222   AC_DEFINE(HAVE_LD_BNDPLT_SUPPORT, 1,
6223         [Define if your linker supports -z bndplt])
6224 fi
6225 AC_MSG_RESULT($ld_bndplt_support)
6226
6227 # Configure the subdirectories
6228 # AC_CONFIG_SUBDIRS($subdirs)
6229
6230 # Create the Makefile
6231 # and configure language subdirectories
6232 AC_CONFIG_FILES($all_outputs)
6233
6234 AC_CONFIG_COMMANDS([default],
6235 [
6236 case ${CONFIG_HEADERS} in
6237   *auto-host.h:config.in*)
6238   echo > cstamp-h ;;
6239 esac
6240 # Make sure all the subdirs exist.
6241 for d in $subdirs doc build common c-family
6242 do
6243     test -d $d || mkdir $d
6244 done
6245 ],
6246 [subdirs='$subdirs'])
6247 AC_OUTPUT
6248