gcc/configure.in

   1 # configure.in for GNU CC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GNU CC.
   7
   8 #GNU CC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12
  13 #GNU CC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU CC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330,
  21 #Boston, MA 02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname).],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as.],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname).],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format.],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format.],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include.],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files.],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib      enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor.],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin.],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       Enable multibyte characters for C and C++.],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC.
 277   --enable-threads=LIB    use LIB thread package for target GCC.],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime.],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2          force the default debug format to be DWARF2.],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared       don't provide a shared libgcc.],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Find the native compiler
 339 AC_PROG_CC
 340 AC_PROG_CC_C_O
 341 # autoconf is lame and doesn't give us any substitution variable for this.
 342 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 343   NO_MINUS_C_MINUS_O=yes
 344 else
 345   OUTPUT_OPTION='-o $@'
 346 fi
 347 AC_SUBST(NO_MINUS_C_MINUS_O)
 348 AC_SUBST(OUTPUT_OPTION)
 349
 350 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 351 ac_cv_prog_cc_no_long_long,
 352 [save_CFLAGS="$CFLAGS"
 353 CFLAGS="-Wno-long-long"
 354 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 355                ac_cv_prog_cc_no_long_long=no)
 356 CFLAGS="$save_CFLAGS"])
 357 strict1_warn=
 358 if test $ac_cv_prog_cc_no_long_long = yes; then
 359   strict1_warn="-pedantic -Wno-long-long"
 360 fi
 361 AC_SUBST(strict1_warn)
 362
 363 AC_PROG_CPP
 364 AC_C_INLINE
 365 gcc_AC_C_VOLATILE
 366
 367 gcc_AC_C_LONG_DOUBLE
 368 gcc_AC_C_LONG_LONG
 369
 370 # sizeof(char) is 1 by definition.
 371 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 372 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 373 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 374 if test $ac_cv_c_long_long = yes; then
 375   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 376 fi
 377 if test $ac_cv_c___int64 = yes; then
 378   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 379 fi
 380
 381 gcc_AC_C_CHARSET
 382
 383 # If the native compiler is GCC, we can enable warnings even in stage1.
 384 # That's useful for people building cross-compilers, or just running a
 385 # quick `make'.
 386 warn_cflags=
 387 if test "x$GCC" = "xyes"; then
 388   warn_cflags='$(GCC_WARN_CFLAGS)'
 389 fi
 390 AC_SUBST(warn_cflags)
 391
 392 # Stage specific cflags for build.
 393 stage1_cflags=
 394 case $build in
 395 vax-*-*)
 396   if test x$GCC = xyes
 397   then
 398     stage1_cflags="-Wa,-J"
 399   else
 400     stage1_cflags="-J"
 401   fi
 402   ;;
 403 esac
 404 AC_SUBST(stage1_cflags)
 405
 406 AC_PROG_MAKE_SET
 407
 408 AC_MSG_CHECKING([whether a default assembler was specified])
 409 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 410     if test x"$gas_flag" = x"no"; then
 411         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 412     else
 413         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 414     fi
 415 else
 416     AC_MSG_RESULT(no)
 417 fi
 418
 419 AC_MSG_CHECKING([whether a default linker was specified])
 420 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 421     if test x"$gnu_ld_flag" = x"no"; then
 422         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 423     else
 424         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 425     fi
 426 else
 427     AC_MSG_RESULT(no)
 428 fi
 429
 430 AC_MSG_CHECKING(for GNU C library)
 431 AC_CACHE_VAL(gcc_cv_glibc,
 432 [AC_TRY_COMPILE(
 433   [#include <features.h>],[
 434 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 435 #error Not a GNU C library system
 436 #endif],
 437   [gcc_cv_glibc=yes],
 438   gcc_cv_glibc=no)])
 439 AC_MSG_RESULT($gcc_cv_glibc)
 440 if test $gcc_cv_glibc = yes; then
 441   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 442 fi
 443
 444 # Find some useful tools
 445 AC_PROG_AWK
 446 gcc_AC_PROG_LN
 447 gcc_AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 gcc_AC_PROG_INSTALL
 450
 451 AC_HEADER_STDC
 452 AC_HEADER_TIME
 453 gcc_AC_HEADER_STRING
 454 AC_HEADER_SYS_WAIT
 455 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 456                  fcntl.h unistd.h sys/file.h sys/time.h \
 457                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 458                  direct.h malloc.h langinfo.h iconv.h stdbool.h)
 459
 460 # Check for thread headers.
 461 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 462 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 463
 464 # These tests can't be done till we know if we have limits.h.
 465 gcc_AC_C_CHAR_BIT
 466 gcc_AC_C_COMPILE_ENDIAN
 467 gcc_AC_C_FLOAT_FORMAT
 468
 469 # See if GNAT has been installed
 470 AC_CHECK_PROG(have_gnat, gnatbind, yes, no)
 471
 472 # See if we have the mktemp command.
 473 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 474
 475 # Do we have a single-tree copy of texinfo?
 476 if test -f $srcdir/../texinfo/Makefile.in; then
 477   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 478   gcc_cv_prog_makeinfo_modern=yes
 479   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 480 else
 481   # See if makeinfo has been installed and is modern enough
 482   # that we can use it.
 483   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 484   [GNU texinfo.* \([0-9][0-9.]*\)],
 485   [4.*])
 486 fi
 487
 488 if test $gcc_cv_prog_makeinfo_modern = no; then
 489   AC_MSG_WARN([
 490 *** Makeinfo is missing or too old.
 491 *** Info documentation will not be built.])
 492   BUILD_INFO=
 493 else
 494   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 495 fi
 496
 497 # Is pod2man recent enough to regenerate manpages?
 498 AC_MSG_CHECKING([for recent Pod::Man])
 499 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 500   AC_MSG_RESULT(yes)
 501   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 502 else
 503   AC_MSG_RESULT(no)
 504   GENERATED_MANPAGES=
 505 fi
 506
 507 # How about lex?
 508 dnl Don't use AC_PROG_LEX; we insist on flex.
 509 dnl LEXLIB is not useful in gcc.
 510 if test -f $srcdir/../flex/skel.c; then
 511   FLEX='$(objdir)/../flex/flex'
 512 else
 513   AC_CHECK_PROG(FLEX, flex, flex, false)
 514 fi
 515
 516 # Bison?
 517 # The -L switch is so bison can find its skeleton file.
 518 if test -f $srcdir/../bison/bison.simple; then
 519   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 520 else
 521   AC_CHECK_PROG(BISON, bison, bison, false)
 522 fi
 523
 524 # These libraries may be used by collect2.
 525 # We may need a special search path to get them linked.
 526 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 527 [save_LIBS="$LIBS"
 528 for libs in '' -lld -lmld '-lmld -lexc' \
 529                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 530                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 531 do
 532         LIBS="$libs"
 533         AC_TRY_LINK_FUNC(ldopen,
 534                 [gcc_cv_collect2_libs="$libs"; break])
 535 done
 536 LIBS="$save_LIBS"
 537 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 538 case $gcc_cv_collect2_libs in
 539         "none required")        ;;
 540         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 541 esac
 542 AC_SUBST(COLLECT2_LIBS)
 543
 544 # See if the stage1 system preprocessor understands the ANSI C
 545 # preprocessor stringification operator.  (Used by symcat.h.)
 546 AC_C_STRINGIZE
 547
 548 # Use <inttypes.h> only if it exists,
 549 # doesn't clash with <sys/types.h>, and declares intmax_t.
 550 AC_MSG_CHECKING(for inttypes.h)
 551 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 552 [AC_TRY_COMPILE(
 553   [#include <sys/types.h>
 554 #include <inttypes.h>],
 555   [intmax_t i = -1;],
 556   [gcc_cv_header_inttypes_h=yes],
 557   gcc_cv_header_inttypes_h=no)])
 558 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 559 if test $gcc_cv_header_inttypes_h = yes; then
 560   AC_DEFINE(HAVE_INTTYPES_H, 1,
 561         [Define if you have a working <inttypes.h> header file.])
 562 fi
 563
 564 dnl Disabled until we have a complete test for buggy enum bitfields.
 565 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 566
 567 AC_CHECK_FUNCS(strtoul bsearch popen times clock \
 568         strchr strrchr kill getrlimit setrlimit atoll atoq \
 569         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 570         fputs_unlocked getrusage iconv nl_langinfo lstat)
 571
 572 AC_CHECK_TYPE(ssize_t, int)
 573
 574 # Try to determine the array type of the second argument of getgroups
 575 # for the target system (int or gid_t).
 576 AC_TYPE_GETGROUPS
 577 if test "${target}" = "${build}"; then
 578   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 579 else
 580   case "${target}" in
 581         # This condition may need some tweaking.  It should include all
 582         # targets where the array type of the second argument of getgroups
 583         # is int and the type of gid_t is not equivalent to int.
 584         *-*-sunos* | *-*-ultrix*)
 585                 TARGET_GETGROUPS_T=int
 586                 ;;
 587         *)
 588                 TARGET_GETGROUPS_T=gid_t
 589                 ;;
 590   esac
 591 fi
 592 AC_SUBST(TARGET_GETGROUPS_T)
 593
 594 gcc_AC_FUNC_VFPRINTF_DOPRNT
 595 gcc_AC_FUNC_STRSTR
 596 gcc_AC_FUNC_PRINTF_PTR
 597
 598 case "${host}" in
 599 *-*-uwin*)
 600   AC_MSG_ERROR([
 601 *** UWIN may not be used as a host platform because
 602 *** linking with posix.dll is not allowed by the GNU GPL])
 603   ;;
 604 esac
 605 AC_FUNC_VFORK
 606 AC_FUNC_MMAP_ANYWHERE
 607 AC_FUNC_MMAP_FILE
 608
 609 # We will need to find libiberty.h and ansidecl.h
 610 saved_CFLAGS="$CFLAGS"
 611 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 612 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 613         strsignal putc_unlocked fputs_unlocked strstr environ errno \
 614         malloc realloc calloc free basename getopt clock, , ,[
 615 #include "ansidecl.h"
 616 #include "system.h"])
 617
 618 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 619 #include "ansidecl.h"
 620 #include "system.h"
 621 #ifdef HAVE_SYS_RESOURCE_H
 622 #include <sys/resource.h>
 623 #endif
 624 ])
 625
 626 gcc_AC_CHECK_DECLS(times, , ,[
 627 #include "ansidecl.h"
 628 #include "system.h"
 629 #ifdef HAVE_SYS_TIMES_H
 630 #include <sys/times.h>
 631 #endif
 632 ])
 633
 634 # More time-related stuff.
 635 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 636 AC_TRY_COMPILE([
 637 #include "ansidecl.h"
 638 #include "system.h"
 639 #ifdef HAVE_SYS_TIMES_H
 640 #include <sys/times.h>
 641 #endif
 642 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 643 if test $ac_cv_struct_tms = yes; then
 644   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 645   [Define if <sys/times.h> defines struct tms.])
 646 fi
 647
 648 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 649 # revisit after autoconf 2.50.
 650 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 651 AC_TRY_COMPILE([
 652 #include "ansidecl.h"
 653 #include "system.h"
 654 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 655 if test $gcc_cv_type_clock_t = yes; then
 656   AC_DEFINE(HAVE_CLOCK_T, 1,
 657   [Define if <time.h> defines clock_t.])
 658 fi
 659
 660 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 661 CFLAGS="$saved_CFLAGS"
 662
 663 # mkdir takes a single argument on some systems.
 664 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 665
 666 # File extensions
 667 manext='.1'
 668 objext='.o'
 669 AC_SUBST(manext)
 670 AC_SUBST(objext)
 671
 672 build_xm_file=
 673 build_xm_defines=
 674 build_install_headers_dir=install-headers-tar
 675 build_exeext=
 676 host_xm_file=
 677 host_xm_defines=
 678 host_xmake_file=
 679 host_truncate_target=
 680 host_exeext=
 681
 682 # Decode the host machine, then the target machine.
 683 # For the host machine, we save the xm_file variable as host_xm_file;
 684 # then we decode the target machine and forget everything else
 685 # that came from the host machine.
 686 for machine in $build $host $target; do
 687         . ${srcdir}/config.gcc
 688 done
 689
 690 extra_objs="${host_extra_objs} ${extra_objs}"
 691
 692 # Default the target-machine variables that were not explicitly set.
 693 if test x"$tm_file" = x
 694 then tm_file=$cpu_type/$cpu_type.h; fi
 695
 696 if test x"$extra_headers" = x
 697 then extra_headers=; fi
 698
 699 if test x$md_file = x
 700 then md_file=$cpu_type/$cpu_type.md; fi
 701
 702 if test x$out_file = x
 703 then out_file=$cpu_type/$cpu_type.c; fi
 704
 705 if test x"$tmake_file" = x
 706 then tmake_file=$cpu_type/t-$cpu_type
 707 fi
 708
 709 if test x"$dwarf2" = xyes
 710 then tm_file="$tm_file tm-dwarf2.h"
 711 fi
 712
 713 if test x$float_format = x
 714 then float_format=i64
 715 fi
 716
 717 if test $float_format = none
 718 then float_h_file=Makefile.in
 719 else float_h_file=float-$float_format.h
 720 fi
 721
 722 # Handle cpp installation.
 723 if test x$enable_cpp != xno
 724 then
 725   tmake_file="$tmake_file t-install-cpp"
 726 fi
 727
 728 # Say what files are being used for the output code and MD file.
 729 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 730 echo "Using \`$srcdir/config/$md_file' as machine description file."
 731
 732 # If any of the xm_file variables contain nonexistent files, warn
 733 # about them and drop them.
 734
 735 changequote(,)dnl
 736 bx=
 737 for x in $build_xm_file; do
 738   if    test -f $srcdir/config/$x
 739   then      bx="$bx $x"
 740   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 741   fi
 742 done
 743 build_xm_file="$bx"
 744
 745 hx=
 746 for x in $host_xm_file; do
 747   if    test -f $srcdir/config/$x
 748   then      hx="$hx $x"
 749   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 750   fi
 751 done
 752 host_xm_file="$hx"
 753
 754 tx=
 755 for x in $xm_file; do
 756   if    test -f $srcdir/config/$x
 757   then      tx="$tx $x"
 758   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 759   fi
 760 done
 761 xm_file="$tx"
 762 changequote([,])dnl
 763
 764 count=a
 765 for f in $tm_file; do
 766         count=${count}x
 767 done
 768 if test $count = ax; then
 769         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 770 else
 771         echo "Using the following target machine macro files:"
 772         for f in $tm_file; do
 773                 echo "  $srcdir/config/$f"
 774         done
 775 fi
 776
 777 count=a
 778 for f in $host_xm_file; do
 779         count=${count}x
 780 done
 781 if test $count = a; then
 782         :
 783 elif test $count = ax; then
 784         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 785 else
 786         echo "Using the following host machine macro files:"
 787         for f in $host_xm_file; do
 788                 echo "  $srcdir/config/$f"
 789         done
 790 fi
 791
 792 if test "$host_xm_file" != "$build_xm_file"; then
 793         count=a
 794         for f in $build_xm_file; do
 795                 count=${count}x
 796         done
 797         if test $count = a; then
 798                 :
 799         elif test $count = ax; then
 800                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 801         else
 802                 echo "Using the following build machine macro files:"
 803                 for f in $build_xm_file; do
 804                         echo "  $srcdir/config/$f"
 805                 done
 806         fi
 807 fi
 808
 809 if test x$thread_file = x; then
 810         if test x$target_thread_file != x; then
 811                 thread_file=$target_thread_file
 812         else
 813                 thread_file='single'
 814         fi
 815 fi
 816
 817 # auto-host.h is the file containing items generated by autoconf and is
 818 # the first file included by config.h.
 819 # If host=build, it is correct to have hconfig include auto-host.h
 820 # as well.  If host!=build, we are in error and need to do more
 821 # work to find out the build config parameters.
 822 if test x$host = x$build
 823 then
 824         build_auto=auto-host.h
 825 else
 826         # We create a subdir, then run autoconf in the subdir.
 827         # To prevent recursion we set host and build for the new
 828         # invocation of configure to the build for this invocation
 829         # of configure.
 830         tempdir=build.$$
 831         rm -rf $tempdir
 832         mkdir $tempdir
 833         cd $tempdir
 834         case ${srcdir} in
 835         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 836         *) realsrcdir=../${srcdir};;
 837         esac
 838         CC=${CC_FOR_BUILD} ${realsrcdir}/configure \
 839                 --target=$target --host=$build --build=$build
 840
 841         # We just finished tests for the build machine, so rename
 842         # the file auto-build.h in the gcc directory.
 843         mv auto-host.h ../auto-build.h
 844         cd ..
 845         rm -rf $tempdir
 846         build_auto=auto-build.h
 847 fi
 848
 849 tm_file="${tm_file} defaults.h"
 850 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 851 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 852 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 853
 854 # Truncate the target if necessary
 855 if test x$host_truncate_target != x; then
 856         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 857 fi
 858
 859 # Get the version trigger filename from the toplevel
 860 if test "${with_gcc_version_trigger+set}" = set; then
 861         gcc_version_trigger=$with_gcc_version_trigger
 862 else
 863         gcc_version_trigger=${srcdir}/version.c
 864 fi
 865 changequote(,)dnl
 866 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 867 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 868
 869 # Compile in configure arguments.
 870 if test -f configargs.h ; then
 871         # Being re-configured.
 872         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
 873         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 874 else
 875         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 876 fi
 877 cat > configargs.h <<EOF
 878 /* Generated automatically. */
 879 static const char configuration_arguments[] = "$gcc_config_arguments";
 880 static const char thread_model[] = "$thread_file";
 881 EOF
 882 changequote([,])dnl
 883
 884 # Internationalization
 885 PACKAGE=gcc
 886 VERSION="$gcc_version"
 887 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 888         [Define to the name of the distribution.])
 889 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 890         [Define to the version of the distribution.])
 891 AC_SUBST(PACKAGE)
 892 AC_SUBST(VERSION)
 893
 894 ALL_LINGUAS="sv"
 895
 896 # Enable NLS support by default
 897 AC_ARG_ENABLE(nls,
 898   [  --enable-nls            use Native Language Support (default)],
 899   , enable_nls=yes)
 900
 901 # if cross compiling, disable NLS support.
 902 # It's not worth the trouble, at least for now.
 903
 904 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 905   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 906   enable_nls=no
 907 fi
 908
 909 # if NLS is enabled, also enable check in po subdir
 910 if test $enable_nls = yes; then
 911   CHECK_PO=check-po
 912 else
 913   CHECK_PO=""
 914 fi
 915
 916 AC_SUBST(CHECK_PO)
 917
 918 AM_GNU_GETTEXT
 919 XGETTEXT="AWK='$AWK' \$(SHELL) \$(top_srcdir)/exgettext $XGETTEXT"
 920
 921 # Windows32 Registry support for specifying GCC installation paths.
 922 AC_ARG_ENABLE(win32-registry,
 923 [  --disable-win32-registry
 924                           Disable lookup of installation paths in the
 925                          Registry on Windows hosts.
 926   --enable-win32-registry Enable registry lookup (default).
 927   --enable-win32-registry=KEY
 928                           Use KEY instead of GCC version as the last portion
 929                          of the registry key.],,)
 930 case $host_os in
 931         win32 | pe | cygwin* | mingw32* | uwin*)
 932 AC_MSG_CHECKING(whether windows registry support is requested)
 933 if test x$enable_win32_registry != xno; then
 934   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 935 [Define to 1 if installation paths should be looked up in Windows32
 936    Registry. Ignored on non windows32 hosts.])
 937   AC_MSG_RESULT(yes)
 938   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 939 else
 940   AC_MSG_RESULT(no)
 941 fi
 942
 943 # Check if user specified a different registry key.
 944 case x${enable_win32_registry} in
 945 x | xyes)
 946   # default.
 947   gcc_cv_win32_registry_key="$VERSION"
 948   ;;
 949 xno)
 950   # no registry lookup.
 951   gcc_cv_win32_registry_key=''
 952   ;;
 953 *)
 954   # user-specified key.
 955   gcc_cv_win32_registry_key="$enable_win32_registry"
 956   ;;
 957 esac
 958
 959 if test x$enable_win32_registry != xno; then
 960   AC_MSG_CHECKING(registry key on windows hosts)
 961   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 962         [Define to be the last portion of registry key on windows hosts.])
 963   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 964 fi
 965 ;;
 966 esac
 967
 968 # Get an absolute path to the GCC top-level source directory
 969 holddir=`pwd`
 970 cd $srcdir
 971 topdir=`pwd`
 972 cd $holddir
 973
 974 # Conditionalize the makefile for this host machine.
 975 # Make-host contains the concatenation of all host makefile fragments
 976 # [there can be more than one].  This file is built by configure.frag.
 977 host_overrides=Make-host
 978 dep_host_xmake_file=
 979 for f in .. ${host_xmake_file}
 980 do
 981         if test -f ${srcdir}/config/$f
 982         then
 983                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 984         fi
 985 done
 986
 987 # Conditionalize the makefile for this target machine.
 988 # Make-target contains the concatenation of all host makefile fragments
 989 # [there can be more than one].  This file is built by configure.frag.
 990 target_overrides=Make-target
 991 dep_tmake_file=
 992 for f in .. ${tmake_file}
 993 do
 994         if test -f ${srcdir}/config/$f
 995         then
 996                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
 997         fi
 998 done
 999
1000 # If the host doesn't support symlinks, modify CC in
1001 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1002 # Otherwise, we can use "CC=$(CC)".
1003 rm -f symtest.tem
1004 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1005 then
1006         cc_set_by_configure="\$(CC)"
1007         quoted_cc_set_by_configure="\$(CC)"
1008         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1009 else
1010         rm -f symtest.tem
1011         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1012         then
1013                 symbolic_link="cp -p"
1014         else
1015                 symbolic_link="cp"
1016         fi
1017         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1018         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1019         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1020 fi
1021 rm -f symtest.tem
1022
1023 out_object_file=`basename $out_file .c`.o
1024
1025 tm_file_list=
1026 for f in $tm_file; do
1027   case $f in
1028     ansidecl.h )
1029        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1030     defaults.h )
1031        tm_file_list="${tm_file_list} $f" ;;
1032     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1033   esac
1034 done
1035
1036 tm_p_file_list=
1037 for f in $tm_p_file; do
1038     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1039 done
1040
1041 host_xm_file_list=
1042 for f in $host_xm_file; do
1043   case $f in
1044     ansidecl.h )
1045        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1046     auto-host.h | defaults.h )
1047        host_xm_file_list="${host_xm_file_list} $f" ;;
1048     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1049   esac
1050 done
1051
1052 build_xm_file_list=
1053 for f in $build_xm_file; do
1054   case $f in
1055     ansidecl.h )
1056        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1057     auto-build.h | auto-host.h | defaults.h )
1058        build_xm_file_list="${build_xm_file_list} $f" ;;
1059     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1060   esac
1061 done
1062
1063 # Define macro CROSS_COMPILE in compilation
1064 # if this is a cross-compiler.
1065 # Also use all.cross instead of all.internal
1066 # and add cross-make to Makefile.
1067 cross_overrides="/dev/null"
1068 if test x$host != x$target
1069 then
1070         cross_defines="CROSS=-DCROSS_COMPILE"
1071         cross_overrides="${topdir}/cross-make"
1072 fi
1073
1074 # If this is a cross-compiler that does not
1075 # have its own set of headers then define
1076 # inhibit_libc
1077
1078 # If this is using newlib, then define inhibit_libc in
1079 # LIBGCC2_CFLAGS.  This will cause __eprintf to be left out of
1080 # libgcc.a, but that's OK because newlib should have its own version of
1081 # assert.h.
1082 inhibit_libc=
1083 if [test x$host != x$target] && [test x$with_headers = x]; then
1084        inhibit_libc=-Dinhibit_libc
1085 else
1086        if [test x$with_newlib = xyes]; then
1087                inhibit_libc=-Dinhibit_libc
1088        fi
1089 fi
1090 AC_SUBST(inhibit_libc)
1091
1092 # When building gcc with a cross-compiler, we need to fix a few things.
1093 # This must come after cross-make as we want all.build to override
1094 # all.cross.
1095 build_overrides="/dev/null"
1096 if test x$build != x$host
1097 then
1098         build_overrides="${topdir}/build-make"
1099 fi
1100
1101 # Expand extra_headers to include complete path.
1102 # This substitutes for lots of t-* files.
1103 extra_headers_list=
1104 if test "x$extra_headers" = x
1105 then true
1106 else
1107         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1108         for file in $extra_headers;
1109         do
1110                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1111         done
1112 fi
1113
1114 if test x$use_collect2 = xno; then
1115         use_collect2=
1116 fi
1117
1118 # Add a definition of USE_COLLECT2 if system wants one.
1119 # Also tell toplev.c what to do.
1120 # This substitutes for lots of t-* files.
1121 if test x$use_collect2 = x
1122 then
1123         will_use_collect2=
1124         maybe_use_collect2=
1125 else
1126         will_use_collect2="collect2"
1127         maybe_use_collect2="-DUSE_COLLECT2"
1128 fi
1129
1130 # If we have gas in the build tree, make a link to it.
1131 if test -f ../gas/Makefile; then
1132         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1133 fi
1134
1135 # If we have nm in the build tree, make a link to it.
1136 if test -f ../binutils/Makefile; then
1137         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1138 fi
1139
1140 # If we have ld in the build tree, make a link to it.
1141 if test -f ../ld/Makefile; then
1142 #       if test x$use_collect2 = x; then
1143 #               rm -f ld; $symbolic_link ../ld/ld-new$host_exeext ld$host_exeext 2>/dev/null
1144 #       else
1145                 rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1146 #       fi
1147 fi
1148
1149 # Figure out what assembler we will be using.
1150 AC_MSG_CHECKING(what assembler to use)
1151 gcc_cv_as=
1152 gcc_cv_gas_major_version=
1153 gcc_cv_gas_minor_version=
1154 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1155 if test -x "$DEFAULT_ASSEMBLER"; then
1156         gcc_cv_as="$DEFAULT_ASSEMBLER"
1157 elif test -x "$AS"; then
1158         gcc_cv_as="$AS"
1159 elif test -x as$host_exeext; then
1160         # Build using assembler in the current directory.
1161         gcc_cv_as=./as$host_exeext
1162 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1163         # Single tree build which includes gas.
1164         for f in $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1165         do
1166 changequote(,)dnl
1167                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1168 changequote([,])dnl
1169                 if test x$gcc_cv_gas_version != x; then
1170                         break
1171                 fi
1172         done
1173 changequote(,)dnl
1174         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1175         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1176 changequote([,])dnl
1177 fi
1178
1179 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1180         # Native build.
1181         # Search the same directories that the installed compiler will
1182         # search.  Else we may find the wrong assembler and lose.  If we
1183         # do not find a suitable assembler binary, then try the user's
1184         # path.
1185         #
1186         # Also note we have to check MD_EXEC_PREFIX before checking the
1187         # user's path.  Unfortunately, there is no good way to get at the
1188         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1189         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1190         # to be fixed as part of the make/configure rewrite too.
1191
1192         if test "x$exec_prefix" = xNONE; then
1193                 if test "x$prefix" = xNONE; then
1194                         test_prefix=/usr/local
1195                 else
1196                         test_prefix=$prefix
1197                 fi
1198         else
1199                 test_prefix=$exec_prefix
1200         fi
1201
1202         # If the loop below does not find an assembler, then use whatever
1203         # one we can find in the users's path.
1204         # user's path.
1205         gcc_cv_as=as$host_exeext
1206
1207         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1208                    $test_prefix/lib/gcc-lib/$target \
1209                    /usr/lib/gcc/$target/$gcc_version \
1210                    /usr/lib/gcc/$target \
1211                    $test_prefix/$target/bin/$target/$gcc_version \
1212                    $test_prefix/$target/bin \
1213                    /usr/libexec \
1214                    /usr/ccs/gcc \
1215                    /usr/ccs/bin \
1216                    /udk/usr/ccs/bin \
1217                    /bsd43/usr/lib/cmplrs/cc \
1218                    /usr/cross64/usr/bin \
1219                    /usr/lib/cmplrs/cc \
1220                    /sysv/usr/lib/cmplrs/cc \
1221                    /svr4/usr/lib/cmplrs/cc \
1222                    /usr/bin"
1223
1224         for dir in $test_dirs; do
1225                 if test -f $dir/as$host_exeext; then
1226                         gcc_cv_as=$dir/as$host_exeext
1227                         break;
1228                 fi
1229         done
1230 fi
1231 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1232   AC_MSG_RESULT("newly built gas")
1233 else
1234   AC_MSG_RESULT($gcc_cv_as)
1235 fi
1236
1237 # Figure out what nm we will be using.
1238 AC_MSG_CHECKING(what nm to use)
1239 if test -x nm$host_exeext; then
1240         gcc_cv_nm=./nm$host_exeext
1241 elif test x$host = x$target; then
1242         # Native build.
1243         gcc_cv_nm=nm$host_exeext
1244 fi
1245 AC_MSG_RESULT($gcc_cv_nm)
1246
1247 # Figure out what assembler alignment features are present.
1248 AC_MSG_CHECKING(assembler alignment features)
1249 gcc_cv_as_alignment_features=none
1250 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1251         # Gas version 2.6 and later support for .balign and .p2align.
1252         # bytes to skip when using .p2align.
1253         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1254                 gcc_cv_as_alignment_features=".balign and .p2align"
1255                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1256         fi
1257         # Gas version 2.8 and later support specifying the maximum
1258         # bytes to skip when using .p2align.
1259         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1260                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1261                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1262         fi
1263 elif test x$gcc_cv_as != x; then
1264         # Check if we have .balign and .p2align
1265         echo ".balign  4" > conftest.s
1266         echo ".p2align  2" >> conftest.s
1267         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1268                 gcc_cv_as_alignment_features=".balign and .p2align"
1269                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1270         fi
1271         rm -f conftest.s conftest.o
1272         # Check if specifying the maximum bytes to skip when
1273         # using .p2align is supported.
1274         echo ".p2align 4,,7" > conftest.s
1275         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1276                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1277                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1278         fi
1279         rm -f conftest.s conftest.o
1280 fi
1281 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1282
1283 AC_MSG_CHECKING(assembler subsection support)
1284 gcc_cv_as_subsections=no
1285 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1286   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1287     gcc_cv_as_subsections="working .subsection -1"
1288   fi
1289 elif test x$gcc_cv_as != x; then
1290         # Check if we have .subsection
1291         echo ".subsection 1" > conftest.s
1292         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1293                 gcc_cv_as_subsections=".subsection"
1294                 if test x$gcc_cv_nm != x; then
1295                         cat > conftest.s <<EOF
1296 conftest_label1: .word 0
1297 .subsection -1
1298 conftest_label2: .word 0
1299 .previous
1300 EOF
1301                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1302                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1303                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1304                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1305                                         :
1306                                 else
1307                                         gcc_cv_as_subsections="working .subsection -1"
1308                                 fi
1309                         fi
1310                 fi
1311         fi
1312         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1313 fi
1314 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1315         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1316 [Define if your assembler supports .subsection and .subsection -1 starts
1317    emitting at the beginning of your section.])
1318 fi
1319 AC_MSG_RESULT($gcc_cv_as_subsections)
1320
1321 AC_MSG_CHECKING(assembler weak support)
1322 gcc_cv_as_weak=no
1323 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1324   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1325     gcc_cv_as_weak="yes"
1326   fi
1327 elif test x$gcc_cv_as != x; then
1328         # Check if we have .weak
1329         echo "  .weak foobar" > conftest.s
1330         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1331                 gcc_cv_as_weak="yes"
1332         fi
1333         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1334 fi
1335 if test x"$gcc_cv_as_weak" = xyes; then
1336         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1337 fi
1338 AC_MSG_RESULT($gcc_cv_as_weak)
1339
1340 AC_MSG_CHECKING(assembler hidden support)
1341 gcc_cv_as_hidden=no
1342 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1343   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1344     gcc_cv_as_hidden="yes"
1345   fi
1346 elif test x$gcc_cv_as != x; then
1347         # Check if we have .hidden
1348         echo "  .hidden foobar" > conftest.s
1349         echo "foobar:" >> conftest.s
1350         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1351                 gcc_cv_as_hidden="yes"
1352         fi
1353         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1354 fi
1355 if test x"$gcc_cv_as_hidden" = xyes; then
1356         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1357                 [Define if your assembler supports .hidden.])
1358 fi
1359 AC_MSG_RESULT($gcc_cv_as_hidden)
1360
1361 AC_MSG_CHECKING(assembler leb128 support)
1362 gcc_cv_as_leb128=no
1363 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1364   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1365     gcc_cv_as_leb128="yes"
1366   fi
1367 elif test x$gcc_cv_as != x; then
1368         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1369         cat > conftest.s <<EOF
1370         .data
1371         .uleb128 L2 - L1
1372 L1:
1373         .uleb128 1280
1374         .sleb128 -1010
1375 L2:
1376 EOF
1377         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1378                 gcc_cv_as_leb128="yes"
1379
1380                 # GAS versions before 2.11 do not support uleb128,
1381                 # despite appearing to.
1382                 # ??? There exists an elf-specific test that will crash
1383                 # the assembler.  Perhaps it's better to figure out whether
1384                 # arbitrary sections are supported and try the test.
1385                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1386                 if echo "$as_ver" | grep GNU > /dev/null; then
1387                         as_ver=`echo $as_ver | sed -e 's/.* //'`
1388                         as_major=`echo $as_ver | sed 's/\..*//'`
1389 changequote(,)dnl
1390                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1391 changequote([,])dnl
1392                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1393                                 gcc_cv_as_leb128="no"
1394                         fi
1395                 fi
1396         fi
1397         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1398 fi
1399 if test x"$gcc_cv_as_leb128" = xyes; then
1400         AC_DEFINE(HAVE_AS_LEB128, 1,
1401                 [Define if your assembler supports .uleb128.])
1402 fi
1403 AC_MSG_RESULT($gcc_cv_as_leb128)
1404
1405 case "$target" in
1406   sparc*-*-*)
1407     AC_CACHE_CHECK([assembler .register pseudo-op support],
1408         gcc_cv_as_register_pseudo_op, [
1409         gcc_cv_as_register_pseudo_op=unknown
1410         if test x$gcc_cv_as != x; then
1411             # Check if we have .register
1412             echo ".register %g2, #scratch" > conftest.s
1413             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1414                 gcc_cv_as_register_pseudo_op=yes
1415             else
1416                 gcc_cv_as_register_pseudo_op=no
1417             fi
1418             rm -f conftest.s conftest.o
1419         fi
1420     ])
1421     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1422         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1423                 [Define if your assembler supports .register.])
1424     fi
1425
1426     AC_CACHE_CHECK([assembler supports -relax],
1427         gcc_cv_as_relax_opt, [
1428         gcc_cv_as_relax_opt=unknown
1429         if test x$gcc_cv_as != x; then
1430             # Check if gas supports -relax
1431             echo ".text" > conftest.s
1432             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1433                 gcc_cv_as_relax_opt=yes
1434             else
1435                 gcc_cv_as_relax_opt=no
1436             fi
1437             rm -f conftest.s conftest.o
1438         fi
1439     ])
1440     if test "x$gcc_cv_as_relax_opt" = xyes; then
1441         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1442                 [Define if your assembler supports -relax option.])
1443     fi
1444
1445     case "$tm_file" in
1446     *64*)
1447         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1448             gcc_cv_as_flags64, [
1449                 if test -n "$gcc_cv_as"; then
1450                     echo ".xword foo" > conftest.s
1451                     gcc_cv_as_flags64=no
1452                     for flag in "-xarch=v9" "-64 -Av9"; do
1453                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1454                             > /dev/null 2>&1; then
1455                             gcc_cv_as_flags64=$flag
1456                             break
1457                         fi
1458                     done
1459                     rm -f conftest.s conftest.o
1460                 else
1461                     if test "$gas" = yes; then
1462                         gcc_cv_as_flags64="-64 -Av9"
1463                     else
1464                         gcc_cv_as_flags64="-xarch=v9"
1465                     fi
1466                 fi
1467         ])
1468         if test "x$gcc_cv_as_flags64" = xno; then
1469 changequote(, )
1470             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1471             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1472 changequote([, ])
1473         else
1474             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1475                         [Define if the assembler supports 64bit sparc.])
1476         fi
1477         ;;
1478     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1479         ;;
1480     esac
1481
1482     if test "x$gcc_cv_as_flags64" != xno; then
1483         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1484             gcc_cv_as_offsetable_lo10, [
1485             gcc_cv_as_offsetable_lo10=unknown
1486             if test "x$gcc_cv_as" != x; then
1487                 # Check if assembler has offsetable %lo()
1488                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1489                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1490                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1491                         > /dev/null 2>&1 &&
1492                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1493                         > /dev/null 2>&1; then
1494                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1495                         gcc_cv_as_offsetable_lo10=no
1496                     else
1497                         gcc_cv_as_offsetable_lo10=yes
1498                     fi
1499                 else
1500                     gcc_cv_as_offsetable_lo10=no
1501                 fi
1502                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1503             fi
1504         ])
1505         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1506             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1507                 [Define if your assembler supports offsetable %lo().])
1508         fi
1509     fi
1510     ;;
1511
1512 changequote(,)dnl
1513   i[34567]86-*-*)
1514 changequote([,])dnl
1515     AC_MSG_CHECKING(assembler instructions)
1516     gcc_cv_as_instructions=
1517     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1518       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1519         gcc_cv_as_instructions="filds fists"
1520       fi
1521     elif test x$gcc_cv_as != x; then
1522         set "filds fists" "filds mem; fists mem"
1523         while test $# -gt 0
1524         do
1525                 echo "$2" > conftest.s
1526                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1527                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1528                 fi
1529                 shift 2
1530         done
1531         rm -f conftest.s conftest.o
1532     fi
1533     if test x"$gcc_cv_as_instructions" != x; then
1534         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1535     fi
1536     AC_MSG_RESULT($gcc_cv_as_instructions)
1537     ;;
1538 esac
1539
1540 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1541 gcc_cv_as_dwarf2_debug_line=no
1542 # ??? Not all targets support dwarf2 debug_line, even within a version
1543 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1544 # info to the output file.  So, as supported targets are added to gas 2.11,
1545 # add some instruction here to (also) show we expect this might work.
1546 # ??? Once 2.11 is released, probably need to add first known working
1547 # version to the per-target configury.
1548 case "$target" in
1549   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-*)
1550     insn="nop"
1551     ;;
1552   ia64*-*-*)
1553     insn="nop 0"
1554     ;;
1555   esac
1556 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1557 then
1558   if test "$gcc_cv_gas_major_version" -eq 2 \
1559         -a "$gcc_cv_gas_minor_version" -ge 11 \
1560         -o "$gcc_cv_gas_major_version" -gt 2 \
1561      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1562      && test x"$insn" != x ; then
1563     gcc_cv_as_dwarf2_debug_line="yes"
1564   fi
1565 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1566         echo '  .file 1 "conftest.s"' > conftest.s
1567         echo '  .loc 1 3 0' >> conftest.s
1568         echo "  $insn" >> conftest.s
1569         # ??? This fails with non-gnu grep.
1570         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1571            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1572                 # The .debug_line file table must be in the exact order that
1573                 # we specified the files, since these indicies are also used
1574                 # by DW_AT_decl_file.  Approximate this test by testing if
1575                 # the assembler bitches if the same index is assigned twice.
1576                 echo '  .file 1 "foo.s"' > conftest.s
1577                 echo '  .file 1 "bar.s"' >> conftest.s
1578                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1579                 then
1580                   gcc_cv_as_dwarf2_debug_line="no"
1581                 else
1582                   gcc_cv_as_dwarf2_debug_line="yes"
1583                 fi
1584         fi
1585         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1586 fi
1587 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1588         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1589 [Define if your assembler supports dwarf2 .file/.loc directives,
1590    and preserves file table indicies exactly as given.])
1591 fi
1592 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1593
1594 # Figure out what language subdirectories are present.
1595 # Look if the user specified --enable-languages="..."; if not, use
1596 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1597 # go away some day.
1598 if test x"${enable_languages+set}" != xset; then
1599         if test x"${LANGUAGES+set}" = xset; then
1600                 enable_languages="`echo ${LANGUAGES} | tr ' ' ','`"
1601         else
1602                 enable_languages=all
1603         fi
1604 else
1605         if test x"${enable_languages}" = x; then
1606                 AC_MSG_ERROR([--enable-languages needs at least one argument])
1607         fi
1608 fi
1609
1610 # First scan to see if an enabled language requires some other language.
1611 # We assume that a given config-lang.in will list all the language
1612 # front ends it requires, even if some are required indirectly.
1613 for lang in ${srcdir}/*/config-lang.in ..
1614 do
1615    case $lang in
1616     ..)
1617        ;;
1618     # The odd quoting in the next line works around
1619     # an apparent bug in bash 1.12 on linux.
1620 changequote(,)dnl
1621     ${srcdir}/[*]/config-lang.in)
1622        ;;
1623     *)
1624        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1625        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1626        for other in $this_lang_requires
1627        do
1628           case ,${enable_languages}, in
1629            *,$other,*)
1630               ;;
1631            *,all,*)
1632               ;;
1633            *,$lang_alias,*)
1634               enable_languages="$enable_languages,$other"
1635               ;;
1636           esac
1637        done
1638        ;;
1639 changequote([,])dnl
1640    esac
1641 done
1642
1643 subdirs=
1644 for lang in ${srcdir}/*/config-lang.in ..
1645 do
1646         case $lang in
1647         ..) ;;
1648         # The odd quoting in the next line works around
1649         # an apparent bug in bash 1.12 on linux.
1650 changequote(,)dnl
1651         ${srcdir}/[*]/config-lang.in) ;;
1652         *)
1653           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1654           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1655           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1656           if test "x$lang_alias" = x
1657           then
1658                 echo "$lang doesn't set \$language." 1>&2
1659                 exit 1
1660           fi
1661           case ${build_by_default},${enable_languages}, in
1662           *,$lang_alias,*) add_this_lang=yes ;;
1663           no,*) add_this_lang=no ;;
1664           *,all,*) add_this_lang=yes ;;
1665           *) add_this_lang=no ;;
1666           esac
1667           if test x"${add_this_lang}" = xyes; then
1668                 case $lang in
1669                     ${srcdir}/ada/config-lang.in)
1670                         if test x$have_gnat = xyes ; then
1671                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1672                         fi
1673                         ;;
1674                     *)
1675                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1676                         ;;
1677                 esac
1678           fi
1679           ;;
1680 changequote([,])dnl
1681         esac
1682 done
1683
1684 # Make gthr-default.h if we have a thread file.
1685 gthread_flags=
1686 if test $thread_file != single; then
1687     rm -f gthr-default.h
1688     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1689     gthread_flags=-DHAVE_GTHR_DEFAULT
1690 fi
1691 AC_SUBST(gthread_flags)
1692
1693 # Find out what GC implementation we want, or may, use.
1694 AC_ARG_WITH(gc,
1695 [  --with-gc={simple,page} Choose the garbage collection mechanism to use
1696                            with the compiler.],
1697 [case "$withval" in
1698   simple | page)
1699     GGC=ggc-$withval
1700     ;;
1701   *)
1702     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1703     ;;
1704 esac],
1705 [GGC=ggc-page])
1706 AC_SUBST(GGC)
1707 echo "Using $GGC for garbage collection."
1708
1709 # Use the system's zlib library.
1710 zlibdir=-L../zlib
1711 zlibinc="-I\$(srcdir)/../zlib"
1712 AC_ARG_WITH(system-zlib,
1713 [  --with-system-zlib      use installed libz],
1714 zlibdir=
1715 zlibinc=
1716 )
1717 AC_SUBST(zlibdir)
1718 AC_SUBST(zlibinc)
1719
1720 dnl Very limited version of automake's enable-maintainer-mode
1721
1722 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1723   dnl maintainer-mode is disabled by default
1724   AC_ARG_ENABLE(maintainer-mode,
1725 [  --enable-maintainer-mode enable make rules and dependencies not useful
1726                           (and sometimes confusing) to the casual installer],
1727       maintainer_mode=$enableval,
1728       maintainer_mode=no)
1729
1730 AC_MSG_RESULT($maintainer_mode)
1731
1732 if test "$maintainer_mode" = "yes"; then
1733   MAINT=''
1734 else
1735   MAINT='#'
1736 fi
1737 AC_SUBST(MAINT)dnl
1738
1739 # With Setjmp/Longjmp based exception handling.
1740 AC_ARG_ENABLE(sjlj-exceptions,
1741 [  --enable-sjlj-exceptions arrange to use setjmp/longjmp exception handling.],
1742 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1743 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1744   [Define 0/1 to force the choice for exception handling model.])])
1745
1746 # Make empty files to contain the specs and options for each language.
1747 # Then add #include lines to for a compiler that has specs and/or options.
1748
1749 lang_specs_files=
1750 lang_options_files=
1751 lang_tree_files=
1752 rm -f specs.h options.h gencheck.h
1753 touch specs.h options.h gencheck.h
1754 for subdir in . $subdirs
1755 do
1756         if test -f $srcdir/$subdir/lang-specs.h; then
1757                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1758                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1759         fi
1760         if test -f $srcdir/$subdir/lang-options.h; then
1761                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1762                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1763         fi
1764         if test -f $srcdir/$subdir/$subdir-tree.def; then
1765                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1766                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1767         fi
1768 done
1769
1770 # These (without "all_") are set in each config-lang.in.
1771 # `language' must be a single word so is spelled singularly.
1772 all_languages=
1773 all_boot_languages=
1774 all_compilers=
1775 all_stagestuff=
1776 all_diff_excludes=
1777 all_outputs='Makefile intl/Makefile po/Makefile.in fixinc/Makefile gccbug mklibgcc'
1778 # List of language makefile fragments.
1779 all_lang_makefiles=
1780 all_headers=
1781 all_lib2funcs=
1782
1783 # Add the language fragments.
1784 # Languages are added via two mechanisms.  Some information must be
1785 # recorded in makefile variables, these are defined in config-lang.in.
1786 # We accumulate them and plug them into the main Makefile.
1787 # The other mechanism is a set of hooks for each of the main targets
1788 # like `clean', `install', etc.
1789
1790 language_fragments="Make-lang"
1791 language_hooks="Make-hooks"
1792
1793 for s in .. $subdirs
1794 do
1795         if test $s != ".."
1796         then
1797                 language=
1798                 boot_language=
1799                 compilers=
1800                 stagestuff=
1801                 diff_excludes=
1802                 headers=
1803                 outputs=
1804                 lib2funcs=
1805                 . ${srcdir}/$s/config-lang.in
1806                 if test "x$language" = x
1807                 then
1808                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
1809                         exit 1
1810                 fi
1811                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
1812                 if test -f ${srcdir}/$s/Makefile.in
1813                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
1814                 fi
1815                 all_languages="$all_languages $language"
1816                 if test "x$boot_language" = xyes
1817                 then
1818                         all_boot_languages="$all_boot_languages $language"
1819                 fi
1820                 all_compilers="$all_compilers $compilers"
1821                 all_stagestuff="$all_stagestuff $stagestuff"
1822                 all_diff_excludes="$all_diff_excludes $diff_excludes"
1823                 all_headers="$all_headers $headers"
1824                 all_outputs="$all_outputs $outputs"
1825                 all_lib2funcs="$all_lib2funcs $lib2funcs"
1826         fi
1827 done
1828
1829 check_languages=
1830 for language in .. $all_languages
1831 do
1832         if test $language != ".."
1833         then
1834                 check_languages="$check_languages check-$language"
1835         fi
1836 done
1837
1838 # Since we can't use `::' targets, we link each language in
1839 # with a set of hooks, reached indirectly via lang.${target}.
1840
1841 rm -f Make-hooks
1842 touch Make-hooks
1843 target_list="all.build all.cross start.encap rest.encap \
1844         info dvi \
1845         install-normal install-common install-info install-man \
1846         uninstall \
1847         mostlyclean clean distclean extraclean maintainer-clean \
1848         stage1 stage2 stage3 stage4"
1849 for t in $target_list
1850 do
1851         x=
1852         for lang in .. $all_languages
1853         do
1854                 if test $lang != ".."; then
1855                         x="$x $lang.$t"
1856                 fi
1857         done
1858         echo "lang.$t: $x" >> Make-hooks
1859 done
1860
1861 # Create .gdbinit.
1862
1863 echo "dir ." > .gdbinit
1864 echo "dir ${srcdir}" >> .gdbinit
1865 if test x$gdb_needs_out_file_path = xyes
1866 then
1867         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
1868 fi
1869 if test "x$subdirs" != x; then
1870         for s in $subdirs
1871         do
1872                 echo "dir ${srcdir}/$s" >> .gdbinit
1873         done
1874 fi
1875 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
1876
1877 # Define variables host_canonical and build_canonical
1878 # because some Cygnus local changes in the Makefile depend on them.
1879 build_canonical=${build}
1880 host_canonical=${host}
1881 target_subdir=
1882 if test "${host}" != "${target}" ; then
1883     target_subdir=${target_alias}/
1884 fi
1885 AC_SUBST(build_canonical)
1886 AC_SUBST(host_canonical)
1887 AC_SUBST(target_subdir)
1888
1889 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
1890 # absolute path for gcc_tooldir based on inserting the number of up-directory
1891 # movements required to get from $(exec_prefix) to $(prefix) into the basic
1892 # $(libsubdir)/@(unlibsubdir) based path.
1893 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
1894 # make and thus we'd get different behavior depending on where we built the
1895 # sources.
1896 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
1897     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
1898 else
1899 changequote(<<, >>)dnl
1900 # An explanation of the sed strings:
1901 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
1902 #  -e 's|/$||'            match a trailing forward slash and eliminates it
1903 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
1904 #  -e 's|/[^/]*|../|g'    replaces each occurance of /<directory> with ../
1905 #
1906 # (*) Note this pattern overwrites the first character of the string
1907 # with a forward slash if one is not already present.  This is not a
1908 # problem because the exact names of the sub-directories concerned is
1909 # unimportant, just the number of them matters.
1910 #
1911 # The practical upshot of these patterns is like this:
1912 #
1913 #  prefix     exec_prefix        result
1914 #  ------     -----------        ------
1915 #   /foo        /foo/bar          ../
1916 #   /foo/       /foo/bar          ../
1917 #   /foo        /foo/bar/         ../
1918 #   /foo/       /foo/bar/         ../
1919 #   /foo        /foo/bar/ugg      ../../
1920 #
1921     dollar='$$'
1922     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
1923 changequote([, ])dnl
1924 fi
1925 AC_SUBST(gcc_tooldir)
1926 AC_SUBST(dollar)
1927
1928 # Find a directory in which to install a shared libgcc.
1929
1930 AC_ARG_ENABLE(version-specific-runtime-libs,
1931 [  --enable-version-specific-runtime-libs    Specify that runtime libraries shou
1932 ld be installed in a compiler-specific directory ])
1933
1934 AC_ARG_WITH(slibdir,
1935 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
1936 slibdir="$with_slibdir",
1937 if test "${enable_version_specific_runtime_libs+set}" = set; then
1938   slibdir='$(libsubdir)'
1939 elif test "$host" != "$target"; then
1940   slibdir='$(build_tooldir)/lib'
1941 else
1942   slibdir='$(libdir)'
1943 fi)
1944 AC_SUBST(slibdir)
1945
1946 # Nothing to do for FLOAT_H, float_format already handled.
1947 objdir=`pwd`
1948 AC_SUBST(objdir)
1949
1950 # Process the language and host/target makefile fragments.
1951 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
1952
1953 # Substitute configuration variables
1954 AC_SUBST(subdirs)
1955 AC_SUBST(all_boot_languages)
1956 AC_SUBST(all_compilers)
1957 AC_SUBST(all_diff_excludes)
1958 AC_SUBST(all_headers)
1959 AC_SUBST(all_lang_makefiles)
1960 AC_SUBST(all_languages)
1961 AC_SUBST(all_lib2funcs)
1962 AC_SUBST(all_stagestuff)
1963 AC_SUBST(build_exeext)
1964 AC_SUBST(build_install_headers_dir)
1965 AC_SUBST(build_xm_file_list)
1966 AC_SUBST(build_xm_file)
1967 AC_SUBST(build_xm_defines)
1968 AC_SUBST(check_languages)
1969 AC_SUBST(cc_set_by_configure)
1970 AC_SUBST(quoted_cc_set_by_configure)
1971 AC_SUBST(cpp_install_dir)
1972 AC_SUBST(dep_host_xmake_file)
1973 AC_SUBST(dep_tmake_file)
1974 AC_SUBST(extra_c_flags)
1975 AC_SUBST(extra_headers_list)
1976 AC_SUBST(extra_objs)
1977 AC_SUBST(extra_parts)
1978 AC_SUBST(extra_passes)
1979 AC_SUBST(extra_programs)
1980 AC_SUBST(float_h_file)
1981 AC_SUBST(gcc_config_arguments)
1982 AC_SUBST(gcc_gxx_include_dir)
1983 AC_SUBST(libstdcxx_incdir)
1984 AC_SUBST(gcc_version)
1985 AC_SUBST(gcc_version_full)
1986 AC_SUBST(gcc_version_trigger)
1987 AC_SUBST(host_exeext)
1988 AC_SUBST(host_extra_gcc_objs)
1989 AC_SUBST(host_xm_file_list)
1990 AC_SUBST(host_xm_file)
1991 AC_SUBST(host_xm_defines)
1992 AC_SUBST(install)
1993 AC_SUBST(lang_options_files)
1994 AC_SUBST(lang_specs_files)
1995 AC_SUBST(lang_tree_files)
1996 AC_SUBST(local_prefix)
1997 AC_SUBST(maybe_use_collect2)
1998 AC_SUBST(md_file)
1999 AC_SUBST(objc_boehm_gc)
2000 AC_SUBST(out_file)
2001 AC_SUBST(out_object_file)
2002 AC_SUBST(stage_prefix_set_by_configure)
2003 AC_SUBST(symbolic_link)
2004 AC_SUBST(thread_file)
2005 AC_SUBST(tm_file_list)
2006 AC_SUBST(tm_file)
2007 AC_SUBST(tm_p_file_list)
2008 AC_SUBST(tm_p_file)
2009 AC_SUBST(xm_file)
2010 AC_SUBST(xm_defines)
2011 AC_SUBST(will_use_collect2)
2012 AC_SUBST(c_target_objs)
2013 AC_SUBST(cxx_target_objs)
2014 AC_SUBST(target_cpu_default)
2015
2016 AC_SUBST_FILE(target_overrides)
2017 AC_SUBST_FILE(host_overrides)
2018 AC_SUBST(cross_defines)
2019 AC_SUBST_FILE(cross_overrides)
2020 AC_SUBST_FILE(build_overrides)
2021 AC_SUBST_FILE(language_fragments)
2022 AC_SUBST_FILE(language_hooks)
2023
2024 # Echo that links are built
2025 if test x$host = x$target
2026 then
2027         str1="native "
2028 else
2029         str1="cross-"
2030         str2=" from $host"
2031 fi
2032
2033 if test x$host != x$build
2034 then
2035         str3=" on a $build system"
2036 fi
2037
2038 if test "x$str2" != x || test "x$str3" != x
2039 then
2040         str4=
2041 fi
2042
2043 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2044
2045 if test "x$str2" != x || test "x$str3" != x
2046 then
2047         echo " ${str2}${str3}." 1>&2
2048 fi
2049
2050 # Truncate the target if necessary
2051 if test x$host_truncate_target != x; then
2052         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2053 fi
2054
2055 # Configure the subdirectories
2056 # AC_CONFIG_SUBDIRS($subdirs)
2057
2058 # Create the Makefile
2059 # and configure language subdirectories
2060 AC_OUTPUT($all_outputs,
2061 [
2062 case x$CONFIG_HEADERS in
2063 xauto-host.h:config.in)
2064 echo > cstamp-h ;;
2065 esac
2066 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2067 # bootstrapping and the installation procedure can still use
2068 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2069 # FLAGS_TO_PASS has been modified to solve the problem there.
2070 # This is virtually a duplicate of what happens in configure.lang; we do
2071 # an extra check to make sure this only happens if ln -s can be used.
2072 if test "$symbolic_link" = "ln -s"; then
2073  for d in .. ${subdirs} ; do
2074    if test $d != ..; then
2075         STARTDIR=`pwd`
2076         cd $d
2077         for t in stage1 stage2 stage3 stage4 include
2078         do
2079                 rm -f $t
2080                 $symbolic_link ../$t $t 2>/dev/null
2081         done
2082         cd $STARTDIR
2083    fi
2084  done
2085 else true ; fi
2086 # Avoid having to add intl to our include paths.
2087 if test -f intl/libintl.h; then
2088   echo creating libintl.h
2089   echo '#include "intl/libintl.h"' >libintl.h
2090 fi
2091 ],
2092 [
2093 host='${host}'
2094 build='${build}'
2095 target='${target}'
2096 target_alias='${target_alias}'
2097 srcdir='${srcdir}'
2098 subdirs='${subdirs}'
2099 symbolic_link='${symbolic_link}'
2100 program_transform_set='${program_transform_set}'
2101 program_transform_name='${program_transform_name}'
2102 dep_host_xmake_file='${dep_host_xmake_file}'
2103 host_xmake_file='${host_xmake_file}'
2104 dep_tmake_file='${dep_tmake_file}'
2105 tmake_file='${tmake_file}'
2106 thread_file='${thread_file}'
2107 gcc_config_arguments='${gcc_config_arguments}'
2108 gcc_version='${gcc_version}'
2109 gcc_version_full='${gcc_version_full}'
2110 gcc_version_trigger='${gcc_version_trigger}'
2111 local_prefix='${local_prefix}'
2112 build_install_headers_dir='${build_install_headers_dir}'
2113 build_exeext='${build_exeext}'
2114 host_exeext='${host_exeext}'
2115 out_file='${out_file}'
2116 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2117 SET_MAKE='${SET_MAKE}'
2118 target_list='${target_list}'
2119 target_overrides='${target_overrides}'
2120 host_overrides='${host_overrides}'
2121 cross_defines='${cross_defines}'
2122 cross_overrides='${cross_overrides}'
2123 build_overrides='${build_overrides}'
2124 cpp_install_dir='${cpp_install_dir}'
2125 ])