libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/toolexeclibdir.m4)
   6 sinclude(../config/acx.m4)
   7 sinclude(../config/no-executables.m4)
   8 sinclude(../config/lib-ld.m4)
   9 sinclude(../config/override.m4)
  10 sinclude(../config/picflag.m4)
  11 sinclude(../config/dfp.m4)
  12 sinclude(../config/unwind_ipinfo.m4)
  13 sinclude(../config/gthr.m4)
  14 sinclude(../config/sjlj.m4)
  15 sinclude(../config/cet.m4)
  16
  17 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  18 AC_CONFIG_SRCDIR([static-object.mk])
  19
  20 # The libgcc should not depend on any header files
  21 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  22   [m4_divert_text([DEFAULTS],
  23     [ac_includes_default='/* none */'])])
  24
  25 AC_ARG_WITH(target-subdir,
  26 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  27 AC_ARG_WITH(cross-host,
  28 [  --with-cross-host=HOST           Configuring with a cross compiler])
  29 AC_ARG_WITH(ld,
  30 [  --with-ld               arrange to use the specified ld (full pathname)])
  31
  32 if test "${srcdir}" = "."; then
  33   if test -n "${with_build_subdir}"; then
  34     libgcc_topdir="${srcdir}/../.."
  35     with_target_subdir=
  36   elif test -z "${with_target_subdir}"; then
  37     libgcc_topdir="${srcdir}/.."
  38   else
  39     if test "${with_target_subdir}" != "."; then
  40       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  41     else
  42       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  43     fi
  44   fi
  45 else
  46   libgcc_topdir="${srcdir}/.."
  47 fi
  48 AC_SUBST(libgcc_topdir)
  49 AC_CONFIG_AUX_DIR($libgcc_topdir)
  50 AC_CONFIG_HEADER(auto-target.h:config.in)
  51
  52 AC_ARG_ENABLE(shared,
  53 [  --disable-shared        don't provide a shared libgcc],
  54 [
  55   case $enable_shared in
  56   yes | no) ;;
  57   *)
  58     enable_shared=no
  59     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  60     for pkg in $enableval; do
  61       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  62         enable_shared=yes
  63       fi
  64     done
  65     IFS="$ac_save_ifs"
  66     ;;
  67   esac
  68 ], [enable_shared=yes])
  69 AC_SUBST(enable_shared)
  70
  71 AC_ARG_ENABLE(gcov,
  72 [  --disable-gcov          don't provide libgcov and related host tools],
  73 [], [enable_gcov=yes])
  74 AC_SUBST(enable_gcov)
  75
  76 AC_ARG_ENABLE(vtable-verify,
  77 [  --enable-vtable-verify    Enable vtable verification feature ],
  78 [case "$enableval" in
  79  yes) enable_vtable_verify=yes ;;
  80  no)  enable_vtable_verify=no ;;
  81  *)   enable_vtable_verify=no;;
  82  esac],
  83 [enable_vtable_verify=no])
  84 AC_SUBST(enable_vtable_verify)
  85
  86 AC_ARG_WITH(aix-soname,
  87 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  88     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  89 [case "${host}:${enable_shared}" in
  90  power*-*-aix[[5-9]]*:yes)
  91    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  92    case ${withval} in
  93      aix|svr4|both) ;;
  94      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  95    esac
  96    AC_MSG_RESULT($withval)
  97    ;;
  98  *) with_aix_soname=aix ;;
  99  esac
 100 ], [with_aix_soname=aix])
 101 AC_SUBST(with_aix_soname)
 102
 103 GCC_PICFLAG
 104 AC_SUBST(PICFLAG)
 105
 106 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 107 AC_ARG_ENABLE(version-specific-runtime-libs,
 108 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 109 [case "$enableval" in
 110  yes) version_specific_libs=yes ;;
 111  no)  version_specific_libs=no ;;
 112  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 113  esac],
 114 [version_specific_libs=no])
 115 AC_MSG_RESULT($version_specific_libs)
 116
 117 GCC_WITH_TOOLEXECLIBDIR
 118
 119 AC_ARG_WITH(slibdir,
 120 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 121 slibdir="$with_slibdir",
 122 [if test "${version_specific_libs}" = yes; then
 123   slibdir='$(libsubdir)'
 124 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 125   case ${with_toolexeclibdir} in
 126     no)
 127       slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 128       ;;
 129     *)
 130       slibdir=${with_toolexeclibdir}
 131       ;;
 132   esac
 133 else
 134   slibdir='$(libdir)'
 135 fi])
 136 AC_SUBST(slibdir)
 137
 138 # Command-line options.
 139 # Very limited version of AC_MAINTAINER_MODE.
 140 AC_ARG_ENABLE([maintainer-mode],
 141   [AC_HELP_STRING([--enable-maintainer-mode],
 142                  [enable make rules and dependencies not useful (and
 143                   sometimes confusing) to the casual installer])],
 144   [case ${enable_maintainer_mode} in
 145      yes) MAINT='' ;;
 146      no) MAINT='#' ;;
 147      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 148    esac
 149    maintainer_mode=${enableval}],
 150   [MAINT='#'])
 151 AC_SUBST([MAINT])dnl
 152
 153 AC_PROG_INSTALL
 154
 155 AC_PROG_AWK
 156 # We need awk; bail out if it's missing.
 157 case ${AWK} in
 158   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 159 esac
 160
 161 AC_CANONICAL_HOST
 162 ACX_NONCANONICAL_HOST
 163 ACX_NONCANONICAL_TARGET
 164 GCC_TOPLEV_SUBDIRS
 165
 166 # Calculate toolexeclibdir
 167 # Also toolexecdir, though it's only used in toolexeclibdir
 168 case ${version_specific_libs} in
 169   yes)
 170     # Need the gcc compiler version to know where to install libraries
 171     # and header files if --enable-version-specific-runtime-libs option
 172     # is selected.
 173     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 174     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 175     ;;
 176   no)
 177     if test -n "$with_cross_host" &&
 178        test x"$with_cross_host" != x"no"; then
 179       # Install a library built with a cross compiler in tooldir, not libdir.
 180       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 181       case ${with_toolexeclibdir} in
 182         no)
 183           toolexeclibdir='$(toolexecdir)/lib'
 184           ;;
 185         *)
 186           toolexeclibdir=${with_toolexeclibdir}
 187           ;;
 188       esac
 189     else
 190       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 191       toolexeclibdir='$(libdir)'
 192     fi
 193     multi_os_directory=`$CC -print-multi-os-directory`
 194     case $multi_os_directory in
 195       .) ;; # Avoid trailing /.
 196       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 197     esac
 198     ;;
 199 esac
 200 AC_SUBST(toolexecdir)
 201 AC_SUBST(toolexeclibdir)
 202
 203 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 204 dnl to call AC_CHECK_PROG.
 205 AC_CHECK_TOOL(AR, ar)
 206 AC_CHECK_TOOL(LIPO, lipo, :)
 207 AC_CHECK_TOOL(NM, nm)
 208 AC_CHECK_TOOL(RANLIB, ranlib, :)
 209 AC_CHECK_TOOL(STRIP, strip, :)
 210 AC_PROG_LN_S
 211
 212 GCC_NO_EXECUTABLES
 213 AC_PROG_CC
 214 AC_PROG_CPP_WERROR
 215
 216 AC_SYS_LARGEFILE
 217
 218 AC_CHECK_SIZEOF([double])
 219 AC_CHECK_SIZEOF([long double])
 220 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 221 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 222 AC_SUBST(double_type_size)
 223 AC_SUBST(long_double_type_size)
 224
 225 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 226         unistd.h sys/stat.h sys/types.h \
 227         string.h strings.h memory.h sys/auxv.h)
 228 AC_HEADER_STDC
 229
 230 # Check for decimal float support.
 231 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 232                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 233 #include <fenv.h>
 234 ]], [[
 235 _Decimal32 x;
 236 int fe_except =
 237   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 238 ]])],
 239                                   [libgcc_cv_dfp=yes],
 240                                   [libgcc_cv_dfp=no])])
 241 decimal_float=$libgcc_cv_dfp
 242 AC_SUBST(decimal_float)
 243
 244 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 245
 246 # Check for fixed-point support.
 247 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 248                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([_Sat _Fract x;])],
 249                                   [libgcc_cv_fixed_point=yes],
 250                                   [libgcc_cv_fixed_point=no])])
 251 fixed_point=$libgcc_cv_fixed_point
 252 AC_SUBST(fixed_point)
 253
 254 # For platforms with the unwind ABI which includes an unwind library,
 255 # libunwind, we can choose to use the system libunwind.
 256 # config.gcc also contains tests of with_system_libunwind.
 257 GCC_CHECK_UNWIND_GETIPINFO
 258
 259 # Check if the compiler is configured for setjmp/longjmp exceptions.
 260 GCC_CHECK_SJLJ_EXCEPTIONS
 261
 262 GCC_CET_FLAGS(CET_FLAGS)
 263 AC_SUBST(CET_FLAGS)
 264
 265 AC_ARG_ENABLE([explicit-exception-frame-registration],
 266   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 267      [register exception tables explicitly at module start, for use
 268       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 269 [
 270 force_explicit_eh_registry=
 271 if test "$enable_explicit_exception_frame_registration" = yes; then
 272   if test $ac_cv_sjlj_exceptions = yes; then
 273     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 274                   with setjmp/longjmp exceptions])
 275   fi
 276   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 277 fi
 278 ])
 279 AC_SUBST([force_explicit_eh_registry])
 280
 281 AC_ARG_ENABLE([tm-clone-registry],
 282 [  --disable-tm-clone-registry    disable TM clone registry],
 283 [
 284 use_tm_clone_registry=
 285 if test "$enable_tm_clone_registry" = no; then
 286   use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 287 fi
 288 ],
 289 [
 290 use_tm_clone_registry=
 291 case $target in
 292   msp430*elfbare)
 293    use_tm_clone_registry=-DUSE_TM_CLONE_REGISTRY=0
 294    ;;
 295 esac
 296 ])
 297 AC_SUBST([use_tm_clone_registry])
 298
 299 AC_LIB_PROG_LD_GNU
 300
 301 AC_MSG_CHECKING([for thread model used by GCC])
 302 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 303 AC_MSG_RESULT([$target_thread_file])
 304
 305 # Check for assembler CFI support.
 306 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 307                [AC_COMPILE_IFELSE(
 308 [AC_LANG_SOURCE([asm("\n\
 309         .text\n\
 310         .cfi_startproc\n\
 311         .cfi_personality 0, symbol\n\
 312         .cfi_endproc");])],
 313   [libgcc_cv_cfi=yes],
 314   [libgcc_cv_cfi=no])])
 315
 316 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 317 # word size rather than the address size.
 318 cat > conftest.c <<EOF
 319 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 320     || defined(__mips64)
 321 host_address=64
 322 #else
 323 host_address=32
 324 #endif
 325 EOF
 326 eval `${CC-cc} -E conftest.c | grep host_address=`
 327 rm -f conftest.c
 328
 329 case ${host} in
 330 mips*-*-*)
 331   AC_CACHE_CHECK([whether the target is hard-float],
 332                  [libgcc_cv_mips_hard_float],
 333                  [AC_COMPILE_IFELSE(
 334     [AC_LANG_SOURCE([#ifndef __mips_hard_float
 335      #error FOO
 336      #endif
 337     ])],
 338     [libgcc_cv_mips_hard_float=yes],
 339     [libgcc_cv_mips_hard_float=no])])
 340 esac
 341
 342 case ${host} in
 343 *-*-solaris2*)
 344   # Check for system-provided CRTs on Solaris 11.4.
 345   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 346                  [libgcc_cv_solaris_crts],
 347     [libgcc_cv_solaris_crts=no
 348      libgcc_sysroot="`${CC} -print-sysroot`"
 349      libgcc_libdir="$libgcc_sysroot/usr/lib"
 350      # At the time they were added, gcrt1.o became a symlink for backwards
 351      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 352      case ${host} in
 353        i?86-*-solaris2* | x86_64-*-solaris2*)
 354          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 355          ;;
 356        sparc*-*-solaris2*)
 357          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 358          ;;
 359      esac])
 360   if test $libgcc_cv_solaris_crts = yes; then
 361     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 362       [Define if the system-provided CRTs are present on Solaris.])
 363   fi
 364   ;;
 365 esac
 366
 367 # Determine the version of glibc, if any, used on the target.
 368 AC_MSG_CHECKING([for target glibc version])
 369 AC_ARG_WITH([glibc-version],
 370   [AS_HELP_STRING([--with-glibc-version=M.N],
 371     [assume GCC used with glibc version M.N or later])], [
 372 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 373   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 374   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 375 else
 376   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 377 fi], [
 378 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 379                                       [#include <features.h>],
 380                                       [glibc_version_major=0])
 381 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 382                                       [#include <features.h>],
 383                                       [glibc_version_minor=0])])
 384 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 385
 386 # Determine floating-point type for powerpc*-*-linux* or vxworks7*.
 387 # Single-precision-only FPRs are not a supported configuration for
 388 # this target, so are not allowed for in this test.
 389 case ${host} in
 390 powerpc*-*-linux* | powerpc*-*-vxworks7*)
 391   cat > conftest.c <<EOF
 392 #ifdef __powerpc64__
 393 ppc_fp_type=64
 394 #elif defined _SOFT_FLOAT
 395 ppc_fp_type=soft
 396 #elif defined _SOFT_DOUBLE
 397 ppc_fp_type=e500v1
 398 #elif defined __NO_FPRS__
 399 ppc_fp_type=e500v2
 400 #else
 401 ppc_fp_type=hard
 402 #endif
 403 EOF
 404 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 405 rm -f conftest.c
 406 # glibc 2.19 and later provide all the soft-fp functions, with proper
 407 # interactions with <fenv.h> exception and rounding mode handling, so
 408 # make libgcc's versions into compat symbols if a recent enough glibc
 409 # version is being used.
 410 ppc_fp_compat=
 411 case ${ppc_fp_type} in
 412 soft|e500v1|e500v2)
 413   if test $glibc_version_major -gt 2 \
 414     || ( test $glibc_version_major -eq 2 \
 415         && test $glibc_version_minor -ge 19 ); then
 416     ppc_fp_compat="t-softfp-compat"
 417   fi
 418   ;;
 419 esac
 420 ;;
 421 esac
 422
 423 case ${host} in
 424 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 425 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 426 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 427 # a new glibc is being used so that __builtin_cpu_supports can be used.
 428 powerpc*-*-linux*)
 429   saved_CFLAGS="$CFLAGS"
 430   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 431   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 432                  [libgcc_cv_powerpc_float128],
 433                  [AC_COMPILE_IFELSE(
 434     [AC_LANG_SOURCE([vector double dadd (vector double a, vector double b) { return a + b; }])],
 435     [libgcc_cv_powerpc_float128=yes],
 436     [libgcc_cv_powerpc_float128=no])])
 437
 438   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 439   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 440                  [libgcc_cv_powerpc_float128_hw],
 441                  [AC_COMPILE_IFELSE(
 442     [AC_LANG_SOURCE([#include <sys/auxv.h>
 443      #ifndef AT_PLATFORM
 444      #error "AT_PLATFORM is not defined"
 445      #endif
 446      #ifndef __BUILTIN_CPU_SUPPORTS__
 447      #error "__builtin_cpu_supports is not available"
 448      #endif
 449      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 450      {
 451        vector unsigned char ret;
 452        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 453        return ret;
 454      }
 455      void *add_resolver (void) { return (void *) add; }
 456      __float128 add_ifunc (__float128, __float128)
 457         __attribute__ ((__ifunc__ ("add_resolver")));])],
 458     [libgcc_cv_powerpc_float128_hw=yes],
 459     [libgcc_cv_powerpc_float128_hw=no])])
 460   CFLAGS="$saved_CFLAGS"
 461 esac
 462
 463 # Collect host-machine-specific information.
 464 . ${srcdir}/config.host
 465
 466 # Used for constructing correct paths for offload compilers.
 467 accel_dir_suffix=
 468 real_host_noncanonical=${host_noncanonical}
 469 if test x"$enable_as_accelerator_for" != x; then
 470   accel_dir_suffix=/accel/${target_noncanonical}
 471   real_host_noncanonical=${enable_as_accelerator_for}
 472 fi
 473 AC_SUBST(accel_dir_suffix)
 474 AC_SUBST(real_host_noncanonical)
 475
 476 if test x"$enable_offload_targets" != x; then
 477   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 478 fi
 479
 480 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 481 # This is after config.host so we can augment tmake_file.
 482 # Link with -nostartfiles -nodefaultlibs since neither are present while
 483 # building libgcc.
 484 case ${host} in
 485 i?86-*-solaris2* | x86_64-*-solaris2*)
 486   cat > conftest.s <<EOF
 487         .section        .eh_frame,"a",@unwind
 488         .zero   4
 489         .section        .jcr,"aw",@progbits
 490         .zero   8
 491 EOF
 492   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 493       tmake_file="${tmake_file} i386/t-crtstuff"
 494   fi
 495   ;;
 496 esac
 497
 498 # Check if Solaris linker support v2 linker mapfile syntax.
 499 # Link with -nostartfiles -nodefaultlibs since neither are present while
 500 # building libgcc.
 501 case ${host} in
 502 *-*-solaris2*)
 503   solaris_ld_v2_maps=no
 504   echo 'int main(void) {return 0;}' > conftest.c
 505   echo '$mapfile_version 2' > conftest.map
 506   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 507       solaris_ld_v2_maps=yes
 508   fi
 509   ;;
 510 esac
 511 AC_SUBST(solaris_ld_v2_maps)
 512
 513 # Check if xtensa target is configured for windowed ABI and thus needs to use
 514 # custom unwind code.
 515 # This is after config.host so we can augment tmake_file.
 516 case ${host} in
 517 xtensa*-*)
 518   AC_COMPILE_IFELSE([AC_LANG_SOURCE(
 519                      [#ifdef __XTENSA_CALL0_ABI__
 520                       #error
 521                       #endif
 522                       ])],
 523                       [tmake_file="${tmake_file} xtensa/t-windowed"])
 524   ;;
 525 esac
 526
 527 # Check for visibility support.  This is after config.host so that
 528 # we can check for asm_hidden_op.
 529 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 530     libgcc_cv_hidden_visibility_attribute, [
 531         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 532         libgcc_cv_hidden_visibility_attribute=no
 533         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 534             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 535                 libgcc_cv_hidden_visibility_attribute=yes
 536             fi
 537         fi
 538         rm -f conftest.*
 539     ])
 540
 541 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 542     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 543     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 544 else
 545     vis_hide=
 546 fi
 547 AC_SUBST(vis_hide)
 548
 549 # Check for .cfi_sections .debug_frame support.
 550 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 551     libgcc_cv_cfi_sections_directive, [
 552         echo 'int foo (int, char *);' > conftest.c
 553         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 554         libgcc_cv_cfi_sections_directive=no
 555         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 556             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 557                 libgcc_cv_cfi_sections_directive=yes
 558             fi
 559         fi
 560         rm -f conftest.*
 561     ])
 562 if test $libgcc_cv_cfi_sections_directive = yes; then
 563     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 564 fi
 565
 566 # See if we have thread-local storage.  We can only test assembler
 567 # since link-time and run-time tests require the newly built
 568 # gcc, which can't be used to build executable due to that libgcc
 569 # is yet to be built here.
 570 GCC_CHECK_CC_TLS
 571 set_have_cc_tls=
 572 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 573   set_have_cc_tls="-DHAVE_CC_TLS"
 574 fi
 575 AC_SUBST(set_have_cc_tls)
 576
 577 # See if we have emulated thread-local storage.
 578 GCC_CHECK_EMUTLS
 579 set_use_emutls=
 580 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 581   set_use_emutls="-DUSE_EMUTLS"
 582 fi
 583 AC_SUBST(set_use_emutls)
 584
 585 dnl Check if as supports AVX instructions.
 586 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 587 case "${target}" in
 588 i[[34567]]86-*-* | x86_64-*-*)
 589   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 590     AC_TRY_COMPILE([], [asm("vzeroupper");],
 591                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 592   ])
 593   if test x$libgcc_cv_as_avx = xyes; then
 594     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 595   fi
 596   ;;
 597 esac])
 598 LIBGCC_CHECK_AS_AVX
 599
 600 dnl Check if as supports LSE instructions.
 601 AC_DEFUN([LIBGCC_CHECK_AS_LSE], [
 602 case "${target}" in
 603 aarch64*-*-*)
 604   AC_CACHE_CHECK([if the assembler supports LSE], libgcc_cv_as_lse, [
 605     AC_TRY_COMPILE([],
 606 changequote(,)dnl
 607                         asm(".arch armv8-a+lse\n\tcas w0, w1, [x2]");
 608 changequote([,])dnl
 609                        ,
 610                    [libgcc_cv_as_lse=yes], [libgcc_cv_as_lse=no])
 611   ])
 612   if test x$libgcc_cv_as_lse = xyes; then
 613     AC_DEFINE(HAVE_AS_LSE, 1, [Define to 1 if the assembler supports LSE.])
 614   fi
 615   ;;
 616 esac])
 617 LIBGCC_CHECK_AS_LSE
 618
 619 dnl Check if as supports RTM instructions.
 620 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 621 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 622   [[void ip (void) __attribute__ ((constructor (1)));]])],
 623   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 624 if test $libgcc_cv_init_priority = yes; then
 625   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 626   [Define if the compiler supports init priority.])
 627 fi
 628
 629 # Conditionalize the sfp-machine.h header for this target machine.
 630 if test -z "${sfp_machine_header}"; then
 631         sfp_machine_header=$cpu_type/sfp-machine.h
 632         if test -f ${srcdir}/config/${sfp_machine_header}; then
 633                 :
 634         else
 635                 sfp_machine_header=no-sfp-machine.h
 636         fi
 637 fi
 638 AC_SUBST(sfp_machine_header)
 639
 640 # Conditionalize the makefile for this target machine.
 641 tmake_file_=
 642 for f in ${tmake_file}
 643 do
 644         if test -f ${srcdir}/config/$f
 645         then
 646                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 647         fi
 648 done
 649 tmake_file="${tmake_file_}"
 650 AC_SUBST(tmake_file)
 651
 652 # Likewise export definitions for libgcc_tm.h
 653 tm_file_=
 654 for f in ${tm_file}
 655 do
 656         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 657 done
 658 tm_file="${tm_file_}"
 659 AC_SUBST(tm_file)
 660 AC_SUBST(tm_defines)
 661
 662 # Map from thread model to thread header.
 663 GCC_AC_THREAD_HEADER([$target_thread_file])
 664
 665 # Determine what GCC version number to use in filesystem paths.
 666 GCC_BASE_VER
 667
 668 # Substitute configuration variables
 669 AC_SUBST(cpu_type)
 670 AC_SUBST(extra_parts)
 671 AC_SUBST(asm_hidden_op)
 672 AC_SUBST(enable_execute_stack)
 673 AC_SUBST(unwind_header)
 674 AC_SUBST(md_unwind_header)
 675 AC_SUBST(sfp_machine_header)
 676 AC_SUBST(thread_header)
 677
 678 # We need multilib support.
 679 AC_CONFIG_FILES([Makefile])
 680 AC_CONFIG_COMMANDS([default],
 681   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 682 if test -n "$CONFIG_FILES"; then
 683   # FIXME: We shouldn't need to set ac_file
 684   ac_file=Makefile
 685   . ${libgcc_topdir}/config-ml.in
 686 fi]],
 687 [[srcdir=${srcdir}
 688 host=${host}
 689 with_target_subdir=${with_target_subdir}
 690 with_multisubdir=${with_multisubdir}
 691 ac_configure_args="--enable-multilib ${ac_configure_args}"
 692 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 693 libgcc_topdir=${libgcc_topdir}
 694 CC="${CC}"
 695 ]])
 696 AC_OUTPUT