gcc/testsuite/g++.dg/compat/struct-layout-1.exp

   1 # Copyright (C) 2002-2015 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16 #
  17 # This file was written by Jakub Jelinek, <jakub@redhat.com>
  18 # Based on compat.exp writte by Janis Johnson, <janis187@us.ibm.com>
  19
  20
  21 # Test interoperability of two compilers that follow the same ABI.
  22 #
  23 # Break simple tests into two pieces and see that they work when linked
  24 # together.  If an alternate compiler is specified then the two main
  25 # pieces of each test are compiled with different compilers.  The
  26 # alternate compiler must be installed, and is specified by defining
  27 # ALT_CXX_UNDER_TEST in the environment.
  28 #
  29 # struct-layout-1 are generated structure layout interoperability tests,
  30 # so a generator first needs to be compiled on host, run there and the
  31 # generated tests then compiled on build and executed on target.
  32
  33 if $tracelevel then {
  34     strace $tracelevel
  35 }
  36
  37 global GXX_UNDER_TEST
  38 global ld_library_path
  39
  40 # Load procedures from common libraries.
  41 load_lib standard.exp
  42 load_lib g++.exp
  43 load_lib target-libpath.exp
  44
  45 #
  46 # compat-use-alt-compiler -- make the alternate compiler the default
  47 #
  48 proc compat-use-alt-compiler { } {
  49     global GXX_UNDER_TEST ALT_CXX_UNDER_TEST
  50     global CXXFLAGS
  51     global ALWAYS_CXXFLAGS
  52     global ld_library_path alt_ld_library_path
  53     global same_alt
  54
  55     # We don't need to do this if the alternate compiler is actually
  56     # the same as the compiler under test.
  57     if { $same_alt == 0 } then {
  58         set GXX_UNDER_TEST $ALT_CXX_UNDER_TEST
  59         set CXXFLAGS ""
  60         set ALWAYS_CXXFLAGS ""
  61         set ld_library_path $alt_ld_library_path
  62         set_ld_library_path_env_vars
  63         restore_gcc_exec_prefix_env_var
  64     }
  65 }
  66
  67 #
  68 # compat-use-tst-compiler -- make compiler under test the default
  69 #
  70 proc compat-use-tst-compiler { } {
  71     global GXX_UNDER_TEST save_gxx_under_test
  72     global CXXFLAGS save_cxxflags
  73     global ALWAYS_CXXFLAGS save_always_cxxflags
  74     global ld_library_path save_ld_library_path
  75     global same_alt
  76
  77     # We don't need to do this if the alternate compiler is actually
  78     # the same as the compiler under test.
  79
  80     if { $same_alt == 0 } then {
  81         set GXX_UNDER_TEST $save_gxx_under_test
  82         set CXXFLAGS $save_cxxflags
  83         set ALWAYS_CXXFLAGS $save_always_cxxflags
  84         set ld_library_path $save_ld_library_path
  85         set_ld_library_path_env_vars
  86     }
  87 }
  88
  89 # Load the language-independent compabibility support procedures.
  90 # This must be done after the compat-use-*-compiler definitions.
  91 load_lib compat.exp
  92
  93 # Provide the g++-dg-prune routine (gcc-dp.exp is loaded by compat.exp)
  94 load_lib g++-dg.exp
  95
  96 g++_init
  97
  98 # Save variables for the C++ compiler under test, which each test will
  99 # change a couple of times.  This must be done after calling g++-init.
 100 set save_gxx_under_test $GXX_UNDER_TEST
 101 set save_cxxflags $CXXFLAGS
 102 set save_always_cxxflags $ALWAYS_CXXFLAGS
 103 set save_ld_library_path $ld_library_path
 104
 105 # Define an identifier for use with this suite to avoid name conflicts
 106 # with other compat tests running at the same time.
 107 set sid "cp_compat"
 108
 109 # Find out whether there is an alternate compiler to test.  If the
 110 # variable is defined but is set to "same", that means we use the same
 111 # compiler twice, which is meaningful if the two parts of COMPAT_OPTIONS
 112 # are different.
 113 set use_alt 0
 114 set same_alt 0
 115 set alt_ld_library_path "."
 116 if [info exists ALT_CXX_UNDER_TEST] then {
 117     set use_alt 1
 118     if [string match "same" $ALT_CXX_UNDER_TEST] then {
 119         set same_alt 1
 120     } else {
 121         if [info exists ALT_LD_LIBRARY_PATH] then {
 122             append alt_ld_library_path ":${ALT_LD_LIBRARY_PATH}"
 123         }
 124     }
 125 }
 126
 127 set tstobjdir "$tmpdir/g++.dg-struct-layout-1"
 128 set generator "$tmpdir/g++.dg-struct-layout-1_generate.exe"
 129
 130 set generator_src "$srcdir/$subdir/struct-layout-1_generate.c"
 131 set generator_src "$generator_src $srcdir/$subdir/../../gcc.dg/compat/generate-random.c"
 132 set generator_src "$generator_src $srcdir/$subdir/../../gcc.dg/compat/generate-random_r.c"
 133 set generator_cmd "-o $generator $generator_src"
 134
 135 # Temporarily switch to the environment of the host compiler.
 136 restore_ld_library_path_env_vars
 137 set status [remote_exec build "$HOSTCC $HOSTCFLAGS $generator_cmd"]
 138 set status [lindex $status 0]
 139 set_ld_library_path_env_vars
 140 if { $status == 0 } then {
 141     file delete -force $tstobjdir
 142     file mkdir $tstobjdir
 143     set generator_args "-s $srcdir/$subdir -d $tstobjdir"
 144     if [info exists env(RUN_ALL_COMPAT_TESTS) ] then {
 145         set generator_args "$generator_args -n 15000"
 146     }
 147     if [check_effective_target_short_enums] then {
 148         set generator_args "-e $generator_args"
 149     }
 150     set status [remote_exec host "$generator $generator_args"]
 151     set status [lindex $status 0]
 152     if { $status == 0 } then {
 153         foreach src [lsort [find $tstobjdir *_main.C]] {
 154             # If we're only testing specific files and this isn't one
 155             # of them, skip it.
 156             if ![runtest_file_p $runtests $src] then {
 157                 continue
 158             }
 159
 160             compat-execute $src $sid $use_alt
 161         }
 162     } else {
 163         warning "Could not execute g++.dg/compat/struct-layout-1 generator"
 164     }
 165 } else {
 166     warning "Could not compile g++.dg/compat/struct-layout-1 generator"
 167 }
 168
 169 # Restore the original compiler under test.
 170 compat-use-tst-compiler