libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14 sinclude(../config/cet.m4)
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  18 AC_CONFIG_SRCDIR([static-object.mk])
  19
  20 # The libgcc should not depend on any header files
  21 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  22   [m4_divert_text([DEFAULTS],
  23     [ac_includes_default='/* none */'])])
  24
  25 AC_ARG_WITH(target-subdir,
  26 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  27 AC_ARG_WITH(cross-host,
  28 [  --with-cross-host=HOST           Configuring with a cross compiler])
  29 AC_ARG_WITH(ld,
  30 [  --with-ld               arrange to use the specified ld (full pathname)])
  31
  32 if test "${srcdir}" = "."; then
  33   if test -n "${with_build_subdir}"; then
  34     libgcc_topdir="${srcdir}/../.."
  35     with_target_subdir=
  36   elif test -z "${with_target_subdir}"; then
  37     libgcc_topdir="${srcdir}/.."
  38   else
  39     if test "${with_target_subdir}" != "."; then
  40       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  41     else
  42       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  43     fi
  44   fi
  45 else
  46   libgcc_topdir="${srcdir}/.."
  47 fi
  48 AC_SUBST(libgcc_topdir)
  49 AC_CONFIG_AUX_DIR($libgcc_topdir)
  50 AC_CONFIG_HEADER(auto-target.h:config.in)
  51
  52 AC_ARG_ENABLE(shared,
  53 [  --disable-shared        don't provide a shared libgcc],
  54 [
  55   case $enable_shared in
  56   yes | no) ;;
  57   *)
  58     enable_shared=no
  59     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  60     for pkg in $enableval; do
  61       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  62         enable_shared=yes
  63       fi
  64     done
  65     IFS="$ac_save_ifs"
  66     ;;
  67   esac
  68 ], [enable_shared=yes])
  69 AC_SUBST(enable_shared)
  70
  71 AC_ARG_ENABLE(gcov,
  72 [  --disable-gcov          don't provide libgcov and related host tools],
  73 [], [enable_gcov=yes])
  74 AC_SUBST(enable_gcov)
  75
  76 AC_ARG_ENABLE(vtable-verify,
  77 [  --enable-vtable-verify    Enable vtable verification feature ],
  78 [case "$enableval" in
  79  yes) enable_vtable_verify=yes ;;
  80  no)  enable_vtable_verify=no ;;
  81  *)   enable_vtable_verify=no;;
  82  esac],
  83 [enable_vtable_verify=no])
  84 AC_SUBST(enable_vtable_verify)
  85
  86 AC_ARG_WITH(aix-soname,
  87 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  88     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  89 [case "${host}:${enable_shared}" in
  90  power*-*-aix[[5-9]]*:yes)
  91    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  92    case ${withval} in
  93      aix|svr4|both) ;;
  94      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  95    esac
  96    AC_MSG_RESULT($withval)
  97    ;;
  98  *) with_aix_soname=aix ;;
  99  esac
 100 ], [with_aix_soname=aix])
 101 AC_SUBST(with_aix_soname)
 102
 103 GCC_PICFLAG
 104 AC_SUBST(PICFLAG)
 105
 106 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 107 AC_ARG_ENABLE(version-specific-runtime-libs,
 108 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 109 [case "$enableval" in
 110  yes) version_specific_libs=yes ;;
 111  no)  version_specific_libs=no ;;
 112  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 113  esac],
 114 [version_specific_libs=no])
 115 AC_MSG_RESULT($version_specific_libs)
 116
 117 AC_ARG_WITH(slibdir,
 118 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 119 slibdir="$with_slibdir",
 120 if test "${version_specific_libs}" = yes; then
 121   slibdir='$(libsubdir)'
 122 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 123   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 124 else
 125   slibdir='$(libdir)'
 126 fi)
 127 AC_SUBST(slibdir)
 128
 129 # Command-line options.
 130 # Very limited version of AC_MAINTAINER_MODE.
 131 AC_ARG_ENABLE([maintainer-mode],
 132   [AC_HELP_STRING([--enable-maintainer-mode],
 133                  [enable make rules and dependencies not useful (and
 134                   sometimes confusing) to the casual installer])],
 135   [case ${enable_maintainer_mode} in
 136      yes) MAINT='' ;;
 137      no) MAINT='#' ;;
 138      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 139    esac
 140    maintainer_mode=${enableval}],
 141   [MAINT='#'])
 142 AC_SUBST([MAINT])dnl
 143
 144 AC_PROG_INSTALL
 145
 146 AC_PROG_AWK
 147 # We need awk; bail out if it's missing.
 148 case ${AWK} in
 149   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 150 esac
 151
 152 AC_CANONICAL_HOST
 153 ACX_NONCANONICAL_HOST
 154 ACX_NONCANONICAL_TARGET
 155 GCC_TOPLEV_SUBDIRS
 156
 157 # Calculate toolexeclibdir
 158 # Also toolexecdir, though it's only used in toolexeclibdir
 159 case ${version_specific_libs} in
 160   yes)
 161     # Need the gcc compiler version to know where to install libraries
 162     # and header files if --enable-version-specific-runtime-libs option
 163     # is selected.
 164     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 165     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 166     ;;
 167   no)
 168     if test -n "$with_cross_host" &&
 169        test x"$with_cross_host" != x"no"; then
 170       # Install a library built with a cross compiler in tooldir, not libdir.
 171       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 172       toolexeclibdir='$(toolexecdir)/lib'
 173     else
 174       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 175       toolexeclibdir='$(libdir)'
 176     fi
 177     multi_os_directory=`$CC -print-multi-os-directory`
 178     case $multi_os_directory in
 179       .) ;; # Avoid trailing /.
 180       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 181     esac
 182     ;;
 183 esac
 184 AC_SUBST(toolexecdir)
 185 AC_SUBST(toolexeclibdir)
 186
 187 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 188 dnl to call AC_CHECK_PROG.
 189 AC_CHECK_TOOL(AR, ar)
 190 AC_CHECK_TOOL(LIPO, lipo, :)
 191 AC_CHECK_TOOL(NM, nm)
 192 AC_CHECK_TOOL(RANLIB, ranlib, :)
 193 AC_CHECK_TOOL(STRIP, strip, :)
 194 AC_PROG_LN_S
 195
 196 GCC_NO_EXECUTABLES
 197 AC_PROG_CC
 198 AC_PROG_CPP_WERROR
 199
 200 AC_SYS_LARGEFILE
 201
 202 AC_CHECK_SIZEOF([double])
 203 AC_CHECK_SIZEOF([long double])
 204 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 205 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 206 AC_SUBST(double_type_size)
 207 AC_SUBST(long_double_type_size)
 208
 209 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 210         unistd.h sys/stat.h sys/types.h \
 211         string.h strings.h memory.h)
 212 AC_HEADER_STDC
 213
 214 # Check for decimal float support.
 215 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 216                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 217 #include <fenv.h>
 218 ]], [[
 219 _Decimal32 x;
 220 int fe_except =
 221   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 222 ]])],
 223                                   [libgcc_cv_dfp=yes],
 224                                   [libgcc_cv_dfp=no])])
 225 decimal_float=$libgcc_cv_dfp
 226 AC_SUBST(decimal_float)
 227
 228 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 229
 230 # Check for fixed-point support.
 231 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 232                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 233                                   [libgcc_cv_fixed_point=no])])
 234 fixed_point=$libgcc_cv_fixed_point
 235 AC_SUBST(fixed_point)
 236
 237 # For platforms with the unwind ABI which includes an unwind library,
 238 # libunwind, we can choose to use the system libunwind.
 239 # config.gcc also contains tests of with_system_libunwind.
 240 GCC_CHECK_UNWIND_GETIPINFO
 241
 242 # Check if the compiler is configured for setjmp/longjmp exceptions.
 243 GCC_CHECK_SJLJ_EXCEPTIONS
 244
 245 GCC_CET_FLAGS(CET_FLAGS)
 246 AC_SUBST(CET_FLAGS)
 247
 248 AC_ARG_ENABLE([explicit-exception-frame-registration],
 249   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 250      [register exception tables explicitly at module start, for use
 251       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 252 [
 253 force_explicit_eh_registry=
 254 if test "$enable_explicit_exception_frame_registration" = yes; then
 255   if test $ac_cv_sjlj_exceptions = yes; then
 256     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 257                   with setjmp/longjmp exceptions])
 258   fi
 259   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 260 fi
 261 ])
 262 AC_SUBST([force_explicit_eh_registry])
 263
 264 AC_LIB_PROG_LD_GNU
 265
 266 AC_MSG_CHECKING([for thread model used by GCC])
 267 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 268 AC_MSG_RESULT([$target_thread_file])
 269
 270 # Check for assembler CFI support.
 271 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 272                [AC_COMPILE_IFELSE(
 273 [asm("\n\
 274         .text\n\
 275         .cfi_startproc\n\
 276         .cfi_personality 0, symbol\n\
 277         .cfi_endproc");],
 278   [libgcc_cv_cfi=yes],
 279   [libgcc_cv_cfi=no])])
 280
 281 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 282 # word size rather than the address size.
 283 cat > conftest.c <<EOF
 284 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 285     || defined(__mips64)
 286 host_address=64
 287 #else
 288 host_address=32
 289 #endif
 290 EOF
 291 eval `${CC-cc} -E conftest.c | grep host_address=`
 292 rm -f conftest.c
 293
 294 case ${host} in
 295 mips*-*-*)
 296   AC_CACHE_CHECK([whether the target is hard-float],
 297                  [libgcc_cv_mips_hard_float],
 298                  [AC_COMPILE_IFELSE(
 299     [#ifndef __mips_hard_float
 300      #error FOO
 301      #endif],
 302     [libgcc_cv_mips_hard_float=yes],
 303     [libgcc_cv_mips_hard_float=no])])
 304 esac
 305
 306 case ${host} in
 307 *-*-solaris2*)
 308   # Check for system-provided CRTs on Solaris 11.4.
 309   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 310                  [libgcc_cv_solaris_crts],
 311     [libgcc_cv_solaris_crts=no
 312      libgcc_sysroot="`${CC} -print-sysroot`"
 313      libgcc_libdir="$libgcc_sysroot/usr/lib"
 314      # At the time they were added, gcrt1.o became a symlink for backwards
 315      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 316      case ${host} in
 317        i?86-*-solaris2* | x86_64-*-solaris2*)
 318          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 319          ;;
 320        sparc*-*-solaris2*)
 321          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 322          ;;
 323      esac])
 324   if test $libgcc_cv_solaris_crts = yes; then
 325     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 326       [Define if the system-provided CRTs are present on Solaris.])
 327   fi
 328   ;;
 329 esac
 330
 331 # Determine the version of glibc, if any, used on the target.
 332 AC_MSG_CHECKING([for target glibc version])
 333 AC_ARG_WITH([glibc-version],
 334   [AS_HELP_STRING([--with-glibc-version=M.N],
 335     [assume GCC used with glibc version M.N or later])], [
 336 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 337   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 338   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 339 else
 340   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 341 fi], [
 342 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 343                                       [#include <features.h>],
 344                                       [glibc_version_major=0])
 345 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 346                                       [#include <features.h>],
 347                                       [glibc_version_minor=0])])
 348 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 349
 350 # Determine floating-point type for powerpc*-*-linux*.
 351 # Single-precision-only FPRs are not a supported configuration for
 352 # this target, so are not allowed for in this test.
 353 case ${host} in
 354 powerpc*-*-linux*)
 355   cat > conftest.c <<EOF
 356 #ifdef __powerpc64__
 357 ppc_fp_type=64
 358 #elif defined _SOFT_FLOAT
 359 ppc_fp_type=soft
 360 #elif defined _SOFT_DOUBLE
 361 ppc_fp_type=e500v1
 362 #elif defined __NO_FPRS__
 363 ppc_fp_type=e500v2
 364 #else
 365 ppc_fp_type=hard
 366 #endif
 367 EOF
 368 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 369 rm -f conftest.c
 370 # glibc 2.19 and later provide all the soft-fp functions, with proper
 371 # interactions with <fenv.h> exception and rounding mode handling, so
 372 # make libgcc's versions into compat symbols if a recent enough glibc
 373 # version is being used.
 374 ppc_fp_compat=
 375 case ${ppc_fp_type} in
 376 soft|e500v1|e500v2)
 377   if test $glibc_version_major -gt 2 \
 378     || ( test $glibc_version_major -eq 2 \
 379         && test $glibc_version_minor -ge 19 ); then
 380     ppc_fp_compat="t-softfp-compat"
 381   fi
 382   ;;
 383 esac
 384 ;;
 385 esac
 386
 387 case ${host} in
 388 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 389 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 390 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 391 # a new glibc is being used so that __builtin_cpu_supports can be used.
 392 powerpc*-*-linux*)
 393   saved_CFLAGS="$CFLAGS"
 394   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 395   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 396                  [libgcc_cv_powerpc_float128],
 397                  [AC_COMPILE_IFELSE(
 398     [vector double dadd (vector double a, vector double b) { return a + b; }],
 399     [libgcc_cv_powerpc_float128=yes],
 400     [libgcc_cv_powerpc_float128=no])])
 401
 402   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 403   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 404                  [libgcc_cv_powerpc_float128_hw],
 405                  [AC_COMPILE_IFELSE(
 406     [#include <sys/auxv.h>
 407      #ifndef AT_PLATFORM
 408      #error "AT_PLATFORM is not defined"
 409      #endif
 410      #ifndef __BUILTIN_CPU_SUPPORTS__
 411      #error "__builtin_cpu_supports is not available"
 412      #endif
 413      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 414      {
 415        vector unsigned char ret;
 416        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 417        return ret;
 418      }
 419      void *add_resolver (void) { return (void *) add; }
 420      __float128 add_ifunc (__float128, __float128)
 421         __attribute__ ((__ifunc__ ("add_resolver")));],
 422     [libgcc_cv_powerpc_float128_hw=yes],
 423     [libgcc_cv_powerpc_float128_hw=no])])
 424   CFLAGS="$saved_CFLAGS"
 425 esac
 426
 427 # Collect host-machine-specific information.
 428 . ${srcdir}/config.host
 429
 430 # Used for constructing correct paths for offload compilers.
 431 accel_dir_suffix=
 432 real_host_noncanonical=${host_noncanonical}
 433 if test x"$enable_as_accelerator_for" != x; then
 434   accel_dir_suffix=/accel/${target_noncanonical}
 435   real_host_noncanonical=${enable_as_accelerator_for}
 436 fi
 437 AC_SUBST(accel_dir_suffix)
 438 AC_SUBST(real_host_noncanonical)
 439
 440 if test x"$enable_offload_targets" != x; then
 441   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 442 fi
 443
 444 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 445 # This is after config.host so we can augment tmake_file.
 446 # Link with -nostartfiles -nodefaultlibs since neither are present while
 447 # building libgcc.
 448 case ${host} in
 449 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 450   cat > conftest.s <<EOF
 451         .section        .eh_frame,"a",@unwind
 452         .zero   4
 453         .section        .jcr,"aw",@progbits
 454         .zero   8
 455 EOF
 456   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 457       tmake_file="${tmake_file} i386/t-crtstuff"
 458   fi
 459   ;;
 460 esac
 461
 462 # Check if Solaris linker support v2 linker mapfile syntax.
 463 # Link with -nostartfiles -nodefaultlibs since neither are present while
 464 # building libgcc.
 465 case ${host} in
 466 *-*-solaris2*)
 467   solaris_ld_v2_maps=no
 468   echo 'int main(void) {return 0;}' > conftest.c
 469   echo '$mapfile_version 2' > conftest.map
 470   if AC_TRY_COMMAND([${CC-cc} -nostartfiles -nodefaultlibs -Wl,-M,conftest.map -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
 471       solaris_ld_v2_maps=yes
 472   fi
 473   ;;
 474 esac
 475 AC_SUBST(solaris_ld_v2_maps)
 476
 477 # Check if xtensa target is configured for windowed ABI and thus needs to use
 478 # custom unwind code.
 479 # This is after config.host so we can augment tmake_file.
 480 case ${host} in
 481 xtensa*-*)
 482   cat > conftest.c <<EOF
 483         #ifdef __XTENSA_CALL0_ABI__
 484         #error
 485         #endif
 486 EOF
 487   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 488       tmake_file="${tmake_file} xtensa/t-windowed"
 489   fi
 490   ;;
 491 esac
 492
 493 # Check for visibility support.  This is after config.host so that
 494 # we can check for asm_hidden_op.
 495 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 496     libgcc_cv_hidden_visibility_attribute, [
 497         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 498         libgcc_cv_hidden_visibility_attribute=no
 499         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 500             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 501                 libgcc_cv_hidden_visibility_attribute=yes
 502             fi
 503         fi
 504         rm -f conftest.*
 505     ])
 506
 507 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 508     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 509     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 510 else
 511     vis_hide=
 512 fi
 513 AC_SUBST(vis_hide)
 514
 515 # Check for .cfi_sections .debug_frame support.
 516 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 517     libgcc_cv_cfi_sections_directive, [
 518         echo 'int foo (int, char *);' > conftest.c
 519         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 520         libgcc_cv_cfi_sections_directive=no
 521         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 522             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 523                 libgcc_cv_cfi_sections_directive=yes
 524             fi
 525         fi
 526         rm -f conftest.*
 527     ])
 528 if test $libgcc_cv_cfi_sections_directive = yes; then
 529     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 530 fi
 531
 532 # See if we have thread-local storage.  We can only test assembler
 533 # since link-time and run-time tests require the newly built
 534 # gcc, which can't be used to build executable due to that libgcc
 535 # is yet to be built here.
 536 GCC_CHECK_CC_TLS
 537 set_have_cc_tls=
 538 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 539   set_have_cc_tls="-DHAVE_CC_TLS"
 540 fi
 541 AC_SUBST(set_have_cc_tls)
 542
 543 # See if we have emulated thread-local storage.
 544 GCC_CHECK_EMUTLS
 545 set_use_emutls=
 546 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 547   set_use_emutls="-DUSE_EMUTLS"
 548 fi
 549 AC_SUBST(set_use_emutls)
 550
 551 dnl Check if as supports AVX instructions.
 552 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 553 case "${target}" in
 554 i[[34567]]86-*-* | x86_64-*-*)
 555   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 556     AC_TRY_COMPILE([], [asm("vzeroupper");],
 557                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 558   ])
 559   if test x$libgcc_cv_as_avx = xyes; then
 560     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 561   fi
 562   ;;
 563 esac])
 564 LIBGCC_CHECK_AS_AVX
 565
 566 dnl Check if as supports RTM instructions.
 567 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 568 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 569   [[void ip (void) __attribute__ ((constructor (1)));]])],
 570   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 571 if test $libgcc_cv_init_priority = yes; then
 572   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 573   [Define if the compiler supports init priority.])
 574 fi
 575
 576 # Conditionalize the sfp-machine.h header for this target machine.
 577 if test -z "${sfp_machine_header}"; then
 578         sfp_machine_header=$cpu_type/sfp-machine.h
 579         if test -f ${srcdir}/config/${sfp_machine_header}; then
 580                 :
 581         else
 582                 sfp_machine_header=no-sfp-machine.h
 583         fi
 584 fi
 585 AC_SUBST(sfp_machine_header)
 586
 587 # Conditionalize the makefile for this target machine.
 588 tmake_file_=
 589 for f in ${tmake_file}
 590 do
 591         if test -f ${srcdir}/config/$f
 592         then
 593                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 594         fi
 595 done
 596 tmake_file="${tmake_file_}"
 597 AC_SUBST(tmake_file)
 598
 599 # Likewise export definitions for libgcc_tm.h
 600 tm_file_=
 601 for f in ${tm_file}
 602 do
 603         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 604 done
 605 tm_file="${tm_file_}"
 606 AC_SUBST(tm_file)
 607 AC_SUBST(tm_defines)
 608
 609 # Map from thread model to thread header.
 610 GCC_AC_THREAD_HEADER([$target_thread_file])
 611
 612 # Determine what GCC version number to use in filesystem paths.
 613 GCC_BASE_VER
 614
 615 # Substitute configuration variables
 616 AC_SUBST(cpu_type)
 617 AC_SUBST(extra_parts)
 618 AC_SUBST(asm_hidden_op)
 619 AC_SUBST(enable_execute_stack)
 620 AC_SUBST(unwind_header)
 621 AC_SUBST(md_unwind_header)
 622 AC_SUBST(sfp_machine_header)
 623 AC_SUBST(thread_header)
 624
 625 # We need multilib support.
 626 AC_CONFIG_FILES([Makefile])
 627 AC_CONFIG_COMMANDS([default],
 628   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 629 if test -n "$CONFIG_FILES"; then
 630   # FIXME: We shouldn't need to set ac_file
 631   ac_file=Makefile
 632   . ${libgcc_topdir}/config-ml.in
 633 fi]],
 634 [[srcdir=${srcdir}
 635 host=${host}
 636 with_target_subdir=${with_target_subdir}
 637 with_multisubdir=${with_multisubdir}
 638 ac_configure_args="--enable-multilib ${ac_configure_args}"
 639 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 640 libgcc_topdir=${libgcc_topdir}
 641 CC="${CC}"
 642 ]])
 643 AC_OUTPUT