gcc/configure.in

   1 # configure.in for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright (C) 1997, 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5
   6 #This file is part of GCC.
   7
   8 #GCC is free software; you can redistribute it and/or modify it under
   9 #the terms of the GNU General Public License as published by the Free
  10 #Software Foundation; either version 2, or (at your option) any later
  11 #version.
  12
  13 #GCC is distributed in the hope that it will be useful, but WITHOUT
  14 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  15 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  16 #for more details.
  17
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to the Free
  20 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 # Initialization and defaults
  24 AC_PREREQ(2.13)
  25 AC_INIT(tree.c)
  26 AC_CONFIG_HEADER(auto-host.h:config.in)
  27
  28 remove=rm
  29 hard_link=ln
  30 symbolic_link='ln -s'
  31 copy=cp
  32
  33 # Check for bogus environment variables.
  34 # Test if LIBRARY_PATH contains the notation for the current directory
  35 # since this would lead to problems installing/building glibc.
  36 # LIBRARY_PATH contains the current directory if one of the following
  37 # is true:
  38 # - one of the terminals (":" and ";") is the first or last sign
  39 # - two terminals occur directly after each other
  40 # - the path contains an element with a dot in it
  41 AC_MSG_CHECKING(LIBRARY_PATH variable)
  42 changequote(,)dnl
  43 case ${LIBRARY_PATH} in
  44   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  45     library_path_setting="contains current directory"
  46     ;;
  47   *)
  48     library_path_setting="ok"
  49     ;;
  50 esac
  51 changequote([,])dnl
  52 AC_MSG_RESULT($library_path_setting)
  53 if test "$library_path_setting" != "ok"; then
  54 AC_MSG_ERROR([
  55 *** LIBRARY_PATH shouldn't contain the current directory when
  56 *** building gcc. Please change the environment variable
  57 *** and run configure again.])
  58 fi
  59
  60 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  61 # since this would lead to problems installing/building glibc.
  62 # GCC_EXEC_PREFIX contains the current directory if one of the following
  63 # is true:
  64 # - one of the terminals (":" and ";") is the first or last sign
  65 # - two terminals occur directly after each other
  66 # - the path contains an element with a dot in it
  67 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  68 changequote(,)dnl
  69 case ${GCC_EXEC_PREFIX} in
  70   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  71     gcc_exec_prefix_setting="contains current directory"
  72     ;;
  73   *)
  74     gcc_exec_prefix_setting="ok"
  75     ;;
  76 esac
  77 changequote([,])dnl
  78 AC_MSG_RESULT($gcc_exec_prefix_setting)
  79 if test "$gcc_exec_prefix_setting" != "ok"; then
  80 AC_MSG_ERROR([
  81 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  82 *** building gcc. Please change the environment variable
  83 *** and run configure again.])
  84 fi
  85
  86 # Check for additional parameters
  87
  88 # With GNU ld
  89 AC_ARG_WITH(gnu-ld,
  90 [  --with-gnu-ld           arrange to work with GNU ld.],
  91 gnu_ld_flag="$with_gnu_ld",
  92 gnu_ld_flag=no)
  93
  94 # With pre-defined ld
  95 AC_ARG_WITH(ld,
  96 [  --with-ld               arrange to use the specified ld (full pathname)],
  97 DEFAULT_LINKER="$with_ld")
  98 if test x"${DEFAULT_LINKER+set}" = x"set"; then
  99   if test ! -x "$DEFAULT_LINKER"; then
 100     AC_MSG_WARN([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 101   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 102     gnu_ld_flag=yes
 103   fi
 104   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 105         [Define to enable the use of a default linker.])
 106 fi
 107
 108 # With GNU as
 109 AC_ARG_WITH(gnu-as,
 110 [  --with-gnu-as           arrange to work with GNU as],
 111 gas_flag="$with_gnu_as",
 112 gas_flag=no)
 113
 114 AC_ARG_WITH(as,
 115 [  --with-as               arrange to use the specified as (full pathname)],
 116 DEFAULT_ASSEMBLER="$with_as")
 117 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 118   if test ! -x "$DEFAULT_ASSEMBLER"; then
 119     AC_MSG_WARN([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 120   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 121     gas_flag=yes
 122   fi
 123   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 124         [Define to enable the use of a default assembler.])
 125 fi
 126
 127 # With stabs
 128 AC_ARG_WITH(stabs,
 129 [  --with-stabs            arrange to use stabs instead of host debug format],
 130 stabs="$with_stabs",
 131 stabs=no)
 132
 133 # With ELF
 134 AC_ARG_WITH(elf,
 135 [  --with-elf              arrange to use ELF instead of host debug format],
 136 elf="$with_elf",
 137 elf=no)
 138
 139 # Specify the local prefix
 140 local_prefix=
 141 AC_ARG_WITH(local-prefix,
 142 [  --with-local-prefix=DIR specifies directory to put local include],
 143 [case "${withval}" in
 144 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 145 no)     ;;
 146 *)      local_prefix=$with_local_prefix ;;
 147 esac])
 148
 149 # Default local prefix if it is empty
 150 if test x$local_prefix = x; then
 151         local_prefix=/usr/local
 152 fi
 153
 154 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 155 # passed in by the toplevel make and thus we'd get different behavior
 156 # depending on where we built the sources.
 157 gcc_gxx_include_dir=
 158 # Specify the g++ header file directory
 159 AC_ARG_WITH(gxx-include-dir,
 160 [  --with-gxx-include-dir=DIR
 161                           specifies directory to put g++ header files],
 162 [case "${withval}" in
 163 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 164 no)     ;;
 165 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 166 esac])
 167
 168 if test x${gcc_gxx_include_dir} = x; then
 169   if test x${enable_version_specific_runtime_libs} = xyes; then
 170     gcc_gxx_include_dir='${libsubdir}/include/g++'
 171   else
 172     topsrcdir=${srcdir}/.. . ${srcdir}/../config.if
 173 changequote(<<, >>)dnl
 174     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 175 changequote([, ])dnl
 176   fi
 177 fi
 178
 179 # Determine whether or not multilibs are enabled.
 180 AC_ARG_ENABLE(multilib,
 181 [  --enable-multilib       enable library support for multiple ABIs],
 182 [], [enable_multilib=yes])
 183 AC_SUBST(enable_multilib)
 184
 185 # Enable expensive internal checks
 186 AC_ARG_ENABLE(checking,
 187 [  --enable-checking[=LIST]
 188                           enable expensive run-time checks.  With LIST,
 189                           enable only specific categories of checks.
 190                           Categories are: misc,tree,rtl,gc,gcac; default
 191                           is misc,tree,gc],
 192 [ac_checking=
 193 ac_tree_checking=
 194 ac_rtl_checking=
 195 ac_gc_checking=
 196 ac_gc_always_collect=
 197 case "${enableval}" in
 198 yes)    ac_checking=1 ; ac_tree_checking=1 ; ac_gc_checking=1 ;;
 199 no)     ;;
 200 *)      IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 201         set fnord $enableval; shift
 202         IFS="$ac_save_IFS"
 203         for check
 204         do
 205                 case $check in
 206                 misc)   ac_checking=1 ;;
 207                 tree)   ac_tree_checking=1 ;;
 208                 rtl)    ac_rtl_checking=1 ;;
 209                 gc)     ac_gc_checking=1 ;;
 210                 gcac)   ac_gc_always_collect=1 ;;
 211                 *)      AC_MSG_ERROR(unknown check category $check) ;;
 212                 esac
 213         done
 214         ;;
 215 esac
 216 ],
 217 # Enable some checks by default for development versions of GCC
 218 [ac_checking=1; ac_tree_checking=1; ac_gc_checking=1;])
 219 if test x$ac_checking != x ; then
 220   AC_DEFINE(ENABLE_CHECKING, 1,
 221 [Define if you want more run-time sanity checks.  This one gets a grab
 222    bag of miscellaneous but relatively cheap checks.])
 223 fi
 224 if test x$ac_tree_checking != x ; then
 225   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 226 [Define if you want all operations on trees (the basic data
 227    structure of the front ends) to be checked for dynamic type safety
 228    at runtime.  This is moderately expensive.])
 229 fi
 230 if test x$ac_rtl_checking != x ; then
 231   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 232 [Define if you want all operations on RTL (the basic data structure
 233    of the optimizer and back end) to be checked for dynamic type safety
 234    at runtime.  This is quite expensive.])
 235 fi
 236 if test x$ac_gc_checking != x ; then
 237   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 238 [Define if you want the garbage collector to do object poisoning and
 239    other memory allocation checks.  This is quite expensive.])
 240 fi
 241 if test x$ac_gc_always_collect != x ; then
 242   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 243 [Define if you want the garbage collector to operate in maximally
 244    paranoid mode, validating the entire heap and collecting garbage at
 245    every opportunity.  This is extremely expensive.])
 246 fi
 247
 248
 249 AC_ARG_ENABLE(cpp,
 250 [  --disable-cpp           don't provide a user-visible C preprocessor],
 251 [], [enable_cpp=yes])
 252
 253 AC_ARG_WITH(cpp_install_dir,
 254 [  --with-cpp-install-dir=DIR
 255                           install the user visible C preprocessor in DIR
 256                           (relative to PREFIX) as well as PREFIX/bin],
 257 [if test x$withval = xyes; then
 258   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 259 elif test x$withval != xno; then
 260   cpp_install_dir=$withval
 261 fi])
 262
 263 # Enable Multibyte Characters for C/C++
 264 AC_ARG_ENABLE(c-mbchar,
 265 [  --enable-c-mbchar       enable multibyte characters for C and C++],
 266 if test x$enable_c_mbchar != xno; then
 267   AC_DEFINE(MULTIBYTE_CHARS, 1,
 268   [Define if you want the C and C++ compilers to support multibyte
 269    character sets for source code.])
 270 fi)
 271
 272 # Enable threads
 273 # Pass with no value to take the default
 274 # Pass with a value to specify a thread package
 275 AC_ARG_ENABLE(threads,
 276 [  --enable-threads        enable thread usage for target GCC
 277   --enable-threads=LIB    use LIB thread package for target GCC],,
 278 enable_threads='')
 279
 280 enable_threads_flag=$enable_threads
 281 # Check if a valid thread package
 282 case x${enable_threads_flag} in
 283         x | xno)
 284                 # No threads
 285                 target_thread_file='single'
 286                 ;;
 287         xyes)
 288                 # default
 289                 target_thread_file=''
 290                 ;;
 291         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
 292         xsolaris | xwin32 | xdce | xrtems| xvxworks | xaix)
 293                 target_thread_file=$enable_threads_flag
 294                 ;;
 295         *)
 296                 echo "$enable_threads is an unknown thread package" 1>&2
 297                 exit 1
 298                 ;;
 299 esac
 300
 301 AC_ARG_ENABLE(objc-gc,
 302 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 303                           the GNU Objective-C runtime],
 304 if test x$enable_objc_gc = xno; then
 305         objc_boehm_gc=''
 306 else
 307         objc_boehm_gc=1
 308 fi,
 309 objc_boehm_gc='')
 310
 311 AC_ARG_WITH(dwarf2,
 312 [  --with-dwarf2           force the default debug format to be DWARF 2],
 313 dwarf2="$with_dwarf2",
 314 dwarf2=no)
 315
 316 AC_ARG_ENABLE(shared,
 317 [  --disable-shared        don't provide a shared libgcc],
 318 [
 319   case $enable_shared in
 320   yes | no) ;;
 321   *)
 322     enable_shared=no
 323     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 324     for pkg in $enableval; do
 325       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 326         enable_shared=yes
 327       fi
 328     done
 329     IFS="$ac_save_ifs"
 330     ;;
 331   esac
 332 ], [enable_shared=yes])
 333 AC_SUBST(enable_shared)
 334
 335 # Determine the host, build, and target systems
 336 AC_CANONICAL_SYSTEM
 337
 338 # Set program_transform_name
 339 AC_ARG_PROGRAM
 340
 341 # Find the native compiler
 342 AC_PROG_CC
 343 AC_PROG_CC_C_O
 344 # autoconf is lame and doesn't give us any substitution variable for this.
 345 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 346   NO_MINUS_C_MINUS_O=yes
 347 else
 348   OUTPUT_OPTION='-o $@'
 349 fi
 350 AC_SUBST(NO_MINUS_C_MINUS_O)
 351 AC_SUBST(OUTPUT_OPTION)
 352
 353 AC_CACHE_CHECK(whether ${CC-cc} accepts -Wno-long-long,
 354 ac_cv_prog_cc_no_long_long,
 355 [save_CFLAGS="$CFLAGS"
 356 CFLAGS="-Wno-long-long"
 357 AC_TRY_COMPILE(,,ac_cv_prog_cc_no_long_long=yes,
 358                ac_cv_prog_cc_no_long_long=no)
 359 CFLAGS="$save_CFLAGS"])
 360 strict1_warn=
 361 if test $ac_cv_prog_cc_no_long_long = yes; then
 362   strict1_warn="-pedantic -Wno-long-long"
 363 fi
 364 AC_SUBST(strict1_warn)
 365
 366 AC_PROG_CPP
 367 AC_C_INLINE
 368 gcc_AC_C_VOLATILE
 369
 370 gcc_AC_C_LONG_DOUBLE
 371 gcc_AC_C_LONG_LONG
 372 gcc_AC_C__BOOL
 373
 374 # sizeof(char) is 1 by definition.
 375 gcc_AC_COMPILE_CHECK_SIZEOF(short)
 376 gcc_AC_COMPILE_CHECK_SIZEOF(int)
 377 gcc_AC_COMPILE_CHECK_SIZEOF(long)
 378 if test $ac_cv_c_long_long = yes; then
 379   gcc_AC_COMPILE_CHECK_SIZEOF(long long)
 380 fi
 381 if test $ac_cv_c___int64 = yes; then
 382   gcc_AC_COMPILE_CHECK_SIZEOF(__int64)
 383 fi
 384
 385 gcc_AC_C_CHARSET
 386
 387 # If the native compiler is GCC, we can enable warnings even in stage1.
 388 # That's useful for people building cross-compilers, or just running a
 389 # quick `make'.
 390 warn_cflags=
 391 if test "x$GCC" = "xyes"; then
 392   warn_cflags='$(GCC_WARN_CFLAGS)'
 393 fi
 394 AC_SUBST(warn_cflags)
 395
 396 # Stage specific cflags for build.
 397 stage1_cflags=
 398 case $build in
 399 vax-*-*)
 400   if test x$GCC = xyes
 401   then
 402     stage1_cflags="-Wa,-J"
 403   else
 404     stage1_cflags="-J"
 405   fi
 406   ;;
 407 esac
 408 AC_SUBST(stage1_cflags)
 409
 410 AC_PROG_MAKE_SET
 411
 412 AC_MSG_CHECKING([whether a default assembler was specified])
 413 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 414     if test x"$gas_flag" = x"no"; then
 415         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 416     else
 417         AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 418     fi
 419 else
 420     AC_MSG_RESULT(no)
 421 fi
 422
 423 AC_MSG_CHECKING([whether a default linker was specified])
 424 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 425     if test x"$gnu_ld_flag" = x"no"; then
 426         AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 427     else
 428         AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 429     fi
 430 else
 431     AC_MSG_RESULT(no)
 432 fi
 433
 434 AC_MSG_CHECKING(for GNU C library)
 435 AC_CACHE_VAL(gcc_cv_glibc,
 436 [AC_TRY_COMPILE(
 437   [#include <features.h>],[
 438 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 439 #error Not a GNU C library system
 440 #endif],
 441   [gcc_cv_glibc=yes],
 442   gcc_cv_glibc=no)])
 443 AC_MSG_RESULT($gcc_cv_glibc)
 444 if test $gcc_cv_glibc = yes; then
 445   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 446 fi
 447
 448 # Find some useful tools
 449 AC_PROG_AWK
 450 gcc_AC_PROG_LN
 451 gcc_AC_PROG_LN_S
 452 AC_PROG_RANLIB
 453 gcc_AC_PROG_INSTALL
 454
 455 AC_HEADER_STDC
 456 AC_HEADER_TIME
 457 gcc_AC_HEADER_STDBOOL
 458 gcc_AC_HEADER_STRING
 459 AC_HEADER_SYS_WAIT
 460 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h \
 461                  fcntl.h unistd.h sys/file.h sys/time.h \
 462                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 463                  direct.h malloc.h langinfo.h)
 464
 465 # Check for thread headers.
 466 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 467 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 468
 469 # These tests can't be done till we know if we have limits.h.
 470 gcc_AC_C_CHAR_BIT
 471 gcc_AC_C_COMPILE_ENDIAN
 472 gcc_AC_C_FLOAT_FORMAT
 473
 474 # See if GNAT has been installed
 475 gcc_AC_PROG_GNAT
 476
 477 # See if we have the mktemp command.
 478 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 479
 480 # Do we have a single-tree copy of texinfo?
 481 if test -f $srcdir/../texinfo/Makefile.in; then
 482   MAKEINFO='$(objdir)/../texinfo/makeinfo/makeinfo'
 483   gcc_cv_prog_makeinfo_modern=yes
 484   AC_MSG_RESULT([Using makeinfo from the unified source tree.])
 485 else
 486   # See if makeinfo has been installed and is modern enough
 487   # that we can use it.
 488   gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 489   [GNU texinfo.* \([0-9][0-9.]*\)],
 490   [4.*])
 491 fi
 492
 493 if test $gcc_cv_prog_makeinfo_modern = no; then
 494   AC_MSG_WARN([
 495 *** Makeinfo is missing or too old.
 496 *** Info documentation will not be built.])
 497   BUILD_INFO=
 498 else
 499   BUILD_INFO=info               AC_SUBST(BUILD_INFO)
 500 fi
 501
 502 # Is pod2man recent enough to regenerate manpages?
 503 AC_MSG_CHECKING([for recent Pod::Man])
 504 if perl -e 'use 1.10 Pod::Man' >/dev/null 2>&1; then
 505   AC_MSG_RESULT(yes)
 506   GENERATED_MANPAGES=generated-manpages         AC_SUBST(GENERATED_MANPAGES)
 507 else
 508   AC_MSG_RESULT(no)
 509   GENERATED_MANPAGES=
 510 fi
 511
 512 # How about lex?
 513 dnl Don't use AC_PROG_LEX; we insist on flex.
 514 dnl LEXLIB is not useful in gcc.
 515 if test -f $srcdir/../flex/skel.c; then
 516   FLEX='$(objdir)/../flex/flex'
 517 else
 518   AC_CHECK_PROG(FLEX, flex, flex, false)
 519 fi
 520
 521 # Bison?
 522 # The -L switch is so bison can find its skeleton file.
 523 if test -f $srcdir/../bison/bison.simple; then
 524   BISON='$(objdir)/../bison/bison -L $(srcdir)/../bison/'
 525 else
 526   AC_CHECK_PROG(BISON, bison, bison, false)
 527 fi
 528
 529 # These libraries may be used by collect2.
 530 # We may need a special search path to get them linked.
 531 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 532 [save_LIBS="$LIBS"
 533 for libs in '' -lld -lmld \
 534                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 535                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 536 do
 537         LIBS="$libs"
 538         AC_TRY_LINK_FUNC(ldopen,
 539                 [gcc_cv_collect2_libs="$libs"; break])
 540 done
 541 LIBS="$save_LIBS"
 542 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 543 case $gcc_cv_collect2_libs in
 544         "none required")        ;;
 545         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 546 esac
 547 AC_SUBST(COLLECT2_LIBS)
 548
 549 # When building Ada code on Alpha, we need exc_resume which is usually in
 550 # -lexc.  So test for it.
 551 save_LIBS="$LIBS"
 552 LIBS=
 553 AC_SEARCH_LIBS(exc_resume, exc)
 554 GNAT_LIBEXC="$LIBS"
 555 LIBS="$save_LIBS"
 556 AC_SUBST(GNAT_LIBEXC)
 557
 558 # See if the stage1 system preprocessor understands the ANSI C
 559 # preprocessor stringification operator.  (Used by symcat.h.)
 560 AC_C_STRINGIZE
 561
 562 # Use <inttypes.h> only if it exists,
 563 # doesn't clash with <sys/types.h>, and declares intmax_t.
 564 AC_MSG_CHECKING(for inttypes.h)
 565 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 566 [AC_TRY_COMPILE(
 567   [#include <sys/types.h>
 568 #include <inttypes.h>],
 569   [intmax_t i = -1;],
 570   [gcc_cv_header_inttypes_h=yes],
 571   gcc_cv_header_inttypes_h=no)])
 572 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 573 if test $gcc_cv_header_inttypes_h = yes; then
 574   AC_DEFINE(HAVE_INTTYPES_H, 1,
 575         [Define if you have a working <inttypes.h> header file.])
 576 fi
 577
 578 dnl Disabled until we have a complete test for buggy enum bitfields.
 579 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 580
 581 AC_CHECK_FUNCS(strtoul bsearch popen times clock dup2 \
 582         strchr strrchr kill getrlimit setrlimit atoll atoq \
 583         sysconf isascii gettimeofday strsignal putc_unlocked fputc_unlocked \
 584         fputs_unlocked fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
 585         lstat)
 586
 587 AC_CHECK_TYPE(ssize_t, int)
 588
 589 # Try to determine the array type of the second argument of getgroups
 590 # for the target system (int or gid_t).
 591 AC_TYPE_GETGROUPS
 592 if test "${target}" = "${build}"; then
 593   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 594 else
 595   case "${target}" in
 596         # This condition may need some tweaking.  It should include all
 597         # targets where the array type of the second argument of getgroups
 598         # is int and the type of gid_t is not equivalent to int.
 599         *-*-sunos* | *-*-ultrix*)
 600                 TARGET_GETGROUPS_T=int
 601                 ;;
 602         *)
 603                 TARGET_GETGROUPS_T=gid_t
 604                 ;;
 605   esac
 606 fi
 607 AC_SUBST(TARGET_GETGROUPS_T)
 608
 609 gcc_AC_FUNC_VFPRINTF_DOPRNT
 610 gcc_AC_FUNC_STRSTR
 611 gcc_AC_FUNC_PRINTF_PTR
 612
 613 case "${host}" in
 614 *-*-uwin*)
 615   AC_MSG_ERROR([
 616 *** UWIN may not be used as a host platform because
 617 *** linking with posix.dll is not allowed by the GNU GPL])
 618   ;;
 619 esac
 620 AC_FUNC_VFORK
 621 AC_FUNC_MMAP_ANYWHERE
 622 AC_FUNC_MMAP_FILE
 623
 624 AM_ICONV
 625
 626 # We will need to find libiberty.h and ansidecl.h
 627 saved_CFLAGS="$CFLAGS"
 628 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
 629 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
 630         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
 631         fprintf_unlocked strstr environ errno \
 632         malloc realloc calloc free basename getopt clock, , ,[
 633 #include "ansidecl.h"
 634 #include "system.h"])
 635
 636 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
 637 #include "ansidecl.h"
 638 #include "system.h"
 639 #ifdef HAVE_SYS_RESOURCE_H
 640 #include <sys/resource.h>
 641 #endif
 642 ])
 643
 644 gcc_AC_CHECK_DECLS(times, , ,[
 645 #include "ansidecl.h"
 646 #include "system.h"
 647 #ifdef HAVE_SYS_TIMES_H
 648 #include <sys/times.h>
 649 #endif
 650 ])
 651
 652 # More time-related stuff.
 653 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
 654 AC_TRY_COMPILE([
 655 #include "ansidecl.h"
 656 #include "system.h"
 657 #ifdef HAVE_SYS_TIMES_H
 658 #include <sys/times.h>
 659 #endif
 660 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
 661 if test $ac_cv_struct_tms = yes; then
 662   AC_DEFINE(HAVE_STRUCT_TMS, 1,
 663   [Define if <sys/times.h> defines struct tms.])
 664 fi
 665
 666 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
 667 # revisit after autoconf 2.50.
 668 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
 669 AC_TRY_COMPILE([
 670 #include "ansidecl.h"
 671 #include "system.h"
 672 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
 673 if test $gcc_cv_type_clock_t = yes; then
 674   AC_DEFINE(HAVE_CLOCK_T, 1,
 675   [Define if <time.h> defines clock_t.])
 676 fi
 677
 678 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
 679 CFLAGS="$saved_CFLAGS"
 680
 681 # mkdir takes a single argument on some systems.
 682 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
 683
 684 # File extensions
 685 manext='.1'
 686 objext='.o'
 687 AC_SUBST(manext)
 688 AC_SUBST(objext)
 689
 690 build_xm_file=
 691 build_xm_defines=
 692 build_install_headers_dir=install-headers-tar
 693 build_exeext=
 694 host_xm_file=
 695 host_xm_defines=
 696 host_xmake_file=
 697 host_truncate_target=
 698 host_exeext=
 699
 700 # Decode the host machine, then the target machine.
 701 # For the host machine, we save the xm_file variable as host_xm_file;
 702 # then we decode the target machine and forget everything else
 703 # that came from the host machine.
 704 for machine in $build $host $target; do
 705         . ${srcdir}/config.gcc
 706 done
 707
 708 extra_objs="${host_extra_objs} ${extra_objs}"
 709
 710 # Default the target-machine variables that were not explicitly set.
 711 if test x"$tm_file" = x
 712 then tm_file=$cpu_type/$cpu_type.h; fi
 713
 714 if test x"$extra_headers" = x
 715 then extra_headers=; fi
 716
 717 if test x$md_file = x
 718 then md_file=$cpu_type/$cpu_type.md; fi
 719
 720 if test x$out_file = x
 721 then out_file=$cpu_type/$cpu_type.c; fi
 722
 723 if test x"$tmake_file" = x
 724 then tmake_file=$cpu_type/t-$cpu_type
 725 fi
 726
 727 if test x"$dwarf2" = xyes
 728 then tm_file="$tm_file tm-dwarf2.h"
 729 fi
 730
 731 if test x$float_format = x
 732 then float_format=i64
 733 fi
 734
 735 if test $float_format = none
 736 then float_h_file=Makefile.in
 737 else float_h_file=float-$float_format.h
 738 fi
 739
 740 # Handle cpp installation.
 741 if test x$enable_cpp != xno
 742 then
 743   tmake_file="$tmake_file t-install-cpp"
 744 fi
 745
 746 # Say what files are being used for the output code and MD file.
 747 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
 748 echo "Using \`$srcdir/config/$md_file' as machine description file."
 749
 750 # If any of the xm_file variables contain nonexistent files, warn
 751 # about them and drop them.
 752
 753 bx=
 754 for x in $build_xm_file; do
 755   if    test -f $srcdir/config/$x
 756   then      bx="$bx $x"
 757   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 758   fi
 759 done
 760 build_xm_file="$bx"
 761
 762 hx=
 763 for x in $host_xm_file; do
 764   if    test -f $srcdir/config/$x
 765   then      hx="$hx $x"
 766   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 767   fi
 768 done
 769 host_xm_file="$hx"
 770
 771 tx=
 772 for x in $xm_file; do
 773   if    test -f $srcdir/config/$x
 774   then      tx="$tx $x"
 775   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
 776   fi
 777 done
 778 xm_file="$tx"
 779
 780 count=a
 781 for f in $tm_file; do
 782         count=${count}x
 783 done
 784 if test $count = ax; then
 785         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
 786 else
 787         echo "Using the following target machine macro files:"
 788         for f in $tm_file; do
 789                 echo "  $srcdir/config/$f"
 790         done
 791 fi
 792
 793 count=a
 794 for f in $host_xm_file; do
 795         count=${count}x
 796 done
 797 if test $count = a; then
 798         :
 799 elif test $count = ax; then
 800         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
 801 else
 802         echo "Using the following host machine macro files:"
 803         for f in $host_xm_file; do
 804                 echo "  $srcdir/config/$f"
 805         done
 806 fi
 807
 808 if test "$host_xm_file" != "$build_xm_file"; then
 809         count=a
 810         for f in $build_xm_file; do
 811                 count=${count}x
 812         done
 813         if test $count = a; then
 814                 :
 815         elif test $count = ax; then
 816                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
 817         else
 818                 echo "Using the following build machine macro files:"
 819                 for f in $build_xm_file; do
 820                         echo "  $srcdir/config/$f"
 821                 done
 822         fi
 823 fi
 824
 825 if test x$thread_file = x; then
 826         if test x$target_thread_file != x; then
 827                 thread_file=$target_thread_file
 828         else
 829                 thread_file='single'
 830         fi
 831 fi
 832
 833 # auto-host.h is the file containing items generated by autoconf and is
 834 # the first file included by config.h.
 835 # If host=build, it is correct to have hconfig include auto-host.h
 836 # as well.  If host!=build, we are in error and need to do more
 837 # work to find out the build config parameters.
 838 if test x$host = x$build
 839 then
 840         build_auto=auto-host.h
 841 else
 842         # We create a subdir, then run autoconf in the subdir.
 843         # To prevent recursion we set host and build for the new
 844         # invocation of configure to the build for this invocation
 845         # of configure.
 846         tempdir=build.$$
 847         rm -rf $tempdir
 848         mkdir $tempdir
 849         cd $tempdir
 850         case ${srcdir} in
 851         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
 852         *) realsrcdir=../${srcdir};;
 853         esac
 854         saved_CFLAGS="${CFLAGS}"
 855         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
 856         ${realsrcdir}/configure \
 857                 --target=$target --host=$build --build=$build
 858         CFLAGS="${saved_CFLAGS}"
 859
 860         # We just finished tests for the build machine, so rename
 861         # the file auto-build.h in the gcc directory.
 862         mv auto-host.h ../auto-build.h
 863         cd ..
 864         rm -rf $tempdir
 865         build_auto=auto-build.h
 866 fi
 867
 868 tm_file="${tm_file} defaults.h"
 869 host_xm_file="auto-host.h ansidecl.h ${host_xm_file} ${tm_file}"
 870 build_xm_file="${build_auto} ansidecl.h ${build_xm_file} ${tm_file}"
 871 xm_file="ansidecl.h ${xm_file} ${tm_file}"
 872
 873 # Truncate the target if necessary
 874 if test x$host_truncate_target != x; then
 875         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
 876 fi
 877
 878 # Get the version trigger filename from the toplevel
 879 if test "${with_gcc_version_trigger+set}" = set; then
 880         gcc_version_trigger=$with_gcc_version_trigger
 881 else
 882         gcc_version_trigger=${srcdir}/version.c
 883 fi
 884 changequote(,)dnl
 885 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*"\([^"]*\)".*/\1/'`
 886 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 887
 888 # Compile in configure arguments.
 889 if test -f configargs.h ; then
 890         # Being re-configured.
 891         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
 892         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
 893 else
 894         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
 895 fi
 896 cat > configargs.h <<EOF
 897 /* Generated automatically. */
 898 static const char configuration_arguments[] = "$gcc_config_arguments";
 899 static const char thread_model[] = "$thread_file";
 900 EOF
 901 changequote([,])dnl
 902
 903 # Internationalization
 904 PACKAGE=gcc
 905 VERSION="$gcc_version"
 906 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
 907         [Define to the name of the distribution.])
 908 AC_DEFINE_UNQUOTED(VERSION, "$VERSION",
 909         [Define to the version of the distribution.])
 910 AC_SUBST(PACKAGE)
 911 AC_SUBST(VERSION)
 912
 913 # Enable NLS support by default
 914 AC_ARG_ENABLE(nls,
 915   [  --enable-nls            use Native Language Support (default)],
 916   , enable_nls=yes)
 917
 918 # if cross compiling, disable NLS support.
 919 # It's not worth the trouble, at least for now.
 920
 921 if test "${build}" != "${host}" && test "x$enable_nls" = "xyes"; then
 922   AC_MSG_WARN(Disabling NLS support for canadian cross compiler.)
 923   enable_nls=no
 924 fi
 925
 926 AM_GNU_GETTEXT
 927
 928 # Windows32 Registry support for specifying GCC installation paths.
 929 AC_ARG_ENABLE(win32-registry,
 930 [  --disable-win32-registry
 931                           disable lookup of installation paths in the
 932                           Registry on Windows hosts
 933   --enable-win32-registry enable registry lookup (default)
 934   --enable-win32-registry=KEY
 935                           use KEY instead of GCC version as the last portion
 936                           of the registry key],,)
 937 case $host_os in
 938         win32 | pe | cygwin* | mingw32* | uwin*)
 939 AC_MSG_CHECKING(whether windows registry support is requested)
 940 if test "x$enable_win32_registry" != xno; then
 941   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
 942 [Define to 1 if installation paths should be looked up in Windows32
 943    Registry. Ignored on non windows32 hosts.])
 944   AC_MSG_RESULT(yes)
 945   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
 946 else
 947   AC_MSG_RESULT(no)
 948 fi
 949
 950 # Check if user specified a different registry key.
 951 case "x${enable_win32_registry}" in
 952 x | xyes)
 953   # default.
 954   gcc_cv_win32_registry_key="$VERSION"
 955   ;;
 956 xno)
 957   # no registry lookup.
 958   gcc_cv_win32_registry_key=''
 959   ;;
 960 *)
 961   # user-specified key.
 962   gcc_cv_win32_registry_key="$enable_win32_registry"
 963   ;;
 964 esac
 965
 966 if test "x$enable_win32_registry" != xno; then
 967   AC_MSG_CHECKING(registry key on windows hosts)
 968   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
 969         [Define to be the last portion of registry key on windows hosts.])
 970   AC_MSG_RESULT($gcc_cv_win32_registry_key)
 971 fi
 972 ;;
 973 esac
 974
 975 # Get an absolute path to the GCC top-level source directory
 976 holddir=`pwd`
 977 cd $srcdir
 978 topdir=`pwd`
 979 cd $holddir
 980
 981 # Conditionalize the makefile for this host machine.
 982 # Make-host contains the concatenation of all host makefile fragments
 983 # [there can be more than one].  This file is built by configure.frag.
 984 host_overrides=Make-host
 985 dep_host_xmake_file=
 986 for f in .. ${host_xmake_file}
 987 do
 988         if test -f ${srcdir}/config/$f
 989         then
 990                 dep_host_xmake_file="${dep_host_xmake_file} ${srcdir}/config/$f"
 991         fi
 992 done
 993
 994 # Conditionalize the makefile for this target machine.
 995 # Make-target contains the concatenation of all host makefile fragments
 996 # [there can be more than one].  This file is built by configure.frag.
 997 target_overrides=Make-target
 998 dep_tmake_file=
 999 for f in .. ${tmake_file}
1000 do
1001         if test -f ${srcdir}/config/$f
1002         then
1003                 dep_tmake_file="${dep_tmake_file} ${srcdir}/config/$f"
1004         fi
1005 done
1006
1007 # If the host doesn't support symlinks, modify CC in
1008 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1009 # Otherwise, we can use "CC=$(CC)".
1010 rm -f symtest.tem
1011 if $symbolic_link $srcdir/gcc.c symtest.tem 2>/dev/null
1012 then
1013         cc_set_by_configure="\$(CC)"
1014         quoted_cc_set_by_configure="\$(CC)"
1015         stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1016 else
1017         rm -f symtest.tem
1018         if cp -p $srcdir/gcc.c symtest.tem 2>/dev/null
1019         then
1020                 symbolic_link="cp -p"
1021         else
1022                 symbolic_link="cp"
1023         fi
1024         cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1025         quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1026         stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1027 fi
1028 rm -f symtest.tem
1029
1030 out_object_file=`basename $out_file .c`.o
1031
1032 tm_file_list=
1033 for f in $tm_file; do
1034   case $f in
1035     ansidecl.h )
1036        tm_file_list="${tm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1037     defaults.h )
1038        tm_file_list="${tm_file_list} $f" ;;
1039     *) tm_file_list="${tm_file_list} \$(srcdir)/config/$f" ;;
1040   esac
1041 done
1042
1043 tm_p_file_list=
1044 for f in $tm_p_file; do
1045     tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1046 done
1047
1048 host_xm_file_list=
1049 for f in $host_xm_file; do
1050   case $f in
1051     ansidecl.h )
1052        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1053     auto-host.h | defaults.h )
1054        host_xm_file_list="${host_xm_file_list} $f" ;;
1055     *) host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f" ;;
1056   esac
1057 done
1058
1059 build_xm_file_list=
1060 for f in $build_xm_file; do
1061   case $f in
1062     ansidecl.h )
1063        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/ansidecl.h" ;;
1064     auto-build.h | auto-host.h | defaults.h )
1065        build_xm_file_list="${build_xm_file_list} $f" ;;
1066     *) build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f" ;;
1067   esac
1068 done
1069
1070 # Define macro CROSS_COMPILE in compilation
1071 # if this is a cross-compiler.
1072 # Also use all.cross instead of all.internal
1073 # and add cross-make to Makefile.
1074 cross_overrides="/dev/null"
1075 if test x$host != x$target
1076 then
1077         cross_defines="CROSS=-DCROSS_COMPILE"
1078         cross_overrides="${topdir}/cross-make"
1079 fi
1080
1081 # If this is a cross-compiler that does not
1082 # have its own set of headers then define
1083 # inhibit_libc
1084
1085 # If this is using newlib, then define inhibit_libc in LIBGCC2_CFLAGS.
1086 # This prevents libgcc2 from containing any code which requires libc
1087 # support.
1088 inhibit_libc=
1089 if [test x$host != x$target] && [test x$with_headers = x]; then
1090        inhibit_libc=-Dinhibit_libc
1091 else
1092        if [test x$with_newlib = xyes]; then
1093                inhibit_libc=-Dinhibit_libc
1094        fi
1095 fi
1096 AC_SUBST(inhibit_libc)
1097
1098 # When building gcc with a cross-compiler, we need to fix a few things.
1099 # This must come after cross-make as we want all.build to override
1100 # all.cross.
1101 build_overrides="/dev/null"
1102 if test x$build != x$host
1103 then
1104         build_overrides="${topdir}/build-make"
1105 fi
1106
1107 # Expand extra_headers to include complete path.
1108 # This substitutes for lots of t-* files.
1109 extra_headers_list=
1110 if test "x$extra_headers" = x
1111 then true
1112 else
1113         # Prepend ${srcdir}/ginclude/ to every entry in extra_headers.
1114         for file in $extra_headers;
1115         do
1116                 extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/${file}"
1117         done
1118 fi
1119
1120 if test x$use_collect2 = xno; then
1121         use_collect2=
1122 fi
1123
1124 # Add a definition of USE_COLLECT2 if system wants one.
1125 if test x$use_collect2 != x
1126 then
1127         host_xm_defines="${host_xm_defines} USE_COLLECT2"
1128         xm_defines="${xm_defines} USE_COLLECT2"
1129 fi
1130
1131 # If we have gas in the build tree, make a link to it.
1132 if test -f ../gas/Makefile; then
1133         rm -f as; $symbolic_link ../gas/as-new$host_exeext as$host_exeext 2>/dev/null
1134 fi
1135
1136 # If we have nm and objdump in the build tree, make a link to them.
1137 if test -f ../binutils/Makefile; then
1138         rm -f nm; $symbolic_link ../binutils/nm-new$host_exeext nm$host_exeext 2>/dev/null
1139         rm -f objdump; $symbolic_link ../binutils/objdump$host_exeext objdump$host_exeext 2>/dev/null
1140 fi
1141
1142 # If we have ld in the build tree, make a link to it.
1143 if test -f ../ld/Makefile; then
1144         rm -f collect-ld; $symbolic_link ../ld/ld-new$host_exeext collect-ld$host_exeext 2>/dev/null
1145 fi
1146
1147 # Figure out what assembler we will be using.
1148 AC_MSG_CHECKING(what assembler to use)
1149 gcc_cv_as=
1150 gcc_cv_gas_major_version=
1151 gcc_cv_gas_minor_version=
1152 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1153 gcc_cv_as_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1154 if test -x "$DEFAULT_ASSEMBLER"; then
1155         gcc_cv_as="$DEFAULT_ASSEMBLER"
1156 elif test -x "$AS"; then
1157         gcc_cv_as="$AS"
1158 elif test -x as$host_exeext; then
1159         # Build using assembler in the current directory.
1160         gcc_cv_as=./as$host_exeext
1161 elif test -f $gcc_cv_as_gas_srcdir/configure.in -a -f ../gas/Makefile; then
1162         # Single tree build which includes gas.
1163         for f in $gcc_cv_as_bfd_srcdir/configure $gcc_cv_as_gas_srcdir/configure $gcc_cv_as_gas_srcdir/configure.in $gcc_cv_as_gas_srcdir/Makefile.in
1164         do
1165 changequote(,)dnl
1166                 gcc_cv_gas_version=`grep '^VERSION=[0-9]*\.[0-9]*' $f`
1167 changequote([,])dnl
1168                 if test x$gcc_cv_gas_version != x; then
1169                         break
1170                 fi
1171         done
1172 changequote(,)dnl
1173         gcc_cv_gas_major_version=`expr "$gcc_cv_gas_version" : "VERSION=\([0-9]*\)"`
1174         gcc_cv_gas_minor_version=`expr "$gcc_cv_gas_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1175 changequote([,])dnl
1176 fi
1177
1178 if test "x$gcc_cv_as" = x -a x$host = x$target; then
1179         # Native build.
1180         # Search the same directories that the installed compiler will
1181         # search.  Else we may find the wrong assembler and lose.  If we
1182         # do not find a suitable assembler binary, then try the user's
1183         # path.
1184         #
1185         # Also note we have to check MD_EXEC_PREFIX before checking the
1186         # user's path.  Unfortunately, there is no good way to get at the
1187         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1188         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1189         # to be fixed as part of the make/configure rewrite too.
1190
1191         if test "x$exec_prefix" = xNONE; then
1192                 if test "x$prefix" = xNONE; then
1193                         test_prefix=/usr/local
1194                 else
1195                         test_prefix=$prefix
1196                 fi
1197         else
1198                 test_prefix=$exec_prefix
1199         fi
1200
1201         # If the loop below does not find an assembler, then use whatever
1202         # one we can find in the users's path.
1203         # user's path.
1204         gcc_cv_as=as$host_exeext
1205
1206         test_dirs="$test_prefix/lib/gcc-lib/$target/$gcc_version \
1207                    $test_prefix/lib/gcc-lib/$target \
1208                    /usr/lib/gcc/$target/$gcc_version \
1209                    /usr/lib/gcc/$target \
1210                    $test_prefix/$target/bin/$target/$gcc_version \
1211                    $test_prefix/$target/bin \
1212                    /usr/libexec \
1213                    /usr/ccs/gcc \
1214                    /usr/ccs/bin \
1215                    /udk/usr/ccs/bin \
1216                    /bsd43/usr/lib/cmplrs/cc \
1217                    /usr/cross64/usr/bin \
1218                    /usr/lib/cmplrs/cc \
1219                    /sysv/usr/lib/cmplrs/cc \
1220                    /svr4/usr/lib/cmplrs/cc \
1221                    /usr/bin"
1222
1223         for dir in $test_dirs; do
1224                 if test -f $dir/as$host_exeext; then
1225                         gcc_cv_as=$dir/as$host_exeext
1226                         break;
1227                 fi
1228         done
1229 fi
1230 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1231   AC_MSG_RESULT("newly built gas")
1232 else
1233   AC_MSG_RESULT($gcc_cv_as)
1234 fi
1235
1236 # Figure out what nm we will be using.
1237 AC_MSG_CHECKING(what nm to use)
1238 if test -x nm$host_exeext; then
1239         gcc_cv_nm=./nm$host_exeext
1240 elif test x$host = x$target; then
1241         # Native build.
1242         gcc_cv_nm=nm$host_exeext
1243 fi
1244 AC_MSG_RESULT($gcc_cv_nm)
1245
1246 # Figure out what objdump we will be using.
1247 AC_MSG_CHECKING(what objdump to use)
1248 if test -x objdump$host_exeext; then
1249         gcc_cv_objdump=./objdump$host_exeext
1250 elif test x$host = x$target; then
1251         # Native build.
1252         gcc_cv_objdump=objdump$host_exeext
1253 fi
1254 AC_MSG_RESULT($gcc_cv_objdump)
1255
1256 # Figure out what assembler alignment features are present.
1257 AC_MSG_CHECKING(assembler alignment features)
1258 gcc_cv_as_alignment_features=none
1259 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1260         # Gas version 2.6 and later support for .balign and .p2align.
1261         # bytes to skip when using .p2align.
1262         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 6 -o "$gcc_cv_gas_major_version" -gt 2; then
1263                 gcc_cv_as_alignment_features=".balign and .p2align"
1264                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1265         fi
1266         # Gas version 2.8 and later support specifying the maximum
1267         # bytes to skip when using .p2align.
1268         if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 8 -o "$gcc_cv_gas_major_version" -gt 2; then
1269                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1270                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1271         fi
1272 elif test x$gcc_cv_as != x; then
1273         # Check if we have .balign and .p2align
1274         echo ".balign  4" > conftest.s
1275         echo ".p2align  2" >> conftest.s
1276         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1277                 gcc_cv_as_alignment_features=".balign and .p2align"
1278                 AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN)
1279         fi
1280         rm -f conftest.s conftest.o
1281         # Check if specifying the maximum bytes to skip when
1282         # using .p2align is supported.
1283         echo ".p2align 4,,7" > conftest.s
1284         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1285                 gcc_cv_as_alignment_features=".p2align including maximum skip"
1286                 AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN)
1287         fi
1288         rm -f conftest.s conftest.o
1289 fi
1290 AC_MSG_RESULT($gcc_cv_as_alignment_features)
1291
1292 AC_MSG_CHECKING(assembler subsection support)
1293 gcc_cv_as_subsections=no
1294 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1295   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1296     gcc_cv_as_subsections="working .subsection -1"
1297   fi
1298 elif test x$gcc_cv_as != x; then
1299         # Check if we have .subsection
1300         echo ".subsection 1" > conftest.s
1301         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1302                 gcc_cv_as_subsections=".subsection"
1303                 if test x$gcc_cv_nm != x; then
1304                         cat > conftest.s <<EOF
1305 conftest_label1: .word 0
1306 .subsection -1
1307 conftest_label2: .word 0
1308 .previous
1309 EOF
1310                         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1311                                 $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1312                                 $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1313                                 if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1; then
1314                                         :
1315                                 else
1316                                         gcc_cv_as_subsections="working .subsection -1"
1317                                 fi
1318                         fi
1319                 fi
1320         fi
1321         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1322 fi
1323 if test x"$gcc_cv_as_subsections" = x"working .subsection -1"; then
1324         AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1325 [Define if your assembler supports .subsection and .subsection -1 starts
1326    emitting at the beginning of your section.])
1327 fi
1328 AC_MSG_RESULT($gcc_cv_as_subsections)
1329
1330 AC_MSG_CHECKING(assembler weak support)
1331 gcc_cv_as_weak=no
1332 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1333   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 2 -o "$gcc_cv_gas_major_version" -gt 2; then
1334     gcc_cv_as_weak="yes"
1335   fi
1336 elif test x$gcc_cv_as != x; then
1337         # Check if we have .weak
1338         echo "  .weak foobar" > conftest.s
1339         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1340                 gcc_cv_as_weak="yes"
1341         fi
1342         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1343 fi
1344 if test x"$gcc_cv_as_weak" = xyes; then
1345         AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])
1346 fi
1347 AC_MSG_RESULT($gcc_cv_as_weak)
1348
1349 AC_MSG_CHECKING(assembler hidden support)
1350 gcc_cv_as_hidden=no
1351 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1352   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 10 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1353     gcc_cv_as_hidden="yes"
1354   fi
1355 elif test x$gcc_cv_as != x; then
1356         # Check if we have .hidden
1357         echo "  .hidden foobar" > conftest.s
1358         echo "foobar:" >> conftest.s
1359         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1360                 gcc_cv_as_hidden="yes"
1361         fi
1362         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1363 fi
1364 if test x"$gcc_cv_as_hidden" = xyes; then
1365         AC_DEFINE(HAVE_GAS_HIDDEN, 1,
1366                 [Define if your assembler supports .hidden.])
1367 fi
1368 AC_MSG_RESULT($gcc_cv_as_hidden)
1369
1370 AC_MSG_CHECKING(assembler leb128 support)
1371 gcc_cv_as_leb128=no
1372 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1373   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 11 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1374     gcc_cv_as_leb128="yes"
1375   fi
1376 elif test x$gcc_cv_as != x; then
1377         # Check if we have .[us]leb128, and support symbol arithmetic with it.
1378         cat > conftest.s <<EOF
1379         .data
1380         .uleb128 L2 - L1
1381 L1:
1382         .uleb128 1280
1383         .sleb128 -1010
1384 L2:
1385 EOF
1386         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1387                 gcc_cv_as_leb128="yes"
1388
1389                 # GAS versions before 2.11 do not support uleb128,
1390                 # despite appearing to.
1391                 # ??? There exists an elf-specific test that will crash
1392                 # the assembler.  Perhaps it's better to figure out whether
1393                 # arbitrary sections are supported and try the test.
1394                 as_ver=`$gcc_cv_as --version 2>/dev/null | head -1`
1395                 if echo "$as_ver" | grep GNU > /dev/null; then
1396 changequote(,)dnl
1397                         as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
1398                         as_major=`echo $as_ver | sed 's/\..*//'`
1399                         as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
1400 changequote([,])dnl
1401                         if test $as_major -eq 2 -a $as_minor -lt 11; then
1402                                 gcc_cv_as_leb128="no"
1403                         fi
1404                 fi
1405         fi
1406         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1407 fi
1408 if test x"$gcc_cv_as_leb128" = xyes; then
1409         AC_DEFINE(HAVE_AS_LEB128, 1,
1410                 [Define if your assembler supports .uleb128.])
1411 fi
1412 AC_MSG_RESULT($gcc_cv_as_leb128)
1413
1414 AC_MSG_CHECKING(assembler eh_frame optimization)
1415 gcc_cv_as_eh_frame=no
1416 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1417   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1418     gcc_cv_as_eh_frame="yes"
1419   fi
1420 elif test x$gcc_cv_as != x; then
1421         # Check if this is GAS.
1422         as_ver=`$gcc_cv_as --version < /dev/null 2> /dev/null | head -1`
1423         rm -f a.out 2> /dev/null
1424         if echo "$as_ver" | grep GNU > /dev/null; then
1425                 # Versions up to and including 2.11.0 may mis-optimize
1426                 # .eh_frame data.  Try something.
1427                 cat > conftest.s <<EOF
1428         .text
1429 .LFB1:
1430         .4byte  0
1431 .L1:
1432         .4byte  0
1433 .LFE1:
1434         .section        .eh_frame,"aw",@progbits
1435 __FRAME_BEGIN__:
1436         .4byte  .LECIE1-.LSCIE1
1437 .LSCIE1:
1438         .4byte  0x0
1439         .byte   0x1
1440         .ascii "z\0"
1441         .byte   0x1
1442         .byte   0x78
1443         .byte   0x1a
1444         .byte   0x0
1445         .byte   0x4
1446         .4byte  1
1447         .p2align 1
1448 .LECIE1:
1449 .LSFDE1:
1450         .4byte  .LEFDE1-.LASFDE1
1451 .LASFDE1:
1452         .4byte  .LASFDE1-__FRAME_BEGIN__
1453         .4byte  .LFB1
1454         .4byte  .LFE1-.LFB1
1455         .byte   0x4
1456         .4byte  .LFE1-.LFB1
1457         .byte   0x4
1458         .4byte  .L1-.LFB1
1459 .LEFDE1:
1460 EOF
1461                 cat > conftest.lit <<EOF
1462  0000 10000000 00000000 017a0001 781a0004  .........z..x...
1463  0010 01000000 12000000 18000000 00000000  ................
1464  0020 08000000 04080000 0044               .........D
1465 EOF
1466                 cat > conftest.big <<EOF
1467  0000 00000010 00000000 017a0001 781a0004  .........z..x...
1468  0010 00000001 00000012 00000018 00000000  ................
1469  0020 00000008 04000000 0844               .........D
1470 EOF
1471                 # If the assembler didn't choke, and we can objdump,
1472                 # and we got the correct data, then succeed.
1473                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1474                    && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
1475                       | tail -3 > conftest.got \
1476                    && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
1477                         || cmp conftest.big conftest.got > /dev/null 2>&1; }
1478                 then
1479                         gcc_cv_as_eh_frame="yes"
1480                 else
1481                         gcc_cv_as_eh_frame="bad"
1482                         if $gcc_cv_as -o conftest.o --traditional-format /dev/null; then
1483                                 AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
1484         [Define if your assembler mis-optimizes .eh_frame data.])
1485                         fi
1486                 fi
1487         fi
1488         rm -f conftest.*
1489 fi
1490 AC_MSG_RESULT($gcc_cv_as_eh_frame)
1491
1492 AC_MSG_CHECKING(assembler section merging support)
1493 gcc_cv_as_shf_merge=no
1494 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1495   if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 12 -o "$gcc_cv_gas_major_version" -gt 2 && grep 'obj_format = elf' ../gas/Makefile > /dev/null; then
1496     gcc_cv_as_shf_merge=yes
1497   fi
1498 elif test x$gcc_cv_as != x; then
1499         # Check if we support SHF_MERGE sections
1500         echo '.section .rodata.str, "aMS", @progbits, 1' > conftest.s
1501         if $gcc_cv_as --fatal-warnings -o conftest.o conftest.s > /dev/null 2>&1; then
1502                 gcc_cv_as_shf_merge=yes
1503         fi
1504         rm -f conftest.s conftest.o
1505 fi
1506 if test x"$gcc_cv_as_shf_merge" = xyes; then
1507         AC_DEFINE(HAVE_GAS_SHF_MERGE, 1,
1508 [Define if your assembler supports marking sections with SHF_MERGE flag.])
1509 fi
1510 AC_MSG_RESULT($gcc_cv_as_shf_merge)
1511
1512 case "$target" in
1513   sparc*-*-*)
1514     AC_CACHE_CHECK([assembler .register pseudo-op support],
1515         gcc_cv_as_register_pseudo_op, [
1516         gcc_cv_as_register_pseudo_op=unknown
1517         if test x$gcc_cv_as != x; then
1518             # Check if we have .register
1519             echo ".register %g2, #scratch" > conftest.s
1520             if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1521                 gcc_cv_as_register_pseudo_op=yes
1522             else
1523                 gcc_cv_as_register_pseudo_op=no
1524             fi
1525             rm -f conftest.s conftest.o
1526         fi
1527     ])
1528     if test "x$gcc_cv_as_register_pseudo_op" = xyes; then
1529         AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
1530                 [Define if your assembler supports .register.])
1531     fi
1532
1533     AC_CACHE_CHECK([assembler supports -relax],
1534         gcc_cv_as_relax_opt, [
1535         gcc_cv_as_relax_opt=unknown
1536         if test x$gcc_cv_as != x; then
1537             # Check if gas supports -relax
1538             echo ".text" > conftest.s
1539             if $gcc_cv_as -relax -o conftest.o conftest.s > /dev/null 2>&1; then
1540                 gcc_cv_as_relax_opt=yes
1541             else
1542                 gcc_cv_as_relax_opt=no
1543             fi
1544             rm -f conftest.s conftest.o
1545         fi
1546     ])
1547     if test "x$gcc_cv_as_relax_opt" = xyes; then
1548         AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
1549                 [Define if your assembler supports -relax option.])
1550     fi
1551
1552     case "$tm_file" in
1553     *64*)
1554         AC_CACHE_CHECK([for 64 bit support in assembler ($gcc_cv_as)],
1555             gcc_cv_as_flags64, [
1556                 if test -n "$gcc_cv_as"; then
1557                     echo ".xword foo" > conftest.s
1558                     gcc_cv_as_flags64=no
1559                     for flag in "-xarch=v9" "-64 -Av9"; do
1560                         if $gcc_cv_as $flag -o conftest.o conftest.s \
1561                             > /dev/null 2>&1; then
1562                             gcc_cv_as_flags64=$flag
1563                             break
1564                         fi
1565                     done
1566                     rm -f conftest.s conftest.o
1567                 else
1568                     if test "$gas" = yes; then
1569                         gcc_cv_as_flags64="-64 -Av9"
1570                     else
1571                         gcc_cv_as_flags64="-xarch=v9"
1572                     fi
1573                 fi
1574         ])
1575         if test "x$gcc_cv_as_flags64" = xno; then
1576 changequote(, )
1577             tmake_file=`echo " $tmake_file " | sed -e 's, sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1578             dep_tmake_file=`echo " $dep_tmake_file " | sed -e 's, [^ ]*/config/sparc/t-sol2-64 , ,' -e 's,^ ,,' -e 's, $,,'`
1579 changequote([, ])
1580         else
1581             AC_DEFINE_UNQUOTED(AS_SPARC64_FLAG, "$gcc_cv_as_flags64",
1582                         [Define if the assembler supports 64bit sparc.])
1583         fi
1584         ;;
1585     *) gcc_cv_as_flags64=${gcc_cv_as_flags64-no}
1586         ;;
1587     esac
1588
1589     if test "x$gcc_cv_as_flags64" != xno; then
1590         AC_CACHE_CHECK([for assembler offsetable %lo() support],
1591             gcc_cv_as_offsetable_lo10, [
1592             gcc_cv_as_offsetable_lo10=unknown
1593             if test "x$gcc_cv_as" != x; then
1594                 # Check if assembler has offsetable %lo()
1595                 echo "or %g1, %lo(ab) + 12, %g1" > conftest.s
1596                 echo "or %g1, %lo(ab + 12), %g1" > conftest1.s
1597                 if $gcc_cv_as $gcc_cv_as_flags64 -o conftest.o conftest.s \
1598                         > /dev/null 2>&1 &&
1599                    $gcc_cv_as $gcc_cv_as_flags64 -o conftest1.o conftest1.s \
1600                         > /dev/null 2>&1; then
1601                     if cmp conftest.o conftest1.o > /dev/null 2>&1; then
1602                         gcc_cv_as_offsetable_lo10=no
1603                     else
1604                         gcc_cv_as_offsetable_lo10=yes
1605                     fi
1606                 else
1607                     gcc_cv_as_offsetable_lo10=no
1608                 fi
1609                 rm -f conftest.s conftest.o conftest1.s conftest1.o
1610             fi
1611         ])
1612         if test "x$gcc_cv_as_offsetable_lo10" = xyes; then
1613             AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
1614                 [Define if your assembler supports offsetable %lo().])
1615         fi
1616     fi
1617
1618     ;;
1619
1620 changequote(,)dnl
1621   i[34567]86-*-* | x86_64-*-*)
1622 changequote([,])dnl
1623     AC_MSG_CHECKING(assembler instructions)
1624     gcc_cv_as_instructions=
1625     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x; then
1626       if test "$gcc_cv_gas_major_version" -eq 2 -a "$gcc_cv_gas_minor_version" -ge 9 -o "$gcc_cv_gas_major_version" -gt 2; then
1627         gcc_cv_as_instructions="filds fists"
1628       fi
1629     elif test x$gcc_cv_as != x; then
1630         set "filds fists" "filds mem; fists mem"
1631         while test $# -gt 0
1632         do
1633                 echo "$2" > conftest.s
1634                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1635                         gcc_cv_as_instructions=${gcc_cv_as_instructions}$1" "
1636                 fi
1637                 shift 2
1638         done
1639         rm -f conftest.s conftest.o
1640     fi
1641     if test x"$gcc_cv_as_instructions" != x; then
1642         AC_DEFINE_UNQUOTED(HAVE_GAS_`echo "$gcc_cv_as_instructions" | sed -e 's/ $//' | tr '[a-z ]' '[A-Z_]'`)
1643     fi
1644     AC_MSG_RESULT($gcc_cv_as_instructions)
1645
1646     AC_MSG_CHECKING(assembler GOTOFF in data directives)
1647     gcc_cv_as_gotoff_in_data=no
1648     if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x
1649     then
1650       if test "$gcc_cv_gas_major_version" -eq 2 \
1651          -a "$gcc_cv_gas_minor_version" -ge 11 \
1652          -o "$gcc_cv_gas_major_version" -gt 2; then
1653         gcc_cv_as_gotoff_in_data=yes
1654       fi
1655     elif test x$gcc_cv_as != x; then
1656         cat > conftest.s <<EOF
1657         .text
1658 .L0:
1659         nop
1660         .data
1661         .long .L0@GOTOFF
1662 EOF
1663         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
1664           gcc_cv_as_gotoff_in_data=yes
1665         fi
1666     fi
1667     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
1668       [`if test $gcc_cv_as_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
1669       [Define true if the assembler supports '.long foo@GOTOFF'.])
1670     AC_MSG_RESULT($gcc_cv_as_gotoff_in_data)
1671     ;;
1672 esac
1673
1674 AC_MSG_CHECKING(assembler dwarf2 debug_line support)
1675 gcc_cv_as_dwarf2_debug_line=no
1676 # ??? Not all targets support dwarf2 debug_line, even within a version
1677 # of gas.  Moreover, we need to emit a valid instruction to trigger any
1678 # info to the output file.  So, as supported targets are added to gas 2.11,
1679 # add some instruction here to (also) show we expect this might work.
1680 # ??? Once 2.11 is released, probably need to add first known working
1681 # version to the per-target configury.
1682 case "$target" in
1683   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* | x86_64*-*-*)
1684     insn="nop"
1685     ;;
1686   ia64*-*-*)
1687     insn="nop 0"
1688     ;;
1689   esac
1690 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1691 then
1692   if test "$gcc_cv_gas_major_version" -eq 2 \
1693         -a "$gcc_cv_gas_minor_version" -ge 11 \
1694         -o "$gcc_cv_gas_major_version" -gt 2 \
1695      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1696      && test x"$insn" != x ; then
1697     gcc_cv_as_dwarf2_debug_line="yes"
1698   fi
1699 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1700         echo '  .file 1 "conftest.s"' > conftest.s
1701         echo '  .loc 1 3 0' >> conftest.s
1702         echo "  $insn" >> conftest.s
1703         # ??? This fails with non-gnu grep.
1704         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
1705            && grep debug_line conftest.o > /dev/null 2>&1 ; then
1706                 # The .debug_line file table must be in the exact order that
1707                 # we specified the files, since these indices are also used
1708                 # by DW_AT_decl_file.  Approximate this test by testing if
1709                 # the assembler bitches if the same index is assigned twice.
1710                 echo '  .file 1 "foo.s"' > conftest.s
1711                 echo '  .file 1 "bar.s"' >> conftest.s
1712                 if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1
1713                 then
1714                   gcc_cv_as_dwarf2_debug_line="no"
1715                 else
1716                   gcc_cv_as_dwarf2_debug_line="yes"
1717                 fi
1718         fi
1719         rm -f conftest.s conftest.o conftest.nm1 conftest.nm2
1720 fi
1721 if test x"$gcc_cv_as_dwarf2_debug_line" = xyes; then
1722         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
1723 [Define if your assembler supports dwarf2 .file/.loc directives,
1724    and preserves file table indices exactly as given.])
1725 fi
1726 AC_MSG_RESULT($gcc_cv_as_dwarf2_debug_line)
1727
1728 AC_MSG_CHECKING(assembler --gdwarf2 support)
1729 gcc_cv_as_gdwarf2_flag=no
1730 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1731 then
1732   if test "$gcc_cv_gas_major_version" -eq 2 \
1733         -a "$gcc_cv_gas_minor_version" -ge 11 \
1734         -o "$gcc_cv_gas_major_version" -gt 2 \
1735      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1736      && test x"$insn" != x ; then
1737     gcc_cv_as_gdwarf2_debug_flag="yes"
1738   fi
1739 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1740         echo '' > conftest.s
1741         # ??? This fails with non-gnu grep.
1742         if $gcc_cv_as --gdwarf2 -o conftest.o conftest.s > /dev/null 2>&1
1743           then
1744           gcc_cv_as_gdwarf2_flag="yes"
1745         fi
1746         rm -f conftest.s conftest.o
1747 fi
1748 if test x"$gcc_cv_as_gdwarf2_flag" = xyes; then
1749         AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
1750 [Define if your assembler supports the --gdwarf2 option.])
1751 fi
1752 AC_MSG_RESULT($gcc_cv_as_gdwarf2_flag)
1753
1754 AC_MSG_CHECKING(assembler --gstabs support)
1755 gcc_cv_as_gstabs_flag=no
1756 if test x$gcc_cv_gas_major_version != x -a x$gcc_cv_gas_minor_version != x;
1757 then
1758   if test "$gcc_cv_gas_major_version" -eq 2 \
1759         -a "$gcc_cv_gas_minor_version" -ge 11 \
1760         -o "$gcc_cv_gas_major_version" -gt 2 \
1761      && grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1762      && test x"$insn" != x ; then
1763     gcc_cv_as_gstabs_debug_flag="yes"
1764   fi
1765 elif test x$gcc_cv_as != x -a x"$insn" != x ; then
1766         echo '' > conftest.s
1767         # ??? This fails with non-gnu grep.
1768         if $gcc_cv_as --gstabs -o conftest.o conftest.s > /dev/null 2>&1 ; then
1769           gcc_cv_as_gstabs_flag="yes"
1770         fi
1771         rm -f conftest.s conftest.o
1772 fi
1773 if test x"$gcc_cv_as_gstabs_flag" = xyes; then
1774         AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
1775 [Define if your assembler supports the --gstabs option.])
1776 fi
1777 AC_MSG_RESULT($gcc_cv_as_gstabs_flag)
1778
1779 if test "$prefix" != "/usr" && test "$prefix" != "/usr/local" ; then
1780   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include")
1781 fi
1782
1783 # Figure out what language subdirectories are present.
1784 # Look if the user specified --enable-languages="..."; if not, use
1785 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1786 # go away some day.
1787 # NB:  embedded tabs in this IF block -- do not untabify
1788 if test x"${enable_languages+set}" != xset; then
1789         if test x"${LANGUAGES+set}" = xset; then
1790                 enable_languages="${LANGUAGES}"
1791                 AC_MSG_WARN([setting LANGUAGES is deprecated, use --enable-languages instead])
1792
1793         else
1794                 enable_languages=all
1795         fi
1796 else
1797         if test x"${enable_languages}" = x ||
1798            test x"${enable_languages}" = xyes;
1799         then
1800                 AC_MSG_ERROR([--enable-languages needs at least one language argument])
1801         fi
1802 fi
1803 enable_languages=`echo "${enable_languages}" | sed -e 's/[[     ,]][[   ,]]*/,/g' -e 's/,$//'`
1804
1805 # First scan to see if an enabled language requires some other language.
1806 # We assume that a given config-lang.in will list all the language
1807 # front ends it requires, even if some are required indirectly.
1808 for lang in ${srcdir}/*/config-lang.in ..
1809 do
1810    case $lang in
1811     ..)
1812        ;;
1813     # The odd quoting in the next line works around
1814     # an apparent bug in bash 1.12 on linux.
1815 changequote(,)dnl
1816     ${srcdir}/[*]/config-lang.in)
1817        ;;
1818     *)
1819        lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^      ]*\).*$,\1,p' $lang`
1820        this_lang_requires=`sed -n -e 's,^lang_requires=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^lang_requires=\([^    ]*\).*$,\1,p' $lang`
1821        for other in $this_lang_requires
1822        do
1823           case ,${enable_languages}, in
1824            *,$other,*)
1825               ;;
1826            *,all,*)
1827               ;;
1828            *,$lang_alias,*)
1829               enable_languages="$enable_languages,$other"
1830               ;;
1831           esac
1832        done
1833        ;;
1834 changequote([,])dnl
1835    esac
1836 done
1837
1838 subdirs=
1839 for lang in ${srcdir}/*/config-lang.in ..
1840 do
1841         case $lang in
1842         ..) ;;
1843         # The odd quoting in the next line works around
1844         # an apparent bug in bash 1.12 on linux.
1845 changequote(,)dnl
1846         ${srcdir}/[*]/config-lang.in) ;;
1847         *)
1848           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
1849           this_lang_libs=`sed -n -e 's,^target_libs=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^target_libs=\([^         ]*\).*$,\1,p' $lang`
1850           build_by_default=`sed -n -e 's,^build_by_default=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^build_by_default=\([^     ]*\).*$,\1,p' $lang`
1851           if test "x$lang_alias" = x
1852           then
1853                 echo "$lang doesn't set \$language." 1>&2
1854                 exit 1
1855           fi
1856           case ${build_by_default},${enable_languages}, in
1857           *,$lang_alias,*) add_this_lang=yes ;;
1858           no,*) add_this_lang=no ;;
1859           *,all,*) add_this_lang=yes ;;
1860           *) add_this_lang=no ;;
1861           esac
1862           if test x"${add_this_lang}" = xyes; then
1863                 case $lang in
1864                     ${srcdir}/ada/config-lang.in)
1865                         if test x$have_gnat = xyes ; then
1866                                 subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1867                         fi
1868                         ;;
1869                     *)
1870                         subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
1871                         ;;
1872                 esac
1873           fi
1874           ;;
1875 changequote([,])dnl
1876         esac
1877 done
1878
1879 # Make gthr-default.h if we have a thread file.
1880 gthread_flags=
1881 if test $thread_file != single; then
1882     rm -f gthr-default.h
1883     echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1884     gthread_flags=-DHAVE_GTHR_DEFAULT
1885 fi
1886 AC_SUBST(gthread_flags)
1887
1888 # Find out what GC implementation we want, or may, use.
1889 AC_ARG_WITH(gc,
1890 [  --with-gc={simple,page} choose the garbage collection mechanism to use
1891                           with the compiler],
1892 [case "$withval" in
1893   simple | page)
1894     GGC=ggc-$withval
1895     ;;
1896   *)
1897     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
1898     ;;
1899 esac],
1900 [GGC=ggc-page])
1901 AC_SUBST(GGC)
1902 echo "Using $GGC for garbage collection."
1903
1904 # Use the system's zlib library.
1905 zlibdir=-L../zlib
1906 zlibinc="-I\$(srcdir)/../zlib"
1907 AC_ARG_WITH(system-zlib,
1908 [  --with-system-zlib      use installed libz],
1909 zlibdir=
1910 zlibinc=
1911 )
1912 AC_SUBST(zlibdir)
1913 AC_SUBST(zlibinc)
1914
1915 dnl Very limited version of automake's enable-maintainer-mode
1916
1917 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1918   dnl maintainer-mode is disabled by default
1919   AC_ARG_ENABLE(maintainer-mode,
1920 [  --enable-maintainer-mode
1921                           enable make rules and dependencies not useful
1922                           (and sometimes confusing) to the casual installer],
1923       maintainer_mode=$enableval,
1924       maintainer_mode=no)
1925
1926 AC_MSG_RESULT($maintainer_mode)
1927
1928 if test "$maintainer_mode" = "yes"; then
1929   MAINT=''
1930 else
1931   MAINT='#'
1932 fi
1933 AC_SUBST(MAINT)dnl
1934
1935 # With Setjmp/Longjmp based exception handling.
1936 AC_ARG_ENABLE(sjlj-exceptions,
1937 [  --enable-sjlj-exceptions
1938                           arrange to use setjmp/longjmp exception handling],
1939 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1940 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1941   [Define 0/1 to force the choice for exception handling model.])])
1942
1943 # Make empty files to contain the specs and options for each language.
1944 # Then add #include lines to for a compiler that has specs and/or options.
1945
1946 lang_specs_files=
1947 lang_options_files=
1948 lang_tree_files=
1949 rm -f specs.h options.h gencheck.h
1950 touch specs.h options.h gencheck.h
1951 for subdir in . $subdirs
1952 do
1953         if test -f $srcdir/$subdir/lang-specs.h; then
1954                 echo "#include \"$subdir/lang-specs.h\"" >>specs.h
1955                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
1956         fi
1957         if test -f $srcdir/$subdir/lang-options.h; then
1958                 echo "#include \"$subdir/lang-options.h\"" >>options.h
1959                 lang_options_files="$lang_options_files $srcdir/$subdir/lang-options.h"
1960         fi
1961         if test -f $srcdir/$subdir/$subdir-tree.def; then
1962                 echo "#include \"$subdir/$subdir-tree.def\"" >>gencheck.h
1963                 lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
1964         fi
1965 done
1966
1967 # These (without "all_") are set in each config-lang.in.
1968 # `language' must be a single word so is spelled singularly.
1969 all_languages=
1970 all_boot_languages=
1971 all_compilers=
1972 all_stagestuff=
1973 all_diff_excludes=
1974 all_outputs='Makefile intl/Makefile fixinc/Makefile gccbug mklibgcc'
1975 # List of language makefile fragments.
1976 all_lang_makefiles=
1977 all_headers=
1978 all_lib2funcs=
1979
1980 # Add the language fragments.
1981 # Languages are added via two mechanisms.  Some information must be
1982 # recorded in makefile variables, these are defined in config-lang.in.
1983 # We accumulate them and plug them into the main Makefile.
1984 # The other mechanism is a set of hooks for each of the main targets
1985 # like `clean', `install', etc.
1986
1987 language_fragments="Make-lang"
1988 language_hooks="Make-hooks"
1989
1990 for s in .. $subdirs
1991 do
1992         if test $s != ".."
1993         then
1994                 language=
1995                 boot_language=
1996                 compilers=
1997                 stagestuff=
1998                 diff_excludes=
1999                 headers=
2000                 outputs=
2001                 lib2funcs=
2002                 . ${srcdir}/$s/config-lang.in
2003                 if test "x$language" = x
2004                 then
2005                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
2006                         exit 1
2007                 fi
2008                 all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Make-lang.in"
2009                 if test -f ${srcdir}/$s/Makefile.in
2010                 then all_lang_makefiles="$all_lang_makefiles ${srcdir}/$s/Makefile.in"
2011                 fi
2012                 all_languages="$all_languages $language"
2013                 if test "x$boot_language" = xyes
2014                 then
2015                         all_boot_languages="$all_boot_languages $language"
2016                 fi
2017                 all_compilers="$all_compilers $compilers"
2018                 all_stagestuff="$all_stagestuff $stagestuff"
2019                 all_diff_excludes="$all_diff_excludes $diff_excludes"
2020                 all_headers="$all_headers $headers"
2021                 all_outputs="$all_outputs $outputs"
2022                 all_lib2funcs="$all_lib2funcs $lib2funcs"
2023         fi
2024 done
2025
2026 check_languages=
2027 for language in .. $all_languages
2028 do
2029         if test $language != ".."
2030         then
2031                 check_languages="$check_languages check-$language"
2032         fi
2033 done
2034
2035 # Since we can't use `::' targets, we link each language in
2036 # with a set of hooks, reached indirectly via lang.${target}.
2037
2038 rm -f Make-hooks
2039 touch Make-hooks
2040 target_list="all.build all.cross start.encap rest.encap \
2041         info dvi \
2042         install-normal install-common install-info install-man \
2043         uninstall \
2044         mostlyclean clean distclean extraclean maintainer-clean \
2045         stage1 stage2 stage3 stage4"
2046 for t in $target_list
2047 do
2048         x=
2049         for lang in .. $all_languages
2050         do
2051                 if test $lang != ".."; then
2052                         x="$x $lang.$t"
2053                 fi
2054         done
2055         echo "lang.$t: $x" >> Make-hooks
2056 done
2057
2058 # Create .gdbinit.
2059
2060 echo "dir ." > .gdbinit
2061 echo "dir ${srcdir}" >> .gdbinit
2062 if test x$gdb_needs_out_file_path = xyes
2063 then
2064         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
2065 fi
2066 if test "x$subdirs" != x; then
2067         for s in $subdirs
2068         do
2069                 echo "dir ${srcdir}/$s" >> .gdbinit
2070         done
2071 fi
2072 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
2073
2074 # Define variables host_canonical and build_canonical
2075 # because some Cygnus local changes in the Makefile depend on them.
2076 build_canonical=${build}
2077 host_canonical=${host}
2078 target_subdir=
2079 if test "${host}" != "${target}" ; then
2080     target_subdir=${target_alias}/
2081 fi
2082 AC_SUBST(build_canonical)
2083 AC_SUBST(host_canonical)
2084 AC_SUBST(target_subdir)
2085
2086 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
2087 # absolute path for gcc_tooldir based on inserting the number of up-directory
2088 # movements required to get from $(exec_prefix) to $(prefix) into the basic
2089 # $(libsubdir)/@(unlibsubdir) based path.
2090 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
2091 # make and thus we'd get different behavior depending on where we built the
2092 # sources.
2093 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
2094     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_alias)'
2095 else
2096 changequote(<<, >>)dnl
2097 # An explanation of the sed strings:
2098 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
2099 #  -e 's|/$||'            match a trailing forward slash and eliminates it
2100 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
2101 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
2102 #
2103 # (*) Note this pattern overwrites the first character of the string
2104 # with a forward slash if one is not already present.  This is not a
2105 # problem because the exact names of the sub-directories concerned is
2106 # unimportant, just the number of them matters.
2107 #
2108 # The practical upshot of these patterns is like this:
2109 #
2110 #  prefix     exec_prefix        result
2111 #  ------     -----------        ------
2112 #   /foo        /foo/bar          ../
2113 #   /foo/       /foo/bar          ../
2114 #   /foo        /foo/bar/         ../
2115 #   /foo/       /foo/bar/         ../
2116 #   /foo        /foo/bar/ugg      ../../
2117 #
2118     dollar='$$'
2119     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_alias)"
2120 changequote([, ])dnl
2121 fi
2122 AC_SUBST(gcc_tooldir)
2123 AC_SUBST(dollar)
2124
2125 # Find a directory in which to install a shared libgcc.
2126
2127 AC_ARG_ENABLE(version-specific-runtime-libs,
2128 [  --enable-version-specific-runtime-libs
2129                           specify that runtime libraries should be
2130                           installed in a compiler-specific directory])
2131
2132 AC_ARG_WITH(slibdir,
2133 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
2134 slibdir="$with_slibdir",
2135 if test "${enable_version_specific_runtime_libs+set}" = set; then
2136   slibdir='$(libsubdir)'
2137 elif test "$host" != "$target"; then
2138   slibdir='$(build_tooldir)/lib'
2139 else
2140   slibdir='$(libdir)'
2141 fi)
2142 AC_SUBST(slibdir)
2143
2144 # Nothing to do for FLOAT_H, float_format already handled.
2145 objdir=`pwd`
2146 AC_SUBST(objdir)
2147
2148 # Process the language and host/target makefile fragments.
2149 ${CONFIG_SHELL-/bin/sh} $srcdir/configure.frag $srcdir "$subdirs" "$dep_host_xmake_file" "$dep_tmake_file"
2150
2151 # Substitute configuration variables
2152 AC_SUBST(subdirs)
2153 AC_SUBST(all_boot_languages)
2154 AC_SUBST(all_compilers)
2155 AC_SUBST(all_diff_excludes)
2156 AC_SUBST(all_headers)
2157 AC_SUBST(all_lang_makefiles)
2158 AC_SUBST(all_languages)
2159 AC_SUBST(all_lib2funcs)
2160 AC_SUBST(all_stagestuff)
2161 AC_SUBST(build_exeext)
2162 AC_SUBST(build_install_headers_dir)
2163 AC_SUBST(build_xm_file_list)
2164 AC_SUBST(build_xm_file)
2165 AC_SUBST(build_xm_defines)
2166 AC_SUBST(check_languages)
2167 AC_SUBST(cc_set_by_configure)
2168 AC_SUBST(quoted_cc_set_by_configure)
2169 AC_SUBST(cpp_install_dir)
2170 AC_SUBST(dep_host_xmake_file)
2171 AC_SUBST(dep_tmake_file)
2172 AC_SUBST(extra_c_flags)
2173 AC_SUBST(extra_headers_list)
2174 AC_SUBST(extra_objs)
2175 AC_SUBST(extra_parts)
2176 AC_SUBST(extra_passes)
2177 AC_SUBST(extra_programs)
2178 AC_SUBST(float_h_file)
2179 AC_SUBST(gcc_config_arguments)
2180 AC_SUBST(gcc_gxx_include_dir)
2181 AC_SUBST(libstdcxx_incdir)
2182 AC_SUBST(gcc_version)
2183 AC_SUBST(gcc_version_full)
2184 AC_SUBST(gcc_version_trigger)
2185 AC_SUBST(host_exeext)
2186 AC_SUBST(host_extra_gcc_objs)
2187 AC_SUBST(host_xm_file_list)
2188 AC_SUBST(host_xm_file)
2189 AC_SUBST(host_xm_defines)
2190 AC_SUBST(install)
2191 AC_SUBST(lang_options_files)
2192 AC_SUBST(lang_specs_files)
2193 AC_SUBST(lang_tree_files)
2194 AC_SUBST(local_prefix)
2195 AC_SUBST(md_file)
2196 AC_SUBST(objc_boehm_gc)
2197 AC_SUBST(out_file)
2198 AC_SUBST(out_object_file)
2199 AC_SUBST(stage_prefix_set_by_configure)
2200 AC_SUBST(symbolic_link)
2201 AC_SUBST(thread_file)
2202 AC_SUBST(tm_file_list)
2203 AC_SUBST(tm_file)
2204 AC_SUBST(tm_p_file_list)
2205 AC_SUBST(tm_p_file)
2206 AC_SUBST(xm_file)
2207 AC_SUBST(xm_defines)
2208 AC_SUBST(c_target_objs)
2209 AC_SUBST(cxx_target_objs)
2210 AC_SUBST(target_cpu_default)
2211
2212 AC_SUBST_FILE(target_overrides)
2213 AC_SUBST_FILE(host_overrides)
2214 AC_SUBST(cross_defines)
2215 AC_SUBST_FILE(cross_overrides)
2216 AC_SUBST_FILE(build_overrides)
2217 AC_SUBST_FILE(language_fragments)
2218 AC_SUBST_FILE(language_hooks)
2219
2220 # Echo that links are built
2221 if test x$host = x$target
2222 then
2223         str1="native "
2224 else
2225         str1="cross-"
2226         str2=" from $host"
2227 fi
2228
2229 if test x$host != x$build
2230 then
2231         str3=" on a $build system"
2232 fi
2233
2234 if test "x$str2" != x || test "x$str3" != x
2235 then
2236         str4=
2237 fi
2238
2239 echo "Links are now set up to build a ${str1}compiler for ${target}$str4" 1>&2
2240
2241 if test "x$str2" != x || test "x$str3" != x
2242 then
2243         echo " ${str2}${str3}." 1>&2
2244 fi
2245
2246 # Truncate the target if necessary
2247 if test x$host_truncate_target != x; then
2248         target=`echo $target | sed -e 's/\(..............\).*/\1/'`
2249 fi
2250
2251 # Configure the subdirectories
2252 # AC_CONFIG_SUBDIRS($subdirs)
2253
2254 # Create the Makefile
2255 # and configure language subdirectories
2256 AC_OUTPUT($all_outputs,
2257 [
2258 case x$CONFIG_HEADERS in
2259 xauto-host.h:config.in)
2260 echo > cstamp-h ;;
2261 esac
2262 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
2263 # bootstrapping and the installation procedure can still use
2264 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
2265 # FLAGS_TO_PASS has been modified to solve the problem there.
2266 # This is virtually a duplicate of what happens in configure.lang; we do
2267 # an extra check to make sure this only happens if ln -s can be used.
2268 if test "$symbolic_link" = "ln -s"; then
2269  for d in .. ${subdirs} fixinc ; do
2270    if test $d != ..; then
2271         STARTDIR=`pwd`
2272         cd $d
2273         for t in stage1 stage2 stage3 stage4 include
2274         do
2275                 rm -f $t
2276                 $symbolic_link ../$t $t 2>/dev/null
2277         done
2278         cd $STARTDIR
2279    fi
2280  done
2281 else true ; fi
2282 # Avoid having to add intl to our include paths.
2283 if test -f intl/libintl.h; then
2284   echo creating libintl.h
2285   echo '#include "intl/libintl.h"' >libintl.h
2286 fi
2287 ],
2288 [
2289 host='${host}'
2290 build='${build}'
2291 target='${target}'
2292 target_alias='${target_alias}'
2293 srcdir='${srcdir}'
2294 subdirs='${subdirs}'
2295 symbolic_link='${symbolic_link}'
2296 program_transform_set='${program_transform_set}'
2297 program_transform_name='${program_transform_name}'
2298 dep_host_xmake_file='${dep_host_xmake_file}'
2299 host_xmake_file='${host_xmake_file}'
2300 dep_tmake_file='${dep_tmake_file}'
2301 tmake_file='${tmake_file}'
2302 thread_file='${thread_file}'
2303 gcc_config_arguments='${gcc_config_arguments}'
2304 gcc_version='${gcc_version}'
2305 gcc_version_full='${gcc_version_full}'
2306 gcc_version_trigger='${gcc_version_trigger}'
2307 local_prefix='${local_prefix}'
2308 build_install_headers_dir='${build_install_headers_dir}'
2309 build_exeext='${build_exeext}'
2310 host_exeext='${host_exeext}'
2311 out_file='${out_file}'
2312 gdb_needs_out_file_path='${gdb_needs_out_file_path}'
2313 SET_MAKE='${SET_MAKE}'
2314 target_list='${target_list}'
2315 target_overrides='${target_overrides}'
2316 host_overrides='${host_overrides}'
2317 cross_defines='${cross_defines}'
2318 cross_overrides='${cross_overrides}'
2319 build_overrides='${build_overrides}'
2320 cpp_install_dir='${cpp_install_dir}'
2321 ])