libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/toolexeclibdir.m4)
   6 sinclude(../config/acx.m4)
   7 sinclude(../config/no-executables.m4)
   8 sinclude(../config/lib-ld.m4)
   9 sinclude(../config/override.m4)
  10 sinclude(../config/picflag.m4)
  11 sinclude(../config/dfp.m4)
  12 sinclude(../config/unwind_ipinfo.m4)
  13 sinclude(../config/gthr.m4)
  14 sinclude(../config/sjlj.m4)
  15 sinclude(../config/cet.m4)
  16
  17 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  18 AC_CONFIG_SRCDIR([static-object.mk])
  19
  20 # The libgcc should not depend on any header files
  21 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  22   [m4_divert_text([DEFAULTS],
  23     [ac_includes_default='/* none */'])])
  24
  25 AC_ARG_WITH(target-subdir,
  26 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  27 AC_ARG_WITH(cross-host,
  28 [  --with-cross-host=HOST           Configuring with a cross compiler])
  29 AC_ARG_WITH(ld,
  30 [  --with-ld               arrange to use the specified ld (full pathname)])
  31
  32 if test "${srcdir}" = "."; then
  33   if test -n "${with_build_subdir}"; then
  34     libgcc_topdir="${srcdir}/../.."
  35     with_target_subdir=
  36   elif test -z "${with_target_subdir}"; then
  37     libgcc_topdir="${srcdir}/.."
  38   else
  39     if test "${with_target_subdir}" != "."; then
  40       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  41     else
  42       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  43     fi
  44   fi
  45 else
  46   libgcc_topdir="${srcdir}/.."
  47 fi
  48 AC_SUBST(libgcc_topdir)
  49 AC_CONFIG_AUX_DIR($libgcc_topdir)
  50 AC_CONFIG_HEADER(auto-target.h:config.in)
  51
  52 AC_ARG_ENABLE(shared,
  53 [  --disable-shared        don't provide a shared libgcc],
  54 [
  55   case $enable_shared in
  56   yes | no) ;;
  57   *)
  58     enable_shared=no
  59     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  60     for pkg in $enableval; do
  61       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  62         enable_shared=yes
  63       fi
  64     done
  65     IFS="$ac_save_ifs"
  66     ;;
  67   esac
  68 ], [enable_shared=yes])
  69 AC_SUBST(enable_shared)
  70
  71 AC_ARG_ENABLE(vtable-verify,
  72 [  --enable-vtable-verify    Enable vtable verification feature ],
  73 [case "$enableval" in
  74  yes) enable_vtable_verify=yes ;;
  75  no)  enable_vtable_verify=no ;;
  76  *)   enable_vtable_verify=no;;
  77  esac],
  78 [enable_vtable_verify=no])
  79 AC_SUBST(enable_vtable_verify)
  80
  81 AC_ARG_WITH(aix-soname,
  82 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  83     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  84 [case "${host}:${enable_shared}" in
  85  power*-*-aix[[5-9]]*:yes)
  86    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  87    case ${withval} in
  88      aix|svr4|both) ;;
  89      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  90    esac
  91    AC_MSG_RESULT($withval)
  92    ;;
  93  *) with_aix_soname=aix ;;
  94  esac
  95 ], [with_aix_soname=aix])
  96 AC_SUBST(with_aix_soname)
  97
  98 GCC_PICFLAG
  99 AC_SUBST(PICFLAG)
 100
 101 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 102 AC_ARG_ENABLE(version-specific-runtime-libs,
 103 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 104 [case "$enableval" in
 105  yes) version_specific_libs=yes ;;
 106  no)  version_specific_libs=no ;;
 107  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 108  esac],
 109 [version_specific_libs=no])
 110 AC_MSG_RESULT($version_specific_libs)
 111
 112 GCC_WITH_TOOLEXECLIBDIR
 113
 114 AC_ARG_WITH(slibdir,
 115 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 116 slibdir="$with_slibdir",
 117 [if test "${version_specific_libs}" = yes; then
 118   slibdir='$(libsubdir)'
 119 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 120   case ${with_toolexeclibdir} in
 121     no)
 122       slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 123       ;;
 124     *)
 125       slibdir=${with_toolexeclibdir}
 126       ;;
 127   esac
 128 else
 129   slibdir='$(libdir)'
 130 fi])
 131 AC_SUBST(slibdir)
 132
 133 # Command-line options.
 134 # Very limited version of AC_MAINTAINER_MODE.
 135 AC_ARG_ENABLE([maintainer-mode],
 136   [AC_HELP_STRING([--enable-maintainer-mode],
 137                  [enable make rules and dependencies not useful (and
 138                   sometimes confusing) to the casual installer])],
 139   [case ${enable_maintainer_mode} in
 140      yes) MAINT='' ;;
 141      no) MAINT='#' ;;
 142      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 143    esac
 144    maintainer_mode=${enableval}],
 145   [MAINT='#'])
 146 AC_SUBST([MAINT])dnl
 147
 148 AC_PROG_INSTALL
 149
 150 AC_PROG_AWK
 151 # We need awk; bail out if it's missing.
 152 case ${AWK} in
 153   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 154 esac
 155
 156 AC_CANONICAL_HOST
 157 ACX_NONCANONICAL_HOST
 158 ACX_NONCANONICAL_TARGET
 159 GCC_TOPLEV_SUBDIRS
 160
 161 AC_ARG_ENABLE(gcov,
 162 [  --disable-gcov          don't provide libgcov and related host tools],
 163 [], [case $target in
 164        bpf-*-*)
 165          enable_gcov=no
 166        ;;
 167        *)
 168          enable_gcov=yes
 169        ;;
 170      esac])
 171 AC_SUBST(enable_gcov)
 172
 173 # Calculate toolexeclibdir
 174 # Also toolexecdir, though it's only used in toolexeclibdir
 175 case ${version_specific_libs} in
 176   yes)
 177     # Need the gcc compiler version to know where to install libraries
 178     # and header files if --enable-version-specific-runtime-libs option
 179     # is selected.
 180     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 181     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 182     ;;
 183   no)
 184     if test -n "$with_cross_host" &&
 185        test x"$with_cross_host" != x"no"; then
 186       # Install a library built with a cross compiler in tooldir, not libdir.
 187       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 188       case ${with_toolexeclibdir} in
 189         no)
 190           toolexeclibdir='$(toolexecdir)/lib'
 191           ;;
 192         *)
 193           toolexeclibdir=${with_toolexeclibdir}
 194           ;;
 195       esac
 196     else
 197       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 198       toolexeclibdir='$(libdir)'
 199     fi
 200     multi_os_directory=`$CC -print-multi-os-directory`
 201     case $multi_os_directory in
 202       .) ;; # Avoid trailing /.
 203       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 204     esac
 205     ;;
 206 esac
 207 AC_SUBST(toolexecdir)
 208 AC_SUBST(toolexeclibdir)
 209
 210 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 211 dnl to call AC_CHECK_PROG.
 212 AC_CHECK_TOOL(AR, ar)
 213 AC_CHECK_TOOL(LIPO, lipo, :)
 214 AC_CHECK_TOOL(NM, nm)
 215 AC_CHECK_TOOL(RANLIB, ranlib, :)
 216 AC_CHECK_TOOL(STRIP, strip, :)
 217 AC_PROG_LN_S
 218
 219 GCC_NO_EXECUTABLES
 220 AC_PROG_CC
 221 AC_PROG_CPP_WERROR
 222
 223 AC_SYS_LARGEFILE
 224
 225 AC_CHECK_SIZEOF([double])
 226 AC_CHECK_SIZEOF([long double])
 227 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 228 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 229 AC_SUBST(double_type_size)
 230 AC_SUBST(long_double_type_size)
 231
 232 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 233         unistd.h sys/stat.h sys/types.h \
 234         string.h strings.h memory.h sys/auxv.h sys/mman.h)
 235 AC_HEADER_STDC
 236
 237 # Check for decimal float support.
 238 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 239                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 240 #include <fenv.h>
 241 ]], [[
 242 _Decimal32 x;
 243 int fe_except =
 244   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 245 ]])],
 246                                   [libgcc_cv_dfp=yes],
 247                                   [libgcc_cv_dfp=no])])
 248 decimal_float=$libgcc_cv_dfp
 249 AC_SUBST(decimal_float)
 250
 251 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 252
 253 # Check for fixed-point support.
 254 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 255                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Sat _Fract x;])],
 256                                   [libgcc_cv_fixed_point=yes],
 257                                   [libgcc_cv_fixed_point=no])])
 258 fixed_point=$libgcc_cv_fixed_point
 259 AC_SUBST(fixed_point)
 260
 261 # For platforms with the unwind ABI which includes an unwind library,
 262 # libunwind, we can choose to use the system libunwind.
 263 # config.gcc also contains tests of with_system_libunwind.
 264 GCC_CHECK_UNWIND_GETIPINFO
 265
 266 # Check if the compiler is configured for setjmp/longjmp exceptions.
 267 GCC_CHECK_SJLJ_EXCEPTIONS
 268
 269 GCC_CET_FLAGS(CET_FLAGS)
 270 AC_SUBST(CET_FLAGS)
 271
 272 AC_ARG_ENABLE([explicit-exception-frame-registration],
 273   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 274      [register exception tables explicitly at module start, for use
 275       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 276 [
 277 force_explicit_eh_registry=
 278 if test "$enable_explicit_exception_frame_registration" = yes; then
 279   if test $ac_cv_sjlj_exceptions = yes; then
 280     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 281                   with setjmp/longjmp exceptions])
 282   fi
 283   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 284 fi
 285 ])
 286 AC_SUBST([force_explicit_eh_registry])
 287
 288 AC_ARG_ENABLE([tm-clone-registry],
 289 [  --disable-tm-clone-registry    disable TM clone registry],
 290 [
 291 use_tm_clone_registry=
 292 if test "$enable_tm_clone_registry" = no; then
 293   use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 294 fi
 295 ],
 296 [
 297 use_tm_clone_registry=
 298 case $target in
 299   msp430*elfbare)
 300    use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 301    ;;
 302 esac
 303 ])
 304 AC_SUBST([use_tm_clone_registry])
 305
 306 AC_LIB_PROG_LD_GNU
 307
 308 AC_MSG_CHECKING([for thread model used by GCC])
 309 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 310 AC_MSG_RESULT([$target_thread_file])
 311
 312 # Check for assembler CFI support.
 313 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 314                [AC_COMPILE_IFELSE(
 315 [AC_LANG_SOURCE([asm("\n\
 316         .text\n\
 317         .cfi_startproc\n\
 318         .cfi_personality 0, symbol\n\
 319         .cfi_endproc");])],
 320   [libgcc_cv_cfi=yes],
 321   [libgcc_cv_cfi=no])])
 322
 323 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 324 # word size rather than the address size.
 325 cat > conftest.c <<EOF
 326 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 327     || defined(__mips64) || defined(__loongarch64)
 328 host_address=64
 329 #else
 330 host_address=32
 331 #endif
 332 EOF
 333 eval `${CC-cc} -E conftest.c | grep host_address=`
 334 rm -f conftest.c
 335
 336 case ${host} in
 337 mips*-*-*)
 338   AC_CACHE_CHECK([whether the target is hard-float],
 339                  [libgcc_cv_mips_hard_float],
 340                  [AC_COMPILE_IFELSE(
 341     [AC_LANG_SOURCE([#ifndef __mips_hard_float
 342      #error FOO
 343      #endif
 344     ])],
 345     [libgcc_cv_mips_hard_float=yes],
 346     [libgcc_cv_mips_hard_float=no])])
 347 esac
 348
 349 case ${host} in
 350 *-*-solaris2*)
 351   # Check for system-provided CRTs on Solaris 11.4.
 352   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 353                  [libgcc_cv_solaris_crts],
 354     [libgcc_cv_solaris_crts=no
 355      libgcc_sysroot="`${CC} -print-sysroot`"
 356      libgcc_libdir="$libgcc_sysroot/usr/lib"
 357      # At the time they were added, gcrt1.o became a symlink for backwards
 358      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 359      case ${host} in
 360        i?86-*-solaris2* | x86_64-*-solaris2*)
 361          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 362          ;;
 363        sparc*-*-solaris2*)
 364          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 365          ;;
 366      esac])
 367   if test $libgcc_cv_solaris_crts = yes; then
 368     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 369       [Define if the system-provided CRTs are present on Solaris.])
 370   fi
 371   ;;
 372 esac
 373
 374 # Determine the version of glibc, if any, used on the target.
 375 AC_MSG_CHECKING([for target glibc version])
 376 AC_ARG_WITH([glibc-version],
 377   [AS_HELP_STRING([--with-glibc-version=M.N],
 378     [assume GCC used with glibc version M.N or later])], [
 379 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 380   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 381   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 382 else
 383   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 384 fi], [
 385 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 386                                       [#include <features.h>],
 387                                       [glibc_version_major=0])
 388 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 389                                       [#include <features.h>],
 390                                       [glibc_version_minor=0])])
 391 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 392
 393 # Determine floating-point type for powerpc*-*-linux* or vxworks7*.
 394 # Single-precision-only FPRs are not a supported configuration for
 395 # this target, so are not allowed for in this test.
 396 case ${host} in
 397 powerpc*-*-linux* | powerpc*-*-vxworks7*)
 398   cat > conftest.c <<EOF
 399 #ifdef __powerpc64__
 400 ppc_fp_type=64
 401 #elif defined _SOFT_FLOAT
 402 ppc_fp_type=soft
 403 #elif defined _SOFT_DOUBLE
 404 ppc_fp_type=e500v1
 405 #elif defined __NO_FPRS__
 406 ppc_fp_type=e500v2
 407 #else
 408 ppc_fp_type=hard
 409 #endif
 410 EOF
 411 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 412 rm -f conftest.c
 413 # glibc 2.19 and later provide all the soft-fp functions, with proper
 414 # interactions with <fenv.h> exception and rounding mode handling, so
 415 # make libgcc's versions into compat symbols if a recent enough glibc
 416 # version is being used.
 417 ppc_fp_compat=
 418 case ${ppc_fp_type} in
 419 soft|e500v1|e500v2)
 420   if test $glibc_version_major -gt 2 \
 421     || ( test $glibc_version_major -eq 2 \
 422         && test $glibc_version_minor -ge 19 ); then
 423     ppc_fp_compat="t-softfp-compat"
 424   fi
 425   ;;
 426 esac
 427 ;;
 428 esac
 429
 430 case ${host} in
 431 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 432 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 433 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 434 # a new glibc is being used so that __builtin_cpu_supports can be used.
 435 powerpc*-*-linux*)
 436   saved_CFLAGS="$CFLAGS"
 437   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 438   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 439                  [libgcc_cv_powerpc_float128],
 440                  [AC_COMPILE_IFELSE(
 441     [AC_LANG_SOURCE([vector double dadd (vector double a, vector double b) { return a + b; }])],
 442     [libgcc_cv_powerpc_float128=yes],
 443     [libgcc_cv_powerpc_float128=no])])
 444
 445   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 446   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 447                  [libgcc_cv_powerpc_float128_hw],
 448                  [AC_COMPILE_IFELSE(
 449     [AC_LANG_SOURCE([#include <sys/auxv.h>
 450      #ifndef AT_PLATFORM
 451      #error "AT_PLATFORM is not defined"
 452      #endif
 453      #ifndef __BUILTIN_CPU_SUPPORTS__
 454      #error "__builtin_cpu_supports is not available"
 455      #endif
 456      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 457      {
 458        vector unsigned char ret;
 459        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 460        return ret;
 461      }
 462      void *add_resolver (void) { return (void *) add; }
 463      __float128 add_ifunc (__float128, __float128)
 464         __attribute__ ((__ifunc__ ("add_resolver")));])],
 465     [libgcc_cv_powerpc_float128_hw=yes],
 466     [libgcc_cv_powerpc_float128_hw=no])])
 467   CFLAGS="$saved_CFLAGS"
 468
 469   saved_CFLAGS="$CFLAGS"
 470   CFLAGS="$CFLAGS -mcpu=power10 -mfloat128-hardware"
 471   AC_CACHE_CHECK([for PowerPC ISA 3.1 to build hardware __float128 libraries],
 472                  [libgcc_cv_powerpc_3_1_float128_hw],
 473                  [AC_COMPILE_IFELSE(
 474     [AC_LANG_SOURCE([#include <sys/auxv.h>
 475      #ifndef AT_PLATFORM
 476      #error "AT_PLATFORM is not defined"
 477      #endif
 478      #ifndef __BUILTIN_CPU_SUPPORTS__
 479      #error "__builtin_cpu_supports is not available"
 480      #endif
 481      vector unsigned char conv (vector unsigned char qs)
 482      {
 483        vector unsigned char ret;
 484        __asm__ ("xscvsqqp %0,%1" : "=v" (ret) : "v" (qs));
 485        return ret;
 486      }
 487      void *conv_resolver (void) { return (void *) conv; }
 488      __float128 conv_ifunc (__float128)
 489         __attribute__ ((__ifunc__ ("conv_resolver")));])],
 490     [libgcc_cv_powerpc_3_1_float128_hw=yes],
 491     [libgcc_cv_powerpc_3_1_float128_hw=no])])
 492   CFLAGS="$saved_CFLAGS"
 493 esac
 494
 495 # Collect host-machine-specific information.
 496 . ${srcdir}/config.host
 497
 498 # Used for constructing correct paths for offload compilers.
 499 accel_dir_suffix=
 500 real_host_noncanonical=${host_noncanonical}
 501 if test x"$enable_as_accelerator_for" != x; then
 502   accel_dir_suffix=/accel/${target_noncanonical}
 503   real_host_noncanonical=${enable_as_accelerator_for}
 504 fi
 505 AC_SUBST(accel_dir_suffix)
 506 AC_SUBST(real_host_noncanonical)
 507
 508 if test x"$enable_offload_targets" != x; then
 509   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 510 fi
 511
 512 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 513 # This is after config.host so we can augment tmake_file.
 514 # Link with -nostartfiles -nodefaultlibs since neither are present while
 515 # building libgcc.
 516 case ${host} in
 517 i?86-*-solaris2* | x86_64-*-solaris2*)
 518   cat > conftest.s <<EOF
 519         .section        .eh_frame,"a",@unwind
 520         .zero   4
 521         .section        .jcr,"aw",@progbits
 522         .zero   8
 523 EOF
 524   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 525       tmake_file="${tmake_file} i386/t-crtstuff"
 526   fi
 527   ;;
 528 esac
 529
 530 # Check if Solaris linker support v2 linker mapfile syntax.
 531 # Link with -nostartfiles -nodefaultlibs since neither are present while
 532 # building libgcc.
 533 case ${host} in
 534 *-*-solaris2*)
 535   solaris_ld_v2_maps=no
 536   echo 'int main(void) {return 0;}' > conftest.c
 537   echo '$mapfile_version 2' > conftest.map
 538   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 539       solaris_ld_v2_maps=yes
 540   fi
 541   ;;
 542 esac
 543 AC_SUBST(solaris_ld_v2_maps)
 544
 545 # Check if xtensa target is configured for windowed ABI and thus needs to use
 546 # custom unwind code.
 547 # This is after config.host so we can augment tmake_file.
 548 case ${host} in
 549 xtensa*-*)
 550   AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 551                      [#ifdef __XTENSA_CALL0_ABI__
 552                       #error
 553                       #endif
 554                       ])],
 555                       [tmake_file="${tmake_file} xtensa/t-windowed"])
 556   ;;
 557 esac
 558
 559 # Check for visibility support.  This is after config.host so that
 560 # we can check for asm_hidden_op.
 561 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 562     libgcc_cv_hidden_visibility_attribute, [
 563         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 564         libgcc_cv_hidden_visibility_attribute=no
 565         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 566             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 567                 libgcc_cv_hidden_visibility_attribute=yes
 568             fi
 569         fi
 570         rm -f conftest.*
 571     ])
 572
 573 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 574     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 575     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 576 else
 577     vis_hide=
 578 fi
 579 AC_SUBST(vis_hide)
 580
 581 # Check for .cfi_sections .debug_frame support.
 582 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 583     libgcc_cv_cfi_sections_directive, [
 584         echo 'int foo (int, char *);' > conftest.c
 585         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 586         libgcc_cv_cfi_sections_directive=no
 587         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 588             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 589                 libgcc_cv_cfi_sections_directive=yes
 590             fi
 591         fi
 592         rm -f conftest.*
 593     ])
 594 if test $libgcc_cv_cfi_sections_directive = yes; then
 595     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 596 fi
 597
 598 # See if we have thread-local storage.  We can only test assembler
 599 # since link-time and run-time tests require the newly built
 600 # gcc, which can't be used to build executable due to that libgcc
 601 # is yet to be built here.
 602 GCC_CHECK_CC_TLS
 603 set_have_cc_tls=
 604 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 605   set_have_cc_tls="-DHAVE_CC_TLS"
 606 fi
 607 AC_SUBST(set_have_cc_tls)
 608
 609 # See if we have emulated thread-local storage.
 610 GCC_CHECK_EMUTLS
 611 set_use_emutls=
 612 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 613   set_use_emutls="-DUSE_EMUTLS"
 614 fi
 615 AC_SUBST(set_use_emutls)
 616
 617 dnl Check if as supports AVX instructions.
 618 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 619 case "${target}" in
 620 i[[34567]]86-*-* | x86_64-*-*)
 621   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 622     AC_TRY_COMPILE([], [asm("vzeroupper");],
 623                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 624   ])
 625   if test x$libgcc_cv_as_avx = xyes; then
 626     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 627   fi
 628   ;;
 629 esac])
 630 LIBGCC_CHECK_AS_AVX
 631
 632 dnl Check if as supports LSE instructions.
 633 AC_DEFUN([LIBGCC_CHECK_AS_LSE], [
 634 case "${target}" in
 635 aarch64*-*-*)
 636   AC_CACHE_CHECK([if the assembler supports LSE], libgcc_cv_as_lse, [
 637     AC_TRY_COMPILE([],
 638 changequote(,)dnl
 639                         asm(".arch armv8-a+lse\n\tcas w0, w1, [x2]");
 640 changequote([,])dnl
 641                        ,
 642                    [libgcc_cv_as_lse=yes], [libgcc_cv_as_lse=no])
 643   ])
 644   if test x$libgcc_cv_as_lse = xyes; then
 645     AC_DEFINE(HAVE_AS_LSE, 1, [Define to 1 if the assembler supports LSE.])
 646   fi
 647   ;;
 648 esac])
 649 LIBGCC_CHECK_AS_LSE
 650
 651 dnl Check if as supports RTM instructions.
 652 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 653 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 654   [[void ip (void) __attribute__ ((constructor (1)));]])],
 655   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 656 if test $libgcc_cv_init_priority = yes; then
 657   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 658   [Define if the compiler supports init priority.])
 659 fi
 660
 661 # Conditionalize the sfp-machine.h header for this target machine.
 662 if test -z "${sfp_machine_header}"; then
 663         sfp_machine_header=$cpu_type/sfp-machine.h
 664         if test -f ${srcdir}/config/${sfp_machine_header}; then
 665                 :
 666         else
 667                 sfp_machine_header=no-sfp-machine.h
 668         fi
 669 fi
 670 AC_SUBST(sfp_machine_header)
 671
 672 # Conditionalize the makefile for this target machine.
 673 tmake_file_=
 674 for f in ${tmake_file}
 675 do
 676         if test -f ${srcdir}/config/$f
 677         then
 678                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 679         fi
 680 done
 681 tmake_file="${tmake_file_}"
 682 AC_SUBST(tmake_file)
 683
 684 # Likewise export definitions for libgcc_tm.h
 685 tm_file_=
 686 for f in ${tm_file}
 687 do
 688         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 689 done
 690 tm_file="${tm_file_}"
 691 AC_SUBST(tm_file)
 692 AC_SUBST(tm_defines)
 693
 694 # Map from thread model to thread header.
 695 GCC_AC_THREAD_HEADER([$target_thread_file])
 696
 697 # Determine what GCC version number to use in filesystem paths.
 698 GCC_BASE_VER
 699
 700 # Substitute configuration variables
 701 AC_SUBST(cpu_type)
 702 AC_SUBST(extra_parts)
 703 AC_SUBST(asm_hidden_op)
 704 AC_SUBST(enable_execute_stack)
 705 AC_SUBST(unwind_header)
 706 AC_SUBST(md_unwind_header)
 707 AC_SUBST(sfp_machine_header)
 708 AC_SUBST(thread_header)
 709
 710 # We need multilib support.
 711 AC_CONFIG_FILES([Makefile])
 712 AC_CONFIG_COMMANDS([default],
 713   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 714 if test -n "$CONFIG_FILES"; then
 715   # FIXME: We shouldn't need to set ac_file
 716   ac_file=Makefile
 717   . ${libgcc_topdir}/config-ml.in
 718 fi]],
 719 [[srcdir=${srcdir}
 720 host=${host}
 721 with_target_subdir=${with_target_subdir}
 722 with_multisubdir=${with_multisubdir}
 723 ac_configure_args="--enable-multilib ${ac_configure_args}"
 724 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 725 libgcc_topdir=${libgcc_topdir}
 726 CC="${CC}"
 727 ]])
 728 AC_OUTPUT