libgfortran/acinclude.m4

   1 dnl Check:
   2 dnl * If we have gettimeofday;
   3 dnl * If we have struct timezone for use in calling it;
   4 dnl * If calling it with a timezone pointer actually works -- this is deemed
   5 dnl   obsolete or undefined on some systems which say you should use a null
   6 dnl   pointer -- and undefine HAVE_TIMEZONE if so;
   7 dnl * Whether it only takes one arg.
   8 AC_DEFUN([LIBGFOR_GETTIMEOFDAY], [
   9   AC_CHECK_FUNCS(gettimeofday)
  10   if test "$ac_cv_func_gettimeofday" = yes; then
  11     AC_CACHE_CHECK([for struct timezone], gfor_cv_struct_timezone,
  12       [AC_TRY_COMPILE([#include <sys/time.h>],
  13       [struct timezone tz;],
  14       gfor_cv_struct_timezone=yes, gfor_cv_struct_timezone=no)])
  15     if test $gfor_cv_struct_timezone = yes; then
  16       dnl It may be that we can't call gettimeofday with a non-null pointer.
  17       dnl In that case we'll lie about struct timezone.
  18       AC_TRY_RUN([
  19 #ifdef TIME_WITH_SYS_TIME
  20 #include <sys/time.h>
  21 #include <time.h>
  22 #else
  23 #ifdef HAVE_SYS_TIME_H
  24 #include <sys/time.h>
  25 #else
  26 #include <time.h>
  27 #endif
  28 #endif
  29 main ()
  30 {
  31   struct timeval time;
  32   struct timezone dummy;
  33   if (gettimeofday (&time, &dummy))
  34     exit (1);
  35   else
  36     exit (0);
  37 }],
  38         [gfor_have_struct_timezone=yes], [gfor_have_struct_timezone=no],
  39         [gfor_have_struct_timezone=yes])
  40       if test $gfor_have_struct_timezone = yes; then
  41         AC_DEFINE(HAVE_TIMEZONE, 1, [Do we have struct timezone])
  42       fi
  43     fi
  44     AC_REQUIRE([AC_HEADER_TIME])
  45     AC_CACHE_CHECK([whether gettimeofday can accept two arguments],
  46       emacs_cv_gettimeofday_two_arguments,
  47       [AC_TRY_LINK([
  48 #ifdef TIME_WITH_SYS_TIME
  49 #include <sys/time.h>
  50 #include <time.h>
  51 #else
  52 #ifdef HAVE_SYS_TIME_H
  53 #include <sys/time.h>
  54 #else
  55 #include <time.h>
  56 #endif
  57 #endif
  58       ],
  59       [
  60       struct timeval time;
  61 #ifdef HAVE_TIMEZONE
  62       struct timezone dummy;
  63 #define DUMMY &dummy
  64 #else
  65 #define DUMMY NULL
  66 #endif
  67       gettimeofday (&time, DUMMY);],
  68       emacs_cv_gettimeofday_two_arguments=yes,
  69       emacs_cv_gettimeofday_two_arguments=no)])
  70     if test $emacs_cv_gettimeofday_two_arguments = no; then
  71       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
  72         [Does gettimeofday take a single argument])
  73     fi
  74   fi])
  75
  76 sinclude(../libtool.m4)
  77 dnl The lines below arrange for aclocal not to bring an installed
  78 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
  79 dnl add a definition of LIBTOOL to Makefile.in.
  80 ifelse(,,,[AC_SUBST(LIBTOOL)
  81 AC_DEFUN([AM_PROG_LIBTOOL])
  82 AC_DEFUN([AC_LIBTOOL_DLOPEN])
  83 AC_DEFUN([AC_PROG_LD])
  84 ])
  85
  86 dnl Check whether the target is ILP32.
  87 AC_DEFUN([LIBGFOR_TARGET_ILP32], [
  88   AC_CACHE_CHECK([whether the target is ILP32], target_ilp32, [
  89   save_CFLAGS="$CFLAGS"
  90   CFLAGS="-O2"
  91   AC_TRY_LINK(,[
  92 if (sizeof(int) == 4 && sizeof(long) == 4 && sizeof(void *) == 4)
  93   ;
  94 else
  95   undefined_function ();
  96                ],
  97                target_ilp32=yes,
  98                target_ilp32=no)
  99   CFLAGS="$save_CFLAGS"])
 100   if test $target_ilp32 = yes; then
 101     AC_DEFINE(TARGET_ILP32, 1,
 102       [Define to 1 if the target is ILP32.])
 103   fi
 104   ])
 105
 106 dnl Check whether the target supports hidden visibility.
 107 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_VISIBILITY], [
 108   AC_CACHE_CHECK([whether the target supports hidden visibility],
 109                  have_attribute_visibility, [
 110   save_CFLAGS="$CFLAGS"
 111   CFLAGS="$CFLAGS -Werror"
 112   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
 113                  [], have_attribute_visibility=yes,
 114                  have_attribute_visibility=no)
 115   CFLAGS="$save_CFLAGS"])
 116   if test $have_attribute_visibility = yes; then
 117     AC_DEFINE(HAVE_ATTRIBUTE_VISIBILITY, 1,
 118       [Define to 1 if the target supports __attribute__((visibility(...))).])
 119   fi])
 120
 121 dnl Check whether the target supports dllexport
 122 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_DLLEXPORT], [
 123   AC_CACHE_CHECK([whether the target supports dllexport],
 124                  have_attribute_dllexport, [
 125   save_CFLAGS="$CFLAGS"
 126   CFLAGS="$CFLAGS -Werror"
 127   AC_TRY_COMPILE([void __attribute__((dllexport)) foo(void) { }],
 128                  [], have_attribute_dllexport=yes,
 129                  have_attribute_dllexport=no)
 130   CFLAGS="$save_CFLAGS"])
 131   if test $have_attribute_dllexport = yes; then
 132     AC_DEFINE(HAVE_ATTRIBUTE_DLLEXPORT, 1,
 133       [Define to 1 if the target supports __attribute__((dllexport)).])
 134   fi])
 135
 136 dnl Check whether the target supports symbol aliases.
 137 AC_DEFUN([LIBGFOR_CHECK_ATTRIBUTE_ALIAS], [
 138   AC_CACHE_CHECK([whether the target supports symbol aliases],
 139                  have_attribute_alias, [
 140   AC_TRY_LINK([
 141 #define ULP     STR1(__USER_LABEL_PREFIX__)
 142 #define STR1(x) STR2(x)
 143 #define STR2(x) #x
 144 void foo(void) { }
 145 extern void bar(void) __attribute__((alias(ULP "foo")));],
 146     [bar();], have_attribute_alias=yes, have_attribute_alias=no)])
 147   if test $have_attribute_alias = yes; then
 148     AC_DEFINE(HAVE_ATTRIBUTE_ALIAS, 1,
 149       [Define to 1 if the target supports __attribute__((alias(...))).])
 150   fi])
 151
 152 dnl Check whether the target supports __sync_fetch_and_add.
 153 AC_DEFUN([LIBGFOR_CHECK_SYNC_FETCH_AND_ADD], [
 154   AC_CACHE_CHECK([whether the target supports __sync_fetch_and_add],
 155                  have_sync_fetch_and_add, [
 156   AC_TRY_LINK([int foovar = 0;], [
 157 if (foovar <= 0) return __sync_fetch_and_add (&foovar, 1);
 158 if (foovar > 10) return __sync_add_and_fetch (&foovar, -1);],
 159               have_sync_fetch_and_add=yes, have_sync_fetch_and_add=no)])
 160   if test $have_sync_fetch_and_add = yes; then
 161     AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD, 1,
 162               [Define to 1 if the target supports __sync_fetch_and_add])
 163   fi])
 164
 165 dnl Check if threads are supported.
 166 AC_DEFUN([LIBGFOR_CHECK_GTHR_DEFAULT], [
 167   AC_CACHE_CHECK([configured target thread model],
 168                  target_thread_file, [
 169 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`])
 170
 171   if test $target_thread_file != single; then
 172     AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
 173               [Define if the compiler has a thread header that is non single.])
 174   fi])
 175
 176 dnl Check for pragma weak.
 177 AC_DEFUN([LIBGFOR_GTHREAD_WEAK], [
 178   AC_CACHE_CHECK([whether pragma weak works],
 179                  have_pragma_weak, [
 180   gfor_save_CFLAGS="$CFLAGS"
 181   CFLAGS="$CFLAGS -Wunknown-pragmas"
 182   AC_TRY_COMPILE([void foo (void);
 183 #pragma weak foo], [if (foo) foo ();],
 184                  have_pragma_weak=yes, have_pragma_weak=no)])
 185   if test $have_pragma_weak = yes; then
 186     AC_DEFINE(SUPPORTS_WEAK, 1,
 187               [Define to 1 if the target supports #pragma weak])
 188   fi
 189   case "$host" in
 190     *-*-darwin* | *-*-hpux* | *-*-cygwin*)
 191       AC_DEFINE(GTHREAD_USE_WEAK, 0,
 192                 [Define to 0 if the target shouldn't use #pragma weak])
 193       ;;
 194   esac])
 195
 196 dnl Check whether target can unlink a file still open.
 197 AC_DEFUN([LIBGFOR_CHECK_UNLINK_OPEN_FILE], [
 198   AC_CACHE_CHECK([whether the target can unlink an open file],
 199                   have_unlink_open_file, [
 200   AC_TRY_RUN([
 201 #include <errno.h>
 202 #include <fcntl.h>
 203 #include <unistd.h>
 204 #include <sys/stat.h>
 205
 206 int main ()
 207 {
 208   int fd;
 209
 210   fd = open ("testfile", O_RDWR | O_CREAT, S_IWRITE | S_IREAD);
 211   if (fd <= 0)
 212     return 0;
 213   if (unlink ("testfile") == -1)
 214     return 1;
 215   write (fd, "This is a test\n", 15);
 216   close (fd);
 217
 218   if (open ("testfile", O_RDONLY, S_IWRITE | S_IREAD) == -1 && errno == ENOENT)
 219     return 0;
 220   else
 221     return 1;
 222 }], have_unlink_open_file=yes, have_unlink_open_file=no, [
 223 case "${target}" in
 224   *mingw*) have_unlink_open_file=no ;;
 225   *) have_unlink_open_file=yes;;
 226 esac])])
 227 if test x"$have_unlink_open_file" = xyes; then
 228   AC_DEFINE(HAVE_UNLINK_OPEN_FILE, 1, [Define if target can unlink open files.])
 229 fi])
 230
 231 dnl Check whether CRLF is the line terminator
 232 AC_DEFUN([LIBGFOR_CHECK_CRLF], [
 233   AC_CACHE_CHECK([whether the target has CRLF as line terminator],
 234                   have_crlf, [
 235   AC_TRY_RUN([
 236 /* This test program should exit with status 0 if system uses a CRLF as
 237    line terminator, and status 1 otherwise.
 238    Since it is used to check for mingw systems, and should return 0 in any
 239    other case, in case of a failure we will not use CRLF.  */
 240 #include <sys/stat.h>
 241 #include <stdlib.h>
 242 #include <fcntl.h>
 243 #include <stdio.h>
 244
 245 int main ()
 246 {
 247 #ifndef O_BINARY
 248   exit(1);
 249 #else
 250   int fd, bytes;
 251   char buff[5];
 252
 253   fd = open ("foo", O_WRONLY | O_CREAT | O_TRUNC, S_IRWXU);
 254   if (fd < 0)
 255     exit(1);
 256   if (write (fd, "\n", 1) < 0)
 257     perror ("write");
 258
 259   close (fd);
 260
 261   if ((fd = open ("foo", O_RDONLY | O_BINARY, S_IRWXU)) < 0)
 262     exit(1);
 263   bytes = read (fd, buff, 5);
 264   if (bytes == 2 && buff[0] == '\r' && buff[1] == '\n')
 265     exit(0);
 266   else
 267     exit(1);
 268 #endif
 269 }], have_crlf=yes, have_crlf=no, [
 270 case "${target}" in
 271   *mingw*) have_crlf=yes ;;
 272   *) have_crlf=no;;
 273 esac])])
 274 if test x"$have_crlf" = xyes; then
 275   AC_DEFINE(HAVE_CRLF, 1, [Define if CRLF is line terminator.])
 276 fi])
 277
 278 dnl Check whether isfinite is broken.
 279 dnl The most common problem is that it does not work on long doubles.
 280 AC_DEFUN([LIBGFOR_CHECK_FOR_BROKEN_ISFINITE], [
 281   AC_CACHE_CHECK([whether isfinite is broken],
 282                   have_broken_isfinite, [
 283   libgfor_check_for_broken_isfinite_save_LIBS=$LIBS
 284   LIBS="$LIBS -lm"
 285   AC_TRY_RUN([
 286 #ifdef HAVE_MATH_H
 287 #include <math.h>
 288 #endif
 289 #include <float.h>
 290 int main ()
 291 {
 292 #ifdef isfinite
 293 #ifdef LDBL_MAX
 294   if (!isfinite(LDBL_MAX)) return 1;
 295 #endif
 296 #ifdef DBL_MAX
 297   if (!isfinite(DBL_MAX)) return 1;
 298 #endif
 299 #endif
 300 return 0;
 301 }], have_broken_isfinite=no, have_broken_isfinite=yes, [
 302 case "${target}" in
 303   hppa*-*-hpux*) have_broken_isfinite=yes ;;
 304   *) have_broken_isfinite=no ;;
 305 esac])]
 306   LIBS=$libgfor_check_for_broken_isfinite_save_LIBS)
 307 if test x"$have_broken_isfinite" = xyes; then
 308   AC_DEFINE(HAVE_BROKEN_ISFINITE, 1, [Define if isfinite is broken.])
 309 fi])
 310
 311 dnl Check whether isnan is broken.
 312 dnl The most common problem is that it does not work on long doubles.
 313 AC_DEFUN([LIBGFOR_CHECK_FOR_BROKEN_ISNAN], [
 314   AC_CACHE_CHECK([whether isnan is broken],
 315                   have_broken_isnan, [
 316   libgfor_check_for_broken_isnan_save_LIBS=$LIBS
 317   LIBS="$LIBS -lm"
 318   AC_TRY_RUN([
 319 #ifdef HAVE_MATH_H
 320 #include <math.h>
 321 #endif
 322 #include <float.h>
 323 int main ()
 324 {
 325 #ifdef isnan
 326 #ifdef LDBL_MAX
 327   {
 328     long double x;
 329     x = __builtin_nanl ("");
 330     if (!isnan(x)) return 1;
 331     if (isnan(LDBL_MAX)) return 1;
 332 #ifdef NAN
 333     x = (long double) NAN;
 334     if (!isnan(x)) return 1;
 335 #endif
 336   }
 337 #endif
 338 #ifdef DBL_MAX
 339   {
 340     double y;
 341     y = __builtin_nan ("");
 342     if (!isnan(y)) return 1;
 343     if (isnan(DBL_MAX)) return 1;
 344 #ifdef NAN
 345     y = (double) NAN;
 346     if (!isnan(y)) return 1;
 347 #endif
 348   }
 349 #endif
 350 #endif
 351 return 0;
 352 }], have_broken_isnan=no, have_broken_isnan=yes, [
 353 case "${target}" in
 354   hppa*-*-hpux*) have_broken_isnan=yes ;;
 355   *) have_broken_isnan=no ;;
 356 esac])]
 357   LIBS=$libgfor_check_for_broken_isnan_save_LIBS)
 358 if test x"$have_broken_isnan" = xyes; then
 359   AC_DEFINE(HAVE_BROKEN_ISNAN, 1, [Define if isnan is broken.])
 360 fi])
 361
 362 dnl Check whether fpclassify is broken.
 363 dnl The most common problem is that it does not work on long doubles.
 364 AC_DEFUN([LIBGFOR_CHECK_FOR_BROKEN_FPCLASSIFY], [
 365   AC_CACHE_CHECK([whether fpclassify is broken],
 366                   have_broken_fpclassify, [
 367   libgfor_check_for_broken_fpclassify_save_LIBS=$LIBS
 368   LIBS="$LIBS -lm"
 369   AC_TRY_RUN([
 370 #ifdef HAVE_MATH_H
 371 #include <math.h>
 372 #endif
 373 #include <float.h>
 374 int main ()
 375 {
 376 #ifdef fpclassify
 377 #ifdef LDBL_MAX
 378         if (fpclassify(LDBL_MAX) == FP_NAN
 379             || fpclassify(LDBL_MAX) == FP_INFINITE) return 1;
 380 #endif
 381 #ifdef DBL_MAX
 382         if (fpclassify(DBL_MAX) == FP_NAN
 383             || fpclassify(DBL_MAX) == FP_INFINITE) return 1;
 384 #endif
 385 #endif
 386 return 0;
 387 }], have_broken_fpclassify=no, have_broken_fpclassify=yes, [
 388 case "${target}" in
 389   hppa*-*-hpux*) have_broken_fpclassify=yes ;;
 390   *) have_broken_fpclassify=no ;;
 391 esac])]
 392   LIBS=$libgfor_check_for_broken_fpclassify_save_LIBS)
 393 if test x"$have_broken_fpclassify" = xyes; then
 394   AC_DEFINE(HAVE_BROKEN_FPCLASSIFY, 1, [Define if fpclassify is broken.])
 395 fi])
 396
 397 dnl Check whether the st_ino and st_dev stat fields taken together uniquely
 398 dnl identify the file within the system. This is should be true for POSIX
 399 dnl systems; it is known to be false on mingw32.
 400 AC_DEFUN([LIBGFOR_CHECK_WORKING_STAT], [
 401   AC_CACHE_CHECK([whether the target stat is reliable],
 402                   have_working_stat, [
 403   AC_TRY_RUN([
 404 #include <stdio.h>
 405 #include <sys/types.h>
 406 #include <sys/stat.h>
 407 #include <unistd.h>
 408
 409 int main ()
 410 {
 411   FILE *f, *g;
 412   struct stat st1, st2;
 413
 414   f = fopen ("foo", "w");
 415   g = fopen ("bar", "w");
 416   if (stat ("foo", &st1) != 0 || stat ("bar", &st2))
 417     return 1;
 418   if (st1.st_dev == st2.st_dev && st1.st_ino == st2.st_ino)
 419     return 1;
 420   fclose(f);
 421   fclose(g);
 422   return 0;
 423 }], have_working_stat=yes, have_working_stat=no, [
 424 case "${target}" in
 425   *mingw*) have_working_stat=no ;;
 426   *) have_working_stat=yes;;
 427 esac])])
 428 if test x"$have_working_stat" = xyes; then
 429   AC_DEFINE(HAVE_WORKING_STAT, 1, [Define if target has a reliable stat.])
 430 fi])
 431
 432 dnl Checks for fpsetmask function.
 433 AC_DEFUN([LIBGFOR_CHECK_FPSETMASK], [
 434   AC_CACHE_CHECK([whether fpsetmask is present], have_fpsetmask, [
 435     AC_TRY_LINK([
 436 #if HAVE_FLOATINGPOINT_H
 437 # include <floatingpoint.h>
 438 #endif /* HAVE_FLOATINGPOINT_H */
 439 #if HAVE_IEEEFP_H
 440 # include <ieeefp.h>
 441 #endif /* HAVE_IEEEFP_H */],[fpsetmask(0);],
 442     eval "have_fpsetmask=yes", eval "have_fpsetmask=no")
 443   ])
 444   if test x"$have_fpsetmask" = xyes; then
 445     AC_DEFINE(HAVE_FPSETMASK, 1, [Define if you have fpsetmask.])
 446   fi
 447 ])