gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 # autoconf is lame and doesn't give us any substitution variable for this.
 280 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 281   NO_MINUS_C_MINUS_O=yes
 282 else
 283   OUTPUT_OPTION='-o $@'
 284 fi
 285 AC_SUBST(NO_MINUS_C_MINUS_O)
 286 AC_SUBST(OUTPUT_OPTION)
 287
 288 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 289 # optimizations to be activated explicitly by the toplevel.
 290 case "$CC" in
 291   */prev-gcc/xgcc*) ;;
 292   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 293 esac
 294 AC_SUBST(CFLAGS)
 295
 296 # -------------------------
 297 # Check C compiler features
 298 # -------------------------
 299
 300 AC_PROG_CPP
 301 AC_C_INLINE
 302
 303 # sizeof(char) is 1 by definition.
 304 AC_CHECK_SIZEOF(void *)
 305 AC_CHECK_SIZEOF(short)
 306 AC_CHECK_SIZEOF(int)
 307 AC_CHECK_SIZEOF(long)
 308 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 309 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 310
 311 # ---------------------
 312 # Warnings and checking
 313 # ---------------------
 314
 315 # Check $CC warning features (if it's GCC).
 316 # We want to use -pedantic, but we don't want warnings about
 317 # * 'long long'
 318 # * variadic macros
 319 # * overlong strings
 320 # So, we only use -pedantic if we can disable those warnings.
 321
 322 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 323                           -Wmissing-prototypes], [loose_warn])
 324 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 325 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 326                           -Wmissing-format-attribute], [strict_warn])
 327 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 328                                      -Wno-overlength-strings], [strict_warn])
 329 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 330
 331 # The above macros do nothing if the compiler is not GCC.  However, the
 332 # Makefile has more goo to add other flags, so this variabl is used to
 333 # enables warnings only for GCC.
 334 warn_cflags=
 335 if test "x$GCC" = "xyes"; then
 336   warn_cflags='$(GCC_WARN_CFLAGS)'
 337 fi
 338 AC_SUBST(warn_cflags)
 339
 340 # Enable expensive internal checks
 341 is_release=
 342 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 343   is_release=yes
 344 fi
 345
 346 AC_ARG_ENABLE(checking,
 347 [  --enable-checking[=LIST]
 348                           enable expensive run-time checks.  With LIST,
 349                           enable only specific categories of checks.
 350                           Categories are: yes,no,all,none,release.
 351                           Flags are: assert,df,fold,gc,gcac,misc,
 352                           rtlflag,rtl,runtime,tree,valgrind,types.],
 353 [ac_checking_flags="${enableval}"],[
 354 # Determine the default checks.
 355 if test x$is_release = x ; then
 356   ac_checking_flags=yes
 357 else
 358   ac_checking_flags=release
 359 fi])
 360 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 361 for check in release $ac_checking_flags
 362 do
 363         case $check in
 364         # these set all the flags to specific states
 365         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 366                         ac_fold_checking= ; ac_gc_checking=1 ;
 367                         ac_gc_always_collect= ; ac_rtl_checking= ;
 368                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 369                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 370                         ac_types_checking= ;;
 371         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 372                         ac_fold_checking= ; ac_gc_checking= ;
 373                         ac_gc_always_collect= ; ac_rtl_checking= ;
 374                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 375                         ac_tree_checking= ; ac_valgrind_checking= ;
 376                         ac_types_checking= ;;
 377         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 378                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 379                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 380                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 381                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 382                         ac_types_checking=1 ;;
 383         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 384                         ac_fold_checking= ; ac_gc_checking= ;
 385                         ac_gc_always_collect= ; ac_rtl_checking= ;
 386                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 387                         ac_tree_checking= ; ac_valgrind_checking= ;
 388                         ac_types_checking= ;;
 389         # these enable particular checks
 390         assert)         ac_assert_checking=1 ;;
 391         df)             ac_df_checking=1 ;;
 392         fold)           ac_fold_checking=1 ;;
 393         gc)             ac_gc_checking=1 ;;
 394         gcac)           ac_gc_always_collect=1 ;;
 395         misc)           ac_checking=1 ;;
 396         rtl)            ac_rtl_checking=1 ;;
 397         rtlflag)        ac_rtlflag_checking=1 ;;
 398         runtime)        ac_runtime_checking=1 ;;
 399         tree)           ac_tree_checking=1 ;;
 400         types)          ac_types_checking=1 ;;
 401         valgrind)       ac_valgrind_checking=1 ;;
 402         *)      AC_MSG_ERROR(unknown check category $check) ;;
 403         esac
 404 done
 405 IFS="$ac_save_IFS"
 406
 407 nocommon_flag=""
 408 if test x$ac_checking != x ; then
 409   AC_DEFINE(ENABLE_CHECKING, 1,
 410 [Define if you want more run-time sanity checks.  This one gets a grab
 411    bag of miscellaneous but relatively cheap checks.])
 412   nocommon_flag=-fno-common
 413 fi
 414 AC_SUBST(nocommon_flag)
 415 if test x$ac_df_checking != x ; then
 416   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 417 [Define if you want more run-time sanity checks for dataflow.])
 418 fi
 419 if test x$ac_assert_checking != x ; then
 420   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 421 [Define if you want assertions enabled.  This is a cheap check.])
 422 fi
 423 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 424 if test x$ac_runtime_checking != x ; then
 425   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 426 [Define if you want runtime assertions enabled.  This is a cheap check.])
 427 fi
 428 if test x$ac_tree_checking != x ; then
 429   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 430 [Define if you want all operations on trees (the basic data
 431    structure of the front ends) to be checked for dynamic type safety
 432    at runtime.  This is moderately expensive.  The tree browser debugging
 433    routines will also be enabled by this option.
 434    ])
 435   TREEBROWSER=tree-browser.o
 436 fi
 437 if test x$ac_types_checking != x ; then
 438   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 439 [Define if you want all gimple types to be verified after gimplifiation.
 440    This is cheap.
 441    ])
 442 fi
 443 AC_SUBST(TREEBROWSER)
 444 if test x$ac_rtl_checking != x ; then
 445   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 446 [Define if you want all operations on RTL (the basic data structure
 447    of the optimizer and back end) to be checked for dynamic type safety
 448    at runtime.  This is quite expensive.])
 449 fi
 450 if test x$ac_rtlflag_checking != x ; then
 451   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 452 [Define if you want RTL flag accesses to be checked against the RTL
 453    codes that are supported for each access macro.  This is relatively
 454    cheap.])
 455 fi
 456 if test x$ac_gc_checking != x ; then
 457   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 458 [Define if you want the garbage collector to do object poisoning and
 459    other memory allocation checks.  This is quite expensive.])
 460 fi
 461 if test x$ac_gc_always_collect != x ; then
 462   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 463 [Define if you want the garbage collector to operate in maximally
 464    paranoid mode, validating the entire heap and collecting garbage at
 465    every opportunity.  This is extremely expensive.])
 466 fi
 467 if test x$ac_fold_checking != x ; then
 468   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 469 [Define if you want fold checked that it never destructs its argument.
 470    This is quite expensive.])
 471 fi
 472 valgrind_path_defines=
 473 valgrind_command=
 474
 475 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 476 dnl # an if statement.  This was the source of very frustrating bugs
 477 dnl # in converting to autoconf 2.5x!
 478 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 479
 480 if test x$ac_valgrind_checking != x ; then
 481   # It is certainly possible that there's valgrind but no valgrind.h.
 482   # GCC relies on making annotations so we must have both.
 483   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 484   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 485     [[#include <valgrind/memcheck.h>
 486 #ifndef VALGRIND_DISCARD
 487 #error VALGRIND_DISCARD not defined
 488 #endif]])],
 489   [gcc_cv_header_valgrind_memcheck_h=yes],
 490   [gcc_cv_header_valgrind_memcheck_h=no])
 491   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 492   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 493   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 494     [[#include <memcheck.h>
 495 #ifndef VALGRIND_DISCARD
 496 #error VALGRIND_DISCARD not defined
 497 #endif]])],
 498   [gcc_cv_header_memcheck_h=yes],
 499   [gcc_cv_header_memcheck_h=no])
 500   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 501   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 502         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 503   if test "x$valgrind_path" = "x" \
 504     || (test $have_valgrind_h = no \
 505         && test $gcc_cv_header_memcheck_h = no \
 506         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 507         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 508   fi
 509   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 510   valgrind_command="$valgrind_path -q"
 511   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 512 [Define if you want to run subprograms and generated programs
 513    through valgrind (a memory checker).  This is extremely expensive.])
 514   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 515     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 516         [Define if valgrind's valgrind/memcheck.h header is installed.])
 517   fi
 518   if test $gcc_cv_header_memcheck_h = yes; then
 519     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 520         [Define if valgrind's memcheck.h header is installed.])
 521   fi
 522 fi
 523 AC_SUBST(valgrind_path_defines)
 524 AC_SUBST(valgrind_command)
 525
 526 AC_ARG_ENABLE(mapped-location,
 527 [  --enable-mapped-location   location_t is fileline integer cookie],,
 528 enable_mapped_location=yes)
 529
 530 if test "$enable_mapped_location" = yes ; then
 531   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 532 [Define if location_t is fileline integer cookie.])
 533 fi
 534
 535 # Enable code coverage collection
 536 AC_ARG_ENABLE(coverage,
 537 [  --enable-coverage[=LEVEL]
 538                           enable compiler's code coverage collection.
 539                           Use to measure compiler performance and locate
 540                           unused parts of the compiler. With LEVEL, specify
 541                           optimization. Values are opt, noopt,
 542                           default is noopt],
 543 [case "${enableval}" in
 544   yes|noopt)
 545     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 546     ;;
 547   opt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 549     ;;
 550   no)
 551     # a.k.a. --disable-coverage
 552     coverage_flags=""
 553     ;;
 554   *)
 555     AC_MSG_ERROR(unknown coverage setting $enableval)
 556     ;;
 557 esac],
 558 [coverage_flags=""])
 559 AC_SUBST(coverage_flags)
 560
 561 AC_ARG_ENABLE(gather-detailed-mem-stats,
 562 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 563 [enable_gather_detailed_mem_stats=no])
 564 if test x$enable_gather_detailed_mem_stats = xyes ; then
 565   AC_DEFINE(GATHER_STATISTICS, 1,
 566         [Define to enable detailed memory allocation stats gathering.])
 567 fi
 568
 569 # -------------------------------
 570 # Miscenalleous configure options
 571 # -------------------------------
 572
 573 # With stabs
 574 AC_ARG_WITH(stabs,
 575 [  --with-stabs            arrange to use stabs instead of host debug format],
 576 stabs="$with_stabs",
 577 stabs=no)
 578
 579 # Determine whether or not multilibs are enabled.
 580 AC_ARG_ENABLE(multilib,
 581 [  --enable-multilib       enable library support for multiple ABIs],
 582 [], [enable_multilib=yes])
 583 AC_SUBST(enable_multilib)
 584
 585 # Enable __cxa_atexit for C++.
 586 AC_ARG_ENABLE(__cxa_atexit,
 587 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 588 [], [])
 589
 590 # Enable C extension for decimal float if target supports it.
 591 AC_ARG_ENABLE(decimal-float,
 592 [  --enable-decimal-float={no,yes,bid,dpd}
 593                         enable decimal float extension to C.  Selecting 'bid'
 594                         or 'dpd' choses which decimal floating point format
 595                         to use],
 596 [
 597   case $enable_decimal_float in
 598     yes | no | bid | dpd) ;;
 599     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 600 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 601   esac
 602 ],
 603 [
 604   case $target in
 605     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 606       enable_decimal_float=yes
 607       ;;
 608     *)
 609       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 610       enable_decimal_float=no
 611       ;;
 612   esac
 613 ])
 614
 615 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 616 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 617 [Define to 1 to enable decimal float extension to C.])
 618
 619 # x86's use BID format instead of DPD
 620 case x$enable_decimal_float in
 621   xyes)
 622     case $target in
 623       i?86*-*-linux* | x86_64*-*-linux*)
 624         enable_decimal_float=bid
 625         ;;
 626       *)
 627         enable_decimal_float=dpd
 628         ;;
 629     esac
 630     ;;
 631   xno)
 632     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 633     # dependency on libdecnumber.
 634     enable_decimal_float=dpd
 635     ;;
 636 esac
 637 AC_SUBST(enable_decimal_float)
 638
 639 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 640 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 641 [Define to 1 to specify that we are using the BID decimal floating
 642 point format instead of DPD])
 643
 644 # Enable C extension for fixed-point arithmetic.
 645 AC_ARG_ENABLE(fixed-point,
 646 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 647 [
 648 ],
 649 [
 650   case $target in
 651     mips*-*-*)
 652       enable_fixed_point=yes
 653       ;;
 654     *)
 655       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 656       enable_fixed_point=no
 657       ;;
 658   esac
 659 ])
 660 AC_SUBST(enable_fixed_point)
 661
 662 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 663 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 664 [Define to 1 to enable fixed-point arithmetic extension to C.])
 665
 666 # Enable threads
 667 # Pass with no value to take the default
 668 # Pass with a value to specify a thread package
 669 AC_ARG_ENABLE(threads,
 670 [  --enable-threads        enable thread usage for target GCC
 671   --enable-threads=LIB    use LIB thread package for target GCC],,
 672 [enable_threads=''])
 673
 674 AC_ARG_ENABLE(tls,
 675 [  --enable-tls            enable or disable generation of tls code
 676                           overriding the assembler check for tls support],
 677 [
 678   case $enable_tls in
 679     yes | no) ;;
 680     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 681 Valid choices are 'yes' and 'no'.]) ;;
 682   esac
 683 ], [enable_tls=''])
 684
 685 AC_ARG_ENABLE(objc-gc,
 686 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 687                           the GNU Objective-C runtime],
 688 if test x$enable_objc_gc = xno; then
 689         objc_boehm_gc=''
 690 else
 691         objc_boehm_gc=1
 692 fi,
 693 objc_boehm_gc='')
 694
 695 AC_ARG_WITH(dwarf2,
 696 [  --with-dwarf2           force the default debug format to be DWARF 2],
 697 dwarf2="$with_dwarf2",
 698 dwarf2=no)
 699
 700 AC_ARG_ENABLE(shared,
 701 [  --disable-shared        don't provide a shared libgcc],
 702 [
 703   case $enable_shared in
 704   yes | no) ;;
 705   *)
 706     enable_shared=no
 707     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 708     for pkg in $enableval; do
 709       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 710         enable_shared=yes
 711       fi
 712     done
 713     IFS="$ac_save_ifs"
 714     ;;
 715   esac
 716 ], [enable_shared=yes])
 717 AC_SUBST(enable_shared)
 718
 719 AC_ARG_WITH(build-sysroot,
 720   [  --with-build-sysroot=sysroot
 721                           use sysroot as the system root during the build])
 722
 723 AC_ARG_WITH(sysroot,
 724 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 725 [
 726  case ${with_sysroot} in
 727  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 728  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 729  esac
 730
 731  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 732  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 733
 734  if test "x$prefix" = xNONE; then
 735   test_prefix=/usr/local
 736  else
 737   test_prefix=$prefix
 738  fi
 739  if test "x$exec_prefix" = xNONE; then
 740   test_exec_prefix=$test_prefix
 741  else
 742   test_exec_prefix=$exec_prefix
 743  fi
 744  case ${TARGET_SYSTEM_ROOT} in
 745  "${test_prefix}"|"${test_prefix}/"*|\
 746  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 747  '${prefix}'|'${prefix}/'*|\
 748  '${exec_prefix}'|'${exec_prefix}/'*)
 749    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 750    TARGET_SYSTEM_ROOT_DEFINE="$t"
 751    ;;
 752  esac
 753 ], [
 754  TARGET_SYSTEM_ROOT=
 755  TARGET_SYSTEM_ROOT_DEFINE=
 756  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 757 ])
 758 AC_SUBST(TARGET_SYSTEM_ROOT)
 759 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 760 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 761
 762 # Build with intermodule optimisations
 763 AC_ARG_ENABLE(intermodule,
 764 [  --enable-intermodule    build the compiler in one step],
 765 [case ${enable_intermodule} in
 766   yes) onestep="-onestep";;
 767   *) onestep="";;
 768 esac],
 769 [onestep=""])
 770 AC_SUBST(onestep)
 771
 772 ACX_PKGVERSION([GCC])
 773 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 774
 775 # Sanity check enable_languages in case someone does not run the toplevel
 776 # configure # script.
 777 AC_ARG_ENABLE(languages,
 778 [  --enable-languages=LIST specify which front-ends to build],
 779 [case ,${enable_languages}, in
 780        ,,|,yes,)
 781                 # go safe -- we cannot be much sure without the toplevel
 782                 # configure's
 783                 # analysis of which target libs are present and usable
 784                 enable_languages=c
 785                 ;;
 786          *,all,*)
 787                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 788                 ;;
 789         *,c,*)
 790                 ;;
 791         *)
 792                 enable_languages=c,${enable_languages}
 793                 ;;
 794 esac],
 795 [enable_languages=c])
 796
 797 # Used by documentation targets
 798 AC_SUBST(datarootdir)
 799 AC_SUBST(docdir)
 800 AC_SUBST(htmldir)
 801
 802 # -------------------------
 803 # Checks for other programs
 804 # -------------------------
 805
 806 AC_PROG_MAKE_SET
 807
 808 # Find some useful tools
 809 AC_PROG_AWK
 810 # We need awk to create options.c and options.h.
 811 # Bail out if it's missing.
 812 case ${AWK} in
 813   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 814 esac
 815
 816 gcc_AC_PROG_LN_S
 817 ACX_PROG_LN($LN_S)
 818 AC_PROG_RANLIB
 819 case "${host}" in
 820 *-*-darwin*)
 821   # By default, the Darwin ranlib will not treat common symbols as
 822   # definitions when  building the archive table of contents.  Other
 823   # ranlibs do that; pass an option to the Darwin ranlib that makes
 824   # it behave similarly.
 825   ranlib_flags="-c"
 826   ;;
 827 *)
 828   ranlib_flags=""
 829 esac
 830 AC_SUBST(ranlib_flags)
 831
 832 gcc_AC_PROG_INSTALL
 833
 834 # See if cmp has --ignore-initial.
 835 gcc_AC_PROG_CMP_IGNORE_INITIAL
 836
 837 # See if we have the mktemp command.
 838 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 839
 840 # See if makeinfo has been installed and is modern enough
 841 # that we can use it.
 842 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 843   [GNU texinfo.* \([0-9][0-9.]*\)],
 844   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 845 if test $gcc_cv_prog_makeinfo_modern = no; then
 846   AC_MSG_WARN([
 847 *** Makeinfo is missing or too old.
 848 *** Info documentation will not be built.])
 849   BUILD_INFO=
 850 else
 851   BUILD_INFO=info
 852 fi
 853 AC_SUBST(BUILD_INFO)
 854
 855 # Is pod2man recent enough to regenerate manpages?
 856 AC_MSG_CHECKING([for recent Pod::Man])
 857 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 858   AC_MSG_RESULT(yes)
 859   GENERATED_MANPAGES=generated-manpages
 860 else
 861   AC_MSG_RESULT(no)
 862   GENERATED_MANPAGES=
 863 fi
 864 AC_SUBST(GENERATED_MANPAGES)
 865
 866 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 867
 868 # How about lex?
 869 dnl Don't use AC_PROG_LEX; we insist on flex.
 870 dnl LEXLIB is not useful in gcc.
 871 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 872
 873 # Bison?
 874 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 875
 876 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 877 # check for build == host before using them.
 878
 879 # NM
 880 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 881   && test -d ../binutils ; then
 882   NM='$(objdir)/../binutils/nm-new'
 883 else
 884   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 885 fi
 886
 887 # AR
 888 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 889   && test -d ../binutils ; then
 890   AR='$(objdir)/../binutils/ar'
 891 else
 892   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 893 fi
 894
 895
 896 # --------------------
 897 # Checks for C headers
 898 # --------------------
 899
 900 AC_MSG_CHECKING(for GNU C library)
 901 AC_CACHE_VAL(gcc_cv_glibc,
 902 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 903   [[#include <features.h>]], [[
 904 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 905 #error Not a GNU C library system
 906 #endif]])],
 907   [gcc_cv_glibc=yes],
 908   [gcc_cv_glibc=no])])
 909 AC_MSG_RESULT($gcc_cv_glibc)
 910 if test $gcc_cv_glibc = yes; then
 911   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 912 fi
 913
 914 # Need to reject headers which give warnings, so that the -Werror bootstrap
 915 # works later. *sigh*  This needs to come before all header checks.
 916 AC_PROG_CPP_WERROR
 917
 918 AC_HEADER_STDC
 919 AC_HEADER_TIME
 920 ACX_HEADER_STRING
 921 AC_HEADER_SYS_WAIT
 922 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 923                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 924                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 925                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 926
 927 # Check for thread headers.
 928 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 929 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 930
 931 # These tests can't be done till we know if we have limits.h.
 932 gcc_AC_C_CHAR_BIT
 933 AC_C_BIGENDIAN
 934
 935 # --------
 936 # UNSORTED
 937 # --------
 938
 939
 940 # These libraries may be used by collect2.
 941 # We may need a special search path to get them linked.
 942 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 943 [save_LIBS="$LIBS"
 944 for libs in '' -lld -lmld \
 945                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 946                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 947 do
 948         LIBS="$libs"
 949         AC_TRY_LINK_FUNC(ldopen,
 950                 [gcc_cv_collect2_libs="$libs"; break])
 951 done
 952 LIBS="$save_LIBS"
 953 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 954 case $gcc_cv_collect2_libs in
 955         "none required")        ;;
 956         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 957 esac
 958 AC_SUBST(COLLECT2_LIBS)
 959
 960 # When building Ada code on Alpha, we need exc_resume which is usually in
 961 # -lexc.  So test for it.
 962 save_LIBS="$LIBS"
 963 LIBS=
 964 AC_SEARCH_LIBS(exc_resume, exc)
 965 GNAT_LIBEXC="$LIBS"
 966 LIBS="$save_LIBS"
 967 AC_SUBST(GNAT_LIBEXC)
 968
 969 # Some systems put ldexp and frexp in libm instead of libc; assume
 970 # they're both in the same place.  jcf-dump needs them.
 971 save_LIBS="$LIBS"
 972 LIBS=
 973 AC_SEARCH_LIBS(ldexp, m)
 974 LDEXP_LIB="$LIBS"
 975 LIBS="$save_LIBS"
 976 AC_SUBST(LDEXP_LIB)
 977
 978 # Use <inttypes.h> only if it exists,
 979 # doesn't clash with <sys/types.h>, and declares intmax_t.
 980 AC_MSG_CHECKING(for inttypes.h)
 981 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 982 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 983 [[#include <sys/types.h>
 984 #include <inttypes.h>]],
 985   [[intmax_t i = -1;]])],
 986   [gcc_cv_header_inttypes_h=yes],
 987   [gcc_cv_header_inttypes_h=no])])
 988 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 989 if test $gcc_cv_header_inttypes_h = yes; then
 990   AC_DEFINE(HAVE_INTTYPES_H, 1,
 991         [Define if you have a working <inttypes.h> header file.])
 992 fi
 993
 994 dnl Disabled until we have a complete test for buggy enum bitfields.
 995 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 996
 997 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 998   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 999   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1000   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1001   putchar_unlocked putc_unlocked)
1002 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1003         sysconf strsignal getrusage nl_langinfo scandir alphasort \
1004         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1005         gcc_UNLOCKED_FUNCS)
1006
1007 if test x$ac_cv_func_mbstowcs = xyes; then
1008   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1009 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1010 int main()
1011 {
1012   mbstowcs(0, "", 0);
1013   return 0;
1014 }]])],
1015     [gcc_cv_func_mbstowcs_works=yes],
1016     [gcc_cv_func_mbstowcs_works=no],
1017     [gcc_cv_func_mbstowcs_works=yes])])
1018   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1019     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1020   [Define this macro if mbstowcs does not crash when its
1021    first argument is NULL.])
1022   fi
1023 fi
1024
1025 AC_CHECK_TYPE(ssize_t, int)
1026
1027 # Try to determine the array type of the second argument of getgroups
1028 # for the target system (int or gid_t).
1029 AC_TYPE_GETGROUPS
1030 if test "${target}" = "${build}"; then
1031   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1032 else
1033   case "${target}" in
1034         # This condition may need some tweaking.  It should include all
1035         # targets where the array type of the second argument of getgroups
1036         # is int and the type of gid_t is not equivalent to int.
1037         *-*-sunos* | *-*-ultrix*)
1038                 TARGET_GETGROUPS_T=int
1039                 ;;
1040         *)
1041                 TARGET_GETGROUPS_T=gid_t
1042                 ;;
1043   esac
1044 fi
1045 AC_SUBST(TARGET_GETGROUPS_T)
1046
1047 gcc_AC_FUNC_MMAP_BLACKLIST
1048
1049 case "${host}" in
1050 *-*-*vms*)
1051   # Under VMS, vfork works very differently than on Unix. The standard test
1052   # won't work, and it isn't easily adaptable. It makes more sense to
1053   # just force it.
1054   ac_cv_func_vfork_works=yes
1055   ;;
1056 esac
1057 AC_FUNC_FORK
1058
1059 AM_ICONV
1060 # Until we have in-tree GNU iconv:
1061 LIBICONV_DEP=
1062 AC_SUBST(LIBICONV_DEP)
1063
1064 AM_LC_MESSAGES
1065
1066 AM_LANGINFO_CODESET
1067
1068 # We will need to find libiberty.h and ansidecl.h
1069 saved_CFLAGS="$CFLAGS"
1070 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1071 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1072         strsignal strstr strverscmp \
1073         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1074         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1075 #include "ansidecl.h"
1076 #include "system.h"])
1077
1078 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1079 #include "ansidecl.h"
1080 #include "system.h"
1081 #ifdef HAVE_SYS_RESOURCE_H
1082 #include <sys/resource.h>
1083 #endif
1084 ])
1085
1086 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1087 #include "ansidecl.h"
1088 #include "system.h"
1089 #ifdef HAVE_SYS_RESOURCE_H
1090 #include <sys/resource.h>
1091 #endif
1092 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1093 [Define to \`long' if <sys/resource.h> doesn't define.])])
1094
1095 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1096 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1097 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1098 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1099 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1100 #include "ansidecl.h"
1101 #include "system.h"
1102 #ifdef HAVE_LDFCN_H
1103 #undef FREAD
1104 #undef FWRITE
1105 #include <ldfcn.h>
1106 #endif
1107 ])
1108
1109 gcc_AC_CHECK_DECLS(times, , ,[
1110 #include "ansidecl.h"
1111 #include "system.h"
1112 #ifdef HAVE_SYS_TIMES_H
1113 #include <sys/times.h>
1114 #endif
1115 ])
1116
1117 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1118 #include "ansidecl.h"
1119 #include "system.h"
1120 #include <signal.h>
1121 ])
1122
1123 # More time-related stuff.
1124 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1125 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1126 #include "ansidecl.h"
1127 #include "system.h"
1128 #ifdef HAVE_SYS_TIMES_H
1129 #include <sys/times.h>
1130 #endif
1131 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1132 if test $ac_cv_struct_tms = yes; then
1133   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1134   [Define if <sys/times.h> defines struct tms.])
1135 fi
1136
1137 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1138 # revisit after autoconf 2.50.
1139 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1140 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1141 #include "ansidecl.h"
1142 #include "system.h"
1143 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1144 if test $gcc_cv_type_clock_t = yes; then
1145   AC_DEFINE(HAVE_CLOCK_T, 1,
1146   [Define if <time.h> defines clock_t.])
1147 fi
1148
1149 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1150 CFLAGS="$saved_CFLAGS"
1151
1152 gcc_AC_INITFINI_ARRAY
1153
1154 # mkdir takes a single argument on some systems.
1155 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1156
1157 # File extensions
1158 manext='.1'
1159 objext='.o'
1160 AC_SUBST(manext)
1161 AC_SUBST(objext)
1162
1163 # With Setjmp/Longjmp based exception handling.
1164 AC_ARG_ENABLE(sjlj-exceptions,
1165 [  --enable-sjlj-exceptions
1166                           arrange to use setjmp/longjmp exception handling],
1167 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1168 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1169   [Define 0/1 to force the choice for exception handling model.])])
1170
1171 # For platforms with the unwind ABI which includes an unwind library,
1172 # libunwind, we can choose to use the system libunwind.
1173 AC_ARG_WITH(system-libunwind,
1174 [  --with-system-libunwind use installed libunwind])
1175
1176 # config.gcc also contains tests of with_system_libunwind.
1177 if test x$with_system_libunwind = xyes; then
1178         AC_DEFINE(HAVE_GETIPINFO, 1,
1179 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1180 fi
1181
1182 # --------------------------------------------------------
1183 # Build, host, and target specific configuration fragments
1184 # --------------------------------------------------------
1185
1186 # Collect build-machine-specific information.
1187 . ${srcdir}/config.build
1188
1189 # Collect host-machine-specific information.
1190 . ${srcdir}/config.host
1191
1192 target_gtfiles=
1193
1194 # Collect target-machine-specific information.
1195 . ${srcdir}/config.gcc
1196
1197 extra_objs="${host_extra_objs} ${extra_objs}"
1198 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1199
1200 # Default the target-machine variables that were not explicitly set.
1201 if test x"$tm_file" = x
1202 then tm_file=$cpu_type/$cpu_type.h; fi
1203
1204 if test x"$extra_headers" = x
1205 then extra_headers=; fi
1206
1207 if test x$md_file = x
1208 then md_file=$cpu_type/$cpu_type.md; fi
1209
1210 if test x$out_file = x
1211 then out_file=$cpu_type/$cpu_type.c; fi
1212
1213 if test x"$tmake_file" = x
1214 then tmake_file=$cpu_type/t-$cpu_type
1215 fi
1216
1217 if test x"$dwarf2" = xyes
1218 then tm_file="$tm_file tm-dwarf2.h"
1219 fi
1220
1221 # Say what files are being used for the output code and MD file.
1222 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1223 echo "Using \`$srcdir/config/$md_file' as machine description file."
1224
1225 # If any of the xm_file variables contain nonexistent files, warn
1226 # about them and drop them.
1227
1228 bx=
1229 for x in $build_xm_file; do
1230   if    test -f $srcdir/config/$x
1231   then      bx="$bx $x"
1232   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1233   fi
1234 done
1235 build_xm_file="$bx"
1236
1237 hx=
1238 for x in $host_xm_file; do
1239   if    test -f $srcdir/config/$x
1240   then      hx="$hx $x"
1241   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1242   fi
1243 done
1244 host_xm_file="$hx"
1245
1246 tx=
1247 for x in $xm_file; do
1248   if    test -f $srcdir/config/$x
1249   then      tx="$tx $x"
1250   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1251   fi
1252 done
1253 xm_file="$tx"
1254
1255 count=a
1256 for f in $tm_file; do
1257         count=${count}x
1258 done
1259 if test $count = ax; then
1260         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1261 else
1262         echo "Using the following target machine macro files:"
1263         for f in $tm_file; do
1264                 echo "  $srcdir/config/$f"
1265         done
1266 fi
1267
1268 if test x$need_64bit_hwint = xyes; then
1269         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1270 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1271 fi
1272
1273 if test x$use_long_long_for_widest_fast_int = xyes; then
1274         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1275 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1276 efficiently supported by the host hardware.])
1277 fi
1278
1279 count=a
1280 for f in $host_xm_file; do
1281         count=${count}x
1282 done
1283 if test $count = a; then
1284         :
1285 elif test $count = ax; then
1286         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1287 else
1288         echo "Using the following host machine macro files:"
1289         for f in $host_xm_file; do
1290                 echo "  $srcdir/config/$f"
1291         done
1292 fi
1293 echo "Using ${out_host_hook_obj} for host machine hooks."
1294
1295 if test "$host_xm_file" != "$build_xm_file"; then
1296         count=a
1297         for f in $build_xm_file; do
1298                 count=${count}x
1299         done
1300         if test $count = a; then
1301                 :
1302         elif test $count = ax; then
1303                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1304         else
1305                 echo "Using the following build machine macro files:"
1306                 for f in $build_xm_file; do
1307                         echo "  $srcdir/config/$f"
1308                 done
1309         fi
1310 fi
1311
1312 case ${host} in
1313   powerpc*-*-darwin*)
1314     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1315       gcc_cv_mcontext_underscores,
1316       AC_COMPILE_IFELSE([
1317 #include <sys/cdefs.h>
1318 #include <sys/signal.h>
1319 #include <ucontext.h>
1320 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1321 ],
1322         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1323       if test $gcc_cv_mcontext_underscores = yes; then
1324         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1325           [mcontext_t fields start with __])
1326       fi
1327     ;;
1328 esac
1329
1330 # ---------
1331 # Threading
1332 # ---------
1333
1334 # Check if a valid thread package
1335 case ${enable_threads} in
1336   "" | no)
1337     # No threads
1338     target_thread_file='single'
1339     ;;
1340   yes)
1341     # default
1342     target_thread_file='single'
1343     ;;
1344   aix | dce | gnat | irix | posix | posix95 | rtems | \
1345   single | solaris | vxworks | win32 | mipssde)
1346     target_thread_file=${enable_threads}
1347     ;;
1348   *)
1349     echo "${enable_threads} is an unknown thread package" 1>&2
1350     exit 1
1351     ;;
1352 esac
1353
1354 if test x${thread_file} = x; then
1355   # No thread file set by target-specific clauses in config.gcc,
1356   # so use file chosen by default logic above
1357   thread_file=${target_thread_file}
1358 fi
1359
1360 # Make gthr-default.h if we have a thread file.
1361 gthread_flags=
1362 if test $thread_file != single; then
1363   rm -f gthr-default.h
1364   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1365   gthread_flags=-DHAVE_GTHR_DEFAULT
1366 fi
1367 AC_SUBST(gthread_flags)
1368
1369 # --------
1370 # UNSORTED
1371 # --------
1372
1373 use_cxa_atexit=no
1374 if test x$enable___cxa_atexit = xyes || \
1375    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1376   if test x$host = x$target; then
1377     case $host in
1378       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1379       # keyed to flag_use_cxa_atexit
1380       *-*-mingw32*)
1381         use_cxa_atexit=yes
1382         ;;
1383       *)
1384         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1385           [echo "__cxa_atexit can't be enabled on this target"])
1386         ;;
1387     esac
1388   else
1389     # We can't check for __cxa_atexit when building a cross, so assume
1390     # it is available
1391     use_cxa_atexit=yes
1392   fi
1393   if test x$use_cxa_atexit = xyes; then
1394     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1395       [Define if you want to use __cxa_atexit, rather than atexit, to
1396       register C++ destructors for local statics and global objects.
1397       This is essential for fully standards-compliant handling of
1398       destructors, but requires __cxa_atexit in libc.])
1399   fi
1400 fi
1401
1402 use_getipinfo=yes
1403 if test x$with_system_libunwind = xyes; then
1404    if test x$host = x$target; then
1405      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1406    fi
1407 fi
1408 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1409 if test x$use_getipinfo = xyes; then
1410    AC_DEFINE(HAVE_GETIPINFO, 1,
1411         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1412 else
1413    echo "The system unwind library does not support _Unwind_GetIPInfo."
1414 fi
1415
1416 # Look for a file containing extra machine modes.
1417 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1418   extra_modes_file='$(srcdir)'/config/${extra_modes}
1419   AC_SUBST(extra_modes_file)
1420   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1421   [Define to the name of a file containing a list of extra machine modes
1422    for this architecture.])
1423 fi
1424
1425 # Convert extra_options into a form suitable for Makefile use.
1426 extra_opt_files=
1427 for f in $extra_options; do
1428   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1429 done
1430 AC_SUBST(extra_opt_files)
1431
1432 # auto-host.h is the file containing items generated by autoconf and is
1433 # the first file included by config.h.
1434 # If host=build, it is correct to have bconfig include auto-host.h
1435 # as well.  If host!=build, we are in error and need to do more
1436 # work to find out the build config parameters.
1437 if test x$host = x$build
1438 then
1439         build_auto=auto-host.h
1440 else
1441         # We create a subdir, then run autoconf in the subdir.
1442         # To prevent recursion we set host and build for the new
1443         # invocation of configure to the build for this invocation
1444         # of configure.
1445         tempdir=build.$$
1446         rm -rf $tempdir
1447         mkdir $tempdir
1448         cd $tempdir
1449         case ${srcdir} in
1450         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1451         *) realsrcdir=../${srcdir};;
1452         esac
1453         saved_CFLAGS="${CFLAGS}"
1454         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1455         ${realsrcdir}/configure \
1456                 --enable-languages=${enable_languages-all} \
1457                 --target=$target_alias --host=$build_alias --build=$build_alias
1458         CFLAGS="${saved_CFLAGS}"
1459
1460         # We just finished tests for the build machine, so rename
1461         # the file auto-build.h in the gcc directory.
1462         mv auto-host.h ../auto-build.h
1463         cd ..
1464         rm -rf $tempdir
1465         build_auto=auto-build.h
1466 fi
1467 AC_SUBST(build_subdir)
1468
1469 tm_file="${tm_file} defaults.h"
1470 tm_p_file="${tm_p_file} tm-preds.h"
1471 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1472 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1473 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1474 # put this back in temporarily.
1475 xm_file="auto-host.h ansidecl.h ${xm_file}"
1476
1477 # --------
1478 # UNSORTED
1479 # --------
1480
1481 changequote(,)dnl
1482 # Compile in configure arguments.
1483 if test -f configargs.h ; then
1484         # Being re-configured.
1485         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1486         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1487 else
1488         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1489 fi
1490
1491 # Double all backslashes and backslash all quotes to turn
1492 # gcc_config_arguments into a C string.
1493 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1494 $gcc_config_arguments
1495 EOF
1496 gcc_config_arguments_str=`cat conftest.out`
1497 rm -f conftest.out
1498
1499 cat > configargs.h <<EOF
1500 /* Generated automatically. */
1501 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1502 static const char thread_model[] = "$thread_file";
1503
1504 static const struct {
1505   const char *name, *value;
1506 } configure_default_options[] = $configure_default_options;
1507 EOF
1508 changequote([,])dnl
1509
1510 # Internationalization
1511 ZW_GNU_GETTEXT_SISTER_DIR
1512
1513 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1514 # -liconv on the link line twice.
1515 case "$LIBINTL" in *$LIBICONV*)
1516         LIBICONV= ;;
1517 esac
1518
1519 AC_ARG_ENABLE(secureplt,
1520 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1521 [], [])
1522
1523 # Windows32 Registry support for specifying GCC installation paths.
1524 AC_ARG_ENABLE(win32-registry,
1525 [  --disable-win32-registry
1526                           disable lookup of installation paths in the
1527                           Registry on Windows hosts
1528   --enable-win32-registry enable registry lookup (default)
1529   --enable-win32-registry=KEY
1530                           use KEY instead of GCC version as the last portion
1531                           of the registry key],,)
1532
1533 case $host_os in
1534   win32 | pe | cygwin* | mingw32* | uwin*)
1535     if test "x$enable_win32_registry" != xno; then
1536       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1537     fi
1538
1539     if test "x$enable_win32_registry" != xno; then
1540       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1541   [Define to 1 if installation paths should be looked up in the Windows
1542    Registry. Ignored on non-Windows hosts.])
1543
1544       if test "x$enable_win32_registry" != xyes \
1545          && test "x$enable_win32_registry" != x; then
1546         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1547   [Define to be the last component of the Windows registry key under which
1548    to look for installation paths.  The full key used will be
1549    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1550    The default is the GCC version number.])
1551       fi
1552     fi
1553   ;;
1554 esac
1555
1556 # Get an absolute path to the GCC top-level source directory
1557 holddir=`${PWDCMD-pwd}`
1558 cd $srcdir
1559 topdir=`${PWDCMD-pwd}`
1560 cd $holddir
1561
1562 # Conditionalize the makefile for this host machine.
1563 xmake_file=
1564 for f in ${host_xmake_file}
1565 do
1566         if test -f ${srcdir}/config/$f
1567         then
1568                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1569         fi
1570 done
1571
1572 # Conditionalize the makefile for this target machine.
1573 tmake_file_=
1574 for f in ${tmake_file}
1575 do
1576         if test -f ${srcdir}/config/$f
1577         then
1578                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1579         fi
1580 done
1581 tmake_file="${tmake_file_}"
1582
1583 # This is a terrible hack which will go away some day.
1584 host_cc_for_libada=${CC}
1585 AC_SUBST(host_cc_for_libada)
1586
1587 out_object_file=`basename $out_file .c`.o
1588
1589 tm_file_list="options.h"
1590 tm_include_list="options.h"
1591 for f in $tm_file; do
1592   case $f in
1593     ./* )
1594        f=`echo $f | sed 's/^..//'`
1595        tm_file_list="${tm_file_list} $f"
1596        tm_include_list="${tm_include_list} $f"
1597        ;;
1598     defaults.h )
1599        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1600        tm_include_list="${tm_include_list} $f"
1601        ;;
1602     * )
1603        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1604        tm_include_list="${tm_include_list} config/$f"
1605        ;;
1606   esac
1607 done
1608
1609 tm_p_file_list=
1610 tm_p_include_list=
1611 for f in $tm_p_file; do
1612   case $f in
1613     tm-preds.h )
1614        tm_p_file_list="${tm_p_file_list} $f"
1615        tm_p_include_list="${tm_p_include_list} $f"
1616        ;;
1617     * )
1618        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1619        tm_p_include_list="${tm_p_include_list} config/$f"
1620   esac
1621 done
1622
1623 xm_file_list=
1624 xm_include_list=
1625 for f in $xm_file; do
1626   case $f in
1627     ansidecl.h )
1628        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1629        xm_include_list="${xm_include_list} $f"
1630        ;;
1631     auto-host.h )
1632        xm_file_list="${xm_file_list} $f"
1633        xm_include_list="${xm_include_list} $f"
1634        ;;
1635     * )
1636        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1637        xm_include_list="${xm_include_list} config/$f"
1638        ;;
1639   esac
1640 done
1641
1642 host_xm_file_list=
1643 host_xm_include_list=
1644 for f in $host_xm_file; do
1645   case $f in
1646     ansidecl.h )
1647        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1648        host_xm_include_list="${host_xm_include_list} $f"
1649        ;;
1650     auto-host.h )
1651        host_xm_file_list="${host_xm_file_list} $f"
1652        host_xm_include_list="${host_xm_include_list} $f"
1653        ;;
1654     * )
1655        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1656        host_xm_include_list="${host_xm_include_list} config/$f"
1657        ;;
1658   esac
1659 done
1660
1661 build_xm_file_list=
1662 for f in $build_xm_file; do
1663   case $f in
1664     ansidecl.h )
1665        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1666        build_xm_include_list="${build_xm_include_list} $f"
1667        ;;
1668     auto-build.h | auto-host.h )
1669        build_xm_file_list="${build_xm_file_list} $f"
1670        build_xm_include_list="${build_xm_include_list} $f"
1671        ;;
1672     * )
1673        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1674        build_xm_include_list="${build_xm_include_list} config/$f"
1675        ;;
1676   esac
1677 done
1678
1679 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1680 # cross-compiler which does not use the native headers and libraries.
1681 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1682 CROSS=                                          AC_SUBST(CROSS)
1683 ALL=all.internal                                AC_SUBST(ALL)
1684 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1685
1686 if test "x$with_build_sysroot" != x; then
1687   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1688 else
1689   # This value is used, even on a native system, because
1690   # CROSS_SYSTEM_HEADER_DIR is just
1691   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1692   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1693 fi
1694
1695 if test x$host != x$target
1696 then
1697         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1698         ALL=all.cross
1699         SYSTEM_HEADER_DIR=$build_system_header_dir
1700         case "$host","$target" in
1701         # Darwin crosses can use the host system's libraries and headers,
1702         # because of the fat library support.  Of course, it must be the
1703         # same version of Darwin on both sides.  Allow the user to
1704         # just say --target=foo-darwin without a version number to mean
1705         # "the version on this system".
1706             *-*-darwin*,*-*-darwin*)
1707                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1708                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1709                 if test $hostos = $targetos -o $targetos = darwin ; then
1710                     CROSS=
1711                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1712                     with_headers=yes
1713                 fi
1714                 ;;
1715
1716             i?86-*-*,x86_64-*-* \
1717             | powerpc*-*-*,powerpc64*-*-*)
1718                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1719         esac
1720 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1721         SYSTEM_HEADER_DIR=$build_system_header_dir
1722 fi
1723
1724 # If this is a cross-compiler that does not
1725 # have its own set of headers then define
1726 # inhibit_libc
1727
1728 # If this is using newlib, without having the headers available now,
1729 # then define inhibit_libc in LIBGCC2_CFLAGS.
1730 # This prevents libgcc2 from containing any code which requires libc
1731 # support.
1732 inhibit_libc=false
1733 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1734        test x$with_newlib = xyes ; } &&
1735      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1736        inhibit_libc=true
1737 fi
1738 AC_SUBST(inhibit_libc)
1739
1740 # When building gcc with a cross-compiler, we need to adjust things so
1741 # that the generator programs are still built with the native compiler.
1742 # Also, we cannot run fixincludes or fix-header.
1743
1744 # These are the normal (build=host) settings:
1745 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1746 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1747 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1748
1749 # Possibly disable fixproto, on a per-target basis.
1750 case ${use_fixproto} in
1751   no)
1752     STMP_FIXPROTO=
1753     ;;
1754   yes)
1755     STMP_FIXPROTO=stmp-fixproto
1756     ;;
1757 esac
1758 AC_SUBST(STMP_FIXPROTO)
1759
1760 # And these apply if build != host, or we are generating coverage data
1761 if test x$build != x$host || test "x$coverage_flags" != x
1762 then
1763     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1764
1765     if test "x$TARGET_SYSTEM_ROOT" = x; then
1766         if test "x$STMP_FIXPROTO" != x; then
1767           STMP_FIXPROTO=stmp-install-fixproto
1768         fi
1769     fi
1770 fi
1771
1772 # Expand extra_headers to include complete path.
1773 # This substitutes for lots of t-* files.
1774 extra_headers_list=
1775 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1776 for file in ${extra_headers} ; do
1777   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1778 done
1779
1780 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1781 if test x"$use_gcc_tgmath" = xyes
1782 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1783 fi
1784
1785 # Define collect2 in Makefile.
1786 case $host_can_use_collect2 in
1787   no) collect2= ;;
1788   *) collect2='collect2$(exeext)' ;;
1789 esac
1790 AC_SUBST([collect2])
1791
1792 # Add a definition of USE_COLLECT2 if system wants one.
1793 case $use_collect2 in
1794   no) use_collect2= ;;
1795   "") ;;
1796   *)
1797     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1798     xm_defines="${xm_defines} USE_COLLECT2"
1799     case $host_can_use_collect2 in
1800       no)
1801         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1802         ;;
1803     esac
1804     ;;
1805 esac
1806
1807 # ---------------------------
1808 # Assembler & linker features
1809 # ---------------------------
1810
1811 # Identify the assembler which will work hand-in-glove with the newly
1812 # built GCC, so that we can examine its features.  This is the assembler
1813 # which will be driven by the driver program.
1814 #
1815 # If build != host, and we aren't building gas in-tree, we identify a
1816 # build->target assembler and hope that it will have the same features
1817 # as the host->target assembler we'll be using.
1818 gcc_cv_gas_major_version=
1819 gcc_cv_gas_minor_version=
1820 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1821
1822 m4_pattern_allow([AS_FOR_TARGET])dnl
1823 AS_VAR_SET_IF(gcc_cv_as,, [
1824 if test -x "$DEFAULT_ASSEMBLER"; then
1825         gcc_cv_as="$DEFAULT_ASSEMBLER"
1826 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1827      && test -f ../gas/Makefile \
1828      && test x$build = x$host; then
1829         gcc_cv_as=../gas/as-new$build_exeext
1830 elif test -x as$build_exeext; then
1831         # Build using assembler in the current directory.
1832         gcc_cv_as=./as$build_exeext
1833 elif test -x $AS_FOR_TARGET; then
1834         gcc_cv_as="$AS_FOR_TARGET"
1835 else
1836         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1837 fi])
1838
1839 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1840 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1841 case "$ORIGINAL_AS_FOR_TARGET" in
1842   ./as | ./as$build_exeext) ;;
1843   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1844 esac
1845
1846 AC_MSG_CHECKING(what assembler to use)
1847 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1848   # Single tree build which includes gas.  We want to prefer it
1849   # over whatever linker top-level may have detected, since
1850   # we'll use what we're building after installation anyway.
1851   AC_MSG_RESULT(newly built gas)
1852   in_tree_gas=yes
1853   _gcc_COMPUTE_GAS_VERSION
1854   in_tree_gas_is_elf=no
1855   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1856      || (grep 'obj_format = multi' ../gas/Makefile \
1857          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1858   then
1859     in_tree_gas_is_elf=yes
1860   fi
1861 else
1862   AC_MSG_RESULT($gcc_cv_as)
1863   in_tree_gas=no
1864 fi
1865
1866 # Identify the linker which will work hand-in-glove with the newly
1867 # built GCC, so that we can examine its features.  This is the linker
1868 # which will be driven by the driver program.
1869 #
1870 # If build != host, and we aren't building gas in-tree, we identify a
1871 # build->target linker and hope that it will have the same features
1872 # as the host->target linker we'll be using.
1873 gcc_cv_gld_major_version=
1874 gcc_cv_gld_minor_version=
1875 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1876 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1877
1878 AS_VAR_SET_IF(gcc_cv_ld,, [
1879 if test -x "$DEFAULT_LINKER"; then
1880         gcc_cv_ld="$DEFAULT_LINKER"
1881 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1882      && test -f ../ld/Makefile \
1883      && test x$build = x$host; then
1884         gcc_cv_ld=../ld/ld-new$build_exeext
1885 elif test -x collect-ld$build_exeext; then
1886         # Build using linker in the current directory.
1887         gcc_cv_ld=./collect-ld$build_exeext
1888 elif test -x $LD_FOR_TARGET; then
1889         gcc_cv_ld="$LD_FOR_TARGET"
1890 else
1891         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1892 fi])
1893
1894 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1895 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1896 case "$ORIGINAL_LD_FOR_TARGET" in
1897   ./collect-ld | ./collect-ld$build_exeext) ;;
1898   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1899 esac
1900
1901 AC_MSG_CHECKING(what linker to use)
1902 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1903         # Single tree build which includes ld.  We want to prefer it
1904         # over whatever linker top-level may have detected, since
1905         # we'll use what we're building after installation anyway.
1906         AC_MSG_RESULT(newly built ld)
1907         in_tree_ld=yes
1908         in_tree_ld_is_elf=no
1909         if (grep 'EMUL = .*elf' ../ld/Makefile \
1910             || grep 'EMUL = .*linux' ../ld/Makefile \
1911             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1912           in_tree_ld_is_elf=yes
1913         fi
1914         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1915         do
1916 changequote(,)dnl
1917                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1918                 if test x$gcc_cv_gld_version != x; then
1919                         break
1920                 fi
1921         done
1922         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1923         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1924 changequote([,])dnl
1925 else
1926         AC_MSG_RESULT($gcc_cv_ld)
1927         in_tree_ld=no
1928 fi
1929
1930 # Figure out what nm we will be using.
1931 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1932 AS_VAR_SET_IF(gcc_cv_nm,, [
1933 if test -f $gcc_cv_binutils_srcdir/configure.in \
1934      && test -f ../binutils/Makefile \
1935      && test x$build = x$host; then
1936         gcc_cv_nm=../binutils/nm-new$build_exeext
1937 elif test -x nm$build_exeext; then
1938         gcc_cv_nm=./nm$build_exeext
1939 elif test -x $NM_FOR_TARGET; then
1940         gcc_cv_nm="$NM_FOR_TARGET"
1941 else
1942         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1943 fi])
1944
1945 AC_MSG_CHECKING(what nm to use)
1946 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1947         # Single tree build which includes binutils.
1948         AC_MSG_RESULT(newly built nm)
1949         in_tree_nm=yes
1950 else
1951         AC_MSG_RESULT($gcc_cv_nm)
1952         in_tree_nm=no
1953 fi
1954
1955 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1956 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1957 case "$ORIGINAL_NM_FOR_TARGET" in
1958   ./nm | ./nm$build_exeext) ;;
1959   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1960 esac
1961
1962
1963 # Figure out what objdump we will be using.
1964 AS_VAR_SET_IF(gcc_cv_objdump,, [
1965 if test -f $gcc_cv_binutils_srcdir/configure.in \
1966      && test -f ../binutils/Makefile \
1967      && test x$build = x$host; then
1968         # Single tree build which includes binutils.
1969         gcc_cv_objdump=../binutils/objdump$build_exeext
1970 elif test -x objdump$build_exeext; then
1971         gcc_cv_objdump=./objdump$build_exeext
1972 elif test -x $OBJDUMP_FOR_TARGET; then
1973         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1974 else
1975         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1976 fi])
1977
1978 AC_MSG_CHECKING(what objdump to use)
1979 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1980         # Single tree build which includes binutils.
1981         AC_MSG_RESULT(newly built objdump)
1982 elif test x$gcc_cv_objdump = x; then
1983         AC_MSG_RESULT(not found)
1984 else
1985         AC_MSG_RESULT($gcc_cv_objdump)
1986 fi
1987
1988 # Figure out what assembler alignment features are present.
1989 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1990  [2,6,0],,
1991 [.balign 4
1992 .p2align 2],,
1993 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1994   [Define if your assembler supports .balign and .p2align.])])
1995
1996 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1997  [2,8,0],,
1998  [.p2align 4,,7],,
1999 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2000   [Define if your assembler supports specifying the maximum number
2001    of bytes to skip when using the GAS .p2align command.])])
2002
2003 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2004  [2,8,0],,
2005  [.literal16],,
2006 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2007   [Define if your assembler supports .literal16.])])
2008
2009 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2010  [elf,2,9,0],,
2011  [conftest_label1: .word 0
2012 .subsection -1
2013 conftest_label2: .word 0
2014 .previous],
2015  [if test x$gcc_cv_nm != x; then
2016     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2017     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2018     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2019     then :
2020     else gcc_cv_as_subsection_m1=yes
2021     fi
2022     rm -f conftest.nm1 conftest.nm2
2023   fi],
2024  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2025   [Define if your assembler supports .subsection and .subsection -1 starts
2026    emitting at the beginning of your section.])])
2027
2028 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2029  [2,2,0],,
2030  [      .weak foobar],,
2031 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2032
2033 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2034  [2,17,0],,
2035  [      .weakref foobar, barfnot],,
2036 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2037
2038 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2039  [2,15,91],,
2040  [      .SPACE $TEXT$
2041         .NSUBSPA $CODE$,COMDAT],,
2042 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2043
2044 # .hidden needs to be supported in both the assembler and the linker,
2045 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2046 # This is irritatingly difficult to feature test for; we have to check the
2047 # date string after the version number.  If we've got an in-tree
2048 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2049 # to be safe.
2050 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2051 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2052  [elf,2,13,0],,
2053 [       .hidden foobar
2054 foobar:])
2055
2056 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2057 [if test $in_tree_ld = yes ; then
2058   gcc_cv_ld_hidden=no
2059   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2060      && test $in_tree_ld_is_elf = yes; then
2061      gcc_cv_ld_hidden=yes
2062   fi
2063 else
2064   gcc_cv_ld_hidden=yes
2065   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2066   if echo "$ld_ver" | grep GNU > /dev/null; then
2067 changequote(,)dnl
2068     ld_vers=`echo $ld_ver | sed -n \
2069         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2070     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2071     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2072     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2073     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2074     if test 0"$ld_date" -lt 20020404; then
2075       if test -n "$ld_date"; then
2076         # If there was date string, but was earlier than 2002-04-04, fail
2077         gcc_cv_ld_hidden=no
2078       elif test -z "$ld_vers"; then
2079         # If there was no date string nor ld version number, something is wrong
2080         gcc_cv_ld_hidden=no
2081       else
2082         test -z "$ld_vers_patch" && ld_vers_patch=0
2083         if test "$ld_vers_major" -lt 2; then
2084           gcc_cv_ld_hidden=no
2085         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2086           gcc_cv_ld_hidden="no"
2087         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2088           gcc_cv_ld_hidden=no
2089         fi
2090       fi
2091 changequote([,])dnl
2092     fi
2093   else
2094     case "${target}" in
2095       hppa64*-*-hpux* | ia64*-*-hpux*)
2096         gcc_cv_ld_hidden=yes
2097         ;;
2098       *)
2099         gcc_cv_ld_hidden=no
2100         ;;
2101     esac
2102   fi
2103 fi])
2104 libgcc_visibility=no
2105 AC_SUBST(libgcc_visibility)
2106 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2107 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2108   libgcc_visibility=yes
2109   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2110   [Define if your assembler and linker support .hidden.])
2111 fi
2112
2113 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2114 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2115   [elf,2,11,0],,
2116 [       .data
2117         .uleb128 L2 - L1
2118 L1:
2119         .uleb128 1280
2120         .sleb128 -1010
2121 L2:],
2122  [# GAS versions before 2.11 do not support uleb128,
2123   # despite appearing to.
2124   # ??? There exists an elf-specific test that will crash
2125   # the assembler.  Perhaps it's better to figure out whether
2126   # arbitrary sections are supported and try the test.
2127   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2128   if echo "$as_ver" | grep GNU > /dev/null; then
2129 changequote(,)dnl
2130     as_vers=`echo $as_ver | sed -n \
2131         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2132     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2133     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2134 changequote([,])dnl
2135     if test $as_major -eq 2 && test $as_minor -lt 11
2136     then :
2137     else gcc_cv_as_leb128=yes
2138     fi
2139   fi],
2140   [AC_DEFINE(HAVE_AS_LEB128, 1,
2141     [Define if your assembler supports .sleb128 and .uleb128.])])
2142
2143 # GAS versions up to and including 2.11.0 may mis-optimize
2144 # .eh_frame data.
2145 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2146   [elf,2,12,0],,
2147 [       .text
2148 .LFB1:
2149         .4byte  0
2150 .L1:
2151         .4byte  0
2152 .LFE1:
2153         .section        .eh_frame,"aw",@progbits
2154 __FRAME_BEGIN__:
2155         .4byte  .LECIE1-.LSCIE1
2156 .LSCIE1:
2157         .4byte  0x0
2158         .byte   0x1
2159         .ascii "z\0"
2160         .byte   0x1
2161         .byte   0x78
2162         .byte   0x1a
2163         .byte   0x0
2164         .byte   0x4
2165         .4byte  1
2166         .p2align 1
2167 .LECIE1:
2168 .LSFDE1:
2169         .4byte  .LEFDE1-.LASFDE1
2170 .LASFDE1:
2171         .4byte  .LASFDE1-__FRAME_BEGIN__
2172         .4byte  .LFB1
2173         .4byte  .LFE1-.LFB1
2174         .byte   0x4
2175         .4byte  .LFE1-.LFB1
2176         .byte   0x4
2177         .4byte  .L1-.LFB1
2178 .LEFDE1:],
2179 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2180 cat > conftest.lit <<EOF
2181  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2182  0010 01000000 12000000 18000000 00000000  ................
2183  0020 08000000 04080000 0044               .........D      @&t@
2184 EOF
2185 cat > conftest.big <<EOF
2186  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2187  0010 00000001 00000012 00000018 00000000  ................
2188  0020 00000008 04000000 0844               .........D      @&t@
2189 EOF
2190   # If the assembler didn't choke, and we can objdump,
2191   # and we got the correct data, then succeed.
2192   # The text in the here-document typically retains its unix-style line
2193   # endings, while the output of objdump will use host line endings.
2194   # Therefore, use diff -b for the comparisons.
2195   if test x$gcc_cv_objdump != x \
2196   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2197      | tail -3 > conftest.got \
2198   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2199     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2200   then
2201     gcc_cv_as_eh_frame=yes
2202   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2203     gcc_cv_as_eh_frame=buggy
2204   else
2205     # Uh oh, what do we do now?
2206     gcc_cv_as_eh_frame=no
2207   fi])
2208
2209 if test $gcc_cv_as_eh_frame = buggy; then
2210   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2211   [Define if your assembler mis-optimizes .eh_frame data.])
2212 fi
2213
2214 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2215  [elf,2,12,0], [--fatal-warnings],
2216  [.section .rodata.str, "aMS", @progbits, 1])
2217 if test $gcc_cv_as_shf_merge = no; then
2218   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2219     [elf,2,12,0], [--fatal-warnings],
2220     [.section .rodata.str, "aMS", %progbits, 1])
2221 fi
2222 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2223   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2224 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2225
2226 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2227  [elf,2,16,0], [--fatal-warnings],
2228  [.section .text,"axG",@progbits,.foo,comdat])
2229 if test $gcc_cv_as_comdat_group = yes; then
2230   gcc_cv_as_comdat_group_percent=no
2231 else
2232  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2233    [elf,2,16,0], [--fatal-warnings],
2234    [.section .text,"axG",%progbits,.foo,comdat])
2235 fi
2236 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2237   comdat_group=yes
2238   if test 0"$ld_date" -lt 20050308; then
2239     if test -n "$ld_date"; then
2240       # If there was date string, but was earlier than 2005-03-08, fail
2241       comdat_group=no
2242     elif test "$ld_vers_major" -lt 2; then
2243       comdat_group=no
2244     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2245       comdat_group=no
2246     fi
2247   fi
2248 else
2249   # assume linkers other than GNU ld don't support COMDAT group
2250   comdat_group=no
2251 fi
2252 if test $comdat_group = no; then
2253   gcc_cv_as_comdat_group=no
2254   gcc_cv_as_comdat_group_percent=no
2255 fi
2256 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2257   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2258 [Define 0/1 if your assembler and linker support COMDAT groups.])
2259
2260 # Thread-local storage - the check is heavily parametrized.
2261 conftest_s=
2262 tls_first_major=
2263 tls_first_minor=
2264 tls_as_opt=
2265 case "$target" in
2266 changequote(,)dnl
2267   alpha*-*-*)
2268     conftest_s='
2269         .section ".tdata","awT",@progbits
2270 foo:    .long   25
2271         .text
2272         ldq     $27,__tls_get_addr($29)         !literal!1
2273         lda     $16,foo($29)                    !tlsgd!1
2274         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2275         ldq     $27,__tls_get_addr($29)         !literal!2
2276         lda     $16,foo($29)                    !tlsldm!2
2277         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2278         ldq     $1,foo($29)                     !gotdtprel
2279         ldah    $2,foo($29)                     !dtprelhi
2280         lda     $3,foo($2)                      !dtprello
2281         lda     $4,foo($29)                     !dtprel
2282         ldq     $1,foo($29)                     !gottprel
2283         ldah    $2,foo($29)                     !tprelhi
2284         lda     $3,foo($2)                      !tprello
2285         lda     $4,foo($29)                     !tprel'
2286         tls_first_major=2
2287         tls_first_minor=13
2288         tls_as_opt=--fatal-warnings
2289         ;;
2290   frv*-*-*)
2291     conftest_s='
2292         .section ".tdata","awT",@progbits
2293 x:      .long   25
2294         .text
2295         call    #gettlsoff(x)'
2296         tls_first_major=2
2297         tls_first_minor=14
2298         ;;
2299   hppa*-*-linux*)
2300     conftest_s='
2301 t1:     .reg    %r20
2302 t2:     .reg    %r21
2303 gp:     .reg    %r19
2304         .section ".tdata","awT",@progbits
2305 foo:    .long   25
2306         .text
2307         .align  4
2308         addil LT%foo-$tls_gdidx$,gp
2309         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2310         b __tls_get_addr
2311         nop
2312         addil LT%foo-$tls_ldidx$,gp
2313         b __tls_get_addr
2314         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2315         addil LR%foo-$tls_dtpoff$,%ret0
2316         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2317         mfctl %cr27,%t1
2318         addil LT%foo-$tls_ieoff$,gp
2319         ldw RT%foo-$tls_ieoff$(%r1),%t2
2320         add %t1,%t2,%t3
2321         mfctl %cr27,%t1
2322         addil LR%foo-$tls_leoff$,%t1
2323         ldo RR%foo-$tls_leoff$(%r1),%t2'
2324         tls_first_major=2
2325         tls_first_minor=15
2326         tls_as_opt=--fatal-warnings
2327         ;;
2328   arm*-*-*)
2329     conftest_s='
2330         .section ".tdata","awT",%progbits
2331 foo:    .long   25
2332         .text
2333 .word foo(gottpoff)
2334 .word foo(tpoff)
2335 .word foo(tlsgd)
2336 .word foo(tlsldm)
2337 .word foo(tlsldo)'
2338         tls_first_major=2
2339         tls_first_minor=17
2340         ;;
2341   i[34567]86-*-*)
2342     conftest_s='
2343         .section ".tdata","awT",@progbits
2344 foo:    .long   25
2345         .text
2346         movl    %gs:0, %eax
2347         leal    foo@TLSGD(,%ebx,1), %eax
2348         leal    foo@TLSLDM(%ebx), %eax
2349         leal    foo@DTPOFF(%eax), %edx
2350         movl    foo@GOTTPOFF(%ebx), %eax
2351         subl    foo@GOTTPOFF(%ebx), %eax
2352         addl    foo@GOTNTPOFF(%ebx), %eax
2353         movl    foo@INDNTPOFF, %eax
2354         movl    $foo@TPOFF, %eax
2355         subl    $foo@TPOFF, %eax
2356         leal    foo@NTPOFF(%ecx), %eax'
2357         tls_first_major=2
2358         tls_first_minor=14
2359         tls_as_opt=--fatal-warnings
2360         ;;
2361   x86_64-*-*)
2362     conftest_s='
2363         .section ".tdata","awT",@progbits
2364 foo:    .long   25
2365         .text
2366         movq    %fs:0, %rax
2367         leaq    foo@TLSGD(%rip), %rdi
2368         leaq    foo@TLSLD(%rip), %rdi
2369         leaq    foo@DTPOFF(%rax), %rdx
2370         movq    foo@GOTTPOFF(%rip), %rax
2371         movq    $foo@TPOFF, %rax'
2372         tls_first_major=2
2373         tls_first_minor=14
2374         tls_as_opt=--fatal-warnings
2375         ;;
2376   ia64-*-*)
2377     conftest_s='
2378         .section ".tdata","awT",@progbits
2379 foo:    data8   25
2380         .text
2381         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2382         addl    r17 = @ltoff(@dtprel(foo#)), gp
2383         addl    r18 = @ltoff(@tprel(foo#)), gp
2384         addl    r19 = @dtprel(foo#), gp
2385         adds    r21 = @dtprel(foo#), r13
2386         movl    r23 = @dtprel(foo#)
2387         addl    r20 = @tprel(foo#), gp
2388         adds    r22 = @tprel(foo#), r13
2389         movl    r24 = @tprel(foo#)'
2390         tls_first_major=2
2391         tls_first_minor=13
2392         tls_as_opt=--fatal-warnings
2393         ;;
2394   mips*-*-*)
2395     conftest_s='
2396         .section .tdata,"awT",@progbits
2397 x:
2398         .word 2
2399         .text
2400         addiu $4, $28, %tlsgd(x)
2401         addiu $4, $28, %tlsldm(x)
2402         lui $4, %dtprel_hi(x)
2403         addiu $4, $4, %dtprel_lo(x)
2404         lw $4, %gottprel(x)($28)
2405         lui $4, %tprel_hi(x)
2406         addiu $4, $4, %tprel_lo(x)'
2407         tls_first_major=2
2408         tls_first_minor=16
2409         tls_as_opt='-32 --fatal-warnings'
2410         ;;
2411   powerpc-*-*)
2412     conftest_s='
2413         .section ".tdata","awT",@progbits
2414         .align 2
2415 ld0:    .space 4
2416 ld1:    .space 4
2417 x1:     .space 4
2418 x2:     .space 4
2419 x3:     .space 4
2420         .text
2421         addi 3,31,ld0@got@tlsgd
2422         bl __tls_get_addr
2423         addi 3,31,x1@got@tlsld
2424         bl __tls_get_addr
2425         addi 9,3,x1@dtprel
2426         addis 9,3,x2@dtprel@ha
2427         addi 9,9,x2@dtprel@l
2428         lwz 9,x3@got@tprel(31)
2429         add 9,9,x@tls
2430         addi 9,2,x1@tprel
2431         addis 9,2,x2@tprel@ha
2432         addi 9,9,x2@tprel@l'
2433         tls_first_major=2
2434         tls_first_minor=14
2435         tls_as_opt="-a32 --fatal-warnings"
2436         ;;
2437   powerpc64-*-*)
2438     conftest_s='
2439         .section ".tdata","awT",@progbits
2440         .align 3
2441 ld0:    .space 8
2442 ld1:    .space 8
2443 x1:     .space 8
2444 x2:     .space 8
2445 x3:     .space 8
2446         .text
2447         addi 3,2,ld0@got@tlsgd
2448         bl .__tls_get_addr
2449         nop
2450         addi 3,2,ld1@toc
2451         bl .__tls_get_addr
2452         nop
2453         addi 3,2,x1@got@tlsld
2454         bl .__tls_get_addr
2455         nop
2456         addi 9,3,x1@dtprel
2457         bl .__tls_get_addr
2458         nop
2459         addis 9,3,x2@dtprel@ha
2460         addi 9,9,x2@dtprel@l
2461         bl .__tls_get_addr
2462         nop
2463         ld 9,x3@got@dtprel(2)
2464         add 9,9,3
2465         bl .__tls_get_addr
2466         nop'
2467         tls_first_major=2
2468         tls_first_minor=14
2469         tls_as_opt="-a64 --fatal-warnings"
2470         ;;
2471   s390-*-*)
2472     conftest_s='
2473         .section ".tdata","awT",@progbits
2474 foo:    .long   25
2475         .text
2476         .long   foo@TLSGD
2477         .long   foo@TLSLDM
2478         .long   foo@DTPOFF
2479         .long   foo@NTPOFF
2480         .long   foo@GOTNTPOFF
2481         .long   foo@INDNTPOFF
2482         l       %r1,foo@GOTNTPOFF(%r12)
2483         l       %r1,0(%r1):tls_load:foo
2484         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2485         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2486         tls_first_major=2
2487         tls_first_minor=14
2488         tls_as_opt="-m31 --fatal-warnings"
2489         ;;
2490   s390x-*-*)
2491     conftest_s='
2492         .section ".tdata","awT",@progbits
2493 foo:    .long   25
2494         .text
2495         .quad   foo@TLSGD
2496         .quad   foo@TLSLDM
2497         .quad   foo@DTPOFF
2498         .quad   foo@NTPOFF
2499         .quad   foo@GOTNTPOFF
2500         lg      %r1,foo@GOTNTPOFF(%r12)
2501         larl    %r1,foo@INDNTPOFF
2502         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2503         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2504         tls_first_major=2
2505         tls_first_minor=14
2506         tls_as_opt="-m64 -Aesame --fatal-warnings"
2507         ;;
2508   sh-*-* | sh[34]-*-*)
2509     conftest_s='
2510         .section ".tdata","awT",@progbits
2511 foo:    .long   25
2512         .text
2513         .long   foo@TLSGD
2514         .long   foo@TLSLDM
2515         .long   foo@DTPOFF
2516         .long   foo@GOTTPOFF
2517         .long   foo@TPOFF'
2518         tls_first_major=2
2519         tls_first_minor=13
2520         tls_as_opt=--fatal-warnings
2521         ;;
2522   sparc*-*-*)
2523     case "$target" in
2524       sparc*-sun-solaris2.[56789]*)
2525         # TLS was introduced in the Solaris 9 4/04 release but
2526         # we do not enable it by default on Solaris 9 either.
2527         if test "x$enable_tls" = xyes ; then
2528           on_solaris=yes
2529         else
2530           enable_tls=no;
2531         fi
2532         ;;
2533       sparc*-sun-solaris2.*)
2534         on_solaris=yes
2535         ;;
2536       *)
2537         on_solaris=no
2538         ;;
2539     esac
2540     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2541       conftest_s='
2542         .section ".tdata",#alloc,#write,#tls
2543 foo:    .long   25
2544         .text
2545         sethi   %tgd_hi22(foo), %o0
2546         add     %o0, %tgd_lo10(foo), %o1
2547         add     %l7, %o1, %o0, %tgd_add(foo)
2548         call    __tls_get_addr, %tgd_call(foo)
2549         sethi   %tldm_hi22(foo), %l1
2550         add     %l1, %tldm_lo10(foo), %l2
2551         add     %l7, %l2, %o0, %tldm_add(foo)
2552         call    __tls_get_addr, %tldm_call(foo)
2553         sethi   %tldo_hix22(foo), %l3
2554         xor     %l3, %tldo_lox10(foo), %l4
2555         add     %o0, %l4, %l5, %tldo_add(foo)
2556         sethi   %tie_hi22(foo), %o3
2557         add     %o3, %tie_lo10(foo), %o3
2558         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2559         add     %g7, %o2, %o4, %tie_add(foo)
2560         sethi   %tle_hix22(foo), %l1
2561         xor     %l1, %tle_lox10(foo), %o5
2562         ld      [%g7 + %o5], %o1'
2563         tls_first_major=0
2564         tls_first_minor=0
2565     else
2566       conftest_s='
2567         .section ".tdata","awT",@progbits
2568 foo:    .long   25
2569         .text
2570         sethi   %tgd_hi22(foo), %o0
2571         add     %o0, %tgd_lo10(foo), %o1
2572         add     %l7, %o1, %o0, %tgd_add(foo)
2573         call    __tls_get_addr, %tgd_call(foo)
2574         sethi   %tldm_hi22(foo), %l1
2575         add     %l1, %tldm_lo10(foo), %l2
2576         add     %l7, %l2, %o0, %tldm_add(foo)
2577         call    __tls_get_addr, %tldm_call(foo)
2578         sethi   %tldo_hix22(foo), %l3
2579         xor     %l3, %tldo_lox10(foo), %l4
2580         add     %o0, %l4, %l5, %tldo_add(foo)
2581         sethi   %tie_hi22(foo), %o3
2582         add     %o3, %tie_lo10(foo), %o3
2583         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2584         add     %g7, %o2, %o4, %tie_add(foo)
2585         sethi   %tle_hix22(foo), %l1
2586         xor     %l1, %tle_lox10(foo), %o5
2587         ld      [%g7 + %o5], %o1'
2588         tls_first_major=2
2589         tls_first_minor=14
2590         tls_as_opt="-32 --fatal-warnings"
2591       fi
2592         ;;
2593 changequote([,])dnl
2594 esac
2595 set_have_as_tls=no
2596 if test "x$enable_tls" = xno ; then
2597   : # TLS explicitly disabled.
2598 elif test "x$enable_tls" = xyes ; then
2599   set_have_as_tls=yes # TLS explicitly enabled.
2600 elif test -z "$tls_first_major"; then
2601   : # If we don't have a check, assume no support.
2602 else
2603   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2604   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2605   [set_have_as_tls=yes])
2606 fi
2607 if test $set_have_as_tls = yes ; then
2608   AC_DEFINE(HAVE_AS_TLS, 1,
2609             [Define if your assembler supports thread-local storage.])
2610 fi
2611
2612 # Target-specific assembler checks.
2613
2614 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2615 gcc_cv_ld_static_dynamic=no
2616 if test $in_tree_ld = yes ; then
2617   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2618     gcc_cv_ld_static_dynamic=yes
2619   fi
2620 elif test x$gcc_cv_ld != x; then
2621         # Check if linker supports -Bstatic/-Bdynamic option
2622         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2623           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2624                 gcc_cv_ld_static_dynamic=yes
2625         fi
2626 fi
2627 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2628         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2629 [Define if your linker supports -Bstatic/-Bdynamic option.])
2630 fi
2631 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2632
2633 if test x"$demangler_in_ld" = xyes; then
2634   AC_MSG_CHECKING(linker --demangle support)
2635   gcc_cv_ld_demangle=no
2636   if test $in_tree_ld = yes; then
2637     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2638       gcc_cv_ld_demangle=yes
2639     fi
2640   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2641     # Check if the GNU linker supports --demangle option
2642     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2643       gcc_cv_ld_demangle=yes
2644     fi
2645   fi
2646   if test x"$gcc_cv_ld_demangle" = xyes; then
2647     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2648 [Define if your linker supports --demangle option.])
2649   fi
2650   AC_MSG_RESULT($gcc_cv_ld_demangle)
2651 fi
2652
2653 case "$target" in
2654   # All TARGET_ABI_OSF targets.
2655   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2656     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2657         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2658 [       .set nomacro
2659         .text
2660         extbl   $3, $2, $3      !lituse_bytoff!1
2661         ldq     $2, a($29)      !literal!1
2662         ldq     $4, b($29)      !literal!2
2663         ldq_u   $3, 0($2)       !lituse_base!1
2664         ldq     $27, f($29)     !literal!5
2665         jsr     $26, ($27), f   !lituse_jsr!5
2666         ldah    $29, 0($26)     !gpdisp!3
2667         lda     $0, c($29)      !gprel
2668         ldah    $1, d($29)      !gprelhigh
2669         lda     $1, d($1)       !gprellow
2670         lda     $29, 0($29)     !gpdisp!3],,
2671     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2672   [Define if your assembler supports explicit relocations.])])
2673     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2674         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2675 [       .set nomacro
2676         .text
2677         ldq     $27, a($29)     !literal!1
2678         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2679     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2680   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2681     ;;
2682
2683   cris-*-*)
2684     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2685       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2686       [-no-mul-bug-abort], [.text],,
2687       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2688                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2689     ;;
2690
2691   sparc*-*-*)
2692     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2693       [.register %g2, #scratch],,
2694       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2695                 [Define if your assembler supports .register.])])
2696
2697     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2698       [-relax], [.text],,
2699       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2700                 [Define if your assembler supports -relax option.])])
2701
2702     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2703       gcc_cv_as_sparc_ua_pcrel,,
2704       [-K PIC],
2705 [.text
2706 foo:
2707         nop
2708 .data
2709 .align 4
2710 .byte 0
2711 .uaword %r_disp32(foo)],
2712       [if test x$gcc_cv_ld != x \
2713        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2714          gcc_cv_as_sparc_ua_pcrel=yes
2715        fi
2716        rm -f conftest],
2717       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2718                 [Define if your assembler and linker support unaligned PC relative relocs.])
2719
2720       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2721         gcc_cv_as_sparc_ua_pcrel_hidden,,
2722         [-K PIC],
2723 [.data
2724 .align 4
2725 .byte 0x31
2726 .uaword %r_disp32(foo)
2727 .byte 0x32, 0x33, 0x34
2728 .global foo
2729 .hidden foo
2730 foo:
2731 .skip 4],
2732         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2733          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2734          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2735             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2736             if $gcc_cv_objdump -R conftest 2> /dev/null \
2737                | grep 'DISP32' > /dev/null 2>&1; then
2738                 :
2739             else
2740                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2741             fi
2742          fi
2743          rm -f conftest],
2744          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2745                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2746     ]) # unaligned pcrel relocs
2747
2748     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2749       gcc_cv_as_sparc_offsetable_lo10,,
2750       [-xarch=v9],
2751 [.text
2752         or %g1, %lo(ab) + 12, %g1
2753         or %g1, %lo(ab + 12), %g1],
2754       [if test x$gcc_cv_objdump != x \
2755        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2756           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2757          gcc_cv_as_sparc_offsetable_lo10=yes
2758        fi],
2759        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2760                  [Define if your assembler supports offsetable %lo().])])
2761     ;;
2762
2763 changequote(,)dnl
2764   i[34567]86-*-* | x86_64-*-*)
2765 changequote([,])dnl
2766     case $target_os in
2767       cygwin* | pe | mingw32*)
2768         # Used for DWARF 2 in PE
2769         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2770           gcc_cv_as_ix86_pe_secrel32,
2771           [2,15,91],,
2772 [.text
2773 foo:    nop
2774 .data
2775         .secrel32 foo],
2776           [if test x$gcc_cv_ld != x \
2777            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2778              gcc_cv_as_ix86_pe_secrel32=yes
2779            fi
2780            rm -f conftest],
2781           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2782             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2783         ;;
2784     esac
2785
2786     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2787        gcc_cv_as_ix86_filds_fists,
2788       [2,9,0],, [filds mem; fists mem],,
2789       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2790         [Define if your assembler uses the new HImode fild and fist notation.])])
2791
2792     gcc_GAS_CHECK_FEATURE([cmov syntax],
2793       gcc_cv_as_ix86_cmov_sun_syntax,,,
2794       [cmovl.l %edx, %eax],,
2795       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2796         [Define if your assembler supports the Sun syntax for cmov.])])
2797
2798     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2799       gcc_cv_as_ix86_ffreep,,,
2800       [ffreep %st(1)],,
2801       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2802         [Define if your assembler supports the ffreep mnemonic.])])
2803
2804     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2805       gcc_cv_as_ix86_sahf,,,
2806       [sahf],,
2807       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2808         [Define if your assembler supports the sahf mnemonic.])])
2809
2810     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2811       gcc_cv_as_ix86_diff_sect_delta,,,
2812       [.section .rodata
2813 .L1:
2814         .long .L2-.L1
2815         .long .L3-.L1
2816         .text
2817 .L3:    nop
2818 .L2:    nop],,
2819       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2820         [Define if your assembler supports the subtraction of symbols in different sections.])])
2821
2822     # This one is used unconditionally by i386.[ch]; it is to be defined
2823     # to 1 if the feature is present, 0 otherwise.
2824     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2825         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2826 [       .text
2827 .L0:
2828         nop
2829         .data
2830         .long .L0@GOTOFF])
2831     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2832       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2833       [Define true if the assembler supports '.long foo@GOTOFF'.])
2834     ;;
2835
2836   ia64*-*-*)
2837     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2838         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2839 [       .text
2840         addl r15 = @ltoffx(x#), gp
2841         ;;
2842         ld8.mov r16 = [[r15]], x#],,
2843     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2844           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2845
2846     ;;
2847
2848   powerpc*-*-*)
2849     case $target in
2850       *-*-aix*) conftest_s='    .machine "pwr5"
2851         .csect .text[[PR]]
2852         mfcr 3,128';;
2853       *-*-darwin*)
2854         gcc_GAS_CHECK_FEATURE([.machine directive support],
2855           gcc_cv_as_machine_directive,,,
2856           [     .machine ppc7400])
2857         if test x$gcc_cv_as_machine_directive != xyes; then
2858           echo "*** This target requires an assembler supporting \".machine\"" >&2
2859           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2860           test x$build = x$target && exit 1
2861         fi
2862         conftest_s='    .text
2863         mfcr r3,128';;
2864       *) conftest_s='   .machine power4
2865         .text
2866         mfcr 3,128';;
2867     esac
2868
2869     gcc_GAS_CHECK_FEATURE([mfcr field support],
2870       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2871       [$conftest_s],,
2872       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2873           [Define if your assembler supports mfcr field.])])
2874
2875     case $target in
2876       *-*-aix*) conftest_s='    .machine "pwr5"
2877         .csect .text[[PR]]
2878         popcntb 3,3';;
2879       *) conftest_s='   .machine power5
2880         .text
2881         popcntb 3,3';;
2882     esac
2883
2884     gcc_GAS_CHECK_FEATURE([popcntb support],
2885       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2886       [$conftest_s],,
2887       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2888           [Define if your assembler supports popcntb field.])])
2889
2890     case $target in
2891       *-*-aix*) conftest_s='    .machine "pwr5x"
2892         .csect .text[[PR]]
2893         frin 1,1';;
2894       *) conftest_s='   .machine power5
2895         .text
2896         frin 1,1';;
2897     esac
2898
2899     gcc_GAS_CHECK_FEATURE([fp round support],
2900       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2901       [$conftest_s],,
2902       [AC_DEFINE(HAVE_AS_FPRND, 1,
2903           [Define if your assembler supports fprnd.])])
2904
2905     case $target in
2906       *-*-aix*) conftest_s='    .machine "pwr6"
2907         .csect .text[[PR]]
2908         mffgpr 1,3';;
2909       *) conftest_s='   .machine power6
2910         .text
2911         mffgpr 1,3';;
2912     esac
2913
2914     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2915       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2916       [$conftest_s],,
2917       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2918           [Define if your assembler supports mffgpr and mftgpr.])])
2919
2920     case $target in
2921       *-*-aix*) conftest_s='    .csect .text[[PR]]
2922 LCF..0:
2923         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2924       *-*-darwin*)
2925         conftest_s='    .text
2926 LCF0:
2927         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2928       *) conftest_s='   .text
2929 .LCF0:
2930         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2931     esac
2932
2933     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2934       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2935       [$conftest_s],,
2936       [AC_DEFINE(HAVE_AS_REL16, 1,
2937           [Define if your assembler supports R_PPC_REL16 relocs.])])
2938
2939     case $target in
2940       *-*-aix*) conftest_s='    .machine "pwr6"
2941         .csect .text[[PR]]
2942         cmpb 3,4,5';;
2943       *) conftest_s='   .machine power6
2944         .text
2945         cmpb 3,4,5';;
2946     esac
2947
2948     gcc_GAS_CHECK_FEATURE([compare bytes support],
2949       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2950       [$conftest_s],,
2951       [AC_DEFINE(HAVE_AS_CMPB, 1,
2952           [Define if your assembler supports cmpb.])])
2953
2954     case $target in
2955       *-*-aix*) conftest_s='    .machine "pwr6"
2956         .csect .text[[PR]]
2957         dadd 1,2,3';;
2958       *) conftest_s='   .machine power6
2959         .text
2960         dadd 1,2,3';;
2961     esac
2962
2963     gcc_GAS_CHECK_FEATURE([decimal float support],
2964       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2965       [$conftest_s],,
2966       [AC_DEFINE(HAVE_AS_DFP, 1,
2967           [Define if your assembler supports DFP instructions.])])
2968
2969     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2970       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
2971       [.gnu_attribute 4,1],,
2972       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2973           [Define if your assembler supports .gnu_attribute.])])
2974     ;;
2975
2976   mips*-*-*)
2977     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2978       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2979 [       lw $4,%gp_rel(foo)($4)],,
2980       [if test x$target_cpu_default = x
2981        then target_cpu_default=MASK_EXPLICIT_RELOCS
2982        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2983        fi])
2984     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2985       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2986       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2987                  [Define if the assembler understands -mno-shared.])])
2988
2989     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2990       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
2991       [.gnu_attribute 4,1],,
2992       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2993           [Define if your assembler supports .gnu_attribute.])])
2994
2995     gcc_GAS_CHECK_FEATURE([.dtprelword support],
2996       gcc_cv_as_mips_dtprelword, [2,18,0],,
2997       [.section .tdata,"awT",@progbits
2998 x:
2999         .word 2
3000         .text
3001         .dtprelword x+0x8000],,
3002       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3003           [Define if your assembler supports .dtprelword.])])
3004     ;;
3005 esac
3006
3007 # Mips and HP-UX need the GNU assembler.
3008 # Linux on IA64 might be able to use the Intel assembler.
3009
3010 case "$target" in
3011   mips*-*-* | *-*-hpux* )
3012     if test x$gas_flag = xyes \
3013        || test x"$host" != x"$build" \
3014        || test ! -x "$gcc_cv_as" \
3015        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3016       :
3017     else
3018       echo "*** This configuration requires the GNU assembler" >&2
3019       exit 1
3020     fi
3021     ;;
3022 esac
3023
3024 # ??? Not all targets support dwarf2 debug_line, even within a version
3025 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3026 # info to the output file.  So, as supported targets are added to gas 2.11,
3027 # add some instruction here to (also) show we expect this might work.
3028 # ??? Once 2.11 is released, probably need to add first known working
3029 # version to the per-target configury.
3030 case "$target" in
3031   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3032   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3033   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3034     insn="nop"
3035     ;;
3036   ia64*-*-* | s390*-*-*)
3037     insn="nop 0"
3038     ;;
3039   mmix-*-*)
3040     insn="swym 0"
3041     ;;
3042 esac
3043 if test x"$insn" != x; then
3044  conftest_s="\
3045         .file 1 \"conftest.s\"
3046         .loc 1 3 0
3047         $insn"
3048  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3049   gcc_cv_as_dwarf2_debug_line,
3050   [elf,2,11,0],, [$conftest_s],
3051   [if test x$gcc_cv_objdump != x \
3052    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3053       | grep debug_line > /dev/null 2>&1; then
3054      gcc_cv_as_dwarf2_debug_line=yes
3055    fi])
3056
3057 # The .debug_line file table must be in the exact order that
3058 # we specified the files, since these indices are also used
3059 # by DW_AT_decl_file.  Approximate this test by testing if
3060 # the assembler bitches if the same index is assigned twice.
3061  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3062   gcc_cv_as_dwarf2_file_buggy,,,
3063 [       .file 1 "foo.s"
3064         .file 1 "bar.s"])
3065
3066  if test $gcc_cv_as_dwarf2_debug_line = yes \
3067  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3068         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3069   [Define if your assembler supports dwarf2 .file/.loc directives,
3070    and preserves file table indices exactly as given.])
3071  fi
3072
3073  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3074   gcc_cv_as_gdwarf2_flag,
3075   [elf,2,11,0], [--gdwarf2], [$insn],,
3076   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3077 [Define if your assembler supports the --gdwarf2 option.])])
3078
3079  gcc_GAS_CHECK_FEATURE([--gstabs option],
3080   gcc_cv_as_gstabs_flag,
3081   [elf,2,11,0], [--gstabs], [$insn],
3082   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3083    # and warns about it, but still exits successfully.  So check for
3084    # this.
3085    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3086    then :
3087    else gcc_cv_as_gstabs_flag=yes
3088    fi],
3089   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3090 [Define if your assembler supports the --gstabs option.])])
3091
3092  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3093   gcc_cv_as_debug_prefix_map_flag,
3094   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3095   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3096 [Define if your assembler supports the --debug-prefix-map option.])])
3097 fi
3098
3099 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3100  [gcc_cv_as_line_zero],
3101  [gcc_cv_as_line_zero=no
3102   if test $in_tree_gas = yes; then
3103     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3104   elif test "x$gcc_cv_as" != x; then
3105     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3106     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3107        test "x`cat conftest.out`" = x
3108     then
3109       gcc_cv_as_line_zero=yes
3110     else
3111       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3112       cat conftest.s >&AS_MESSAGE_LOG_FD
3113       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3114       cat conftest.out >&AS_MESSAGE_LOG_FD
3115     fi
3116     rm -f conftest.o conftest.s conftest.out
3117   fi])
3118 if test "x$gcc_cv_as_line_zero" = xyes; then
3119   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3120 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3121 fi
3122
3123 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3124 gcc_cv_ld_ro_rw_mix=unknown
3125 if test $in_tree_ld = yes ; then
3126   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3127      && test $in_tree_ld_is_elf = yes; then
3128     gcc_cv_ld_ro_rw_mix=read-write
3129   fi
3130 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3131   echo '.section myfoosect, "a"' > conftest1.s
3132   echo '.section myfoosect, "aw"' > conftest2.s
3133   echo '.byte 1' >> conftest2.s
3134   echo '.section myfoosect, "a"' > conftest3.s
3135   echo '.byte 0' >> conftest3.s
3136   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3137      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3138      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3139      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3140         conftest2.o conftest3.o > /dev/null 2>&1; then
3141     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3142                          | sed -e '/myfoosect/!d' -e N`
3143     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3144       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3145         gcc_cv_ld_ro_rw_mix=read-only
3146       else
3147         gcc_cv_ld_ro_rw_mix=read-write
3148       fi
3149     fi
3150   fi
3151 changequote(,)dnl
3152   rm -f conftest.* conftest[123].*
3153 changequote([,])dnl
3154 fi
3155 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3156         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3157   [Define if your linker links a mix of read-only
3158    and read-write sections into a read-write section.])
3159 fi
3160 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3161
3162 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3163 gcc_cv_ld_eh_frame_hdr=no
3164 if test $in_tree_ld = yes ; then
3165   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3166      && test $in_tree_ld_is_elf = yes; then
3167     gcc_cv_ld_eh_frame_hdr=yes
3168   fi
3169 elif test x$gcc_cv_ld != x; then
3170         # Check if linker supports --eh-frame-hdr option
3171         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3172                 gcc_cv_ld_eh_frame_hdr=yes
3173         fi
3174 fi
3175 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3176 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3177         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3178 [Define if your linker supports --eh-frame-hdr option.])
3179 fi
3180 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3181
3182 AC_MSG_CHECKING(linker position independent executable support)
3183 gcc_cv_ld_pie=no
3184 if test $in_tree_ld = yes ; then
3185   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3186      && test $in_tree_ld_is_elf = yes; then
3187     gcc_cv_ld_pie=yes
3188   fi
3189 elif test x$gcc_cv_ld != x; then
3190         # Check if linker supports -pie option
3191         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3192                 gcc_cv_ld_pie=yes
3193         fi
3194 fi
3195 if test x"$gcc_cv_ld_pie" = xyes; then
3196         AC_DEFINE(HAVE_LD_PIE, 1,
3197 [Define if your linker supports -pie option.])
3198 fi
3199 AC_MSG_RESULT($gcc_cv_ld_pie)
3200
3201 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3202 gcc_cv_ld_eh_gc_sections=no
3203 if test $in_tree_ld = yes ; then
3204   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3205      && test $in_tree_ld_is_elf = yes; then
3206     gcc_cv_ld_eh_gc_sections=yes
3207   fi
3208 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3209   cat > conftest.s <<EOF
3210         .section        .text
3211 .globl _start
3212         .type _start, @function
3213 _start:
3214         .long foo
3215         .size _start, .-_start
3216         .section        .text.foo,"ax",@progbits
3217         .type foo, @function
3218 foo:
3219         .long 0
3220         .size foo, .-foo
3221         .section        .gcc_except_table.foo,"a",@progbits
3222 .L0:
3223         .long 0
3224         .section        .eh_frame,"a",@progbits
3225         .long .L0
3226 EOF
3227   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3228     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3229          | grep "gc-sections option ignored" > /dev/null; then
3230       gcc_cv_ld_eh_gc_sections=no
3231     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3232       gcc_cv_ld_eh_gc_sections=yes
3233       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3234       if test x$gcc_cv_as_comdat_group != xyes; then
3235         gcc_cv_ld_eh_gc_sections=no
3236         cat > conftest.s <<EOF
3237         .section        .text
3238 .globl _start
3239         .type _start, @function
3240 _start:
3241         .long foo
3242         .size _start, .-_start
3243         .section        .gnu.linkonce.t.foo,"ax",@progbits
3244         .type foo, @function
3245 foo:
3246         .long 0
3247         .size foo, .-foo
3248         .section        .gcc_except_table.foo,"a",@progbits
3249 .L0:
3250         .long 0
3251         .section        .eh_frame,"a",@progbits
3252         .long .L0
3253 EOF
3254         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3255           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3256                | grep "gc-sections option ignored" > /dev/null; then
3257             gcc_cv_ld_eh_gc_sections=no
3258           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3259             gcc_cv_ld_eh_gc_sections=yes
3260           fi
3261         fi
3262       fi
3263     fi
3264   fi
3265   rm -f conftest.s conftest.o conftest
3266 fi
3267 case "$target" in
3268   hppa*-*-linux*)
3269     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3270     gcc_cv_ld_eh_gc_sections=no
3271     ;;
3272 esac
3273 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3274         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3275   [Define if your linker supports garbage collection of
3276    sections in presence of EH frames.])
3277 fi
3278 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3279
3280 # --------
3281 # UNSORTED
3282 # --------
3283
3284 AC_CACHE_CHECK(linker --as-needed support,
3285 gcc_cv_ld_as_needed,
3286 [gcc_cv_ld_as_needed=no
3287 if test $in_tree_ld = yes ; then
3288   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3289      && test $in_tree_ld_is_elf = yes; then
3290     gcc_cv_ld_as_needed=yes
3291   fi
3292 elif test x$gcc_cv_ld != x; then
3293         # Check if linker supports --as-needed and --no-as-needed options
3294         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3295                 gcc_cv_ld_as_needed=yes
3296         fi
3297 fi
3298 ])
3299 if test x"$gcc_cv_ld_as_needed" = xyes; then
3300         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3301 [Define if your linker supports --as-needed and --no-as-needed options.])
3302 fi
3303
3304 case "$target:$tm_file" in
3305   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3306     AC_CACHE_CHECK(linker support for omitting dot symbols,
3307     gcc_cv_ld_no_dot_syms,
3308     [gcc_cv_ld_no_dot_syms=no
3309     if test $in_tree_ld = yes ; then
3310       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3311         gcc_cv_ld_no_dot_syms=yes
3312       fi
3313     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3314       cat > conftest1.s <<EOF
3315         .text
3316         bl .foo
3317 EOF
3318       cat > conftest2.s <<EOF
3319         .section ".opd","aw"
3320         .align 3
3321         .globl foo
3322         .type foo,@function
3323 foo:
3324         .quad .LEfoo,.TOC.@tocbase,0
3325         .text
3326 .LEfoo:
3327         blr
3328         .size foo,.-.LEfoo
3329 EOF
3330       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3331          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3332          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3333         gcc_cv_ld_no_dot_syms=yes
3334       fi
3335       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3336     fi
3337     ])
3338     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3339       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3340     [Define if your PowerPC64 linker only needs function descriptor syms.])
3341     fi
3342     ;;
3343 esac
3344
3345 AC_CACHE_CHECK(linker --sysroot support,
3346   gcc_cv_ld_sysroot,
3347   [gcc_cv_ld_sysroot=no
3348   if test $in_tree_ld = yes ; then
3349       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3350         gcc_cv_ld_sysroot=yes
3351       fi
3352   elif test x$gcc_cv_ld != x; then
3353     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3354       gcc_cv_ld_sysroot=yes
3355     fi
3356   fi])
3357 if test x"$gcc_cv_ld_sysroot" = xyes; then
3358   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3359   [Define if your linker supports --sysroot.])
3360 fi
3361
3362 if test x$with_sysroot = x && test x$host = x$target \
3363    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3364    && test "$prefix" != "NONE"; then
3365   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3366 [Define to PREFIX/include if cpp should also search that directory.])
3367 fi
3368
3369 # Test for stack protector support in target C library.
3370 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3371       gcc_cv_libc_provides_ssp,
3372       [gcc_cv_libc_provides_ssp=no
3373     case "$target" in
3374        *-*-linux*)
3375       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3376         if test "x$with_sysroot" = x; then
3377           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3378         elif test "x$with_build_sysroot" != "x"; then
3379           glibc_header_dir="${with_build_sysroot}/usr/include"
3380         elif test "x$with_sysroot" = xyes; then
3381           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3382         else
3383           glibc_header_dir="${with_sysroot}/usr/include"
3384         fi
3385       else
3386         glibc_header_dir=/usr/include
3387       fi
3388       # glibc 2.4 and later provides __stack_chk_fail and
3389       # either __stack_chk_guard, or TLS access to stack guard canary.
3390       if test -f $glibc_header_dir/features.h \
3391          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3392             $glibc_header_dir/features.h > /dev/null; then
3393         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3394            $glibc_header_dir/features.h > /dev/null; then
3395           gcc_cv_libc_provides_ssp=yes
3396         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3397              $glibc_header_dir/features.h > /dev/null \
3398              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3399              $glibc_header_dir/features.h > /dev/null; then
3400           gcc_cv_libc_provides_ssp=yes
3401         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3402              $glibc_header_dir/features.h > /dev/null && \
3403              test -f $glibc_header_dir/bits/uClibc_config.h && \
3404              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3405              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3406           gcc_cv_libc_provides_ssp=yes
3407         fi
3408       fi
3409         ;;
3410        *-*-darwin*)
3411          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3412            [echo "no __stack_chk_fail on this target"])
3413         ;;
3414   *) gcc_cv_libc_provides_ssp=no ;;
3415     esac])
3416
3417 if test x$gcc_cv_libc_provides_ssp = xyes; then
3418   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3419             [Define if your target C library provides stack protector support])
3420 fi
3421
3422 # Check if TFmode long double should be used by default or not.
3423 # Some glibc targets used DFmode long double, but with glibc 2.4
3424 # and later they can use TFmode.
3425 case "$target" in
3426   powerpc*-*-linux* | \
3427   powerpc*-*-gnu* | \
3428   sparc*-*-linux* | \
3429   s390*-*-linux* | \
3430   alpha*-*-linux*)
3431     AC_ARG_WITH(long-double-128,
3432 [  --with-long-double-128  Use 128-bit long double by default.],
3433       gcc_cv_target_ldbl128="$with_long_double_128",
3434       [gcc_cv_target_ldbl128=no
3435       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3436         if test "x$with_sysroot" = x; then
3437           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3438         elif test "x$with_build_sysroot" != "x"; then
3439           glibc_header_dir="${with_build_sysroot}/usr/include"
3440         elif test "x$with_sysroot" = xyes; then
3441           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3442         else
3443           glibc_header_dir="${with_sysroot}/usr/include"
3444         fi
3445       else
3446         glibc_header_dir=/usr/include
3447       fi
3448 changequote(,)dnl
3449       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3450         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3451       && gcc_cv_target_ldbl128=yes
3452 changequote([,])dnl
3453       ])
3454     ;;
3455 esac
3456 if test x$gcc_cv_target_ldbl128 = xyes; then
3457   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3458             [Define if TFmode long double should be the default])
3459 fi
3460
3461 # Find out what GC implementation we want, or may, use.
3462 AC_ARG_WITH(gc,
3463 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3464                           with the compiler],
3465 [case "$withval" in
3466   page)
3467     GGC=ggc-$withval
3468     ;;
3469   zone)
3470     GGC=ggc-$withval
3471     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3472     ;;
3473   *)
3474     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3475     ;;
3476 esac],
3477 [GGC=ggc-page])
3478 AC_SUBST(GGC)
3479 echo "Using $GGC for garbage collection."
3480
3481 # Use the system's zlib library.
3482 zlibdir=-L../zlib
3483 zlibinc="-I\$(srcdir)/../zlib"
3484 AC_ARG_WITH(system-zlib,
3485 [  --with-system-zlib      use installed libz],
3486 zlibdir=
3487 zlibinc=
3488 )
3489 AC_SUBST(zlibdir)
3490 AC_SUBST(zlibinc)
3491
3492 dnl Very limited version of automake's enable-maintainer-mode
3493
3494 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3495   dnl maintainer-mode is disabled by default
3496   AC_ARG_ENABLE(maintainer-mode,
3497 [  --enable-maintainer-mode
3498                           enable make rules and dependencies not useful
3499                           (and sometimes confusing) to the casual installer],
3500       maintainer_mode=$enableval,
3501       maintainer_mode=no)
3502
3503 AC_MSG_RESULT($maintainer_mode)
3504
3505 if test "$maintainer_mode" = "yes"; then
3506   MAINT=''
3507 else
3508   MAINT='#'
3509 fi
3510 AC_SUBST(MAINT)dnl
3511
3512 # --------------
3513 # Language hooks
3514 # --------------
3515
3516 # Make empty files to contain the specs and options for each language.
3517 # Then add #include lines to for a compiler that has specs and/or options.
3518
3519 subdirs=
3520 lang_opt_files=
3521 lang_specs_files=
3522 lang_tree_files=
3523 # These (without "all_") are set in each config-lang.in.
3524 # `language' must be a single word so is spelled singularly.
3525 all_languages=
3526 all_compilers=
3527 all_outputs='Makefile gccbug libada-mk'
3528 # List of language makefile fragments.
3529 all_lang_makefrags=
3530 # List of language subdirectory makefiles.  Deprecated.
3531 all_lang_makefiles=
3532 # Additional files for gengtype
3533 all_gtfiles="$target_gtfiles"
3534
3535 # These are the languages that are set in --enable-languages,
3536 # and are available in the GCC tree.
3537 all_selected_languages=
3538
3539 # Add the language fragments.
3540 # Languages are added via two mechanisms.  Some information must be
3541 # recorded in makefile variables, these are defined in config-lang.in.
3542 # We accumulate them and plug them into the main Makefile.
3543 # The other mechanism is a set of hooks for each of the main targets
3544 # like `clean', `install', etc.
3545
3546 language_hooks="Make-hooks"
3547
3548 for lang in ${srcdir}/*/config-lang.in
3549 do
3550 changequote(,)dnl
3551         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3552
3553         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3554         if test "x$lang_alias" = x
3555         then
3556               echo "$lang doesn't set \$language." 1>&2
3557               exit 1
3558         fi
3559         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3560         subdirs="$subdirs $subdir"
3561         case ",$enable_languages," in
3562         *,$lang_alias,*)
3563             all_selected_languages="$all_selected_languages $lang_alias"
3564             if test -f $srcdir/$subdir/lang-specs.h; then
3565                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3566             fi
3567             ;;
3568         esac
3569 changequote([,])dnl
3570
3571         language=
3572         boot_language=
3573         compilers=
3574         outputs=
3575         gtfiles=
3576         subdir_requires=
3577         . ${srcdir}/$subdir/config-lang.in
3578         if test "x$language" = x
3579         then
3580                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3581                 exit 1
3582         fi
3583
3584         ok=:
3585         case ",$enable_languages," in
3586                 *,$lang_alias,*) ;;
3587                 *)
3588                         for i in $subdir_requires; do
3589                                 test -f "${srcdir}/$i/config-lang.in" && continue
3590                                 ok=false
3591                                 break
3592                         done
3593                 ;;
3594         esac
3595         $ok || continue
3596
3597         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3598         if test -f $srcdir/$subdir/lang.opt; then
3599             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3600         fi
3601         if test -f $srcdir/$subdir/$subdir-tree.def; then
3602             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3603         fi
3604         if test -f ${srcdir}/$subdir/Makefile.in
3605                 then all_lang_makefiles="$subdir/Makefile"
3606         fi
3607         all_languages="$all_languages $language"
3608         all_compilers="$all_compilers $compilers"
3609         all_outputs="$all_outputs $outputs"
3610         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3611 done
3612
3613 # Pick up gtfiles for c
3614 gtfiles=
3615 . ${srcdir}/c-config-lang.in
3616 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3617
3618 check_languages=
3619 for language in $all_selected_languages
3620 do
3621         check_languages="$check_languages check-$language"
3622 done
3623
3624 # We link each language in with a set of hooks, reached indirectly via
3625 # lang.${target}.  Only do so for selected languages.
3626
3627 rm -f Make-hooks
3628 touch Make-hooks
3629 target_list="all.cross start.encap rest.encap tags \
3630         install-common install-man install-info install-pdf dvi pdf \
3631         html uninstall info man srcextra srcman srcinfo \
3632         mostlyclean clean distclean maintainer-clean"
3633
3634 for t in $target_list
3635 do
3636         x=
3637         for lang in $all_selected_languages
3638         do
3639                 x="$x $lang.$t"
3640         done
3641         echo "lang.$t: $x" >> Make-hooks
3642 done
3643
3644 # --------
3645 # UNSORTED
3646 # --------
3647
3648 # Create .gdbinit.
3649
3650 echo "dir ." > .gdbinit
3651 echo "dir ${srcdir}" >> .gdbinit
3652 if test x$gdb_needs_out_file_path = xyes
3653 then
3654         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3655 fi
3656 if test "x$subdirs" != x; then
3657         for s in $subdirs
3658         do
3659                 echo "dir ${srcdir}/$s" >> .gdbinit
3660         done
3661 fi
3662 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3663
3664 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3665 AC_SUBST(gcc_tooldir)
3666 AC_SUBST(dollar)
3667
3668 # Find a directory in which to install a shared libgcc.
3669
3670 AC_ARG_ENABLE(version-specific-runtime-libs,
3671 [  --enable-version-specific-runtime-libs
3672                           specify that runtime libraries should be
3673                           installed in a compiler-specific directory])
3674
3675 AC_ARG_WITH(slibdir,
3676 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3677 slibdir="$with_slibdir",
3678 if test "${enable_version_specific_runtime_libs+set}" = set; then
3679   slibdir='$(libsubdir)'
3680 elif test "$host" != "$target"; then
3681   slibdir='$(build_tooldir)/lib'
3682 else
3683   slibdir='$(libdir)'
3684 fi)
3685 AC_SUBST(slibdir)
3686
3687 objdir=`${PWDCMD-pwd}`
3688 AC_SUBST(objdir)
3689
3690 AC_ARG_WITH(datarootdir,
3691 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3692 datarootdir="\${prefix}/$with_datarootdir",
3693 datarootdir='$(prefix)/share')
3694 AC_SUBST(datarootdir)
3695
3696 AC_ARG_WITH(docdir,
3697 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3698 docdir="\${prefix}/$with_docdir",
3699 docdir='$(datarootdir)')
3700 AC_SUBST(docdir)
3701
3702 AC_ARG_WITH(htmldir,
3703 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3704 htmldir="\${prefix}/$with_htmldir",
3705 htmldir='$(docdir)')
3706 AC_SUBST(htmldir)
3707
3708 # Substitute configuration variables
3709 AC_SUBST(subdirs)
3710 AC_SUBST(srcdir)
3711 AC_SUBST(all_compilers)
3712 AC_SUBST(all_gtfiles)
3713 AC_SUBST(all_lang_makefrags)
3714 AC_SUBST(all_lang_makefiles)
3715 AC_SUBST(all_languages)
3716 AC_SUBST(all_selected_languages)
3717 AC_SUBST(build_exeext)
3718 AC_SUBST(build_install_headers_dir)
3719 AC_SUBST(build_xm_file_list)
3720 AC_SUBST(build_xm_include_list)
3721 AC_SUBST(build_xm_defines)
3722 AC_SUBST(check_languages)
3723 AC_SUBST(cpp_install_dir)
3724 AC_SUBST(xmake_file)
3725 AC_SUBST(tmake_file)
3726 AC_SUBST(extra_gcc_objs)
3727 AC_SUBST(extra_headers_list)
3728 AC_SUBST(extra_objs)
3729 AC_SUBST(extra_parts)
3730 AC_SUBST(extra_passes)
3731 AC_SUBST(extra_programs)
3732 AC_SUBST(float_h_file)
3733 AC_SUBST(gcc_config_arguments)
3734 AC_SUBST(gcc_gxx_include_dir)
3735 AC_SUBST(host_exeext)
3736 AC_SUBST(host_xm_file_list)
3737 AC_SUBST(host_xm_include_list)
3738 AC_SUBST(host_xm_defines)
3739 AC_SUBST(out_host_hook_obj)
3740 AC_SUBST(install)
3741 AC_SUBST(lang_opt_files)
3742 AC_SUBST(lang_specs_files)
3743 AC_SUBST(lang_tree_files)
3744 AC_SUBST(local_prefix)
3745 AC_SUBST(md_file)
3746 AC_SUBST(objc_boehm_gc)
3747 AC_SUBST(out_file)
3748 AC_SUBST(out_object_file)
3749 AC_SUBST(thread_file)
3750 AC_SUBST(tm_file_list)
3751 AC_SUBST(tm_include_list)
3752 AC_SUBST(tm_defines)
3753 AC_SUBST(tm_p_file_list)
3754 AC_SUBST(tm_p_include_list)
3755 AC_SUBST(xm_file_list)
3756 AC_SUBST(xm_include_list)
3757 AC_SUBST(xm_defines)
3758 AC_SUBST(c_target_objs)
3759 AC_SUBST(cxx_target_objs)
3760 AC_SUBST(target_cpu_default)
3761
3762 AC_SUBST_FILE(language_hooks)
3763
3764 # Echo link setup.
3765 if test x${build} = x${host} ; then
3766   if test x${host} = x${target} ; then
3767     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3768   else
3769     echo "Links are now set up to build a cross-compiler" 1>&2
3770     echo " from ${host} to ${target}." 1>&2
3771   fi
3772 else
3773   if test x${host} = x${target} ; then
3774     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3775     echo " for ${target}." 1>&2
3776   else
3777     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3778     echo " from ${host} to ${target}." 1>&2
3779   fi
3780 fi
3781
3782 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3783 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3784
3785 # Configure the subdirectories
3786 # AC_CONFIG_SUBDIRS($subdirs)
3787
3788 # Create the Makefile
3789 # and configure language subdirectories
3790 AC_CONFIG_FILES($all_outputs)
3791
3792 AC_CONFIG_COMMANDS([default],
3793 [
3794 case ${CONFIG_HEADERS} in
3795   *auto-host.h:config.in*)
3796   echo > cstamp-h ;;
3797 esac
3798 # Make sure all the subdirs exist.
3799 for d in $subdirs doc build
3800 do
3801     test -d $d || mkdir $d
3802 done
3803 ],
3804 [subdirs='$subdirs'])
3805 AC_OUTPUT