libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 LIBGCJ_CFLAGS="${libgcj_cflags}"
 218 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 219 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 220 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 221 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 222 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 223 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 224 AC_SUBST(LIBGCJ_CFLAGS)
 225 AC_SUBST(LIBGCJ_CXXFLAGS)
 226 AC_SUBST(LIBGCJ_JAVAFLAGS)
 227 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 228 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 229 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 231
 232 # Only use libltdl for non-newlib builds.
 233 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 234    AC_LTDL_SHLIBPATH
 235 fi
 236
 237 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 238
 239 # Possibly build libgcj as many sub-libraries.
 240 AC_ARG_ENABLE(libgcj-sublibs,
 241   AS_HELP_STRING([--enable-libgcj-sublibs],
 242                  [build libgcj as many sub-libraries]))
 243
 244 if test -z "$enable_libgcj_sublibs"; then
 245    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 246 fi
 247 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 248 if test "$enable_libgcj_sublibs" = yes ; then
 249   # In theory we could make do with only one override and simply
 250   # tag "_bc" onto the end of it when we use it to generate the
 251   # spec, but that's an ugly thing to do when there are multiple
 252   # words in the string and you're relying on the ordering to
 253   # append the correct one.
 254   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 255   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 256 fi
 257
 258
 259 # See if the user has requested runtime debugging.
 260 LIBGCJDEBUG="disable"
 261 AC_SUBST(LIBGCJDEBUG)
 262 AC_ARG_ENABLE(libgcj-debug,
 263   AS_HELP_STRING([--enable-libgcj-debug],
 264                  [enable runtime debugging code]),
 265   [if test "$enable_libgcj_debug" = yes; then
 266     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 267     LIBGCJDEBUG="enable"
 268   fi])
 269
 270 AC_ARG_WITH([escher],
 271          AS_HELP_STRING([--with-escher=ABS.PATH],
 272                         [specify path to escher dir or JAR for X peers]))
 273 case "$with_escher" in
 274 "")
 275         use_escher=false
 276         ;;
 277 "no")
 278         use_escher=false
 279         ;;
 280 "yes")
 281         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 282         ;;
 283 *)
 284         use_escher=true
 285         ;;
 286 esac
 287
 288 # Determine which AWT peer libraries to build
 289 AC_ARG_ENABLE(java-awt,
 290   AS_HELP_STRING([--enable-java-awt],
 291                  [list of AWT peer implementations to be built]))
 292
 293 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 294 use_xlib_awt=""
 295 use_gtk_awt=""
 296 use_qt_awt=""
 297 use_x_awt=""
 298 # The default toolkit to use is the first one specified.
 299 TOOLKIT=
 300 AC_SUBST(TOOLKIT)
 301
 302 for peer in $peerlibs ; do
 303   case $peer in
 304     xlib)
 305       if test "$no_x" = yes; then
 306         echo "*** xlib peers requested but no X library available" 1>&2
 307         exit 1
 308       else
 309         use_xlib_awt="yes"
 310         if test -z "$TOOLKIT"; then
 311            TOOLKIT=gnu.awt.xlib.XToolkit
 312         fi
 313       fi
 314       ;;
 315     gtk)
 316       if test "$no_x" = yes; then
 317          echo "*** gtk peers requested but no X library available" 1>&2
 318          exit 1
 319       else
 320          use_gtk_awt=yes
 321          if test -z "$TOOLKIT"; then
 322             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 323          fi
 324       fi
 325       ;;
 326     qt)
 327       if test "$no_x" = yes; then
 328          # Perhaps we should admit the possibility of embedded Qt.
 329          echo "*** Qt peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_qt_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 335          fi
 336       fi
 337       ;;
 338     x)
 339       use_x_awt=yes
 340       if test -z "$TOOLKIT"; then
 341          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 342       fi
 343       ;;
 344     no)
 345       use_xlib_awt=
 346       use_gtk_awt=
 347       use_qt_awt=
 348       use_x_awt=
 349       break
 350       ;;
 351     *)
 352       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 353       exit 1
 354   esac
 355 done
 356
 357 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 358 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 359
 360 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 361
 362 expanded_prefix=$prefix
 363 if test "X$prefix" = XNONE; then
 364   expanded_prefix=${ac_default_prefix}
 365 fi
 366
 367 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 368
 369 # Create standard.omit based on decisions we just made.
 370 cp $srcdir/standard.omit.in standard.omit
 371 if test "$use_xlib_awt" != yes; then
 372    echo gnu/awt/xlib >> standard.omit
 373    echo gnu/gcj/xlib >> standard.omit
 374 fi
 375 if test "$use_x_awt" != yes; then
 376    echo gnu/java/awt/peer/x >> standard.omit
 377 fi
 378
 379 # Tools that need to be compiled against classpath's tools classes
 380 : > vm-tools-packages
 381 for package in gnu/gcj/tools/gc_analyze ; do
 382     echo $package >> standard.omit
 383     echo $package >> vm-tools-packages
 384 done
 385
 386 if test -z "${with_multisubdir}"; then
 387    builddotdot=.
 388 else
 389    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 390 fi
 391
 392 NATIVE=yes
 393
 394 # Which gcj and host gcj (for ecjx) do we use?
 395 which_gcj=default
 396 host_exeext=${ac_exeext}
 397 GCJ_FOR_ECJX=
 398 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 399 if test -n "${with_cross_host}"; then
 400   # We are being configured with a cross compiler. We can't
 401   # use ac_exeext, because that is for the target platform.
 402   NATIVE=no
 403   cross_host_exeext=
 404   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 405   case "${with_cross_host}" in
 406      *mingw* | *cygwin*)
 407          cross_host_exeext=.exe
 408      ;;
 409   esac
 410   host_exeext=${cross_host_exeext}
 411   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 412      if test x"$build_noncanonical" = x"$with_cross_host"; then
 413         # Ordinary cross (host!=target and host=build)
 414         which_gcj=built
 415      else
 416         # Canadian cross (host!=target and host!=build)
 417         which_gcj=cross
 418      fi
 419   else
 420      which_gcj=cross
 421   fi
 422 else
 423   # We are being configured with a native or crossed-native compiler
 424   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 425      if test x"$build" = x"$host"; then
 426         # True native build (host=target and host=build)
 427         which_gcj=built
 428      else
 429         # Crossed-native build (host=target and host!=build)
 430         which_gcj=cross
 431      fi
 432   else
 433      which_gcj=path
 434   fi
 435 fi
 436 libgcjdir=`${PWDCMD-pwd}`
 437 case $GCJ in
 438 *" -B"*)
 439   # Just in case there is a comma in the build dir, quote it for the
 440   # sed command below.
 441   case $libgcjdir in
 442   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 443   *) qlibgcjdir=$libgcjdir;;
 444   esac
 445   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 446   ;;
 447 *)
 448   GCJ=$GCJ" -B$libgcjdir/"
 449   ;;
 450 esac
 451 case "${which_gcj}" in
 452    built)
 453       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 454    ;;
 455    cross)
 456       if test "x${with_newlib}" = "xyes"; then
 457          # FIXME (comment): Why is this needed?
 458          GCC_UNWIND_INCLUDE=
 459       fi
 460       GCJH='$(target_noncanonical)-gcjh'
 461    ;;
 462    path)
 463       GCJH=gcjh
 464    ;;
 465 esac
 466 JAVAC="$GCJ -C"
 467 export JAVAC
 468
 469 AC_SUBST(GCJ_FOR_ECJX)
 470 AC_SUBST(GCJH)
 471 AC_SUBST(host_exeext)
 472
 473 # Create it, so that compile/link tests don't fail
 474 test -f libgcj.spec || touch libgcj.spec
 475
 476
 477
 478 # Set up to configure Classpath.
 479 # FIXME: no supported way to pass args in autoconf.
 480 # Disable tool wrappers to avoid ltdl.h configure check.
 481 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 482 ac_configure_args="$ac_configure_args --disable-load-library"
 483 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 484 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 485 dir1=`cd $srcdir && pwd`
 486 dir2=`pwd`
 487 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 488 ac_configure_args="$ac_configure_args --disable-core-jni"
 489 dnl FIXME?
 490 ac_configure_args="$ac_configure_args --disable-examples"
 491 ac_configure_args="$ac_configure_args --with-glibj=build"
 492 if test "$browser_plugin_enabled" != yes; then
 493   ac_configure_args="$ac_configure_args --disable-plugin"
 494 else
 495   ac_configure_args="$ac_configure_args --enable-plugin"
 496 fi
 497 if test "$gconf_enabled" != yes; then
 498   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 499   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 500 fi
 501 if test "$use_gtk_awt" != yes; then
 502   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 503 fi
 504 if test "$use_qt_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-qt-peer"
 506 else
 507   # We need this as qt is disabled by default in classpath.
 508   ac_configure_args="$ac_configure_args --enable-qt-peer"
 509 fi
 510 if test "$use_x_awt" != yes; then
 511   ac_configure_args="$ac_configure_args --without-escher"
 512 else
 513   # We need this as escher is disabled by default in classpath.
 514   if test "$use_escher" != true; then
 515     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 516   else
 517     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 518   fi
 519 fi
 520 if test "x$BUILD_GJDOC" = xno; then
 521   ac_configure_args="$ac_configure_args --disable-gjdoc"
 522 fi
 523 # -Werror causes unavoidable problems in code using alsa.
 524 ac_configure_args="$ac_configure_args --disable-regen-headers"
 525 ac_configure_args="$ac_configure_args --disable-Werror"
 526 dnl --with-gcj=$GCJ
 527 dnl --with-javah=$GCJH
 528 dnl gtk-cairo -- just export here...
 529 dnl --enable-regen-headers?
 530
 531 # Only use libltdl for non-newlib builds.
 532 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 533    AC_LIBLTDL_CONVENIENCE
 534    AC_LIBTOOL_DLOPEN
 535    DIRLTDL=libltdl
 536    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 537    # Sigh.  Libtool's macro doesn't do the right thing.
 538    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 539    # FIXME: this is a hack.
 540    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 541    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 542 fi
 543 AC_SUBST(INCLTDL)
 544 AC_SUBST(LIBLTDL)
 545 AC_SUBST(DIRLTDL)
 546 AC_PROG_LIBTOOL
 547 AM_PROG_GCJ
 548 AM_PROG_CC_C_O
 549
 550 AC_CONFIG_SUBDIRS(classpath libltdl)
 551
 552 # The -no-testsuite modules omit the test subdir.
 553 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 554
 555 # Should the runtime set system properties by examining the
 556 # environment variable GCJ_PROPERTIES?
 557 AC_ARG_ENABLE(getenv-properties,
 558   AS_HELP_STRING([--disable-getenv-properties],
 559                  [don't set system properties from GCJ_PROPERTIES]))
 560
 561 # Whether GCJ_PROPERTIES is used depends on the target.
 562 if test -z "$enable_getenv_properties"; then
 563    enable_getenv_properties=${enable_getenv_properties_default-yes}
 564 fi
 565 if test "$enable_getenv_properties" = no; then
 566    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 567      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 568 fi
 569
 570 # Whether we should use arguments to main()
 571 if test -z "$enable_main_args"; then
 572    enable_main_args=${enable_main_args_default-yes}
 573 fi
 574 if test "$enable_main_args" = no; then
 575    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 576 fi
 577
 578
 579 # Should we use hashtable-based synchronization?
 580 # Currently works only for Linux X86/ia64
 581 # Typically faster and more space-efficient
 582 AC_ARG_ENABLE(hash-synchronization,
 583   AS_HELP_STRING([--enable-hash-synchronization],
 584                  [use global hash table for monitor locks]))
 585
 586 if test -z "$enable_hash_synchronization"; then
 587    enable_hash_synchronization=$enable_hash_synchronization_default
 588 fi
 589
 590
 591 install_ecj_jar=no
 592 ECJ_BUILD_JAR=
 593 ECJ_JAR=
 594 AC_ARG_WITH(ecj-jar,
 595         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 596         [ECJ_JAR=$withval],
 597         [if test -f $multi_basedir/ecj.jar; then
 598            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 599            ECJ_JAR='$(jardir)/ecj.jar'
 600            install_ecj_jar=yes
 601          fi])
 602 AC_SUBST(ECJ_BUILD_JAR)
 603 AC_SUBST(ECJ_JAR)
 604 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 605 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 606
 607 AC_ARG_WITH(java-home,
 608   AS_HELP_STRING([--with-java-home=DIRECTORY],
 609                  [value of java.home system property]),
 610                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 611 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 612 AC_SUBST(JAVA_HOME)
 613
 614 suppress_libgcj_bc=no
 615 AC_ARG_ENABLE(libgcj-bc,
 616   AS_HELP_STRING([--enable-libgcj-bc],
 617                  [enable(default) or disable BC ABI for portions of libgcj]),
 618   [if test "$enable_libgcj_bc" = "no"; then
 619      suppress_libgcj_bc=yes
 620    fi])
 621 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 622
 623 build_libgcj_reduced_reflection=no
 624 AC_ARG_ENABLE(reduced-reflection,
 625   AS_HELP_STRING([--enable-reduced-reflection],
 626                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 627   [if test "$enable_reduced_reflection" = "yes"; then
 628      build_libgcj_reduced_reflection=yes
 629    fi])
 630 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 631
 632 # What is the native OS API for MinGW?
 633 AC_ARG_WITH(win32-nlsapi,
 634   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 635                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 636 [case "${withval}" in
 637   ansi) with_win32_nlsapi=ansi ;;
 638   unicows) with_win32_nlsapi=unicows ;;
 639   unicode) with_win32_nlsapi=unicode ;;
 640   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 641 esac],[with_win32_nlsapi=ansi])
 642
 643 case "${with_win32_nlsapi}" in
 644   unicows | unicode)
 645     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 646       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 647     ;;
 648 esac
 649
 650 # configure.host sets slow_pthread_self if the synchronization code should
 651 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 652 if test "${slow_pthread_self}" = "yes"; then
 653   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 654     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 655 fi
 656
 657 # Check for gc debugging.  This option is handled both here and in the GC.
 658 AC_ARG_ENABLE(gc-debug,
 659    AS_HELP_STRING([--enable-gc-debug],
 660                   [include full support for pointer backtracing etc.]),
 661 [ if test "$enable_gc_debug" = "yes"; then
 662     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 663               [Define if we want to use debug calls into the garbage collector.])
 664   fi])
 665
 666 # See if the user has the interpreter included.
 667 AC_ARG_ENABLE(interpreter,
 668   AS_HELP_STRING([--enable-interpreter],
 669                  [enable interpreter]),
 670   [if test "$enable_interpreter" = yes; then
 671     # This can also be set in configure.host.
 672     libgcj_interpreter=yes
 673   elif test "$enable_interpreter" = no; then
 674     libgcj_interpreter=no
 675   fi])
 676
 677 if test "$libgcj_interpreter" = yes; then
 678    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 679 fi
 680 INTERPRETER="$libgcj_interpreter"
 681 AC_SUBST(INTERPRETER)
 682 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 683
 684 AC_MSG_CHECKING([for exception model to use])
 685 AC_LANG_PUSH(C++)
 686 AC_ARG_ENABLE(sjlj-exceptions,
 687   AS_HELP_STRING([--enable-sjlj-exceptions],
 688                  [force use of builtin_setjmp for exceptions]),
 689 [:],
 690 [dnl Botheration.  Now we've got to detect the exception model.
 691 dnl Link tests against libgcc.a are problematic since -- at least
 692 dnl as of this writing -- we've not been given proper -L bits for
 693 dnl single-tree newlib and libgloss.
 694 dnl
 695 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 696 dnl conftest files before we got a change to grep them first.
 697 cat > conftest.$ac_ext << EOF
 698 [#]line __oline__ "configure"
 699 struct S { ~S(); };
 700 void bar();
 701 void foo()
 702 {
 703   S s;
 704   bar();
 705 }
 706 EOF
 707 old_CXXFLAGS="$CXXFLAGS"
 708 CXXFLAGS=-S
 709 if AC_TRY_EVAL(ac_compile); then
 710   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 711     enable_sjlj_exceptions=yes
 712   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 713     enable_sjlj_exceptions=no
 714   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 715     # ARM EH ABI.
 716     enable_sjlj_exceptions=no
 717   fi
 718 fi
 719 CXXFLAGS="$old_CXXFLAGS"
 720 rm -f conftest*])
 721 if test x$enable_sjlj_exceptions = xyes; then
 722   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 723         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 724   ac_exception_model_name=sjlj
 725 elif test x$enable_sjlj_exceptions = xno; then
 726   ac_exception_model_name="call frame"
 727 else
 728   AC_MSG_ERROR([unable to detect exception model])
 729 fi
 730 AC_LANG_POP(C++)
 731 AC_MSG_RESULT($ac_exception_model_name)
 732
 733 # If we are non using SJLJ exceptions, and this host does not have support
 734 # for unwinding from a signal handler, enable checked dereferences and divides.
 735 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 736   CHECKREFSPEC=-fcheck-references
 737   DIVIDESPEC=-fuse-divide-subroutine
 738   EXCEPTIONSPEC=
 739 fi
 740
 741 # See if the user wants to disable java.net.  This is the mildly
 742 # ugly way that we admit that target-side configuration sucks.
 743 AC_ARG_ENABLE(java-net,
 744   AS_HELP_STRING([--disable-java-net],
 745                  [disable java.net]))
 746
 747 # Whether java.net is built by default can depend on the target.
 748 if test -z "$enable_java_net"; then
 749    enable_java_net=${enable_java_net_default-yes}
 750 fi
 751 if test "$enable_java_net" = no; then
 752    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 753 fi
 754
 755 # See if the user wants to configure without libffi.  Some
 756 # architectures don't support it, and default values are set in
 757 # configure.host.
 758 AC_ARG_WITH(libffi,
 759   AS_HELP_STRING([--without-libffi],
 760                  [don't use libffi]),
 761   [:],
 762   [with_libffi=${with_libffi_default-yes}])
 763
 764 LIBFFI=
 765 LIBFFIINCS=
 766 if test "$with_libffi" != no; then
 767    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 768    LIBFFI=../libffi/libffi_convenience.la
 769    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 770 fi
 771 AC_SUBST(LIBFFI)
 772 AC_SUBST(LIBFFIINCS)
 773
 774 # See if the user wants to disable JVMPI support.
 775 AC_ARG_ENABLE(jvmpi,
 776   AS_HELP_STRING([--disable-jvmpi],
 777                  [disable JVMPI support]))
 778
 779 if test "$enable_jvmpi" != no; then
 780     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 781 fi
 782
 783 # If the target is an eCos system, use the appropriate eCos
 784 # I/O routines.
 785 # FIXME: this should not be a local option but a global target
 786 # system; at present there is no eCos target.
 787 TARGET_ECOS=${PROCESS-"no"}
 788 AC_ARG_WITH(ecos,
 789 [  --with-ecos             enable runtime eCos target support],
 790 TARGET_ECOS="$with_ecos"
 791 )
 792
 793 case "$TARGET_ECOS" in
 794    no) case "$host" in
 795       *mingw*)
 796             PLATFORM=Win32
 797             PLATFORMNET=Win32
 798             PLATFORMH=win32.h
 799         CHECK_FOR_BROKEN_MINGW_LD
 800       ;;
 801       *)
 802             PLATFORM=Posix
 803             PLATFORMNET=Posix
 804             PLATFORMH=posix.h
 805       ;;
 806       esac
 807       ;;
 808    *)
 809       PLATFORM=Ecos
 810       PLATFORMNET=NoNet
 811       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 812       PLATFORMH=posix.h
 813       ;;
 814 esac
 815 AC_SUBST(PLATFORM)
 816 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 817
 818 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 819                                       [Define if you have int32_t and uint32_t.]))
 820 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 821                                         [Define if you have int32_t and uint32_t.]))
 822 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 823                                           [Define if you have u_int32_t]))
 824 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 825                                            [Define if you have u_int32_t]))
 826
 827 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 828 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 829
 830 case "$host" in
 831   *-darwin*) DARWIN_CRT=true ;;
 832   *) DARWIN_CRT=false ;;
 833 esac
 834 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 835
 836 # This may not be defined in a non-ANS conformant embedded system.
 837 # FIXME: Should these case a runtime exception in that case?
 838 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 839                                   [Define is you have 'localtime' in <time.h>]))
 840
 841 # Create the subdirectory for natFile.cc, or the attempt
 842 # to create the link will fail.
 843 test -d java || mkdir java
 844 test -d java/io || mkdir java/io
 845 test -d gnu || mkdir gnu
 846 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 847
 848 # Likewise for natConcreteProcess.cc.
 849 test -d java/lang || mkdir java/lang
 850 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 851
 852 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 853 test -d java/net || mkdir java/net
 854 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 855 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 856
 857 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 858 test -d gnu/java || mkdir gnu/java
 859 test -d gnu/java/net || mkdir gnu/java/net
 860 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 861 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 862
 863 # Likewise for natVMPipe.cc and natVMSelector.cc.
 864 test -d gnu/java/nio || mkdir gnu/java/nio
 865 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 866 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 867
 868 # Likewise for natFileChannelImpl.cc
 869 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 870 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 871
 872 # Likewise for natVMSecureRandom.cc
 873 test -d gnu/java/security || mkdir gnu/java/security
 874 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 875 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 876 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 877
 878 case "${host}" in
 879     *mingw*)
 880       SYSTEMSPEC="-lgdi32 -lws2_32"
 881       if test "${with_win32_nlsapi}" = "unicows"; then
 882         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 883       fi
 884     ;;
 885     *-*-darwin[[912]]*)
 886       SYSTEMSPEC="-allow_stack_execute"
 887     ;;
 888     *)
 889       SYSTEMSPEC=
 890     ;;
 891 esac
 892 AC_SUBST(SYSTEMSPEC)
 893
 894 AC_ARG_WITH(system-zlib,
 895   AS_HELP_STRING([--with-system-zlib],
 896                  [use installed libz]))
 897 ZLIBSPEC=
 898 AC_SUBST(ZLIBSPEC)
 899 ZLIBTESTSPEC=
 900 AC_SUBST(ZLIBTESTSPEC)
 901
 902 AC_PATH_XTRA
 903
 904 # FIXME: this should be _libs on some hosts.
 905 libsubdir=.libs
 906
 907 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 908
 909 LIBSTDCXXSPEC=
 910 # extra LD Flags which are required for targets
 911 case "${host}" in
 912 *-*-darwin[[0-7]].*)
 913     # For now we have to disable it on darwin[8-9] because it slows down
 914     # the linking phase. A possible bug in ld?
 915     # on Darwin -single_module speeds up loading of the dynamic libraries.
 916     extra_ldflags_libjava=-Wl,-single_module
 917     ;;
 918 arm*linux*eabi)
 919     # Some of the ARM unwinder code is actually in libstdc++.  We
 920     # could in principle replicate it in libgcj, but it's better to
 921     # have a dependency on libstdc++.
 922     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 923     LIBSTDCXXSPEC=-lstdc++
 924     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 925     ;;
 926 *-*-cygwin)
 927     extra_ldflags_libjava=-liconv
 928     ;;
 929 esac
 930 AC_SUBST(extra_ldflags_libjava)
 931 AC_SUBST(extra_ldflags)
 932 AC_SUBST(LIBSTDCXXSPEC)
 933
 934 AC_SUBST(LIBGCJTESTSPEC)
 935
 936 # Allow the GC to be disabled.  Can be useful when debugging.
 937 AC_MSG_CHECKING([for garbage collector to use])
 938 AC_ARG_ENABLE(java-gc,
 939   AS_HELP_STRING([--enable-java-gc=TYPE],
 940                  [choose garbage collector (default is boehm)]),
 941   [GC=$enableval],
 942   [GC=boehm])
 943 GCLIBS=
 944 GCINCS=
 945 GCDEPS=
 946 GCSPEC=
 947 JC1GCSPEC=
 948 GCTESTSPEC=
 949 case "$GC" in
 950  boehm)
 951     AC_MSG_RESULT(boehm)
 952     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 953     JC1GCSPEC='-fuse-boehm-gc'
 954     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 955     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 956     GCOBJS=boehm.lo
 957     GCHDR=boehm-gc.h
 958     # The POSIX thread support needs to know this.
 959     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 960     ;;
 961  no)
 962     AC_MSG_RESULT(none)
 963     GCHDR=no-gc.h
 964     ;;
 965  *)
 966     AC_MSG_ERROR([unrecognized collector "$GC"])
 967     ;;
 968 esac
 969 AC_SUBST(GCLIBS)
 970 AC_SUBST(GCINCS)
 971 AC_SUBST(GCDEPS)
 972 AC_SUBST(GCSPEC)
 973 AC_SUBST(JC1GCSPEC)
 974 AC_SUBST(GCTESTSPEC)
 975 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 976 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 977 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 978
 979
 980 AC_MSG_CHECKING([for thread model used by GCC])
 981 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 982 AC_MSG_RESULT([$THREADS])
 983
 984 case "$THREADS" in
 985  no | none | single)
 986     THREADS=none
 987     ;;
 988  aix | posix | posix95 | pthreads)
 989     THREADS=posix
 990     case "$host" in
 991      *-*-linux*)
 992         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 993         ;;
 994     esac
 995     ;;
 996  win32)
 997     ;;
 998  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 999     AC_MSG_ERROR(thread package $THREADS not yet supported)
1000     ;;
1001  *)
1002     AC_MSG_ERROR($THREADS is an unknown thread package)
1003     ;;
1004 esac
1005
1006 THREADCXXFLAGS=
1007 THREADLDFLAGS=
1008 THREADLIBS=
1009 THREADINCS=
1010 THREADDEPS=
1011 THREADH=
1012 THREADSPEC=
1013 THREADSTARTFILESPEC=
1014 case "$THREADS" in
1015  posix)
1016     case "$host" in
1017      *-*-cygwin*)
1018         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1019         ;;
1020      *-*-freebsd[[1234]]*)
1021         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1022         # merely adds pthread_* functions) but it does have a -pthread switch
1023         # which is required at link-time to select -lc_r *instead* of -lc.
1024         THREADLDFLAGS=-pthread
1025         # Don't set THREADSPEC here as might be expected since -pthread is
1026         # not processed when found within a spec file, it must come from
1027         # the command line.  For now, the user must provide the -pthread
1028         # switch to link code compiled with gcj.  In future, consider adding
1029         # support for weak references to pthread_* functions ala gthr.h API.
1030         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1031         ;;
1032      *-*-freebsd*)
1033         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1034         # systems which support threads and -lpthread.
1035         THREADLDFLAGS=-pthread
1036         THREADSPEC=-lpthread
1037         ;;
1038      alpha*-dec-osf* | hppa*-hp-hpux*)
1039         THREADCXXFLAGS=-pthread
1040         # boehm-gc needs some functions from librt, so link that too.
1041         THREADLIBS='-lpthread -lrt'
1042         THREADSPEC='-lpthread -lrt'
1043         ;;
1044      *)
1045         THREADLIBS=-lpthread
1046         THREADSPEC=-lpthread
1047         ;;
1048     esac
1049     THREADH=posix-threads.h
1050     # MIT pthreads doesn't seem to have the mutexattr functions.
1051     # But for now we don't check for it.  We just assume you aren't
1052     # using MIT pthreads.
1053     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1054
1055     # If we're using the Boehm GC, then we happen to know that it
1056     # defines _REENTRANT, so we don't bother.  Eww.
1057     if test "$GC" != boehm; then
1058        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1059     fi
1060     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1061     ;;
1062
1063  win32)
1064     THREADH=win32-threads.h
1065     THREADCXXFLAGS=-mthreads
1066     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1067     # But we do not want the executables created to be dependent on
1068     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1069     # exception handling contexts.  The following kludge achieves this effect
1070     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1071     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1072     # A workaround is to explicitly use -mthreads while linking Java programs.
1073     # See PR libgcj/28263.
1074     #
1075     # FIXME: In Java we are able to detect thread death at the end of
1076     # Thread.run() so we should be able to clean up the exception handling
1077     # contexts ourselves.
1078     THREADSTARTFILESPEC='crtmt%O%s'
1079     ;;
1080
1081  none)
1082     THREADH=no-threads.h
1083     ;;
1084 esac
1085 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1086 AC_SUBST(THREADLIBS)
1087 AC_SUBST(THREADINCS)
1088 AC_SUBST(THREADDEPS)
1089 AC_SUBST(THREADSPEC)
1090 AC_SUBST(THREADSTARTFILESPEC)
1091 AC_SUBST(THREADLDFLAGS)
1092 AC_SUBST(THREADCXXFLAGS)
1093 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1094 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1095 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1096 if test "$enable_shared" != yes; then
1097   use_libgcj_bc=no
1098 fi
1099 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1100
1101 if test -d sysdep; then true; else mkdir sysdep; fi
1102 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1103 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1104 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1105
1106 LIBGCJ_SPEC_LGCJ=-lgcj
1107 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1108 if test x"$libgcj_spec_lgcj_override" != x ; then
1109   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1110 fi
1111 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1112   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1113 fi
1114 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1115 if test "$use_libgcj_bc" = yes; then
1116   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1117   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1118 fi
1119 AC_SUBST(LIBGCJ_SPEC)
1120 AC_SUBST(LIBGCJ_BC_SPEC)
1121
1122 HASH_SYNC_SPEC=
1123 # Hash synchronization is only useful with posix threads right now.
1124 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1125    HASH_SYNC_SPEC=-fhash-synchronization
1126    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1127 fi
1128 AC_SUBST(HASH_SYNC_SPEC)
1129
1130 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1131
1132 # We're in the tree with gcc, and need to include some of its headers.
1133 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1134
1135 if test "x${with_newlib}" = "xyes"; then
1136    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1137    # may not work correctly, because the compiler may not be able to
1138    # link executables.
1139
1140    # We assume newlib.  This lets us hard-code the functions we know
1141    # we'll have.
1142    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1143    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1144    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1145    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1146    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1147    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1148    # This is only for POSIX threads.
1149    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1150
1151    # Assume we do not have getuid and friends.
1152    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1153    PLATFORMNET=NoNet
1154 else
1155    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1156                    localtime_r getpwuid_r getcwd \
1157                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1158                    nl_langinfo setlocale \
1159                    inet_pton uname inet_ntoa \
1160                    getrlimit sigaction ftruncate mmap \
1161                    getifaddrs])
1162    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1163    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1164    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1165    AC_CHECK_LIB(dl, dladdr, [
1166        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1167        AC_CHECK_LIB(dld, dladdr, [
1168        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1169
1170    if test x"$cross_compiling" = x"no"; then
1171      AC_CHECK_FILES(/proc/self/exe, [
1172        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1173      AC_CHECK_FILES(/proc/self/maps, [
1174        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1175          [Define if you have /proc/self/maps])])
1176    else
1177      case $host in
1178      *-linux*)
1179        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1180        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1181        ;;
1182      esac
1183    fi
1184
1185    AM_ICONV
1186    AM_LC_MESSAGES
1187    AC_STRUCT_TIMEZONE
1188
1189    AC_CHECK_FUNCS(gethostbyname_r, [
1190      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1191        [Define if you have the 'gethostbyname_r' function.])
1192      # There are two different kinds of gethostbyname_r.
1193      # We look for the one that returns `int'.
1194      # Hopefully this check is robust enough.
1195      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1196        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1197
1198      case " $GCINCS " in
1199      *" -D_REENTRANT "*) ;;
1200      *)
1201         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1202         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1203         [libjava_cv_gethostbyname_r_needs_reentrant],
1204         [ AC_LANG_PUSH(C++)
1205           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1206             [[gethostbyname_r("", 0, 0);]])],
1207             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1208                 CPPFLAGS_SAVE="$CPPFLAGS"
1209                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1210                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1211                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1212                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1213                 CPPFLAGS="$CPPFLAGS_SAVE"
1214           ])
1215           AC_LANG_POP(C++)
1216         ])
1217         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1218           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1219         fi
1220      ;;
1221      esac
1222
1223      AC_CACHE_CHECK([for struct hostent_data],
1224         [libjava_cv_struct_hostent_data], [dnl
1225         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1226 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1227 # define _REENTRANT 1
1228 #endif
1229 #include <netdb.h>]], [[struct hostent_data data;]])],
1230           [libjava_cv_struct_hostent_data=yes],
1231           [libjava_cv_struct_hostent_data=no])])
1232      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1233        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1234          [Define if struct hostent_data is defined in netdb.h])
1235      fi
1236    ])
1237
1238    # FIXME: libjava source code expects to find a prototype for
1239    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1240    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1241    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1242    # linkage check is enough, yet C++ code requires proper prototypes.)
1243    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1244    AC_CHECK_FUNCS(gethostbyaddr_r, [
1245      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1246        [Define if you have the 'gethostbyaddr_r' function.])
1247      # There are two different kinds of gethostbyaddr_r.
1248      # We look for the one that returns `int'.
1249      # Hopefully this check is robust enough.
1250      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1251        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1252          [Define if gethostbyaddr_r returns 'int'.])])])])
1253
1254    AC_CHECK_FUNCS(gethostname, [
1255      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1256        [Define if you have the 'gethostname' function.])
1257      AC_EGREP_HEADER(gethostname, unistd.h, [
1258        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1259          [Define if gethostname is declared in <unistd.h>.])])])
1260
1261    AC_CHECK_FUNCS(usleep, [
1262      AC_EGREP_HEADER(usleep, unistd.h, [
1263        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1264           [Define if usleep is declared in <unistd.h>.])])])
1265
1266    # Look for these functions in the thread library, but only bother
1267    # if using POSIX threads.
1268    if test "$THREADS" = posix; then
1269       save_LIBS="$LIBS"
1270       LIBS="$LIBS $THREADLIBS"
1271
1272       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1273       # Solaris 7 the name librt is preferred.
1274       AC_CHECK_FUNCS(sched_yield, , [
1275         AC_CHECK_LIB(rt, sched_yield, [
1276           AC_DEFINE(HAVE_SCHED_YIELD)
1277           THREADLIBS="$THREADLIBS -lrt"
1278           THREADSPEC="$THREADSPEC -lrt"], [
1279           AC_CHECK_LIB(posix4, sched_yield, [
1280             AC_DEFINE(HAVE_SCHED_YIELD)
1281             THREADLIBS="$THREADLIBS -lposix4"
1282             THREADSPEC="$THREADSPEC -lposix4"])])])
1283
1284       AC_CHECK_LIB(rt, clock_gettime, [
1285          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1286          case "$THREADSPEC" in
1287            *-lrt*) ;;
1288            *)
1289              THREADSPEC="$THREADSPEC -lrt"
1290              THREADLIBS="$THREADLIBS -lrt"
1291              ;;
1292          esac])
1293
1294       LIBS="$save_LIBS"
1295
1296       # We can save a little space at runtime if the mutex has m_count
1297       # or __m_count.  This is a nice hack for Linux.
1298       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1299           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1300         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1301              [Define if pthread_mutex_t has m_count member.]), [
1302         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1303             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1304           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1305             [Define if pthread_mutex_t has __m_count member.]))])
1306    fi
1307
1308    # We require a way to get the time.
1309    time_found=no
1310    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1311    if test "$time_found" = no; then
1312       AC_MSG_ERROR([no function found to get the time])
1313    fi
1314
1315    AC_CHECK_FUNCS(memmove)
1316
1317    # We require memcpy.
1318    memcpy_found=no
1319    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1320    if test "$memcpy_found" = no; then
1321       AC_MSG_ERROR([memcpy is required])
1322    fi
1323    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1324    AC_CHECK_LIB(dl, dlopen, [
1325        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1326        AC_CHECK_LIB(dld, dlopen, [
1327        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1328
1329    # Some library-finding code we stole from Tcl.
1330    #--------------------------------------------------------------------
1331    #    Check for the existence of the -lsocket and -lnsl libraries.
1332    #    The order here is important, so that they end up in the right
1333    #    order in the command line generated by make.  Here are some
1334    #    special considerations:
1335    #    1. Use "connect" and "accept" to check for -lsocket, and
1336    #       "gethostbyname" to check for -lnsl.
1337    #    2. Use each function name only once:  can't redo a check because
1338    #       autoconf caches the results of the last check and won't redo it.
1339    #    3. Use -lnsl and -lsocket only if they supply procedures that
1340    #       aren't already present in the normal libraries.  This is because
1341    #       IRIX 5.2 has libraries, but they aren't needed and they're
1342    #       bogus:  they goof up name resolution if used.
1343    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1344    #       To get around this problem, check for both libraries together
1345    #       if -lsocket doesn't work by itself.
1346    #--------------------------------------------------------------------
1347
1348    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1349     [gcj_cv_lib_sockets=
1350      gcj_checkBoth=0
1351      unset ac_cv_func_connect
1352      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1353      if test "$gcj_checkSocket" = 1; then
1354          unset ac_cv_func_connect
1355          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1356                       gcj_checkBoth=1)
1357      fi
1358      if test "$gcj_checkBoth" = 1; then
1359          gcj_oldLibs=$LIBS
1360          LIBS="$LIBS -lsocket -lnsl"
1361          unset ac_cv_func_accept
1362          AC_CHECK_FUNC(accept,
1363                        [gcj_checkNsl=0
1364                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1365          unset ac_cv_func_accept
1366          LIBS=$gcj_oldLibs
1367      fi
1368      unset ac_cv_func_gethostbyname
1369      gcj_oldLibs=$LIBS
1370      LIBS="$LIBS $gcj_cv_lib_sockets"
1371      AC_CHECK_FUNC(gethostbyname, ,
1372                    [AC_CHECK_LIB(nsl, main,
1373                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1374      unset ac_cv_func_gethostbyname
1375      LIBS=$gcj_oldLIBS
1376    ])
1377    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1378
1379    if test "$with_system_zlib" = yes; then
1380       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1381    fi
1382
1383    # Test for Gtk stuff, if asked for.
1384    if test "$use_gtk_awt" = yes; then
1385       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1386       AC_SUBST(GTK_CFLAGS)
1387       AC_SUBST(GTK_LIBS)
1388
1389       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1390       AC_SUBST(GLIB_CFLAGS)
1391       AC_SUBST(GLIB_LIBS)
1392
1393       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1394       AC_SUBST(LIBART_CFLAGS)
1395       AC_SUBST(LIBART_LIBS)
1396
1397       # We require the XTest Extension to support java.awt.Robot.
1398       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1399                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1400                    [${X_LIBS}])
1401    fi
1402
1403    # On Solaris, and maybe other architectures, the Boehm collector
1404    # requires -ldl.
1405    if test "$GC" = boehm; then
1406       case "${host}" in
1407           mips-sgi-irix6*)
1408             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1409             # libgcj.spec is used, so override here
1410             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1411           ;;
1412           *)
1413             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1414           ;;
1415       esac
1416    fi
1417 fi
1418
1419 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1420 case $build in
1421     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1422     *)         CLASSPATH_SEPARATOR=':' ;;
1423 esac
1424 AC_SUBST(CLASSPATH_SEPARATOR)
1425
1426 # We must search the source tree for java.lang, since we still don't
1427 # have libgcj.jar nor java/lang/*.class
1428 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1429 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1430
1431 # Since some classes depend on this one, we need its source available
1432 # before we can do any GCJ compilation test :-(
1433 if test ! -f gnu/classpath/Configuration.java; then
1434   test -d gnu || mkdir gnu
1435   test -d gnu/classpath || mkdir gnu/classpath
1436   # Note that it is not crucial that all the values here be correct.
1437   sed -e "s,@prefix@,$expanded_prefix," \
1438       -e "s,@VERSION@,$VERSION," \
1439       -e "s,@LIBDEBUG@,false," \
1440       -e "s,@INIT_LOAD_LIBRARY@,false," \
1441       -e "s,@@,$LIBGCJDEBUG," \
1442       -e "s,@default_toolkit@,$TOOLKIT," \
1443       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1444       -e "s,@GTK_CAIRO_ENABLED@,false," \
1445       -e "s,@ECJ_JAR@,," \
1446       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1447         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1448         > gnu/classpath/Configuration.java
1449   # We do not want to redirect the output of the grep below to /dev/null,
1450   # but we add /dev/null to the input list so that grep will print the
1451   # filename of Configuration.java in case it finds any matches.
1452   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1453     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1454   fi
1455 fi
1456
1457 LT_AC_PROG_GCJ
1458
1459 # Now remove it.
1460 rm -f gnu/classpath/Configuration.java
1461
1462 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1463
1464 AC_CHECK_SIZEOF(void *)
1465
1466 AC_C_BIGENDIAN
1467
1468 ZLIBS=
1469 SYS_ZLIBS=
1470 ZINCS=
1471
1472 if test -z "$ZLIBSPEC"; then
1473    # Use zlib from the GCC tree.
1474    ZINCS='-I$(top_srcdir)/../zlib'
1475    ZLIBS=../zlib/libzgcj_convenience.la
1476 else
1477    # System's zlib.
1478    SYS_ZLIBS="$ZLIBSPEC"
1479 fi
1480 AC_SUBST(ZLIBS)
1481 AC_SUBST(SYS_ZLIBS)
1482 AC_SUBST(ZINCS)
1483 AC_SUBST(DIVIDESPEC)
1484 AC_SUBST(CHECKREFSPEC)
1485 AC_SUBST(EXCEPTIONSPEC)
1486 AC_SUBST(BACKTRACESPEC)
1487 AC_SUBST(IEEESPEC)
1488 AC_SUBST(ATOMICSPEC)
1489
1490 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1491 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1492 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1493 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1494 AC_SUBST(GCC_UNWIND_INCLUDE)
1495
1496 # Process the option "--enable-version-specific-runtime-libs"
1497 # Calculate toolexeclibdir
1498 case ${version_specific_libs} in
1499   yes)
1500     # Need the gcc compiler version to know where to install libraries
1501     # and header files if --enable-version-specific-runtime-libs option
1502     # is selected.
1503     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1504     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1505     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1506     toolexeclibdir=$toolexecmainlibdir
1507     ;;
1508   no)
1509     if test -n "$with_cross_host" &&
1510        test x"$with_cross_host" != x"no"; then
1511       # Install a library built with a cross compiler in tooldir, not libdir.
1512       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1513       toolexecmainlibdir='$(toolexecdir)/lib'
1514     else
1515       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1516       toolexecmainlibdir='$(libdir)'
1517     fi
1518     multi_os_directory=`$CC -print-multi-os-directory`
1519     case $multi_os_directory in
1520       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1521       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1522     esac
1523     ;;
1524 esac
1525 AC_SUBST(toolexecdir)
1526 AC_SUBST(toolexecmainlibdir)
1527 AC_SUBST(toolexeclibdir)
1528
1529 # Determine gcj and libgcj version number.
1530 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1531 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1532 GCJVERSION=$gcjversion
1533 AC_SUBST(GCJVERSION)
1534 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1535
1536 # Determine where the standard .db file and GNU Classpath JNI
1537 # libraries are found.
1538 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1539 multi_os_directory=`$CC -print-multi-os-directory`
1540 case $multi_os_directory in
1541   .)
1542    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1543    ;;
1544   *)
1545    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1546    ;;
1547 esac
1548 AC_SUBST(dbexecdir)
1549 AC_SUBST(gcjsubdir)
1550
1551 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1552 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1553
1554 TL_AC_GXX_INCLUDE_DIR
1555
1556 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1557 # On that system, sys/ioctl.h will not include sys/filio.h unless
1558 # BSD_COMP is defined; just including sys/filio.h is simpler.
1559 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1560 # for now.  If you change this, you also must update natFile.cc.
1561 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1562                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1563                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1564                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1565                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1566
1567 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1568 AC_CHECK_HEADERS(net/if.h, [], [], [
1569 #ifdef HAVE_SYS_SOCKET_H
1570 #include <sys/socket.h>
1571 #endif
1572 ])
1573
1574 AC_CHECK_HEADERS(inttypes.h, [
1575     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1576     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1577 ])
1578
1579 AC_CHECK_TYPE([ssize_t], [int])
1580 AC_CHECK_TYPE([magic_t], [
1581     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1582 #ifdef HAVE_MAGIC_H
1583 #include <magic.h>
1584 #endif])
1585
1586 AC_MSG_CHECKING([for in_addr_t])
1587 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1588 #if STDC_HEADERS
1589 #include <stdlib.h>
1590 #include <stddef.h>
1591 #endif
1592 #if HAVE_NETINET_IN_H
1593 #include <netinet/in.h>
1594 #endif]], [[in_addr_t foo;]])],
1595   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1596      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1597    AC_MSG_RESULT(yes)],
1598   [AC_MSG_RESULT(no)])
1599
1600 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1601 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1602   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1603      [Define if struct ip_mreq is defined in netinet/in.h.])
1604    AC_MSG_RESULT(yes)],
1605   [AC_MSG_RESULT(no)])
1606
1607 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1609   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1610      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1611    AC_MSG_RESULT(yes)],
1612   [AC_MSG_RESULT(no)])
1613
1614 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1615 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1616   [AC_DEFINE(HAVE_INET6, 1,
1617      [Define if inet6 structures are defined in netinet/in.h.])
1618    AC_MSG_RESULT(yes)],
1619   [AC_MSG_RESULT(no)])
1620
1621 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1623 #include <sys/types.h>
1624 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1625   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1626    AC_MSG_RESULT(yes)],
1627   [AC_MSG_RESULT(no)])
1628
1629 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1630 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1631   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1632    AC_MSG_RESULT(yes)],
1633   [AC_MSG_RESULT(no)
1634    AC_MSG_CHECKING([for global timezone variable])
1635    dnl FIXME: we don't want a link check here because that won't work
1636    dnl when cross-compiling.  So instead we make an assumption that
1637    dnl the header file will mention timezone if it exists.
1638    dnl Don't find the win32 function timezone
1639    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1640      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1641       AC_MSG_RESULT(yes)],
1642      [AC_MSG_RESULT(no)
1643        AC_MSG_CHECKING([for global _timezone variable])
1644        dnl FIXME: As above, don't want link check
1645        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1646          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1647             [Define if your platform has the global _timezone variable.])
1648           AC_MSG_RESULT(yes)],
1649           [AC_MSG_RESULT(no)])])])
1650
1651 AC_CHECK_PROGS(PERL, perl, false)
1652
1653 SYSDEP_SOURCES=
1654 SIGNAL_HANDLER_AUX=
1655
1656 case "${host}" in
1657  i?86-*-linux*)
1658     SIGNAL_HANDLER=include/i386-signal.h
1659     ;;
1660  sparc*-sun-solaris*)
1661     SIGNAL_HANDLER=include/sparc-signal.h
1662     ;;
1663 # ia64-*)
1664 #    SYSDEP_SOURCES=sysdep/ia64.c
1665 #    test -d sysdep || mkdir sysdep
1666 #    ;;
1667  hppa*-*-linux*)
1668     SIGNAL_HANDLER=include/pa-signal.h
1669     ;;
1670  hppa*-hp-hpux*)
1671     SIGNAL_HANDLER=include/hppa-signal.h
1672     ;;
1673  ia64-*-linux*)
1674     SIGNAL_HANDLER=include/dwarf2-signal.h
1675     ;;
1676  powerpc*-*-linux*)
1677     SIGNAL_HANDLER=include/powerpc-signal.h
1678     ;;
1679  alpha*-*-linux*)
1680     SIGNAL_HANDLER=include/dwarf2-signal.h
1681     ;;
1682  s390*-*-linux*)
1683     SIGNAL_HANDLER=include/s390-signal.h
1684     ;;
1685  x86_64*-*-linux*)
1686     SIGNAL_HANDLER=include/x86_64-signal.h
1687     SIGNAL_HANDLER_AUX=include/i386-signal.h
1688     ;;
1689  sparc*-*-linux*)
1690     SIGNAL_HANDLER=include/dwarf2-signal.h
1691     ;;
1692  sh*-*-linux*)
1693     SIGNAL_HANDLER=include/sh-signal.h
1694     ;;
1695  *mingw*)
1696     SIGNAL_HANDLER=include/win32-signal.h
1697     ;;
1698  mips*-*-linux*)
1699     SIGNAL_HANDLER=include/mips-signal.h
1700     ;;
1701  m68*-*-linux*)
1702     SIGNAL_HANDLER=include/dwarf2-signal.h
1703     ;;
1704  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1705     SIGNAL_HANDLER=include/darwin-signal.h
1706     ;;
1707  powerpc*-*-aix*)
1708     SIGNAL_HANDLER=include/aix-signal.h
1709     ;;
1710  *)
1711     SIGNAL_HANDLER=include/default-signal.h
1712     ;;
1713 esac
1714
1715 # If we're using sjlj exceptions, forget what we just learned.
1716 if test "$enable_sjlj_exceptions" = yes; then
1717    SIGNAL_HANDLER=include/default-signal.h
1718    SIGNAL_HANDLER_AUX=
1719 fi
1720
1721 AC_SUBST(SYSDEP_SOURCES)
1722
1723 if test -z "$SIGNAL_HANDLER_AUX"; then
1724   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1725 fi
1726
1727 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1728                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1729
1730 if test "${multilib}" = "yes"; then
1731   multilib_arg="--enable-multilib"
1732 else
1733   multilib_arg=
1734 fi
1735
1736 # See if we support thread-local storage.
1737 GCC_CHECK_TLS
1738
1739 # For _Unwind_GetIPInfo.
1740 GCC_CHECK_UNWIND_GETIPINFO
1741
1742 # See if linker supports anonymous version scripts.
1743 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1744   [libjava_cv_anon_version_script],
1745   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1746    libjava_cv_anon_version_script=no
1747    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1748    echo '{ global: globalsymb*; local: *; };' > conftest.map
1749    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1750                [libjava_cv_anon_version_script=yes], [])
1751    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1752   ])
1753 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1754
1755 # Check if linker supports static linking on a per library basis
1756 LD_START_STATIC_SPEC=
1757 LD_FINISH_STATIC_SPEC=
1758 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1759   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1760     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1761     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1762   fi
1763 fi
1764 AC_SUBST(LD_START_STATIC_SPEC)
1765 AC_SUBST(LD_FINISH_STATIC_SPEC)
1766
1767 here=`${PWDCMD-pwd}`
1768 AC_SUBST(here)
1769
1770 # We get this from the environment.
1771 AC_SUBST(GCJFLAGS)
1772
1773 AC_ARG_WITH([python-dir],
1774             AS_HELP_STRING([--with-python-dir],
1775                            [the location to install Python modules. This path should NOT include the prefix.]),
1776             [with_python_dir=$withval], [with_python_dir=""])
1777
1778 if test "x${with_python_dir}" = "x"
1779 then
1780   # Needed for installing Python modules during make install.
1781   python_mod_dir="\${prefix}/share/python"
1782   # Needed for substituting into aot-compile*
1783   python_mod_dir_expanded="${expanded_prefix}/share/python"
1784 else
1785   python_mod_dir="\${prefix}${with_python_dir}"
1786   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1787 fi
1788 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1789 AC_SUBST(python_mod_dir)
1790 AC_SUBST(python_mod_dir_expanded)
1791
1792 # needed for aot-compile-rpm
1793 MAKE=`which make`
1794 AC_SUBST(MAKE)
1795
1796 AC_ARG_ENABLE([aot-compile-rpm],
1797   [AS_HELP_STRING([--enable-aot-compile-rpm],
1798                  [enable installation of aot-compile-rpm [default=no]])],
1799   [case "${enableval}" in
1800     yes) AOT_RPM_ENABLED=yes ;;
1801     no)  AOT_RPM_ENABLED=no ;;
1802     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1803   esac],
1804   [AOT_RPM_ENABLED=no]
1805 )
1806 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1807
1808 AC_ARG_ENABLE([java-home],
1809   [AS_HELP_STRING([--enable-java-home],
1810                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1811   [case "${enableval}" in
1812     yes) JAVA_HOME_ENABLED=yes ;;
1813     no)  JAVA_HOME_ENABLED=no ;;
1814     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1815   esac],
1816   [JAVA_HOME_ENABLED=no]
1817 )
1818 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1819
1820 # Only do these checks if java-home above is enabled.
1821 if test "x${JAVA_HOME_ENABLED}" = xyes
1822 then
1823
1824   AC_ARG_WITH([gcc-suffix],
1825               AS_HELP_STRING([--with-gcc-suffix],
1826                              [the GCC tool suffix (defaults to empty string)]),
1827               [gcc_suffix=$withval], [gcc_suffix=""])
1828   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1829   AC_SUBST(gcc_suffix)
1830
1831   AC_ARG_WITH([arch-directory],
1832               AS_HELP_STRING([--with-arch-directory],
1833                              [the arch directory under jre/lib (defaults to auto-detect)]),
1834               [host_cpu=$withval], [host_cpu=""])
1835
1836   AC_ARG_WITH([os-directory],
1837               AS_HELP_STRING([--with-os-directory],
1838                              [the os directory under include (defaults to auto-detect)]),
1839               [host_os=$withval], [host_os=""])
1840
1841   AC_ARG_WITH([origin-name],
1842               AS_HELP_STRING([--with-origin-name],
1843                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1844               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1845   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1846
1847   AC_ARG_WITH([arch-suffix],
1848               AS_HELP_STRING([--with-arch-suffix],
1849                              [the arch directory suffix (default is the empty string]),
1850               [arch_suffix=$withval], [arch_suffix=""])
1851   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1852
1853   AC_ARG_WITH([jvm-root-dir],
1854               AS_HELP_STRING([--with-jvm-root-dir],
1855                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1856               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1857   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1858
1859   AC_ARG_WITH([jvm-jar-dir],
1860               AS_HELP_STRING([--with-jvm-jar-dir],
1861                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1862               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1863   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1864
1865   JAVA_VERSION=1.5.0
1866   BUILD_VERSION=0
1867   AC_SUBST(JAVA_VERSION)
1868   AC_SUBST(BUILD_VERSION)
1869   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1870
1871   jre_dir=jre
1872   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1873   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1874
1875   JVM_ROOT_DIR=${jvm_root_dir}
1876   AC_SUBST(JVM_ROOT_DIR)
1877   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1878
1879   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1880   AC_SUBST(JVM_JAR_ROOT_DIR)
1881   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1882
1883   JVM_JAR_DIR=${jvm_jar_dir}
1884   AC_SUBST(JVM_JAR_DIR)
1885   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1886
1887   JRE_DIR=${jre_dir}
1888   AC_SUBST(JRE_DIR)
1889
1890   JRE_LNK=${jre_lnk}
1891   AC_SUBST(JRE_LNK)
1892
1893   SDK_LNK=${sdk_lnk}
1894   AC_SUBST(SDK_LNK)
1895
1896   SDK_BIN_DIR=${jvm_root_dir}/bin
1897   AC_SUBST(SDK_BIN_DIR)
1898   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1899
1900   SDK_LIB_DIR=${jvm_root_dir}/lib
1901   AC_SUBST(SDK_LIB_DIR)
1902   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1903
1904   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1905   AC_SUBST(SDK_INCLUDE_DIR)
1906   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1907
1908   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1909   AC_SUBST(JRE_BIN_DIR)
1910   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1911
1912   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1913   AC_SUBST(JRE_LIB_DIR)
1914   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1915
1916   # Find gcj prefix using gcj found in PATH.
1917   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1918
1919   # Where do the gcj binaries live?
1920   # For jhbuild based builds, they all live in a sibling of bin called
1921   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1922   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1923   AC_SUBST(GCJ_BIN_DIR)
1924   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1925
1926   AC_MSG_RESULT(host is ${host})
1927   if test "x${host_cpu}" = "x"
1928   then
1929     case ${host} in
1930       *-mingw* | *-cygwin*)
1931         host_cpu=x86;;
1932       i486-* | i586-* | i686-*)
1933         host_cpu=i386;;
1934       x86_64-*)
1935         host_cpu=amd64;;
1936       *)
1937         host_cpu=${host_cpu};;
1938     esac
1939   fi
1940   AC_MSG_RESULT(arch directory: ${host_cpu})
1941   CPU=${host_cpu}
1942   AC_SUBST(CPU)
1943
1944   if test "x${host_os}" = "x"
1945   then
1946     case ${host} in
1947       *-mingw* | *-cygwin*)
1948         host_os=win32;;
1949       *-linux*)
1950         host_os=linux;;
1951       *)
1952         host_os=${host_os};;
1953     esac
1954   fi
1955   echo os directory: ${host_os}
1956   OS=${host_os}
1957   AC_SUBST(OS)
1958
1959   # make an expanded $libdir, for substituting into
1960   # scripts (and other non-Makefile things).
1961   LIBDIR=$libdir
1962   if test "x${exec_prefix}" = "xNONE"
1963   then
1964       lib_exec_prefix=$expanded_prefix
1965   else
1966       lib_exec_prefix=$exec_prefix
1967   fi
1968   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1969   AC_SUBST(LIBDIR)
1970 fi
1971
1972 AC_CONFIG_FILES([
1973 Makefile
1974 libgcj.pc
1975 libgcj.spec
1976 libgcj-test.spec
1977 gcj/Makefile
1978 include/Makefile
1979 testsuite/Makefile
1980 contrib/aotcompile.py
1981 contrib/aot-compile
1982 contrib/aot-compile-rpm
1983 contrib/generate-cacerts.pl
1984 contrib/rebuild-gcj-db
1985 ])
1986
1987 if test ${multilib} = yes; then
1988   multilib_arg="--enable-multilib"
1989 else
1990   multilib_arg=
1991 fi
1992
1993 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1994 AC_OUTPUT