libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_INIT(package-unused, version-unused,, libgo)
  10 AC_CONFIG_SRCDIR(Makefile.am)
  11 AC_CONFIG_HEADER(config.h)
  12
  13 libtool_VERSION=15:0:0
  14 AC_SUBST(libtool_VERSION)
  15
  16 AM_ENABLE_MULTILIB(, ..)
  17
  18 AC_CANONICAL_SYSTEM
  19 target_alias=${target_alias-$host_alias}
  20
  21 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist subdir-objects -Wall -Wno-portability -Wno-override])
  22 AH_TEMPLATE(PACKAGE, [Name of package])
  23 AH_TEMPLATE(VERSION, [Version number of package])
  24
  25 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  26 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  27 AC_PROG_CC
  28 AC_PROG_GO
  29 AM_PROG_AS
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_libffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd hurd illumos irix js linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 is_hurd=no
 170 GOOS=unknown
 171 case ${host} in
 172   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 173   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 174   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 175   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 176   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 177   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 178   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 179   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 180   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 181   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 182   *-*-gnu*)      is_hurd=yes;    GOOS=hurd ;;
 183 esac
 184 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 185 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 186 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 187 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 188 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 189 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 190 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 191 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 192 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 193 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 194 AM_CONDITIONAL(LIBGO_IS_HURD, test $is_hurd = yes)
 195 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 196 AC_SUBST(GOOS)
 197 AC_SUBST(ALLGOOS)
 198
 199 dnl Test whether we need to use DejaGNU or whether we can use the
 200 dnl simpler gotest approach.  We can only use gotest for a native
 201 dnl build.
 202 USE_DEJAGNU=no
 203 case ${host} in
 204   *-*-rtems*) USE_DEJAGNU=yes ;;
 205   ${build}) ;;
 206   *) USE_DEJAGNU=yes ;;
 207 esac
 208 AC_SUBST(USE_DEJAGNU)
 209
 210 # All known GOARCH values.  This is the union of all architectures
 211 # supported by the gofrontend and all architectures supported by the
 212 # gc toolchain.
 213 # To add a new architecture:
 214 # - add it to this list
 215 # - if appropriate, add an entry to ALLGOARCHFAMILY below
 216 # - add an entry to the case on ${host} below to set GOARCH
 217 # - update goarchList in libgo/go/go/build/syslist.go
 218 # - update goarch.sh to report the values for this architecture
 219 # - update go-set-goarch in gcc/testsuite/go.test/go-test.exp
 220 # - update ptrSizeMap and intSizeMap in libgo/go/cmd/cgo/main.go
 221 # - update arch lists in libgo/match.sh
 222 # - update arch lists in libgo/testsuite/gotest
 223 # - update +build lines in several places
 224 #   - libgo/go/runtime/lfstack_NNbit.go
 225 #   - libgo/go/runtime/hashNN.go
 226 #   - libgo/go/runtime/unalignedN.go
 227 #   - libgo/go/syscall/endian_XX.go
 228 #   - possibly others
 229 # - possibly update files in libgo/go/internal/syscall/unix
 230 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le nios2 ppc ppc64 ppc64le riscv riscv64 s390 s390x sh shbe sparc sparc64 wasm"
 231
 232 # All known GOARCH family values.
 233 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 NIOS2 PPC PPC64 RISCV RISCV64 S390 S390X SH SPARC SPARC64 WASM"
 234
 235 GOARCH=unknown
 236 case ${host} in
 237   alpha*-*-*)
 238     GOARCH=alpha
 239     ;;
 240   aarch64-*-*)
 241     GOARCH=arm64
 242     ;;
 243   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 244     GOARCH=arm
 245     case ${host} in
 246       arm*b*-*-*)
 247         GOARCH=armbe
 248         ;;
 249     esac
 250     ;;
 251 changequote(,)dnl
 252   i[34567]86-*-* | x86_64-*-*)
 253 changequote([,])dnl
 254     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 255 #ifdef __x86_64__
 256 #error 64-bit
 257 #endif
 258 ])],
 259         [GOARCH=386],
 260         AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 261 #ifdef __ILP32__
 262 #error x32
 263 #endif
 264 ])],
 265         [GOARCH=amd64],
 266         [GOARCH=amd64p32]))
 267     ;;
 268   ia64-*-*)
 269     GOARCH=ia64
 270     ;;
 271   m68k*-*-*)
 272     GOARCH=m68k
 273     ;;
 274   mips*-*-*)
 275     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 276 #if _MIPS_SIM != _ABIO32
 277 #error not o32
 278 #endif
 279 ])],
 280 [mips_abi="o32"],
 281         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 282 #if _MIPS_SIM != _ABIN32
 283 #error not n32
 284 #endif
 285 ])],
 286 [mips_abi="n32"],
 287         [AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 288 #if _MIPS_SIM != _ABI64
 289 #error not n64
 290 #endif
 291 ])],
 292 [mips_abi="n64"],
 293         [AC_MSG_ERROR([unknown MIPS ABI])
 294 [mips_abi="n32"]])])])
 295     case "$mips_abi" in
 296     "o32") GOARCH=mips ;;
 297     "n32") GOARCH=mips64p32 ;;
 298     "n64") GOARCH=mips64 ;;
 299     esac
 300     case "${host}" in
 301     mips*el-*-*)
 302         GOARCH="${GOARCH}le"
 303         ;;
 304     esac
 305     ;;
 306   nios2-*-*)
 307     GOARCH=nios2
 308     ;;
 309   rs6000*-*-* | powerpc*-*-*)
 310     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 311 #ifdef _ARCH_PPC64
 312 #error 64-bit
 313 #endif
 314 ])],
 315 [GOARCH=ppc],
 316     [
 317 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 318 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 319 #error 64be
 320 #endif
 321 ])],
 322 [GOARCH=ppc64le],
 323 [GOARCH=ppc64])])
 324     ;;
 325   riscv64-*-*)
 326     GOARCH=riscv64
 327     ;;
 328   s390*-*-*)
 329     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 330 #if defined(__s390x__)
 331 #error 64-bit
 332 #endif
 333 ])],
 334 [GOARCH=s390],
 335 [GOARCH=s390x])
 336     ;;
 337   sh3eb*-*-* | sh4eb*-*-*)
 338     GOARCH=shbe
 339     ;;
 340   sh3*-*-* | sh4*-*-*)
 341     GOARCH=sh
 342     ;;
 343   sparc*-*-*)
 344     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 345 #if defined(__sparcv9) || defined(__arch64__)
 346 #error 64-bit
 347 #endif
 348 ])],
 349 [GOARCH=sparc],
 350 [GOARCH=sparc64])
 351     ;;
 352 esac
 353 AC_SUBST(GOARCH)
 354 AC_SUBST(ALLGOARCH)
 355 AC_SUBST(ALLGOARCHFAMILY)
 356
 357 AM_CONDITIONAL(LIBGO_IS_X86, test "$GOARCH" = "386" -o "$GOARCH" = "amd64" -o "$GOARCH" = "amd64p32")
 358
 359 FUNCTION_DESCRIPTORS=false
 360 case ${host} in
 361   rs6000*-*-* | powerpc*-*-*)
 362     AC_COMPILE_IFELSE([AC_LANG_SOURCE([
 363 #if _CALL_ELF == 1
 364 #error descriptors
 365 #endif
 366 ])],
 367         [FUNCTION_DESCRIPTORS=false],
 368         [FUNCTION_DESCRIPTORS=true])
 369     ;;
 370 esac
 371 AC_SUBST(FUNCTION_DESCRIPTORS)
 372
 373 dnl Some files are only present when needed for specific architectures.
 374 GO_LIBCALL_OS_FILE=
 375 GO_LIBCALL_OS_ARCH_FILE=
 376 GO_SYSCALL_OS_FILE=
 377 GO_SYSCALL_OS_ARCH_FILE=
 378 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 379   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 380 fi
 381 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 382   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 383 fi
 384 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 385   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 386 fi
 387 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 388   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 389 fi
 390 AC_SUBST(GO_LIBCALL_OS_FILE)
 391 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 392 AC_SUBST(GO_SYSCALL_OS_FILE)
 393 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 394
 395 dnl Special flags used to generate sysinfo.go.
 396 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 397 case "$target" in
 398     mips-sgi-irix6.5*)
 399         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 400         # msghdr in <sys/socket.h>.
 401         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 402         ;;
 403     *-*-solaris2.*)
 404         # Solaris 10+ needs this so struct msghdr gets the msg_control
 405         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 406         # above doesn't work with C99.
 407         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 408         ;;
 409 esac
 410 AC_SUBST(OSCFLAGS)
 411
 412 dnl Check if assembler supports disabling hardware capability support.
 413 GCC_CHECK_ASSEMBLER_HWCAP
 414
 415 dnl Use -fsplit-stack when compiling C code if available.
 416 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 417 [libgo_cv_c_split_stack_supported],
 418 [CFLAGS_hold=$CFLAGS
 419 CFLAGS="$CFLAGS -fsplit-stack"
 420 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 421 [libgo_cv_c_split_stack_supported=yes],
 422 [libgo_cv_c_split_stack_supported=no])
 423 CFLAGS=$CFLAGS_hold])
 424
 425 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 426 dnl reject split-stack code calling non-split-stack code on targets
 427 dnl they don't support.
 428 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 429 [libgo_cv_c_linker_split_non_split],
 430 [cat > conftest1.c << EOF
 431 extern void f();
 432 int main() { f(); return 0; }
 433 EOF
 434 cat > conftest2.c << EOF
 435 void f() {}
 436 EOF
 437 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 438 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 439 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 440   libgo_cv_c_linker_split_non_split=yes
 441 else
 442   libgo_cv_c_linker_split_non_split=no
 443 fi
 444 rm -f conftest1.* conftest2.* conftest])
 445
 446 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 447   SPLIT_STACK=-fsplit-stack
 448   AC_DEFINE(USING_SPLIT_STACK, 1,
 449                 [Define if the compiler supports -fsplit-stack])
 450 else
 451   SPLIT_STACK=
 452 fi
 453 AC_SUBST(SPLIT_STACK)
 454 AM_CONDITIONAL(USING_SPLIT_STACK,
 455         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 456
 457 dnl If the compiler supports split-stack but the linker does not, then
 458 dnl we need to explicitly disable split-stack for Go.
 459 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 460   GO_SPLIT_STACK=-fno-split-stack
 461 else
 462   GO_SPLIT_STACK=
 463 fi
 464 AC_SUBST(GO_SPLIT_STACK)
 465
 466 dnl Check whether the linker does stack munging when calling from
 467 dnl split-stack into non-split-stack code.  We check this by looking
 468 dnl at the --help output.  FIXME: This is only half right: it's
 469 dnl possible for the linker to support this for some targets but not
 470 dnl others.
 471 dnl This is slightly different from the above check, which is whether
 472 dnl the linker permits the call at all.
 473 AC_CACHE_CHECK([whether linker supports split stack],
 474 [libgo_cv_c_linker_supports_split_stack],
 475 [libgo_cv_c_linker_supports_split_stack=no
 476 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 477   libgo_cv_c_linker_supports_split_stack=yes
 478 fi])
 479 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 480   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 481             [Define if the linker support split stack adjustments])
 482 fi
 483
 484 AC_CACHE_CHECK([whether compiler is llgo],
 485 [libgo_cv_c_goc_is_llgo],
 486 [libgo_cv_c_goc_is_llgo=no
 487 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 488   libgo_cv_c_goc_is_llgo=yes
 489 fi])
 490 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 491
 492 dnl Test for the -lm library.
 493 MATH_LIBS=
 494 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 495 AC_SUBST(MATH_LIBS)
 496
 497 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 498 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 499   [libgo_cv_lib_sockets=
 500    libgo_check_both=no
 501    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 502    if test "$libgo_check_socket" = "yes"; then
 503      unset ac_cv_func_connect
 504      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 505                   libgo_check_both=yes)
 506    fi
 507    if test "$libgo_check_both" = "yes"; then
 508      libgo_old_libs=$LIBS
 509      LIBS="$LIBS -lsocket -lnsl"
 510      unset ac_cv_func_accept
 511      AC_CHECK_FUNC(accept,
 512                    [libgo_check_nsl=no
 513                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 514      unset ac_cv_func_accept
 515      LIBS=$libgo_old_libs
 516    fi
 517    unset ac_cv_func_gethostbyname
 518    libgo_old_libs="$LIBS"
 519    AC_CHECK_FUNC(gethostbyname, ,
 520                  [AC_CHECK_LIB(nsl, main,
 521                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 522    unset ac_cv_func_gethostbyname
 523    AC_CHECK_FUNC(sendfile, ,
 524                  [AC_CHECK_LIB(sendfile, main,
 525                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 526    LIBS=$libgo_old_libs
 527 ])
 528 NET_LIBS="$libgo_cv_lib_sockets"
 529 AC_SUBST(NET_LIBS)
 530
 531 dnl Test whether the compiler supports the -pthread option.
 532 AC_CACHE_CHECK([whether -pthread is supported],
 533 [libgo_cv_lib_pthread],
 534 [CFLAGS_hold=$CFLAGS
 535 CFLAGS="$CFLAGS -pthread -L../libatomic/.libs"
 536 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 537 [libgo_cv_lib_pthread=yes],
 538 [libgo_cv_lib_pthread=no])
 539 CFLAGS=$CFLAGS_hold])
 540 PTHREAD_CFLAGS=
 541 if test "$libgo_cv_lib_pthread" = yes; then
 542   # RISC-V apparently adds -latomic when using -pthread.
 543   PTHREAD_CFLAGS="-pthread -L../libatomic/.libs"
 544 fi
 545 AC_SUBST(PTHREAD_CFLAGS)
 546
 547 dnl Test for the -lpthread library.
 548 PTHREAD_LIBS=
 549 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 550 AC_SUBST(PTHREAD_LIBS)
 551
 552 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 553 AC_SEARCH_LIBS([sched_yield], [rt])
 554 AC_SEARCH_LIBS([nanosleep], [rt])
 555 AC_SEARCH_LIBS([clock_gettime], [rt])
 556
 557 AC_C_BIGENDIAN
 558
 559 GCC_CHECK_UNWIND_GETIPINFO
 560
 561 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 562
 563 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 564 [#include <netinet/in.h>
 565 ])
 566
 567 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 568 [#ifdef HAVE_SYS_SOCKET_H
 569 #include <sys/socket.h>
 570 #endif
 571 ])
 572
 573 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 574
 575 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr memmem)
 576 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 577 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 578
 579 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 580 AC_TYPE_OFF_T
 581 AC_CHECK_TYPES([loff_t])
 582
 583 LIBS_hold="$LIBS"
 584 LIBS="$LIBS -lm"
 585 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 586 LIBS="$LIBS_hold"
 587
 588 CFLAGS_hold="$CFLAGS"
 589 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 590 LIBS_hold="$LIBS"
 591 LIBS="$LIBS $PTHREAD_LIBS"
 592 AC_CHECK_FUNCS(sem_timedwait)
 593 CFLAGS="$CFLAGS_hold"
 594 LIBS="$LIBS_hold"
 595
 596 LIBS_hold="$LIBS"
 597 LIBS="$LIBS $MATH_LIBS"
 598 AC_CHECK_FUNCS(matherr)
 599 LIBS="$LIBS_hold"
 600
 601 dnl For x86 we want to use the -minline-all-stringops option to avoid
 602 dnl forcing a stack split when calling memcpy and friends.
 603 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 604 [libgo_cv_c_stringops],
 605 [CFLAGS_hold=$CFLAGS
 606 CFLAGS="$CFLAGS -minline-all-stringops"
 607 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 608 [libgo_cv_c_stringops=yes],
 609 [libgo_cv_c_stringops=no])
 610 CFLAGS=$CFLAGS_hold])
 611 STRINGOPS_FLAG=
 612 if test "$libgo_cv_c_stringops" = yes; then
 613   STRINGOPS_FLAG=-minline-all-stringops
 614 fi
 615 AC_SUBST(STRINGOPS_FLAG)
 616
 617 dnl For x86 we want to compile the math library with -mfancy-math-387
 618 dnl so that we can use the builtin instructions directly.
 619 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 620 [libgo_cv_c_fancymath],
 621 [CFLAGS_hold=$CFLAGS
 622 CFLAGS="$CFLAGS -mfancy-math-387"
 623 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 624 [libgo_cv_c_fancymath=yes],
 625 [libgo_cv_c_fancymath=no])
 626 CFLAGS=$CFLAGS_hold])
 627 MATH_FLAG=
 628 if test "$libgo_cv_c_fancymath" = yes; then
 629   MATH_FLAG="-mfancy-math-387"
 630 fi
 631 MATH_FLAG="${MATH_FLAG} -ffp-contract=off -fno-math-errno -fno-trapping-math"
 632 AC_SUBST(MATH_FLAG)
 633
 634 CFLAGS_hold=$CFLAGS
 635 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 636 AC_CHECK_TYPES([off64_t])
 637 CFLAGS=$CFLAGS_hold
 638
 639 dnl Work out the size of the epoll_events struct on GNU/Linux.
 640 AC_CACHE_CHECK([epoll_event size],
 641 [libgo_cv_c_epoll_event_size],
 642 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 643 [sizeof (struct epoll_event)],
 644 [#include <sys/epoll.h>],
 645 [libgo_cv_c_epoll_event_size=0])])
 646 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 647 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 648
 649 dnl Work out the offset of the fd field in the epoll_events struct on
 650 dnl GNU/Linux.
 651 AC_CACHE_CHECK([epoll_event data.fd offset],
 652 [libgo_cv_c_epoll_event_fd_offset],
 653 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 654 [offsetof (struct epoll_event, data.fd)],
 655 [#include <stddef.h>
 656 #include <sys/epoll.h>],
 657 [libgo_cv_c_epoll_event_fd_offset=0])])
 658 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 659 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 660
 661 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 662 dnl in Solaris 11.4 for XPG7 compatibility.
 663 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 664                 [have_stat_timespec=yes], [have_stat_timespec=no])
 665 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 666
 667 dnl See if struct exception is defined in <math.h>.
 668 AC_CHECK_TYPE([struct exception],
 669 [libgo_has_struct_exception=yes],
 670 [libgo_has_struct_exception=no],
 671 [#include <math.h>])
 672 if test "$libgo_has_struct_exception" = "yes"; then
 673   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 674             [Define to 1 if <math.h> defines struct exception])
 675 fi
 676
 677 dnl See whether setcontext changes the value of TLS variables.
 678 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 679 [libgo_cv_lib_setcontext_clobbers_tls],
 680 [CFLAGS_hold="$CFLAGS"
 681 CFLAGS="$PTHREAD_CFLAGS"
 682 LIBS_hold="$LIBS"
 683 LIBS="$LIBS $PTHREAD_LIBS"
 684 AC_CHECK_SIZEOF([void *])
 685 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 686 AC_RUN_IFELSE(
 687   [AC_LANG_SOURCE([
 688 #include <pthread.h>
 689 #include <stdlib.h>
 690 #include <ucontext.h>
 691 #include <unistd.h>
 692
 693 __thread int tls;
 694
 695 static char stack[[10 * 1024 * 1024]];
 696 static ucontext_t c;
 697
 698 /* Called via makecontext/setcontext.  */
 699
 700 static void
 701 cfn (void)
 702 {
 703   exit (tls);
 704 }
 705
 706 /* Called via pthread_create.  */
 707
 708 static void *
 709 tfn (void *dummy)
 710 {
 711   /* The thread should still see this value after calling
 712      setcontext.  */
 713   tls = 0;
 714
 715   setcontext (&c);
 716
 717   /* The call to setcontext should not return.  */
 718   abort ();
 719 }
 720
 721 int
 722 main ()
 723 {
 724   pthread_t tid;
 725
 726   /* The thread should not see this value.  */
 727   tls = 1;
 728
 729   if (getcontext (&c) < 0)
 730     abort ();
 731
 732   c.uc_stack.ss_sp = stack;
 733 #ifdef MAKECONTEXT_STACK_TOP
 734   c.uc_stack.ss_sp += sizeof stack;
 735 #endif
 736   c.uc_stack.ss_flags = 0;
 737   c.uc_stack.ss_size = sizeof stack;
 738   c.uc_link = NULL;
 739   makecontext (&c, cfn, 0);
 740
 741   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 742     abort ();
 743
 744   if (pthread_join (tid, NULL) != 0)
 745     abort ();
 746
 747   /* The thread should have called exit.  */
 748   abort ();
 749 }
 750 ])],
 751 [libgo_cv_lib_setcontext_clobbers_tls=no],
 752 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 753 [case "$target:$ptr_type_size" in
 754   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 755     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 756   *)
 757     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 758  esac
 759 ])
 760 CFLAGS="$CFLAGS_hold"
 761 LIBS="$LIBS_hold"
 762 ])
 763 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 764   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 765             [Define if setcontext clobbers TLS variables])
 766 fi
 767
 768 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 769 libgo_cv_ro_eh_frame, [
 770 libgo_cv_ro_eh_frame=no
 771 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 772 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 773   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 774     libgo_cv_ro_eh_frame=yes
 775   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 776        | grep -v '#write' > /dev/null; then
 777     libgo_cv_ro_eh_frame=yes
 778   fi
 779 fi
 780 rm -f conftest.*
 781 ])
 782 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 783   AC_DEFINE(EH_FRAME_FLAGS, "a",
 784             [Define to the flags needed for the .section .eh_frame directive.])
 785 else
 786   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 787             [Define to the flags needed for the .section .eh_frame directive.])
 788 fi
 789
 790 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 791 [libgo_cv_c_unused_arguments],
 792 [CFLAGS_hold=$CFLAGS
 793 CFLAGS="$CFLAGS -Qunused-arguments"
 794 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 795 [libgo_cv_c_unused_arguments=yes],
 796 [libgo_cv_c_unused_arguments=no])
 797 CFLAGS=$CFLAGS_hold])
 798
 799 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 800 libgo_cv_as_comdat_gnu, [
 801 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 802 CFLAGS_hold=$CFLAGS
 803 if test "$libgo_cv_c_unused_arguments" = yes; then
 804   CFLAGS="$CFLAGS -Qunused-arguments"
 805 fi
 806 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 807   libgo_cv_as_comdat_gnu=yes
 808 else
 809   libgo_cv_as_comdat_gnu=no
 810 fi
 811 CFLAGS=$CFLAGS_hold
 812 ])
 813 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 814   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 815             [Define if your assembler supports GNU comdat group syntax.])
 816 fi
 817
 818 AC_CACHE_CHECK([assembler supports pc related relocs],
 819 libgo_cv_as_x86_pcrel, [
 820 libgo_cv_as_x86_pcrel=yes
 821 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 822 CFLAGS_hold=$CFLAGS
 823 if test "$libgo_cv_c_unused_arguments" = yes; then
 824   CFLAGS="$CFLAGS -Qunused-arguments"
 825 fi
 826 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 827     libgo_cv_as_x86_pcrel=no
 828 fi
 829 CFLAGS=$CFLAGS_hold
 830 ])
 831 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 832   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 833             [Define if your assembler supports PC relative relocs.])
 834 fi
 835
 836 AC_CACHE_CHECK([assembler supports unwind section type],
 837 libgo_cv_as_x86_64_unwind_section_type, [
 838 libgo_cv_as_x86_64_unwind_section_type=yes
 839 echo '.section .eh_frame,"a",@unwind' > conftest.s
 840 CFLAGS_hold=$CFLAGS
 841 if test "$libgo_cv_c_unused_arguments" = yes; then
 842   CFLAGS="$CFLAGS -Qunused-arguments"
 843 fi
 844 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 845     libgo_cv_as_x86_64_unwind_section_type=no
 846 fi
 847 CFLAGS=$CFLAGS_hold
 848 ])
 849 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 850   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 851             [Define if your assembler supports unwind section type.])
 852 fi
 853
 854 AC_CACHE_CHECK([assembler supports AES instructions],
 855 libgo_cv_as_x86_aes, [
 856 libgo_cv_as_x86_aes=yes
 857 echo 'aesenc %xmm0, %xmm1' > conftest.s
 858 CFLAGS_hold=$CFLAGS
 859 if test "$libgo_cv_c_unused_arguments" = yes; then
 860   CFLAGS="$CFLAGS -Qunused-arguments"
 861 fi
 862 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 863     libgo_cv_as_x86_aes=no
 864 fi
 865 CFLAGS=$CFLAGS_hold
 866 ])
 867 if test "x$libgo_cv_as_x86_aes" = xyes; then
 868   AC_DEFINE(HAVE_AS_X86_AES, 1,
 869             [Define if your assembler supports AES instructions.])
 870 fi
 871
 872 AC_CACHE_SAVE
 873
 874 if test ${multilib} = yes; then
 875   multilib_arg="--enable-multilib"
 876 else
 877   multilib_arg=
 878 fi
 879
 880 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 881
 882 AC_CONFIG_COMMANDS([default],
 883 [if test -n "$CONFIG_FILES"; then
 884    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 885    # that multilib installs will end up installed in the correct place.
 886    # The testsuite needs it for multilib-aware ABI baseline files.
 887    # To work around this not being passed down from config-ml.in ->
 888    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 889    # append it here.  Only modify Makefiles that have just been created.
 890    #
 891    # Also, get rid of this simulated-VPATH thing that automake does.
 892    cat > vpsed << \_EOF
 893 s!`test -f '$<' || echo '$(srcdir)/'`!!
 894 _EOF
 895    for i in $SUBDIRS; do
 896     case $CONFIG_FILES in
 897      *${i}/Makefile*)
 898        #echo "Adding MULTISUBDIR to $i/Makefile"
 899        sed -f vpsed $i/Makefile > tmp
 900        grep '^MULTISUBDIR =' Makefile >> tmp
 901        mv tmp $i/Makefile
 902        ;;
 903     esac
 904    done
 905    rm vpsed
 906  fi
 907 ],
 908 [
 909 # Variables needed in config.status (file generation) which aren't already
 910 # passed by autoconf.
 911 SUBDIRS="$SUBDIRS"
 912 ])
 913
 914 AC_OUTPUT