gcc/opt-functions.awk

   1 #  Copyright (C) 2003, 2004, 2007 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 3, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 # Some common subroutines for use by opt[ch]-gen.awk.
  20
  21 # Return nonzero if FLAGS contains a flag matching REGEX.
  22 function flag_set_p(regex, flags)
  23 {
  24         return (" " flags " ") ~ (" " regex " ")
  25 }
  26
  27 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  28 # otherwise return the empty string.
  29 function test_flag(regex, flags, string)
  30 {
  31         if (flag_set_p(regex, flags))
  32                 return string
  33         return ""
  34 }
  35
  36 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  37 # of the argument.  Return the empty string otherwise.
  38 function opt_args(name, flags)
  39 {
  40         flags = " " flags
  41         if (flags !~ " " name "\\(")
  42                 return ""
  43         sub(".* " name "\\(", "", flags)
  44         sub("\\).*", "", flags)
  45
  46         return flags
  47 }
  48
  49 # Return the Nth comma-separated element of S.  Return the empty string
  50 # if S does not contain N elements.
  51 function nth_arg(n, s)
  52 {
  53         while (n-- > 0) {
  54                 if (s !~ ",")
  55                         return ""
  56                 sub("[^,]*, *", "", s)
  57         }
  58         sub(",.*", "", s)
  59         return s
  60 }
  61
  62 # Return a bitmask of CL_* values for option flags FLAGS.
  63 function switch_flags (flags)
  64 {
  65         result = "0"
  66         for (j = 0; j < n_langs; j++) {
  67                 regex = langs[j]
  68                 gsub ( "\\+", "\\+", regex )
  69                 result = result test_flag(regex, flags, " | " macros[j])
  70         }
  71         result = result \
  72           test_flag("Common", flags, " | CL_COMMON") \
  73           test_flag("Target", flags, " | CL_TARGET") \
  74           test_flag("Joined", flags, " | CL_JOINED") \
  75           test_flag("JoinedOrMissing", flags, " | CL_JOINED | CL_MISSING_OK") \
  76           test_flag("Separate", flags, " | CL_SEPARATE") \
  77           test_flag("RejectNegative", flags, " | CL_REJECT_NEGATIVE") \
  78           test_flag("UInteger", flags, " | CL_UINTEGER") \
  79           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
  80           test_flag("Warning", flags,  " | CL_WARNING") \
  81           test_flag("Optimization", flags,  " | CL_OPTIMIZATION") \
  82           test_flag("Report", flags, " | CL_REPORT")
  83         sub( "^0 \\| ", "", result )
  84         return result
  85 }
  86
  87 # If FLAGS includes a Var flag, return the name of the variable it specifies.
  88 # Return the empty string otherwise.
  89 function var_name(flags)
  90 {
  91         return nth_arg(0, opt_args("Var", flags))
  92 }
  93
  94 # Return true if the option described by FLAGS has a globally-visible state.
  95 function global_state_p(flags)
  96 {
  97         return (var_name(flags) != "" \
  98                 || opt_args("Mask", flags) != "" \
  99                 || opt_args("InverseMask", flags) != "")
 100 }
 101
 102 # Return true if the option described by FLAGS must have some state
 103 # associated with it.
 104 function needs_state_p(flags)
 105 {
 106         return flag_set_p("Target", flags)
 107 }
 108
 109 # If FLAGS describes an option that needs a static state variable,
 110 # return the name of that variable, otherwise return "".  NAME is
 111 # the name of the option.
 112 function static_var(name, flags)
 113 {
 114         if (global_state_p(flags) || !needs_state_p(flags))
 115                 return ""
 116         gsub ("[^A-Za-z0-9]", "_", name)
 117         return "VAR_" name
 118 }
 119
 120 # Return the type of variable that should be associated with the given flags.
 121 function var_type(flags)
 122 {
 123         if (!flag_set_p("Joined.*", flags))
 124                 return "int "
 125         else if (flag_set_p("UInteger", flags))
 126                 return "int "
 127         else
 128                 return "const char *"
 129 }
 130
 131 # Return the type of variable that should be associated with the given flags
 132 # for use within a structure.  Simple variables are changed to unsigned char
 133 # type instead of int to save space.
 134 function var_type_struct(flags)
 135 {
 136         if (flag_set_p("UInteger", flags))
 137                 return "int "
 138         else if (!flag_set_p("Joined.*", flags)) {
 139                 if (flag_set_p(".*Mask.*", flags))
 140                         return "int "
 141                 else
 142                         return "unsigned char "
 143         }
 144         else
 145                 return "const char *"
 146 }
 147
 148 # Given that an option has flags FLAGS, return an initializer for the
 149 # "var_cond" and "var_value" fields of its cl_options[] entry.
 150 function var_set(flags)
 151 {
 152         s = nth_arg(1, opt_args("Var", flags))
 153         if (s != "")
 154                 return "CLVC_EQUAL, " s
 155         s = opt_args("Mask", flags);
 156         if (s != "") {
 157                 vn = var_name(flags);
 158                 if (vn)
 159                         return "CLVC_BIT_SET, OPTION_MASK_" s
 160                 else
 161                         return "CLVC_BIT_SET, MASK_" s
 162         }
 163         s = nth_arg(0, opt_args("InverseMask", flags));
 164         if (s != "") {
 165                 vn = var_name(flags);
 166                 if (vn)
 167                         return "CLVC_BIT_CLEAR, OPTION_MASK_" s
 168                 else
 169                         return "CLVC_BIT_CLEAR, MASK_" s
 170         }
 171         if (var_type(flags) == "const char *")
 172                 return "CLVC_STRING, 0"
 173         return "CLVC_BOOLEAN, 0"
 174 }
 175
 176 # Given that an option called NAME has flags FLAGS, return an initializer
 177 # for the "flag_var" field of its cl_options[] entry.
 178 function var_ref(name, flags)
 179 {
 180         name = var_name(flags) static_var(name, flags)
 181         if (name != "")
 182                 return "&" name
 183         if (opt_args("Mask", flags) != "")
 184                 return "&target_flags"
 185         if (opt_args("InverseMask", flags) != "")
 186                 return "&target_flags"
 187         return "0"
 188 }