gcc/testsuite/lib/prune.exp

   1 #   Copyright (C) 1997-2021 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with GCC; see the file COPYING3.  If not see
  15 # <http://www.gnu.org/licenses/>.
  16
  17 # Prune messages from gcc that aren't useful.
  18
  19 load_lib multiline.exp
  20
  21 # Add options to TEST_ALWAYS_FLAGS so that diagnostics have the expected output
  22 # format.  Note: You should not normally need to add more options here.  If you
  23 # have made a change to the default diagnostic output format and are wanting to
  24 # undo that in the testsuite here, then please update the handling of
  25 # -fdiagnostics-plain-output in opts-common.c instead.
  26
  27 if ![info exists TEST_ALWAYS_FLAGS] {
  28     set TEST_ALWAYS_FLAGS ""
  29 }
  30 set TEST_ALWAYS_FLAGS "-fdiagnostics-plain-output $TEST_ALWAYS_FLAGS"
  31
  32 proc prune_gcc_output { text } {
  33     global srcdir
  34
  35     #send_user "Before:$text\n"
  36
  37     # Handle any freeform regexps.
  38     set text [handle-dg-regexps $text]
  39
  40     regsub -all "(^|\n)(\[^\n\]*: \[iI\]|I)n ((static member |lambda )?function|member|method|(copy )?constructor|destructor|instantiation|substitution|program|subroutine|block-data)\[^\n\]*" $text "" text
  41     regsub -all "(^|\n)\[^\n\]*(: )?At (top level|global scope):\[^\n\]*" $text "" text
  42     regsub -all "(^|\n)\[^\n\]*:   (recursively )?required \[^\n\]*" $text "" text
  43     regsub -all "(^|\n)\[^\n\]*:   . skipping \[0-9\]* instantiation contexts \[^\n\]*" $text "" text
  44     regsub -all "(^|\n)\[^\n\]*:   in .constexpr. expansion \[^\n\]*" $text "" text
  45     regsub -all "(^|\n)\[^\n\]*:   in requirements \[^\n\]*" $text "" text
  46     regsub -all "(^|\n)    inlined from \[^\n\]*" $text "" text
  47     regsub -all "(^|\n)\[^\n\]*: error: ld returned \[^\n\]*" $text "" text
  48     regsub -all "(^|\n)\[^\n\]*: re(compiling|linking)\[^\n\]*" $text "" text
  49     regsub -all "(^|\n)Please submit.*instructions\[^\n\]*" $text "" text
  50     regsub -all "(^|\n)\[0-9\]\[0-9\]* errors\." $text "" text
  51
  52     # Diagnostic inclusion stack
  53     regsub -all "(^|\n)(In file)?\[ \]+included from \[^\n\]*" $text "" text
  54     regsub -all "(^|\n)\[ \]+from \[^\n\]*" $text "" text
  55     regsub -all "(^|\n)(In|of) module( \[^\n \]*,)? imported at \[^\n\]*" $text "" text
  56
  57     # Ignore informational notes.
  58     regsub -all "(^|\n)\[^\n\]*: note: \[^\n\]*" $text "" text
  59
  60     # Ignore harmless -fpic warnings.
  61     regsub -all "(^|\n)\[^\n\]*: warning: -f(pic|PIC) ignored for target\[^\n\]*" $text "" text
  62     regsub -all "(^|\n)\[^\n\]*: warning: -f(pic|PIC)( and -fpic are| is)? not supported\[^\n\]*" $text "" text
  63
  64     # Ignore errata warning from IA64 assembler.
  65     regsub -all "(^|\n)\[^\n\]*: Additional NOP may be necessary to workaround Itanium processor A/B step errata" $text "" text
  66     regsub -all "(^|\n)\[^\n*\]*: Assembler messages:\[^\n\]*" $text "" text
  67
  68     # Ignore harmless VTA note.
  69     regsub -all "(^|\n)\[^\n\]*: note: variable tracking size limit exceeded with -fvar-tracking-assignments, retrying without\[^\n\]*" $text "" text
  70
  71     # It would be nice to avoid passing anything to gcc that would cause it to
  72     # issue these messages (since ignoring them seems like a hack on our part),
  73     # but that's too difficult in the general case.  For example, sometimes
  74     # you need to use -B to point gcc at crt0.o, but there are some targets
  75     # that don't have crt0.o.
  76     regsub -all "(^|\n)\[^\n\]*file path prefix \[^\n\]* never used" $text "" text
  77     regsub -all "(^|\n)\[^\n\]*linker input file unused since linking not done" $text "" text
  78
  79     # Ignore harmless warnings from Xcode 3.2.x.
  80     regsub -all "(^|\n)\[^\n\]*ld: warning: can't add line info to anonymous symbol\[^\n\]*" $text "" text
  81     regsub -all "(^|\n)\[^\n\]*warning: DWARFDebugInfoEntry::AppendDependants\[^\n\]*AT_\[^\n\]*FORM_ref4\[^\n\]*" $text "" text
  82     regsub -all "(^|\n)\[^\n\]*warning:\[^\n\]*TAG_variable:  AT_location\[^\n\]*didn't have valid function low pc\[^\n\]*" $text "" text
  83
  84     # Ignore harmless warnings from Xcode 4.0.
  85     regsub -all "(^|\n)\[^\n\]*ld: warning: could not create compact unwind for\[^\n\]*" $text "" text
  86
  87     # If dg-enable-nn-line-numbers was provided, then obscure source-margin
  88     # line numbers by converting them to "NN" form.
  89     set text [maybe-handle-nn-line-numbers $text]
  90
  91     # Call into multiline.exp to handle any multiline output directives.
  92     set text [handle-multiline-outputs $text]
  93
  94     #send_user "After:$text\n"
  95
  96     return $text
  97 }
  98
  99 # escape metacharacters in literal string, so it can be used in regex
 100
 101 proc escape_regex_chars { line } {
 102     return [string map {"^" "\\^"
 103                         "$" "\\$"
 104                         "(" "\\("
 105                         ")" "\\)"
 106                         "[" "\\["
 107                         "]" "\\]"
 108                         "{" "\\{"
 109                         "}" "\\}"
 110                         "." "\\."
 111                         "\\" "\\\\"
 112                         "?" "\\?"
 113                         "+" "\\+"
 114                         "*" "\\*"
 115                         "|" "\\|"} $line]
 116 }
 117
 118 proc prune_file_path { text } {
 119     global srcdir
 120
 121     set safedir [escape_regex_chars $srcdir]
 122     regsub -all "$safedir\/" $text "" text
 123
 124     # Truncate absolute file path into relative path.
 125     set topdir "[file dirname [file dirname [file dirname $safedir]]]"
 126     regsub -all "$topdir\/" $text "" text
 127
 128     return $text
 129 }
 130
 131 # Prune internal compiler error messages, including the "Please submit..."
 132 # footnote.
 133
 134 proc prune_ices { text } {
 135   regsub -all "(^|\n)\[^\n\]*: internal compiler error:.*\nSee \[^\n\]*" $text "" text
 136   regsub -all "(^|\n|')*Internal compiler error:.*\nSee \[^\n\]*" $text "" text
 137   return $text
 138 }
 139
 140 # Provide a definition of this if missing (delete after next dejagnu release).
 141
 142 if { [info procs prune_warnings] == "" } then {
 143     proc prune_warnings { text } {
 144         return $text
 145     }
 146 }