libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 LIBGCJ_CFLAGS="${libgcj_cflags}"
 218 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 219 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 220 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 221 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 222 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 223 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 224 AC_SUBST(LIBGCJ_CFLAGS)
 225 AC_SUBST(LIBGCJ_CXXFLAGS)
 226 AC_SUBST(LIBGCJ_JAVAFLAGS)
 227 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 228 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 229 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 230 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 231
 232 # Only use libltdl for non-newlib builds.
 233 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 234    AC_LTDL_SHLIBPATH
 235 fi
 236
 237 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 238
 239 # Possibly build libgcj as many sub-libraries.
 240 AC_ARG_ENABLE(libgcj-sublibs,
 241   AS_HELP_STRING([--enable-libgcj-sublibs],
 242                  [build libgcj as many sub-libraries]))
 243
 244 if test -z "$enable_libgcj_sublibs"; then
 245    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 246 fi
 247 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 248 if test "$enable_libgcj_sublibs" = yes ; then
 249   # In theory we could make do with only one override and simply
 250   # tag "_bc" onto the end of it when we use it to generate the
 251   # spec, but that's an ugly thing to do when there are multiple
 252   # words in the string and you're relying on the ordering to
 253   # append the correct one.
 254   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 255   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 256 fi
 257
 258
 259 # See if the user has requested runtime debugging.
 260 LIBGCJDEBUG="disable"
 261 AC_SUBST(LIBGCJDEBUG)
 262 AC_ARG_ENABLE(libgcj-debug,
 263   AS_HELP_STRING([--enable-libgcj-debug],
 264                  [enable runtime debugging code]),
 265   [if test "$enable_libgcj_debug" = yes; then
 266     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 267     LIBGCJDEBUG="enable"
 268   fi])
 269
 270 AC_ARG_WITH([escher],
 271          AS_HELP_STRING([--with-escher=ABS.PATH],
 272                         [specify path to escher dir or JAR for X peers]))
 273 case "$with_escher" in
 274 "")
 275         use_escher=false
 276         ;;
 277 "no")
 278         use_escher=false
 279         ;;
 280 "yes")
 281         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 282         ;;
 283 *)
 284         use_escher=true
 285         ;;
 286 esac
 287
 288 # Determine which AWT peer libraries to build
 289 AC_ARG_ENABLE(java-awt,
 290   AS_HELP_STRING([--enable-java-awt],
 291                  [list of AWT peer implementations to be built]))
 292
 293 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 294 use_xlib_awt=""
 295 use_gtk_awt=""
 296 use_qt_awt=""
 297 use_x_awt=""
 298 # The default toolkit to use is the first one specified.
 299 TOOLKIT=
 300 AC_SUBST(TOOLKIT)
 301
 302 for peer in $peerlibs ; do
 303   case $peer in
 304     xlib)
 305       if test "$no_x" = yes; then
 306         echo "*** xlib peers requested but no X library available" 1>&2
 307         exit 1
 308       else
 309         use_xlib_awt="yes"
 310         if test -z "$TOOLKIT"; then
 311            TOOLKIT=gnu.awt.xlib.XToolkit
 312         fi
 313       fi
 314       ;;
 315     gtk)
 316       if test "$no_x" = yes; then
 317          echo "*** gtk peers requested but no X library available" 1>&2
 318          exit 1
 319       else
 320          use_gtk_awt=yes
 321          if test -z "$TOOLKIT"; then
 322             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 323          fi
 324       fi
 325       ;;
 326     qt)
 327       if test "$no_x" = yes; then
 328          # Perhaps we should admit the possibility of embedded Qt.
 329          echo "*** Qt peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_qt_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 335          fi
 336       fi
 337       ;;
 338     x)
 339       use_x_awt=yes
 340       if test -z "$TOOLKIT"; then
 341          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 342       fi
 343       ;;
 344     no)
 345       use_xlib_awt=
 346       use_gtk_awt=
 347       use_qt_awt=
 348       use_x_awt=
 349       break
 350       ;;
 351     *)
 352       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 353       exit 1
 354   esac
 355 done
 356
 357 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 358 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 359
 360 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 361
 362 expanded_prefix=$prefix
 363 if test "X$prefix" = XNONE; then
 364   expanded_prefix=${ac_default_prefix}
 365 fi
 366
 367 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 368
 369 # Create standard.omit based on decisions we just made.
 370 cp $srcdir/standard.omit.in standard.omit
 371 if test "$use_xlib_awt" != yes; then
 372    echo gnu/awt/xlib >> standard.omit
 373    echo gnu/gcj/xlib >> standard.omit
 374 fi
 375 if test "$use_x_awt" != yes; then
 376    echo gnu/java/awt/peer/x >> standard.omit
 377 fi
 378
 379 # Tools that need to be compiled against classpath's tools classes
 380 : > vm-tools-packages
 381 for package in gnu/gcj/tools/gc_analyze ; do
 382     echo $package >> standard.omit
 383     echo $package >> vm-tools-packages
 384 done
 385
 386 if test -z "${with_multisubdir}"; then
 387    builddotdot=.
 388 else
 389    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 390 fi
 391
 392 NATIVE=yes
 393
 394 # Which gcj and host gcj (for ecjx) do we use?
 395 which_gcj=default
 396 host_exeext=${ac_exeext}
 397 GCJ_FOR_ECJX=
 398 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 399 if test -n "${with_cross_host}"; then
 400   # We are being configured with a cross compiler. We can't
 401   # use ac_exeext, because that is for the target platform.
 402   NATIVE=no
 403   cross_host_exeext=
 404   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 405   case "${with_cross_host}" in
 406      *mingw* | *cygwin*)
 407          cross_host_exeext=.exe
 408      ;;
 409   esac
 410   host_exeext=${cross_host_exeext}
 411   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 412      if test x"$build_noncanonical" = x"$with_cross_host"; then
 413         # Ordinary cross (host!=target and host=build)
 414         which_gcj=built
 415      else
 416         # Canadian cross (host!=target and host!=build)
 417         which_gcj=cross
 418      fi
 419   else
 420      which_gcj=cross
 421   fi
 422 else
 423   # We are being configured with a native or crossed-native compiler
 424   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 425      if test x"$build" = x"$host"; then
 426         # True native build (host=target and host=build)
 427         which_gcj=built
 428      else
 429         # Crossed-native build (host=target and host!=build)
 430         which_gcj=cross
 431      fi
 432   else
 433      which_gcj=path
 434   fi
 435 fi
 436 libgcjdir=`${PWDCMD-pwd}`
 437 case $GCJ in
 438 *" -B"*)
 439   # Just in case there is a comma in the build dir, quote it for the
 440   # sed command below.
 441   case $libgcjdir in
 442   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 443   *) qlibgcjdir=$libgcjdir;;
 444   esac
 445   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 446   ;;
 447 *)
 448   GCJ=$GCJ" -B$libgcjdir/"
 449   ;;
 450 esac
 451 case "${which_gcj}" in
 452    built)
 453       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 454    ;;
 455    cross)
 456       if test "x${with_newlib}" = "xyes"; then
 457          # FIXME (comment): Why is this needed?
 458          GCC_UNWIND_INCLUDE=
 459       fi
 460       GCJH='$(target_noncanonical)-gcjh'
 461    ;;
 462    path)
 463       GCJH=gcjh
 464    ;;
 465 esac
 466 JAVAC="$GCJ -C"
 467 export JAVAC
 468
 469 AC_SUBST(GCJ_FOR_ECJX)
 470 AC_SUBST(GCJH)
 471 AC_SUBST(host_exeext)
 472
 473 # Create it, so that compile/link tests don't fail
 474 test -f libgcj.spec || touch libgcj.spec
 475
 476
 477
 478 # Set up to configure Classpath.
 479 # FIXME: no supported way to pass args in autoconf.
 480 # Disable tool wrappers to avoid ltdl.h configure check.
 481 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 482 ac_configure_args="$ac_configure_args --disable-load-library"
 483 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 484 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 485 dir1=`cd $srcdir && pwd`
 486 dir2=`pwd`
 487 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 488 ac_configure_args="$ac_configure_args --disable-core-jni"
 489 dnl FIXME?
 490 ac_configure_args="$ac_configure_args --disable-examples"
 491 ac_configure_args="$ac_configure_args --with-glibj=build"
 492 if test "$browser_plugin_enabled" != yes; then
 493   ac_configure_args="$ac_configure_args --disable-plugin"
 494 else
 495   ac_configure_args="$ac_configure_args --enable-plugin"
 496 fi
 497 if test "$gconf_enabled" != yes; then
 498   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 499   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 500 fi
 501 if test "$use_gtk_awt" != yes; then
 502   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 503 fi
 504 if test "$use_qt_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-qt-peer"
 506 else
 507   # We need this as qt is disabled by default in classpath.
 508   ac_configure_args="$ac_configure_args --enable-qt-peer"
 509 fi
 510 if test "$use_x_awt" != yes; then
 511   ac_configure_args="$ac_configure_args --without-escher"
 512 else
 513   # We need this as escher is disabled by default in classpath.
 514   if test "$use_escher" != true; then
 515     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 516   else
 517     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 518   fi
 519 fi
 520 if test "x$BUILD_GJDOC" = xno; then
 521   ac_configure_args="$ac_configure_args --disable-gjdoc"
 522 fi
 523 # -Werror causes unavoidable problems in code using alsa.
 524 ac_configure_args="$ac_configure_args --disable-regen-headers"
 525 ac_configure_args="$ac_configure_args --disable-Werror"
 526 dnl --with-gcj=$GCJ
 527 dnl --with-javah=$GCJH
 528 dnl gtk-cairo -- just export here...
 529 dnl --enable-regen-headers?
 530
 531 # Only use libltdl for non-newlib builds.
 532 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 533    AC_LIBLTDL_CONVENIENCE
 534    AC_LIBTOOL_DLOPEN
 535    DIRLTDL=libltdl
 536    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 537    # Sigh.  Libtool's macro doesn't do the right thing.
 538    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 539    # FIXME: this is a hack.
 540    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 541    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 542 fi
 543 AC_SUBST(INCLTDL)
 544 AC_SUBST(LIBLTDL)
 545 AC_SUBST(DIRLTDL)
 546 AC_PROG_LIBTOOL
 547 AM_PROG_GCJ
 548 AM_PROG_CC_C_O
 549
 550 AC_CONFIG_SUBDIRS(classpath libltdl)
 551
 552 # The -no-testsuite modules omit the test subdir.
 553 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 554
 555 # Should the runtime set system properties by examining the
 556 # environment variable GCJ_PROPERTIES?
 557 AC_ARG_ENABLE(getenv-properties,
 558   AS_HELP_STRING([--disable-getenv-properties],
 559                  [don't set system properties from GCJ_PROPERTIES]))
 560
 561 # Whether GCJ_PROPERTIES is used depends on the target.
 562 if test -z "$enable_getenv_properties"; then
 563    enable_getenv_properties=${enable_getenv_properties_default-yes}
 564 fi
 565 if test "$enable_getenv_properties" = no; then
 566    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 567      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 568 fi
 569
 570 # Whether we should use arguments to main()
 571 if test -z "$enable_main_args"; then
 572    enable_main_args=${enable_main_args_default-yes}
 573 fi
 574 if test "$enable_main_args" = no; then
 575    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 576 fi
 577
 578
 579 # Should we use hashtable-based synchronization?
 580 # Currently works only for Linux X86/ia64
 581 # Typically faster and more space-efficient
 582 AC_ARG_ENABLE(hash-synchronization,
 583   AS_HELP_STRING([--enable-hash-synchronization],
 584                  [use global hash table for monitor locks]))
 585
 586 if test -z "$enable_hash_synchronization"; then
 587    enable_hash_synchronization=$enable_hash_synchronization_default
 588 fi
 589
 590
 591 install_ecj_jar=no
 592 ECJ_BUILD_JAR=
 593 ECJ_JAR=
 594 AC_ARG_WITH(ecj-jar,
 595         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 596         [ECJ_JAR=$withval],
 597         [if test -f $multi_basedir/ecj.jar; then
 598            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 599            ECJ_JAR='$(jardir)/ecj.jar'
 600            install_ecj_jar=yes
 601          fi])
 602 AC_SUBST(ECJ_BUILD_JAR)
 603 AC_SUBST(ECJ_JAR)
 604 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 605 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 606
 607 AC_ARG_WITH(java-home,
 608   AS_HELP_STRING([--with-java-home=DIRECTORY],
 609                  [value of java.home system property]),
 610                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 611 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 612 AC_SUBST(JAVA_HOME)
 613
 614 suppress_libgcj_bc=no
 615 AC_ARG_ENABLE(libgcj-bc,
 616   AS_HELP_STRING([--enable-libgcj-bc],
 617                  [enable(default) or disable BC ABI for portions of libgcj]),
 618   [if test "$enable_libgcj_bc" = "no"; then
 619      suppress_libgcj_bc=yes
 620    fi])
 621 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 622
 623 build_libgcj_reduced_reflection=no
 624 AC_ARG_ENABLE(reduced-reflection,
 625   AS_HELP_STRING([--enable-reduced-reflection],
 626                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 627   [if test "$enable_reduced_reflection" = "yes"; then
 628      build_libgcj_reduced_reflection=yes
 629    fi])
 630 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 631
 632 # What is the native OS API for MinGW?
 633 AC_ARG_WITH(win32-nlsapi,
 634   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 635                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 636 [case "${withval}" in
 637   ansi) with_win32_nlsapi=ansi ;;
 638   unicows) with_win32_nlsapi=unicows ;;
 639   unicode) with_win32_nlsapi=unicode ;;
 640   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 641 esac],[with_win32_nlsapi=ansi])
 642
 643 case "${with_win32_nlsapi}" in
 644   unicows | unicode)
 645     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 646       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 647     ;;
 648 esac
 649
 650 # configure.host sets slow_pthread_self if the synchronization code should
 651 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 652 if test "${slow_pthread_self}" = "yes"; then
 653   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 654     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 655 fi
 656
 657 # Check for gc debugging.  This option is handled both here and in the GC.
 658 AC_ARG_ENABLE(gc-debug,
 659    AS_HELP_STRING([--enable-gc-debug],
 660                   [include full support for pointer backtracing etc.]),
 661 [ if test "$enable_gc_debug" = "yes"; then
 662     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 663               [Define if we want to use debug calls into the garbage collector.])
 664   fi])
 665
 666 # See if the user has the interpreter included.
 667 AC_ARG_ENABLE(interpreter,
 668   AS_HELP_STRING([--enable-interpreter],
 669                  [enable interpreter]),
 670   [if test "$enable_interpreter" = yes; then
 671     # This can also be set in configure.host.
 672     libgcj_interpreter=yes
 673   elif test "$enable_interpreter" = no; then
 674     libgcj_interpreter=no
 675   fi])
 676
 677 if test "$libgcj_interpreter" = yes; then
 678    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 679 fi
 680 INTERPRETER="$libgcj_interpreter"
 681 AC_SUBST(INTERPRETER)
 682 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 683
 684 AC_MSG_CHECKING([for exception model to use])
 685 AC_LANG_PUSH(C++)
 686 AC_ARG_ENABLE(sjlj-exceptions,
 687   AS_HELP_STRING([--enable-sjlj-exceptions],
 688                  [force use of builtin_setjmp for exceptions]),
 689 [:],
 690 [dnl Botheration.  Now we've got to detect the exception model.
 691 dnl Link tests against libgcc.a are problematic since -- at least
 692 dnl as of this writing -- we've not been given proper -L bits for
 693 dnl single-tree newlib and libgloss.
 694 dnl
 695 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 696 dnl conftest files before we got a change to grep them first.
 697 cat > conftest.$ac_ext << EOF
 698 [#]line __oline__ "configure"
 699 struct S { ~S(); };
 700 void bar();
 701 void foo()
 702 {
 703   S s;
 704   bar();
 705 }
 706 EOF
 707 old_CXXFLAGS="$CXXFLAGS"
 708 CXXFLAGS=-S
 709 if AC_TRY_EVAL(ac_compile); then
 710   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 711     enable_sjlj_exceptions=yes
 712   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 713     enable_sjlj_exceptions=no
 714   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 715     # ARM EH ABI.
 716     enable_sjlj_exceptions=no
 717   fi
 718 fi
 719 CXXFLAGS="$old_CXXFLAGS"
 720 rm -f conftest*])
 721 if test x$enable_sjlj_exceptions = xyes; then
 722   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 723         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 724   ac_exception_model_name=sjlj
 725 elif test x$enable_sjlj_exceptions = xno; then
 726   ac_exception_model_name="call frame"
 727 else
 728   AC_MSG_ERROR([unable to detect exception model])
 729 fi
 730 AC_LANG_POP(C++)
 731 AC_MSG_RESULT($ac_exception_model_name)
 732
 733 # If we are non using SJLJ exceptions, and this host does not have support
 734 # for unwinding from a signal handler, enable checked dereferences and divides.
 735 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 736   CHECKREFSPEC=-fcheck-references
 737   DIVIDESPEC=-fuse-divide-subroutine
 738   EXCEPTIONSPEC=
 739 fi
 740
 741 # See if the user wants to disable java.net.  This is the mildly
 742 # ugly way that we admit that target-side configuration sucks.
 743 AC_ARG_ENABLE(java-net,
 744   AS_HELP_STRING([--disable-java-net],
 745                  [disable java.net]))
 746
 747 # Whether java.net is built by default can depend on the target.
 748 if test -z "$enable_java_net"; then
 749    enable_java_net=${enable_java_net_default-yes}
 750 fi
 751 if test "$enable_java_net" = no; then
 752    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 753 fi
 754
 755 # See if the user wants to configure without libffi.  Some
 756 # architectures don't support it, and default values are set in
 757 # configure.host.
 758 AC_ARG_WITH(libffi,
 759   AS_HELP_STRING([--without-libffi],
 760                  [don't use libffi]),
 761   [:],
 762   [with_libffi=${with_libffi_default-yes}])
 763
 764 LIBFFI=
 765 LIBFFIINCS=
 766 if test "$with_libffi" != no; then
 767    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 768    LIBFFI=../libffi/libffi_convenience.la
 769    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 770 fi
 771 AC_SUBST(LIBFFI)
 772 AC_SUBST(LIBFFIINCS)
 773
 774 # See if the user wants to disable JVMPI support.
 775 AC_ARG_ENABLE(jvmpi,
 776   AS_HELP_STRING([--disable-jvmpi],
 777                  [disable JVMPI support]))
 778
 779 if test "$enable_jvmpi" != no; then
 780     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 781 fi
 782
 783 # If the target is an eCos system, use the appropriate eCos
 784 # I/O routines.
 785 # FIXME: this should not be a local option but a global target
 786 # system; at present there is no eCos target.
 787 TARGET_ECOS=${PROCESS-"no"}
 788 AC_ARG_WITH(ecos,
 789 [  --with-ecos             enable runtime eCos target support],
 790 TARGET_ECOS="$with_ecos"
 791 )
 792
 793 case "$TARGET_ECOS" in
 794    no) case "$host" in
 795       *mingw*)
 796             PLATFORM=Win32
 797             PLATFORMNET=Win32
 798             PLATFORMH=win32.h
 799         CHECK_FOR_BROKEN_MINGW_LD
 800       ;;
 801       *)
 802             PLATFORM=Posix
 803             PLATFORMNET=Posix
 804             PLATFORMH=posix.h
 805       ;;
 806       esac
 807       ;;
 808    *)
 809       PLATFORM=Ecos
 810       PLATFORMNET=NoNet
 811       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 812       PLATFORMH=posix.h
 813       ;;
 814 esac
 815 AC_SUBST(PLATFORM)
 816 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 817
 818 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 819                                       [Define if you have int32_t and uint32_t.]))
 820 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 821                                         [Define if you have int32_t and uint32_t.]))
 822 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 823                                           [Define if you have u_int32_t]))
 824 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 825                                            [Define if you have u_int32_t]))
 826
 827 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 828 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 829
 830 case "$host" in
 831   *-darwin*) DARWIN_CRT=true ;;
 832   *) DARWIN_CRT=false ;;
 833 esac
 834 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 835
 836 # This may not be defined in a non-ANS conformant embedded system.
 837 # FIXME: Should these case a runtime exception in that case?
 838 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 839                                   [Define is you have 'localtime' in <time.h>]))
 840
 841 # Create the subdirectory for natFile.cc, or the attempt
 842 # to create the link will fail.
 843 test -d java || mkdir java
 844 test -d java/io || mkdir java/io
 845 test -d gnu || mkdir gnu
 846 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 847
 848 # Likewise for natConcreteProcess.cc.
 849 test -d java/lang || mkdir java/lang
 850 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 851
 852 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 853 test -d java/net || mkdir java/net
 854 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 855 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 856
 857 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 858 test -d gnu/java || mkdir gnu/java
 859 test -d gnu/java/net || mkdir gnu/java/net
 860 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 861 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 862
 863 # Likewise for natVMPipe.cc and natVMSelector.cc.
 864 test -d gnu/java/nio || mkdir gnu/java/nio
 865 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 866 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 867
 868 # Likewise for natFileChannelImpl.cc
 869 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 870 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 871
 872 # Likewise for natVMSecureRandom.cc
 873 test -d gnu/java/security || mkdir gnu/java/security
 874 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 875 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 876 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 877
 878 case "${host}" in
 879     *mingw*)
 880       SYSTEMSPEC="-lgdi32 -lws2_32"
 881       if test "${with_win32_nlsapi}" = "unicows"; then
 882         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 883       fi
 884     ;;
 885     *-*-darwin[[912]]*)
 886       SYSTEMSPEC="-allow_stack_execute"
 887     ;;
 888     *)
 889       SYSTEMSPEC=
 890     ;;
 891 esac
 892 AC_SUBST(SYSTEMSPEC)
 893
 894 AC_ARG_WITH(system-zlib,
 895   AS_HELP_STRING([--with-system-zlib],
 896                  [use installed libz]))
 897 ZLIBSPEC=
 898 AC_SUBST(ZLIBSPEC)
 899 ZLIBTESTSPEC=
 900 AC_SUBST(ZLIBTESTSPEC)
 901
 902 AC_PATH_XTRA
 903
 904 # FIXME: this should be _libs on some hosts.
 905 libsubdir=.libs
 906
 907 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 908
 909 LIBSTDCXXSPEC=
 910 # extra LD Flags which are required for targets
 911 case "${host}" in
 912 *-*-darwin[[0-7]].*)
 913     # For now we have to disable it on darwin[8-9] because it slows down
 914     # the linking phase. A possible bug in ld?
 915     # on Darwin -single_module speeds up loading of the dynamic libraries.
 916     extra_ldflags_libjava=-Wl,-single_module
 917     ;;
 918 arm*linux*eabi)
 919     # Some of the ARM unwinder code is actually in libstdc++.  We
 920     # could in principle replicate it in libgcj, but it's better to
 921     # have a dependency on libstdc++.
 922     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 923     LIBSTDCXXSPEC=-lstdc++
 924     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 925     ;;
 926 *-*-cygwin)
 927     extra_ldflags_libjava=-liconv
 928     ;;
 929 esac
 930
 931 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 932 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 933   [saved_ldflags="$LDFLAGS"
 934    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 935    # The IRIX 6 ld doesn't recognize --no-merge-exidx-entries, but only
 936    # warns about unknown options, which breaks the testsuite.  So enable
 937    # AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 938    # it off again.  As a workaround, save and restore werror flag like
 939    # AC_PATH_XTRA.
 940    ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 941    AC_LANG_WERROR
 942    AC_LINK_IFELSE([int main(void){ return 0;} ],
 943                       [eval "libgcj_cv_exidx=yes"],
 944                       [eval "libgcj_cv_exidx=no"])
 945    ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 946    LDFLAGS="${saved_ldflags}"]
 947 )
 948 if test "${libgcj_cv_exidx}" = "yes"; then
 949   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 950   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 951 fi
 952
 953 AC_SUBST(extra_ldflags_libjava)
 954 AC_SUBST(extra_ldflags)
 955 AC_SUBST(LIBSTDCXXSPEC)
 956
 957 AC_SUBST(LIBGCJTESTSPEC)
 958
 959 # Allow the GC to be disabled.  Can be useful when debugging.
 960 AC_MSG_CHECKING([for garbage collector to use])
 961 AC_ARG_ENABLE(java-gc,
 962   AS_HELP_STRING([--enable-java-gc=TYPE],
 963                  [choose garbage collector (default is boehm)]),
 964   [GC=$enableval],
 965   [GC=boehm])
 966 GCLIBS=
 967 GCINCS=
 968 GCDEPS=
 969 GCSPEC=
 970 JC1GCSPEC=
 971 GCTESTSPEC=
 972 case "$GC" in
 973  boehm)
 974     AC_MSG_RESULT(boehm)
 975     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 976     JC1GCSPEC='-fuse-boehm-gc'
 977     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 978     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 979     GCOBJS=boehm.lo
 980     GCHDR=boehm-gc.h
 981     # The POSIX thread support needs to know this.
 982     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 983     ;;
 984  no)
 985     AC_MSG_RESULT(none)
 986     GCHDR=no-gc.h
 987     ;;
 988  *)
 989     AC_MSG_ERROR([unrecognized collector "$GC"])
 990     ;;
 991 esac
 992 AC_SUBST(GCLIBS)
 993 AC_SUBST(GCINCS)
 994 AC_SUBST(GCDEPS)
 995 AC_SUBST(GCSPEC)
 996 AC_SUBST(JC1GCSPEC)
 997 AC_SUBST(GCTESTSPEC)
 998 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 999 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1000 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1001
1002
1003 AC_MSG_CHECKING([for thread model used by GCC])
1004 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1005 AC_MSG_RESULT([$THREADS])
1006
1007 case "$THREADS" in
1008  no | none | single)
1009     THREADS=none
1010     ;;
1011  aix | posix | posix95 | pthreads)
1012     THREADS=posix
1013     case "$host" in
1014      *-*-linux*)
1015         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1016         ;;
1017     esac
1018     ;;
1019  win32)
1020     ;;
1021  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1022     AC_MSG_ERROR(thread package $THREADS not yet supported)
1023     ;;
1024  *)
1025     AC_MSG_ERROR($THREADS is an unknown thread package)
1026     ;;
1027 esac
1028
1029 THREADCXXFLAGS=
1030 THREADLDFLAGS=
1031 THREADLIBS=
1032 THREADINCS=
1033 THREADDEPS=
1034 THREADH=
1035 THREADSPEC=
1036 THREADSTARTFILESPEC=
1037 case "$THREADS" in
1038  posix)
1039     case "$host" in
1040      *-*-cygwin*)
1041         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1042         ;;
1043      *-*-freebsd[[1234]]*)
1044         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1045         # merely adds pthread_* functions) but it does have a -pthread switch
1046         # which is required at link-time to select -lc_r *instead* of -lc.
1047         THREADLDFLAGS=-pthread
1048         # Don't set THREADSPEC here as might be expected since -pthread is
1049         # not processed when found within a spec file, it must come from
1050         # the command line.  For now, the user must provide the -pthread
1051         # switch to link code compiled with gcj.  In future, consider adding
1052         # support for weak references to pthread_* functions ala gthr.h API.
1053         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1054         ;;
1055      *-*-freebsd*)
1056         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1057         # systems which support threads and -lpthread.
1058         THREADLDFLAGS=-pthread
1059         THREADSPEC=-lpthread
1060         ;;
1061      alpha*-dec-osf* | hppa*-hp-hpux*)
1062         THREADCXXFLAGS=-pthread
1063         # boehm-gc needs some functions from librt, so link that too.
1064         THREADLIBS='-lpthread -lrt'
1065         THREADSPEC='-lpthread -lrt'
1066         ;;
1067      *)
1068         THREADLIBS=-lpthread
1069         THREADSPEC=-lpthread
1070         ;;
1071     esac
1072     THREADH=posix-threads.h
1073     # MIT pthreads doesn't seem to have the mutexattr functions.
1074     # But for now we don't check for it.  We just assume you aren't
1075     # using MIT pthreads.
1076     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1077
1078     # If we're using the Boehm GC, then we happen to know that it
1079     # defines _REENTRANT, so we don't bother.  Eww.
1080     if test "$GC" != boehm; then
1081        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1082     fi
1083     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1084     ;;
1085
1086  win32)
1087     THREADH=win32-threads.h
1088     THREADCXXFLAGS=-mthreads
1089     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1090     # But we do not want the executables created to be dependent on
1091     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1092     # exception handling contexts.  The following kludge achieves this effect
1093     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1094     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1095     # A workaround is to explicitly use -mthreads while linking Java programs.
1096     # See PR libgcj/28263.
1097     #
1098     # FIXME: In Java we are able to detect thread death at the end of
1099     # Thread.run() so we should be able to clean up the exception handling
1100     # contexts ourselves.
1101     THREADSTARTFILESPEC='crtmt%O%s'
1102     ;;
1103
1104  none)
1105     THREADH=no-threads.h
1106     ;;
1107 esac
1108 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1109 AC_SUBST(THREADLIBS)
1110 AC_SUBST(THREADINCS)
1111 AC_SUBST(THREADDEPS)
1112 AC_SUBST(THREADSPEC)
1113 AC_SUBST(THREADSTARTFILESPEC)
1114 AC_SUBST(THREADLDFLAGS)
1115 AC_SUBST(THREADCXXFLAGS)
1116 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1117 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1118 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1119 if test "$enable_shared" != yes; then
1120   use_libgcj_bc=no
1121 fi
1122 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1123
1124 if test -d sysdep; then true; else mkdir sysdep; fi
1125 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1126 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1127 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1128
1129 LIBGCJ_SPEC_LGCJ=-lgcj
1130 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1131 if test x"$libgcj_spec_lgcj_override" != x ; then
1132   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1133 fi
1134 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1135   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1136 fi
1137 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1138 if test "$use_libgcj_bc" = yes; then
1139   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1140   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1141 fi
1142 AC_SUBST(LIBGCJ_SPEC)
1143 AC_SUBST(LIBGCJ_BC_SPEC)
1144
1145 HASH_SYNC_SPEC=
1146 # Hash synchronization is only useful with posix threads right now.
1147 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1148    HASH_SYNC_SPEC=-fhash-synchronization
1149    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1150 fi
1151 AC_SUBST(HASH_SYNC_SPEC)
1152
1153 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1154
1155 # We're in the tree with gcc, and need to include some of its headers.
1156 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1157
1158 if test "x${with_newlib}" = "xyes"; then
1159    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1160    # may not work correctly, because the compiler may not be able to
1161    # link executables.
1162
1163    # We assume newlib.  This lets us hard-code the functions we know
1164    # we'll have.
1165    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1166    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1167    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1168    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1169    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1170    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1171    # This is only for POSIX threads.
1172    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1173
1174    # Assume we do not have getuid and friends.
1175    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1176    PLATFORMNET=NoNet
1177 else
1178    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1179                    localtime_r getpwuid_r getcwd \
1180                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1181                    nl_langinfo setlocale \
1182                    inet_pton uname inet_ntoa \
1183                    getrlimit sigaction ftruncate mmap \
1184                    getifaddrs])
1185    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1186    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1187    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1188    AC_CHECK_LIB(dl, dladdr, [
1189        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1190        AC_CHECK_LIB(dld, dladdr, [
1191        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1192
1193    if test x"$cross_compiling" = x"no"; then
1194      AC_CHECK_FILES(/proc/self/exe, [
1195        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1196      AC_CHECK_FILES(/proc/self/maps, [
1197        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1198          [Define if you have /proc/self/maps])])
1199    else
1200      case $host in
1201      *-linux*)
1202        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1203        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1204        ;;
1205      esac
1206    fi
1207
1208    AM_ICONV
1209    AM_LC_MESSAGES
1210    AC_STRUCT_TIMEZONE
1211
1212    AC_CHECK_FUNCS(gethostbyname_r, [
1213      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1214        [Define if you have the 'gethostbyname_r' function.])
1215      # There are two different kinds of gethostbyname_r.
1216      # We look for the one that returns `int'.
1217      # Hopefully this check is robust enough.
1218      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1219        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1220
1221      case " $GCINCS " in
1222      *" -D_REENTRANT "*) ;;
1223      *)
1224         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1225         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1226         [libjava_cv_gethostbyname_r_needs_reentrant],
1227         [ AC_LANG_PUSH(C++)
1228           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1229             [[gethostbyname_r("", 0, 0);]])],
1230             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1231                 CPPFLAGS_SAVE="$CPPFLAGS"
1232                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1233                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1234                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1235                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1236                 CPPFLAGS="$CPPFLAGS_SAVE"
1237           ])
1238           AC_LANG_POP(C++)
1239         ])
1240         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1241           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1242         fi
1243      ;;
1244      esac
1245
1246      AC_CACHE_CHECK([for struct hostent_data],
1247         [libjava_cv_struct_hostent_data], [dnl
1248         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1249 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1250 # define _REENTRANT 1
1251 #endif
1252 #include <netdb.h>]], [[struct hostent_data data;]])],
1253           [libjava_cv_struct_hostent_data=yes],
1254           [libjava_cv_struct_hostent_data=no])])
1255      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1256        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1257          [Define if struct hostent_data is defined in netdb.h])
1258      fi
1259    ])
1260
1261    # FIXME: libjava source code expects to find a prototype for
1262    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1263    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1264    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1265    # linkage check is enough, yet C++ code requires proper prototypes.)
1266    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1267    AC_CHECK_FUNCS(gethostbyaddr_r, [
1268      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1269        [Define if you have the 'gethostbyaddr_r' function.])
1270      # There are two different kinds of gethostbyaddr_r.
1271      # We look for the one that returns `int'.
1272      # Hopefully this check is robust enough.
1273      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1274        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1275          [Define if gethostbyaddr_r returns 'int'.])])])])
1276
1277    AC_CHECK_FUNCS(gethostname, [
1278      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1279        [Define if you have the 'gethostname' function.])
1280      AC_EGREP_HEADER(gethostname, unistd.h, [
1281        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1282          [Define if gethostname is declared in <unistd.h>.])])])
1283
1284    AC_CHECK_FUNCS(usleep, [
1285      AC_EGREP_HEADER(usleep, unistd.h, [
1286        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1287           [Define if usleep is declared in <unistd.h>.])])])
1288
1289    # Look for these functions in the thread library, but only bother
1290    # if using POSIX threads.
1291    if test "$THREADS" = posix; then
1292       save_LIBS="$LIBS"
1293       LIBS="$LIBS $THREADLIBS"
1294
1295       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1296       # Solaris 7 the name librt is preferred.
1297       AC_CHECK_FUNCS(sched_yield, , [
1298         AC_CHECK_LIB(rt, sched_yield, [
1299           AC_DEFINE(HAVE_SCHED_YIELD)
1300           THREADLIBS="$THREADLIBS -lrt"
1301           THREADSPEC="$THREADSPEC -lrt"], [
1302           AC_CHECK_LIB(posix4, sched_yield, [
1303             AC_DEFINE(HAVE_SCHED_YIELD)
1304             THREADLIBS="$THREADLIBS -lposix4"
1305             THREADSPEC="$THREADSPEC -lposix4"])])])
1306
1307       AC_CHECK_LIB(rt, clock_gettime, [
1308          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1309          case "$THREADSPEC" in
1310            *-lrt*) ;;
1311            *)
1312              THREADSPEC="$THREADSPEC -lrt"
1313              THREADLIBS="$THREADLIBS -lrt"
1314              ;;
1315          esac])
1316
1317       LIBS="$save_LIBS"
1318
1319       # We can save a little space at runtime if the mutex has m_count
1320       # or __m_count.  This is a nice hack for Linux.
1321       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1322           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1323         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1324              [Define if pthread_mutex_t has m_count member.]), [
1325         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1326             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1327           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1328             [Define if pthread_mutex_t has __m_count member.]))])
1329    fi
1330
1331    # We require a way to get the time.
1332    time_found=no
1333    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1334    if test "$time_found" = no; then
1335       AC_MSG_ERROR([no function found to get the time])
1336    fi
1337
1338    AC_CHECK_FUNCS(memmove)
1339
1340    # We require memcpy.
1341    memcpy_found=no
1342    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1343    if test "$memcpy_found" = no; then
1344       AC_MSG_ERROR([memcpy is required])
1345    fi
1346    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1347    AC_CHECK_LIB(dl, dlopen, [
1348        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1349        AC_CHECK_LIB(dld, dlopen, [
1350        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1351
1352    # Some library-finding code we stole from Tcl.
1353    #--------------------------------------------------------------------
1354    #    Check for the existence of the -lsocket and -lnsl libraries.
1355    #    The order here is important, so that they end up in the right
1356    #    order in the command line generated by make.  Here are some
1357    #    special considerations:
1358    #    1. Use "connect" and "accept" to check for -lsocket, and
1359    #       "gethostbyname" to check for -lnsl.
1360    #    2. Use each function name only once:  can't redo a check because
1361    #       autoconf caches the results of the last check and won't redo it.
1362    #    3. Use -lnsl and -lsocket only if they supply procedures that
1363    #       aren't already present in the normal libraries.  This is because
1364    #       IRIX 5.2 has libraries, but they aren't needed and they're
1365    #       bogus:  they goof up name resolution if used.
1366    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1367    #       To get around this problem, check for both libraries together
1368    #       if -lsocket doesn't work by itself.
1369    #--------------------------------------------------------------------
1370
1371    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1372     [gcj_cv_lib_sockets=
1373      gcj_checkBoth=0
1374      unset ac_cv_func_connect
1375      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1376      if test "$gcj_checkSocket" = 1; then
1377          unset ac_cv_func_connect
1378          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1379                       gcj_checkBoth=1)
1380      fi
1381      if test "$gcj_checkBoth" = 1; then
1382          gcj_oldLibs=$LIBS
1383          LIBS="$LIBS -lsocket -lnsl"
1384          unset ac_cv_func_accept
1385          AC_CHECK_FUNC(accept,
1386                        [gcj_checkNsl=0
1387                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1388          unset ac_cv_func_accept
1389          LIBS=$gcj_oldLibs
1390      fi
1391      unset ac_cv_func_gethostbyname
1392      gcj_oldLibs=$LIBS
1393      LIBS="$LIBS $gcj_cv_lib_sockets"
1394      AC_CHECK_FUNC(gethostbyname, ,
1395                    [AC_CHECK_LIB(nsl, main,
1396                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1397      unset ac_cv_func_gethostbyname
1398      LIBS=$gcj_oldLIBS
1399    ])
1400    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1401
1402    if test "$with_system_zlib" = yes; then
1403       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1404    fi
1405
1406    # Test for Gtk stuff, if asked for.
1407    if test "$use_gtk_awt" = yes; then
1408       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1409       AC_SUBST(GTK_CFLAGS)
1410       AC_SUBST(GTK_LIBS)
1411
1412       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1413       AC_SUBST(GLIB_CFLAGS)
1414       AC_SUBST(GLIB_LIBS)
1415
1416       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1417       AC_SUBST(LIBART_CFLAGS)
1418       AC_SUBST(LIBART_LIBS)
1419
1420       # We require the XTest Extension to support java.awt.Robot.
1421       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1422                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1423                    [${X_LIBS}])
1424    fi
1425
1426    # On Solaris, and maybe other architectures, the Boehm collector
1427    # requires -ldl.
1428    if test "$GC" = boehm; then
1429       case "${host}" in
1430           mips-sgi-irix6*)
1431             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1432             # libgcj.spec is used, so override here
1433             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1434           ;;
1435           *)
1436             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1437           ;;
1438       esac
1439    fi
1440 fi
1441
1442 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1443 case $build in
1444     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1445     *)         CLASSPATH_SEPARATOR=':' ;;
1446 esac
1447 AC_SUBST(CLASSPATH_SEPARATOR)
1448
1449 # We must search the source tree for java.lang, since we still don't
1450 # have libgcj.jar nor java/lang/*.class
1451 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1452 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1453
1454 # Since some classes depend on this one, we need its source available
1455 # before we can do any GCJ compilation test :-(
1456 if test ! -f gnu/classpath/Configuration.java; then
1457   test -d gnu || mkdir gnu
1458   test -d gnu/classpath || mkdir gnu/classpath
1459   # Note that it is not crucial that all the values here be correct.
1460   sed -e "s,@prefix@,$expanded_prefix," \
1461       -e "s,@VERSION@,$VERSION," \
1462       -e "s,@LIBDEBUG@,false," \
1463       -e "s,@INIT_LOAD_LIBRARY@,false," \
1464       -e "s,@@,$LIBGCJDEBUG," \
1465       -e "s,@default_toolkit@,$TOOLKIT," \
1466       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1467       -e "s,@GTK_CAIRO_ENABLED@,false," \
1468       -e "s,@ECJ_JAR@,," \
1469       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1470         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1471         > gnu/classpath/Configuration.java
1472   # We do not want to redirect the output of the grep below to /dev/null,
1473   # but we add /dev/null to the input list so that grep will print the
1474   # filename of Configuration.java in case it finds any matches.
1475   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1476     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1477   fi
1478 fi
1479
1480 LT_AC_PROG_GCJ
1481
1482 # Now remove it.
1483 rm -f gnu/classpath/Configuration.java
1484
1485 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1486
1487 AC_CHECK_SIZEOF(void *)
1488
1489 AC_C_BIGENDIAN
1490
1491 ZLIBS=
1492 SYS_ZLIBS=
1493 ZINCS=
1494
1495 if test -z "$ZLIBSPEC"; then
1496    # Use zlib from the GCC tree.
1497    ZINCS='-I$(top_srcdir)/../zlib'
1498    ZLIBS=../zlib/libzgcj_convenience.la
1499 else
1500    # System's zlib.
1501    SYS_ZLIBS="$ZLIBSPEC"
1502 fi
1503 AC_SUBST(ZLIBS)
1504 AC_SUBST(SYS_ZLIBS)
1505 AC_SUBST(ZINCS)
1506 AC_SUBST(DIVIDESPEC)
1507 AC_SUBST(CHECKREFSPEC)
1508 AC_SUBST(EXCEPTIONSPEC)
1509 AC_SUBST(BACKTRACESPEC)
1510 AC_SUBST(IEEESPEC)
1511 AC_SUBST(ATOMICSPEC)
1512
1513 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1514 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1515 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1516 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1517 AC_SUBST(GCC_UNWIND_INCLUDE)
1518
1519 # Process the option "--enable-version-specific-runtime-libs"
1520 # Calculate toolexeclibdir
1521 case ${version_specific_libs} in
1522   yes)
1523     # Need the gcc compiler version to know where to install libraries
1524     # and header files if --enable-version-specific-runtime-libs option
1525     # is selected.
1526     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1527     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1528     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1529     toolexeclibdir=$toolexecmainlibdir
1530     ;;
1531   no)
1532     if test -n "$with_cross_host" &&
1533        test x"$with_cross_host" != x"no"; then
1534       # Install a library built with a cross compiler in tooldir, not libdir.
1535       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1536       toolexecmainlibdir='$(toolexecdir)/lib'
1537     else
1538       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1539       toolexecmainlibdir='$(libdir)'
1540     fi
1541     multi_os_directory=`$CC -print-multi-os-directory`
1542     case $multi_os_directory in
1543       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1544       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1545     esac
1546     ;;
1547 esac
1548 AC_SUBST(toolexecdir)
1549 AC_SUBST(toolexecmainlibdir)
1550 AC_SUBST(toolexeclibdir)
1551
1552 # Determine gcj and libgcj version number.
1553 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1554 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1555 GCJVERSION=$gcjversion
1556 AC_SUBST(GCJVERSION)
1557 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1558
1559 # Determine where the standard .db file and GNU Classpath JNI
1560 # libraries are found.
1561 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1562 multi_os_directory=`$CC -print-multi-os-directory`
1563 case $multi_os_directory in
1564   .)
1565    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1566    ;;
1567   *)
1568    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1569    ;;
1570 esac
1571 AC_SUBST(dbexecdir)
1572 AC_SUBST(gcjsubdir)
1573
1574 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1575 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1576
1577 TL_AC_GXX_INCLUDE_DIR
1578
1579 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1580 # On that system, sys/ioctl.h will not include sys/filio.h unless
1581 # BSD_COMP is defined; just including sys/filio.h is simpler.
1582 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1583 # for now.  If you change this, you also must update natFile.cc.
1584 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1585                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1586                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1587                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1588                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1589
1590 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1591 AC_CHECK_HEADERS(net/if.h, [], [], [
1592 #ifdef HAVE_SYS_SOCKET_H
1593 #include <sys/socket.h>
1594 #endif
1595 ])
1596
1597 AC_CHECK_HEADERS(inttypes.h, [
1598     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1599     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1600 ])
1601
1602 AC_CHECK_TYPE([ssize_t], [int])
1603 AC_CHECK_TYPE([magic_t], [
1604     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1605 #ifdef HAVE_MAGIC_H
1606 #include <magic.h>
1607 #endif])
1608
1609 AC_MSG_CHECKING([for in_addr_t])
1610 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1611 #if STDC_HEADERS
1612 #include <stdlib.h>
1613 #include <stddef.h>
1614 #endif
1615 #if HAVE_NETINET_IN_H
1616 #include <netinet/in.h>
1617 #endif]], [[in_addr_t foo;]])],
1618   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1619      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1620    AC_MSG_RESULT(yes)],
1621   [AC_MSG_RESULT(no)])
1622
1623 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1624 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1625   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1626      [Define if struct ip_mreq is defined in netinet/in.h.])
1627    AC_MSG_RESULT(yes)],
1628   [AC_MSG_RESULT(no)])
1629
1630 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1631 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1632   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1633      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1634    AC_MSG_RESULT(yes)],
1635   [AC_MSG_RESULT(no)])
1636
1637 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1638 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1639   [AC_DEFINE(HAVE_INET6, 1,
1640      [Define if inet6 structures are defined in netinet/in.h.])
1641    AC_MSG_RESULT(yes)],
1642   [AC_MSG_RESULT(no)])
1643
1644 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1645 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1646 #include <sys/types.h>
1647 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1648   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1649    AC_MSG_RESULT(yes)],
1650   [AC_MSG_RESULT(no)])
1651
1652 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1653 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1654   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1655    AC_MSG_RESULT(yes)],
1656   [AC_MSG_RESULT(no)
1657    AC_MSG_CHECKING([for global timezone variable])
1658    dnl FIXME: we don't want a link check here because that won't work
1659    dnl when cross-compiling.  So instead we make an assumption that
1660    dnl the header file will mention timezone if it exists.
1661    dnl Don't find the win32 function timezone
1662    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1663      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1664       AC_MSG_RESULT(yes)],
1665      [AC_MSG_RESULT(no)
1666        AC_MSG_CHECKING([for global _timezone variable])
1667        dnl FIXME: As above, don't want link check
1668        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1669          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1670             [Define if your platform has the global _timezone variable.])
1671           AC_MSG_RESULT(yes)],
1672           [AC_MSG_RESULT(no)])])])
1673
1674 AC_CHECK_PROGS(PERL, perl, false)
1675
1676 SYSDEP_SOURCES=
1677 SIGNAL_HANDLER_AUX=
1678
1679 case "${host}" in
1680  i?86-*-linux*)
1681     SIGNAL_HANDLER=include/i386-signal.h
1682     ;;
1683  sparc*-sun-solaris*)
1684     SIGNAL_HANDLER=include/sparc-signal.h
1685     ;;
1686 # ia64-*)
1687 #    SYSDEP_SOURCES=sysdep/ia64.c
1688 #    test -d sysdep || mkdir sysdep
1689 #    ;;
1690  hppa*-*-linux*)
1691     SIGNAL_HANDLER=include/pa-signal.h
1692     ;;
1693  hppa*-hp-hpux*)
1694     SIGNAL_HANDLER=include/hppa-signal.h
1695     ;;
1696  ia64-*-linux*)
1697     SIGNAL_HANDLER=include/dwarf2-signal.h
1698     ;;
1699  powerpc*-*-linux*)
1700     SIGNAL_HANDLER=include/powerpc-signal.h
1701     ;;
1702  alpha*-*-linux*)
1703     SIGNAL_HANDLER=include/dwarf2-signal.h
1704     ;;
1705  s390*-*-linux*)
1706     SIGNAL_HANDLER=include/s390-signal.h
1707     ;;
1708  x86_64*-*-linux*)
1709     SIGNAL_HANDLER=include/x86_64-signal.h
1710     SIGNAL_HANDLER_AUX=include/i386-signal.h
1711     ;;
1712  sparc*-*-linux*)
1713     SIGNAL_HANDLER=include/dwarf2-signal.h
1714     ;;
1715  sh*-*-linux*)
1716     SIGNAL_HANDLER=include/sh-signal.h
1717     ;;
1718  *mingw*)
1719     SIGNAL_HANDLER=include/win32-signal.h
1720     ;;
1721  mips*-*-linux*)
1722     SIGNAL_HANDLER=include/mips-signal.h
1723     ;;
1724  m68*-*-linux*)
1725     SIGNAL_HANDLER=include/dwarf2-signal.h
1726     ;;
1727  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1728     SIGNAL_HANDLER=include/darwin-signal.h
1729     ;;
1730  powerpc*-*-aix*)
1731     SIGNAL_HANDLER=include/aix-signal.h
1732     ;;
1733  *)
1734     SIGNAL_HANDLER=include/default-signal.h
1735     ;;
1736 esac
1737
1738 # If we're using sjlj exceptions, forget what we just learned.
1739 if test "$enable_sjlj_exceptions" = yes; then
1740    SIGNAL_HANDLER=include/default-signal.h
1741    SIGNAL_HANDLER_AUX=
1742 fi
1743
1744 AC_SUBST(SYSDEP_SOURCES)
1745
1746 if test -z "$SIGNAL_HANDLER_AUX"; then
1747   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1748 fi
1749
1750 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1751                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1752
1753 if test "${multilib}" = "yes"; then
1754   multilib_arg="--enable-multilib"
1755 else
1756   multilib_arg=
1757 fi
1758
1759 # See if we support thread-local storage.
1760 GCC_CHECK_TLS
1761
1762 # For _Unwind_GetIPInfo.
1763 GCC_CHECK_UNWIND_GETIPINFO
1764
1765 # See if linker supports anonymous version scripts.
1766 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1767   [libjava_cv_anon_version_script],
1768   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1769    libjava_cv_anon_version_script=no
1770    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1771    echo '{ global: globalsymb*; local: *; };' > conftest.map
1772    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1773                [libjava_cv_anon_version_script=yes], [])
1774    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1775   ])
1776 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1777
1778 # Check if linker supports static linking on a per library basis
1779 LD_START_STATIC_SPEC=
1780 LD_FINISH_STATIC_SPEC=
1781 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1782   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1783     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1784     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1785   fi
1786 fi
1787 AC_SUBST(LD_START_STATIC_SPEC)
1788 AC_SUBST(LD_FINISH_STATIC_SPEC)
1789
1790 here=`${PWDCMD-pwd}`
1791 AC_SUBST(here)
1792
1793 # We get this from the environment.
1794 AC_SUBST(GCJFLAGS)
1795
1796 AC_ARG_WITH([python-dir],
1797             AS_HELP_STRING([--with-python-dir],
1798                            [the location to install Python modules. This path should NOT include the prefix.]),
1799             [with_python_dir=$withval], [with_python_dir=""])
1800
1801 if test "x${with_python_dir}" = "x"
1802 then
1803   # Needed for installing Python modules during make install.
1804   python_mod_dir="\${prefix}/share/python"
1805   # Needed for substituting into aot-compile*
1806   python_mod_dir_expanded="${expanded_prefix}/share/python"
1807 else
1808   python_mod_dir="\${prefix}${with_python_dir}"
1809   python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1810 fi
1811 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1812 AC_SUBST(python_mod_dir)
1813 AC_SUBST(python_mod_dir_expanded)
1814
1815 # needed for aot-compile-rpm
1816 MAKE=`which make`
1817 AC_SUBST(MAKE)
1818
1819 AC_ARG_ENABLE([aot-compile-rpm],
1820   [AS_HELP_STRING([--enable-aot-compile-rpm],
1821                  [enable installation of aot-compile-rpm [default=no]])],
1822   [case "${enableval}" in
1823     yes) AOT_RPM_ENABLED=yes ;;
1824     no)  AOT_RPM_ENABLED=no ;;
1825     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1826   esac],
1827   [AOT_RPM_ENABLED=no]
1828 )
1829 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1830
1831 AC_ARG_ENABLE([java-home],
1832   [AS_HELP_STRING([--enable-java-home],
1833                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1834   [case "${enableval}" in
1835     yes) JAVA_HOME_ENABLED=yes ;;
1836     no)  JAVA_HOME_ENABLED=no ;;
1837     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1838   esac],
1839   [JAVA_HOME_ENABLED=no]
1840 )
1841 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1842
1843 # Only do these checks if java-home above is enabled.
1844 if test "x${JAVA_HOME_ENABLED}" = xyes
1845 then
1846
1847   AC_ARG_WITH([gcc-suffix],
1848               AS_HELP_STRING([--with-gcc-suffix],
1849                              [the GCC tool suffix (defaults to empty string)]),
1850               [gcc_suffix=$withval], [gcc_suffix=""])
1851   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1852   AC_SUBST(gcc_suffix)
1853
1854   AC_ARG_WITH([arch-directory],
1855               AS_HELP_STRING([--with-arch-directory],
1856                              [the arch directory under jre/lib (defaults to auto-detect)]),
1857               [host_cpu=$withval], [host_cpu=""])
1858
1859   AC_ARG_WITH([os-directory],
1860               AS_HELP_STRING([--with-os-directory],
1861                              [the os directory under include (defaults to auto-detect)]),
1862               [host_os=$withval], [host_os=""])
1863
1864   AC_ARG_WITH([origin-name],
1865               AS_HELP_STRING([--with-origin-name],
1866                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1867               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1868   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1869
1870   AC_ARG_WITH([arch-suffix],
1871               AS_HELP_STRING([--with-arch-suffix],
1872                              [the arch directory suffix (default is the empty string]),
1873               [arch_suffix=$withval], [arch_suffix=""])
1874   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1875
1876   AC_ARG_WITH([jvm-root-dir],
1877               AS_HELP_STRING([--with-jvm-root-dir],
1878                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1879               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1880   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1881
1882   AC_ARG_WITH([jvm-jar-dir],
1883               AS_HELP_STRING([--with-jvm-jar-dir],
1884                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1885               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1886   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1887
1888   JAVA_VERSION=1.5.0
1889   BUILD_VERSION=0
1890   AC_SUBST(JAVA_VERSION)
1891   AC_SUBST(BUILD_VERSION)
1892   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1893
1894   jre_dir=jre
1895   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1896   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1897
1898   JVM_ROOT_DIR=${jvm_root_dir}
1899   AC_SUBST(JVM_ROOT_DIR)
1900   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1901
1902   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1903   AC_SUBST(JVM_JAR_ROOT_DIR)
1904   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1905
1906   JVM_JAR_DIR=${jvm_jar_dir}
1907   AC_SUBST(JVM_JAR_DIR)
1908   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1909
1910   JRE_DIR=${jre_dir}
1911   AC_SUBST(JRE_DIR)
1912
1913   JRE_LNK=${jre_lnk}
1914   AC_SUBST(JRE_LNK)
1915
1916   SDK_LNK=${sdk_lnk}
1917   AC_SUBST(SDK_LNK)
1918
1919   SDK_BIN_DIR=${jvm_root_dir}/bin
1920   AC_SUBST(SDK_BIN_DIR)
1921   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1922
1923   SDK_LIB_DIR=${jvm_root_dir}/lib
1924   AC_SUBST(SDK_LIB_DIR)
1925   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1926
1927   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1928   AC_SUBST(SDK_INCLUDE_DIR)
1929   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1930
1931   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1932   AC_SUBST(JRE_BIN_DIR)
1933   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1934
1935   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1936   AC_SUBST(JRE_LIB_DIR)
1937   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1938
1939   # Find gcj prefix using gcj found in PATH.
1940   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1941
1942   # Where do the gcj binaries live?
1943   # For jhbuild based builds, they all live in a sibling of bin called
1944   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1945   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1946   AC_SUBST(GCJ_BIN_DIR)
1947   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1948
1949   AC_MSG_RESULT(host is ${host})
1950   if test "x${host_cpu}" = "x"
1951   then
1952     case ${host} in
1953       *-mingw* | *-cygwin*)
1954         host_cpu=x86;;
1955       i486-* | i586-* | i686-*)
1956         host_cpu=i386;;
1957       x86_64-*)
1958         host_cpu=amd64;;
1959       *)
1960         host_cpu=${host_cpu};;
1961     esac
1962   fi
1963   AC_MSG_RESULT(arch directory: ${host_cpu})
1964   CPU=${host_cpu}
1965   AC_SUBST(CPU)
1966
1967   if test "x${host_os}" = "x"
1968   then
1969     case ${host} in
1970       *-mingw* | *-cygwin*)
1971         host_os=win32;;
1972       *-linux*)
1973         host_os=linux;;
1974       *)
1975         host_os=${host_os};;
1976     esac
1977   fi
1978   echo os directory: ${host_os}
1979   OS=${host_os}
1980   AC_SUBST(OS)
1981
1982   # make an expanded $libdir, for substituting into
1983   # scripts (and other non-Makefile things).
1984   LIBDIR=$libdir
1985   if test "x${exec_prefix}" = "xNONE"
1986   then
1987       lib_exec_prefix=$expanded_prefix
1988   else
1989       lib_exec_prefix=$exec_prefix
1990   fi
1991   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1992   AC_SUBST(LIBDIR)
1993 fi
1994
1995 AC_CONFIG_FILES([
1996 Makefile
1997 libgcj.pc
1998 libgcj.spec
1999 libgcj-test.spec
2000 gcj/Makefile
2001 include/Makefile
2002 testsuite/Makefile
2003 contrib/aotcompile.py
2004 contrib/aot-compile
2005 contrib/aot-compile-rpm
2006 contrib/generate-cacerts.pl
2007 contrib/rebuild-gcj-db
2008 ])
2009
2010 if test ${multilib} = yes; then
2011   multilib_arg="--enable-multilib"
2012 else
2013   multilib_arg=
2014 fi
2015
2016 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2017 AC_OUTPUT