libgfortran/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Fortran Runtime Library], 0.3,,[libgfortran])
   5 AC_CONFIG_HEADER(config.h)
   6 GCC_TOPLEV_SUBDIRS
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 AC_ARG_ENABLE(version-specific-runtime-libs,
  14 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  15   [specify that runtime libraries should be installed in a compiler-specific directory]),
  16 [case "$enableval" in
  17  yes) version_specific_libs=yes ;;
  18  no)  version_specific_libs=no ;;
  19  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  20  esac],
  21 [version_specific_libs=no])
  22 AC_MSG_RESULT($version_specific_libs)
  23
  24 # Build with intermodule optimisations
  25 AC_MSG_CHECKING([for --enable-intermodule])
  26 AC_ARG_ENABLE(intermodule,
  27 AS_HELP_STRING([--enable-intermodule],[build the library in one step]),
  28 [case "$enable_intermodule" in
  29   yes) onestep="-onestep";;
  30     *) onestep="";;
  31 esac],
  32 [onestep=""])
  33 AC_MSG_RESULT($enable_intermodule)
  34 AM_CONDITIONAL(onestep,[test x$onestep = x-onestep])
  35 AC_SUBST(onestep)
  36
  37 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  38 #
  39 # You will slowly go insane if you do not grok the following fact:  when
  40 # building this library, the top-level /target/ becomes the library's /host/.
  41 #
  42 # configure then causes --target to default to --host, exactly like any
  43 # other package using autoconf.  Therefore, 'target' and 'host' will
  44 # always be the same.  This makes sense both for native and cross compilers
  45 # just think about it for a little while.  :-)
  46 #
  47 # Also, if this library is being configured as part of a cross compiler, the
  48 # top-level configure script will pass the "real" host as $with_cross_host.
  49 #
  50 # Do not delete or change the following two lines.  For why, see
  51 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  52 AC_CANONICAL_SYSTEM
  53 ACX_NONCANONICAL_TARGET
  54
  55 target_alias=${target_alias-$host_alias}
  56 AC_SUBST(target_alias)
  57
  58 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  59 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  60 #  1.9.6:  minimum required version
  61 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  62 #              of other PACKAGE_* variables will, however, and there's nothing
  63 #              we can do about that; they come from AC_INIT).
  64 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  65 #            file in the top srcdir, etc, etc), so stop complaining.
  66 #  no-dist:  we don't want 'dist' and related rules.
  67 #  -Wall:  turns on all automake warnings...
  68 #  -Wno-portability:  ...except this one, since GNU make is required.
  69 AM_INIT_AUTOMAKE([1.9.6 no-define foreign no-dist -Wall -Wno-portability])
  70
  71 AM_MAINTAINER_MODE
  72 AM_ENABLE_MULTILIB(, ..)
  73
  74 # Handy for debugging:
  75 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  76
  77 # Are we being configured with some form of cross compiler?
  78 # NB: We don't actually need to know this just now, but when, say, a test
  79 #     suite is included, we'll have to know.
  80 if test "$build" != "$host"; then
  81   LIBGFOR_IS_NATIVE=false
  82   GCC_NO_EXECUTABLES
  83 else
  84   LIBGFOR_IS_NATIVE=true
  85 fi
  86
  87 AC_USE_SYSTEM_EXTENSIONS
  88
  89 GCC_WITH_TOOLEXECLIBDIR
  90
  91 # Calculate toolexeclibdir
  92 # Also toolexecdir, though it's only used in toolexeclibdir
  93 case ${version_specific_libs} in
  94   yes)
  95     # Need the gcc compiler version to know where to install libraries
  96     # and header files if --enable-version-specific-runtime-libs option
  97     # is selected.
  98     toolexecdir='$(libdir)/gcc/$(target_alias)'
  99     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 100     ;;
 101   no)
 102     if test -n "$with_cross_host" &&
 103        test x"$with_cross_host" != x"no"; then
 104       # Install a library built with a cross compiler in tooldir, not libdir.
 105       toolexecdir='$(exec_prefix)/$(target_alias)'
 106       case ${with_toolexeclibdir} in
 107         no)
 108           toolexeclibdir='$(toolexecdir)/lib'
 109           ;;
 110         *)
 111           toolexeclibdir=${with_toolexeclibdir}
 112           ;;
 113       esac
 114     else
 115       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 116       toolexeclibdir='$(libdir)'
 117     fi
 118     multi_os_directory=`$CC -print-multi-os-directory`
 119     case $multi_os_directory in
 120       .) ;; # Avoid trailing /.
 121       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 122     esac
 123     ;;
 124 esac
 125 AC_SUBST(toolexecdir)
 126 AC_SUBST(toolexeclibdir)
 127
 128 # Create a spec file, so that compile/link tests don't fail
 129 test -f libgfortran.spec || touch libgfortran.spec
 130
 131 AC_LANG_C
 132 # Check the compiler.
 133 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 134 # We must force CC to /not/ be precious variables; otherwise
 135 # the wrong, non-multilib-adjusted value will be used in multilibs.
 136 # As a side effect, we have to subst CFLAGS ourselves.
 137
 138 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 139 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 140 AC_PROG_CC
 141 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 142
 143 AC_SUBST(CFLAGS)
 144
 145 AM_PROG_CC_C_O
 146
 147 # Add -Wall -fno-repack-arrays -fno-underscoring if we are using GCC.
 148 if test "x$GCC" = "xyes"; then
 149   AM_FCFLAGS="-I . -Wall -Werror -fimplicit-none -fno-repack-arrays -fno-underscoring"
 150   ## We like to use C11 and C99 routines when available.  This makes
 151   ## sure that
 152   ## __STDC_VERSION__ is set such that libc includes make them available.
 153   AM_CFLAGS="-std=gnu11 -Wall -Wstrict-prototypes -Wmissing-prototypes -Wold-style-definition -Wextra -Wwrite-strings -Werror=implicit-function-declaration -Werror=vla"
 154   ## Compile the following tests with the same system header contents
 155   ## that we'll encounter when compiling our own source files.
 156   CFLAGS="-std=gnu11 $CFLAGS"
 157 fi
 158
 159 # Add CET specific flags if CET is enabled
 160 GCC_CET_FLAGS(CET_FLAGS)
 161 AM_FCFLAGS="$AM_FCFLAGS $CET_FLAGS"
 162 AM_CFLAGS="$AM_CFLAGS $CET_FLAGS"
 163 CFLAGS="$CFLAGS $CET_FLAGS"
 164
 165 AC_SUBST(AM_FCFLAGS)
 166 AC_SUBST(AM_CFLAGS)
 167 AC_SUBST(CFLAGS)
 168
 169 # Check for symbol versioning (copied from libssp).
 170 AC_MSG_CHECKING([whether symbol versioning is supported])
 171 AC_ARG_ENABLE(symvers,
 172 AS_HELP_STRING([--disable-symvers],
 173   [disable symbol versioning for libgfortran]),
 174 gfortran_use_symver=$enableval,
 175 gfortran_use_symver=yes)
 176 if test "x$gfortran_use_symver" != xno; then
 177   save_LDFLAGS="$LDFLAGS"
 178   LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 179   cat > conftest.map <<EOF
 180 FOO_1.0 {
 181   global: *foo*; bar; local: *;
 182 };
 183 EOF
 184   AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=gnu],[gfortran_use_symver=no])
 185   if test x$gfortran_use_symver = xno; then
 186     case "$target_os" in
 187       solaris2*)
 188         LDFLAGS="$save_LDFLAGS"
 189         LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 190         # Sun ld cannot handle wildcards and treats all entries as undefined.
 191         cat > conftest.map <<EOF
 192 FOO_1.0 {
 193   global: foo; local: *;
 194 };
 195 EOF
 196         AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=sun],[gfortran_use_symver=no])
 197         ;;
 198     esac
 199   fi
 200   LDFLAGS="$save_LDFLAGS"
 201 fi
 202 AC_MSG_RESULT($gfortran_use_symver)
 203 AM_CONDITIONAL(LIBGFOR_USE_SYMVER, [test "x$gfortran_use_symver" != xno])
 204 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_GNU, [test "x$gfortran_use_symver" = xgnu])
 205 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_SUN, [test "x$gfortran_use_symver" = xsun])
 206
 207 # For GPU offloading, not everything in libfortran can be supported.
 208 # Currently, the only target that has this problem is nvptx.  The
 209 # following is a (partial) list of features that are unsupportable on
 210 # this particular target:
 211 # * Constructors
 212 # * alloca
 213 # * C library support for I/O, with printf as the one notable exception
 214 # * C library support for other features such as signal, environment
 215 #   variables, time functions
 216
 217 AM_CONDITIONAL(LIBGFOR_MINIMAL, [test "x${target_cpu}" = xnvptx])
 218
 219 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
 220 # similarly to how libstdc++ does it
 221 ac_test_CFLAGS="${CFLAGS+set}"
 222 ac_save_CFLAGS="$CFLAGS"
 223
 224 # Check for -ffunction-sections -fdata-sections
 225 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
 226 CFLAGS='-Werror -ffunction-sections -fdata-sections'
 227 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int foo;]])], [ac_fdsections=yes], [ac_fdsections=no])
 228 if test "$ac_test_CFLAGS" = set; then
 229   CFLAGS="$ac_save_CFLAGS"
 230 else
 231   # this is the suspicious part
 232   CFLAGS=""
 233 fi
 234 if test x"$ac_fdsections" = x"yes"; then
 235   SECTION_FLAGS='-ffunction-sections -fdata-sections'
 236 fi
 237 AC_MSG_RESULT($ac_fdsections)
 238 AC_SUBST(SECTION_FLAGS)
 239
 240 # Check linker hardware capability support.
 241 GCC_CHECK_LINKER_HWCAP
 242
 243 # Find other programs we need.
 244 AC_CHECK_TOOL(AS, as)
 245 AC_CHECK_TOOL(AR, ar)
 246 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 247 AC_PROG_MAKE_SET
 248 AC_PROG_INSTALL
 249
 250 # Configure libtool
 251 #AC_MSG_NOTICE([====== Starting libtool configuration])
 252 AC_LIBTOOL_DLOPEN
 253 AM_PROG_LIBTOOL
 254 ACX_LT_HOST_FLAGS
 255 AC_SUBST(enable_shared)
 256 AC_SUBST(enable_static)
 257 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
 258
 259 # We need gfortran to compile parts of the library
 260 #AC_PROG_FC(gfortran)
 261 FC="$GFORTRAN"
 262 AC_PROG_FC(gfortran)
 263
 264 # extra LD Flags which are required for targets
 265 case "${host}" in
 266   *-darwin*)
 267     # Darwin needs -single_module when linking libgfortran
 268     extra_ldflags_libgfortran=-Wl,-single_module
 269     ;;
 270 esac
 271 AC_SUBST(extra_ldflags_libgfortran)
 272
 273 # We need a working compiler at that point, otherwise give a clear
 274 # error message and bail out.
 275 LIBGFOR_WORKING_GFORTRAN
 276
 277 AC_SYS_LARGEFILE
 278
 279 # Types
 280 AC_TYPE_OFF_T
 281 AC_TYPE_INTPTR_T
 282 AC_TYPE_UINTPTR_T
 283 AC_CHECK_TYPES([ptrdiff_t])
 284
 285 # check header files (we assume C89 is available, so don't check for that)
 286 AC_CHECK_HEADERS_ONCE(unistd.h sys/random.h sys/time.h sys/times.h \
 287 sys/resource.h sys/types.h sys/stat.h sys/uio.h sys/wait.h \
 288 floatingpoint.h ieeefp.h fenv.h fptrap.h \
 289 fpxcp.h pwd.h complex.h xlocale.h)
 290
 291 GCC_HEADER_STDINT(gstdint.h)
 292
 293 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct stat.st_rdev])
 294
 295 case "${host}--x${with_newlib}" in
 296   mips*--xyes)
 297     hardwire_newlib=1;;
 298   nvptx*--xyes)
 299     hardwire_newlib=1;;
 300 esac
 301
 302 # Check for library functions.
 303 if test "${hardwire_newlib:-0}" -eq 1; then
 304    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 305    # may not work correctly, because the compiler may not be able to
 306    # link executables.
 307    AC_DEFINE(HAVE_MKSTEMP, 1, [Define if you have mkstemp.])
 308    AC_DEFINE(HAVE_STRTOF, 1, [Define if you have strtof.])
 309    AC_DEFINE(HAVE_SNPRINTF, 1, [Define if you have snprintf.])
 310    AC_DEFINE(HAVE_VSNPRINTF, 1, [Define if you have vsnprintf.])
 311    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have localtime_r.])
 312    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have gmtime_r.])
 313    AC_DEFINE(HAVE_STRNLEN, 1, [Define if you have strnlen.])
 314    AC_DEFINE(HAVE_STRNDUP, 1, [Define if you have strndup.])
 315
 316    # At some point, we should differentiate between architectures
 317    # like x86, which have long double versions, and alpha/powerpc/etc.,
 318    # which don't. For the time being, punt.
 319    if test x"long_double_math_on_this_cpu" = x"yes"; then
 320      AC_DEFINE(HAVE_STRTOLD, 1, [Define if you have strtold.])
 321    fi
 322 else
 323    AC_CHECK_FUNCS_ONCE(getrusage times mkstemp strtof strtold snprintf \
 324    ftruncate chsize chdir getentropy getlogin gethostname kill link symlink \
 325    sleep ttyname sigaction waitpid \
 326    alarm access fork posix_spawn setmode fcntl writev \
 327    gettimeofday stat fstat lstat getpwuid vsnprintf dup \
 328    getcwd localtime_r gmtime_r getpwuid_r ttyname_r clock_gettime \
 329    getgid getpid getuid geteuid umask getegid \
 330    secure_getenv __secure_getenv mkostemp strnlen strndup newlocale \
 331    freelocale uselocale strerror_l)
 332 fi
 333
 334 # Check strerror_r, cannot be above as versions with two and three arguments exist
 335 LIBGFOR_CHECK_STRERROR_R
 336
 337 # Check for C99 (and other IEEE) math functions
 338 GCC_CHECK_MATH_FUNC([acosf])
 339 GCC_CHECK_MATH_FUNC([acos])
 340 GCC_CHECK_MATH_FUNC([acosl])
 341 GCC_CHECK_MATH_FUNC([acoshf])
 342 GCC_CHECK_MATH_FUNC([acosh])
 343 GCC_CHECK_MATH_FUNC([acoshl])
 344 GCC_CHECK_MATH_FUNC([asinf])
 345 GCC_CHECK_MATH_FUNC([asin])
 346 GCC_CHECK_MATH_FUNC([asinl])
 347 GCC_CHECK_MATH_FUNC([asinhf])
 348 GCC_CHECK_MATH_FUNC([asinh])
 349 GCC_CHECK_MATH_FUNC([asinhl])
 350 GCC_CHECK_MATH_FUNC([atan2f])
 351 GCC_CHECK_MATH_FUNC([atan2])
 352 GCC_CHECK_MATH_FUNC([atan2l])
 353 GCC_CHECK_MATH_FUNC([atanf])
 354 GCC_CHECK_MATH_FUNC([atan])
 355 GCC_CHECK_MATH_FUNC([atanl])
 356 GCC_CHECK_MATH_FUNC([atanhf])
 357 GCC_CHECK_MATH_FUNC([atanh])
 358 GCC_CHECK_MATH_FUNC([atanhl])
 359 GCC_CHECK_MATH_FUNC([cargf])
 360 GCC_CHECK_MATH_FUNC([carg])
 361 GCC_CHECK_MATH_FUNC([cargl])
 362 GCC_CHECK_MATH_FUNC([ceilf])
 363 GCC_CHECK_MATH_FUNC([ceil])
 364 GCC_CHECK_MATH_FUNC([ceill])
 365 GCC_CHECK_MATH_FUNC([copysignf])
 366 GCC_CHECK_MATH_FUNC([copysign])
 367 GCC_CHECK_MATH_FUNC([copysignl])
 368 GCC_CHECK_MATH_FUNC([cosf])
 369 GCC_CHECK_MATH_FUNC([cos])
 370 GCC_CHECK_MATH_FUNC([cosl])
 371 GCC_CHECK_MATH_FUNC([ccosf])
 372 GCC_CHECK_MATH_FUNC([ccos])
 373 GCC_CHECK_MATH_FUNC([ccosl])
 374 GCC_CHECK_MATH_FUNC([coshf])
 375 GCC_CHECK_MATH_FUNC([cosh])
 376 GCC_CHECK_MATH_FUNC([coshl])
 377 GCC_CHECK_MATH_FUNC([ccoshf])
 378 GCC_CHECK_MATH_FUNC([ccosh])
 379 GCC_CHECK_MATH_FUNC([ccoshl])
 380 GCC_CHECK_MATH_FUNC([expf])
 381 GCC_CHECK_MATH_FUNC([exp])
 382 GCC_CHECK_MATH_FUNC([expl])
 383 GCC_CHECK_MATH_FUNC([cexpf])
 384 GCC_CHECK_MATH_FUNC([cexp])
 385 GCC_CHECK_MATH_FUNC([cexpl])
 386 GCC_CHECK_MATH_FUNC([fabsf])
 387 GCC_CHECK_MATH_FUNC([fabs])
 388 GCC_CHECK_MATH_FUNC([fabsl])
 389 GCC_CHECK_MATH_FUNC([cabsf])
 390 GCC_CHECK_MATH_FUNC([cabs])
 391 GCC_CHECK_MATH_FUNC([cabsl])
 392 GCC_CHECK_MATH_FUNC([floorf])
 393 GCC_CHECK_MATH_FUNC([floor])
 394 GCC_CHECK_MATH_FUNC([floorl])
 395 GCC_CHECK_MATH_FUNC([fmaf])
 396 GCC_CHECK_MATH_FUNC([fma])
 397 GCC_CHECK_MATH_FUNC([fmal])
 398 GCC_CHECK_MATH_FUNC([fmodf])
 399 GCC_CHECK_MATH_FUNC([fmod])
 400 GCC_CHECK_MATH_FUNC([fmodl])
 401 GCC_CHECK_MATH_FUNC([frexpf])
 402 GCC_CHECK_MATH_FUNC([frexp])
 403 GCC_CHECK_MATH_FUNC([frexpl])
 404 GCC_CHECK_MATH_FUNC([hypotf])
 405 GCC_CHECK_MATH_FUNC([hypot])
 406 GCC_CHECK_MATH_FUNC([hypotl])
 407 GCC_CHECK_MATH_FUNC([ldexpf])
 408 GCC_CHECK_MATH_FUNC([ldexp])
 409 GCC_CHECK_MATH_FUNC([ldexpl])
 410 GCC_CHECK_MATH_FUNC([logf])
 411 GCC_CHECK_MATH_FUNC([log])
 412 GCC_CHECK_MATH_FUNC([logl])
 413 GCC_CHECK_MATH_FUNC([clogf])
 414 GCC_CHECK_MATH_FUNC([clog])
 415 GCC_CHECK_MATH_FUNC([clogl])
 416 GCC_CHECK_MATH_FUNC([log10f])
 417 GCC_CHECK_MATH_FUNC([log10])
 418 GCC_CHECK_MATH_FUNC([log10l])
 419 GCC_CHECK_MATH_FUNC([clog10f])
 420 GCC_CHECK_MATH_FUNC([clog10])
 421 GCC_CHECK_MATH_FUNC([clog10l])
 422 GCC_CHECK_MATH_FUNC([nextafterf])
 423 GCC_CHECK_MATH_FUNC([nextafter])
 424 GCC_CHECK_MATH_FUNC([nextafterl])
 425 GCC_CHECK_MATH_FUNC([powf])
 426 GCC_CHECK_MATH_FUNC([pow])
 427 GCC_CHECK_MATH_FUNC([cpowf])
 428 GCC_CHECK_MATH_FUNC([cpow])
 429 GCC_CHECK_MATH_FUNC([cpowl])
 430 GCC_CHECK_MATH_FUNC([roundf])
 431 GCC_CHECK_MATH_FUNC([round])
 432 GCC_CHECK_MATH_FUNC([roundl])
 433 GCC_CHECK_MATH_FUNC([lroundf])
 434 GCC_CHECK_MATH_FUNC([lround])
 435 GCC_CHECK_MATH_FUNC([lroundl])
 436 GCC_CHECK_MATH_FUNC([llroundf])
 437 GCC_CHECK_MATH_FUNC([llround])
 438 GCC_CHECK_MATH_FUNC([llroundl])
 439 GCC_CHECK_MATH_FUNC([scalbnf])
 440 GCC_CHECK_MATH_FUNC([scalbn])
 441 GCC_CHECK_MATH_FUNC([scalbnl])
 442 GCC_CHECK_MATH_FUNC([sinf])
 443 GCC_CHECK_MATH_FUNC([sin])
 444 GCC_CHECK_MATH_FUNC([sinl])
 445 GCC_CHECK_MATH_FUNC([csinf])
 446 GCC_CHECK_MATH_FUNC([csin])
 447 GCC_CHECK_MATH_FUNC([csinl])
 448 GCC_CHECK_MATH_FUNC([sinhf])
 449 GCC_CHECK_MATH_FUNC([sinh])
 450 GCC_CHECK_MATH_FUNC([sinhl])
 451 GCC_CHECK_MATH_FUNC([csinhf])
 452 GCC_CHECK_MATH_FUNC([csinh])
 453 GCC_CHECK_MATH_FUNC([csinhl])
 454 GCC_CHECK_MATH_FUNC([sqrtf])
 455 GCC_CHECK_MATH_FUNC([sqrt])
 456 GCC_CHECK_MATH_FUNC([sqrtl])
 457 GCC_CHECK_MATH_FUNC([csqrtf])
 458 GCC_CHECK_MATH_FUNC([csqrt])
 459 GCC_CHECK_MATH_FUNC([csqrtl])
 460 GCC_CHECK_MATH_FUNC([tanf])
 461 GCC_CHECK_MATH_FUNC([tan])
 462 GCC_CHECK_MATH_FUNC([tanl])
 463 GCC_CHECK_MATH_FUNC([ctanf])
 464 GCC_CHECK_MATH_FUNC([ctan])
 465 GCC_CHECK_MATH_FUNC([ctanl])
 466 GCC_CHECK_MATH_FUNC([tanhf])
 467 GCC_CHECK_MATH_FUNC([tanh])
 468 GCC_CHECK_MATH_FUNC([tanhl])
 469 GCC_CHECK_MATH_FUNC([ctanhf])
 470 GCC_CHECK_MATH_FUNC([ctanh])
 471 GCC_CHECK_MATH_FUNC([ctanhl])
 472 GCC_CHECK_MATH_FUNC([truncf])
 473 GCC_CHECK_MATH_FUNC([trunc])
 474 GCC_CHECK_MATH_FUNC([truncl])
 475 GCC_CHECK_MATH_FUNC([erff])
 476 GCC_CHECK_MATH_FUNC([erf])
 477 GCC_CHECK_MATH_FUNC([erfcf])
 478 GCC_CHECK_MATH_FUNC([erfc])
 479 GCC_CHECK_MATH_FUNC([erfcl])
 480 GCC_CHECK_MATH_FUNC([j0f])
 481 GCC_CHECK_MATH_FUNC([j0])
 482 GCC_CHECK_MATH_FUNC([j1f])
 483 GCC_CHECK_MATH_FUNC([j1])
 484 GCC_CHECK_MATH_FUNC([jnf])
 485 GCC_CHECK_MATH_FUNC([jn])
 486 GCC_CHECK_MATH_FUNC([jnl])
 487 GCC_CHECK_MATH_FUNC([y0f])
 488 GCC_CHECK_MATH_FUNC([y0])
 489 GCC_CHECK_MATH_FUNC([y1f])
 490 GCC_CHECK_MATH_FUNC([y1])
 491 GCC_CHECK_MATH_FUNC([ynf])
 492 GCC_CHECK_MATH_FUNC([yn])
 493 GCC_CHECK_MATH_FUNC([ynl])
 494 GCC_CHECK_MATH_FUNC([tgamma])
 495 GCC_CHECK_MATH_FUNC([tgammaf])
 496 GCC_CHECK_MATH_FUNC([lgamma])
 497 GCC_CHECK_MATH_FUNC([lgammaf])
 498
 499 # Check for GFORTRAN_C99_1.1 funcs
 500 GCC_CHECK_MATH_FUNC([cacos])
 501 GCC_CHECK_MATH_FUNC([cacosf])
 502 GCC_CHECK_MATH_FUNC([cacosh])
 503 GCC_CHECK_MATH_FUNC([cacoshf])
 504 GCC_CHECK_MATH_FUNC([cacoshl])
 505 GCC_CHECK_MATH_FUNC([cacosl])
 506 GCC_CHECK_MATH_FUNC([casin])
 507 GCC_CHECK_MATH_FUNC([casinf])
 508 GCC_CHECK_MATH_FUNC([casinh])
 509 GCC_CHECK_MATH_FUNC([casinhf])
 510 GCC_CHECK_MATH_FUNC([casinhl])
 511 GCC_CHECK_MATH_FUNC([casinl])
 512 GCC_CHECK_MATH_FUNC([catan])
 513 GCC_CHECK_MATH_FUNC([catanf])
 514 GCC_CHECK_MATH_FUNC([catanh])
 515 GCC_CHECK_MATH_FUNC([catanhf])
 516 GCC_CHECK_MATH_FUNC([catanhl])
 517 GCC_CHECK_MATH_FUNC([catanl])
 518
 519 # On AIX, clog is present in libm as __clog
 520 AC_CHECK_LIB([m],[__clog],[AC_DEFINE([HAVE_CLOG],[1],[libm includes clog])])
 521
 522 GCC_CHECK_MATH_INLINE_BUILTIN_FALLBACK2([copysign], [double])
 523 GCC_CHECK_MATH_INLINE_BUILTIN_FALLBACK2([copysignl], [long double])
 524 GCC_CHECK_MATH_INLINE_BUILTIN_FALLBACK1([fabs], [double])
 525 GCC_CHECK_MATH_INLINE_BUILTIN_FALLBACK1([fabsl], [long double])
 526
 527 # Check whether the system has a working stat()
 528 LIBGFOR_CHECK_WORKING_STAT
 529
 530 # Check whether __mingw_snprintf() is present
 531 LIBGFOR_CHECK_MINGW_SNPRINTF
 532
 533 # Check whether libquadmath should be used
 534 AC_ARG_ENABLE(libquadmath-support,
 535 AS_HELP_STRING([--disable-libquadmath-support],
 536   [disable libquadmath support for Fortran]),
 537 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 538 ENABLE_LIBQUADMATH_SUPPORT=yes)
 539 enable_libquadmath_support=
 540 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 541   enable_libquadmath_support=no
 542 fi
 543
 544 # Check whether we have a __float128 type, depends on enable_libquadmath_support
 545 LIBGFOR_CHECK_FLOAT128
 546
 547 # Check for GNU libc feenableexcept
 548 AC_CHECK_LIB([m],[feenableexcept],[have_feenableexcept=yes AC_DEFINE([HAVE_FEENABLEEXCEPT],[1],[libm includes feenableexcept])])
 549
 550 # At least for glibc, clock_gettime is in librt.  But don't
 551 # pull that in if it still doesn't give us the function we want.  This
 552 # test is copied from libgomp, and modified to not link in -lrt as
 553 # libgfortran calls clock_gettime via a weak reference if it's found
 554 # in librt.
 555 if test "$ac_cv_func_clock_gettime" = no; then
 556   AC_CHECK_LIB(rt, clock_gettime,
 557     [AC_DEFINE(HAVE_CLOCK_GETTIME_LIBRT, 1,
 558                [Define to 1 if you have the `clock_gettime' function in librt.])])
 559 fi
 560
 561 # Check for SysV fpsetmask
 562 LIBGFOR_CHECK_FPSETMASK
 563 AC_CHECK_TYPES([fp_except,fp_except_t], [], [], [[
 564 #ifdef HAVE_IEEEFP_H
 565 #include <ieeefp.h>
 566 #endif
 567 #include <math.h>
 568 ]])
 569 AC_CHECK_TYPES([fp_rnd,fp_rnd_t], [], [], [[
 570 #ifdef HAVE_IEEEFP_H
 571 #include <ieeefp.h>
 572 #endif
 573 #include <math.h>
 574 ]])
 575
 576 # Check whether we have fpsetsticky or fpresetsticky
 577 AC_CHECK_FUNC([fpsetsticky],[have_fpsetsticky=yes AC_DEFINE([HAVE_FPSETSTICKY],[1],[fpsetsticky is present])])
 578 AC_CHECK_FUNC([fpresetsticky],[have_fpresetsticky=yes AC_DEFINE([HAVE_FPRESETSTICKY],[1],[fpresetsticky is present])])
 579
 580 # Check for AIX fp_trap and fp_enable
 581 AC_CHECK_FUNC([fp_trap],[have_fp_trap=yes AC_DEFINE([HAVE_FP_TRAP],[1],[fp_trap is present])])
 582 AC_CHECK_FUNC([fp_enable],[have_fp_enable=yes AC_DEFINE([HAVE_FP_ENABLE],[1],[fp_enable is present])])
 583
 584 # Check if _SOFT_FLOAT is defined
 585 AC_CHECK_DEFINE([_SOFT_FLOAT],[have_soft_float=yes])
 586
 587 # Runs configure.host to set up necessary host-dependent shell variables.
 588 # We then display a message about it, and propagate them through the
 589 # build chain.
 590 . ${srcdir}/configure.host
 591 AC_MSG_NOTICE([FPU dependent file will be ${fpu_host}.h])
 592 AC_MSG_NOTICE([Support for IEEE modules: ${ieee_support}])
 593 FPU_HOST_HEADER=config/${fpu_host}.h
 594 AC_SUBST(FPU_HOST_HEADER)
 595
 596 # Whether we will build the IEEE modules
 597 AM_CONDITIONAL(IEEE_SUPPORT,[test x${ieee_support} = xyes])
 598 AC_SUBST(IEEE_SUPPORT)
 599
 600 # Some targets require additional compiler options for IEEE compatibility.
 601 IEEE_FLAGS="${ieee_flags}"
 602 AC_SUBST(IEEE_FLAGS)
 603
 604
 605 # Check for POSIX getpwuid_r
 606 #
 607 # There are two versions of getpwuid_r, the POSIX one with 5
 608 # arguments, and another one with 4 arguments used by at least HP-UX
 609 # 10.2.
 610 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 611    AC_CACHE_CHECK([POSIX version of getpwuid_r with 5 arguments], libgfor_cv_posix_getpwuid_r, [
 612    AC_LINK_IFELSE([AC_LANG_PROGRAM([
 613 #include <stdio.h>
 614 #include <sys/types.h>
 615 #include <pwd.h>], [
 616     getpwuid_r(0, NULL, NULL, 0, NULL);
 617     ])],  [libgfor_cv_posix_getpwuid_r="yes"], [libgfor_cv_posix_getpwuid_r="no"])])
 618 fi
 619 if test "$libgfor_cv_posix_getpwuid_r" = "yes"; then
 620     AC_DEFINE([HAVE_POSIX_GETPWUID_R], [1], [Define to 1 if we have POSIX getpwuid_r which takes 5 arguments.])
 621 fi
 622
 623
 624 # Check out attribute support.
 625 LIBGFOR_CHECK_ATTRIBUTE_VISIBILITY
 626 LIBGFOR_CHECK_ATTRIBUTE_ALIAS
 627
 628 # Check out atomic builtins support.
 629 LIBGFOR_CHECK_ATOMIC_FETCH_ADD
 630
 631 # Check out #pragma weak.
 632 LIBGFOR_GTHREAD_WEAK
 633
 634 # Check out weakref support.
 635 LIBGFOR_CHECK_WEAKREF
 636
 637 # Various other checks on target
 638 LIBGFOR_CHECK_UNLINK_OPEN_FILE
 639
 640 # Check whether line terminator is LF or CRLF
 641 LIBGFOR_CHECK_CRLF
 642
 643 # Check whether we support AVX extensions
 644 LIBGFOR_CHECK_AVX
 645
 646 # Check wether we support AVX2 extensions
 647 LIBGFOR_CHECK_AVX2
 648
 649 # Check wether we support AVX512f extensions
 650 LIBGFOR_CHECK_AVX512F
 651
 652 # Check for FMA3 extensions
 653 LIBGFOR_CHECK_FMA3
 654
 655 # Check for FMA4 extensions
 656 LIBGFOR_CHECK_FMA4
 657
 658 # Check if AVX128 works
 659 LIBGFOR_CHECK_AVX128
 660
 661 # Determine what GCC version number to use in filesystem paths.
 662 GCC_BASE_VER
 663
 664 AC_CACHE_SAVE
 665
 666 if test ${multilib} = yes; then
 667   multilib_arg="--enable-multilib"
 668 else
 669   multilib_arg=
 670 fi
 671
 672 # Write our Makefile and spec file.
 673 AC_CONFIG_FILES([
 674 Makefile
 675 libgfortran.spec
 676 ])
 677 AC_OUTPUT